FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Try::Tiny;
  24 use Scalar::Util qw( blessed );
  25 use List::Util qw(min);
  26 use Tie::IxHash;
  27 use File::Temp; #qw( tempfile );
  28 use Data::Dumper;
  29 use Time::Local qw(timelocal);
  30 use Date::Format;
  31 #use Date::Manip;
  32 use Email::Address;
  33 use Business::CreditCard 0.28;
  34 use FS::UID qw( dbh driver_name );
  35 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  36 use FS::Cursor;
  37 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  38 use FS::Msgcat qw(gettext);
  39 use FS::CurrentUser;
  40 use FS::TicketSystem;
  41 use FS::payby;
  42 use FS::cust_pkg;
  43 use FS::cust_svc;
  44 use FS::cust_bill;
  45 use FS::cust_bill_void;
  46 use FS::legacy_cust_bill;
  47 use FS::cust_pay;
  48 use FS::cust_pay_pending;
  49 use FS::cust_pay_void;
  50 use FS::cust_pay_batch;
  51 use FS::cust_credit;
  52 use FS::cust_refund;
  53 use FS::part_referral;
  54 use FS::cust_main_county;
  55 use FS::cust_location;
  56 use FS::cust_class;
  57 use FS::tax_status;
  58 use FS::cust_main_exemption;
  59 use FS::cust_tax_adjustment;
  60 use FS::cust_tax_location;
  61 use FS::agent_currency;
  62 use FS::cust_main_invoice;
  63 use FS::cust_tag;
  64 use FS::prepay_credit;
  65 use FS::queue;
  66 use FS::part_pkg;
  67 use FS::part_export;
  68 #use FS::cust_event;
  69 use FS::type_pkgs;
  70 use FS::payment_gateway;
  71 use FS::agent_payment_gateway;
  72 use FS::banned_pay;
  73 use FS::cust_main_note;
  74 use FS::cust_attachment;
  75 use FS::cust_contact;
  76 use FS::Locales;
  77 use FS::upgrade_journal;
  78 use FS::sales;
  79 use FS::cust_payby;
  80 use FS::contact;
  81 use FS::reason;
  82
  83 # 1 is mostly method/subroutine entry and options
  84 # 2 traces progress of some operations
  85 # 3 is even more information including possibly sensitive data
  86 our $DEBUG = 0;
  87 our $me = '[FS::cust_main]';
  88
  89 our $import = 0;
  90 our $ignore_expired_card = 0;
  91 our $ignore_banned_card = 0;
  92 our $ignore_invalid_card = 0;
  93
  94 our $skip_fuzzyfiles = 0;
  95
  96 our $ucfirst_nowarn = 0;
  97
  98 #this info is in cust_payby as of 4.x
  99 #this and the fields themselves can be removed in 5.x
 100 our @encrypted_fields = ('payinfo', 'paycvv');
 101 sub nohistory_fields { ('payinfo', 'paycvv'); }
 102
 103 our $conf;
 104 our $default_agent_custid;
 105 our $custnum_display_length;
 106 #ask FS::UID to run this stuff for us later
 107 #$FS::UID::callback{'FS::cust_main'} = sub {
 108 install_callback FS::UID sub {
 109   $conf = new FS::Conf;
 110   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 111   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 112   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 113 };
 114
 115 sub _cache {
 116   my $self = shift;
 117   my ( $hashref, $cache ) = @_;
 118   if ( exists $hashref->{'pkgnum'} ) {
 119     #@{ $self->{'_pkgnum'} } = ();
 120     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 121     $self->{'_pkgnum'} = $subcache;
 122     #push @{ $self->{'_pkgnum'} },
 123     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 124   }
 125 }
 126
 127 =head1 NAME
 128
 129 FS::cust_main - Object methods for cust_main records
 130
 131 =head1 SYNOPSIS
 132
 133   use FS::cust_main;
 134
 135   $record = new FS::cust_main \%hash;
 136   $record = new FS::cust_main { 'column' => 'value' };
 137
 138   $error = $record->insert;
 139
 140   $error = $new_record->replace($old_record);
 141
 142   $error = $record->delete;
 143
 144   $error = $record->check;
 145
 146   @cust_pkg = $record->all_pkgs;
 147
 148   @cust_pkg = $record->ncancelled_pkgs;
 149
 150   @cust_pkg = $record->suspended_pkgs;
 151
 152   $error = $record->bill;
 153   $error = $record->bill %options;
 154   $error = $record->bill 'time' => $time;
 155
 156   $error = $record->collect;
 157   $error = $record->collect %options;
 158   $error = $record->collect 'invoice_time'   => $time,
 159                           ;
 160
 161 =head1 DESCRIPTION
 162
 163 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 164 FS::Record.  The following fields are currently supported:
 165
 166 =over 4
 167
 168 =item custnum
 169
 170 Primary key (assigned automatically for new customers)
 171
 172 =item agentnum
 173
 174 Agent (see L<FS::agent>)
 175
 176 =item refnum
 177
 178 Advertising source (see L<FS::part_referral>)
 179
 180 =item first
 181
 182 First name
 183
 184 =item last
 185
 186 Last name
 187
 188 =item ss
 189
 190 Cocial security number (optional)
 191
 192 =item company
 193
 194 (optional)
 195
 196 =item daytime
 197
 198 phone (optional)
 199
 200 =item night
 201
 202 phone (optional)
 203
 204 =item fax
 205
 206 phone (optional)
 207
 208 =item mobile
 209
 210 phone (optional)
 211
 212 =item payby
 213
 214 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 215
 216 =item payinfo
 217
 218 Payment Information (See L<FS::payinfo_Mixin> for data format)
 219
 220 =item paymask
 221
 222 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 223
 224 =item paycvv
 225
 226 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 227
 228 =item paydate
 229
 230 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 231
 232 =item paystart_month
 233
 234 Start date month (maestro/solo cards only)
 235
 236 =item paystart_year
 237
 238 Start date year (maestro/solo cards only)
 239
 240 =item payissue
 241
 242 Issue number (maestro/solo cards only)
 243
 244 =item payname
 245
 246 Name on card or billing name
 247
 248 =item payip
 249
 250 IP address from which payment information was received
 251
 252 =item tax
 253
 254 Tax exempt, empty or `Y'
 255
 256 =item usernum
 257
 258 Order taker (see L<FS::access_user>)
 259
 260 =item comments
 261
 262 Comments (optional)
 263
 264 =item referral_custnum
 265
 266 Referring customer number
 267
 268 =item spool_cdr
 269
 270 Enable individual CDR spooling, empty or `Y'
 271
 272 =item dundate
 273
 274 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 275
 276 =item squelch_cdr
 277
 278 Discourage individual CDR printing, empty or `Y'
 279
 280 =item edit_subject
 281
 282 Allow self-service editing of ticket subjects, empty or 'Y'
 283
 284 =item calling_list_exempt
 285
 286 Do not call, empty or 'Y'
 287
 288 =item invoice_ship_address
 289
 290 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 291
 292 =back
 293
 294 =head1 METHODS
 295
 296 =over 4
 297
 298 =item new HASHREF
 299
 300 Creates a new customer.  To add the customer to the database, see L<"insert">.
 301
 302 Note that this stores the hash reference, not a distinct copy of the hash it
 303 points to.  You can ask the object for a copy with the I<hash> method.
 304
 305 =cut
 306
 307 sub table { 'cust_main'; }
 308
 309 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 310
 311 Adds this customer to the database.  If there is an error, returns the error,
 312 otherwise returns false.
 313
 314 Usually the customer's location will not yet exist in the database, and
 315 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 316 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 317 (in both directions) to the new customer record.  If they're references
 318 to the same object, they will become the same location.
 319
 320 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 321 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 322 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 323 hash reference is equivalent to not supplying this parameter.  There should be
 324 a better explanation of this, but until then, here's an example:
 325
 326   use Tie::RefHash;
 327   tie %hash, 'Tie::RefHash'; #this part is important
 328   %hash = (
 329     $cust_pkg => [ $svc_acct ],
 330     ...
 331   );
 332   $cust_main->insert( \%hash );
 333
 334 INVOICING_LIST_ARYREF: No longer supported.
 335
 336 Currently available options are: I<depend_jobnum>, I<noexport>,
 337 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 338
 339 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 340 on the supplied jobnum (they will not run until the specific job completes).
 341 This can be used to defer provisioning until some action completes (such
 342 as running the customer's credit card successfully).
 343
 344 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 345 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 346 the B<reexport> method.)
 347
 348 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 349 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 350 created and inserted.
 351
 352 If I<prospectnum> is set, moves contacts and locations from that prospect.
 353
 354 If I<contact> is set to an arrayref of FS::contact objects, those will be
 355 inserted.
 356
 357 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 358 unset), inserts those new contacts with this new customer.  Handles CGI
 359 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 360
 361 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 362 new stored payment records with this new customer.  Handles CGI parameters
 363 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 364
 365 =cut
 366
 367 sub insert {
 368   my $self = shift;
 369   my $cust_pkgs = @_ ? shift : {};
 370   my $invoicing_list;
 371   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 372     warn "cust_main::insert using deprecated invoicing list argument";
 373     $invoicing_list = shift;
 374   }
 375   my %options = @_;
 376   warn "$me insert called with options ".
 377        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 378     if $DEBUG;
 379
 380   local $SIG{HUP} = 'IGNORE';
 381   local $SIG{INT} = 'IGNORE';
 382   local $SIG{QUIT} = 'IGNORE';
 383   local $SIG{TERM} = 'IGNORE';
 384   local $SIG{TSTP} = 'IGNORE';
 385   local $SIG{PIPE} = 'IGNORE';
 386
 387   my $oldAutoCommit = $FS::UID::AutoCommit;
 388   local $FS::UID::AutoCommit = 0;
 389   my $dbh = dbh;
 390
 391   my $prepay_identifier = '';
 392   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 393   my $payby = '';
 394   if ( $self->payby eq 'PREPAY' ) {
 395
 396     $self->payby(''); #'BILL');
 397     $prepay_identifier = $self->payinfo;
 398     $self->payinfo('');
 399
 400     warn "  looking up prepaid card $prepay_identifier\n"
 401       if $DEBUG > 1;
 402
 403     my $error = $self->get_prepay( $prepay_identifier,
 404                                    'amount_ref'     => \$amount,
 405                                    'seconds_ref'    => \$seconds,
 406                                    'upbytes_ref'    => \$upbytes,
 407                                    'downbytes_ref'  => \$downbytes,
 408                                    'totalbytes_ref' => \$totalbytes,
 409                                  );
 410     if ( $error ) {
 411       $dbh->rollback if $oldAutoCommit;
 412       #return "error applying prepaid card (transaction rolled back): $error";
 413       return $error;
 414     }
 415
 416     $payby = 'PREP' if $amount;
 417
 418   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 419
 420     $payby = $1;
 421     $self->payby(''); #'BILL');
 422     $amount = $self->paid;
 423
 424   }
 425
 426   # insert locations
 427   foreach my $l (qw(bill_location ship_location)) {
 428
 429     my $loc = delete $self->hashref->{$l} or next;
 430
 431     if ( !$loc->locationnum ) {
 432       # warn the location that we're going to insert it with no custnum
 433       $loc->set(custnum_pending => 1);
 434       warn "  inserting $l\n"
 435         if $DEBUG > 1;
 436       my $error = $loc->insert;
 437       if ( $error ) {
 438         $dbh->rollback if $oldAutoCommit;
 439         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 440         return "$error (in $label location)";
 441       }
 442
 443     } elsif ( $loc->prospectnum ) {
 444
 445       $loc->prospectnum('');
 446       $loc->set(custnum_pending => 1);
 447       my $error = $loc->replace;
 448       if ( $error ) {
 449         $dbh->rollback if $oldAutoCommit;
 450         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 451         return "$error (moving $label location)";
 452       }
 453
 454     } elsif ( ($loc->custnum || 0) > 0 ) {
 455       # then it somehow belongs to another customer--shouldn't happen
 456       $dbh->rollback if $oldAutoCommit;
 457       return "$l belongs to customer ".$loc->custnum;
 458     }
 459     # else it already belongs to this customer
 460     # (happens when ship_location is identical to bill_location)
 461
 462     $self->set($l.'num', $loc->locationnum);
 463
 464     if ( $self->get($l.'num') eq '' ) {
 465       $dbh->rollback if $oldAutoCommit;
 466       return "$l not set";
 467     }
 468   }
 469
 470   warn "  inserting $self\n"
 471     if $DEBUG > 1;
 472
 473   $self->signupdate(time) unless $self->signupdate;
 474
 475   $self->auto_agent_custid()
 476     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 477
 478   my $error =  $self->check_payinfo_cardtype
 479             || $self->SUPER::insert;
 480   if ( $error ) {
 481     $dbh->rollback if $oldAutoCommit;
 482     #return "inserting cust_main record (transaction rolled back): $error";
 483     return $error;
 484   }
 485
 486   # now set cust_location.custnum
 487   foreach my $l (qw(bill_location ship_location)) {
 488     warn "  setting $l.custnum\n"
 489       if $DEBUG > 1;
 490     my $loc = $self->$l or next;
 491     unless ( $loc->custnum ) {
 492       $loc->set(custnum => $self->custnum);
 493       $error ||= $loc->replace;
 494     }
 495
 496     if ( $error ) {
 497       $dbh->rollback if $oldAutoCommit;
 498       return "error setting $l custnum: $error";
 499     }
 500   }
 501
 502   warn "  setting customer tags\n"
 503     if $DEBUG > 1;
 504
 505   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 506     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 507                                       'custnum' => $self->custnum };
 508     my $error = $cust_tag->insert;
 509     if ( $error ) {
 510       $dbh->rollback if $oldAutoCommit;
 511       return $error;
 512     }
 513   }
 514
 515   my $prospectnum = delete $options{'prospectnum'};
 516   if ( $prospectnum ) {
 517
 518     warn "  moving contacts and locations from prospect $prospectnum\n"
 519       if $DEBUG > 1;
 520
 521     my $prospect_main =
 522       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 523     unless ( $prospect_main ) {
 524       $dbh->rollback if $oldAutoCommit;
 525       return "Unknown prospectnum $prospectnum";
 526     }
 527     $prospect_main->custnum($self->custnum);
 528     $prospect_main->disabled('Y');
 529     my $error = $prospect_main->replace;
 530     if ( $error ) {
 531       $dbh->rollback if $oldAutoCommit;
 532       return $error;
 533     }
 534
 535     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 536       my $cust_contact = new FS::cust_contact {
 537         'custnum' => $self->custnum,
 538         'invoice_dest' => 'Y', # invoice_dest currently not set for prospect contacts
 539         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 540       };
 541       my $error =  $cust_contact->insert
 542                 || $prospect_contact->delete;
 543       if ( $error ) {
 544         $dbh->rollback if $oldAutoCommit;
 545         return $error;
 546       }
 547     }
 548
 549     my @cust_location = $prospect_main->cust_location;
 550     my @qual = $prospect_main->qual;
 551
 552     foreach my $r ( @cust_location, @qual ) {
 553       $r->prospectnum('');
 554       $r->custnum($self->custnum);
 555       my $error = $r->replace;
 556       if ( $error ) {
 557         $dbh->rollback if $oldAutoCommit;
 558         return $error;
 559       }
 560     }
 561     # since we set invoice_dest on all migrated prospect contacts (for now),
 562     # don't process invoicing_list.
 563     delete $options{'invoicing_list'};
 564     $invoicing_list = undef;
 565   }
 566
 567   warn "  setting contacts\n"
 568     if $DEBUG > 1;
 569
 570   $invoicing_list ||= $options{'invoicing_list'};
 571   if ( $invoicing_list ) {
 572
 573     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 574
 575     my $email = '';
 576     foreach my $dest (@$invoicing_list ) {
 577       if ($dest eq 'POST') {
 578         $self->set('postal_invoice', 'Y');
 579       } else {
 580
 581         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 582         if ( $contact_email ) {
 583           my $cust_contact = FS::cust_contact->new({
 584               contactnum    => $contact_email->contactnum,
 585               custnum       => $self->custnum,
 586           });
 587           $cust_contact->set('invoice_dest', 'Y');
 588           my $error = $cust_contact->insert;
 589           if ( $error ) {
 590             $dbh->rollback if $oldAutoCommit;
 591             return "$error (linking to email address $dest)";
 592           }
 593
 594         } else {
 595           # this email address is not yet linked to any contact
 596           $email .= ',' if length($email);
 597           $email .= $dest;
 598         }
 599       }
 600     }
 601
 602     if ( $email ) {
 603
 604       my $contact = FS::contact->new({
 605         'custnum'       => $self->get('custnum'),
 606         'last'          => $self->get('last'),
 607         'first'         => $self->get('first'),
 608         'emailaddress'  => $email,
 609         'invoice_dest'  => 'Y', # yes, you can set this via the contact
 610       });
 611       my $error = $contact->insert;
 612       if ( $error ) {
 613         $dbh->rollback if $oldAutoCommit;
 614         return $error;
 615       }
 616
 617     }
 618
 619   }
 620
 621   if ( my $contact = delete $options{'contact'} ) {
 622
 623     foreach my $c ( @$contact ) {
 624       $c->custnum($self->custnum);
 625       my $error = $c->insert;
 626       if ( $error ) {
 627         $dbh->rollback if $oldAutoCommit;
 628         return $error;
 629       }
 630
 631     }
 632
 633   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 634
 635     my $error = $self->process_o2m( 'table'  => 'contact',
 636                                     'fields' => FS::contact->cgi_contact_fields,
 637                                     'params' => $contact_params,
 638                                   );
 639     if ( $error ) {
 640       $dbh->rollback if $oldAutoCommit;
 641       return $error;
 642     }
 643   }
 644
 645   warn "  setting cust_payby\n"
 646     if $DEBUG > 1;
 647
 648   if ( $options{cust_payby} ) {
 649
 650     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 651       $cust_payby->custnum($self->custnum);
 652       my $error = $cust_payby->insert;
 653       if ( $error ) {
 654         $dbh->rollback if $oldAutoCommit;
 655         return $error;
 656       }
 657     }
 658
 659   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 660
 661     my $error = $self->process_o2m(
 662       'table'         => 'cust_payby',
 663       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 664       'params'        => $cust_payby_params,
 665       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 666     );
 667     if ( $error ) {
 668       $dbh->rollback if $oldAutoCommit;
 669       return $error;
 670     }
 671
 672   }
 673
 674   warn "  setting cust_main_exemption\n"
 675     if $DEBUG > 1;
 676
 677   my $tax_exemption = delete $options{'tax_exemption'};
 678   if ( $tax_exemption ) {
 679
 680     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 681       if ref($tax_exemption) eq 'ARRAY';
 682
 683     foreach my $taxname ( keys %$tax_exemption ) {
 684       my $cust_main_exemption = new FS::cust_main_exemption {
 685         'custnum'       => $self->custnum,
 686         'taxname'       => $taxname,
 687         'exempt_number' => $tax_exemption->{$taxname},
 688       };
 689       my $error = $cust_main_exemption->insert;
 690       if ( $error ) {
 691         $dbh->rollback if $oldAutoCommit;
 692         return "inserting cust_main_exemption (transaction rolled back): $error";
 693       }
 694     }
 695   }
 696
 697   warn "  ordering packages\n"
 698     if $DEBUG > 1;
 699
 700   $error = $self->order_pkgs( $cust_pkgs,
 701                               %options,
 702                               'seconds_ref'    => \$seconds,
 703                               'upbytes_ref'    => \$upbytes,
 704                               'downbytes_ref'  => \$downbytes,
 705                               'totalbytes_ref' => \$totalbytes,
 706                             );
 707   if ( $error ) {
 708     $dbh->rollback if $oldAutoCommit;
 709     return $error;
 710   }
 711
 712   if ( $seconds ) {
 713     $dbh->rollback if $oldAutoCommit;
 714     return "No svc_acct record to apply pre-paid time";
 715   }
 716   if ( $upbytes || $downbytes || $totalbytes ) {
 717     $dbh->rollback if $oldAutoCommit;
 718     return "No svc_acct record to apply pre-paid data";
 719   }
 720
 721   if ( $amount ) {
 722     warn "  inserting initial $payby payment of $amount\n"
 723       if $DEBUG > 1;
 724     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 725     if ( $error ) {
 726       $dbh->rollback if $oldAutoCommit;
 727       return "inserting payment (transaction rolled back): $error";
 728     }
 729   }
 730
 731   unless ( $import || $skip_fuzzyfiles ) {
 732     warn "  queueing fuzzyfiles update\n"
 733       if $DEBUG > 1;
 734     $error = $self->queue_fuzzyfiles_update;
 735     if ( $error ) {
 736       $dbh->rollback if $oldAutoCommit;
 737       return "updating fuzzy search cache: $error";
 738     }
 739   }
 740
 741   # FS::geocode_Mixin::after_insert or something?
 742   if ( $conf->config('tax_district_method') and !$import ) {
 743     # if anything non-empty, try to look it up
 744     my $queue = new FS::queue {
 745       'job'     => 'FS::geocode_Mixin::process_district_update',
 746       'custnum' => $self->custnum,
 747     };
 748     my $error = $queue->insert( ref($self), $self->custnum );
 749     if ( $error ) {
 750       $dbh->rollback if $oldAutoCommit;
 751       return "queueing tax district update: $error";
 752     }
 753   }
 754
 755   # cust_main exports!
 756   warn "  exporting\n" if $DEBUG > 1;
 757
 758   my $export_args = $options{'export_args'} || [];
 759
 760   my @part_export =
 761     map qsearch( 'part_export', {exportnum=>$_} ),
 762       $conf->config('cust_main-exports'); #, $agentnum
 763
 764   foreach my $part_export ( @part_export ) {
 765     my $error = $part_export->export_insert($self, @$export_args);
 766     if ( $error ) {
 767       $dbh->rollback if $oldAutoCommit;
 768       return "exporting to ". $part_export->exporttype.
 769              " (transaction rolled back): $error";
 770     }
 771   }
 772
 773   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 774   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 775   #      if $DEBUG;
 776   #    foreach my $jobnum ( @jobnums ) {
 777   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 778   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 779   #        if $DEBUG;
 780   #      my $error = $queue->depend_insert($depend_jobnum);
 781   #      if ( $error ) {
 782   #        $dbh->rollback if $oldAutoCommit;
 783   #        return "error queuing job dependancy: $error";
 784   #      }
 785   #    }
 786   #  }
 787   #
 788   #}
 789   #
 790   #if ( exists $options{'jobnums'} ) {
 791   #  push @{ $options{'jobnums'} }, @jobnums;
 792   #}
 793
 794   warn "  insert complete; committing transaction\n"
 795     if $DEBUG > 1;
 796
 797   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 798   '';
 799
 800 }
 801
 802 use File::CounterFile;
 803 sub auto_agent_custid {
 804   my $self = shift;
 805
 806   my $format = $conf->config('cust_main-auto_agent_custid');
 807   my $agent_custid;
 808   if ( $format eq '1YMMXXXXXXXX' ) {
 809
 810     my $counter = new File::CounterFile 'cust_main.agent_custid';
 811     $counter->lock;
 812
 813     my $ym = 100000000000 + time2str('%y%m00000000', time);
 814     if ( $ym > $counter->value ) {
 815       $counter->{'value'} = $agent_custid = $ym;
 816       $counter->{'updated'} = 1;
 817     } else {
 818       $agent_custid = $counter->inc;
 819     }
 820
 821     $counter->unlock;
 822
 823   } else {
 824     die "Unknown cust_main-auto_agent_custid format: $format";
 825   }
 826
 827   $self->agent_custid($agent_custid);
 828
 829 }
 830
 831 =item PACKAGE METHODS
 832
 833 Documentation on customer package methods has been moved to
 834 L<FS::cust_main::Packages>.
 835
 836 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 837
 838 Recharges this (existing) customer with the specified prepaid card (see
 839 L<FS::prepay_credit>), specified either by I<identifier> or as an
 840 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 841 returns false.
 842
 843 Optionally, five scalar references can be passed as well.  They will have their
 844 values filled in with the amount, number of seconds, and number of upload,
 845 download, and total bytes applied by this prepaid card.
 846
 847 =cut
 848
 849 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 850 #the only place that uses these args
 851 sub recharge_prepay {
 852   my( $self, $prepay_credit, $amountref, $secondsref,
 853       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 854
 855   local $SIG{HUP} = 'IGNORE';
 856   local $SIG{INT} = 'IGNORE';
 857   local $SIG{QUIT} = 'IGNORE';
 858   local $SIG{TERM} = 'IGNORE';
 859   local $SIG{TSTP} = 'IGNORE';
 860   local $SIG{PIPE} = 'IGNORE';
 861
 862   my $oldAutoCommit = $FS::UID::AutoCommit;
 863   local $FS::UID::AutoCommit = 0;
 864   my $dbh = dbh;
 865
 866   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 867
 868   my $error = $self->get_prepay( $prepay_credit,
 869                                  'amount_ref'     => \$amount,
 870                                  'seconds_ref'    => \$seconds,
 871                                  'upbytes_ref'    => \$upbytes,
 872                                  'downbytes_ref'  => \$downbytes,
 873                                  'totalbytes_ref' => \$totalbytes,
 874                                )
 875            || $self->increment_seconds($seconds)
 876            || $self->increment_upbytes($upbytes)
 877            || $self->increment_downbytes($downbytes)
 878            || $self->increment_totalbytes($totalbytes)
 879            || $self->insert_cust_pay_prepay( $amount,
 880                                              ref($prepay_credit)
 881                                                ? $prepay_credit->identifier
 882                                                : $prepay_credit
 883                                            );
 884
 885   if ( $error ) {
 886     $dbh->rollback if $oldAutoCommit;
 887     return $error;
 888   }
 889
 890   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 891   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 892   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 893   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 894   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 895
 896   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 897   '';
 898
 899 }
 900
 901 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 902
 903 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 904 specified either by I<identifier> or as an FS::prepay_credit object.
 905
 906 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 907 incremented by the values of the prepaid card.
 908
 909 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 910 check or set this customer's I<agentnum>.
 911
 912 If there is an error, returns the error, otherwise returns false.
 913
 914 =cut
 915
 916
 917 sub get_prepay {
 918   my( $self, $prepay_credit, %opt ) = @_;
 919
 920   local $SIG{HUP} = 'IGNORE';
 921   local $SIG{INT} = 'IGNORE';
 922   local $SIG{QUIT} = 'IGNORE';
 923   local $SIG{TERM} = 'IGNORE';
 924   local $SIG{TSTP} = 'IGNORE';
 925   local $SIG{PIPE} = 'IGNORE';
 926
 927   my $oldAutoCommit = $FS::UID::AutoCommit;
 928   local $FS::UID::AutoCommit = 0;
 929   my $dbh = dbh;
 930
 931   unless ( ref($prepay_credit) ) {
 932
 933     my $identifier = $prepay_credit;
 934
 935     $prepay_credit = qsearchs(
 936       'prepay_credit',
 937       { 'identifier' => $identifier },
 938       '',
 939       'FOR UPDATE'
 940     );
 941
 942     unless ( $prepay_credit ) {
 943       $dbh->rollback if $oldAutoCommit;
 944       return "Invalid prepaid card: ". $identifier;
 945     }
 946
 947   }
 948
 949   if ( $prepay_credit->agentnum ) {
 950     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 951       $dbh->rollback if $oldAutoCommit;
 952       return "prepaid card not valid for agent ". $self->agentnum;
 953     }
 954     $self->agentnum($prepay_credit->agentnum);
 955   }
 956
 957   my $error = $prepay_credit->delete;
 958   if ( $error ) {
 959     $dbh->rollback if $oldAutoCommit;
 960     return "removing prepay_credit (transaction rolled back): $error";
 961   }
 962
 963   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 964     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 965
 966   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 967   '';
 968
 969 }
 970
 971 =item increment_upbytes SECONDS
 972
 973 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 974 the specified number of upbytes.  If there is an error, returns the error,
 975 otherwise returns false.
 976
 977 =cut
 978
 979 sub increment_upbytes {
 980   _increment_column( shift, 'upbytes', @_);
 981 }
 982
 983 =item increment_downbytes SECONDS
 984
 985 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 986 the specified number of downbytes.  If there is an error, returns the error,
 987 otherwise returns false.
 988
 989 =cut
 990
 991 sub increment_downbytes {
 992   _increment_column( shift, 'downbytes', @_);
 993 }
 994
 995 =item increment_totalbytes SECONDS
 996
 997 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 998 the specified number of totalbytes.  If there is an error, returns the error,
 999 otherwise returns false.
1000
1001 =cut
1002
1003 sub increment_totalbytes {
1004   _increment_column( shift, 'totalbytes', @_);
1005 }
1006
1007 =item increment_seconds SECONDS
1008
1009 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1010 the specified number of seconds.  If there is an error, returns the error,
1011 otherwise returns false.
1012
1013 =cut
1014
1015 sub increment_seconds {
1016   _increment_column( shift, 'seconds', @_);
1017 }
1018
1019 =item _increment_column AMOUNT
1020
1021 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1022 the specified number of seconds or bytes.  If there is an error, returns
1023 the error, otherwise returns false.
1024
1025 =cut
1026
1027 sub _increment_column {
1028   my( $self, $column, $amount ) = @_;
1029   warn "$me increment_column called: $column, $amount\n"
1030     if $DEBUG;
1031
1032   return '' unless $amount;
1033
1034   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1035                       $self->ncancelled_pkgs;
1036
1037   if ( ! @cust_pkg ) {
1038     return 'No packages with primary or single services found'.
1039            ' to apply pre-paid time';
1040   } elsif ( scalar(@cust_pkg) > 1 ) {
1041     #maybe have a way to specify the package/account?
1042     return 'Multiple packages found to apply pre-paid time';
1043   }
1044
1045   my $cust_pkg = $cust_pkg[0];
1046   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1047     if $DEBUG > 1;
1048
1049   my @cust_svc =
1050     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1051
1052   if ( ! @cust_svc ) {
1053     return 'No account found to apply pre-paid time';
1054   } elsif ( scalar(@cust_svc) > 1 ) {
1055     return 'Multiple accounts found to apply pre-paid time';
1056   }
1057
1058   my $svc_acct = $cust_svc[0]->svc_x;
1059   warn "  found service svcnum ". $svc_acct->pkgnum.
1060        ' ('. $svc_acct->email. ")\n"
1061     if $DEBUG > 1;
1062
1063   $column = "increment_$column";
1064   $svc_acct->$column($amount);
1065
1066 }
1067
1068 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1069
1070 Inserts a prepayment in the specified amount for this customer.  An optional
1071 second argument can specify the prepayment identifier for tracking purposes.
1072 If there is an error, returns the error, otherwise returns false.
1073
1074 =cut
1075
1076 sub insert_cust_pay_prepay {
1077   shift->insert_cust_pay('PREP', @_);
1078 }
1079
1080 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1081
1082 Inserts a cash payment in the specified amount for this customer.  An optional
1083 second argument can specify the payment identifier for tracking purposes.
1084 If there is an error, returns the error, otherwise returns false.
1085
1086 =cut
1087
1088 sub insert_cust_pay_cash {
1089   shift->insert_cust_pay('CASH', @_);
1090 }
1091
1092 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1093
1094 Inserts a Western Union payment in the specified amount for this customer.  An
1095 optional second argument can specify the prepayment identifier for tracking
1096 purposes.  If there is an error, returns the error, otherwise returns false.
1097
1098 =cut
1099
1100 sub insert_cust_pay_west {
1101   shift->insert_cust_pay('WEST', @_);
1102 }
1103
1104 sub insert_cust_pay {
1105   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1106   my $payinfo = scalar(@_) ? shift : '';
1107
1108   my $cust_pay = new FS::cust_pay {
1109     'custnum' => $self->custnum,
1110     'paid'    => sprintf('%.2f', $amount),
1111     #'_date'   => #date the prepaid card was purchased???
1112     'payby'   => $payby,
1113     'payinfo' => $payinfo,
1114   };
1115   $cust_pay->insert;
1116
1117 }
1118
1119 =item delete [ OPTION => VALUE ... ]
1120
1121 This deletes the customer.  If there is an error, returns the error, otherwise
1122 returns false.
1123
1124 This will completely remove all traces of the customer record.  This is not
1125 what you want when a customer cancels service; for that, cancel all of the
1126 customer's packages (see L</cancel>).
1127
1128 If the customer has any uncancelled packages, you need to pass a new (valid)
1129 customer number for those packages to be transferred to, as the "new_customer"
1130 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1131 what you want when a customer cancels service and that you really should be
1132 looking at L<FS::cust_pkg/cancel>?
1133
1134 You can't delete a customer with invoices (see L<FS::cust_bill>),
1135 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1136 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1137 set the "delete_financials" option to a true value.
1138
1139 =cut
1140
1141 sub delete {
1142   my( $self, %opt ) = @_;
1143
1144   local $SIG{HUP} = 'IGNORE';
1145   local $SIG{INT} = 'IGNORE';
1146   local $SIG{QUIT} = 'IGNORE';
1147   local $SIG{TERM} = 'IGNORE';
1148   local $SIG{TSTP} = 'IGNORE';
1149   local $SIG{PIPE} = 'IGNORE';
1150
1151   my $oldAutoCommit = $FS::UID::AutoCommit;
1152   local $FS::UID::AutoCommit = 0;
1153   my $dbh = dbh;
1154
1155   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1156      $dbh->rollback if $oldAutoCommit;
1157      return "Can't delete a master agent customer";
1158   }
1159
1160   #use FS::access_user
1161   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1162      $dbh->rollback if $oldAutoCommit;
1163      return "Can't delete a master employee customer";
1164   }
1165
1166   tie my %financial_tables, 'Tie::IxHash',
1167     'cust_bill'      => 'invoices',
1168     'cust_statement' => 'statements',
1169     'cust_credit'    => 'credits',
1170     'cust_pay'       => 'payments',
1171     'cust_refund'    => 'refunds',
1172   ;
1173
1174   foreach my $table ( keys %financial_tables ) {
1175
1176     my @records = $self->$table();
1177
1178     if ( @records && ! $opt{'delete_financials'} ) {
1179       $dbh->rollback if $oldAutoCommit;
1180       return "Can't delete a customer with ". $financial_tables{$table};
1181     }
1182
1183     foreach my $record ( @records ) {
1184       my $error = $record->delete;
1185       if ( $error ) {
1186         $dbh->rollback if $oldAutoCommit;
1187         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1188       }
1189     }
1190
1191   }
1192
1193   my @cust_pkg = $self->ncancelled_pkgs;
1194   if ( @cust_pkg ) {
1195     my $new_custnum = $opt{'new_custnum'};
1196     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1197       $dbh->rollback if $oldAutoCommit;
1198       return "Invalid new customer number: $new_custnum";
1199     }
1200     foreach my $cust_pkg ( @cust_pkg ) {
1201       my %hash = $cust_pkg->hash;
1202       $hash{'custnum'} = $new_custnum;
1203       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1204       my $error = $new_cust_pkg->replace($cust_pkg,
1205                                          options => { $cust_pkg->options },
1206                                         );
1207       if ( $error ) {
1208         $dbh->rollback if $oldAutoCommit;
1209         return $error;
1210       }
1211     }
1212   }
1213   my @cancelled_cust_pkg = $self->all_pkgs;
1214   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1215     my $error = $cust_pkg->delete;
1216     if ( $error ) {
1217       $dbh->rollback if $oldAutoCommit;
1218       return $error;
1219     }
1220   }
1221
1222   #cust_tax_adjustment in financials?
1223   #cust_pay_pending?  ouch
1224   foreach my $table (qw(
1225     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1226     cust_payby cust_location cust_main_note cust_tax_adjustment
1227     cust_pay_void cust_pay_batch queue cust_tax_exempt
1228   )) {
1229     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1230       my $error = $record->delete;
1231       if ( $error ) {
1232         $dbh->rollback if $oldAutoCommit;
1233         return $error;
1234       }
1235     }
1236   }
1237
1238   my $sth = $dbh->prepare(
1239     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1240   ) or do {
1241     my $errstr = $dbh->errstr;
1242     $dbh->rollback if $oldAutoCommit;
1243     return $errstr;
1244   };
1245   $sth->execute($self->custnum) or do {
1246     my $errstr = $sth->errstr;
1247     $dbh->rollback if $oldAutoCommit;
1248     return $errstr;
1249   };
1250
1251   #tickets
1252
1253   my $ticket_dbh = '';
1254   if ($conf->config('ticket_system') eq 'RT_Internal') {
1255     $ticket_dbh = $dbh;
1256   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1257     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1258     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1259       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1260   }
1261
1262   if ( $ticket_dbh ) {
1263
1264     my $ticket_sth = $ticket_dbh->prepare(
1265       'DELETE FROM Links WHERE Target = ?'
1266     ) or do {
1267       my $errstr = $ticket_dbh->errstr;
1268       $dbh->rollback if $oldAutoCommit;
1269       return $errstr;
1270     };
1271     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1272       or do {
1273         my $errstr = $ticket_sth->errstr;
1274         $dbh->rollback if $oldAutoCommit;
1275         return $errstr;
1276       };
1277
1278     #check and see if the customer is the only link on the ticket, and
1279     #if so, set the ticket to deleted status in RT?
1280     #maybe someday, for now this will at least fix tickets not displaying
1281
1282   }
1283
1284   #delete the customer record
1285
1286   my $error = $self->SUPER::delete;
1287   if ( $error ) {
1288     $dbh->rollback if $oldAutoCommit;
1289     return $error;
1290   }
1291
1292   # cust_main exports!
1293
1294   #my $export_args = $options{'export_args'} || [];
1295
1296   my @part_export =
1297     map qsearch( 'part_export', {exportnum=>$_} ),
1298       $conf->config('cust_main-exports'); #, $agentnum
1299
1300   foreach my $part_export ( @part_export ) {
1301     my $error = $part_export->export_delete( $self ); #, @$export_args);
1302     if ( $error ) {
1303       $dbh->rollback if $oldAutoCommit;
1304       return "exporting to ". $part_export->exporttype.
1305              " (transaction rolled back): $error";
1306     }
1307   }
1308
1309   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1310   '';
1311
1312 }
1313
1314 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1315
1316 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1317 returns the error, otherwise returns false.
1318
1319 To change the customer's address, set the pseudo-fields C<bill_location> and
1320 C<ship_location>.  The address will still only change if at least one of the
1321 address fields differs from the existing values.
1322
1323 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1324 set as the contact email address for a default contact with the same name as
1325 the customer.
1326
1327 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1328 I<contact_params>, I<invoicing_list>.
1329
1330 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1331 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1332 deleted and inserted as appropriate.
1333
1334 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1335 groups (describing the customer's payment methods and contacts, respectively)
1336 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1337 and L<FS::contact> for the fields these can contain.
1338
1339 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1340 should be used instead if possible.
1341
1342 =cut
1343
1344 sub replace {
1345   my $self = shift;
1346
1347   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1348               ? shift
1349               : $self->replace_old;
1350
1351   my @param = @_;
1352
1353   warn "$me replace called\n"
1354     if $DEBUG;
1355
1356   my $curuser = $FS::CurrentUser::CurrentUser;
1357   return "You are not permitted to create complimentary accounts."
1358     if $self->complimentary eq 'Y'
1359     && $self->complimentary ne $old->complimentary
1360     && ! $curuser->access_right('Complimentary customer');
1361
1362   local($ignore_expired_card) = 1
1363     if $old->payby  =~ /^(CARD|DCRD)$/
1364     && $self->payby =~ /^(CARD|DCRD)$/
1365     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1366
1367   local($ignore_banned_card) = 1
1368     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1369          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1370     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1371
1372   if (    $self->payby =~ /^(CARD|DCRD)$/
1373        && $old->payinfo ne $self->payinfo
1374        && $old->paymask ne $self->paymask )
1375   {
1376     my $error = $self->check_payinfo_cardtype;
1377     return $error if $error;
1378   }
1379
1380   return "Invoicing locale is required"
1381     if $old->locale
1382     && ! $self->locale
1383     && $conf->exists('cust_main-require_locale');
1384
1385   local $SIG{HUP} = 'IGNORE';
1386   local $SIG{INT} = 'IGNORE';
1387   local $SIG{QUIT} = 'IGNORE';
1388   local $SIG{TERM} = 'IGNORE';
1389   local $SIG{TSTP} = 'IGNORE';
1390   local $SIG{PIPE} = 'IGNORE';
1391
1392   my $oldAutoCommit = $FS::UID::AutoCommit;
1393   local $FS::UID::AutoCommit = 0;
1394   my $dbh = dbh;
1395
1396   for my $l (qw(bill_location ship_location)) {
1397     #my $old_loc = $old->$l;
1398     my $new_loc = $self->$l or next;
1399
1400     # find the existing location if there is one
1401     $new_loc->set('custnum' => $self->custnum);
1402     my $error = $new_loc->find_or_insert;
1403     if ( $error ) {
1404       $dbh->rollback if $oldAutoCommit;
1405       return $error;
1406     }
1407     $self->set($l.'num', $new_loc->locationnum);
1408   } #for $l
1409
1410   my $invoicing_list;
1411   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1412     warn "cust_main::replace: using deprecated invoicing list argument";
1413     $invoicing_list = shift @param;
1414   }
1415
1416   my %options = @param;
1417
1418   $invoicing_list ||= $options{invoicing_list};
1419
1420   my @contacts = map { $_->contact } $self->cust_contact;
1421   # find a contact that matches the customer's name
1422   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1423                               and $_->last  eq $old->get('last') }
1424                             @contacts;
1425   $implicit_contact ||= FS::contact->new({
1426       'custnum'       => $self->custnum,
1427       'locationnum'   => $self->get('bill_locationnum'),
1428   });
1429
1430   # for any of these that are already contact emails, link to the existing
1431   # contact
1432   if ( $invoicing_list ) {
1433     my $email = '';
1434
1435     # kind of like process_m2m on these, except:
1436     # - the other side is two tables in a join
1437     # - and we might have to create new contact_emails
1438     # - and possibly a new contact
1439     #
1440     # Find existing invoice emails that aren't on the implicit contact.
1441     # Any of these that are not on the new invoicing list will be removed.
1442     my %old_email_cust_contact;
1443     foreach my $cust_contact ($self->cust_contact) {
1444       next if !$cust_contact->invoice_dest;
1445       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1446
1447       foreach my $contact_email ($cust_contact->contact->contact_email) {
1448         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1449       }
1450     }
1451
1452     foreach my $dest (@$invoicing_list) {
1453
1454       if ($dest eq 'POST') {
1455
1456         $self->set('postal_invoice', 'Y');
1457
1458       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1459
1460         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1461
1462       } else {
1463
1464         # See if it belongs to some other contact; if so, link it.
1465         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1466         if ( $contact_email
1467              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1468           my $cust_contact = qsearchs('cust_contact', {
1469               contactnum  => $contact_email->contactnum,
1470               custnum     => $self->custnum,
1471           }) || FS::cust_contact->new({
1472               contactnum    => $contact_email->contactnum,
1473               custnum       => $self->custnum,
1474           });
1475           $cust_contact->set('invoice_dest', 'Y');
1476           my $error = $cust_contact->custcontactnum ?
1477                         $cust_contact->replace : $cust_contact->insert;
1478           if ( $error ) {
1479             $dbh->rollback if $oldAutoCommit;
1480             return "$error (linking to email address $dest)";
1481           }
1482
1483         } else {
1484           # This email address is not yet linked to any contact, so it will
1485           # be added to the implicit contact.
1486           $email .= ',' if length($email);
1487           $email .= $dest;
1488         }
1489       }
1490     }
1491
1492     foreach my $remove_dest (keys %old_email_cust_contact) {
1493       my $cust_contact = $old_email_cust_contact{$remove_dest};
1494       # These were not in the list of requested destinations, so take them off.
1495       $cust_contact->set('invoice_dest', '');
1496       my $error = $cust_contact->replace;
1497       if ( $error ) {
1498         $dbh->rollback if $oldAutoCommit;
1499         return "$error (unlinking email address $remove_dest)";
1500       }
1501     }
1502
1503     # make sure it keeps up with the changed customer name, if any
1504     $implicit_contact->set('last', $self->get('last'));
1505     $implicit_contact->set('first', $self->get('first'));
1506     $implicit_contact->set('emailaddress', $email);
1507     $implicit_contact->set('invoice_dest', 'Y');
1508     $implicit_contact->set('custnum', $self->custnum);
1509
1510     my $error;
1511     if ( $implicit_contact->contactnum ) {
1512       $error = $implicit_contact->replace;
1513     } elsif ( length($email) ) { # don't create a new contact if not needed
1514       $error = $implicit_contact->insert;
1515     }
1516
1517     if ( $error ) {
1518       $dbh->rollback if $oldAutoCommit;
1519       return "$error (adding email address $email)";
1520     }
1521
1522   }
1523
1524   # replace the customer record
1525   my $error = $self->SUPER::replace($old);
1526
1527   if ( $error ) {
1528     $dbh->rollback if $oldAutoCommit;
1529     return $error;
1530   }
1531
1532   # now move packages to the new service location
1533   $self->set('ship_location', ''); #flush cache
1534   if ( $old->ship_locationnum and # should only be null during upgrade...
1535        $old->ship_locationnum != $self->ship_locationnum ) {
1536     $error = $old->ship_location->move_to($self->ship_location);
1537     if ( $error ) {
1538       $dbh->rollback if $oldAutoCommit;
1539       return $error;
1540     }
1541   }
1542   # don't move packages based on the billing location, but
1543   # disable it if it's no longer in use
1544   if ( $old->bill_locationnum and
1545        $old->bill_locationnum != $self->bill_locationnum ) {
1546     $error = $old->bill_location->disable_if_unused;
1547     if ( $error ) {
1548       $dbh->rollback if $oldAutoCommit;
1549       return $error;
1550     }
1551   }
1552
1553   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1554
1555     #this could be more efficient than deleting and re-inserting, if it matters
1556     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1557       my $error = $cust_tag->delete;
1558       if ( $error ) {
1559         $dbh->rollback if $oldAutoCommit;
1560         return $error;
1561       }
1562     }
1563     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1564       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1565                                         'custnum' => $self->custnum };
1566       my $error = $cust_tag->insert;
1567       if ( $error ) {
1568         $dbh->rollback if $oldAutoCommit;
1569         return $error;
1570       }
1571     }
1572
1573   }
1574
1575   my $tax_exemption = delete $options{'tax_exemption'};
1576   if ( $tax_exemption ) {
1577
1578     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1579       if ref($tax_exemption) eq 'ARRAY';
1580
1581     my %cust_main_exemption =
1582       map { $_->taxname => $_ }
1583           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1584
1585     foreach my $taxname ( keys %$tax_exemption ) {
1586
1587       if ( $cust_main_exemption{$taxname} &&
1588            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1589          )
1590       {
1591         delete $cust_main_exemption{$taxname};
1592         next;
1593       }
1594
1595       my $cust_main_exemption = new FS::cust_main_exemption {
1596         'custnum'       => $self->custnum,
1597         'taxname'       => $taxname,
1598         'exempt_number' => $tax_exemption->{$taxname},
1599       };
1600       my $error = $cust_main_exemption->insert;
1601       if ( $error ) {
1602         $dbh->rollback if $oldAutoCommit;
1603         return "inserting cust_main_exemption (transaction rolled back): $error";
1604       }
1605     }
1606
1607     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1608       my $error = $cust_main_exemption->delete;
1609       if ( $error ) {
1610         $dbh->rollback if $oldAutoCommit;
1611         return "deleting cust_main_exemption (transaction rolled back): $error";
1612       }
1613     }
1614
1615   }
1616
1617   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1618
1619     my $error = $self->process_o2m(
1620       'table'         => 'cust_payby',
1621       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1622       'params'        => $cust_payby_params,
1623       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1624     );
1625     if ( $error ) {
1626       $dbh->rollback if $oldAutoCommit;
1627       return $error;
1628     }
1629
1630   }
1631
1632   if ( my $contact_params = delete $options{'contact_params'} ) {
1633
1634     # this can potentially replace contacts that were created by the
1635     # invoicing list argument, but the UI shouldn't allow both of them
1636     # to be specified
1637
1638     my $error = $self->process_o2m(
1639       'table'         => 'contact',
1640       'fields'        => FS::contact->cgi_contact_fields,
1641       'params'        => $contact_params,
1642     );
1643     if ( $error ) {
1644       $dbh->rollback if $oldAutoCommit;
1645       return $error;
1646     }
1647
1648   }
1649
1650   unless ( $import || $skip_fuzzyfiles ) {
1651     $error = $self->queue_fuzzyfiles_update;
1652     if ( $error ) {
1653       $dbh->rollback if $oldAutoCommit;
1654       return "updating fuzzy search cache: $error";
1655     }
1656   }
1657
1658   # tax district update in cust_location
1659
1660   # cust_main exports!
1661
1662   my $export_args = $options{'export_args'} || [];
1663
1664   my @part_export =
1665     map qsearch( 'part_export', {exportnum=>$_} ),
1666       $conf->config('cust_main-exports'); #, $agentnum
1667
1668   foreach my $part_export ( @part_export ) {
1669     my $error = $part_export->export_replace( $self, $old, @$export_args);
1670     if ( $error ) {
1671       $dbh->rollback if $oldAutoCommit;
1672       return "exporting to ". $part_export->exporttype.
1673              " (transaction rolled back): $error";
1674     }
1675   }
1676
1677   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1678   '';
1679
1680 }
1681
1682 =item queue_fuzzyfiles_update
1683
1684 Used by insert & replace to update the fuzzy search cache
1685
1686 =cut
1687
1688 use FS::cust_main::Search;
1689 sub queue_fuzzyfiles_update {
1690   my $self = shift;
1691
1692   local $SIG{HUP} = 'IGNORE';
1693   local $SIG{INT} = 'IGNORE';
1694   local $SIG{QUIT} = 'IGNORE';
1695   local $SIG{TERM} = 'IGNORE';
1696   local $SIG{TSTP} = 'IGNORE';
1697   local $SIG{PIPE} = 'IGNORE';
1698
1699   my $oldAutoCommit = $FS::UID::AutoCommit;
1700   local $FS::UID::AutoCommit = 0;
1701   my $dbh = dbh;
1702
1703   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1704     my $queue = new FS::queue {
1705       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1706     };
1707     my @args = "cust_main.$field", $self->get($field);
1708     my $error = $queue->insert( @args );
1709     if ( $error ) {
1710       $dbh->rollback if $oldAutoCommit;
1711       return "queueing job (transaction rolled back): $error";
1712     }
1713   }
1714
1715   my @locations = ();
1716   push @locations, $self->bill_location if $self->bill_locationnum;
1717   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1718   foreach my $location (@locations) {
1719     my $queue = new FS::queue {
1720       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1721     };
1722     my @args = 'cust_location.address1', $location->address1;
1723     my $error = $queue->insert( @args );
1724     if ( $error ) {
1725       $dbh->rollback if $oldAutoCommit;
1726       return "queueing job (transaction rolled back): $error";
1727     }
1728   }
1729
1730   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1731   '';
1732
1733 }
1734
1735 =item check
1736
1737 Checks all fields to make sure this is a valid customer record.  If there is
1738 an error, returns the error, otherwise returns false.  Called by the insert
1739 and replace methods.
1740
1741 =cut
1742
1743 sub check {
1744   my $self = shift;
1745
1746   warn "$me check BEFORE: \n". $self->_dump
1747     if $DEBUG > 2;
1748
1749   my $error =
1750     $self->ut_numbern('custnum')
1751     || $self->ut_number('agentnum')
1752     || $self->ut_textn('agent_custid')
1753     || $self->ut_number('refnum')
1754     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1755     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1756     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1757     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1758     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1759     || $self->ut_textn('custbatch')
1760     || $self->ut_name('last')
1761     || $self->ut_name('first')
1762     || $self->ut_snumbern('signupdate')
1763     || $self->ut_snumbern('birthdate')
1764     || $self->ut_namen('spouse_last')
1765     || $self->ut_namen('spouse_first')
1766     || $self->ut_snumbern('spouse_birthdate')
1767     || $self->ut_snumbern('anniversary_date')
1768     || $self->ut_textn('company')
1769     || $self->ut_textn('ship_company')
1770     || $self->ut_anything('comments')
1771     || $self->ut_numbern('referral_custnum')
1772     || $self->ut_textn('stateid')
1773     || $self->ut_textn('stateid_state')
1774     || $self->ut_textn('invoice_terms')
1775     || $self->ut_floatn('cdr_termination_percentage')
1776     || $self->ut_floatn('credit_limit')
1777     || $self->ut_numbern('billday')
1778     || $self->ut_numbern('prorate_day')
1779     || $self->ut_flag('force_prorate_day')
1780     || $self->ut_flag('edit_subject')
1781     || $self->ut_flag('calling_list_exempt')
1782     || $self->ut_flag('invoice_noemail')
1783     || $self->ut_flag('message_noemail')
1784     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1785     || $self->ut_currencyn('currency')
1786     || $self->ut_textn('po_number')
1787     || $self->ut_enum('complimentary', [ '', 'Y' ])
1788     || $self->ut_flag('invoice_ship_address')
1789     || $self->ut_flag('invoice_dest')
1790   ;
1791
1792   foreach (qw(company ship_company)) {
1793     my $company = $self->get($_);
1794     $company =~ s/^\s+//;
1795     $company =~ s/\s+$//;
1796     $company =~ s/\s+/ /g;
1797     $self->set($_, $company);
1798   }
1799
1800   #barf.  need message catalogs.  i18n.  etc.
1801   $error .= "Please select an advertising source."
1802     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1803   return $error if $error;
1804
1805   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1806     or return "Unknown agent";
1807
1808   if ( $self->currency ) {
1809     my $agent_currency = qsearchs( 'agent_currency', {
1810       'agentnum' => $agent->agentnum,
1811       'currency' => $self->currency,
1812     })
1813       or return "Agent ". $agent->agent.
1814                 " not permitted to offer ".  $self->currency. " invoicing";
1815   }
1816
1817   return "Unknown refnum"
1818     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1819
1820   return "Unknown referring custnum: ". $self->referral_custnum
1821     unless ! $self->referral_custnum
1822            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1823
1824   if ( $self->ss eq '' ) {
1825     $self->ss('');
1826   } else {
1827     my $ss = $self->ss;
1828     $ss =~ s/\D//g;
1829     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1830       or return "Illegal social security number: ". $self->ss;
1831     $self->ss("$1-$2-$3");
1832   }
1833
1834   #turn off invoice_ship_address if ship & bill are the same
1835   if ($self->bill_locationnum eq $self->ship_locationnum) {
1836     $self->invoice_ship_address('');
1837   }
1838
1839   # cust_main_county verification now handled by cust_location check
1840
1841   $error =
1842        $self->ut_phonen('daytime', $self->country)
1843     || $self->ut_phonen('night',   $self->country)
1844     || $self->ut_phonen('fax',     $self->country)
1845     || $self->ut_phonen('mobile',  $self->country)
1846   ;
1847   return $error if $error;
1848
1849   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1850        && ! $import
1851        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1852      ) {
1853
1854     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1855                           ? 'Day Phone'
1856                           : FS::Msgcat::_gettext('daytime');
1857     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1858                         ? 'Night Phone'
1859                         : FS::Msgcat::_gettext('night');
1860
1861     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1862                         ? 'Mobile Phone'
1863                         : FS::Msgcat::_gettext('mobile');
1864
1865     return "$daytime_label, $night_label or $mobile_label is required"
1866
1867   }
1868
1869   ### start of stuff moved to cust_payby
1870   # then mostly kept here to support upgrades (can remove in 5.x)
1871   #  but modified to allow everything to be empty
1872
1873   if ( $self->payby ) {
1874     FS::payby->can_payby($self->table, $self->payby)
1875       or return "Illegal payby: ". $self->payby;
1876   } else {
1877     $self->payby('');
1878   }
1879
1880   $error =    $self->ut_numbern('paystart_month')
1881            || $self->ut_numbern('paystart_year')
1882            || $self->ut_numbern('payissue')
1883            || $self->ut_textn('paytype')
1884   ;
1885   return $error if $error;
1886
1887   if ( $self->payip eq '' ) {
1888     $self->payip('');
1889   } else {
1890     $error = $self->ut_ip('payip');
1891     return $error if $error;
1892   }
1893
1894   # If it is encrypted and the private key is not availaible then we can't
1895   # check the credit card.
1896   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1897
1898   # Need some kind of global flag to accept invalid cards, for testing
1899   # on scrubbed data.
1900   if ( !$import && !$ignore_invalid_card && $check_payinfo &&
1901     $self->payby =~ /^(CARD|DCRD)$/ ) {
1902
1903     my $payinfo = $self->payinfo;
1904     $payinfo =~ s/\D//g;
1905     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1906       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1907     $payinfo = $1;
1908     $self->payinfo($payinfo);
1909     validate($payinfo)
1910       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1911
1912     return gettext('unknown_card_type')
1913       if $self->payinfo !~ /^99\d{14}$/ #token
1914       && cardtype($self->payinfo) eq "Unknown";
1915
1916     unless ( $ignore_banned_card ) {
1917       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1918       if ( $ban ) {
1919         if ( $ban->bantype eq 'warn' ) {
1920           #or others depending on value of $ban->reason ?
1921           return '_duplicate_card'.
1922                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1923                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1924                  ' (ban# '. $ban->bannum. ')'
1925             unless $self->override_ban_warn;
1926         } else {
1927           return 'Banned credit card: banned on '.
1928                  time2str('%a %h %o at %r', $ban->_date).
1929                  ' by '. $ban->otaker.
1930                  ' (ban# '. $ban->bannum. ')';
1931         }
1932       }
1933     }
1934
1935     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1936       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1937         $self->paycvv =~ /^(\d{4})$/
1938           or return "CVV2 (CID) for American Express cards is four digits.";
1939         $self->paycvv($1);
1940       } else {
1941         $self->paycvv =~ /^(\d{3})$/
1942           or return "CVV2 (CVC2/CID) is three digits.";
1943         $self->paycvv($1);
1944       }
1945     } else {
1946       $self->paycvv('');
1947     }
1948
1949     my $cardtype = cardtype($payinfo);
1950     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1951
1952       return "Start date or issue number is required for $cardtype cards"
1953         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1954
1955       return "Start month must be between 1 and 12"
1956         if $self->paystart_month
1957            and $self->paystart_month < 1 || $self->paystart_month > 12;
1958
1959       return "Start year must be 1990 or later"
1960         if $self->paystart_year
1961            and $self->paystart_year < 1990;
1962
1963       return "Issue number must be beween 1 and 99"
1964         if $self->payissue
1965           and $self->payissue < 1 || $self->payissue > 99;
1966
1967     } else {
1968       $self->paystart_month('');
1969       $self->paystart_year('');
1970       $self->payissue('');
1971     }
1972
1973   } elsif ( !$ignore_invalid_card && $check_payinfo &&
1974     $self->payby =~ /^(CHEK|DCHK)$/ ) {
1975
1976     my $payinfo = $self->payinfo;
1977     $payinfo =~ s/[^\d\@\.]//g;
1978     if ( $conf->config('echeck-country') eq 'CA' ) {
1979       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1980         or return 'invalid echeck account@branch.bank';
1981       $payinfo = "$1\@$2.$3";
1982     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1983       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1984       $payinfo = "$1\@$2";
1985     } else {
1986       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1987       $payinfo = "$1\@$2";
1988     }
1989     $self->payinfo($payinfo);
1990     $self->paycvv('');
1991
1992     unless ( $ignore_banned_card ) {
1993       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1994       if ( $ban ) {
1995         if ( $ban->bantype eq 'warn' ) {
1996           #or others depending on value of $ban->reason ?
1997           return '_duplicate_ach' unless $self->override_ban_warn;
1998         } else {
1999           return 'Banned ACH account: banned on '.
2000                  time2str('%a %h %o at %r', $ban->_date).
2001                  ' by '. $ban->otaker.
2002                  ' (ban# '. $ban->bannum. ')';
2003         }
2004       }
2005     }
2006
2007   } elsif ( $self->payby eq 'LECB' ) {
2008
2009     my $payinfo = $self->payinfo;
2010     $payinfo =~ s/\D//g;
2011     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
2012     $payinfo = $1;
2013     $self->payinfo($payinfo);
2014     $self->paycvv('');
2015
2016   } elsif ( $self->payby eq 'BILL' ) {
2017
2018     $error = $self->ut_textn('payinfo');
2019     return "Illegal P.O. number: ". $self->payinfo if $error;
2020     $self->paycvv('');
2021
2022   } elsif ( $self->payby eq 'COMP' ) {
2023
2024     my $curuser = $FS::CurrentUser::CurrentUser;
2025     if (    ! $self->custnum
2026          && ! $curuser->access_right('Complimentary customer')
2027        )
2028     {
2029       return "You are not permitted to create complimentary accounts."
2030     }
2031
2032     $error = $self->ut_textn('payinfo');
2033     return "Illegal comp account issuer: ". $self->payinfo if $error;
2034     $self->paycvv('');
2035
2036   } elsif ( $self->payby eq 'PREPAY' ) {
2037
2038     my $payinfo = $self->payinfo;
2039     $payinfo =~ s/\W//g; #anything else would just confuse things
2040     $self->payinfo($payinfo);
2041     $error = $self->ut_alpha('payinfo');
2042     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2043     return "Unknown prepayment identifier"
2044       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2045     $self->paycvv('');
2046
2047   }
2048
2049   return "You are not permitted to create complimentary accounts."
2050     if ! $self->custnum
2051     && $self->complimentary eq 'Y'
2052     && ! $FS::CurrentUser::CurrentUser->access_right('Complimentary customer');
2053
2054   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2055     return "Expiration date required"
2056       # shouldn't payinfo_check do this?
2057       unless ! $self->payby
2058             || $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2059     $self->paydate('');
2060   } else {
2061     my( $m, $y );
2062     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2063       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2064     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2065       ( $m, $y ) = ( $2, "19$1" );
2066     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2067       ( $m, $y ) = ( $3, "20$2" );
2068     } else {
2069       return "Illegal expiration date: ". $self->paydate;
2070     }
2071     $m = sprintf('%02d',$m);
2072     $self->paydate("$y-$m-01");
2073     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2074     return gettext('expired_card')
2075       if !$import
2076       && !$ignore_expired_card
2077       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2078   }
2079
2080   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2081        ( ! $conf->exists('require_cardname')
2082          || $self->payby !~ /^(CARD|DCRD)$/  )
2083   ) {
2084     $self->payname( $self->first. " ". $self->getfield('last') );
2085   } else {
2086
2087     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2088       $self->payname =~ /^([\w \,\.\-\']*)$/
2089         or return gettext('illegal_name'). " payname: ". $self->payname;
2090       $self->payname($1);
2091     } else {
2092       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
2093         or return gettext('illegal_name'). " payname: ". $self->payname;
2094       $self->payname($1);
2095     }
2096
2097   }
2098
2099   ### end of stuff moved to cust_payby
2100
2101   return "Please select an invoicing locale"
2102     if ! $self->locale
2103     && ! $self->custnum
2104     && $conf->exists('cust_main-require_locale');
2105
2106   return "Please select a customer class"
2107     if ! $self->classnum
2108     && $conf->exists('cust_main-require_classnum');
2109
2110   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2111     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2112     $self->$flag($1);
2113   }
2114
2115   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2116
2117   warn "$me check AFTER: \n". $self->_dump
2118     if $DEBUG > 2;
2119
2120   $self->SUPER::check;
2121 }
2122
2123 sub check_payinfo_cardtype {
2124   my $self = shift;
2125
2126   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
2127
2128   my $payinfo = $self->payinfo;
2129   $payinfo =~ s/\D//g;
2130
2131   return '' if $payinfo =~ /^99\d{14}$/; #token
2132
2133   my %bop_card_types = map { $_=>1 } values %{ card_types() };
2134   my $cardtype = cardtype($payinfo);
2135
2136   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
2137
2138   '';
2139
2140 }
2141
2142 =item replace_check
2143
2144 Additional checks for replace only.
2145
2146 =cut
2147
2148 sub replace_check {
2149   my ($new,$old) = @_;
2150   #preserve old value if global config is set
2151   if ($old && $conf->exists('invoice-ship_address')) {
2152     $new->invoice_ship_address($old->invoice_ship_address);
2153   }
2154   return '';
2155 }
2156
2157 =item addr_fields
2158
2159 Returns a list of fields which have ship_ duplicates.
2160
2161 =cut
2162
2163 sub addr_fields {
2164   qw( last first company
2165       locationname
2166       address1 address2 city county state zip country
2167       latitude longitude
2168       daytime night fax mobile
2169     );
2170 }
2171
2172 =item has_ship_address
2173
2174 Returns true if this customer record has a separate shipping address.
2175
2176 =cut
2177
2178 sub has_ship_address {
2179   my $self = shift;
2180   $self->bill_locationnum != $self->ship_locationnum;
2181 }
2182
2183 =item location_hash
2184
2185 Returns a list of key/value pairs, with the following keys: address1,
2186 adddress2, city, county, state, zip, country, district, and geocode.  The
2187 shipping address is used if present.
2188
2189 =cut
2190
2191 sub location_hash {
2192   my $self = shift;
2193   $self->ship_location->location_hash;
2194 }
2195
2196 =item cust_location
2197
2198 Returns all locations (see L<FS::cust_location>) for this customer.
2199
2200 =cut
2201
2202 sub cust_location {
2203   my $self = shift;
2204   qsearch({
2205     'table'   => 'cust_location',
2206     'hashref' => { 'custnum'     => $self->custnum,
2207                    'prospectnum' => '',
2208                  },
2209     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
2210   });
2211 }
2212
2213 =item cust_contact
2214
2215 Returns all contact associations (see L<FS::cust_contact>) for this customer.
2216
2217 =cut
2218
2219 sub cust_contact {
2220   my $self = shift;
2221   qsearch('cust_contact', { 'custnum' => $self->custnum } );
2222 }
2223
2224 =item cust_payby PAYBY
2225
2226 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2227
2228 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
2229 Does not validate PAYBY.
2230
2231 =cut
2232
2233 sub cust_payby {
2234   my $self = shift;
2235   my @payby = @_;
2236   my $search = {
2237     'table'    => 'cust_payby',
2238     'hashref'  => { 'custnum' => $self->custnum },
2239     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
2240   };
2241   $search->{'extra_sql'} = ' AND payby IN ( '.
2242                                join(',', map dbh->quote($_), @payby).
2243                              ' ) '
2244     if @payby;
2245
2246   qsearch($search);
2247 }
2248
2249 =item has_cust_payby_auto
2250
2251 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2252
2253 =cut
2254
2255 sub has_cust_payby_auto {
2256   my $self = shift;
2257   scalar( qsearch({
2258     'table'     => 'cust_payby',
2259     'hashref'   => { 'custnum' => $self->custnum, },
2260     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2261     'order_by'  => 'LIMIT 1',
2262   }) );
2263
2264 }
2265
2266 =item unsuspend
2267
2268 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2269 and L<FS::cust_pkg>) for this customer, except those on hold.
2270
2271 Returns a list: an empty list on success or a list of errors.
2272
2273 =cut
2274
2275 sub unsuspend {
2276   my $self = shift;
2277   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs;
2278 }
2279
2280 =item release_hold
2281
2282 Unsuspends all suspended packages in the on-hold state (those without setup
2283 dates) for this customer.
2284
2285 =cut
2286
2287 sub release_hold {
2288   my $self = shift;
2289   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2290 }
2291
2292 =item suspend
2293
2294 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2295
2296 Returns a list: an empty list on success or a list of errors.
2297
2298 =cut
2299
2300 sub suspend {
2301   my $self = shift;
2302   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2303 }
2304
2305 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2306
2307 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2308 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2309 of a list of pkgparts; the hashref has the following keys:
2310
2311 =over 4
2312
2313 =item pkgparts - listref of pkgparts
2314
2315 =item (other options are passed to the suspend method)
2316
2317 =back
2318
2319
2320 Returns a list: an empty list on success or a list of errors.
2321
2322 =cut
2323
2324 sub suspend_if_pkgpart {
2325   my $self = shift;
2326   my (@pkgparts, %opt);
2327   if (ref($_[0]) eq 'HASH'){
2328     @pkgparts = @{$_[0]{pkgparts}};
2329     %opt      = %{$_[0]};
2330   }else{
2331     @pkgparts = @_;
2332   }
2333   grep { $_->suspend(%opt) }
2334     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2335       $self->unsuspended_pkgs;
2336 }
2337
2338 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2339
2340 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2341 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2342 instead of a list of pkgparts; the hashref has the following keys:
2343
2344 =over 4
2345
2346 =item pkgparts - listref of pkgparts
2347
2348 =item (other options are passed to the suspend method)
2349
2350 =back
2351
2352 Returns a list: an empty list on success or a list of errors.
2353
2354 =cut
2355
2356 sub suspend_unless_pkgpart {
2357   my $self = shift;
2358   my (@pkgparts, %opt);
2359   if (ref($_[0]) eq 'HASH'){
2360     @pkgparts = @{$_[0]{pkgparts}};
2361     %opt      = %{$_[0]};
2362   }else{
2363     @pkgparts = @_;
2364   }
2365   grep { $_->suspend(%opt) }
2366     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2367       $self->unsuspended_pkgs;
2368 }
2369
2370 =item cancel [ OPTION => VALUE ... ]
2371
2372 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2373 The cancellation time will be now.
2374
2375 =back
2376
2377 Always returns a list: an empty list on success or a list of errors.
2378
2379 =cut
2380
2381 sub cancel {
2382   my $self = shift;
2383   my %opt = @_;
2384   warn "$me cancel called on customer ". $self->custnum. " with options ".
2385        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2386     if $DEBUG;
2387   my @pkgs = $self->ncancelled_pkgs;
2388
2389   $self->cancel_pkgs( %opt, 'cust_pkg' => \@pkgs );
2390 }
2391
2392 =item cancel_pkgs OPTIONS
2393
2394 Cancels a specified list of packages. OPTIONS can include:
2395
2396 =over 4
2397
2398 =item cust_pkg - an arrayref of the packages. Required.
2399
2400 =item time - the cancellation time, used to calculate final bills and
2401 unused-time credits if any. Will be passed through to the bill() and
2402 FS::cust_pkg::cancel() methods.
2403
2404 =item quiet - can be set true to supress email cancellation notices.
2405
2406 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a
2407 reasonnum of an existing reason, or passing a hashref will create a new reason.
2408 The hashref should have the following keys:
2409 typenum - Reason type (see L<FS::reason_type>)
2410 reason - Text of the new reason.
2411
2412 =item cust_pkg_reason - can be an arrayref of L<FS::cust_pkg_reason> objects
2413 for the individual packages, parallel to the C<cust_pkg> argument. The
2414 reason and reason_otaker arguments will be taken from those objects.
2415
2416 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2417
2418 =item nobill - can be set true to skip billing if it might otherwise be done.
2419
2420 =cut
2421
2422 sub cancel_pkgs {
2423   my( $self, %opt ) = @_;
2424
2425   # we're going to cancel services, which is not reversible
2426   die "cancel_pkgs cannot be run inside a transaction"
2427     if $FS::UID::AutoCommit == 0;
2428
2429   local $FS::UID::AutoCommit = 0;
2430
2431   return ( 'access denied' )
2432     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2433
2434   if ( $opt{'ban'} ) {
2435
2436     foreach my $cust_payby ( $self->cust_payby ) {
2437
2438       #well, if they didn't get decrypted on search, then we don't have to
2439       # try again... queue a job for the server that does have decryption
2440       # capability if we're in a paranoid multi-server implementation?
2441       return ( "Can't (yet) ban encrypted credit cards" )
2442         if $cust_payby->is_encrypted($cust_payby->payinfo);
2443
2444       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2445       my $error = $ban->insert;
2446       if ($error) {
2447         dbh->rollback;
2448         return ( $error );
2449       }
2450
2451     }
2452
2453   }
2454
2455   my @pkgs = @{ delete $opt{'cust_pkg'} };
2456   my $cancel_time = $opt{'time'} || time;
2457
2458   # bill all packages first, so we don't lose usage, service counts for
2459   # bulk billing, etc.
2460   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2461     $opt{nobill} = 1;
2462     my $error = $self->bill( 'pkg_list' => [ @pkgs ],
2463                              'cancel'   => 1,
2464                              'time'     => $cancel_time );
2465     if ($error) {
2466       warn "Error billing during cancel, custnum ". $self->custnum. ": $error";
2467       dbh->rollback;
2468       return ( "Error billing during cancellation: $error" );
2469     }
2470   }
2471   dbh->commit;
2472
2473   $FS::UID::AutoCommit = 1;
2474   my @errors;
2475   # now cancel all services, the same way we would for individual packages.
2476   # if any of them fail, cancel the rest anyway.
2477   my @cust_svc = map { $_->cust_svc } @pkgs;
2478   my @sorted_cust_svc =
2479     map  { $_->[0] }
2480     sort { $a->[1] <=> $b->[1] }
2481     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; } @cust_svc
2482   ;
2483   warn "$me removing ".scalar(@sorted_cust_svc)." service(s) for customer ".
2484     $self->custnum."\n"
2485     if $DEBUG;
2486   foreach my $cust_svc (@sorted_cust_svc) {
2487     my $part_svc = $cust_svc->part_svc;
2488     next if ( defined($part_svc) and $part_svc->preserve );
2489     my $error = $cust_svc->cancel; # immediate cancel, no date option
2490     push @errors, $error if $error;
2491   }
2492   if (@errors) {
2493     return @errors;
2494   }
2495
2496   warn "$me cancelling ". scalar(@pkgs) ." package(s) for customer ".
2497     $self->custnum. "\n"
2498     if $DEBUG;
2499
2500   my @cprs;
2501   if ($opt{'cust_pkg_reason'}) {
2502     @cprs = @{ delete $opt{'cust_pkg_reason'} };
2503   }
2504   my $null_reason;
2505   foreach (@pkgs) {
2506     my %lopt = %opt;
2507     if (@cprs) {
2508       my $cpr = shift @cprs;
2509       if ( $cpr ) {
2510         $lopt{'reason'}        = $cpr->reasonnum;
2511         $lopt{'reason_otaker'} = $cpr->otaker;
2512       } else {
2513         warn "no reason found when canceling package ".$_->pkgnum."\n";
2514         # we're not actually required to pass a reason to cust_pkg::cancel,
2515         # but if we're getting to this point, something has gone awry.
2516         $null_reason ||= FS::reason->new_or_existing(
2517           reason  => 'unknown reason',
2518           type    => 'Cancel Reason',
2519           class   => 'C',
2520         );
2521         $lopt{'reason'} = $null_reason->reasonnum;
2522         $lopt{'reason_otaker'} = $FS::CurrentUser::CurrentUser->username;
2523       }
2524     }
2525     my $error = $_->cancel(%lopt);
2526     push @errors, 'pkgnum '.$_->pkgnum.': '.$error if $error;
2527   }
2528
2529   return @errors;
2530 }
2531
2532 sub _banned_pay_hashref {
2533   my $self = shift;
2534
2535   my %payby2ban = (
2536     'CARD' => 'CARD',
2537     'DCRD' => 'CARD',
2538     'CHEK' => 'CHEK',
2539     'DCHK' => 'CHEK'
2540   );
2541
2542   {
2543     'payby'   => $payby2ban{$self->payby},
2544     'payinfo' => $self->payinfo,
2545     #don't ever *search* on reason! #'reason'  =>
2546   };
2547 }
2548
2549 =item notes
2550
2551 Returns all notes (see L<FS::cust_main_note>) for this customer.
2552
2553 =cut
2554
2555 sub notes {
2556   my($self,$orderby_classnum) = (shift,shift);
2557   my $orderby = "sticky DESC, _date DESC";
2558   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2559   qsearch( 'cust_main_note',
2560            { 'custnum' => $self->custnum },
2561            '',
2562            "ORDER BY $orderby",
2563          );
2564 }
2565
2566 =item agent
2567
2568 Returns the agent (see L<FS::agent>) for this customer.
2569
2570 =item agent_name
2571
2572 Returns the agent name (see L<FS::agent>) for this customer.
2573
2574 =cut
2575
2576 sub agent_name {
2577   my $self = shift;
2578   $self->agent->agent;
2579 }
2580
2581 =item cust_tag
2582
2583 Returns any tags associated with this customer, as FS::cust_tag objects,
2584 or an empty list if there are no tags.
2585
2586 =item part_tag
2587
2588 Returns any tags associated with this customer, as FS::part_tag objects,
2589 or an empty list if there are no tags.
2590
2591 =cut
2592
2593 sub part_tag {
2594   my $self = shift;
2595   map $_->part_tag, $self->cust_tag;
2596 }
2597
2598
2599 =item cust_class
2600
2601 Returns the customer class, as an FS::cust_class object, or the empty string
2602 if there is no customer class.
2603
2604 =item categoryname
2605
2606 Returns the customer category name, or the empty string if there is no customer
2607 category.
2608
2609 =cut
2610
2611 sub categoryname {
2612   my $self = shift;
2613   my $cust_class = $self->cust_class;
2614   $cust_class
2615     ? $cust_class->categoryname
2616     : '';
2617 }
2618
2619 =item classname
2620
2621 Returns the customer class name, or the empty string if there is no customer
2622 class.
2623
2624 =cut
2625
2626 sub classname {
2627   my $self = shift;
2628   my $cust_class = $self->cust_class;
2629   $cust_class
2630     ? $cust_class->classname
2631     : '';
2632 }
2633
2634 =item tax_status
2635
2636 Returns the external tax status, as an FS::tax_status object, or the empty
2637 string if there is no tax status.
2638
2639 =cut
2640
2641 sub tax_status {
2642   my $self = shift;
2643   if ( $self->taxstatusnum ) {
2644     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2645   } else {
2646     return '';
2647   }
2648 }
2649
2650 =item taxstatus
2651
2652 Returns the tax status code if there is one.
2653
2654 =cut
2655
2656 sub taxstatus {
2657   my $self = shift;
2658   my $tax_status = $self->tax_status;
2659   $tax_status
2660     ? $tax_status->taxstatus
2661     : '';
2662 }
2663
2664 =item BILLING METHODS
2665
2666 Documentation on billing methods has been moved to
2667 L<FS::cust_main::Billing>.
2668
2669 =item REALTIME BILLING METHODS
2670
2671 Documentation on realtime billing methods has been moved to
2672 L<FS::cust_main::Billing_Realtime>.
2673
2674 =item remove_cvv
2675
2676 Removes the I<paycvv> field from the database directly.
2677
2678 If there is an error, returns the error, otherwise returns false.
2679
2680 DEPRECATED.  Use L</remove_cvv_from_cust_payby> instead.
2681
2682 =cut
2683
2684 sub remove_cvv {
2685   my $self = shift;
2686   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2687     or return dbh->errstr;
2688   $sth->execute($self->custnum)
2689     or return $sth->errstr;
2690   $self->paycvv('');
2691   '';
2692 }
2693
2694 =item total_owed
2695
2696 Returns the total owed for this customer on all invoices
2697 (see L<FS::cust_bill/owed>).
2698
2699 =cut
2700
2701 sub total_owed {
2702   my $self = shift;
2703   $self->total_owed_date(2145859200); #12/31/2037
2704 }
2705
2706 =item total_owed_date TIME
2707
2708 Returns the total owed for this customer on all invoices with date earlier than
2709 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2710 see L<Time::Local> and L<Date::Parse> for conversion functions.
2711
2712 =cut
2713
2714 sub total_owed_date {
2715   my $self = shift;
2716   my $time = shift;
2717
2718   my $custnum = $self->custnum;
2719
2720   my $owed_sql = FS::cust_bill->owed_sql;
2721
2722   my $sql = "
2723     SELECT SUM($owed_sql) FROM cust_bill
2724       WHERE custnum = $custnum
2725         AND _date <= $time
2726   ";
2727
2728   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2729
2730 }
2731
2732 =item total_owed_pkgnum PKGNUM
2733
2734 Returns the total owed on all invoices for this customer's specific package
2735 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2736
2737 =cut
2738
2739 sub total_owed_pkgnum {
2740   my( $self, $pkgnum ) = @_;
2741   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2742 }
2743
2744 =item total_owed_date_pkgnum TIME PKGNUM
2745
2746 Returns the total owed for this customer's specific package when using
2747 experimental package balances on all invoices with date earlier than
2748 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2749 see L<Time::Local> and L<Date::Parse> for conversion functions.
2750
2751 =cut
2752
2753 sub total_owed_date_pkgnum {
2754   my( $self, $time, $pkgnum ) = @_;
2755
2756   my $total_bill = 0;
2757   foreach my $cust_bill (
2758     grep { $_->_date <= $time }
2759       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2760   ) {
2761     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2762   }
2763   sprintf( "%.2f", $total_bill );
2764
2765 }
2766
2767 =item total_paid
2768
2769 Returns the total amount of all payments.
2770
2771 =cut
2772
2773 sub total_paid {
2774   my $self = shift;
2775   my $total = 0;
2776   $total += $_->paid foreach $self->cust_pay;
2777   sprintf( "%.2f", $total );
2778 }
2779
2780 =item total_unapplied_credits
2781
2782 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2783 customer.  See L<FS::cust_credit/credited>.
2784
2785 =item total_credited
2786
2787 Old name for total_unapplied_credits.  Don't use.
2788
2789 =cut
2790
2791 sub total_credited {
2792   #carp "total_credited deprecated, use total_unapplied_credits";
2793   shift->total_unapplied_credits(@_);
2794 }
2795
2796 sub total_unapplied_credits {
2797   my $self = shift;
2798
2799   my $custnum = $self->custnum;
2800
2801   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2802
2803   my $sql = "
2804     SELECT SUM($unapplied_sql) FROM cust_credit
2805       WHERE custnum = $custnum
2806   ";
2807
2808   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2809
2810 }
2811
2812 =item total_unapplied_credits_pkgnum PKGNUM
2813
2814 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2815 customer.  See L<FS::cust_credit/credited>.
2816
2817 =cut
2818
2819 sub total_unapplied_credits_pkgnum {
2820   my( $self, $pkgnum ) = @_;
2821   my $total_credit = 0;
2822   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2823   sprintf( "%.2f", $total_credit );
2824 }
2825
2826
2827 =item total_unapplied_payments
2828
2829 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2830 See L<FS::cust_pay/unapplied>.
2831
2832 =cut
2833
2834 sub total_unapplied_payments {
2835   my $self = shift;
2836
2837   my $custnum = $self->custnum;
2838
2839   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2840
2841   my $sql = "
2842     SELECT SUM($unapplied_sql) FROM cust_pay
2843       WHERE custnum = $custnum
2844   ";
2845
2846   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2847
2848 }
2849
2850 =item total_unapplied_payments_pkgnum PKGNUM
2851
2852 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2853 specific package when using experimental package balances.  See
2854 L<FS::cust_pay/unapplied>.
2855
2856 =cut
2857
2858 sub total_unapplied_payments_pkgnum {
2859   my( $self, $pkgnum ) = @_;
2860   my $total_unapplied = 0;
2861   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2862   sprintf( "%.2f", $total_unapplied );
2863 }
2864
2865
2866 =item total_unapplied_refunds
2867
2868 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2869 customer.  See L<FS::cust_refund/unapplied>.
2870
2871 =cut
2872
2873 sub total_unapplied_refunds {
2874   my $self = shift;
2875   my $custnum = $self->custnum;
2876
2877   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2878
2879   my $sql = "
2880     SELECT SUM($unapplied_sql) FROM cust_refund
2881       WHERE custnum = $custnum
2882   ";
2883
2884   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2885
2886 }
2887
2888 =item balance
2889
2890 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2891 total_unapplied_credits minus total_unapplied_payments).
2892
2893 =cut
2894
2895 sub balance {
2896   my $self = shift;
2897   $self->balance_date_range;
2898 }
2899
2900 =item balance_date TIME
2901
2902 Returns the balance for this customer, only considering invoices with date
2903 earlier than TIME (total_owed_date minus total_credited minus
2904 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2905 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2906 functions.
2907
2908 =cut
2909
2910 sub balance_date {
2911   my $self = shift;
2912   $self->balance_date_range(shift);
2913 }
2914
2915 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2916
2917 Returns the balance for this customer, optionally considering invoices with
2918 date earlier than START_TIME, and not later than END_TIME
2919 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2920
2921 Times are specified as SQL fragments or numeric
2922 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2923 L<Date::Parse> for conversion functions.  The empty string can be passed
2924 to disable that time constraint completely.
2925
2926 Accepts the same options as L<balance_date_sql>:
2927
2928 =over 4
2929
2930 =item unapplied_date
2931
2932 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2933
2934 =item cutoff
2935
2936 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2937 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2938 range for invoices and I<unapplied> payments, credits, and refunds.
2939
2940 =back
2941
2942 =cut
2943
2944 sub balance_date_range {
2945   my $self = shift;
2946   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2947             ') FROM cust_main WHERE custnum='. $self->custnum;
2948   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2949 }
2950
2951 =item balance_pkgnum PKGNUM
2952
2953 Returns the balance for this customer's specific package when using
2954 experimental package balances (total_owed plus total_unrefunded, minus
2955 total_unapplied_credits minus total_unapplied_payments)
2956
2957 =cut
2958
2959 sub balance_pkgnum {
2960   my( $self, $pkgnum ) = @_;
2961
2962   sprintf( "%.2f",
2963       $self->total_owed_pkgnum($pkgnum)
2964 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2965 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2966     - $self->total_unapplied_credits_pkgnum($pkgnum)
2967     - $self->total_unapplied_payments_pkgnum($pkgnum)
2968   );
2969 }
2970
2971 =item payment_info
2972
2973 Returns a hash of useful information for making a payment.
2974
2975 =over 4
2976
2977 =item balance
2978
2979 Current balance.
2980
2981 =item payby
2982
2983 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2984 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2985 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2986
2987 =back
2988
2989 For credit card transactions:
2990
2991 =over 4
2992
2993 =item card_type 1
2994
2995 =item payname
2996
2997 Exact name on card
2998
2999 =back
3000
3001 For electronic check transactions:
3002
3003 =over 4
3004
3005 =item stateid_state
3006
3007 =back
3008
3009 =cut
3010
3011 sub payment_info {
3012   my $self = shift;
3013
3014   my %return = ();
3015
3016   $return{balance} = $self->balance;
3017
3018   $return{payname} = $self->payname
3019                      || ( $self->first. ' '. $self->get('last') );
3020
3021   $return{$_} = $self->bill_location->$_
3022     for qw(address1 address2 city state zip);
3023
3024   $return{payby} = $self->payby;
3025   $return{stateid_state} = $self->stateid_state;
3026
3027   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
3028     $return{card_type} = cardtype($self->payinfo);
3029     $return{payinfo} = $self->paymask;
3030
3031     @return{'month', 'year'} = $self->paydate_monthyear;
3032
3033   }
3034
3035   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
3036     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
3037     $return{payinfo1} = $payinfo1;
3038     $return{payinfo2} = $payinfo2;
3039     $return{paytype}  = $self->paytype;
3040     $return{paystate} = $self->paystate;
3041
3042   }
3043
3044   #doubleclick protection
3045   my $_date = time;
3046   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
3047
3048   %return;
3049
3050 }
3051
3052 =item paydate_epoch
3053
3054 Returns the next payment expiration date for this customer. If they have no
3055 payment methods that will expire, returns 0.
3056
3057 =cut
3058
3059 sub paydate_epoch {
3060   my $self = shift;
3061   # filter out the ones that individually return 0, but then return 0 if
3062   # there are no results
3063   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
3064   min( @epochs ) || 0;
3065 }
3066
3067 =item paydate_epoch_sql
3068
3069 Returns an SQL expression to get the next payment expiration date for a
3070 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
3071 dates, so that it's safe to test for "will it expire before date X" for any
3072 date up to then.
3073
3074 =cut
3075
3076 sub paydate_epoch_sql {
3077   my $class = shift;
3078   my $paydate = FS::cust_payby->paydate_epoch_sql;
3079   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
3080 }
3081
3082 sub tax_exemption {
3083   my( $self, $taxname ) = @_;
3084
3085   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3086                                      'taxname' => $taxname,
3087                                    },
3088           );
3089 }
3090
3091 =item cust_main_exemption
3092
3093 =item invoicing_list
3094
3095 Returns a list of email addresses (with svcnum entries expanded), and the word
3096 'POST' if the customer receives postal invoices.
3097
3098 =cut
3099
3100 sub invoicing_list {
3101   my( $self, $arrayref ) = @_;
3102
3103   if ( $arrayref ) {
3104     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
3105   }
3106
3107   my @emails = $self->invoicing_list_emailonly;
3108   push @emails, 'POST' if $self->get('postal_invoice');
3109
3110   @emails;
3111 }
3112
3113 =item check_invoicing_list ARRAYREF
3114
3115 Checks these arguements as valid input for the invoicing_list method.  If there
3116 is an error, returns the error, otherwise returns false.
3117
3118 =cut
3119
3120 sub check_invoicing_list {
3121   my( $self, $arrayref ) = @_;
3122
3123   foreach my $address ( @$arrayref ) {
3124
3125     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3126       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3127     }
3128
3129     my $cust_main_invoice = new FS::cust_main_invoice ( {
3130       'custnum' => $self->custnum,
3131       'dest'    => $address,
3132     } );
3133     my $error = $self->custnum
3134                 ? $cust_main_invoice->check
3135                 : $cust_main_invoice->checkdest
3136     ;
3137     return $error if $error;
3138
3139   }
3140
3141   return "Email address required"
3142     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3143     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3144
3145   '';
3146 }
3147
3148 =item all_emails
3149
3150 Returns the email addresses of all accounts provisioned for this customer.
3151
3152 =cut
3153
3154 sub all_emails {
3155   my $self = shift;
3156   my %list;
3157   foreach my $cust_pkg ( $self->all_pkgs ) {
3158     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3159     my @svc_acct =
3160       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3161         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3162           @cust_svc;
3163     $list{$_}=1 foreach map { $_->email } @svc_acct;
3164   }
3165   keys %list;
3166 }
3167
3168 =item invoicing_list_addpost
3169
3170 Adds postal invoicing to this customer.  If this customer is already configured
3171 to receive postal invoices, does nothing.
3172
3173 =cut
3174
3175 sub invoicing_list_addpost {
3176   my $self = shift;
3177   if ( $self->get('postal_invoice') eq '' ) {
3178     $self->set('postal_invoice', 'Y');
3179     my $error = $self->replace;
3180     warn $error if $error; # should fail harder, but this is traditional
3181   }
3182 }
3183
3184 =item invoicing_list_emailonly
3185
3186 Returns the list of email invoice recipients (invoicing_list without non-email
3187 destinations such as POST and FAX).
3188
3189 =cut
3190
3191 sub invoicing_list_emailonly {
3192   my $self = shift;
3193   warn "$me invoicing_list_emailonly called"
3194     if $DEBUG;
3195   return () if !$self->custnum; # not yet inserted
3196   return map { $_->emailaddress }
3197     qsearch({
3198         table     => 'cust_contact',
3199         select    => 'emailaddress',
3200         addl_from => ' JOIN contact USING (contactnum) '.
3201                      ' JOIN contact_email USING (contactnum)',
3202         hashref   => { 'custnum' => $self->custnum, },
3203         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
3204     });
3205 }
3206
3207 =item invoicing_list_emailonly_scalar
3208
3209 Returns the list of email invoice recipients (invoicing_list without non-email
3210 destinations such as POST and FAX) as a comma-separated scalar.
3211
3212 =cut
3213
3214 sub invoicing_list_emailonly_scalar {
3215   my $self = shift;
3216   warn "$me invoicing_list_emailonly_scalar called"
3217     if $DEBUG;
3218   join(', ', $self->invoicing_list_emailonly);
3219 }
3220
3221 =item contact_list [ CLASSNUM, ... ]
3222
3223 Returns a list of contacts (L<FS::contact> objects) for the customer. If
3224 a list of contact classnums is given, returns only contacts in those
3225 classes. If the pseudo-classnum 'invoice' is given, returns contacts that
3226 are marked as invoice destinations. If '0' is given, also returns contacts
3227 with no class.
3228
3229 If no arguments are given, returns all contacts for the customer.
3230
3231 =cut
3232
3233 sub contact_list {
3234   my $self = shift;
3235   my $search = {
3236     table       => 'contact',
3237     select      => 'contact.*, cust_contact.invoice_dest',
3238     addl_from   => ' JOIN cust_contact USING (contactnum)',
3239     extra_sql   => ' WHERE cust_contact.custnum = '.$self->custnum,
3240   };
3241
3242   my @orwhere;
3243   my @classnums;
3244   foreach (@_) {
3245     if ( $_ eq 'invoice' ) {
3246       push @orwhere, 'cust_contact.invoice_dest = \'Y\'';
3247     } elsif ( $_ eq '0' ) {
3248       push @orwhere, 'cust_contact.classnum is null';
3249     } elsif ( /^\d+$/ ) {
3250       push @classnums, $_;
3251     } else {
3252       die "bad classnum argument '$_'";
3253     }
3254   }
3255
3256   if (@classnums) {
3257     push @orwhere, 'cust_contact.classnum IN ('.join(',', @classnums).')';
3258   }
3259   if (@orwhere) {
3260     $search->{extra_sql} .= ' AND (' .
3261                             join(' OR ', map "( $_ )", @orwhere) .
3262                             ')';
3263   }
3264
3265   qsearch($search);
3266 }
3267
3268 =item contact_list_email [ CLASSNUM, ... ]
3269
3270 Same as L</contact_list>, but returns email destinations instead of contact
3271 objects.
3272
3273 =cut
3274
3275 sub contact_list_email {
3276   my $self = shift;
3277   my @contacts = $self->contact_list(@_);
3278   my @emails;
3279   foreach my $contact (@contacts) {
3280     foreach my $contact_email ($contact->contact_email) {
3281       push @emails,  Email::Address->new( $contact->firstlast,
3282                                           $contact_email->emailaddress
3283                      )->format;
3284     }
3285   }
3286   @emails;
3287 }
3288
3289 =item referral_custnum_cust_main
3290
3291 Returns the customer who referred this customer (or the empty string, if
3292 this customer was not referred).
3293
3294 Note the difference with referral_cust_main method: This method,
3295 referral_custnum_cust_main returns the single customer (if any) who referred
3296 this customer, while referral_cust_main returns an array of customers referred
3297 BY this customer.
3298
3299 =cut
3300
3301 sub referral_custnum_cust_main {
3302   my $self = shift;
3303   return '' unless $self->referral_custnum;
3304   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3305 }
3306
3307 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3308
3309 Returns an array of customers referred by this customer (referral_custnum set
3310 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3311 customers referred by customers referred by this customer and so on, inclusive.
3312 The default behavior is DEPTH 1 (no recursion).
3313
3314 Note the difference with referral_custnum_cust_main method: This method,
3315 referral_cust_main, returns an array of customers referred BY this customer,
3316 while referral_custnum_cust_main returns the single customer (if any) who
3317 referred this customer.
3318
3319 =cut
3320
3321 sub referral_cust_main {
3322   my $self = shift;
3323   my $depth = @_ ? shift : 1;
3324   my $exclude = @_ ? shift : {};
3325
3326   my @cust_main =
3327     map { $exclude->{$_->custnum}++; $_; }
3328       grep { ! $exclude->{ $_->custnum } }
3329         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3330
3331   if ( $depth > 1 ) {
3332     push @cust_main,
3333       map { $_->referral_cust_main($depth-1, $exclude) }
3334         @cust_main;
3335   }
3336
3337   @cust_main;
3338 }
3339
3340 =item referral_cust_main_ncancelled
3341
3342 Same as referral_cust_main, except only returns customers with uncancelled
3343 packages.
3344
3345 =cut
3346
3347 sub referral_cust_main_ncancelled {
3348   my $self = shift;
3349   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3350 }
3351
3352 =item referral_cust_pkg [ DEPTH ]
3353
3354 Like referral_cust_main, except returns a flat list of all unsuspended (and
3355 uncancelled) packages for each customer.  The number of items in this list may
3356 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3357
3358 =cut
3359
3360 sub referral_cust_pkg {
3361   my $self = shift;
3362   my $depth = @_ ? shift : 1;
3363
3364   map { $_->unsuspended_pkgs }
3365     grep { $_->unsuspended_pkgs }
3366       $self->referral_cust_main($depth);
3367 }
3368
3369 =item referring_cust_main
3370
3371 Returns the single cust_main record for the customer who referred this customer
3372 (referral_custnum), or false.
3373
3374 =cut
3375
3376 sub referring_cust_main {
3377   my $self = shift;
3378   return '' unless $self->referral_custnum;
3379   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3380 }
3381
3382 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3383
3384 Applies a credit to this customer.  If there is an error, returns the error,
3385 otherwise returns false.
3386
3387 REASON can be a text string, an FS::reason object, or a scalar reference to
3388 a reasonnum.  If a text string, it will be automatically inserted as a new
3389 reason, and a 'reason_type' option must be passed to indicate the
3390 FS::reason_type for the new reason.
3391
3392 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3393 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3394 I<commission_pkgnum>.
3395
3396 Any other options are passed to FS::cust_credit::insert.
3397
3398 =cut
3399
3400 sub credit {
3401   my( $self, $amount, $reason, %options ) = @_;
3402
3403   my $cust_credit = new FS::cust_credit {
3404     'custnum' => $self->custnum,
3405     'amount'  => $amount,
3406   };
3407
3408   if ( ref($reason) ) {
3409
3410     if ( ref($reason) eq 'SCALAR' ) {
3411       $cust_credit->reasonnum( $$reason );
3412     } else {
3413       $cust_credit->reasonnum( $reason->reasonnum );
3414     }
3415
3416   } else {
3417     $cust_credit->set('reason', $reason)
3418   }
3419
3420   $cust_credit->$_( delete $options{$_} )
3421     foreach grep exists($options{$_}),
3422               qw( addlinfo eventnum ),
3423               map "commission_$_", qw( agentnum salesnum pkgnum );
3424
3425   $cust_credit->insert(%options);
3426
3427 }
3428
3429 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3430
3431 Creates a one-time charge for this customer.  If there is an error, returns
3432 the error, otherwise returns false.
3433
3434 New-style, with a hashref of options:
3435
3436   my $error = $cust_main->charge(
3437                                   {
3438                                     'amount'     => 54.32,
3439                                     'quantity'   => 1,
3440                                     'start_date' => str2time('7/4/2009'),
3441                                     'pkg'        => 'Description',
3442                                     'comment'    => 'Comment',
3443                                     'additional' => [], #extra invoice detail
3444                                     'classnum'   => 1,  #pkg_class
3445
3446                                     'setuptax'   => '', # or 'Y' for tax exempt
3447
3448                                     'locationnum'=> 1234, # optional
3449
3450                                     #internal taxation
3451                                     'taxclass'   => 'Tax class',
3452
3453                                     #vendor taxation
3454                                     'taxproduct' => 2,  #part_pkg_taxproduct
3455                                     'override'   => {}, #XXX describe
3456
3457                                     #will be filled in with the new object
3458                                     'cust_pkg_ref' => \$cust_pkg,
3459
3460                                     #generate an invoice immediately
3461                                     'bill_now' => 0,
3462                                     'invoice_terms' => '', #with these terms
3463                                   }
3464                                 );
3465
3466 Old-style:
3467
3468   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3469
3470 =cut
3471
3472 #super false laziness w/quotation::charge
3473 sub charge {
3474   my $self = shift;
3475   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3476   my ( $pkg, $comment, $additional );
3477   my ( $setuptax, $taxclass );   #internal taxes
3478   my ( $taxproduct, $override ); #vendor (CCH) taxes
3479   my $no_auto = '';
3480   my $separate_bill = '';
3481   my $cust_pkg_ref = '';
3482   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3483   my $locationnum;
3484   if ( ref( $_[0] ) ) {
3485     $amount     = $_[0]->{amount};
3486     $setup_cost = $_[0]->{setup_cost};
3487     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3488     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3489     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3490     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3491     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3492                                            : '$'. sprintf("%.2f",$amount);
3493     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3494     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3495     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3496     $additional = $_[0]->{additional} || [];
3497     $taxproduct = $_[0]->{taxproductnum};
3498     $override   = { '' => $_[0]->{tax_override} };
3499     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3500     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3501     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3502     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3503     $separate_bill = $_[0]->{separate_bill} || '';
3504   } else { # yuck
3505     $amount     = shift;
3506     $setup_cost = '';
3507     $quantity   = 1;
3508     $start_date = '';
3509     $pkg        = @_ ? shift : 'One-time charge';
3510     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3511     $setuptax   = '';
3512     $taxclass   = @_ ? shift : '';
3513     $additional = [];
3514   }
3515
3516   local $SIG{HUP} = 'IGNORE';
3517   local $SIG{INT} = 'IGNORE';
3518   local $SIG{QUIT} = 'IGNORE';
3519   local $SIG{TERM} = 'IGNORE';
3520   local $SIG{TSTP} = 'IGNORE';
3521   local $SIG{PIPE} = 'IGNORE';
3522
3523   my $oldAutoCommit = $FS::UID::AutoCommit;
3524   local $FS::UID::AutoCommit = 0;
3525   my $dbh = dbh;
3526
3527   my $part_pkg = new FS::part_pkg ( {
3528     'pkg'           => $pkg,
3529     'comment'       => $comment,
3530     'plan'          => 'flat',
3531     'freq'          => 0,
3532     'disabled'      => 'Y',
3533     'classnum'      => ( $classnum ? $classnum : '' ),
3534     'setuptax'      => $setuptax,
3535     'taxclass'      => $taxclass,
3536     'taxproductnum' => $taxproduct,
3537     'setup_cost'    => $setup_cost,
3538   } );
3539
3540   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3541                         ( 0 .. @$additional - 1 )
3542                   ),
3543                   'additional_count' => scalar(@$additional),
3544                   'setup_fee' => $amount,
3545                 );
3546
3547   my $error = $part_pkg->insert( options       => \%options,
3548                                  tax_overrides => $override,
3549                                );
3550   if ( $error ) {
3551     $dbh->rollback if $oldAutoCommit;
3552     return $error;
3553   }
3554
3555   my $pkgpart = $part_pkg->pkgpart;
3556   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3557   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3558     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3559     $error = $type_pkgs->insert;
3560     if ( $error ) {
3561       $dbh->rollback if $oldAutoCommit;
3562       return $error;
3563     }
3564   }
3565
3566   my $cust_pkg = new FS::cust_pkg ( {
3567     'custnum'    => $self->custnum,
3568     'pkgpart'    => $pkgpart,
3569     'quantity'   => $quantity,
3570     'start_date' => $start_date,
3571     'no_auto'    => $no_auto,
3572     'separate_bill' => $separate_bill,
3573     'locationnum'=> $locationnum,
3574   } );
3575
3576   $error = $cust_pkg->insert;
3577   if ( $error ) {
3578     $dbh->rollback if $oldAutoCommit;
3579     return $error;
3580   } elsif ( $cust_pkg_ref ) {
3581     ${$cust_pkg_ref} = $cust_pkg;
3582   }
3583
3584   if ( $bill_now ) {
3585     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3586                              'pkg_list'      => [ $cust_pkg ],
3587                            );
3588     if ( $error ) {
3589       $dbh->rollback if $oldAutoCommit;
3590       return $error;
3591     }
3592   }
3593
3594   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3595   return '';
3596
3597 }
3598
3599 #=item charge_postal_fee
3600 #
3601 #Applies a one time charge this customer.  If there is an error,
3602 #returns the error, returns the cust_pkg charge object or false
3603 #if there was no charge.
3604 #
3605 #=cut
3606 #
3607 # This should be a customer event.  For that to work requires that bill
3608 # also be a customer event.
3609
3610 sub charge_postal_fee {
3611   my $self = shift;
3612
3613   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3614   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3615
3616   my $cust_pkg = new FS::cust_pkg ( {
3617     'custnum'  => $self->custnum,
3618     'pkgpart'  => $pkgpart,
3619     'quantity' => 1,
3620   } );
3621
3622   my $error = $cust_pkg->insert;
3623   $error ? $error : $cust_pkg;
3624 }
3625
3626 =item num_cust_attachment_deleted
3627
3628 Returns the number of deleted attachments for this customer (see
3629 L<FS::num_cust_attachment>).
3630
3631 =cut
3632
3633 sub num_cust_attachments_deleted {
3634   my $self = shift;
3635   $self->scalar_sql(
3636     " SELECT COUNT(*) FROM cust_attachment ".
3637       " WHERE custnum = ? AND disabled IS NOT NULL AND disabled > 0",
3638     $self->custnum
3639   );
3640 }
3641
3642 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3643
3644 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3645
3646 Optionally, a list or hashref of additional arguments to the qsearch call can
3647 be passed.
3648
3649 =cut
3650
3651 sub cust_bill {
3652   my $self = shift;
3653   my $opt = ref($_[0]) ? shift : { @_ };
3654
3655   #return $self->num_cust_bill unless wantarray || keys %$opt;
3656
3657   $opt->{'table'} = 'cust_bill';
3658   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3659   $opt->{'hashref'}{'custnum'} = $self->custnum;
3660   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3661
3662   map { $_ } #behavior of sort undefined in scalar context
3663     sort { $a->_date <=> $b->_date }
3664       qsearch($opt);
3665 }
3666
3667 =item open_cust_bill
3668
3669 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3670 customer.
3671
3672 =cut
3673
3674 sub open_cust_bill {
3675   my $self = shift;
3676
3677   $self->cust_bill(
3678     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3679     #@_
3680   );
3681
3682 }
3683
3684 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3685
3686 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3687
3688 =cut
3689
3690 sub legacy_cust_bill {
3691   my $self = shift;
3692
3693   #return $self->num_legacy_cust_bill unless wantarray;
3694
3695   map { $_ } #behavior of sort undefined in scalar context
3696     sort { $a->_date <=> $b->_date }
3697       qsearch({ 'table'    => 'legacy_cust_bill',
3698                 'hashref'  => { 'custnum' => $self->custnum, },
3699                 'order_by' => 'ORDER BY _date ASC',
3700              });
3701 }
3702
3703 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3704
3705 Returns all the statements (see L<FS::cust_statement>) for this customer.
3706
3707 Optionally, a list or hashref of additional arguments to the qsearch call can
3708 be passed.
3709
3710 =cut
3711
3712 =item cust_bill_void
3713
3714 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3715
3716 =cut
3717
3718 sub cust_bill_void {
3719   my $self = shift;
3720
3721   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3722   sort { $a->_date <=> $b->_date }
3723     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3724 }
3725
3726 sub cust_statement {
3727   my $self = shift;
3728   my $opt = ref($_[0]) ? shift : { @_ };
3729
3730   #return $self->num_cust_statement unless wantarray || keys %$opt;
3731
3732   $opt->{'table'} = 'cust_statement';
3733   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3734   $opt->{'hashref'}{'custnum'} = $self->custnum;
3735   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3736
3737   map { $_ } #behavior of sort undefined in scalar context
3738     sort { $a->_date <=> $b->_date }
3739       qsearch($opt);
3740 }
3741
3742 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3743
3744 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3745
3746 Optionally, a list or hashref of additional arguments to the qsearch call can
3747 be passed following the SVCDB.
3748
3749 =cut
3750
3751 sub svc_x {
3752   my $self = shift;
3753   my $svcdb = shift;
3754   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3755     warn "$me svc_x requires a svcdb";
3756     return;
3757   }
3758   my $opt = ref($_[0]) ? shift : { @_ };
3759
3760   $opt->{'table'} = $svcdb;
3761   $opt->{'addl_from'} =
3762     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3763     ($opt->{'addl_from'} || '');
3764
3765   my $custnum = $self->custnum;
3766   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3767   my $where = "cust_pkg.custnum = $custnum";
3768
3769   my $extra_sql = $opt->{'extra_sql'} || '';
3770   if ( keys %{ $opt->{'hashref'} } ) {
3771     $extra_sql = " AND $where $extra_sql";
3772   }
3773   else {
3774     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3775       $extra_sql = "WHERE $where AND $1";
3776     }
3777     else {
3778       $extra_sql = "WHERE $where $extra_sql";
3779     }
3780   }
3781   $opt->{'extra_sql'} = $extra_sql;
3782
3783   qsearch($opt);
3784 }
3785
3786 # required for use as an eventtable;
3787 sub svc_acct {
3788   my $self = shift;
3789   $self->svc_x('svc_acct', @_);
3790 }
3791
3792 =item cust_credit
3793
3794 Returns all the credits (see L<FS::cust_credit>) for this customer.
3795
3796 =cut
3797
3798 sub cust_credit {
3799   my $self = shift;
3800
3801   #return $self->num_cust_credit unless wantarray;
3802
3803   map { $_ } #behavior of sort undefined in scalar context
3804     sort { $a->_date <=> $b->_date }
3805       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3806 }
3807
3808 =item cust_credit_pkgnum
3809
3810 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3811 package when using experimental package balances.
3812
3813 =cut
3814
3815 sub cust_credit_pkgnum {
3816   my( $self, $pkgnum ) = @_;
3817   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3818   sort { $a->_date <=> $b->_date }
3819     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3820                               'pkgnum'  => $pkgnum,
3821                             }
3822     );
3823 }
3824
3825 =item cust_credit_void
3826
3827 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3828
3829 =cut
3830
3831 sub cust_credit_void {
3832   my $self = shift;
3833   map { $_ }
3834   sort { $a->_date <=> $b->_date }
3835     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3836 }
3837
3838 =item cust_pay
3839
3840 Returns all the payments (see L<FS::cust_pay>) for this customer.
3841
3842 =cut
3843
3844 sub cust_pay {
3845   my $self = shift;
3846   my $opt = ref($_[0]) ? shift : { @_ };
3847
3848   return $self->num_cust_pay unless wantarray || keys %$opt;
3849
3850   $opt->{'table'} = 'cust_pay';
3851   $opt->{'hashref'}{'custnum'} = $self->custnum;
3852
3853   map { $_ } #behavior of sort undefined in scalar context
3854     sort { $a->_date <=> $b->_date }
3855       qsearch($opt);
3856
3857 }
3858
3859 =item num_cust_pay
3860
3861 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3862 called automatically when the cust_pay method is used in a scalar context.
3863
3864 =cut
3865
3866 sub num_cust_pay {
3867   my $self = shift;
3868   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3869   my $sth = dbh->prepare($sql) or die dbh->errstr;
3870   $sth->execute($self->custnum) or die $sth->errstr;
3871   $sth->fetchrow_arrayref->[0];
3872 }
3873
3874 =item unapplied_cust_pay
3875
3876 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3877
3878 =cut
3879
3880 sub unapplied_cust_pay {
3881   my $self = shift;
3882
3883   $self->cust_pay(
3884     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3885     #@_
3886   );
3887
3888 }
3889
3890 =item cust_pay_pkgnum
3891
3892 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3893 package when using experimental package balances.
3894
3895 =cut
3896
3897 sub cust_pay_pkgnum {
3898   my( $self, $pkgnum ) = @_;
3899   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3900   sort { $a->_date <=> $b->_date }
3901     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3902                            'pkgnum'  => $pkgnum,
3903                          }
3904     );
3905 }
3906
3907 =item cust_pay_void
3908
3909 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3910
3911 =cut
3912
3913 sub cust_pay_void {
3914   my $self = shift;
3915   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3916   sort { $a->_date <=> $b->_date }
3917     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3918 }
3919
3920 =item cust_pay_pending
3921
3922 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3923 (without status "done").
3924
3925 =cut
3926
3927 sub cust_pay_pending {
3928   my $self = shift;
3929   return $self->num_cust_pay_pending unless wantarray;
3930   sort { $a->_date <=> $b->_date }
3931     qsearch( 'cust_pay_pending', {
3932                                    'custnum' => $self->custnum,
3933                                    'status'  => { op=>'!=', value=>'done' },
3934                                  },
3935            );
3936 }
3937
3938 =item cust_pay_pending_attempt
3939
3940 Returns all payment attempts / declined payments for this customer, as pending
3941 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3942 a corresponding payment (see L<FS::cust_pay>).
3943
3944 =cut
3945
3946 sub cust_pay_pending_attempt {
3947   my $self = shift;
3948   return $self->num_cust_pay_pending_attempt unless wantarray;
3949   sort { $a->_date <=> $b->_date }
3950     qsearch( 'cust_pay_pending', {
3951                                    'custnum' => $self->custnum,
3952                                    'status'  => 'done',
3953                                    'paynum'  => '',
3954                                  },
3955            );
3956 }
3957
3958 =item num_cust_pay_pending
3959
3960 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3961 customer (without status "done").  Also called automatically when the
3962 cust_pay_pending method is used in a scalar context.
3963
3964 =cut
3965
3966 sub num_cust_pay_pending {
3967   my $self = shift;
3968   $self->scalar_sql(
3969     " SELECT COUNT(*) FROM cust_pay_pending ".
3970       " WHERE custnum = ? AND status != 'done' ",
3971     $self->custnum
3972   );
3973 }
3974
3975 =item num_cust_pay_pending_attempt
3976
3977 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3978 customer, with status "done" but without a corresp.  Also called automatically when the
3979 cust_pay_pending method is used in a scalar context.
3980
3981 =cut
3982
3983 sub num_cust_pay_pending_attempt {
3984   my $self = shift;
3985   $self->scalar_sql(
3986     " SELECT COUNT(*) FROM cust_pay_pending ".
3987       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3988     $self->custnum
3989   );
3990 }
3991
3992 =item cust_refund
3993
3994 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3995
3996 =cut
3997
3998 sub cust_refund {
3999   my $self = shift;
4000   map { $_ } #return $self->num_cust_refund unless wantarray;
4001   sort { $a->_date <=> $b->_date }
4002     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
4003 }
4004
4005 =item display_custnum
4006
4007 Returns the displayed customer number for this customer: agent_custid if
4008 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
4009
4010 =cut
4011
4012 sub display_custnum {
4013   my $self = shift;
4014
4015   return $self->agent_custid
4016     if $default_agent_custid && $self->agent_custid;
4017
4018   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
4019
4020   if ( $prefix ) {
4021     return $prefix .
4022            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
4023   } elsif ( $custnum_display_length ) {
4024     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
4025   } else {
4026     return $self->custnum;
4027   }
4028 }
4029
4030 =item name
4031
4032 Returns a name string for this customer, either "Company (Last, First)" or
4033 "Last, First".
4034
4035 =cut
4036
4037 sub name {
4038   my $self = shift;
4039   my $name = $self->contact;
4040   $name = $self->company. " ($name)" if $self->company;
4041   $name;
4042 }
4043
4044 =item service_contact
4045
4046 Returns the L<FS::contact> object for this customer that has the 'Service'
4047 contact class, or undef if there is no such contact.  Deprecated; don't use
4048 this in new code.
4049
4050 =cut
4051
4052 sub service_contact {
4053   my $self = shift;
4054   if ( !exists($self->{service_contact}) ) {
4055     my $classnum = $self->scalar_sql(
4056       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
4057     ) || 0; #if it's zero, qsearchs will return nothing
4058     my $cust_contact = qsearchs('cust_contact', {
4059         'classnum' => $classnum,
4060         'custnum'  => $self->custnum,
4061     });
4062     $self->{service_contact} = $cust_contact->contact if $cust_contact;
4063   }
4064   $self->{service_contact};
4065 }
4066
4067 =item ship_name
4068
4069 Returns a name string for this (service/shipping) contact, either
4070 "Company (Last, First)" or "Last, First".
4071
4072 =cut
4073
4074 sub ship_name {
4075   my $self = shift;
4076
4077   my $name = $self->ship_contact;
4078   $name = $self->company. " ($name)" if $self->company;
4079   $name;
4080 }
4081
4082 =item name_short
4083
4084 Returns a name string for this customer, either "Company" or "First Last".
4085
4086 =cut
4087
4088 sub name_short {
4089   my $self = shift;
4090   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4091 }
4092
4093 =item ship_name_short
4094
4095 Returns a name string for this (service/shipping) contact, either "Company"
4096 or "First Last".
4097
4098 =cut
4099
4100 sub ship_name_short {
4101   my $self = shift;
4102   $self->service_contact
4103     ? $self->ship_contact_firstlast
4104     : $self->name_short
4105 }
4106
4107 =item contact
4108
4109 Returns this customer's full (billing) contact name only, "Last, First"
4110
4111 =cut
4112
4113 sub contact {
4114   my $self = shift;
4115   $self->get('last'). ', '. $self->first;
4116 }
4117
4118 =item ship_contact
4119
4120 Returns this customer's full (shipping) contact name only, "Last, First"
4121
4122 =cut
4123
4124 sub ship_contact {
4125   my $self = shift;
4126   my $contact = $self->service_contact || $self;
4127   $contact->get('last') . ', ' . $contact->get('first');
4128 }
4129
4130 =item contact_firstlast
4131
4132 Returns this customers full (billing) contact name only, "First Last".
4133
4134 =cut
4135
4136 sub contact_firstlast {
4137   my $self = shift;
4138   $self->first. ' '. $self->get('last');
4139 }
4140
4141 =item ship_contact_firstlast
4142
4143 Returns this customer's full (shipping) contact name only, "First Last".
4144
4145 =cut
4146
4147 sub ship_contact_firstlast {
4148   my $self = shift;
4149   my $contact = $self->service_contact || $self;
4150   $contact->get('first') . ' '. $contact->get('last');
4151 }
4152
4153 sub bill_country_full {
4154   my $self = shift;
4155   $self->bill_location->country_full;
4156 }
4157
4158 sub ship_country_full {
4159   my $self = shift;
4160   $self->ship_location->country_full;
4161 }
4162
4163 =item county_state_county [ PREFIX ]
4164
4165 Returns a string consisting of just the county, state and country.
4166
4167 =cut
4168
4169 sub county_state_country {
4170   my $self = shift;
4171   my $locationnum;
4172   if ( @_ && $_[0] && $self->has_ship_address ) {
4173     $locationnum = $self->ship_locationnum;
4174   } else {
4175     $locationnum = $self->bill_locationnum;
4176   }
4177   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4178   $cust_location->county_state_country;
4179 }
4180
4181 =item geocode DATA_VENDOR
4182
4183 Returns a value for the customer location as encoded by DATA_VENDOR.
4184 Currently this only makes sense for "CCH" as DATA_VENDOR.
4185
4186 =cut
4187
4188 =item cust_status
4189
4190 =item status
4191
4192 Returns a status string for this customer, currently:
4193
4194 =over 4
4195
4196 =item prospect
4197
4198 No packages have ever been ordered.  Displayed as "No packages".
4199
4200 =item ordered
4201
4202 Recurring packages all are new (not yet billed).
4203
4204 =item active
4205
4206 One or more recurring packages is active.
4207
4208 =item inactive
4209
4210 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
4211
4212 =item suspended
4213
4214 All non-cancelled recurring packages are suspended.
4215
4216 =item cancelled
4217
4218 All recurring packages are cancelled.
4219
4220 =back
4221
4222 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4223 cust_main-status_module configuration option.
4224
4225 =cut
4226
4227 sub status { shift->cust_status(@_); }
4228
4229 sub cust_status {
4230   my $self = shift;
4231   return $self->hashref->{cust_status} if $self->hashref->{cust_status};
4232   for my $status ( FS::cust_main->statuses() ) {
4233     my $method = $status.'_sql';
4234     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4235     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4236     $sth->execute( ($self->custnum) x $numnum )
4237       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4238     if ( $sth->fetchrow_arrayref->[0] ) {
4239       $self->hashref->{cust_status} = $status;
4240       return $status;
4241     }
4242   }
4243 }
4244
4245 =item is_status_delay_cancel
4246
4247 Returns true if customer status is 'suspended'
4248 and all suspended cust_pkg return true for
4249 cust_pkg->is_status_delay_cancel.
4250
4251 This is not a real status, this only meant for hacking display
4252 values, because otherwise treating the customer as suspended is
4253 really the whole point of the delay_cancel option.
4254
4255 =cut
4256
4257 sub is_status_delay_cancel {
4258   my ($self) = @_;
4259   return 0 unless $self->status eq 'suspended';
4260   foreach my $cust_pkg ($self->ncancelled_pkgs) {
4261     return 0 unless $cust_pkg->is_status_delay_cancel;
4262   }
4263   return 1;
4264 }
4265
4266 =item ucfirst_cust_status
4267
4268 =item ucfirst_status
4269
4270 Deprecated, use the cust_status_label method instead.
4271
4272 Returns the status with the first character capitalized.
4273
4274 =cut
4275
4276 sub ucfirst_status {
4277   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4278   local($ucfirst_nowarn) = 1;
4279   shift->ucfirst_cust_status(@_);
4280 }
4281
4282 sub ucfirst_cust_status {
4283   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4284   my $self = shift;
4285   ucfirst($self->cust_status);
4286 }
4287
4288 =item cust_status_label
4289
4290 =item status_label
4291
4292 Returns the display label for this status.
4293
4294 =cut
4295
4296 sub status_label { shift->cust_status_label(@_); }
4297
4298 sub cust_status_label {
4299   my $self = shift;
4300   __PACKAGE__->statuslabels->{$self->cust_status};
4301 }
4302
4303 =item statuscolor
4304
4305 Returns a hex triplet color string for this customer's status.
4306
4307 =cut
4308
4309 sub statuscolor { shift->cust_statuscolor(@_); }
4310
4311 sub cust_statuscolor {
4312   my $self = shift;
4313   __PACKAGE__->statuscolors->{$self->cust_status};
4314 }
4315
4316 =item tickets [ STATUS ]
4317
4318 Returns an array of hashes representing the customer's RT tickets.
4319
4320 An optional status (or arrayref or hashref of statuses) may be specified.
4321
4322 =cut
4323
4324 sub tickets {
4325   my $self = shift;
4326   my $status = ( @_ && $_[0] ) ? shift : '';
4327
4328   my $num = $conf->config('cust_main-max_tickets') || 10;
4329   my @tickets = ();
4330
4331   if ( $conf->config('ticket_system') ) {
4332     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4333
4334       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4335                                                         $num,
4336                                                         undef,
4337                                                         $status,
4338                                                       )
4339                   };
4340
4341     } else {
4342
4343       foreach my $priority (
4344         $conf->config('ticket_system-custom_priority_field-values'), ''
4345       ) {
4346         last if scalar(@tickets) >= $num;
4347         push @tickets,
4348           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4349                                                  $num - scalar(@tickets),
4350                                                  $priority,
4351                                                  $status,
4352                                                )
4353            };
4354       }
4355     }
4356   }
4357   (@tickets);
4358 }
4359
4360 =item appointments [ STATUS ]
4361
4362 Returns an array of hashes representing the customer's RT tickets which
4363 are appointments.
4364
4365 =cut
4366
4367 sub appointments {
4368   my $self = shift;
4369   my $status = ( @_ && $_[0] ) ? shift : '';
4370
4371   return () unless $conf->config('ticket_system');
4372
4373   my $queueid = $conf->config('ticket_system-appointment-queueid');
4374
4375   @{ FS::TicketSystem->customer_tickets( $self->custnum,
4376                                          99,
4377                                          undef,
4378                                          $status,
4379                                          $queueid,
4380                                        )
4381   };
4382 }
4383
4384 # Return services representing svc_accts in customer support packages
4385 sub support_services {
4386   my $self = shift;
4387   my %packages = map { $_ => 1 } $conf->config('support_packages');
4388
4389   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4390     grep { $_->part_svc->svcdb eq 'svc_acct' }
4391     map { $_->cust_svc }
4392     grep { exists $packages{ $_->pkgpart } }
4393     $self->ncancelled_pkgs;
4394
4395 }
4396
4397 # Return a list of latitude/longitude for one of the services (if any)
4398 sub service_coordinates {
4399   my $self = shift;
4400
4401   my @svc_X =
4402     grep { $_->latitude && $_->longitude }
4403     map { $_->svc_x }
4404     map { $_->cust_svc }
4405     $self->ncancelled_pkgs;
4406
4407   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4408 }
4409
4410 =item masked FIELD
4411
4412 Returns a masked version of the named field
4413
4414 =cut
4415
4416 sub masked {
4417 my ($self,$field) = @_;
4418
4419 # Show last four
4420
4421 'x'x(length($self->getfield($field))-4).
4422   substr($self->getfield($field), (length($self->getfield($field))-4));
4423
4424 }
4425
4426 =item payment_history
4427
4428 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4429 cust_credit and cust_refund objects.  Each hashref has the following fields:
4430
4431 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4432
4433 I<date> - value of _date field, unix timestamp
4434
4435 I<date_pretty> - user-friendly date
4436
4437 I<description> - user-friendly description of item
4438
4439 I<amount> - impact of item on user's balance
4440 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4441 Not to be confused with the native 'amount' field in cust_credit, see below.
4442
4443 I<amount_pretty> - includes money char
4444
4445 I<balance> - customer balance, chronologically as of this item
4446
4447 I<balance_pretty> - includes money char
4448
4449 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4450
4451 I<paid> - amount paid for cust_pay records, undef for other types
4452
4453 I<credit> - amount credited for cust_credit records, undef for other types.
4454 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4455
4456 I<refund> - amount refunded for cust_refund records, undef for other types
4457
4458 The four table-specific keys always have positive values, whether they reflect charges or payments.
4459
4460 The following options may be passed to this method:
4461
4462 I<line_items> - if true, returns charges ('Line item') rather than invoices
4463
4464 I<start_date> - unix timestamp, only include records on or after.
4465 If specified, an item of type 'Previous' will also be included.
4466 It does not have table-specific fields.
4467
4468 I<end_date> - unix timestamp, only include records before
4469
4470 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4471
4472 I<conf> - optional already-loaded FS::Conf object.
4473
4474 =cut
4475
4476 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4477 # and also for sending customer statements, which should both be kept customer-friendly.
4478 # If you add anything that shouldn't be passed on through the API or exposed
4479 # to customers, add a new option to include it, don't include it by default
4480 sub payment_history {
4481   my $self = shift;
4482   my $opt = ref($_[0]) ? $_[0] : { @_ };
4483
4484   my $conf = $$opt{'conf'} || new FS::Conf;
4485   my $money_char = $conf->config("money_char") || '$',
4486
4487   #first load entire history,
4488   #need previous to calculate previous balance
4489   #loading after end_date shouldn't hurt too much?
4490   my @history = ();
4491   if ( $$opt{'line_items'} ) {
4492
4493     foreach my $cust_bill ( $self->cust_bill ) {
4494
4495       push @history, {
4496         'type'        => 'Line item',
4497         'description' => $_->desc( $self->locale ).
4498                            ( $_->sdate && $_->edate
4499                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4500                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4501                                : ''
4502                            ),
4503         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4504         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4505         'date'        => $cust_bill->_date,
4506         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4507       }
4508         foreach $cust_bill->cust_bill_pkg;
4509
4510     }
4511
4512   } else {
4513
4514     push @history, {
4515                      'type'        => 'Invoice',
4516                      'description' => 'Invoice #'. $_->display_invnum,
4517                      'amount'      => sprintf('%.2f', $_->charged ),
4518                      'charged'     => sprintf('%.2f', $_->charged ),
4519                      'date'        => $_->_date,
4520                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4521                    }
4522       foreach $self->cust_bill;
4523
4524   }
4525
4526   push @history, {
4527                    'type'        => 'Payment',
4528                    'description' => 'Payment', #XXX type
4529                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4530                    'paid'        => sprintf('%.2f', $_->paid ),
4531                    'date'        => $_->_date,
4532                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4533                  }
4534     foreach $self->cust_pay;
4535
4536   push @history, {
4537                    'type'        => 'Credit',
4538                    'description' => 'Credit', #more info?
4539                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4540                    'credit'      => sprintf('%.2f', $_->amount ),
4541                    'date'        => $_->_date,
4542                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4543                  }
4544     foreach $self->cust_credit;
4545
4546   push @history, {
4547                    'type'        => 'Refund',
4548                    'description' => 'Refund', #more info?  type, like payment?
4549                    'amount'      => $_->refund,
4550                    'refund'      => $_->refund,
4551                    'date'        => $_->_date,
4552                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4553                  }
4554     foreach $self->cust_refund;
4555
4556   #put it all in chronological order
4557   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4558
4559   #calculate balance, filter items outside date range
4560   my $previous = 0;
4561   my $balance = 0;
4562   my @out = ();
4563   foreach my $item (@history) {
4564     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4565     $balance += $$item{'amount'};
4566     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4567       $previous += $$item{'amount'};
4568       next;
4569     }
4570     $$item{'balance'} = sprintf("%.2f",$balance);
4571     foreach my $key ( qw(amount balance) ) {
4572       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4573     }
4574     push(@out,$item);
4575   }
4576
4577   # start with previous balance, if there was one
4578   if ($previous) {
4579     my $item = {
4580       'type'        => 'Previous',
4581       'description' => 'Previous balance',
4582       'amount'      => sprintf("%.2f",$previous),
4583       'balance'     => sprintf("%.2f",$previous),
4584       'date'        => $$opt{'start_date'},
4585       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4586     };
4587     #false laziness with above
4588     foreach my $key ( qw(amount balance) ) {
4589       $$item{$key.'_pretty'} = $$item{$key};
4590       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4591     }
4592     unshift(@out,$item);
4593   }
4594
4595   @out = reverse @history if $$opt{'reverse_sort'};
4596
4597   return @out;
4598 }
4599
4600 =item save_cust_payby
4601
4602 Saves a new cust_payby for this customer, replacing an existing entry only
4603 in select circumstances.  Does not validate input.
4604
4605 If auto is specified, marks this as the customer's primary method, or the
4606 specified weight.  Existing payment methods have their weight incremented as
4607 appropriate.
4608
4609 If bill_location is specified with auto, also sets location in cust_main.
4610
4611 Will not insert complete duplicates of existing records, or records in which the
4612 only difference from an existing record is to turn off automatic payment (will
4613 return without error.)  Will replace existing records in which the only difference
4614 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4615 Fields marked as preserved are optional, and existing values will not be overwritten with
4616 blanks when replacing.
4617
4618 Accepts the following named parameters:
4619
4620 =over 4
4621
4622 =item payment_payby
4623
4624 either CARD or CHEK
4625
4626 =item auto
4627
4628 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4629
4630 =item weight
4631
4632 optional, set higher than 1 for secondary, etc.
4633
4634 =item payinfo
4635
4636 required
4637
4638 =item paymask
4639
4640 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4641
4642 =item payname
4643
4644 required
4645
4646 =item payip
4647
4648 optional, will be preserved when replacing
4649
4650 =item paydate
4651
4652 CARD only, required
4653
4654 =item bill_location
4655
4656 CARD only, required, FS::cust_location object
4657
4658 =item paystart_month
4659
4660 CARD only, optional, will be preserved when replacing
4661
4662 =item paystart_year
4663
4664 CARD only, optional, will be preserved when replacing
4665
4666 =item payissue
4667
4668 CARD only, optional, will be preserved when replacing
4669
4670 =item paycvv
4671
4672 CARD only, only used if conf cvv-save is set appropriately
4673
4674 =item paytype
4675
4676 CHEK only
4677
4678 =item paystate
4679
4680 CHEK only
4681
4682 =item saved_cust_payby
4683
4684 scalar reference, for returning saved object
4685
4686 =back
4687
4688 =cut
4689
4690 #The code for this option is in place, but it's not currently used
4691 #
4692 # =item replace
4693 #
4694 # existing cust_payby object to be replaced (must match custnum)
4695
4696 # stateid/stateid_state/ss are not currently supported in cust_payby,
4697 # might not even work properly in 4.x, but will need to work here if ever added
4698
4699 sub save_cust_payby {
4700   my $self = shift;
4701   my %opt = @_;
4702
4703   my $old = $opt{'replace'};
4704   my $new = new FS::cust_payby { $old ? $old->hash : () };
4705   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4706   $new->set( 'custnum' => $self->custnum );
4707
4708   my $payby = $opt{'payment_payby'};
4709   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4710
4711   # don't allow turning off auto when replacing
4712   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4713
4714   my @check_existing; # payby relevant to this payment_payby
4715
4716   # set payby based on auto
4717   if ( $payby eq 'CARD' ) {
4718     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4719     @check_existing = qw( CARD DCRD );
4720   } elsif ( $payby eq 'CHEK' ) {
4721     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4722     @check_existing = qw( CHEK DCHK );
4723   }
4724
4725   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4726
4727   # basic fields
4728   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4729   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4730   $new->set( 'payname' => $opt{'payname'} );
4731   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4732
4733   my $conf = new FS::Conf;
4734
4735   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4736   if ( $payby eq 'CARD' &&
4737        ( (grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save'))
4738          || $conf->exists('business-onlinepayment-verification')
4739        )
4740   ) {
4741     $new->set( 'paycvv' => $opt{'paycvv'} );
4742   } else {
4743     $new->set( 'paycvv' => '');
4744   }
4745
4746   local $SIG{HUP} = 'IGNORE';
4747   local $SIG{INT} = 'IGNORE';
4748   local $SIG{QUIT} = 'IGNORE';
4749   local $SIG{TERM} = 'IGNORE';
4750   local $SIG{TSTP} = 'IGNORE';
4751   local $SIG{PIPE} = 'IGNORE';
4752
4753   my $oldAutoCommit = $FS::UID::AutoCommit;
4754   local $FS::UID::AutoCommit = 0;
4755   my $dbh = dbh;
4756
4757   # set fields specific to payment_payby
4758   if ( $payby eq 'CARD' ) {
4759     if ($opt{'bill_location'}) {
4760       $opt{'bill_location'}->set('custnum' => $self->custnum);
4761       my $error = $opt{'bill_location'}->find_or_insert;
4762       if ( $error ) {
4763         $dbh->rollback if $oldAutoCommit;
4764         return $error;
4765       }
4766       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4767     }
4768     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4769       $new->set( $field => $opt{$field} );
4770     }
4771   } else {
4772     foreach my $field ( qw(paytype paystate) ) {
4773       $new->set( $field => $opt{$field} );
4774     }
4775   }
4776
4777   # other cust_payby to compare this to
4778   my @existing = $self->cust_payby(@check_existing);
4779
4780   # fields that can overwrite blanks with values, but not values with blanks
4781   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4782
4783   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4784   unless ($old) {
4785     # generally, we don't want to overwrite existing cust_payby with this,
4786     # but we can replace if we're only marking it auto or adding a preserved field
4787     # and we can avoid saving a total duplicate or merely turning off auto
4788 PAYBYLOOP:
4789     foreach my $cust_payby (@existing) {
4790       # check fields that absolutely should not change
4791       foreach my $field ($new->fields) {
4792         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4793         next if grep(/^$field$/, @preserve );
4794         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4795       }
4796       # now check fields that can replace if one value is blank
4797       my $replace = 0;
4798       foreach my $field (@preserve) {
4799         if (
4800           ( $new->get($field) and !$cust_payby->get($field) ) or
4801           ( $cust_payby->get($field) and !$new->get($field) )
4802         ) {
4803           # prevention of overwriting values with blanks happens farther below
4804           $replace = 1;
4805         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4806           next PAYBYLOOP;
4807         }
4808       }
4809       unless ( $replace ) {
4810         # nearly identical, now check weight
4811         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4812           # ignore identical cust_payby, and ignore attempts to turn off auto
4813           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4814           $skip_cust_payby = 1;
4815           last PAYBYLOOP;
4816         }
4817         # otherwise, only change is to mark this as primary
4818       }
4819       # if we got this far, we're definitely replacing
4820       $old = $cust_payby;
4821       last PAYBYLOOP;
4822     } #PAYBYLOOP
4823   }
4824
4825   if ($old) {
4826     $new->set( 'custpaybynum' => $old->custpaybynum );
4827     # don't turn off automatic payment (but allow it to be turned on)
4828     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4829       $opt{'auto'} = 1;
4830       $new->set( 'payby' => $old->payby );
4831       $new->set( 'weight' => 1 );
4832     }
4833     # make sure we're not overwriting values with blanks
4834     foreach my $field (@preserve) {
4835       if ( $old->get($field) and !$new->get($field) ) {
4836         $new->set( $field => $old->get($field) );
4837       }
4838     }
4839   }
4840
4841   # only overwrite cust_main bill_location if auto
4842   if ($opt{'auto'} && $opt{'bill_location'}) {
4843     $self->set('bill_location' => $opt{'bill_location'});
4844     my $error = $self->replace;
4845     if ( $error ) {
4846       $dbh->rollback if $oldAutoCommit;
4847       return $error;
4848     }
4849   }
4850
4851   # done with everything except reweighting and saving cust_payby
4852   # still need to commit changes to cust_main and cust_location
4853   if ($skip_cust_payby) {
4854     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4855     return '';
4856   }
4857
4858   # re-weight existing primary cust_pay for this payby
4859   if ($opt{'auto'}) {
4860     foreach my $cust_payby (@existing) {
4861       # relies on cust_payby return order
4862       last unless $cust_payby->payby !~ /^D/;
4863       last if $cust_payby->weight > 1;
4864       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4865       next if $cust_payby->weight < ($opt{'weight'} || 1);
4866       $cust_payby->weight( $cust_payby->weight + 1 );
4867       my $error = $cust_payby->replace;
4868       if ( $error ) {
4869         $dbh->rollback if $oldAutoCommit;
4870         return "Error reweighting cust_payby: $error";
4871       }
4872     }
4873   }
4874
4875   # finally, save cust_payby
4876   my $error = $old ? $new->replace($old) : $new->insert;
4877   if ( $error ) {
4878     $dbh->rollback if $oldAutoCommit;
4879     return $error;
4880   }
4881
4882   ${$opt{'saved_cust_payby'}} = $new
4883     if $opt{'saved_cust_payby'};
4884
4885   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4886   '';
4887
4888 }
4889
4890 =item remove_cvv_from_cust_payby PAYINFO
4891
4892 Removes paycvv from associated cust_payby with matching PAYINFO.
4893
4894 =cut
4895
4896 sub remove_cvv_from_cust_payby {
4897   my ($self,$payinfo) = @_;
4898
4899   my $oldAutoCommit = $FS::UID::AutoCommit;
4900   local $FS::UID::AutoCommit = 0;
4901   my $dbh = dbh;
4902
4903   foreach my $cust_payby ( qsearch('cust_payby',{ custnum => $self->custnum }) ) {
4904     next unless $cust_payby->payinfo eq $payinfo; # can't qsearch on payinfo
4905     $cust_payby->paycvv('');
4906     my $error = $cust_payby->replace;
4907     if ($error) {
4908       $dbh->rollback if $oldAutoCommit;
4909       return $error;
4910     }
4911   }
4912
4913   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4914   '';
4915 }
4916
4917 =back
4918
4919 =head1 CLASS METHODS
4920
4921 =over 4
4922
4923 =item statuses
4924
4925 Class method that returns the list of possible status strings for customers
4926 (see L<the status method|/status>).  For example:
4927
4928   @statuses = FS::cust_main->statuses();
4929
4930 =cut
4931
4932 sub statuses {
4933   my $self = shift;
4934   keys %{ $self->statuscolors };
4935 }
4936
4937 =item cust_status_sql
4938
4939 Returns an SQL fragment to determine the status of a cust_main record, as a
4940 string.
4941
4942 =cut
4943
4944 sub cust_status_sql {
4945   my $sql = 'CASE';
4946   for my $status ( FS::cust_main->statuses() ) {
4947     my $method = $status.'_sql';
4948     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4949   }
4950   $sql .= ' END';
4951   return $sql;
4952 }
4953
4954
4955 =item prospect_sql
4956
4957 Returns an SQL expression identifying prospective cust_main records (customers
4958 with no packages ever ordered)
4959
4960 =cut
4961
4962 use vars qw($select_count_pkgs);
4963 $select_count_pkgs =
4964   "SELECT COUNT(*) FROM cust_pkg
4965     WHERE cust_pkg.custnum = cust_main.custnum";
4966
4967 sub select_count_pkgs_sql {
4968   $select_count_pkgs;
4969 }
4970
4971 sub prospect_sql {
4972   " 0 = ( $select_count_pkgs ) ";
4973 }
4974
4975 =item ordered_sql
4976
4977 Returns an SQL expression identifying ordered cust_main records (customers with
4978 no active packages, but recurring packages not yet setup or one time charges
4979 not yet billed).
4980
4981 =cut
4982
4983 sub ordered_sql {
4984   FS::cust_main->none_active_sql.
4985   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4986 }
4987
4988 =item active_sql
4989
4990 Returns an SQL expression identifying active cust_main records (customers with
4991 active recurring packages).
4992
4993 =cut
4994
4995 sub active_sql {
4996   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4997 }
4998
4999 =item none_active_sql
5000
5001 Returns an SQL expression identifying cust_main records with no active
5002 recurring packages.  This includes customers of status prospect, ordered,
5003 inactive, and suspended.
5004
5005 =cut
5006
5007 sub none_active_sql {
5008   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
5009 }
5010
5011 =item inactive_sql
5012
5013 Returns an SQL expression identifying inactive cust_main records (customers with
5014 no active recurring packages, but otherwise unsuspended/uncancelled).
5015
5016 =cut
5017
5018 sub inactive_sql {
5019   FS::cust_main->none_active_sql.
5020   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
5021 }
5022
5023 =item susp_sql
5024 =item suspended_sql
5025
5026 Returns an SQL expression identifying suspended cust_main records.
5027
5028 =cut
5029
5030
5031 sub suspended_sql { susp_sql(@_); }
5032 sub susp_sql {
5033   FS::cust_main->none_active_sql.
5034   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
5035 }
5036
5037 =item cancel_sql
5038 =item cancelled_sql
5039
5040 Returns an SQL expression identifying cancelled cust_main records.
5041
5042 =cut
5043
5044 sub cancel_sql { shift->cancelled_sql(@_); }
5045
5046 =item uncancel_sql
5047 =item uncancelled_sql
5048
5049 Returns an SQL expression identifying un-cancelled cust_main records.
5050
5051 =cut
5052
5053 sub uncancelled_sql { uncancel_sql(@_); }
5054 sub uncancel_sql {
5055   my $self = shift;
5056   "( NOT (".$self->cancelled_sql.") )"; #sensitive to cust_main-status_module
5057 }
5058
5059 =item balance_sql
5060
5061 Returns an SQL fragment to retreive the balance.
5062
5063 =cut
5064
5065 sub balance_sql { "
5066     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
5067         WHERE cust_bill.custnum   = cust_main.custnum     )
5068   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
5069         WHERE cust_pay.custnum    = cust_main.custnum     )
5070   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
5071         WHERE cust_credit.custnum = cust_main.custnum     )
5072   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
5073         WHERE cust_refund.custnum = cust_main.custnum     )
5074 "; }
5075
5076 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
5077
5078 Returns an SQL fragment to retreive the balance for this customer, optionally
5079 considering invoices with date earlier than START_TIME, and not
5080 later than END_TIME (total_owed_date minus total_unapplied_credits minus
5081 total_unapplied_payments).
5082
5083 Times are specified as SQL fragments or numeric
5084 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5085 L<Date::Parse> for conversion functions.  The empty string can be passed
5086 to disable that time constraint completely.
5087
5088 Available options are:
5089
5090 =over 4
5091
5092 =item unapplied_date
5093
5094 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
5095
5096 =item total
5097
5098 (unused.  obsolete?)
5099 set to true to remove all customer comparison clauses, for totals
5100
5101 =item where
5102
5103 (unused.  obsolete?)
5104 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
5105
5106 =item join
5107
5108 (unused.  obsolete?)
5109 JOIN clause (typically used with the total option)
5110
5111 =item cutoff
5112
5113 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
5114 time will be ignored.  Note that START_TIME and END_TIME only limit the date
5115 range for invoices and I<unapplied> payments, credits, and refunds.
5116
5117 =back
5118
5119 =cut
5120
5121 sub balance_date_sql {
5122   my( $class, $start, $end, %opt ) = @_;
5123
5124   my $cutoff = $opt{'cutoff'};
5125
5126   my $owed         = FS::cust_bill->owed_sql($cutoff);
5127   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
5128   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
5129   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5130
5131   my $j = $opt{'join'} || '';
5132
5133   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
5134   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
5135   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
5136   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
5137
5138   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
5139     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
5140     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
5141     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
5142   ";
5143
5144 }
5145
5146 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
5147
5148 Returns an SQL fragment to retreive the total unapplied payments for this
5149 customer, only considering payments with date earlier than START_TIME, and
5150 optionally not later than END_TIME.
5151
5152 Times are specified as SQL fragments or numeric
5153 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5154 L<Date::Parse> for conversion functions.  The empty string can be passed
5155 to disable that time constraint completely.
5156
5157 Available options are:
5158
5159 =cut
5160
5161 sub unapplied_payments_date_sql {
5162   my( $class, $start, $end, %opt ) = @_;
5163
5164   my $cutoff = $opt{'cutoff'};
5165
5166   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5167
5168   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
5169                                                           'unapplied_date'=>1 );
5170
5171   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
5172 }
5173
5174 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
5175
5176 Helper method for balance_date_sql; name (and usage) subject to change
5177 (suggestions welcome).
5178
5179 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
5180 cust_refund, cust_credit or cust_pay).
5181
5182 If TABLE is "cust_bill" or the unapplied_date option is true, only
5183 considers records with date earlier than START_TIME, and optionally not
5184 later than END_TIME .
5185
5186 =cut
5187
5188 sub _money_table_where {
5189   my( $class, $table, $start, $end, %opt ) = @_;
5190
5191   my @where = ();
5192   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
5193   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
5194     push @where, "$table._date <= $start" if defined($start) && length($start);
5195     push @where, "$table._date >  $end"   if defined($end)   && length($end);
5196   }
5197   push @where, @{$opt{'where'}} if $opt{'where'};
5198   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
5199
5200   $where;
5201
5202 }
5203
5204 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
5205 use FS::cust_main::Search;
5206 sub search {
5207   my $class = shift;
5208   FS::cust_main::Search->search(@_);
5209 }
5210
5211 =back
5212
5213 =head1 SUBROUTINES
5214
5215 =over 4
5216
5217 #=item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5218
5219 #Deprecated.  Use event notification and message templates
5220 #(L<FS::msg_template>) instead.
5221
5222 #Sends a templated email notification to the customer (see L<Text::Template>).
5223
5224 #OPTIONS is a hash and may include
5225
5226 #I<from> - the email sender (default is invoice_from)
5227
5228 #I<to> - comma-separated scalar or arrayref of recipients
5229 #   (default is invoicing_list)
5230
5231 #I<subject> - The subject line of the sent email notification
5232 #   (default is "Notice from company_name")
5233
5234 #I<extra_fields> - a hashref of name/value pairs which will be substituted
5235 #   into the template
5236
5237 #The following variables are vavailable in the template.
5238
5239 #I<$first> - the customer first name
5240 #I<$last> - the customer last name
5241 #I<$company> - the customer company
5242 #I<$payby> - a description of the method of payment for the customer
5243 #            # would be nice to use FS::payby::shortname
5244 #I<$payinfo> - the account information used to collect for this customer
5245 #I<$expdate> - the expiration of the customer payment in seconds from epoch
5246
5247 #=cut
5248
5249 #sub notify {
5250 #  my ($self, $template, %options) = @_;
5251
5252 #  return unless $conf->exists($template);
5253
5254 #  my $from = $conf->invoice_from_full($self->agentnum)
5255 #    if $conf->exists('invoice_from', $self->agentnum);
5256 #  $from = $options{from} if exists($options{from});
5257
5258 #  my $to = join(',', $self->invoicing_list_emailonly);
5259 #  $to = $options{to} if exists($options{to});
5260 #
5261 #  my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
5262 #    if $conf->exists('company_name', $self->agentnum);
5263 #  $subject = $options{subject} if exists($options{subject});
5264
5265 #  my $notify_template = new Text::Template (TYPE => 'ARRAY',
5266 #                                            SOURCE => [ map "$_\n",
5267 #                                              $conf->config($template)]
5268 #                                           )
5269 #    or die "can't create new Text::Template object: Text::Template::ERROR";
5270 #  $notify_template->compile()
5271 #    or die "can't compile template: Text::Template::ERROR";
5272
5273 #  $FS::notify_template::_template::company_name =
5274 #    $conf->config('company_name', $self->agentnum);
5275 #  $FS::notify_template::_template::company_address =
5276 #    join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
5277
5278 #  my $paydate = $self->paydate || '2037-12-31';
5279 #  $FS::notify_template::_template::first = $self->first;
5280 #  $FS::notify_template::_template::last = $self->last;
5281 #  $FS::notify_template::_template::company = $self->company;
5282 #  $FS::notify_template::_template::payinfo = $self->mask_payinfo;
5283 #  my $payby = $self->payby;
5284 #  my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5285 #  my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5286
5287 #  #credit cards expire at the end of the month/year of their exp date
5288 #  if ($payby eq 'CARD' || $payby eq 'DCRD') {
5289 #    $FS::notify_template::_template::payby = 'credit card';
5290 #    ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5291 #    $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5292 #    $expire_time--;
5293 #  }elsif ($payby eq 'COMP') {
5294 #    $FS::notify_template::_template::payby = 'complimentary account';
5295 #  }else{
5296 #    $FS::notify_template::_template::payby = 'current method';
5297 #  }
5298 #  $FS::notify_template::_template::expdate = $expire_time;
5299
5300 #  for (keys %{$options{extra_fields}}){
5301 #    no strict "refs";
5302 #    ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
5303 #  }
5304
5305 #  send_email(from => $from,
5306 #             to => $to,
5307 #             subject => $subject,
5308 #             body => $notify_template->fill_in( PACKAGE =>
5309 #                                                'FS::notify_template::_template'                                              ),
5310 #            );
5311
5312 #}
5313
5314 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5315
5316 Generates a templated notification to the customer (see L<Text::Template>).
5317
5318 OPTIONS is a hash and may include
5319
5320 I<extra_fields> - a hashref of name/value pairs which will be substituted
5321    into the template.  These values may override values mentioned below
5322    and those from the customer record.
5323
5324 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
5325
5326 The following variables are available in the template instead of or in addition
5327 to the fields of the customer record.
5328
5329 I<$payby> - a description of the method of payment for the customer
5330             # would be nice to use FS::payby::shortname
5331 I<$payinfo> - the masked account information used to collect for this customer
5332 I<$expdate> - the expiration of the customer payment method in seconds from epoch
5333 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
5334
5335 =cut
5336
5337 # a lot like cust_bill::print_latex
5338 sub generate_letter {
5339   my ($self, $template, %options) = @_;
5340
5341   warn "Template $template does not exist" && return
5342     unless $conf->exists($template) || $options{'template_text'};
5343
5344   my $template_source = $options{'template_text'}
5345                         ? [ $options{'template_text'} ]
5346                         : [ map "$_\n", $conf->config($template) ];
5347
5348   my $letter_template = new Text::Template
5349                         ( TYPE       => 'ARRAY',
5350                           SOURCE     => $template_source,
5351                           DELIMITERS => [ '[@--', '--@]' ],
5352                         )
5353     or die "can't create new Text::Template object: Text::Template::ERROR";
5354
5355   $letter_template->compile()
5356     or die "can't compile template: Text::Template::ERROR";
5357
5358   my %letter_data = map { $_ => $self->$_ } $self->fields;
5359   $letter_data{payinfo} = $self->mask_payinfo;
5360
5361   #my $paydate = $self->paydate || '2037-12-31';
5362   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
5363
5364   my $payby = $self->payby;
5365   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5366   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5367
5368   #credit cards expire at the end of the month/year of their exp date
5369   if ($payby eq 'CARD' || $payby eq 'DCRD') {
5370     $letter_data{payby} = 'credit card';
5371     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5372     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5373     $expire_time--;
5374   }elsif ($payby eq 'COMP') {
5375     $letter_data{payby} = 'complimentary account';
5376   }else{
5377     $letter_data{payby} = 'current method';
5378   }
5379   $letter_data{expdate} = $expire_time;
5380
5381   for (keys %{$options{extra_fields}}){
5382     $letter_data{$_} = $options{extra_fields}->{$_};
5383   }
5384
5385   unless(exists($letter_data{returnaddress})){
5386     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
5387                                                   $self->agent_template)
5388                      );
5389     if ( length($retadd) ) {
5390       $letter_data{returnaddress} = $retadd;
5391     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
5392       $letter_data{returnaddress} =
5393         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
5394                           s/$/\\\\\*/;
5395                           $_;
5396                         }
5397                     ( $conf->config('company_name', $self->agentnum),
5398                       $conf->config('company_address', $self->agentnum),
5399                     )
5400         );
5401     } else {
5402       $letter_data{returnaddress} = '~';
5403     }
5404   }
5405
5406   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
5407
5408   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
5409
5410   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
5411
5412   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5413                            DIR      => $dir,
5414                            SUFFIX   => '.eps',
5415                            UNLINK   => 0,
5416                          ) or die "can't open temp file: $!\n";
5417   print $lh $conf->config_binary('logo.eps', $self->agentnum)
5418     or die "can't write temp file: $!\n";
5419   close $lh;
5420   $letter_data{'logo_file'} = $lh->filename;
5421
5422   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5423                            DIR      => $dir,
5424                            SUFFIX   => '.tex',
5425                            UNLINK   => 0,
5426                          ) or die "can't open temp file: $!\n";
5427
5428   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
5429   close $fh;
5430   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
5431   return ($1, $letter_data{'logo_file'});
5432
5433 }
5434
5435 =item print_ps TEMPLATE
5436
5437 Returns an postscript letter filled in from TEMPLATE, as a scalar.
5438
5439 =cut
5440
5441 sub print_ps {
5442   my $self = shift;
5443   my($file, $lfile) = $self->generate_letter(@_);
5444   my $ps = FS::Misc::generate_ps($file);
5445   unlink($file.'.tex');
5446   unlink($lfile);
5447
5448   $ps;
5449 }
5450
5451 =item print TEMPLATE
5452
5453 Prints the filled in template.
5454
5455 TEMPLATE is the name of a L<Text::Template> to fill in and print.
5456
5457 =cut
5458
5459 sub queueable_print {
5460   my %opt = @_;
5461
5462   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
5463     or die "invalid customer number: " . $opt{custnum};
5464
5465 #do not backport this change to 3.x
5466 #  my $error = $self->print( { 'template' => $opt{template} } );
5467   my $error = $self->print( $opt{'template'} );
5468   die $error if $error;
5469 }
5470
5471 sub print {
5472   my ($self, $template) = (shift, shift);
5473   do_print(
5474     [ $self->print_ps($template) ],
5475     'agentnum' => $self->agentnum,
5476   );
5477 }
5478
5479 #these three subs should just go away once agent stuff is all config overrides
5480
5481 sub agent_template {
5482   my $self = shift;
5483   $self->_agent_plandata('agent_templatename');
5484 }
5485
5486 sub agent_invoice_from {
5487   my $self = shift;
5488   $self->_agent_plandata('agent_invoice_from');
5489 }
5490
5491 sub _agent_plandata {
5492   my( $self, $option ) = @_;
5493
5494   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
5495   #agent-specific Conf
5496
5497   use FS::part_event::Condition;
5498
5499   my $agentnum = $self->agentnum;
5500
5501   my $regexp = regexp_sql();
5502
5503   my $part_event_option =
5504     qsearchs({
5505       'select'    => 'part_event_option.*',
5506       'table'     => 'part_event_option',
5507       'addl_from' => q{
5508         LEFT JOIN part_event USING ( eventpart )
5509         LEFT JOIN part_event_option AS peo_agentnum
5510           ON ( part_event.eventpart = peo_agentnum.eventpart
5511                AND peo_agentnum.optionname = 'agentnum'
5512                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
5513              )
5514         LEFT JOIN part_event_condition
5515           ON ( part_event.eventpart = part_event_condition.eventpart
5516                AND part_event_condition.conditionname = 'cust_bill_age'
5517              )
5518         LEFT JOIN part_event_condition_option
5519           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
5520                AND part_event_condition_option.optionname = 'age'
5521              )
5522       },
5523       #'hashref'   => { 'optionname' => $option },
5524       #'hashref'   => { 'part_event_option.optionname' => $option },
5525       'extra_sql' =>
5526         " WHERE part_event_option.optionname = ". dbh->quote($option).
5527         " AND action = 'cust_bill_send_agent' ".
5528         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
5529         " AND peo_agentnum.optionname = 'agentnum' ".
5530         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
5531         " ORDER BY
5532            CASE WHEN part_event_condition_option.optionname IS NULL
5533            THEN -1
5534            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5535         " END
5536           , part_event.weight".
5537         " LIMIT 1"
5538     });
5539
5540   unless ( $part_event_option ) {
5541     return $self->agent->invoice_template || ''
5542       if $option eq 'agent_templatename';
5543     return '';
5544   }
5545
5546   $part_event_option->optionvalue;
5547
5548 }
5549
5550 sub process_o2m_qsearch {
5551   my $self = shift;
5552   my $table = shift;
5553   return qsearch($table, @_) unless $table eq 'contact';
5554
5555   my $hashref = shift;
5556   my %hash = %$hashref;
5557   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5558     or die 'guru meditation #4343';
5559
5560   qsearch({ 'table'     => 'contact',
5561             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5562             'hashref'   => \%hash,
5563             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5564                            " cust_contact.custnum = $custnum "
5565          });
5566 }
5567
5568 sub process_o2m_qsearchs {
5569   my $self = shift;
5570   my $table = shift;
5571   return qsearchs($table, @_) unless $table eq 'contact';
5572
5573   my $hashref = shift;
5574   my %hash = %$hashref;
5575   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5576     or die 'guru meditation #2121';
5577
5578   qsearchs({ 'table'     => 'contact',
5579              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5580              'hashref'   => \%hash,
5581              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5582                             " cust_contact.custnum = $custnum "
5583           });
5584 }
5585
5586 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5587
5588 Subroutine (not a method), designed to be called from the queue.
5589
5590 Takes a list of options and values.
5591
5592 Pulls up the customer record via the custnum option and calls bill_and_collect.
5593
5594 =cut
5595
5596 sub queued_bill {
5597   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5598
5599   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5600   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5601
5602   #without this errors don't get rolled back
5603   $args{'fatal'} = 1; # runs from job queue, will be caught
5604
5605   $cust_main->bill_and_collect( %args );
5606 }
5607
5608 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5609
5610 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5611 C<collect> part.  This is used in batch tax calculation, where invoice
5612 generation and collection events have to be completely separated.
5613
5614 =cut
5615
5616 sub queued_collect {
5617   my (%args) = @_;
5618   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5619
5620   $cust_main->collect(%args);
5621 }
5622
5623 sub process_bill_and_collect {
5624   my $job = shift;
5625   my $param = shift;
5626   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5627       or die "custnum '$param->{custnum}' not found!\n";
5628   $param->{'job'}   = $job;
5629   $param->{'fatal'} = 1; # runs from job queue, will be caught
5630   $param->{'retry'} = 1;
5631
5632   $cust_main->bill_and_collect( %$param );
5633 }
5634
5635 #starting to take quite a while for big dbs
5636 #   (JRNL: journaled so it only happens once per database)
5637 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5638 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5639 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5640 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5641 # JRNL leading/trailing spaces in first, last, company
5642 # JRNL migrate to cust_payby
5643 # - otaker upgrade?  journal and call it good?  (double check to make sure
5644 #    we're not still setting otaker here)
5645 #
5646 #only going to get worse with new location stuff...
5647
5648 sub _upgrade_data { #class method
5649   my ($class, %opts) = @_;
5650
5651   my @statements = (
5652     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5653   );
5654
5655   #this seems to be the only expensive one.. why does it take so long?
5656   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5657     push @statements,
5658       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5659     FS::upgrade_journal->set_done('cust_main__signupdate');
5660   }
5661
5662   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5663
5664     # fix yyyy-m-dd formatted paydates
5665     if ( driver_name =~ /^mysql/i ) {
5666       push @statements,
5667       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5668     } else { # the SQL standard
5669       push @statements,
5670       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5671     }
5672     FS::upgrade_journal->set_done('cust_main__paydate');
5673   }
5674
5675   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5676
5677     push @statements, #fix the weird BILL with a cc# in payinfo problem
5678       #DCRD to be safe
5679       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5680
5681     FS::upgrade_journal->set_done('cust_main__payinfo');
5682
5683   }
5684
5685   my $t = time;
5686   foreach my $sql ( @statements ) {
5687     my $sth = dbh->prepare($sql) or die dbh->errstr;
5688     $sth->execute or die $sth->errstr;
5689     #warn ( (time - $t). " seconds\n" );
5690     #$t = time;
5691   }
5692
5693   local($ignore_expired_card) = 1;
5694   local($ignore_banned_card) = 1;
5695   local($skip_fuzzyfiles) = 1;
5696   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5697
5698   unless ( FS::upgrade_journal->is_done('cust_main__cust_payby') ) {
5699
5700     #we don't want to decrypt them, just stuff them as-is into cust_payby
5701     local(@encrypted_fields) = ();
5702
5703     local($FS::cust_payby::ignore_expired_card) = 1;
5704     local($FS::cust_payby::ignore_banned_card)  = 1;
5705     local($FS::cust_payby::ignore_cardtype)     = 1;
5706
5707     my @payfields = qw( payby payinfo paycvv paymask
5708                         paydate paystart_month paystart_year payissue
5709                         payname paystate paytype payip
5710                       );
5711
5712     my $search = new FS::Cursor {
5713       'table'     => 'cust_main',
5714       'extra_sql' => " WHERE ( payby IS NOT NULL AND payby != '' ) ",
5715     };
5716
5717     while (my $cust_main = $search->fetch) {
5718
5719       unless ( $cust_main->payby =~ /^(BILL|COMP)$/ ) {
5720
5721         my $cust_payby = new FS::cust_payby {
5722           'custnum' => $cust_main->custnum,
5723           'weight'  => 1,
5724           map { $_ => $cust_main->$_(); } @payfields
5725         };
5726
5727         my $error = $cust_payby->insert;
5728         die $error if $error;
5729
5730       }
5731
5732       # at the time we do this, also migrate paytype into cust_pay_batch
5733       # so that batches that are open before the migration can still be
5734       # processed
5735       my @cust_pay_batch = qsearch('cust_pay_batch', {
5736           'custnum' => $cust_main->custnum,
5737           'payby'   => 'CHEK',
5738           'paytype' => '',
5739       });
5740       foreach my $cust_pay_batch (@cust_pay_batch) {
5741         $cust_pay_batch->set('paytype', $cust_main->get('paytype'));
5742         my $error = $cust_pay_batch->replace;
5743         die "$error (setting cust_pay_batch.paytype)" if $error;
5744       }
5745
5746       $cust_main->complimentary('Y') if $cust_main->payby eq 'COMP';
5747
5748       $cust_main->invoice_attn( $cust_main->payname )
5749         if $cust_main->payby eq 'BILL' && $cust_main->payname;
5750       $cust_main->po_number( $cust_main->payinfo )
5751         if $cust_main->payby eq 'BILL' && $cust_main->payinfo;
5752
5753       $cust_main->setfield($_, '') foreach @payfields;
5754       my $error = $cust_main->replace;
5755       die "Error upgradging payment information for custnum ".
5756           $cust_main->custnum. ": $error"
5757         if $error;
5758
5759     };
5760
5761     FS::upgrade_journal->set_done('cust_main__cust_payby');
5762   }
5763
5764   FS::cust_main::Location->_upgrade_data(%opts);
5765
5766   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5767
5768     foreach my $cust_main ( qsearch({
5769       'table'     => 'cust_main',
5770       'hashref'   => {},
5771       'extra_sql' => 'WHERE '.
5772                        join(' OR ',
5773                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5774                            qw( first last company )
5775                        ),
5776     }) ) {
5777       my $error = $cust_main->replace;
5778       die $error if $error;
5779     }
5780
5781     FS::upgrade_journal->set_done('cust_main__trimspaces');
5782
5783   }
5784
5785   $class->_upgrade_otaker(%opts);
5786
5787 }
5788
5789 =back
5790
5791 =head1 BUGS
5792
5793 The delete method.
5794
5795 The delete method should possibly take an FS::cust_main object reference
5796 instead of a scalar customer number.
5797
5798 Bill and collect options should probably be passed as references instead of a
5799 list.
5800
5801 There should probably be a configuration file with a list of allowed credit
5802 card types.
5803
5804 No multiple currency support (probably a larger project than just this module).
5805
5806 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5807
5808 Birthdates rely on negative epoch values.
5809
5810 The payby for card/check batches is broken.  With mixed batching, bad
5811 things will happen.
5812
5813 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5814
5815 =head1 SEE ALSO
5816
5817 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5818 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5819 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5820
5821 =cut
5822
5823 1;
5824