FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Data::Dumper;
  26 use Tie::IxHash;
  27 use Date::Format;
  28 #use Date::Manip;
  29 use File::Temp; #qw( tempfile );
  30 use Business::CreditCard 0.28;
  31 use List::Util qw(min);
  32 use FS::UID qw( dbh driver_name );
  33 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  34 use FS::Cursor;
  35 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  36 use FS::Msgcat qw(gettext);
  37 use FS::CurrentUser;
  38 use FS::TicketSystem;
  39 use FS::payby;
  40 use FS::cust_pkg;
  41 use FS::cust_svc;
  42 use FS::cust_bill;
  43 use FS::cust_bill_void;
  44 use FS::legacy_cust_bill;
  45 use FS::cust_pay;
  46 use FS::cust_pay_pending;
  47 use FS::cust_pay_void;
  48 use FS::cust_pay_batch;
  49 use FS::cust_credit;
  50 use FS::cust_refund;
  51 use FS::part_referral;
  52 use FS::cust_main_county;
  53 use FS::cust_location;
  54 use FS::cust_class;
  55 use FS::tax_status;
  56 use FS::cust_main_exemption;
  57 use FS::cust_tax_adjustment;
  58 use FS::cust_tax_location;
  59 use FS::agent_currency;
  60 use FS::cust_main_invoice;
  61 use FS::cust_tag;
  62 use FS::prepay_credit;
  63 use FS::queue;
  64 use FS::part_pkg;
  65 use FS::part_export;
  66 #use FS::cust_event;
  67 use FS::type_pkgs;
  68 use FS::payment_gateway;
  69 use FS::agent_payment_gateway;
  70 use FS::banned_pay;
  71 use FS::cust_main_note;
  72 use FS::cust_attachment;
  73 use FS::cust_contact;
  74 use FS::Locales;
  75 use FS::upgrade_journal;
  76 use FS::sales;
  77 use FS::cust_payby;
  78 use FS::contact;
  79
  80 # 1 is mostly method/subroutine entry and options
  81 # 2 traces progress of some operations
  82 # 3 is even more information including possibly sensitive data
  83 our $DEBUG = 0;
  84 our $me = '[FS::cust_main]';
  85
  86 our $import = 0;
  87 our $ignore_expired_card = 0;
  88 our $ignore_banned_card = 0;
  89 our $ignore_invalid_card = 0;
  90
  91 our $skip_fuzzyfiles = 0;
  92
  93 our $ucfirst_nowarn = 0;
  94
  95 #this info is in cust_payby as of 4.x
  96 #this and the fields themselves can be removed in 5.x
  97 our @encrypted_fields = ('payinfo', 'paycvv');
  98 sub nohistory_fields { ('payinfo', 'paycvv'); }
  99
 100 our $conf;
 101 our $default_agent_custid;
 102 our $custnum_display_length;
 103 #ask FS::UID to run this stuff for us later
 104 #$FS::UID::callback{'FS::cust_main'} = sub {
 105 install_callback FS::UID sub {
 106   $conf = new FS::Conf;
 107   #yes, need it for stuff below (prolly should be cached)
 108   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 109   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 110   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 111 };
 112
 113 sub _cache {
 114   my $self = shift;
 115   my ( $hashref, $cache ) = @_;
 116   if ( exists $hashref->{'pkgnum'} ) {
 117     #@{ $self->{'_pkgnum'} } = ();
 118     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 119     $self->{'_pkgnum'} = $subcache;
 120     #push @{ $self->{'_pkgnum'} },
 121     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 122   }
 123 }
 124
 125 =head1 NAME
 126
 127 FS::cust_main - Object methods for cust_main records
 128
 129 =head1 SYNOPSIS
 130
 131   use FS::cust_main;
 132
 133   $record = new FS::cust_main \%hash;
 134   $record = new FS::cust_main { 'column' => 'value' };
 135
 136   $error = $record->insert;
 137
 138   $error = $new_record->replace($old_record);
 139
 140   $error = $record->delete;
 141
 142   $error = $record->check;
 143
 144   @cust_pkg = $record->all_pkgs;
 145
 146   @cust_pkg = $record->ncancelled_pkgs;
 147
 148   @cust_pkg = $record->suspended_pkgs;
 149
 150   $error = $record->bill;
 151   $error = $record->bill %options;
 152   $error = $record->bill 'time' => $time;
 153
 154   $error = $record->collect;
 155   $error = $record->collect %options;
 156   $error = $record->collect 'invoice_time'   => $time,
 157                           ;
 158
 159 =head1 DESCRIPTION
 160
 161 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 162 FS::Record.  The following fields are currently supported:
 163
 164 =over 4
 165
 166 =item custnum
 167
 168 Primary key (assigned automatically for new customers)
 169
 170 =item agentnum
 171
 172 Agent (see L<FS::agent>)
 173
 174 =item refnum
 175
 176 Advertising source (see L<FS::part_referral>)
 177
 178 =item first
 179
 180 First name
 181
 182 =item last
 183
 184 Last name
 185
 186 =item ss
 187
 188 Cocial security number (optional)
 189
 190 =item company
 191
 192 (optional)
 193
 194 =item daytime
 195
 196 phone (optional)
 197
 198 =item night
 199
 200 phone (optional)
 201
 202 =item fax
 203
 204 phone (optional)
 205
 206 =item mobile
 207
 208 phone (optional)
 209
 210 =item payby
 211
 212 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 213
 214 =item payinfo
 215
 216 Payment Information (See L<FS::payinfo_Mixin> for data format)
 217
 218 =item paymask
 219
 220 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 221
 222 =item paycvv
 223
 224 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 225
 226 =item paydate
 227
 228 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 229
 230 =item paystart_month
 231
 232 Start date month (maestro/solo cards only)
 233
 234 =item paystart_year
 235
 236 Start date year (maestro/solo cards only)
 237
 238 =item payissue
 239
 240 Issue number (maestro/solo cards only)
 241
 242 =item payname
 243
 244 Name on card or billing name
 245
 246 =item payip
 247
 248 IP address from which payment information was received
 249
 250 =item tax
 251
 252 Tax exempt, empty or `Y'
 253
 254 =item usernum
 255
 256 Order taker (see L<FS::access_user>)
 257
 258 =item comments
 259
 260 Comments (optional)
 261
 262 =item referral_custnum
 263
 264 Referring customer number
 265
 266 =item spool_cdr
 267
 268 Enable individual CDR spooling, empty or `Y'
 269
 270 =item dundate
 271
 272 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 273
 274 =item squelch_cdr
 275
 276 Discourage individual CDR printing, empty or `Y'
 277
 278 =item edit_subject
 279
 280 Allow self-service editing of ticket subjects, empty or 'Y'
 281
 282 =item calling_list_exempt
 283
 284 Do not call, empty or 'Y'
 285
 286 =item invoice_ship_address
 287
 288 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 289
 290 =back
 291
 292 =head1 METHODS
 293
 294 =over 4
 295
 296 =item new HASHREF
 297
 298 Creates a new customer.  To add the customer to the database, see L<"insert">.
 299
 300 Note that this stores the hash reference, not a distinct copy of the hash it
 301 points to.  You can ask the object for a copy with the I<hash> method.
 302
 303 =cut
 304
 305 sub table { 'cust_main'; }
 306
 307 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 308
 309 Adds this customer to the database.  If there is an error, returns the error,
 310 otherwise returns false.
 311
 312 Usually the customer's location will not yet exist in the database, and
 313 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 314 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 315 (in both directions) to the new customer record.  If they're references
 316 to the same object, they will become the same location.
 317
 318 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 319 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 320 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 321 hash reference is equivalent to not supplying this parameter.  There should be
 322 a better explanation of this, but until then, here's an example:
 323
 324   use Tie::RefHash;
 325   tie %hash, 'Tie::RefHash'; #this part is important
 326   %hash = (
 327     $cust_pkg => [ $svc_acct ],
 328     ...
 329   );
 330   $cust_main->insert( \%hash );
 331
 332 INVOICING_LIST_ARYREF: No longer supported.
 333
 334 Currently available options are: I<depend_jobnum>, I<noexport>,
 335 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 336
 337 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 338 on the supplied jobnum (they will not run until the specific job completes).
 339 This can be used to defer provisioning until some action completes (such
 340 as running the customer's credit card successfully).
 341
 342 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 343 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 344 the B<reexport> method.)
 345
 346 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 347 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 348 created and inserted.
 349
 350 If I<prospectnum> is set, moves contacts and locations from that prospect.
 351
 352 If I<contact> is set to an arrayref of FS::contact objects, those will be
 353 inserted.
 354
 355 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 356 unset), inserts those new contacts with this new customer.  Handles CGI
 357 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 358
 359 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 360 new stored payment records with this new customer.  Handles CGI parameters
 361 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 362
 363 =cut
 364
 365 sub insert {
 366   my $self = shift;
 367   my $cust_pkgs = @_ ? shift : {};
 368   my $invoicing_list;
 369   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 370     warn "cust_main::insert using deprecated invoicing list argument";
 371     $invoicing_list = shift;
 372   }
 373   my %options = @_;
 374   warn "$me insert called with options ".
 375        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 376     if $DEBUG;
 377
 378   local $SIG{HUP} = 'IGNORE';
 379   local $SIG{INT} = 'IGNORE';
 380   local $SIG{QUIT} = 'IGNORE';
 381   local $SIG{TERM} = 'IGNORE';
 382   local $SIG{TSTP} = 'IGNORE';
 383   local $SIG{PIPE} = 'IGNORE';
 384
 385   my $oldAutoCommit = $FS::UID::AutoCommit;
 386   local $FS::UID::AutoCommit = 0;
 387   my $dbh = dbh;
 388
 389   my $prepay_identifier = '';
 390   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 391   my $payby = '';
 392   if ( $self->payby eq 'PREPAY' ) {
 393
 394     $self->payby(''); #'BILL');
 395     $prepay_identifier = $self->payinfo;
 396     $self->payinfo('');
 397
 398     warn "  looking up prepaid card $prepay_identifier\n"
 399       if $DEBUG > 1;
 400
 401     my $error = $self->get_prepay( $prepay_identifier,
 402                                    'amount_ref'     => \$amount,
 403                                    'seconds_ref'    => \$seconds,
 404                                    'upbytes_ref'    => \$upbytes,
 405                                    'downbytes_ref'  => \$downbytes,
 406                                    'totalbytes_ref' => \$totalbytes,
 407                                  );
 408     if ( $error ) {
 409       $dbh->rollback if $oldAutoCommit;
 410       #return "error applying prepaid card (transaction rolled back): $error";
 411       return $error;
 412     }
 413
 414     $payby = 'PREP' if $amount;
 415
 416   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 417
 418     $payby = $1;
 419     $self->payby(''); #'BILL');
 420     $amount = $self->paid;
 421
 422   }
 423
 424   # insert locations
 425   foreach my $l (qw(bill_location ship_location)) {
 426
 427     my $loc = delete $self->hashref->{$l} or next;
 428
 429     if ( !$loc->locationnum ) {
 430       # warn the location that we're going to insert it with no custnum
 431       $loc->set(custnum_pending => 1);
 432       warn "  inserting $l\n"
 433         if $DEBUG > 1;
 434       my $error = $loc->insert;
 435       if ( $error ) {
 436         $dbh->rollback if $oldAutoCommit;
 437         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 438         return "$error (in $label location)";
 439       }
 440
 441     } elsif ( $loc->prospectnum ) {
 442
 443       $loc->prospectnum('');
 444       $loc->set(custnum_pending => 1);
 445       my $error = $loc->replace;
 446       if ( $error ) {
 447         $dbh->rollback if $oldAutoCommit;
 448         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 449         return "$error (moving $label location)";
 450       }
 451
 452     } elsif ( ($loc->custnum || 0) > 0 ) {
 453       # then it somehow belongs to another customer--shouldn't happen
 454       $dbh->rollback if $oldAutoCommit;
 455       return "$l belongs to customer ".$loc->custnum;
 456     }
 457     # else it already belongs to this customer
 458     # (happens when ship_location is identical to bill_location)
 459
 460     $self->set($l.'num', $loc->locationnum);
 461
 462     if ( $self->get($l.'num') eq '' ) {
 463       $dbh->rollback if $oldAutoCommit;
 464       return "$l not set";
 465     }
 466   }
 467
 468   warn "  inserting $self\n"
 469     if $DEBUG > 1;
 470
 471   $self->signupdate(time) unless $self->signupdate;
 472
 473   $self->auto_agent_custid()
 474     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 475
 476   my $error =  $self->check_payinfo_cardtype
 477             || $self->SUPER::insert;
 478   if ( $error ) {
 479     $dbh->rollback if $oldAutoCommit;
 480     #return "inserting cust_main record (transaction rolled back): $error";
 481     return $error;
 482   }
 483
 484   # now set cust_location.custnum
 485   foreach my $l (qw(bill_location ship_location)) {
 486     warn "  setting $l.custnum\n"
 487       if $DEBUG > 1;
 488     my $loc = $self->$l or next;
 489     unless ( $loc->custnum ) {
 490       $loc->set(custnum => $self->custnum);
 491       $error ||= $loc->replace;
 492     }
 493
 494     if ( $error ) {
 495       $dbh->rollback if $oldAutoCommit;
 496       return "error setting $l custnum: $error";
 497     }
 498   }
 499
 500   warn "  setting customer tags\n"
 501     if $DEBUG > 1;
 502
 503   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 504     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 505                                       'custnum' => $self->custnum };
 506     my $error = $cust_tag->insert;
 507     if ( $error ) {
 508       $dbh->rollback if $oldAutoCommit;
 509       return $error;
 510     }
 511   }
 512
 513   my $prospectnum = delete $options{'prospectnum'};
 514   if ( $prospectnum ) {
 515
 516     warn "  moving contacts and locations from prospect $prospectnum\n"
 517       if $DEBUG > 1;
 518
 519     my $prospect_main =
 520       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 521     unless ( $prospect_main ) {
 522       $dbh->rollback if $oldAutoCommit;
 523       return "Unknown prospectnum $prospectnum";
 524     }
 525     $prospect_main->custnum($self->custnum);
 526     $prospect_main->disabled('Y');
 527     my $error = $prospect_main->replace;
 528     if ( $error ) {
 529       $dbh->rollback if $oldAutoCommit;
 530       return $error;
 531     }
 532
 533     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 534       my $cust_contact = new FS::cust_contact {
 535         'custnum' => $self->custnum,
 536         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 537       };
 538       my $error =  $cust_contact->insert
 539                 || $prospect_contact->delete;
 540       if ( $error ) {
 541         $dbh->rollback if $oldAutoCommit;
 542         return $error;
 543       }
 544     }
 545
 546     my @cust_location = $prospect_main->cust_location;
 547     my @qual = $prospect_main->qual;
 548
 549     foreach my $r ( @cust_location, @qual ) {
 550       $r->prospectnum('');
 551       $r->custnum($self->custnum);
 552       my $error = $r->replace;
 553       if ( $error ) {
 554         $dbh->rollback if $oldAutoCommit;
 555         return $error;
 556       }
 557     }
 558
 559   }
 560
 561   warn "  setting contacts\n"
 562     if $DEBUG > 1;
 563
 564   $invoicing_list ||= $options{'invoicing_list'};
 565   if ( $invoicing_list ) {
 566
 567     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 568
 569     my $email = '';
 570     foreach my $dest (@$invoicing_list ) {
 571       if ($dest eq 'POST') {
 572         $self->set('postal_invoice', 'Y');
 573       } else {
 574
 575         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 576         if ( $contact_email ) {
 577           my $cust_contact = FS::cust_contact->new({
 578               contactnum    => $contact_email->contactnum,
 579               custnum       => $self->custnum,
 580           });
 581           $cust_contact->set('invoice_dest', 'Y');
 582           my $error = $cust_contact->contactnum ?
 583                         $cust_contact->replace : $cust_contact->insert;
 584           if ( $error ) {
 585             $dbh->rollback if $oldAutoCommit;
 586             return "$error (linking to email address $dest)";
 587           }
 588
 589         } else {
 590           # this email address is not yet linked to any contact
 591           $email .= ',' if length($email);
 592           $email .= $dest;
 593         }
 594       }
 595     }
 596
 597     my $contact = FS::contact->new({
 598       'custnum'       => $self->get('custnum'),
 599       'last'          => $self->get('last'),
 600       'first'         => $self->get('first'),
 601       'emailaddress'  => $email,
 602       'invoice_dest'  => 'Y', # yes, you can set this via the contact
 603     });
 604     my $error = $contact->insert;
 605     if ( $error ) {
 606       $dbh->rollback if $oldAutoCommit;
 607       return $error;
 608     }
 609
 610   }
 611
 612   if ( my $contact = delete $options{'contact'} ) {
 613
 614     foreach my $c ( @$contact ) {
 615       $c->custnum($self->custnum);
 616       my $error = $c->insert;
 617       if ( $error ) {
 618         $dbh->rollback if $oldAutoCommit;
 619         return $error;
 620       }
 621
 622     }
 623
 624   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 625
 626     my $error = $self->process_o2m( 'table'  => 'contact',
 627                                     'fields' => FS::contact->cgi_contact_fields,
 628                                     'params' => $contact_params,
 629                                   );
 630     if ( $error ) {
 631       $dbh->rollback if $oldAutoCommit;
 632       return $error;
 633     }
 634   }
 635
 636   warn "  setting cust_payby\n"
 637     if $DEBUG > 1;
 638
 639   if ( $options{cust_payby} ) {
 640
 641     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 642       $cust_payby->custnum($self->custnum);
 643       my $error = $cust_payby->insert;
 644       if ( $error ) {
 645         $dbh->rollback if $oldAutoCommit;
 646         return $error;
 647       }
 648     }
 649
 650   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 651
 652     my $error = $self->process_o2m(
 653       'table'         => 'cust_payby',
 654       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 655       'params'        => $cust_payby_params,
 656       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 657     );
 658     if ( $error ) {
 659       $dbh->rollback if $oldAutoCommit;
 660       return $error;
 661     }
 662
 663   }
 664
 665   warn "  setting cust_main_exemption\n"
 666     if $DEBUG > 1;
 667
 668   my $tax_exemption = delete $options{'tax_exemption'};
 669   if ( $tax_exemption ) {
 670
 671     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 672       if ref($tax_exemption) eq 'ARRAY';
 673
 674     foreach my $taxname ( keys %$tax_exemption ) {
 675       my $cust_main_exemption = new FS::cust_main_exemption {
 676         'custnum'       => $self->custnum,
 677         'taxname'       => $taxname,
 678         'exempt_number' => $tax_exemption->{$taxname},
 679       };
 680       my $error = $cust_main_exemption->insert;
 681       if ( $error ) {
 682         $dbh->rollback if $oldAutoCommit;
 683         return "inserting cust_main_exemption (transaction rolled back): $error";
 684       }
 685     }
 686   }
 687
 688   warn "  ordering packages\n"
 689     if $DEBUG > 1;
 690
 691   $error = $self->order_pkgs( $cust_pkgs,
 692                               %options,
 693                               'seconds_ref'    => \$seconds,
 694                               'upbytes_ref'    => \$upbytes,
 695                               'downbytes_ref'  => \$downbytes,
 696                               'totalbytes_ref' => \$totalbytes,
 697                             );
 698   if ( $error ) {
 699     $dbh->rollback if $oldAutoCommit;
 700     return $error;
 701   }
 702
 703   if ( $seconds ) {
 704     $dbh->rollback if $oldAutoCommit;
 705     return "No svc_acct record to apply pre-paid time";
 706   }
 707   if ( $upbytes || $downbytes || $totalbytes ) {
 708     $dbh->rollback if $oldAutoCommit;
 709     return "No svc_acct record to apply pre-paid data";
 710   }
 711
 712   if ( $amount ) {
 713     warn "  inserting initial $payby payment of $amount\n"
 714       if $DEBUG > 1;
 715     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 716     if ( $error ) {
 717       $dbh->rollback if $oldAutoCommit;
 718       return "inserting payment (transaction rolled back): $error";
 719     }
 720   }
 721
 722   unless ( $import || $skip_fuzzyfiles ) {
 723     warn "  queueing fuzzyfiles update\n"
 724       if $DEBUG > 1;
 725     $error = $self->queue_fuzzyfiles_update;
 726     if ( $error ) {
 727       $dbh->rollback if $oldAutoCommit;
 728       return "updating fuzzy search cache: $error";
 729     }
 730   }
 731
 732   # FS::geocode_Mixin::after_insert or something?
 733   if ( $conf->config('tax_district_method') and !$import ) {
 734     # if anything non-empty, try to look it up
 735     my $queue = new FS::queue {
 736       'job'     => 'FS::geocode_Mixin::process_district_update',
 737       'custnum' => $self->custnum,
 738     };
 739     my $error = $queue->insert( ref($self), $self->custnum );
 740     if ( $error ) {
 741       $dbh->rollback if $oldAutoCommit;
 742       return "queueing tax district update: $error";
 743     }
 744   }
 745
 746   # cust_main exports!
 747   warn "  exporting\n" if $DEBUG > 1;
 748
 749   my $export_args = $options{'export_args'} || [];
 750
 751   my @part_export =
 752     map qsearch( 'part_export', {exportnum=>$_} ),
 753       $conf->config('cust_main-exports'); #, $agentnum
 754
 755   foreach my $part_export ( @part_export ) {
 756     my $error = $part_export->export_insert($self, @$export_args);
 757     if ( $error ) {
 758       $dbh->rollback if $oldAutoCommit;
 759       return "exporting to ". $part_export->exporttype.
 760              " (transaction rolled back): $error";
 761     }
 762   }
 763
 764   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 765   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 766   #      if $DEBUG;
 767   #    foreach my $jobnum ( @jobnums ) {
 768   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 769   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 770   #        if $DEBUG;
 771   #      my $error = $queue->depend_insert($depend_jobnum);
 772   #      if ( $error ) {
 773   #        $dbh->rollback if $oldAutoCommit;
 774   #        return "error queuing job dependancy: $error";
 775   #      }
 776   #    }
 777   #  }
 778   #
 779   #}
 780   #
 781   #if ( exists $options{'jobnums'} ) {
 782   #  push @{ $options{'jobnums'} }, @jobnums;
 783   #}
 784
 785   warn "  insert complete; committing transaction\n"
 786     if $DEBUG > 1;
 787
 788   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 789   '';
 790
 791 }
 792
 793 use File::CounterFile;
 794 sub auto_agent_custid {
 795   my $self = shift;
 796
 797   my $format = $conf->config('cust_main-auto_agent_custid');
 798   my $agent_custid;
 799   if ( $format eq '1YMMXXXXXXXX' ) {
 800
 801     my $counter = new File::CounterFile 'cust_main.agent_custid';
 802     $counter->lock;
 803
 804     my $ym = 100000000000 + time2str('%y%m00000000', time);
 805     if ( $ym > $counter->value ) {
 806       $counter->{'value'} = $agent_custid = $ym;
 807       $counter->{'updated'} = 1;
 808     } else {
 809       $agent_custid = $counter->inc;
 810     }
 811
 812     $counter->unlock;
 813
 814   } else {
 815     die "Unknown cust_main-auto_agent_custid format: $format";
 816   }
 817
 818   $self->agent_custid($agent_custid);
 819
 820 }
 821
 822 =item PACKAGE METHODS
 823
 824 Documentation on customer package methods has been moved to
 825 L<FS::cust_main::Packages>.
 826
 827 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 828
 829 Recharges this (existing) customer with the specified prepaid card (see
 830 L<FS::prepay_credit>), specified either by I<identifier> or as an
 831 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 832 returns false.
 833
 834 Optionally, five scalar references can be passed as well.  They will have their
 835 values filled in with the amount, number of seconds, and number of upload,
 836 download, and total bytes applied by this prepaid card.
 837
 838 =cut
 839
 840 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 841 #the only place that uses these args
 842 sub recharge_prepay {
 843   my( $self, $prepay_credit, $amountref, $secondsref,
 844       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 845
 846   local $SIG{HUP} = 'IGNORE';
 847   local $SIG{INT} = 'IGNORE';
 848   local $SIG{QUIT} = 'IGNORE';
 849   local $SIG{TERM} = 'IGNORE';
 850   local $SIG{TSTP} = 'IGNORE';
 851   local $SIG{PIPE} = 'IGNORE';
 852
 853   my $oldAutoCommit = $FS::UID::AutoCommit;
 854   local $FS::UID::AutoCommit = 0;
 855   my $dbh = dbh;
 856
 857   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 858
 859   my $error = $self->get_prepay( $prepay_credit,
 860                                  'amount_ref'     => \$amount,
 861                                  'seconds_ref'    => \$seconds,
 862                                  'upbytes_ref'    => \$upbytes,
 863                                  'downbytes_ref'  => \$downbytes,
 864                                  'totalbytes_ref' => \$totalbytes,
 865                                )
 866            || $self->increment_seconds($seconds)
 867            || $self->increment_upbytes($upbytes)
 868            || $self->increment_downbytes($downbytes)
 869            || $self->increment_totalbytes($totalbytes)
 870            || $self->insert_cust_pay_prepay( $amount,
 871                                              ref($prepay_credit)
 872                                                ? $prepay_credit->identifier
 873                                                : $prepay_credit
 874                                            );
 875
 876   if ( $error ) {
 877     $dbh->rollback if $oldAutoCommit;
 878     return $error;
 879   }
 880
 881   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 882   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 883   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 884   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 885   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 886
 887   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 888   '';
 889
 890 }
 891
 892 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 893
 894 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 895 specified either by I<identifier> or as an FS::prepay_credit object.
 896
 897 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 898 incremented by the values of the prepaid card.
 899
 900 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 901 check or set this customer's I<agentnum>.
 902
 903 If there is an error, returns the error, otherwise returns false.
 904
 905 =cut
 906
 907
 908 sub get_prepay {
 909   my( $self, $prepay_credit, %opt ) = @_;
 910
 911   local $SIG{HUP} = 'IGNORE';
 912   local $SIG{INT} = 'IGNORE';
 913   local $SIG{QUIT} = 'IGNORE';
 914   local $SIG{TERM} = 'IGNORE';
 915   local $SIG{TSTP} = 'IGNORE';
 916   local $SIG{PIPE} = 'IGNORE';
 917
 918   my $oldAutoCommit = $FS::UID::AutoCommit;
 919   local $FS::UID::AutoCommit = 0;
 920   my $dbh = dbh;
 921
 922   unless ( ref($prepay_credit) ) {
 923
 924     my $identifier = $prepay_credit;
 925
 926     $prepay_credit = qsearchs(
 927       'prepay_credit',
 928       { 'identifier' => $identifier },
 929       '',
 930       'FOR UPDATE'
 931     );
 932
 933     unless ( $prepay_credit ) {
 934       $dbh->rollback if $oldAutoCommit;
 935       return "Invalid prepaid card: ". $identifier;
 936     }
 937
 938   }
 939
 940   if ( $prepay_credit->agentnum ) {
 941     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 942       $dbh->rollback if $oldAutoCommit;
 943       return "prepaid card not valid for agent ". $self->agentnum;
 944     }
 945     $self->agentnum($prepay_credit->agentnum);
 946   }
 947
 948   my $error = $prepay_credit->delete;
 949   if ( $error ) {
 950     $dbh->rollback if $oldAutoCommit;
 951     return "removing prepay_credit (transaction rolled back): $error";
 952   }
 953
 954   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 955     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 956
 957   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 958   '';
 959
 960 }
 961
 962 =item increment_upbytes SECONDS
 963
 964 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 965 the specified number of upbytes.  If there is an error, returns the error,
 966 otherwise returns false.
 967
 968 =cut
 969
 970 sub increment_upbytes {
 971   _increment_column( shift, 'upbytes', @_);
 972 }
 973
 974 =item increment_downbytes SECONDS
 975
 976 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 977 the specified number of downbytes.  If there is an error, returns the error,
 978 otherwise returns false.
 979
 980 =cut
 981
 982 sub increment_downbytes {
 983   _increment_column( shift, 'downbytes', @_);
 984 }
 985
 986 =item increment_totalbytes SECONDS
 987
 988 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 989 the specified number of totalbytes.  If there is an error, returns the error,
 990 otherwise returns false.
 991
 992 =cut
 993
 994 sub increment_totalbytes {
 995   _increment_column( shift, 'totalbytes', @_);
 996 }
 997
 998 =item increment_seconds SECONDS
 999
1000 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1001 the specified number of seconds.  If there is an error, returns the error,
1002 otherwise returns false.
1003
1004 =cut
1005
1006 sub increment_seconds {
1007   _increment_column( shift, 'seconds', @_);
1008 }
1009
1010 =item _increment_column AMOUNT
1011
1012 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1013 the specified number of seconds or bytes.  If there is an error, returns
1014 the error, otherwise returns false.
1015
1016 =cut
1017
1018 sub _increment_column {
1019   my( $self, $column, $amount ) = @_;
1020   warn "$me increment_column called: $column, $amount\n"
1021     if $DEBUG;
1022
1023   return '' unless $amount;
1024
1025   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1026                       $self->ncancelled_pkgs;
1027
1028   if ( ! @cust_pkg ) {
1029     return 'No packages with primary or single services found'.
1030            ' to apply pre-paid time';
1031   } elsif ( scalar(@cust_pkg) > 1 ) {
1032     #maybe have a way to specify the package/account?
1033     return 'Multiple packages found to apply pre-paid time';
1034   }
1035
1036   my $cust_pkg = $cust_pkg[0];
1037   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1038     if $DEBUG > 1;
1039
1040   my @cust_svc =
1041     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1042
1043   if ( ! @cust_svc ) {
1044     return 'No account found to apply pre-paid time';
1045   } elsif ( scalar(@cust_svc) > 1 ) {
1046     return 'Multiple accounts found to apply pre-paid time';
1047   }
1048
1049   my $svc_acct = $cust_svc[0]->svc_x;
1050   warn "  found service svcnum ". $svc_acct->pkgnum.
1051        ' ('. $svc_acct->email. ")\n"
1052     if $DEBUG > 1;
1053
1054   $column = "increment_$column";
1055   $svc_acct->$column($amount);
1056
1057 }
1058
1059 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1060
1061 Inserts a prepayment in the specified amount for this customer.  An optional
1062 second argument can specify the prepayment identifier for tracking purposes.
1063 If there is an error, returns the error, otherwise returns false.
1064
1065 =cut
1066
1067 sub insert_cust_pay_prepay {
1068   shift->insert_cust_pay('PREP', @_);
1069 }
1070
1071 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1072
1073 Inserts a cash payment in the specified amount for this customer.  An optional
1074 second argument can specify the payment identifier for tracking purposes.
1075 If there is an error, returns the error, otherwise returns false.
1076
1077 =cut
1078
1079 sub insert_cust_pay_cash {
1080   shift->insert_cust_pay('CASH', @_);
1081 }
1082
1083 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1084
1085 Inserts a Western Union payment in the specified amount for this customer.  An
1086 optional second argument can specify the prepayment identifier for tracking
1087 purposes.  If there is an error, returns the error, otherwise returns false.
1088
1089 =cut
1090
1091 sub insert_cust_pay_west {
1092   shift->insert_cust_pay('WEST', @_);
1093 }
1094
1095 sub insert_cust_pay {
1096   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1097   my $payinfo = scalar(@_) ? shift : '';
1098
1099   my $cust_pay = new FS::cust_pay {
1100     'custnum' => $self->custnum,
1101     'paid'    => sprintf('%.2f', $amount),
1102     #'_date'   => #date the prepaid card was purchased???
1103     'payby'   => $payby,
1104     'payinfo' => $payinfo,
1105   };
1106   $cust_pay->insert;
1107
1108 }
1109
1110 =item delete [ OPTION => VALUE ... ]
1111
1112 This deletes the customer.  If there is an error, returns the error, otherwise
1113 returns false.
1114
1115 This will completely remove all traces of the customer record.  This is not
1116 what you want when a customer cancels service; for that, cancel all of the
1117 customer's packages (see L</cancel>).
1118
1119 If the customer has any uncancelled packages, you need to pass a new (valid)
1120 customer number for those packages to be transferred to, as the "new_customer"
1121 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1122 what you want when a customer cancels service and that you really should be
1123 looking at L<FS::cust_pkg/cancel>?
1124
1125 You can't delete a customer with invoices (see L<FS::cust_bill>),
1126 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1127 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1128 set the "delete_financials" option to a true value.
1129
1130 =cut
1131
1132 sub delete {
1133   my( $self, %opt ) = @_;
1134
1135   local $SIG{HUP} = 'IGNORE';
1136   local $SIG{INT} = 'IGNORE';
1137   local $SIG{QUIT} = 'IGNORE';
1138   local $SIG{TERM} = 'IGNORE';
1139   local $SIG{TSTP} = 'IGNORE';
1140   local $SIG{PIPE} = 'IGNORE';
1141
1142   my $oldAutoCommit = $FS::UID::AutoCommit;
1143   local $FS::UID::AutoCommit = 0;
1144   my $dbh = dbh;
1145
1146   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1147      $dbh->rollback if $oldAutoCommit;
1148      return "Can't delete a master agent customer";
1149   }
1150
1151   #use FS::access_user
1152   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1153      $dbh->rollback if $oldAutoCommit;
1154      return "Can't delete a master employee customer";
1155   }
1156
1157   tie my %financial_tables, 'Tie::IxHash',
1158     'cust_bill'      => 'invoices',
1159     'cust_statement' => 'statements',
1160     'cust_credit'    => 'credits',
1161     'cust_pay'       => 'payments',
1162     'cust_refund'    => 'refunds',
1163   ;
1164
1165   foreach my $table ( keys %financial_tables ) {
1166
1167     my @records = $self->$table();
1168
1169     if ( @records && ! $opt{'delete_financials'} ) {
1170       $dbh->rollback if $oldAutoCommit;
1171       return "Can't delete a customer with ". $financial_tables{$table};
1172     }
1173
1174     foreach my $record ( @records ) {
1175       my $error = $record->delete;
1176       if ( $error ) {
1177         $dbh->rollback if $oldAutoCommit;
1178         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1179       }
1180     }
1181
1182   }
1183
1184   my @cust_pkg = $self->ncancelled_pkgs;
1185   if ( @cust_pkg ) {
1186     my $new_custnum = $opt{'new_custnum'};
1187     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1188       $dbh->rollback if $oldAutoCommit;
1189       return "Invalid new customer number: $new_custnum";
1190     }
1191     foreach my $cust_pkg ( @cust_pkg ) {
1192       my %hash = $cust_pkg->hash;
1193       $hash{'custnum'} = $new_custnum;
1194       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1195       my $error = $new_cust_pkg->replace($cust_pkg,
1196                                          options => { $cust_pkg->options },
1197                                         );
1198       if ( $error ) {
1199         $dbh->rollback if $oldAutoCommit;
1200         return $error;
1201       }
1202     }
1203   }
1204   my @cancelled_cust_pkg = $self->all_pkgs;
1205   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1206     my $error = $cust_pkg->delete;
1207     if ( $error ) {
1208       $dbh->rollback if $oldAutoCommit;
1209       return $error;
1210     }
1211   }
1212
1213   #cust_tax_adjustment in financials?
1214   #cust_pay_pending?  ouch
1215   foreach my $table (qw(
1216     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1217     cust_payby cust_location cust_main_note cust_tax_adjustment
1218     cust_pay_void cust_pay_batch queue cust_tax_exempt
1219   )) {
1220     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1221       my $error = $record->delete;
1222       if ( $error ) {
1223         $dbh->rollback if $oldAutoCommit;
1224         return $error;
1225       }
1226     }
1227   }
1228
1229   my $sth = $dbh->prepare(
1230     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1231   ) or do {
1232     my $errstr = $dbh->errstr;
1233     $dbh->rollback if $oldAutoCommit;
1234     return $errstr;
1235   };
1236   $sth->execute($self->custnum) or do {
1237     my $errstr = $sth->errstr;
1238     $dbh->rollback if $oldAutoCommit;
1239     return $errstr;
1240   };
1241
1242   #tickets
1243
1244   my $ticket_dbh = '';
1245   if ($conf->config('ticket_system') eq 'RT_Internal') {
1246     $ticket_dbh = $dbh;
1247   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1248     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1249     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1250       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1251   }
1252
1253   if ( $ticket_dbh ) {
1254
1255     my $ticket_sth = $ticket_dbh->prepare(
1256       'DELETE FROM Links WHERE Target = ?'
1257     ) or do {
1258       my $errstr = $ticket_dbh->errstr;
1259       $dbh->rollback if $oldAutoCommit;
1260       return $errstr;
1261     };
1262     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1263       or do {
1264         my $errstr = $ticket_sth->errstr;
1265         $dbh->rollback if $oldAutoCommit;
1266         return $errstr;
1267       };
1268
1269     #check and see if the customer is the only link on the ticket, and
1270     #if so, set the ticket to deleted status in RT?
1271     #maybe someday, for now this will at least fix tickets not displaying
1272
1273   }
1274
1275   #delete the customer record
1276
1277   my $error = $self->SUPER::delete;
1278   if ( $error ) {
1279     $dbh->rollback if $oldAutoCommit;
1280     return $error;
1281   }
1282
1283   # cust_main exports!
1284
1285   #my $export_args = $options{'export_args'} || [];
1286
1287   my @part_export =
1288     map qsearch( 'part_export', {exportnum=>$_} ),
1289       $conf->config('cust_main-exports'); #, $agentnum
1290
1291   foreach my $part_export ( @part_export ) {
1292     my $error = $part_export->export_delete( $self ); #, @$export_args);
1293     if ( $error ) {
1294       $dbh->rollback if $oldAutoCommit;
1295       return "exporting to ". $part_export->exporttype.
1296              " (transaction rolled back): $error";
1297     }
1298   }
1299
1300   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1301   '';
1302
1303 }
1304
1305 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1306
1307 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1308 returns the error, otherwise returns false.
1309
1310 To change the customer's address, set the pseudo-fields C<bill_location> and
1311 C<ship_location>.  The address will still only change if at least one of the
1312 address fields differs from the existing values.
1313
1314 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1315 set as the contact email address for a default contact with the same name as
1316 the customer.
1317
1318 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1319 I<contact_params>, I<invoicing_list>.
1320
1321 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1322 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1323 deleted and inserted as appropriate.
1324
1325 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1326 groups (describing the customer's payment methods and contacts, respectively)
1327 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1328 and L<FS::contact> for the fields these can contain.
1329
1330 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1331 should be used instead if possible.
1332
1333 =cut
1334
1335 sub replace {
1336   my $self = shift;
1337
1338   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1339               ? shift
1340               : $self->replace_old;
1341
1342   my @param = @_;
1343
1344   warn "$me replace called\n"
1345     if $DEBUG;
1346
1347   my $curuser = $FS::CurrentUser::CurrentUser;
1348   return "You are not permitted to create complimentary accounts."
1349     if $self->complimentary eq 'Y'
1350     && $self->complimentary ne $old->complimentary
1351     && ! $curuser->access_right('Complimentary customer');
1352
1353   local($ignore_expired_card) = 1
1354     if $old->payby  =~ /^(CARD|DCRD)$/
1355     && $self->payby =~ /^(CARD|DCRD)$/
1356     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1357
1358   local($ignore_banned_card) = 1
1359     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1360          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1361     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1362
1363   if (    $self->payby =~ /^(CARD|DCRD)$/
1364        && $old->payinfo ne $self->payinfo
1365        && $old->paymask ne $self->paymask )
1366   {
1367     my $error = $self->check_payinfo_cardtype;
1368     return $error if $error;
1369   }
1370
1371   return "Invoicing locale is required"
1372     if $old->locale
1373     && ! $self->locale
1374     && $conf->exists('cust_main-require_locale');
1375
1376   local $SIG{HUP} = 'IGNORE';
1377   local $SIG{INT} = 'IGNORE';
1378   local $SIG{QUIT} = 'IGNORE';
1379   local $SIG{TERM} = 'IGNORE';
1380   local $SIG{TSTP} = 'IGNORE';
1381   local $SIG{PIPE} = 'IGNORE';
1382
1383   my $oldAutoCommit = $FS::UID::AutoCommit;
1384   local $FS::UID::AutoCommit = 0;
1385   my $dbh = dbh;
1386
1387   for my $l (qw(bill_location ship_location)) {
1388     #my $old_loc = $old->$l;
1389     my $new_loc = $self->$l or next;
1390
1391     # find the existing location if there is one
1392     $new_loc->set('custnum' => $self->custnum);
1393     my $error = $new_loc->find_or_insert;
1394     if ( $error ) {
1395       $dbh->rollback if $oldAutoCommit;
1396       return $error;
1397     }
1398     $self->set($l.'num', $new_loc->locationnum);
1399   } #for $l
1400
1401   my $invoicing_list;
1402   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1403     warn "cust_main::replace: using deprecated invoicing list argument";
1404     $invoicing_list = shift @param;
1405   }
1406
1407   my %options = @param;
1408
1409   $invoicing_list ||= $options{invoicing_list};
1410
1411   my @contacts = map { $_->contact } $self->cust_contact;
1412   # find a contact that matches the customer's name
1413   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1414                               and $_->last  eq $old->get('last') }
1415                             @contacts;
1416   $implicit_contact ||= FS::contact->new({
1417       'custnum'       => $self->custnum,
1418       'locationnum'   => $self->get('bill_locationnum'),
1419   });
1420
1421   # for any of these that are already contact emails, link to the existing
1422   # contact
1423   if ( $invoicing_list ) {
1424     my $email = '';
1425
1426     # kind of like process_m2m on these, except:
1427     # - the other side is two tables in a join
1428     # - and we might have to create new contact_emails
1429     # - and possibly a new contact
1430     #
1431     # Find existing invoice emails that aren't on the implicit contact.
1432     # Any of these that are not on the new invoicing list will be removed.
1433     my %old_email_cust_contact;
1434     foreach my $cust_contact ($self->cust_contact) {
1435       next if !$cust_contact->invoice_dest;
1436       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1437
1438       foreach my $contact_email ($cust_contact->contact->contact_email) {
1439         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1440       }
1441     }
1442
1443     foreach my $dest (@$invoicing_list) {
1444
1445       if ($dest eq 'POST') {
1446
1447         $self->set('postal_invoice', 'Y');
1448
1449       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1450
1451         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1452
1453       } else {
1454
1455         # See if it belongs to some other contact; if so, link it.
1456         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1457         if ( $contact_email
1458              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1459           my $cust_contact = qsearchs('cust_contact', {
1460               contactnum  => $contact_email->contactnum,
1461               custnum     => $self->custnum,
1462           }) || FS::cust_contact->new({
1463               contactnum    => $contact_email->contactnum,
1464               custnum       => $self->custnum,
1465           });
1466           $cust_contact->set('invoice_dest', 'Y');
1467           my $error = $cust_contact->custcontactnum ?
1468                         $cust_contact->replace : $cust_contact->insert;
1469           if ( $error ) {
1470             $dbh->rollback if $oldAutoCommit;
1471             return "$error (linking to email address $dest)";
1472           }
1473
1474         } else {
1475           # This email address is not yet linked to any contact, so it will
1476           # be added to the implicit contact.
1477           $email .= ',' if length($email);
1478           $email .= $dest;
1479         }
1480       }
1481     }
1482
1483     foreach my $remove_dest (keys %old_email_cust_contact) {
1484       my $cust_contact = $old_email_cust_contact{$remove_dest};
1485       # These were not in the list of requested destinations, so take them off.
1486       $cust_contact->set('invoice_dest', '');
1487       my $error = $cust_contact->replace;
1488       if ( $error ) {
1489         $dbh->rollback if $oldAutoCommit;
1490         return "$error (unlinking email address $remove_dest)";
1491       }
1492     }
1493
1494     # make sure it keeps up with the changed customer name, if any
1495     $implicit_contact->set('last', $self->get('last'));
1496     $implicit_contact->set('first', $self->get('first'));
1497     $implicit_contact->set('emailaddress', $email);
1498     $implicit_contact->set('invoice_dest', 'Y');
1499     $implicit_contact->set('custnum', $self->custnum);
1500
1501     my $error;
1502     if ( $implicit_contact->contactnum ) {
1503       $error = $implicit_contact->replace;
1504     } elsif ( length($email) ) { # don't create a new contact if not needed
1505       $error = $implicit_contact->insert;
1506     }
1507
1508     if ( $error ) {
1509       $dbh->rollback if $oldAutoCommit;
1510       return "$error (adding email address $email)";
1511     }
1512
1513   }
1514
1515   # replace the customer record
1516   my $error = $self->SUPER::replace($old);
1517
1518   if ( $error ) {
1519     $dbh->rollback if $oldAutoCommit;
1520     return $error;
1521   }
1522
1523   # now move packages to the new service location
1524   $self->set('ship_location', ''); #flush cache
1525   if ( $old->ship_locationnum and # should only be null during upgrade...
1526        $old->ship_locationnum != $self->ship_locationnum ) {
1527     $error = $old->ship_location->move_to($self->ship_location);
1528     if ( $error ) {
1529       $dbh->rollback if $oldAutoCommit;
1530       return $error;
1531     }
1532   }
1533   # don't move packages based on the billing location, but
1534   # disable it if it's no longer in use
1535   if ( $old->bill_locationnum and
1536        $old->bill_locationnum != $self->bill_locationnum ) {
1537     $error = $old->bill_location->disable_if_unused;
1538     if ( $error ) {
1539       $dbh->rollback if $oldAutoCommit;
1540       return $error;
1541     }
1542   }
1543
1544   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1545
1546     #this could be more efficient than deleting and re-inserting, if it matters
1547     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1548       my $error = $cust_tag->delete;
1549       if ( $error ) {
1550         $dbh->rollback if $oldAutoCommit;
1551         return $error;
1552       }
1553     }
1554     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1555       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1556                                         'custnum' => $self->custnum };
1557       my $error = $cust_tag->insert;
1558       if ( $error ) {
1559         $dbh->rollback if $oldAutoCommit;
1560         return $error;
1561       }
1562     }
1563
1564   }
1565
1566   my $tax_exemption = delete $options{'tax_exemption'};
1567   if ( $tax_exemption ) {
1568
1569     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1570       if ref($tax_exemption) eq 'ARRAY';
1571
1572     my %cust_main_exemption =
1573       map { $_->taxname => $_ }
1574           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1575
1576     foreach my $taxname ( keys %$tax_exemption ) {
1577
1578       if ( $cust_main_exemption{$taxname} &&
1579            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1580          )
1581       {
1582         delete $cust_main_exemption{$taxname};
1583         next;
1584       }
1585
1586       my $cust_main_exemption = new FS::cust_main_exemption {
1587         'custnum'       => $self->custnum,
1588         'taxname'       => $taxname,
1589         'exempt_number' => $tax_exemption->{$taxname},
1590       };
1591       my $error = $cust_main_exemption->insert;
1592       if ( $error ) {
1593         $dbh->rollback if $oldAutoCommit;
1594         return "inserting cust_main_exemption (transaction rolled back): $error";
1595       }
1596     }
1597
1598     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1599       my $error = $cust_main_exemption->delete;
1600       if ( $error ) {
1601         $dbh->rollback if $oldAutoCommit;
1602         return "deleting cust_main_exemption (transaction rolled back): $error";
1603       }
1604     }
1605
1606   }
1607
1608   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1609
1610     my $error = $self->process_o2m(
1611       'table'         => 'cust_payby',
1612       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1613       'params'        => $cust_payby_params,
1614       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1615     );
1616     if ( $error ) {
1617       $dbh->rollback if $oldAutoCommit;
1618       return $error;
1619     }
1620
1621   }
1622
1623   if ( my $contact_params = delete $options{'contact_params'} ) {
1624
1625     # this can potentially replace contacts that were created by the
1626     # invoicing list argument, but the UI shouldn't allow both of them
1627     # to be specified
1628
1629     my $error = $self->process_o2m(
1630       'table'         => 'contact',
1631       'fields'        => FS::contact->cgi_contact_fields,
1632       'params'        => $contact_params,
1633     );
1634     if ( $error ) {
1635       $dbh->rollback if $oldAutoCommit;
1636       return $error;
1637     }
1638
1639   }
1640
1641   unless ( $import || $skip_fuzzyfiles ) {
1642     $error = $self->queue_fuzzyfiles_update;
1643     if ( $error ) {
1644       $dbh->rollback if $oldAutoCommit;
1645       return "updating fuzzy search cache: $error";
1646     }
1647   }
1648
1649   # tax district update in cust_location
1650
1651   # cust_main exports!
1652
1653   my $export_args = $options{'export_args'} || [];
1654
1655   my @part_export =
1656     map qsearch( 'part_export', {exportnum=>$_} ),
1657       $conf->config('cust_main-exports'); #, $agentnum
1658
1659   foreach my $part_export ( @part_export ) {
1660     my $error = $part_export->export_replace( $self, $old, @$export_args);
1661     if ( $error ) {
1662       $dbh->rollback if $oldAutoCommit;
1663       return "exporting to ". $part_export->exporttype.
1664              " (transaction rolled back): $error";
1665     }
1666   }
1667
1668   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1669   '';
1670
1671 }
1672
1673 =item queue_fuzzyfiles_update
1674
1675 Used by insert & replace to update the fuzzy search cache
1676
1677 =cut
1678
1679 use FS::cust_main::Search;
1680 sub queue_fuzzyfiles_update {
1681   my $self = shift;
1682
1683   local $SIG{HUP} = 'IGNORE';
1684   local $SIG{INT} = 'IGNORE';
1685   local $SIG{QUIT} = 'IGNORE';
1686   local $SIG{TERM} = 'IGNORE';
1687   local $SIG{TSTP} = 'IGNORE';
1688   local $SIG{PIPE} = 'IGNORE';
1689
1690   my $oldAutoCommit = $FS::UID::AutoCommit;
1691   local $FS::UID::AutoCommit = 0;
1692   my $dbh = dbh;
1693
1694   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1695     my $queue = new FS::queue {
1696       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1697     };
1698     my @args = "cust_main.$field", $self->get($field);
1699     my $error = $queue->insert( @args );
1700     if ( $error ) {
1701       $dbh->rollback if $oldAutoCommit;
1702       return "queueing job (transaction rolled back): $error";
1703     }
1704   }
1705
1706   my @locations = ();
1707   push @locations, $self->bill_location if $self->bill_locationnum;
1708   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1709   foreach my $location (@locations) {
1710     my $queue = new FS::queue {
1711       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1712     };
1713     my @args = 'cust_location.address1', $location->address1;
1714     my $error = $queue->insert( @args );
1715     if ( $error ) {
1716       $dbh->rollback if $oldAutoCommit;
1717       return "queueing job (transaction rolled back): $error";
1718     }
1719   }
1720
1721   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1722   '';
1723
1724 }
1725
1726 =item check
1727
1728 Checks all fields to make sure this is a valid customer record.  If there is
1729 an error, returns the error, otherwise returns false.  Called by the insert
1730 and replace methods.
1731
1732 =cut
1733
1734 sub check {
1735   my $self = shift;
1736
1737   warn "$me check BEFORE: \n". $self->_dump
1738     if $DEBUG > 2;
1739
1740   my $error =
1741     $self->ut_numbern('custnum')
1742     || $self->ut_number('agentnum')
1743     || $self->ut_textn('agent_custid')
1744     || $self->ut_number('refnum')
1745     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1746     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1747     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1748     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1749     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1750     || $self->ut_textn('custbatch')
1751     || $self->ut_name('last')
1752     || $self->ut_name('first')
1753     || $self->ut_snumbern('signupdate')
1754     || $self->ut_snumbern('birthdate')
1755     || $self->ut_namen('spouse_last')
1756     || $self->ut_namen('spouse_first')
1757     || $self->ut_snumbern('spouse_birthdate')
1758     || $self->ut_snumbern('anniversary_date')
1759     || $self->ut_textn('company')
1760     || $self->ut_textn('ship_company')
1761     || $self->ut_anything('comments')
1762     || $self->ut_numbern('referral_custnum')
1763     || $self->ut_textn('stateid')
1764     || $self->ut_textn('stateid_state')
1765     || $self->ut_textn('invoice_terms')
1766     || $self->ut_floatn('cdr_termination_percentage')
1767     || $self->ut_floatn('credit_limit')
1768     || $self->ut_numbern('billday')
1769     || $self->ut_numbern('prorate_day')
1770     || $self->ut_flag('edit_subject')
1771     || $self->ut_flag('calling_list_exempt')
1772     || $self->ut_flag('invoice_noemail')
1773     || $self->ut_flag('message_noemail')
1774     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1775     || $self->ut_currencyn('currency')
1776     || $self->ut_alphan('po_number')
1777     || $self->ut_enum('complimentary', [ '', 'Y' ])
1778     || $self->ut_flag('invoice_ship_address')
1779     || $self->ut_flag('invoice_dest')
1780   ;
1781
1782   foreach (qw(company ship_company)) {
1783     my $company = $self->get($_);
1784     $company =~ s/^\s+//;
1785     $company =~ s/\s+$//;
1786     $company =~ s/\s+/ /g;
1787     $self->set($_, $company);
1788   }
1789
1790   #barf.  need message catalogs.  i18n.  etc.
1791   $error .= "Please select an advertising source."
1792     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1793   return $error if $error;
1794
1795   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1796     or return "Unknown agent";
1797
1798   if ( $self->currency ) {
1799     my $agent_currency = qsearchs( 'agent_currency', {
1800       'agentnum' => $agent->agentnum,
1801       'currency' => $self->currency,
1802     })
1803       or return "Agent ". $agent->agent.
1804                 " not permitted to offer ".  $self->currency. " invoicing";
1805   }
1806
1807   return "Unknown refnum"
1808     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1809
1810   return "Unknown referring custnum: ". $self->referral_custnum
1811     unless ! $self->referral_custnum
1812            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1813
1814   if ( $self->ss eq '' ) {
1815     $self->ss('');
1816   } else {
1817     my $ss = $self->ss;
1818     $ss =~ s/\D//g;
1819     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1820       or return "Illegal social security number: ". $self->ss;
1821     $self->ss("$1-$2-$3");
1822   }
1823
1824   #turn off invoice_ship_address if ship & bill are the same
1825   if ($self->bill_locationnum eq $self->ship_locationnum) {
1826     $self->invoice_ship_address('');
1827   }
1828
1829   # cust_main_county verification now handled by cust_location check
1830
1831   $error =
1832        $self->ut_phonen('daytime', $self->country)
1833     || $self->ut_phonen('night',   $self->country)
1834     || $self->ut_phonen('fax',     $self->country)
1835     || $self->ut_phonen('mobile',  $self->country)
1836   ;
1837   return $error if $error;
1838
1839   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1840        && ! $import
1841        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1842      ) {
1843
1844     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1845                           ? 'Day Phone'
1846                           : FS::Msgcat::_gettext('daytime');
1847     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1848                         ? 'Night Phone'
1849                         : FS::Msgcat::_gettext('night');
1850
1851     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1852                         ? 'Mobile Phone'
1853                         : FS::Msgcat::_gettext('mobile');
1854
1855     return "$daytime_label, $night_label or $mobile_label is required"
1856
1857   }
1858
1859   return "Please select an invoicing locale"
1860     if ! $self->locale
1861     && ! $self->custnum
1862     && $conf->exists('cust_main-require_locale');
1863
1864   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
1865     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
1866     $self->$flag($1);
1867   }
1868
1869   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
1870
1871   warn "$me check AFTER: \n". $self->_dump
1872     if $DEBUG > 2;
1873
1874   $self->SUPER::check;
1875 }
1876
1877 sub check_payinfo_cardtype {
1878   my $self = shift;
1879
1880   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
1881
1882   my $payinfo = $self->payinfo;
1883   $payinfo =~ s/\D//g;
1884
1885   return '' if $payinfo =~ /^99\d{14}$/; #token
1886
1887   my %bop_card_types = map { $_=>1 } values %{ card_types() };
1888   my $cardtype = cardtype($payinfo);
1889
1890   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
1891
1892   '';
1893
1894 }
1895
1896 =item replace_check
1897
1898 Additional checks for replace only.
1899
1900 =cut
1901
1902 sub replace_check {
1903   my ($new,$old) = @_;
1904   #preserve old value if global config is set
1905   if ($old && $conf->exists('invoice-ship_address')) {
1906     $new->invoice_ship_address($old->invoice_ship_address);
1907   }
1908   return '';
1909 }
1910
1911 =item addr_fields
1912
1913 Returns a list of fields which have ship_ duplicates.
1914
1915 =cut
1916
1917 sub addr_fields {
1918   qw( last first company
1919       locationname
1920       address1 address2 city county state zip country
1921       latitude longitude
1922       daytime night fax mobile
1923     );
1924 }
1925
1926 =item has_ship_address
1927
1928 Returns true if this customer record has a separate shipping address.
1929
1930 =cut
1931
1932 sub has_ship_address {
1933   my $self = shift;
1934   $self->bill_locationnum != $self->ship_locationnum;
1935 }
1936
1937 =item location_hash
1938
1939 Returns a list of key/value pairs, with the following keys: address1,
1940 adddress2, city, county, state, zip, country, district, and geocode.  The
1941 shipping address is used if present.
1942
1943 =cut
1944
1945 sub location_hash {
1946   my $self = shift;
1947   $self->ship_location->location_hash;
1948 }
1949
1950 =item cust_location
1951
1952 Returns all locations (see L<FS::cust_location>) for this customer.
1953
1954 =cut
1955
1956 sub cust_location {
1957   my $self = shift;
1958   qsearch({
1959     'table'   => 'cust_location',
1960     'hashref' => { 'custnum'     => $self->custnum,
1961                    'prospectnum' => '',
1962                  },
1963     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
1964   });
1965 }
1966
1967 =item cust_contact
1968
1969 Returns all contact associations (see L<FS::cust_contact>) for this customer.
1970
1971 =cut
1972
1973 sub cust_contact {
1974   my $self = shift;
1975   qsearch('cust_contact', { 'custnum' => $self->custnum } );
1976 }
1977
1978 =item cust_payby PAYBY
1979
1980 Returns all payment methods (see L<FS::cust_payby>) for this customer.
1981
1982 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
1983 Does not validate PAYBY.
1984
1985 =cut
1986
1987 sub cust_payby {
1988   my $self = shift;
1989   my @payby = @_;
1990   my $search = {
1991     'table'    => 'cust_payby',
1992     'hashref'  => { 'custnum' => $self->custnum },
1993     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
1994   };
1995   $search->{'extra_sql'} = ' AND payby IN ( ' . join(',', map { dbh->quote($_) } @payby) . ' ) '
1996     if @payby;
1997
1998   qsearch($search);
1999 }
2000
2001 =item has_cust_payby_auto
2002
2003 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2004
2005 =cut
2006
2007 sub has_cust_payby_auto {
2008   my $self = shift;
2009   scalar( qsearch({
2010     'table'     => 'cust_payby',
2011     'hashref'   => { 'custnum' => $self->custnum, },
2012     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2013     'order_by'  => 'LIMIT 1',
2014   }) );
2015
2016 }
2017
2018 =item unsuspend
2019
2020 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2021 and L<FS::cust_pkg>) for this customer, except those on hold.
2022
2023 Returns a list: an empty list on success or a list of errors.
2024
2025 =cut
2026
2027 sub unsuspend {
2028   my $self = shift;
2029   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs;
2030 }
2031
2032 =item release_hold
2033
2034 Unsuspends all suspended packages in the on-hold state (those without setup
2035 dates) for this customer.
2036
2037 =cut
2038
2039 sub release_hold {
2040   my $self = shift;
2041   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2042 }
2043
2044 =item suspend
2045
2046 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2047
2048 Returns a list: an empty list on success or a list of errors.
2049
2050 =cut
2051
2052 sub suspend {
2053   my $self = shift;
2054   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2055 }
2056
2057 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2058
2059 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2060 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2061 of a list of pkgparts; the hashref has the following keys:
2062
2063 =over 4
2064
2065 =item pkgparts - listref of pkgparts
2066
2067 =item (other options are passed to the suspend method)
2068
2069 =back
2070
2071
2072 Returns a list: an empty list on success or a list of errors.
2073
2074 =cut
2075
2076 sub suspend_if_pkgpart {
2077   my $self = shift;
2078   my (@pkgparts, %opt);
2079   if (ref($_[0]) eq 'HASH'){
2080     @pkgparts = @{$_[0]{pkgparts}};
2081     %opt      = %{$_[0]};
2082   }else{
2083     @pkgparts = @_;
2084   }
2085   grep { $_->suspend(%opt) }
2086     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2087       $self->unsuspended_pkgs;
2088 }
2089
2090 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2091
2092 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2093 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2094 instead of a list of pkgparts; the hashref has the following keys:
2095
2096 =over 4
2097
2098 =item pkgparts - listref of pkgparts
2099
2100 =item (other options are passed to the suspend method)
2101
2102 =back
2103
2104 Returns a list: an empty list on success or a list of errors.
2105
2106 =cut
2107
2108 sub suspend_unless_pkgpart {
2109   my $self = shift;
2110   my (@pkgparts, %opt);
2111   if (ref($_[0]) eq 'HASH'){
2112     @pkgparts = @{$_[0]{pkgparts}};
2113     %opt      = %{$_[0]};
2114   }else{
2115     @pkgparts = @_;
2116   }
2117   grep { $_->suspend(%opt) }
2118     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2119       $self->unsuspended_pkgs;
2120 }
2121
2122 =item cancel [ OPTION => VALUE ... ]
2123
2124 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2125
2126 Available options are:
2127
2128 =over 4
2129
2130 =item quiet - can be set true to supress email cancellation notices.
2131
2132 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2133
2134 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2135
2136 =item nobill - can be set true to skip billing if it might otherwise be done.
2137
2138 =back
2139
2140 Always returns a list: an empty list on success or a list of errors.
2141
2142 =cut
2143
2144 # nb that dates are not specified as valid options to this method
2145
2146 sub cancel {
2147   my( $self, %opt ) = @_;
2148
2149   warn "$me cancel called on customer ". $self->custnum. " with options ".
2150        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2151     if $DEBUG;
2152
2153   return ( 'access denied' )
2154     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2155
2156   if ( $opt{'ban'} ) {
2157
2158     foreach my $cust_payby ( $self->cust_payby ) {
2159
2160       #well, if they didn't get decrypted on search, then we don't have to
2161       # try again... queue a job for the server that does have decryption
2162       # capability if we're in a paranoid multi-server implementation?
2163       return ( "Can't (yet) ban encrypted credit cards" )
2164         if $cust_payby->is_encrypted($cust_payby->payinfo);
2165
2166       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2167       my $error = $ban->insert;
2168       return ( $error ) if $error;
2169
2170     }
2171
2172   }
2173
2174   my @pkgs = $self->ncancelled_pkgs;
2175
2176   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2177     $opt{nobill} = 1;
2178     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2179     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2180       if $error;
2181   }
2182
2183   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2184        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2185     if $DEBUG;
2186
2187   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2188 }
2189
2190 sub _banned_pay_hashref {
2191   die 'cust_main->_banned_pay_hashref deprecated';
2192
2193   my $self = shift;
2194
2195   my %payby2ban = (
2196     'CARD' => 'CARD',
2197     'DCRD' => 'CARD',
2198     'CHEK' => 'CHEK',
2199     'DCHK' => 'CHEK'
2200   );
2201
2202   {
2203     'payby'   => $payby2ban{$self->payby},
2204     'payinfo' => $self->payinfo,
2205     #don't ever *search* on reason! #'reason'  =>
2206   };
2207 }
2208
2209 =item notes
2210
2211 Returns all notes (see L<FS::cust_main_note>) for this customer.
2212
2213 =cut
2214
2215 sub notes {
2216   my($self,$orderby_classnum) = (shift,shift);
2217   my $orderby = "sticky DESC, _date DESC";
2218   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2219   qsearch( 'cust_main_note',
2220            { 'custnum' => $self->custnum },
2221            '',
2222            "ORDER BY $orderby",
2223          );
2224 }
2225
2226 =item agent
2227
2228 Returns the agent (see L<FS::agent>) for this customer.
2229
2230 =item agent_name
2231
2232 Returns the agent name (see L<FS::agent>) for this customer.
2233
2234 =cut
2235
2236 sub agent_name {
2237   my $self = shift;
2238   $self->agent->agent;
2239 }
2240
2241 =item cust_tag
2242
2243 Returns any tags associated with this customer, as FS::cust_tag objects,
2244 or an empty list if there are no tags.
2245
2246 =item part_tag
2247
2248 Returns any tags associated with this customer, as FS::part_tag objects,
2249 or an empty list if there are no tags.
2250
2251 =cut
2252
2253 sub part_tag {
2254   my $self = shift;
2255   map $_->part_tag, $self->cust_tag;
2256 }
2257
2258
2259 =item cust_class
2260
2261 Returns the customer class, as an FS::cust_class object, or the empty string
2262 if there is no customer class.
2263
2264 =item categoryname
2265
2266 Returns the customer category name, or the empty string if there is no customer
2267 category.
2268
2269 =cut
2270
2271 sub categoryname {
2272   my $self = shift;
2273   my $cust_class = $self->cust_class;
2274   $cust_class
2275     ? $cust_class->categoryname
2276     : '';
2277 }
2278
2279 =item classname
2280
2281 Returns the customer class name, or the empty string if there is no customer
2282 class.
2283
2284 =cut
2285
2286 sub classname {
2287   my $self = shift;
2288   my $cust_class = $self->cust_class;
2289   $cust_class
2290     ? $cust_class->classname
2291     : '';
2292 }
2293
2294 =item tax_status
2295
2296 Returns the external tax status, as an FS::tax_status object, or the empty
2297 string if there is no tax status.
2298
2299 =cut
2300
2301 sub tax_status {
2302   my $self = shift;
2303   if ( $self->taxstatusnum ) {
2304     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2305   } else {
2306     return '';
2307   }
2308 }
2309
2310 =item taxstatus
2311
2312 Returns the tax status code if there is one.
2313
2314 =cut
2315
2316 sub taxstatus {
2317   my $self = shift;
2318   my $tax_status = $self->tax_status;
2319   $tax_status
2320     ? $tax_status->taxstatus
2321     : '';
2322 }
2323
2324 =item BILLING METHODS
2325
2326 Documentation on billing methods has been moved to
2327 L<FS::cust_main::Billing>.
2328
2329 =item REALTIME BILLING METHODS
2330
2331 Documentation on realtime billing methods has been moved to
2332 L<FS::cust_main::Billing_Realtime>.
2333
2334 =item remove_cvv
2335
2336 Removes the I<paycvv> field from the database directly.
2337
2338 If there is an error, returns the error, otherwise returns false.
2339
2340 =cut
2341
2342 sub remove_cvv {
2343   die 'cust_main->remove_cvv deprecated';
2344   my $self = shift;
2345   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2346     or return dbh->errstr;
2347   $sth->execute($self->custnum)
2348     or return $sth->errstr;
2349   $self->paycvv('');
2350   '';
2351 }
2352
2353 =item total_owed
2354
2355 Returns the total owed for this customer on all invoices
2356 (see L<FS::cust_bill/owed>).
2357
2358 =cut
2359
2360 sub total_owed {
2361   my $self = shift;
2362   $self->total_owed_date(2145859200); #12/31/2037
2363 }
2364
2365 =item total_owed_date TIME
2366
2367 Returns the total owed for this customer on all invoices with date earlier than
2368 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2369 see L<Time::Local> and L<Date::Parse> for conversion functions.
2370
2371 =cut
2372
2373 sub total_owed_date {
2374   my $self = shift;
2375   my $time = shift;
2376
2377   my $custnum = $self->custnum;
2378
2379   my $owed_sql = FS::cust_bill->owed_sql;
2380
2381   my $sql = "
2382     SELECT SUM($owed_sql) FROM cust_bill
2383       WHERE custnum = $custnum
2384         AND _date <= $time
2385   ";
2386
2387   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2388
2389 }
2390
2391 =item total_owed_pkgnum PKGNUM
2392
2393 Returns the total owed on all invoices for this customer's specific package
2394 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2395
2396 =cut
2397
2398 sub total_owed_pkgnum {
2399   my( $self, $pkgnum ) = @_;
2400   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2401 }
2402
2403 =item total_owed_date_pkgnum TIME PKGNUM
2404
2405 Returns the total owed for this customer's specific package when using
2406 experimental package balances on all invoices with date earlier than
2407 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2408 see L<Time::Local> and L<Date::Parse> for conversion functions.
2409
2410 =cut
2411
2412 sub total_owed_date_pkgnum {
2413   my( $self, $time, $pkgnum ) = @_;
2414
2415   my $total_bill = 0;
2416   foreach my $cust_bill (
2417     grep { $_->_date <= $time }
2418       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2419   ) {
2420     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2421   }
2422   sprintf( "%.2f", $total_bill );
2423
2424 }
2425
2426 =item total_paid
2427
2428 Returns the total amount of all payments.
2429
2430 =cut
2431
2432 sub total_paid {
2433   my $self = shift;
2434   my $total = 0;
2435   $total += $_->paid foreach $self->cust_pay;
2436   sprintf( "%.2f", $total );
2437 }
2438
2439 =item total_unapplied_credits
2440
2441 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2442 customer.  See L<FS::cust_credit/credited>.
2443
2444 =item total_credited
2445
2446 Old name for total_unapplied_credits.  Don't use.
2447
2448 =cut
2449
2450 sub total_credited {
2451   #carp "total_credited deprecated, use total_unapplied_credits";
2452   shift->total_unapplied_credits(@_);
2453 }
2454
2455 sub total_unapplied_credits {
2456   my $self = shift;
2457
2458   my $custnum = $self->custnum;
2459
2460   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2461
2462   my $sql = "
2463     SELECT SUM($unapplied_sql) FROM cust_credit
2464       WHERE custnum = $custnum
2465   ";
2466
2467   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2468
2469 }
2470
2471 =item total_unapplied_credits_pkgnum PKGNUM
2472
2473 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2474 customer.  See L<FS::cust_credit/credited>.
2475
2476 =cut
2477
2478 sub total_unapplied_credits_pkgnum {
2479   my( $self, $pkgnum ) = @_;
2480   my $total_credit = 0;
2481   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2482   sprintf( "%.2f", $total_credit );
2483 }
2484
2485
2486 =item total_unapplied_payments
2487
2488 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2489 See L<FS::cust_pay/unapplied>.
2490
2491 =cut
2492
2493 sub total_unapplied_payments {
2494   my $self = shift;
2495
2496   my $custnum = $self->custnum;
2497
2498   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2499
2500   my $sql = "
2501     SELECT SUM($unapplied_sql) FROM cust_pay
2502       WHERE custnum = $custnum
2503   ";
2504
2505   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2506
2507 }
2508
2509 =item total_unapplied_payments_pkgnum PKGNUM
2510
2511 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2512 specific package when using experimental package balances.  See
2513 L<FS::cust_pay/unapplied>.
2514
2515 =cut
2516
2517 sub total_unapplied_payments_pkgnum {
2518   my( $self, $pkgnum ) = @_;
2519   my $total_unapplied = 0;
2520   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2521   sprintf( "%.2f", $total_unapplied );
2522 }
2523
2524
2525 =item total_unapplied_refunds
2526
2527 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2528 customer.  See L<FS::cust_refund/unapplied>.
2529
2530 =cut
2531
2532 sub total_unapplied_refunds {
2533   my $self = shift;
2534   my $custnum = $self->custnum;
2535
2536   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2537
2538   my $sql = "
2539     SELECT SUM($unapplied_sql) FROM cust_refund
2540       WHERE custnum = $custnum
2541   ";
2542
2543   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2544
2545 }
2546
2547 =item balance
2548
2549 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2550 total_unapplied_credits minus total_unapplied_payments).
2551
2552 =cut
2553
2554 sub balance {
2555   my $self = shift;
2556   $self->balance_date_range;
2557 }
2558
2559 =item balance_date TIME
2560
2561 Returns the balance for this customer, only considering invoices with date
2562 earlier than TIME (total_owed_date minus total_credited minus
2563 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2564 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2565 functions.
2566
2567 =cut
2568
2569 sub balance_date {
2570   my $self = shift;
2571   $self->balance_date_range(shift);
2572 }
2573
2574 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2575
2576 Returns the balance for this customer, optionally considering invoices with
2577 date earlier than START_TIME, and not later than END_TIME
2578 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2579
2580 Times are specified as SQL fragments or numeric
2581 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2582 L<Date::Parse> for conversion functions.  The empty string can be passed
2583 to disable that time constraint completely.
2584
2585 Accepts the same options as L<balance_date_sql>:
2586
2587 =over 4
2588
2589 =item unapplied_date
2590
2591 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2592
2593 =item cutoff
2594
2595 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2596 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2597 range for invoices and I<unapplied> payments, credits, and refunds.
2598
2599 =back
2600
2601 =cut
2602
2603 sub balance_date_range {
2604   my $self = shift;
2605   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2606             ') FROM cust_main WHERE custnum='. $self->custnum;
2607   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2608 }
2609
2610 =item balance_pkgnum PKGNUM
2611
2612 Returns the balance for this customer's specific package when using
2613 experimental package balances (total_owed plus total_unrefunded, minus
2614 total_unapplied_credits minus total_unapplied_payments)
2615
2616 =cut
2617
2618 sub balance_pkgnum {
2619   my( $self, $pkgnum ) = @_;
2620
2621   sprintf( "%.2f",
2622       $self->total_owed_pkgnum($pkgnum)
2623 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2624 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2625     - $self->total_unapplied_credits_pkgnum($pkgnum)
2626     - $self->total_unapplied_payments_pkgnum($pkgnum)
2627   );
2628 }
2629
2630 =item payment_info
2631
2632 Returns a hash of useful information for making a payment.
2633
2634 =over 4
2635
2636 =item balance
2637
2638 Current balance.
2639
2640 =item payby
2641
2642 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2643 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2644 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2645
2646 =back
2647
2648 For credit card transactions:
2649
2650 =over 4
2651
2652 =item card_type 1
2653
2654 =item payname
2655
2656 Exact name on card
2657
2658 =back
2659
2660 For electronic check transactions:
2661
2662 =over 4
2663
2664 =item stateid_state
2665
2666 =back
2667
2668 =cut
2669
2670 #XXX i need to be updated for 4.x+
2671 sub payment_info {
2672   my $self = shift;
2673
2674   my %return = ();
2675
2676   $return{balance} = $self->balance;
2677
2678   $return{payname} = $self->payname
2679                      || ( $self->first. ' '. $self->get('last') );
2680
2681   $return{$_} = $self->bill_location->$_
2682     for qw(address1 address2 city state zip);
2683
2684   $return{payby} = $self->payby;
2685   $return{stateid_state} = $self->stateid_state;
2686
2687   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2688     $return{card_type} = cardtype($self->payinfo);
2689     $return{payinfo} = $self->paymask;
2690
2691     @return{'month', 'year'} = $self->paydate_monthyear;
2692
2693   }
2694
2695   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2696     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2697     $return{payinfo1} = $payinfo1;
2698     $return{payinfo2} = $payinfo2;
2699     $return{paytype}  = $self->paytype;
2700     $return{paystate} = $self->paystate;
2701
2702   }
2703
2704   #doubleclick protection
2705   my $_date = time;
2706   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2707
2708   %return;
2709
2710 }
2711
2712 =item paydate_epoch
2713
2714 Returns the next payment expiration date for this customer. If they have no
2715 payment methods that will expire, returns 0.
2716
2717 =cut
2718
2719 sub paydate_epoch {
2720   my $self = shift;
2721   # filter out the ones that individually return 0, but then return 0 if
2722   # there are no results
2723   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
2724   min( @epochs ) || 0;
2725 }
2726
2727 =item paydate_epoch_sql
2728
2729 Returns an SQL expression to get the next payment expiration date for a
2730 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
2731 dates, so that it's safe to test for "will it expire before date X" for any
2732 date up to then.
2733
2734 =cut
2735
2736 sub paydate_epoch_sql {
2737   my $class = shift;
2738   my $paydate = FS::cust_payby->paydate_epoch_sql;
2739   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
2740 }
2741
2742 sub tax_exemption {
2743   my( $self, $taxname ) = @_;
2744
2745   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
2746                                      'taxname' => $taxname,
2747                                    },
2748           );
2749 }
2750
2751 =item cust_main_exemption
2752
2753 =item invoicing_list
2754
2755 Returns a list of email addresses (with svcnum entries expanded), and the word
2756 'POST' if the customer receives postal invoices.
2757
2758 =cut
2759
2760 sub invoicing_list {
2761   my( $self, $arrayref ) = @_;
2762
2763   if ( $arrayref ) {
2764     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
2765   }
2766
2767   my @emails = $self->invoicing_list_emailonly;
2768   push @emails, 'POST' if $self->get('postal_invoice');
2769
2770   @emails;
2771 }
2772
2773 =item check_invoicing_list ARRAYREF
2774
2775 Checks these arguements as valid input for the invoicing_list method.  If there
2776 is an error, returns the error, otherwise returns false.
2777
2778 =cut
2779
2780 sub check_invoicing_list {
2781   my( $self, $arrayref ) = @_;
2782
2783   foreach my $address ( @$arrayref ) {
2784
2785     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
2786       return 'Can\'t add FAX invoice destination with a blank FAX number.';
2787     }
2788
2789     my $cust_main_invoice = new FS::cust_main_invoice ( {
2790       'custnum' => $self->custnum,
2791       'dest'    => $address,
2792     } );
2793     my $error = $self->custnum
2794                 ? $cust_main_invoice->check
2795                 : $cust_main_invoice->checkdest
2796     ;
2797     return $error if $error;
2798
2799   }
2800
2801   return "Email address required"
2802     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
2803     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
2804
2805   '';
2806 }
2807
2808 =item all_emails
2809
2810 Returns the email addresses of all accounts provisioned for this customer.
2811
2812 =cut
2813
2814 sub all_emails {
2815   my $self = shift;
2816   my %list;
2817   foreach my $cust_pkg ( $self->all_pkgs ) {
2818     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
2819     my @svc_acct =
2820       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2821         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2822           @cust_svc;
2823     $list{$_}=1 foreach map { $_->email } @svc_acct;
2824   }
2825   keys %list;
2826 }
2827
2828 =item invoicing_list_addpost
2829
2830 Adds postal invoicing to this customer.  If this customer is already configured
2831 to receive postal invoices, does nothing.
2832
2833 =cut
2834
2835 sub invoicing_list_addpost {
2836   my $self = shift;
2837   if ( $self->get('postal_invoice') eq '' ) {
2838     $self->set('postal_invoice', 'Y');
2839     my $error = $self->replace;
2840     warn $error if $error; # should fail harder, but this is traditional
2841   }
2842 }
2843
2844 =item invoicing_list_emailonly
2845
2846 Returns the list of email invoice recipients (invoicing_list without non-email
2847 destinations such as POST and FAX).
2848
2849 =cut
2850
2851 sub invoicing_list_emailonly {
2852   my $self = shift;
2853   warn "$me invoicing_list_emailonly called"
2854     if $DEBUG;
2855   return () if !$self->custnum; # not yet inserted
2856   return map { $_->emailaddress }
2857     qsearch({
2858         table     => 'cust_contact',
2859         select    => 'emailaddress',
2860         addl_from => ' JOIN contact USING (contactnum) '.
2861                      ' JOIN contact_email USING (contactnum)',
2862         hashref   => { 'custnum' => $self->custnum, },
2863         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
2864     });
2865 }
2866
2867 =item invoicing_list_emailonly_scalar
2868
2869 Returns the list of email invoice recipients (invoicing_list without non-email
2870 destinations such as POST and FAX) as a comma-separated scalar.
2871
2872 =cut
2873
2874 sub invoicing_list_emailonly_scalar {
2875   my $self = shift;
2876   warn "$me invoicing_list_emailonly_scalar called"
2877     if $DEBUG;
2878   join(', ', $self->invoicing_list_emailonly);
2879 }
2880
2881 =item referral_custnum_cust_main
2882
2883 Returns the customer who referred this customer (or the empty string, if
2884 this customer was not referred).
2885
2886 Note the difference with referral_cust_main method: This method,
2887 referral_custnum_cust_main returns the single customer (if any) who referred
2888 this customer, while referral_cust_main returns an array of customers referred
2889 BY this customer.
2890
2891 =cut
2892
2893 sub referral_custnum_cust_main {
2894   my $self = shift;
2895   return '' unless $self->referral_custnum;
2896   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
2897 }
2898
2899 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
2900
2901 Returns an array of customers referred by this customer (referral_custnum set
2902 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
2903 customers referred by customers referred by this customer and so on, inclusive.
2904 The default behavior is DEPTH 1 (no recursion).
2905
2906 Note the difference with referral_custnum_cust_main method: This method,
2907 referral_cust_main, returns an array of customers referred BY this customer,
2908 while referral_custnum_cust_main returns the single customer (if any) who
2909 referred this customer.
2910
2911 =cut
2912
2913 sub referral_cust_main {
2914   my $self = shift;
2915   my $depth = @_ ? shift : 1;
2916   my $exclude = @_ ? shift : {};
2917
2918   my @cust_main =
2919     map { $exclude->{$_->custnum}++; $_; }
2920       grep { ! $exclude->{ $_->custnum } }
2921         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
2922
2923   if ( $depth > 1 ) {
2924     push @cust_main,
2925       map { $_->referral_cust_main($depth-1, $exclude) }
2926         @cust_main;
2927   }
2928
2929   @cust_main;
2930 }
2931
2932 =item referral_cust_main_ncancelled
2933
2934 Same as referral_cust_main, except only returns customers with uncancelled
2935 packages.
2936
2937 =cut
2938
2939 sub referral_cust_main_ncancelled {
2940   my $self = shift;
2941   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
2942 }
2943
2944 =item referral_cust_pkg [ DEPTH ]
2945
2946 Like referral_cust_main, except returns a flat list of all unsuspended (and
2947 uncancelled) packages for each customer.  The number of items in this list may
2948 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
2949
2950 =cut
2951
2952 sub referral_cust_pkg {
2953   my $self = shift;
2954   my $depth = @_ ? shift : 1;
2955
2956   map { $_->unsuspended_pkgs }
2957     grep { $_->unsuspended_pkgs }
2958       $self->referral_cust_main($depth);
2959 }
2960
2961 =item referring_cust_main
2962
2963 Returns the single cust_main record for the customer who referred this customer
2964 (referral_custnum), or false.
2965
2966 =cut
2967
2968 sub referring_cust_main {
2969   my $self = shift;
2970   return '' unless $self->referral_custnum;
2971   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
2972 }
2973
2974 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
2975
2976 Applies a credit to this customer.  If there is an error, returns the error,
2977 otherwise returns false.
2978
2979 REASON can be a text string, an FS::reason object, or a scalar reference to
2980 a reasonnum.  If a text string, it will be automatically inserted as a new
2981 reason, and a 'reason_type' option must be passed to indicate the
2982 FS::reason_type for the new reason.
2983
2984 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
2985 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
2986 I<commission_pkgnum>.
2987
2988 Any other options are passed to FS::cust_credit::insert.
2989
2990 =cut
2991
2992 sub credit {
2993   my( $self, $amount, $reason, %options ) = @_;
2994
2995   my $cust_credit = new FS::cust_credit {
2996     'custnum' => $self->custnum,
2997     'amount'  => $amount,
2998   };
2999
3000   if ( ref($reason) ) {
3001
3002     if ( ref($reason) eq 'SCALAR' ) {
3003       $cust_credit->reasonnum( $$reason );
3004     } else {
3005       $cust_credit->reasonnum( $reason->reasonnum );
3006     }
3007
3008   } else {
3009     $cust_credit->set('reason', $reason)
3010   }
3011
3012   $cust_credit->$_( delete $options{$_} )
3013     foreach grep exists($options{$_}),
3014               qw( addlinfo eventnum ),
3015               map "commission_$_", qw( agentnum salesnum pkgnum );
3016
3017   $cust_credit->insert(%options);
3018
3019 }
3020
3021 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3022
3023 Creates a one-time charge for this customer.  If there is an error, returns
3024 the error, otherwise returns false.
3025
3026 New-style, with a hashref of options:
3027
3028   my $error = $cust_main->charge(
3029                                   {
3030                                     'amount'     => 54.32,
3031                                     'quantity'   => 1,
3032                                     'start_date' => str2time('7/4/2009'),
3033                                     'pkg'        => 'Description',
3034                                     'comment'    => 'Comment',
3035                                     'additional' => [], #extra invoice detail
3036                                     'classnum'   => 1,  #pkg_class
3037
3038                                     'setuptax'   => '', # or 'Y' for tax exempt
3039
3040                                     'locationnum'=> 1234, # optional
3041
3042                                     #internal taxation
3043                                     'taxclass'   => 'Tax class',
3044
3045                                     #vendor taxation
3046                                     'taxproduct' => 2,  #part_pkg_taxproduct
3047                                     'override'   => {}, #XXX describe
3048
3049                                     #will be filled in with the new object
3050                                     'cust_pkg_ref' => \$cust_pkg,
3051
3052                                     #generate an invoice immediately
3053                                     'bill_now' => 0,
3054                                     'invoice_terms' => '', #with these terms
3055                                   }
3056                                 );
3057
3058 Old-style:
3059
3060   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3061
3062 =cut
3063
3064 #super false laziness w/quotation::charge
3065 sub charge {
3066   my $self = shift;
3067   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3068   my ( $pkg, $comment, $additional );
3069   my ( $setuptax, $taxclass );   #internal taxes
3070   my ( $taxproduct, $override ); #vendor (CCH) taxes
3071   my $no_auto = '';
3072   my $separate_bill = '';
3073   my $cust_pkg_ref = '';
3074   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3075   my $locationnum;
3076   if ( ref( $_[0] ) ) {
3077     $amount     = $_[0]->{amount};
3078     $setup_cost = $_[0]->{setup_cost};
3079     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3080     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3081     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3082     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3083     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3084                                            : '$'. sprintf("%.2f",$amount);
3085     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3086     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3087     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3088     $additional = $_[0]->{additional} || [];
3089     $taxproduct = $_[0]->{taxproductnum};
3090     $override   = { '' => $_[0]->{tax_override} };
3091     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3092     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3093     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3094     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3095     $separate_bill = $_[0]->{separate_bill} || '';
3096   } else { # yuck
3097     $amount     = shift;
3098     $setup_cost = '';
3099     $quantity   = 1;
3100     $start_date = '';
3101     $pkg        = @_ ? shift : 'One-time charge';
3102     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3103     $setuptax   = '';
3104     $taxclass   = @_ ? shift : '';
3105     $additional = [];
3106   }
3107
3108   local $SIG{HUP} = 'IGNORE';
3109   local $SIG{INT} = 'IGNORE';
3110   local $SIG{QUIT} = 'IGNORE';
3111   local $SIG{TERM} = 'IGNORE';
3112   local $SIG{TSTP} = 'IGNORE';
3113   local $SIG{PIPE} = 'IGNORE';
3114
3115   my $oldAutoCommit = $FS::UID::AutoCommit;
3116   local $FS::UID::AutoCommit = 0;
3117   my $dbh = dbh;
3118
3119   my $part_pkg = new FS::part_pkg ( {
3120     'pkg'           => $pkg,
3121     'comment'       => $comment,
3122     'plan'          => 'flat',
3123     'freq'          => 0,
3124     'disabled'      => 'Y',
3125     'classnum'      => ( $classnum ? $classnum : '' ),
3126     'setuptax'      => $setuptax,
3127     'taxclass'      => $taxclass,
3128     'taxproductnum' => $taxproduct,
3129     'setup_cost'    => $setup_cost,
3130   } );
3131
3132   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3133                         ( 0 .. @$additional - 1 )
3134                   ),
3135                   'additional_count' => scalar(@$additional),
3136                   'setup_fee' => $amount,
3137                 );
3138
3139   my $error = $part_pkg->insert( options       => \%options,
3140                                  tax_overrides => $override,
3141                                );
3142   if ( $error ) {
3143     $dbh->rollback if $oldAutoCommit;
3144     return $error;
3145   }
3146
3147   my $pkgpart = $part_pkg->pkgpart;
3148   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3149   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3150     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3151     $error = $type_pkgs->insert;
3152     if ( $error ) {
3153       $dbh->rollback if $oldAutoCommit;
3154       return $error;
3155     }
3156   }
3157
3158   my $cust_pkg = new FS::cust_pkg ( {
3159     'custnum'    => $self->custnum,
3160     'pkgpart'    => $pkgpart,
3161     'quantity'   => $quantity,
3162     'start_date' => $start_date,
3163     'no_auto'    => $no_auto,
3164     'separate_bill' => $separate_bill,
3165     'locationnum'=> $locationnum,
3166   } );
3167
3168   $error = $cust_pkg->insert;
3169   if ( $error ) {
3170     $dbh->rollback if $oldAutoCommit;
3171     return $error;
3172   } elsif ( $cust_pkg_ref ) {
3173     ${$cust_pkg_ref} = $cust_pkg;
3174   }
3175
3176   if ( $bill_now ) {
3177     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3178                              'pkg_list'      => [ $cust_pkg ],
3179                            );
3180     if ( $error ) {
3181       $dbh->rollback if $oldAutoCommit;
3182       return $error;
3183     }
3184   }
3185
3186   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3187   return '';
3188
3189 }
3190
3191 #=item charge_postal_fee
3192 #
3193 #Applies a one time charge this customer.  If there is an error,
3194 #returns the error, returns the cust_pkg charge object or false
3195 #if there was no charge.
3196 #
3197 #=cut
3198 #
3199 # This should be a customer event.  For that to work requires that bill
3200 # also be a customer event.
3201
3202 sub charge_postal_fee {
3203   my $self = shift;
3204
3205   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3206   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3207
3208   my $cust_pkg = new FS::cust_pkg ( {
3209     'custnum'  => $self->custnum,
3210     'pkgpart'  => $pkgpart,
3211     'quantity' => 1,
3212   } );
3213
3214   my $error = $cust_pkg->insert;
3215   $error ? $error : $cust_pkg;
3216 }
3217
3218 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3219
3220 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3221
3222 Optionally, a list or hashref of additional arguments to the qsearch call can
3223 be passed.
3224
3225 =cut
3226
3227 sub cust_bill {
3228   my $self = shift;
3229   my $opt = ref($_[0]) ? shift : { @_ };
3230
3231   #return $self->num_cust_bill unless wantarray || keys %$opt;
3232
3233   $opt->{'table'} = 'cust_bill';
3234   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3235   $opt->{'hashref'}{'custnum'} = $self->custnum;
3236   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3237
3238   map { $_ } #behavior of sort undefined in scalar context
3239     sort { $a->_date <=> $b->_date }
3240       qsearch($opt);
3241 }
3242
3243 =item open_cust_bill
3244
3245 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3246 customer.
3247
3248 =cut
3249
3250 sub open_cust_bill {
3251   my $self = shift;
3252
3253   $self->cust_bill(
3254     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3255     #@_
3256   );
3257
3258 }
3259
3260 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3261
3262 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3263
3264 =cut
3265
3266 sub legacy_cust_bill {
3267   my $self = shift;
3268
3269   #return $self->num_legacy_cust_bill unless wantarray;
3270
3271   map { $_ } #behavior of sort undefined in scalar context
3272     sort { $a->_date <=> $b->_date }
3273       qsearch({ 'table'    => 'legacy_cust_bill',
3274                 'hashref'  => { 'custnum' => $self->custnum, },
3275                 'order_by' => 'ORDER BY _date ASC',
3276              });
3277 }
3278
3279 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3280
3281 Returns all the statements (see L<FS::cust_statement>) for this customer.
3282
3283 Optionally, a list or hashref of additional arguments to the qsearch call can
3284 be passed.
3285
3286 =cut
3287
3288 =item cust_bill_void
3289
3290 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3291
3292 =cut
3293
3294 sub cust_bill_void {
3295   my $self = shift;
3296
3297   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3298   sort { $a->_date <=> $b->_date }
3299     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3300 }
3301
3302 sub cust_statement {
3303   my $self = shift;
3304   my $opt = ref($_[0]) ? shift : { @_ };
3305
3306   #return $self->num_cust_statement unless wantarray || keys %$opt;
3307
3308   $opt->{'table'} = 'cust_statement';
3309   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3310   $opt->{'hashref'}{'custnum'} = $self->custnum;
3311   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3312
3313   map { $_ } #behavior of sort undefined in scalar context
3314     sort { $a->_date <=> $b->_date }
3315       qsearch($opt);
3316 }
3317
3318 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3319
3320 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3321
3322 Optionally, a list or hashref of additional arguments to the qsearch call can
3323 be passed following the SVCDB.
3324
3325 =cut
3326
3327 sub svc_x {
3328   my $self = shift;
3329   my $svcdb = shift;
3330   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3331     warn "$me svc_x requires a svcdb";
3332     return;
3333   }
3334   my $opt = ref($_[0]) ? shift : { @_ };
3335
3336   $opt->{'table'} = $svcdb;
3337   $opt->{'addl_from'} =
3338     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3339     ($opt->{'addl_from'} || '');
3340
3341   my $custnum = $self->custnum;
3342   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3343   my $where = "cust_pkg.custnum = $custnum";
3344
3345   my $extra_sql = $opt->{'extra_sql'} || '';
3346   if ( keys %{ $opt->{'hashref'} } ) {
3347     $extra_sql = " AND $where $extra_sql";
3348   }
3349   else {
3350     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3351       $extra_sql = "WHERE $where AND $1";
3352     }
3353     else {
3354       $extra_sql = "WHERE $where $extra_sql";
3355     }
3356   }
3357   $opt->{'extra_sql'} = $extra_sql;
3358
3359   qsearch($opt);
3360 }
3361
3362 # required for use as an eventtable;
3363 sub svc_acct {
3364   my $self = shift;
3365   $self->svc_x('svc_acct', @_);
3366 }
3367
3368 =item cust_credit
3369
3370 Returns all the credits (see L<FS::cust_credit>) for this customer.
3371
3372 =cut
3373
3374 sub cust_credit {
3375   my $self = shift;
3376
3377   #return $self->num_cust_credit unless wantarray;
3378
3379   map { $_ } #behavior of sort undefined in scalar context
3380     sort { $a->_date <=> $b->_date }
3381       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3382 }
3383
3384 =item cust_credit_pkgnum
3385
3386 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3387 package when using experimental package balances.
3388
3389 =cut
3390
3391 sub cust_credit_pkgnum {
3392   my( $self, $pkgnum ) = @_;
3393   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3394   sort { $a->_date <=> $b->_date }
3395     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3396                               'pkgnum'  => $pkgnum,
3397                             }
3398     );
3399 }
3400
3401 =item cust_credit_void
3402
3403 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3404
3405 =cut
3406
3407 sub cust_credit_void {
3408   my $self = shift;
3409   map { $_ }
3410   sort { $a->_date <=> $b->_date }
3411     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3412 }
3413
3414 =item cust_pay
3415
3416 Returns all the payments (see L<FS::cust_pay>) for this customer.
3417
3418 =cut
3419
3420 sub cust_pay {
3421   my $self = shift;
3422   my $opt = ref($_[0]) ? shift : { @_ };
3423
3424   return $self->num_cust_pay unless wantarray || keys %$opt;
3425
3426   $opt->{'table'} = 'cust_pay';
3427   $opt->{'hashref'}{'custnum'} = $self->custnum;
3428
3429   map { $_ } #behavior of sort undefined in scalar context
3430     sort { $a->_date <=> $b->_date }
3431       qsearch($opt);
3432
3433 }
3434
3435 =item num_cust_pay
3436
3437 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3438 called automatically when the cust_pay method is used in a scalar context.
3439
3440 =cut
3441
3442 sub num_cust_pay {
3443   my $self = shift;
3444   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3445   my $sth = dbh->prepare($sql) or die dbh->errstr;
3446   $sth->execute($self->custnum) or die $sth->errstr;
3447   $sth->fetchrow_arrayref->[0];
3448 }
3449
3450 =item unapplied_cust_pay
3451
3452 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3453
3454 =cut
3455
3456 sub unapplied_cust_pay {
3457   my $self = shift;
3458
3459   $self->cust_pay(
3460     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3461     #@_
3462   );
3463
3464 }
3465
3466 =item cust_pay_pkgnum
3467
3468 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3469 package when using experimental package balances.
3470
3471 =cut
3472
3473 sub cust_pay_pkgnum {
3474   my( $self, $pkgnum ) = @_;
3475   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3476   sort { $a->_date <=> $b->_date }
3477     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3478                            'pkgnum'  => $pkgnum,
3479                          }
3480     );
3481 }
3482
3483 =item cust_pay_void
3484
3485 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3486
3487 =cut
3488
3489 sub cust_pay_void {
3490   my $self = shift;
3491   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3492   sort { $a->_date <=> $b->_date }
3493     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3494 }
3495
3496 =item cust_pay_pending
3497
3498 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3499 (without status "done").
3500
3501 =cut
3502
3503 sub cust_pay_pending {
3504   my $self = shift;
3505   return $self->num_cust_pay_pending unless wantarray;
3506   sort { $a->_date <=> $b->_date }
3507     qsearch( 'cust_pay_pending', {
3508                                    'custnum' => $self->custnum,
3509                                    'status'  => { op=>'!=', value=>'done' },
3510                                  },
3511            );
3512 }
3513
3514 =item cust_pay_pending_attempt
3515
3516 Returns all payment attempts / declined payments for this customer, as pending
3517 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3518 a corresponding payment (see L<FS::cust_pay>).
3519
3520 =cut
3521
3522 sub cust_pay_pending_attempt {
3523   my $self = shift;
3524   return $self->num_cust_pay_pending_attempt unless wantarray;
3525   sort { $a->_date <=> $b->_date }
3526     qsearch( 'cust_pay_pending', {
3527                                    'custnum' => $self->custnum,
3528                                    'status'  => 'done',
3529                                    'paynum'  => '',
3530                                  },
3531            );
3532 }
3533
3534 =item num_cust_pay_pending
3535
3536 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3537 customer (without status "done").  Also called automatically when the
3538 cust_pay_pending method is used in a scalar context.
3539
3540 =cut
3541
3542 sub num_cust_pay_pending {
3543   my $self = shift;
3544   $self->scalar_sql(
3545     " SELECT COUNT(*) FROM cust_pay_pending ".
3546       " WHERE custnum = ? AND status != 'done' ",
3547     $self->custnum
3548   );
3549 }
3550
3551 =item num_cust_pay_pending_attempt
3552
3553 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3554 customer, with status "done" but without a corresp.  Also called automatically when the
3555 cust_pay_pending method is used in a scalar context.
3556
3557 =cut
3558
3559 sub num_cust_pay_pending_attempt {
3560   my $self = shift;
3561   $self->scalar_sql(
3562     " SELECT COUNT(*) FROM cust_pay_pending ".
3563       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3564     $self->custnum
3565   );
3566 }
3567
3568 =item cust_refund
3569
3570 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3571
3572 =cut
3573
3574 sub cust_refund {
3575   my $self = shift;
3576   map { $_ } #return $self->num_cust_refund unless wantarray;
3577   sort { $a->_date <=> $b->_date }
3578     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3579 }
3580
3581 =item display_custnum
3582
3583 Returns the displayed customer number for this customer: agent_custid if
3584 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3585
3586 =cut
3587
3588 sub display_custnum {
3589   my $self = shift;
3590
3591   return $self->agent_custid
3592     if $default_agent_custid && $self->agent_custid;
3593
3594   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3595
3596   if ( $prefix ) {
3597     return $prefix .
3598            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
3599   } elsif ( $custnum_display_length ) {
3600     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
3601   } else {
3602     return $self->custnum;
3603   }
3604 }
3605
3606 =item name
3607
3608 Returns a name string for this customer, either "Company (Last, First)" or
3609 "Last, First".
3610
3611 =cut
3612
3613 sub name {
3614   my $self = shift;
3615   my $name = $self->contact;
3616   $name = $self->company. " ($name)" if $self->company;
3617   $name;
3618 }
3619
3620 =item service_contact
3621
3622 Returns the L<FS::contact> object for this customer that has the 'Service'
3623 contact class, or undef if there is no such contact.  Deprecated; don't use
3624 this in new code.
3625
3626 =cut
3627
3628 sub service_contact {
3629   my $self = shift;
3630   if ( !exists($self->{service_contact}) ) {
3631     my $classnum = $self->scalar_sql(
3632       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
3633     ) || 0; #if it's zero, qsearchs will return nothing
3634     my $cust_contact = qsearchs('cust_contact', {
3635         'classnum' => $classnum,
3636         'custnum'  => $self->custnum,
3637     });
3638     $self->{service_contact} = $cust_contact->contact if $cust_contact;
3639   }
3640   $self->{service_contact};
3641 }
3642
3643 =item ship_name
3644
3645 Returns a name string for this (service/shipping) contact, either
3646 "Company (Last, First)" or "Last, First".
3647
3648 =cut
3649
3650 sub ship_name {
3651   my $self = shift;
3652
3653   my $name = $self->ship_contact;
3654   $name = $self->company. " ($name)" if $self->company;
3655   $name;
3656 }
3657
3658 =item name_short
3659
3660 Returns a name string for this customer, either "Company" or "First Last".
3661
3662 =cut
3663
3664 sub name_short {
3665   my $self = shift;
3666   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
3667 }
3668
3669 =item ship_name_short
3670
3671 Returns a name string for this (service/shipping) contact, either "Company"
3672 or "First Last".
3673
3674 =cut
3675
3676 sub ship_name_short {
3677   my $self = shift;
3678   $self->service_contact
3679     ? $self->ship_contact_firstlast
3680     : $self->name_short
3681 }
3682
3683 =item contact
3684
3685 Returns this customer's full (billing) contact name only, "Last, First"
3686
3687 =cut
3688
3689 sub contact {
3690   my $self = shift;
3691   $self->get('last'). ', '. $self->first;
3692 }
3693
3694 =item ship_contact
3695
3696 Returns this customer's full (shipping) contact name only, "Last, First"
3697
3698 =cut
3699
3700 sub ship_contact {
3701   my $self = shift;
3702   my $contact = $self->service_contact || $self;
3703   $contact->get('last') . ', ' . $contact->get('first');
3704 }
3705
3706 =item contact_firstlast
3707
3708 Returns this customers full (billing) contact name only, "First Last".
3709
3710 =cut
3711
3712 sub contact_firstlast {
3713   my $self = shift;
3714   $self->first. ' '. $self->get('last');
3715 }
3716
3717 =item ship_contact_firstlast
3718
3719 Returns this customer's full (shipping) contact name only, "First Last".
3720
3721 =cut
3722
3723 sub ship_contact_firstlast {
3724   my $self = shift;
3725   my $contact = $self->service_contact || $self;
3726   $contact->get('first') . ' '. $contact->get('last');
3727 }
3728
3729 sub bill_country_full {
3730   my $self = shift;
3731   $self->bill_location->country_full;
3732 }
3733
3734 sub ship_country_full {
3735   my $self = shift;
3736   $self->ship_location->country_full;
3737 }
3738
3739 =item county_state_county [ PREFIX ]
3740
3741 Returns a string consisting of just the county, state and country.
3742
3743 =cut
3744
3745 sub county_state_country {
3746   my $self = shift;
3747   my $locationnum;
3748   if ( @_ && $_[0] && $self->has_ship_address ) {
3749     $locationnum = $self->ship_locationnum;
3750   } else {
3751     $locationnum = $self->bill_locationnum;
3752   }
3753   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
3754   $cust_location->county_state_country;
3755 }
3756
3757 =item geocode DATA_VENDOR
3758
3759 Returns a value for the customer location as encoded by DATA_VENDOR.
3760 Currently this only makes sense for "CCH" as DATA_VENDOR.
3761
3762 =cut
3763
3764 =item cust_status
3765
3766 =item status
3767
3768 Returns a status string for this customer, currently:
3769
3770 =over 4
3771
3772 =item prospect
3773
3774 No packages have ever been ordered.  Displayed as "No packages".
3775
3776 =item ordered
3777
3778 Recurring packages all are new (not yet billed).
3779
3780 =item active
3781
3782 One or more recurring packages is active.
3783
3784 =item inactive
3785
3786 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
3787
3788 =item suspended
3789
3790 All non-cancelled recurring packages are suspended.
3791
3792 =item cancelled
3793
3794 All recurring packages are cancelled.
3795
3796 =back
3797
3798 Behavior of inactive vs. cancelled edge cases can be adjusted with the
3799 cust_main-status_module configuration option.
3800
3801 =cut
3802
3803 sub status { shift->cust_status(@_); }
3804
3805 sub cust_status {
3806   my $self = shift;
3807   for my $status ( FS::cust_main->statuses() ) {
3808     my $method = $status.'_sql';
3809     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
3810     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
3811     $sth->execute( ($self->custnum) x $numnum )
3812       or die "Error executing 'SELECT $sql': ". $sth->errstr;
3813     return $status if $sth->fetchrow_arrayref->[0];
3814   }
3815 }
3816
3817 =item is_status_delay_cancel
3818
3819 Returns true if customer status is 'suspended'
3820 and all suspended cust_pkg return true for
3821 cust_pkg->is_status_delay_cancel.
3822
3823 This is not a real status, this only meant for hacking display
3824 values, because otherwise treating the customer as suspended is
3825 really the whole point of the delay_cancel option.
3826
3827 =cut
3828
3829 sub is_status_delay_cancel {
3830   my ($self) = @_;
3831   return 0 unless $self->status eq 'suspended';
3832   foreach my $cust_pkg ($self->ncancelled_pkgs) {
3833     return 0 unless $cust_pkg->is_status_delay_cancel;
3834   }
3835   return 1;
3836 }
3837
3838 =item ucfirst_cust_status
3839
3840 =item ucfirst_status
3841
3842 Deprecated, use the cust_status_label method instead.
3843
3844 Returns the status with the first character capitalized.
3845
3846 =cut
3847
3848 sub ucfirst_status {
3849   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
3850   local($ucfirst_nowarn) = 1;
3851   shift->ucfirst_cust_status(@_);
3852 }
3853
3854 sub ucfirst_cust_status {
3855   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
3856   my $self = shift;
3857   ucfirst($self->cust_status);
3858 }
3859
3860 =item cust_status_label
3861
3862 =item status_label
3863
3864 Returns the display label for this status.
3865
3866 =cut
3867
3868 sub status_label { shift->cust_status_label(@_); }
3869
3870 sub cust_status_label {
3871   my $self = shift;
3872   __PACKAGE__->statuslabels->{$self->cust_status};
3873 }
3874
3875 =item statuscolor
3876
3877 Returns a hex triplet color string for this customer's status.
3878
3879 =cut
3880
3881 sub statuscolor { shift->cust_statuscolor(@_); }
3882
3883 sub cust_statuscolor {
3884   my $self = shift;
3885   __PACKAGE__->statuscolors->{$self->cust_status};
3886 }
3887
3888 =item tickets [ STATUS ]
3889
3890 Returns an array of hashes representing the customer's RT tickets.
3891
3892 An optional status (or arrayref or hashref of statuses) may be specified.
3893
3894 =cut
3895
3896 sub tickets {
3897   my $self = shift;
3898   my $status = ( @_ && $_[0] ) ? shift : '';
3899
3900   my $num = $conf->config('cust_main-max_tickets') || 10;
3901   my @tickets = ();
3902
3903   if ( $conf->config('ticket_system') ) {
3904     unless ( $conf->config('ticket_system-custom_priority_field') ) {
3905
3906       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
3907                                                         $num,
3908                                                         undef,
3909                                                         $status,
3910                                                       )
3911                   };
3912
3913     } else {
3914
3915       foreach my $priority (
3916         $conf->config('ticket_system-custom_priority_field-values'), ''
3917       ) {
3918         last if scalar(@tickets) >= $num;
3919         push @tickets,
3920           @{ FS::TicketSystem->customer_tickets( $self->custnum,
3921                                                  $num - scalar(@tickets),
3922                                                  $priority,
3923                                                  $status,
3924                                                )
3925            };
3926       }
3927     }
3928   }
3929   (@tickets);
3930 }
3931
3932 =item appointments [ STATUS ]
3933
3934 Returns an array of hashes representing the customer's RT tickets which
3935 are appointments.
3936
3937 =cut
3938
3939 sub appointments {
3940   my $self = shift;
3941   my $status = ( @_ && $_[0] ) ? shift : '';
3942
3943   return () unless $conf->config('ticket_system');
3944
3945   my $queueid = $conf->config('ticket_system-appointment-queueid');
3946
3947   @{ FS::TicketSystem->customer_tickets( $self->custnum,
3948                                          99,
3949                                          undef,
3950                                          $status,
3951                                          $queueid,
3952                                        )
3953   };
3954 }
3955
3956 # Return services representing svc_accts in customer support packages
3957 sub support_services {
3958   my $self = shift;
3959   my %packages = map { $_ => 1 } $conf->config('support_packages');
3960
3961   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
3962     grep { $_->part_svc->svcdb eq 'svc_acct' }
3963     map { $_->cust_svc }
3964     grep { exists $packages{ $_->pkgpart } }
3965     $self->ncancelled_pkgs;
3966
3967 }
3968
3969 # Return a list of latitude/longitude for one of the services (if any)
3970 sub service_coordinates {
3971   my $self = shift;
3972
3973   my @svc_X =
3974     grep { $_->latitude && $_->longitude }
3975     map { $_->svc_x }
3976     map { $_->cust_svc }
3977     $self->ncancelled_pkgs;
3978
3979   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
3980 }
3981
3982 =item masked FIELD
3983
3984 Returns a masked version of the named field
3985
3986 =cut
3987
3988 sub masked {
3989 my ($self,$field) = @_;
3990
3991 # Show last four
3992
3993 'x'x(length($self->getfield($field))-4).
3994   substr($self->getfield($field), (length($self->getfield($field))-4));
3995
3996 }
3997
3998 =item payment_history
3999
4000 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4001 cust_credit and cust_refund objects.  Each hashref has the following fields:
4002
4003 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4004
4005 I<date> - value of _date field, unix timestamp
4006
4007 I<date_pretty> - user-friendly date
4008
4009 I<description> - user-friendly description of item
4010
4011 I<amount> - impact of item on user's balance
4012 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4013 Not to be confused with the native 'amount' field in cust_credit, see below.
4014
4015 I<amount_pretty> - includes money char
4016
4017 I<balance> - customer balance, chronologically as of this item
4018
4019 I<balance_pretty> - includes money char
4020
4021 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4022
4023 I<paid> - amount paid for cust_pay records, undef for other types
4024
4025 I<credit> - amount credited for cust_credit records, undef for other types.
4026 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4027
4028 I<refund> - amount refunded for cust_refund records, undef for other types
4029
4030 The four table-specific keys always have positive values, whether they reflect charges or payments.
4031
4032 The following options may be passed to this method:
4033
4034 I<line_items> - if true, returns charges ('Line item') rather than invoices
4035
4036 I<start_date> - unix timestamp, only include records on or after.
4037 If specified, an item of type 'Previous' will also be included.
4038 It does not have table-specific fields.
4039
4040 I<end_date> - unix timestamp, only include records before
4041
4042 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4043
4044 I<conf> - optional already-loaded FS::Conf object.
4045
4046 =cut
4047
4048 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4049 # and also for sending customer statements, which should both be kept customer-friendly.
4050 # If you add anything that shouldn't be passed on through the API or exposed
4051 # to customers, add a new option to include it, don't include it by default
4052 sub payment_history {
4053   my $self = shift;
4054   my $opt = ref($_[0]) ? $_[0] : { @_ };
4055
4056   my $conf = $$opt{'conf'} || new FS::Conf;
4057   my $money_char = $conf->config("money_char") || '$',
4058
4059   #first load entire history,
4060   #need previous to calculate previous balance
4061   #loading after end_date shouldn't hurt too much?
4062   my @history = ();
4063   if ( $$opt{'line_items'} ) {
4064
4065     foreach my $cust_bill ( $self->cust_bill ) {
4066
4067       push @history, {
4068         'type'        => 'Line item',
4069         'description' => $_->desc( $self->locale ).
4070                            ( $_->sdate && $_->edate
4071                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4072                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4073                                : ''
4074                            ),
4075         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4076         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4077         'date'        => $cust_bill->_date,
4078         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4079       }
4080         foreach $cust_bill->cust_bill_pkg;
4081
4082     }
4083
4084   } else {
4085
4086     push @history, {
4087                      'type'        => 'Invoice',
4088                      'description' => 'Invoice #'. $_->display_invnum,
4089                      'amount'      => sprintf('%.2f', $_->charged ),
4090                      'charged'     => sprintf('%.2f', $_->charged ),
4091                      'date'        => $_->_date,
4092                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4093                    }
4094       foreach $self->cust_bill;
4095
4096   }
4097
4098   push @history, {
4099                    'type'        => 'Payment',
4100                    'description' => 'Payment', #XXX type
4101                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4102                    'paid'        => sprintf('%.2f', $_->paid ),
4103                    'date'        => $_->_date,
4104                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4105                  }
4106     foreach $self->cust_pay;
4107
4108   push @history, {
4109                    'type'        => 'Credit',
4110                    'description' => 'Credit', #more info?
4111                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4112                    'credit'      => sprintf('%.2f', $_->amount ),
4113                    'date'        => $_->_date,
4114                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4115                  }
4116     foreach $self->cust_credit;
4117
4118   push @history, {
4119                    'type'        => 'Refund',
4120                    'description' => 'Refund', #more info?  type, like payment?
4121                    'amount'      => $_->refund,
4122                    'refund'      => $_->refund,
4123                    'date'        => $_->_date,
4124                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4125                  }
4126     foreach $self->cust_refund;
4127
4128   #put it all in chronological order
4129   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4130
4131   #calculate balance, filter items outside date range
4132   my $previous = 0;
4133   my $balance = 0;
4134   my @out = ();
4135   foreach my $item (@history) {
4136     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4137     $balance += $$item{'amount'};
4138     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4139       $previous += $$item{'amount'};
4140       next;
4141     }
4142     $$item{'balance'} = sprintf("%.2f",$balance);
4143     foreach my $key ( qw(amount balance) ) {
4144       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4145     }
4146     push(@out,$item);
4147   }
4148
4149   # start with previous balance, if there was one
4150   if ($previous) {
4151     my $item = {
4152       'type'        => 'Previous',
4153       'description' => 'Previous balance',
4154       'amount'      => sprintf("%.2f",$previous),
4155       'balance'     => sprintf("%.2f",$previous),
4156       'date'        => $$opt{'start_date'},
4157       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4158     };
4159     #false laziness with above
4160     foreach my $key ( qw(amount balance) ) {
4161       $$item{$key.'_pretty'} = $$item{$key};
4162       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4163     }
4164     unshift(@out,$item);
4165   }
4166
4167   @out = reverse @history if $$opt{'reverse_sort'};
4168
4169   return @out;
4170 }
4171
4172 =item save_cust_payby
4173
4174 Saves a new cust_payby for this customer, replacing an existing entry only
4175 in select circumstances.  Does not validate input.
4176
4177 If auto is specified, marks this as the customer's primary method, or the
4178 specified weight.  Existing payment methods have their weight incremented as
4179 appropriate.
4180
4181 If bill_location is specified with auto, also sets location in cust_main.
4182
4183 Will not insert complete duplicates of existing records, or records in which the
4184 only difference from an existing record is to turn off automatic payment (will
4185 return without error.)  Will replace existing records in which the only difference
4186 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4187 Fields marked as preserved are optional, and existing values will not be overwritten with
4188 blanks when replacing.
4189
4190 Accepts the following named parameters:
4191
4192 =over 4
4193
4194 =item payment_payby
4195
4196 either CARD or CHEK
4197
4198 =item auto
4199
4200 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4201
4202 =item weight
4203
4204 optional, set higher than 1 for secondary, etc.
4205
4206 =item payinfo
4207
4208 required
4209
4210 =item paymask
4211
4212 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4213
4214 =item payname
4215
4216 required
4217
4218 =item payip
4219
4220 optional, will be preserved when replacing
4221
4222 =item paydate
4223
4224 CARD only, required
4225
4226 =item bill_location
4227
4228 CARD only, required, FS::cust_location object
4229
4230 =item paystart_month
4231
4232 CARD only, optional, will be preserved when replacing
4233
4234 =item paystart_year
4235
4236 CARD only, optional, will be preserved when replacing
4237
4238 =item payissue
4239
4240 CARD only, optional, will be preserved when replacing
4241
4242 =item paycvv
4243
4244 CARD only, only used if conf cvv-save is set appropriately
4245
4246 =item paytype
4247
4248 CHEK only
4249
4250 =item paystate
4251
4252 CHEK only
4253
4254 =back
4255
4256 =cut
4257
4258 #The code for this option is in place, but it's not currently used
4259 #
4260 # =item replace
4261 #
4262 # existing cust_payby object to be replaced (must match custnum)
4263
4264 # stateid/stateid_state/ss are not currently supported in cust_payby,
4265 # might not even work properly in 4.x, but will need to work here if ever added
4266
4267 sub save_cust_payby {
4268   my $self = shift;
4269   my %opt = @_;
4270
4271   my $old = $opt{'replace'};
4272   my $new = new FS::cust_payby { $old ? $old->hash : () };
4273   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4274   $new->set( 'custnum' => $self->custnum );
4275
4276   my $payby = $opt{'payment_payby'};
4277   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4278
4279   # don't allow turning off auto when replacing
4280   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4281
4282   my @check_existing; # payby relevant to this payment_payby
4283
4284   # set payby based on auto
4285   if ( $payby eq 'CARD' ) {
4286     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4287     @check_existing = qw( CARD DCRD );
4288   } elsif ( $payby eq 'CHEK' ) {
4289     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4290     @check_existing = qw( CHEK DCHK );
4291   }
4292
4293   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4294
4295   # basic fields
4296   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4297   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4298   $new->set( 'payname' => $opt{'payname'} );
4299   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4300
4301   my $conf = new FS::Conf;
4302
4303   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4304   if ( $payby eq 'CARD' &&
4305        grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save') ) {
4306     $new->set( 'paycvv' => $opt{'paycvv'} );
4307   } else {
4308     $new->set( 'paycvv' => '');
4309   }
4310
4311   local $SIG{HUP} = 'IGNORE';
4312   local $SIG{INT} = 'IGNORE';
4313   local $SIG{QUIT} = 'IGNORE';
4314   local $SIG{TERM} = 'IGNORE';
4315   local $SIG{TSTP} = 'IGNORE';
4316   local $SIG{PIPE} = 'IGNORE';
4317
4318   my $oldAutoCommit = $FS::UID::AutoCommit;
4319   local $FS::UID::AutoCommit = 0;
4320   my $dbh = dbh;
4321
4322   # set fields specific to payment_payby
4323   if ( $payby eq 'CARD' ) {
4324     if ($opt{'bill_location'}) {
4325       $opt{'bill_location'}->set('custnum' => $self->custnum);
4326       my $error = $opt{'bill_location'}->find_or_insert;
4327       if ( $error ) {
4328         $dbh->rollback if $oldAutoCommit;
4329         return $error;
4330       }
4331       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4332     }
4333     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4334       $new->set( $field => $opt{$field} );
4335     }
4336   } else {
4337     foreach my $field ( qw(paytype paystate) ) {
4338       $new->set( $field => $opt{$field} );
4339     }
4340   }
4341
4342   # other cust_payby to compare this to
4343   my @existing = $self->cust_payby(@check_existing);
4344
4345   # fields that can overwrite blanks with values, but not values with blanks
4346   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4347
4348   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4349   unless ($old) {
4350     # generally, we don't want to overwrite existing cust_payby with this,
4351     # but we can replace if we're only marking it auto or adding a preserved field
4352     # and we can avoid saving a total duplicate or merely turning off auto
4353 PAYBYLOOP:
4354     foreach my $cust_payby (@existing) {
4355       # check fields that absolutely should not change
4356       foreach my $field ($new->fields) {
4357         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4358         next if grep(/^$field$/, @preserve );
4359         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4360       }
4361       # now check fields that can replace if one value is blank
4362       my $replace = 0;
4363       foreach my $field (@preserve) {
4364         if (
4365           ( $new->get($field) and !$cust_payby->get($field) ) or
4366           ( $cust_payby->get($field) and !$new->get($field) )
4367         ) {
4368           # prevention of overwriting values with blanks happens farther below
4369           $replace = 1;
4370         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4371           next PAYBYLOOP;
4372         }
4373       }
4374       unless ( $replace ) {
4375         # nearly identical, now check weight
4376         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4377           # ignore identical cust_payby, and ignore attempts to turn off auto
4378           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4379           $skip_cust_payby = 1;
4380           last PAYBYLOOP;
4381         }
4382         # otherwise, only change is to mark this as primary
4383       }
4384       # if we got this far, we're definitely replacing
4385       $old = $cust_payby;
4386       last PAYBYLOOP;
4387     } #PAYBYLOOP
4388   }
4389
4390   if ($old) {
4391     $new->set( 'custpaybynum' => $old->custpaybynum );
4392     # don't turn off automatic payment (but allow it to be turned on)
4393     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4394       $opt{'auto'} = 1;
4395       $new->set( 'payby' => $old->payby );
4396       $new->set( 'weight' => 1 );
4397     }
4398     # make sure we're not overwriting values with blanks
4399     foreach my $field (@preserve) {
4400       if ( $old->get($field) and !$new->get($field) ) {
4401         $new->set( $field => $old->get($field) );
4402       }
4403     }
4404   }
4405
4406   # only overwrite cust_main bill_location if auto
4407   if ($opt{'auto'} && $opt{'bill_location'}) {
4408     $self->set('bill_location' => $opt{'bill_location'});
4409     my $error = $self->replace;
4410     if ( $error ) {
4411       $dbh->rollback if $oldAutoCommit;
4412       return $error;
4413     }
4414   }
4415
4416   # done with everything except reweighting and saving cust_payby
4417   # still need to commit changes to cust_main and cust_location
4418   if ($skip_cust_payby) {
4419     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4420     return '';
4421   }
4422
4423   # re-weight existing primary cust_pay for this payby
4424   if ($opt{'auto'}) {
4425     foreach my $cust_payby (@existing) {
4426       # relies on cust_payby return order
4427       last unless $cust_payby->payby !~ /^D/;
4428       last if $cust_payby->weight > 1;
4429       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4430       next if $cust_payby->weight < ($opt{'weight'} || 1);
4431       $cust_payby->weight( $cust_payby->weight + 1 );
4432       my $error = $cust_payby->replace;
4433       if ( $error ) {
4434         $dbh->rollback if $oldAutoCommit;
4435         return "Error reweighting cust_payby: $error";
4436       }
4437     }
4438   }
4439
4440   # finally, save cust_payby
4441   my $error = $old ? $new->replace($old) : $new->insert;
4442   if ( $error ) {
4443     $dbh->rollback if $oldAutoCommit;
4444     return $error;
4445   }
4446
4447   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4448   '';
4449
4450 }
4451
4452 =back
4453
4454 =head1 CLASS METHODS
4455
4456 =over 4
4457
4458 =item statuses
4459
4460 Class method that returns the list of possible status strings for customers
4461 (see L<the status method|/status>).  For example:
4462
4463   @statuses = FS::cust_main->statuses();
4464
4465 =cut
4466
4467 sub statuses {
4468   my $self = shift;
4469   keys %{ $self->statuscolors };
4470 }
4471
4472 =item cust_status_sql
4473
4474 Returns an SQL fragment to determine the status of a cust_main record, as a
4475 string.
4476
4477 =cut
4478
4479 sub cust_status_sql {
4480   my $sql = 'CASE';
4481   for my $status ( FS::cust_main->statuses() ) {
4482     my $method = $status.'_sql';
4483     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4484   }
4485   $sql .= ' END';
4486   return $sql;
4487 }
4488
4489
4490 =item prospect_sql
4491
4492 Returns an SQL expression identifying prospective cust_main records (customers
4493 with no packages ever ordered)
4494
4495 =cut
4496
4497 use vars qw($select_count_pkgs);
4498 $select_count_pkgs =
4499   "SELECT COUNT(*) FROM cust_pkg
4500     WHERE cust_pkg.custnum = cust_main.custnum";
4501
4502 sub select_count_pkgs_sql {
4503   $select_count_pkgs;
4504 }
4505
4506 sub prospect_sql {
4507   " 0 = ( $select_count_pkgs ) ";
4508 }
4509
4510 =item ordered_sql
4511
4512 Returns an SQL expression identifying ordered cust_main records (customers with
4513 no active packages, but recurring packages not yet setup or one time charges
4514 not yet billed).
4515
4516 =cut
4517
4518 sub ordered_sql {
4519   FS::cust_main->none_active_sql.
4520   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4521 }
4522
4523 =item active_sql
4524
4525 Returns an SQL expression identifying active cust_main records (customers with
4526 active recurring packages).
4527
4528 =cut
4529
4530 sub active_sql {
4531   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4532 }
4533
4534 =item none_active_sql
4535
4536 Returns an SQL expression identifying cust_main records with no active
4537 recurring packages.  This includes customers of status prospect, ordered,
4538 inactive, and suspended.
4539
4540 =cut
4541
4542 sub none_active_sql {
4543   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4544 }
4545
4546 =item inactive_sql
4547
4548 Returns an SQL expression identifying inactive cust_main records (customers with
4549 no active recurring packages, but otherwise unsuspended/uncancelled).
4550
4551 =cut
4552
4553 sub inactive_sql {
4554   FS::cust_main->none_active_sql.
4555   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4556 }
4557
4558 =item susp_sql
4559 =item suspended_sql
4560
4561 Returns an SQL expression identifying suspended cust_main records.
4562
4563 =cut
4564
4565
4566 sub suspended_sql { susp_sql(@_); }
4567 sub susp_sql {
4568   FS::cust_main->none_active_sql.
4569   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4570 }
4571
4572 =item cancel_sql
4573 =item cancelled_sql
4574
4575 Returns an SQL expression identifying cancelled cust_main records.
4576
4577 =cut
4578
4579 sub cancel_sql { shift->cancelled_sql(@_); }
4580
4581 =item uncancel_sql
4582 =item uncancelled_sql
4583
4584 Returns an SQL expression identifying un-cancelled cust_main records.
4585
4586 =cut
4587
4588 sub uncancelled_sql { uncancel_sql(@_); }
4589 sub uncancel_sql { "
4590   ( 0 < ( $select_count_pkgs
4591                    AND ( cust_pkg.cancel IS NULL
4592                          OR cust_pkg.cancel = 0
4593                        )
4594         )
4595     OR 0 = ( $select_count_pkgs )
4596   )
4597 "; }
4598
4599 =item balance_sql
4600
4601 Returns an SQL fragment to retreive the balance.
4602
4603 =cut
4604
4605 sub balance_sql { "
4606     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4607         WHERE cust_bill.custnum   = cust_main.custnum     )
4608   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4609         WHERE cust_pay.custnum    = cust_main.custnum     )
4610   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4611         WHERE cust_credit.custnum = cust_main.custnum     )
4612   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4613         WHERE cust_refund.custnum = cust_main.custnum     )
4614 "; }
4615
4616 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4617
4618 Returns an SQL fragment to retreive the balance for this customer, optionally
4619 considering invoices with date earlier than START_TIME, and not
4620 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4621 total_unapplied_payments).
4622
4623 Times are specified as SQL fragments or numeric
4624 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4625 L<Date::Parse> for conversion functions.  The empty string can be passed
4626 to disable that time constraint completely.
4627
4628 Available options are:
4629
4630 =over 4
4631
4632 =item unapplied_date
4633
4634 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4635
4636 =item total
4637
4638 (unused.  obsolete?)
4639 set to true to remove all customer comparison clauses, for totals
4640
4641 =item where
4642
4643 (unused.  obsolete?)
4644 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4645
4646 =item join
4647
4648 (unused.  obsolete?)
4649 JOIN clause (typically used with the total option)
4650
4651 =item cutoff
4652
4653 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4654 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4655 range for invoices and I<unapplied> payments, credits, and refunds.
4656
4657 =back
4658
4659 =cut
4660
4661 sub balance_date_sql {
4662   my( $class, $start, $end, %opt ) = @_;
4663
4664   my $cutoff = $opt{'cutoff'};
4665
4666   my $owed         = FS::cust_bill->owed_sql($cutoff);
4667   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4668   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4669   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4670
4671   my $j = $opt{'join'} || '';
4672
4673   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4674   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4675   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4676   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4677
4678   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4679     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4680     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4681     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4682   ";
4683
4684 }
4685
4686 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4687
4688 Returns an SQL fragment to retreive the total unapplied payments for this
4689 customer, only considering payments with date earlier than START_TIME, and
4690 optionally not later than END_TIME.
4691
4692 Times are specified as SQL fragments or numeric
4693 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4694 L<Date::Parse> for conversion functions.  The empty string can be passed
4695 to disable that time constraint completely.
4696
4697 Available options are:
4698
4699 =cut
4700
4701 sub unapplied_payments_date_sql {
4702   my( $class, $start, $end, %opt ) = @_;
4703
4704   my $cutoff = $opt{'cutoff'};
4705
4706   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4707
4708   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4709                                                           'unapplied_date'=>1 );
4710
4711   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4712 }
4713
4714 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4715
4716 Helper method for balance_date_sql; name (and usage) subject to change
4717 (suggestions welcome).
4718
4719 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4720 cust_refund, cust_credit or cust_pay).
4721
4722 If TABLE is "cust_bill" or the unapplied_date option is true, only
4723 considers records with date earlier than START_TIME, and optionally not
4724 later than END_TIME .
4725
4726 =cut
4727
4728 sub _money_table_where {
4729   my( $class, $table, $start, $end, %opt ) = @_;
4730
4731   my @where = ();
4732   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4733   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4734     push @where, "$table._date <= $start" if defined($start) && length($start);
4735     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4736   }
4737   push @where, @{$opt{'where'}} if $opt{'where'};
4738   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4739
4740   $where;
4741
4742 }
4743
4744 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4745 use FS::cust_main::Search;
4746 sub search {
4747   my $class = shift;
4748   FS::cust_main::Search->search(@_);
4749 }
4750
4751 =back
4752
4753 =head1 SUBROUTINES
4754
4755 =over 4
4756
4757 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4758
4759 Generates a templated notification to the customer (see L<Text::Template>).
4760
4761 OPTIONS is a hash and may include
4762
4763 I<extra_fields> - a hashref of name/value pairs which will be substituted
4764    into the template.  These values may override values mentioned below
4765    and those from the customer record.
4766
4767 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
4768
4769 The following variables are available in the template instead of or in addition
4770 to the fields of the customer record.
4771
4772 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4773
4774 =cut
4775
4776 # a lot like cust_bill::print_latex
4777 sub generate_letter {
4778   my ($self, $template, %options) = @_;
4779
4780   warn "Template $template does not exist" && return
4781     unless $conf->exists($template) || $options{'template_text'};
4782
4783   my $template_source = $options{'template_text'}
4784                         ? [ $options{'template_text'} ]
4785                         : [ map "$_\n", $conf->config($template) ];
4786
4787   my $letter_template = new Text::Template
4788                         ( TYPE       => 'ARRAY',
4789                           SOURCE     => $template_source,
4790                           DELIMITERS => [ '[@--', '--@]' ],
4791                         )
4792     or die "can't create new Text::Template object: Text::Template::ERROR";
4793
4794   $letter_template->compile()
4795     or die "can't compile template: Text::Template::ERROR";
4796
4797   my %letter_data = map { $_ => $self->$_ } $self->fields;
4798
4799   for (keys %{$options{extra_fields}}){
4800     $letter_data{$_} = $options{extra_fields}->{$_};
4801   }
4802
4803   unless(exists($letter_data{returnaddress})){
4804     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4805                                                   $self->agent_template)
4806                      );
4807     if ( length($retadd) ) {
4808       $letter_data{returnaddress} = $retadd;
4809     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4810       $letter_data{returnaddress} =
4811         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4812                           s/$/\\\\\*/;
4813                           $_;
4814                         }
4815                     ( $conf->config('company_name', $self->agentnum),
4816                       $conf->config('company_address', $self->agentnum),
4817                     )
4818         );
4819     } else {
4820       $letter_data{returnaddress} = '~';
4821     }
4822   }
4823
4824   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4825
4826   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4827
4828   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4829
4830   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4831                            DIR      => $dir,
4832                            SUFFIX   => '.eps',
4833                            UNLINK   => 0,
4834                          ) or die "can't open temp file: $!\n";
4835   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4836     or die "can't write temp file: $!\n";
4837   close $lh;
4838   $letter_data{'logo_file'} = $lh->filename;
4839
4840   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4841                            DIR      => $dir,
4842                            SUFFIX   => '.tex',
4843                            UNLINK   => 0,
4844                          ) or die "can't open temp file: $!\n";
4845
4846   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4847   close $fh;
4848   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4849   return ($1, $letter_data{'logo_file'});
4850
4851 }
4852
4853 =item print_ps TEMPLATE
4854
4855 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4856
4857 =cut
4858
4859 sub print_ps {
4860   my $self = shift;
4861   my($file, $lfile) = $self->generate_letter(@_);
4862   my $ps = FS::Misc::generate_ps($file);
4863   unlink($file.'.tex');
4864   unlink($lfile);
4865
4866   $ps;
4867 }
4868
4869 =item print TEMPLATE
4870
4871 Prints the filled in template.
4872
4873 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4874
4875 =cut
4876
4877 sub queueable_print {
4878   my %opt = @_;
4879
4880   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4881     or die "invalid customer number: " . $opt{custnum};
4882
4883 #do not backport this change to 3.x
4884 #  my $error = $self->print( { 'template' => $opt{template} } );
4885   my $error = $self->print( $opt{'template'} );
4886   die $error if $error;
4887 }
4888
4889 sub print {
4890   my ($self, $template) = (shift, shift);
4891   do_print(
4892     [ $self->print_ps($template) ],
4893     'agentnum' => $self->agentnum,
4894   );
4895 }
4896
4897 #these three subs should just go away once agent stuff is all config overrides
4898
4899 sub agent_template {
4900   my $self = shift;
4901   $self->_agent_plandata('agent_templatename');
4902 }
4903
4904 sub agent_invoice_from {
4905   my $self = shift;
4906   $self->_agent_plandata('agent_invoice_from');
4907 }
4908
4909 sub _agent_plandata {
4910   my( $self, $option ) = @_;
4911
4912   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4913   #agent-specific Conf
4914
4915   use FS::part_event::Condition;
4916
4917   my $agentnum = $self->agentnum;
4918
4919   my $regexp = regexp_sql();
4920
4921   my $part_event_option =
4922     qsearchs({
4923       'select'    => 'part_event_option.*',
4924       'table'     => 'part_event_option',
4925       'addl_from' => q{
4926         LEFT JOIN part_event USING ( eventpart )
4927         LEFT JOIN part_event_option AS peo_agentnum
4928           ON ( part_event.eventpart = peo_agentnum.eventpart
4929                AND peo_agentnum.optionname = 'agentnum'
4930                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4931              )
4932         LEFT JOIN part_event_condition
4933           ON ( part_event.eventpart = part_event_condition.eventpart
4934                AND part_event_condition.conditionname = 'cust_bill_age'
4935              )
4936         LEFT JOIN part_event_condition_option
4937           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4938                AND part_event_condition_option.optionname = 'age'
4939              )
4940       },
4941       #'hashref'   => { 'optionname' => $option },
4942       #'hashref'   => { 'part_event_option.optionname' => $option },
4943       'extra_sql' =>
4944         " WHERE part_event_option.optionname = ". dbh->quote($option).
4945         " AND action = 'cust_bill_send_agent' ".
4946         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4947         " AND peo_agentnum.optionname = 'agentnum' ".
4948         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4949         " ORDER BY
4950            CASE WHEN part_event_condition_option.optionname IS NULL
4951            THEN -1
4952            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
4953         " END
4954           , part_event.weight".
4955         " LIMIT 1"
4956     });
4957
4958   unless ( $part_event_option ) {
4959     return $self->agent->invoice_template || ''
4960       if $option eq 'agent_templatename';
4961     return '';
4962   }
4963
4964   $part_event_option->optionvalue;
4965
4966 }
4967
4968 sub process_o2m_qsearch {
4969   my $self = shift;
4970   my $table = shift;
4971   return qsearch($table, @_) unless $table eq 'contact';
4972
4973   my $hashref = shift;
4974   my %hash = %$hashref;
4975   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
4976     or die 'guru meditation #4343';
4977
4978   qsearch({ 'table'     => 'contact',
4979             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
4980             'hashref'   => \%hash,
4981             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
4982                            " cust_contact.custnum = $custnum "
4983          });
4984 }
4985
4986 sub process_o2m_qsearchs {
4987   my $self = shift;
4988   my $table = shift;
4989   return qsearchs($table, @_) unless $table eq 'contact';
4990
4991   my $hashref = shift;
4992   my %hash = %$hashref;
4993   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
4994     or die 'guru meditation #2121';
4995
4996   qsearchs({ 'table'     => 'contact',
4997              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
4998              'hashref'   => \%hash,
4999              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5000                             " cust_contact.custnum = $custnum "
5001           });
5002 }
5003
5004 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5005
5006 Subroutine (not a method), designed to be called from the queue.
5007
5008 Takes a list of options and values.
5009
5010 Pulls up the customer record via the custnum option and calls bill_and_collect.
5011
5012 =cut
5013
5014 sub queued_bill {
5015   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5016
5017   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5018   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5019
5020   #without this errors don't get rolled back
5021   $args{'fatal'} = 1; # runs from job queue, will be caught
5022
5023   $cust_main->bill_and_collect( %args );
5024 }
5025
5026 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5027
5028 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5029 C<collect> part.  This is used in batch tax calculation, where invoice
5030 generation and collection events have to be completely separated.
5031
5032 =cut
5033
5034 sub queued_collect {
5035   my (%args) = @_;
5036   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5037
5038   $cust_main->collect(%args);
5039 }
5040
5041 sub process_bill_and_collect {
5042   my $job = shift;
5043   my $param = shift;
5044   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5045       or die "custnum '$param->{custnum}' not found!\n";
5046   $param->{'job'}   = $job;
5047   $param->{'fatal'} = 1; # runs from job queue, will be caught
5048   $param->{'retry'} = 1;
5049
5050   $cust_main->bill_and_collect( %$param );
5051 }
5052
5053 #starting to take quite a while for big dbs
5054 #   (JRNL: journaled so it only happens once per database)
5055 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5056 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5057 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5058 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5059 # JRNL leading/trailing spaces in first, last, company
5060 # JRNL migrate to cust_payby
5061 # - otaker upgrade?  journal and call it good?  (double check to make sure
5062 #    we're not still setting otaker here)
5063 #
5064 #only going to get worse with new location stuff...
5065
5066 sub _upgrade_data { #class method
5067   my ($class, %opts) = @_;
5068
5069   my @statements = ();
5070
5071   #this seems to be the only expensive one.. why does it take so long?
5072   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5073     push @statements,
5074       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5075     FS::upgrade_journal->set_done('cust_main__signupdate');
5076   }
5077
5078   my $t = time;
5079   foreach my $sql ( @statements ) {
5080     my $sth = dbh->prepare($sql) or die dbh->errstr;
5081     $sth->execute or die $sth->errstr;
5082     #warn ( (time - $t). " seconds\n" );
5083     #$t = time;
5084   }
5085
5086   local($ignore_expired_card) = 1;
5087   local($ignore_banned_card) = 1;
5088   local($skip_fuzzyfiles) = 1;
5089   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5090
5091   FS::cust_main::Location->_upgrade_data(%opts);
5092
5093   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5094
5095     foreach my $cust_main ( qsearch({
5096       'table'     => 'cust_main',
5097       'hashref'   => {},
5098       'extra_sql' => 'WHERE '.
5099                        join(' OR ',
5100                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5101                            qw( first last company )
5102                        ),
5103     }) ) {
5104       my $error = $cust_main->replace;
5105       die $error if $error;
5106     }
5107
5108     FS::upgrade_journal->set_done('cust_main__trimspaces');
5109
5110   }
5111
5112   $class->_upgrade_otaker(%opts);
5113
5114 }
5115
5116 =back
5117
5118 =head1 BUGS
5119
5120 The delete method.
5121
5122 The delete method should possibly take an FS::cust_main object reference
5123 instead of a scalar customer number.
5124
5125 Bill and collect options should probably be passed as references instead of a
5126 list.
5127
5128 There should probably be a configuration file with a list of allowed credit
5129 card types.
5130
5131 No multiple currency support (probably a larger project than just this module).
5132
5133 Birthdates rely on negative epoch values.
5134
5135 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5136
5137 =head1 SEE ALSO
5138
5139 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5140 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5141 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5142
5143 =cut
5144
5145 1;
5146