FS/FS/cust_credit.pm

   1 package FS::cust_credit;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::reason_Mixin
   5              FS::Record );
   6
   7 use vars qw( $conf $unsuspendauto $me $DEBUG
   8              $otaker_upgrade_kludge $ignore_empty_reasonnum
   9            );
  10 use List::Util qw( min );
  11 use Date::Format;
  12 use FS::UID qw( dbh getotaker );
  13 use FS::Misc qw(send_email);
  14 use FS::Record qw( qsearch qsearchs dbdef );
  15 use FS::CurrentUser;
  16 use FS::cust_main;
  17 use FS::cust_pkg;
  18 use FS::cust_refund;
  19 use FS::cust_credit_bill;
  20 use FS::part_pkg;
  21 use FS::reason_type;
  22 use FS::reason;
  23 use FS::cust_event;
  24 use FS::agent;
  25 use FS::sales;
  26 use FS::cust_credit_void;
  27 use FS::cust_bill_pkg;
  28 use FS::upgrade_journal;
  29
  30 $me = '[ FS::cust_credit ]';
  31 $DEBUG = 0;
  32
  33 $otaker_upgrade_kludge = 0;
  34 $ignore_empty_reasonnum = 0;
  35
  36 #ask FS::UID to run this stuff for us later
  37 $FS::UID::callback{'FS::cust_credit'} = sub {
  38
  39   $conf = new FS::Conf;
  40   $unsuspendauto = $conf->exists('unsuspendauto');
  41
  42 };
  43
  44 our %reasontype_map = ( 'referral_credit_type' => 'Referral Credit',
  45                         'cancel_credit_type'   => 'Cancellation Credit',
  46                       );
  47
  48 =head1 NAME
  49
  50 FS::cust_credit - Object methods for cust_credit records
  51
  52 =head1 SYNOPSIS
  53
  54   use FS::cust_credit;
  55
  56   $record = new FS::cust_credit \%hash;
  57   $record = new FS::cust_credit { 'column' => 'value' };
  58
  59   $error = $record->insert;
  60
  61   $error = $new_record->replace($old_record);
  62
  63   $error = $record->delete;
  64
  65   $error = $record->check;
  66
  67 =head1 DESCRIPTION
  68
  69 An FS::cust_credit object represents a credit; the equivalent of a negative
  70 B<cust_bill> record (see L<FS::cust_bill>).  FS::cust_credit inherits from
  71 FS::Record.  The following fields are currently supported:
  72
  73 =over 4
  74
  75 =item crednum
  76
  77 Primary key (assigned automatically for new credits)
  78
  79 =item custnum
  80
  81 Customer (see L<FS::cust_main>)
  82
  83 =item amount
  84
  85 Amount of the credit
  86
  87 =item _date
  88
  89 Specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  90 L<Time::Local> and L<Date::Parse> for conversion functions.
  91
  92 =item usernum
  93
  94 Order taker (see L<FS::access_user>)
  95
  96 =item reason
  97
  98 Text ( deprecated )
  99
 100 =item reasonnum
 101
 102 Reason (see L<FS::reason>)
 103
 104 =item addlinfo
 105
 106 Text
 107
 108 =item closed
 109
 110 Books closed flag, empty or `Y'
 111
 112 =item pkgnum
 113
 114 Desired pkgnum when using experimental package balances.
 115
 116 =back
 117
 118 =head1 METHODS
 119
 120 =over 4
 121
 122 =item new HASHREF
 123
 124 Creates a new credit.  To add the credit to the database, see L<"insert">.
 125
 126 =cut
 127
 128 sub table { 'cust_credit'; }
 129 sub cust_linked { $_[0]->cust_main_custnum; }
 130 sub cust_unlinked_msg {
 131   my $self = shift;
 132   "WARNING: can't find cust_main.custnum ". $self->custnum.
 133   ' (cust_credit.crednum '. $self->crednum. ')';
 134 }
 135
 136 =item insert
 137
 138 Adds this credit to the database ("Posts" the credit).  If there is an error,
 139 returns the error, otherwise returns false.
 140
 141 =cut
 142
 143 sub insert {
 144   my ($self, %options) = @_;
 145
 146   local $SIG{HUP} = 'IGNORE';
 147   local $SIG{INT} = 'IGNORE';
 148   local $SIG{QUIT} = 'IGNORE';
 149   local $SIG{TERM} = 'IGNORE';
 150   local $SIG{TSTP} = 'IGNORE';
 151   local $SIG{PIPE} = 'IGNORE';
 152
 153   my $oldAutoCommit = $FS::UID::AutoCommit;
 154   local $FS::UID::AutoCommit = 0;
 155   my $dbh = dbh;
 156
 157   my $cust_main = qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 158   my $old_balance = $cust_main->balance;
 159
 160   if (!$self->reasonnum) {
 161     my $reason_text = $self->get('reason')
 162       or return "reason text or existing reason required";
 163     my $reason_type = $options{'reason_type'}
 164       or return "reason type required";
 165
 166     local $@;
 167     my $reason = FS::reason->new_or_existing(
 168       reason => $reason_text,
 169       type   => $reason_type,
 170       class  => 'R',
 171     );
 172     if ($@) {
 173       $dbh->rollback if $oldAutoCommit;
 174       return "failed to set credit reason: $@";
 175     }
 176     $self->set('reasonnum', $reason->reasonnum);
 177   }
 178
 179   $self->setfield('reason', '');
 180
 181   my $error = $self->SUPER::insert;
 182   if ( $error ) {
 183     $dbh->rollback if $oldAutoCommit;
 184     return "error inserting $self: $error";
 185   }
 186
 187   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 188
 189   #false laziness w/ cust_pay::insert
 190   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 191     my @errors = $cust_main->unsuspend;
 192     #return
 193     # side-fx with nested transactions?  upstack rolls back?
 194     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 195          join(' / ', @errors)
 196       if @errors;
 197   }
 198   #eslaf
 199
 200   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 201
 202   '';
 203
 204 }
 205
 206 =item delete
 207
 208 Unless the closed flag is set, deletes this credit and all associated
 209 applications (see L<FS::cust_credit_bill>).  In most cases, you want to use
 210 the void method instead to leave a record of the deleted credit.
 211
 212 =cut
 213
 214 # very similar to FS::cust_pay::delete
 215 sub delete {
 216   my $self = shift;
 217   my %opt = @_;
 218
 219   return "Can't delete closed credit" if $self->closed =~ /^Y/i;
 220
 221   local $SIG{HUP} = 'IGNORE';
 222   local $SIG{INT} = 'IGNORE';
 223   local $SIG{QUIT} = 'IGNORE';
 224   local $SIG{TERM} = 'IGNORE';
 225   local $SIG{TSTP} = 'IGNORE';
 226   local $SIG{PIPE} = 'IGNORE';
 227
 228   my $oldAutoCommit = $FS::UID::AutoCommit;
 229   local $FS::UID::AutoCommit = 0;
 230   my $dbh = dbh;
 231
 232   foreach my $cust_credit_bill ( $self->cust_credit_bill ) {
 233     my $error = $cust_credit_bill->delete;
 234     if ( $error ) {
 235       $dbh->rollback if $oldAutoCommit;
 236       return $error;
 237     }
 238   }
 239
 240   foreach my $cust_credit_refund ( $self->cust_credit_refund ) {
 241     my $error = $cust_credit_refund->delete;
 242     if ( $error ) {
 243       $dbh->rollback if $oldAutoCommit;
 244       return $error;
 245     }
 246   }
 247
 248   my $error = $self->SUPER::delete(@_);
 249   if ( $error ) {
 250     $dbh->rollback if $oldAutoCommit;
 251     return $error;
 252   }
 253
 254   if ( !$opt{void} and $conf->config('deletecredits') ne '' ) {
 255
 256     my $cust_main = $self->cust_main;
 257
 258     my $error = send_email(
 259       'from'    => $conf->invoice_from_full($self->cust_main->agentnum),
 260                                  #invoice_from??? well as good as any
 261       'to'      => $conf->config('deletecredits'),
 262       'subject' => 'FREESIDE NOTIFICATION: Credit deleted',
 263       'body'    => [
 264         "This is an automatic message from your Freeside installation\n",
 265         "informing you that the following credit has been deleted:\n",
 266         "\n",
 267         'crednum: '. $self->crednum. "\n",
 268         'custnum: '. $self->custnum.
 269           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 270         'amount: $'. sprintf("%.2f", $self->amount). "\n",
 271         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 272         'reason: '. $self->reason. "\n",
 273       ],
 274     );
 275
 276     if ( $error ) {
 277       $dbh->rollback if $oldAutoCommit;
 278       return "can't send credit deletion notification: $error";
 279     }
 280
 281   }
 282
 283   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 284
 285   '';
 286
 287 }
 288
 289 =item replace [ OLD_RECORD ]
 290
 291 You can, but probably shouldn't modify credits...
 292
 293 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 294 supplied, replaces this record.  If there is an error, returns the error,
 295 otherwise returns false.
 296
 297 =cut
 298
 299 sub replace {
 300   my $self = shift;
 301   return "Can't modify closed credit" if $self->closed =~ /^Y/i;
 302   $self->SUPER::replace(@_);
 303 }
 304
 305 =item check
 306
 307 Checks all fields to make sure this is a valid credit.  If there is an error,
 308 returns the error, otherwise returns false.  Called by the insert and replace
 309 methods.
 310
 311 =cut
 312
 313 sub check {
 314   my $self = shift;
 315
 316   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 317
 318   my $error =
 319     $self->ut_numbern('crednum')
 320     || $self->ut_number('custnum')
 321     || $self->ut_numbern('_date')
 322     || $self->ut_money('amount')
 323     || $self->ut_alphan('otaker')
 324     || $self->ut_textn('reason')
 325     || $self->ut_textn('addlinfo')
 326     || $self->ut_enum('closed', [ '', 'Y' ])
 327     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 328     || $self->ut_foreign_keyn('eventnum', 'cust_event', 'eventnum')
 329     || $self->ut_foreign_keyn('commission_agentnum',  'agent', 'agentnum')
 330     || $self->ut_foreign_keyn('commission_salesnum',  'sales', 'salesnum')
 331     || $self->ut_foreign_keyn('commission_pkgnum', 'cust_pkg', 'pkgnum')
 332   ;
 333   return $error if $error;
 334
 335   my $method = $ignore_empty_reasonnum ? 'ut_foreign_keyn' : 'ut_foreign_key';
 336   $error = $self->$method('reasonnum', 'reason', 'reasonnum');
 337   return $error if $error;
 338
 339   return "amount must be > 0 " if $self->amount <= 0;
 340
 341   return "amount must be greater or equal to amount applied"
 342     if $self->unapplied < 0 && ! $otaker_upgrade_kludge;
 343
 344   return "Unknown customer"
 345     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 346
 347   $self->_date(time) unless $self->_date;
 348
 349   $self->SUPER::check;
 350 }
 351
 352 =item void [ REASON ]
 353
 354 Voids this credit: deletes the credit and all associated applications and
 355 adds a record of the voided credit to the cust_credit_void table.
 356
 357 =cut
 358
 359 sub void {
 360   my $self = shift;
 361   my $reason = shift;
 362
 363   unless (ref($reason) || !$reason) {
 364     $reason = FS::reason->new_or_existing(
 365       'class'  => 'X',
 366       'type'   => 'Void credit',
 367       'reason' => $reason
 368     );
 369   }
 370
 371   local $SIG{HUP} = 'IGNORE';
 372   local $SIG{INT} = 'IGNORE';
 373   local $SIG{QUIT} = 'IGNORE';
 374   local $SIG{TERM} = 'IGNORE';
 375   local $SIG{TSTP} = 'IGNORE';
 376   local $SIG{PIPE} = 'IGNORE';
 377
 378   my $oldAutoCommit = $FS::UID::AutoCommit;
 379   local $FS::UID::AutoCommit = 0;
 380   my $dbh = dbh;
 381
 382   my $cust_credit_void = new FS::cust_credit_void ( {
 383       map { $_ => $self->get($_) } $self->fields
 384     } );
 385   $cust_credit_void->set('void_reasonnum', $reason->reasonnum);
 386   my $error = $cust_credit_void->insert;
 387   if ( $error ) {
 388     $dbh->rollback if $oldAutoCommit;
 389     return $error;
 390   }
 391
 392   $error = $self->delete(void => 1); # suppress deletecredits warning
 393   if ( $error ) {
 394     $dbh->rollback if $oldAutoCommit;
 395     return $error;
 396   }
 397
 398   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 399
 400   '';
 401
 402 }
 403
 404 =item cust_credit_refund
 405
 406 Returns all refund applications (see L<FS::cust_credit_refund>) for this credit.
 407
 408 =cut
 409
 410 sub cust_credit_refund {
 411   my $self = shift;
 412   map { $_ } #return $self->num_cust_credit_refund unless wantarray;
 413   sort { $a->_date <=> $b->_date }
 414     qsearch( 'cust_credit_refund', { 'crednum' => $self->crednum } )
 415   ;
 416 }
 417
 418 =item cust_credit_bill
 419
 420 Returns all application to invoices (see L<FS::cust_credit_bill>) for this
 421 credit.
 422
 423 =cut
 424
 425 sub cust_credit_bill {
 426   my $self = shift;
 427   map { $_ } #return $self->num_cust_credit_bill unless wantarray;
 428   sort { $a->_date <=> $b->_date }
 429     qsearch( 'cust_credit_bill', { 'crednum' => $self->crednum } )
 430   ;
 431 }
 432
 433 =item unapplied
 434
 435 Returns the amount of this credit that is still unapplied/outstanding;
 436 amount minus all refund applications (see L<FS::cust_credit_refund>) and
 437 applications to invoices (see L<FS::cust_credit_bill>).
 438
 439 =cut
 440
 441 sub unapplied {
 442   my $self = shift;
 443   my $amount = $self->amount;
 444   $amount -= $_->amount foreach ( $self->cust_credit_refund );
 445   $amount -= $_->amount foreach ( $self->cust_credit_bill );
 446   sprintf( "%.2f", $amount );
 447 }
 448
 449 =item credited
 450
 451 Deprecated name for the unapplied method.
 452
 453 =cut
 454
 455 sub credited {
 456   my $self = shift;
 457   #carp "cust_credit->credited deprecated; use ->unapplied";
 458   $self->unapplied(@_);
 459 }
 460
 461 =item cust_main
 462
 463 Returns the customer (see L<FS::cust_main>) for this credit.
 464
 465 =cut
 466
 467 sub cust_main {
 468   my $self = shift;
 469   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 470 }
 471
 472 =item reason
 473
 474 Returns the text of the associated reason (see L<FS::reason>) for this credit.
 475
 476 =cut
 477
 478 # _upgrade_data
 479 #
 480 # Used by FS::Upgrade to migrate to a new database.
 481
 482 sub _upgrade_data {  # class method
 483   my ($class, %opts) = @_;
 484
 485   warn "$me upgrading $class\n" if $DEBUG;
 486
 487   $class->_upgrade_reasonnum(%opts);
 488
 489   if (defined dbdef->table($class->table)->column('reason')) {
 490
 491     warn "$me Ensuring existance of auto reasons\n" if $DEBUG;
 492
 493     foreach ( keys %reasontype_map ) {
 494       unless ($conf->config($_)) {       # hmmmm
 495 #       warn "$me Found $_ reason type lacking\n" if $DEBUG;
 496 #       my $hashref = { 'class' => 'R', 'type' => $reasontype_map{$_} };
 497         my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
 498         my $reason_type = qsearchs( 'reason_type', $hashref );
 499         unless ($reason_type) {
 500           $reason_type  = new FS::reason_type( $hashref );
 501           my $error   = $reason_type->insert();
 502           die "$class had error inserting FS::reason_type into database: $error\n"
 503             if $error;
 504         }
 505         $conf->set($_, $reason_type->typenum);
 506       }
 507     }
 508
 509     warn "$me Ensuring commission packages have a reason type\n" if $DEBUG;
 510
 511     my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
 512     my $reason_type = qsearchs( 'reason_type', $hashref );
 513     unless ($reason_type) {
 514       $reason_type  = new FS::reason_type( $hashref );
 515       my $error   = $reason_type->insert();
 516       die "$class had error inserting FS::reason_type into database: $error\n"
 517         if $error;
 518     }
 519
 520     my @plans = qw( flat_comission flat_comission_cust flat_comission_pkg );
 521     foreach my $plan ( @plans ) {
 522       foreach my $pkg ( qsearch('part_pkg', { 'plan' => $plan } ) ) {
 523         unless ($pkg->option('reason_type', 1) ) {
 524           my $plandata = $pkg->plandata.
 525                         "reason_type=". $reason_type->typenum. "\n";
 526           $pkg->plandata($plandata);
 527           my $error =
 528             $pkg->replace( undef,
 529                            'pkg_svc' => { map { $_->svcpart => $_->quantity }
 530                                           $pkg->pkg_svc
 531                                         },
 532                            'primary_svc' => $pkg->svcpart,
 533                          );
 534             die "failed setting reason_type option: $error"
 535               if $error;
 536         }
 537       }
 538     }
 539   }
 540
 541   local($otaker_upgrade_kludge) = 1;
 542   local($ignore_empty_reasonnum) = 1;
 543   $class->_upgrade_otaker(%opts);
 544
 545   if ( !FS::upgrade_journal->is_done('cust_credit__tax_link')
 546       and !$conf->exists('enable_taxproducts') ) {
 547     # RT#25458: fix credit line item applications that should refer to a
 548     # specific tax allocation
 549     my @cust_credit_bill_pkg = qsearch({
 550         table     => 'cust_credit_bill_pkg',
 551         select    => 'cust_credit_bill_pkg.*',
 552         addl_from => ' LEFT JOIN cust_bill_pkg USING (billpkgnum)',
 553         extra_sql =>
 554           'WHERE cust_credit_bill_pkg.billpkgtaxlocationnum IS NULL '.
 555           'AND cust_bill_pkg.pkgnum = 0', # is a tax
 556     });
 557     my %tax_items;
 558     my %credits;
 559     foreach (@cust_credit_bill_pkg) {
 560       my $billpkgnum = $_->billpkgnum;
 561       $tax_items{$billpkgnum} ||= FS::cust_bill_pkg->by_key($billpkgnum);
 562       $credits{$billpkgnum} ||= [];
 563       push @{ $credits{$billpkgnum} }, $_;
 564     }
 565     TAX_ITEM: foreach my $tax_item (values %tax_items) {
 566       my $billpkgnum = $tax_item->billpkgnum;
 567       # get all pkg/location/taxrate allocations of this tax line item
 568       my @allocations = sort {$b->amount <=> $a->amount}
 569                         qsearch('cust_bill_pkg_tax_location', {
 570                             billpkgnum => $billpkgnum
 571                         });
 572       # and these are all credit applications to it
 573       my @credits = sort {$b->amount <=> $a->amount}
 574                     @{ $credits{$billpkgnum} };
 575       my $c = shift @credits;
 576       my $a = shift @allocations; # we will NOT modify these
 577       while ($c and $a) {
 578         if ( abs($c->amount - $a->amount) < 0.005 ) {
 579           # by far the most common case: the tax line item is for a single
 580           # tax, so we just fill in the billpkgtaxlocationnum
 581           $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
 582           my $error = $c->replace;
 583           if ($error) {
 584             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 585             next TAX_ITEM;
 586           }
 587           $c = shift @credits;
 588           $a = shift @allocations;
 589         } elsif ( $c->amount > $a->amount ) {
 590           # fairly common: the tax line contains tax for multiple packages
 591           # (or multiple taxes) but the credit isn't divided up
 592           my $new_link = FS::cust_credit_bill_pkg->new({
 593               creditbillnum         => $c->creditbillnum,
 594               billpkgnum            => $c->billpkgnum,
 595               billpkgtaxlocationnum => $a->billpkgtaxlocationnum,
 596               amount                => $a->amount,
 597               setuprecur            => 'setup',
 598           });
 599           my $error = $new_link->insert;
 600           if ($error) {
 601             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 602             next TAX_ITEM;
 603           }
 604           $c->set(amount => sprintf('%.2f', $c->amount - $a->amount));
 605           $a = shift @allocations;
 606         } elsif ( $c->amount < 0.005 ) {
 607           # also fairly common; we can delete these with no harm
 608           my $error = $c->delete;
 609           warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
 610           $c = shift @credits;
 611         } elsif ( $c->amount < $a->amount ) {
 612           # should never happen, but if it does, handle it gracefully
 613           $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
 614           my $error = $c->replace;
 615           if ($error) {
 616             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 617             next TAX_ITEM;
 618           }
 619           $a->set(amount => $a->amount - $c->amount);
 620           $c = shift @credits;
 621         }
 622       } # while $c and $a
 623       if ( $c ) {
 624         if ( $c->amount < 0.005 ) {
 625           my $error = $c->delete;
 626           warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
 627         } elsif ( $c->modified ) {
 628           # then we've allocated part of it, so reduce the nonspecific
 629           # application by that much
 630           my $error = $c->replace;
 631           warn "error fixing credit application to tax item #$billpkgnum:\n$error\n" if $error;
 632         }
 633         # else there are probably no allocations, i.e. this is a pre-3.x
 634         # record that was never migrated over, so leave it alone
 635       } # if $c
 636     } # foreach $tax_item
 637     FS::upgrade_journal->set_done('cust_credit__tax_link');
 638   }
 639 }
 640
 641 =back
 642
 643 =head1 CLASS METHODS
 644
 645 =over 4
 646
 647 =item unapplied_sql
 648
 649 Returns an SQL fragment to retreive the unapplied amount.
 650
 651 =cut
 652
 653 sub unapplied_sql {
 654   my ($class, $start, $end) = @_;
 655
 656   my $bill_start   = $start ? "AND cust_credit_bill._date <= $start"   : '';
 657   my $bill_end     = $end   ? "AND cust_credit_bill._date > $end"     : '';
 658   my $refund_start = $start ? "AND cust_credit_refund._date <= $start" : '';
 659   my $refund_end   = $end   ? "AND cust_credit_refund._date > $end"   : '';
 660
 661   "amount
 662         - COALESCE(
 663                     ( SELECT SUM(amount) FROM cust_credit_refund
 664                         WHERE cust_credit.crednum = cust_credit_refund.crednum
 665                         $refund_start $refund_end )
 666                     ,0
 667                   )
 668         - COALESCE(
 669                     ( SELECT SUM(amount) FROM cust_credit_bill
 670                         WHERE cust_credit.crednum = cust_credit_bill.crednum
 671                         $bill_start $bill_end )
 672                     ,0
 673                   )
 674   ";
 675
 676 }
 677
 678 =item credited_sql
 679
 680 Deprecated name for the unapplied_sql method.
 681
 682 =cut
 683
 684 sub credited_sql {
 685   #my $class = shift;
 686
 687   #carp "cust_credit->credited_sql deprecated; use ->unapplied_sql";
 688
 689   #$class->unapplied_sql(@_);
 690   unapplied_sql();
 691 }
 692
 693 =item calculate_tax_adjustment PARAMS
 694
 695 Calculate the amount of tax that needs to be credited as part of a lineitem
 696 credit.
 697
 698 PARAMS must include:
 699
 700 - billpkgnums: arrayref identifying the line items to credit
 701 - setuprecurs: arrayref of 'setup' or 'recur', indicating which part of
 702   the lineitem charge is being credited
 703 - amounts: arrayref of the amounts to credit on each line item
 704 - custnum: the customer all of these invoices belong to, for error checking
 705
 706 Returns a hash containing:
 707 - subtotal: the total non-tax amount to be credited (the sum of the 'amounts')
 708 - taxtotal: the total tax amount to be credited
 709 - taxlines: an arrayref of hashrefs for each tax line to be credited, each with:
 710   - table: "cust_bill_pkg_tax_location" or "cust_bill_pkg_tax_rate_location"
 711   - num: the key within that table
 712   - credit: the credit amount to apply to that line
 713
 714 =cut
 715
 716 sub calculate_tax_adjustment {
 717   my ($class, %arg) = @_;
 718
 719   my $error;
 720   my @taxlines;
 721   my $subtotal = 0;
 722   my $taxtotal = 0;
 723
 724   my (%cust_bill_pkg, %cust_bill);
 725
 726   for (my $i = 0; ; $i++) {
 727     my $billpkgnum = $arg{billpkgnums}[$i]
 728       or last;
 729     my $setuprecur = $arg{setuprecurs}[$i];
 730     my $amount = $arg{amounts}[$i];
 731     next if $amount == 0;
 732     $subtotal += $amount;
 733     my $cust_bill_pkg = $cust_bill_pkg{$billpkgnum}
 734                     ||= FS::cust_bill_pkg->by_key($billpkgnum)
 735       or die "lineitem #$billpkgnum not found\n";
 736
 737     my $invnum = $cust_bill_pkg->invnum;
 738     $cust_bill{ $invnum } ||= FS::cust_bill->by_key($invnum);
 739     $cust_bill{ $invnum}->custnum == $arg{custnum}
 740       or die "lineitem #$billpkgnum not found\n";
 741
 742     # calculate credit ratio.
 743     # (First deduct any existing credits applied to this line item, to avoid
 744     # rounding errors.)
 745     my $charged = $cust_bill_pkg->get($setuprecur);
 746     my $previously_credited =
 747       $cust_bill_pkg->credited( '', '', setuprecur => $setuprecur) || 0;
 748
 749     $charged -= $previously_credited;
 750     if ($charged < $amount) {
 751       $error = "invoice #$invnum: tried to credit $amount, but only $charged was charged";
 752       last;
 753     }
 754     my $ratio = $amount / $charged;
 755
 756     # gather taxes that apply to the selected item
 757     foreach my $table (
 758       qw(cust_bill_pkg_tax_location cust_bill_pkg_tax_rate_location)
 759     ) {
 760       foreach my $tax_link (
 761         qsearch($table, { taxable_billpkgnum => $billpkgnum })
 762       ) {
 763         my $tax_amount = $tax_link->amount;
 764         # deduct existing credits applied to the tax, for the same reason as
 765         # above
 766         foreach ($tax_link->cust_credit_bill_pkg) {
 767           $tax_amount -= $_->amount;
 768         }
 769         my $tax_credit = sprintf('%.2f', $tax_amount * $ratio);
 770         my $pkey = $tax_link->get($tax_link->primary_key);
 771         push @taxlines, {
 772           table   => $table,
 773           num     => $pkey,
 774           credit  => $tax_credit,
 775         };
 776         $taxtotal += $tax_credit;
 777
 778       } #foreach cust_bill_pkg_tax_(rate_)?location
 779     }
 780   } # foreach $billpkgnum
 781
 782   return (
 783     subtotal => sprintf('%.2f', $subtotal),
 784     taxtotal => sprintf('%.2f', $taxtotal),
 785     taxlines => \@taxlines,
 786   );
 787 }
 788
 789 =item credit_lineitems
 790
 791 Example:
 792
 793   my $error = FS::cust_credit->credit_lineitems(
 794
 795     #the lineitems to credit
 796     'billpkgnums'       => \@billpkgnums,
 797     'setuprecurs'       => \@setuprecurs,
 798     'amounts'           => \@amounts,
 799     'apply'             => 1, #0 leaves the credit unapplied
 800
 801     #the credit
 802     map { $_ => scalar($cgi->param($_)) }
 803       #fields('cust_credit')
 804       qw( custnum _date amount reasonnum addlinfo ), #pkgnum eventnum
 805
 806   );
 807
 808 =cut
 809
 810 #maybe i should just be an insert with extra args instead of a class method
 811 sub credit_lineitems {
 812   my( $class, %arg ) = @_;
 813   my $curuser = $FS::CurrentUser::CurrentUser;
 814
 815   #some false laziness w/misc/xmlhttp-cust_bill_pkg-calculate_taxes.html
 816
 817   my $cust_main = qsearchs({
 818     'table'     => 'cust_main',
 819     'hashref'   => { 'custnum' => $arg{custnum} },
 820     'extra_sql' => ' AND '. $curuser->agentnums_sql,
 821   }) or return 'unknown customer';
 822
 823
 824   local $SIG{HUP} = 'IGNORE';
 825   local $SIG{INT} = 'IGNORE';
 826   local $SIG{QUIT} = 'IGNORE';
 827   local $SIG{TERM} = 'IGNORE';
 828   local $SIG{TSTP} = 'IGNORE';
 829   local $SIG{PIPE} = 'IGNORE';
 830
 831   my $oldAutoCommit = $FS::UID::AutoCommit;
 832   local $FS::UID::AutoCommit = 0;
 833   my $dbh = dbh;
 834
 835   #my @cust_bill_pkg = qsearch({
 836   #  'select'    => 'cust_bill_pkg.*',
 837   #  'table'     => 'cust_bill_pkg',
 838   #  'addl_from' => ' LEFT JOIN cust_bill USING (invnum)  '.
 839   #                 ' LEFT JOIN cust_main USING (custnum) ',
 840   #  'extra_sql' => ' WHERE custnum = $custnum AND billpkgnum IN ('.
 841   #                     join( ',', @{$arg{billpkgnums}} ). ')',
 842   #  'order_by'  => 'ORDER BY invnum ASC, billpkgnum ASC',
 843   #});
 844
 845   my $error = '';
 846
 847   my $cust_credit = new FS::cust_credit ( {
 848     map { $_ => $arg{$_} }
 849       #fields('cust_credit')
 850       qw( custnum _date amount reasonnum addlinfo ), #pkgnum eventnum
 851   } );
 852   $error = $cust_credit->insert;
 853   if ( $error ) {
 854     $dbh->rollback if $oldAutoCommit;
 855     return "Error inserting credit: $error";
 856   }
 857
 858   unless ( $arg{'apply'} ) {
 859     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 860     return '';
 861   }
 862
 863   #my $subtotal = 0;
 864   # keys in all of these are invoice numbers
 865   my %cust_credit_bill = ();
 866   my %cust_bill_pkg = ();
 867   my %cust_credit_bill_pkg = ();
 868   my %unapplied_payments = (); #invoice numbers, and then billpaynums
 869
 870   # determine the tax adjustments
 871   my %tax_adjust = $class->calculate_tax_adjustment(%arg);
 872
 873   foreach my $billpkgnum ( @{$arg{billpkgnums}} ) {
 874     my $setuprecur = shift @{$arg{setuprecurs}};
 875     my $amount = shift @{$arg{amounts}};
 876
 877     my $cust_bill_pkg = qsearchs({
 878       'table'     => 'cust_bill_pkg',
 879       'hashref'   => { 'billpkgnum' => $billpkgnum },
 880       'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
 881       'extra_sql' => 'AND custnum = '. $cust_main->custnum,
 882     }) or die "unknown billpkgnum $billpkgnum";
 883
 884     my $invnum = $cust_bill_pkg->invnum;
 885
 886     push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
 887
 888     $cust_credit_bill{$invnum} += $amount;
 889     push @{ $cust_credit_bill_pkg{$invnum} },
 890       new FS::cust_credit_bill_pkg {
 891         'billpkgnum' => $billpkgnum,
 892         'amount'     => sprintf('%.2f',$amount),
 893         'setuprecur' => $setuprecur,
 894         'sdate'      => $cust_bill_pkg->sdate,
 895         'edate'      => $cust_bill_pkg->edate,
 896       };
 897     # unapply payments (but not other credits) from this line item
 898     foreach my $cust_bill_pay_pkg (
 899       $cust_bill_pkg->cust_bill_pay_pkg($setuprecur)
 900     ) {
 901       $error = $cust_bill_pay_pkg->delete;
 902       if ( $error ) {
 903         $dbh->rollback if $oldAutoCommit;
 904         return "Error unapplying payment: $error";
 905       }
 906       $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum}
 907         += $cust_bill_pay_pkg->amount;
 908     }
 909   }
 910
 911   # do the same for taxes
 912   foreach my $tax_credit ( @{ $tax_adjust{taxlines} } ) {
 913     my $table = $tax_credit->{table};
 914     my $tax_link = "FS::$table"->by_key( $tax_credit->{num} )
 915       or die "tried to credit $table #$tax_credit->{num} but it doesn't exist";
 916
 917     my $billpkgnum = $tax_link->billpkgnum;
 918     my $cust_bill_pkg = qsearchs({
 919       'table'     => 'cust_bill_pkg',
 920       'hashref'   => { 'billpkgnum' => $billpkgnum },
 921       'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
 922       'extra_sql' => 'AND custnum = '. $cust_main->custnum,
 923     }) or die "unknown billpkgnum $billpkgnum";
 924
 925     my $invnum = $cust_bill_pkg->invnum;
 926     push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
 927
 928     my $amount = $tax_credit->{credit};
 929     $cust_credit_bill{$invnum} += $amount;
 930
 931     # create a credit application record to the tax line item, earmarked
 932     # to the specific cust_bill_pkg_Xlocation
 933     push @{ $cust_credit_bill_pkg{$invnum} },
 934       new FS::cust_credit_bill_pkg {
 935         'billpkgnum' => $billpkgnum,
 936         'amount'     => sprintf('%.2f', $amount),
 937         'setuprecur' => 'setup',
 938         $tax_link->primary_key, $tax_credit->{num}
 939       };
 940     # unapply any payments from the tax
 941     foreach my $cust_bill_pay_pkg (
 942       $cust_bill_pkg->cust_bill_pay_pkg('setup')
 943     ) {
 944       $error = $cust_bill_pay_pkg->delete;
 945       if ( $error ) {
 946         $dbh->rollback if $oldAutoCommit;
 947         return "Error unapplying payment: $error";
 948       }
 949       $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum}
 950         += $cust_bill_pay_pkg->amount;
 951     }
 952   }
 953
 954   ###
 955   # now loop through %cust_credit_bill and insert those
 956   ###
 957
 958   # (hack to prevent cust_credit_bill_pkg insertion)
 959   local($FS::cust_bill_ApplicationCommon::skip_apply_to_lineitems_hack) = 1;
 960
 961   foreach my $invnum ( sort { $a <=> $b } keys %cust_credit_bill ) {
 962
 963     # if we unapplied any payments from line items, also unapply that
 964     # amount from the invoice
 965     foreach my $billpaynum (keys %{$unapplied_payments{$invnum}}) {
 966       my $cust_bill_pay = FS::cust_bill_pay->by_key($billpaynum)
 967         or die "broken payment application $billpaynum";
 968       my @subapps = $cust_bill_pay->lineitem_applications;
 969       $error = $cust_bill_pay->delete; # can't replace
 970
 971       my $new_cust_bill_pay = FS::cust_bill_pay->new({
 972           $cust_bill_pay->hash,
 973           billpaynum => '',
 974           amount => sprintf('%.2f',
 975               $cust_bill_pay->amount
 976               - $unapplied_payments{$invnum}{$billpaynum}),
 977       });
 978
 979       if ( $new_cust_bill_pay->amount > 0 ) {
 980         $error ||= $new_cust_bill_pay->insert;
 981         # Also reapply it to everything it was applied to before.
 982         # Note that we've already deleted cust_bill_pay_pkg records for the
 983         # items we're crediting, so they aren't on this list.
 984         foreach my $cust_bill_pay_pkg (@subapps) {
 985           $cust_bill_pay_pkg->billpaypkgnum('');
 986           $cust_bill_pay_pkg->billpaynum($new_cust_bill_pay->billpaynum);
 987           $error ||= $cust_bill_pay_pkg->insert;
 988         }
 989       }
 990       if ( $error ) {
 991         $dbh->rollback if $oldAutoCommit;
 992         return "Error unapplying payment: $error";
 993       }
 994     }
 995     #insert cust_credit_bill
 996
 997     my $cust_credit_bill = new FS::cust_credit_bill {
 998       'crednum' => $cust_credit->crednum,
 999       'invnum'  => $invnum,
1000       'amount'  => sprintf('%.2f', $cust_credit_bill{$invnum}),
1001     };
1002     $error = $cust_credit_bill->insert;
1003     if ( $error ) {
1004       $dbh->rollback if $oldAutoCommit;
1005       return "Error applying credit of $cust_credit_bill{$invnum} ".
1006              " to invoice $invnum: $error";
1007     }
1008
1009     #and then insert cust_credit_bill_pkg for each cust_bill_pkg
1010     foreach my $cust_credit_bill_pkg ( @{$cust_credit_bill_pkg{$invnum}} ) {
1011       $cust_credit_bill_pkg->creditbillnum( $cust_credit_bill->creditbillnum );
1012       $error = $cust_credit_bill_pkg->insert;
1013       if ( $error ) {
1014         $dbh->rollback if $oldAutoCommit;
1015         return "Error applying credit to line item: $error";
1016       }
1017     }
1018
1019   }
1020
1021   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1022   '';
1023
1024 }
1025
1026 =back
1027
1028 =head1 SUBROUTINES
1029
1030 =over 4
1031
1032 =item process_batch_import
1033
1034 =cut
1035
1036 use List::Util qw( min );
1037 use FS::cust_bill;
1038 use FS::cust_credit_bill;
1039 sub process_batch_import {
1040   my $job = shift;
1041
1042   my $opt = { 'table'   => 'cust_credit',
1043               'params'  => [ '_date', 'credbatch' ],
1044               'formats' => { 'simple' =>
1045                                [ 'custnum', 'amount', 'reasonnum', 'invnum' ],
1046                            },
1047               'default_csv' => 1,
1048               'postinsert_callback' => sub {
1049                 my $cust_credit = shift; #my ($cust_credit, $param ) = @_;
1050
1051                 if ( $cust_credit->invnum ) {
1052
1053                   my $cust_bill = qsearchs('cust_bill', { invnum=>$cust_credit->invnum } );
1054                   my $amount = min( $cust_credit->credited, $cust_bill->owed );
1055
1056                   my $cust_credit_bill = new FS::cust_credit_bill ( {
1057                     'crednum' => $cust_credit->crednum,
1058                     'invnum'  => $cust_bill->invnum,
1059                     'amount'  => $amount,
1060                   } );
1061                   my $error = $cust_credit_bill->insert;
1062                   return '' unless $error;
1063
1064                 }
1065
1066                 #apply_payments_and_credits ?
1067                 $cust_credit->cust_main->apply_credits;
1068
1069                 return '';
1070
1071               },
1072             };
1073
1074   FS::Record::process_batch_import( $job, $opt, @_ );
1075
1076 }
1077
1078 =back
1079
1080 =head1 BUGS
1081
1082 The delete method.  The replace method.
1083
1084 B<credited> and B<credited_sql> are now called B<unapplied> and
1085 B<unapplied_sql>.  The old method names should start to give warnings.
1086
1087 =head1 SEE ALSO
1088
1089 L<FS::Record>, L<FS::cust_credit_refund>, L<FS::cust_refund>,
1090 L<FS::cust_credit_bill> L<FS::cust_bill>, schema.html from the base
1091 documentation.
1092
1093 =cut
1094
1095 1;
1096