FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG $me $conf @encrypted_fields
   5              $import $skip_fuzzyfiles $ignore_expired_card );
   6 use vars qw( $realtime_bop_decline_quiet ); #ugh
   7 use Safe;
   8 use Carp;
   9 use Exporter;
  10 BEGIN {
  11   eval "use Time::Local;";
  12   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  13     if $] < 5.006 && !defined($Time::Local::VERSION);
  14   #eval "use Time::Local qw(timelocal timelocal_nocheck);";
  15   eval "use Time::Local qw(timelocal_nocheck);";
  16 }
  17 use Digest::MD5 qw(md5_base64);
  18 use Date::Format;
  19 use Date::Parse;
  20 #use Date::Manip;
  21 use String::Approx qw(amatch);
  22 use Business::CreditCard 0.28;
  23 use Locale::Country;
  24 use FS::UID qw( getotaker dbh );
  25 use FS::Record qw( qsearchs qsearch dbdef );
  26 use FS::Misc qw( send_email );
  27 use FS::Msgcat qw(gettext);
  28 use FS::cust_pkg;
  29 use FS::cust_svc;
  30 use FS::cust_bill;
  31 use FS::cust_bill_pkg;
  32 use FS::cust_pay;
  33 use FS::cust_pay_void;
  34 use FS::cust_credit;
  35 use FS::cust_refund;
  36 use FS::part_referral;
  37 use FS::cust_main_county;
  38 use FS::agent;
  39 use FS::cust_main_invoice;
  40 use FS::cust_credit_bill;
  41 use FS::cust_bill_pay;
  42 use FS::prepay_credit;
  43 use FS::queue;
  44 use FS::part_pkg;
  45 use FS::part_bill_event qw(due_events);
  46 use FS::cust_bill_event;
  47 use FS::cust_tax_exempt;
  48 use FS::cust_tax_exempt_pkg;
  49 use FS::type_pkgs;
  50 use FS::payment_gateway;
  51 use FS::agent_payment_gateway;
  52 use FS::banned_pay;
  53 use FS::payinfo_Mixin;
  54
  55 @ISA = qw( FS::Record FS::payinfo_Mixin );
  56
  57 @EXPORT_OK = qw( smart_search );
  58
  59 $realtime_bop_decline_quiet = 0;
  60
  61 # 1 is mostly method/subroutine entry and options
  62 # 2 traces progress of some operations
  63 # 3 is even more information including possibly sensitive data
  64 $DEBUG = 0;
  65 $me = '[FS::cust_main]';
  66
  67 $import = 0;
  68 $skip_fuzzyfiles = 0;
  69 $ignore_expired_card = 0;
  70
  71 @encrypted_fields = ('payinfo', 'paycvv');
  72
  73 #ask FS::UID to run this stuff for us later
  74 #$FS::UID::callback{'FS::cust_main'} = sub {
  75 install_callback FS::UID sub {
  76   $conf = new FS::Conf;
  77   #yes, need it for stuff below (prolly should be cached)
  78 };
  79
  80 sub _cache {
  81   my $self = shift;
  82   my ( $hashref, $cache ) = @_;
  83   if ( exists $hashref->{'pkgnum'} ) {
  84     #@{ $self->{'_pkgnum'} } = ();
  85     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
  86     $self->{'_pkgnum'} = $subcache;
  87     #push @{ $self->{'_pkgnum'} },
  88     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
  89   }
  90 }
  91
  92 =head1 NAME
  93
  94 FS::cust_main - Object methods for cust_main records
  95
  96 =head1 SYNOPSIS
  97
  98   use FS::cust_main;
  99
 100   $record = new FS::cust_main \%hash;
 101   $record = new FS::cust_main { 'column' => 'value' };
 102
 103   $error = $record->insert;
 104
 105   $error = $new_record->replace($old_record);
 106
 107   $error = $record->delete;
 108
 109   $error = $record->check;
 110
 111   @cust_pkg = $record->all_pkgs;
 112
 113   @cust_pkg = $record->ncancelled_pkgs;
 114
 115   @cust_pkg = $record->suspended_pkgs;
 116
 117   $error = $record->bill;
 118   $error = $record->bill %options;
 119   $error = $record->bill 'time' => $time;
 120
 121   $error = $record->collect;
 122   $error = $record->collect %options;
 123   $error = $record->collect 'invoice_time'   => $time,
 124                           ;
 125
 126 =head1 DESCRIPTION
 127
 128 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 129 FS::Record.  The following fields are currently supported:
 130
 131 =over 4
 132
 133 =item custnum - primary key (assigned automatically for new customers)
 134
 135 =item agentnum - agent (see L<FS::agent>)
 136
 137 =item refnum - Advertising source (see L<FS::part_referral>)
 138
 139 =item first - name
 140
 141 =item last - name
 142
 143 =item ss - social security number (optional)
 144
 145 =item company - (optional)
 146
 147 =item address1
 148
 149 =item address2 - (optional)
 150
 151 =item city
 152
 153 =item county - (optional, see L<FS::cust_main_county>)
 154
 155 =item state - (see L<FS::cust_main_county>)
 156
 157 =item zip
 158
 159 =item country - (see L<FS::cust_main_county>)
 160
 161 =item daytime - phone (optional)
 162
 163 =item night - phone (optional)
 164
 165 =item fax - phone (optional)
 166
 167 =item ship_first - name
 168
 169 =item ship_last - name
 170
 171 =item ship_company - (optional)
 172
 173 =item ship_address1
 174
 175 =item ship_address2 - (optional)
 176
 177 =item ship_city
 178
 179 =item ship_county - (optional, see L<FS::cust_main_county>)
 180
 181 =item ship_state - (see L<FS::cust_main_county>)
 182
 183 =item ship_zip
 184
 185 =item ship_country - (see L<FS::cust_main_county>)
 186
 187 =item ship_daytime - phone (optional)
 188
 189 =item ship_night - phone (optional)
 190
 191 =item ship_fax - phone (optional)
 192
 193 =item payby - Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 194
 195 =item payinfo - Payment Information (See L<FS::payinfo_Mixin> for data format)
 196
 197 =item paymask - Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 198
 199 =item paycvv
 200
 201 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 202
 203 =item paydate - expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 204
 205 =item paystart_month - start date month (maestro/solo cards only)
 206
 207 =item paystart_year - start date year (maestro/solo cards only)
 208
 209 =item payissue - issue number (maestro/solo cards only)
 210
 211 =item payname - name on card or billing name
 212
 213 =item payip - IP address from which payment information was received
 214
 215 =item tax - tax exempt, empty or `Y'
 216
 217 =item otaker - order taker (assigned automatically, see L<FS::UID>)
 218
 219 =item comments - comments (optional)
 220
 221 =item referral_custnum - referring customer number
 222
 223 =item spool_cdr - Enable individual CDR spooling, empty or `Y'
 224
 225 =back
 226
 227 =head1 METHODS
 228
 229 =over 4
 230
 231 =item new HASHREF
 232
 233 Creates a new customer.  To add the customer to the database, see L<"insert">.
 234
 235 Note that this stores the hash reference, not a distinct copy of the hash it
 236 points to.  You can ask the object for a copy with the I<hash> method.
 237
 238 =cut
 239
 240 sub table { 'cust_main'; }
 241
 242 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 243
 244 Adds this customer to the database.  If there is an error, returns the error,
 245 otherwise returns false.
 246
 247 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 248 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 249 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 250 hash reference is equivalent to not supplying this parameter.  There should be
 251 a better explanation of this, but until then, here's an example:
 252
 253   use Tie::RefHash;
 254   tie %hash, 'Tie::RefHash'; #this part is important
 255   %hash = (
 256     $cust_pkg => [ $svc_acct ],
 257     ...
 258   );
 259   $cust_main->insert( \%hash );
 260
 261 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 262 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 263 expected and rollback the entire transaction; it is not necessary to call
 264 check_invoicing_list first.  The invoicing_list is set after the records in the
 265 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 266 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 267
 268   $cust_main->insert( {}, [ $email, 'POST' ] );
 269
 270 Currently available options are: I<depend_jobnum> and I<noexport>.
 271
 272 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 273 on the supplied jobnum (they will not run until the specific job completes).
 274 This can be used to defer provisioning until some action completes (such
 275 as running the customer's credit card successfully).
 276
 277 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 278 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 279 the B<reexport> method.)
 280
 281 =cut
 282
 283 sub insert {
 284   my $self = shift;
 285   my $cust_pkgs = @_ ? shift : {};
 286   my $invoicing_list = @_ ? shift : '';
 287   my %options = @_;
 288   warn "$me insert called with options ".
 289        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 290     if $DEBUG;
 291
 292   local $SIG{HUP} = 'IGNORE';
 293   local $SIG{INT} = 'IGNORE';
 294   local $SIG{QUIT} = 'IGNORE';
 295   local $SIG{TERM} = 'IGNORE';
 296   local $SIG{TSTP} = 'IGNORE';
 297   local $SIG{PIPE} = 'IGNORE';
 298
 299   my $oldAutoCommit = $FS::UID::AutoCommit;
 300   local $FS::UID::AutoCommit = 0;
 301   my $dbh = dbh;
 302
 303   my $prepay_identifier = '';
 304   my( $amount, $seconds ) = ( 0, 0 );
 305   my $payby = '';
 306   if ( $self->payby eq 'PREPAY' ) {
 307
 308     $self->payby('BILL');
 309     $prepay_identifier = $self->payinfo;
 310     $self->payinfo('');
 311
 312     warn "  looking up prepaid card $prepay_identifier\n"
 313       if $DEBUG > 1;
 314
 315     my $error = $self->get_prepay($prepay_identifier, \$amount, \$seconds);
 316     if ( $error ) {
 317       $dbh->rollback if $oldAutoCommit;
 318       #return "error applying prepaid card (transaction rolled back): $error";
 319       return $error;
 320     }
 321
 322     $payby = 'PREP' if $amount;
 323
 324   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD)$/ ) {
 325
 326     $payby = $1;
 327     $self->payby('BILL');
 328     $amount = $self->paid;
 329
 330   }
 331
 332   warn "  inserting $self\n"
 333     if $DEBUG > 1;
 334
 335   $self->signupdate(time) unless $self->signupdate;
 336
 337   my $error = $self->SUPER::insert;
 338   if ( $error ) {
 339     $dbh->rollback if $oldAutoCommit;
 340     #return "inserting cust_main record (transaction rolled back): $error";
 341     return $error;
 342   }
 343
 344   warn "  setting invoicing list\n"
 345     if $DEBUG > 1;
 346
 347   if ( $invoicing_list ) {
 348     $error = $self->check_invoicing_list( $invoicing_list );
 349     if ( $error ) {
 350       $dbh->rollback if $oldAutoCommit;
 351       return "checking invoicing_list (transaction rolled back): $error";
 352     }
 353     $self->invoicing_list( $invoicing_list );
 354   }
 355
 356   if (    $conf->config('cust_main-skeleton_tables')
 357        && $conf->config('cust_main-skeleton_custnum') ) {
 358
 359     warn "  inserting skeleton records\n"
 360       if $DEBUG > 1;
 361
 362     my $error = $self->start_copy_skel;
 363     if ( $error ) {
 364       $dbh->rollback if $oldAutoCommit;
 365       return $error;
 366     }
 367
 368   }
 369
 370   warn "  ordering packages\n"
 371     if $DEBUG > 1;
 372
 373   $error = $self->order_pkgs($cust_pkgs, \$seconds, %options);
 374   if ( $error ) {
 375     $dbh->rollback if $oldAutoCommit;
 376     return $error;
 377   }
 378
 379   if ( $seconds ) {
 380     $dbh->rollback if $oldAutoCommit;
 381     return "No svc_acct record to apply pre-paid time";
 382   }
 383
 384   if ( $amount ) {
 385     warn "  inserting initial $payby payment of $amount\n"
 386       if $DEBUG > 1;
 387     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 388     if ( $error ) {
 389       $dbh->rollback if $oldAutoCommit;
 390       return "inserting payment (transaction rolled back): $error";
 391     }
 392   }
 393
 394   unless ( $import || $skip_fuzzyfiles ) {
 395     warn "  queueing fuzzyfiles update\n"
 396       if $DEBUG > 1;
 397     $error = $self->queue_fuzzyfiles_update;
 398     if ( $error ) {
 399       $dbh->rollback if $oldAutoCommit;
 400       return "updating fuzzy search cache: $error";
 401     }
 402   }
 403
 404   warn "  insert complete; committing transaction\n"
 405     if $DEBUG > 1;
 406
 407   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 408   '';
 409
 410 }
 411
 412 sub start_copy_skel {
 413   my $self = shift;
 414
 415   #'mg_user_preference' => {},
 416   #'mg_user_indicator_profile.user_indicator_profile_id' => { 'mg_profile_indicator.profile_indicator_id' => { 'mg_profile_details.profile_detail_id' }, },
 417   #'mg_watchlist_header.watchlist_header_id' => { 'mg_watchlist_details.watchlist_details_id' },
 418   #'mg_user_grid_header.grid_header_id' => { 'mg_user_grid_details.user_grid_details_id' },
 419   #'mg_portfolio_header.portfolio_header_id' => { 'mg_portfolio_trades.portfolio_trades_id' => { 'mg_portfolio_trades_positions.portfolio_trades_positions_id' } },
 420   my @tables = eval($conf->config_binary('cust_main-skeleton_tables'));
 421   die $@ if $@;
 422
 423   _copy_skel( 'cust_main',                                 #tablename
 424               $conf->config('cust_main-skeleton_custnum'), #sourceid
 425               $self->custnum,                              #destid
 426               @tables,                                     #child tables
 427             );
 428 }
 429
 430 #recursive subroutine, not a method
 431 sub _copy_skel {
 432   my( $table, $sourceid, $destid, %child_tables ) = @_;
 433
 434   my $primary_key;
 435   if ( $table =~ /^(\w+)\.(\w+)$/ ) {
 436     ( $table, $primary_key ) = ( $1, $2 );
 437   } else {
 438     my $dbdef_table = dbdef->table($table);
 439     $primary_key = $dbdef_table->primary_key
 440       or return "$table has no primary key".
 441                 " (or do you need to run dbdef-create?)";
 442   }
 443
 444   warn "  _copy_skel: $table.$primary_key $sourceid to $destid for ".
 445        join (', ', keys %child_tables). "\n"
 446     if $DEBUG > 2;
 447
 448   foreach my $child_table_def ( keys %child_tables ) {
 449
 450     my $child_table;
 451     my $child_pkey = '';
 452     if ( $child_table_def =~ /^(\w+)\.(\w+)$/ ) {
 453       ( $child_table, $child_pkey ) = ( $1, $2 );
 454     } else {
 455       $child_table = $child_table_def;
 456
 457       $child_pkey = dbdef->table($child_table)->primary_key;
 458       #  or return "$table has no primary key".
 459       #            " (or do you need to run dbdef-create?)\n";
 460     }
 461
 462     my $sequence = '';
 463     if ( keys %{ $child_tables{$child_table_def} } ) {
 464
 465       return "$child_table has no primary key".
 466              " (run dbdef-create or try specifying it?)\n"
 467         unless $child_pkey;
 468
 469       #false laziness w/Record::insert and only works on Pg
 470       #refactor the proper last-inserted-id stuff out of Record::insert if this
 471       # ever gets use for anything besides a quick kludge for one customer
 472       my $default = dbdef->table($child_table)->column($child_pkey)->default;
 473       $default =~ /^nextval\(\(?'"?([\w\.]+)"?'/i
 474         or return "can't parse $child_table.$child_pkey default value ".
 475                   " for sequence name: $default";
 476       $sequence = $1;
 477
 478     }
 479
 480     my @sel_columns = grep { $_ ne $primary_key }
 481                            dbdef->table($child_table)->columns;
 482     my $sel_columns = join(', ', @sel_columns );
 483
 484     my @ins_columns = grep { $_ ne $child_pkey } @sel_columns;
 485     my $ins_columns = ' ( '. join(', ', $primary_key, @ins_columns ). ' ) ';
 486     my $placeholders = ' ( ?, '. join(', ', map '?', @ins_columns ). ' ) ';
 487
 488     my $sel_st = "SELECT $sel_columns FROM $child_table".
 489                  " WHERE $primary_key = $sourceid";
 490     warn "    $sel_st\n"
 491       if $DEBUG > 2;
 492     my $sel_sth = dbh->prepare( $sel_st )
 493       or return dbh->errstr;
 494
 495     $sel_sth->execute or return $sel_sth->errstr;
 496
 497     while ( my $row = $sel_sth->fetchrow_hashref ) {
 498
 499       warn "    selected row: ".
 500            join(', ', map { "$_=".$row->{$_} } keys %$row ). "\n"
 501         if $DEBUG > 2;
 502
 503       my $statement =
 504         "INSERT INTO $child_table $ins_columns VALUES $placeholders";
 505       my $ins_sth =dbh->prepare($statement)
 506           or return dbh->errstr;
 507       my @param = ( $destid, map $row->{$_}, @ins_columns );
 508       warn "    $statement: [ ". join(', ', @param). " ]\n"
 509         if $DEBUG > 2;
 510       $ins_sth->execute( @param )
 511         or return $ins_sth->errstr;
 512
 513       #next unless keys %{ $child_tables{$child_table} };
 514       next unless $sequence;
 515
 516       #another section of that laziness
 517       my $seq_sql = "SELECT currval('$sequence')";
 518       my $seq_sth = dbh->prepare($seq_sql) or return dbh->errstr;
 519       $seq_sth->execute or return $seq_sth->errstr;
 520       my $insertid = $seq_sth->fetchrow_arrayref->[0];
 521
 522       # don't drink soap!  recurse!  recurse!  okay!
 523       my $error =
 524         _copy_skel( $child_table_def,
 525                     $row->{$child_pkey}, #sourceid
 526                     $insertid, #destid
 527                     %{ $child_tables{$child_table_def} },
 528                   );
 529       return $error if $error;
 530
 531     }
 532
 533   }
 534
 535   return '';
 536
 537 }
 538
 539 =item order_pkgs HASHREF, [ SECONDSREF, [ , OPTION => VALUE ... ] ]
 540
 541 Like the insert method on an existing record, this method orders a package
 542 and included services atomicaly.  Pass a Tie::RefHash data structure to this
 543 method containing FS::cust_pkg and FS::svc_I<tablename> objects.  There should
 544 be a better explanation of this, but until then, here's an example:
 545
 546   use Tie::RefHash;
 547   tie %hash, 'Tie::RefHash'; #this part is important
 548   %hash = (
 549     $cust_pkg => [ $svc_acct ],
 550     ...
 551   );
 552   $cust_main->order_pkgs( \%hash, \'0', 'noexport'=>1 );
 553
 554 Services can be new, in which case they are inserted, or existing unaudited
 555 services, in which case they are linked to the newly-created package.
 556
 557 Currently available options are: I<depend_jobnum> and I<noexport>.
 558
 559 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 560 on the supplied jobnum (they will not run until the specific job completes).
 561 This can be used to defer provisioning until some action completes (such
 562 as running the customer's credit card successfully).
 563
 564 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 565 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 566 the B<reexport> method for each cust_pkg object.  Using the B<reexport> method
 567 on the cust_main object is not recommended, as existing services will also be
 568 reexported.)
 569
 570 =cut
 571
 572 sub order_pkgs {
 573   my $self = shift;
 574   my $cust_pkgs = shift;
 575   my $seconds = shift;
 576   my %options = @_;
 577   my %svc_options = ();
 578   $svc_options{'depend_jobnum'} = $options{'depend_jobnum'}
 579     if exists $options{'depend_jobnum'};
 580   warn "$me order_pkgs called with options ".
 581        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 582     if $DEBUG;
 583
 584   local $SIG{HUP} = 'IGNORE';
 585   local $SIG{INT} = 'IGNORE';
 586   local $SIG{QUIT} = 'IGNORE';
 587   local $SIG{TERM} = 'IGNORE';
 588   local $SIG{TSTP} = 'IGNORE';
 589   local $SIG{PIPE} = 'IGNORE';
 590
 591   my $oldAutoCommit = $FS::UID::AutoCommit;
 592   local $FS::UID::AutoCommit = 0;
 593   my $dbh = dbh;
 594
 595   local $FS::svc_Common::noexport_hack = 1 if $options{'noexport'};
 596
 597   foreach my $cust_pkg ( keys %$cust_pkgs ) {
 598     $cust_pkg->custnum( $self->custnum );
 599     my $error = $cust_pkg->insert;
 600     if ( $error ) {
 601       $dbh->rollback if $oldAutoCommit;
 602       return "inserting cust_pkg (transaction rolled back): $error";
 603     }
 604     foreach my $svc_something ( @{$cust_pkgs->{$cust_pkg}} ) {
 605       if ( $svc_something->svcnum ) {
 606         my $old_cust_svc = $svc_something->cust_svc;
 607         my $new_cust_svc = new FS::cust_svc { $old_cust_svc->hash };
 608         $new_cust_svc->pkgnum( $cust_pkg->pkgnum);
 609         $error = $new_cust_svc->replace($old_cust_svc);
 610       } else {
 611         $svc_something->pkgnum( $cust_pkg->pkgnum );
 612         if ( $seconds && $$seconds && $svc_something->isa('FS::svc_acct') ) {
 613           $svc_something->seconds( $svc_something->seconds + $$seconds );
 614           $$seconds = 0;
 615         }
 616         $error = $svc_something->insert(%svc_options);
 617       }
 618       if ( $error ) {
 619         $dbh->rollback if $oldAutoCommit;
 620         #return "inserting svc_ (transaction rolled back): $error";
 621         return $error;
 622       }
 623     }
 624   }
 625
 626   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 627   ''; #no error
 628 }
 629
 630 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 631
 632 Recharges this (existing) customer with the specified prepaid card (see
 633 L<FS::prepay_credit>), specified either by I<identifier> or as an
 634 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 635 returns false.
 636
 637 Optionally, four scalar references can be passed as well.  They will have their
 638 values filled in with the amount, number of seconds, and number of upload and
 639 download bytes applied by this prepaid
 640 card.
 641
 642 =cut
 643
 644 sub recharge_prepay {
 645   my( $self, $prepay_credit, $amountref, $secondsref,
 646       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 647
 648   local $SIG{HUP} = 'IGNORE';
 649   local $SIG{INT} = 'IGNORE';
 650   local $SIG{QUIT} = 'IGNORE';
 651   local $SIG{TERM} = 'IGNORE';
 652   local $SIG{TSTP} = 'IGNORE';
 653   local $SIG{PIPE} = 'IGNORE';
 654
 655   my $oldAutoCommit = $FS::UID::AutoCommit;
 656   local $FS::UID::AutoCommit = 0;
 657   my $dbh = dbh;
 658
 659   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 660
 661   my $error = $self->get_prepay($prepay_credit, \$amount,
 662                                 \$seconds, \$upbytes, \$downbytes, \$totalbytes)
 663            || $self->increment_seconds($seconds)
 664            || $self->increment_upbytes($upbytes)
 665            || $self->increment_downbytes($downbytes)
 666            || $self->increment_totalbytes($totalbytes)
 667            || $self->insert_cust_pay_prepay( $amount,
 668                                              ref($prepay_credit)
 669                                                ? $prepay_credit->identifier
 670                                                : $prepay_credit
 671                                            );
 672
 673   if ( $error ) {
 674     $dbh->rollback if $oldAutoCommit;
 675     return $error;
 676   }
 677
 678   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 679   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 680   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 681   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 682   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 683
 684   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 685   '';
 686
 687 }
 688
 689 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ , AMOUNTREF, SECONDSREF
 690
 691 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 692 specified either by I<identifier> or as an FS::prepay_credit object.
 693
 694 References to I<amount> and I<seconds> scalars should be passed as arguments
 695 and will be incremented by the values of the prepaid card.
 696
 697 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 698 check or set this customer's I<agentnum>.
 699
 700 If there is an error, returns the error, otherwise returns false.
 701
 702 =cut
 703
 704
 705 sub get_prepay {
 706   my( $self, $prepay_credit, $amountref, $secondsref,
 707       $upref, $downref, $totalref) = @_;
 708
 709   local $SIG{HUP} = 'IGNORE';
 710   local $SIG{INT} = 'IGNORE';
 711   local $SIG{QUIT} = 'IGNORE';
 712   local $SIG{TERM} = 'IGNORE';
 713   local $SIG{TSTP} = 'IGNORE';
 714   local $SIG{PIPE} = 'IGNORE';
 715
 716   my $oldAutoCommit = $FS::UID::AutoCommit;
 717   local $FS::UID::AutoCommit = 0;
 718   my $dbh = dbh;
 719
 720   unless ( ref($prepay_credit) ) {
 721
 722     my $identifier = $prepay_credit;
 723
 724     $prepay_credit = qsearchs(
 725       'prepay_credit',
 726       { 'identifier' => $prepay_credit },
 727       '',
 728       'FOR UPDATE'
 729     );
 730
 731     unless ( $prepay_credit ) {
 732       $dbh->rollback if $oldAutoCommit;
 733       return "Invalid prepaid card: ". $identifier;
 734     }
 735
 736   }
 737
 738   if ( $prepay_credit->agentnum ) {
 739     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 740       $dbh->rollback if $oldAutoCommit;
 741       return "prepaid card not valid for agent ". $self->agentnum;
 742     }
 743     $self->agentnum($prepay_credit->agentnum);
 744   }
 745
 746   my $error = $prepay_credit->delete;
 747   if ( $error ) {
 748     $dbh->rollback if $oldAutoCommit;
 749     return "removing prepay_credit (transaction rolled back): $error";
 750   }
 751
 752   $$amountref  += $prepay_credit->amount;
 753   $$secondsref += $prepay_credit->seconds;
 754   $$upref      += $prepay_credit->upbytes;
 755   $$downref    += $prepay_credit->downbytes;
 756   $$totalref   += $prepay_credit->totalbytes;
 757
 758   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 759   '';
 760
 761 }
 762
 763 =item increment_upbytes SECONDS
 764
 765 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 766 the specified number of upbytes.  If there is an error, returns the error,
 767 otherwise returns false.
 768
 769 =cut
 770
 771 sub increment_upbytes {
 772   _increment_column( shift, 'upbytes', @_);
 773 }
 774
 775 =item increment_downbytes SECONDS
 776
 777 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 778 the specified number of downbytes.  If there is an error, returns the error,
 779 otherwise returns false.
 780
 781 =cut
 782
 783 sub increment_downbytes {
 784   _increment_column( shift, 'downbytes', @_);
 785 }
 786
 787 =item increment_totalbytes SECONDS
 788
 789 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 790 the specified number of totalbytes.  If there is an error, returns the error,
 791 otherwise returns false.
 792
 793 =cut
 794
 795 sub increment_totalbytes {
 796   _increment_column( shift, 'totalbytes', @_);
 797 }
 798
 799 =item increment_seconds SECONDS
 800
 801 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 802 the specified number of seconds.  If there is an error, returns the error,
 803 otherwise returns false.
 804
 805 =cut
 806
 807 sub increment_seconds {
 808   _increment_column( shift, 'seconds', @_);
 809 }
 810
 811 =item _increment_column AMOUNT
 812
 813 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 814 the specified number of seconds or bytes.  If there is an error, returns
 815 the error, otherwise returns false.
 816
 817 =cut
 818
 819 sub _increment_column {
 820   my( $self, $column, $amount ) = @_;
 821   warn "$me increment_column called: $column, $amount\n"
 822     if $DEBUG;
 823
 824   return '' unless $amount;
 825
 826   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 827                       $self->ncancelled_pkgs;
 828
 829   if ( ! @cust_pkg ) {
 830     return 'No packages with primary or single services found'.
 831            ' to apply pre-paid time';
 832   } elsif ( scalar(@cust_pkg) > 1 ) {
 833     #maybe have a way to specify the package/account?
 834     return 'Multiple packages found to apply pre-paid time';
 835   }
 836
 837   my $cust_pkg = $cust_pkg[0];
 838   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 839     if $DEBUG > 1;
 840
 841   my @cust_svc =
 842     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 843
 844   if ( ! @cust_svc ) {
 845     return 'No account found to apply pre-paid time';
 846   } elsif ( scalar(@cust_svc) > 1 ) {
 847     return 'Multiple accounts found to apply pre-paid time';
 848   }
 849
 850   my $svc_acct = $cust_svc[0]->svc_x;
 851   warn "  found service svcnum ". $svc_acct->pkgnum.
 852        ' ('. $svc_acct->email. ")\n"
 853     if $DEBUG > 1;
 854
 855   $column = "increment_$column";
 856   $svc_acct->$column($amount);
 857
 858 }
 859
 860 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 861
 862 Inserts a prepayment in the specified amount for this customer.  An optional
 863 second argument can specify the prepayment identifier for tracking purposes.
 864 If there is an error, returns the error, otherwise returns false.
 865
 866 =cut
 867
 868 sub insert_cust_pay_prepay {
 869   shift->insert_cust_pay('PREP', @_);
 870 }
 871
 872 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 873
 874 Inserts a cash payment in the specified amount for this customer.  An optional
 875 second argument can specify the payment identifier for tracking purposes.
 876 If there is an error, returns the error, otherwise returns false.
 877
 878 =cut
 879
 880 sub insert_cust_pay_cash {
 881   shift->insert_cust_pay('CASH', @_);
 882 }
 883
 884 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 885
 886 Inserts a Western Union payment in the specified amount for this customer.  An
 887 optional second argument can specify the prepayment identifier for tracking
 888 purposes.  If there is an error, returns the error, otherwise returns false.
 889
 890 =cut
 891
 892 sub insert_cust_pay_west {
 893   shift->insert_cust_pay('WEST', @_);
 894 }
 895
 896 sub insert_cust_pay {
 897   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 898   my $payinfo = scalar(@_) ? shift : '';
 899
 900   my $cust_pay = new FS::cust_pay {
 901     'custnum' => $self->custnum,
 902     'paid'    => sprintf('%.2f', $amount),
 903     #'_date'   => #date the prepaid card was purchased???
 904     'payby'   => $payby,
 905     'payinfo' => $payinfo,
 906   };
 907   $cust_pay->insert;
 908
 909 }
 910
 911 =item reexport
 912
 913 This method is deprecated.  See the I<depend_jobnum> option to the insert and
 914 order_pkgs methods for a better way to defer provisioning.
 915
 916 Re-schedules all exports by calling the B<reexport> method of all associated
 917 packages (see L<FS::cust_pkg>).  If there is an error, returns the error;
 918 otherwise returns false.
 919
 920 =cut
 921
 922 sub reexport {
 923   my $self = shift;
 924
 925   carp "WARNING: FS::cust_main::reexport is deprectated; ".
 926        "use the depend_jobnum option to insert or order_pkgs to delay export";
 927
 928   local $SIG{HUP} = 'IGNORE';
 929   local $SIG{INT} = 'IGNORE';
 930   local $SIG{QUIT} = 'IGNORE';
 931   local $SIG{TERM} = 'IGNORE';
 932   local $SIG{TSTP} = 'IGNORE';
 933   local $SIG{PIPE} = 'IGNORE';
 934
 935   my $oldAutoCommit = $FS::UID::AutoCommit;
 936   local $FS::UID::AutoCommit = 0;
 937   my $dbh = dbh;
 938
 939   foreach my $cust_pkg ( $self->ncancelled_pkgs ) {
 940     my $error = $cust_pkg->reexport;
 941     if ( $error ) {
 942       $dbh->rollback if $oldAutoCommit;
 943       return $error;
 944     }
 945   }
 946
 947   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 948   '';
 949
 950 }
 951
 952 =item delete NEW_CUSTNUM
 953
 954 This deletes the customer.  If there is an error, returns the error, otherwise
 955 returns false.
 956
 957 This will completely remove all traces of the customer record.  This is not
 958 what you want when a customer cancels service; for that, cancel all of the
 959 customer's packages (see L</cancel>).
 960
 961 If the customer has any uncancelled packages, you need to pass a new (valid)
 962 customer number for those packages to be transferred to.  Cancelled packages
 963 will be deleted.  Did I mention that this is NOT what you want when a customer
 964 cancels service and that you really should be looking see L<FS::cust_pkg/cancel>?
 965
 966 You can't delete a customer with invoices (see L<FS::cust_bill>),
 967 or credits (see L<FS::cust_credit>), payments (see L<FS::cust_pay>) or
 968 refunds (see L<FS::cust_refund>).
 969
 970 =cut
 971
 972 sub delete {
 973   my $self = shift;
 974
 975   local $SIG{HUP} = 'IGNORE';
 976   local $SIG{INT} = 'IGNORE';
 977   local $SIG{QUIT} = 'IGNORE';
 978   local $SIG{TERM} = 'IGNORE';
 979   local $SIG{TSTP} = 'IGNORE';
 980   local $SIG{PIPE} = 'IGNORE';
 981
 982   my $oldAutoCommit = $FS::UID::AutoCommit;
 983   local $FS::UID::AutoCommit = 0;
 984   my $dbh = dbh;
 985
 986   if ( $self->cust_bill ) {
 987     $dbh->rollback if $oldAutoCommit;
 988     return "Can't delete a customer with invoices";
 989   }
 990   if ( $self->cust_credit ) {
 991     $dbh->rollback if $oldAutoCommit;
 992     return "Can't delete a customer with credits";
 993   }
 994   if ( $self->cust_pay ) {
 995     $dbh->rollback if $oldAutoCommit;
 996     return "Can't delete a customer with payments";
 997   }
 998   if ( $self->cust_refund ) {
 999     $dbh->rollback if $oldAutoCommit;
1000     return "Can't delete a customer with refunds";
1001   }
1002
1003   my @cust_pkg = $self->ncancelled_pkgs;
1004   if ( @cust_pkg ) {
1005     my $new_custnum = shift;
1006     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1007       $dbh->rollback if $oldAutoCommit;
1008       return "Invalid new customer number: $new_custnum";
1009     }
1010     foreach my $cust_pkg ( @cust_pkg ) {
1011       my %hash = $cust_pkg->hash;
1012       $hash{'custnum'} = $new_custnum;
1013       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1014       my $error = $new_cust_pkg->replace($cust_pkg,
1015                                          options => { $cust_pkg->options },
1016                                         );
1017       if ( $error ) {
1018         $dbh->rollback if $oldAutoCommit;
1019         return $error;
1020       }
1021     }
1022   }
1023   my @cancelled_cust_pkg = $self->all_pkgs;
1024   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1025     my $error = $cust_pkg->delete;
1026     if ( $error ) {
1027       $dbh->rollback if $oldAutoCommit;
1028       return $error;
1029     }
1030   }
1031
1032   foreach my $cust_main_invoice ( #(email invoice destinations, not invoices)
1033     qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } )
1034   ) {
1035     my $error = $cust_main_invoice->delete;
1036     if ( $error ) {
1037       $dbh->rollback if $oldAutoCommit;
1038       return $error;
1039     }
1040   }
1041
1042   my $error = $self->SUPER::delete;
1043   if ( $error ) {
1044     $dbh->rollback if $oldAutoCommit;
1045     return $error;
1046   }
1047
1048   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1049   '';
1050
1051 }
1052
1053 =item replace OLD_RECORD [ INVOICING_LIST_ARYREF ]
1054
1055 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1056 returns the error, otherwise returns false.
1057
1058 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1059 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1060 expected and rollback the entire transaction; it is not necessary to call
1061 check_invoicing_list first.  Here's an example:
1062
1063   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1064
1065 =cut
1066
1067 sub replace {
1068   my $self = shift;
1069   my $old = shift;
1070   my @param = @_;
1071   warn "$me replace called\n"
1072     if $DEBUG;
1073
1074   local $SIG{HUP} = 'IGNORE';
1075   local $SIG{INT} = 'IGNORE';
1076   local $SIG{QUIT} = 'IGNORE';
1077   local $SIG{TERM} = 'IGNORE';
1078   local $SIG{TSTP} = 'IGNORE';
1079   local $SIG{PIPE} = 'IGNORE';
1080
1081   # We absolutely have to have an old vs. new record to make this work.
1082   if (!defined($old)) {
1083     $old = qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
1084   }
1085
1086   my $curuser = $FS::CurrentUser::CurrentUser;
1087   if (    $self->payby eq 'COMP'
1088        && $self->payby ne $old->payby
1089        && ! $curuser->access_right('Complimentary customer')
1090      )
1091   {
1092     return "You are not permitted to create complimentary accounts.";
1093   }
1094
1095   local($ignore_expired_card) = 1
1096     if $old->payby  =~ /^(CARD|DCRD)$/
1097     && $self->payby =~ /^(CARD|DCRD)$/
1098     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1099
1100   my $oldAutoCommit = $FS::UID::AutoCommit;
1101   local $FS::UID::AutoCommit = 0;
1102   my $dbh = dbh;
1103
1104   my $error = $self->SUPER::replace($old);
1105
1106   if ( $error ) {
1107     $dbh->rollback if $oldAutoCommit;
1108     return $error;
1109   }
1110
1111   if ( @param ) { # INVOICING_LIST_ARYREF
1112     my $invoicing_list = shift @param;
1113     $error = $self->check_invoicing_list( $invoicing_list );
1114     if ( $error ) {
1115       $dbh->rollback if $oldAutoCommit;
1116       return $error;
1117     }
1118     $self->invoicing_list( $invoicing_list );
1119   }
1120
1121   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/ &&
1122        grep { $self->get($_) ne $old->get($_) } qw(payinfo paydate payname) ) {
1123     # card/check/lec info has changed, want to retry realtime_ invoice events
1124     my $error = $self->retry_realtime;
1125     if ( $error ) {
1126       $dbh->rollback if $oldAutoCommit;
1127       return $error;
1128     }
1129   }
1130
1131   unless ( $import || $skip_fuzzyfiles ) {
1132     $error = $self->queue_fuzzyfiles_update;
1133     if ( $error ) {
1134       $dbh->rollback if $oldAutoCommit;
1135       return "updating fuzzy search cache: $error";
1136     }
1137   }
1138
1139   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1140   '';
1141
1142 }
1143
1144 =item queue_fuzzyfiles_update
1145
1146 Used by insert & replace to update the fuzzy search cache
1147
1148 =cut
1149
1150 sub queue_fuzzyfiles_update {
1151   my $self = shift;
1152
1153   local $SIG{HUP} = 'IGNORE';
1154   local $SIG{INT} = 'IGNORE';
1155   local $SIG{QUIT} = 'IGNORE';
1156   local $SIG{TERM} = 'IGNORE';
1157   local $SIG{TSTP} = 'IGNORE';
1158   local $SIG{PIPE} = 'IGNORE';
1159
1160   my $oldAutoCommit = $FS::UID::AutoCommit;
1161   local $FS::UID::AutoCommit = 0;
1162   my $dbh = dbh;
1163
1164   my $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
1165   my $error = $queue->insert( map $self->getfield($_),
1166                                   qw(first last company)
1167                             );
1168   if ( $error ) {
1169     $dbh->rollback if $oldAutoCommit;
1170     return "queueing job (transaction rolled back): $error";
1171   }
1172
1173   if ( $self->ship_last ) {
1174     $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
1175     $error = $queue->insert( map $self->getfield("ship_$_"),
1176                                  qw(first last company)
1177                            );
1178     if ( $error ) {
1179       $dbh->rollback if $oldAutoCommit;
1180       return "queueing job (transaction rolled back): $error";
1181     }
1182   }
1183
1184   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1185   '';
1186
1187 }
1188
1189 =item check
1190
1191 Checks all fields to make sure this is a valid customer record.  If there is
1192 an error, returns the error, otherwise returns false.  Called by the insert
1193 and replace methods.
1194
1195 =cut
1196
1197 sub check {
1198   my $self = shift;
1199
1200   warn "$me check BEFORE: \n". $self->_dump
1201     if $DEBUG > 2;
1202
1203   my $error =
1204     $self->ut_numbern('custnum')
1205     || $self->ut_number('agentnum')
1206     || $self->ut_textn('agent_custid')
1207     || $self->ut_number('refnum')
1208     || $self->ut_name('last')
1209     || $self->ut_name('first')
1210     || $self->ut_snumbern('birthdate')
1211     || $self->ut_snumbern('signupdate')
1212     || $self->ut_textn('company')
1213     || $self->ut_text('address1')
1214     || $self->ut_textn('address2')
1215     || $self->ut_text('city')
1216     || $self->ut_textn('county')
1217     || $self->ut_textn('state')
1218     || $self->ut_country('country')
1219     || $self->ut_anything('comments')
1220     || $self->ut_numbern('referral_custnum')
1221   ;
1222   #barf.  need message catalogs.  i18n.  etc.
1223   $error .= "Please select an advertising source."
1224     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1225   return $error if $error;
1226
1227   return "Unknown agent"
1228     unless qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
1229
1230   return "Unknown refnum"
1231     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1232
1233   return "Unknown referring custnum: ". $self->referral_custnum
1234     unless ! $self->referral_custnum
1235            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1236
1237   if ( $self->ss eq '' ) {
1238     $self->ss('');
1239   } else {
1240     my $ss = $self->ss;
1241     $ss =~ s/\D//g;
1242     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1243       or return "Illegal social security number: ". $self->ss;
1244     $self->ss("$1-$2-$3");
1245   }
1246
1247
1248 # bad idea to disable, causes billing to fail because of no tax rates later
1249 #  unless ( $import ) {
1250     unless ( qsearch('cust_main_county', {
1251       'country' => $self->country,
1252       'state'   => '',
1253      } ) ) {
1254       return "Unknown state/county/country: ".
1255         $self->state. "/". $self->county. "/". $self->country
1256         unless qsearch('cust_main_county',{
1257           'state'   => $self->state,
1258           'county'  => $self->county,
1259           'country' => $self->country,
1260         } );
1261     }
1262 #  }
1263
1264   $error =
1265     $self->ut_phonen('daytime', $self->country)
1266     || $self->ut_phonen('night', $self->country)
1267     || $self->ut_phonen('fax', $self->country)
1268     || $self->ut_zip('zip', $self->country)
1269   ;
1270   return $error if $error;
1271
1272   my @addfields = qw(
1273     last first company address1 address2 city county state zip
1274     country daytime night fax
1275   );
1276
1277   if ( defined $self->dbdef_table->column('ship_last') ) {
1278     if ( scalar ( grep { $self->getfield($_) ne $self->getfield("ship_$_") }
1279                        @addfields )
1280          && scalar ( grep { $self->getfield("ship_$_") ne '' } @addfields )
1281        )
1282     {
1283       my $error =
1284         $self->ut_name('ship_last')
1285         || $self->ut_name('ship_first')
1286         || $self->ut_textn('ship_company')
1287         || $self->ut_text('ship_address1')
1288         || $self->ut_textn('ship_address2')
1289         || $self->ut_text('ship_city')
1290         || $self->ut_textn('ship_county')
1291         || $self->ut_textn('ship_state')
1292         || $self->ut_country('ship_country')
1293       ;
1294       return $error if $error;
1295
1296       #false laziness with above
1297       unless ( qsearchs('cust_main_county', {
1298         'country' => $self->ship_country,
1299         'state'   => '',
1300        } ) ) {
1301         return "Unknown ship_state/ship_county/ship_country: ".
1302           $self->ship_state. "/". $self->ship_county. "/". $self->ship_country
1303           unless qsearch('cust_main_county',{
1304             'state'   => $self->ship_state,
1305             'county'  => $self->ship_county,
1306             'country' => $self->ship_country,
1307           } );
1308       }
1309       #eofalse
1310
1311       $error =
1312         $self->ut_phonen('ship_daytime', $self->ship_country)
1313         || $self->ut_phonen('ship_night', $self->ship_country)
1314         || $self->ut_phonen('ship_fax', $self->ship_country)
1315         || $self->ut_zip('ship_zip', $self->ship_country)
1316       ;
1317       return $error if $error;
1318
1319     } else { # ship_ info eq billing info, so don't store dup info in database
1320       $self->setfield("ship_$_", '')
1321         foreach qw( last first company address1 address2 city county state zip
1322                     country daytime night fax );
1323     }
1324   }
1325
1326   #$self->payby =~ /^(CARD|DCRD|CHEK|DCHK|LECB|BILL|COMP|PREPAY|CASH|WEST|MCRD)$/
1327   #  or return "Illegal payby: ". $self->payby;
1328   #$self->payby($1);
1329   FS::payby->can_payby($self->table, $self->payby)
1330     or return "Illegal payby: ". $self->payby;
1331
1332   $error =    $self->ut_numbern('paystart_month')
1333            || $self->ut_numbern('paystart_year')
1334            || $self->ut_numbern('payissue')
1335   ;
1336   return $error if $error;
1337
1338   if ( $self->payip eq '' ) {
1339     $self->payip('');
1340   } else {
1341     $error = $self->ut_ip('payip');
1342     return $error if $error;
1343   }
1344
1345   # If it is encrypted and the private key is not availaible then we can't
1346   # check the credit card.
1347
1348   my $check_payinfo = 1;
1349
1350   if ($self->is_encrypted($self->payinfo)) {
1351     $check_payinfo = 0;
1352   }
1353
1354   if ( $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
1355
1356     my $payinfo = $self->payinfo;
1357     $payinfo =~ s/\D//g;
1358     $payinfo =~ /^(\d{13,16})$/
1359       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1360     $payinfo = $1;
1361     $self->payinfo($payinfo);
1362     validate($payinfo)
1363       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1364
1365     return gettext('unknown_card_type')
1366       if cardtype($self->payinfo) eq "Unknown";
1367
1368     my $ban = qsearchs('banned_pay', $self->_banned_pay_hashref);
1369     if ( $ban ) {
1370       return 'Banned credit card: banned on '.
1371              time2str('%a %h %o at %r', $ban->_date).
1372              ' by '. $ban->otaker.
1373              ' (ban# '. $ban->bannum. ')';
1374     }
1375
1376     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1377       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1378         $self->paycvv =~ /^(\d{4})$/
1379           or return "CVV2 (CID) for American Express cards is four digits.";
1380         $self->paycvv($1);
1381       } else {
1382         $self->paycvv =~ /^(\d{3})$/
1383           or return "CVV2 (CVC2/CID) is three digits.";
1384         $self->paycvv($1);
1385       }
1386     } else {
1387       $self->paycvv('');
1388     }
1389
1390     my $cardtype = cardtype($payinfo);
1391     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1392
1393       return "Start date or issue number is required for $cardtype cards"
1394         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1395
1396       return "Start month must be between 1 and 12"
1397         if $self->paystart_month
1398            and $self->paystart_month < 1 || $self->paystart_month > 12;
1399
1400       return "Start year must be 1990 or later"
1401         if $self->paystart_year
1402            and $self->paystart_year < 1990;
1403
1404       return "Issue number must be beween 1 and 99"
1405         if $self->payissue
1406           and $self->payissue < 1 || $self->payissue > 99;
1407
1408     } else {
1409       $self->paystart_month('');
1410       $self->paystart_year('');
1411       $self->payissue('');
1412     }
1413
1414   } elsif ( $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
1415
1416     my $payinfo = $self->payinfo;
1417     $payinfo =~ s/[^\d\@]//g;
1418     if ( $conf->exists('echeck-nonus') ) {
1419       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@aba';
1420       $payinfo = "$1\@$2";
1421     } else {
1422       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1423       $payinfo = "$1\@$2";
1424     }
1425     $self->payinfo($payinfo);
1426     $self->paycvv('');
1427
1428     my $ban = qsearchs('banned_pay', $self->_banned_pay_hashref);
1429     if ( $ban ) {
1430       return 'Banned ACH account: banned on '.
1431              time2str('%a %h %o at %r', $ban->_date).
1432              ' by '. $ban->otaker.
1433              ' (ban# '. $ban->bannum. ')';
1434     }
1435
1436   } elsif ( $self->payby eq 'LECB' ) {
1437
1438     my $payinfo = $self->payinfo;
1439     $payinfo =~ s/\D//g;
1440     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1441     $payinfo = $1;
1442     $self->payinfo($payinfo);
1443     $self->paycvv('');
1444
1445   } elsif ( $self->payby eq 'BILL' ) {
1446
1447     $error = $self->ut_textn('payinfo');
1448     return "Illegal P.O. number: ". $self->payinfo if $error;
1449     $self->paycvv('');
1450
1451   } elsif ( $self->payby eq 'COMP' ) {
1452
1453     my $curuser = $FS::CurrentUser::CurrentUser;
1454     if (    ! $self->custnum
1455          && ! $curuser->access_right('Complimentary customer')
1456        )
1457     {
1458       return "You are not permitted to create complimentary accounts."
1459     }
1460
1461     $error = $self->ut_textn('payinfo');
1462     return "Illegal comp account issuer: ". $self->payinfo if $error;
1463     $self->paycvv('');
1464
1465   } elsif ( $self->payby eq 'PREPAY' ) {
1466
1467     my $payinfo = $self->payinfo;
1468     $payinfo =~ s/\W//g; #anything else would just confuse things
1469     $self->payinfo($payinfo);
1470     $error = $self->ut_alpha('payinfo');
1471     return "Illegal prepayment identifier: ". $self->payinfo if $error;
1472     return "Unknown prepayment identifier"
1473       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
1474     $self->paycvv('');
1475
1476   }
1477
1478   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
1479     return "Expiration date required"
1480       unless $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD)$/;
1481     $self->paydate('');
1482   } else {
1483     my( $m, $y );
1484     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
1485       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
1486     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
1487       ( $m, $y ) = ( $3, "20$2" );
1488     } else {
1489       return "Illegal expiration date: ". $self->paydate;
1490     }
1491     $self->paydate("$y-$m-01");
1492     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
1493     return gettext('expired_card')
1494       if !$import
1495       && !$ignore_expired_card
1496       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
1497   }
1498
1499   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
1500        ( ! $conf->exists('require_cardname')
1501          || $self->payby !~ /^(CARD|DCRD)$/  )
1502   ) {
1503     $self->payname( $self->first. " ". $self->getfield('last') );
1504   } else {
1505     $self->payname =~ /^([\w \,\.\-\'\&]+)$/
1506       or return gettext('illegal_name'). " payname: ". $self->payname;
1507     $self->payname($1);
1508   }
1509
1510   foreach my $flag (qw( tax spool_cdr )) {
1511     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
1512     $self->$flag($1);
1513   }
1514
1515   $self->otaker(getotaker) unless $self->otaker;
1516
1517   warn "$me check AFTER: \n". $self->_dump
1518     if $DEBUG > 2;
1519
1520   $self->SUPER::check;
1521 }
1522
1523 =item all_pkgs
1524
1525 Returns all packages (see L<FS::cust_pkg>) for this customer.
1526
1527 =cut
1528
1529 sub all_pkgs {
1530   my $self = shift;
1531
1532   return $self->num_pkgs unless wantarray;
1533
1534   my @cust_pkg = ();
1535   if ( $self->{'_pkgnum'} ) {
1536     @cust_pkg = values %{ $self->{'_pkgnum'}->cache };
1537   } else {
1538     @cust_pkg = qsearch( 'cust_pkg', { 'custnum' => $self->custnum });
1539   }
1540
1541   sort sort_packages @cust_pkg;
1542 }
1543
1544 =item ncancelled_pkgs
1545
1546 Returns all non-cancelled packages (see L<FS::cust_pkg>) for this customer.
1547
1548 =cut
1549
1550 sub ncancelled_pkgs {
1551   my $self = shift;
1552
1553   return $self->num_ncancelled_pkgs unless wantarray;
1554
1555   my @cust_pkg = ();
1556   if ( $self->{'_pkgnum'} ) {
1557
1558     @cust_pkg = grep { ! $_->getfield('cancel') }
1559                 values %{ $self->{'_pkgnum'}->cache };
1560
1561   } else {
1562
1563     @cust_pkg =
1564       qsearch( 'cust_pkg', {
1565                              'custnum' => $self->custnum,
1566                              'cancel'  => '',
1567                            });
1568     push @cust_pkg,
1569       qsearch( 'cust_pkg', {
1570                              'custnum' => $self->custnum,
1571                              'cancel'  => 0,
1572                            });
1573   }
1574
1575   sort sort_packages @cust_pkg;
1576
1577 }
1578
1579 # This should be generalized to use config options to determine order.
1580 sub sort_packages {
1581   if ( $a->get('cancel') and $b->get('cancel') ) {
1582     $a->pkgnum <=> $b->pkgnum;
1583   } elsif ( $a->get('cancel') or $b->get('cancel') ) {
1584     return -1 if $b->get('cancel');
1585     return  1 if $a->get('cancel');
1586     return 0;
1587   } else {
1588     $a->pkgnum <=> $b->pkgnum;
1589   }
1590 }
1591
1592 =item suspended_pkgs
1593
1594 Returns all suspended packages (see L<FS::cust_pkg>) for this customer.
1595
1596 =cut
1597
1598 sub suspended_pkgs {
1599   my $self = shift;
1600   grep { $_->susp } $self->ncancelled_pkgs;
1601 }
1602
1603 =item unflagged_suspended_pkgs
1604
1605 Returns all unflagged suspended packages (see L<FS::cust_pkg>) for this
1606 customer (thouse packages without the `manual_flag' set).
1607
1608 =cut
1609
1610 sub unflagged_suspended_pkgs {
1611   my $self = shift;
1612   return $self->suspended_pkgs
1613     unless dbdef->table('cust_pkg')->column('manual_flag');
1614   grep { ! $_->manual_flag } $self->suspended_pkgs;
1615 }
1616
1617 =item unsuspended_pkgs
1618
1619 Returns all unsuspended (and uncancelled) packages (see L<FS::cust_pkg>) for
1620 this customer.
1621
1622 =cut
1623
1624 sub unsuspended_pkgs {
1625   my $self = shift;
1626   grep { ! $_->susp } $self->ncancelled_pkgs;
1627 }
1628
1629 =item num_cancelled_pkgs
1630
1631 Returns the number of cancelled packages (see L<FS::cust_pkg>) for this
1632 customer.
1633
1634 =cut
1635
1636 sub num_cancelled_pkgs {
1637   shift->num_pkgs("cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0");
1638 }
1639
1640 sub num_ncancelled_pkgs {
1641   shift->num_pkgs("( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )");
1642 }
1643
1644 sub num_pkgs {
1645   my( $self, $sql ) = @_;
1646   $sql = "AND $sql" if $sql && $sql !~ /^\s*$/ && $sql !~ /^\s*AND/i;
1647   my $sth = dbh->prepare(
1648     "SELECT COUNT(*) FROM cust_pkg WHERE custnum = ? $sql"
1649   ) or die dbh->errstr;
1650   $sth->execute($self->custnum) or die $sth->errstr;
1651   $sth->fetchrow_arrayref->[0];
1652 }
1653
1654 =item unsuspend
1655
1656 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
1657 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
1658 on success or a list of errors.
1659
1660 =cut
1661
1662 sub unsuspend {
1663   my $self = shift;
1664   grep { $_->unsuspend } $self->suspended_pkgs;
1665 }
1666
1667 =item suspend
1668
1669 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
1670
1671 Returns a list: an empty list on success or a list of errors.
1672
1673 =cut
1674
1675 sub suspend {
1676   my $self = shift;
1677   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
1678 }
1679
1680 =item suspend_if_pkgpart PKGPART [ , PKGPART ... ]
1681
1682 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
1683 PKGPARTs (see L<FS::part_pkg>).
1684
1685 Returns a list: an empty list on success or a list of errors.
1686
1687 =cut
1688
1689 sub suspend_if_pkgpart {
1690   my $self = shift;
1691   my (@pkgparts, %opt);
1692   if (ref($_[0]) eq 'HASH'){
1693     @pkgparts = @{$_[0]{pkgparts}};
1694     %opt      = %{$_[0]};
1695   }else{
1696     @pkgparts = @_;
1697   }
1698   grep { $_->suspend(%opt) }
1699     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
1700       $self->unsuspended_pkgs;
1701 }
1702
1703 =item suspend_unless_pkgpart PKGPART [ , PKGPART ... ]
1704
1705 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
1706 listed PKGPARTs (see L<FS::part_pkg>).
1707
1708 Returns a list: an empty list on success or a list of errors.
1709
1710 =cut
1711
1712 sub suspend_unless_pkgpart {
1713   my $self = shift;
1714   my (@pkgparts, %opt);
1715   if (ref($_[0]) eq 'HASH'){
1716     @pkgparts = @{$_[0]{pkgparts}};
1717     %opt      = %{$_[0]};
1718   }else{
1719     @pkgparts = @_;
1720   }
1721   grep { $_->suspend(%opt) }
1722     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
1723       $self->unsuspended_pkgs;
1724 }
1725
1726 =item cancel [ OPTION => VALUE ... ]
1727
1728 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
1729
1730 Available options are: I<quiet>, I<reasonnum>, and I<ban>
1731
1732 I<quiet> can be set true to supress email cancellation notices.
1733
1734 # I<reasonnum> can be set to a cancellation reason (see L<FS::cancel_reason>)
1735
1736 I<ban> can be set true to ban this customer's credit card or ACH information,
1737 if present.
1738
1739 Always returns a list: an empty list on success or a list of errors.
1740
1741 =cut
1742
1743 sub cancel {
1744   my $self = shift;
1745   my %opt = @_;
1746
1747   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
1748
1749     #should try decryption (we might have the private key)
1750     # and if not maybe queue a job for the server that does?
1751     return ( "Can't (yet) ban encrypted credit cards" )
1752       if $self->is_encrypted($self->payinfo);
1753
1754     my $ban = new FS::banned_pay $self->_banned_pay_hashref;
1755     my $error = $ban->insert;
1756     return ( $error ) if $error;
1757
1758   }
1759
1760   grep { $_ } map { $_->cancel(@_) } $self->ncancelled_pkgs;
1761 }
1762
1763 sub _banned_pay_hashref {
1764   my $self = shift;
1765
1766   my %payby2ban = (
1767     'CARD' => 'CARD',
1768     'DCRD' => 'CARD',
1769     'CHEK' => 'CHEK',
1770     'DCHK' => 'CHEK'
1771   );
1772
1773   {
1774     'payby'   => $payby2ban{$self->payby},
1775     'payinfo' => md5_base64($self->payinfo),
1776     #don't ever *search* on reason! #'reason'  =>
1777   };
1778 }
1779
1780 =item notes
1781
1782 Returns all notes (see L<FS::cust_main_note>) for this customer.
1783
1784 =cut
1785
1786 sub notes {
1787   my $self = shift;
1788   #order by?
1789   qsearch( 'cust_main_note',
1790            { 'custnum' => $self->custnum },
1791            '',
1792            'ORDER BY _DATE DESC'
1793          );
1794 }
1795
1796 =item agent
1797
1798 Returns the agent (see L<FS::agent>) for this customer.
1799
1800 =cut
1801
1802 sub agent {
1803   my $self = shift;
1804   qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
1805 }
1806
1807 =item bill OPTIONS
1808
1809 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
1810 conjunction with the collect method.
1811
1812 Options are passed as name-value pairs.
1813
1814 Currently available options are:
1815
1816 resetup - if set true, re-charges setup fees.
1817
1818 time - bills the customer as if it were that time.  Specified as a UNIX
1819 timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and
1820 L<Date::Parse> for conversion functions.  For example:
1821
1822  use Date::Parse;
1823  ...
1824  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
1825
1826
1827 If there is an error, returns the error, otherwise returns false.
1828
1829 =cut
1830
1831 sub bill {
1832   my( $self, %options ) = @_;
1833   return '' if $self->payby eq 'COMP';
1834   warn "$me bill customer ". $self->custnum. "\n"
1835     if $DEBUG;
1836
1837   my $time = $options{'time'} || time;
1838
1839   my $error;
1840
1841   #put below somehow?
1842   local $SIG{HUP} = 'IGNORE';
1843   local $SIG{INT} = 'IGNORE';
1844   local $SIG{QUIT} = 'IGNORE';
1845   local $SIG{TERM} = 'IGNORE';
1846   local $SIG{TSTP} = 'IGNORE';
1847   local $SIG{PIPE} = 'IGNORE';
1848
1849   my $oldAutoCommit = $FS::UID::AutoCommit;
1850   local $FS::UID::AutoCommit = 0;
1851   my $dbh = dbh;
1852
1853   $self->select_for_update; #mutex
1854
1855   #create a new invoice
1856   #(we'll remove it later if it doesn't actually need to be generated [contains
1857   # no line items] and we're inside a transaciton so nothing else will see it)
1858   my $cust_bill = new FS::cust_bill ( {
1859     'custnum' => $self->custnum,
1860     '_date'   => $time,
1861     #'charged' => $charged,
1862     'charged' => 0,
1863   } );
1864   $error = $cust_bill->insert;
1865   if ( $error ) {
1866     $dbh->rollback if $oldAutoCommit;
1867     return "can't create invoice for customer #". $self->custnum. ": $error";
1868   }
1869   my $invnum = $cust_bill->invnum;
1870
1871   ###
1872   # find the packages which are due for billing, find out how much they are
1873   # & generate invoice database.
1874   ###
1875
1876   my( $total_setup, $total_recur ) = ( 0, 0 );
1877   my %tax;
1878   my @precommit_hooks = ();
1879
1880   foreach my $cust_pkg (
1881     qsearch('cust_pkg', { 'custnum' => $self->custnum } )
1882   ) {
1883
1884     #NO!! next if $cust_pkg->cancel;
1885     next if $cust_pkg->getfield('cancel');
1886
1887     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
1888
1889     #? to avoid use of uninitialized value errors... ?
1890     $cust_pkg->setfield('bill', '')
1891       unless defined($cust_pkg->bill);
1892
1893     my $part_pkg = $cust_pkg->part_pkg;
1894
1895     my %hash = $cust_pkg->hash;
1896     my $old_cust_pkg = new FS::cust_pkg \%hash;
1897
1898     my @details = ();
1899
1900     ###
1901     # bill setup
1902     ###
1903
1904     my $setup = 0;
1905     if ( !$cust_pkg->setup || $options{'resetup'} ) {
1906
1907       warn "    bill setup\n" if $DEBUG > 1;
1908
1909       $setup = eval { $cust_pkg->calc_setup( $time, \@details ) };
1910       if ( $@ ) {
1911         $dbh->rollback if $oldAutoCommit;
1912         return "$@ running calc_setup for $cust_pkg\n";
1913       }
1914
1915       $cust_pkg->setfield('setup', $time) unless $cust_pkg->setup;
1916     }
1917
1918     ###
1919     # bill recurring fee
1920     ###
1921
1922     my $recur = 0;
1923     my $sdate;
1924     if ( $part_pkg->getfield('freq') ne '0' &&
1925          ! $cust_pkg->getfield('susp') &&
1926          ( $cust_pkg->getfield('bill') || 0 ) <= $time
1927     ) {
1928
1929       warn "    bill recur\n" if $DEBUG > 1;
1930
1931       # XXX shared with $recur_prog
1932       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1933
1934       #over two params!  lets at least switch to a hashref for the rest...
1935       my %param = ( 'precommit_hooks' => \@precommit_hooks, );
1936
1937       $recur = eval { $cust_pkg->calc_recur( \$sdate, \@details, \%param ) };
1938       if ( $@ ) {
1939         $dbh->rollback if $oldAutoCommit;
1940         return "$@ running calc_recur for $cust_pkg\n";
1941       }
1942
1943       #change this bit to use Date::Manip? CAREFUL with timezones (see
1944       # mailing list archive)
1945       my ($sec,$min,$hour,$mday,$mon,$year) =
1946         (localtime($sdate) )[0,1,2,3,4,5];
1947
1948       #pro-rating magic - if $recur_prog fiddles $sdate, want to use that
1949       # only for figuring next bill date, nothing else, so, reset $sdate again
1950       # here
1951       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1952       $cust_pkg->last_bill($sdate)
1953         if $cust_pkg->dbdef_table->column('last_bill');
1954
1955       if ( $part_pkg->freq =~ /^\d+$/ ) {
1956         $mon += $part_pkg->freq;
1957         until ( $mon < 12 ) { $mon -= 12; $year++; }
1958       } elsif ( $part_pkg->freq =~ /^(\d+)w$/ ) {
1959         my $weeks = $1;
1960         $mday += $weeks * 7;
1961       } elsif ( $part_pkg->freq =~ /^(\d+)d$/ ) {
1962         my $days = $1;
1963         $mday += $days;
1964       } elsif ( $part_pkg->freq =~ /^(\d+)h$/ ) {
1965         my $hours = $1;
1966         $hour += $hours;
1967       } else {
1968         $dbh->rollback if $oldAutoCommit;
1969         return "unparsable frequency: ". $part_pkg->freq;
1970       }
1971       $cust_pkg->setfield('bill',
1972         timelocal_nocheck($sec,$min,$hour,$mday,$mon,$year));
1973     }
1974
1975     warn "\$setup is undefined" unless defined($setup);
1976     warn "\$recur is undefined" unless defined($recur);
1977     warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1978
1979     ###
1980     # If $cust_pkg has been modified, update it and create cust_bill_pkg records
1981     ###
1982
1983     if ( $cust_pkg->modified ) {  # hmmm.. and if the options are modified?
1984
1985       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1986         if $DEBUG >1;
1987
1988       $error=$cust_pkg->replace($old_cust_pkg,
1989                                 options => { $cust_pkg->options },
1990                                );
1991       if ( $error ) { #just in case
1992         $dbh->rollback if $oldAutoCommit;
1993         return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error";
1994       }
1995
1996       $setup = sprintf( "%.2f", $setup );
1997       $recur = sprintf( "%.2f", $recur );
1998       if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1999         $dbh->rollback if $oldAutoCommit;
2000         return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
2001       }
2002       if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
2003         $dbh->rollback if $oldAutoCommit;
2004         return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
2005       }
2006
2007       if ( $setup != 0 || $recur != 0 ) {
2008
2009         warn "    charges (setup=$setup, recur=$recur); adding line items\n"
2010           if $DEBUG > 1;
2011         my $cust_bill_pkg = new FS::cust_bill_pkg ({
2012           'invnum'  => $invnum,
2013           'pkgnum'  => $cust_pkg->pkgnum,
2014           'setup'   => $setup,
2015           'recur'   => $recur,
2016           'sdate'   => $sdate,
2017           'edate'   => $cust_pkg->bill,
2018           'details' => \@details,
2019         });
2020         $error = $cust_bill_pkg->insert;
2021         if ( $error ) {
2022           $dbh->rollback if $oldAutoCommit;
2023           return "can't create invoice line item for invoice #$invnum: $error";
2024         }
2025         $total_setup += $setup;
2026         $total_recur += $recur;
2027
2028         ###
2029         # handle taxes
2030         ###
2031
2032         unless ( $self->tax =~ /Y/i || $self->payby eq 'COMP' ) {
2033
2034           my $prefix =
2035             ( $conf->exists('tax-ship_address') && length($self->ship_last) )
2036             ? 'ship_'
2037             : '';
2038           my %taxhash = map { $_ => $self->get("$prefix$_") }
2039                             qw( state county country );
2040
2041           $taxhash{'taxclass'} = $part_pkg->taxclass;
2042
2043           my @taxes = qsearch( 'cust_main_county', \%taxhash );
2044
2045           unless ( @taxes ) {
2046             $taxhash{'taxclass'} = '';
2047             @taxes =  qsearch( 'cust_main_county', \%taxhash );
2048           }
2049
2050           #one more try at a whole-country tax rate
2051           unless ( @taxes ) {
2052             $taxhash{$_} = '' foreach qw( state county );
2053             @taxes =  qsearch( 'cust_main_county', \%taxhash );
2054           }
2055
2056           # maybe eliminate this entirely, along with all the 0% records
2057           unless ( @taxes ) {
2058             $dbh->rollback if $oldAutoCommit;
2059             return
2060               "fatal: can't find tax rate for state/county/country/taxclass ".
2061               join('/', ( map $self->get("$prefix$_"),
2062                               qw(state county country)
2063                         ),
2064                         $part_pkg->taxclass ). "\n";
2065           }
2066
2067           foreach my $tax ( @taxes ) {
2068
2069             my $taxable_charged = 0;
2070             $taxable_charged += $setup
2071               unless $part_pkg->setuptax =~ /^Y$/i
2072                   || $tax->setuptax =~ /^Y$/i;
2073             $taxable_charged += $recur
2074               unless $part_pkg->recurtax =~ /^Y$/i
2075                   || $tax->recurtax =~ /^Y$/i;
2076             next unless $taxable_charged;
2077
2078             if ( $tax->exempt_amount && $tax->exempt_amount > 0 ) {
2079               #my ($mon,$year) = (localtime($sdate) )[4,5];
2080               my ($mon,$year) = (localtime( $sdate || $cust_bill->_date ) )[4,5];
2081               $mon++;
2082               my $freq = $part_pkg->freq || 1;
2083               if ( $freq !~ /(\d+)$/ ) {
2084                 $dbh->rollback if $oldAutoCommit;
2085                 return "daily/weekly package definitions not (yet?)".
2086                        " compatible with monthly tax exemptions";
2087               }
2088               my $taxable_per_month =
2089                 sprintf("%.2f", $taxable_charged / $freq );
2090
2091               #call the whole thing off if this customer has any old
2092               #exemption records...
2093               my @cust_tax_exempt =
2094                 qsearch( 'cust_tax_exempt' => { custnum=> $self->custnum } );
2095               if ( @cust_tax_exempt ) {
2096                 $dbh->rollback if $oldAutoCommit;
2097                 return
2098                   'this customer still has old-style tax exemption records; '.
2099                   'run bin/fs-migrate-cust_tax_exempt?';
2100               }
2101
2102               foreach my $which_month ( 1 .. $freq ) {
2103
2104                 #maintain the new exemption table now
2105                 my $sql = "
2106                   SELECT SUM(amount)
2107                     FROM cust_tax_exempt_pkg
2108                       LEFT JOIN cust_bill_pkg USING ( billpkgnum )
2109                       LEFT JOIN cust_bill     USING ( invnum     )
2110                     WHERE custnum = ?
2111                       AND taxnum  = ?
2112                       AND year    = ?
2113                       AND month   = ?
2114                 ";
2115                 my $sth = dbh->prepare($sql) or do {
2116                   $dbh->rollback if $oldAutoCommit;
2117                   return "fatal: can't lookup exising exemption: ". dbh->errstr;
2118                 };
2119                 $sth->execute(
2120                   $self->custnum,
2121                   $tax->taxnum,
2122                   1900+$year,
2123                   $mon,
2124                 ) or do {
2125                   $dbh->rollback if $oldAutoCommit;
2126                   return "fatal: can't lookup exising exemption: ". dbh->errstr;
2127                 };
2128                 my $existing_exemption = $sth->fetchrow_arrayref->[0] || 0;
2129
2130                 my $remaining_exemption =
2131                   $tax->exempt_amount - $existing_exemption;
2132                 if ( $remaining_exemption > 0 ) {
2133                   my $addl = $remaining_exemption > $taxable_per_month
2134                     ? $taxable_per_month
2135                     : $remaining_exemption;
2136                   $taxable_charged -= $addl;
2137
2138                   my $cust_tax_exempt_pkg = new FS::cust_tax_exempt_pkg ( {
2139                     'billpkgnum' => $cust_bill_pkg->billpkgnum,
2140                     'taxnum'     => $tax->taxnum,
2141                     'year'       => 1900+$year,
2142                     'month'      => $mon,
2143                     'amount'     => sprintf("%.2f", $addl ),
2144                   } );
2145                   $error = $cust_tax_exempt_pkg->insert;
2146                   if ( $error ) {
2147                     $dbh->rollback if $oldAutoCommit;
2148                     return "fatal: can't insert cust_tax_exempt_pkg: $error";
2149                   }
2150                 } # if $remaining_exemption > 0
2151
2152                 #++
2153                 $mon++;
2154                 #until ( $mon < 12 ) { $mon -= 12; $year++; }
2155                 until ( $mon < 13 ) { $mon -= 12; $year++; }
2156
2157               } #foreach $which_month
2158
2159             } #if $tax->exempt_amount
2160
2161             $taxable_charged = sprintf( "%.2f", $taxable_charged);
2162
2163             #$tax += $taxable_charged * $cust_main_county->tax / 100
2164             $tax{ $tax->taxname || 'Tax' } +=
2165               $taxable_charged * $tax->tax / 100
2166
2167           } #foreach my $tax ( @taxes )
2168
2169         } #unless $self->tax =~ /Y/i || $self->payby eq 'COMP'
2170
2171       } #if $setup != 0 || $recur != 0
2172
2173     } #if $cust_pkg->modified
2174
2175   } #foreach my $cust_pkg
2176
2177   unless ( $cust_bill->cust_bill_pkg ) {
2178     $cust_bill->delete; #don't create an invoice w/o line items
2179     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2180     return '';
2181   }
2182
2183   my $charged = sprintf( "%.2f", $total_setup + $total_recur );
2184
2185   foreach my $taxname ( grep { $tax{$_} > 0 } keys %tax ) {
2186     my $tax = sprintf("%.2f", $tax{$taxname} );
2187     $charged = sprintf( "%.2f", $charged+$tax );
2188
2189     my $cust_bill_pkg = new FS::cust_bill_pkg ({
2190       'invnum'   => $invnum,
2191       'pkgnum'   => 0,
2192       'setup'    => $tax,
2193       'recur'    => 0,
2194       'sdate'    => '',
2195       'edate'    => '',
2196       'itemdesc' => $taxname,
2197     });
2198     $error = $cust_bill_pkg->insert;
2199     if ( $error ) {
2200       $dbh->rollback if $oldAutoCommit;
2201       return "can't create invoice line item for invoice #$invnum: $error";
2202     }
2203     $total_setup += $tax;
2204
2205   }
2206
2207   $cust_bill->charged( sprintf( "%.2f", $total_setup + $total_recur ) );
2208   $error = $cust_bill->replace;
2209   if ( $error ) {
2210     $dbh->rollback if $oldAutoCommit;
2211     return "can't update charged for invoice #$invnum: $error";
2212   }
2213
2214   foreach my $hook ( @precommit_hooks ) {
2215     eval {
2216       &{$hook}; #($self) ?
2217     };
2218     if ( $@ ) {
2219       $dbh->rollback if $oldAutoCommit;
2220       return "$@ running precommit hook $hook\n";
2221     }
2222   }
2223
2224   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2225   ''; #no error
2226 }
2227
2228 =item collect OPTIONS
2229
2230 (Attempt to) collect money for this customer's outstanding invoices (see
2231 L<FS::cust_bill>).  Usually used after the bill method.
2232
2233 Depending on the value of `payby', this may print or email an invoice (I<BILL>,
2234 I<DCRD>, or I<DCHK>), charge a credit card (I<CARD>), charge via electronic
2235 check/ACH (I<CHEK>), or just add any necessary (pseudo-)payment (I<COMP>).
2236
2237 Most actions are now triggered by invoice events; see L<FS::part_bill_event>
2238 and the invoice events web interface.
2239
2240 If there is an error, returns the error, otherwise returns false.
2241
2242 Options are passed as name-value pairs.
2243
2244 Currently available options are:
2245
2246 invoice_time - Use this time when deciding when to print invoices and
2247 late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse>
2248 for conversion functions.
2249
2250 retry - Retry card/echeck/LEC transactions even when not scheduled by invoice
2251 events.
2252
2253 quiet - set true to surpress email card/ACH decline notices.
2254
2255 freq - "1d" for the traditional, daily events (the default), or "1m" for the
2256 new monthly events
2257
2258 payby - allows for one time override of normal customer billing method
2259
2260 =cut
2261
2262 sub collect {
2263   my( $self, %options ) = @_;
2264   my $invoice_time = $options{'invoice_time'} || time;
2265
2266   #put below somehow?
2267   local $SIG{HUP} = 'IGNORE';
2268   local $SIG{INT} = 'IGNORE';
2269   local $SIG{QUIT} = 'IGNORE';
2270   local $SIG{TERM} = 'IGNORE';
2271   local $SIG{TSTP} = 'IGNORE';
2272   local $SIG{PIPE} = 'IGNORE';
2273
2274   my $oldAutoCommit = $FS::UID::AutoCommit;
2275   local $FS::UID::AutoCommit = 0;
2276   my $dbh = dbh;
2277
2278   $self->select_for_update; #mutex
2279
2280   my $balance = $self->balance;
2281   warn "$me collect customer ". $self->custnum. ": balance $balance\n"
2282     if $DEBUG;
2283   unless ( $balance > 0 ) { #redundant?????
2284     $dbh->rollback if $oldAutoCommit; #hmm
2285     return '';
2286   }
2287
2288   if ( exists($options{'retry_card'}) ) {
2289     carp 'retry_card option passed to collect is deprecated; use retry';
2290     $options{'retry'} ||= $options{'retry_card'};
2291   }
2292   if ( exists($options{'retry'}) && $options{'retry'} ) {
2293     my $error = $self->retry_realtime;
2294     if ( $error ) {
2295       $dbh->rollback if $oldAutoCommit;
2296       return $error;
2297     }
2298   }
2299
2300   my $extra_sql = '';
2301   if ( defined $options{'freq'} && $options{'freq'} eq '1m' ) {
2302     $extra_sql = " AND freq = '1m' ";
2303   } else {
2304     $extra_sql = " AND ( freq = '1d' OR freq IS NULL OR freq = '' ) ";
2305   }
2306
2307   foreach my $cust_bill ( $self->open_cust_bill ) {
2308
2309     # don't try to charge for the same invoice if it's already in a batch
2310     #next if qsearchs( 'cust_pay_batch', { 'invnum' => $cust_bill->invnum } );
2311
2312     last if $self->balance <= 0;
2313
2314     warn "  invnum ". $cust_bill->invnum. " (owed ". $cust_bill->owed. ")\n"
2315       if $DEBUG > 1;
2316
2317     foreach my $part_bill_event ( due_events ( $cust_bill,
2318                                                exists($options{'payby'})
2319                                                  ? $options{'payby'}
2320                                                  : $self->payby,
2321                                                $invoice_time,
2322                                                $extra_sql ) ) {
2323
2324       last if $cust_bill->owed <= 0  # don't run subsequent events if owed<=0
2325            || $self->balance   <= 0; # or if balance<=0
2326
2327       {
2328         local $realtime_bop_decline_quiet = 1 if $options{'quiet'};
2329         warn "  do_event " .  $cust_bill . " ". (%options) .  "\n"
2330           if $DEBUG > 1;
2331
2332         if (my $error = $part_bill_event->do_event($cust_bill, %options)) {
2333           # gah, even with transactions.
2334           $dbh->commit if $oldAutoCommit; #well.
2335           return $error;
2336         }
2337       }
2338
2339     }
2340
2341   }
2342
2343   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2344   '';
2345
2346 }
2347
2348 =item retry_realtime
2349
2350 Schedules realtime / batch  credit card / electronic check / LEC billing
2351 events for for retry.  Useful if card information has changed or manual
2352 retry is desired.  The 'collect' method must be called to actually retry
2353 the transaction.
2354
2355 Implementation details: For each of this customer's open invoices, changes
2356 the status of the first "done" (with statustext error) realtime processing
2357 event to "failed".
2358
2359 =cut
2360
2361 sub retry_realtime {
2362   my $self = shift;
2363
2364   local $SIG{HUP} = 'IGNORE';
2365   local $SIG{INT} = 'IGNORE';
2366   local $SIG{QUIT} = 'IGNORE';
2367   local $SIG{TERM} = 'IGNORE';
2368   local $SIG{TSTP} = 'IGNORE';
2369   local $SIG{PIPE} = 'IGNORE';
2370
2371   my $oldAutoCommit = $FS::UID::AutoCommit;
2372   local $FS::UID::AutoCommit = 0;
2373   my $dbh = dbh;
2374
2375   foreach my $cust_bill (
2376     grep { $_->cust_bill_event }
2377       $self->open_cust_bill
2378   ) {
2379     my @cust_bill_event =
2380       sort { $a->part_bill_event->seconds <=> $b->part_bill_event->seconds }
2381         grep {
2382                #$_->part_bill_event->plan eq 'realtime-card'
2383                $_->part_bill_event->eventcode =~
2384                    /\$cust_bill\->(batch|realtime)_(card|ach|lec)/
2385                  && $_->status eq 'done'
2386                  && $_->statustext
2387              }
2388           $cust_bill->cust_bill_event;
2389     next unless @cust_bill_event;
2390     my $error = $cust_bill_event[0]->retry;
2391     if ( $error ) {
2392       $dbh->rollback if $oldAutoCommit;
2393       return "error scheduling invoice event for retry: $error";
2394     }
2395
2396   }
2397
2398   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2399   '';
2400
2401 }
2402
2403 =item realtime_bop METHOD AMOUNT [ OPTION => VALUE ... ]
2404
2405 Runs a realtime credit card, ACH (electronic check) or phone bill transaction
2406 via a Business::OnlinePayment realtime gateway.  See
2407 L<http://420.am/business-onlinepayment> for supported gateways.
2408
2409 Available methods are: I<CC>, I<ECHECK> and I<LEC>
2410
2411 Available options are: I<description>, I<invnum>, I<quiet>
2412
2413 The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
2414 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
2415 if set, will override the value from the customer record.
2416
2417 I<description> is a free-text field passed to the gateway.  It defaults to
2418 "Internet services".
2419
2420 If an I<invnum> is specified, this payment (if successful) is applied to the
2421 specified invoice.  If you don't specify an I<invnum> you might want to
2422 call the B<apply_payments> method.
2423
2424 I<quiet> can be set true to surpress email decline notices.
2425
2426 (moved from cust_bill) (probably should get realtime_{card,ach,lec} here too)
2427
2428 =cut
2429
2430 sub realtime_bop {
2431   my( $self, $method, $amount, %options ) = @_;
2432   if ( $DEBUG ) {
2433     warn "$me realtime_bop: $method $amount\n";
2434     warn "  $_ => $options{$_}\n" foreach keys %options;
2435   }
2436
2437   $options{'description'} ||= 'Internet services';
2438
2439   eval "use Business::OnlinePayment";
2440   die $@ if $@;
2441
2442   my $payinfo = exists($options{'payinfo'})
2443                   ? $options{'payinfo'}
2444                   : $self->payinfo;
2445
2446   ###
2447   # select a gateway
2448   ###
2449
2450   my $taxclass = '';
2451   if ( $options{'invnum'} ) {
2452     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $options{'invnum'} } );
2453     die "invnum ". $options{'invnum'}. " not found" unless $cust_bill;
2454     my @taxclasses =
2455       map  { $_->part_pkg->taxclass }
2456       grep { $_ }
2457       map  { $_->cust_pkg }
2458       $cust_bill->cust_bill_pkg;
2459     unless ( grep { $taxclasses[0] ne $_ } @taxclasses ) { #unless there are
2460                                                            #different taxclasses
2461       $taxclass = $taxclasses[0];
2462     }
2463   }
2464
2465   #look for an agent gateway override first
2466   my $cardtype;
2467   if ( $method eq 'CC' ) {
2468     $cardtype = cardtype($payinfo);
2469   } elsif ( $method eq 'ECHECK' ) {
2470     $cardtype = 'ACH';
2471   } else {
2472     $cardtype = $method;
2473   }
2474
2475   my $override =
2476        qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2477                                            cardtype => $cardtype,
2478                                            taxclass => $taxclass,       } )
2479     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2480                                            cardtype => '',
2481                                            taxclass => $taxclass,       } )
2482     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2483                                            cardtype => $cardtype,
2484                                            taxclass => '',              } )
2485     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2486                                            cardtype => '',
2487                                            taxclass => '',              } );
2488
2489   my $payment_gateway = '';
2490   my( $processor, $login, $password, $action, @bop_options );
2491   if ( $override ) { #use a payment gateway override
2492
2493     $payment_gateway = $override->payment_gateway;
2494
2495     $processor   = $payment_gateway->gateway_module;
2496     $login       = $payment_gateway->gateway_username;
2497     $password    = $payment_gateway->gateway_password;
2498     $action      = $payment_gateway->gateway_action;
2499     @bop_options = $payment_gateway->options;
2500
2501   } else { #use the standard settings from the config
2502
2503     ( $processor, $login, $password, $action, @bop_options ) =
2504       $self->default_payment_gateway($method);
2505
2506   }
2507
2508   ###
2509   # massage data
2510   ###
2511
2512   my $address = exists($options{'address1'})
2513                     ? $options{'address1'}
2514                     : $self->address1;
2515   my $address2 = exists($options{'address2'})
2516                     ? $options{'address2'}
2517                     : $self->address2;
2518   $address .= ", ". $address2 if length($address2);
2519
2520   my $o_payname = exists($options{'payname'})
2521                     ? $options{'payname'}
2522                     : $self->payname;
2523   my($payname, $payfirst, $paylast);
2524   if ( $o_payname && $method ne 'ECHECK' ) {
2525     ($payname = $o_payname) =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
2526       or return "Illegal payname $payname";
2527     ($payfirst, $paylast) = ($1, $2);
2528   } else {
2529     $payfirst = $self->getfield('first');
2530     $paylast = $self->getfield('last');
2531     $payname =  "$payfirst $paylast";
2532   }
2533
2534   # invoicing_list_emailonly instead? push one?  which one?
2535   my @invoicing_list = grep { $_ ne 'POST' } $self->invoicing_list;
2536   if ( $conf->exists('emailinvoiceautoalways')
2537        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
2538        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
2539     push @invoicing_list, $self->all_emails;
2540   }
2541
2542   my $email = ($conf->exists('business-onlinepayment-email-override'))
2543               ? $conf->config('business-onlinepayment-email-override')
2544               : $invoicing_list[0];
2545
2546   my %content = ();
2547
2548   my $payip = exists($options{'payip'})
2549                 ? $options{'payip'}
2550                 : $self->payip;
2551   $content{customer_ip} = $payip
2552     if length($payip);
2553
2554   $content{invoice_number} = $options{'invnum'}
2555     if exists($options{'invnum'}) && length($options{'invnum'});
2556
2557   if ( $method eq 'CC' ) {
2558
2559     $content{card_number} = $payinfo;
2560     my $paydate = exists($options{'paydate'})
2561                     ? $options{'paydate'}
2562                     : $self->paydate;
2563     $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
2564     $content{expiration} = "$2/$1";
2565
2566     my $paycvv = exists($options{'paycvv'})
2567                    ? $options{'paycvv'}
2568                    : $self->paycvv;
2569     $content{cvv2} = $self->paycvv
2570       if length($paycvv);
2571
2572     my $paystart_month = exists($options{'paystart_month'})
2573                            ? $options{'paystart_month'}
2574                            : $self->paystart_month;
2575
2576     my $paystart_year  = exists($options{'paystart_year'})
2577                            ? $options{'paystart_year'}
2578                            : $self->paystart_year;
2579
2580     $content{card_start} = "$paystart_month/$paystart_year"
2581       if $paystart_month && $paystart_year;
2582
2583     my $payissue       = exists($options{'payissue'})
2584                            ? $options{'payissue'}
2585                            : $self->payissue;
2586     $content{issue_number} = $payissue if $payissue;
2587
2588     $content{recurring_billing} = 'YES'
2589       if qsearch('cust_pay', { 'custnum' => $self->custnum,
2590                                'payby'   => 'CARD',
2591                                'payinfo' => $payinfo,
2592                              } )
2593       || qsearch('cust_pay', { 'custnum' => $self->custnum,
2594                                'payby'   => 'CARD',
2595                                'paymask' => $self->mask_payinfo('CARD', $payinfo),
2596                              } );
2597
2598
2599   } elsif ( $method eq 'ECHECK' ) {
2600     ( $content{account_number}, $content{routing_code} ) =
2601       split('@', $payinfo);
2602     $content{bank_name} = $o_payname;
2603     $content{account_type} = 'CHECKING';
2604     $content{account_name} = $payname;
2605     $content{customer_org} = $self->company ? 'B' : 'I';
2606     $content{customer_ssn} = exists($options{'ss'})
2607                                ? $options{'ss'}
2608                                : $self->ss;
2609   } elsif ( $method eq 'LEC' ) {
2610     $content{phone} = $payinfo;
2611   }
2612
2613   ###
2614   # run transaction(s)
2615   ###
2616
2617   my( $action1, $action2 ) = split(/\s*\,\s*/, $action );
2618
2619   my $transaction = new Business::OnlinePayment( $processor, @bop_options );
2620   $transaction->content(
2621     'type'           => $method,
2622     'login'          => $login,
2623     'password'       => $password,
2624     'action'         => $action1,
2625     'description'    => $options{'description'},
2626     'amount'         => $amount,
2627     #'invoice_number' => $options{'invnum'},
2628     'customer_id'    => $self->custnum,
2629     'last_name'      => $paylast,
2630     'first_name'     => $payfirst,
2631     'name'           => $payname,
2632     'address'        => $address,
2633     'city'           => ( exists($options{'city'})
2634                             ? $options{'city'}
2635                             : $self->city          ),
2636     'state'          => ( exists($options{'state'})
2637                             ? $options{'state'}
2638                             : $self->state          ),
2639     'zip'            => ( exists($options{'zip'})
2640                             ? $options{'zip'}
2641                             : $self->zip          ),
2642     'country'        => ( exists($options{'country'})
2643                             ? $options{'country'}
2644                             : $self->country          ),
2645     'referer'        => 'http://cleanwhisker.420.am/',
2646     'email'          => $email,
2647     'phone'          => $self->daytime || $self->night,
2648     %content, #after
2649   );
2650   $transaction->submit();
2651
2652   if ( $transaction->is_success() && $action2 ) {
2653     my $auth = $transaction->authorization;
2654     my $ordernum = $transaction->can('order_number')
2655                    ? $transaction->order_number
2656                    : '';
2657
2658     my $capture =
2659       new Business::OnlinePayment( $processor, @bop_options );
2660
2661     my %capture = (
2662       %content,
2663       type           => $method,
2664       action         => $action2,
2665       login          => $login,
2666       password       => $password,
2667       order_number   => $ordernum,
2668       amount         => $amount,
2669       authorization  => $auth,
2670       description    => $options{'description'},
2671     );
2672
2673     foreach my $field (qw( authorization_source_code returned_ACI
2674                            transaction_identifier validation_code
2675                            transaction_sequence_num local_transaction_date
2676                            local_transaction_time AVS_result_code          )) {
2677       $capture{$field} = $transaction->$field() if $transaction->can($field);
2678     }
2679
2680     $capture->content( %capture );
2681
2682     $capture->submit();
2683
2684     unless ( $capture->is_success ) {
2685       my $e = "Authorization successful but capture failed, custnum #".
2686               $self->custnum. ': '.  $capture->result_code.
2687               ": ". $capture->error_message;
2688       warn $e;
2689       return $e;
2690     }
2691
2692   }
2693
2694   ###
2695   # remove paycvv after initial transaction
2696   ###
2697
2698   #false laziness w/misc/process/payment.cgi - check both to make sure working
2699   # correctly
2700   if ( defined $self->dbdef_table->column('paycvv')
2701        && length($self->paycvv)
2702        && ! grep { $_ eq cardtype($payinfo) } $conf->config('cvv-save')
2703   ) {
2704     my $error = $self->remove_cvv;
2705     if ( $error ) {
2706       warn "WARNING: error removing cvv: $error\n";
2707     }
2708   }
2709
2710   ###
2711   # result handling
2712   ###
2713
2714   if ( $transaction->is_success() ) {
2715
2716     my %method2payby = (
2717       'CC'     => 'CARD',
2718       'ECHECK' => 'CHEK',
2719       'LEC'    => 'LECB',
2720     );
2721
2722     my $paybatch = '';
2723     if ( $payment_gateway ) { # agent override
2724       $paybatch = $payment_gateway->gatewaynum. '-';
2725     }
2726
2727     $paybatch .= "$processor:". $transaction->authorization;
2728
2729     $paybatch .= ':'. $transaction->order_number
2730       if $transaction->can('order_number')
2731       && length($transaction->order_number);
2732
2733     my $cust_pay = new FS::cust_pay ( {
2734        'custnum'  => $self->custnum,
2735        'invnum'   => $options{'invnum'},
2736        'paid'     => $amount,
2737        '_date'     => '',
2738        'payby'    => $method2payby{$method},
2739        'payinfo'  => $payinfo,
2740        'paybatch' => $paybatch,
2741     } );
2742     my $error = $cust_pay->insert($options{'manual'} ? ( 'manual' => 1 ) : () );
2743     if ( $error ) {
2744       $cust_pay->invnum(''); #try again with no specific invnum
2745       my $error2 = $cust_pay->insert( $options{'manual'} ?
2746                                       ( 'manual' => 1 ) : ()
2747                                     );
2748       if ( $error2 ) {
2749         # gah, even with transactions.
2750         my $e = 'WARNING: Card/ACH debited but database not updated - '.
2751                 "error inserting payment ($processor): $error2".
2752                 " (previously tried insert with invnum #$options{'invnum'}" .
2753                 ": $error )";
2754         warn $e;
2755         return $e;
2756       }
2757     }
2758     return ''; #no error
2759
2760   } else {
2761
2762     my $perror = "$processor error: ". $transaction->error_message;
2763
2764     if ( !$options{'quiet'} && !$realtime_bop_decline_quiet
2765          && $conf->exists('emaildecline')
2766          && grep { $_ ne 'POST' } $self->invoicing_list
2767          && ! grep { $transaction->error_message =~ /$_/ }
2768                    $conf->config('emaildecline-exclude')
2769     ) {
2770       my @templ = $conf->config('declinetemplate');
2771       my $template = new Text::Template (
2772         TYPE   => 'ARRAY',
2773         SOURCE => [ map "$_\n", @templ ],
2774       ) or return "($perror) can't create template: $Text::Template::ERROR";
2775       $template->compile()
2776         or return "($perror) can't compile template: $Text::Template::ERROR";
2777
2778       my $templ_hash = { error => $transaction->error_message };
2779
2780       my $error = send_email(
2781         'from'    => $conf->config('invoice_from'),
2782         'to'      => [ grep { $_ ne 'POST' } $self->invoicing_list ],
2783         'subject' => 'Your payment could not be processed',
2784         'body'    => [ $template->fill_in(HASH => $templ_hash) ],
2785       );
2786
2787       $perror .= " (also received error sending decline notification: $error)"
2788         if $error;
2789
2790     }
2791
2792     return $perror;
2793   }
2794
2795 }
2796
2797 =item default_payment_gateway
2798
2799 =cut
2800
2801 sub default_payment_gateway {
2802   my( $self, $method ) = @_;
2803
2804   die "Real-time processing not enabled\n"
2805     unless $conf->exists('business-onlinepayment');
2806
2807   #load up config
2808   my $bop_config = 'business-onlinepayment';
2809   $bop_config .= '-ach'
2810     if $method eq 'ECHECK' && $conf->exists($bop_config. '-ach');
2811   my ( $processor, $login, $password, $action, @bop_options ) =
2812     $conf->config($bop_config);
2813   $action ||= 'normal authorization';
2814   pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
2815   die "No real-time processor is enabled - ".
2816       "did you set the business-onlinepayment configuration value?\n"
2817     unless $processor;
2818
2819   ( $processor, $login, $password, $action, @bop_options )
2820 }
2821
2822 =item remove_cvv
2823
2824 Removes the I<paycvv> field from the database directly.
2825
2826 If there is an error, returns the error, otherwise returns false.
2827
2828 =cut
2829
2830 sub remove_cvv {
2831   my $self = shift;
2832   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2833     or return dbh->errstr;
2834   $sth->execute($self->custnum)
2835     or return $sth->errstr;
2836   $self->paycvv('');
2837   '';
2838 }
2839
2840 =item realtime_refund_bop METHOD [ OPTION => VALUE ... ]
2841
2842 Refunds a realtime credit card, ACH (electronic check) or phone bill transaction
2843 via a Business::OnlinePayment realtime gateway.  See
2844 L<http://420.am/business-onlinepayment> for supported gateways.
2845
2846 Available methods are: I<CC>, I<ECHECK> and I<LEC>
2847
2848 Available options are: I<amount>, I<reason>, I<paynum>
2849
2850 Most gateways require a reference to an original payment transaction to refund,
2851 so you probably need to specify a I<paynum>.
2852
2853 I<amount> defaults to the original amount of the payment if not specified.
2854
2855 I<reason> specifies a reason for the refund.
2856
2857 Implementation note: If I<amount> is unspecified or equal to the amount of the
2858 orignal payment, first an attempt is made to "void" the transaction via
2859 the gateway (to cancel a not-yet settled transaction) and then if that fails,
2860 the normal attempt is made to "refund" ("credit") the transaction via the
2861 gateway is attempted.
2862
2863 #The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
2864 #I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
2865 #if set, will override the value from the customer record.
2866
2867 #If an I<invnum> is specified, this payment (if successful) is applied to the
2868 #specified invoice.  If you don't specify an I<invnum> you might want to
2869 #call the B<apply_payments> method.
2870
2871 =cut
2872
2873 #some false laziness w/realtime_bop, not enough to make it worth merging
2874 #but some useful small subs should be pulled out
2875 sub realtime_refund_bop {
2876   my( $self, $method, %options ) = @_;
2877   if ( $DEBUG ) {
2878     warn "$me realtime_refund_bop: $method refund\n";
2879     warn "  $_ => $options{$_}\n" foreach keys %options;
2880   }
2881
2882   eval "use Business::OnlinePayment";
2883   die $@ if $@;
2884
2885   ###
2886   # look up the original payment and optionally a gateway for that payment
2887   ###
2888
2889   my $cust_pay = '';
2890   my $amount = $options{'amount'};
2891
2892   my( $processor, $login, $password, @bop_options ) ;
2893   my( $auth, $order_number ) = ( '', '', '' );
2894
2895   if ( $options{'paynum'} ) {
2896
2897     warn "  paynum: $options{paynum}\n" if $DEBUG > 1;
2898     $cust_pay = qsearchs('cust_pay', { paynum=>$options{'paynum'} } )
2899       or return "Unknown paynum $options{'paynum'}";
2900     $amount ||= $cust_pay->paid;
2901
2902     $cust_pay->paybatch =~ /^((\d+)\-)?(\w+):\s*([\w\-]*)(:([\w\-]+))?$/
2903       or return "Can't parse paybatch for paynum $options{'paynum'}: ".
2904                 $cust_pay->paybatch;
2905     my $gatewaynum = '';
2906     ( $gatewaynum, $processor, $auth, $order_number ) = ( $2, $3, $4, $6 );
2907
2908     if ( $gatewaynum ) { #gateway for the payment to be refunded
2909
2910       my $payment_gateway =
2911         qsearchs('payment_gateway', { 'gatewaynum' => $gatewaynum } );
2912       die "payment gateway $gatewaynum not found"
2913         unless $payment_gateway;
2914
2915       $processor   = $payment_gateway->gateway_module;
2916       $login       = $payment_gateway->gateway_username;
2917       $password    = $payment_gateway->gateway_password;
2918       @bop_options = $payment_gateway->options;
2919
2920     } else { #try the default gateway
2921
2922       my( $conf_processor, $unused_action );
2923       ( $conf_processor, $login, $password, $unused_action, @bop_options ) =
2924         $self->default_payment_gateway($method);
2925
2926       return "processor of payment $options{'paynum'} $processor does not".
2927              " match default processor $conf_processor"
2928         unless $processor eq $conf_processor;
2929
2930     }
2931
2932
2933   } else { # didn't specify a paynum, so look for agent gateway overrides
2934            # like a normal transaction
2935
2936     my $cardtype;
2937     if ( $method eq 'CC' ) {
2938       $cardtype = cardtype($self->payinfo);
2939     } elsif ( $method eq 'ECHECK' ) {
2940       $cardtype = 'ACH';
2941     } else {
2942       $cardtype = $method;
2943     }
2944     my $override =
2945            qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2946                                                cardtype => $cardtype,
2947                                                taxclass => '',              } )
2948         || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
2949                                                cardtype => '',
2950                                                taxclass => '',              } );
2951
2952     if ( $override ) { #use a payment gateway override
2953
2954       my $payment_gateway = $override->payment_gateway;
2955
2956       $processor   = $payment_gateway->gateway_module;
2957       $login       = $payment_gateway->gateway_username;
2958       $password    = $payment_gateway->gateway_password;
2959       #$action      = $payment_gateway->gateway_action;
2960       @bop_options = $payment_gateway->options;
2961
2962     } else { #use the standard settings from the config
2963
2964       my $unused_action;
2965       ( $processor, $login, $password, $unused_action, @bop_options ) =
2966         $self->default_payment_gateway($method);
2967
2968     }
2969
2970   }
2971   return "neither amount nor paynum specified" unless $amount;
2972
2973   my %content = (
2974     'type'           => $method,
2975     'login'          => $login,
2976     'password'       => $password,
2977     'order_number'   => $order_number,
2978     'amount'         => $amount,
2979     'referer'        => 'http://cleanwhisker.420.am/',
2980   );
2981   $content{authorization} = $auth
2982     if length($auth); #echeck/ACH transactions have an order # but no auth
2983                       #(at least with authorize.net)
2984
2985   #first try void if applicable
2986   if ( $cust_pay && $cust_pay->paid == $amount ) { #and check dates?
2987     warn "  attempting void\n" if $DEBUG > 1;
2988     my $void = new Business::OnlinePayment( $processor, @bop_options );
2989     $void->content( 'action' => 'void', %content );
2990     $void->submit();
2991     if ( $void->is_success ) {
2992       my $error = $cust_pay->void($options{'reason'});
2993       if ( $error ) {
2994         # gah, even with transactions.
2995         my $e = 'WARNING: Card/ACH voided but database not updated - '.
2996                 "error voiding payment: $error";
2997         warn $e;
2998         return $e;
2999       }
3000       warn "  void successful\n" if $DEBUG > 1;
3001       return '';
3002     }
3003   }
3004
3005   warn "  void unsuccessful, trying refund\n"
3006     if $DEBUG > 1;
3007
3008   #massage data
3009   my $address = $self->address1;
3010   $address .= ", ". $self->address2 if $self->address2;
3011
3012   my($payname, $payfirst, $paylast);
3013   if ( $self->payname && $method ne 'ECHECK' ) {
3014     $payname = $self->payname;
3015     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
3016       or return "Illegal payname $payname";
3017     ($payfirst, $paylast) = ($1, $2);
3018   } else {
3019     $payfirst = $self->getfield('first');
3020     $paylast = $self->getfield('last');
3021     $payname =  "$payfirst $paylast";
3022   }
3023
3024   # invoicing_list_emailonly instead? push one?  which one?
3025   my @invoicing_list = grep { $_ ne 'POST' } $self->invoicing_list;
3026   if ( $conf->exists('emailinvoiceautoalways')
3027        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
3028        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
3029     push @invoicing_list, $self->all_emails;
3030   }
3031
3032   my $email = ($conf->exists('business-onlinepayment-email-override'))
3033               ? $conf->config('business-onlinepayment-email-override')
3034               : $invoicing_list[0];
3035
3036   my $payip = exists($options{'payip'})
3037                 ? $options{'payip'}
3038                 : $self->payip;
3039   $content{customer_ip} = $payip
3040     if length($payip);
3041
3042   my $payinfo = '';
3043   if ( $method eq 'CC' ) {
3044
3045     if ( $cust_pay ) {
3046       $content{card_number} = $payinfo = $cust_pay->payinfo;
3047       #$self->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
3048       #$content{expiration} = "$2/$1";
3049     } else {
3050       $content{card_number} = $payinfo = $self->payinfo;
3051       $self->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
3052       $content{expiration} = "$2/$1";
3053     }
3054
3055   } elsif ( $method eq 'ECHECK' ) {
3056     ( $content{account_number}, $content{routing_code} ) =
3057       split('@', $payinfo = $self->payinfo);
3058     $content{bank_name} = $self->payname;
3059     $content{account_type} = 'CHECKING';
3060     $content{account_name} = $payname;
3061     $content{customer_org} = $self->company ? 'B' : 'I';
3062     $content{customer_ssn} = $self->ss;
3063   } elsif ( $method eq 'LEC' ) {
3064     $content{phone} = $payinfo = $self->payinfo;
3065   }
3066
3067   #then try refund
3068   my $refund = new Business::OnlinePayment( $processor, @bop_options );
3069   my %sub_content = $refund->content(
3070     'action'         => 'credit',
3071     'customer_id'    => $self->custnum,
3072     'last_name'      => $paylast,
3073     'first_name'     => $payfirst,
3074     'name'           => $payname,
3075     'address'        => $address,
3076     'city'           => $self->city,
3077     'state'          => $self->state,
3078     'zip'            => $self->zip,
3079     'country'        => $self->country,
3080     'email'          => $email,
3081     'phone'          => $self->daytime || $self->night,
3082     %content, #after
3083   );
3084   warn join('', map { "  $_ => $sub_content{$_}\n" } keys %sub_content )
3085     if $DEBUG > 1;
3086   $refund->submit();
3087
3088   return "$processor error: ". $refund->error_message
3089     unless $refund->is_success();
3090
3091   my %method2payby = (
3092     'CC'     => 'CARD',
3093     'ECHECK' => 'CHEK',
3094     'LEC'    => 'LECB',
3095   );
3096
3097   my $paybatch = "$processor:". $refund->authorization;
3098   $paybatch .= ':'. $refund->order_number
3099     if $refund->can('order_number') && $refund->order_number;
3100
3101   while ( $cust_pay && $cust_pay->unapplied < $amount ) {
3102     my @cust_bill_pay = $cust_pay->cust_bill_pay;
3103     last unless @cust_bill_pay;
3104     my $cust_bill_pay = pop @cust_bill_pay;
3105     my $error = $cust_bill_pay->delete;
3106     last if $error;
3107   }
3108
3109   my $cust_refund = new FS::cust_refund ( {
3110     'custnum'  => $self->custnum,
3111     'paynum'   => $options{'paynum'},
3112     'refund'   => $amount,
3113     '_date'    => '',
3114     'payby'    => $method2payby{$method},
3115     'payinfo'  => $payinfo,
3116     'paybatch' => $paybatch,
3117     'reason'   => $options{'reason'} || 'card or ACH refund',
3118   } );
3119   my $error = $cust_refund->insert;
3120   if ( $error ) {
3121     $cust_refund->paynum(''); #try again with no specific paynum
3122     my $error2 = $cust_refund->insert;
3123     if ( $error2 ) {
3124       # gah, even with transactions.
3125       my $e = 'WARNING: Card/ACH refunded but database not updated - '.
3126               "error inserting refund ($processor): $error2".
3127               " (previously tried insert with paynum #$options{'paynum'}" .
3128               ": $error )";
3129       warn $e;
3130       return $e;
3131     }
3132   }
3133
3134   ''; #no error
3135
3136 }
3137
3138 =item total_owed
3139
3140 Returns the total owed for this customer on all invoices
3141 (see L<FS::cust_bill/owed>).
3142
3143 =cut
3144
3145 sub total_owed {
3146   my $self = shift;
3147   $self->total_owed_date(2145859200); #12/31/2037
3148 }
3149
3150 =item total_owed_date TIME
3151
3152 Returns the total owed for this customer on all invoices with date earlier than
3153 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
3154 see L<Time::Local> and L<Date::Parse> for conversion functions.
3155
3156 =cut
3157
3158 sub total_owed_date {
3159   my $self = shift;
3160   my $time = shift;
3161   my $total_bill = 0;
3162   foreach my $cust_bill (
3163     grep { $_->_date <= $time }
3164       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
3165   ) {
3166     $total_bill += $cust_bill->owed;
3167   }
3168   sprintf( "%.2f", $total_bill );
3169 }
3170
3171 =item apply_payments_and_credits
3172
3173 Applies unapplied payments and credits.
3174
3175 In most cases, this new method should be used in place of sequential
3176 apply_payments and apply_credits methods.
3177
3178 =cut
3179
3180 sub apply_payments_and_credits {
3181   my $self = shift;
3182
3183   foreach my $cust_bill ( $self->open_cust_bill ) {
3184     $cust_bill->apply_payments_and_credits;
3185   }
3186
3187 }
3188
3189 =item apply_credits OPTION => VALUE ...
3190
3191 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
3192 to outstanding invoice balances in chronological order (or reverse
3193 chronological order if the I<order> option is set to B<newest>) and returns the
3194 value of any remaining unapplied credits available for refund (see
3195 L<FS::cust_refund>).
3196
3197 =cut
3198
3199 sub apply_credits {
3200   my $self = shift;
3201   my %opt = @_;
3202
3203   return 0 unless $self->total_credited;
3204
3205   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
3206       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
3207
3208   my @invoices = $self->open_cust_bill;
3209   @invoices = sort { $b->_date <=> $a->_date } @invoices
3210     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
3211
3212   my $credit;
3213   foreach my $cust_bill ( @invoices ) {
3214     my $amount;
3215
3216     if ( !defined($credit) || $credit->credited == 0) {
3217       $credit = pop @credits or last;
3218     }
3219
3220     if ($cust_bill->owed >= $credit->credited) {
3221       $amount=$credit->credited;
3222     }else{
3223       $amount=$cust_bill->owed;
3224     }
3225
3226     my $cust_credit_bill = new FS::cust_credit_bill ( {
3227       'crednum' => $credit->crednum,
3228       'invnum'  => $cust_bill->invnum,
3229       'amount'  => $amount,
3230     } );
3231     my $error = $cust_credit_bill->insert;
3232     die $error if $error;
3233
3234     redo if ($cust_bill->owed > 0);
3235
3236   }
3237
3238   return $self->total_credited;
3239 }
3240
3241 =item apply_payments
3242
3243 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
3244 to outstanding invoice balances in chronological order.
3245
3246  #and returns the value of any remaining unapplied payments.
3247
3248 =cut
3249
3250 sub apply_payments {
3251   my $self = shift;
3252
3253   #return 0 unless
3254
3255   my @payments = sort { $b->_date <=> $a->_date } ( grep { $_->unapplied > 0 }
3256       qsearch('cust_pay', { 'custnum' => $self->custnum } ) );
3257
3258   my @invoices = sort { $a->_date <=> $b->_date} (grep { $_->owed > 0 }
3259       qsearch('cust_bill', { 'custnum' => $self->custnum } ) );
3260
3261   my $payment;
3262
3263   foreach my $cust_bill ( @invoices ) {
3264     my $amount;
3265
3266     if ( !defined($payment) || $payment->unapplied == 0 ) {
3267       $payment = pop @payments or last;
3268     }
3269
3270     if ( $cust_bill->owed >= $payment->unapplied ) {
3271       $amount = $payment->unapplied;
3272     } else {
3273       $amount = $cust_bill->owed;
3274     }
3275
3276     my $cust_bill_pay = new FS::cust_bill_pay ( {
3277       'paynum' => $payment->paynum,
3278       'invnum' => $cust_bill->invnum,
3279       'amount' => $amount,
3280     } );
3281     my $error = $cust_bill_pay->insert;
3282     die $error if $error;
3283
3284     redo if ( $cust_bill->owed > 0);
3285
3286   }
3287
3288   return $self->total_unapplied_payments;
3289 }
3290
3291 =item total_credited
3292
3293 Returns the total outstanding credit (see L<FS::cust_credit>) for this
3294 customer.  See L<FS::cust_credit/credited>.
3295
3296 =cut
3297
3298 sub total_credited {
3299   my $self = shift;
3300   my $total_credit = 0;
3301   foreach my $cust_credit ( qsearch('cust_credit', {
3302     'custnum' => $self->custnum,
3303   } ) ) {
3304     $total_credit += $cust_credit->credited;
3305   }
3306   sprintf( "%.2f", $total_credit );
3307 }
3308
3309 =item total_unapplied_payments
3310
3311 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
3312 See L<FS::cust_pay/unapplied>.
3313
3314 =cut
3315
3316 sub total_unapplied_payments {
3317   my $self = shift;
3318   my $total_unapplied = 0;
3319   foreach my $cust_pay ( qsearch('cust_pay', {
3320     'custnum' => $self->custnum,
3321   } ) ) {
3322     $total_unapplied += $cust_pay->unapplied;
3323   }
3324   sprintf( "%.2f", $total_unapplied );
3325 }
3326
3327 =item balance
3328
3329 Returns the balance for this customer (total_owed minus total_credited
3330 minus total_unapplied_payments).
3331
3332 =cut
3333
3334 sub balance {
3335   my $self = shift;
3336   sprintf( "%.2f",
3337     $self->total_owed - $self->total_credited - $self->total_unapplied_payments
3338   );
3339 }
3340
3341 =item balance_date TIME
3342
3343 Returns the balance for this customer, only considering invoices with date
3344 earlier than TIME (total_owed_date minus total_credited minus
3345 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
3346 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
3347 functions.
3348
3349 =cut
3350
3351 sub balance_date {
3352   my $self = shift;
3353   my $time = shift;
3354   sprintf( "%.2f",
3355     $self->total_owed_date($time)
3356       - $self->total_credited
3357       - $self->total_unapplied_payments
3358   );
3359 }
3360
3361 =item in_transit_payments
3362
3363 Returns the total of requests for payments for this customer pending in
3364 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
3365
3366 =cut
3367
3368 sub in_transit_payments {
3369   my $self = shift;
3370   my $in_transit_payments = 0;
3371   foreach my $pay_batch ( qsearch('pay_batch', {
3372     'status' => 'I',
3373   } ) ) {
3374     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
3375       'batchnum' => $pay_batch->batchnum,
3376       'custnum' => $self->custnum,
3377     } ) ) {
3378       $in_transit_payments += $cust_pay_batch->amount;
3379     }
3380   }
3381   sprintf( "%.2f", $in_transit_payments );
3382 }
3383
3384 =item paydate_monthyear
3385
3386 Returns a two-element list consisting of the month and year of this customer's
3387 paydate (credit card expiration date for CARD customers)
3388
3389 =cut
3390
3391 sub paydate_monthyear {
3392   my $self = shift;
3393   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
3394     ( $2, $1 );
3395   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
3396     ( $1, $3 );
3397   } else {
3398     ('', '');
3399   }
3400 }
3401
3402 =item invoicing_list [ ARRAYREF ]
3403
3404 If an arguement is given, sets these email addresses as invoice recipients
3405 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3406 (except as warnings), so use check_invoicing_list first.
3407
3408 Returns a list of email addresses (with svcnum entries expanded).
3409
3410 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3411 check it without disturbing anything by passing nothing.
3412
3413 This interface may change in the future.
3414
3415 =cut
3416
3417 sub invoicing_list {
3418   my( $self, $arrayref ) = @_;
3419
3420   if ( $arrayref ) {
3421     my @cust_main_invoice;
3422     if ( $self->custnum ) {
3423       @cust_main_invoice =
3424         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3425     } else {
3426       @cust_main_invoice = ();
3427     }
3428     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3429       #warn $cust_main_invoice->destnum;
3430       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3431         #warn $cust_main_invoice->destnum;
3432         my $error = $cust_main_invoice->delete;
3433         warn $error if $error;
3434       }
3435     }
3436     if ( $self->custnum ) {
3437       @cust_main_invoice =
3438         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3439     } else {
3440       @cust_main_invoice = ();
3441     }
3442     my %seen = map { $_->address => 1 } @cust_main_invoice;
3443     foreach my $address ( @{$arrayref} ) {
3444       next if exists $seen{$address} && $seen{$address};
3445       $seen{$address} = 1;
3446       my $cust_main_invoice = new FS::cust_main_invoice ( {
3447         'custnum' => $self->custnum,
3448         'dest'    => $address,
3449       } );
3450       my $error = $cust_main_invoice->insert;
3451       warn $error if $error;
3452     }
3453   }
3454
3455   if ( $self->custnum ) {
3456     map { $_->address }
3457       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3458   } else {
3459     ();
3460   }
3461
3462 }
3463
3464 =item check_invoicing_list ARRAYREF
3465
3466 Checks these arguements as valid input for the invoicing_list method.  If there
3467 is an error, returns the error, otherwise returns false.
3468
3469 =cut
3470
3471 sub check_invoicing_list {
3472   my( $self, $arrayref ) = @_;
3473   foreach my $address ( @{$arrayref} ) {
3474
3475     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3476       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3477     }
3478
3479     my $cust_main_invoice = new FS::cust_main_invoice ( {
3480       'custnum' => $self->custnum,
3481       'dest'    => $address,
3482     } );
3483     my $error = $self->custnum
3484                 ? $cust_main_invoice->check
3485                 : $cust_main_invoice->checkdest
3486     ;
3487     return $error if $error;
3488   }
3489   '';
3490 }
3491
3492 =item set_default_invoicing_list
3493
3494 Sets the invoicing list to all accounts associated with this customer,
3495 overwriting any previous invoicing list.
3496
3497 =cut
3498
3499 sub set_default_invoicing_list {
3500   my $self = shift;
3501   $self->invoicing_list($self->all_emails);
3502 }
3503
3504 =item all_emails
3505
3506 Returns the email addresses of all accounts provisioned for this customer.
3507
3508 =cut
3509
3510 sub all_emails {
3511   my $self = shift;
3512   my %list;
3513   foreach my $cust_pkg ( $self->all_pkgs ) {
3514     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3515     my @svc_acct =
3516       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3517         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3518           @cust_svc;
3519     $list{$_}=1 foreach map { $_->email } @svc_acct;
3520   }
3521   keys %list;
3522 }
3523
3524 =item invoicing_list_addpost
3525
3526 Adds postal invoicing to this customer.  If this customer is already configured
3527 to receive postal invoices, does nothing.
3528
3529 =cut
3530
3531 sub invoicing_list_addpost {
3532   my $self = shift;
3533   return if grep { $_ eq 'POST' } $self->invoicing_list;
3534   my @invoicing_list = $self->invoicing_list;
3535   push @invoicing_list, 'POST';
3536   $self->invoicing_list(\@invoicing_list);
3537 }
3538
3539 =item invoicing_list_emailonly
3540
3541 Returns the list of email invoice recipients (invoicing_list without non-email
3542 destinations such as POST and FAX).
3543
3544 =cut
3545
3546 sub invoicing_list_emailonly {
3547   my $self = shift;
3548   warn "$me invoicing_list_emailonly called"
3549     if $DEBUG;
3550   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3551 }
3552
3553 =item invoicing_list_emailonly_scalar
3554
3555 Returns the list of email invoice recipients (invoicing_list without non-email
3556 destinations such as POST and FAX) as a comma-separated scalar.
3557
3558 =cut
3559
3560 sub invoicing_list_emailonly_scalar {
3561   my $self = shift;
3562   warn "$me invoicing_list_emailonly_scalar called"
3563     if $DEBUG;
3564   join(', ', $self->invoicing_list_emailonly);
3565 }
3566
3567 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3568
3569 Returns an array of customers referred by this customer (referral_custnum set
3570 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3571 customers referred by customers referred by this customer and so on, inclusive.
3572 The default behavior is DEPTH 1 (no recursion).
3573
3574 =cut
3575
3576 sub referral_cust_main {
3577   my $self = shift;
3578   my $depth = @_ ? shift : 1;
3579   my $exclude = @_ ? shift : {};
3580
3581   my @cust_main =
3582     map { $exclude->{$_->custnum}++; $_; }
3583       grep { ! $exclude->{ $_->custnum } }
3584         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3585
3586   if ( $depth > 1 ) {
3587     push @cust_main,
3588       map { $_->referral_cust_main($depth-1, $exclude) }
3589         @cust_main;
3590   }
3591
3592   @cust_main;
3593 }
3594
3595 =item referral_cust_main_ncancelled
3596
3597 Same as referral_cust_main, except only returns customers with uncancelled
3598 packages.
3599
3600 =cut
3601
3602 sub referral_cust_main_ncancelled {
3603   my $self = shift;
3604   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3605 }
3606
3607 =item referral_cust_pkg [ DEPTH ]
3608
3609 Like referral_cust_main, except returns a flat list of all unsuspended (and
3610 uncancelled) packages for each customer.  The number of items in this list may
3611 be useful for comission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3612
3613 =cut
3614
3615 sub referral_cust_pkg {
3616   my $self = shift;
3617   my $depth = @_ ? shift : 1;
3618
3619   map { $_->unsuspended_pkgs }
3620     grep { $_->unsuspended_pkgs }
3621       $self->referral_cust_main($depth);
3622 }
3623
3624 =item referring_cust_main
3625
3626 Returns the single cust_main record for the customer who referred this customer
3627 (referral_custnum), or false.
3628
3629 =cut
3630
3631 sub referring_cust_main {
3632   my $self = shift;
3633   return '' unless $self->referral_custnum;
3634   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3635 }
3636
3637 =item credit AMOUNT, REASON
3638
3639 Applies a credit to this customer.  If there is an error, returns the error,
3640 otherwise returns false.
3641
3642 =cut
3643
3644 sub credit {
3645   my( $self, $amount, $reason ) = @_;
3646   my $cust_credit = new FS::cust_credit {
3647     'custnum' => $self->custnum,
3648     'amount'  => $amount,
3649     'reason'  => $reason,
3650   };
3651   $cust_credit->insert;
3652 }
3653
3654 =item charge AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3655
3656 Creates a one-time charge for this customer.  If there is an error, returns
3657 the error, otherwise returns false.
3658
3659 =cut
3660
3661 sub charge {
3662   my $self = shift;
3663   my ( $amount, $pkg, $comment, $taxclass, $additional );
3664   if ( ref( $_[0] ) ) {
3665     $amount     = $_[0]->{amount};
3666     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3667     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3668                                            : '$'. sprintf("%.2f",$amount);
3669     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3670     $additional = $_[0]->{additional};
3671   }else{
3672     $amount     = shift;
3673     $pkg        = @_ ? shift : 'One-time charge';
3674     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3675     $taxclass   = @_ ? shift : '';
3676     $additional = [];
3677   }
3678
3679   local $SIG{HUP} = 'IGNORE';
3680   local $SIG{INT} = 'IGNORE';
3681   local $SIG{QUIT} = 'IGNORE';
3682   local $SIG{TERM} = 'IGNORE';
3683   local $SIG{TSTP} = 'IGNORE';
3684   local $SIG{PIPE} = 'IGNORE';
3685
3686   my $oldAutoCommit = $FS::UID::AutoCommit;
3687   local $FS::UID::AutoCommit = 0;
3688   my $dbh = dbh;
3689
3690   my $part_pkg = new FS::part_pkg ( {
3691     'pkg'      => $pkg,
3692     'comment'  => $comment,
3693     'plan'     => 'flat',
3694     'freq'     => 0,
3695     'disabled' => 'Y',
3696     'taxclass' => $taxclass,
3697   } );
3698
3699   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3700                         ( 0 .. @$additional - 1 )
3701                   ),
3702                   'additional_count' => scalar(@$additional),
3703                   'setup_fee' => $amount,
3704                 );
3705
3706   my $error = $part_pkg->insert( options => \%options );
3707   if ( $error ) {
3708     $dbh->rollback if $oldAutoCommit;
3709     return $error;
3710   }
3711
3712   my $pkgpart = $part_pkg->pkgpart;
3713   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3714   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3715     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3716     $error = $type_pkgs->insert;
3717     if ( $error ) {
3718       $dbh->rollback if $oldAutoCommit;
3719       return $error;
3720     }
3721   }
3722
3723   my $cust_pkg = new FS::cust_pkg ( {
3724     'custnum' => $self->custnum,
3725     'pkgpart' => $pkgpart,
3726   } );
3727
3728   $error = $cust_pkg->insert;
3729   if ( $error ) {
3730     $dbh->rollback if $oldAutoCommit;
3731     return $error;
3732   }
3733
3734   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3735   '';
3736
3737 }
3738
3739 =item cust_bill
3740
3741 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3742
3743 =cut
3744
3745 sub cust_bill {
3746   my $self = shift;
3747   sort { $a->_date <=> $b->_date }
3748     qsearch('cust_bill', { 'custnum' => $self->custnum, } )
3749 }
3750
3751 =item open_cust_bill
3752
3753 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3754 customer.
3755
3756 =cut
3757
3758 sub open_cust_bill {
3759   my $self = shift;
3760   grep { $_->owed > 0 } $self->cust_bill;
3761 }
3762
3763 =item cust_credit
3764
3765 Returns all the credits (see L<FS::cust_credit>) for this customer.
3766
3767 =cut
3768
3769 sub cust_credit {
3770   my $self = shift;
3771   sort { $a->_date <=> $b->_date }
3772     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3773 }
3774
3775 =item cust_pay
3776
3777 Returns all the payments (see L<FS::cust_pay>) for this customer.
3778
3779 =cut
3780
3781 sub cust_pay {
3782   my $self = shift;
3783   sort { $a->_date <=> $b->_date }
3784     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
3785 }
3786
3787 =item cust_pay_void
3788
3789 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3790
3791 =cut
3792
3793 sub cust_pay_void {
3794   my $self = shift;
3795   sort { $a->_date <=> $b->_date }
3796     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3797 }
3798
3799
3800 =item cust_refund
3801
3802 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3803
3804 =cut
3805
3806 sub cust_refund {
3807   my $self = shift;
3808   sort { $a->_date <=> $b->_date }
3809     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3810 }
3811
3812 =item select_for_update
3813
3814 Selects this record with the SQL "FOR UPDATE" command.  This can be useful as
3815 a mutex.
3816
3817 =cut
3818
3819 sub select_for_update {
3820   my $self = shift;
3821   qsearch('cust_main', { 'custnum' => $self->custnum }, '*', 'FOR UPDATE' );
3822 }
3823
3824 =item name
3825
3826 Returns a name string for this customer, either "Company (Last, First)" or
3827 "Last, First".
3828
3829 =cut
3830
3831 sub name {
3832   my $self = shift;
3833   my $name = $self->contact;
3834   $name = $self->company. " ($name)" if $self->company;
3835   $name;
3836 }
3837
3838 =item ship_name
3839
3840 Returns a name string for this (service/shipping) contact, either
3841 "Company (Last, First)" or "Last, First".
3842
3843 =cut
3844
3845 sub ship_name {
3846   my $self = shift;
3847   if ( $self->get('ship_last') ) {
3848     my $name = $self->ship_contact;
3849     $name = $self->ship_company. " ($name)" if $self->ship_company;
3850     $name;
3851   } else {
3852     $self->name;
3853   }
3854 }
3855
3856 =item contact
3857
3858 Returns this customer's full (billing) contact name only, "Last, First"
3859
3860 =cut
3861
3862 sub contact {
3863   my $self = shift;
3864   $self->get('last'). ', '. $self->first;
3865 }
3866
3867 =item ship_contact
3868
3869 Returns this customer's full (shipping) contact name only, "Last, First"
3870
3871 =cut
3872
3873 sub ship_contact {
3874   my $self = shift;
3875   $self->get('ship_last')
3876     ? $self->get('ship_last'). ', '. $self->ship_first
3877     : $self->contact;
3878 }
3879
3880 =item country_full
3881
3882 Returns this customer's full country name
3883
3884 =cut
3885
3886 sub country_full {
3887   my $self = shift;
3888   code2country($self->country);
3889 }
3890
3891 =item status
3892
3893 Returns a status string for this customer, currently:
3894
3895 =over 4
3896
3897 =item prospect - No packages have ever been ordered
3898
3899 =item active - One or more recurring packages is active
3900
3901 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
3902
3903 =item suspended - All non-cancelled recurring packages are suspended
3904
3905 =item cancelled - All recurring packages are cancelled
3906
3907 =back
3908
3909 =cut
3910
3911 sub status {
3912   my $self = shift;
3913   for my $status (qw( prospect active inactive suspended cancelled )) {
3914     my $method = $status.'_sql';
3915     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
3916     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
3917     $sth->execute( ($self->custnum) x $numnum ) or die $sth->errstr;
3918     return $status if $sth->fetchrow_arrayref->[0];
3919   }
3920 }
3921
3922 =item statuscolor
3923
3924 Returns a hex triplet color string for this customer's status.
3925
3926 =cut
3927
3928 use vars qw(%statuscolor);
3929 %statuscolor = (
3930   'prospect'  => '7e0079', #'000000', #black?  naw, purple
3931   'active'    => '00CC00', #green
3932   'inactive'  => '0000CC', #blue
3933   'suspended' => 'FF9900', #yellow
3934   'cancelled' => 'FF0000', #red
3935 );
3936
3937 sub statuscolor {
3938   my $self = shift;
3939   $statuscolor{$self->status};
3940 }
3941
3942 =back
3943
3944 =head1 CLASS METHODS
3945
3946 =over 4
3947
3948 =item prospect_sql
3949
3950 Returns an SQL expression identifying prospective cust_main records (customers
3951 with no packages ever ordered)
3952
3953 =cut
3954
3955 use vars qw($select_count_pkgs);
3956 $select_count_pkgs =
3957   "SELECT COUNT(*) FROM cust_pkg
3958     WHERE cust_pkg.custnum = cust_main.custnum";
3959
3960 sub select_count_pkgs_sql {
3961   $select_count_pkgs;
3962 }
3963
3964 sub prospect_sql { "
3965   0 = ( $select_count_pkgs )
3966 "; }
3967
3968 =item active_sql
3969
3970 Returns an SQL expression identifying active cust_main records (customers with
3971 no active recurring packages, but otherwise unsuspended/uncancelled).
3972
3973 =cut
3974
3975 sub active_sql { "
3976   0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. "
3977       )
3978 "; }
3979
3980 =item inactive_sql
3981
3982 Returns an SQL expression identifying inactive cust_main records (customers with
3983 active recurring packages).
3984
3985 =cut
3986
3987 sub inactive_sql { "
3988   0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " )
3989   AND
3990   0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " )
3991 "; }
3992
3993 =item susp_sql
3994 =item suspended_sql
3995
3996 Returns an SQL expression identifying suspended cust_main records.
3997
3998 =cut
3999
4000
4001 sub suspended_sql { susp_sql(@_); }
4002 sub susp_sql { "
4003     0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " )
4004     AND
4005     0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " )
4006 "; }
4007
4008 =item cancel_sql
4009 =item cancelled_sql
4010
4011 Returns an SQL expression identifying cancelled cust_main records.
4012
4013 =cut
4014
4015 sub cancelled_sql { cancel_sql(@_); }
4016 sub cancel_sql {
4017
4018   my $recurring_sql = FS::cust_pkg->recurring_sql;
4019   #my $recurring_sql = "
4020   #  '0' != ( select freq from part_pkg
4021   #             where cust_pkg.pkgpart = part_pkg.pkgpart )
4022   #";
4023
4024   "
4025     0 < ( $select_count_pkgs )
4026     AND 0 = ( $select_count_pkgs AND $recurring_sql
4027                   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4028             )
4029   ";
4030 }
4031
4032 =item uncancel_sql
4033 =item uncancelled_sql
4034
4035 Returns an SQL expression identifying un-cancelled cust_main records.
4036
4037 =cut
4038
4039 sub uncancelled_sql { uncancel_sql(@_); }
4040 sub uncancel_sql { "
4041   ( 0 < ( $select_count_pkgs
4042                    AND ( cust_pkg.cancel IS NULL
4043                          OR cust_pkg.cancel = 0
4044                        )
4045         )
4046     OR 0 = ( $select_count_pkgs )
4047   )
4048 "; }
4049
4050 =item fuzzy_search FUZZY_HASHREF [ HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ ]
4051
4052 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
4053 records.  Currently, I<first>, I<last> and/or I<company> may be specified (the
4054 appropriate ship_ field is also searched).
4055
4056 Additional options are the same as FS::Record::qsearch
4057
4058 =cut
4059
4060 sub fuzzy_search {
4061   my( $self, $fuzzy, $hash, @opt) = @_;
4062   #$self
4063   $hash ||= {};
4064   my @cust_main = ();
4065
4066   check_and_rebuild_fuzzyfiles();
4067   foreach my $field ( keys %$fuzzy ) {
4068
4069     my $all = $self->all_X($field);
4070     next unless scalar(@$all);
4071
4072     my %match = ();
4073     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, ['i'], @$all ) );
4074
4075     my @fcust = ();
4076     foreach ( keys %match ) {
4077       push @fcust, qsearch('cust_main', { %$hash, $field=>$_}, @opt);
4078       push @fcust, qsearch('cust_main', { %$hash, "ship_$field"=>$_}, @opt);
4079     }
4080     my %fsaw = ();
4081     push @cust_main, grep { ! $fsaw{$_->custnum}++ } @fcust;
4082   }
4083
4084   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
4085   my %saw = ();
4086   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
4087
4088   @cust_main;
4089
4090 }
4091
4092 =back
4093
4094 =head1 SUBROUTINES
4095
4096 =over 4
4097
4098 =item smart_search OPTION => VALUE ...
4099
4100 Accepts the following options: I<search>, the string to search for.  The string
4101 will be searched for as a customer number, phone number, name or company name,
4102 as an exact, or, in some cases, a substring or fuzzy match (see the source code
4103 for the exact heuristics used).
4104
4105 Any additional options are treated as an additional qualifier on the search
4106 (i.e. I<agentnum>).
4107
4108 Returns a (possibly empty) array of FS::cust_main objects.
4109
4110 =cut
4111
4112 sub smart_search {
4113   my %options = @_;
4114
4115   #here is the agent virtualization
4116   my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
4117
4118   my @cust_main = ();
4119
4120   my $search = delete $options{'search'};
4121   ( my $alphanum_search = $search ) =~ s/\W//g;
4122
4123   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
4124
4125     #false laziness w/Record::ut_phone
4126     my $phonen = "$1-$2-$3";
4127     $phonen .= " x$4" if $4;
4128
4129     push @cust_main, qsearch( {
4130       'table'   => 'cust_main',
4131       'hashref' => { %options },
4132       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
4133                      ' ( '.
4134                          join(' OR ', map "$_ = '$phonen'",
4135                                           qw( daytime night fax
4136                                               ship_daytime ship_night ship_fax )
4137                              ).
4138                      ' ) '.
4139                      " AND $agentnums_sql", #agent virtualization
4140     } );
4141
4142     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
4143       #try looking for matches with extensions unless one was specified
4144
4145       push @cust_main, qsearch( {
4146         'table'   => 'cust_main',
4147         'hashref' => { %options },
4148         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
4149                        ' ( '.
4150                            join(' OR ', map "$_ LIKE '$phonen\%'",
4151                                             qw( daytime night
4152                                                 ship_daytime ship_night )
4153                                ).
4154                        ' ) '.
4155                        " AND $agentnums_sql", #agent virtualization
4156       } );
4157
4158     }
4159
4160   } elsif ( $search =~ /^\s*(\d+)\s*$/ ) { # customer # search
4161
4162     push @cust_main, qsearch( {
4163       'table'     => 'cust_main',
4164       'hashref'   => { 'custnum' => $1, %options },
4165       'extra_sql' => " AND $agentnums_sql", #agent virtualization
4166     } );
4167
4168   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
4169
4170     my($company, $last, $first) = ( $1, $2, $3 );
4171
4172     # "Company (Last, First)"
4173     #this is probably something a browser remembered,
4174     #so just do an exact search
4175
4176     foreach my $prefix ( '', 'ship_' ) {
4177       push @cust_main, qsearch( {
4178         'table'     => 'cust_main',
4179         'hashref'   => { $prefix.'first'   => $first,
4180                          $prefix.'last'    => $last,
4181                          $prefix.'company' => $company,
4182                          %options,
4183                        },
4184         'extra_sql' => " AND $agentnums_sql",
4185       } );
4186     }
4187
4188   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
4189                                               # try (ship_){last,company}
4190
4191     my $value = lc($1);
4192
4193     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
4194     # # full strings the browser remembers won't work
4195     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
4196
4197     use Lingua::EN::NameParse;
4198     my $NameParse = new Lingua::EN::NameParse(
4199              auto_clean     => 1,
4200              allow_reversed => 1,
4201     );
4202
4203     my($last, $first) = ( '', '' );
4204     #maybe disable this too and just rely on NameParse?
4205     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
4206
4207       ($last, $first) = ( $1, $2 );
4208
4209     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
4210     } elsif ( ! $NameParse->parse($value) ) {
4211
4212       my %name = $NameParse->components;
4213       $first = $name{'given_name_1'};
4214       $last  = $name{'surname_1'};
4215
4216     }
4217
4218     if ( $first && $last ) {
4219
4220       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
4221
4222       #exact
4223       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
4224       $sql .= "
4225         (     ( LOWER(last) = $q_last AND LOWER(first) = $q_first )
4226            OR ( LOWER(ship_last) = $q_last AND LOWER(ship_first) = $q_first )
4227         )";
4228
4229       push @cust_main, qsearch( {
4230         'table'     => 'cust_main',
4231         'hashref'   => \%options,
4232         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
4233       } );
4234
4235       # or it just be something that was typed in... (try that in a sec)
4236
4237     }
4238
4239     my $q_value = dbh->quote($value);
4240
4241     #exact
4242     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
4243     $sql .= " (    LOWER(last)         = $q_value
4244                 OR LOWER(company)      = $q_value
4245                 OR LOWER(ship_last)    = $q_value
4246                 OR LOWER(ship_company) = $q_value
4247               )";
4248
4249     push @cust_main, qsearch( {
4250       'table'     => 'cust_main',
4251       'hashref'   => \%options,
4252       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
4253     } );
4254
4255     #always do substring & fuzzy,
4256     #getting complains searches are not returning enough
4257     #unless ( @cust_main ) {  #no exact match, trying substring/fuzzy
4258
4259       #still some false laziness w/ search/cust_main.cgi
4260
4261       #substring
4262
4263       my @hashrefs = (
4264         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
4265         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
4266       );
4267
4268       if ( $first && $last ) {
4269
4270         push @hashrefs,
4271           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
4272             'last'         => { op=>'ILIKE', value=>"%$last%" },
4273           },
4274           { 'ship_first'   => { op=>'ILIKE', value=>"%$first%" },
4275             'ship_last'    => { op=>'ILIKE', value=>"%$last%" },
4276           },
4277         ;
4278
4279       } else {
4280
4281         push @hashrefs,
4282           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
4283           { 'ship_last'    => { op=>'ILIKE', value=>"%$value%" }, },
4284         ;
4285       }
4286
4287       foreach my $hashref ( @hashrefs ) {
4288
4289         push @cust_main, qsearch( {
4290           'table'     => 'cust_main',
4291           'hashref'   => { %$hashref,
4292                            %options,
4293                          },
4294           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
4295         } );
4296
4297       }
4298
4299       #fuzzy
4300       my @fuzopts = (
4301         \%options,                #hashref
4302         '',                       #select
4303         " AND $agentnums_sql",    #extra_sql  #agent virtualization
4304       );
4305
4306       if ( $first && $last ) {
4307         push @cust_main, FS::cust_main->fuzzy_search(
4308           { 'last'   => $last,    #fuzzy hashref
4309             'first'  => $first }, #
4310           @fuzopts
4311         );
4312       }
4313       foreach my $field ( 'last', 'company' ) {
4314         push @cust_main,
4315           FS::cust_main->fuzzy_search( { $field => $value }, @fuzopts );
4316       }
4317
4318     #}
4319
4320     #eliminate duplicates
4321     my %saw = ();
4322     @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
4323
4324   }
4325
4326   @cust_main;
4327
4328 }
4329
4330 =item check_and_rebuild_fuzzyfiles
4331
4332 =cut
4333
4334 use vars qw(@fuzzyfields);
4335 @fuzzyfields = ( 'last', 'first', 'company' );
4336
4337 sub check_and_rebuild_fuzzyfiles {
4338   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
4339   rebuild_fuzzyfiles() if grep { ! -e "$dir/cust_main.$_" } @fuzzyfields
4340 }
4341
4342 =item rebuild_fuzzyfiles
4343
4344 =cut
4345
4346 sub rebuild_fuzzyfiles {
4347
4348   use Fcntl qw(:flock);
4349
4350   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
4351   mkdir $dir, 0700 unless -d $dir;
4352
4353   foreach my $fuzzy ( @fuzzyfields ) {
4354
4355     open(LOCK,">>$dir/cust_main.$fuzzy")
4356       or die "can't open $dir/cust_main.$fuzzy: $!";
4357     flock(LOCK,LOCK_EX)
4358       or die "can't lock $dir/cust_main.$fuzzy: $!";
4359
4360     open (CACHE,">$dir/cust_main.$fuzzy.tmp")
4361       or die "can't open $dir/cust_main.$fuzzy.tmp: $!";
4362
4363     foreach my $field ( $fuzzy, "ship_$fuzzy" ) {
4364       my $sth = dbh->prepare("SELECT $field FROM cust_main".
4365                              " WHERE $field != '' AND $field IS NOT NULL");
4366       $sth->execute or die $sth->errstr;
4367
4368       while ( my $row = $sth->fetchrow_arrayref ) {
4369         print CACHE $row->[0]. "\n";
4370       }
4371
4372     }
4373
4374     close CACHE or die "can't close $dir/cust_main.$fuzzy.tmp: $!";
4375
4376     rename "$dir/cust_main.$fuzzy.tmp", "$dir/cust_main.$fuzzy";
4377     close LOCK;
4378   }
4379
4380 }
4381
4382 =item all_X
4383
4384 =cut
4385
4386 sub all_X {
4387   my( $self, $field ) = @_;
4388   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
4389   open(CACHE,"<$dir/cust_main.$field")
4390     or die "can't open $dir/cust_main.$field: $!";
4391   my @array = map { chomp; $_; } <CACHE>;
4392   close CACHE;
4393   \@array;
4394 }
4395
4396 =item append_fuzzyfiles LASTNAME COMPANY
4397
4398 =cut
4399
4400 sub append_fuzzyfiles {
4401   #my( $first, $last, $company ) = @_;
4402
4403   &check_and_rebuild_fuzzyfiles;
4404
4405   use Fcntl qw(:flock);
4406
4407   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
4408
4409   foreach my $field (qw( first last company )) {
4410     my $value = shift;
4411
4412     if ( $value ) {
4413
4414       open(CACHE,">>$dir/cust_main.$field")
4415         or die "can't open $dir/cust_main.$field: $!";
4416       flock(CACHE,LOCK_EX)
4417         or die "can't lock $dir/cust_main.$field: $!";
4418
4419       print CACHE "$value\n";
4420
4421       flock(CACHE,LOCK_UN)
4422         or die "can't unlock $dir/cust_main.$field: $!";
4423       close CACHE;
4424     }
4425
4426   }
4427
4428   1;
4429 }
4430
4431 =item batch_import
4432
4433 =cut
4434
4435 sub batch_import {
4436   my $param = shift;
4437   #warn join('-',keys %$param);
4438   my $fh = $param->{filehandle};
4439   my $agentnum = $param->{agentnum};
4440
4441   my $refnum = $param->{refnum};
4442   my $pkgpart = $param->{pkgpart};
4443
4444   #my @fields = @{$param->{fields}};
4445   my $format = $param->{'format'};
4446   my @fields;
4447   my $payby;
4448   if ( $format eq 'simple' ) {
4449     @fields = qw( cust_pkg.setup dayphone first last
4450                   address1 address2 city state zip comments );
4451     $payby = 'BILL';
4452   } elsif ( $format eq 'extended' ) {
4453     @fields = qw( agent_custid refnum
4454                   last first address1 address2 city state zip country
4455                   daytime night
4456                   ship_last ship_first ship_address1 ship_address2
4457                   ship_city ship_state ship_zip ship_country
4458                   payinfo paycvv paydate
4459                   invoicing_list
4460                   cust_pkg.pkgpart
4461                   svc_acct.username svc_acct._password
4462                 );
4463     $payby = 'BILL';
4464   } else {
4465     die "unknown format $format";
4466   }
4467
4468   eval "use Text::CSV_XS;";
4469   die $@ if $@;
4470
4471   my $csv = new Text::CSV_XS;
4472   #warn $csv;
4473   #warn $fh;
4474
4475   my $imported = 0;
4476   #my $columns;
4477
4478   local $SIG{HUP} = 'IGNORE';
4479   local $SIG{INT} = 'IGNORE';
4480   local $SIG{QUIT} = 'IGNORE';
4481   local $SIG{TERM} = 'IGNORE';
4482   local $SIG{TSTP} = 'IGNORE';
4483   local $SIG{PIPE} = 'IGNORE';
4484
4485   my $oldAutoCommit = $FS::UID::AutoCommit;
4486   local $FS::UID::AutoCommit = 0;
4487   my $dbh = dbh;
4488
4489   #while ( $columns = $csv->getline($fh) ) {
4490   my $line;
4491   while ( defined($line=<$fh>) ) {
4492
4493     $csv->parse($line) or do {
4494       $dbh->rollback if $oldAutoCommit;
4495       return "can't parse: ". $csv->error_input();
4496     };
4497
4498     my @columns = $csv->fields();
4499     #warn join('-',@columns);
4500
4501     my %cust_main = (
4502       agentnum => $agentnum,
4503       refnum   => $refnum,
4504       country  => $conf->config('countrydefault') || 'US',
4505       payby    => $payby, #default
4506       paydate  => '12/2037', #default
4507     );
4508     my $billtime = time;
4509     my %cust_pkg = ( pkgpart => $pkgpart );
4510     my %svc_acct = ();
4511     foreach my $field ( @fields ) {
4512
4513       if ( $field =~ /^cust_pkg\.(pkgpart|setup|bill|susp|expire|cancel)$/ ) {
4514
4515         #$cust_pkg{$1} = str2time( shift @$columns );
4516         if ( $1 eq 'pkgpart' ) {
4517           $cust_pkg{$1} = shift @columns;
4518         } elsif ( $1 eq 'setup' ) {
4519           $billtime = str2time(shift @columns);
4520         } else {
4521           $cust_pkg{$1} = str2time( shift @columns );
4522         }
4523
4524       } elsif ( $field =~ /^svc_acct\.(username|_password)$/ ) {
4525
4526         $svc_acct{$1} = shift @columns;
4527
4528       } else {
4529
4530         #refnum interception
4531         if ( $field eq 'refnum' && $columns[0] !~ /^\s*(\d+)\s*$/ ) {
4532
4533           my $referral = $columns[0];
4534           my %hash = ( 'referral' => $referral,
4535                        'agentnum' => $agentnum,
4536                        'disabled' => '',
4537                      );
4538
4539           my $part_referral = qsearchs('part_referral', \%hash )
4540                               || new FS::part_referral \%hash;
4541
4542           unless ( $part_referral->refnum ) {
4543             my $error = $part_referral->insert;
4544             if ( $error ) {
4545               $dbh->rollback if $oldAutoCommit;
4546               return "can't auto-insert advertising source: $referral: $error";
4547             }
4548           }
4549
4550           $columns[0] = $part_referral->refnum;
4551         }
4552
4553         #$cust_main{$field} = shift @$columns;
4554         $cust_main{$field} = shift @columns;
4555       }
4556     }
4557
4558     $cust_main{'payby'} = 'CARD' if length($cust_main{'payinfo'});
4559
4560     my $invoicing_list = $cust_main{'invoicing_list'}
4561                            ? [ delete $cust_main{'invoicing_list'} ]
4562                            : [];
4563
4564     my $cust_main = new FS::cust_main ( \%cust_main );
4565
4566     use Tie::RefHash;
4567     tie my %hash, 'Tie::RefHash'; #this part is important
4568
4569     if ( $cust_pkg{'pkgpart'} ) {
4570       my $cust_pkg = new FS::cust_pkg ( \%cust_pkg );
4571
4572       my @svc_acct = ();
4573       if ( $svc_acct{'username'} ) {
4574         my $part_pkg = $cust_pkg->part_pkg;
4575         unless ( $part_pkg ) {
4576           $dbh->rollback if $oldAutoCommit;
4577           return "unknown pkgnum ". $cust_pkg{'pkgpart'};
4578         }
4579         $svc_acct{svcpart} = $part_pkg->svcpart( 'svc_acct' );
4580         push @svc_acct, new FS::svc_acct ( \%svc_acct )
4581       }
4582
4583       $hash{$cust_pkg} = \@svc_acct;
4584     }
4585
4586     my $error = $cust_main->insert( \%hash, $invoicing_list );
4587
4588     if ( $error ) {
4589       $dbh->rollback if $oldAutoCommit;
4590       return "can't insert customer for $line: $error";
4591     }
4592
4593     if ( $format eq 'simple' ) {
4594
4595       #false laziness w/bill.cgi
4596       $error = $cust_main->bill( 'time' => $billtime );
4597       if ( $error ) {
4598         $dbh->rollback if $oldAutoCommit;
4599         return "can't bill customer for $line: $error";
4600       }
4601
4602       $cust_main->apply_payments_and_credits;
4603
4604       $error = $cust_main->collect();
4605       if ( $error ) {
4606         $dbh->rollback if $oldAutoCommit;
4607         return "can't collect customer for $line: $error";
4608       }
4609
4610     }
4611
4612     $imported++;
4613   }
4614
4615   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4616
4617   return "Empty file!" unless $imported;
4618
4619   ''; #no error
4620
4621 }
4622
4623 =item batch_charge
4624
4625 =cut
4626
4627 sub batch_charge {
4628   my $param = shift;
4629   #warn join('-',keys %$param);
4630   my $fh = $param->{filehandle};
4631   my @fields = @{$param->{fields}};
4632
4633   eval "use Text::CSV_XS;";
4634   die $@ if $@;
4635
4636   my $csv = new Text::CSV_XS;
4637   #warn $csv;
4638   #warn $fh;
4639
4640   my $imported = 0;
4641   #my $columns;
4642
4643   local $SIG{HUP} = 'IGNORE';
4644   local $SIG{INT} = 'IGNORE';
4645   local $SIG{QUIT} = 'IGNORE';
4646   local $SIG{TERM} = 'IGNORE';
4647   local $SIG{TSTP} = 'IGNORE';
4648   local $SIG{PIPE} = 'IGNORE';
4649
4650   my $oldAutoCommit = $FS::UID::AutoCommit;
4651   local $FS::UID::AutoCommit = 0;
4652   my $dbh = dbh;
4653
4654   #while ( $columns = $csv->getline($fh) ) {
4655   my $line;
4656   while ( defined($line=<$fh>) ) {
4657
4658     $csv->parse($line) or do {
4659       $dbh->rollback if $oldAutoCommit;
4660       return "can't parse: ". $csv->error_input();
4661     };
4662
4663     my @columns = $csv->fields();
4664     #warn join('-',@columns);
4665
4666     my %row = ();
4667     foreach my $field ( @fields ) {
4668       $row{$field} = shift @columns;
4669     }
4670
4671     my $cust_main = qsearchs('cust_main', { 'custnum' => $row{'custnum'} } );
4672     unless ( $cust_main ) {
4673       $dbh->rollback if $oldAutoCommit;
4674       return "unknown custnum $row{'custnum'}";
4675     }
4676
4677     if ( $row{'amount'} > 0 ) {
4678       my $error = $cust_main->charge($row{'amount'}, $row{'pkg'});
4679       if ( $error ) {
4680         $dbh->rollback if $oldAutoCommit;
4681         return $error;
4682       }
4683       $imported++;
4684     } elsif ( $row{'amount'} < 0 ) {
4685       my $error = $cust_main->credit( sprintf( "%.2f", 0-$row{'amount'} ),
4686                                       $row{'pkg'}                         );
4687       if ( $error ) {
4688         $dbh->rollback if $oldAutoCommit;
4689         return $error;
4690       }
4691       $imported++;
4692     } else {
4693       #hmm?
4694     }
4695
4696   }
4697
4698   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4699
4700   return "Empty file!" unless $imported;
4701
4702   ''; #no error
4703
4704 }
4705
4706 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4707
4708 Sends a templated email notification to the customer (see L<Text::Template).
4709
4710 OPTIONS is a hash and may include
4711
4712 I<from> - the email sender (default is invoice_from)
4713
4714 I<to> - comma-separated scalar or arrayref of recipients
4715    (default is invoicing_list)
4716
4717 I<subject> - The subject line of the sent email notification
4718    (default is "Notice from company_name")
4719
4720 I<extra_fields> - a hashref of name/value pairs which will be substituted
4721    into the template
4722
4723 The following variables are vavailable in the template.
4724
4725 I<$first> - the customer first name
4726 I<$last> - the customer last name
4727 I<$company> - the customer company
4728 I<$payby> - a description of the method of payment for the customer
4729             # would be nice to use FS::payby::shortname
4730 I<$payinfo> - the account information used to collect for this customer
4731 I<$expdate> - the expiration of the customer payment in seconds from epoch
4732
4733 =cut
4734
4735 sub notify {
4736   my ($customer, $template, %options) = @_;
4737
4738   return unless $conf->exists($template);
4739
4740   my $from = $conf->config('invoice_from') if $conf->exists('invoice_from');
4741   $from = $options{from} if exists($options{from});
4742
4743   my $to = join(',', $customer->invoicing_list_emailonly);
4744   $to = $options{to} if exists($options{to});
4745
4746   my $subject = "Notice from " . $conf->config('company_name')
4747     if $conf->exists('company_name');
4748   $subject = $options{subject} if exists($options{subject});
4749
4750   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4751                                             SOURCE => [ map "$_\n",
4752                                               $conf->config($template)]
4753                                            )
4754     or die "can't create new Text::Template object: Text::Template::ERROR";
4755   $notify_template->compile()
4756     or die "can't compile template: Text::Template::ERROR";
4757
4758   my $paydate = $customer->paydate;
4759   $FS::notify_template::_template::first = $customer->first;
4760   $FS::notify_template::_template::last = $customer->last;
4761   $FS::notify_template::_template::company = $customer->company;
4762   $FS::notify_template::_template::payinfo = $customer->mask_payinfo;
4763   my $payby = $customer->payby;
4764   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4765   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4766
4767   #credit cards expire at the end of the month/year of their exp date
4768   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4769     $FS::notify_template::_template::payby = 'credit card';
4770     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4771     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4772     $expire_time--;
4773   }elsif ($payby eq 'COMP') {
4774     $FS::notify_template::_template::payby = 'complimentary account';
4775   }else{
4776     $FS::notify_template::_template::payby = 'current method';
4777   }
4778   $FS::notify_template::_template::expdate = $expire_time;
4779
4780   for (keys %{$options{extra_fields}}){
4781     no strict "refs";
4782     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4783   }
4784
4785   send_email(from => $from,
4786              to => $to,
4787              subject => $subject,
4788              body => $notify_template->fill_in( PACKAGE =>
4789                                                 'FS::notify_template::_template'                                              ),
4790             );
4791
4792 }
4793
4794 =back
4795
4796 =head1 BUGS
4797
4798 The delete method.
4799
4800 The delete method should possibly take an FS::cust_main object reference
4801 instead of a scalar customer number.
4802
4803 Bill and collect options should probably be passed as references instead of a
4804 list.
4805
4806 There should probably be a configuration file with a list of allowed credit
4807 card types.
4808
4809 No multiple currency support (probably a larger project than just this module).
4810
4811 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
4812
4813 Birthdates rely on negative epoch values.
4814
4815 =head1 SEE ALSO
4816
4817 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
4818 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
4819 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
4820
4821 =cut
4822
4823 1;
4824