FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Data::Dumper;
  26 use Tie::IxHash;
  27 use Date::Format;
  28 #use Date::Manip;
  29 use File::Temp; #qw( tempfile );
  30 use Business::CreditCard 0.28;
  31 use List::Util qw(min);
  32 use FS::UID qw( dbh driver_name );
  33 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  34 use FS::Cursor;
  35 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  36 use FS::Msgcat qw(gettext);
  37 use FS::CurrentUser;
  38 use FS::TicketSystem;
  39 use FS::payby;
  40 use FS::cust_pkg;
  41 use FS::cust_svc;
  42 use FS::cust_bill;
  43 use FS::cust_bill_void;
  44 use FS::legacy_cust_bill;
  45 use FS::cust_pay;
  46 use FS::cust_pay_pending;
  47 use FS::cust_pay_void;
  48 use FS::cust_pay_batch;
  49 use FS::cust_credit;
  50 use FS::cust_refund;
  51 use FS::part_referral;
  52 use FS::cust_main_county;
  53 use FS::cust_location;
  54 use FS::cust_class;
  55 use FS::tax_status;
  56 use FS::cust_main_exemption;
  57 use FS::cust_tax_adjustment;
  58 use FS::cust_tax_location;
  59 use FS::agent_currency;
  60 use FS::cust_main_invoice;
  61 use FS::cust_tag;
  62 use FS::prepay_credit;
  63 use FS::queue;
  64 use FS::part_pkg;
  65 use FS::part_export;
  66 #use FS::cust_event;
  67 use FS::type_pkgs;
  68 use FS::payment_gateway;
  69 use FS::agent_payment_gateway;
  70 use FS::banned_pay;
  71 use FS::cust_main_note;
  72 use FS::cust_attachment;
  73 use FS::cust_contact;
  74 use FS::Locales;
  75 use FS::upgrade_journal;
  76 use FS::sales;
  77 use FS::cust_payby;
  78 use FS::contact;
  79 use FS::reason;
  80
  81 # 1 is mostly method/subroutine entry and options
  82 # 2 traces progress of some operations
  83 # 3 is even more information including possibly sensitive data
  84 our $DEBUG = 0;
  85 our $me = '[FS::cust_main]';
  86
  87 our $import = 0;
  88 our $ignore_expired_card = 0;
  89 our $ignore_banned_card = 0;
  90 our $ignore_invalid_card = 0;
  91
  92 our $skip_fuzzyfiles = 0;
  93
  94 our $ucfirst_nowarn = 0;
  95
  96 #this info is in cust_payby as of 4.x
  97 #this and the fields themselves can be removed in 5.x
  98 our @encrypted_fields = ('payinfo', 'paycvv');
  99 sub nohistory_fields { ('payinfo', 'paycvv'); }
 100
 101 our $conf;
 102 our $default_agent_custid;
 103 our $custnum_display_length;
 104 #ask FS::UID to run this stuff for us later
 105 #$FS::UID::callback{'FS::cust_main'} = sub {
 106 install_callback FS::UID sub {
 107   $conf = new FS::Conf;
 108   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 109   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 110   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 111 };
 112
 113 sub _cache {
 114   my $self = shift;
 115   my ( $hashref, $cache ) = @_;
 116   if ( exists $hashref->{'pkgnum'} ) {
 117     #@{ $self->{'_pkgnum'} } = ();
 118     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 119     $self->{'_pkgnum'} = $subcache;
 120     #push @{ $self->{'_pkgnum'} },
 121     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 122   }
 123 }
 124
 125 =head1 NAME
 126
 127 FS::cust_main - Object methods for cust_main records
 128
 129 =head1 SYNOPSIS
 130
 131   use FS::cust_main;
 132
 133   $record = new FS::cust_main \%hash;
 134   $record = new FS::cust_main { 'column' => 'value' };
 135
 136   $error = $record->insert;
 137
 138   $error = $new_record->replace($old_record);
 139
 140   $error = $record->delete;
 141
 142   $error = $record->check;
 143
 144   @cust_pkg = $record->all_pkgs;
 145
 146   @cust_pkg = $record->ncancelled_pkgs;
 147
 148   @cust_pkg = $record->suspended_pkgs;
 149
 150   $error = $record->bill;
 151   $error = $record->bill %options;
 152   $error = $record->bill 'time' => $time;
 153
 154   $error = $record->collect;
 155   $error = $record->collect %options;
 156   $error = $record->collect 'invoice_time'   => $time,
 157                           ;
 158
 159 =head1 DESCRIPTION
 160
 161 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 162 FS::Record.  The following fields are currently supported:
 163
 164 =over 4
 165
 166 =item custnum
 167
 168 Primary key (assigned automatically for new customers)
 169
 170 =item agentnum
 171
 172 Agent (see L<FS::agent>)
 173
 174 =item refnum
 175
 176 Advertising source (see L<FS::part_referral>)
 177
 178 =item first
 179
 180 First name
 181
 182 =item last
 183
 184 Last name
 185
 186 =item ss
 187
 188 Cocial security number (optional)
 189
 190 =item company
 191
 192 (optional)
 193
 194 =item daytime
 195
 196 phone (optional)
 197
 198 =item night
 199
 200 phone (optional)
 201
 202 =item fax
 203
 204 phone (optional)
 205
 206 =item mobile
 207
 208 phone (optional)
 209
 210 =item payby
 211
 212 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 213
 214 =item payinfo
 215
 216 Payment Information (See L<FS::payinfo_Mixin> for data format)
 217
 218 =item paymask
 219
 220 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 221
 222 =item paycvv
 223
 224 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 225
 226 =item paydate
 227
 228 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 229
 230 =item paystart_month
 231
 232 Start date month (maestro/solo cards only)
 233
 234 =item paystart_year
 235
 236 Start date year (maestro/solo cards only)
 237
 238 =item payissue
 239
 240 Issue number (maestro/solo cards only)
 241
 242 =item payname
 243
 244 Name on card or billing name
 245
 246 =item payip
 247
 248 IP address from which payment information was received
 249
 250 =item tax
 251
 252 Tax exempt, empty or `Y'
 253
 254 =item usernum
 255
 256 Order taker (see L<FS::access_user>)
 257
 258 =item comments
 259
 260 Comments (optional)
 261
 262 =item referral_custnum
 263
 264 Referring customer number
 265
 266 =item spool_cdr
 267
 268 Enable individual CDR spooling, empty or `Y'
 269
 270 =item dundate
 271
 272 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 273
 274 =item squelch_cdr
 275
 276 Discourage individual CDR printing, empty or `Y'
 277
 278 =item edit_subject
 279
 280 Allow self-service editing of ticket subjects, empty or 'Y'
 281
 282 =item calling_list_exempt
 283
 284 Do not call, empty or 'Y'
 285
 286 =item invoice_ship_address
 287
 288 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 289
 290 =back
 291
 292 =head1 METHODS
 293
 294 =over 4
 295
 296 =item new HASHREF
 297
 298 Creates a new customer.  To add the customer to the database, see L<"insert">.
 299
 300 Note that this stores the hash reference, not a distinct copy of the hash it
 301 points to.  You can ask the object for a copy with the I<hash> method.
 302
 303 =cut
 304
 305 sub table { 'cust_main'; }
 306
 307 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 308
 309 Adds this customer to the database.  If there is an error, returns the error,
 310 otherwise returns false.
 311
 312 Usually the customer's location will not yet exist in the database, and
 313 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 314 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 315 (in both directions) to the new customer record.  If they're references
 316 to the same object, they will become the same location.
 317
 318 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 319 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 320 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 321 hash reference is equivalent to not supplying this parameter.  There should be
 322 a better explanation of this, but until then, here's an example:
 323
 324   use Tie::RefHash;
 325   tie %hash, 'Tie::RefHash'; #this part is important
 326   %hash = (
 327     $cust_pkg => [ $svc_acct ],
 328     ...
 329   );
 330   $cust_main->insert( \%hash );
 331
 332 INVOICING_LIST_ARYREF: No longer supported.
 333
 334 Currently available options are: I<depend_jobnum>, I<noexport>,
 335 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 336
 337 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 338 on the supplied jobnum (they will not run until the specific job completes).
 339 This can be used to defer provisioning until some action completes (such
 340 as running the customer's credit card successfully).
 341
 342 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 343 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 344 the B<reexport> method.)
 345
 346 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 347 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 348 created and inserted.
 349
 350 If I<prospectnum> is set, moves contacts and locations from that prospect.
 351
 352 If I<contact> is set to an arrayref of FS::contact objects, those will be
 353 inserted.
 354
 355 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 356 unset), inserts those new contacts with this new customer.  Handles CGI
 357 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 358
 359 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 360 new stored payment records with this new customer.  Handles CGI parameters
 361 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 362
 363 =cut
 364
 365 sub insert {
 366   my $self = shift;
 367   my $cust_pkgs = @_ ? shift : {};
 368   my $invoicing_list;
 369   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 370     warn "cust_main::insert using deprecated invoicing list argument";
 371     $invoicing_list = shift;
 372   }
 373   my %options = @_;
 374   warn "$me insert called with options ".
 375        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 376     if $DEBUG;
 377
 378   local $SIG{HUP} = 'IGNORE';
 379   local $SIG{INT} = 'IGNORE';
 380   local $SIG{QUIT} = 'IGNORE';
 381   local $SIG{TERM} = 'IGNORE';
 382   local $SIG{TSTP} = 'IGNORE';
 383   local $SIG{PIPE} = 'IGNORE';
 384
 385   my $oldAutoCommit = $FS::UID::AutoCommit;
 386   local $FS::UID::AutoCommit = 0;
 387   my $dbh = dbh;
 388
 389   my $prepay_identifier = '';
 390   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 391   my $payby = '';
 392   if ( $self->payby eq 'PREPAY' ) {
 393
 394     $self->payby(''); #'BILL');
 395     $prepay_identifier = $self->payinfo;
 396     $self->payinfo('');
 397
 398     warn "  looking up prepaid card $prepay_identifier\n"
 399       if $DEBUG > 1;
 400
 401     my $error = $self->get_prepay( $prepay_identifier,
 402                                    'amount_ref'     => \$amount,
 403                                    'seconds_ref'    => \$seconds,
 404                                    'upbytes_ref'    => \$upbytes,
 405                                    'downbytes_ref'  => \$downbytes,
 406                                    'totalbytes_ref' => \$totalbytes,
 407                                  );
 408     if ( $error ) {
 409       $dbh->rollback if $oldAutoCommit;
 410       #return "error applying prepaid card (transaction rolled back): $error";
 411       return $error;
 412     }
 413
 414     $payby = 'PREP' if $amount;
 415
 416   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 417
 418     $payby = $1;
 419     $self->payby(''); #'BILL');
 420     $amount = $self->paid;
 421
 422   }
 423
 424   # insert locations
 425   foreach my $l (qw(bill_location ship_location)) {
 426
 427     my $loc = delete $self->hashref->{$l} or next;
 428
 429     if ( !$loc->locationnum ) {
 430       # warn the location that we're going to insert it with no custnum
 431       $loc->set(custnum_pending => 1);
 432       warn "  inserting $l\n"
 433         if $DEBUG > 1;
 434       my $error = $loc->insert;
 435       if ( $error ) {
 436         $dbh->rollback if $oldAutoCommit;
 437         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 438         return "$error (in $label location)";
 439       }
 440
 441     } elsif ( $loc->prospectnum ) {
 442
 443       $loc->prospectnum('');
 444       $loc->set(custnum_pending => 1);
 445       my $error = $loc->replace;
 446       if ( $error ) {
 447         $dbh->rollback if $oldAutoCommit;
 448         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 449         return "$error (moving $label location)";
 450       }
 451
 452     } elsif ( ($loc->custnum || 0) > 0 ) {
 453       # then it somehow belongs to another customer--shouldn't happen
 454       $dbh->rollback if $oldAutoCommit;
 455       return "$l belongs to customer ".$loc->custnum;
 456     }
 457     # else it already belongs to this customer
 458     # (happens when ship_location is identical to bill_location)
 459
 460     $self->set($l.'num', $loc->locationnum);
 461
 462     if ( $self->get($l.'num') eq '' ) {
 463       $dbh->rollback if $oldAutoCommit;
 464       return "$l not set";
 465     }
 466   }
 467
 468   warn "  inserting $self\n"
 469     if $DEBUG > 1;
 470
 471   $self->signupdate(time) unless $self->signupdate;
 472
 473   $self->auto_agent_custid()
 474     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 475
 476   my $error =  $self->check_payinfo_cardtype
 477             || $self->SUPER::insert;
 478   if ( $error ) {
 479     $dbh->rollback if $oldAutoCommit;
 480     #return "inserting cust_main record (transaction rolled back): $error";
 481     return $error;
 482   }
 483
 484   # now set cust_location.custnum
 485   foreach my $l (qw(bill_location ship_location)) {
 486     warn "  setting $l.custnum\n"
 487       if $DEBUG > 1;
 488     my $loc = $self->$l or next;
 489     unless ( $loc->custnum ) {
 490       $loc->set(custnum => $self->custnum);
 491       $error ||= $loc->replace;
 492     }
 493
 494     if ( $error ) {
 495       $dbh->rollback if $oldAutoCommit;
 496       return "error setting $l custnum: $error";
 497     }
 498   }
 499
 500   warn "  setting customer tags\n"
 501     if $DEBUG > 1;
 502
 503   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 504     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 505                                       'custnum' => $self->custnum };
 506     my $error = $cust_tag->insert;
 507     if ( $error ) {
 508       $dbh->rollback if $oldAutoCommit;
 509       return $error;
 510     }
 511   }
 512
 513   my $prospectnum = delete $options{'prospectnum'};
 514   if ( $prospectnum ) {
 515
 516     warn "  moving contacts and locations from prospect $prospectnum\n"
 517       if $DEBUG > 1;
 518
 519     my $prospect_main =
 520       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 521     unless ( $prospect_main ) {
 522       $dbh->rollback if $oldAutoCommit;
 523       return "Unknown prospectnum $prospectnum";
 524     }
 525     $prospect_main->custnum($self->custnum);
 526     $prospect_main->disabled('Y');
 527     my $error = $prospect_main->replace;
 528     if ( $error ) {
 529       $dbh->rollback if $oldAutoCommit;
 530       return $error;
 531     }
 532
 533     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 534       my $cust_contact = new FS::cust_contact {
 535         'custnum' => $self->custnum,
 536         'invoice_dest' => 'Y', # invoice_dest currently not set for prospect contacts
 537         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 538       };
 539       my $error =  $cust_contact->insert
 540                 || $prospect_contact->delete;
 541       if ( $error ) {
 542         $dbh->rollback if $oldAutoCommit;
 543         return $error;
 544       }
 545     }
 546
 547     my @cust_location = $prospect_main->cust_location;
 548     my @qual = $prospect_main->qual;
 549
 550     foreach my $r ( @cust_location, @qual ) {
 551       $r->prospectnum('');
 552       $r->custnum($self->custnum);
 553       my $error = $r->replace;
 554       if ( $error ) {
 555         $dbh->rollback if $oldAutoCommit;
 556         return $error;
 557       }
 558     }
 559     # since we set invoice_dest on all migrated prospect contacts (for now),
 560     # don't process invoicing_list.
 561     delete $options{'invoicing_list'};
 562     $invoicing_list = undef;
 563   }
 564
 565   warn "  setting contacts\n"
 566     if $DEBUG > 1;
 567
 568   $invoicing_list ||= $options{'invoicing_list'};
 569   if ( $invoicing_list ) {
 570
 571     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 572
 573     my $email = '';
 574     foreach my $dest (@$invoicing_list ) {
 575       if ($dest eq 'POST') {
 576         $self->set('postal_invoice', 'Y');
 577       } else {
 578
 579         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 580         if ( $contact_email ) {
 581           my $cust_contact = FS::cust_contact->new({
 582               contactnum    => $contact_email->contactnum,
 583               custnum       => $self->custnum,
 584           });
 585           $cust_contact->set('invoice_dest', 'Y');
 586           my $error = $cust_contact->insert;
 587           if ( $error ) {
 588             $dbh->rollback if $oldAutoCommit;
 589             return "$error (linking to email address $dest)";
 590           }
 591
 592         } else {
 593           # this email address is not yet linked to any contact
 594           $email .= ',' if length($email);
 595           $email .= $dest;
 596         }
 597       }
 598     }
 599
 600     if ( $email ) {
 601
 602       my $contact = FS::contact->new({
 603         'custnum'       => $self->get('custnum'),
 604         'last'          => $self->get('last'),
 605         'first'         => $self->get('first'),
 606         'emailaddress'  => $email,
 607         'invoice_dest'  => 'Y', # yes, you can set this via the contact
 608       });
 609       my $error = $contact->insert;
 610       if ( $error ) {
 611         $dbh->rollback if $oldAutoCommit;
 612         return $error;
 613       }
 614
 615     }
 616
 617   }
 618
 619   if ( my $contact = delete $options{'contact'} ) {
 620
 621     foreach my $c ( @$contact ) {
 622       $c->custnum($self->custnum);
 623       my $error = $c->insert;
 624       if ( $error ) {
 625         $dbh->rollback if $oldAutoCommit;
 626         return $error;
 627       }
 628
 629     }
 630
 631   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 632
 633     my $error = $self->process_o2m( 'table'  => 'contact',
 634                                     'fields' => FS::contact->cgi_contact_fields,
 635                                     'params' => $contact_params,
 636                                   );
 637     if ( $error ) {
 638       $dbh->rollback if $oldAutoCommit;
 639       return $error;
 640     }
 641   }
 642
 643   warn "  setting cust_payby\n"
 644     if $DEBUG > 1;
 645
 646   if ( $options{cust_payby} ) {
 647
 648     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 649       $cust_payby->custnum($self->custnum);
 650       my $error = $cust_payby->insert;
 651       if ( $error ) {
 652         $dbh->rollback if $oldAutoCommit;
 653         return $error;
 654       }
 655     }
 656
 657   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 658
 659     my $error = $self->process_o2m(
 660       'table'         => 'cust_payby',
 661       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 662       'params'        => $cust_payby_params,
 663       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 664     );
 665     if ( $error ) {
 666       $dbh->rollback if $oldAutoCommit;
 667       return $error;
 668     }
 669
 670   }
 671
 672   warn "  setting cust_main_exemption\n"
 673     if $DEBUG > 1;
 674
 675   my $tax_exemption = delete $options{'tax_exemption'};
 676   if ( $tax_exemption ) {
 677
 678     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 679       if ref($tax_exemption) eq 'ARRAY';
 680
 681     foreach my $taxname ( keys %$tax_exemption ) {
 682       my $cust_main_exemption = new FS::cust_main_exemption {
 683         'custnum'       => $self->custnum,
 684         'taxname'       => $taxname,
 685         'exempt_number' => $tax_exemption->{$taxname},
 686       };
 687       my $error = $cust_main_exemption->insert;
 688       if ( $error ) {
 689         $dbh->rollback if $oldAutoCommit;
 690         return "inserting cust_main_exemption (transaction rolled back): $error";
 691       }
 692     }
 693   }
 694
 695   warn "  ordering packages\n"
 696     if $DEBUG > 1;
 697
 698   $error = $self->order_pkgs( $cust_pkgs,
 699                               %options,
 700                               'seconds_ref'    => \$seconds,
 701                               'upbytes_ref'    => \$upbytes,
 702                               'downbytes_ref'  => \$downbytes,
 703                               'totalbytes_ref' => \$totalbytes,
 704                             );
 705   if ( $error ) {
 706     $dbh->rollback if $oldAutoCommit;
 707     return $error;
 708   }
 709
 710   if ( $seconds ) {
 711     $dbh->rollback if $oldAutoCommit;
 712     return "No svc_acct record to apply pre-paid time";
 713   }
 714   if ( $upbytes || $downbytes || $totalbytes ) {
 715     $dbh->rollback if $oldAutoCommit;
 716     return "No svc_acct record to apply pre-paid data";
 717   }
 718
 719   if ( $amount ) {
 720     warn "  inserting initial $payby payment of $amount\n"
 721       if $DEBUG > 1;
 722     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 723     if ( $error ) {
 724       $dbh->rollback if $oldAutoCommit;
 725       return "inserting payment (transaction rolled back): $error";
 726     }
 727   }
 728
 729   unless ( $import || $skip_fuzzyfiles ) {
 730     warn "  queueing fuzzyfiles update\n"
 731       if $DEBUG > 1;
 732     $error = $self->queue_fuzzyfiles_update;
 733     if ( $error ) {
 734       $dbh->rollback if $oldAutoCommit;
 735       return "updating fuzzy search cache: $error";
 736     }
 737   }
 738
 739   # FS::geocode_Mixin::after_insert or something?
 740   if ( $conf->config('tax_district_method') and !$import ) {
 741     # if anything non-empty, try to look it up
 742     my $queue = new FS::queue {
 743       'job'     => 'FS::geocode_Mixin::process_district_update',
 744       'custnum' => $self->custnum,
 745     };
 746     my $error = $queue->insert( ref($self), $self->custnum );
 747     if ( $error ) {
 748       $dbh->rollback if $oldAutoCommit;
 749       return "queueing tax district update: $error";
 750     }
 751   }
 752
 753   # cust_main exports!
 754   warn "  exporting\n" if $DEBUG > 1;
 755
 756   my $export_args = $options{'export_args'} || [];
 757
 758   my @part_export =
 759     map qsearch( 'part_export', {exportnum=>$_} ),
 760       $conf->config('cust_main-exports'); #, $agentnum
 761
 762   foreach my $part_export ( @part_export ) {
 763     my $error = $part_export->export_insert($self, @$export_args);
 764     if ( $error ) {
 765       $dbh->rollback if $oldAutoCommit;
 766       return "exporting to ". $part_export->exporttype.
 767              " (transaction rolled back): $error";
 768     }
 769   }
 770
 771   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 772   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 773   #      if $DEBUG;
 774   #    foreach my $jobnum ( @jobnums ) {
 775   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 776   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 777   #        if $DEBUG;
 778   #      my $error = $queue->depend_insert($depend_jobnum);
 779   #      if ( $error ) {
 780   #        $dbh->rollback if $oldAutoCommit;
 781   #        return "error queuing job dependancy: $error";
 782   #      }
 783   #    }
 784   #  }
 785   #
 786   #}
 787   #
 788   #if ( exists $options{'jobnums'} ) {
 789   #  push @{ $options{'jobnums'} }, @jobnums;
 790   #}
 791
 792   warn "  insert complete; committing transaction\n"
 793     if $DEBUG > 1;
 794
 795   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 796   '';
 797
 798 }
 799
 800 use File::CounterFile;
 801 sub auto_agent_custid {
 802   my $self = shift;
 803
 804   my $format = $conf->config('cust_main-auto_agent_custid');
 805   my $agent_custid;
 806   if ( $format eq '1YMMXXXXXXXX' ) {
 807
 808     my $counter = new File::CounterFile 'cust_main.agent_custid';
 809     $counter->lock;
 810
 811     my $ym = 100000000000 + time2str('%y%m00000000', time);
 812     if ( $ym > $counter->value ) {
 813       $counter->{'value'} = $agent_custid = $ym;
 814       $counter->{'updated'} = 1;
 815     } else {
 816       $agent_custid = $counter->inc;
 817     }
 818
 819     $counter->unlock;
 820
 821   } else {
 822     die "Unknown cust_main-auto_agent_custid format: $format";
 823   }
 824
 825   $self->agent_custid($agent_custid);
 826
 827 }
 828
 829 =item PACKAGE METHODS
 830
 831 Documentation on customer package methods has been moved to
 832 L<FS::cust_main::Packages>.
 833
 834 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 835
 836 Recharges this (existing) customer with the specified prepaid card (see
 837 L<FS::prepay_credit>), specified either by I<identifier> or as an
 838 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 839 returns false.
 840
 841 Optionally, five scalar references can be passed as well.  They will have their
 842 values filled in with the amount, number of seconds, and number of upload,
 843 download, and total bytes applied by this prepaid card.
 844
 845 =cut
 846
 847 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 848 #the only place that uses these args
 849 sub recharge_prepay {
 850   my( $self, $prepay_credit, $amountref, $secondsref,
 851       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 852
 853   local $SIG{HUP} = 'IGNORE';
 854   local $SIG{INT} = 'IGNORE';
 855   local $SIG{QUIT} = 'IGNORE';
 856   local $SIG{TERM} = 'IGNORE';
 857   local $SIG{TSTP} = 'IGNORE';
 858   local $SIG{PIPE} = 'IGNORE';
 859
 860   my $oldAutoCommit = $FS::UID::AutoCommit;
 861   local $FS::UID::AutoCommit = 0;
 862   my $dbh = dbh;
 863
 864   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 865
 866   my $error = $self->get_prepay( $prepay_credit,
 867                                  'amount_ref'     => \$amount,
 868                                  'seconds_ref'    => \$seconds,
 869                                  'upbytes_ref'    => \$upbytes,
 870                                  'downbytes_ref'  => \$downbytes,
 871                                  'totalbytes_ref' => \$totalbytes,
 872                                )
 873            || $self->increment_seconds($seconds)
 874            || $self->increment_upbytes($upbytes)
 875            || $self->increment_downbytes($downbytes)
 876            || $self->increment_totalbytes($totalbytes)
 877            || $self->insert_cust_pay_prepay( $amount,
 878                                              ref($prepay_credit)
 879                                                ? $prepay_credit->identifier
 880                                                : $prepay_credit
 881                                            );
 882
 883   if ( $error ) {
 884     $dbh->rollback if $oldAutoCommit;
 885     return $error;
 886   }
 887
 888   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 889   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 890   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 891   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 892   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 893
 894   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 895   '';
 896
 897 }
 898
 899 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 900
 901 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 902 specified either by I<identifier> or as an FS::prepay_credit object.
 903
 904 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 905 incremented by the values of the prepaid card.
 906
 907 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 908 check or set this customer's I<agentnum>.
 909
 910 If there is an error, returns the error, otherwise returns false.
 911
 912 =cut
 913
 914
 915 sub get_prepay {
 916   my( $self, $prepay_credit, %opt ) = @_;
 917
 918   local $SIG{HUP} = 'IGNORE';
 919   local $SIG{INT} = 'IGNORE';
 920   local $SIG{QUIT} = 'IGNORE';
 921   local $SIG{TERM} = 'IGNORE';
 922   local $SIG{TSTP} = 'IGNORE';
 923   local $SIG{PIPE} = 'IGNORE';
 924
 925   my $oldAutoCommit = $FS::UID::AutoCommit;
 926   local $FS::UID::AutoCommit = 0;
 927   my $dbh = dbh;
 928
 929   unless ( ref($prepay_credit) ) {
 930
 931     my $identifier = $prepay_credit;
 932
 933     $prepay_credit = qsearchs(
 934       'prepay_credit',
 935       { 'identifier' => $identifier },
 936       '',
 937       'FOR UPDATE'
 938     );
 939
 940     unless ( $prepay_credit ) {
 941       $dbh->rollback if $oldAutoCommit;
 942       return "Invalid prepaid card: ". $identifier;
 943     }
 944
 945   }
 946
 947   if ( $prepay_credit->agentnum ) {
 948     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 949       $dbh->rollback if $oldAutoCommit;
 950       return "prepaid card not valid for agent ". $self->agentnum;
 951     }
 952     $self->agentnum($prepay_credit->agentnum);
 953   }
 954
 955   my $error = $prepay_credit->delete;
 956   if ( $error ) {
 957     $dbh->rollback if $oldAutoCommit;
 958     return "removing prepay_credit (transaction rolled back): $error";
 959   }
 960
 961   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 962     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 963
 964   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 965   '';
 966
 967 }
 968
 969 =item increment_upbytes SECONDS
 970
 971 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 972 the specified number of upbytes.  If there is an error, returns the error,
 973 otherwise returns false.
 974
 975 =cut
 976
 977 sub increment_upbytes {
 978   _increment_column( shift, 'upbytes', @_);
 979 }
 980
 981 =item increment_downbytes SECONDS
 982
 983 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 984 the specified number of downbytes.  If there is an error, returns the error,
 985 otherwise returns false.
 986
 987 =cut
 988
 989 sub increment_downbytes {
 990   _increment_column( shift, 'downbytes', @_);
 991 }
 992
 993 =item increment_totalbytes SECONDS
 994
 995 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 996 the specified number of totalbytes.  If there is an error, returns the error,
 997 otherwise returns false.
 998
 999 =cut
1000
1001 sub increment_totalbytes {
1002   _increment_column( shift, 'totalbytes', @_);
1003 }
1004
1005 =item increment_seconds SECONDS
1006
1007 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1008 the specified number of seconds.  If there is an error, returns the error,
1009 otherwise returns false.
1010
1011 =cut
1012
1013 sub increment_seconds {
1014   _increment_column( shift, 'seconds', @_);
1015 }
1016
1017 =item _increment_column AMOUNT
1018
1019 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1020 the specified number of seconds or bytes.  If there is an error, returns
1021 the error, otherwise returns false.
1022
1023 =cut
1024
1025 sub _increment_column {
1026   my( $self, $column, $amount ) = @_;
1027   warn "$me increment_column called: $column, $amount\n"
1028     if $DEBUG;
1029
1030   return '' unless $amount;
1031
1032   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1033                       $self->ncancelled_pkgs;
1034
1035   if ( ! @cust_pkg ) {
1036     return 'No packages with primary or single services found'.
1037            ' to apply pre-paid time';
1038   } elsif ( scalar(@cust_pkg) > 1 ) {
1039     #maybe have a way to specify the package/account?
1040     return 'Multiple packages found to apply pre-paid time';
1041   }
1042
1043   my $cust_pkg = $cust_pkg[0];
1044   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1045     if $DEBUG > 1;
1046
1047   my @cust_svc =
1048     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1049
1050   if ( ! @cust_svc ) {
1051     return 'No account found to apply pre-paid time';
1052   } elsif ( scalar(@cust_svc) > 1 ) {
1053     return 'Multiple accounts found to apply pre-paid time';
1054   }
1055
1056   my $svc_acct = $cust_svc[0]->svc_x;
1057   warn "  found service svcnum ". $svc_acct->pkgnum.
1058        ' ('. $svc_acct->email. ")\n"
1059     if $DEBUG > 1;
1060
1061   $column = "increment_$column";
1062   $svc_acct->$column($amount);
1063
1064 }
1065
1066 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1067
1068 Inserts a prepayment in the specified amount for this customer.  An optional
1069 second argument can specify the prepayment identifier for tracking purposes.
1070 If there is an error, returns the error, otherwise returns false.
1071
1072 =cut
1073
1074 sub insert_cust_pay_prepay {
1075   shift->insert_cust_pay('PREP', @_);
1076 }
1077
1078 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1079
1080 Inserts a cash payment in the specified amount for this customer.  An optional
1081 second argument can specify the payment identifier for tracking purposes.
1082 If there is an error, returns the error, otherwise returns false.
1083
1084 =cut
1085
1086 sub insert_cust_pay_cash {
1087   shift->insert_cust_pay('CASH', @_);
1088 }
1089
1090 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1091
1092 Inserts a Western Union payment in the specified amount for this customer.  An
1093 optional second argument can specify the prepayment identifier for tracking
1094 purposes.  If there is an error, returns the error, otherwise returns false.
1095
1096 =cut
1097
1098 sub insert_cust_pay_west {
1099   shift->insert_cust_pay('WEST', @_);
1100 }
1101
1102 sub insert_cust_pay {
1103   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1104   my $payinfo = scalar(@_) ? shift : '';
1105
1106   my $cust_pay = new FS::cust_pay {
1107     'custnum' => $self->custnum,
1108     'paid'    => sprintf('%.2f', $amount),
1109     #'_date'   => #date the prepaid card was purchased???
1110     'payby'   => $payby,
1111     'payinfo' => $payinfo,
1112   };
1113   $cust_pay->insert;
1114
1115 }
1116
1117 =item delete [ OPTION => VALUE ... ]
1118
1119 This deletes the customer.  If there is an error, returns the error, otherwise
1120 returns false.
1121
1122 This will completely remove all traces of the customer record.  This is not
1123 what you want when a customer cancels service; for that, cancel all of the
1124 customer's packages (see L</cancel>).
1125
1126 If the customer has any uncancelled packages, you need to pass a new (valid)
1127 customer number for those packages to be transferred to, as the "new_customer"
1128 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1129 what you want when a customer cancels service and that you really should be
1130 looking at L<FS::cust_pkg/cancel>?
1131
1132 You can't delete a customer with invoices (see L<FS::cust_bill>),
1133 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1134 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1135 set the "delete_financials" option to a true value.
1136
1137 =cut
1138
1139 sub delete {
1140   my( $self, %opt ) = @_;
1141
1142   local $SIG{HUP} = 'IGNORE';
1143   local $SIG{INT} = 'IGNORE';
1144   local $SIG{QUIT} = 'IGNORE';
1145   local $SIG{TERM} = 'IGNORE';
1146   local $SIG{TSTP} = 'IGNORE';
1147   local $SIG{PIPE} = 'IGNORE';
1148
1149   my $oldAutoCommit = $FS::UID::AutoCommit;
1150   local $FS::UID::AutoCommit = 0;
1151   my $dbh = dbh;
1152
1153   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1154      $dbh->rollback if $oldAutoCommit;
1155      return "Can't delete a master agent customer";
1156   }
1157
1158   #use FS::access_user
1159   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1160      $dbh->rollback if $oldAutoCommit;
1161      return "Can't delete a master employee customer";
1162   }
1163
1164   tie my %financial_tables, 'Tie::IxHash',
1165     'cust_bill'      => 'invoices',
1166     'cust_statement' => 'statements',
1167     'cust_credit'    => 'credits',
1168     'cust_pay'       => 'payments',
1169     'cust_refund'    => 'refunds',
1170   ;
1171
1172   foreach my $table ( keys %financial_tables ) {
1173
1174     my @records = $self->$table();
1175
1176     if ( @records && ! $opt{'delete_financials'} ) {
1177       $dbh->rollback if $oldAutoCommit;
1178       return "Can't delete a customer with ". $financial_tables{$table};
1179     }
1180
1181     foreach my $record ( @records ) {
1182       my $error = $record->delete;
1183       if ( $error ) {
1184         $dbh->rollback if $oldAutoCommit;
1185         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1186       }
1187     }
1188
1189   }
1190
1191   my @cust_pkg = $self->ncancelled_pkgs;
1192   if ( @cust_pkg ) {
1193     my $new_custnum = $opt{'new_custnum'};
1194     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1195       $dbh->rollback if $oldAutoCommit;
1196       return "Invalid new customer number: $new_custnum";
1197     }
1198     foreach my $cust_pkg ( @cust_pkg ) {
1199       my %hash = $cust_pkg->hash;
1200       $hash{'custnum'} = $new_custnum;
1201       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1202       my $error = $new_cust_pkg->replace($cust_pkg,
1203                                          options => { $cust_pkg->options },
1204                                         );
1205       if ( $error ) {
1206         $dbh->rollback if $oldAutoCommit;
1207         return $error;
1208       }
1209     }
1210   }
1211   my @cancelled_cust_pkg = $self->all_pkgs;
1212   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1213     my $error = $cust_pkg->delete;
1214     if ( $error ) {
1215       $dbh->rollback if $oldAutoCommit;
1216       return $error;
1217     }
1218   }
1219
1220   #cust_tax_adjustment in financials?
1221   #cust_pay_pending?  ouch
1222   foreach my $table (qw(
1223     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1224     cust_payby cust_location cust_main_note cust_tax_adjustment
1225     cust_pay_void cust_pay_batch queue cust_tax_exempt
1226   )) {
1227     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1228       my $error = $record->delete;
1229       if ( $error ) {
1230         $dbh->rollback if $oldAutoCommit;
1231         return $error;
1232       }
1233     }
1234   }
1235
1236   my $sth = $dbh->prepare(
1237     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1238   ) or do {
1239     my $errstr = $dbh->errstr;
1240     $dbh->rollback if $oldAutoCommit;
1241     return $errstr;
1242   };
1243   $sth->execute($self->custnum) or do {
1244     my $errstr = $sth->errstr;
1245     $dbh->rollback if $oldAutoCommit;
1246     return $errstr;
1247   };
1248
1249   #tickets
1250
1251   my $ticket_dbh = '';
1252   if ($conf->config('ticket_system') eq 'RT_Internal') {
1253     $ticket_dbh = $dbh;
1254   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1255     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1256     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1257       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1258   }
1259
1260   if ( $ticket_dbh ) {
1261
1262     my $ticket_sth = $ticket_dbh->prepare(
1263       'DELETE FROM Links WHERE Target = ?'
1264     ) or do {
1265       my $errstr = $ticket_dbh->errstr;
1266       $dbh->rollback if $oldAutoCommit;
1267       return $errstr;
1268     };
1269     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1270       or do {
1271         my $errstr = $ticket_sth->errstr;
1272         $dbh->rollback if $oldAutoCommit;
1273         return $errstr;
1274       };
1275
1276     #check and see if the customer is the only link on the ticket, and
1277     #if so, set the ticket to deleted status in RT?
1278     #maybe someday, for now this will at least fix tickets not displaying
1279
1280   }
1281
1282   #delete the customer record
1283
1284   my $error = $self->SUPER::delete;
1285   if ( $error ) {
1286     $dbh->rollback if $oldAutoCommit;
1287     return $error;
1288   }
1289
1290   # cust_main exports!
1291
1292   #my $export_args = $options{'export_args'} || [];
1293
1294   my @part_export =
1295     map qsearch( 'part_export', {exportnum=>$_} ),
1296       $conf->config('cust_main-exports'); #, $agentnum
1297
1298   foreach my $part_export ( @part_export ) {
1299     my $error = $part_export->export_delete( $self ); #, @$export_args);
1300     if ( $error ) {
1301       $dbh->rollback if $oldAutoCommit;
1302       return "exporting to ". $part_export->exporttype.
1303              " (transaction rolled back): $error";
1304     }
1305   }
1306
1307   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1308   '';
1309
1310 }
1311
1312 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1313
1314 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1315 returns the error, otherwise returns false.
1316
1317 To change the customer's address, set the pseudo-fields C<bill_location> and
1318 C<ship_location>.  The address will still only change if at least one of the
1319 address fields differs from the existing values.
1320
1321 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1322 set as the contact email address for a default contact with the same name as
1323 the customer.
1324
1325 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1326 I<contact_params>, I<invoicing_list>.
1327
1328 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1329 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1330 deleted and inserted as appropriate.
1331
1332 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1333 groups (describing the customer's payment methods and contacts, respectively)
1334 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1335 and L<FS::contact> for the fields these can contain.
1336
1337 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1338 should be used instead if possible.
1339
1340 =cut
1341
1342 sub replace {
1343   my $self = shift;
1344
1345   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1346               ? shift
1347               : $self->replace_old;
1348
1349   my @param = @_;
1350
1351   warn "$me replace called\n"
1352     if $DEBUG;
1353
1354   my $curuser = $FS::CurrentUser::CurrentUser;
1355   return "You are not permitted to create complimentary accounts."
1356     if $self->complimentary eq 'Y'
1357     && $self->complimentary ne $old->complimentary
1358     && ! $curuser->access_right('Complimentary customer');
1359
1360   local($ignore_expired_card) = 1
1361     if $old->payby  =~ /^(CARD|DCRD)$/
1362     && $self->payby =~ /^(CARD|DCRD)$/
1363     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1364
1365   local($ignore_banned_card) = 1
1366     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1367          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1368     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1369
1370   if (    $self->payby =~ /^(CARD|DCRD)$/
1371        && $old->payinfo ne $self->payinfo
1372        && $old->paymask ne $self->paymask )
1373   {
1374     my $error = $self->check_payinfo_cardtype;
1375     return $error if $error;
1376   }
1377
1378   return "Invoicing locale is required"
1379     if $old->locale
1380     && ! $self->locale
1381     && $conf->exists('cust_main-require_locale');
1382
1383   local $SIG{HUP} = 'IGNORE';
1384   local $SIG{INT} = 'IGNORE';
1385   local $SIG{QUIT} = 'IGNORE';
1386   local $SIG{TERM} = 'IGNORE';
1387   local $SIG{TSTP} = 'IGNORE';
1388   local $SIG{PIPE} = 'IGNORE';
1389
1390   my $oldAutoCommit = $FS::UID::AutoCommit;
1391   local $FS::UID::AutoCommit = 0;
1392   my $dbh = dbh;
1393
1394   for my $l (qw(bill_location ship_location)) {
1395     #my $old_loc = $old->$l;
1396     my $new_loc = $self->$l or next;
1397
1398     # find the existing location if there is one
1399     $new_loc->set('custnum' => $self->custnum);
1400     my $error = $new_loc->find_or_insert;
1401     if ( $error ) {
1402       $dbh->rollback if $oldAutoCommit;
1403       return $error;
1404     }
1405     $self->set($l.'num', $new_loc->locationnum);
1406   } #for $l
1407
1408   my $invoicing_list;
1409   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1410     warn "cust_main::replace: using deprecated invoicing list argument";
1411     $invoicing_list = shift @param;
1412   }
1413
1414   my %options = @param;
1415
1416   $invoicing_list ||= $options{invoicing_list};
1417
1418   my @contacts = map { $_->contact } $self->cust_contact;
1419   # find a contact that matches the customer's name
1420   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1421                               and $_->last  eq $old->get('last') }
1422                             @contacts;
1423   $implicit_contact ||= FS::contact->new({
1424       'custnum'       => $self->custnum,
1425       'locationnum'   => $self->get('bill_locationnum'),
1426   });
1427
1428   # for any of these that are already contact emails, link to the existing
1429   # contact
1430   if ( $invoicing_list ) {
1431     my $email = '';
1432
1433     # kind of like process_m2m on these, except:
1434     # - the other side is two tables in a join
1435     # - and we might have to create new contact_emails
1436     # - and possibly a new contact
1437     #
1438     # Find existing invoice emails that aren't on the implicit contact.
1439     # Any of these that are not on the new invoicing list will be removed.
1440     my %old_email_cust_contact;
1441     foreach my $cust_contact ($self->cust_contact) {
1442       next if !$cust_contact->invoice_dest;
1443       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1444
1445       foreach my $contact_email ($cust_contact->contact->contact_email) {
1446         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1447       }
1448     }
1449
1450     foreach my $dest (@$invoicing_list) {
1451
1452       if ($dest eq 'POST') {
1453
1454         $self->set('postal_invoice', 'Y');
1455
1456       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1457
1458         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1459
1460       } else {
1461
1462         # See if it belongs to some other contact; if so, link it.
1463         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1464         if ( $contact_email
1465              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1466           my $cust_contact = qsearchs('cust_contact', {
1467               contactnum  => $contact_email->contactnum,
1468               custnum     => $self->custnum,
1469           }) || FS::cust_contact->new({
1470               contactnum    => $contact_email->contactnum,
1471               custnum       => $self->custnum,
1472           });
1473           $cust_contact->set('invoice_dest', 'Y');
1474           my $error = $cust_contact->custcontactnum ?
1475                         $cust_contact->replace : $cust_contact->insert;
1476           if ( $error ) {
1477             $dbh->rollback if $oldAutoCommit;
1478             return "$error (linking to email address $dest)";
1479           }
1480
1481         } else {
1482           # This email address is not yet linked to any contact, so it will
1483           # be added to the implicit contact.
1484           $email .= ',' if length($email);
1485           $email .= $dest;
1486         }
1487       }
1488     }
1489
1490     foreach my $remove_dest (keys %old_email_cust_contact) {
1491       my $cust_contact = $old_email_cust_contact{$remove_dest};
1492       # These were not in the list of requested destinations, so take them off.
1493       $cust_contact->set('invoice_dest', '');
1494       my $error = $cust_contact->replace;
1495       if ( $error ) {
1496         $dbh->rollback if $oldAutoCommit;
1497         return "$error (unlinking email address $remove_dest)";
1498       }
1499     }
1500
1501     # make sure it keeps up with the changed customer name, if any
1502     $implicit_contact->set('last', $self->get('last'));
1503     $implicit_contact->set('first', $self->get('first'));
1504     $implicit_contact->set('emailaddress', $email);
1505     $implicit_contact->set('invoice_dest', 'Y');
1506     $implicit_contact->set('custnum', $self->custnum);
1507
1508     my $error;
1509     if ( $implicit_contact->contactnum ) {
1510       $error = $implicit_contact->replace;
1511     } elsif ( length($email) ) { # don't create a new contact if not needed
1512       $error = $implicit_contact->insert;
1513     }
1514
1515     if ( $error ) {
1516       $dbh->rollback if $oldAutoCommit;
1517       return "$error (adding email address $email)";
1518     }
1519
1520   }
1521
1522   # replace the customer record
1523   my $error = $self->SUPER::replace($old);
1524
1525   if ( $error ) {
1526     $dbh->rollback if $oldAutoCommit;
1527     return $error;
1528   }
1529
1530   # now move packages to the new service location
1531   $self->set('ship_location', ''); #flush cache
1532   if ( $old->ship_locationnum and # should only be null during upgrade...
1533        $old->ship_locationnum != $self->ship_locationnum ) {
1534     $error = $old->ship_location->move_to($self->ship_location);
1535     if ( $error ) {
1536       $dbh->rollback if $oldAutoCommit;
1537       return $error;
1538     }
1539   }
1540   # don't move packages based on the billing location, but
1541   # disable it if it's no longer in use
1542   if ( $old->bill_locationnum and
1543        $old->bill_locationnum != $self->bill_locationnum ) {
1544     $error = $old->bill_location->disable_if_unused;
1545     if ( $error ) {
1546       $dbh->rollback if $oldAutoCommit;
1547       return $error;
1548     }
1549   }
1550
1551   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1552
1553     #this could be more efficient than deleting and re-inserting, if it matters
1554     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1555       my $error = $cust_tag->delete;
1556       if ( $error ) {
1557         $dbh->rollback if $oldAutoCommit;
1558         return $error;
1559       }
1560     }
1561     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1562       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1563                                         'custnum' => $self->custnum };
1564       my $error = $cust_tag->insert;
1565       if ( $error ) {
1566         $dbh->rollback if $oldAutoCommit;
1567         return $error;
1568       }
1569     }
1570
1571   }
1572
1573   my $tax_exemption = delete $options{'tax_exemption'};
1574   if ( $tax_exemption ) {
1575
1576     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1577       if ref($tax_exemption) eq 'ARRAY';
1578
1579     my %cust_main_exemption =
1580       map { $_->taxname => $_ }
1581           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1582
1583     foreach my $taxname ( keys %$tax_exemption ) {
1584
1585       if ( $cust_main_exemption{$taxname} &&
1586            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1587          )
1588       {
1589         delete $cust_main_exemption{$taxname};
1590         next;
1591       }
1592
1593       my $cust_main_exemption = new FS::cust_main_exemption {
1594         'custnum'       => $self->custnum,
1595         'taxname'       => $taxname,
1596         'exempt_number' => $tax_exemption->{$taxname},
1597       };
1598       my $error = $cust_main_exemption->insert;
1599       if ( $error ) {
1600         $dbh->rollback if $oldAutoCommit;
1601         return "inserting cust_main_exemption (transaction rolled back): $error";
1602       }
1603     }
1604
1605     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1606       my $error = $cust_main_exemption->delete;
1607       if ( $error ) {
1608         $dbh->rollback if $oldAutoCommit;
1609         return "deleting cust_main_exemption (transaction rolled back): $error";
1610       }
1611     }
1612
1613   }
1614
1615   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1616
1617     my $error = $self->process_o2m(
1618       'table'         => 'cust_payby',
1619       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1620       'params'        => $cust_payby_params,
1621       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1622     );
1623     if ( $error ) {
1624       $dbh->rollback if $oldAutoCommit;
1625       return $error;
1626     }
1627
1628   }
1629
1630   if ( my $contact_params = delete $options{'contact_params'} ) {
1631
1632     # this can potentially replace contacts that were created by the
1633     # invoicing list argument, but the UI shouldn't allow both of them
1634     # to be specified
1635
1636     my $error = $self->process_o2m(
1637       'table'         => 'contact',
1638       'fields'        => FS::contact->cgi_contact_fields,
1639       'params'        => $contact_params,
1640     );
1641     if ( $error ) {
1642       $dbh->rollback if $oldAutoCommit;
1643       return $error;
1644     }
1645
1646   }
1647
1648   unless ( $import || $skip_fuzzyfiles ) {
1649     $error = $self->queue_fuzzyfiles_update;
1650     if ( $error ) {
1651       $dbh->rollback if $oldAutoCommit;
1652       return "updating fuzzy search cache: $error";
1653     }
1654   }
1655
1656   # tax district update in cust_location
1657
1658   # cust_main exports!
1659
1660   my $export_args = $options{'export_args'} || [];
1661
1662   my @part_export =
1663     map qsearch( 'part_export', {exportnum=>$_} ),
1664       $conf->config('cust_main-exports'); #, $agentnum
1665
1666   foreach my $part_export ( @part_export ) {
1667     my $error = $part_export->export_replace( $self, $old, @$export_args);
1668     if ( $error ) {
1669       $dbh->rollback if $oldAutoCommit;
1670       return "exporting to ". $part_export->exporttype.
1671              " (transaction rolled back): $error";
1672     }
1673   }
1674
1675   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1676   '';
1677
1678 }
1679
1680 =item queue_fuzzyfiles_update
1681
1682 Used by insert & replace to update the fuzzy search cache
1683
1684 =cut
1685
1686 use FS::cust_main::Search;
1687 sub queue_fuzzyfiles_update {
1688   my $self = shift;
1689
1690   local $SIG{HUP} = 'IGNORE';
1691   local $SIG{INT} = 'IGNORE';
1692   local $SIG{QUIT} = 'IGNORE';
1693   local $SIG{TERM} = 'IGNORE';
1694   local $SIG{TSTP} = 'IGNORE';
1695   local $SIG{PIPE} = 'IGNORE';
1696
1697   my $oldAutoCommit = $FS::UID::AutoCommit;
1698   local $FS::UID::AutoCommit = 0;
1699   my $dbh = dbh;
1700
1701   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1702     my $queue = new FS::queue {
1703       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1704     };
1705     my @args = "cust_main.$field", $self->get($field);
1706     my $error = $queue->insert( @args );
1707     if ( $error ) {
1708       $dbh->rollback if $oldAutoCommit;
1709       return "queueing job (transaction rolled back): $error";
1710     }
1711   }
1712
1713   my @locations = ();
1714   push @locations, $self->bill_location if $self->bill_locationnum;
1715   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1716   foreach my $location (@locations) {
1717     my $queue = new FS::queue {
1718       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1719     };
1720     my @args = 'cust_location.address1', $location->address1;
1721     my $error = $queue->insert( @args );
1722     if ( $error ) {
1723       $dbh->rollback if $oldAutoCommit;
1724       return "queueing job (transaction rolled back): $error";
1725     }
1726   }
1727
1728   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1729   '';
1730
1731 }
1732
1733 =item check
1734
1735 Checks all fields to make sure this is a valid customer record.  If there is
1736 an error, returns the error, otherwise returns false.  Called by the insert
1737 and replace methods.
1738
1739 =cut
1740
1741 sub check {
1742   my $self = shift;
1743
1744   warn "$me check BEFORE: \n". $self->_dump
1745     if $DEBUG > 2;
1746
1747   my $error =
1748     $self->ut_numbern('custnum')
1749     || $self->ut_number('agentnum')
1750     || $self->ut_textn('agent_custid')
1751     || $self->ut_number('refnum')
1752     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1753     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1754     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1755     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1756     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1757     || $self->ut_textn('custbatch')
1758     || $self->ut_name('last')
1759     || $self->ut_name('first')
1760     || $self->ut_snumbern('signupdate')
1761     || $self->ut_snumbern('birthdate')
1762     || $self->ut_namen('spouse_last')
1763     || $self->ut_namen('spouse_first')
1764     || $self->ut_snumbern('spouse_birthdate')
1765     || $self->ut_snumbern('anniversary_date')
1766     || $self->ut_textn('company')
1767     || $self->ut_textn('ship_company')
1768     || $self->ut_anything('comments')
1769     || $self->ut_numbern('referral_custnum')
1770     || $self->ut_textn('stateid')
1771     || $self->ut_textn('stateid_state')
1772     || $self->ut_textn('invoice_terms')
1773     || $self->ut_floatn('cdr_termination_percentage')
1774     || $self->ut_floatn('credit_limit')
1775     || $self->ut_numbern('billday')
1776     || $self->ut_numbern('prorate_day')
1777     || $self->ut_flag('edit_subject')
1778     || $self->ut_flag('calling_list_exempt')
1779     || $self->ut_flag('invoice_noemail')
1780     || $self->ut_flag('message_noemail')
1781     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1782     || $self->ut_currencyn('currency')
1783     || $self->ut_textn('po_number')
1784     || $self->ut_enum('complimentary', [ '', 'Y' ])
1785     || $self->ut_flag('invoice_ship_address')
1786     || $self->ut_flag('invoice_dest')
1787   ;
1788
1789   foreach (qw(company ship_company)) {
1790     my $company = $self->get($_);
1791     $company =~ s/^\s+//;
1792     $company =~ s/\s+$//;
1793     $company =~ s/\s+/ /g;
1794     $self->set($_, $company);
1795   }
1796
1797   #barf.  need message catalogs.  i18n.  etc.
1798   $error .= "Please select an advertising source."
1799     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1800   return $error if $error;
1801
1802   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1803     or return "Unknown agent";
1804
1805   if ( $self->currency ) {
1806     my $agent_currency = qsearchs( 'agent_currency', {
1807       'agentnum' => $agent->agentnum,
1808       'currency' => $self->currency,
1809     })
1810       or return "Agent ". $agent->agent.
1811                 " not permitted to offer ".  $self->currency. " invoicing";
1812   }
1813
1814   return "Unknown refnum"
1815     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1816
1817   return "Unknown referring custnum: ". $self->referral_custnum
1818     unless ! $self->referral_custnum
1819            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1820
1821   if ( $self->ss eq '' ) {
1822     $self->ss('');
1823   } else {
1824     my $ss = $self->ss;
1825     $ss =~ s/\D//g;
1826     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1827       or return "Illegal social security number: ". $self->ss;
1828     $self->ss("$1-$2-$3");
1829   }
1830
1831   #turn off invoice_ship_address if ship & bill are the same
1832   if ($self->bill_locationnum eq $self->ship_locationnum) {
1833     $self->invoice_ship_address('');
1834   }
1835
1836   # cust_main_county verification now handled by cust_location check
1837
1838   $error =
1839        $self->ut_phonen('daytime', $self->country)
1840     || $self->ut_phonen('night',   $self->country)
1841     || $self->ut_phonen('fax',     $self->country)
1842     || $self->ut_phonen('mobile',  $self->country)
1843   ;
1844   return $error if $error;
1845
1846   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1847        && ! $import
1848        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1849      ) {
1850
1851     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1852                           ? 'Day Phone'
1853                           : FS::Msgcat::_gettext('daytime');
1854     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1855                         ? 'Night Phone'
1856                         : FS::Msgcat::_gettext('night');
1857
1858     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1859                         ? 'Mobile Phone'
1860                         : FS::Msgcat::_gettext('mobile');
1861
1862     return "$daytime_label, $night_label or $mobile_label is required"
1863
1864   }
1865
1866   ### start of stuff moved to cust_payby
1867   # then mostly kept here to support upgrades (can remove in 5.x)
1868   #  but modified to allow everything to be empty
1869
1870   if ( $self->payby ) {
1871     FS::payby->can_payby($self->table, $self->payby)
1872       or return "Illegal payby: ". $self->payby;
1873   } else {
1874     $self->payby('');
1875   }
1876
1877   $error =    $self->ut_numbern('paystart_month')
1878            || $self->ut_numbern('paystart_year')
1879            || $self->ut_numbern('payissue')
1880            || $self->ut_textn('paytype')
1881   ;
1882   return $error if $error;
1883
1884   if ( $self->payip eq '' ) {
1885     $self->payip('');
1886   } else {
1887     $error = $self->ut_ip('payip');
1888     return $error if $error;
1889   }
1890
1891   # If it is encrypted and the private key is not availaible then we can't
1892   # check the credit card.
1893   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1894
1895   # Need some kind of global flag to accept invalid cards, for testing
1896   # on scrubbed data.
1897   if ( !$import && !$ignore_invalid_card && $check_payinfo &&
1898     $self->payby =~ /^(CARD|DCRD)$/ ) {
1899
1900     my $payinfo = $self->payinfo;
1901     $payinfo =~ s/\D//g;
1902     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1903       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1904     $payinfo = $1;
1905     $self->payinfo($payinfo);
1906     validate($payinfo)
1907       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1908
1909     return gettext('unknown_card_type')
1910       if $self->payinfo !~ /^99\d{14}$/ #token
1911       && cardtype($self->payinfo) eq "Unknown";
1912
1913     unless ( $ignore_banned_card ) {
1914       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1915       if ( $ban ) {
1916         if ( $ban->bantype eq 'warn' ) {
1917           #or others depending on value of $ban->reason ?
1918           return '_duplicate_card'.
1919                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1920                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1921                  ' (ban# '. $ban->bannum. ')'
1922             unless $self->override_ban_warn;
1923         } else {
1924           return 'Banned credit card: banned on '.
1925                  time2str('%a %h %o at %r', $ban->_date).
1926                  ' by '. $ban->otaker.
1927                  ' (ban# '. $ban->bannum. ')';
1928         }
1929       }
1930     }
1931
1932     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1933       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1934         $self->paycvv =~ /^(\d{4})$/
1935           or return "CVV2 (CID) for American Express cards is four digits.";
1936         $self->paycvv($1);
1937       } else {
1938         $self->paycvv =~ /^(\d{3})$/
1939           or return "CVV2 (CVC2/CID) is three digits.";
1940         $self->paycvv($1);
1941       }
1942     } else {
1943       $self->paycvv('');
1944     }
1945
1946     my $cardtype = cardtype($payinfo);
1947     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1948
1949       return "Start date or issue number is required for $cardtype cards"
1950         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1951
1952       return "Start month must be between 1 and 12"
1953         if $self->paystart_month
1954            and $self->paystart_month < 1 || $self->paystart_month > 12;
1955
1956       return "Start year must be 1990 or later"
1957         if $self->paystart_year
1958            and $self->paystart_year < 1990;
1959
1960       return "Issue number must be beween 1 and 99"
1961         if $self->payissue
1962           and $self->payissue < 1 || $self->payissue > 99;
1963
1964     } else {
1965       $self->paystart_month('');
1966       $self->paystart_year('');
1967       $self->payissue('');
1968     }
1969
1970   } elsif ( !$ignore_invalid_card && $check_payinfo &&
1971     $self->payby =~ /^(CHEK|DCHK)$/ ) {
1972
1973     my $payinfo = $self->payinfo;
1974     $payinfo =~ s/[^\d\@\.]//g;
1975     if ( $conf->config('echeck-country') eq 'CA' ) {
1976       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1977         or return 'invalid echeck account@branch.bank';
1978       $payinfo = "$1\@$2.$3";
1979     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1980       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1981       $payinfo = "$1\@$2";
1982     } else {
1983       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1984       $payinfo = "$1\@$2";
1985     }
1986     $self->payinfo($payinfo);
1987     $self->paycvv('');
1988
1989     unless ( $ignore_banned_card ) {
1990       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1991       if ( $ban ) {
1992         if ( $ban->bantype eq 'warn' ) {
1993           #or others depending on value of $ban->reason ?
1994           return '_duplicate_ach' unless $self->override_ban_warn;
1995         } else {
1996           return 'Banned ACH account: banned on '.
1997                  time2str('%a %h %o at %r', $ban->_date).
1998                  ' by '. $ban->otaker.
1999                  ' (ban# '. $ban->bannum. ')';
2000         }
2001       }
2002     }
2003
2004   } elsif ( $self->payby eq 'LECB' ) {
2005
2006     my $payinfo = $self->payinfo;
2007     $payinfo =~ s/\D//g;
2008     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
2009     $payinfo = $1;
2010     $self->payinfo($payinfo);
2011     $self->paycvv('');
2012
2013   } elsif ( $self->payby eq 'BILL' ) {
2014
2015     $error = $self->ut_textn('payinfo');
2016     return "Illegal P.O. number: ". $self->payinfo if $error;
2017     $self->paycvv('');
2018
2019   } elsif ( $self->payby eq 'COMP' ) {
2020
2021     my $curuser = $FS::CurrentUser::CurrentUser;
2022     if (    ! $self->custnum
2023          && ! $curuser->access_right('Complimentary customer')
2024        )
2025     {
2026       return "You are not permitted to create complimentary accounts."
2027     }
2028
2029     $error = $self->ut_textn('payinfo');
2030     return "Illegal comp account issuer: ". $self->payinfo if $error;
2031     $self->paycvv('');
2032
2033   } elsif ( $self->payby eq 'PREPAY' ) {
2034
2035     my $payinfo = $self->payinfo;
2036     $payinfo =~ s/\W//g; #anything else would just confuse things
2037     $self->payinfo($payinfo);
2038     $error = $self->ut_alpha('payinfo');
2039     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2040     return "Unknown prepayment identifier"
2041       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2042     $self->paycvv('');
2043
2044   }
2045
2046   return "You are not permitted to create complimentary accounts."
2047     if ! $self->custnum
2048     && $self->complimentary eq 'Y'
2049     && ! $FS::CurrentUser::CurrentUser->access_right('Complimentary customer');
2050
2051   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2052     return "Expiration date required"
2053       # shouldn't payinfo_check do this?
2054       unless ! $self->payby
2055             || $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2056     $self->paydate('');
2057   } else {
2058     my( $m, $y );
2059     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2060       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2061     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2062       ( $m, $y ) = ( $2, "19$1" );
2063     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2064       ( $m, $y ) = ( $3, "20$2" );
2065     } else {
2066       return "Illegal expiration date: ". $self->paydate;
2067     }
2068     $m = sprintf('%02d',$m);
2069     $self->paydate("$y-$m-01");
2070     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2071     return gettext('expired_card')
2072       if !$import
2073       && !$ignore_expired_card
2074       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2075   }
2076
2077   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2078        ( ! $conf->exists('require_cardname')
2079          || $self->payby !~ /^(CARD|DCRD)$/  )
2080   ) {
2081     $self->payname( $self->first. " ". $self->getfield('last') );
2082   } else {
2083
2084     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2085       $self->payname =~ /^([\w \,\.\-\']*)$/
2086         or return gettext('illegal_name'). " payname: ". $self->payname;
2087       $self->payname($1);
2088     } else {
2089       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
2090         or return gettext('illegal_name'). " payname: ". $self->payname;
2091       $self->payname($1);
2092     }
2093
2094   }
2095
2096   ### end of stuff moved to cust_payby
2097
2098   return "Please select an invoicing locale"
2099     if ! $self->locale
2100     && ! $self->custnum
2101     && $conf->exists('cust_main-require_locale');
2102
2103   return "Please select a customer class"
2104     if ! $self->classnum
2105     && $conf->exists('cust_main-require_classnum');
2106
2107   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2108     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2109     $self->$flag($1);
2110   }
2111
2112   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2113
2114   warn "$me check AFTER: \n". $self->_dump
2115     if $DEBUG > 2;
2116
2117   $self->SUPER::check;
2118 }
2119
2120 sub check_payinfo_cardtype {
2121   my $self = shift;
2122
2123   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
2124
2125   my $payinfo = $self->payinfo;
2126   $payinfo =~ s/\D//g;
2127
2128   return '' if $payinfo =~ /^99\d{14}$/; #token
2129
2130   my %bop_card_types = map { $_=>1 } values %{ card_types() };
2131   my $cardtype = cardtype($payinfo);
2132
2133   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
2134
2135   '';
2136
2137 }
2138
2139 =item replace_check
2140
2141 Additional checks for replace only.
2142
2143 =cut
2144
2145 sub replace_check {
2146   my ($new,$old) = @_;
2147   #preserve old value if global config is set
2148   if ($old && $conf->exists('invoice-ship_address')) {
2149     $new->invoice_ship_address($old->invoice_ship_address);
2150   }
2151   return '';
2152 }
2153
2154 =item addr_fields
2155
2156 Returns a list of fields which have ship_ duplicates.
2157
2158 =cut
2159
2160 sub addr_fields {
2161   qw( last first company
2162       locationname
2163       address1 address2 city county state zip country
2164       latitude longitude
2165       daytime night fax mobile
2166     );
2167 }
2168
2169 =item has_ship_address
2170
2171 Returns true if this customer record has a separate shipping address.
2172
2173 =cut
2174
2175 sub has_ship_address {
2176   my $self = shift;
2177   $self->bill_locationnum != $self->ship_locationnum;
2178 }
2179
2180 =item location_hash
2181
2182 Returns a list of key/value pairs, with the following keys: address1,
2183 adddress2, city, county, state, zip, country, district, and geocode.  The
2184 shipping address is used if present.
2185
2186 =cut
2187
2188 sub location_hash {
2189   my $self = shift;
2190   $self->ship_location->location_hash;
2191 }
2192
2193 =item cust_location
2194
2195 Returns all locations (see L<FS::cust_location>) for this customer.
2196
2197 =cut
2198
2199 sub cust_location {
2200   my $self = shift;
2201   qsearch({
2202     'table'   => 'cust_location',
2203     'hashref' => { 'custnum'     => $self->custnum,
2204                    'prospectnum' => '',
2205                  },
2206     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
2207   });
2208 }
2209
2210 =item cust_contact
2211
2212 Returns all contact associations (see L<FS::cust_contact>) for this customer.
2213
2214 =cut
2215
2216 sub cust_contact {
2217   my $self = shift;
2218   qsearch('cust_contact', { 'custnum' => $self->custnum } );
2219 }
2220
2221 =item cust_payby PAYBY
2222
2223 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2224
2225 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
2226 Does not validate PAYBY.
2227
2228 =cut
2229
2230 sub cust_payby {
2231   my $self = shift;
2232   my @payby = @_;
2233   my $search = {
2234     'table'    => 'cust_payby',
2235     'hashref'  => { 'custnum' => $self->custnum },
2236     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
2237   };
2238   $search->{'extra_sql'} = ' AND payby IN ( '.
2239                                join(',', map dbh->quote($_), @payby).
2240                              ' ) '
2241     if @payby;
2242
2243   qsearch($search);
2244 }
2245
2246 =item has_cust_payby_auto
2247
2248 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2249
2250 =cut
2251
2252 sub has_cust_payby_auto {
2253   my $self = shift;
2254   scalar( qsearch({
2255     'table'     => 'cust_payby',
2256     'hashref'   => { 'custnum' => $self->custnum, },
2257     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2258     'order_by'  => 'LIMIT 1',
2259   }) );
2260
2261 }
2262
2263 =item unsuspend
2264
2265 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2266 and L<FS::cust_pkg>) for this customer, except those on hold.
2267
2268 Returns a list: an empty list on success or a list of errors.
2269
2270 =cut
2271
2272 sub unsuspend {
2273   my $self = shift;
2274   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs;
2275 }
2276
2277 =item release_hold
2278
2279 Unsuspends all suspended packages in the on-hold state (those without setup
2280 dates) for this customer.
2281
2282 =cut
2283
2284 sub release_hold {
2285   my $self = shift;
2286   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2287 }
2288
2289 =item suspend
2290
2291 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2292
2293 Returns a list: an empty list on success or a list of errors.
2294
2295 =cut
2296
2297 sub suspend {
2298   my $self = shift;
2299   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2300 }
2301
2302 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2303
2304 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2305 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2306 of a list of pkgparts; the hashref has the following keys:
2307
2308 =over 4
2309
2310 =item pkgparts - listref of pkgparts
2311
2312 =item (other options are passed to the suspend method)
2313
2314 =back
2315
2316
2317 Returns a list: an empty list on success or a list of errors.
2318
2319 =cut
2320
2321 sub suspend_if_pkgpart {
2322   my $self = shift;
2323   my (@pkgparts, %opt);
2324   if (ref($_[0]) eq 'HASH'){
2325     @pkgparts = @{$_[0]{pkgparts}};
2326     %opt      = %{$_[0]};
2327   }else{
2328     @pkgparts = @_;
2329   }
2330   grep { $_->suspend(%opt) }
2331     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2332       $self->unsuspended_pkgs;
2333 }
2334
2335 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2336
2337 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2338 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2339 instead of a list of pkgparts; the hashref has the following keys:
2340
2341 =over 4
2342
2343 =item pkgparts - listref of pkgparts
2344
2345 =item (other options are passed to the suspend method)
2346
2347 =back
2348
2349 Returns a list: an empty list on success or a list of errors.
2350
2351 =cut
2352
2353 sub suspend_unless_pkgpart {
2354   my $self = shift;
2355   my (@pkgparts, %opt);
2356   if (ref($_[0]) eq 'HASH'){
2357     @pkgparts = @{$_[0]{pkgparts}};
2358     %opt      = %{$_[0]};
2359   }else{
2360     @pkgparts = @_;
2361   }
2362   grep { $_->suspend(%opt) }
2363     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2364       $self->unsuspended_pkgs;
2365 }
2366
2367 =item cancel [ OPTION => VALUE ... ]
2368
2369 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2370 The cancellation time will be now.
2371
2372 =back
2373
2374 Always returns a list: an empty list on success or a list of errors.
2375
2376 =cut
2377
2378 sub cancel {
2379   my $self = shift;
2380   my %opt = @_;
2381   warn "$me cancel called on customer ". $self->custnum. " with options ".
2382        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2383     if $DEBUG;
2384   my @pkgs = $self->ncancelled_pkgs;
2385
2386   $self->cancel_pkgs( %opt, 'cust_pkg' => \@pkgs );
2387 }
2388
2389 =item cancel_pkgs OPTIONS
2390
2391 Cancels a specified list of packages. OPTIONS can include:
2392
2393 =over 4
2394
2395 =item cust_pkg - an arrayref of the packages. Required.
2396
2397 =item time - the cancellation time, used to calculate final bills and
2398 unused-time credits if any. Will be passed through to the bill() and
2399 FS::cust_pkg::cancel() methods.
2400
2401 =item quiet - can be set true to supress email cancellation notices.
2402
2403 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a
2404 reasonnum of an existing reason, or passing a hashref will create a new reason.
2405 The hashref should have the following keys:
2406 typenum - Reason type (see L<FS::reason_type>)
2407 reason - Text of the new reason.
2408
2409 =item cust_pkg_reason - can be an arrayref of L<FS::cust_pkg_reason> objects
2410 for the individual packages, parallel to the C<cust_pkg> argument. The
2411 reason and reason_otaker arguments will be taken from those objects.
2412
2413 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2414
2415 =item nobill - can be set true to skip billing if it might otherwise be done.
2416
2417 =cut
2418
2419 sub cancel_pkgs {
2420   my( $self, %opt ) = @_;
2421
2422   # we're going to cancel services, which is not reversible
2423   die "cancel_pkgs cannot be run inside a transaction"
2424     if $FS::UID::AutoCommit == 0;
2425
2426   local $FS::UID::AutoCommit = 0;
2427
2428   return ( 'access denied' )
2429     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2430
2431   if ( $opt{'ban'} ) {
2432
2433     foreach my $cust_payby ( $self->cust_payby ) {
2434
2435       #well, if they didn't get decrypted on search, then we don't have to
2436       # try again... queue a job for the server that does have decryption
2437       # capability if we're in a paranoid multi-server implementation?
2438       return ( "Can't (yet) ban encrypted credit cards" )
2439         if $cust_payby->is_encrypted($cust_payby->payinfo);
2440
2441       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2442       my $error = $ban->insert;
2443       if ($error) {
2444         dbh->rollback;
2445         return ( $error );
2446       }
2447
2448     }
2449
2450   }
2451
2452   my @pkgs = @{ delete $opt{'cust_pkg'} };
2453   my $cancel_time = $opt{'time'} || time;
2454
2455   # bill all packages first, so we don't lose usage, service counts for
2456   # bulk billing, etc.
2457   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2458     $opt{nobill} = 1;
2459     my $error = $self->bill( 'pkg_list' => [ @pkgs ],
2460                              'cancel'   => 1,
2461                              'time'     => $cancel_time );
2462     if ($error) {
2463       warn "Error billing during cancel, custnum ". $self->custnum. ": $error";
2464       dbh->rollback;
2465       return ( "Error billing during cancellation: $error" );
2466     }
2467   }
2468   dbh->commit;
2469
2470   $FS::UID::AutoCommit = 1;
2471   my @errors;
2472   # now cancel all services, the same way we would for individual packages.
2473   # if any of them fail, cancel the rest anyway.
2474   my @cust_svc = map { $_->cust_svc } @pkgs;
2475   my @sorted_cust_svc =
2476     map  { $_->[0] }
2477     sort { $a->[1] <=> $b->[1] }
2478     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; } @cust_svc
2479   ;
2480   warn "$me removing ".scalar(@sorted_cust_svc)." service(s) for customer ".
2481     $self->custnum."\n"
2482     if $DEBUG;
2483   foreach my $cust_svc (@sorted_cust_svc) {
2484     my $part_svc = $cust_svc->part_svc;
2485     next if ( defined($part_svc) and $part_svc->preserve );
2486     my $error = $cust_svc->cancel; # immediate cancel, no date option
2487     push @errors, $error if $error;
2488   }
2489   if (@errors) {
2490     return @errors;
2491   }
2492
2493   warn "$me cancelling ". scalar(@pkgs) ." package(s) for customer ".
2494     $self->custnum. "\n"
2495     if $DEBUG;
2496
2497   my @cprs;
2498   if ($opt{'cust_pkg_reason'}) {
2499     @cprs = @{ delete $opt{'cust_pkg_reason'} };
2500   }
2501   my $null_reason;
2502   foreach (@pkgs) {
2503     my %lopt = %opt;
2504     if (@cprs) {
2505       my $cpr = shift @cprs;
2506       if ( $cpr ) {
2507         $lopt{'reason'}        = $cpr->reasonnum;
2508         $lopt{'reason_otaker'} = $cpr->otaker;
2509       } else {
2510         warn "no reason found when canceling package ".$_->pkgnum."\n";
2511         # we're not actually required to pass a reason to cust_pkg::cancel,
2512         # but if we're getting to this point, something has gone awry.
2513         $null_reason ||= FS::reason->new_or_existing(
2514           reason  => 'unknown reason',
2515           type    => 'Cancel Reason',
2516           class   => 'C',
2517         );
2518         $lopt{'reason'} = $null_reason->reasonnum;
2519         $lopt{'reason_otaker'} = $FS::CurrentUser::CurrentUser->username;
2520       }
2521     }
2522     my $error = $_->cancel(%lopt);
2523     push @errors, 'pkgnum '.$_->pkgnum.': '.$error if $error;
2524   }
2525
2526   return @errors;
2527 }
2528
2529 sub _banned_pay_hashref {
2530   my $self = shift;
2531
2532   my %payby2ban = (
2533     'CARD' => 'CARD',
2534     'DCRD' => 'CARD',
2535     'CHEK' => 'CHEK',
2536     'DCHK' => 'CHEK'
2537   );
2538
2539   {
2540     'payby'   => $payby2ban{$self->payby},
2541     'payinfo' => $self->payinfo,
2542     #don't ever *search* on reason! #'reason'  =>
2543   };
2544 }
2545
2546 =item notes
2547
2548 Returns all notes (see L<FS::cust_main_note>) for this customer.
2549
2550 =cut
2551
2552 sub notes {
2553   my($self,$orderby_classnum) = (shift,shift);
2554   my $orderby = "sticky DESC, _date DESC";
2555   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2556   qsearch( 'cust_main_note',
2557            { 'custnum' => $self->custnum },
2558            '',
2559            "ORDER BY $orderby",
2560          );
2561 }
2562
2563 =item agent
2564
2565 Returns the agent (see L<FS::agent>) for this customer.
2566
2567 =item agent_name
2568
2569 Returns the agent name (see L<FS::agent>) for this customer.
2570
2571 =cut
2572
2573 sub agent_name {
2574   my $self = shift;
2575   $self->agent->agent;
2576 }
2577
2578 =item cust_tag
2579
2580 Returns any tags associated with this customer, as FS::cust_tag objects,
2581 or an empty list if there are no tags.
2582
2583 =item part_tag
2584
2585 Returns any tags associated with this customer, as FS::part_tag objects,
2586 or an empty list if there are no tags.
2587
2588 =cut
2589
2590 sub part_tag {
2591   my $self = shift;
2592   map $_->part_tag, $self->cust_tag;
2593 }
2594
2595
2596 =item cust_class
2597
2598 Returns the customer class, as an FS::cust_class object, or the empty string
2599 if there is no customer class.
2600
2601 =item categoryname
2602
2603 Returns the customer category name, or the empty string if there is no customer
2604 category.
2605
2606 =cut
2607
2608 sub categoryname {
2609   my $self = shift;
2610   my $cust_class = $self->cust_class;
2611   $cust_class
2612     ? $cust_class->categoryname
2613     : '';
2614 }
2615
2616 =item classname
2617
2618 Returns the customer class name, or the empty string if there is no customer
2619 class.
2620
2621 =cut
2622
2623 sub classname {
2624   my $self = shift;
2625   my $cust_class = $self->cust_class;
2626   $cust_class
2627     ? $cust_class->classname
2628     : '';
2629 }
2630
2631 =item tax_status
2632
2633 Returns the external tax status, as an FS::tax_status object, or the empty
2634 string if there is no tax status.
2635
2636 =cut
2637
2638 sub tax_status {
2639   my $self = shift;
2640   if ( $self->taxstatusnum ) {
2641     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2642   } else {
2643     return '';
2644   }
2645 }
2646
2647 =item taxstatus
2648
2649 Returns the tax status code if there is one.
2650
2651 =cut
2652
2653 sub taxstatus {
2654   my $self = shift;
2655   my $tax_status = $self->tax_status;
2656   $tax_status
2657     ? $tax_status->taxstatus
2658     : '';
2659 }
2660
2661 =item BILLING METHODS
2662
2663 Documentation on billing methods has been moved to
2664 L<FS::cust_main::Billing>.
2665
2666 =item REALTIME BILLING METHODS
2667
2668 Documentation on realtime billing methods has been moved to
2669 L<FS::cust_main::Billing_Realtime>.
2670
2671 =item remove_cvv
2672
2673 Removes the I<paycvv> field from the database directly.
2674
2675 If there is an error, returns the error, otherwise returns false.
2676
2677 DEPRECATED.  Use L</remove_cvv_from_cust_payby> instead.
2678
2679 =cut
2680
2681 sub remove_cvv {
2682   my $self = shift;
2683   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2684     or return dbh->errstr;
2685   $sth->execute($self->custnum)
2686     or return $sth->errstr;
2687   $self->paycvv('');
2688   '';
2689 }
2690
2691 =item total_owed
2692
2693 Returns the total owed for this customer on all invoices
2694 (see L<FS::cust_bill/owed>).
2695
2696 =cut
2697
2698 sub total_owed {
2699   my $self = shift;
2700   $self->total_owed_date(2145859200); #12/31/2037
2701 }
2702
2703 =item total_owed_date TIME
2704
2705 Returns the total owed for this customer on all invoices with date earlier than
2706 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2707 see L<Time::Local> and L<Date::Parse> for conversion functions.
2708
2709 =cut
2710
2711 sub total_owed_date {
2712   my $self = shift;
2713   my $time = shift;
2714
2715   my $custnum = $self->custnum;
2716
2717   my $owed_sql = FS::cust_bill->owed_sql;
2718
2719   my $sql = "
2720     SELECT SUM($owed_sql) FROM cust_bill
2721       WHERE custnum = $custnum
2722         AND _date <= $time
2723   ";
2724
2725   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2726
2727 }
2728
2729 =item total_owed_pkgnum PKGNUM
2730
2731 Returns the total owed on all invoices for this customer's specific package
2732 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2733
2734 =cut
2735
2736 sub total_owed_pkgnum {
2737   my( $self, $pkgnum ) = @_;
2738   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2739 }
2740
2741 =item total_owed_date_pkgnum TIME PKGNUM
2742
2743 Returns the total owed for this customer's specific package when using
2744 experimental package balances on all invoices with date earlier than
2745 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2746 see L<Time::Local> and L<Date::Parse> for conversion functions.
2747
2748 =cut
2749
2750 sub total_owed_date_pkgnum {
2751   my( $self, $time, $pkgnum ) = @_;
2752
2753   my $total_bill = 0;
2754   foreach my $cust_bill (
2755     grep { $_->_date <= $time }
2756       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2757   ) {
2758     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2759   }
2760   sprintf( "%.2f", $total_bill );
2761
2762 }
2763
2764 =item total_paid
2765
2766 Returns the total amount of all payments.
2767
2768 =cut
2769
2770 sub total_paid {
2771   my $self = shift;
2772   my $total = 0;
2773   $total += $_->paid foreach $self->cust_pay;
2774   sprintf( "%.2f", $total );
2775 }
2776
2777 =item total_unapplied_credits
2778
2779 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2780 customer.  See L<FS::cust_credit/credited>.
2781
2782 =item total_credited
2783
2784 Old name for total_unapplied_credits.  Don't use.
2785
2786 =cut
2787
2788 sub total_credited {
2789   #carp "total_credited deprecated, use total_unapplied_credits";
2790   shift->total_unapplied_credits(@_);
2791 }
2792
2793 sub total_unapplied_credits {
2794   my $self = shift;
2795
2796   my $custnum = $self->custnum;
2797
2798   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2799
2800   my $sql = "
2801     SELECT SUM($unapplied_sql) FROM cust_credit
2802       WHERE custnum = $custnum
2803   ";
2804
2805   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2806
2807 }
2808
2809 =item total_unapplied_credits_pkgnum PKGNUM
2810
2811 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2812 customer.  See L<FS::cust_credit/credited>.
2813
2814 =cut
2815
2816 sub total_unapplied_credits_pkgnum {
2817   my( $self, $pkgnum ) = @_;
2818   my $total_credit = 0;
2819   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2820   sprintf( "%.2f", $total_credit );
2821 }
2822
2823
2824 =item total_unapplied_payments
2825
2826 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2827 See L<FS::cust_pay/unapplied>.
2828
2829 =cut
2830
2831 sub total_unapplied_payments {
2832   my $self = shift;
2833
2834   my $custnum = $self->custnum;
2835
2836   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2837
2838   my $sql = "
2839     SELECT SUM($unapplied_sql) FROM cust_pay
2840       WHERE custnum = $custnum
2841   ";
2842
2843   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2844
2845 }
2846
2847 =item total_unapplied_payments_pkgnum PKGNUM
2848
2849 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2850 specific package when using experimental package balances.  See
2851 L<FS::cust_pay/unapplied>.
2852
2853 =cut
2854
2855 sub total_unapplied_payments_pkgnum {
2856   my( $self, $pkgnum ) = @_;
2857   my $total_unapplied = 0;
2858   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2859   sprintf( "%.2f", $total_unapplied );
2860 }
2861
2862
2863 =item total_unapplied_refunds
2864
2865 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2866 customer.  See L<FS::cust_refund/unapplied>.
2867
2868 =cut
2869
2870 sub total_unapplied_refunds {
2871   my $self = shift;
2872   my $custnum = $self->custnum;
2873
2874   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2875
2876   my $sql = "
2877     SELECT SUM($unapplied_sql) FROM cust_refund
2878       WHERE custnum = $custnum
2879   ";
2880
2881   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2882
2883 }
2884
2885 =item balance
2886
2887 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2888 total_unapplied_credits minus total_unapplied_payments).
2889
2890 =cut
2891
2892 sub balance {
2893   my $self = shift;
2894   $self->balance_date_range;
2895 }
2896
2897 =item balance_date TIME
2898
2899 Returns the balance for this customer, only considering invoices with date
2900 earlier than TIME (total_owed_date minus total_credited minus
2901 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2902 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2903 functions.
2904
2905 =cut
2906
2907 sub balance_date {
2908   my $self = shift;
2909   $self->balance_date_range(shift);
2910 }
2911
2912 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2913
2914 Returns the balance for this customer, optionally considering invoices with
2915 date earlier than START_TIME, and not later than END_TIME
2916 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2917
2918 Times are specified as SQL fragments or numeric
2919 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2920 L<Date::Parse> for conversion functions.  The empty string can be passed
2921 to disable that time constraint completely.
2922
2923 Accepts the same options as L<balance_date_sql>:
2924
2925 =over 4
2926
2927 =item unapplied_date
2928
2929 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2930
2931 =item cutoff
2932
2933 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2934 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2935 range for invoices and I<unapplied> payments, credits, and refunds.
2936
2937 =back
2938
2939 =cut
2940
2941 sub balance_date_range {
2942   my $self = shift;
2943   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2944             ') FROM cust_main WHERE custnum='. $self->custnum;
2945   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2946 }
2947
2948 =item balance_pkgnum PKGNUM
2949
2950 Returns the balance for this customer's specific package when using
2951 experimental package balances (total_owed plus total_unrefunded, minus
2952 total_unapplied_credits minus total_unapplied_payments)
2953
2954 =cut
2955
2956 sub balance_pkgnum {
2957   my( $self, $pkgnum ) = @_;
2958
2959   sprintf( "%.2f",
2960       $self->total_owed_pkgnum($pkgnum)
2961 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2962 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2963     - $self->total_unapplied_credits_pkgnum($pkgnum)
2964     - $self->total_unapplied_payments_pkgnum($pkgnum)
2965   );
2966 }
2967
2968 =item payment_info
2969
2970 Returns a hash of useful information for making a payment.
2971
2972 =over 4
2973
2974 =item balance
2975
2976 Current balance.
2977
2978 =item payby
2979
2980 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2981 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2982 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2983
2984 =back
2985
2986 For credit card transactions:
2987
2988 =over 4
2989
2990 =item card_type 1
2991
2992 =item payname
2993
2994 Exact name on card
2995
2996 =back
2997
2998 For electronic check transactions:
2999
3000 =over 4
3001
3002 =item stateid_state
3003
3004 =back
3005
3006 =cut
3007
3008 sub payment_info {
3009   my $self = shift;
3010
3011   my %return = ();
3012
3013   $return{balance} = $self->balance;
3014
3015   $return{payname} = $self->payname
3016                      || ( $self->first. ' '. $self->get('last') );
3017
3018   $return{$_} = $self->bill_location->$_
3019     for qw(address1 address2 city state zip);
3020
3021   $return{payby} = $self->payby;
3022   $return{stateid_state} = $self->stateid_state;
3023
3024   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
3025     $return{card_type} = cardtype($self->payinfo);
3026     $return{payinfo} = $self->paymask;
3027
3028     @return{'month', 'year'} = $self->paydate_monthyear;
3029
3030   }
3031
3032   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
3033     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
3034     $return{payinfo1} = $payinfo1;
3035     $return{payinfo2} = $payinfo2;
3036     $return{paytype}  = $self->paytype;
3037     $return{paystate} = $self->paystate;
3038
3039   }
3040
3041   #doubleclick protection
3042   my $_date = time;
3043   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
3044
3045   %return;
3046
3047 }
3048
3049 =item paydate_epoch
3050
3051 Returns the next payment expiration date for this customer. If they have no
3052 payment methods that will expire, returns 0.
3053
3054 =cut
3055
3056 sub paydate_epoch {
3057   my $self = shift;
3058   # filter out the ones that individually return 0, but then return 0 if
3059   # there are no results
3060   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
3061   min( @epochs ) || 0;
3062 }
3063
3064 =item paydate_epoch_sql
3065
3066 Returns an SQL expression to get the next payment expiration date for a
3067 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
3068 dates, so that it's safe to test for "will it expire before date X" for any
3069 date up to then.
3070
3071 =cut
3072
3073 sub paydate_epoch_sql {
3074   my $class = shift;
3075   my $paydate = FS::cust_payby->paydate_epoch_sql;
3076   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
3077 }
3078
3079 sub tax_exemption {
3080   my( $self, $taxname ) = @_;
3081
3082   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3083                                      'taxname' => $taxname,
3084                                    },
3085           );
3086 }
3087
3088 =item cust_main_exemption
3089
3090 =item invoicing_list
3091
3092 Returns a list of email addresses (with svcnum entries expanded), and the word
3093 'POST' if the customer receives postal invoices.
3094
3095 =cut
3096
3097 sub invoicing_list {
3098   my( $self, $arrayref ) = @_;
3099
3100   if ( $arrayref ) {
3101     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
3102   }
3103
3104   my @emails = $self->invoicing_list_emailonly;
3105   push @emails, 'POST' if $self->get('postal_invoice');
3106
3107   @emails;
3108 }
3109
3110 =item check_invoicing_list ARRAYREF
3111
3112 Checks these arguements as valid input for the invoicing_list method.  If there
3113 is an error, returns the error, otherwise returns false.
3114
3115 =cut
3116
3117 sub check_invoicing_list {
3118   my( $self, $arrayref ) = @_;
3119
3120   foreach my $address ( @$arrayref ) {
3121
3122     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3123       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3124     }
3125
3126     my $cust_main_invoice = new FS::cust_main_invoice ( {
3127       'custnum' => $self->custnum,
3128       'dest'    => $address,
3129     } );
3130     my $error = $self->custnum
3131                 ? $cust_main_invoice->check
3132                 : $cust_main_invoice->checkdest
3133     ;
3134     return $error if $error;
3135
3136   }
3137
3138   return "Email address required"
3139     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3140     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3141
3142   '';
3143 }
3144
3145 =item all_emails
3146
3147 Returns the email addresses of all accounts provisioned for this customer.
3148
3149 =cut
3150
3151 sub all_emails {
3152   my $self = shift;
3153   my %list;
3154   foreach my $cust_pkg ( $self->all_pkgs ) {
3155     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3156     my @svc_acct =
3157       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3158         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3159           @cust_svc;
3160     $list{$_}=1 foreach map { $_->email } @svc_acct;
3161   }
3162   keys %list;
3163 }
3164
3165 =item invoicing_list_addpost
3166
3167 Adds postal invoicing to this customer.  If this customer is already configured
3168 to receive postal invoices, does nothing.
3169
3170 =cut
3171
3172 sub invoicing_list_addpost {
3173   my $self = shift;
3174   if ( $self->get('postal_invoice') eq '' ) {
3175     $self->set('postal_invoice', 'Y');
3176     my $error = $self->replace;
3177     warn $error if $error; # should fail harder, but this is traditional
3178   }
3179 }
3180
3181 =item invoicing_list_emailonly
3182
3183 Returns the list of email invoice recipients (invoicing_list without non-email
3184 destinations such as POST and FAX).
3185
3186 =cut
3187
3188 sub invoicing_list_emailonly {
3189   my $self = shift;
3190   warn "$me invoicing_list_emailonly called"
3191     if $DEBUG;
3192   return () if !$self->custnum; # not yet inserted
3193   return map { $_->emailaddress }
3194     qsearch({
3195         table     => 'cust_contact',
3196         select    => 'emailaddress',
3197         addl_from => ' JOIN contact USING (contactnum) '.
3198                      ' JOIN contact_email USING (contactnum)',
3199         hashref   => { 'custnum' => $self->custnum, },
3200         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
3201     });
3202 }
3203
3204 =item invoicing_list_emailonly_scalar
3205
3206 Returns the list of email invoice recipients (invoicing_list without non-email
3207 destinations such as POST and FAX) as a comma-separated scalar.
3208
3209 =cut
3210
3211 sub invoicing_list_emailonly_scalar {
3212   my $self = shift;
3213   warn "$me invoicing_list_emailonly_scalar called"
3214     if $DEBUG;
3215   join(', ', $self->invoicing_list_emailonly);
3216 }
3217
3218 =item contact_list [ CLASSNUM, ... ]
3219
3220 Returns a list of contacts (L<FS::contact> objects) for the customer. If
3221 a list of contact classnums is given, returns only contacts in those
3222 classes. If the pseudo-classnum 'invoice' is given, returns contacts that
3223 are marked as invoice destinations. If '0' is given, also returns contacts
3224 with no class.
3225
3226 If no arguments are given, returns all contacts for the customer.
3227
3228 =cut
3229
3230 sub contact_list {
3231   my $self = shift;
3232   my $search = {
3233     table       => 'contact',
3234     select      => 'contact.*, cust_contact.invoice_dest',
3235     addl_from   => ' JOIN cust_contact USING (contactnum)',
3236     extra_sql   => ' WHERE cust_contact.custnum = '.$self->custnum,
3237   };
3238
3239   my @orwhere;
3240   my @classnums;
3241   foreach (@_) {
3242     if ( $_ eq 'invoice' ) {
3243       push @orwhere, 'cust_contact.invoice_dest = \'Y\'';
3244     } elsif ( $_ eq '0' ) {
3245       push @orwhere, 'cust_contact.classnum is null';
3246     } elsif ( /^\d+$/ ) {
3247       push @classnums, $_;
3248     } else {
3249       die "bad classnum argument '$_'";
3250     }
3251   }
3252
3253   if (@classnums) {
3254     push @orwhere, 'cust_contact.classnum IN ('.join(',', @classnums).')';
3255   }
3256   if (@orwhere) {
3257     $search->{extra_sql} .= ' AND (' .
3258                             join(' OR ', map "( $_ )", @orwhere) .
3259                             ')';
3260   }
3261
3262   qsearch($search);
3263 }
3264
3265 =item contact_list_email [ CLASSNUM, ... ]
3266
3267 Same as L</contact_list>, but returns email destinations instead of contact
3268 objects.
3269
3270 =cut
3271
3272 sub contact_list_email {
3273   my $self = shift;
3274   my @contacts = $self->contact_list(@_);
3275   my @emails;
3276   foreach my $contact (@contacts) {
3277     foreach my $contact_email ($contact->contact_email) {
3278       push @emails,
3279         $contact->firstlast . ' <' . $contact_email->emailaddress . '>';
3280     }
3281   }
3282   @emails;
3283 }
3284
3285 =item referral_custnum_cust_main
3286
3287 Returns the customer who referred this customer (or the empty string, if
3288 this customer was not referred).
3289
3290 Note the difference with referral_cust_main method: This method,
3291 referral_custnum_cust_main returns the single customer (if any) who referred
3292 this customer, while referral_cust_main returns an array of customers referred
3293 BY this customer.
3294
3295 =cut
3296
3297 sub referral_custnum_cust_main {
3298   my $self = shift;
3299   return '' unless $self->referral_custnum;
3300   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3301 }
3302
3303 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3304
3305 Returns an array of customers referred by this customer (referral_custnum set
3306 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3307 customers referred by customers referred by this customer and so on, inclusive.
3308 The default behavior is DEPTH 1 (no recursion).
3309
3310 Note the difference with referral_custnum_cust_main method: This method,
3311 referral_cust_main, returns an array of customers referred BY this customer,
3312 while referral_custnum_cust_main returns the single customer (if any) who
3313 referred this customer.
3314
3315 =cut
3316
3317 sub referral_cust_main {
3318   my $self = shift;
3319   my $depth = @_ ? shift : 1;
3320   my $exclude = @_ ? shift : {};
3321
3322   my @cust_main =
3323     map { $exclude->{$_->custnum}++; $_; }
3324       grep { ! $exclude->{ $_->custnum } }
3325         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3326
3327   if ( $depth > 1 ) {
3328     push @cust_main,
3329       map { $_->referral_cust_main($depth-1, $exclude) }
3330         @cust_main;
3331   }
3332
3333   @cust_main;
3334 }
3335
3336 =item referral_cust_main_ncancelled
3337
3338 Same as referral_cust_main, except only returns customers with uncancelled
3339 packages.
3340
3341 =cut
3342
3343 sub referral_cust_main_ncancelled {
3344   my $self = shift;
3345   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3346 }
3347
3348 =item referral_cust_pkg [ DEPTH ]
3349
3350 Like referral_cust_main, except returns a flat list of all unsuspended (and
3351 uncancelled) packages for each customer.  The number of items in this list may
3352 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3353
3354 =cut
3355
3356 sub referral_cust_pkg {
3357   my $self = shift;
3358   my $depth = @_ ? shift : 1;
3359
3360   map { $_->unsuspended_pkgs }
3361     grep { $_->unsuspended_pkgs }
3362       $self->referral_cust_main($depth);
3363 }
3364
3365 =item referring_cust_main
3366
3367 Returns the single cust_main record for the customer who referred this customer
3368 (referral_custnum), or false.
3369
3370 =cut
3371
3372 sub referring_cust_main {
3373   my $self = shift;
3374   return '' unless $self->referral_custnum;
3375   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3376 }
3377
3378 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3379
3380 Applies a credit to this customer.  If there is an error, returns the error,
3381 otherwise returns false.
3382
3383 REASON can be a text string, an FS::reason object, or a scalar reference to
3384 a reasonnum.  If a text string, it will be automatically inserted as a new
3385 reason, and a 'reason_type' option must be passed to indicate the
3386 FS::reason_type for the new reason.
3387
3388 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3389 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3390 I<commission_pkgnum>.
3391
3392 Any other options are passed to FS::cust_credit::insert.
3393
3394 =cut
3395
3396 sub credit {
3397   my( $self, $amount, $reason, %options ) = @_;
3398
3399   my $cust_credit = new FS::cust_credit {
3400     'custnum' => $self->custnum,
3401     'amount'  => $amount,
3402   };
3403
3404   if ( ref($reason) ) {
3405
3406     if ( ref($reason) eq 'SCALAR' ) {
3407       $cust_credit->reasonnum( $$reason );
3408     } else {
3409       $cust_credit->reasonnum( $reason->reasonnum );
3410     }
3411
3412   } else {
3413     $cust_credit->set('reason', $reason)
3414   }
3415
3416   $cust_credit->$_( delete $options{$_} )
3417     foreach grep exists($options{$_}),
3418               qw( addlinfo eventnum ),
3419               map "commission_$_", qw( agentnum salesnum pkgnum );
3420
3421   $cust_credit->insert(%options);
3422
3423 }
3424
3425 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3426
3427 Creates a one-time charge for this customer.  If there is an error, returns
3428 the error, otherwise returns false.
3429
3430 New-style, with a hashref of options:
3431
3432   my $error = $cust_main->charge(
3433                                   {
3434                                     'amount'     => 54.32,
3435                                     'quantity'   => 1,
3436                                     'start_date' => str2time('7/4/2009'),
3437                                     'pkg'        => 'Description',
3438                                     'comment'    => 'Comment',
3439                                     'additional' => [], #extra invoice detail
3440                                     'classnum'   => 1,  #pkg_class
3441
3442                                     'setuptax'   => '', # or 'Y' for tax exempt
3443
3444                                     'locationnum'=> 1234, # optional
3445
3446                                     #internal taxation
3447                                     'taxclass'   => 'Tax class',
3448
3449                                     #vendor taxation
3450                                     'taxproduct' => 2,  #part_pkg_taxproduct
3451                                     'override'   => {}, #XXX describe
3452
3453                                     #will be filled in with the new object
3454                                     'cust_pkg_ref' => \$cust_pkg,
3455
3456                                     #generate an invoice immediately
3457                                     'bill_now' => 0,
3458                                     'invoice_terms' => '', #with these terms
3459                                   }
3460                                 );
3461
3462 Old-style:
3463
3464   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3465
3466 =cut
3467
3468 #super false laziness w/quotation::charge
3469 sub charge {
3470   my $self = shift;
3471   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3472   my ( $pkg, $comment, $additional );
3473   my ( $setuptax, $taxclass );   #internal taxes
3474   my ( $taxproduct, $override ); #vendor (CCH) taxes
3475   my $no_auto = '';
3476   my $separate_bill = '';
3477   my $cust_pkg_ref = '';
3478   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3479   my $locationnum;
3480   if ( ref( $_[0] ) ) {
3481     $amount     = $_[0]->{amount};
3482     $setup_cost = $_[0]->{setup_cost};
3483     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3484     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3485     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3486     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3487     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3488                                            : '$'. sprintf("%.2f",$amount);
3489     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3490     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3491     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3492     $additional = $_[0]->{additional} || [];
3493     $taxproduct = $_[0]->{taxproductnum};
3494     $override   = { '' => $_[0]->{tax_override} };
3495     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3496     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3497     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3498     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3499     $separate_bill = $_[0]->{separate_bill} || '';
3500   } else { # yuck
3501     $amount     = shift;
3502     $setup_cost = '';
3503     $quantity   = 1;
3504     $start_date = '';
3505     $pkg        = @_ ? shift : 'One-time charge';
3506     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3507     $setuptax   = '';
3508     $taxclass   = @_ ? shift : '';
3509     $additional = [];
3510   }
3511
3512   local $SIG{HUP} = 'IGNORE';
3513   local $SIG{INT} = 'IGNORE';
3514   local $SIG{QUIT} = 'IGNORE';
3515   local $SIG{TERM} = 'IGNORE';
3516   local $SIG{TSTP} = 'IGNORE';
3517   local $SIG{PIPE} = 'IGNORE';
3518
3519   my $oldAutoCommit = $FS::UID::AutoCommit;
3520   local $FS::UID::AutoCommit = 0;
3521   my $dbh = dbh;
3522
3523   my $part_pkg = new FS::part_pkg ( {
3524     'pkg'           => $pkg,
3525     'comment'       => $comment,
3526     'plan'          => 'flat',
3527     'freq'          => 0,
3528     'disabled'      => 'Y',
3529     'classnum'      => ( $classnum ? $classnum : '' ),
3530     'setuptax'      => $setuptax,
3531     'taxclass'      => $taxclass,
3532     'taxproductnum' => $taxproduct,
3533     'setup_cost'    => $setup_cost,
3534   } );
3535
3536   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3537                         ( 0 .. @$additional - 1 )
3538                   ),
3539                   'additional_count' => scalar(@$additional),
3540                   'setup_fee' => $amount,
3541                 );
3542
3543   my $error = $part_pkg->insert( options       => \%options,
3544                                  tax_overrides => $override,
3545                                );
3546   if ( $error ) {
3547     $dbh->rollback if $oldAutoCommit;
3548     return $error;
3549   }
3550
3551   my $pkgpart = $part_pkg->pkgpart;
3552   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3553   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3554     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3555     $error = $type_pkgs->insert;
3556     if ( $error ) {
3557       $dbh->rollback if $oldAutoCommit;
3558       return $error;
3559     }
3560   }
3561
3562   my $cust_pkg = new FS::cust_pkg ( {
3563     'custnum'    => $self->custnum,
3564     'pkgpart'    => $pkgpart,
3565     'quantity'   => $quantity,
3566     'start_date' => $start_date,
3567     'no_auto'    => $no_auto,
3568     'separate_bill' => $separate_bill,
3569     'locationnum'=> $locationnum,
3570   } );
3571
3572   $error = $cust_pkg->insert;
3573   if ( $error ) {
3574     $dbh->rollback if $oldAutoCommit;
3575     return $error;
3576   } elsif ( $cust_pkg_ref ) {
3577     ${$cust_pkg_ref} = $cust_pkg;
3578   }
3579
3580   if ( $bill_now ) {
3581     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3582                              'pkg_list'      => [ $cust_pkg ],
3583                            );
3584     if ( $error ) {
3585       $dbh->rollback if $oldAutoCommit;
3586       return $error;
3587     }
3588   }
3589
3590   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3591   return '';
3592
3593 }
3594
3595 #=item charge_postal_fee
3596 #
3597 #Applies a one time charge this customer.  If there is an error,
3598 #returns the error, returns the cust_pkg charge object or false
3599 #if there was no charge.
3600 #
3601 #=cut
3602 #
3603 # This should be a customer event.  For that to work requires that bill
3604 # also be a customer event.
3605
3606 sub charge_postal_fee {
3607   my $self = shift;
3608
3609   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3610   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3611
3612   my $cust_pkg = new FS::cust_pkg ( {
3613     'custnum'  => $self->custnum,
3614     'pkgpart'  => $pkgpart,
3615     'quantity' => 1,
3616   } );
3617
3618   my $error = $cust_pkg->insert;
3619   $error ? $error : $cust_pkg;
3620 }
3621
3622 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3623
3624 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3625
3626 Optionally, a list or hashref of additional arguments to the qsearch call can
3627 be passed.
3628
3629 =cut
3630
3631 sub cust_bill {
3632   my $self = shift;
3633   my $opt = ref($_[0]) ? shift : { @_ };
3634
3635   #return $self->num_cust_bill unless wantarray || keys %$opt;
3636
3637   $opt->{'table'} = 'cust_bill';
3638   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3639   $opt->{'hashref'}{'custnum'} = $self->custnum;
3640   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3641
3642   map { $_ } #behavior of sort undefined in scalar context
3643     sort { $a->_date <=> $b->_date }
3644       qsearch($opt);
3645 }
3646
3647 =item open_cust_bill
3648
3649 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3650 customer.
3651
3652 =cut
3653
3654 sub open_cust_bill {
3655   my $self = shift;
3656
3657   $self->cust_bill(
3658     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3659     #@_
3660   );
3661
3662 }
3663
3664 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3665
3666 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3667
3668 =cut
3669
3670 sub legacy_cust_bill {
3671   my $self = shift;
3672
3673   #return $self->num_legacy_cust_bill unless wantarray;
3674
3675   map { $_ } #behavior of sort undefined in scalar context
3676     sort { $a->_date <=> $b->_date }
3677       qsearch({ 'table'    => 'legacy_cust_bill',
3678                 'hashref'  => { 'custnum' => $self->custnum, },
3679                 'order_by' => 'ORDER BY _date ASC',
3680              });
3681 }
3682
3683 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3684
3685 Returns all the statements (see L<FS::cust_statement>) for this customer.
3686
3687 Optionally, a list or hashref of additional arguments to the qsearch call can
3688 be passed.
3689
3690 =cut
3691
3692 =item cust_bill_void
3693
3694 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3695
3696 =cut
3697
3698 sub cust_bill_void {
3699   my $self = shift;
3700
3701   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3702   sort { $a->_date <=> $b->_date }
3703     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3704 }
3705
3706 sub cust_statement {
3707   my $self = shift;
3708   my $opt = ref($_[0]) ? shift : { @_ };
3709
3710   #return $self->num_cust_statement unless wantarray || keys %$opt;
3711
3712   $opt->{'table'} = 'cust_statement';
3713   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3714   $opt->{'hashref'}{'custnum'} = $self->custnum;
3715   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3716
3717   map { $_ } #behavior of sort undefined in scalar context
3718     sort { $a->_date <=> $b->_date }
3719       qsearch($opt);
3720 }
3721
3722 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3723
3724 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3725
3726 Optionally, a list or hashref of additional arguments to the qsearch call can
3727 be passed following the SVCDB.
3728
3729 =cut
3730
3731 sub svc_x {
3732   my $self = shift;
3733   my $svcdb = shift;
3734   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3735     warn "$me svc_x requires a svcdb";
3736     return;
3737   }
3738   my $opt = ref($_[0]) ? shift : { @_ };
3739
3740   $opt->{'table'} = $svcdb;
3741   $opt->{'addl_from'} =
3742     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3743     ($opt->{'addl_from'} || '');
3744
3745   my $custnum = $self->custnum;
3746   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3747   my $where = "cust_pkg.custnum = $custnum";
3748
3749   my $extra_sql = $opt->{'extra_sql'} || '';
3750   if ( keys %{ $opt->{'hashref'} } ) {
3751     $extra_sql = " AND $where $extra_sql";
3752   }
3753   else {
3754     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3755       $extra_sql = "WHERE $where AND $1";
3756     }
3757     else {
3758       $extra_sql = "WHERE $where $extra_sql";
3759     }
3760   }
3761   $opt->{'extra_sql'} = $extra_sql;
3762
3763   qsearch($opt);
3764 }
3765
3766 # required for use as an eventtable;
3767 sub svc_acct {
3768   my $self = shift;
3769   $self->svc_x('svc_acct', @_);
3770 }
3771
3772 =item cust_credit
3773
3774 Returns all the credits (see L<FS::cust_credit>) for this customer.
3775
3776 =cut
3777
3778 sub cust_credit {
3779   my $self = shift;
3780
3781   #return $self->num_cust_credit unless wantarray;
3782
3783   map { $_ } #behavior of sort undefined in scalar context
3784     sort { $a->_date <=> $b->_date }
3785       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3786 }
3787
3788 =item cust_credit_pkgnum
3789
3790 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3791 package when using experimental package balances.
3792
3793 =cut
3794
3795 sub cust_credit_pkgnum {
3796   my( $self, $pkgnum ) = @_;
3797   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3798   sort { $a->_date <=> $b->_date }
3799     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3800                               'pkgnum'  => $pkgnum,
3801                             }
3802     );
3803 }
3804
3805 =item cust_credit_void
3806
3807 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3808
3809 =cut
3810
3811 sub cust_credit_void {
3812   my $self = shift;
3813   map { $_ }
3814   sort { $a->_date <=> $b->_date }
3815     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3816 }
3817
3818 =item cust_pay
3819
3820 Returns all the payments (see L<FS::cust_pay>) for this customer.
3821
3822 =cut
3823
3824 sub cust_pay {
3825   my $self = shift;
3826   my $opt = ref($_[0]) ? shift : { @_ };
3827
3828   return $self->num_cust_pay unless wantarray || keys %$opt;
3829
3830   $opt->{'table'} = 'cust_pay';
3831   $opt->{'hashref'}{'custnum'} = $self->custnum;
3832
3833   map { $_ } #behavior of sort undefined in scalar context
3834     sort { $a->_date <=> $b->_date }
3835       qsearch($opt);
3836
3837 }
3838
3839 =item num_cust_pay
3840
3841 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3842 called automatically when the cust_pay method is used in a scalar context.
3843
3844 =cut
3845
3846 sub num_cust_pay {
3847   my $self = shift;
3848   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3849   my $sth = dbh->prepare($sql) or die dbh->errstr;
3850   $sth->execute($self->custnum) or die $sth->errstr;
3851   $sth->fetchrow_arrayref->[0];
3852 }
3853
3854 =item unapplied_cust_pay
3855
3856 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3857
3858 =cut
3859
3860 sub unapplied_cust_pay {
3861   my $self = shift;
3862
3863   $self->cust_pay(
3864     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3865     #@_
3866   );
3867
3868 }
3869
3870 =item cust_pay_pkgnum
3871
3872 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3873 package when using experimental package balances.
3874
3875 =cut
3876
3877 sub cust_pay_pkgnum {
3878   my( $self, $pkgnum ) = @_;
3879   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3880   sort { $a->_date <=> $b->_date }
3881     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3882                            'pkgnum'  => $pkgnum,
3883                          }
3884     );
3885 }
3886
3887 =item cust_pay_void
3888
3889 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3890
3891 =cut
3892
3893 sub cust_pay_void {
3894   my $self = shift;
3895   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3896   sort { $a->_date <=> $b->_date }
3897     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3898 }
3899
3900 =item cust_pay_pending
3901
3902 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3903 (without status "done").
3904
3905 =cut
3906
3907 sub cust_pay_pending {
3908   my $self = shift;
3909   return $self->num_cust_pay_pending unless wantarray;
3910   sort { $a->_date <=> $b->_date }
3911     qsearch( 'cust_pay_pending', {
3912                                    'custnum' => $self->custnum,
3913                                    'status'  => { op=>'!=', value=>'done' },
3914                                  },
3915            );
3916 }
3917
3918 =item cust_pay_pending_attempt
3919
3920 Returns all payment attempts / declined payments for this customer, as pending
3921 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3922 a corresponding payment (see L<FS::cust_pay>).
3923
3924 =cut
3925
3926 sub cust_pay_pending_attempt {
3927   my $self = shift;
3928   return $self->num_cust_pay_pending_attempt unless wantarray;
3929   sort { $a->_date <=> $b->_date }
3930     qsearch( 'cust_pay_pending', {
3931                                    'custnum' => $self->custnum,
3932                                    'status'  => 'done',
3933                                    'paynum'  => '',
3934                                  },
3935            );
3936 }
3937
3938 =item num_cust_pay_pending
3939
3940 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3941 customer (without status "done").  Also called automatically when the
3942 cust_pay_pending method is used in a scalar context.
3943
3944 =cut
3945
3946 sub num_cust_pay_pending {
3947   my $self = shift;
3948   $self->scalar_sql(
3949     " SELECT COUNT(*) FROM cust_pay_pending ".
3950       " WHERE custnum = ? AND status != 'done' ",
3951     $self->custnum
3952   );
3953 }
3954
3955 =item num_cust_pay_pending_attempt
3956
3957 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3958 customer, with status "done" but without a corresp.  Also called automatically when the
3959 cust_pay_pending method is used in a scalar context.
3960
3961 =cut
3962
3963 sub num_cust_pay_pending_attempt {
3964   my $self = shift;
3965   $self->scalar_sql(
3966     " SELECT COUNT(*) FROM cust_pay_pending ".
3967       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3968     $self->custnum
3969   );
3970 }
3971
3972 =item cust_refund
3973
3974 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3975
3976 =cut
3977
3978 sub cust_refund {
3979   my $self = shift;
3980   map { $_ } #return $self->num_cust_refund unless wantarray;
3981   sort { $a->_date <=> $b->_date }
3982     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3983 }
3984
3985 =item display_custnum
3986
3987 Returns the displayed customer number for this customer: agent_custid if
3988 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3989
3990 =cut
3991
3992 sub display_custnum {
3993   my $self = shift;
3994
3995   return $self->agent_custid
3996     if $default_agent_custid && $self->agent_custid;
3997
3998   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3999
4000   if ( $prefix ) {
4001     return $prefix .
4002            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
4003   } elsif ( $custnum_display_length ) {
4004     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
4005   } else {
4006     return $self->custnum;
4007   }
4008 }
4009
4010 =item name
4011
4012 Returns a name string for this customer, either "Company (Last, First)" or
4013 "Last, First".
4014
4015 =cut
4016
4017 sub name {
4018   my $self = shift;
4019   my $name = $self->contact;
4020   $name = $self->company. " ($name)" if $self->company;
4021   $name;
4022 }
4023
4024 =item service_contact
4025
4026 Returns the L<FS::contact> object for this customer that has the 'Service'
4027 contact class, or undef if there is no such contact.  Deprecated; don't use
4028 this in new code.
4029
4030 =cut
4031
4032 sub service_contact {
4033   my $self = shift;
4034   if ( !exists($self->{service_contact}) ) {
4035     my $classnum = $self->scalar_sql(
4036       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
4037     ) || 0; #if it's zero, qsearchs will return nothing
4038     my $cust_contact = qsearchs('cust_contact', {
4039         'classnum' => $classnum,
4040         'custnum'  => $self->custnum,
4041     });
4042     $self->{service_contact} = $cust_contact->contact if $cust_contact;
4043   }
4044   $self->{service_contact};
4045 }
4046
4047 =item ship_name
4048
4049 Returns a name string for this (service/shipping) contact, either
4050 "Company (Last, First)" or "Last, First".
4051
4052 =cut
4053
4054 sub ship_name {
4055   my $self = shift;
4056
4057   my $name = $self->ship_contact;
4058   $name = $self->company. " ($name)" if $self->company;
4059   $name;
4060 }
4061
4062 =item name_short
4063
4064 Returns a name string for this customer, either "Company" or "First Last".
4065
4066 =cut
4067
4068 sub name_short {
4069   my $self = shift;
4070   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4071 }
4072
4073 =item ship_name_short
4074
4075 Returns a name string for this (service/shipping) contact, either "Company"
4076 or "First Last".
4077
4078 =cut
4079
4080 sub ship_name_short {
4081   my $self = shift;
4082   $self->service_contact
4083     ? $self->ship_contact_firstlast
4084     : $self->name_short
4085 }
4086
4087 =item contact
4088
4089 Returns this customer's full (billing) contact name only, "Last, First"
4090
4091 =cut
4092
4093 sub contact {
4094   my $self = shift;
4095   $self->get('last'). ', '. $self->first;
4096 }
4097
4098 =item ship_contact
4099
4100 Returns this customer's full (shipping) contact name only, "Last, First"
4101
4102 =cut
4103
4104 sub ship_contact {
4105   my $self = shift;
4106   my $contact = $self->service_contact || $self;
4107   $contact->get('last') . ', ' . $contact->get('first');
4108 }
4109
4110 =item contact_firstlast
4111
4112 Returns this customers full (billing) contact name only, "First Last".
4113
4114 =cut
4115
4116 sub contact_firstlast {
4117   my $self = shift;
4118   $self->first. ' '. $self->get('last');
4119 }
4120
4121 =item ship_contact_firstlast
4122
4123 Returns this customer's full (shipping) contact name only, "First Last".
4124
4125 =cut
4126
4127 sub ship_contact_firstlast {
4128   my $self = shift;
4129   my $contact = $self->service_contact || $self;
4130   $contact->get('first') . ' '. $contact->get('last');
4131 }
4132
4133 sub bill_country_full {
4134   my $self = shift;
4135   $self->bill_location->country_full;
4136 }
4137
4138 sub ship_country_full {
4139   my $self = shift;
4140   $self->ship_location->country_full;
4141 }
4142
4143 =item county_state_county [ PREFIX ]
4144
4145 Returns a string consisting of just the county, state and country.
4146
4147 =cut
4148
4149 sub county_state_country {
4150   my $self = shift;
4151   my $locationnum;
4152   if ( @_ && $_[0] && $self->has_ship_address ) {
4153     $locationnum = $self->ship_locationnum;
4154   } else {
4155     $locationnum = $self->bill_locationnum;
4156   }
4157   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4158   $cust_location->county_state_country;
4159 }
4160
4161 =item geocode DATA_VENDOR
4162
4163 Returns a value for the customer location as encoded by DATA_VENDOR.
4164 Currently this only makes sense for "CCH" as DATA_VENDOR.
4165
4166 =cut
4167
4168 =item cust_status
4169
4170 =item status
4171
4172 Returns a status string for this customer, currently:
4173
4174 =over 4
4175
4176 =item prospect
4177
4178 No packages have ever been ordered.  Displayed as "No packages".
4179
4180 =item ordered
4181
4182 Recurring packages all are new (not yet billed).
4183
4184 =item active
4185
4186 One or more recurring packages is active.
4187
4188 =item inactive
4189
4190 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
4191
4192 =item suspended
4193
4194 All non-cancelled recurring packages are suspended.
4195
4196 =item cancelled
4197
4198 All recurring packages are cancelled.
4199
4200 =back
4201
4202 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4203 cust_main-status_module configuration option.
4204
4205 =cut
4206
4207 sub status { shift->cust_status(@_); }
4208
4209 sub cust_status {
4210   my $self = shift;
4211   return $self->hashref->{cust_status} if $self->hashref->{cust_status};
4212   for my $status ( FS::cust_main->statuses() ) {
4213     my $method = $status.'_sql';
4214     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4215     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4216     $sth->execute( ($self->custnum) x $numnum )
4217       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4218     if ( $sth->fetchrow_arrayref->[0] ) {
4219       $self->hashref->{cust_status} = $status;
4220       return $status;
4221     }
4222   }
4223 }
4224
4225 =item is_status_delay_cancel
4226
4227 Returns true if customer status is 'suspended'
4228 and all suspended cust_pkg return true for
4229 cust_pkg->is_status_delay_cancel.
4230
4231 This is not a real status, this only meant for hacking display
4232 values, because otherwise treating the customer as suspended is
4233 really the whole point of the delay_cancel option.
4234
4235 =cut
4236
4237 sub is_status_delay_cancel {
4238   my ($self) = @_;
4239   return 0 unless $self->status eq 'suspended';
4240   foreach my $cust_pkg ($self->ncancelled_pkgs) {
4241     return 0 unless $cust_pkg->is_status_delay_cancel;
4242   }
4243   return 1;
4244 }
4245
4246 =item ucfirst_cust_status
4247
4248 =item ucfirst_status
4249
4250 Deprecated, use the cust_status_label method instead.
4251
4252 Returns the status with the first character capitalized.
4253
4254 =cut
4255
4256 sub ucfirst_status {
4257   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4258   local($ucfirst_nowarn) = 1;
4259   shift->ucfirst_cust_status(@_);
4260 }
4261
4262 sub ucfirst_cust_status {
4263   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4264   my $self = shift;
4265   ucfirst($self->cust_status);
4266 }
4267
4268 =item cust_status_label
4269
4270 =item status_label
4271
4272 Returns the display label for this status.
4273
4274 =cut
4275
4276 sub status_label { shift->cust_status_label(@_); }
4277
4278 sub cust_status_label {
4279   my $self = shift;
4280   __PACKAGE__->statuslabels->{$self->cust_status};
4281 }
4282
4283 =item statuscolor
4284
4285 Returns a hex triplet color string for this customer's status.
4286
4287 =cut
4288
4289 sub statuscolor { shift->cust_statuscolor(@_); }
4290
4291 sub cust_statuscolor {
4292   my $self = shift;
4293   __PACKAGE__->statuscolors->{$self->cust_status};
4294 }
4295
4296 =item tickets [ STATUS ]
4297
4298 Returns an array of hashes representing the customer's RT tickets.
4299
4300 An optional status (or arrayref or hashref of statuses) may be specified.
4301
4302 =cut
4303
4304 sub tickets {
4305   my $self = shift;
4306   my $status = ( @_ && $_[0] ) ? shift : '';
4307
4308   my $num = $conf->config('cust_main-max_tickets') || 10;
4309   my @tickets = ();
4310
4311   if ( $conf->config('ticket_system') ) {
4312     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4313
4314       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4315                                                         $num,
4316                                                         undef,
4317                                                         $status,
4318                                                       )
4319                   };
4320
4321     } else {
4322
4323       foreach my $priority (
4324         $conf->config('ticket_system-custom_priority_field-values'), ''
4325       ) {
4326         last if scalar(@tickets) >= $num;
4327         push @tickets,
4328           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4329                                                  $num - scalar(@tickets),
4330                                                  $priority,
4331                                                  $status,
4332                                                )
4333            };
4334       }
4335     }
4336   }
4337   (@tickets);
4338 }
4339
4340 =item appointments [ STATUS ]
4341
4342 Returns an array of hashes representing the customer's RT tickets which
4343 are appointments.
4344
4345 =cut
4346
4347 sub appointments {
4348   my $self = shift;
4349   my $status = ( @_ && $_[0] ) ? shift : '';
4350
4351   return () unless $conf->config('ticket_system');
4352
4353   my $queueid = $conf->config('ticket_system-appointment-queueid');
4354
4355   @{ FS::TicketSystem->customer_tickets( $self->custnum,
4356                                          99,
4357                                          undef,
4358                                          $status,
4359                                          $queueid,
4360                                        )
4361   };
4362 }
4363
4364 # Return services representing svc_accts in customer support packages
4365 sub support_services {
4366   my $self = shift;
4367   my %packages = map { $_ => 1 } $conf->config('support_packages');
4368
4369   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4370     grep { $_->part_svc->svcdb eq 'svc_acct' }
4371     map { $_->cust_svc }
4372     grep { exists $packages{ $_->pkgpart } }
4373     $self->ncancelled_pkgs;
4374
4375 }
4376
4377 # Return a list of latitude/longitude for one of the services (if any)
4378 sub service_coordinates {
4379   my $self = shift;
4380
4381   my @svc_X =
4382     grep { $_->latitude && $_->longitude }
4383     map { $_->svc_x }
4384     map { $_->cust_svc }
4385     $self->ncancelled_pkgs;
4386
4387   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4388 }
4389
4390 =item masked FIELD
4391
4392 Returns a masked version of the named field
4393
4394 =cut
4395
4396 sub masked {
4397 my ($self,$field) = @_;
4398
4399 # Show last four
4400
4401 'x'x(length($self->getfield($field))-4).
4402   substr($self->getfield($field), (length($self->getfield($field))-4));
4403
4404 }
4405
4406 =item payment_history
4407
4408 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4409 cust_credit and cust_refund objects.  Each hashref has the following fields:
4410
4411 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4412
4413 I<date> - value of _date field, unix timestamp
4414
4415 I<date_pretty> - user-friendly date
4416
4417 I<description> - user-friendly description of item
4418
4419 I<amount> - impact of item on user's balance
4420 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4421 Not to be confused with the native 'amount' field in cust_credit, see below.
4422
4423 I<amount_pretty> - includes money char
4424
4425 I<balance> - customer balance, chronologically as of this item
4426
4427 I<balance_pretty> - includes money char
4428
4429 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4430
4431 I<paid> - amount paid for cust_pay records, undef for other types
4432
4433 I<credit> - amount credited for cust_credit records, undef for other types.
4434 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4435
4436 I<refund> - amount refunded for cust_refund records, undef for other types
4437
4438 The four table-specific keys always have positive values, whether they reflect charges or payments.
4439
4440 The following options may be passed to this method:
4441
4442 I<line_items> - if true, returns charges ('Line item') rather than invoices
4443
4444 I<start_date> - unix timestamp, only include records on or after.
4445 If specified, an item of type 'Previous' will also be included.
4446 It does not have table-specific fields.
4447
4448 I<end_date> - unix timestamp, only include records before
4449
4450 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4451
4452 I<conf> - optional already-loaded FS::Conf object.
4453
4454 =cut
4455
4456 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4457 # and also for sending customer statements, which should both be kept customer-friendly.
4458 # If you add anything that shouldn't be passed on through the API or exposed
4459 # to customers, add a new option to include it, don't include it by default
4460 sub payment_history {
4461   my $self = shift;
4462   my $opt = ref($_[0]) ? $_[0] : { @_ };
4463
4464   my $conf = $$opt{'conf'} || new FS::Conf;
4465   my $money_char = $conf->config("money_char") || '$',
4466
4467   #first load entire history,
4468   #need previous to calculate previous balance
4469   #loading after end_date shouldn't hurt too much?
4470   my @history = ();
4471   if ( $$opt{'line_items'} ) {
4472
4473     foreach my $cust_bill ( $self->cust_bill ) {
4474
4475       push @history, {
4476         'type'        => 'Line item',
4477         'description' => $_->desc( $self->locale ).
4478                            ( $_->sdate && $_->edate
4479                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4480                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4481                                : ''
4482                            ),
4483         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4484         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4485         'date'        => $cust_bill->_date,
4486         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4487       }
4488         foreach $cust_bill->cust_bill_pkg;
4489
4490     }
4491
4492   } else {
4493
4494     push @history, {
4495                      'type'        => 'Invoice',
4496                      'description' => 'Invoice #'. $_->display_invnum,
4497                      'amount'      => sprintf('%.2f', $_->charged ),
4498                      'charged'     => sprintf('%.2f', $_->charged ),
4499                      'date'        => $_->_date,
4500                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4501                    }
4502       foreach $self->cust_bill;
4503
4504   }
4505
4506   push @history, {
4507                    'type'        => 'Payment',
4508                    'description' => 'Payment', #XXX type
4509                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4510                    'paid'        => sprintf('%.2f', $_->paid ),
4511                    'date'        => $_->_date,
4512                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4513                  }
4514     foreach $self->cust_pay;
4515
4516   push @history, {
4517                    'type'        => 'Credit',
4518                    'description' => 'Credit', #more info?
4519                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4520                    'credit'      => sprintf('%.2f', $_->amount ),
4521                    'date'        => $_->_date,
4522                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4523                  }
4524     foreach $self->cust_credit;
4525
4526   push @history, {
4527                    'type'        => 'Refund',
4528                    'description' => 'Refund', #more info?  type, like payment?
4529                    'amount'      => $_->refund,
4530                    'refund'      => $_->refund,
4531                    'date'        => $_->_date,
4532                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4533                  }
4534     foreach $self->cust_refund;
4535
4536   #put it all in chronological order
4537   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4538
4539   #calculate balance, filter items outside date range
4540   my $previous = 0;
4541   my $balance = 0;
4542   my @out = ();
4543   foreach my $item (@history) {
4544     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4545     $balance += $$item{'amount'};
4546     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4547       $previous += $$item{'amount'};
4548       next;
4549     }
4550     $$item{'balance'} = sprintf("%.2f",$balance);
4551     foreach my $key ( qw(amount balance) ) {
4552       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4553     }
4554     push(@out,$item);
4555   }
4556
4557   # start with previous balance, if there was one
4558   if ($previous) {
4559     my $item = {
4560       'type'        => 'Previous',
4561       'description' => 'Previous balance',
4562       'amount'      => sprintf("%.2f",$previous),
4563       'balance'     => sprintf("%.2f",$previous),
4564       'date'        => $$opt{'start_date'},
4565       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4566     };
4567     #false laziness with above
4568     foreach my $key ( qw(amount balance) ) {
4569       $$item{$key.'_pretty'} = $$item{$key};
4570       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4571     }
4572     unshift(@out,$item);
4573   }
4574
4575   @out = reverse @history if $$opt{'reverse_sort'};
4576
4577   return @out;
4578 }
4579
4580 =item save_cust_payby
4581
4582 Saves a new cust_payby for this customer, replacing an existing entry only
4583 in select circumstances.  Does not validate input.
4584
4585 If auto is specified, marks this as the customer's primary method, or the
4586 specified weight.  Existing payment methods have their weight incremented as
4587 appropriate.
4588
4589 If bill_location is specified with auto, also sets location in cust_main.
4590
4591 Will not insert complete duplicates of existing records, or records in which the
4592 only difference from an existing record is to turn off automatic payment (will
4593 return without error.)  Will replace existing records in which the only difference
4594 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4595 Fields marked as preserved are optional, and existing values will not be overwritten with
4596 blanks when replacing.
4597
4598 Accepts the following named parameters:
4599
4600 =over 4
4601
4602 =item payment_payby
4603
4604 either CARD or CHEK
4605
4606 =item auto
4607
4608 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4609
4610 =item weight
4611
4612 optional, set higher than 1 for secondary, etc.
4613
4614 =item payinfo
4615
4616 required
4617
4618 =item paymask
4619
4620 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4621
4622 =item payname
4623
4624 required
4625
4626 =item payip
4627
4628 optional, will be preserved when replacing
4629
4630 =item paydate
4631
4632 CARD only, required
4633
4634 =item bill_location
4635
4636 CARD only, required, FS::cust_location object
4637
4638 =item paystart_month
4639
4640 CARD only, optional, will be preserved when replacing
4641
4642 =item paystart_year
4643
4644 CARD only, optional, will be preserved when replacing
4645
4646 =item payissue
4647
4648 CARD only, optional, will be preserved when replacing
4649
4650 =item paycvv
4651
4652 CARD only, only used if conf cvv-save is set appropriately
4653
4654 =item paytype
4655
4656 CHEK only
4657
4658 =item paystate
4659
4660 CHEK only
4661
4662 =back
4663
4664 =cut
4665
4666 #The code for this option is in place, but it's not currently used
4667 #
4668 # =item replace
4669 #
4670 # existing cust_payby object to be replaced (must match custnum)
4671
4672 # stateid/stateid_state/ss are not currently supported in cust_payby,
4673 # might not even work properly in 4.x, but will need to work here if ever added
4674
4675 sub save_cust_payby {
4676   my $self = shift;
4677   my %opt = @_;
4678
4679   my $old = $opt{'replace'};
4680   my $new = new FS::cust_payby { $old ? $old->hash : () };
4681   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4682   $new->set( 'custnum' => $self->custnum );
4683
4684   my $payby = $opt{'payment_payby'};
4685   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4686
4687   # don't allow turning off auto when replacing
4688   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4689
4690   my @check_existing; # payby relevant to this payment_payby
4691
4692   # set payby based on auto
4693   if ( $payby eq 'CARD' ) {
4694     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4695     @check_existing = qw( CARD DCRD );
4696   } elsif ( $payby eq 'CHEK' ) {
4697     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4698     @check_existing = qw( CHEK DCHK );
4699   }
4700
4701   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4702
4703   # basic fields
4704   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4705   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4706   $new->set( 'payname' => $opt{'payname'} );
4707   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4708
4709   my $conf = new FS::Conf;
4710
4711   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4712   if ( $payby eq 'CARD' &&
4713        ( (grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save'))
4714          || $conf->exists('business-onlinepayment-verification')
4715        )
4716   ) {
4717     $new->set( 'paycvv' => $opt{'paycvv'} );
4718   } else {
4719     $new->set( 'paycvv' => '');
4720   }
4721
4722   local $SIG{HUP} = 'IGNORE';
4723   local $SIG{INT} = 'IGNORE';
4724   local $SIG{QUIT} = 'IGNORE';
4725   local $SIG{TERM} = 'IGNORE';
4726   local $SIG{TSTP} = 'IGNORE';
4727   local $SIG{PIPE} = 'IGNORE';
4728
4729   my $oldAutoCommit = $FS::UID::AutoCommit;
4730   local $FS::UID::AutoCommit = 0;
4731   my $dbh = dbh;
4732
4733   # set fields specific to payment_payby
4734   if ( $payby eq 'CARD' ) {
4735     if ($opt{'bill_location'}) {
4736       $opt{'bill_location'}->set('custnum' => $self->custnum);
4737       my $error = $opt{'bill_location'}->find_or_insert;
4738       if ( $error ) {
4739         $dbh->rollback if $oldAutoCommit;
4740         return $error;
4741       }
4742       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4743     }
4744     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4745       $new->set( $field => $opt{$field} );
4746     }
4747   } else {
4748     foreach my $field ( qw(paytype paystate) ) {
4749       $new->set( $field => $opt{$field} );
4750     }
4751   }
4752
4753   # other cust_payby to compare this to
4754   my @existing = $self->cust_payby(@check_existing);
4755
4756   # fields that can overwrite blanks with values, but not values with blanks
4757   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4758
4759   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4760   unless ($old) {
4761     # generally, we don't want to overwrite existing cust_payby with this,
4762     # but we can replace if we're only marking it auto or adding a preserved field
4763     # and we can avoid saving a total duplicate or merely turning off auto
4764 PAYBYLOOP:
4765     foreach my $cust_payby (@existing) {
4766       # check fields that absolutely should not change
4767       foreach my $field ($new->fields) {
4768         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4769         next if grep(/^$field$/, @preserve );
4770         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4771       }
4772       # now check fields that can replace if one value is blank
4773       my $replace = 0;
4774       foreach my $field (@preserve) {
4775         if (
4776           ( $new->get($field) and !$cust_payby->get($field) ) or
4777           ( $cust_payby->get($field) and !$new->get($field) )
4778         ) {
4779           # prevention of overwriting values with blanks happens farther below
4780           $replace = 1;
4781         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4782           next PAYBYLOOP;
4783         }
4784       }
4785       unless ( $replace ) {
4786         # nearly identical, now check weight
4787         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4788           # ignore identical cust_payby, and ignore attempts to turn off auto
4789           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4790           $skip_cust_payby = 1;
4791           last PAYBYLOOP;
4792         }
4793         # otherwise, only change is to mark this as primary
4794       }
4795       # if we got this far, we're definitely replacing
4796       $old = $cust_payby;
4797       last PAYBYLOOP;
4798     } #PAYBYLOOP
4799   }
4800
4801   if ($old) {
4802     $new->set( 'custpaybynum' => $old->custpaybynum );
4803     # don't turn off automatic payment (but allow it to be turned on)
4804     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4805       $opt{'auto'} = 1;
4806       $new->set( 'payby' => $old->payby );
4807       $new->set( 'weight' => 1 );
4808     }
4809     # make sure we're not overwriting values with blanks
4810     foreach my $field (@preserve) {
4811       if ( $old->get($field) and !$new->get($field) ) {
4812         $new->set( $field => $old->get($field) );
4813       }
4814     }
4815   }
4816
4817   # only overwrite cust_main bill_location if auto
4818   if ($opt{'auto'} && $opt{'bill_location'}) {
4819     $self->set('bill_location' => $opt{'bill_location'});
4820     my $error = $self->replace;
4821     if ( $error ) {
4822       $dbh->rollback if $oldAutoCommit;
4823       return $error;
4824     }
4825   }
4826
4827   # done with everything except reweighting and saving cust_payby
4828   # still need to commit changes to cust_main and cust_location
4829   if ($skip_cust_payby) {
4830     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4831     return '';
4832   }
4833
4834   # re-weight existing primary cust_pay for this payby
4835   if ($opt{'auto'}) {
4836     foreach my $cust_payby (@existing) {
4837       # relies on cust_payby return order
4838       last unless $cust_payby->payby !~ /^D/;
4839       last if $cust_payby->weight > 1;
4840       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4841       next if $cust_payby->weight < ($opt{'weight'} || 1);
4842       $cust_payby->weight( $cust_payby->weight + 1 );
4843       my $error = $cust_payby->replace;
4844       if ( $error ) {
4845         $dbh->rollback if $oldAutoCommit;
4846         return "Error reweighting cust_payby: $error";
4847       }
4848     }
4849   }
4850
4851   # finally, save cust_payby
4852   my $error = $old ? $new->replace($old) : $new->insert;
4853   if ( $error ) {
4854     $dbh->rollback if $oldAutoCommit;
4855     return $error;
4856   }
4857
4858   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4859   '';
4860
4861 }
4862
4863 =item remove_cvv_from_cust_payby PAYINFO
4864
4865 Removes paycvv from associated cust_payby with matching PAYINFO.
4866
4867 =cut
4868
4869 sub remove_cvv_from_cust_payby {
4870   my ($self,$payinfo) = @_;
4871
4872   my $oldAutoCommit = $FS::UID::AutoCommit;
4873   local $FS::UID::AutoCommit = 0;
4874   my $dbh = dbh;
4875
4876   foreach my $cust_payby ( qsearch('cust_payby',{ custnum => $self->custnum }) ) {
4877     next unless $cust_payby->payinfo eq $payinfo; # can't qsearch on payinfo
4878     $cust_payby->paycvv('');
4879     my $error = $cust_payby->replace;
4880     if ($error) {
4881       $dbh->rollback if $oldAutoCommit;
4882       return $error;
4883     }
4884   }
4885
4886   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4887   '';
4888 }
4889
4890 =back
4891
4892 =head1 CLASS METHODS
4893
4894 =over 4
4895
4896 =item statuses
4897
4898 Class method that returns the list of possible status strings for customers
4899 (see L<the status method|/status>).  For example:
4900
4901   @statuses = FS::cust_main->statuses();
4902
4903 =cut
4904
4905 sub statuses {
4906   my $self = shift;
4907   keys %{ $self->statuscolors };
4908 }
4909
4910 =item cust_status_sql
4911
4912 Returns an SQL fragment to determine the status of a cust_main record, as a
4913 string.
4914
4915 =cut
4916
4917 sub cust_status_sql {
4918   my $sql = 'CASE';
4919   for my $status ( FS::cust_main->statuses() ) {
4920     my $method = $status.'_sql';
4921     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4922   }
4923   $sql .= ' END';
4924   return $sql;
4925 }
4926
4927
4928 =item prospect_sql
4929
4930 Returns an SQL expression identifying prospective cust_main records (customers
4931 with no packages ever ordered)
4932
4933 =cut
4934
4935 use vars qw($select_count_pkgs);
4936 $select_count_pkgs =
4937   "SELECT COUNT(*) FROM cust_pkg
4938     WHERE cust_pkg.custnum = cust_main.custnum";
4939
4940 sub select_count_pkgs_sql {
4941   $select_count_pkgs;
4942 }
4943
4944 sub prospect_sql {
4945   " 0 = ( $select_count_pkgs ) ";
4946 }
4947
4948 =item ordered_sql
4949
4950 Returns an SQL expression identifying ordered cust_main records (customers with
4951 no active packages, but recurring packages not yet setup or one time charges
4952 not yet billed).
4953
4954 =cut
4955
4956 sub ordered_sql {
4957   FS::cust_main->none_active_sql.
4958   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4959 }
4960
4961 =item active_sql
4962
4963 Returns an SQL expression identifying active cust_main records (customers with
4964 active recurring packages).
4965
4966 =cut
4967
4968 sub active_sql {
4969   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4970 }
4971
4972 =item none_active_sql
4973
4974 Returns an SQL expression identifying cust_main records with no active
4975 recurring packages.  This includes customers of status prospect, ordered,
4976 inactive, and suspended.
4977
4978 =cut
4979
4980 sub none_active_sql {
4981   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4982 }
4983
4984 =item inactive_sql
4985
4986 Returns an SQL expression identifying inactive cust_main records (customers with
4987 no active recurring packages, but otherwise unsuspended/uncancelled).
4988
4989 =cut
4990
4991 sub inactive_sql {
4992   FS::cust_main->none_active_sql.
4993   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4994 }
4995
4996 =item susp_sql
4997 =item suspended_sql
4998
4999 Returns an SQL expression identifying suspended cust_main records.
5000
5001 =cut
5002
5003
5004 sub suspended_sql { susp_sql(@_); }
5005 sub susp_sql {
5006   FS::cust_main->none_active_sql.
5007   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
5008 }
5009
5010 =item cancel_sql
5011 =item cancelled_sql
5012
5013 Returns an SQL expression identifying cancelled cust_main records.
5014
5015 =cut
5016
5017 sub cancel_sql { shift->cancelled_sql(@_); }
5018
5019 =item uncancel_sql
5020 =item uncancelled_sql
5021
5022 Returns an SQL expression identifying un-cancelled cust_main records.
5023
5024 =cut
5025
5026 sub uncancelled_sql { uncancel_sql(@_); }
5027 sub uncancel_sql {
5028   my $self = shift;
5029   "( NOT (".$self->cancelled_sql.") )"; #sensitive to cust_main-status_module
5030 }
5031
5032 =item balance_sql
5033
5034 Returns an SQL fragment to retreive the balance.
5035
5036 =cut
5037
5038 sub balance_sql { "
5039     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
5040         WHERE cust_bill.custnum   = cust_main.custnum     )
5041   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
5042         WHERE cust_pay.custnum    = cust_main.custnum     )
5043   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
5044         WHERE cust_credit.custnum = cust_main.custnum     )
5045   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
5046         WHERE cust_refund.custnum = cust_main.custnum     )
5047 "; }
5048
5049 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
5050
5051 Returns an SQL fragment to retreive the balance for this customer, optionally
5052 considering invoices with date earlier than START_TIME, and not
5053 later than END_TIME (total_owed_date minus total_unapplied_credits minus
5054 total_unapplied_payments).
5055
5056 Times are specified as SQL fragments or numeric
5057 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5058 L<Date::Parse> for conversion functions.  The empty string can be passed
5059 to disable that time constraint completely.
5060
5061 Available options are:
5062
5063 =over 4
5064
5065 =item unapplied_date
5066
5067 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
5068
5069 =item total
5070
5071 (unused.  obsolete?)
5072 set to true to remove all customer comparison clauses, for totals
5073
5074 =item where
5075
5076 (unused.  obsolete?)
5077 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
5078
5079 =item join
5080
5081 (unused.  obsolete?)
5082 JOIN clause (typically used with the total option)
5083
5084 =item cutoff
5085
5086 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
5087 time will be ignored.  Note that START_TIME and END_TIME only limit the date
5088 range for invoices and I<unapplied> payments, credits, and refunds.
5089
5090 =back
5091
5092 =cut
5093
5094 sub balance_date_sql {
5095   my( $class, $start, $end, %opt ) = @_;
5096
5097   my $cutoff = $opt{'cutoff'};
5098
5099   my $owed         = FS::cust_bill->owed_sql($cutoff);
5100   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
5101   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
5102   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5103
5104   my $j = $opt{'join'} || '';
5105
5106   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
5107   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
5108   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
5109   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
5110
5111   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
5112     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
5113     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
5114     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
5115   ";
5116
5117 }
5118
5119 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
5120
5121 Returns an SQL fragment to retreive the total unapplied payments for this
5122 customer, only considering payments with date earlier than START_TIME, and
5123 optionally not later than END_TIME.
5124
5125 Times are specified as SQL fragments or numeric
5126 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5127 L<Date::Parse> for conversion functions.  The empty string can be passed
5128 to disable that time constraint completely.
5129
5130 Available options are:
5131
5132 =cut
5133
5134 sub unapplied_payments_date_sql {
5135   my( $class, $start, $end, %opt ) = @_;
5136
5137   my $cutoff = $opt{'cutoff'};
5138
5139   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5140
5141   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
5142                                                           'unapplied_date'=>1 );
5143
5144   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
5145 }
5146
5147 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
5148
5149 Helper method for balance_date_sql; name (and usage) subject to change
5150 (suggestions welcome).
5151
5152 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
5153 cust_refund, cust_credit or cust_pay).
5154
5155 If TABLE is "cust_bill" or the unapplied_date option is true, only
5156 considers records with date earlier than START_TIME, and optionally not
5157 later than END_TIME .
5158
5159 =cut
5160
5161 sub _money_table_where {
5162   my( $class, $table, $start, $end, %opt ) = @_;
5163
5164   my @where = ();
5165   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
5166   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
5167     push @where, "$table._date <= $start" if defined($start) && length($start);
5168     push @where, "$table._date >  $end"   if defined($end)   && length($end);
5169   }
5170   push @where, @{$opt{'where'}} if $opt{'where'};
5171   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
5172
5173   $where;
5174
5175 }
5176
5177 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
5178 use FS::cust_main::Search;
5179 sub search {
5180   my $class = shift;
5181   FS::cust_main::Search->search(@_);
5182 }
5183
5184 =back
5185
5186 =head1 SUBROUTINES
5187
5188 =over 4
5189
5190 #=item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5191
5192 #Deprecated.  Use event notification and message templates
5193 #(L<FS::msg_template>) instead.
5194
5195 #Sends a templated email notification to the customer (see L<Text::Template>).
5196
5197 #OPTIONS is a hash and may include
5198
5199 #I<from> - the email sender (default is invoice_from)
5200
5201 #I<to> - comma-separated scalar or arrayref of recipients
5202 #   (default is invoicing_list)
5203
5204 #I<subject> - The subject line of the sent email notification
5205 #   (default is "Notice from company_name")
5206
5207 #I<extra_fields> - a hashref of name/value pairs which will be substituted
5208 #   into the template
5209
5210 #The following variables are vavailable in the template.
5211
5212 #I<$first> - the customer first name
5213 #I<$last> - the customer last name
5214 #I<$company> - the customer company
5215 #I<$payby> - a description of the method of payment for the customer
5216 #            # would be nice to use FS::payby::shortname
5217 #I<$payinfo> - the account information used to collect for this customer
5218 #I<$expdate> - the expiration of the customer payment in seconds from epoch
5219
5220 #=cut
5221
5222 #sub notify {
5223 #  my ($self, $template, %options) = @_;
5224
5225 #  return unless $conf->exists($template);
5226
5227 #  my $from = $conf->invoice_from_full($self->agentnum)
5228 #    if $conf->exists('invoice_from', $self->agentnum);
5229 #  $from = $options{from} if exists($options{from});
5230
5231 #  my $to = join(',', $self->invoicing_list_emailonly);
5232 #  $to = $options{to} if exists($options{to});
5233 #
5234 #  my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
5235 #    if $conf->exists('company_name', $self->agentnum);
5236 #  $subject = $options{subject} if exists($options{subject});
5237
5238 #  my $notify_template = new Text::Template (TYPE => 'ARRAY',
5239 #                                            SOURCE => [ map "$_\n",
5240 #                                              $conf->config($template)]
5241 #                                           )
5242 #    or die "can't create new Text::Template object: Text::Template::ERROR";
5243 #  $notify_template->compile()
5244 #    or die "can't compile template: Text::Template::ERROR";
5245
5246 #  $FS::notify_template::_template::company_name =
5247 #    $conf->config('company_name', $self->agentnum);
5248 #  $FS::notify_template::_template::company_address =
5249 #    join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
5250
5251 #  my $paydate = $self->paydate || '2037-12-31';
5252 #  $FS::notify_template::_template::first = $self->first;
5253 #  $FS::notify_template::_template::last = $self->last;
5254 #  $FS::notify_template::_template::company = $self->company;
5255 #  $FS::notify_template::_template::payinfo = $self->mask_payinfo;
5256 #  my $payby = $self->payby;
5257 #  my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5258 #  my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5259
5260 #  #credit cards expire at the end of the month/year of their exp date
5261 #  if ($payby eq 'CARD' || $payby eq 'DCRD') {
5262 #    $FS::notify_template::_template::payby = 'credit card';
5263 #    ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5264 #    $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5265 #    $expire_time--;
5266 #  }elsif ($payby eq 'COMP') {
5267 #    $FS::notify_template::_template::payby = 'complimentary account';
5268 #  }else{
5269 #    $FS::notify_template::_template::payby = 'current method';
5270 #  }
5271 #  $FS::notify_template::_template::expdate = $expire_time;
5272
5273 #  for (keys %{$options{extra_fields}}){
5274 #    no strict "refs";
5275 #    ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
5276 #  }
5277
5278 #  send_email(from => $from,
5279 #             to => $to,
5280 #             subject => $subject,
5281 #             body => $notify_template->fill_in( PACKAGE =>
5282 #                                                'FS::notify_template::_template'                                              ),
5283 #            );
5284
5285 #}
5286
5287 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5288
5289 Generates a templated notification to the customer (see L<Text::Template>).
5290
5291 OPTIONS is a hash and may include
5292
5293 I<extra_fields> - a hashref of name/value pairs which will be substituted
5294    into the template.  These values may override values mentioned below
5295    and those from the customer record.
5296
5297 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
5298
5299 The following variables are available in the template instead of or in addition
5300 to the fields of the customer record.
5301
5302 I<$payby> - a description of the method of payment for the customer
5303             # would be nice to use FS::payby::shortname
5304 I<$payinfo> - the masked account information used to collect for this customer
5305 I<$expdate> - the expiration of the customer payment method in seconds from epoch
5306 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
5307
5308 =cut
5309
5310 # a lot like cust_bill::print_latex
5311 sub generate_letter {
5312   my ($self, $template, %options) = @_;
5313
5314   warn "Template $template does not exist" && return
5315     unless $conf->exists($template) || $options{'template_text'};
5316
5317   my $template_source = $options{'template_text'}
5318                         ? [ $options{'template_text'} ]
5319                         : [ map "$_\n", $conf->config($template) ];
5320
5321   my $letter_template = new Text::Template
5322                         ( TYPE       => 'ARRAY',
5323                           SOURCE     => $template_source,
5324                           DELIMITERS => [ '[@--', '--@]' ],
5325                         )
5326     or die "can't create new Text::Template object: Text::Template::ERROR";
5327
5328   $letter_template->compile()
5329     or die "can't compile template: Text::Template::ERROR";
5330
5331   my %letter_data = map { $_ => $self->$_ } $self->fields;
5332   $letter_data{payinfo} = $self->mask_payinfo;
5333
5334   #my $paydate = $self->paydate || '2037-12-31';
5335   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
5336
5337   my $payby = $self->payby;
5338   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5339   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5340
5341   #credit cards expire at the end of the month/year of their exp date
5342   if ($payby eq 'CARD' || $payby eq 'DCRD') {
5343     $letter_data{payby} = 'credit card';
5344     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5345     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5346     $expire_time--;
5347   }elsif ($payby eq 'COMP') {
5348     $letter_data{payby} = 'complimentary account';
5349   }else{
5350     $letter_data{payby} = 'current method';
5351   }
5352   $letter_data{expdate} = $expire_time;
5353
5354   for (keys %{$options{extra_fields}}){
5355     $letter_data{$_} = $options{extra_fields}->{$_};
5356   }
5357
5358   unless(exists($letter_data{returnaddress})){
5359     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
5360                                                   $self->agent_template)
5361                      );
5362     if ( length($retadd) ) {
5363       $letter_data{returnaddress} = $retadd;
5364     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
5365       $letter_data{returnaddress} =
5366         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
5367                           s/$/\\\\\*/;
5368                           $_;
5369                         }
5370                     ( $conf->config('company_name', $self->agentnum),
5371                       $conf->config('company_address', $self->agentnum),
5372                     )
5373         );
5374     } else {
5375       $letter_data{returnaddress} = '~';
5376     }
5377   }
5378
5379   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
5380
5381   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
5382
5383   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
5384
5385   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5386                            DIR      => $dir,
5387                            SUFFIX   => '.eps',
5388                            UNLINK   => 0,
5389                          ) or die "can't open temp file: $!\n";
5390   print $lh $conf->config_binary('logo.eps', $self->agentnum)
5391     or die "can't write temp file: $!\n";
5392   close $lh;
5393   $letter_data{'logo_file'} = $lh->filename;
5394
5395   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5396                            DIR      => $dir,
5397                            SUFFIX   => '.tex',
5398                            UNLINK   => 0,
5399                          ) or die "can't open temp file: $!\n";
5400
5401   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
5402   close $fh;
5403   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
5404   return ($1, $letter_data{'logo_file'});
5405
5406 }
5407
5408 =item print_ps TEMPLATE
5409
5410 Returns an postscript letter filled in from TEMPLATE, as a scalar.
5411
5412 =cut
5413
5414 sub print_ps {
5415   my $self = shift;
5416   my($file, $lfile) = $self->generate_letter(@_);
5417   my $ps = FS::Misc::generate_ps($file);
5418   unlink($file.'.tex');
5419   unlink($lfile);
5420
5421   $ps;
5422 }
5423
5424 =item print TEMPLATE
5425
5426 Prints the filled in template.
5427
5428 TEMPLATE is the name of a L<Text::Template> to fill in and print.
5429
5430 =cut
5431
5432 sub queueable_print {
5433   my %opt = @_;
5434
5435   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
5436     or die "invalid customer number: " . $opt{custnum};
5437
5438 #do not backport this change to 3.x
5439 #  my $error = $self->print( { 'template' => $opt{template} } );
5440   my $error = $self->print( $opt{'template'} );
5441   die $error if $error;
5442 }
5443
5444 sub print {
5445   my ($self, $template) = (shift, shift);
5446   do_print(
5447     [ $self->print_ps($template) ],
5448     'agentnum' => $self->agentnum,
5449   );
5450 }
5451
5452 #these three subs should just go away once agent stuff is all config overrides
5453
5454 sub agent_template {
5455   my $self = shift;
5456   $self->_agent_plandata('agent_templatename');
5457 }
5458
5459 sub agent_invoice_from {
5460   my $self = shift;
5461   $self->_agent_plandata('agent_invoice_from');
5462 }
5463
5464 sub _agent_plandata {
5465   my( $self, $option ) = @_;
5466
5467   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
5468   #agent-specific Conf
5469
5470   use FS::part_event::Condition;
5471
5472   my $agentnum = $self->agentnum;
5473
5474   my $regexp = regexp_sql();
5475
5476   my $part_event_option =
5477     qsearchs({
5478       'select'    => 'part_event_option.*',
5479       'table'     => 'part_event_option',
5480       'addl_from' => q{
5481         LEFT JOIN part_event USING ( eventpart )
5482         LEFT JOIN part_event_option AS peo_agentnum
5483           ON ( part_event.eventpart = peo_agentnum.eventpart
5484                AND peo_agentnum.optionname = 'agentnum'
5485                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
5486              )
5487         LEFT JOIN part_event_condition
5488           ON ( part_event.eventpart = part_event_condition.eventpart
5489                AND part_event_condition.conditionname = 'cust_bill_age'
5490              )
5491         LEFT JOIN part_event_condition_option
5492           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
5493                AND part_event_condition_option.optionname = 'age'
5494              )
5495       },
5496       #'hashref'   => { 'optionname' => $option },
5497       #'hashref'   => { 'part_event_option.optionname' => $option },
5498       'extra_sql' =>
5499         " WHERE part_event_option.optionname = ". dbh->quote($option).
5500         " AND action = 'cust_bill_send_agent' ".
5501         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
5502         " AND peo_agentnum.optionname = 'agentnum' ".
5503         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
5504         " ORDER BY
5505            CASE WHEN part_event_condition_option.optionname IS NULL
5506            THEN -1
5507            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5508         " END
5509           , part_event.weight".
5510         " LIMIT 1"
5511     });
5512
5513   unless ( $part_event_option ) {
5514     return $self->agent->invoice_template || ''
5515       if $option eq 'agent_templatename';
5516     return '';
5517   }
5518
5519   $part_event_option->optionvalue;
5520
5521 }
5522
5523 sub process_o2m_qsearch {
5524   my $self = shift;
5525   my $table = shift;
5526   return qsearch($table, @_) unless $table eq 'contact';
5527
5528   my $hashref = shift;
5529   my %hash = %$hashref;
5530   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5531     or die 'guru meditation #4343';
5532
5533   qsearch({ 'table'     => 'contact',
5534             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5535             'hashref'   => \%hash,
5536             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5537                            " cust_contact.custnum = $custnum "
5538          });
5539 }
5540
5541 sub process_o2m_qsearchs {
5542   my $self = shift;
5543   my $table = shift;
5544   return qsearchs($table, @_) unless $table eq 'contact';
5545
5546   my $hashref = shift;
5547   my %hash = %$hashref;
5548   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5549     or die 'guru meditation #2121';
5550
5551   qsearchs({ 'table'     => 'contact',
5552              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5553              'hashref'   => \%hash,
5554              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5555                             " cust_contact.custnum = $custnum "
5556           });
5557 }
5558
5559 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5560
5561 Subroutine (not a method), designed to be called from the queue.
5562
5563 Takes a list of options and values.
5564
5565 Pulls up the customer record via the custnum option and calls bill_and_collect.
5566
5567 =cut
5568
5569 sub queued_bill {
5570   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5571
5572   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5573   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5574
5575   #without this errors don't get rolled back
5576   $args{'fatal'} = 1; # runs from job queue, will be caught
5577
5578   $cust_main->bill_and_collect( %args );
5579 }
5580
5581 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5582
5583 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5584 C<collect> part.  This is used in batch tax calculation, where invoice
5585 generation and collection events have to be completely separated.
5586
5587 =cut
5588
5589 sub queued_collect {
5590   my (%args) = @_;
5591   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5592
5593   $cust_main->collect(%args);
5594 }
5595
5596 sub process_bill_and_collect {
5597   my $job = shift;
5598   my $param = shift;
5599   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5600       or die "custnum '$param->{custnum}' not found!\n";
5601   $param->{'job'}   = $job;
5602   $param->{'fatal'} = 1; # runs from job queue, will be caught
5603   $param->{'retry'} = 1;
5604
5605   $cust_main->bill_and_collect( %$param );
5606 }
5607
5608 #starting to take quite a while for big dbs
5609 #   (JRNL: journaled so it only happens once per database)
5610 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5611 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5612 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5613 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5614 # JRNL leading/trailing spaces in first, last, company
5615 # JRNL migrate to cust_payby
5616 # - otaker upgrade?  journal and call it good?  (double check to make sure
5617 #    we're not still setting otaker here)
5618 #
5619 #only going to get worse with new location stuff...
5620
5621 sub _upgrade_data { #class method
5622   my ($class, %opts) = @_;
5623
5624   my @statements = (
5625     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5626   );
5627
5628   #this seems to be the only expensive one.. why does it take so long?
5629   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5630     push @statements,
5631       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5632     FS::upgrade_journal->set_done('cust_main__signupdate');
5633   }
5634
5635   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5636
5637     # fix yyyy-m-dd formatted paydates
5638     if ( driver_name =~ /^mysql/i ) {
5639       push @statements,
5640       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5641     } else { # the SQL standard
5642       push @statements,
5643       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5644     }
5645     FS::upgrade_journal->set_done('cust_main__paydate');
5646   }
5647
5648   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5649
5650     push @statements, #fix the weird BILL with a cc# in payinfo problem
5651       #DCRD to be safe
5652       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5653
5654     FS::upgrade_journal->set_done('cust_main__payinfo');
5655
5656   }
5657
5658   my $t = time;
5659   foreach my $sql ( @statements ) {
5660     my $sth = dbh->prepare($sql) or die dbh->errstr;
5661     $sth->execute or die $sth->errstr;
5662     #warn ( (time - $t). " seconds\n" );
5663     #$t = time;
5664   }
5665
5666   local($ignore_expired_card) = 1;
5667   local($ignore_banned_card) = 1;
5668   local($skip_fuzzyfiles) = 1;
5669   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5670
5671   unless ( FS::upgrade_journal->is_done('cust_main__cust_payby') ) {
5672
5673     #we don't want to decrypt them, just stuff them as-is into cust_payby
5674     local(@encrypted_fields) = ();
5675
5676     local($FS::cust_payby::ignore_expired_card) = 1;
5677     local($FS::cust_payby::ignore_banned_card)  = 1;
5678     local($FS::cust_payby::ignore_cardtype)     = 1;
5679
5680     my @payfields = qw( payby payinfo paycvv paymask
5681                         paydate paystart_month paystart_year payissue
5682                         payname paystate paytype payip
5683                       );
5684
5685     my $search = new FS::Cursor {
5686       'table'     => 'cust_main',
5687       'extra_sql' => " WHERE ( payby IS NOT NULL AND payby != '' ) ",
5688     };
5689
5690     while (my $cust_main = $search->fetch) {
5691
5692       unless ( $cust_main->payby =~ /^(BILL|COMP)$/ ) {
5693
5694         my $cust_payby = new FS::cust_payby {
5695           'custnum' => $cust_main->custnum,
5696           'weight'  => 1,
5697           map { $_ => $cust_main->$_(); } @payfields
5698         };
5699
5700         my $error = $cust_payby->insert;
5701         die $error if $error;
5702
5703       }
5704
5705       # at the time we do this, also migrate paytype into cust_pay_batch
5706       # so that batches that are open before the migration can still be
5707       # processed
5708       my @cust_pay_batch = qsearch('cust_pay_batch', {
5709           'custnum' => $cust_main->custnum,
5710           'payby'   => 'CHEK',
5711           'paytype' => '',
5712       });
5713       foreach my $cust_pay_batch (@cust_pay_batch) {
5714         $cust_pay_batch->set('paytype', $cust_main->get('paytype'));
5715         my $error = $cust_pay_batch->replace;
5716         die "$error (setting cust_pay_batch.paytype)" if $error;
5717       }
5718
5719       $cust_main->complimentary('Y') if $cust_main->payby eq 'COMP';
5720
5721       $cust_main->invoice_attn( $cust_main->payname )
5722         if $cust_main->payby eq 'BILL' && $cust_main->payname;
5723       $cust_main->po_number( $cust_main->payinfo )
5724         if $cust_main->payby eq 'BILL' && $cust_main->payinfo;
5725
5726       $cust_main->setfield($_, '') foreach @payfields;
5727       my $error = $cust_main->replace;
5728       die "Error upgradging payment information for custnum ".
5729           $cust_main->custnum. ": $error"
5730         if $error;
5731
5732     };
5733
5734     FS::upgrade_journal->set_done('cust_main__cust_payby');
5735   }
5736
5737   FS::cust_main::Location->_upgrade_data(%opts);
5738
5739   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5740
5741     foreach my $cust_main ( qsearch({
5742       'table'     => 'cust_main',
5743       'hashref'   => {},
5744       'extra_sql' => 'WHERE '.
5745                        join(' OR ',
5746                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5747                            qw( first last company )
5748                        ),
5749     }) ) {
5750       my $error = $cust_main->replace;
5751       die $error if $error;
5752     }
5753
5754     FS::upgrade_journal->set_done('cust_main__trimspaces');
5755
5756   }
5757
5758   $class->_upgrade_otaker(%opts);
5759
5760 }
5761
5762 =back
5763
5764 =head1 BUGS
5765
5766 The delete method.
5767
5768 The delete method should possibly take an FS::cust_main object reference
5769 instead of a scalar customer number.
5770
5771 Bill and collect options should probably be passed as references instead of a
5772 list.
5773
5774 There should probably be a configuration file with a list of allowed credit
5775 card types.
5776
5777 No multiple currency support (probably a larger project than just this module).
5778
5779 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5780
5781 Birthdates rely on negative epoch values.
5782
5783 The payby for card/check batches is broken.  With mixed batching, bad
5784 things will happen.
5785
5786 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5787
5788 =head1 SEE ALSO
5789
5790 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5791 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5792 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5793
5794 =cut
5795
5796 1;
5797