FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Try::Tiny;
  24 use Scalar::Util qw( blessed );
  25 use List::Util qw(min);
  26 use Tie::IxHash;
  27 use File::Temp; #qw( tempfile );
  28 use Data::Dumper;
  29 use Time::Local qw(timelocal);
  30 use Date::Format;
  31 #use Date::Manip;
  32 use Email::Address;
  33 use Business::CreditCard 0.28;
  34 use FS::UID qw( dbh driver_name );
  35 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  36 use FS::Cursor;
  37 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  38 use FS::Msgcat qw(gettext);
  39 use FS::CurrentUser;
  40 use FS::TicketSystem;
  41 use FS::payby;
  42 use FS::cust_pkg;
  43 use FS::cust_svc;
  44 use FS::cust_bill;
  45 use FS::cust_bill_void;
  46 use FS::legacy_cust_bill;
  47 use FS::cust_pay;
  48 use FS::cust_pay_pending;
  49 use FS::cust_pay_void;
  50 use FS::cust_pay_batch;
  51 use FS::cust_credit;
  52 use FS::cust_refund;
  53 use FS::part_referral;
  54 use FS::cust_main_county;
  55 use FS::cust_location;
  56 use FS::cust_class;
  57 use FS::tax_status;
  58 use FS::cust_main_exemption;
  59 use FS::cust_tax_adjustment;
  60 use FS::cust_tax_location;
  61 use FS::agent_currency;
  62 use FS::cust_main_invoice;
  63 use FS::cust_tag;
  64 use FS::prepay_credit;
  65 use FS::queue;
  66 use FS::part_pkg;
  67 use FS::part_export;
  68 #use FS::cust_event;
  69 use FS::type_pkgs;
  70 use FS::payment_gateway;
  71 use FS::agent_payment_gateway;
  72 use FS::banned_pay;
  73 use FS::cust_main_note;
  74 use FS::cust_attachment;
  75 use FS::cust_contact;
  76 use FS::Locales;
  77 use FS::upgrade_journal;
  78 use FS::sales;
  79 use FS::cust_payby;
  80 use FS::contact;
  81 use FS::reason;
  82 use FS::Misc::Savepoint;
  83 use FS::DBI;
  84
  85 # 1 is mostly method/subroutine entry and options
  86 # 2 traces progress of some operations
  87 # 3 is even more information including possibly sensitive data
  88 our $DEBUG = 0;
  89 our $me = '[FS::cust_main]';
  90
  91 our $import = 0;
  92 our $ignore_expired_card = 0;
  93 our $ignore_banned_card = 0;
  94 our $ignore_invalid_card = 0;
  95
  96 our $skip_fuzzyfiles = 0;
  97
  98 our $ucfirst_nowarn = 0;
  99
 100 #this info is in cust_payby as of 4.x
 101 #this and the fields themselves can be removed in 5.x
 102 our @encrypted_fields = ('payinfo', 'paycvv');
 103 sub nohistory_fields { ('payinfo', 'paycvv'); }
 104
 105 our $conf;
 106 our $default_agent_custid;
 107 our $custnum_display_length;
 108 #ask FS::UID to run this stuff for us later
 109 #$FS::UID::callback{'FS::cust_main'} = sub {
 110 install_callback FS::UID sub {
 111   $conf = new FS::Conf;
 112   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 113   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 114   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 115 };
 116
 117 sub _cache {
 118   my $self = shift;
 119   my ( $hashref, $cache ) = @_;
 120   if ( exists $hashref->{'pkgnum'} ) {
 121     #@{ $self->{'_pkgnum'} } = ();
 122     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 123     $self->{'_pkgnum'} = $subcache;
 124     #push @{ $self->{'_pkgnum'} },
 125     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 126   }
 127 }
 128
 129 =head1 NAME
 130
 131 FS::cust_main - Object methods for cust_main records
 132
 133 =head1 SYNOPSIS
 134
 135   use FS::cust_main;
 136
 137   $record = new FS::cust_main \%hash;
 138   $record = new FS::cust_main { 'column' => 'value' };
 139
 140   $error = $record->insert;
 141
 142   $error = $new_record->replace($old_record);
 143
 144   $error = $record->delete;
 145
 146   $error = $record->check;
 147
 148   @cust_pkg = $record->all_pkgs;
 149
 150   @cust_pkg = $record->ncancelled_pkgs;
 151
 152   @cust_pkg = $record->suspended_pkgs;
 153
 154   $error = $record->bill;
 155   $error = $record->bill %options;
 156   $error = $record->bill 'time' => $time;
 157
 158   $error = $record->collect;
 159   $error = $record->collect %options;
 160   $error = $record->collect 'invoice_time'   => $time,
 161                           ;
 162
 163 =head1 DESCRIPTION
 164
 165 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 166 FS::Record.  The following fields are currently supported:
 167
 168 =over 4
 169
 170 =item custnum
 171
 172 Primary key (assigned automatically for new customers)
 173
 174 =item agentnum
 175
 176 Agent (see L<FS::agent>)
 177
 178 =item refnum
 179
 180 Advertising source (see L<FS::part_referral>)
 181
 182 =item first
 183
 184 First name
 185
 186 =item last
 187
 188 Last name
 189
 190 =item ss
 191
 192 Cocial security number (optional)
 193
 194 =item company
 195
 196 (optional)
 197
 198 =item daytime
 199
 200 phone (optional)
 201
 202 =item night
 203
 204 phone (optional)
 205
 206 =item fax
 207
 208 phone (optional)
 209
 210 =item mobile
 211
 212 phone (optional)
 213
 214 =item payby
 215
 216 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 217
 218 =item payinfo
 219
 220 Payment Information (See L<FS::payinfo_Mixin> for data format)
 221
 222 =item paymask
 223
 224 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 225
 226 =item paycvv
 227
 228 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 229
 230 =item paydate
 231
 232 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 233
 234 =item paystart_month
 235
 236 Start date month (maestro/solo cards only)
 237
 238 =item paystart_year
 239
 240 Start date year (maestro/solo cards only)
 241
 242 =item payissue
 243
 244 Issue number (maestro/solo cards only)
 245
 246 =item payname
 247
 248 Name on card or billing name
 249
 250 =item payip
 251
 252 IP address from which payment information was received
 253
 254 =item tax
 255
 256 Tax exempt, empty or `Y'
 257
 258 =item usernum
 259
 260 Order taker (see L<FS::access_user>)
 261
 262 =item comments
 263
 264 Comments (optional)
 265
 266 =item referral_custnum
 267
 268 Referring customer number
 269
 270 =item spool_cdr
 271
 272 Enable individual CDR spooling, empty or `Y'
 273
 274 =item dundate
 275
 276 A suggestion to events (see L<FS::part_bill_event>) to delay until this unix timestamp
 277
 278 =item squelch_cdr
 279
 280 Discourage individual CDR printing, empty or `Y'
 281
 282 =item edit_subject
 283
 284 Allow self-service editing of ticket subjects, empty or 'Y'
 285
 286 =item calling_list_exempt
 287
 288 Do not call, empty or 'Y'
 289
 290 =item invoice_ship_address
 291
 292 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 293
 294 =back
 295
 296 =head1 METHODS
 297
 298 =over 4
 299
 300 =item new HASHREF
 301
 302 Creates a new customer.  To add the customer to the database, see L<"insert">.
 303
 304 Note that this stores the hash reference, not a distinct copy of the hash it
 305 points to.  You can ask the object for a copy with the I<hash> method.
 306
 307 =cut
 308
 309 sub table { 'cust_main'; }
 310
 311 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 312
 313 Adds this customer to the database.  If there is an error, returns the error,
 314 otherwise returns false.
 315
 316 Usually the customer's location will not yet exist in the database, and
 317 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 318 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 319 (in both directions) to the new customer record.  If they're references
 320 to the same object, they will become the same location.
 321
 322 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 323 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 324 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 325 hash reference is equivalent to not supplying this parameter.  There should be
 326 a better explanation of this, but until then, here's an example:
 327
 328   use Tie::RefHash;
 329   tie %hash, 'Tie::RefHash'; #this part is important
 330   %hash = (
 331     $cust_pkg => [ $svc_acct ],
 332     ...
 333   );
 334   $cust_main->insert( \%hash );
 335
 336 INVOICING_LIST_ARYREF: No longer supported.
 337
 338 Currently available options are: I<depend_jobnum>, I<noexport>,
 339 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 340
 341 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 342 on the supplied jobnum (they will not run until the specific job completes).
 343 This can be used to defer provisioning until some action completes (such
 344 as running the customer's credit card successfully).
 345
 346 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 347 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 348 the B<reexport> method.)
 349
 350 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 351 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 352 created and inserted.
 353
 354 If I<prospectnum> is set, moves contacts and locations from that prospect.
 355
 356 If I<contact> is set to an arrayref of FS::contact objects, those will be
 357 inserted.
 358
 359 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 360 unset), inserts those new contacts with this new customer.  Handles CGI
 361 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 362
 363 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 364 new stored payment records with this new customer.  Handles CGI parameters
 365 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 366
 367 =cut
 368
 369 sub insert {
 370   my $self = shift;
 371   my $cust_pkgs = @_ ? shift : {};
 372   my $invoicing_list;
 373   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 374     warn "cust_main::insert using deprecated invoicing list argument";
 375     $invoicing_list = shift;
 376   }
 377   my %options = @_;
 378   warn "$me insert called with options ".
 379        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 380     if $DEBUG;
 381
 382   return "You are not permitted to change customer invoicing terms."
 383     if $self->invoice_terms #i.e. not the default
 384     && ! $FS::CurrentUser::CurrentUser->access_right('Edit customer invoice terms');
 385
 386   local $SIG{HUP} = 'IGNORE';
 387   local $SIG{INT} = 'IGNORE';
 388   local $SIG{QUIT} = 'IGNORE';
 389   local $SIG{TERM} = 'IGNORE';
 390   local $SIG{TSTP} = 'IGNORE';
 391   local $SIG{PIPE} = 'IGNORE';
 392
 393   my $oldAutoCommit = $FS::UID::AutoCommit;
 394   local $FS::UID::AutoCommit = 0;
 395   my $dbh = dbh;
 396
 397   my $prepay_identifier = '';
 398   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 399   my $payby = '';
 400   if ( $self->payby eq 'PREPAY' ) {
 401
 402     $self->payby(''); #'BILL');
 403     $prepay_identifier = $self->payinfo;
 404     $self->payinfo('');
 405
 406     warn "  looking up prepaid card $prepay_identifier\n"
 407       if $DEBUG > 1;
 408
 409     my $error = $self->get_prepay( $prepay_identifier,
 410                                    'amount_ref'     => \$amount,
 411                                    'seconds_ref'    => \$seconds,
 412                                    'upbytes_ref'    => \$upbytes,
 413                                    'downbytes_ref'  => \$downbytes,
 414                                    'totalbytes_ref' => \$totalbytes,
 415                                  );
 416     if ( $error ) {
 417       $dbh->rollback if $oldAutoCommit;
 418       #return "error applying prepaid card (transaction rolled back): $error";
 419       return $error;
 420     }
 421
 422     $payby = 'PREP' if $amount;
 423
 424   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 425
 426     $payby = $1;
 427     $self->payby(''); #'BILL');
 428     $amount = $self->paid;
 429
 430   }
 431
 432   # insert locations
 433   foreach my $l (qw(bill_location ship_location)) {
 434
 435     my $loc = delete $self->hashref->{$l} or next;
 436
 437     if ( !$loc->locationnum ) {
 438       # warn the location that we're going to insert it with no custnum
 439       $loc->set(custnum_pending => 1);
 440       warn "  inserting $l\n"
 441         if $DEBUG > 1;
 442       my $error = $loc->insert;
 443       if ( $error ) {
 444         $dbh->rollback if $oldAutoCommit;
 445         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 446         return "$error (in $label location)";
 447       }
 448
 449     } elsif ( $loc->prospectnum ) {
 450
 451       $loc->prospectnum('');
 452       $loc->set(custnum_pending => 1);
 453       my $error = $loc->replace;
 454       if ( $error ) {
 455         $dbh->rollback if $oldAutoCommit;
 456         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 457         return "$error (moving $label location)";
 458       }
 459
 460     } elsif ( ($loc->custnum || 0) > 0 ) {
 461       # then it somehow belongs to another customer--shouldn't happen
 462       $dbh->rollback if $oldAutoCommit;
 463       return "$l belongs to customer ".$loc->custnum;
 464     }
 465     # else it already belongs to this customer
 466     # (happens when ship_location is identical to bill_location)
 467
 468     $self->set($l.'num', $loc->locationnum);
 469
 470     if ( $self->get($l.'num') eq '' ) {
 471       $dbh->rollback if $oldAutoCommit;
 472       return "$l not set";
 473     }
 474   }
 475
 476   warn "  inserting $self\n"
 477     if $DEBUG > 1;
 478
 479   $self->signupdate(time) unless $self->signupdate;
 480
 481   $self->auto_agent_custid()
 482     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 483
 484   my $error =  $self->check_payinfo_cardtype
 485             || $self->SUPER::insert;
 486   if ( $error ) {
 487     $dbh->rollback if $oldAutoCommit;
 488     #return "inserting cust_main record (transaction rolled back): $error";
 489     return $error;
 490   }
 491
 492   # now set cust_location.custnum
 493   foreach my $l (qw(bill_location ship_location)) {
 494     warn "  setting $l.custnum\n"
 495       if $DEBUG > 1;
 496     my $loc = $self->$l or next;
 497     unless ( $loc->custnum ) {
 498       $loc->set(custnum => $self->custnum);
 499       $error ||= $loc->replace;
 500     }
 501
 502     if ( $error ) {
 503       $dbh->rollback if $oldAutoCommit;
 504       return "error setting $l custnum: $error";
 505     }
 506   }
 507
 508   warn "  setting customer tags\n"
 509     if $DEBUG > 1;
 510
 511   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 512     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 513                                       'custnum' => $self->custnum };
 514     my $error = $cust_tag->insert;
 515     if ( $error ) {
 516       $dbh->rollback if $oldAutoCommit;
 517       return $error;
 518     }
 519   }
 520
 521   my $prospectnum = delete $options{'prospectnum'};
 522   if ( $prospectnum ) {
 523
 524     warn "  moving contacts and locations from prospect $prospectnum\n"
 525       if $DEBUG > 1;
 526
 527     my $prospect_main =
 528       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 529     unless ( $prospect_main ) {
 530       $dbh->rollback if $oldAutoCommit;
 531       return "Unknown prospectnum $prospectnum";
 532     }
 533     $prospect_main->custnum($self->custnum);
 534     $prospect_main->disabled('Y');
 535     my $error = $prospect_main->replace;
 536     if ( $error ) {
 537       $dbh->rollback if $oldAutoCommit;
 538       return $error;
 539     }
 540
 541     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 542       my $cust_contact = new FS::cust_contact {
 543         'custnum' => $self->custnum,
 544         'invoice_dest' => 'Y', # invoice_dest currently not set for prospect contacts
 545         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 546       };
 547       my $error =  $cust_contact->insert
 548                 || $prospect_contact->delete;
 549       if ( $error ) {
 550         $dbh->rollback if $oldAutoCommit;
 551         return $error;
 552       }
 553     }
 554
 555     my @cust_location = $prospect_main->cust_location;
 556     my @qual = $prospect_main->qual;
 557
 558     foreach my $r ( @cust_location, @qual ) {
 559       $r->prospectnum('');
 560       $r->custnum($self->custnum);
 561       my $error = $r->replace;
 562       if ( $error ) {
 563         $dbh->rollback if $oldAutoCommit;
 564         return $error;
 565       }
 566     }
 567     # since we set invoice_dest on all migrated prospect contacts (for now),
 568     # don't process invoicing_list.
 569     delete $options{'invoicing_list'};
 570     $invoicing_list = undef;
 571   }
 572
 573   warn "  setting contacts\n"
 574     if $DEBUG > 1;
 575
 576   $invoicing_list ||= $options{'invoicing_list'};
 577   if ( $invoicing_list ) {
 578
 579     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 580
 581     my $email = '';
 582     foreach my $dest (@$invoicing_list ) {
 583       if ($dest eq 'POST') {
 584         $self->set('postal_invoice', 'Y');
 585       } else {
 586
 587         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 588         if ( $contact_email ) {
 589           my $cust_contact = FS::cust_contact->new({
 590               contactnum    => $contact_email->contactnum,
 591               custnum       => $self->custnum,
 592           });
 593           $cust_contact->set('invoice_dest', 'Y');
 594           my $error = $cust_contact->insert;
 595           if ( $error ) {
 596             $dbh->rollback if $oldAutoCommit;
 597             return "$error (linking to email address $dest)";
 598           }
 599
 600         } else {
 601           # this email address is not yet linked to any contact
 602           $email .= ',' if length($email);
 603           $email .= $dest;
 604         }
 605       }
 606     }
 607
 608     if ( $email ) {
 609
 610       my $contact = FS::contact->new({
 611         'custnum'       => $self->get('custnum'),
 612         'last'          => $self->get('last'),
 613         'first'         => $self->get('first'),
 614         'emailaddress'  => $email,
 615         'invoice_dest'  => 'Y', # yes, you can set this via the contact
 616       });
 617       my $error = $contact->insert;
 618       if ( $error ) {
 619         $dbh->rollback if $oldAutoCommit;
 620         return $error;
 621       }
 622
 623     }
 624
 625   }
 626
 627   if ( my $contact = delete $options{'contact'} ) {
 628
 629     foreach my $c ( @$contact ) {
 630       $c->custnum($self->custnum);
 631       my $error = $c->insert;
 632       if ( $error ) {
 633         $dbh->rollback if $oldAutoCommit;
 634         return $error;
 635       }
 636
 637     }
 638
 639   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 640
 641     my $error = $self->process_o2m( 'table'  => 'contact',
 642                                     'fields' => FS::contact->cgi_contact_fields,
 643                                     'params' => $contact_params,
 644                                   );
 645     if ( $error ) {
 646       $dbh->rollback if $oldAutoCommit;
 647       return $error;
 648     }
 649   }
 650
 651   warn "  setting cust_payby\n"
 652     if $DEBUG > 1;
 653
 654   if ( $options{cust_payby} ) {
 655
 656     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 657       $cust_payby->custnum($self->custnum);
 658       my $error = $cust_payby->insert;
 659       if ( $error ) {
 660         $dbh->rollback if $oldAutoCommit;
 661         return $error;
 662       }
 663     }
 664
 665   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 666
 667     my $error = $self->process_o2m(
 668       'table'         => 'cust_payby',
 669       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 670       'params'        => $cust_payby_params,
 671       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 672     );
 673     if ( $error ) {
 674       $dbh->rollback if $oldAutoCommit;
 675       return $error;
 676     }
 677
 678   }
 679
 680   warn "  setting cust_main_exemption\n"
 681     if $DEBUG > 1;
 682
 683   my $tax_exemption = delete $options{'tax_exemption'};
 684   if ( $tax_exemption ) {
 685
 686     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 687       if ref($tax_exemption) eq 'ARRAY';
 688
 689     foreach my $taxname ( keys %$tax_exemption ) {
 690       my $cust_main_exemption = new FS::cust_main_exemption {
 691         'custnum'       => $self->custnum,
 692         'taxname'       => $taxname,
 693         'exempt_number' => $tax_exemption->{$taxname},
 694       };
 695       my $error = $cust_main_exemption->insert;
 696       if ( $error ) {
 697         $dbh->rollback if $oldAutoCommit;
 698         return "inserting cust_main_exemption (transaction rolled back): $error";
 699       }
 700     }
 701   }
 702
 703   warn "  ordering packages\n"
 704     if $DEBUG > 1;
 705
 706   $error = $self->order_pkgs( $cust_pkgs,
 707                               %options,
 708                               'seconds_ref'    => \$seconds,
 709                               'upbytes_ref'    => \$upbytes,
 710                               'downbytes_ref'  => \$downbytes,
 711                               'totalbytes_ref' => \$totalbytes,
 712                             );
 713   if ( $error ) {
 714     $dbh->rollback if $oldAutoCommit;
 715     return $error;
 716   }
 717
 718   if ( $seconds ) {
 719     $dbh->rollback if $oldAutoCommit;
 720     return "No svc_acct record to apply pre-paid time";
 721   }
 722   if ( $upbytes || $downbytes || $totalbytes ) {
 723     $dbh->rollback if $oldAutoCommit;
 724     return "No svc_acct record to apply pre-paid data";
 725   }
 726
 727   if ( $amount ) {
 728     warn "  inserting initial $payby payment of $amount\n"
 729       if $DEBUG > 1;
 730     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 731     if ( $error ) {
 732       $dbh->rollback if $oldAutoCommit;
 733       return "inserting payment (transaction rolled back): $error";
 734     }
 735   }
 736
 737   unless ( $import || $skip_fuzzyfiles ) {
 738     warn "  queueing fuzzyfiles update\n"
 739       if $DEBUG > 1;
 740     $error = $self->queue_fuzzyfiles_update;
 741     if ( $error ) {
 742       $dbh->rollback if $oldAutoCommit;
 743       return "updating fuzzy search cache: $error";
 744     }
 745   }
 746
 747   # cust_main exports!
 748   warn "  exporting\n" if $DEBUG > 1;
 749
 750   my $export_args = $options{'export_args'} || [];
 751
 752   my @part_export =
 753     map qsearch( 'part_export', {exportnum=>$_} ),
 754       $conf->config('cust_main-exports'); #, $agentnum
 755
 756   foreach my $part_export ( @part_export ) {
 757     my $error = $part_export->export_insert($self, @$export_args);
 758     if ( $error ) {
 759       $dbh->rollback if $oldAutoCommit;
 760       return "exporting to ". $part_export->exporttype.
 761              " (transaction rolled back): $error";
 762     }
 763   }
 764
 765   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 766   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 767   #      if $DEBUG;
 768   #    foreach my $jobnum ( @jobnums ) {
 769   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 770   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 771   #        if $DEBUG;
 772   #      my $error = $queue->depend_insert($depend_jobnum);
 773   #      if ( $error ) {
 774   #        $dbh->rollback if $oldAutoCommit;
 775   #        return "error queuing job dependancy: $error";
 776   #      }
 777   #    }
 778   #  }
 779   #
 780   #}
 781   #
 782   #if ( exists $options{'jobnums'} ) {
 783   #  push @{ $options{'jobnums'} }, @jobnums;
 784   #}
 785
 786   warn "  insert complete; committing transaction\n"
 787     if $DEBUG > 1;
 788
 789   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 790   '';
 791
 792 }
 793
 794 use File::CounterFile;
 795 sub auto_agent_custid {
 796   my $self = shift;
 797
 798   my $format = $conf->config('cust_main-auto_agent_custid');
 799   my $agent_custid;
 800   if ( $format eq '1YMMXXXXXXXX' ) {
 801
 802     my $counter = new File::CounterFile 'cust_main.agent_custid';
 803     $counter->lock;
 804
 805     my $ym = 100000000000 + time2str('%y%m00000000', time);
 806     if ( $ym > $counter->value ) {
 807       $counter->{'value'} = $agent_custid = $ym;
 808       $counter->{'updated'} = 1;
 809     } else {
 810       $agent_custid = $counter->inc;
 811     }
 812
 813     $counter->unlock;
 814
 815   } else {
 816     die "Unknown cust_main-auto_agent_custid format: $format";
 817   }
 818
 819   $self->agent_custid($agent_custid);
 820
 821 }
 822
 823 =item PACKAGE METHODS
 824
 825 Documentation on customer package methods has been moved to
 826 L<FS::cust_main::Packages>.
 827
 828 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 829
 830 Recharges this (existing) customer with the specified prepaid card (see
 831 L<FS::prepay_credit>), specified either by I<identifier> or as an
 832 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 833 returns false.
 834
 835 Optionally, five scalar references can be passed as well.  They will have their
 836 values filled in with the amount, number of seconds, and number of upload,
 837 download, and total bytes applied by this prepaid card.
 838
 839 =cut
 840
 841 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 842 #the only place that uses these args
 843 sub recharge_prepay {
 844   my( $self, $prepay_credit, $amountref, $secondsref,
 845       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 846
 847   local $SIG{HUP} = 'IGNORE';
 848   local $SIG{INT} = 'IGNORE';
 849   local $SIG{QUIT} = 'IGNORE';
 850   local $SIG{TERM} = 'IGNORE';
 851   local $SIG{TSTP} = 'IGNORE';
 852   local $SIG{PIPE} = 'IGNORE';
 853
 854   my $oldAutoCommit = $FS::UID::AutoCommit;
 855   local $FS::UID::AutoCommit = 0;
 856   my $dbh = dbh;
 857
 858   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 859
 860   my $error = $self->get_prepay( $prepay_credit,
 861                                  'amount_ref'     => \$amount,
 862                                  'seconds_ref'    => \$seconds,
 863                                  'upbytes_ref'    => \$upbytes,
 864                                  'downbytes_ref'  => \$downbytes,
 865                                  'totalbytes_ref' => \$totalbytes,
 866                                )
 867            || $self->increment_seconds($seconds)
 868            || $self->increment_upbytes($upbytes)
 869            || $self->increment_downbytes($downbytes)
 870            || $self->increment_totalbytes($totalbytes)
 871            || $self->insert_cust_pay_prepay( $amount,
 872                                              ref($prepay_credit)
 873                                                ? $prepay_credit->identifier
 874                                                : $prepay_credit
 875                                            );
 876
 877   if ( $error ) {
 878     $dbh->rollback if $oldAutoCommit;
 879     return $error;
 880   }
 881
 882   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 883   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 884   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 885   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 886   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 887
 888   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 889   '';
 890
 891 }
 892
 893 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 894
 895 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 896 specified either by I<identifier> or as an FS::prepay_credit object.
 897
 898 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 899 incremented by the values of the prepaid card.
 900
 901 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 902 check or set this customer's I<agentnum>.
 903
 904 If there is an error, returns the error, otherwise returns false.
 905
 906 =cut
 907
 908
 909 sub get_prepay {
 910   my( $self, $prepay_credit, %opt ) = @_;
 911
 912   local $SIG{HUP} = 'IGNORE';
 913   local $SIG{INT} = 'IGNORE';
 914   local $SIG{QUIT} = 'IGNORE';
 915   local $SIG{TERM} = 'IGNORE';
 916   local $SIG{TSTP} = 'IGNORE';
 917   local $SIG{PIPE} = 'IGNORE';
 918
 919   my $oldAutoCommit = $FS::UID::AutoCommit;
 920   local $FS::UID::AutoCommit = 0;
 921   my $dbh = dbh;
 922
 923   unless ( ref($prepay_credit) ) {
 924
 925     my $identifier = $prepay_credit;
 926
 927     $prepay_credit = qsearchs(
 928       'prepay_credit',
 929       { 'identifier' => $identifier },
 930       '',
 931       'FOR UPDATE'
 932     );
 933
 934     unless ( $prepay_credit ) {
 935       $dbh->rollback if $oldAutoCommit;
 936       return "Invalid prepaid card: ". $identifier;
 937     }
 938
 939   }
 940
 941   if ( $prepay_credit->agentnum ) {
 942     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 943       $dbh->rollback if $oldAutoCommit;
 944       return "prepaid card not valid for agent ". $self->agentnum;
 945     }
 946     $self->agentnum($prepay_credit->agentnum);
 947   }
 948
 949   my $error = $prepay_credit->delete;
 950   if ( $error ) {
 951     $dbh->rollback if $oldAutoCommit;
 952     return "removing prepay_credit (transaction rolled back): $error";
 953   }
 954
 955   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 956     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 957
 958   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 959   '';
 960
 961 }
 962
 963 =item increment_upbytes SECONDS
 964
 965 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 966 the specified number of upbytes.  If there is an error, returns the error,
 967 otherwise returns false.
 968
 969 =cut
 970
 971 sub increment_upbytes {
 972   _increment_column( shift, 'upbytes', @_);
 973 }
 974
 975 =item increment_downbytes SECONDS
 976
 977 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 978 the specified number of downbytes.  If there is an error, returns the error,
 979 otherwise returns false.
 980
 981 =cut
 982
 983 sub increment_downbytes {
 984   _increment_column( shift, 'downbytes', @_);
 985 }
 986
 987 =item increment_totalbytes SECONDS
 988
 989 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 990 the specified number of totalbytes.  If there is an error, returns the error,
 991 otherwise returns false.
 992
 993 =cut
 994
 995 sub increment_totalbytes {
 996   _increment_column( shift, 'totalbytes', @_);
 997 }
 998
 999 =item increment_seconds SECONDS
1000
1001 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1002 the specified number of seconds.  If there is an error, returns the error,
1003 otherwise returns false.
1004
1005 =cut
1006
1007 sub increment_seconds {
1008   _increment_column( shift, 'seconds', @_);
1009 }
1010
1011 =item _increment_column AMOUNT
1012
1013 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1014 the specified number of seconds or bytes.  If there is an error, returns
1015 the error, otherwise returns false.
1016
1017 =cut
1018
1019 sub _increment_column {
1020   my( $self, $column, $amount ) = @_;
1021   warn "$me increment_column called: $column, $amount\n"
1022     if $DEBUG;
1023
1024   return '' unless $amount;
1025
1026   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1027                       $self->ncancelled_pkgs;
1028
1029   if ( ! @cust_pkg ) {
1030     return 'No packages with primary or single services found'.
1031            ' to apply pre-paid time';
1032   } elsif ( scalar(@cust_pkg) > 1 ) {
1033     #maybe have a way to specify the package/account?
1034     return 'Multiple packages found to apply pre-paid time';
1035   }
1036
1037   my $cust_pkg = $cust_pkg[0];
1038   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1039     if $DEBUG > 1;
1040
1041   my @cust_svc =
1042     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1043
1044   if ( ! @cust_svc ) {
1045     return 'No account found to apply pre-paid time';
1046   } elsif ( scalar(@cust_svc) > 1 ) {
1047     return 'Multiple accounts found to apply pre-paid time';
1048   }
1049
1050   my $svc_acct = $cust_svc[0]->svc_x;
1051   warn "  found service svcnum ". $svc_acct->pkgnum.
1052        ' ('. $svc_acct->email. ")\n"
1053     if $DEBUG > 1;
1054
1055   $column = "increment_$column";
1056   $svc_acct->$column($amount);
1057
1058 }
1059
1060 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1061
1062 Inserts a prepayment in the specified amount for this customer.  An optional
1063 second argument can specify the prepayment identifier for tracking purposes.
1064 If there is an error, returns the error, otherwise returns false.
1065
1066 =cut
1067
1068 sub insert_cust_pay_prepay {
1069   shift->insert_cust_pay('PREP', @_);
1070 }
1071
1072 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1073
1074 Inserts a cash payment in the specified amount for this customer.  An optional
1075 second argument can specify the payment identifier for tracking purposes.
1076 If there is an error, returns the error, otherwise returns false.
1077
1078 =cut
1079
1080 sub insert_cust_pay_cash {
1081   shift->insert_cust_pay('CASH', @_);
1082 }
1083
1084 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1085
1086 Inserts a Western Union payment in the specified amount for this customer.  An
1087 optional second argument can specify the prepayment identifier for tracking
1088 purposes.  If there is an error, returns the error, otherwise returns false.
1089
1090 =cut
1091
1092 sub insert_cust_pay_west {
1093   shift->insert_cust_pay('WEST', @_);
1094 }
1095
1096 sub insert_cust_pay {
1097   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1098   my $payinfo = scalar(@_) ? shift : '';
1099
1100   my $cust_pay = new FS::cust_pay {
1101     'custnum' => $self->custnum,
1102     'paid'    => sprintf('%.2f', $amount),
1103     #'_date'   => #date the prepaid card was purchased???
1104     'payby'   => $payby,
1105     'payinfo' => $payinfo,
1106   };
1107   $cust_pay->insert;
1108
1109 }
1110
1111 =item delete [ OPTION => VALUE ... ]
1112
1113 This deletes the customer.  If there is an error, returns the error, otherwise
1114 returns false.
1115
1116 This will completely remove all traces of the customer record.  This is not
1117 what you want when a customer cancels service; for that, cancel all of the
1118 customer's packages (see L</cancel>).
1119
1120 If the customer has any uncancelled packages, you need to pass a new (valid)
1121 customer number for those packages to be transferred to, as the "new_customer"
1122 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1123 what you want when a customer cancels service and that you really should be
1124 looking at L<FS::cust_pkg/cancel>?
1125
1126 You can't delete a customer with invoices (see L<FS::cust_bill>),
1127 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1128 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1129 set the "delete_financials" option to a true value.
1130
1131 =cut
1132
1133 sub delete {
1134   my( $self, %opt ) = @_;
1135
1136   local $SIG{HUP} = 'IGNORE';
1137   local $SIG{INT} = 'IGNORE';
1138   local $SIG{QUIT} = 'IGNORE';
1139   local $SIG{TERM} = 'IGNORE';
1140   local $SIG{TSTP} = 'IGNORE';
1141   local $SIG{PIPE} = 'IGNORE';
1142
1143   my $oldAutoCommit = $FS::UID::AutoCommit;
1144   local $FS::UID::AutoCommit = 0;
1145   my $dbh = dbh;
1146
1147   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1148      $dbh->rollback if $oldAutoCommit;
1149      return "Can't delete a master agent customer";
1150   }
1151
1152   #use FS::access_user
1153   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1154      $dbh->rollback if $oldAutoCommit;
1155      return "Can't delete a master employee customer";
1156   }
1157
1158   tie my %financial_tables, 'Tie::IxHash',
1159     'cust_bill'      => 'invoices',
1160     'cust_statement' => 'statements',
1161     'cust_credit'    => 'credits',
1162     'cust_pay'       => 'payments',
1163     'cust_refund'    => 'refunds',
1164   ;
1165
1166   foreach my $table ( keys %financial_tables ) {
1167
1168     my @records = $self->$table();
1169
1170     if ( @records && ! $opt{'delete_financials'} ) {
1171       $dbh->rollback if $oldAutoCommit;
1172       return "Can't delete a customer with ". $financial_tables{$table};
1173     }
1174
1175     foreach my $record ( @records ) {
1176       my $error = $record->delete;
1177       if ( $error ) {
1178         $dbh->rollback if $oldAutoCommit;
1179         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1180       }
1181     }
1182
1183   }
1184
1185   my @cust_pkg = $self->ncancelled_pkgs;
1186   if ( @cust_pkg ) {
1187     my $new_custnum = $opt{'new_custnum'};
1188     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1189       $dbh->rollback if $oldAutoCommit;
1190       return "Invalid new customer number: $new_custnum";
1191     }
1192     foreach my $cust_pkg ( @cust_pkg ) {
1193       my %hash = $cust_pkg->hash;
1194       $hash{'custnum'} = $new_custnum;
1195       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1196       my $error = $new_cust_pkg->replace($cust_pkg,
1197                                          options => { $cust_pkg->options },
1198                                         );
1199       if ( $error ) {
1200         $dbh->rollback if $oldAutoCommit;
1201         return $error;
1202       }
1203     }
1204   }
1205   my @cancelled_cust_pkg = $self->all_pkgs;
1206   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1207     my $error = $cust_pkg->delete;
1208     if ( $error ) {
1209       $dbh->rollback if $oldAutoCommit;
1210       return $error;
1211     }
1212   }
1213
1214   #cust_tax_adjustment in financials?
1215   #cust_pay_pending?  ouch
1216   foreach my $table (qw(
1217     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1218     cust_payby cust_location cust_main_note cust_tax_adjustment
1219     cust_pay_void cust_pay_batch queue cust_tax_exempt
1220   )) {
1221     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1222       my $error = $record->delete;
1223       if ( $error ) {
1224         $dbh->rollback if $oldAutoCommit;
1225         return $error;
1226       }
1227     }
1228   }
1229
1230   my $sth = $dbh->prepare(
1231     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1232   ) or do {
1233     my $errstr = $dbh->errstr;
1234     $dbh->rollback if $oldAutoCommit;
1235     return $errstr;
1236   };
1237   $sth->execute($self->custnum) or do {
1238     my $errstr = $sth->errstr;
1239     $dbh->rollback if $oldAutoCommit;
1240     return $errstr;
1241   };
1242
1243   #tickets
1244
1245   my $ticket_dbh = '';
1246   if ($conf->config('ticket_system') eq 'RT_Internal') {
1247     $ticket_dbh = $dbh;
1248   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1249     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1250     $ticket_dbh = FS::DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1251       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1252   }
1253
1254   if ( $ticket_dbh ) {
1255
1256     my $ticket_sth = $ticket_dbh->prepare(
1257       'DELETE FROM Links WHERE Target = ?'
1258     ) or do {
1259       my $errstr = $ticket_dbh->errstr;
1260       $dbh->rollback if $oldAutoCommit;
1261       return $errstr;
1262     };
1263     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1264       or do {
1265         my $errstr = $ticket_sth->errstr;
1266         $dbh->rollback if $oldAutoCommit;
1267         return $errstr;
1268       };
1269
1270     #check and see if the customer is the only link on the ticket, and
1271     #if so, set the ticket to deleted status in RT?
1272     #maybe someday, for now this will at least fix tickets not displaying
1273
1274   }
1275
1276   #delete the customer record
1277
1278   my $error = $self->SUPER::delete;
1279   if ( $error ) {
1280     $dbh->rollback if $oldAutoCommit;
1281     return $error;
1282   }
1283
1284   # cust_main exports!
1285
1286   #my $export_args = $options{'export_args'} || [];
1287
1288   my @part_export =
1289     map qsearch( 'part_export', {exportnum=>$_} ),
1290       $conf->config('cust_main-exports'); #, $agentnum
1291
1292   foreach my $part_export ( @part_export ) {
1293     my $error = $part_export->export_delete( $self ); #, @$export_args);
1294     if ( $error ) {
1295       $dbh->rollback if $oldAutoCommit;
1296       return "exporting to ". $part_export->exporttype.
1297              " (transaction rolled back): $error";
1298     }
1299   }
1300
1301   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1302   '';
1303
1304 }
1305
1306 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1307
1308 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1309 returns the error, otherwise returns false.
1310
1311 To change the customer's address, set the pseudo-fields C<bill_location> and
1312 C<ship_location>.  The address will still only change if at least one of the
1313 address fields differs from the existing values.
1314
1315 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1316 set as the contact email address for a default contact with the same name as
1317 the customer.
1318
1319 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1320 I<contact_params>, I<invoicing_list>, and I<move_pkgs>.
1321
1322 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1323 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1324 deleted and inserted as appropriate.
1325
1326 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1327 groups (describing the customer's payment methods and contacts, respectively)
1328 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1329 and L<FS::contact> for the fields these can contain.
1330
1331 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1332 should be used instead if possible.
1333
1334 If I<move_pkgs> is an arrayref, it will override the list of packages
1335 to be moved to the new address (see L<FS::cust_location/move_pkgs>.)
1336
1337 =cut
1338
1339 sub replace {
1340   my $self = shift;
1341
1342   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1343               ? shift
1344               : $self->replace_old;
1345
1346   my @param = @_;
1347
1348   warn "$me replace called\n"
1349     if $DEBUG;
1350
1351   my $curuser = $FS::CurrentUser::CurrentUser;
1352   return "You are not permitted to create complimentary accounts."
1353     if $self->complimentary eq 'Y'
1354     && $self->complimentary ne $old->complimentary
1355     && ! $curuser->access_right('Complimentary customer');
1356
1357   local($ignore_expired_card) = 1
1358     if $old->payby  =~ /^(CARD|DCRD)$/
1359     && $self->payby =~ /^(CARD|DCRD)$/
1360     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1361
1362   local($ignore_banned_card) = 1
1363     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1364          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1365     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1366
1367   if (    $self->payby =~ /^(CARD|DCRD)$/
1368        && $old->payinfo ne $self->payinfo
1369        && $old->paymask ne $self->paymask )
1370   {
1371     my $error = $self->check_payinfo_cardtype;
1372     return $error if $error;
1373   }
1374
1375   return "Invoicing locale is required"
1376     if $old->locale
1377     && ! $self->locale
1378     && $conf->exists('cust_main-require_locale');
1379
1380   return "You are not permitted to change customer invoicing terms."
1381     if $old->invoice_terms ne $self->invoice_terms
1382     && ! $curuser->access_right('Edit customer invoice terms');
1383
1384   local $SIG{HUP} = 'IGNORE';
1385   local $SIG{INT} = 'IGNORE';
1386   local $SIG{QUIT} = 'IGNORE';
1387   local $SIG{TERM} = 'IGNORE';
1388   local $SIG{TSTP} = 'IGNORE';
1389   local $SIG{PIPE} = 'IGNORE';
1390
1391   my $oldAutoCommit = $FS::UID::AutoCommit;
1392   local $FS::UID::AutoCommit = 0;
1393   my $dbh = dbh;
1394
1395   for my $l (qw(bill_location ship_location)) {
1396     #my $old_loc = $old->$l;
1397     my $new_loc = $self->$l or next;
1398
1399     # find the existing location if there is one
1400     $new_loc->set('custnum' => $self->custnum);
1401     my $error = $new_loc->find_or_insert;
1402     if ( $error ) {
1403       $dbh->rollback if $oldAutoCommit;
1404       return $error;
1405     }
1406     $self->set($l.'num', $new_loc->locationnum);
1407   } #for $l
1408
1409   my $invoicing_list;
1410   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1411     warn "cust_main::replace: using deprecated invoicing list argument";
1412     $invoicing_list = shift @param;
1413   }
1414
1415   my %options = @param;
1416
1417   $invoicing_list ||= $options{invoicing_list};
1418
1419   my @contacts = map { $_->contact } $self->cust_contact;
1420   # find a contact that matches the customer's name
1421   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1422                               and $_->last  eq $old->get('last') }
1423                             @contacts;
1424   $implicit_contact ||= FS::contact->new({
1425       'custnum'       => $self->custnum,
1426       'locationnum'   => $self->get('bill_locationnum'),
1427   });
1428
1429   # for any of these that are already contact emails, link to the existing
1430   # contact
1431   if ( $invoicing_list ) {
1432     my $email = '';
1433
1434     # kind of like process_m2m on these, except:
1435     # - the other side is two tables in a join
1436     # - and we might have to create new contact_emails
1437     # - and possibly a new contact
1438     #
1439     # Find existing invoice emails that aren't on the implicit contact.
1440     # Any of these that are not on the new invoicing list will be removed.
1441     my %old_email_cust_contact;
1442     foreach my $cust_contact ($self->cust_contact) {
1443       next if !$cust_contact->invoice_dest;
1444       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1445
1446       foreach my $contact_email ($cust_contact->contact->contact_email) {
1447         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1448       }
1449     }
1450
1451     foreach my $dest (@$invoicing_list) {
1452
1453       if ($dest eq 'POST') {
1454
1455         $self->set('postal_invoice', 'Y');
1456
1457       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1458
1459         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1460
1461       } else {
1462
1463         # See if it belongs to some other contact; if so, link it.
1464         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1465         if ( $contact_email
1466              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1467           my $cust_contact = qsearchs('cust_contact', {
1468               contactnum  => $contact_email->contactnum,
1469               custnum     => $self->custnum,
1470           }) || FS::cust_contact->new({
1471               contactnum    => $contact_email->contactnum,
1472               custnum       => $self->custnum,
1473           });
1474           $cust_contact->set('invoice_dest', 'Y');
1475           my $error = $cust_contact->custcontactnum ?
1476                         $cust_contact->replace : $cust_contact->insert;
1477           if ( $error ) {
1478             $dbh->rollback if $oldAutoCommit;
1479             return "$error (linking to email address $dest)";
1480           }
1481
1482         } else {
1483           # This email address is not yet linked to any contact, so it will
1484           # be added to the implicit contact.
1485           $email .= ',' if length($email);
1486           $email .= $dest;
1487         }
1488       }
1489     }
1490
1491     foreach my $remove_dest (keys %old_email_cust_contact) {
1492       my $cust_contact = $old_email_cust_contact{$remove_dest};
1493       # These were not in the list of requested destinations, so take them off.
1494       $cust_contact->set('invoice_dest', '');
1495       my $error = $cust_contact->replace;
1496       if ( $error ) {
1497         $dbh->rollback if $oldAutoCommit;
1498         return "$error (unlinking email address $remove_dest)";
1499       }
1500     }
1501
1502     # make sure it keeps up with the changed customer name, if any
1503     $implicit_contact->set('last', $self->get('last'));
1504     $implicit_contact->set('first', $self->get('first'));
1505     $implicit_contact->set('emailaddress', $email);
1506     $implicit_contact->set('invoice_dest', 'Y');
1507     $implicit_contact->set('custnum', $self->custnum);
1508     my $i_cust_contact =
1509       qsearchs('cust_contact', {
1510                                  contactnum  => $implicit_contact->contactnum,
1511                                  custnum     => $self->custnum,
1512                                }
1513       );
1514     if ( $i_cust_contact ) {
1515       $implicit_contact->set($_, $i_cust_contact->$_)
1516         foreach qw( classnum selfservice_access comment );
1517     }
1518
1519     my $error;
1520     if ( $implicit_contact->contactnum ) {
1521       $error = $implicit_contact->replace;
1522     } elsif ( length($email) ) { # don't create a new contact if not needed
1523       $error = $implicit_contact->insert;
1524     }
1525
1526     if ( $error ) {
1527       $dbh->rollback if $oldAutoCommit;
1528       return "$error (adding email address $email)";
1529     }
1530
1531   }
1532
1533   # replace the customer record
1534   my $error = $self->SUPER::replace($old);
1535
1536   if ( $error ) {
1537     $dbh->rollback if $oldAutoCommit;
1538     return $error;
1539   }
1540
1541   # now move packages to the new service location
1542   $self->set('ship_location', ''); #flush cache
1543   if ( $old->ship_locationnum and # should only be null during upgrade...
1544        $old->ship_locationnum != $self->ship_locationnum ) {
1545     $error = $old->ship_location->move_to($self->ship_location, move_pkgs => $options{'move_pkgs'});
1546     if ( $error ) {
1547       $dbh->rollback if $oldAutoCommit;
1548       return $error;
1549     }
1550   }
1551   # don't move packages based on the billing location, but
1552   # disable it if it's no longer in use
1553   if ( $old->bill_locationnum and
1554        $old->bill_locationnum != $self->bill_locationnum ) {
1555     $error = $old->bill_location->disable_if_unused;
1556     if ( $error ) {
1557       $dbh->rollback if $oldAutoCommit;
1558       return $error;
1559     }
1560   }
1561
1562   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1563
1564     #this could be more efficient than deleting and re-inserting, if it matters
1565     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1566       my $error = $cust_tag->delete;
1567       if ( $error ) {
1568         $dbh->rollback if $oldAutoCommit;
1569         return $error;
1570       }
1571     }
1572     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1573       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1574                                         'custnum' => $self->custnum };
1575       my $error = $cust_tag->insert;
1576       if ( $error ) {
1577         $dbh->rollback if $oldAutoCommit;
1578         return $error;
1579       }
1580     }
1581
1582   }
1583
1584   my $tax_exemption = delete $options{'tax_exemption'};
1585   if ( $tax_exemption ) {
1586
1587     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1588       if ref($tax_exemption) eq 'ARRAY';
1589
1590     my %cust_main_exemption =
1591       map { $_->taxname => $_ }
1592           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1593
1594     foreach my $taxname ( keys %$tax_exemption ) {
1595
1596       if ( $cust_main_exemption{$taxname} &&
1597            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1598          )
1599       {
1600         delete $cust_main_exemption{$taxname};
1601         next;
1602       }
1603
1604       my $cust_main_exemption = new FS::cust_main_exemption {
1605         'custnum'       => $self->custnum,
1606         'taxname'       => $taxname,
1607         'exempt_number' => $tax_exemption->{$taxname},
1608       };
1609       my $error = $cust_main_exemption->insert;
1610       if ( $error ) {
1611         $dbh->rollback if $oldAutoCommit;
1612         return "inserting cust_main_exemption (transaction rolled back): $error";
1613       }
1614     }
1615
1616     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1617       my $error = $cust_main_exemption->delete;
1618       if ( $error ) {
1619         $dbh->rollback if $oldAutoCommit;
1620         return "deleting cust_main_exemption (transaction rolled back): $error";
1621       }
1622     }
1623
1624   }
1625
1626   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1627
1628     my $error = $self->process_o2m(
1629       'table'         => 'cust_payby',
1630       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1631       'params'        => $cust_payby_params,
1632       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1633     );
1634     if ( $error ) {
1635       $dbh->rollback if $oldAutoCommit;
1636       return $error;
1637     }
1638
1639   }
1640
1641   if ( my $contact_params = delete $options{'contact_params'} ) {
1642
1643     # this can potentially replace contacts that were created by the
1644     # invoicing list argument, but the UI shouldn't allow both of them
1645     # to be specified
1646
1647     my $error = $self->process_o2m(
1648       'table'         => 'contact',
1649       'fields'        => FS::contact->cgi_contact_fields,
1650       'params'        => $contact_params,
1651     );
1652     if ( $error ) {
1653       $dbh->rollback if $oldAutoCommit;
1654       return $error;
1655     }
1656
1657   }
1658
1659   unless ( $import || $skip_fuzzyfiles ) {
1660     $error = $self->queue_fuzzyfiles_update;
1661     if ( $error ) {
1662       $dbh->rollback if $oldAutoCommit;
1663       return "updating fuzzy search cache: $error";
1664     }
1665   }
1666
1667   # tax district update in cust_location
1668
1669   # cust_main exports!
1670
1671   my $export_args = $options{'export_args'} || [];
1672
1673   my @part_export =
1674     map qsearch( 'part_export', {exportnum=>$_} ),
1675       $conf->config('cust_main-exports'); #, $agentnum
1676
1677   foreach my $part_export ( @part_export ) {
1678     my $error = $part_export->export_replace( $self, $old, @$export_args);
1679     if ( $error ) {
1680       $dbh->rollback if $oldAutoCommit;
1681       return "exporting to ". $part_export->exporttype.
1682              " (transaction rolled back): $error";
1683     }
1684   }
1685
1686   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1687   '';
1688
1689 }
1690
1691 =item queue_fuzzyfiles_update
1692
1693 Used by insert & replace to update the fuzzy search cache
1694
1695 =cut
1696
1697 use FS::cust_main::Search;
1698 sub queue_fuzzyfiles_update {
1699   my $self = shift;
1700
1701   local $SIG{HUP} = 'IGNORE';
1702   local $SIG{INT} = 'IGNORE';
1703   local $SIG{QUIT} = 'IGNORE';
1704   local $SIG{TERM} = 'IGNORE';
1705   local $SIG{TSTP} = 'IGNORE';
1706   local $SIG{PIPE} = 'IGNORE';
1707
1708   my $oldAutoCommit = $FS::UID::AutoCommit;
1709   local $FS::UID::AutoCommit = 0;
1710   my $dbh = dbh;
1711
1712   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1713     my $queue = new FS::queue {
1714       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1715     };
1716     my @args = "cust_main.$field", $self->get($field);
1717     my $error = $queue->insert( @args );
1718     if ( $error ) {
1719       $dbh->rollback if $oldAutoCommit;
1720       return "queueing job (transaction rolled back): $error";
1721     }
1722   }
1723
1724   my @locations = ();
1725   push @locations, $self->bill_location if $self->bill_locationnum;
1726   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1727   foreach my $location (@locations) {
1728     my $queue = new FS::queue {
1729       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1730     };
1731     my @args = 'cust_location.address1', $location->address1;
1732     my $error = $queue->insert( @args );
1733     if ( $error ) {
1734       $dbh->rollback if $oldAutoCommit;
1735       return "queueing job (transaction rolled back): $error";
1736     }
1737   }
1738
1739   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1740   '';
1741
1742 }
1743
1744 =item check
1745
1746 Checks all fields to make sure this is a valid customer record.  If there is
1747 an error, returns the error, otherwise returns false.  Called by the insert
1748 and replace methods.
1749
1750 =cut
1751
1752 sub check {
1753   my $self = shift;
1754
1755   warn "$me check BEFORE: \n". $self->_dump
1756     if $DEBUG > 2;
1757
1758   my $error =
1759     $self->ut_numbern('custnum')
1760     || $self->ut_number('agentnum')
1761     || $self->ut_textn('agent_custid')
1762     || $self->ut_number('refnum')
1763     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1764     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1765     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1766     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1767     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1768     || $self->ut_textn('custbatch')
1769     || $self->ut_name('last')
1770     || $self->ut_name('first')
1771     || $self->ut_snumbern('signupdate')
1772     || $self->ut_snumbern('birthdate')
1773     || $self->ut_namen('spouse_last')
1774     || $self->ut_namen('spouse_first')
1775     || $self->ut_snumbern('spouse_birthdate')
1776     || $self->ut_snumbern('anniversary_date')
1777     || $self->ut_textn('company')
1778     || $self->ut_textn('ship_company')
1779     || $self->ut_anything('comments')
1780     || $self->ut_numbern('referral_custnum')
1781     || $self->ut_textn('stateid')
1782     || $self->ut_textn('stateid_state')
1783     || $self->ut_textn('invoice_terms')
1784     || $self->ut_floatn('cdr_termination_percentage')
1785     || $self->ut_floatn('credit_limit')
1786     || $self->ut_numbern('billday')
1787     || $self->ut_numbern('prorate_day')
1788     || $self->ut_flag('force_prorate_day')
1789     || $self->ut_flag('edit_subject')
1790     || $self->ut_flag('calling_list_exempt')
1791     || $self->ut_flag('invoice_noemail')
1792     || $self->ut_flag('message_noemail')
1793     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1794     || $self->ut_currencyn('currency')
1795     || $self->ut_textn('po_number')
1796     || $self->ut_enum('complimentary', [ '', 'Y' ])
1797     || $self->ut_flag('invoice_ship_address')
1798     || $self->ut_flag('invoice_dest')
1799   ;
1800
1801   foreach (qw(company ship_company)) {
1802     my $company = $self->get($_);
1803     $company =~ s/^\s+//;
1804     $company =~ s/\s+$//;
1805     $company =~ s/\s+/ /g;
1806     $self->set($_, $company);
1807   }
1808
1809   #barf.  need message catalogs.  i18n.  etc.
1810   $error .= "Please select an advertising source."
1811     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1812   return $error if $error;
1813
1814   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1815     or return "Unknown agent";
1816
1817   if ( $self->currency ) {
1818     my $agent_currency = qsearchs( 'agent_currency', {
1819       'agentnum' => $agent->agentnum,
1820       'currency' => $self->currency,
1821     })
1822       or return "Agent ". $agent->agent.
1823                 " not permitted to offer ".  $self->currency. " invoicing";
1824   }
1825
1826   return "Unknown refnum"
1827     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1828
1829   return "Unknown referring custnum: ". $self->referral_custnum
1830     unless ! $self->referral_custnum
1831            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1832
1833   if ( $self->ss eq '' ) {
1834     $self->ss('');
1835   } else {
1836     my $ss = $self->ss;
1837     $ss =~ s/\D//g;
1838     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1839       or return "Illegal social security number: ". $self->ss;
1840     $self->ss("$1-$2-$3");
1841   }
1842
1843   #turn off invoice_ship_address if ship & bill are the same
1844   if ($self->bill_locationnum eq $self->ship_locationnum) {
1845     $self->invoice_ship_address('');
1846   }
1847
1848   # cust_main_county verification now handled by cust_location check
1849
1850   $error =
1851        $self->ut_phonen('daytime', $self->country)
1852     || $self->ut_phonen('night',   $self->country)
1853     || $self->ut_phonen('fax',     $self->country)
1854     || $self->ut_phonen('mobile',  $self->country)
1855   ;
1856   return $error if $error;
1857
1858   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1859        && ! $import
1860        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1861      ) {
1862
1863     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1864                           ? 'Day Phone'
1865                           : FS::Msgcat::_gettext('daytime');
1866     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1867                         ? 'Night Phone'
1868                         : FS::Msgcat::_gettext('night');
1869
1870     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1871                         ? 'Mobile Phone'
1872                         : FS::Msgcat::_gettext('mobile');
1873
1874     return "$daytime_label, $night_label or $mobile_label is required"
1875
1876   }
1877
1878   return "Please select an invoicing locale"
1879     if ! $self->locale
1880     && ! $self->custnum
1881     && $conf->exists('cust_main-require_locale');
1882
1883   return "Please select a customer class"
1884     if ! $self->classnum
1885     && $conf->exists('cust_main-require_classnum');
1886
1887   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
1888     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
1889     $self->$flag($1);
1890   }
1891
1892   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
1893
1894   warn "$me check AFTER: \n". $self->_dump
1895     if $DEBUG > 2;
1896
1897   $self->SUPER::check;
1898 }
1899
1900 sub check_payinfo_cardtype {
1901   my $self = shift;
1902
1903   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
1904
1905   my $payinfo = $self->payinfo;
1906   $payinfo =~ s/\D//g;
1907
1908   return '' if $self->tokenized($payinfo); #token
1909
1910   my %bop_card_types = map { $_=>1 } values %{ card_types() };
1911   my $cardtype = cardtype($payinfo);
1912
1913   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
1914
1915   '';
1916
1917 }
1918
1919 =item replace_check
1920
1921 Additional checks for replace only.
1922
1923 =cut
1924
1925 sub replace_check {
1926   my ($new,$old) = @_;
1927   #preserve old value if global config is set
1928   if ($old && $conf->exists('invoice-ship_address')) {
1929     $new->invoice_ship_address($old->invoice_ship_address);
1930   }
1931   return '';
1932 }
1933
1934 =item addr_fields
1935
1936 Returns a list of fields which have ship_ duplicates.
1937
1938 =cut
1939
1940 sub addr_fields {
1941   qw( last first company
1942       locationname
1943       address1 address2 city county state zip country
1944       latitude longitude
1945       daytime night fax mobile
1946     );
1947 }
1948
1949 =item has_ship_address
1950
1951 Returns true if this customer record has a separate shipping address.
1952
1953 =cut
1954
1955 sub has_ship_address {
1956   my $self = shift;
1957   $self->bill_locationnum != $self->ship_locationnum;
1958 }
1959
1960 =item location_hash
1961
1962 Returns a list of key/value pairs, with the following keys: address1,
1963 adddress2, city, county, state, zip, country, district, and geocode.  The
1964 shipping address is used if present.
1965
1966 =cut
1967
1968 sub location_hash {
1969   my $self = shift;
1970   $self->ship_location->location_hash;
1971 }
1972
1973 =item cust_location
1974
1975 Returns all locations (see L<FS::cust_location>) for this customer.
1976
1977 =cut
1978
1979 sub cust_location {
1980   my $self = shift;
1981   qsearch({
1982     'table'   => 'cust_location',
1983     'hashref' => { 'custnum'     => $self->custnum,
1984                    'prospectnum' => '',
1985                  },
1986     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
1987   });
1988 }
1989
1990 =item cust_contact
1991
1992 Returns all contact associations (see L<FS::cust_contact>) for this customer.
1993
1994 =cut
1995
1996 sub cust_contact {
1997   my $self = shift;
1998   qsearch('cust_contact', { 'custnum' => $self->custnum } );
1999 }
2000
2001 =item cust_payby PAYBY
2002
2003 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2004
2005 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
2006 Does not validate PAYBY.
2007
2008 =cut
2009
2010 sub cust_payby {
2011   my $self = shift;
2012   my @payby = @_;
2013   my $search = {
2014     'table'    => 'cust_payby',
2015     'hashref'  => { 'custnum' => $self->custnum },
2016     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
2017   };
2018   $search->{'extra_sql'} = ' AND payby IN ( '.
2019                                join(',', map dbh->quote($_), @payby).
2020                              ' ) '
2021     if @payby;
2022
2023   qsearch($search);
2024 }
2025
2026 =item has_cust_payby_auto
2027
2028 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2029
2030 =cut
2031
2032 sub has_cust_payby_auto {
2033   my $self = shift;
2034   scalar( qsearch({
2035     'table'     => 'cust_payby',
2036     'hashref'   => { 'custnum' => $self->custnum, },
2037     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2038     'order_by'  => 'LIMIT 1',
2039   }) );
2040
2041 }
2042
2043 =item unsuspend
2044
2045 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2046 and L<FS::cust_pkg>) for this customer, except those on hold.
2047
2048 Returns a list: an empty list on success or a list of errors.
2049
2050 =cut
2051
2052 sub unsuspend {
2053   my $self = shift;
2054   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs(@_);
2055 }
2056
2057 =item release_hold
2058
2059 Unsuspends all suspended packages in the on-hold state (those without setup
2060 dates) for this customer.
2061
2062 =cut
2063
2064 sub release_hold {
2065   my $self = shift;
2066   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2067 }
2068
2069 =item suspend
2070
2071 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2072
2073 Returns a list: an empty list on success or a list of errors.
2074
2075 =cut
2076
2077 sub suspend {
2078   my $self = shift;
2079   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2080 }
2081
2082 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2083
2084 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2085 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2086 of a list of pkgparts; the hashref has the following keys:
2087
2088 =over 4
2089
2090 =item pkgparts - listref of pkgparts
2091
2092 =item (other options are passed to the suspend method)
2093
2094 =back
2095
2096
2097 Returns a list: an empty list on success or a list of errors.
2098
2099 =cut
2100
2101 sub suspend_if_pkgpart {
2102   my $self = shift;
2103   my (@pkgparts, %opt);
2104   if (ref($_[0]) eq 'HASH'){
2105     @pkgparts = @{$_[0]{pkgparts}};
2106     %opt      = %{$_[0]};
2107   }else{
2108     @pkgparts = @_;
2109   }
2110   grep { $_->suspend(%opt) }
2111     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2112       $self->unsuspended_pkgs;
2113 }
2114
2115 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2116
2117 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2118 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2119 instead of a list of pkgparts; the hashref has the following keys:
2120
2121 =over 4
2122
2123 =item pkgparts - listref of pkgparts
2124
2125 =item (other options are passed to the suspend method)
2126
2127 =back
2128
2129 Returns a list: an empty list on success or a list of errors.
2130
2131 =cut
2132
2133 sub suspend_unless_pkgpart {
2134   my $self = shift;
2135   my (@pkgparts, %opt);
2136   if (ref($_[0]) eq 'HASH'){
2137     @pkgparts = @{$_[0]{pkgparts}};
2138     %opt      = %{$_[0]};
2139   }else{
2140     @pkgparts = @_;
2141   }
2142   grep { $_->suspend(%opt) }
2143     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2144       $self->unsuspended_pkgs;
2145 }
2146
2147 =item cancel [ OPTION => VALUE ... ]
2148
2149 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2150 The cancellation time will be now.
2151
2152 =back
2153
2154 Always returns a list: an empty list on success or a list of errors.
2155
2156 =cut
2157
2158 sub cancel {
2159   my $self = shift;
2160   my %opt = @_;
2161   warn "$me cancel called on customer ". $self->custnum. " with options ".
2162        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2163     if $DEBUG;
2164   my @pkgs = $self->ncancelled_pkgs;
2165
2166   $self->cancel_pkgs( %opt, 'cust_pkg' => \@pkgs );
2167 }
2168
2169 =item cancel_pkgs OPTIONS
2170
2171 Cancels a specified list of packages. OPTIONS can include:
2172
2173 =over 4
2174
2175 =item cust_pkg - an arrayref of the packages. Required.
2176
2177 =item time - the cancellation time, used to calculate final bills and
2178 unused-time credits if any. Will be passed through to the bill() and
2179 FS::cust_pkg::cancel() methods.
2180
2181 =item quiet - can be set true to supress email cancellation notices.
2182
2183 =item reason - can be set to a cancellation reason (see L<FS::reason>), either a
2184 reasonnum of an existing reason, or passing a hashref will create a new reason.
2185 The hashref should have the following keys:
2186 typenum - Reason type (see L<FS::reason_type>)
2187 reason - Text of the new reason.
2188
2189 =item cust_pkg_reason - can be an arrayref of L<FS::cust_pkg_reason> objects
2190 for the individual packages, parallel to the C<cust_pkg> argument. The
2191 reason and reason_otaker arguments will be taken from those objects.
2192
2193 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2194
2195 =item nobill - can be set true to skip billing if it might otherwise be done.
2196
2197 =cut
2198
2199 sub cancel_pkgs {
2200   my( $self, %opt ) = @_;
2201
2202   # we're going to cancel services, which is not reversible
2203   #   unless exports are suppressed
2204   die "cancel_pkgs cannot be run inside a transaction"
2205     if !$FS::UID::AutoCommit && !$FS::svc_Common::noexport_hack;
2206
2207   my $oldAutoCommit = $FS::UID::AutoCommit;
2208   local $FS::UID::AutoCommit = 0;
2209
2210   savepoint_create('cancel_pkgs');
2211
2212   return ( 'access denied' )
2213     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2214
2215   if ( $opt{'ban'} ) {
2216
2217     foreach my $cust_payby ( $self->cust_payby ) {
2218
2219       #well, if they didn't get decrypted on search, then we don't have to
2220       # try again... queue a job for the server that does have decryption
2221       # capability if we're in a paranoid multi-server implementation?
2222       return ( "Can't (yet) ban encrypted credit cards" )
2223         if $cust_payby->is_encrypted($cust_payby->payinfo);
2224
2225       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2226       my $error = $ban->insert;
2227       if ($error) {
2228         savepoint_rollback_and_release('cancel_pkgs');
2229         dbh->rollback if $oldAutoCommit;
2230         return ( $error );
2231       }
2232
2233     }
2234
2235   }
2236
2237   my @pkgs = @{ delete $opt{'cust_pkg'} };
2238   my $cancel_time = $opt{'time'} || time;
2239
2240   # bill all packages first, so we don't lose usage, service counts for
2241   # bulk billing, etc.
2242   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2243     $opt{nobill} = 1;
2244     my $error = $self->bill( 'pkg_list' => [ @pkgs ],
2245                              'cancel'   => 1,
2246                              'time'     => $cancel_time );
2247     if ($error) {
2248       warn "Error billing during cancel, custnum ". $self->custnum. ": $error";
2249       savepoint_rollback_and_release('cancel_pkgs');
2250       dbh->rollback if $oldAutoCommit;
2251       return ( "Error billing during cancellation: $error" );
2252     }
2253   }
2254   savepoint_release('cancel_pkgs');
2255   dbh->commit if $oldAutoCommit;
2256
2257   my @errors;
2258   # try to cancel each service, the same way we would for individual packages,
2259   # but in cancel weight order.
2260   my @cust_svc = map { $_->cust_svc } @pkgs;
2261   my @sorted_cust_svc =
2262     map  { $_->[0] }
2263     sort { $a->[1] <=> $b->[1] }
2264     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; } @cust_svc
2265   ;
2266   warn "$me removing ".scalar(@sorted_cust_svc)." service(s) for customer ".
2267     $self->custnum."\n"
2268     if $DEBUG;
2269   my $i = 0;
2270   foreach my $cust_svc (@sorted_cust_svc) {
2271     my $savepoint = 'cancel_pkgs_'.$i++;
2272     savepoint_create( $savepoint );
2273     my $part_svc = $cust_svc->part_svc;
2274     next if ( defined($part_svc) and $part_svc->preserve );
2275     # immediate cancel, no date option
2276     # transactionize individually
2277     my $error = try { $cust_svc->cancel } catch { $_ };
2278     if ( $error ) {
2279       savepoint_rollback_and_release( $savepoint );
2280       dbh->rollback if $oldAutoCommit;
2281       push @errors, $error;
2282     } else {
2283       savepoint_release( $savepoint );
2284       dbh->commit if $oldAutoCommit;
2285     }
2286   }
2287   if (@errors) {
2288     return @errors;
2289   }
2290
2291   warn "$me cancelling ". scalar(@pkgs) ." package(s) for customer ".
2292     $self->custnum. "\n"
2293     if $DEBUG;
2294
2295   my @cprs;
2296   if ($opt{'cust_pkg_reason'}) {
2297     @cprs = @{ delete $opt{'cust_pkg_reason'} };
2298   }
2299   my $null_reason;
2300   $i = 0;
2301   foreach (@pkgs) {
2302     my %lopt = %opt;
2303     my $savepoint = 'cancel_pkgs_'.$i++;
2304     savepoint_create( $savepoint );
2305     if (@cprs) {
2306       my $cpr = shift @cprs;
2307       if ( $cpr ) {
2308         $lopt{'reason'}        = $cpr->reasonnum;
2309         $lopt{'reason_otaker'} = $cpr->otaker;
2310       } else {
2311         warn "no reason found when canceling package ".$_->pkgnum."\n";
2312         # we're not actually required to pass a reason to cust_pkg::cancel,
2313         # but if we're getting to this point, something has gone awry.
2314         $null_reason ||= FS::reason->new_or_existing(
2315           reason  => 'unknown reason',
2316           type    => 'Cancel Reason',
2317           class   => 'C',
2318         );
2319         $lopt{'reason'} = $null_reason->reasonnum;
2320         $lopt{'reason_otaker'} = $FS::CurrentUser::CurrentUser->username;
2321       }
2322     }
2323     my $error = $_->cancel(%lopt);
2324     if ( $error ) {
2325       savepoint_rollback_and_release( $savepoint );
2326       dbh->rollback if $oldAutoCommit;
2327       push @errors, 'pkgnum '.$_->pkgnum.': '.$error;
2328     } else {
2329       savepoint_release( $savepoint );
2330       dbh->commit if $oldAutoCommit;
2331     }
2332   }
2333
2334   return @errors;
2335 }
2336
2337 sub _banned_pay_hashref {
2338   die 'cust_main->_banned_pay_hashref deprecated';
2339
2340   my $self = shift;
2341
2342   my %payby2ban = (
2343     'CARD' => 'CARD',
2344     'DCRD' => 'CARD',
2345     'CHEK' => 'CHEK',
2346     'DCHK' => 'CHEK'
2347   );
2348
2349   {
2350     'payby'   => $payby2ban{$self->payby},
2351     'payinfo' => $self->payinfo,
2352     #don't ever *search* on reason! #'reason'  =>
2353   };
2354 }
2355
2356 =item notes
2357
2358 Returns all notes (see L<FS::cust_main_note>) for this customer.
2359
2360 =cut
2361
2362 sub notes {
2363   my($self,$orderby_classnum) = (shift,shift);
2364   my $orderby = "sticky DESC, _date DESC";
2365   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2366   qsearch( 'cust_main_note',
2367            { 'custnum' => $self->custnum },
2368            '',
2369            "ORDER BY $orderby",
2370          );
2371 }
2372
2373 =item agent
2374
2375 Returns the agent (see L<FS::agent>) for this customer.
2376
2377 =item agent_name
2378
2379 Returns the agent name (see L<FS::agent>) for this customer.
2380
2381 =cut
2382
2383 sub agent_name {
2384   my $self = shift;
2385   $self->agent->agent;
2386 }
2387
2388 =item cust_tag
2389
2390 Returns any tags associated with this customer, as FS::cust_tag objects,
2391 or an empty list if there are no tags.
2392
2393 =item part_tag
2394
2395 Returns any tags associated with this customer, as FS::part_tag objects,
2396 or an empty list if there are no tags.
2397
2398 =cut
2399
2400 sub part_tag {
2401   my $self = shift;
2402   map $_->part_tag, $self->cust_tag;
2403 }
2404
2405
2406 =item cust_class
2407
2408 Returns the customer class, as an FS::cust_class object, or the empty string
2409 if there is no customer class.
2410
2411 =item categoryname
2412
2413 Returns the customer category name, or the empty string if there is no customer
2414 category.
2415
2416 =cut
2417
2418 sub categoryname {
2419   my $self = shift;
2420   my $cust_class = $self->cust_class;
2421   $cust_class
2422     ? $cust_class->categoryname
2423     : '';
2424 }
2425
2426 =item classname
2427
2428 Returns the customer class name, or the empty string if there is no customer
2429 class.
2430
2431 =cut
2432
2433 sub classname {
2434   my $self = shift;
2435   my $cust_class = $self->cust_class;
2436   $cust_class
2437     ? $cust_class->classname
2438     : '';
2439 }
2440
2441 =item tax_status
2442
2443 Returns the external tax status, as an FS::tax_status object, or the empty
2444 string if there is no tax status.
2445
2446 =cut
2447
2448 sub tax_status {
2449   my $self = shift;
2450   if ( $self->taxstatusnum ) {
2451     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2452   } else {
2453     return '';
2454   }
2455 }
2456
2457 =item taxstatus
2458
2459 Returns the tax status code if there is one.
2460
2461 =cut
2462
2463 sub taxstatus {
2464   my $self = shift;
2465   my $tax_status = $self->tax_status;
2466   $tax_status
2467     ? $tax_status->taxstatus
2468     : '';
2469 }
2470
2471 =item BILLING METHODS
2472
2473 Documentation on billing methods has been moved to
2474 L<FS::cust_main::Billing>.
2475
2476 =item REALTIME BILLING METHODS
2477
2478 Documentation on realtime billing methods has been moved to
2479 L<FS::cust_main::Billing_Realtime>.
2480
2481 =item remove_cvv
2482
2483 Removes the I<paycvv> field from the database directly.
2484
2485 If there is an error, returns the error, otherwise returns false.
2486
2487 DEPRECATED.  Use L</remove_cvv_from_cust_payby> instead.
2488
2489 =cut
2490
2491 sub remove_cvv {
2492   die 'cust_main->remove_cvv deprecated';
2493   my $self = shift;
2494   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2495     or return dbh->errstr;
2496   $sth->execute($self->custnum)
2497     or return $sth->errstr;
2498   $self->paycvv('');
2499   '';
2500 }
2501
2502 =item total_owed
2503
2504 Returns the total owed for this customer on all invoices
2505 (see L<FS::cust_bill/owed>).
2506
2507 =cut
2508
2509 sub total_owed {
2510   my $self = shift;
2511   $self->total_owed_date(2145859200); #12/31/2037
2512 }
2513
2514 =item total_owed_date TIME
2515
2516 Returns the total owed for this customer on all invoices with date earlier than
2517 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2518 see L<Time::Local> and L<Date::Parse> for conversion functions.
2519
2520 =cut
2521
2522 sub total_owed_date {
2523   my $self = shift;
2524   my $time = shift;
2525
2526   my $custnum = $self->custnum;
2527
2528   my $owed_sql = FS::cust_bill->owed_sql;
2529
2530   my $sql = "
2531     SELECT SUM($owed_sql) FROM cust_bill
2532       WHERE custnum = $custnum
2533         AND _date <= $time
2534   ";
2535
2536   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2537
2538 }
2539
2540 =item total_owed_pkgnum PKGNUM
2541
2542 Returns the total owed on all invoices for this customer's specific package
2543 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2544
2545 =cut
2546
2547 sub total_owed_pkgnum {
2548   my( $self, $pkgnum ) = @_;
2549   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2550 }
2551
2552 =item total_owed_date_pkgnum TIME PKGNUM
2553
2554 Returns the total owed for this customer's specific package when using
2555 experimental package balances on all invoices with date earlier than
2556 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2557 see L<Time::Local> and L<Date::Parse> for conversion functions.
2558
2559 =cut
2560
2561 sub total_owed_date_pkgnum {
2562   my( $self, $time, $pkgnum ) = @_;
2563
2564   my $total_bill = 0;
2565   foreach my $cust_bill (
2566     grep { $_->_date <= $time }
2567       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2568   ) {
2569     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2570   }
2571   sprintf( "%.2f", $total_bill );
2572
2573 }
2574
2575 =item total_paid
2576
2577 Returns the total amount of all payments.
2578
2579 =cut
2580
2581 sub total_paid {
2582   my $self = shift;
2583   my $total = 0;
2584   $total += $_->paid foreach $self->cust_pay;
2585   sprintf( "%.2f", $total );
2586 }
2587
2588 =item total_unapplied_credits
2589
2590 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2591 customer.  See L<FS::cust_credit/credited>.
2592
2593 =item total_credited
2594
2595 Old name for total_unapplied_credits.  Don't use.
2596
2597 =cut
2598
2599 sub total_credited {
2600   #carp "total_credited deprecated, use total_unapplied_credits";
2601   shift->total_unapplied_credits(@_);
2602 }
2603
2604 sub total_unapplied_credits {
2605   my $self = shift;
2606
2607   my $custnum = $self->custnum;
2608
2609   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2610
2611   my $sql = "
2612     SELECT SUM($unapplied_sql) FROM cust_credit
2613       WHERE custnum = $custnum
2614   ";
2615
2616   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2617
2618 }
2619
2620 =item total_unapplied_credits_pkgnum PKGNUM
2621
2622 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2623 customer.  See L<FS::cust_credit/credited>.
2624
2625 =cut
2626
2627 sub total_unapplied_credits_pkgnum {
2628   my( $self, $pkgnum ) = @_;
2629   my $total_credit = 0;
2630   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2631   sprintf( "%.2f", $total_credit );
2632 }
2633
2634
2635 =item total_unapplied_payments
2636
2637 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2638 See L<FS::cust_pay/unapplied>.
2639
2640 =cut
2641
2642 sub total_unapplied_payments {
2643   my $self = shift;
2644
2645   my $custnum = $self->custnum;
2646
2647   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2648
2649   my $sql = "
2650     SELECT SUM($unapplied_sql) FROM cust_pay
2651       WHERE custnum = $custnum
2652   ";
2653
2654   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2655
2656 }
2657
2658 =item total_unapplied_payments_pkgnum PKGNUM
2659
2660 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2661 specific package when using experimental package balances.  See
2662 L<FS::cust_pay/unapplied>.
2663
2664 =cut
2665
2666 sub total_unapplied_payments_pkgnum {
2667   my( $self, $pkgnum ) = @_;
2668   my $total_unapplied = 0;
2669   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2670   sprintf( "%.2f", $total_unapplied );
2671 }
2672
2673
2674 =item total_unapplied_refunds
2675
2676 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2677 customer.  See L<FS::cust_refund/unapplied>.
2678
2679 =cut
2680
2681 sub total_unapplied_refunds {
2682   my $self = shift;
2683   my $custnum = $self->custnum;
2684
2685   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2686
2687   my $sql = "
2688     SELECT SUM($unapplied_sql) FROM cust_refund
2689       WHERE custnum = $custnum
2690   ";
2691
2692   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2693
2694 }
2695
2696 =item balance
2697
2698 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2699 total_unapplied_credits minus total_unapplied_payments).
2700
2701 =cut
2702
2703 sub balance {
2704   my $self = shift;
2705   $self->balance_date_range;
2706 }
2707
2708 =item balance_date TIME
2709
2710 Returns the balance for this customer, only considering invoices with date
2711 earlier than TIME (total_owed_date minus total_credited minus
2712 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2713 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2714 functions.
2715
2716 =cut
2717
2718 sub balance_date {
2719   my $self = shift;
2720   $self->balance_date_range(shift);
2721 }
2722
2723 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2724
2725 Returns the balance for this customer, optionally considering invoices with
2726 date earlier than START_TIME, and not later than END_TIME
2727 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2728
2729 Times are specified as SQL fragments or numeric
2730 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2731 L<Date::Parse> for conversion functions.  The empty string can be passed
2732 to disable that time constraint completely.
2733
2734 Accepts the same options as L</balance_date_sql>:
2735
2736 =over 4
2737
2738 =item unapplied_date
2739
2740 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2741
2742 =item cutoff
2743
2744 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2745 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2746 range for invoices and I<unapplied> payments, credits, and refunds.
2747
2748 =back
2749
2750 =cut
2751
2752 sub balance_date_range {
2753   my $self = shift;
2754   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2755             ') FROM cust_main WHERE custnum='. $self->custnum;
2756   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2757 }
2758
2759 =item balance_pkgnum PKGNUM
2760
2761 Returns the balance for this customer's specific package when using
2762 experimental package balances (total_owed plus total_unrefunded, minus
2763 total_unapplied_credits minus total_unapplied_payments)
2764
2765 =cut
2766
2767 sub balance_pkgnum {
2768   my( $self, $pkgnum ) = @_;
2769
2770   sprintf( "%.2f",
2771       $self->total_owed_pkgnum($pkgnum)
2772 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2773 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2774     - $self->total_unapplied_credits_pkgnum($pkgnum)
2775     - $self->total_unapplied_payments_pkgnum($pkgnum)
2776   );
2777 }
2778
2779 =item payment_info
2780
2781 Returns a hash of useful information for making a payment.
2782
2783 =over 4
2784
2785 =item balance
2786
2787 Current balance.
2788
2789 =item payby
2790
2791 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2792 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2793 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2794
2795 =back
2796
2797 For credit card transactions:
2798
2799 =over 4
2800
2801 =item card_type 1
2802
2803 =item payname
2804
2805 Exact name on card
2806
2807 =back
2808
2809 For electronic check transactions:
2810
2811 =over 4
2812
2813 =item stateid_state
2814
2815 =back
2816
2817 =cut
2818
2819 #XXX i need to be updated for 4.x+
2820 sub payment_info {
2821   my $self = shift;
2822
2823   my %return = ();
2824
2825   $return{balance} = $self->balance;
2826
2827   $return{payname} = $self->payname
2828                      || ( $self->first. ' '. $self->get('last') );
2829
2830   $return{$_} = $self->bill_location->$_
2831     for qw(address1 address2 city state zip);
2832
2833   $return{payby} = $self->payby;
2834   $return{stateid_state} = $self->stateid_state;
2835
2836   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2837     $return{card_type} = cardtype($self->payinfo);
2838     $return{payinfo} = $self->paymask;
2839
2840     @return{'month', 'year'} = $self->paydate_monthyear;
2841
2842   }
2843
2844   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2845     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2846     $return{payinfo1} = $payinfo1;
2847     $return{payinfo2} = $payinfo2;
2848     $return{paytype}  = $self->paytype;
2849     $return{paystate} = $self->paystate;
2850
2851   }
2852
2853   #doubleclick protection
2854   my $_date = time;
2855   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2856
2857   %return;
2858
2859 }
2860
2861 =item paydate_epoch
2862
2863 Returns the next payment expiration date for this customer. If they have no
2864 payment methods that will expire, returns 0.
2865
2866 =cut
2867
2868 sub paydate_epoch {
2869   my $self = shift;
2870   # filter out the ones that individually return 0, but then return 0 if
2871   # there are no results
2872   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
2873   min( @epochs ) || 0;
2874 }
2875
2876 =item paydate_epoch_sql
2877
2878 Returns an SQL expression to get the next payment expiration date for a
2879 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
2880 dates, so that it's safe to test for "will it expire before date X" for any
2881 date up to then.
2882
2883 =cut
2884
2885 sub paydate_epoch_sql {
2886   my $class = shift;
2887   my $paydate = FS::cust_payby->paydate_epoch_sql;
2888   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
2889 }
2890
2891 sub tax_exemption {
2892   my( $self, $taxname ) = @_;
2893
2894   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
2895                                      'taxname' => $taxname,
2896                                    },
2897           );
2898 }
2899
2900 =item cust_main_exemption
2901
2902 =item invoicing_list
2903
2904 Returns a list of email addresses (with svcnum entries expanded), and the word
2905 'POST' if the customer receives postal invoices.
2906
2907 =cut
2908
2909 sub invoicing_list {
2910   my( $self, $arrayref ) = @_;
2911
2912   if ( $arrayref ) {
2913     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
2914   }
2915
2916   my @emails = $self->invoicing_list_emailonly;
2917   push @emails, 'POST' if $self->get('postal_invoice');
2918
2919   @emails;
2920 }
2921
2922 =item check_invoicing_list ARRAYREF
2923
2924 Checks these arguements as valid input for the invoicing_list method.  If there
2925 is an error, returns the error, otherwise returns false.
2926
2927 =cut
2928
2929 sub check_invoicing_list {
2930   my( $self, $arrayref ) = @_;
2931
2932   foreach my $address ( @$arrayref ) {
2933
2934     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
2935       return 'Can\'t add FAX invoice destination with a blank FAX number.';
2936     }
2937
2938     my $cust_main_invoice = new FS::cust_main_invoice ( {
2939       'custnum' => $self->custnum,
2940       'dest'    => $address,
2941     } );
2942     my $error = $self->custnum
2943                 ? $cust_main_invoice->check
2944                 : $cust_main_invoice->checkdest
2945     ;
2946     return $error if $error;
2947
2948   }
2949
2950   return "Email address required"
2951     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
2952     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
2953
2954   '';
2955 }
2956
2957 =item all_emails
2958
2959 Returns the email addresses of all accounts provisioned for this customer.
2960
2961 =cut
2962
2963 sub all_emails {
2964   my $self = shift;
2965   my %list;
2966   foreach my $cust_pkg ( $self->all_pkgs ) {
2967     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
2968     my @svc_acct =
2969       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2970         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2971           @cust_svc;
2972     $list{$_}=1 foreach map { $_->email } @svc_acct;
2973   }
2974   keys %list;
2975 }
2976
2977 =item invoicing_list_addpost
2978
2979 Adds postal invoicing to this customer.  If this customer is already configured
2980 to receive postal invoices, does nothing.
2981
2982 =cut
2983
2984 sub invoicing_list_addpost {
2985   my $self = shift;
2986   if ( $self->get('postal_invoice') eq '' ) {
2987     $self->set('postal_invoice', 'Y');
2988     my $error = $self->replace;
2989     warn $error if $error; # should fail harder, but this is traditional
2990   }
2991 }
2992
2993 =item invoicing_list_emailonly
2994
2995 Returns the list of email invoice recipients (invoicing_list without non-email
2996 destinations such as POST and FAX).
2997
2998 =cut
2999
3000 sub invoicing_list_emailonly {
3001   my $self = shift;
3002   warn "$me invoicing_list_emailonly called"
3003     if $DEBUG;
3004   return () if !$self->custnum; # not yet inserted
3005   return map { $_->emailaddress }
3006     qsearch({
3007         table     => 'cust_contact',
3008         select    => 'emailaddress',
3009         addl_from => ' JOIN contact USING (contactnum) '.
3010                      ' JOIN contact_email USING (contactnum)',
3011         hashref   => { 'custnum' => $self->custnum, },
3012         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
3013     });
3014 }
3015
3016 =item invoicing_list_emailonly_scalar
3017
3018 Returns the list of email invoice recipients (invoicing_list without non-email
3019 destinations such as POST and FAX) as a comma-separated scalar.
3020
3021 =cut
3022
3023 sub invoicing_list_emailonly_scalar {
3024   my $self = shift;
3025   warn "$me invoicing_list_emailonly_scalar called"
3026     if $DEBUG;
3027   join(', ', $self->invoicing_list_emailonly);
3028 }
3029
3030 =item contact_list [ CLASSNUM, DEST_FLAG... ]
3031
3032 Returns a list of contacts (L<FS::contact> objects) for the customer.
3033
3034 If no arguments are given, returns all contacts for the customer.
3035
3036 Arguments may contain classnums.  When classnums are specified, only
3037 contacts with a matching cust_contact.classnum are returned.  When a
3038 classnum of 0 is given, contacts with a null classnum are also included.
3039
3040 Arguments may also contain the dest flag names 'invoice' or 'message'.
3041 If given, contacts who's invoice_dest and/or message_dest flags are
3042 not set to 'Y' will be excluded.
3043
3044 =cut
3045
3046 sub contact_list {
3047   my $self = shift;
3048   my $search = {
3049     table       => 'contact',
3050     select      => join(', ',(
3051                     'contact.*',
3052                     'cust_contact.invoice_dest',
3053                     'cust_contact.message_dest',
3054     )),
3055     addl_from   => ' JOIN cust_contact USING (contactnum)',
3056     extra_sql   => ' WHERE cust_contact.custnum = '.$self->custnum,
3057   };
3058
3059   # Bugfix notes:
3060   #   Calling methods were relying on this method to use invoice_dest to
3061   #   block e-mail messages.  Depending on parameters, this may or may not
3062   #   have actually happened.
3063   #
3064   #   The bug could cause this SQL to be used to filter e-mail addresses:
3065   #
3066   #   AND (
3067   #     cust_contact.classnums IN (1,2,3)
3068   #     OR cust_contact.invoice_dest = 'Y'
3069   #   )
3070   #
3071   #   improperly including everybody with the opt-in flag AND everybody
3072   #   in the contact classes
3073   #
3074   # Possibility to introduce new bugs:
3075   #   If callers of this method called it incorrectly, and didn't notice
3076   #   because it seemed to send the e-mails they wanted.
3077
3078   # WHERE ...
3079   # AND (
3080   #   (
3081   #     cust_contact.classnum IN (1,2,3)
3082   #     OR
3083   #     cust_contact.classnum IS NULL
3084   #   )
3085   #   AND (
3086   #     cust_contact.invoice_dest = 'Y'
3087   #     OR
3088   #     cust_contact.message_dest = 'Y'
3089   #   )
3090   # )
3091
3092   my @and_dest;
3093   my @or_classnum;
3094   my @classnums;
3095   for (@_) {
3096     if ($_ eq 'invoice' || $_ eq 'message') {
3097       push @and_dest, " cust_contact.${_}_dest = 'Y' ";
3098     } elsif ($_ eq '0') {
3099       push @or_classnum, ' cust_contact.classnum IS NULL ';
3100     } elsif ( /^\d+$/ ) {
3101       push @classnums, $_;
3102     } else {
3103       croak "bad classnum argument '$_'";
3104     }
3105   }
3106
3107   push @or_classnum, 'cust_contact.classnum IN ('.join(',',@classnums).')'
3108     if @classnums;
3109
3110   if (@or_classnum || @and_dest) { # catch, no arguments given
3111     $search->{extra_sql} .= ' AND ( ';
3112
3113       if (@or_classnum) {
3114         $search->{extra_sql} .= ' ( ';
3115         $search->{extra_sql} .= join ' OR ', map {" $_ "} @or_classnum;
3116         $search->{extra_sql} .= ' ) ';
3117         $search->{extra_sql} .= ' AND ( ' if @and_dest;
3118       }
3119
3120       if (@and_dest) {
3121         $search->{extra_sql} .= join ' OR ', map {" $_ "} @and_dest;
3122         $search->{extra_sql} .= ' ) ' if @or_classnum;
3123       }
3124
3125     $search->{extra_sql} .= ' ) ';
3126
3127     warn "\$extra_sql: $search->{extra_sql} \n" if $DEBUG;
3128   }
3129
3130   qsearch($search);
3131 }
3132
3133 =item contact_list_email [ CLASSNUM, ... ]
3134
3135 Same as L</contact_list>, but returns email destinations instead of contact
3136 objects.
3137
3138 =cut
3139
3140 sub contact_list_email {
3141   my $self = shift;
3142   my @contacts = $self->contact_list(@_);
3143   my @emails;
3144   foreach my $contact (@contacts) {
3145     foreach my $contact_email ($contact->contact_email) {
3146       push @emails,  Email::Address->new( $contact->firstlast,
3147                                           $contact_email->emailaddress
3148                      )->format;
3149     }
3150   }
3151   @emails;
3152 }
3153
3154 =item contact_list_email_destinations
3155
3156 Returns a list of emails and whether they receive invoices or messages destinations.
3157 { emailaddress => 'email.com', invoice => 'Y', message => '', }
3158
3159 =cut
3160
3161 sub contact_list_email_destinations {
3162   my $self = shift;
3163   warn "$me contact_list_email_destinations"
3164     if $DEBUG;
3165   return () if !$self->custnum; # not yet inserted
3166   return map { $_ }
3167     qsearch({
3168         table     => 'cust_contact',
3169         select    => 'emailaddress, cust_contact.invoice_dest as invoice, cust_contact.message_dest as message',
3170         addl_from => ' JOIN contact USING (contactnum) '.
3171                      ' JOIN contact_email USING (contactnum)',
3172         hashref   => { 'custnum' => $self->custnum, },
3173         order_by  => 'ORDER BY custcontactnum DESC',
3174         extra_sql => '',
3175     });
3176 }
3177
3178 =item contact_list_name_phones
3179
3180 Returns a list of contact phone numbers.
3181 { phonetypenum => '1', phonenum => 'xxxxxxxxxx', first => 'firstname', last => 'lastname', countrycode => '1' }
3182
3183 =cut
3184
3185 sub contact_list_name_phones {
3186   my $self = shift;
3187   my $phone_type = shift;
3188
3189   warn "$me contact_list_phones" if $DEBUG;
3190
3191   return () if !$self->custnum; # not yet inserted
3192   return map { $_ }
3193     qsearch({
3194         table     => 'cust_contact',
3195         select    => 'phonetypenum, phonenum, first, last, countrycode',
3196         addl_from => ' JOIN contact USING (contactnum) '.
3197                      ' JOIN contact_phone USING (contactnum)',
3198         hashref   => { 'custnum' => $self->custnum, 'phonetypenum' => $phone_type, },
3199         order_by  => 'ORDER BY custcontactnum DESC',
3200         extra_sql => '',
3201     });
3202 }
3203
3204 =item contact_list_emailonly
3205
3206 Returns an array of hashes containing the emails. Used for displaying contact email field in advanced customer reports.
3207 [ { data => 'email.com', }, ]
3208
3209 =cut
3210
3211 sub contact_list_emailonly {
3212   my $self = shift;
3213   warn "$me contact_list_emailonly called"
3214     if $DEBUG;
3215   my @emails;
3216   foreach ($self->contact_list_email_destinations) {
3217     my $data = [
3218       {
3219         'data'  => $_->emailaddress,
3220       },
3221     ];
3222     push @emails, $data;
3223   }
3224   return \@emails;
3225 }
3226
3227 =item contact_list_cust_invoice_only
3228
3229 Returns an array of hashes containing cust_contact.invoice_dest.  Does this email receive invoices. Used for displaying email Invoice field in advanced customer reports.
3230 [ { data => 'Yes', }, ]
3231
3232 =cut
3233
3234 sub contact_list_cust_invoice_only {
3235   my $self = shift;
3236   warn "$me contact_list_cust_invoice_only called"
3237     if $DEBUG;
3238   my @emails;
3239   foreach ($self->contact_list_email_destinations) {
3240     my $invoice = $_->invoice ? 'Yes' : 'No';
3241     my $data = [
3242       {
3243         'data'  => $invoice,
3244       },
3245     ];
3246     push @emails, $data;
3247   }
3248   return \@emails;
3249 }
3250
3251 =item contact_list_cust_message_only
3252
3253 Returns an array of hashes containing cust_contact.message_dest.  Does this email receive message notifications. Used for displaying email Message field in advanced customer reports.
3254 [ { data => 'Yes', }, ]
3255
3256 =cut
3257
3258 sub contact_list_cust_message_only {
3259   my $self = shift;
3260   warn "$me contact_list_cust_message_only called"
3261     if $DEBUG;
3262   my @emails;
3263   foreach ($self->contact_list_email_destinations) {
3264     my $message = $_->message ? 'Yes' : 'No';
3265     my $data = [
3266       {
3267         'data'  => $message,
3268       },
3269     ];
3270     push @emails, $data;
3271   }
3272   return \@emails;
3273 }
3274
3275 =item referral_custnum_cust_main
3276
3277 Returns the customer who referred this customer (or the empty string, if
3278 this customer was not referred).
3279
3280 Note the difference with referral_cust_main method: This method,
3281 referral_custnum_cust_main returns the single customer (if any) who referred
3282 this customer, while referral_cust_main returns an array of customers referred
3283 BY this customer.
3284
3285 =cut
3286
3287 sub referral_custnum_cust_main {
3288   my $self = shift;
3289   return '' unless $self->referral_custnum;
3290   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3291 }
3292
3293 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3294
3295 Returns an array of customers referred by this customer (referral_custnum set
3296 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3297 customers referred by customers referred by this customer and so on, inclusive.
3298 The default behavior is DEPTH 1 (no recursion).
3299
3300 Note the difference with referral_custnum_cust_main method: This method,
3301 referral_cust_main, returns an array of customers referred BY this customer,
3302 while referral_custnum_cust_main returns the single customer (if any) who
3303 referred this customer.
3304
3305 =cut
3306
3307 sub referral_cust_main {
3308   my $self = shift;
3309   my $depth = @_ ? shift : 1;
3310   my $exclude = @_ ? shift : {};
3311
3312   my @cust_main =
3313     map { $exclude->{$_->custnum}++; $_; }
3314       grep { ! $exclude->{ $_->custnum } }
3315         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3316
3317   if ( $depth > 1 ) {
3318     push @cust_main,
3319       map { $_->referral_cust_main($depth-1, $exclude) }
3320         @cust_main;
3321   }
3322
3323   @cust_main;
3324 }
3325
3326 =item referral_cust_main_ncancelled
3327
3328 Same as referral_cust_main, except only returns customers with uncancelled
3329 packages.
3330
3331 =cut
3332
3333 sub referral_cust_main_ncancelled {
3334   my $self = shift;
3335   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3336 }
3337
3338 =item referral_cust_pkg [ DEPTH ]
3339
3340 Like referral_cust_main, except returns a flat list of all unsuspended (and
3341 uncancelled) packages for each customer.  The number of items in this list may
3342 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3343
3344 =cut
3345
3346 sub referral_cust_pkg {
3347   my $self = shift;
3348   my $depth = @_ ? shift : 1;
3349
3350   map { $_->unsuspended_pkgs }
3351     grep { $_->unsuspended_pkgs }
3352       $self->referral_cust_main($depth);
3353 }
3354
3355 =item referring_cust_main
3356
3357 Returns the single cust_main record for the customer who referred this customer
3358 (referral_custnum), or false.
3359
3360 =cut
3361
3362 sub referring_cust_main {
3363   my $self = shift;
3364   return '' unless $self->referral_custnum;
3365   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3366 }
3367
3368 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3369
3370 Applies a credit to this customer.  If there is an error, returns the error,
3371 otherwise returns false.
3372
3373 REASON can be a text string, an FS::reason object, or a scalar reference to
3374 a reasonnum.  If a text string, it will be automatically inserted as a new
3375 reason, and a 'reason_type' option must be passed to indicate the
3376 FS::reason_type for the new reason.
3377
3378 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3379 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3380 I<commission_pkgnum>.
3381
3382 Any other options are passed to FS::cust_credit::insert.
3383
3384 =cut
3385
3386 sub credit {
3387   my( $self, $amount, $reason, %options ) = @_;
3388
3389   my $cust_credit = new FS::cust_credit {
3390     'custnum' => $self->custnum,
3391     'amount'  => $amount,
3392   };
3393
3394   if ( ref($reason) ) {
3395
3396     if ( ref($reason) eq 'SCALAR' ) {
3397       $cust_credit->reasonnum( $$reason );
3398     } else {
3399       $cust_credit->reasonnum( $reason->reasonnum );
3400     }
3401
3402   } else {
3403     $cust_credit->set('reason', $reason)
3404   }
3405
3406   $cust_credit->$_( delete $options{$_} )
3407     foreach grep exists($options{$_}),
3408               qw( addlinfo eventnum ),
3409               map "commission_$_", qw( agentnum salesnum pkgnum );
3410
3411   $cust_credit->insert(%options);
3412
3413 }
3414
3415 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3416
3417 Creates a one-time charge for this customer.  If there is an error, returns
3418 the error, otherwise returns false.
3419
3420 New-style, with a hashref of options:
3421
3422   my $error = $cust_main->charge(
3423                                   {
3424                                     'amount'     => 54.32,
3425                                     'quantity'   => 1,
3426                                     'start_date' => str2time('7/4/2009'),
3427                                     'pkg'        => 'Description',
3428                                     'comment'    => 'Comment',
3429                                     'additional' => [], #extra invoice detail
3430                                     'classnum'   => 1,  #pkg_class
3431
3432                                     'setuptax'   => '', # or 'Y' for tax exempt
3433
3434                                     'locationnum'=> 1234, # optional
3435
3436                                     #internal taxation
3437                                     'taxclass'   => 'Tax class',
3438
3439                                     #vendor taxation
3440                                     'taxproduct' => 2,  #part_pkg_taxproduct
3441                                     'override'   => {}, #XXX describe
3442
3443                                     #will be filled in with the new object
3444                                     'cust_pkg_ref' => \$cust_pkg,
3445
3446                                     #generate an invoice immediately
3447                                     'bill_now' => 0,
3448                                     'invoice_terms' => '', #with these terms
3449                                   }
3450                                 );
3451
3452 Old-style:
3453
3454   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3455
3456 =cut
3457
3458 #super false laziness w/quotation::charge
3459 sub charge {
3460   my $self = shift;
3461   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3462   my ( $pkg, $comment, $additional );
3463   my ( $setuptax, $taxclass );   #internal taxes
3464   my ( $taxproduct, $override ); #vendor (CCH) taxes
3465   my $no_auto = '';
3466   my $separate_bill = '';
3467   my $cust_pkg_ref = '';
3468   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3469   my $locationnum;
3470   my ( $discountnum, $discountnum_amount, $discountnum_percent ) = ( '','','' );
3471   if ( ref( $_[0] ) ) {
3472     $amount     = $_[0]->{amount};
3473     $setup_cost = $_[0]->{setup_cost};
3474     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3475     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3476     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3477     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3478     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3479                                            : '$'. sprintf("%.2f",$amount);
3480     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3481     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3482     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3483     $additional = $_[0]->{additional} || [];
3484     $taxproduct = $_[0]->{taxproductnum};
3485     $override   = { '' => $_[0]->{tax_override} };
3486     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3487     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3488     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3489     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3490     $separate_bill = $_[0]->{separate_bill} || '';
3491     $discountnum = $_[0]->{setup_discountnum};
3492     $discountnum_amount = $_[0]->{setup_discountnum_amount};
3493     $discountnum_percent = $_[0]->{setup_discountnum_percent};
3494   } else { # yuck
3495     $amount     = shift;
3496     $setup_cost = '';
3497     $quantity   = 1;
3498     $start_date = '';
3499     $pkg        = @_ ? shift : 'One-time charge';
3500     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3501     $setuptax   = '';
3502     $taxclass   = @_ ? shift : '';
3503     $additional = [];
3504   }
3505
3506   local $SIG{HUP} = 'IGNORE';
3507   local $SIG{INT} = 'IGNORE';
3508   local $SIG{QUIT} = 'IGNORE';
3509   local $SIG{TERM} = 'IGNORE';
3510   local $SIG{TSTP} = 'IGNORE';
3511   local $SIG{PIPE} = 'IGNORE';
3512
3513   my $oldAutoCommit = $FS::UID::AutoCommit;
3514   local $FS::UID::AutoCommit = 0;
3515   my $dbh = dbh;
3516
3517   my $part_pkg = new FS::part_pkg ( {
3518     'pkg'           => $pkg,
3519     'comment'       => $comment,
3520     'plan'          => 'flat',
3521     'freq'          => 0,
3522     'disabled'      => 'Y',
3523     'classnum'      => ( $classnum ? $classnum : '' ),
3524     'setuptax'      => $setuptax,
3525     'taxclass'      => $taxclass,
3526     'taxproductnum' => $taxproduct,
3527     'setup_cost'    => $setup_cost,
3528   } );
3529
3530   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3531                         ( 0 .. @$additional - 1 )
3532                   ),
3533                   'additional_count' => scalar(@$additional),
3534                   'setup_fee' => $amount,
3535                 );
3536
3537   my $error = $part_pkg->insert( options       => \%options,
3538                                  tax_overrides => $override,
3539                                );
3540   if ( $error ) {
3541     $dbh->rollback if $oldAutoCommit;
3542     return $error;
3543   }
3544
3545   my $pkgpart = $part_pkg->pkgpart;
3546   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3547   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3548     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3549     $error = $type_pkgs->insert;
3550     if ( $error ) {
3551       $dbh->rollback if $oldAutoCommit;
3552       return $error;
3553     }
3554   }
3555
3556   my $cust_pkg = new FS::cust_pkg ( {
3557     'custnum'                   => $self->custnum,
3558     'pkgpart'                   => $pkgpart,
3559     'quantity'                  => $quantity,
3560     'start_date'                => $start_date,
3561     'no_auto'                   => $no_auto,
3562     'separate_bill'             => $separate_bill,
3563     'locationnum'               => $locationnum,
3564     'setup_discountnum'         => $discountnum,
3565     'setup_discountnum_amount'  => $discountnum_amount,
3566     'setup_discountnum_percent' => $discountnum_percent,
3567   } );
3568
3569   $error = $cust_pkg->insert;
3570   if ( $error ) {
3571     $dbh->rollback if $oldAutoCommit;
3572     return $error;
3573   } elsif ( $cust_pkg_ref ) {
3574     ${$cust_pkg_ref} = $cust_pkg;
3575   }
3576
3577   if ( $bill_now ) {
3578     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3579                              'pkg_list'      => [ $cust_pkg ],
3580                            );
3581     if ( $error ) {
3582       $dbh->rollback if $oldAutoCommit;
3583       return $error;
3584     }
3585   }
3586
3587   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3588   return '';
3589
3590 }
3591
3592 #=item charge_postal_fee
3593 #
3594 #Applies a one time charge this customer.  If there is an error,
3595 #returns the error, returns the cust_pkg charge object or false
3596 #if there was no charge.
3597 #
3598 #=cut
3599 #
3600 # This should be a customer event.  For that to work requires that bill
3601 # also be a customer event.
3602
3603 sub charge_postal_fee {
3604   my $self = shift;
3605
3606   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3607   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3608
3609   my $cust_pkg = new FS::cust_pkg ( {
3610     'custnum'  => $self->custnum,
3611     'pkgpart'  => $pkgpart,
3612     'quantity' => 1,
3613   } );
3614
3615   my $error = $cust_pkg->insert;
3616   $error ? $error : $cust_pkg;
3617 }
3618
3619 =item num_cust_attachment_deleted
3620
3621 Returns the number of deleted attachments for this customer (see
3622 L<FS::num_cust_attachment>).
3623
3624 =cut
3625
3626 sub num_cust_attachments_deleted {
3627   my $self = shift;
3628   $self->scalar_sql(
3629     " SELECT COUNT(*) FROM cust_attachment ".
3630       " WHERE custnum = ? AND disabled IS NOT NULL AND disabled > 0",
3631     $self->custnum
3632   );
3633 }
3634
3635 =item max_invnum
3636
3637 Returns the most recent invnum (invoice number) for this customer.
3638
3639 =cut
3640
3641 sub max_invnum {
3642   my $self = shift;
3643   $self->scalar_sql(
3644     " SELECT MAX(invnum) FROM cust_bill WHERE custnum = ?",
3645     $self->custnum
3646   );
3647 }
3648
3649 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3650
3651 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3652
3653 Optionally, a list or hashref of additional arguments to the qsearch call can
3654 be passed.
3655
3656 =cut
3657
3658 sub cust_bill {
3659   my $self = shift;
3660   my $opt = ref($_[0]) ? shift : { @_ };
3661
3662   #return $self->num_cust_bill unless wantarray || keys %$opt;
3663
3664   $opt->{'table'} = 'cust_bill';
3665   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3666   $opt->{'hashref'}{'custnum'} = $self->custnum;
3667   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3668
3669   map { $_ } #behavior of sort undefined in scalar context
3670     sort { $a->_date <=> $b->_date }
3671       qsearch($opt);
3672 }
3673
3674 =item open_cust_bill
3675
3676 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3677 customer.
3678
3679 =cut
3680
3681 sub open_cust_bill {
3682   my $self = shift;
3683
3684   $self->cust_bill(
3685     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3686     #@_
3687   );
3688
3689 }
3690
3691 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3692
3693 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3694
3695 =cut
3696
3697 sub legacy_cust_bill {
3698   my $self = shift;
3699
3700   #return $self->num_legacy_cust_bill unless wantarray;
3701
3702   map { $_ } #behavior of sort undefined in scalar context
3703     sort { $a->_date <=> $b->_date }
3704       qsearch({ 'table'    => 'legacy_cust_bill',
3705                 'hashref'  => { 'custnum' => $self->custnum, },
3706                 'order_by' => 'ORDER BY _date ASC',
3707              });
3708 }
3709
3710 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3711
3712 Returns all the statements (see L<FS::cust_statement>) for this customer.
3713
3714 Optionally, a list or hashref of additional arguments to the qsearch call can
3715 be passed.
3716
3717 =cut
3718
3719 =item cust_bill_void
3720
3721 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3722
3723 =cut
3724
3725 sub cust_bill_void {
3726   my $self = shift;
3727
3728   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3729   sort { $a->_date <=> $b->_date }
3730     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3731 }
3732
3733 sub cust_statement {
3734   my $self = shift;
3735   my $opt = ref($_[0]) ? shift : { @_ };
3736
3737   #return $self->num_cust_statement unless wantarray || keys %$opt;
3738
3739   $opt->{'table'} = 'cust_statement';
3740   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3741   $opt->{'hashref'}{'custnum'} = $self->custnum;
3742   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3743
3744   map { $_ } #behavior of sort undefined in scalar context
3745     sort { $a->_date <=> $b->_date }
3746       qsearch($opt);
3747 }
3748
3749 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3750
3751 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3752
3753 Optionally, a list or hashref of additional arguments to the qsearch call can
3754 be passed following the SVCDB.
3755
3756 =cut
3757
3758 sub svc_x {
3759   my $self = shift;
3760   my $svcdb = shift;
3761   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3762     warn "$me svc_x requires a svcdb";
3763     return;
3764   }
3765   my $opt = ref($_[0]) ? shift : { @_ };
3766
3767   $opt->{'table'} = $svcdb;
3768   $opt->{'addl_from'} =
3769     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3770     ($opt->{'addl_from'} || '');
3771
3772   my $custnum = $self->custnum;
3773   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3774   my $where = "cust_pkg.custnum = $custnum";
3775
3776   my $extra_sql = $opt->{'extra_sql'} || '';
3777   if ( keys %{ $opt->{'hashref'} } ) {
3778     $extra_sql = " AND $where $extra_sql";
3779   }
3780   else {
3781     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3782       $extra_sql = "WHERE $where AND $1";
3783     }
3784     else {
3785       $extra_sql = "WHERE $where $extra_sql";
3786     }
3787   }
3788   $opt->{'extra_sql'} = $extra_sql;
3789
3790   qsearch($opt);
3791 }
3792
3793 # required for use as an eventtable;
3794 sub svc_acct {
3795   my $self = shift;
3796   $self->svc_x('svc_acct', @_);
3797 }
3798
3799 =item cust_credit
3800
3801 Returns all the credits (see L<FS::cust_credit>) for this customer.
3802
3803 =cut
3804
3805 sub cust_credit {
3806   my $self = shift;
3807
3808   #return $self->num_cust_credit unless wantarray;
3809
3810   map { $_ } #behavior of sort undefined in scalar context
3811     sort { $a->_date <=> $b->_date }
3812       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3813 }
3814
3815 =item cust_credit_pkgnum
3816
3817 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3818 package when using experimental package balances.
3819
3820 =cut
3821
3822 sub cust_credit_pkgnum {
3823   my( $self, $pkgnum ) = @_;
3824   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3825   sort { $a->_date <=> $b->_date }
3826     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3827                               'pkgnum'  => $pkgnum,
3828                             }
3829     );
3830 }
3831
3832 =item cust_credit_void
3833
3834 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3835
3836 =cut
3837
3838 sub cust_credit_void {
3839   my $self = shift;
3840   map { $_ }
3841   sort { $a->_date <=> $b->_date }
3842     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3843 }
3844
3845 =item cust_pay
3846
3847 Returns all the payments (see L<FS::cust_pay>) for this customer.
3848
3849 =cut
3850
3851 sub cust_pay {
3852   my $self = shift;
3853   my $opt = ref($_[0]) ? shift : { @_ };
3854
3855   return $self->num_cust_pay unless wantarray || keys %$opt;
3856
3857   $opt->{'table'} = 'cust_pay';
3858   $opt->{'hashref'}{'custnum'} = $self->custnum;
3859
3860   map { $_ } #behavior of sort undefined in scalar context
3861     sort { $a->_date <=> $b->_date }
3862       qsearch($opt);
3863
3864 }
3865
3866 =item num_cust_pay
3867
3868 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3869 called automatically when the cust_pay method is used in a scalar context.
3870
3871 =cut
3872
3873 sub num_cust_pay {
3874   my $self = shift;
3875   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3876   my $sth = dbh->prepare($sql) or die dbh->errstr;
3877   $sth->execute($self->custnum) or die $sth->errstr;
3878   $sth->fetchrow_arrayref->[0];
3879 }
3880
3881 =item unapplied_cust_pay
3882
3883 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3884
3885 =cut
3886
3887 sub unapplied_cust_pay {
3888   my $self = shift;
3889
3890   $self->cust_pay(
3891     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3892     #@_
3893   );
3894
3895 }
3896
3897 =item cust_pay_pkgnum
3898
3899 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3900 package when using experimental package balances.
3901
3902 =cut
3903
3904 sub cust_pay_pkgnum {
3905   my( $self, $pkgnum ) = @_;
3906   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3907   sort { $a->_date <=> $b->_date }
3908     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3909                            'pkgnum'  => $pkgnum,
3910                          }
3911     );
3912 }
3913
3914 =item cust_pay_void
3915
3916 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3917
3918 =cut
3919
3920 sub cust_pay_void {
3921   my $self = shift;
3922   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3923   sort { $a->_date <=> $b->_date }
3924     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3925 }
3926
3927 =item cust_pay_pending
3928
3929 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3930 (without status "done").
3931
3932 =cut
3933
3934 sub cust_pay_pending {
3935   my $self = shift;
3936   return $self->num_cust_pay_pending unless wantarray;
3937   sort { $a->_date <=> $b->_date }
3938     qsearch( 'cust_pay_pending', {
3939                                    'custnum' => $self->custnum,
3940                                    'status'  => { op=>'!=', value=>'done' },
3941                                  },
3942            );
3943 }
3944
3945 =item cust_pay_pending_attempt
3946
3947 Returns all payment attempts / declined payments for this customer, as pending
3948 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3949 a corresponding payment (see L<FS::cust_pay>).
3950
3951 =cut
3952
3953 sub cust_pay_pending_attempt {
3954   my $self = shift;
3955   return $self->num_cust_pay_pending_attempt unless wantarray;
3956   sort { $a->_date <=> $b->_date }
3957     qsearch( 'cust_pay_pending', {
3958                                    'custnum' => $self->custnum,
3959                                    'status'  => 'done',
3960                                    'paynum'  => '',
3961                                  },
3962            );
3963 }
3964
3965 =item num_cust_pay_pending
3966
3967 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3968 customer (without status "done").  Also called automatically when the
3969 cust_pay_pending method is used in a scalar context.
3970
3971 =cut
3972
3973 sub num_cust_pay_pending {
3974   my $self = shift;
3975   $self->scalar_sql(
3976     " SELECT COUNT(*) FROM cust_pay_pending ".
3977       " WHERE custnum = ? AND status != 'done' ",
3978     $self->custnum
3979   );
3980 }
3981
3982 =item num_cust_pay_pending_attempt
3983
3984 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3985 customer, with status "done" but without a corresp.  Also called automatically when the
3986 cust_pay_pending method is used in a scalar context.
3987
3988 =cut
3989
3990 sub num_cust_pay_pending_attempt {
3991   my $self = shift;
3992   $self->scalar_sql(
3993     " SELECT COUNT(*) FROM cust_pay_pending ".
3994       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3995     $self->custnum
3996   );
3997 }
3998
3999 =item cust_refund
4000
4001 Returns all the refunds (see L<FS::cust_refund>) for this customer.
4002
4003 =cut
4004
4005 sub cust_refund {
4006   my $self = shift;
4007   map { $_ } #return $self->num_cust_refund unless wantarray;
4008   sort { $a->_date <=> $b->_date }
4009     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
4010 }
4011
4012 =item display_custnum
4013
4014 Returns the displayed customer number for this customer: agent_custid if
4015 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
4016
4017 =cut
4018
4019 sub display_custnum {
4020   my $self = shift;
4021
4022   return $self->agent_custid
4023     if $default_agent_custid && $self->agent_custid;
4024
4025   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
4026
4027   if ( $prefix ) {
4028     return $prefix .
4029            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
4030   } elsif ( $custnum_display_length ) {
4031     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
4032   } else {
4033     return $self->custnum;
4034   }
4035 }
4036
4037 =item name
4038
4039 Returns a name string for this customer, either "Company (Last, First)" or
4040 "Last, First".
4041
4042 =cut
4043
4044 sub name {
4045   my $self = shift;
4046   my $name = $self->contact;
4047   $name = $self->company. " ($name)" if $self->company;
4048   $name;
4049 }
4050
4051 =item batch_payment_payname
4052
4053 Returns a name string for this customer, either "cust_batch_payment->payname" or "First Last" or "Company,
4054 based on if a company name exists and is the account being used a business account.
4055
4056 =cut
4057
4058 sub batch_payment_payname {
4059   my $self = shift;
4060   my $cust_pay_batch = shift;
4061   my $name;
4062
4063   if ($cust_pay_batch->{Hash}->{payby} eq "CARD") { $name = $cust_pay_batch->payname; }
4064   else { $name = $self->first .' '. $self->last; }
4065
4066   $name = $self->company
4067     if (($cust_pay_batch->{Hash}->{paytype} eq "Business checking" || $cust_pay_batch->{Hash}->{paytype} eq "Business savings") && $self->company);
4068
4069   $name;
4070 }
4071
4072 =item service_contact
4073
4074 Returns the L<FS::contact> object for this customer that has the 'Service'
4075 contact class, or undef if there is no such contact.  Deprecated; don't use
4076 this in new code.
4077
4078 =cut
4079
4080 sub service_contact {
4081   my $self = shift;
4082   if ( !exists($self->{service_contact}) ) {
4083     my $classnum = $self->scalar_sql(
4084       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
4085     ) || 0; #if it's zero, qsearchs will return nothing
4086     my $cust_contact = qsearchs('cust_contact', {
4087         'classnum' => $classnum,
4088         'custnum'  => $self->custnum,
4089     });
4090     $self->{service_contact} = $cust_contact->contact if $cust_contact;
4091   }
4092   $self->{service_contact};
4093 }
4094
4095 =item ship_name
4096
4097 Returns a name string for this (service/shipping) contact, either
4098 "Company (Last, First)" or "Last, First".
4099
4100 =cut
4101
4102 sub ship_name {
4103   my $self = shift;
4104
4105   my $name = $self->ship_contact;
4106   $name = $self->company. " ($name)" if $self->company;
4107   $name;
4108 }
4109
4110 =item name_short
4111
4112 Returns a name string for this customer, either "Company" or "First Last".
4113
4114 =cut
4115
4116 sub name_short {
4117   my $self = shift;
4118   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4119 }
4120
4121 =item ship_name_short
4122
4123 Returns a name string for this (service/shipping) contact, either "Company"
4124 or "First Last".
4125
4126 =cut
4127
4128 sub ship_name_short {
4129   my $self = shift;
4130   $self->service_contact
4131     ? $self->ship_contact_firstlast
4132     : $self->name_short
4133 }
4134
4135 =item contact
4136
4137 Returns this customer's full (billing) contact name only, "Last, First"
4138
4139 =cut
4140
4141 sub contact {
4142   my $self = shift;
4143   $self->get('last'). ', '. $self->first;
4144 }
4145
4146 =item ship_contact
4147
4148 Returns this customer's full (shipping) contact name only, "Last, First"
4149
4150 =cut
4151
4152 sub ship_contact {
4153   my $self = shift;
4154   my $contact = $self->service_contact || $self;
4155   $contact->get('last') . ', ' . $contact->get('first');
4156 }
4157
4158 =item contact_firstlast
4159
4160 Returns this customers full (billing) contact name only, "First Last".
4161
4162 =cut
4163
4164 sub contact_firstlast {
4165   my $self = shift;
4166   $self->first. ' '. $self->get('last');
4167 }
4168
4169 =item ship_contact_firstlast
4170
4171 Returns this customer's full (shipping) contact name only, "First Last".
4172
4173 =cut
4174
4175 sub ship_contact_firstlast {
4176   my $self = shift;
4177   my $contact = $self->service_contact || $self;
4178   $contact->get('first') . ' '. $contact->get('last');
4179 }
4180
4181 sub bill_country_full {
4182   my $self = shift;
4183   $self->bill_location->country_full;
4184 }
4185
4186 sub ship_country_full {
4187   my $self = shift;
4188   $self->ship_location->country_full;
4189 }
4190
4191 =item county_state_county [ PREFIX ]
4192
4193 Returns a string consisting of just the county, state and country.
4194
4195 =cut
4196
4197 sub county_state_country {
4198   my $self = shift;
4199   my $locationnum;
4200   if ( @_ && $_[0] && $self->has_ship_address ) {
4201     $locationnum = $self->ship_locationnum;
4202   } else {
4203     $locationnum = $self->bill_locationnum;
4204   }
4205   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4206   $cust_location->county_state_country;
4207 }
4208
4209 =item geocode DATA_VENDOR
4210
4211 Returns a value for the customer location as encoded by DATA_VENDOR.
4212 Currently this only makes sense for "CCH" as DATA_VENDOR.
4213
4214 =cut
4215
4216 =item cust_status
4217
4218 =item status
4219
4220 Returns a status string for this customer, currently:
4221
4222 =over 4
4223
4224 =item prospect
4225
4226 No packages have ever been ordered.  Displayed as "No packages".
4227
4228 =item ordered
4229
4230 Recurring packages all are new (not yet billed).
4231
4232 =item active
4233
4234 One or more recurring packages is active.
4235
4236 =item inactive
4237
4238 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
4239
4240 =item suspended
4241
4242 All non-cancelled recurring packages are suspended.
4243
4244 =item cancelled
4245
4246 All recurring packages are cancelled.
4247
4248 =back
4249
4250 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4251 cust_main-status_module configuration option.
4252
4253 =cut
4254
4255 sub status { shift->cust_status(@_); }
4256
4257 sub cust_status {
4258   my $self = shift;
4259   return $self->hashref->{cust_status} if $self->hashref->{cust_status};
4260   for my $status ( FS::cust_main->statuses() ) {
4261     my $method = $status.'_sql';
4262     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4263     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4264     $sth->execute( ($self->custnum) x $numnum )
4265       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4266     if ( $sth->fetchrow_arrayref->[0] ) {
4267       $self->hashref->{cust_status} = $status;
4268       return $status;
4269     }
4270   }
4271 }
4272
4273 =item is_status_delay_cancel
4274
4275 Returns true if customer status is 'suspended'
4276 and all suspended cust_pkg return true for
4277 cust_pkg->is_status_delay_cancel.
4278
4279 This is not a real status, this only meant for hacking display
4280 values, because otherwise treating the customer as suspended is
4281 really the whole point of the delay_cancel option.
4282
4283 =cut
4284
4285 sub is_status_delay_cancel {
4286   my ($self) = @_;
4287   return 0 unless $self->status eq 'suspended';
4288   foreach my $cust_pkg ($self->ncancelled_pkgs) {
4289     return 0 unless $cust_pkg->is_status_delay_cancel;
4290   }
4291   return 1;
4292 }
4293
4294 =item ucfirst_cust_status
4295
4296 =item ucfirst_status
4297
4298 Deprecated, use the cust_status_label method instead.
4299
4300 Returns the status with the first character capitalized.
4301
4302 =cut
4303
4304 sub ucfirst_status {
4305   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4306   local($ucfirst_nowarn) = 1;
4307   shift->ucfirst_cust_status(@_);
4308 }
4309
4310 sub ucfirst_cust_status {
4311   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4312   my $self = shift;
4313   ucfirst($self->cust_status);
4314 }
4315
4316 =item cust_status_label
4317
4318 =item status_label
4319
4320 Returns the display label for this status.
4321
4322 =cut
4323
4324 sub status_label { shift->cust_status_label(@_); }
4325
4326 sub cust_status_label {
4327   my $self = shift;
4328   __PACKAGE__->statuslabels->{$self->cust_status};
4329 }
4330
4331 =item statuscolor
4332
4333 Returns a hex triplet color string for this customer's status.
4334
4335 =cut
4336
4337 sub statuscolor { shift->cust_statuscolor(@_); }
4338
4339 sub cust_statuscolor {
4340   my $self = shift;
4341   __PACKAGE__->statuscolors->{$self->cust_status};
4342 }
4343
4344 =item tickets [ STATUS ]
4345
4346 Returns an array of hashes representing the customer's RT tickets.
4347
4348 An optional status (or arrayref or hashref of statuses) may be specified.
4349
4350 =cut
4351
4352 sub tickets {
4353   my $self = shift;
4354   my $status = ( @_ && $_[0] ) ? shift : '';
4355
4356   my $num = $conf->config('cust_main-max_tickets') || 10;
4357   my @tickets = ();
4358
4359   if ( $conf->config('ticket_system') ) {
4360     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4361
4362       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4363                                                         $num,
4364                                                         undef,
4365                                                         $status,
4366                                                       )
4367                   };
4368
4369     } else {
4370
4371       foreach my $priority (
4372         $conf->config('ticket_system-custom_priority_field-values'), ''
4373       ) {
4374         last if scalar(@tickets) >= $num;
4375         push @tickets,
4376           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4377                                                  $num - scalar(@tickets),
4378                                                  $priority,
4379                                                  $status,
4380                                                )
4381            };
4382       }
4383     }
4384   }
4385   (@tickets);
4386 }
4387
4388 =item appointments [ STATUS ]
4389
4390 Returns an array of hashes representing the customer's RT tickets which
4391 are appointments.
4392
4393 =cut
4394
4395 sub appointments {
4396   my $self = shift;
4397   my $status = ( @_ && $_[0] ) ? shift : '';
4398
4399   return () unless $conf->config('ticket_system');
4400
4401   my $queueid = $conf->config('ticket_system-appointment-queueid');
4402
4403   @{ FS::TicketSystem->customer_tickets( $self->custnum,
4404                                          99,
4405                                          undef,
4406                                          $status,
4407                                          $queueid,
4408                                        )
4409   };
4410 }
4411
4412 # Return services representing svc_accts in customer support packages
4413 sub support_services {
4414   my $self = shift;
4415   my %packages = map { $_ => 1 } $conf->config('support_packages');
4416
4417   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4418     grep { $_->part_svc->svcdb eq 'svc_acct' }
4419     map { $_->cust_svc }
4420     grep { exists $packages{ $_->pkgpart } }
4421     $self->ncancelled_pkgs;
4422
4423 }
4424
4425 # Return a list of latitude/longitude for one of the services (if any)
4426 sub service_coordinates {
4427   my $self = shift;
4428
4429   my @svc_X =
4430     grep { $_->latitude && $_->longitude }
4431     map { $_->svc_x }
4432     map { $_->cust_svc }
4433     $self->ncancelled_pkgs;
4434
4435   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4436 }
4437
4438 =item masked FIELD
4439
4440 Returns a masked version of the named field
4441
4442 =cut
4443
4444 sub masked {
4445 my ($self,$field) = @_;
4446
4447 # Show last four
4448
4449 'x'x(length($self->getfield($field))-4).
4450   substr($self->getfield($field), (length($self->getfield($field))-4));
4451
4452 }
4453
4454 =item payment_history
4455
4456 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4457 cust_credit and cust_refund objects.  Each hashref has the following fields:
4458
4459 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4460
4461 I<date> - value of _date field, unix timestamp
4462
4463 I<date_pretty> - user-friendly date
4464
4465 I<description> - user-friendly description of item
4466
4467 I<amount> - impact of item on user's balance
4468 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4469 Not to be confused with the native 'amount' field in cust_credit, see below.
4470
4471 I<amount_pretty> - includes money char
4472
4473 I<balance> - customer balance, chronologically as of this item
4474
4475 I<balance_pretty> - includes money char
4476
4477 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4478
4479 I<paid> - amount paid for cust_pay records, undef for other types
4480
4481 I<credit> - amount credited for cust_credit records, undef for other types.
4482 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4483
4484 I<refund> - amount refunded for cust_refund records, undef for other types
4485
4486 The four table-specific keys always have positive values, whether they reflect charges or payments.
4487
4488 The following options may be passed to this method:
4489
4490 I<line_items> - if true, returns charges ('Line item') rather than invoices
4491
4492 I<start_date> - unix timestamp, only include records on or after.
4493 If specified, an item of type 'Previous' will also be included.
4494 It does not have table-specific fields.
4495
4496 I<end_date> - unix timestamp, only include records before
4497
4498 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4499
4500 I<conf> - optional already-loaded FS::Conf object.
4501
4502 =cut
4503
4504 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4505 # and also for sending customer statements, which should both be kept customer-friendly.
4506 # If you add anything that shouldn't be passed on through the API or exposed
4507 # to customers, add a new option to include it, don't include it by default
4508 sub payment_history {
4509   my $self = shift;
4510   my $opt = ref($_[0]) ? $_[0] : { @_ };
4511
4512   my $conf = $$opt{'conf'} || new FS::Conf;
4513   my $money_char = $conf->config("money_char") || '$',
4514
4515   #first load entire history,
4516   #need previous to calculate previous balance
4517   #loading after end_date shouldn't hurt too much?
4518   my @history = ();
4519   if ( $$opt{'line_items'} ) {
4520
4521     foreach my $cust_bill ( $self->cust_bill ) {
4522
4523       push @history, {
4524         'type'        => 'Line item',
4525         'description' => $_->desc( $self->locale ).
4526                            ( $_->sdate && $_->edate
4527                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4528                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4529                                : ''
4530                            ),
4531         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4532         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4533         'date'        => $cust_bill->_date,
4534         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4535       }
4536         foreach $cust_bill->cust_bill_pkg;
4537
4538     }
4539
4540   } else {
4541
4542     push @history, {
4543                      'type'        => 'Invoice',
4544                      'description' => 'Invoice #'. $_->display_invnum,
4545                      'amount'      => sprintf('%.2f', $_->charged ),
4546                      'charged'     => sprintf('%.2f', $_->charged ),
4547                      'date'        => $_->_date,
4548                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4549                    }
4550       foreach $self->cust_bill;
4551
4552   }
4553
4554   push @history, {
4555                    'type'        => 'Payment',
4556                    'description' => 'Payment', #XXX type
4557                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4558                    'paid'        => sprintf('%.2f', $_->paid ),
4559                    'date'        => $_->_date,
4560                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4561                  }
4562     foreach $self->cust_pay;
4563
4564   push @history, {
4565                    'type'        => 'Credit',
4566                    'description' => 'Credit', #more info?
4567                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4568                    'credit'      => sprintf('%.2f', $_->amount ),
4569                    'date'        => $_->_date,
4570                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4571                  }
4572     foreach $self->cust_credit;
4573
4574   push @history, {
4575                    'type'        => 'Refund',
4576                    'description' => 'Refund', #more info?  type, like payment?
4577                    'amount'      => $_->refund,
4578                    'refund'      => $_->refund,
4579                    'date'        => $_->_date,
4580                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4581                  }
4582     foreach $self->cust_refund;
4583
4584   #put it all in chronological order
4585   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4586
4587   #calculate balance, filter items outside date range
4588   my $previous = 0;
4589   my $balance = 0;
4590   my @out = ();
4591   foreach my $item (@history) {
4592     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4593     $balance += $$item{'amount'};
4594     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4595       $previous += $$item{'amount'};
4596       next;
4597     }
4598     $$item{'balance'} = sprintf("%.2f",$balance);
4599     foreach my $key ( qw(amount balance) ) {
4600       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4601     }
4602     push(@out,$item);
4603   }
4604
4605   # start with previous balance, if there was one
4606   if ($previous) {
4607     my $item = {
4608       'type'        => 'Previous',
4609       'description' => 'Previous balance',
4610       'amount'      => sprintf("%.2f",$previous),
4611       'balance'     => sprintf("%.2f",$previous),
4612       'date'        => $$opt{'start_date'},
4613       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4614     };
4615     #false laziness with above
4616     foreach my $key ( qw(amount balance) ) {
4617       $$item{$key.'_pretty'} = $$item{$key};
4618       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4619     }
4620     unshift(@out,$item);
4621   }
4622
4623   @out = reverse @history if $$opt{'reverse_sort'};
4624
4625   return @out;
4626 }
4627
4628 =item save_cust_payby
4629
4630 Saves a new cust_payby for this customer, replacing an existing entry only
4631 in select circumstances.  Does not validate input.
4632
4633 If auto is specified, marks this as the customer's primary method, or the
4634 specified weight.  Existing payment methods have their weight incremented as
4635 appropriate.
4636
4637 If bill_location is specified with auto, also sets location in cust_main.
4638
4639 Will not insert complete duplicates of existing records, or records in which the
4640 only difference from an existing record is to turn off automatic payment (will
4641 return without error.)  Will replace existing records in which the only difference
4642 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4643 Fields marked as preserved are optional, and existing values will not be overwritten with
4644 blanks when replacing.
4645
4646 Accepts the following named parameters:
4647
4648 =over 4
4649
4650 =item payment_payby
4651
4652 either CARD or CHEK
4653
4654 =item auto
4655
4656 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4657
4658 =item weight
4659
4660 optional, set higher than 1 for secondary, etc.
4661
4662 =item payinfo
4663
4664 required
4665
4666 =item paymask
4667
4668 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4669
4670 =item payname
4671
4672 required
4673
4674 =item payip
4675
4676 optional, will be preserved when replacing
4677
4678 =item paydate
4679
4680 CARD only, required
4681
4682 =item bill_location
4683
4684 CARD only, required, FS::cust_location object
4685
4686 =item paystart_month
4687
4688 CARD only, optional, will be preserved when replacing
4689
4690 =item paystart_year
4691
4692 CARD only, optional, will be preserved when replacing
4693
4694 =item payissue
4695
4696 CARD only, optional, will be preserved when replacing
4697
4698 =item paycvv
4699
4700 CARD only, only used if conf cvv-save is set appropriately
4701
4702 =item paytype
4703
4704 CHEK only
4705
4706 =item paystate
4707
4708 CHEK only
4709
4710 =item saved_cust_payby
4711
4712 scalar reference, for returning saved object
4713
4714 =back
4715
4716 =cut
4717
4718 #The code for this option is in place, but it's not currently used
4719 #
4720 # =item replace
4721 #
4722 # existing cust_payby object to be replaced (must match custnum)
4723
4724 # stateid/stateid_state/ss are not currently supported in cust_payby,
4725 # might not even work properly in 4.x, but will need to work here if ever added
4726
4727 sub save_cust_payby {
4728   my $self = shift;
4729   my %opt = @_;
4730
4731   my $old = $opt{'replace'};
4732   my $new = new FS::cust_payby { $old ? $old->hash : () };
4733   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4734   $new->set( 'custnum' => $self->custnum );
4735
4736   my $payby = $opt{'payment_payby'};
4737   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4738
4739   # don't allow turning off auto when replacing
4740   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4741
4742   my @check_existing; # payby relevant to this payment_payby
4743
4744   # set payby based on auto
4745   if ( $payby eq 'CARD' ) {
4746     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4747     @check_existing = qw( CARD DCRD );
4748   } elsif ( $payby eq 'CHEK' ) {
4749     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4750     @check_existing = qw( CHEK DCHK );
4751   }
4752
4753   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4754
4755   # basic fields
4756   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4757   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4758   $new->set( 'payname' => $opt{'payname'} );
4759   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4760
4761   my $conf = new FS::Conf;
4762
4763   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4764   if ( $payby eq 'CARD' &&
4765        ( (grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save'))
4766          || $conf->exists('business-onlinepayment-verification')
4767        )
4768   ) {
4769     $new->set( 'paycvv' => $opt{'paycvv'} );
4770   } else {
4771     $new->set( 'paycvv' => '');
4772   }
4773
4774   local $SIG{HUP} = 'IGNORE';
4775   local $SIG{INT} = 'IGNORE';
4776   local $SIG{QUIT} = 'IGNORE';
4777   local $SIG{TERM} = 'IGNORE';
4778   local $SIG{TSTP} = 'IGNORE';
4779   local $SIG{PIPE} = 'IGNORE';
4780
4781   my $oldAutoCommit = $FS::UID::AutoCommit;
4782   local $FS::UID::AutoCommit = 0;
4783   my $dbh = dbh;
4784
4785   # set fields specific to payment_payby
4786   if ( $payby eq 'CARD' ) {
4787     if ($opt{'bill_location'}) {
4788       $opt{'bill_location'}->set('custnum' => $self->custnum);
4789       my $error = $opt{'bill_location'}->find_or_insert;
4790       if ( $error ) {
4791         $dbh->rollback if $oldAutoCommit;
4792         return $error;
4793       }
4794       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4795     }
4796     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4797       $new->set( $field => $opt{$field} );
4798     }
4799   } else {
4800     foreach my $field ( qw(paytype paystate) ) {
4801       $new->set( $field => $opt{$field} );
4802     }
4803   }
4804
4805   # other cust_payby to compare this to
4806   my @existing = $self->cust_payby(@check_existing);
4807
4808   # fields that can overwrite blanks with values, but not values with blanks
4809   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4810
4811   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4812   unless ($old) {
4813     # generally, we don't want to overwrite existing cust_payby with this,
4814     # but we can replace if we're only marking it auto or adding a preserved field
4815     # and we can avoid saving a total duplicate or merely turning off auto
4816 PAYBYLOOP:
4817     foreach my $cust_payby (@existing) {
4818       # check fields that absolutely should not change
4819       foreach my $field ($new->fields) {
4820         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4821         next if grep(/^$field$/, @preserve );
4822         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4823         # check if paymask exists,  if so stop and don't save, no need for a duplicate.
4824         return '' if $new->get('paymask') eq $cust_payby->get('paymask');
4825       }
4826       # now check fields that can replace if one value is blank
4827       my $replace = 0;
4828       foreach my $field (@preserve) {
4829         if (
4830           ( $new->get($field) and !$cust_payby->get($field) ) or
4831           ( $cust_payby->get($field) and !$new->get($field) )
4832         ) {
4833           # prevention of overwriting values with blanks happens farther below
4834           $replace = 1;
4835         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4836           next PAYBYLOOP;
4837         }
4838       }
4839       unless ( $replace ) {
4840         # nearly identical, now check weight
4841         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4842           # ignore identical cust_payby, and ignore attempts to turn off auto
4843           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4844           $skip_cust_payby = 1;
4845           last PAYBYLOOP;
4846         }
4847         # otherwise, only change is to mark this as primary
4848       }
4849       # if we got this far, we're definitely replacing
4850       $old = $cust_payby;
4851       last PAYBYLOOP;
4852     } #PAYBYLOOP
4853   }
4854
4855   if ($old) {
4856     $new->set( 'custpaybynum' => $old->custpaybynum );
4857     # don't turn off automatic payment (but allow it to be turned on)
4858     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4859       $opt{'auto'} = 1;
4860       $new->set( 'payby' => $old->payby );
4861       $new->set( 'weight' => 1 );
4862     }
4863     # make sure we're not overwriting values with blanks
4864     foreach my $field (@preserve) {
4865       if ( $old->get($field) and !$new->get($field) ) {
4866         $new->set( $field => $old->get($field) );
4867       }
4868     }
4869   }
4870
4871   # only overwrite cust_main bill_location if auto
4872   if ($opt{'auto'} && $opt{'bill_location'}) {
4873     $self->set('bill_location' => $opt{'bill_location'});
4874     my $error = $self->replace;
4875     if ( $error ) {
4876       $dbh->rollback if $oldAutoCommit;
4877       return $error;
4878     }
4879   }
4880
4881   # done with everything except reweighting and saving cust_payby
4882   # still need to commit changes to cust_main and cust_location
4883   if ($skip_cust_payby) {
4884     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4885     return '';
4886   }
4887
4888   # re-weight existing primary cust_pay for this payby
4889   if ($opt{'auto'}) {
4890     foreach my $cust_payby (@existing) {
4891       # relies on cust_payby return order
4892       last unless $cust_payby->payby !~ /^D/;
4893       last if $cust_payby->weight > 1;
4894       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4895       next if $cust_payby->weight < ($opt{'weight'} || 1);
4896       $cust_payby->weight( $cust_payby->weight + 1 );
4897       my $error = $cust_payby->replace;
4898       if ( $error ) {
4899         $dbh->rollback if $oldAutoCommit;
4900         return "Error reweighting cust_payby: $error";
4901       }
4902     }
4903   }
4904
4905   # finally, save cust_payby
4906   my $error = $old ? $new->replace($old) : $new->insert;
4907   if ( $error ) {
4908     $dbh->rollback if $oldAutoCommit;
4909     return $error;
4910   }
4911
4912   ${$opt{'saved_cust_payby'}} = $new
4913     if $opt{'saved_cust_payby'};
4914
4915   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4916   '';
4917
4918 }
4919
4920 =item remove_cvv_from_cust_payby PAYINFO
4921
4922 Removes paycvv from associated cust_payby with matching PAYINFO.
4923
4924 =cut
4925
4926 sub remove_cvv_from_cust_payby {
4927   my ($self,$payinfo) = @_;
4928
4929   my $oldAutoCommit = $FS::UID::AutoCommit;
4930   local $FS::UID::AutoCommit = 0;
4931   my $dbh = dbh;
4932
4933   foreach my $cust_payby ( qsearch('cust_payby',{ custnum => $self->custnum }) ) {
4934     next unless $cust_payby->payinfo eq $payinfo; # can't qsearch on payinfo
4935     $cust_payby->paycvv('');
4936     my $error = $cust_payby->replace;
4937     if ($error) {
4938       $dbh->rollback if $oldAutoCommit;
4939       return $error;
4940     }
4941   }
4942
4943   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4944   '';
4945 }
4946
4947 =back
4948
4949 =head1 CLASS METHODS
4950
4951 =over 4
4952
4953 =item statuses
4954
4955 Class method that returns the list of possible status strings for customers
4956 (see L<the status method|/status>).  For example:
4957
4958   @statuses = FS::cust_main->statuses();
4959
4960 =cut
4961
4962 sub statuses {
4963   my $self = shift;
4964   keys %{ $self->statuscolors };
4965 }
4966
4967 =item cust_status_sql
4968
4969 Returns an SQL fragment to determine the status of a cust_main record, as a
4970 string.
4971
4972 =cut
4973
4974 sub cust_status_sql {
4975   my $sql = 'CASE';
4976   for my $status ( FS::cust_main->statuses() ) {
4977     my $method = $status.'_sql';
4978     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4979   }
4980   $sql .= ' END';
4981   return $sql;
4982 }
4983
4984
4985 =item prospect_sql
4986
4987 Returns an SQL expression identifying prospective cust_main records (customers
4988 with no packages ever ordered)
4989
4990 =cut
4991
4992 use vars qw($select_count_pkgs);
4993 $select_count_pkgs =
4994   "SELECT COUNT(*) FROM cust_pkg
4995     WHERE cust_pkg.custnum = cust_main.custnum";
4996
4997 sub select_count_pkgs_sql {
4998   $select_count_pkgs;
4999 }
5000
5001 sub prospect_sql {
5002   " 0 = ( $select_count_pkgs ) ";
5003 }
5004
5005 =item ordered_sql
5006
5007 Returns an SQL expression identifying ordered cust_main records (customers with
5008 no active packages, but recurring packages not yet setup or one time charges
5009 not yet billed).
5010
5011 =cut
5012
5013 sub ordered_sql {
5014   FS::cust_main->none_active_sql.
5015   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
5016 }
5017
5018 =item active_sql
5019
5020 Returns an SQL expression identifying active cust_main records (customers with
5021 active recurring packages).
5022
5023 =cut
5024
5025 sub active_sql {
5026   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
5027 }
5028
5029 =item none_active_sql
5030
5031 Returns an SQL expression identifying cust_main records with no active
5032 recurring packages.  This includes customers of status prospect, ordered,
5033 inactive, and suspended.
5034
5035 =cut
5036
5037 sub none_active_sql {
5038   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
5039 }
5040
5041 =item inactive_sql
5042
5043 Returns an SQL expression identifying inactive cust_main records (customers with
5044 no active recurring packages, but otherwise unsuspended/uncancelled).
5045
5046 =cut
5047
5048 sub inactive_sql {
5049   FS::cust_main->none_active_sql.
5050   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
5051 }
5052
5053 =item susp_sql
5054 =item suspended_sql
5055
5056 Returns an SQL expression identifying suspended cust_main records.
5057
5058 =cut
5059
5060
5061 sub suspended_sql { susp_sql(@_); }
5062 sub susp_sql {
5063   FS::cust_main->none_active_sql.
5064   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
5065 }
5066
5067 =item cancel_sql
5068 =item cancelled_sql
5069
5070 Returns an SQL expression identifying cancelled cust_main records.
5071
5072 =cut
5073
5074 sub cancel_sql { shift->cancelled_sql(@_); }
5075
5076 =item uncancel_sql
5077 =item uncancelled_sql
5078
5079 Returns an SQL expression identifying un-cancelled cust_main records.
5080
5081 =cut
5082
5083 sub uncancelled_sql { uncancel_sql(@_); }
5084 sub uncancel_sql {
5085   my $self = shift;
5086   "( NOT (".$self->cancelled_sql.") )"; #sensitive to cust_main-status_module
5087 }
5088
5089 =item balance_sql
5090
5091 Returns an SQL fragment to retreive the balance.
5092
5093 =cut
5094
5095 sub balance_sql { "
5096     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
5097         WHERE cust_bill.custnum   = cust_main.custnum     )
5098   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
5099         WHERE cust_pay.custnum    = cust_main.custnum     )
5100   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
5101         WHERE cust_credit.custnum = cust_main.custnum     )
5102   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
5103         WHERE cust_refund.custnum = cust_main.custnum     )
5104 "; }
5105
5106 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
5107
5108 Returns an SQL fragment to retreive the balance for this customer, optionally
5109 considering invoices with date earlier than START_TIME, and not
5110 later than END_TIME (total_owed_date minus total_unapplied_credits minus
5111 total_unapplied_payments).
5112
5113 Times are specified as SQL fragments or numeric
5114 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5115 L<Date::Parse> for conversion functions.  The empty string can be passed
5116 to disable that time constraint completely.
5117
5118 Available options are:
5119
5120 =over 4
5121
5122 =item unapplied_date
5123
5124 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
5125
5126 =item total
5127
5128 (unused.  obsolete?)
5129 set to true to remove all customer comparison clauses, for totals
5130
5131 =item where
5132
5133 (unused.  obsolete?)
5134 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
5135
5136 =item join
5137
5138 (unused.  obsolete?)
5139 JOIN clause (typically used with the total option)
5140
5141 =item cutoff
5142
5143 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
5144 time will be ignored.  Note that START_TIME and END_TIME only limit the date
5145 range for invoices and I<unapplied> payments, credits, and refunds.
5146
5147 =back
5148
5149 =cut
5150
5151 sub balance_date_sql {
5152   my( $class, $start, $end, %opt ) = @_;
5153
5154   my $cutoff = $opt{'cutoff'};
5155
5156   my $owed         = FS::cust_bill->owed_sql($cutoff);
5157   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
5158   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
5159   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5160
5161   my $j = $opt{'join'} || '';
5162
5163   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
5164   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
5165   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
5166   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
5167
5168   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
5169     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
5170     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
5171     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
5172   ";
5173
5174 }
5175
5176 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
5177
5178 Returns an SQL fragment to retreive the total unapplied payments for this
5179 customer, only considering payments with date earlier than START_TIME, and
5180 optionally not later than END_TIME.
5181
5182 Times are specified as SQL fragments or numeric
5183 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5184 L<Date::Parse> for conversion functions.  The empty string can be passed
5185 to disable that time constraint completely.
5186
5187 Available options are:
5188
5189 =cut
5190
5191 sub unapplied_payments_date_sql {
5192   my( $class, $start, $end, %opt ) = @_;
5193
5194   my $cutoff = $opt{'cutoff'};
5195
5196   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5197
5198   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
5199                                                           'unapplied_date'=>1 );
5200
5201   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
5202 }
5203
5204 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
5205
5206 Helper method for balance_date_sql; name (and usage) subject to change
5207 (suggestions welcome).
5208
5209 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
5210 cust_refund, cust_credit or cust_pay).
5211
5212 If TABLE is "cust_bill" or the unapplied_date option is true, only
5213 considers records with date earlier than START_TIME, and optionally not
5214 later than END_TIME .
5215
5216 =cut
5217
5218 sub _money_table_where {
5219   my( $class, $table, $start, $end, %opt ) = @_;
5220
5221   my @where = ();
5222   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
5223   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
5224     push @where, "$table._date <= $start" if defined($start) && length($start);
5225     push @where, "$table._date >  $end"   if defined($end)   && length($end);
5226   }
5227   push @where, @{$opt{'where'}} if $opt{'where'};
5228   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
5229
5230   $where;
5231
5232 }
5233
5234 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
5235 use FS::cust_main::Search;
5236 sub search {
5237   my $class = shift;
5238   FS::cust_main::Search->search(@_);
5239 }
5240
5241 =back
5242
5243 =head1 SUBROUTINES
5244
5245 =over 4
5246
5247 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5248
5249 Generates a templated notification to the customer (see L<Text::Template>).
5250
5251 OPTIONS is a hash and may include
5252
5253 I<extra_fields> - a hashref of name/value pairs which will be substituted
5254    into the template.  These values may override values mentioned below
5255    and those from the customer record.
5256
5257 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
5258
5259 The following variables are available in the template instead of or in addition
5260 to the fields of the customer record.
5261
5262 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
5263
5264 =cut
5265
5266 # a lot like cust_bill::print_latex
5267 sub generate_letter {
5268   my ($self, $template, %options) = @_;
5269
5270   warn "Template $template does not exist" && return
5271     unless $conf->exists($template) || $options{'template_text'};
5272
5273   my $template_source = $options{'template_text'}
5274                         ? [ $options{'template_text'} ]
5275                         : [ map "$_\n", $conf->config($template) ];
5276
5277   my $letter_template = new Text::Template
5278                         ( TYPE       => 'ARRAY',
5279                           SOURCE     => $template_source,
5280                           DELIMITERS => [ '[@--', '--@]' ],
5281                         )
5282     or die "can't create new Text::Template object: Text::Template::ERROR";
5283
5284   $letter_template->compile()
5285     or die "can't compile template: Text::Template::ERROR";
5286
5287   my %letter_data = map { $_ => $self->$_ } $self->fields;
5288
5289   for (keys %{$options{extra_fields}}){
5290     $letter_data{$_} = $options{extra_fields}->{$_};
5291   }
5292
5293   unless(exists($letter_data{returnaddress})){
5294     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
5295                                                   $self->agent_template)
5296                      );
5297     if ( length($retadd) ) {
5298       $letter_data{returnaddress} = $retadd;
5299     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
5300       $letter_data{returnaddress} =
5301         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
5302                           s/$/\\\\\*/;
5303                           $_;
5304                         }
5305                     ( $conf->config('company_name', $self->agentnum),
5306                       $conf->config('company_address', $self->agentnum),
5307                     )
5308         );
5309     } else {
5310       $letter_data{returnaddress} = '~';
5311     }
5312   }
5313
5314   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
5315
5316   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
5317
5318   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
5319
5320   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5321                            DIR      => $dir,
5322                            SUFFIX   => '.eps',
5323                            UNLINK   => 0,
5324                          ) or die "can't open temp file: $!\n";
5325   print $lh $conf->config_binary('logo.eps', $self->agentnum)
5326     or die "can't write temp file: $!\n";
5327   close $lh;
5328   $letter_data{'logo_file'} = $lh->filename;
5329
5330   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5331                            DIR      => $dir,
5332                            SUFFIX   => '.tex',
5333                            UNLINK   => 0,
5334                          ) or die "can't open temp file: $!\n";
5335
5336   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
5337   close $fh;
5338   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
5339   return ($1, $letter_data{'logo_file'});
5340
5341 }
5342
5343 =item print_ps TEMPLATE
5344
5345 Returns an postscript letter filled in from TEMPLATE, as a scalar.
5346
5347 =cut
5348
5349 sub print_ps {
5350   my $self = shift;
5351   my($file, $lfile) = $self->generate_letter(@_);
5352   my $ps = FS::Misc::generate_ps($file);
5353   unlink($file.'.tex');
5354   unlink($lfile);
5355
5356   $ps;
5357 }
5358
5359 =item print TEMPLATE
5360
5361 Prints the filled in template.
5362
5363 TEMPLATE is the name of a L<Text::Template> to fill in and print.
5364
5365 =cut
5366
5367 sub queueable_print {
5368   my %opt = @_;
5369
5370   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
5371     or die "invalid customer number: " . $opt{custnum};
5372
5373 #do not backport this change to 3.x
5374 #  my $error = $self->print( { 'template' => $opt{template} } );
5375   my $error = $self->print( $opt{'template'} );
5376   die $error if $error;
5377 }
5378
5379 sub print {
5380   my ($self, $template) = (shift, shift);
5381   do_print(
5382     [ $self->print_ps($template) ],
5383     'agentnum' => $self->agentnum,
5384   );
5385 }
5386
5387 #these three subs should just go away once agent stuff is all config overrides
5388
5389 sub agent_template {
5390   my $self = shift;
5391   $self->_agent_plandata('agent_templatename');
5392 }
5393
5394 sub agent_invoice_from {
5395   my $self = shift;
5396   $self->_agent_plandata('agent_invoice_from');
5397 }
5398
5399 sub _agent_plandata {
5400   my( $self, $option ) = @_;
5401
5402   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
5403   #agent-specific Conf
5404
5405   use FS::part_event::Condition;
5406
5407   my $agentnum = $self->agentnum;
5408
5409   my $regexp = regexp_sql();
5410
5411   my $part_event_option =
5412     qsearchs({
5413       'select'    => 'part_event_option.*',
5414       'table'     => 'part_event_option',
5415       'addl_from' => q{
5416         LEFT JOIN part_event USING ( eventpart )
5417         LEFT JOIN part_event_option AS peo_agentnum
5418           ON ( part_event.eventpart = peo_agentnum.eventpart
5419                AND peo_agentnum.optionname = 'agentnum'
5420                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
5421              )
5422         LEFT JOIN part_event_condition
5423           ON ( part_event.eventpart = part_event_condition.eventpart
5424                AND part_event_condition.conditionname = 'cust_bill_age'
5425              )
5426         LEFT JOIN part_event_condition_option
5427           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
5428                AND part_event_condition_option.optionname = 'age'
5429              )
5430       },
5431       #'hashref'   => { 'optionname' => $option },
5432       #'hashref'   => { 'part_event_option.optionname' => $option },
5433       'extra_sql' =>
5434         " WHERE part_event_option.optionname = ". dbh->quote($option).
5435         " AND action = 'cust_bill_send_agent' ".
5436         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
5437         " AND peo_agentnum.optionname = 'agentnum' ".
5438         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
5439         " ORDER BY
5440            CASE WHEN part_event_condition_option.optionname IS NULL
5441            THEN -1
5442            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5443         " END
5444           , part_event.weight".
5445         " LIMIT 1"
5446     });
5447
5448   unless ( $part_event_option ) {
5449     return $self->agent->invoice_template || ''
5450       if $option eq 'agent_templatename';
5451     return '';
5452   }
5453
5454   $part_event_option->optionvalue;
5455
5456 }
5457
5458 sub process_o2m_qsearch {
5459   my $self = shift;
5460   my $table = shift;
5461   return qsearch($table, @_) unless $table eq 'contact';
5462
5463   my $hashref = shift;
5464   my %hash = %$hashref;
5465   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5466     or die 'guru meditation #4343';
5467
5468   qsearch({ 'table'     => 'contact',
5469             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5470             'hashref'   => \%hash,
5471             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5472                            " cust_contact.custnum = $custnum "
5473          });
5474 }
5475
5476 sub process_o2m_qsearchs {
5477   my $self = shift;
5478   my $table = shift;
5479   return qsearchs($table, @_) unless $table eq 'contact';
5480
5481   my $hashref = shift;
5482   my %hash = %$hashref;
5483   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5484     or die 'guru meditation #2121';
5485
5486   qsearchs({ 'table'     => 'contact',
5487              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5488              'hashref'   => \%hash,
5489              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5490                             " cust_contact.custnum = $custnum "
5491           });
5492 }
5493
5494 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5495
5496 Subroutine (not a method), designed to be called from the queue.
5497
5498 Takes a list of options and values.
5499
5500 Pulls up the customer record via the custnum option and calls bill_and_collect.
5501
5502 =cut
5503
5504 sub queued_bill {
5505   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5506
5507   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5508   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5509
5510   #without this errors don't get rolled back
5511   $args{'fatal'} = 1; # runs from job queue, will be caught
5512
5513   $cust_main->bill_and_collect( %args );
5514 }
5515
5516 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5517
5518 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5519 C<collect> part.  This is used in batch tax calculation, where invoice
5520 generation and collection events have to be completely separated.
5521
5522 =cut
5523
5524 sub queued_collect {
5525   my (%args) = @_;
5526   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5527
5528   $cust_main->collect(%args);
5529 }
5530
5531 sub process_bill_and_collect {
5532   my $job = shift;
5533   my $param = shift;
5534   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5535       or die "custnum '$param->{custnum}' not found!\n";
5536   $param->{'job'}   = $job;
5537   $param->{'fatal'} = 1; # runs from job queue, will be caught
5538   $param->{'retry'} = 1;
5539
5540   local $@;
5541   eval { $cust_main->bill_and_collect( %$param) };
5542   if ( $@ ) {
5543     die $@ =~ /cancel_pkgs cannot be run inside a transaction/
5544       ? "Bill Now unavailable for customer with pending package expiration\n"
5545       : $@;
5546   }
5547 }
5548
5549 =item pending_invoice_count
5550
5551 Return number of cust_bill with pending=Y for this customer
5552
5553 =cut
5554
5555 sub pending_invoice_count {
5556   FS::cust_bill->count( 'custnum = '.shift->custnum."AND pending = 'Y'" );
5557 }
5558
5559 =item cust_locations_missing_district
5560
5561 Always returns empty list, unless tax_district_method eq 'wa_sales'
5562
5563 Return cust_location rows for this customer, associated with active
5564 customer packages, where tax district column is empty.  Presense of
5565 these rows should block billing, because invoice would be generated
5566 with incorrect taxes
5567
5568 =cut
5569
5570 sub cust_locations_missing_district {
5571   my ( $self ) = @_;
5572
5573   my $tax_district_method = FS::Conf->new->config('tax_district_method');
5574
5575   return ()
5576     unless $tax_district_method
5577         && $tax_district_method eq 'wa_sales';
5578
5579   qsearch({
5580     table => 'cust_location',
5581     select => 'cust_location.*',
5582     addl_from => '
5583       LEFT JOIN cust_main USING (custnum)
5584       LEFT JOIN cust_pkg ON cust_location.locationnum = cust_pkg.locationnum
5585     ',
5586     extra_sql => sprintf(q{
5587         WHERE cust_location.state = 'WA'
5588         AND   cust_location.custnum = %s
5589         AND (
5590              cust_location.district IS NULL
5591           or cust_location.district = ''
5592         )
5593         AND cust_pkg.pkgnum IS NOT NULL
5594         AND (
5595              cust_pkg.cancel > %s
5596           OR cust_pkg.cancel IS NULL
5597         )
5598       },
5599       $self->custnum, time()
5600     ),
5601   });
5602 }
5603
5604 #starting to take quite a while for big dbs
5605 #   (JRNL: journaled so it only happens once per database)
5606 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5607 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5608 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5609 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5610 # JRNL leading/trailing spaces in first, last, company
5611 # JRNL migrate to cust_payby
5612 # - otaker upgrade?  journal and call it good?  (double check to make sure
5613 #    we're not still setting otaker here)
5614 #
5615 #only going to get worse with new location stuff...
5616
5617 sub _upgrade_data { #class method
5618   my ($class, %opts) = @_;
5619
5620   my @statements = ();
5621
5622   #this seems to be the only expensive one.. why does it take so long?
5623   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5624     push @statements,
5625       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5626     FS::upgrade_journal->set_done('cust_main__signupdate');
5627   }
5628
5629   my $t = time;
5630   foreach my $sql ( @statements ) {
5631     my $sth = dbh->prepare($sql) or die dbh->errstr;
5632     $sth->execute or die $sth->errstr;
5633     #warn ( (time - $t). " seconds\n" );
5634     #$t = time;
5635   }
5636
5637   local($ignore_expired_card) = 1;
5638   local($ignore_banned_card) = 1;
5639   local($skip_fuzzyfiles) = 1;
5640   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5641
5642   FS::cust_main::Location->_upgrade_data(%opts);
5643
5644   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5645
5646     foreach my $cust_main ( qsearch({
5647       'table'     => 'cust_main',
5648       'hashref'   => {},
5649       'extra_sql' => 'WHERE '.
5650                        join(' OR ',
5651                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5652                            qw( first last company )
5653                        ),
5654     }) ) {
5655       my $error = $cust_main->replace;
5656       die $error if $error;
5657     }
5658
5659     FS::upgrade_journal->set_done('cust_main__trimspaces');
5660
5661   }
5662
5663   $class->_upgrade_otaker(%opts);
5664
5665   # turn on encryption as part of regular upgrade, so all new records are immediately encrypted
5666   # existing records will be encrypted in queueable_upgrade (below)
5667   unless ($conf->exists('encryptionpublickey') || $conf->exists('encryptionprivatekey')) {
5668     eval "use FS::Setup";
5669     die $@ if $@;
5670     FS::Setup::enable_encryption();
5671   }
5672
5673 }
5674
5675 sub queueable_upgrade {
5676   my $class = shift;
5677
5678   ### encryption gets turned on in _upgrade_data, above
5679
5680   eval "use FS::upgrade_journal";
5681   die $@ if $@;
5682
5683   # prior to 2013 (commit f16665c9) payinfo was stored in history if not
5684   # encrypted, clear that out before encrypting/tokenizing anything else
5685   if (!FS::upgrade_journal->is_done('clear_payinfo_history')) {
5686     foreach my $table (qw(
5687       cust_payby cust_pay_pending cust_pay cust_pay_void cust_refund
5688     )) {
5689       my $sql =
5690         'UPDATE h_'.$table.' SET payinfo = NULL WHERE payinfo IS NOT NULL';
5691       my $sth = dbh->prepare($sql) or die dbh->errstr;
5692       $sth->execute or die $sth->errstr;
5693     }
5694     FS::upgrade_journal->set_done('clear_payinfo_history');
5695   }
5696
5697   # fix Tokenized paycardtype and encrypt old records
5698   if (    ! FS::upgrade_journal->is_done('paycardtype_Tokenized')
5699        || ! FS::upgrade_journal->is_done('encryption_check')
5700      )
5701   {
5702
5703     # allow replacement of closed cust_pay/cust_refund records
5704     local $FS::payinfo_Mixin::allow_closed_replace = 1;
5705
5706     # because it looks like nothing's changing
5707     local $FS::Record::no_update_diff = 1;
5708
5709     # commit everything immediately
5710     local $FS::UID::AutoCommit = 1;
5711
5712     # encrypt what's there
5713     foreach my $table (qw(
5714       cust_payby cust_pay_pending cust_pay cust_pay_void cust_refund
5715     )) {
5716       my $tclass = 'FS::'.$table;
5717       my $lastrecnum = 0;
5718       my @recnums = ();
5719       while (
5720         my $recnum = _upgrade_next_recnum(dbh,$table,\$lastrecnum,\@recnums)
5721       ) {
5722         my $record = $tclass->by_key($recnum);
5723         next unless $record; # small chance it's been deleted, that's ok
5724         next unless grep { $record->payby eq $_ } @FS::Record::encrypt_payby;
5725         # window for possible conflict is practically nonexistant,
5726         #   but just in case...
5727         $record = $record->select_for_update;
5728         if (!$record->custnum && $table eq 'cust_pay_pending') {
5729           $record->set('custnum_pending',1);
5730         }
5731         $record->paycardtype('') if $record->paycardtype eq 'Tokenized';
5732
5733         local($ignore_expired_card) = 1;
5734         local($ignore_banned_card) = 1;
5735         local($skip_fuzzyfiles) = 1;
5736         local($import) = 1;#prevent automatic geocoding (need its own variable?)
5737
5738         my $error = $record->replace;
5739         die "Error replacing $table ".$record->get($record->primary_key).": $error" if $error;
5740       }
5741     }
5742
5743     FS::upgrade_journal->set_done('paycardtype_Tokenized');
5744     FS::upgrade_journal->set_done('encryption_check') if $conf->exists('encryption');
5745   }
5746
5747   # now that everything's encrypted, tokenize...
5748   FS::cust_main::Billing_Realtime::token_check(@_);
5749 }
5750
5751 # not entirely false laziness w/ Billing_Realtime::_token_check_next_recnum
5752 # cust_payby might get deleted while this runs
5753 # not a method!
5754 sub _upgrade_next_recnum {
5755   my ($dbh,$table,$lastrecnum,$recnums) = @_;
5756   my $recnum = shift @$recnums;
5757   return $recnum if $recnum;
5758   my $tclass = 'FS::'.$table;
5759   my $paycardtypecheck = ($table ne 'cust_pay_pending') ? q( OR paycardtype = 'Tokenized') : '';
5760   my $sql = 'SELECT '.$tclass->primary_key.
5761             ' FROM '.$table.
5762             ' WHERE '.$tclass->primary_key.' > '.$$lastrecnum.
5763             "   AND payby IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
5764             "   AND ( length(payinfo) < 80$paycardtypecheck ) ".
5765             ' ORDER BY '.$tclass->primary_key.' LIMIT 500';
5766   my $sth = $dbh->prepare($sql) or die $dbh->errstr;
5767   $sth->execute() or die $sth->errstr;
5768   my @recnums;
5769   while (my $rec = $sth->fetchrow_hashref) {
5770     push @$recnums, $rec->{$tclass->primary_key};
5771   }
5772   $sth->finish();
5773   $$lastrecnum = $$recnums[-1];
5774   return shift @$recnums;
5775 }
5776
5777 =back
5778
5779 =head1 BUGS
5780
5781 The delete method.
5782
5783 The delete method should possibly take an FS::cust_main object reference
5784 instead of a scalar customer number.
5785
5786 Bill and collect options should probably be passed as references instead of a
5787 list.
5788
5789 There should probably be a configuration file with a list of allowed credit
5790 card types.
5791
5792 No multiple currency support (probably a larger project than just this module).
5793
5794 Birthdates rely on negative epoch values.
5795
5796 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5797
5798 =head1 SEE ALSO
5799
5800 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5801 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5802 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5803
5804 =cut
5805
5806 1;