FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $conf $DEBUG $import );
   5 use vars qw( $realtime_bop_decline_quiet ); #ugh
   6 use Safe;
   7 use Carp;
   8 use Exporter;
   9 BEGIN {
  10   eval "use Time::Local;";
  11   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  12     if $] < 5.006 && !defined($Time::Local::VERSION);
  13   #eval "use Time::Local qw(timelocal timelocal_nocheck);";
  14   eval "use Time::Local qw(timelocal_nocheck);";
  15 }
  16 use Date::Format;
  17 #use Date::Manip;
  18 use String::Approx qw(amatch);
  19 use Business::CreditCard;
  20 use FS::UID qw( getotaker dbh );
  21 use FS::Record qw( qsearchs qsearch dbdef );
  22 use FS::Misc qw( send_email );
  23 use FS::cust_pkg;
  24 use FS::cust_bill;
  25 use FS::cust_bill_pkg;
  26 use FS::cust_pay;
  27 use FS::cust_pay_void;
  28 use FS::cust_credit;
  29 use FS::cust_refund;
  30 use FS::part_referral;
  31 use FS::cust_main_county;
  32 use FS::agent;
  33 use FS::cust_main_invoice;
  34 use FS::cust_credit_bill;
  35 use FS::cust_bill_pay;
  36 use FS::prepay_credit;
  37 use FS::queue;
  38 use FS::part_pkg;
  39 use FS::part_bill_event;
  40 use FS::cust_bill_event;
  41 use FS::cust_tax_exempt;
  42 use FS::type_pkgs;
  43 use FS::Msgcat qw(gettext);
  44
  45 @ISA = qw( FS::Record );
  46
  47 @EXPORT_OK = qw( smart_search );
  48
  49 $realtime_bop_decline_quiet = 0;
  50
  51 $DEBUG = 0;
  52 #$DEBUG = 1;
  53
  54 $import = 0;
  55
  56 #ask FS::UID to run this stuff for us later
  57 #$FS::UID::callback{'FS::cust_main'} = sub {
  58 install_callback FS::UID sub {
  59   $conf = new FS::Conf;
  60   #yes, need it for stuff below (prolly should be cached)
  61 };
  62
  63 sub _cache {
  64   my $self = shift;
  65   my ( $hashref, $cache ) = @_;
  66   if ( exists $hashref->{'pkgnum'} ) {
  67 #    #@{ $self->{'_pkgnum'} } = ();
  68     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
  69     $self->{'_pkgnum'} = $subcache;
  70     #push @{ $self->{'_pkgnum'} },
  71     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
  72   }
  73 }
  74
  75 =head1 NAME
  76
  77 FS::cust_main - Object methods for cust_main records
  78
  79 =head1 SYNOPSIS
  80
  81   use FS::cust_main;
  82
  83   $record = new FS::cust_main \%hash;
  84   $record = new FS::cust_main { 'column' => 'value' };
  85
  86   $error = $record->insert;
  87
  88   $error = $new_record->replace($old_record);
  89
  90   $error = $record->delete;
  91
  92   $error = $record->check;
  93
  94   @cust_pkg = $record->all_pkgs;
  95
  96   @cust_pkg = $record->ncancelled_pkgs;
  97
  98   @cust_pkg = $record->suspended_pkgs;
  99
 100   $error = $record->bill;
 101   $error = $record->bill %options;
 102   $error = $record->bill 'time' => $time;
 103
 104   $error = $record->collect;
 105   $error = $record->collect %options;
 106   $error = $record->collect 'invoice_time'   => $time,
 107                             'batch_card'     => 'yes',
 108                             'report_badcard' => 'yes',
 109                           ;
 110
 111 =head1 DESCRIPTION
 112
 113 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 114 FS::Record.  The following fields are currently supported:
 115
 116 =over 4
 117
 118 =item custnum - primary key (assigned automatically for new customers)
 119
 120 =item agentnum - agent (see L<FS::agent>)
 121
 122 =item refnum - Advertising source (see L<FS::part_referral>)
 123
 124 =item first - name
 125
 126 =item last - name
 127
 128 =item ss - social security number (optional)
 129
 130 =item company - (optional)
 131
 132 =item address1
 133
 134 =item address2 - (optional)
 135
 136 =item city
 137
 138 =item county - (optional, see L<FS::cust_main_county>)
 139
 140 =item state - (see L<FS::cust_main_county>)
 141
 142 =item zip
 143
 144 =item country - (see L<FS::cust_main_county>)
 145
 146 =item daytime - phone (optional)
 147
 148 =item night - phone (optional)
 149
 150 =item fax - phone (optional)
 151
 152 =item ship_first - name
 153
 154 =item ship_last - name
 155
 156 =item ship_company - (optional)
 157
 158 =item ship_address1
 159
 160 =item ship_address2 - (optional)
 161
 162 =item ship_city
 163
 164 =item ship_county - (optional, see L<FS::cust_main_county>)
 165
 166 =item ship_state - (see L<FS::cust_main_county>)
 167
 168 =item ship_zip
 169
 170 =item ship_country - (see L<FS::cust_main_county>)
 171
 172 =item ship_daytime - phone (optional)
 173
 174 =item ship_night - phone (optional)
 175
 176 =item ship_fax - phone (optional)
 177
 178 =item payby - I<CARD> (credit card - automatic), I<DCRD> (credit card - on-demand), I<CHEK> (electronic check - automatic), I<DCHK> (electronic check - on-demand), I<LECB> (Phone bill billing), I<BILL> (billing), I<COMP> (free), or I<PREPAY> (special billing type: applies a payment from a prepaid card - see L<FS::prepay_credit> - and sets billing type to I<BILL>)
 179
 180 =item payinfo - card number, P.O., comp issuer (4-8 lowercase alphanumerics; think username) or prepayment identifier (see L<FS::prepay_credit>)
 181
 182 =item paycvv - Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 183
 184 =item paydate - expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 185
 186 =item payname - name on card or billing name
 187
 188 =item tax - tax exempt, empty or `Y'
 189
 190 =item otaker - order taker (assigned automatically, see L<FS::UID>)
 191
 192 =item comments - comments (optional)
 193
 194 =item referral_custnum - referring customer number
 195
 196 =back
 197
 198 =head1 METHODS
 199
 200 =over 4
 201
 202 =item new HASHREF
 203
 204 Creates a new customer.  To add the customer to the database, see L<"insert">.
 205
 206 Note that this stores the hash reference, not a distinct copy of the hash it
 207 points to.  You can ask the object for a copy with the I<hash> method.
 208
 209 =cut
 210
 211 sub table { 'cust_main'; }
 212
 213 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 214
 215 Adds this customer to the database.  If there is an error, returns the error,
 216 otherwise returns false.
 217
 218 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 219 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 220 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 221 hash reference is equivalent to not supplying this parameter.  There should be
 222 a better explanation of this, but until then, here's an example:
 223
 224   use Tie::RefHash;
 225   tie %hash, 'Tie::RefHash'; #this part is important
 226   %hash = (
 227     $cust_pkg => [ $svc_acct ],
 228     ...
 229   );
 230   $cust_main->insert( \%hash );
 231
 232 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 233 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 234 expected and rollback the entire transaction; it is not necessary to call
 235 check_invoicing_list first.  The invoicing_list is set after the records in the
 236 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 237 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 238
 239   $cust_main->insert( {}, [ $email, 'POST' ] );
 240
 241 Currently available options are: I<depend_jobnum> and I<noexport>.
 242
 243 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 244 on the supplied jobnum (they will not run until the specific job completes).
 245 This can be used to defer provisioning until some action completes (such
 246 as running the customer's credit card sucessfully).
 247
 248 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 249 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 250 the B<reexport> method.)
 251
 252 =cut
 253
 254 sub insert {
 255   my $self = shift;
 256   my $cust_pkgs = @_ ? shift : {};
 257   my $invoicing_list = @_ ? shift : '';
 258   my %options = @_;
 259   warn "FS::cust_main::insert called with options ".
 260        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 261     if $DEBUG;
 262
 263   local $SIG{HUP} = 'IGNORE';
 264   local $SIG{INT} = 'IGNORE';
 265   local $SIG{QUIT} = 'IGNORE';
 266   local $SIG{TERM} = 'IGNORE';
 267   local $SIG{TSTP} = 'IGNORE';
 268   local $SIG{PIPE} = 'IGNORE';
 269
 270   my $oldAutoCommit = $FS::UID::AutoCommit;
 271   local $FS::UID::AutoCommit = 0;
 272   my $dbh = dbh;
 273
 274   my $prepay_credit = '';
 275   my $seconds = 0;
 276   if ( $self->payby eq 'PREPAY' ) {
 277     $self->payby('BILL');
 278     $prepay_credit = qsearchs(
 279       'prepay_credit',
 280       { 'identifier' => $self->payinfo },
 281       '',
 282       'FOR UPDATE'
 283     );
 284     unless ( $prepay_credit ) {
 285       $dbh->rollback if $oldAutoCommit;
 286       return "Invalid prepaid card: ". $self->payinfo;
 287     }
 288     $seconds = $prepay_credit->seconds;
 289     if ( $prepay_credit->agentnum ) {
 290       if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 291         $dbh->rollback if $oldAutoCommit;
 292         return "prepaid card not valid for agent ". $self->agentnum;
 293       }
 294       $self->agentnum($prepay_credit->agentnum);
 295     }
 296     my $error = $prepay_credit->delete;
 297     if ( $error ) {
 298       $dbh->rollback if $oldAutoCommit;
 299       return "removing prepay_credit (transaction rolled back): $error";
 300     }
 301   }
 302
 303   my $error = $self->SUPER::insert;
 304   if ( $error ) {
 305     $dbh->rollback if $oldAutoCommit;
 306     #return "inserting cust_main record (transaction rolled back): $error";
 307     return $error;
 308   }
 309
 310   # invoicing list
 311   if ( $invoicing_list ) {
 312     $error = $self->check_invoicing_list( $invoicing_list );
 313     if ( $error ) {
 314       $dbh->rollback if $oldAutoCommit;
 315       return "checking invoicing_list (transaction rolled back): $error";
 316     }
 317     $self->invoicing_list( $invoicing_list );
 318   }
 319
 320   # packages
 321   $error = $self->order_pkgs($cust_pkgs, \$seconds, %options);
 322   if ( $error ) {
 323     $dbh->rollback if $oldAutoCommit;
 324     return $error;
 325   }
 326
 327   if ( $seconds ) {
 328     $dbh->rollback if $oldAutoCommit;
 329     return "No svc_acct record to apply pre-paid time";
 330   }
 331
 332   if ( $prepay_credit && $prepay_credit->amount ) {
 333     my $cust_pay = new FS::cust_pay {
 334       'custnum' => $self->custnum,
 335       'paid'    => $prepay_credit->amount,
 336       #'_date'   => #date the prepaid card was purchased???
 337       'payby'   => 'PREP',
 338       'payinfo' => $prepay_credit->identifier,
 339     };
 340     $error = $cust_pay->insert;
 341     if ( $error ) {
 342       $dbh->rollback if $oldAutoCommit;
 343       return "inserting prepayment (transaction rolled back): $error";
 344     }
 345   }
 346
 347   $error = $self->queue_fuzzyfiles_update;
 348   if ( $error ) {
 349     $dbh->rollback if $oldAutoCommit;
 350     return "updating fuzzy search cache: $error";
 351   }
 352
 353   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 354   '';
 355
 356 }
 357
 358 =item order_pkgs HASHREF, [ SECONDSREF, [ , OPTION => VALUE ... ] ]
 359
 360 Like the insert method on an existing record, this method orders a package
 361 and included services atomicaly.  Pass a Tie::RefHash data structure to this
 362 method containing FS::cust_pkg and FS::svc_I<tablename> objects.  There should
 363 be a better explanation of this, but until then, here's an example:
 364
 365   use Tie::RefHash;
 366   tie %hash, 'Tie::RefHash'; #this part is important
 367   %hash = (
 368     $cust_pkg => [ $svc_acct ],
 369     ...
 370   );
 371   $cust_main->order_pkgs( \%hash, \'0', 'noexport'=>1 );
 372
 373 Currently available options are: I<depend_jobnum> and I<noexport>.
 374
 375 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 376 on the supplied jobnum (they will not run until the specific job completes).
 377 This can be used to defer provisioning until some action completes (such
 378 as running the customer's credit card sucessfully).
 379
 380 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 381 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 382 the B<reexport> method for each cust_pkg object.  Using the B<reexport> method
 383 on the cust_main object is not recommended, as existing services will also be
 384 reexported.)
 385
 386 =cut
 387
 388 sub order_pkgs {
 389   my $self = shift;
 390   my $cust_pkgs = shift;
 391   my $seconds = shift;
 392   my %options = @_;
 393   my %svc_options = ();
 394   $svc_options{'depend_jobnum'} = $options{'depend_jobnum'}
 395     if exists $options{'depend_jobnum'};
 396   warn "FS::cust_main::order_pkgs called with options ".
 397        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 398     if $DEBUG;
 399
 400   local $SIG{HUP} = 'IGNORE';
 401   local $SIG{INT} = 'IGNORE';
 402   local $SIG{QUIT} = 'IGNORE';
 403   local $SIG{TERM} = 'IGNORE';
 404   local $SIG{TSTP} = 'IGNORE';
 405   local $SIG{PIPE} = 'IGNORE';
 406
 407   my $oldAutoCommit = $FS::UID::AutoCommit;
 408   local $FS::UID::AutoCommit = 0;
 409   my $dbh = dbh;
 410
 411   local $FS::svc_Common::noexport_hack = 1 if $options{'noexport'};
 412
 413   foreach my $cust_pkg ( keys %$cust_pkgs ) {
 414     $cust_pkg->custnum( $self->custnum );
 415     my $error = $cust_pkg->insert;
 416     if ( $error ) {
 417       $dbh->rollback if $oldAutoCommit;
 418       return "inserting cust_pkg (transaction rolled back): $error";
 419     }
 420     foreach my $svc_something ( @{$cust_pkgs->{$cust_pkg}} ) {
 421       $svc_something->pkgnum( $cust_pkg->pkgnum );
 422       if ( $seconds && $$seconds && $svc_something->isa('FS::svc_acct') ) {
 423         $svc_something->seconds( $svc_something->seconds + $$seconds );
 424         $$seconds = 0;
 425       }
 426       $error = $svc_something->insert(%svc_options);
 427       if ( $error ) {
 428         $dbh->rollback if $oldAutoCommit;
 429         #return "inserting svc_ (transaction rolled back): $error";
 430         return $error;
 431       }
 432     }
 433   }
 434
 435   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 436   ''; #no error
 437 }
 438
 439 =item reexport
 440
 441 This method is deprecated.  See the I<depend_jobnum> option to the insert and
 442 order_pkgs methods for a better way to defer provisioning.
 443
 444 Re-schedules all exports by calling the B<reexport> method of all associated
 445 packages (see L<FS::cust_pkg>).  If there is an error, returns the error;
 446 otherwise returns false.
 447
 448 =cut
 449
 450 sub reexport {
 451   my $self = shift;
 452
 453   carp "warning: FS::cust_main::reexport is deprectated; ".
 454        "use the depend_jobnum option to insert or order_pkgs to delay export";
 455
 456   local $SIG{HUP} = 'IGNORE';
 457   local $SIG{INT} = 'IGNORE';
 458   local $SIG{QUIT} = 'IGNORE';
 459   local $SIG{TERM} = 'IGNORE';
 460   local $SIG{TSTP} = 'IGNORE';
 461   local $SIG{PIPE} = 'IGNORE';
 462
 463   my $oldAutoCommit = $FS::UID::AutoCommit;
 464   local $FS::UID::AutoCommit = 0;
 465   my $dbh = dbh;
 466
 467   foreach my $cust_pkg ( $self->ncancelled_pkgs ) {
 468     my $error = $cust_pkg->reexport;
 469     if ( $error ) {
 470       $dbh->rollback if $oldAutoCommit;
 471       return $error;
 472     }
 473   }
 474
 475   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 476   '';
 477
 478 }
 479
 480 =item delete NEW_CUSTNUM
 481
 482 This deletes the customer.  If there is an error, returns the error, otherwise
 483 returns false.
 484
 485 This will completely remove all traces of the customer record.  This is not
 486 what you want when a customer cancels service; for that, cancel all of the
 487 customer's packages (see L</cancel>).
 488
 489 If the customer has any uncancelled packages, you need to pass a new (valid)
 490 customer number for those packages to be transferred to.  Cancelled packages
 491 will be deleted.  Did I mention that this is NOT what you want when a customer
 492 cancels service and that you really should be looking see L<FS::cust_pkg/cancel>?
 493
 494 You can't delete a customer with invoices (see L<FS::cust_bill>),
 495 or credits (see L<FS::cust_credit>), payments (see L<FS::cust_pay>) or
 496 refunds (see L<FS::cust_refund>).
 497
 498 =cut
 499
 500 sub delete {
 501   my $self = shift;
 502
 503   local $SIG{HUP} = 'IGNORE';
 504   local $SIG{INT} = 'IGNORE';
 505   local $SIG{QUIT} = 'IGNORE';
 506   local $SIG{TERM} = 'IGNORE';
 507   local $SIG{TSTP} = 'IGNORE';
 508   local $SIG{PIPE} = 'IGNORE';
 509
 510   my $oldAutoCommit = $FS::UID::AutoCommit;
 511   local $FS::UID::AutoCommit = 0;
 512   my $dbh = dbh;
 513
 514   if ( $self->cust_bill ) {
 515     $dbh->rollback if $oldAutoCommit;
 516     return "Can't delete a customer with invoices";
 517   }
 518   if ( $self->cust_credit ) {
 519     $dbh->rollback if $oldAutoCommit;
 520     return "Can't delete a customer with credits";
 521   }
 522   if ( $self->cust_pay ) {
 523     $dbh->rollback if $oldAutoCommit;
 524     return "Can't delete a customer with payments";
 525   }
 526   if ( $self->cust_refund ) {
 527     $dbh->rollback if $oldAutoCommit;
 528     return "Can't delete a customer with refunds";
 529   }
 530
 531   my @cust_pkg = $self->ncancelled_pkgs;
 532   if ( @cust_pkg ) {
 533     my $new_custnum = shift;
 534     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
 535       $dbh->rollback if $oldAutoCommit;
 536       return "Invalid new customer number: $new_custnum";
 537     }
 538     foreach my $cust_pkg ( @cust_pkg ) {
 539       my %hash = $cust_pkg->hash;
 540       $hash{'custnum'} = $new_custnum;
 541       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
 542       my $error = $new_cust_pkg->replace($cust_pkg);
 543       if ( $error ) {
 544         $dbh->rollback if $oldAutoCommit;
 545         return $error;
 546       }
 547     }
 548   }
 549   my @cancelled_cust_pkg = $self->all_pkgs;
 550   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
 551     my $error = $cust_pkg->delete;
 552     if ( $error ) {
 553       $dbh->rollback if $oldAutoCommit;
 554       return $error;
 555     }
 556   }
 557
 558   foreach my $cust_main_invoice ( #(email invoice destinations, not invoices)
 559     qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } )
 560   ) {
 561     my $error = $cust_main_invoice->delete;
 562     if ( $error ) {
 563       $dbh->rollback if $oldAutoCommit;
 564       return $error;
 565     }
 566   }
 567
 568   my $error = $self->SUPER::delete;
 569   if ( $error ) {
 570     $dbh->rollback if $oldAutoCommit;
 571     return $error;
 572   }
 573
 574   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 575   '';
 576
 577 }
 578
 579 =item replace OLD_RECORD [ INVOICING_LIST_ARYREF ]
 580
 581 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 582 returns the error, otherwise returns false.
 583
 584 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 585 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 586 expected and rollback the entire transaction; it is not necessary to call
 587 check_invoicing_list first.  Here's an example:
 588
 589   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
 590
 591 =cut
 592
 593 sub replace {
 594   my $self = shift;
 595   my $old = shift;
 596   my @param = @_;
 597
 598   local $SIG{HUP} = 'IGNORE';
 599   local $SIG{INT} = 'IGNORE';
 600   local $SIG{QUIT} = 'IGNORE';
 601   local $SIG{TERM} = 'IGNORE';
 602   local $SIG{TSTP} = 'IGNORE';
 603   local $SIG{PIPE} = 'IGNORE';
 604
 605   if ( $self->payby eq 'COMP' && $self->payby ne $old->payby
 606        && $conf->config('users-allow_comp')                  ) {
 607     return "You are not permitted to create complimentary accounts."
 608       unless grep { $_ eq getotaker } $conf->config('users-allow_comp');
 609   }
 610
 611   my $oldAutoCommit = $FS::UID::AutoCommit;
 612   local $FS::UID::AutoCommit = 0;
 613   my $dbh = dbh;
 614
 615   my $error = $self->SUPER::replace($old);
 616
 617   if ( $error ) {
 618     $dbh->rollback if $oldAutoCommit;
 619     return $error;
 620   }
 621
 622   if ( @param ) { # INVOICING_LIST_ARYREF
 623     my $invoicing_list = shift @param;
 624     $error = $self->check_invoicing_list( $invoicing_list );
 625     if ( $error ) {
 626       $dbh->rollback if $oldAutoCommit;
 627       return $error;
 628     }
 629     $self->invoicing_list( $invoicing_list );
 630   }
 631
 632   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/ &&
 633        grep { $self->get($_) ne $old->get($_) } qw(payinfo paydate payname) ) {
 634     # card/check/lec info has changed, want to retry realtime_ invoice events
 635     my $error = $self->retry_realtime;
 636     if ( $error ) {
 637       $dbh->rollback if $oldAutoCommit;
 638       return $error;
 639     }
 640   }
 641
 642   $error = $self->queue_fuzzyfiles_update;
 643   if ( $error ) {
 644     $dbh->rollback if $oldAutoCommit;
 645     return "updating fuzzy search cache: $error";
 646   }
 647
 648   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 649   '';
 650
 651 }
 652
 653 =item queue_fuzzyfiles_update
 654
 655 Used by insert & replace to update the fuzzy search cache
 656
 657 =cut
 658
 659 sub queue_fuzzyfiles_update {
 660   my $self = shift;
 661
 662   local $SIG{HUP} = 'IGNORE';
 663   local $SIG{INT} = 'IGNORE';
 664   local $SIG{QUIT} = 'IGNORE';
 665   local $SIG{TERM} = 'IGNORE';
 666   local $SIG{TSTP} = 'IGNORE';
 667   local $SIG{PIPE} = 'IGNORE';
 668
 669   my $oldAutoCommit = $FS::UID::AutoCommit;
 670   local $FS::UID::AutoCommit = 0;
 671   my $dbh = dbh;
 672
 673   my $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 674   my $error = $queue->insert($self->getfield('last'), $self->company);
 675   if ( $error ) {
 676     $dbh->rollback if $oldAutoCommit;
 677     return "queueing job (transaction rolled back): $error";
 678   }
 679
 680   if ( defined $self->dbdef_table->column('ship_last') && $self->ship_last ) {
 681     $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 682     $error = $queue->insert($self->getfield('ship_last'), $self->ship_company);
 683     if ( $error ) {
 684       $dbh->rollback if $oldAutoCommit;
 685       return "queueing job (transaction rolled back): $error";
 686     }
 687   }
 688
 689   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 690   '';
 691
 692 }
 693
 694 =item check
 695
 696 Checks all fields to make sure this is a valid customer record.  If there is
 697 an error, returns the error, otherwise returns false.  Called by the insert
 698 and repalce methods.
 699
 700 =cut
 701
 702 sub check {
 703   my $self = shift;
 704
 705   #warn "BEFORE: \n". $self->_dump;
 706
 707   my $error =
 708     $self->ut_numbern('custnum')
 709     || $self->ut_number('agentnum')
 710     || $self->ut_number('refnum')
 711     || $self->ut_name('last')
 712     || $self->ut_name('first')
 713     || $self->ut_textn('company')
 714     || $self->ut_text('address1')
 715     || $self->ut_textn('address2')
 716     || $self->ut_text('city')
 717     || $self->ut_textn('county')
 718     || $self->ut_textn('state')
 719     || $self->ut_country('country')
 720     || $self->ut_anything('comments')
 721     || $self->ut_numbern('referral_custnum')
 722   ;
 723   #barf.  need message catalogs.  i18n.  etc.
 724   $error .= "Please select an advertising source."
 725     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
 726   return $error if $error;
 727
 728   return "Unknown agent"
 729     unless qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
 730
 731   return "Unknown refnum"
 732     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
 733
 734   return "Unknown referring custnum ". $self->referral_custnum
 735     unless ! $self->referral_custnum
 736            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
 737
 738   if ( $self->ss eq '' ) {
 739     $self->ss('');
 740   } else {
 741     my $ss = $self->ss;
 742     $ss =~ s/\D//g;
 743     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
 744       or return "Illegal social security number: ". $self->ss;
 745     $self->ss("$1-$2-$3");
 746   }
 747
 748
 749 # bad idea to disable, causes billing to fail because of no tax rates later
 750 #  unless ( $import ) {
 751     unless ( qsearch('cust_main_county', {
 752       'country' => $self->country,
 753       'state'   => '',
 754      } ) ) {
 755       return "Unknown state/county/country: ".
 756         $self->state. "/". $self->county. "/". $self->country
 757         unless qsearch('cust_main_county',{
 758           'state'   => $self->state,
 759           'county'  => $self->county,
 760           'country' => $self->country,
 761         } );
 762     }
 763 #  }
 764
 765   $error =
 766     $self->ut_phonen('daytime', $self->country)
 767     || $self->ut_phonen('night', $self->country)
 768     || $self->ut_phonen('fax', $self->country)
 769     || $self->ut_zip('zip', $self->country)
 770   ;
 771   return $error if $error;
 772
 773   my @addfields = qw(
 774     last first company address1 address2 city county state zip
 775     country daytime night fax
 776   );
 777
 778   if ( defined $self->dbdef_table->column('ship_last') ) {
 779     if ( scalar ( grep { $self->getfield($_) ne $self->getfield("ship_$_") }
 780                        @addfields )
 781          && scalar ( grep { $self->getfield("ship_$_") ne '' } @addfields )
 782        )
 783     {
 784       my $error =
 785         $self->ut_name('ship_last')
 786         || $self->ut_name('ship_first')
 787         || $self->ut_textn('ship_company')
 788         || $self->ut_text('ship_address1')
 789         || $self->ut_textn('ship_address2')
 790         || $self->ut_text('ship_city')
 791         || $self->ut_textn('ship_county')
 792         || $self->ut_textn('ship_state')
 793         || $self->ut_country('ship_country')
 794       ;
 795       return $error if $error;
 796
 797       #false laziness with above
 798       unless ( qsearchs('cust_main_county', {
 799         'country' => $self->ship_country,
 800         'state'   => '',
 801        } ) ) {
 802         return "Unknown ship_state/ship_county/ship_country: ".
 803           $self->ship_state. "/". $self->ship_county. "/". $self->ship_country
 804           unless qsearchs('cust_main_county',{
 805             'state'   => $self->ship_state,
 806             'county'  => $self->ship_county,
 807             'country' => $self->ship_country,
 808           } );
 809       }
 810       #eofalse
 811
 812       $error =
 813         $self->ut_phonen('ship_daytime', $self->ship_country)
 814         || $self->ut_phonen('ship_night', $self->ship_country)
 815         || $self->ut_phonen('ship_fax', $self->ship_country)
 816         || $self->ut_zip('ship_zip', $self->ship_country)
 817       ;
 818       return $error if $error;
 819
 820     } else { # ship_ info eq billing info, so don't store dup info in database
 821       $self->setfield("ship_$_", '')
 822         foreach qw( last first company address1 address2 city county state zip
 823                     country daytime night fax );
 824     }
 825   }
 826
 827   $self->payby =~ /^(CARD|DCRD|CHEK|DCHK|LECB|BILL|COMP|PREPAY)$/
 828     or return "Illegal payby: ". $self->payby;
 829   $self->payby($1);
 830
 831   if ( $self->payby eq 'CARD' || $self->payby eq 'DCRD' ) {
 832
 833     my $payinfo = $self->payinfo;
 834     $payinfo =~ s/\D//g;
 835     $payinfo =~ /^(\d{13,16})$/
 836       or return gettext('invalid_card'); # . ": ". $self->payinfo;
 837     $payinfo = $1;
 838     $self->payinfo($payinfo);
 839     validate($payinfo)
 840       or return gettext('invalid_card'); # . ": ". $self->payinfo;
 841     return gettext('unknown_card_type')
 842       if cardtype($self->payinfo) eq "Unknown";
 843     if ( defined $self->dbdef_table->column('paycvv') ) {
 844       if ( length($self->paycvv) ) {
 845         if ( cardtype($self->payinfo) eq 'American Express card' ) {
 846           $self->paycvv =~ /^(\d{4})$/
 847             or return "CVV2 (CID) for American Express cards is four digits.";
 848           $self->paycvv($1);
 849         } else {
 850           $self->paycvv =~ /^(\d{3})$/
 851             or return "CVV2 (CVC2/CID) is three digits.";
 852           $self->paycvv($1);
 853         }
 854       } else {
 855         $self->paycvv('');
 856       }
 857     }
 858
 859   } elsif ( $self->payby eq 'CHEK' || $self->payby eq 'DCHK' ) {
 860
 861     my $payinfo = $self->payinfo;
 862     $payinfo =~ s/[^\d\@]//g;
 863     $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
 864     $payinfo = "$1\@$2";
 865     $self->payinfo($payinfo);
 866     $self->paycvv('') if $self->dbdef_table->column('paycvv');
 867
 868   } elsif ( $self->payby eq 'LECB' ) {
 869
 870     my $payinfo = $self->payinfo;
 871     $payinfo =~ s/\D//g;
 872     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
 873     $payinfo = $1;
 874     $self->payinfo($payinfo);
 875     $self->paycvv('') if $self->dbdef_table->column('paycvv');
 876
 877   } elsif ( $self->payby eq 'BILL' ) {
 878
 879     $error = $self->ut_textn('payinfo');
 880     return "Illegal P.O. number: ". $self->payinfo if $error;
 881     $self->paycvv('') if $self->dbdef_table->column('paycvv');
 882
 883   } elsif ( $self->payby eq 'COMP' ) {
 884
 885     if ( !$self->custnum && $conf->config('users-allow_comp') ) {
 886       return "You are not permitted to create complimentary accounts."
 887         unless grep { $_ eq getotaker } $conf->config('users-allow_comp');
 888     }
 889
 890     $error = $self->ut_textn('payinfo');
 891     return "Illegal comp account issuer: ". $self->payinfo if $error;
 892     $self->paycvv('') if $self->dbdef_table->column('paycvv');
 893
 894   } elsif ( $self->payby eq 'PREPAY' ) {
 895
 896     my $payinfo = $self->payinfo;
 897     $payinfo =~ s/\W//g; #anything else would just confuse things
 898     $self->payinfo($payinfo);
 899     $error = $self->ut_alpha('payinfo');
 900     return "Illegal prepayment identifier: ". $self->payinfo if $error;
 901     return "Unknown prepayment identifier"
 902       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
 903     $self->paycvv('') if $self->dbdef_table->column('paycvv');
 904
 905   }
 906
 907   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
 908     return "Expriation date required"
 909       unless $self->payby =~ /^(BILL|PREPAY|CHEK|LECB)$/;
 910     $self->paydate('');
 911   } else {
 912     my( $m, $y );
 913     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 914       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
 915     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 916       ( $m, $y ) = ( $3, "20$2" );
 917     } else {
 918       return "Illegal expiration date: ". $self->paydate;
 919     }
 920     $self->paydate("$y-$m-01");
 921     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
 922     return gettext('expired_card')
 923       if !$import && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
 924   }
 925
 926   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
 927        ( ! $conf->exists('require_cardname')
 928          || $self->payby !~ /^(CARD|DCRD)$/  )
 929   ) {
 930     $self->payname( $self->first. " ". $self->getfield('last') );
 931   } else {
 932     $self->payname =~ /^([\w \,\.\-\']+)$/
 933       or return gettext('illegal_name'). " payname: ". $self->payname;
 934     $self->payname($1);
 935   }
 936
 937   $self->tax =~ /^(Y?)$/ or return "Illegal tax: ". $self->tax;
 938   $self->tax($1);
 939
 940   $self->otaker(getotaker) unless $self->otaker;
 941
 942   #warn "AFTER: \n". $self->_dump;
 943
 944   $self->SUPER::check;
 945 }
 946
 947 =item all_pkgs
 948
 949 Returns all packages (see L<FS::cust_pkg>) for this customer.
 950
 951 =cut
 952
 953 sub all_pkgs {
 954   my $self = shift;
 955   if ( $self->{'_pkgnum'} ) {
 956     values %{ $self->{'_pkgnum'}->cache };
 957   } else {
 958     qsearch( 'cust_pkg', { 'custnum' => $self->custnum });
 959   }
 960 }
 961
 962 =item ncancelled_pkgs
 963
 964 Returns all non-cancelled packages (see L<FS::cust_pkg>) for this customer.
 965
 966 =cut
 967
 968 sub ncancelled_pkgs {
 969   my $self = shift;
 970   if ( $self->{'_pkgnum'} ) {
 971     grep { ! $_->getfield('cancel') } values %{ $self->{'_pkgnum'}->cache };
 972   } else {
 973     @{ [ # force list context
 974       qsearch( 'cust_pkg', {
 975         'custnum' => $self->custnum,
 976         'cancel'  => '',
 977       }),
 978       qsearch( 'cust_pkg', {
 979         'custnum' => $self->custnum,
 980         'cancel'  => 0,
 981       }),
 982     ] };
 983   }
 984 }
 985
 986 =item suspended_pkgs
 987
 988 Returns all suspended packages (see L<FS::cust_pkg>) for this customer.
 989
 990 =cut
 991
 992 sub suspended_pkgs {
 993   my $self = shift;
 994   grep { $_->susp } $self->ncancelled_pkgs;
 995 }
 996
 997 =item unflagged_suspended_pkgs
 998
 999 Returns all unflagged suspended packages (see L<FS::cust_pkg>) for this
1000 customer (thouse packages without the `manual_flag' set).
1001
1002 =cut
1003
1004 sub unflagged_suspended_pkgs {
1005   my $self = shift;
1006   return $self->suspended_pkgs
1007     unless dbdef->table('cust_pkg')->column('manual_flag');
1008   grep { ! $_->manual_flag } $self->suspended_pkgs;
1009 }
1010
1011 =item unsuspended_pkgs
1012
1013 Returns all unsuspended (and uncancelled) packages (see L<FS::cust_pkg>) for
1014 this customer.
1015
1016 =cut
1017
1018 sub unsuspended_pkgs {
1019   my $self = shift;
1020   grep { ! $_->susp } $self->ncancelled_pkgs;
1021 }
1022
1023 =item num_cancelled_pkgs
1024
1025 Returns the number of cancelled packages (see L<FS::cust_pkg>) for this
1026 customer.
1027
1028 =cut
1029
1030 sub num_cancelled_pkgs {
1031   my $self = shift;
1032   $self->num_pkgs("cancel IS NOT NULL AND cust_pkg.cancel != 0");
1033 }
1034
1035 sub num_pkgs {
1036   my( $self, $sql ) = @_;
1037   my $sth = dbh->prepare(
1038     "SELECT COUNT(*) FROM cust_pkg WHERE custnum = ? AND $sql"
1039   ) or die dbh->errstr;
1040   $sth->execute($self->custnum) or die $sth->errstr;
1041   $sth->fetchrow_arrayref->[0];
1042 }
1043
1044 =item unsuspend
1045
1046 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
1047 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
1048 on success or a list of errors.
1049
1050 =cut
1051
1052 sub unsuspend {
1053   my $self = shift;
1054   grep { $_->unsuspend } $self->suspended_pkgs;
1055 }
1056
1057 =item suspend
1058
1059 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
1060 Always returns a list: an empty list on success or a list of errors.
1061
1062 =cut
1063
1064 sub suspend {
1065   my $self = shift;
1066   grep { $_->suspend } $self->unsuspended_pkgs;
1067 }
1068
1069 =item suspend_if_pkgpart PKGPART [ , PKGPART ... ]
1070
1071 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
1072 PKGPARTs (see L<FS::part_pkg>).  Always returns a list: an empty list on
1073 success or a list of errors.
1074
1075 =cut
1076
1077 sub suspend_if_pkgpart {
1078   my $self = shift;
1079   my @pkgparts = @_;
1080   grep { $_->suspend }
1081     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
1082       $self->unsuspended_pkgs;
1083 }
1084
1085 =item suspend_unless_pkgpart PKGPART [ , PKGPART ... ]
1086
1087 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
1088 listed PKGPARTs (see L<FS::part_pkg>).  Always returns a list: an empty list
1089 on success or a list of errors.
1090
1091 =cut
1092
1093 sub suspend_unless_pkgpart {
1094   my $self = shift;
1095   my @pkgparts = @_;
1096   grep { $_->suspend }
1097     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
1098       $self->unsuspended_pkgs;
1099 }
1100
1101 =item cancel [ OPTION => VALUE ... ]
1102
1103 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
1104
1105 Available options are: I<quiet>
1106
1107 I<quiet> can be set true to supress email cancellation notices.
1108
1109 Always returns a list: an empty list on success or a list of errors.
1110
1111 =cut
1112
1113 sub cancel {
1114   my $self = shift;
1115   grep { $_ } map { $_->cancel(@_) } $self->ncancelled_pkgs;
1116 }
1117
1118 =item agent
1119
1120 Returns the agent (see L<FS::agent>) for this customer.
1121
1122 =cut
1123
1124 sub agent {
1125   my $self = shift;
1126   qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
1127 }
1128
1129 =item bill OPTIONS
1130
1131 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
1132 conjunction with the collect method.
1133
1134 Options are passed as name-value pairs.
1135
1136 Currently available options are:
1137
1138 resetup - if set true, re-charges setup fees.
1139
1140 time - bills the customer as if it were that time.  Specified as a UNIX
1141 timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and
1142 L<Date::Parse> for conversion functions.  For example:
1143
1144  use Date::Parse;
1145  ...
1146  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
1147
1148
1149 If there is an error, returns the error, otherwise returns false.
1150
1151 =cut
1152
1153 sub bill {
1154   my( $self, %options ) = @_;
1155   return '' if $self->payby eq 'COMP';
1156   warn "bill customer ". $self->custnum if $DEBUG;
1157
1158   my $time = $options{'time'} || time;
1159
1160   my $error;
1161
1162   #put below somehow?
1163   local $SIG{HUP} = 'IGNORE';
1164   local $SIG{INT} = 'IGNORE';
1165   local $SIG{QUIT} = 'IGNORE';
1166   local $SIG{TERM} = 'IGNORE';
1167   local $SIG{TSTP} = 'IGNORE';
1168   local $SIG{PIPE} = 'IGNORE';
1169
1170   my $oldAutoCommit = $FS::UID::AutoCommit;
1171   local $FS::UID::AutoCommit = 0;
1172   my $dbh = dbh;
1173
1174   $self->select_for_update; #mutex
1175
1176   # find the packages which are due for billing, find out how much they are
1177   # & generate invoice database.
1178
1179   my( $total_setup, $total_recur ) = ( 0, 0 );
1180   #my( $taxable_setup, $taxable_recur ) = ( 0, 0 );
1181   my @cust_bill_pkg = ();
1182   #my $tax = 0;##
1183   #my $taxable_charged = 0;##
1184   #my $charged = 0;##
1185
1186   my %tax;
1187
1188   foreach my $cust_pkg (
1189     qsearch('cust_pkg', { 'custnum' => $self->custnum } )
1190   ) {
1191
1192     #NO!! next if $cust_pkg->cancel;
1193     next if $cust_pkg->getfield('cancel');
1194
1195     warn "  bill package ". $cust_pkg->pkgnum if $DEBUG;
1196
1197     #? to avoid use of uninitialized value errors... ?
1198     $cust_pkg->setfield('bill', '')
1199       unless defined($cust_pkg->bill);
1200
1201     my $part_pkg = $cust_pkg->part_pkg;
1202
1203     my %hash = $cust_pkg->hash;
1204     my $old_cust_pkg = new FS::cust_pkg \%hash;
1205
1206     my @details = ();
1207
1208     # bill setup
1209     my $setup = 0;
1210     if ( !$cust_pkg->setup || $options{'resetup'} ) {
1211
1212       warn "    bill setup" if $DEBUG;
1213
1214       $setup = eval { $cust_pkg->calc_setup( $time ) };
1215       if ( $@ ) {
1216         $dbh->rollback if $oldAutoCommit;
1217         return $@;
1218       }
1219
1220       $cust_pkg->setfield('setup', $time) unless $cust_pkg->setup;
1221     }
1222
1223     #bill recurring fee
1224     my $recur = 0;
1225     my $sdate;
1226     if ( $part_pkg->getfield('freq') ne '0' &&
1227          ! $cust_pkg->getfield('susp') &&
1228          ( $cust_pkg->getfield('bill') || 0 ) <= $time
1229     ) {
1230
1231       warn "    bill recur" if $DEBUG;
1232
1233       # XXX shared with $recur_prog
1234       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1235
1236       $recur = eval { $cust_pkg->calc_recur( \$sdate, \@details ) };
1237       if ( $@ ) {
1238         $dbh->rollback if $oldAutoCommit;
1239         return $@;
1240       }
1241
1242       #change this bit to use Date::Manip? CAREFUL with timezones (see
1243       # mailing list archive)
1244       my ($sec,$min,$hour,$mday,$mon,$year) =
1245         (localtime($sdate) )[0,1,2,3,4,5];
1246
1247       #pro-rating magic - if $recur_prog fiddles $sdate, want to use that
1248       # only for figuring next bill date, nothing else, so, reset $sdate again
1249       # here
1250       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1251       $cust_pkg->last_bill($sdate)
1252         if $cust_pkg->dbdef_table->column('last_bill');
1253
1254       if ( $part_pkg->freq =~ /^\d+$/ ) {
1255         $mon += $part_pkg->freq;
1256         until ( $mon < 12 ) { $mon -= 12; $year++; }
1257       } elsif ( $part_pkg->freq =~ /^(\d+)w$/ ) {
1258         my $weeks = $1;
1259         $mday += $weeks * 7;
1260       } elsif ( $part_pkg->freq =~ /^(\d+)d$/ ) {
1261         my $days = $1;
1262         $mday += $days;
1263       } else {
1264         $dbh->rollback if $oldAutoCommit;
1265         return "unparsable frequency: ". $part_pkg->freq;
1266       }
1267       $cust_pkg->setfield('bill',
1268         timelocal_nocheck($sec,$min,$hour,$mday,$mon,$year));
1269     }
1270
1271     warn "\$setup is undefined" unless defined($setup);
1272     warn "\$recur is undefined" unless defined($recur);
1273     warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1274
1275     if ( $cust_pkg->modified ) {
1276
1277       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n" if $DEBUG;
1278
1279       $error=$cust_pkg->replace($old_cust_pkg);
1280       if ( $error ) { #just in case
1281         $dbh->rollback if $oldAutoCommit;
1282         return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error";
1283       }
1284
1285       $setup = sprintf( "%.2f", $setup );
1286       $recur = sprintf( "%.2f", $recur );
1287       if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1288         $dbh->rollback if $oldAutoCommit;
1289         return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1290       }
1291       if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1292         $dbh->rollback if $oldAutoCommit;
1293         return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1294       }
1295       if ( $setup != 0 || $recur != 0 ) {
1296         warn "    charges (setup=$setup, recur=$recur); queueing line items\n"
1297           if $DEBUG;
1298         my $cust_bill_pkg = new FS::cust_bill_pkg ({
1299           'pkgnum'  => $cust_pkg->pkgnum,
1300           'setup'   => $setup,
1301           'recur'   => $recur,
1302           'sdate'   => $sdate,
1303           'edate'   => $cust_pkg->bill,
1304           'details' => \@details,
1305         });
1306         push @cust_bill_pkg, $cust_bill_pkg;
1307         $total_setup += $setup;
1308         $total_recur += $recur;
1309
1310         unless ( $self->tax =~ /Y/i || $self->payby eq 'COMP' ) {
1311
1312           my @taxes = qsearch( 'cust_main_county', {
1313                                  'state'    => $self->state,
1314                                  'county'   => $self->county,
1315                                  'country'  => $self->country,
1316                                  'taxclass' => $part_pkg->taxclass,
1317                                                                       } );
1318           unless ( @taxes ) {
1319             @taxes =  qsearch( 'cust_main_county', {
1320                                   'state'    => $self->state,
1321                                   'county'   => $self->county,
1322                                   'country'  => $self->country,
1323                                   'taxclass' => '',
1324                                                                       } );
1325           }
1326
1327           #one more try at a whole-country tax rate
1328           unless ( @taxes ) {
1329             @taxes =  qsearch( 'cust_main_county', {
1330                                   'state'    => '',
1331                                   'county'   => '',
1332                                   'country'  => $self->country,
1333                                   'taxclass' => '',
1334                                                                       } );
1335           }
1336
1337           # maybe eliminate this entirely, along with all the 0% records
1338           unless ( @taxes ) {
1339             $dbh->rollback if $oldAutoCommit;
1340             return
1341               "fatal: can't find tax rate for state/county/country/taxclass ".
1342               join('/', ( map $self->$_(), qw(state county country) ),
1343                         $part_pkg->taxclass ).  "\n";
1344           }
1345
1346           foreach my $tax ( @taxes ) {
1347
1348             my $taxable_charged = 0;
1349             $taxable_charged += $setup
1350               unless $part_pkg->setuptax =~ /^Y$/i
1351                   || $tax->setuptax =~ /^Y$/i;
1352             $taxable_charged += $recur
1353               unless $part_pkg->recurtax =~ /^Y$/i
1354                   || $tax->recurtax =~ /^Y$/i;
1355             next unless $taxable_charged;
1356
1357             if ( $tax->exempt_amount && $tax->exempt_amount > 0 ) {
1358               my ($mon,$year) = (localtime($sdate) )[4,5];
1359               $mon++;
1360               my $freq = $part_pkg->freq || 1;
1361               if ( $freq !~ /(\d+)$/ ) {
1362                 $dbh->rollback if $oldAutoCommit;
1363                 return "daily/weekly package definitions not (yet?)".
1364                        " compatible with monthly tax exemptions";
1365               }
1366               my $taxable_per_month = sprintf("%.2f", $taxable_charged / $freq );
1367               foreach my $which_month ( 1 .. $freq ) {
1368                 my %hash = (
1369                   'custnum' => $self->custnum,
1370                   'taxnum'  => $tax->taxnum,
1371                   'year'    => 1900+$year,
1372                   'month'   => $mon++,
1373                 );
1374                 #until ( $mon < 12 ) { $mon -= 12; $year++; }
1375                 until ( $mon < 13 ) { $mon -= 12; $year++; }
1376                 my $cust_tax_exempt =
1377                   qsearchs('cust_tax_exempt', \%hash)
1378                   || new FS::cust_tax_exempt( { %hash, 'amount' => 0 } );
1379                 my $remaining_exemption = sprintf("%.2f",
1380                   $tax->exempt_amount - $cust_tax_exempt->amount );
1381                 if ( $remaining_exemption > 0 ) {
1382                   my $addl = $remaining_exemption > $taxable_per_month
1383                     ? $taxable_per_month
1384                     : $remaining_exemption;
1385                   $taxable_charged -= $addl;
1386                   my $new_cust_tax_exempt = new FS::cust_tax_exempt ( {
1387                     $cust_tax_exempt->hash,
1388                     'amount' =>
1389                       sprintf("%.2f", $cust_tax_exempt->amount + $addl),
1390                   } );
1391                   $error = $new_cust_tax_exempt->exemptnum
1392                     ? $new_cust_tax_exempt->replace($cust_tax_exempt)
1393                     : $new_cust_tax_exempt->insert;
1394                   if ( $error ) {
1395                     $dbh->rollback if $oldAutoCommit;
1396                     return "fatal: can't update cust_tax_exempt: $error";
1397                   }
1398
1399                 } # if $remaining_exemption > 0
1400
1401               } #foreach $which_month
1402
1403             } #if $tax->exempt_amount
1404
1405             $taxable_charged = sprintf( "%.2f", $taxable_charged);
1406
1407             #$tax += $taxable_charged * $cust_main_county->tax / 100
1408             $tax{ $tax->taxname || 'Tax' } +=
1409               $taxable_charged * $tax->tax / 100
1410
1411           } #foreach my $tax ( @taxes )
1412
1413         } #unless $self->tax =~ /Y/i || $self->payby eq 'COMP'
1414
1415       } #if $setup != 0 || $recur != 0
1416
1417     } #if $cust_pkg->modified
1418
1419   } #foreach my $cust_pkg
1420
1421   my $charged = sprintf( "%.2f", $total_setup + $total_recur );
1422 #  my $taxable_charged = sprintf( "%.2f", $taxable_setup + $taxable_recur );
1423
1424   unless ( @cust_bill_pkg ) { #don't create invoices with no line items
1425     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1426     return '';
1427   }
1428
1429 #  unless ( $self->tax =~ /Y/i
1430 #           || $self->payby eq 'COMP'
1431 #           || $taxable_charged == 0 ) {
1432 #    my $cust_main_county = qsearchs('cust_main_county',{
1433 #        'state'   => $self->state,
1434 #        'county'  => $self->county,
1435 #        'country' => $self->country,
1436 #    } ) or die "fatal: can't find tax rate for state/county/country ".
1437 #               $self->state. "/". $self->county. "/". $self->country. "\n";
1438 #    my $tax = sprintf( "%.2f",
1439 #      $taxable_charged * ( $cust_main_county->getfield('tax') / 100 )
1440 #    );
1441
1442   if ( dbdef->table('cust_bill_pkg')->column('itemdesc') ) { #1.5 schema
1443
1444     foreach my $taxname ( grep { $tax{$_} > 0 } keys %tax ) {
1445       my $tax = sprintf("%.2f", $tax{$taxname} );
1446       $charged = sprintf( "%.2f", $charged+$tax );
1447
1448       my $cust_bill_pkg = new FS::cust_bill_pkg ({
1449         'pkgnum'   => 0,
1450         'setup'    => $tax,
1451         'recur'    => 0,
1452         'sdate'    => '',
1453         'edate'    => '',
1454         'itemdesc' => $taxname,
1455       });
1456       push @cust_bill_pkg, $cust_bill_pkg;
1457     }
1458
1459   } else { #1.4 schema
1460
1461     my $tax = 0;
1462     foreach ( values %tax ) { $tax += $_ };
1463     $tax = sprintf("%.2f", $tax);
1464     if ( $tax > 0 ) {
1465       $charged = sprintf( "%.2f", $charged+$tax );
1466
1467       my $cust_bill_pkg = new FS::cust_bill_pkg ({
1468         'pkgnum' => 0,
1469         'setup'  => $tax,
1470         'recur'  => 0,
1471         'sdate'  => '',
1472         'edate'  => '',
1473       });
1474       push @cust_bill_pkg, $cust_bill_pkg;
1475     }
1476
1477   }
1478
1479   my $cust_bill = new FS::cust_bill ( {
1480     'custnum' => $self->custnum,
1481     '_date'   => $time,
1482     'charged' => $charged,
1483   } );
1484   $error = $cust_bill->insert;
1485   if ( $error ) {
1486     $dbh->rollback if $oldAutoCommit;
1487     return "can't create invoice for customer #". $self->custnum. ": $error";
1488   }
1489
1490   my $invnum = $cust_bill->invnum;
1491   my $cust_bill_pkg;
1492   foreach $cust_bill_pkg ( @cust_bill_pkg ) {
1493     #warn $invnum;
1494     $cust_bill_pkg->invnum($invnum);
1495     $error = $cust_bill_pkg->insert;
1496     if ( $error ) {
1497       $dbh->rollback if $oldAutoCommit;
1498       return "can't create invoice line item for customer #". $self->custnum.
1499              ": $error";
1500     }
1501   }
1502
1503   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1504   ''; #no error
1505 }
1506
1507 =item collect OPTIONS
1508
1509 (Attempt to) collect money for this customer's outstanding invoices (see
1510 L<FS::cust_bill>).  Usually used after the bill method.
1511
1512 Depending on the value of `payby', this may print or email an invoice (I<BILL>,
1513 I<DCRD>, or I<DCHK>), charge a credit card (I<CARD>), charge via electronic
1514 check/ACH (I<CHEK>), or just add any necessary (pseudo-)payment (I<COMP>).
1515
1516 Most actions are now triggered by invoice events; see L<FS::part_bill_event>
1517 and the invoice events web interface.
1518
1519 If there is an error, returns the error, otherwise returns false.
1520
1521 Options are passed as name-value pairs.
1522
1523 Currently available options are:
1524
1525 invoice_time - Use this time when deciding when to print invoices and
1526 late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse>
1527 for conversion functions.
1528
1529 retry - Retry card/echeck/LEC transactions even when not scheduled by invoice
1530 events.
1531
1532 retry_card - Deprecated alias for 'retry'
1533
1534 batch_card - This option is deprecated.  See the invoice events web interface
1535 to control whether cards are batched or run against a realtime gateway.
1536
1537 report_badcard - This option is deprecated.
1538
1539 force_print - This option is deprecated; see the invoice events web interface.
1540
1541 quiet - set true to surpress email card/ACH decline notices.
1542
1543 =cut
1544
1545 sub collect {
1546   my( $self, %options ) = @_;
1547   my $invoice_time = $options{'invoice_time'} || time;
1548
1549   #put below somehow?
1550   local $SIG{HUP} = 'IGNORE';
1551   local $SIG{INT} = 'IGNORE';
1552   local $SIG{QUIT} = 'IGNORE';
1553   local $SIG{TERM} = 'IGNORE';
1554   local $SIG{TSTP} = 'IGNORE';
1555   local $SIG{PIPE} = 'IGNORE';
1556
1557   my $oldAutoCommit = $FS::UID::AutoCommit;
1558   local $FS::UID::AutoCommit = 0;
1559   my $dbh = dbh;
1560
1561   $self->select_for_update; #mutex
1562
1563   my $balance = $self->balance;
1564   warn "collect customer ". $self->custnum. ": balance $balance" if $DEBUG;
1565   unless ( $balance > 0 ) { #redundant?????
1566     $dbh->rollback if $oldAutoCommit; #hmm
1567     return '';
1568   }
1569
1570   if ( exists($options{'retry_card'}) ) {
1571     carp 'retry_card option passed to collect is deprecated; use retry';
1572     $options{'retry'} ||= $options{'retry_card'};
1573   }
1574   if ( exists($options{'retry'}) && $options{'retry'} ) {
1575     my $error = $self->retry_realtime;
1576     if ( $error ) {
1577       $dbh->rollback if $oldAutoCommit;
1578       return $error;
1579     }
1580   }
1581
1582   foreach my $cust_bill ( $self->open_cust_bill ) {
1583
1584     # don't try to charge for the same invoice if it's already in a batch
1585     #next if qsearchs( 'cust_pay_batch', { 'invnum' => $cust_bill->invnum } );
1586
1587     last if $self->balance <= 0;
1588
1589     warn "invnum ". $cust_bill->invnum. " (owed ". $cust_bill->owed. ")"
1590       if $DEBUG;
1591
1592     foreach my $part_bill_event (
1593       sort {    $a->seconds   <=> $b->seconds
1594              || $a->weight    <=> $b->weight
1595              || $a->eventpart <=> $b->eventpart }
1596         grep { $_->seconds <= ( $invoice_time - $cust_bill->_date )
1597                && ! qsearch( 'cust_bill_event', {
1598                                 'invnum'    => $cust_bill->invnum,
1599                                 'eventpart' => $_->eventpart,
1600                                 'status'    => 'done',
1601                                                                    } )
1602              }
1603           qsearch('part_bill_event', { 'payby'    => $self->payby,
1604                                        'disabled' => '',           } )
1605     ) {
1606
1607       last if $cust_bill->owed <= 0  # don't run subsequent events if owed<=0
1608            || $self->balance   <= 0; # or if balance<=0
1609
1610       warn "calling invoice event (". $part_bill_event->eventcode. ")\n"
1611         if $DEBUG;
1612       my $cust_main = $self; #for callback
1613
1614       my $error;
1615       {
1616         local $realtime_bop_decline_quiet = 1 if $options{'quiet'};
1617         local $SIG{__DIE__}; # don't want Mason __DIE__ handler active
1618         $error = eval $part_bill_event->eventcode;
1619       }
1620
1621       my $status = '';
1622       my $statustext = '';
1623       if ( $@ ) {
1624         $status = 'failed';
1625         $statustext = $@;
1626       } elsif ( $error ) {
1627         $status = 'done';
1628         $statustext = $error;
1629       } else {
1630         $status = 'done'
1631       }
1632
1633       #add cust_bill_event
1634       my $cust_bill_event = new FS::cust_bill_event {
1635         'invnum'     => $cust_bill->invnum,
1636         'eventpart'  => $part_bill_event->eventpart,
1637         #'_date'      => $invoice_time,
1638         '_date'      => time,
1639         'status'     => $status,
1640         'statustext' => $statustext,
1641       };
1642       $error = $cust_bill_event->insert;
1643       if ( $error ) {
1644         #$dbh->rollback if $oldAutoCommit;
1645         #return "error: $error";
1646
1647         # gah, even with transactions.
1648         $dbh->commit if $oldAutoCommit; #well.
1649         my $e = 'WARNING: Event run but database not updated - '.
1650                 'error inserting cust_bill_event, invnum #'. $cust_bill->invnum.
1651                 ', eventpart '. $part_bill_event->eventpart.
1652                 ": $error";
1653         warn $e;
1654         return $e;
1655       }
1656
1657
1658     }
1659
1660   }
1661
1662   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1663   '';
1664
1665 }
1666
1667 =item retry_realtime
1668
1669 Schedules realtime credit card / electronic check / LEC billing events for
1670 for retry.  Useful if card information has changed or manual retry is desired.
1671 The 'collect' method must be called to actually retry the transaction.
1672
1673 Implementation details: For each of this customer's open invoices, changes
1674 the status of the first "done" (with statustext error) realtime processing
1675 event to "failed".
1676
1677 =cut
1678
1679 sub retry_realtime {
1680   my $self = shift;
1681
1682   local $SIG{HUP} = 'IGNORE';
1683   local $SIG{INT} = 'IGNORE';
1684   local $SIG{QUIT} = 'IGNORE';
1685   local $SIG{TERM} = 'IGNORE';
1686   local $SIG{TSTP} = 'IGNORE';
1687   local $SIG{PIPE} = 'IGNORE';
1688
1689   my $oldAutoCommit = $FS::UID::AutoCommit;
1690   local $FS::UID::AutoCommit = 0;
1691   my $dbh = dbh;
1692
1693   foreach my $cust_bill (
1694     grep { $_->cust_bill_event }
1695       $self->open_cust_bill
1696   ) {
1697     my @cust_bill_event =
1698       sort { $a->part_bill_event->seconds <=> $b->part_bill_event->seconds }
1699         grep {
1700                #$_->part_bill_event->plan eq 'realtime-card'
1701                $_->part_bill_event->eventcode =~
1702                    /\$cust_bill\->realtime_(card|ach|lec)/
1703                  && $_->status eq 'done'
1704                  && $_->statustext
1705              }
1706           $cust_bill->cust_bill_event;
1707     next unless @cust_bill_event;
1708     my $error = $cust_bill_event[0]->retry;
1709     if ( $error ) {
1710       $dbh->rollback if $oldAutoCommit;
1711       return "error scheduling invoice event for retry: $error";
1712     }
1713
1714   }
1715
1716   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1717   '';
1718
1719 }
1720
1721 =item realtime_bop METHOD AMOUNT [ OPTION => VALUE ... ]
1722
1723 Runs a realtime credit card, ACH (electronic check) or phone bill transaction
1724 via a Business::OnlinePayment realtime gateway.  See
1725 L<http://420.am/business-onlinepayment> for supported gateways.
1726
1727 Available methods are: I<CC>, I<ECHECK> and I<LEC>
1728
1729 Available options are: I<description>, I<invnum>, I<quiet>
1730
1731 The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
1732 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
1733 if set, will override the value from the customer record.
1734
1735 I<description> is a free-text field passed to the gateway.  It defaults to
1736 "Internet services".
1737
1738 If an I<invnum> is specified, this payment (if sucessful) is applied to the
1739 specified invoice.  If you don't specify an I<invnum> you might want to
1740 call the B<apply_payments> method.
1741
1742 I<quiet> can be set true to surpress email decline notices.
1743
1744 (moved from cust_bill) (probably should get realtime_{card,ach,lec} here too)
1745
1746 =cut
1747
1748 sub realtime_bop {
1749   my( $self, $method, $amount, %options ) = @_;
1750   if ( $DEBUG ) {
1751     warn "$self $method $amount\n";
1752     warn "  $_ => $options{$_}\n" foreach keys %options;
1753   }
1754
1755   $options{'description'} ||= 'Internet services';
1756
1757   #pre-requisites
1758   die "Real-time processing not enabled\n"
1759     unless $conf->exists('business-onlinepayment');
1760   eval "use Business::OnlinePayment";
1761   die $@ if $@;
1762
1763   #load up config
1764   my $bop_config = 'business-onlinepayment';
1765   $bop_config .= '-ach'
1766     if $method eq 'ECHECK' && $conf->exists($bop_config. '-ach');
1767   my ( $processor, $login, $password, $action, @bop_options ) =
1768     $conf->config($bop_config);
1769   $action ||= 'normal authorization';
1770   pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
1771   die "No real-time processor is enabled - ".
1772       "did you set the business-onlinepayment configuration value?\n"
1773     unless $processor;
1774
1775   #massage data
1776
1777   my $address = exists($options{'address1'})
1778                     ? $options{'address1'}
1779                     : $self->address1;
1780   my $address2 = exists($options{'address2'})
1781                     ? $options{'address2'}
1782                     : $self->address2;
1783   $address .= ", ". $address2 if length($address2);
1784
1785   my $o_payname = exists($options{'payname'})
1786                     ? $options{'payname'}
1787                     : $self->payname;
1788   my($payname, $payfirst, $paylast);
1789   if ( $o_payname && $method ne 'ECHECK' ) {
1790     ($payname = $o_payname) =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
1791       or return "Illegal payname $payname";
1792     ($payfirst, $paylast) = ($1, $2);
1793   } else {
1794     $payfirst = $self->getfield('first');
1795     $paylast = $self->getfield('last');
1796     $payname =  "$payfirst $paylast";
1797   }
1798
1799   my @invoicing_list = grep { $_ ne 'POST' } $self->invoicing_list;
1800   if ( $conf->exists('emailinvoiceauto')
1801        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1802     push @invoicing_list, $self->all_emails;
1803   }
1804   my $email = $invoicing_list[0];
1805
1806   my $payinfo = exists($options{'payinfo'})
1807                   ? $options{'payinfo'}
1808                   : $self->payinfo;
1809
1810   my %content = ();
1811   if ( $method eq 'CC' ) {
1812
1813     $content{card_number} = $payinfo;
1814     my $paydate = exists($options{'paydate'})
1815                     ? $options{'paydate'}
1816                     : $self->paydate;
1817     $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
1818     $content{expiration} = "$2/$1";
1819
1820     if ( defined $self->dbdef_table->column('paycvv') ) {
1821       my $paycvv = exists($options{'paycvv'})
1822                      ? $options{'paycvv'}
1823                      : $self->paycvv;
1824       $content{cvv2} = $self->paycvv
1825         if length($paycvv);
1826     }
1827
1828     $content{recurring_billing} = 'YES'
1829       if qsearch('cust_pay', { 'custnum' => $self->custnum,
1830                                'payby'   => 'CARD',
1831                                'payinfo' => $payinfo,
1832                              } );
1833
1834   } elsif ( $method eq 'ECHECK' ) {
1835     ( $content{account_number}, $content{routing_code} ) =
1836       split('@', $payinfo);
1837     $content{bank_name} = $o_payname;
1838     $content{account_type} = 'CHECKING';
1839     $content{account_name} = $payname;
1840     $content{customer_org} = $self->company ? 'B' : 'I';
1841     $content{customer_ssn} = exists($options{'ss'})
1842                                ? $options{'ss'}
1843                                : $self->ss;
1844   } elsif ( $method eq 'LEC' ) {
1845     $content{phone} = $payinfo;
1846   }
1847
1848   #transaction(s)
1849
1850   my( $action1, $action2 ) = split(/\s*\,\s*/, $action );
1851
1852   my $transaction = new Business::OnlinePayment( $processor, @bop_options );
1853   $transaction->content(
1854     'type'           => $method,
1855     'login'          => $login,
1856     'password'       => $password,
1857     'action'         => $action1,
1858     'description'    => $options{'description'},
1859     'amount'         => $amount,
1860     'invoice_number' => $options{'invnum'},
1861     'customer_id'    => $self->custnum,
1862     'last_name'      => $paylast,
1863     'first_name'     => $payfirst,
1864     'name'           => $payname,
1865     'address'        => $address,
1866     'city'           => ( exists($options{'city'})
1867                             ? $options{'city'}
1868                             : $self->city          ),
1869     'state'          => ( exists($options{'state'})
1870                             ? $options{'state'}
1871                             : $self->state          ),
1872     'zip'            => ( exists($options{'zip'})
1873                             ? $options{'zip'}
1874                             : $self->zip          ),
1875     'country'        => ( exists($options{'country'})
1876                             ? $options{'country'}
1877                             : $self->country          ),
1878     'referer'        => 'http://cleanwhisker.420.am/',
1879     'email'          => $email,
1880     'phone'          => $self->daytime || $self->night,
1881     %content, #after
1882   );
1883   $transaction->submit();
1884
1885   if ( $transaction->is_success() && $action2 ) {
1886     my $auth = $transaction->authorization;
1887     my $ordernum = $transaction->can('order_number')
1888                    ? $transaction->order_number
1889                    : '';
1890
1891     my $capture =
1892       new Business::OnlinePayment( $processor, @bop_options );
1893
1894     my %capture = (
1895       %content,
1896       type           => $method,
1897       action         => $action2,
1898       login          => $login,
1899       password       => $password,
1900       order_number   => $ordernum,
1901       amount         => $amount,
1902       authorization  => $auth,
1903       description    => $options{'description'},
1904     );
1905
1906     foreach my $field (qw( authorization_source_code returned_ACI                                          transaction_identifier validation_code
1907                            transaction_sequence_num local_transaction_date
1908                            local_transaction_time AVS_result_code          )) {
1909       $capture{$field} = $transaction->$field() if $transaction->can($field);
1910     }
1911
1912     $capture->content( %capture );
1913
1914     $capture->submit();
1915
1916     unless ( $capture->is_success ) {
1917       my $e = "Authorization sucessful but capture failed, custnum #".
1918               $self->custnum. ': '.  $capture->result_code.
1919               ": ". $capture->error_message;
1920       warn $e;
1921       return $e;
1922     }
1923
1924   }
1925
1926   #remove paycvv after initial transaction
1927   #false laziness w/misc/process/payment.cgi - check both to make sure working
1928   # correctly
1929   if ( defined $self->dbdef_table->column('paycvv')
1930        && length($self->paycvv)
1931        && ! grep { $_ eq cardtype($payinfo) } $conf->config('cvv-save')
1932   ) {
1933     my $error = $self->remove_cvv;
1934     if ( $error ) {
1935       warn "error removing cvv: $error\n";
1936     }
1937   }
1938
1939   #result handling
1940   if ( $transaction->is_success() ) {
1941
1942     my %method2payby = (
1943       'CC'     => 'CARD',
1944       'ECHECK' => 'CHEK',
1945       'LEC'    => 'LECB',
1946     );
1947
1948     my $paybatch = "$processor:". $transaction->authorization;
1949     $paybatch .= ':'. $transaction->order_number
1950       if $transaction->can('order_number')
1951       && length($transaction->order_number);
1952
1953     my $cust_pay = new FS::cust_pay ( {
1954        'custnum'  => $self->custnum,
1955        'invnum'   => $options{'invnum'},
1956        'paid'     => $amount,
1957        '_date'     => '',
1958        'payby'    => $method2payby{$method},
1959        'payinfo'  => $payinfo,
1960        'paybatch' => $paybatch,
1961     } );
1962     my $error = $cust_pay->insert;
1963     if ( $error ) {
1964       $cust_pay->invnum(''); #try again with no specific invnum
1965       my $error2 = $cust_pay->insert;
1966       if ( $error2 ) {
1967         # gah, even with transactions.
1968         my $e = 'WARNING: Card/ACH debited but database not updated - '.
1969                 "error inserting payment ($processor): $error2".
1970                 " (previously tried insert with invnum #$options{'invnum'}" .
1971                 ": $error )";
1972         warn $e;
1973         return $e;
1974       }
1975     }
1976     return ''; #no error
1977
1978   } else {
1979
1980     my $perror = "$processor error: ". $transaction->error_message;
1981
1982     if ( !$options{'quiet'} && !$realtime_bop_decline_quiet
1983          && $conf->exists('emaildecline')
1984          && grep { $_ ne 'POST' } $self->invoicing_list
1985          && ! grep { $transaction->error_message =~ /$_/ }
1986                    $conf->config('emaildecline-exclude')
1987     ) {
1988       my @templ = $conf->config('declinetemplate');
1989       my $template = new Text::Template (
1990         TYPE   => 'ARRAY',
1991         SOURCE => [ map "$_\n", @templ ],
1992       ) or return "($perror) can't create template: $Text::Template::ERROR";
1993       $template->compile()
1994         or return "($perror) can't compile template: $Text::Template::ERROR";
1995
1996       my $templ_hash = { error => $transaction->error_message };
1997
1998       my $error = send_email(
1999         'from'    => $conf->config('invoice_from'),
2000         'to'      => [ grep { $_ ne 'POST' } $self->invoicing_list ],
2001         'subject' => 'Your payment could not be processed',
2002         'body'    => [ $template->fill_in(HASH => $templ_hash) ],
2003       );
2004
2005       $perror .= " (also received error sending decline notification: $error)"
2006         if $error;
2007
2008     }
2009
2010     return $perror;
2011   }
2012
2013 }
2014
2015 =item remove_cvv
2016
2017 Removes the I<paycvv> field from the database directly.
2018
2019 If there is an error, returns the error, otherwise returns false.
2020
2021 =cut
2022
2023 sub remove_cvv {
2024   my $self = shift;
2025   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2026     or return dbh->errstr;
2027   $sth->execute($self->custnum)
2028     or return $sth->errstr;
2029   $self->paycvv('');
2030   '';
2031 }
2032
2033 =item realtime_refund_bop METHOD [ OPTION => VALUE ... ]
2034
2035 Refunds a realtime credit card, ACH (electronic check) or phone bill transaction
2036 via a Business::OnlinePayment realtime gateway.  See
2037 L<http://420.am/business-onlinepayment> for supported gateways.
2038
2039 Available methods are: I<CC>, I<ECHECK> and I<LEC>
2040
2041 Available options are: I<amount>, I<reason>, I<paynum>
2042
2043 Most gateways require a reference to an original payment transaction to refund,
2044 so you probably need to specify a I<paynum>.
2045
2046 I<amount> defaults to the original amount of the payment if not specified.
2047
2048 I<reason> specifies a reason for the refund.
2049
2050 Implementation note: If I<amount> is unspecified or equal to the amount of the
2051 orignal payment, first an attempt is made to "void" the transaction via
2052 the gateway (to cancel a not-yet settled transaction) and then if that fails,
2053 the normal attempt is made to "refund" ("credit") the transaction via the
2054 gateway is attempted.
2055
2056 #The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
2057 #I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
2058 #if set, will override the value from the customer record.
2059
2060 #If an I<invnum> is specified, this payment (if sucessful) is applied to the
2061 #specified invoice.  If you don't specify an I<invnum> you might want to
2062 #call the B<apply_payments> method.
2063
2064 =cut
2065
2066 #some false laziness w/realtime_bop, not enough to make it worth merging
2067 #but some useful small subs should be pulled out
2068 sub realtime_refund_bop {
2069   my( $self, $method, %options ) = @_;
2070   if ( $DEBUG ) {
2071     warn "$self $method refund\n";
2072     warn "  $_ => $options{$_}\n" foreach keys %options;
2073   }
2074
2075   #pre-requisites
2076   die "Real-time processing not enabled\n"
2077     unless $conf->exists('business-onlinepayment');
2078   eval "use Business::OnlinePayment";
2079   die $@ if $@;
2080
2081   #load up config
2082   my $bop_config = 'business-onlinepayment';
2083   $bop_config .= '-ach'
2084     if $method eq 'ECHECK' && $conf->exists($bop_config. '-ach');
2085   my ( $processor, $login, $password, $unused_action, @bop_options ) =
2086     $conf->config($bop_config);
2087   #$action ||= 'normal authorization';
2088   pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
2089   die "No real-time processor is enabled - ".
2090       "did you set the business-onlinepayment configuration value?\n"
2091     unless $processor;
2092
2093   my $cust_pay = '';
2094   my $amount = $options{'amount'};
2095   my( $pay_processor, $auth, $order_number ) = ( '', '', '' );
2096   if ( $options{'paynum'} ) {
2097     warn "FS::cust_main::realtime_bop: paynum: $options{paynum}\n" if $DEBUG;
2098     $cust_pay = qsearchs('cust_pay', { paynum=>$options{'paynum'} } )
2099       or return "Unknown paynum $options{'paynum'}";
2100     $amount ||= $cust_pay->paid;
2101     $cust_pay->paybatch =~ /^(\w+):(\w*)(:(\w+))?$/
2102       or return "Can't parse paybatch for paynum $options{'paynum'}: ".
2103                 $cust_pay->paybatch;
2104     ( $pay_processor, $auth, $order_number ) = ( $1, $2, $4 );
2105     return "processor of payment $options{'paynum'} $pay_processor does not".
2106            " match current processor $processor"
2107       unless $pay_processor eq $processor;
2108   }
2109   return "neither amount nor paynum specified" unless $amount;
2110
2111   my %content = (
2112     'type'           => $method,
2113     'login'          => $login,
2114     'password'       => $password,
2115     'order_number'   => $order_number,
2116     'amount'         => $amount,
2117     'referer'        => 'http://cleanwhisker.420.am/',
2118   );
2119   $content{authorization} = $auth
2120     if length($auth); #echeck/ACH transactions have an order # but no auth
2121                       #(at least with authorize.net)
2122
2123   #first try void if applicable
2124   if ( $cust_pay && $cust_pay->paid == $amount ) { #and check dates?
2125     my $void = new Business::OnlinePayment( $processor, @bop_options );
2126     $void->content( 'action' => 'void', %content );
2127     $void->submit();
2128     if ( $void->is_success ) {
2129       my $error = $cust_pay->void($options{'reason'});
2130       if ( $error ) {
2131         # gah, even with transactions.
2132         my $e = 'WARNING: Card/ACH voided but database not updated - '.
2133                 "error voiding payment: $error";
2134         warn $e;
2135         return $e;
2136       }
2137       return '';
2138     }
2139   }
2140
2141   #massage data
2142   my $address = $self->address1;
2143   $address .= ", ". $self->address2 if $self->address2;
2144
2145   my($payname, $payfirst, $paylast);
2146   if ( $self->payname && $method ne 'ECHECK' ) {
2147     $payname = $self->payname;
2148     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
2149       or return "Illegal payname $payname";
2150     ($payfirst, $paylast) = ($1, $2);
2151   } else {
2152     $payfirst = $self->getfield('first');
2153     $paylast = $self->getfield('last');
2154     $payname =  "$payfirst $paylast";
2155   }
2156
2157   if ( $method eq 'CC' ) {
2158
2159     $content{card_number} = $self->payinfo;
2160     $self->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
2161     $content{expiration} = "$2/$1";
2162
2163     #$content{cvv2} = $self->paycvv
2164     #  if defined $self->dbdef_table->column('paycvv')
2165     #     && length($self->paycvv);
2166
2167     #$content{recurring_billing} = 'YES'
2168     #  if qsearch('cust_pay', { 'custnum' => $self->custnum,
2169     #                           'payby'   => 'CARD',
2170     #                           'payinfo' => $self->payinfo, } );
2171
2172   } elsif ( $method eq 'ECHECK' ) {
2173     ( $content{account_number}, $content{routing_code} ) =
2174       split('@', $self->payinfo);
2175     $content{bank_name} = $self->payname;
2176     $content{account_type} = 'CHECKING';
2177     $content{account_name} = $payname;
2178     $content{customer_org} = $self->company ? 'B' : 'I';
2179     $content{customer_ssn} = $self->ss;
2180   } elsif ( $method eq 'LEC' ) {
2181     $content{phone} = $self->payinfo;
2182   }
2183
2184   #then try refund
2185   my $refund = new Business::OnlinePayment( $processor, @bop_options );
2186   $refund->content(
2187     'action'         => 'credit',
2188     'customer_id'    => $self->custnum,
2189     'last_name'      => $paylast,
2190     'first_name'     => $payfirst,
2191     'name'           => $payname,
2192     'address'        => $address,
2193     'city'           => $self->city,
2194     'state'          => $self->state,
2195     'zip'            => $self->zip,
2196     'country'        => $self->country,
2197     %content, #after
2198   );
2199   $refund->submit();
2200
2201   return "$processor error: ". $refund->error_message
2202     unless $refund->is_success();
2203
2204   my %method2payby = (
2205     'CC'     => 'CARD',
2206     'ECHECK' => 'CHEK',
2207     'LEC'    => 'LECB',
2208   );
2209
2210   my $paybatch = "$processor:". $refund->authorization;
2211   $paybatch .= ':'. $refund->order_number
2212     if $refund->can('order_number') && $refund->order_number;
2213
2214   while ( $cust_pay && $cust_pay->unappled < $amount ) {
2215     my @cust_bill_pay = $cust_pay->cust_bill_pay;
2216     last unless @cust_bill_pay;
2217     my $cust_bill_pay = pop @cust_bill_pay;
2218     my $error = $cust_bill_pay->delete;
2219     last if $error;
2220   }
2221
2222   my $cust_refund = new FS::cust_refund ( {
2223     'custnum'  => $self->custnum,
2224     'paynum'   => $options{'paynum'},
2225     'refund'   => $amount,
2226     '_date'    => '',
2227     'payby'    => $method2payby{$method},
2228     'payinfo'  => $self->payinfo,
2229     'paybatch' => $paybatch,
2230     'reason'   => $options{'reason'} || 'card or ACH refund',
2231   } );
2232   my $error = $cust_refund->insert;
2233   if ( $error ) {
2234     $cust_refund->paynum(''); #try again with no specific paynum
2235     my $error2 = $cust_refund->insert;
2236     if ( $error2 ) {
2237       # gah, even with transactions.
2238       my $e = 'WARNING: Card/ACH refunded but database not updated - '.
2239               "error inserting refund ($processor): $error2".
2240               " (previously tried insert with paynum #$options{'paynum'}" .
2241               ": $error )";
2242       warn $e;
2243       return $e;
2244     }
2245   }
2246
2247   ''; #no error
2248
2249 }
2250
2251 =item total_owed
2252
2253 Returns the total owed for this customer on all invoices
2254 (see L<FS::cust_bill/owed>).
2255
2256 =cut
2257
2258 sub total_owed {
2259   my $self = shift;
2260   $self->total_owed_date(2145859200); #12/31/2037
2261 }
2262
2263 =item total_owed_date TIME
2264
2265 Returns the total owed for this customer on all invoices with date earlier than
2266 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2267 see L<Time::Local> and L<Date::Parse> for conversion functions.
2268
2269 =cut
2270
2271 sub total_owed_date {
2272   my $self = shift;
2273   my $time = shift;
2274   my $total_bill = 0;
2275   foreach my $cust_bill (
2276     grep { $_->_date <= $time }
2277       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2278   ) {
2279     $total_bill += $cust_bill->owed;
2280   }
2281   sprintf( "%.2f", $total_bill );
2282 }
2283
2284 =item apply_credits OPTION => VALUE ...
2285
2286 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2287 to outstanding invoice balances in chronological order (or reverse
2288 chronological order if the I<order> option is set to B<newest>) and returns the
2289 value of any remaining unapplied credits available for refund (see
2290 L<FS::cust_refund>).
2291
2292 =cut
2293
2294 sub apply_credits {
2295   my $self = shift;
2296   my %opt = @_;
2297
2298   return 0 unless $self->total_credited;
2299
2300   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2301       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2302
2303   my @invoices = $self->open_cust_bill;
2304   @invoices = sort { $b->_date <=> $a->_date } @invoices
2305     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2306
2307   my $credit;
2308   foreach my $cust_bill ( @invoices ) {
2309     my $amount;
2310
2311     if ( !defined($credit) || $credit->credited == 0) {
2312       $credit = pop @credits or last;
2313     }
2314
2315     if ($cust_bill->owed >= $credit->credited) {
2316       $amount=$credit->credited;
2317     }else{
2318       $amount=$cust_bill->owed;
2319     }
2320
2321     my $cust_credit_bill = new FS::cust_credit_bill ( {
2322       'crednum' => $credit->crednum,
2323       'invnum'  => $cust_bill->invnum,
2324       'amount'  => $amount,
2325     } );
2326     my $error = $cust_credit_bill->insert;
2327     die $error if $error;
2328
2329     redo if ($cust_bill->owed > 0);
2330
2331   }
2332
2333   return $self->total_credited;
2334 }
2335
2336 =item apply_payments
2337
2338 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2339 to outstanding invoice balances in chronological order.
2340
2341  #and returns the value of any remaining unapplied payments.
2342
2343 =cut
2344
2345 sub apply_payments {
2346   my $self = shift;
2347
2348   #return 0 unless
2349
2350   my @payments = sort { $b->_date <=> $a->_date } ( grep { $_->unapplied > 0 }
2351       qsearch('cust_pay', { 'custnum' => $self->custnum } ) );
2352
2353   my @invoices = sort { $a->_date <=> $b->_date} (grep { $_->owed > 0 }
2354       qsearch('cust_bill', { 'custnum' => $self->custnum } ) );
2355
2356   my $payment;
2357
2358   foreach my $cust_bill ( @invoices ) {
2359     my $amount;
2360
2361     if ( !defined($payment) || $payment->unapplied == 0 ) {
2362       $payment = pop @payments or last;
2363     }
2364
2365     if ( $cust_bill->owed >= $payment->unapplied ) {
2366       $amount = $payment->unapplied;
2367     } else {
2368       $amount = $cust_bill->owed;
2369     }
2370
2371     my $cust_bill_pay = new FS::cust_bill_pay ( {
2372       'paynum' => $payment->paynum,
2373       'invnum' => $cust_bill->invnum,
2374       'amount' => $amount,
2375     } );
2376     my $error = $cust_bill_pay->insert;
2377     die $error if $error;
2378
2379     redo if ( $cust_bill->owed > 0);
2380
2381   }
2382
2383   return $self->total_unapplied_payments;
2384 }
2385
2386 =item total_credited
2387
2388 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2389 customer.  See L<FS::cust_credit/credited>.
2390
2391 =cut
2392
2393 sub total_credited {
2394   my $self = shift;
2395   my $total_credit = 0;
2396   foreach my $cust_credit ( qsearch('cust_credit', {
2397     'custnum' => $self->custnum,
2398   } ) ) {
2399     $total_credit += $cust_credit->credited;
2400   }
2401   sprintf( "%.2f", $total_credit );
2402 }
2403
2404 =item total_unapplied_payments
2405
2406 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2407 See L<FS::cust_pay/unapplied>.
2408
2409 =cut
2410
2411 sub total_unapplied_payments {
2412   my $self = shift;
2413   my $total_unapplied = 0;
2414   foreach my $cust_pay ( qsearch('cust_pay', {
2415     'custnum' => $self->custnum,
2416   } ) ) {
2417     $total_unapplied += $cust_pay->unapplied;
2418   }
2419   sprintf( "%.2f", $total_unapplied );
2420 }
2421
2422 =item balance
2423
2424 Returns the balance for this customer (total_owed minus total_credited
2425 minus total_unapplied_payments).
2426
2427 =cut
2428
2429 sub balance {
2430   my $self = shift;
2431   sprintf( "%.2f",
2432     $self->total_owed - $self->total_credited - $self->total_unapplied_payments
2433   );
2434 }
2435
2436 =item balance_date TIME
2437
2438 Returns the balance for this customer, only considering invoices with date
2439 earlier than TIME (total_owed_date minus total_credited minus
2440 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2441 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2442 functions.
2443
2444 =cut
2445
2446 sub balance_date {
2447   my $self = shift;
2448   my $time = shift;
2449   sprintf( "%.2f",
2450     $self->total_owed_date($time)
2451       - $self->total_credited
2452       - $self->total_unapplied_payments
2453   );
2454 }
2455
2456 =item paydate_monthyear
2457
2458 Returns a two-element list consisting of the month and year of this customer's
2459 paydate (credit card expiration date for CARD customers)
2460
2461 =cut
2462
2463 sub paydate_monthyear {
2464   my $self = shift;
2465   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
2466     ( $2, $1 );
2467   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
2468     ( $1, $3 );
2469   } else {
2470     ('', '');
2471   }
2472 }
2473
2474 =item payinfo_masked
2475
2476 Returns a "masked" payinfo field with all but the last four characters replaced
2477 by 'x'es.  Useful for displaying credit cards.
2478
2479 =cut
2480
2481 sub payinfo_masked {
2482   my $self = shift;
2483   my $payinfo = $self->payinfo;
2484   'x'x(length($payinfo)-4). substr($payinfo,(length($payinfo)-4));
2485 }
2486
2487 =item invoicing_list [ ARRAYREF ]
2488
2489 If an arguement is given, sets these email addresses as invoice recipients
2490 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
2491 (except as warnings), so use check_invoicing_list first.
2492
2493 Returns a list of email addresses (with svcnum entries expanded).
2494
2495 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
2496 check it without disturbing anything by passing nothing.
2497
2498 This interface may change in the future.
2499
2500 =cut
2501
2502 sub invoicing_list {
2503   my( $self, $arrayref ) = @_;
2504   if ( $arrayref ) {
2505     my @cust_main_invoice;
2506     if ( $self->custnum ) {
2507       @cust_main_invoice =
2508         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
2509     } else {
2510       @cust_main_invoice = ();
2511     }
2512     foreach my $cust_main_invoice ( @cust_main_invoice ) {
2513       #warn $cust_main_invoice->destnum;
2514       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
2515         #warn $cust_main_invoice->destnum;
2516         my $error = $cust_main_invoice->delete;
2517         warn $error if $error;
2518       }
2519     }
2520     if ( $self->custnum ) {
2521       @cust_main_invoice =
2522         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
2523     } else {
2524       @cust_main_invoice = ();
2525     }
2526     my %seen = map { $_->address => 1 } @cust_main_invoice;
2527     foreach my $address ( @{$arrayref} ) {
2528       next if exists $seen{$address} && $seen{$address};
2529       $seen{$address} = 1;
2530       my $cust_main_invoice = new FS::cust_main_invoice ( {
2531         'custnum' => $self->custnum,
2532         'dest'    => $address,
2533       } );
2534       my $error = $cust_main_invoice->insert;
2535       warn $error if $error;
2536     }
2537   }
2538   if ( $self->custnum ) {
2539     map { $_->address }
2540       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
2541   } else {
2542     ();
2543   }
2544 }
2545
2546 =item check_invoicing_list ARRAYREF
2547
2548 Checks these arguements as valid input for the invoicing_list method.  If there
2549 is an error, returns the error, otherwise returns false.
2550
2551 =cut
2552
2553 sub check_invoicing_list {
2554   my( $self, $arrayref ) = @_;
2555   foreach my $address ( @{$arrayref} ) {
2556     my $cust_main_invoice = new FS::cust_main_invoice ( {
2557       'custnum' => $self->custnum,
2558       'dest'    => $address,
2559     } );
2560     my $error = $self->custnum
2561                 ? $cust_main_invoice->check
2562                 : $cust_main_invoice->checkdest
2563     ;
2564     return $error if $error;
2565   }
2566   '';
2567 }
2568
2569 =item set_default_invoicing_list
2570
2571 Sets the invoicing list to all accounts associated with this customer,
2572 overwriting any previous invoicing list.
2573
2574 =cut
2575
2576 sub set_default_invoicing_list {
2577   my $self = shift;
2578   $self->invoicing_list($self->all_emails);
2579 }
2580
2581 =item all_emails
2582
2583 Returns the email addresses of all accounts provisioned for this customer.
2584
2585 =cut
2586
2587 sub all_emails {
2588   my $self = shift;
2589   my %list;
2590   foreach my $cust_pkg ( $self->all_pkgs ) {
2591     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
2592     my @svc_acct =
2593       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2594         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2595           @cust_svc;
2596     $list{$_}=1 foreach map { $_->email } @svc_acct;
2597   }
2598   keys %list;
2599 }
2600
2601 =item invoicing_list_addpost
2602
2603 Adds postal invoicing to this customer.  If this customer is already configured
2604 to receive postal invoices, does nothing.
2605
2606 =cut
2607
2608 sub invoicing_list_addpost {
2609   my $self = shift;
2610   return if grep { $_ eq 'POST' } $self->invoicing_list;
2611   my @invoicing_list = $self->invoicing_list;
2612   push @invoicing_list, 'POST';
2613   $self->invoicing_list(\@invoicing_list);
2614 }
2615
2616 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
2617
2618 Returns an array of customers referred by this customer (referral_custnum set
2619 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
2620 customers referred by customers referred by this customer and so on, inclusive.
2621 The default behavior is DEPTH 1 (no recursion).
2622
2623 =cut
2624
2625 sub referral_cust_main {
2626   my $self = shift;
2627   my $depth = @_ ? shift : 1;
2628   my $exclude = @_ ? shift : {};
2629
2630   my @cust_main =
2631     map { $exclude->{$_->custnum}++; $_; }
2632       grep { ! $exclude->{ $_->custnum } }
2633         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
2634
2635   if ( $depth > 1 ) {
2636     push @cust_main,
2637       map { $_->referral_cust_main($depth-1, $exclude) }
2638         @cust_main;
2639   }
2640
2641   @cust_main;
2642 }
2643
2644 =item referral_cust_main_ncancelled
2645
2646 Same as referral_cust_main, except only returns customers with uncancelled
2647 packages.
2648
2649 =cut
2650
2651 sub referral_cust_main_ncancelled {
2652   my $self = shift;
2653   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
2654 }
2655
2656 =item referral_cust_pkg [ DEPTH ]
2657
2658 Like referral_cust_main, except returns a flat list of all unsuspended (and
2659 uncancelled) packages for each customer.  The number of items in this list may
2660 be useful for comission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
2661
2662 =cut
2663
2664 sub referral_cust_pkg {
2665   my $self = shift;
2666   my $depth = @_ ? shift : 1;
2667
2668   map { $_->unsuspended_pkgs }
2669     grep { $_->unsuspended_pkgs }
2670       $self->referral_cust_main($depth);
2671 }
2672
2673 =item referring_cust_main
2674
2675 Returns the single cust_main record for the customer who referred this customer
2676 (referral_custnum), or false.
2677
2678 =cut
2679
2680 sub referring_cust_main {
2681   my $self = shift;
2682   return '' unless $self->referral_custnum;
2683   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
2684 }
2685
2686 =item credit AMOUNT, REASON
2687
2688 Applies a credit to this customer.  If there is an error, returns the error,
2689 otherwise returns false.
2690
2691 =cut
2692
2693 sub credit {
2694   my( $self, $amount, $reason ) = @_;
2695   my $cust_credit = new FS::cust_credit {
2696     'custnum' => $self->custnum,
2697     'amount'  => $amount,
2698     'reason'  => $reason,
2699   };
2700   $cust_credit->insert;
2701 }
2702
2703 =item charge AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
2704
2705 Creates a one-time charge for this customer.  If there is an error, returns
2706 the error, otherwise returns false.
2707
2708 =cut
2709
2710 sub charge {
2711   my ( $self, $amount ) = ( shift, shift );
2712   my $pkg      = @_ ? shift : 'One-time charge';
2713   my $comment  = @_ ? shift : '$'. sprintf("%.2f",$amount);
2714   my $taxclass = @_ ? shift : '';
2715
2716   local $SIG{HUP} = 'IGNORE';
2717   local $SIG{INT} = 'IGNORE';
2718   local $SIG{QUIT} = 'IGNORE';
2719   local $SIG{TERM} = 'IGNORE';
2720   local $SIG{TSTP} = 'IGNORE';
2721   local $SIG{PIPE} = 'IGNORE';
2722
2723   my $oldAutoCommit = $FS::UID::AutoCommit;
2724   local $FS::UID::AutoCommit = 0;
2725   my $dbh = dbh;
2726
2727   my $part_pkg = new FS::part_pkg ( {
2728     'pkg'      => $pkg,
2729     'comment'  => $comment,
2730     #'setup'    => $amount,
2731     #'recur'    => '0',
2732     'plan'     => 'flat',
2733     'plandata' => "setup_fee=$amount",
2734     'freq'     => 0,
2735     'disabled' => 'Y',
2736     'taxclass' => $taxclass,
2737   } );
2738
2739   my $error = $part_pkg->insert;
2740   if ( $error ) {
2741     $dbh->rollback if $oldAutoCommit;
2742     return $error;
2743   }
2744
2745   my $pkgpart = $part_pkg->pkgpart;
2746   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
2747   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
2748     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
2749     $error = $type_pkgs->insert;
2750     if ( $error ) {
2751       $dbh->rollback if $oldAutoCommit;
2752       return $error;
2753     }
2754   }
2755
2756   my $cust_pkg = new FS::cust_pkg ( {
2757     'custnum' => $self->custnum,
2758     'pkgpart' => $pkgpart,
2759   } );
2760
2761   $error = $cust_pkg->insert;
2762   if ( $error ) {
2763     $dbh->rollback if $oldAutoCommit;
2764     return $error;
2765   }
2766
2767   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2768   '';
2769
2770 }
2771
2772 =item cust_bill
2773
2774 Returns all the invoices (see L<FS::cust_bill>) for this customer.
2775
2776 =cut
2777
2778 sub cust_bill {
2779   my $self = shift;
2780   sort { $a->_date <=> $b->_date }
2781     qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2782 }
2783
2784 =item open_cust_bill
2785
2786 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
2787 customer.
2788
2789 =cut
2790
2791 sub open_cust_bill {
2792   my $self = shift;
2793   grep { $_->owed > 0 } $self->cust_bill;
2794 }
2795
2796 =item cust_credit
2797
2798 Returns all the credits (see L<FS::cust_credit>) for this customer.
2799
2800 =cut
2801
2802 sub cust_credit {
2803   my $self = shift;
2804   sort { $a->_date <=> $b->_date }
2805     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
2806 }
2807
2808 =item cust_pay
2809
2810 Returns all the payments (see L<FS::cust_pay>) for this customer.
2811
2812 =cut
2813
2814 sub cust_pay {
2815   my $self = shift;
2816   sort { $a->_date <=> $b->_date }
2817     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
2818 }
2819
2820 =item cust_pay_void
2821
2822 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
2823
2824 =cut
2825
2826 sub cust_pay_void {
2827   my $self = shift;
2828   sort { $a->_date <=> $b->_date }
2829     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
2830 }
2831
2832
2833 =item cust_refund
2834
2835 Returns all the refunds (see L<FS::cust_refund>) for this customer.
2836
2837 =cut
2838
2839 sub cust_refund {
2840   my $self = shift;
2841   sort { $a->_date <=> $b->_date }
2842     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
2843 }
2844
2845 =item select_for_update
2846
2847 Selects this record with the SQL "FOR UPDATE" command.  This can be useful as
2848 a mutex.
2849
2850 =cut
2851
2852 sub select_for_update {
2853   my $self = shift;
2854   qsearch('cust_main', { 'custnum' => $self->custnum }, '*', 'FOR UPDATE' );
2855 }
2856
2857 =item name
2858
2859 Returns a name string for this customer, either "Company (Last, First)" or
2860 "Last, First".
2861
2862 =cut
2863
2864 sub name {
2865   my $self = shift;
2866   my $name = $self->get('last'). ', '. $self->first;
2867   $name = $self->company. " ($name)" if $self->company;
2868   $name;
2869 }
2870
2871 =item status
2872
2873 Returns a status string for this customer, currently:
2874
2875 =over 4
2876
2877 =item prospect - No packages have ever been ordered
2878
2879 =item active - One or more recurring packages is active
2880
2881 =item suspended - All non-cancelled recurring packages are suspended
2882
2883 =item cancelled - All recurring packages are cancelled
2884
2885 =back
2886
2887 =cut
2888
2889 sub status {
2890   my $self = shift;
2891   for my $status (qw( prospect active suspended cancelled )) {
2892     my $method = $status.'_sql';
2893     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
2894     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
2895     $sth->execute( ($self->custnum) x $numnum ) or die $sth->errstr;
2896     return $status if $sth->fetchrow_arrayref->[0];
2897   }
2898 }
2899
2900 =item statuscolor
2901
2902 Returns a hex triplet color string for this customer's status.
2903
2904 =cut
2905
2906 my %statuscolor = (
2907   'prospect'  => '000000',
2908   'active'    => '00CC00',
2909   'suspended' => 'FF9900',
2910   'cancelled' => 'FF0000',
2911 );
2912 sub statuscolor {
2913   my $self = shift;
2914   $statuscolor{$self->status};
2915 }
2916
2917 =back
2918
2919 =head1 CLASS METHODS
2920
2921 =over 4
2922
2923 =item prospect_sql
2924
2925 Returns an SQL expression identifying prospective cust_main records (customers
2926 with no packages ever ordered)
2927
2928 =cut
2929
2930 sub prospect_sql { "
2931   0 = ( SELECT COUNT(*) FROM cust_pkg
2932           WHERE cust_pkg.custnum = cust_main.custnum
2933       )
2934 "; }
2935
2936 =item active_sql
2937
2938 Returns an SQL expression identifying active cust_main records.
2939
2940 =cut
2941
2942 sub active_sql { "
2943   0 < ( SELECT COUNT(*) FROM cust_pkg
2944           WHERE cust_pkg.custnum = cust_main.custnum
2945             AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
2946             AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
2947       )
2948 "; }
2949
2950 =item susp_sql
2951 =item suspended_sql
2952
2953 Returns an SQL expression identifying suspended cust_main records.
2954
2955 =cut
2956
2957 sub suspended_sql { susp_sql(@_); }
2958 sub susp_sql { "
2959     0 < ( SELECT COUNT(*) FROM cust_pkg
2960             WHERE cust_pkg.custnum = cust_main.custnum
2961               AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
2962         )
2963     AND 0 = ( SELECT COUNT(*) FROM cust_pkg
2964                 WHERE cust_pkg.custnum = cust_main.custnum
2965                   AND ( cust_pkg.susp IS NULL OR cust_pkg.susp = 0 )
2966                   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
2967             )
2968 "; }
2969
2970 =item cancel_sql
2971 =item cancelled_sql
2972
2973 Returns an SQL expression identifying cancelled cust_main records.
2974
2975 =cut
2976
2977 sub cancelled_sql { cancel_sql(@_); }
2978 sub cancel_sql { "
2979   0 < ( SELECT COUNT(*) FROM cust_pkg
2980           WHERE cust_pkg.custnum = cust_main.custnum
2981       )
2982   AND 0 = ( SELECT COUNT(*) FROM cust_pkg
2983               WHERE cust_pkg.custnum = cust_main.custnum
2984                 AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
2985           )
2986 "; }
2987
2988 =item fuzzy_search FUZZY_HASHREF [ HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ ]
2989
2990 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
2991 records.  Currently, only I<last> or I<company> may be specified (the
2992 appropriate ship_ field is also searched if applicable).
2993
2994 Additional options are the same as FS::Record::qsearch
2995
2996 =cut
2997
2998 sub fuzzy_search {
2999   my( $self, $fuzzy, $hash, @opt) = @_;
3000   #$self
3001   $hash ||= {};
3002   my @cust_main = ();
3003
3004   check_and_rebuild_fuzzyfiles();
3005   foreach my $field ( keys %$fuzzy ) {
3006     my $sub = \&{"all_$field"};
3007     my %match = ();
3008     $match{$_}=1 foreach ( amatch($fuzzy->{$field}, ['i'], @{ &$sub() } ) );
3009
3010     foreach ( keys %match ) {
3011       push @cust_main, qsearch('cust_main', { %$hash, $field=>$_}, @opt);
3012       push @cust_main, qsearch('cust_main', { %$hash, "ship_$field"=>$_}, @opt)
3013         if defined dbdef->table('cust_main')->column('ship_last');
3014     }
3015   }
3016
3017   my %saw = ();
3018   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
3019
3020   @cust_main;
3021
3022 }
3023
3024 =back
3025
3026 =head1 SUBROUTINES
3027
3028 =over 4
3029
3030 =item smart_search OPTION => VALUE ...
3031
3032 Accepts the following options: I<search>, the string to search for.  The string
3033 will be searched for as a customer number, last name or company name, first
3034 searching for an exact match then fuzzy and substring matches.
3035
3036 Any additional options treated as an additional qualifier on the search
3037 (i.e. I<agentnum>).
3038
3039 Returns a (possibly empty) array of FS::cust_main objects.
3040
3041 =cut
3042
3043 sub smart_search {
3044   my %options = @_;
3045   my $search = delete $options{'search'};
3046   my @cust_main = ();
3047
3048   if ( $search =~ /^\s*(\d+)\s*$/ ) { # customer # search
3049
3050     push @cust_main, qsearch('cust_main', { 'custnum' => $1, %options } );
3051
3052   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { #value search
3053
3054     my $value = lc($1);
3055     my $q_value = dbh->quote($value);
3056
3057     #exact
3058     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
3059     $sql .= " ( LOWER(last) = $q_value OR LOWER(company) = $q_value";
3060     $sql .= " OR LOWER(ship_last) = $q_value OR LOWER(ship_company) = $q_value"
3061       if defined dbdef->table('cust_main')->column('ship_last');
3062     $sql .= ' )';
3063
3064     push @cust_main, qsearch( 'cust_main', \%options, '', $sql );
3065
3066     unless ( @cust_main ) {  #no exact match, trying substring/fuzzy
3067
3068       #still some false laziness w/ search/cust_main.cgi
3069
3070       #substring
3071       push @cust_main, qsearch( 'cust_main',
3072                                 { 'last'     => { 'op'    => 'ILIKE',
3073                                                   'value' => "%$q_value%" },
3074                                   %options,
3075                                 }
3076                               );
3077       push @cust_main, qsearch( 'cust_main',
3078                                 { 'ship_last' => { 'op'    => 'ILIKE',
3079                                                    'value' => "%$q_value%" },
3080                                   %options,
3081
3082                                 }
3083                               )
3084         if defined dbdef->table('cust_main')->column('ship_last');
3085
3086       push @cust_main, qsearch( 'cust_main',
3087                                 { 'company'  => { 'op'    => 'ILIKE',
3088                                                   'value' => "%$q_value%" },
3089                                   %options,
3090                                 }
3091                               );
3092       push @cust_main, qsearch( 'cust_main',
3093                                 { 'ship_company' => { 'op' => 'ILIKE',
3094                                                    'value' => "%$q_value%" },
3095                                   %options,
3096                                 }
3097                               )
3098         if defined dbdef->table('cust_main')->column('ship_last');
3099
3100       #fuzzy
3101       push @cust_main, FS::cust_main->fuzzy_search(
3102         { 'last'     => $value },
3103         \%options,
3104       );
3105       push @cust_main, FS::cust_main->fuzzy_search(
3106         { 'company'  => $value },
3107         \%options,
3108       );
3109
3110     }
3111
3112   }
3113
3114   @cust_main;
3115
3116 }
3117
3118 =item check_and_rebuild_fuzzyfiles
3119
3120 =cut
3121
3122 sub check_and_rebuild_fuzzyfiles {
3123   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
3124   -e "$dir/cust_main.last" && -e "$dir/cust_main.company"
3125     or &rebuild_fuzzyfiles;
3126 }
3127
3128 =item rebuild_fuzzyfiles
3129
3130 =cut
3131
3132 sub rebuild_fuzzyfiles {
3133
3134   use Fcntl qw(:flock);
3135
3136   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
3137
3138   #last
3139
3140   open(LASTLOCK,">>$dir/cust_main.last")
3141     or die "can't open $dir/cust_main.last: $!";
3142   flock(LASTLOCK,LOCK_EX)
3143     or die "can't lock $dir/cust_main.last: $!";
3144
3145   my @all_last = map $_->getfield('last'), qsearch('cust_main', {});
3146   push @all_last,
3147                  grep $_, map $_->getfield('ship_last'), qsearch('cust_main',{})
3148     if defined dbdef->table('cust_main')->column('ship_last');
3149
3150   open (LASTCACHE,">$dir/cust_main.last.tmp")
3151     or die "can't open $dir/cust_main.last.tmp: $!";
3152   print LASTCACHE join("\n", @all_last), "\n";
3153   close LASTCACHE or die "can't close $dir/cust_main.last.tmp: $!";
3154
3155   rename "$dir/cust_main.last.tmp", "$dir/cust_main.last";
3156   close LASTLOCK;
3157
3158   #company
3159
3160   open(COMPANYLOCK,">>$dir/cust_main.company")
3161     or die "can't open $dir/cust_main.company: $!";
3162   flock(COMPANYLOCK,LOCK_EX)
3163     or die "can't lock $dir/cust_main.company: $!";
3164
3165   my @all_company = grep $_ ne '', map $_->company, qsearch('cust_main',{});
3166   push @all_company,
3167        grep $_ ne '', map $_->ship_company, qsearch('cust_main', {})
3168     if defined dbdef->table('cust_main')->column('ship_last');
3169
3170   open (COMPANYCACHE,">$dir/cust_main.company.tmp")
3171     or die "can't open $dir/cust_main.company.tmp: $!";
3172   print COMPANYCACHE join("\n", @all_company), "\n";
3173   close COMPANYCACHE or die "can't close $dir/cust_main.company.tmp: $!";
3174
3175   rename "$dir/cust_main.company.tmp", "$dir/cust_main.company";
3176   close COMPANYLOCK;
3177
3178 }
3179
3180 =item all_last
3181
3182 =cut
3183
3184 sub all_last {
3185   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
3186   open(LASTCACHE,"<$dir/cust_main.last")
3187     or die "can't open $dir/cust_main.last: $!";
3188   my @array = map { chomp; $_; } <LASTCACHE>;
3189   close LASTCACHE;
3190   \@array;
3191 }
3192
3193 =item all_company
3194
3195 =cut
3196
3197 sub all_company {
3198   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
3199   open(COMPANYCACHE,"<$dir/cust_main.company")
3200     or die "can't open $dir/cust_main.last: $!";
3201   my @array = map { chomp; $_; } <COMPANYCACHE>;
3202   close COMPANYCACHE;
3203   \@array;
3204 }
3205
3206 =item append_fuzzyfiles LASTNAME COMPANY
3207
3208 =cut
3209
3210 sub append_fuzzyfiles {
3211   my( $last, $company ) = @_;
3212
3213   &check_and_rebuild_fuzzyfiles;
3214
3215   use Fcntl qw(:flock);
3216
3217   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
3218
3219   if ( $last ) {
3220
3221     open(LAST,">>$dir/cust_main.last")
3222       or die "can't open $dir/cust_main.last: $!";
3223     flock(LAST,LOCK_EX)
3224       or die "can't lock $dir/cust_main.last: $!";
3225
3226     print LAST "$last\n";
3227
3228     flock(LAST,LOCK_UN)
3229       or die "can't unlock $dir/cust_main.last: $!";
3230     close LAST;
3231   }
3232
3233   if ( $company ) {
3234
3235     open(COMPANY,">>$dir/cust_main.company")
3236       or die "can't open $dir/cust_main.company: $!";
3237     flock(COMPANY,LOCK_EX)
3238       or die "can't lock $dir/cust_main.company: $!";
3239
3240     print COMPANY "$company\n";
3241
3242     flock(COMPANY,LOCK_UN)
3243       or die "can't unlock $dir/cust_main.company: $!";
3244
3245     close COMPANY;
3246   }
3247
3248   1;
3249 }
3250
3251 =item batch_import
3252
3253 =cut
3254
3255 sub batch_import {
3256   my $param = shift;
3257   #warn join('-',keys %$param);
3258   my $fh = $param->{filehandle};
3259   my $agentnum = $param->{agentnum};
3260   my $refnum = $param->{refnum};
3261   my $pkgpart = $param->{pkgpart};
3262   my @fields = @{$param->{fields}};
3263
3264   eval "use Date::Parse;";
3265   die $@ if $@;
3266   eval "use Text::CSV_XS;";
3267   die $@ if $@;
3268
3269   my $csv = new Text::CSV_XS;
3270   #warn $csv;
3271   #warn $fh;
3272
3273   my $imported = 0;
3274   #my $columns;
3275
3276   local $SIG{HUP} = 'IGNORE';
3277   local $SIG{INT} = 'IGNORE';
3278   local $SIG{QUIT} = 'IGNORE';
3279   local $SIG{TERM} = 'IGNORE';
3280   local $SIG{TSTP} = 'IGNORE';
3281   local $SIG{PIPE} = 'IGNORE';
3282
3283   my $oldAutoCommit = $FS::UID::AutoCommit;
3284   local $FS::UID::AutoCommit = 0;
3285   my $dbh = dbh;
3286
3287   #while ( $columns = $csv->getline($fh) ) {
3288   my $line;
3289   while ( defined($line=<$fh>) ) {
3290
3291     $csv->parse($line) or do {
3292       $dbh->rollback if $oldAutoCommit;
3293       return "can't parse: ". $csv->error_input();
3294     };
3295
3296     my @columns = $csv->fields();
3297     #warn join('-',@columns);
3298
3299     my %cust_main = (
3300       agentnum => $agentnum,
3301       refnum   => $refnum,
3302       country  => $conf->config('countrydefault') || 'US',
3303       payby    => 'BILL', #default
3304       paydate  => '12/2037', #default
3305     );
3306     my $billtime = time;
3307     my %cust_pkg = ( pkgpart => $pkgpart );
3308     foreach my $field ( @fields ) {
3309       if ( $field =~ /^cust_pkg\.(setup|bill|susp|expire|cancel)$/ ) {
3310         #$cust_pkg{$1} = str2time( shift @$columns );
3311         if ( $1 eq 'setup' ) {
3312           $billtime = str2time(shift @columns);
3313         } else {
3314           $cust_pkg{$1} = str2time( shift @columns );
3315         }
3316       } else {
3317         #$cust_main{$field} = shift @$columns;
3318         $cust_main{$field} = shift @columns;
3319       }
3320     }
3321
3322     my $cust_pkg = new FS::cust_pkg ( \%cust_pkg ) if $pkgpart;
3323     my $cust_main = new FS::cust_main ( \%cust_main );
3324     use Tie::RefHash;
3325     tie my %hash, 'Tie::RefHash'; #this part is important
3326     $hash{$cust_pkg} = [] if $pkgpart;
3327     my $error = $cust_main->insert( \%hash );
3328
3329     if ( $error ) {
3330       $dbh->rollback if $oldAutoCommit;
3331       return "can't insert customer for $line: $error";
3332     }
3333
3334     #false laziness w/bill.cgi
3335     $error = $cust_main->bill( 'time' => $billtime );
3336     if ( $error ) {
3337       $dbh->rollback if $oldAutoCommit;
3338       return "can't bill customer for $line: $error";
3339     }
3340
3341     $cust_main->apply_payments;
3342     $cust_main->apply_credits;
3343
3344     $error = $cust_main->collect();
3345     if ( $error ) {
3346       $dbh->rollback if $oldAutoCommit;
3347       return "can't collect customer for $line: $error";
3348     }
3349
3350     $imported++;
3351   }
3352
3353   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3354
3355   return "Empty file!" unless $imported;
3356
3357   ''; #no error
3358
3359 }
3360
3361 =item batch_charge
3362
3363 =cut
3364
3365 sub batch_charge {
3366   my $param = shift;
3367   #warn join('-',keys %$param);
3368   my $fh = $param->{filehandle};
3369   my @fields = @{$param->{fields}};
3370
3371   eval "use Date::Parse;";
3372   die $@ if $@;
3373   eval "use Text::CSV_XS;";
3374   die $@ if $@;
3375
3376   my $csv = new Text::CSV_XS;
3377   #warn $csv;
3378   #warn $fh;
3379
3380   my $imported = 0;
3381   #my $columns;
3382
3383   local $SIG{HUP} = 'IGNORE';
3384   local $SIG{INT} = 'IGNORE';
3385   local $SIG{QUIT} = 'IGNORE';
3386   local $SIG{TERM} = 'IGNORE';
3387   local $SIG{TSTP} = 'IGNORE';
3388   local $SIG{PIPE} = 'IGNORE';
3389
3390   my $oldAutoCommit = $FS::UID::AutoCommit;
3391   local $FS::UID::AutoCommit = 0;
3392   my $dbh = dbh;
3393
3394   #while ( $columns = $csv->getline($fh) ) {
3395   my $line;
3396   while ( defined($line=<$fh>) ) {
3397
3398     $csv->parse($line) or do {
3399       $dbh->rollback if $oldAutoCommit;
3400       return "can't parse: ". $csv->error_input();
3401     };
3402
3403     my @columns = $csv->fields();
3404     #warn join('-',@columns);
3405
3406     my %row = ();
3407     foreach my $field ( @fields ) {
3408       $row{$field} = shift @columns;
3409     }
3410
3411     my $cust_main = qsearchs('cust_main', { 'custnum' => $row{'custnum'} } );
3412     unless ( $cust_main ) {
3413       $dbh->rollback if $oldAutoCommit;
3414       return "unknown custnum $row{'custnum'}";
3415     }
3416
3417     if ( $row{'amount'} > 0 ) {
3418       my $error = $cust_main->charge($row{'amount'}, $row{'pkg'});
3419       if ( $error ) {
3420         $dbh->rollback if $oldAutoCommit;
3421         return $error;
3422       }
3423       $imported++;
3424     } elsif ( $row{'amount'} < 0 ) {
3425       my $error = $cust_main->credit( sprintf( "%.2f", 0-$row{'amount'} ),
3426                                       $row{'pkg'}                         );
3427       if ( $error ) {
3428         $dbh->rollback if $oldAutoCommit;
3429         return $error;
3430       }
3431       $imported++;
3432     } else {
3433       #hmm?
3434     }
3435
3436   }
3437
3438   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3439
3440   return "Empty file!" unless $imported;
3441
3442   ''; #no error
3443
3444 }
3445
3446 =back
3447
3448 =head1 BUGS
3449
3450 The delete method.
3451
3452 The delete method should possibly take an FS::cust_main object reference
3453 instead of a scalar customer number.
3454
3455 Bill and collect options should probably be passed as references instead of a
3456 list.
3457
3458 There should probably be a configuration file with a list of allowed credit
3459 card types.
3460
3461 No multiple currency support (probably a larger project than just this module).
3462
3463 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
3464
3465 =head1 SEE ALSO
3466
3467 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
3468 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
3469 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
3470
3471 =cut
3472
3473 1;
3474