FS/FS/cust_bill_ApplicationCommon.pm

   1 package FS::cust_bill_ApplicationCommon;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $skip_apply_to_lineitems_hack );
   5 use List::Util qw(min);
   6 use FS::Schema qw( dbdef );
   7 use FS::Record qw( qsearch qsearchs dbh );
   8
   9 @ISA = qw( FS::Record );
  10
  11 $DEBUG = 0;
  12 $me = '[FS::cust_bill_ApplicationCommon]';
  13
  14 $skip_apply_to_lineitems_hack = 0;
  15
  16 =head1 NAME
  17
  18 FS::cust_bill_ApplicationCommon - Base class for bill application classes
  19
  20 =head1 SYNOPSIS
  21
  22 use FS::cust_bill_ApplicationCommon;
  23
  24 @ISA = qw( FS::cust_bill_ApplicationCommon );
  25
  26 sub _app_source_name  { 'payment'; }
  27 sub _app_source_table { 'cust_pay'; }
  28 sub _app_lineitem_breakdown_table { 'cust_bill_pay_pkg'; }
  29
  30 =head1 DESCRIPTION
  31
  32 FS::cust_bill_ApplicationCommon is intended as a base class for classes which
  33 represent application of things to invoices, currently payments
  34 (see L<FS::cust_bill_pay>) or credits (see L<FS::cust_credit_bill>).
  35
  36 =head1 METHODS
  37
  38 =over 4
  39
  40 =item insert
  41
  42 =cut
  43
  44 sub insert {
  45   my $self = shift;
  46
  47   local $SIG{HUP} = 'IGNORE';
  48   local $SIG{INT} = 'IGNORE';
  49   local $SIG{QUIT} = 'IGNORE';
  50   local $SIG{TERM} = 'IGNORE';
  51   local $SIG{TSTP} = 'IGNORE';
  52   local $SIG{PIPE} = 'IGNORE';
  53
  54   my $oldAutoCommit = $FS::UID::AutoCommit;
  55   local $FS::UID::AutoCommit = 0;
  56   my $dbh = dbh;
  57
  58   my $error =    $self->SUPER::insert(@_)
  59               || $self->apply_to_lineitems;
  60   if ( $error ) {
  61     $dbh->rollback if $oldAutoCommit;
  62     return $error;
  63   }
  64
  65   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
  66
  67   '';
  68
  69 }
  70
  71 =item delete
  72
  73 =cut
  74
  75 sub delete {
  76   my $self = shift;
  77
  78   local $SIG{HUP} = 'IGNORE';
  79   local $SIG{INT} = 'IGNORE';
  80   local $SIG{QUIT} = 'IGNORE';
  81   local $SIG{TERM} = 'IGNORE';
  82   local $SIG{TSTP} = 'IGNORE';
  83   local $SIG{PIPE} = 'IGNORE';
  84
  85   my $oldAutoCommit = $FS::UID::AutoCommit;
  86   local $FS::UID::AutoCommit = 0;
  87   my $dbh = dbh;
  88
  89   foreach my $app ( $self->lineitem_applications ) {
  90     my $error = $app->delete;
  91     if ( $error ) {
  92       $dbh->rollback if $oldAutoCommit;
  93       return $error;
  94     }
  95   }
  96
  97   my $error = $self->SUPER::delete(@_);
  98   if ( $error ) {
  99     $dbh->rollback if $oldAutoCommit;
 100     return $error;
 101   }
 102
 103   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 104
 105   '';
 106
 107 }
 108
 109 =item apply_to_lineitems
 110
 111 Auto-applies this invoice application to specific line items, if possible.
 112
 113 =cut
 114
 115 sub apply_to_lineitems {
 116   my $self = shift;
 117
 118   return '' if $skip_apply_to_lineitems_hack;
 119
 120   my @apply = ();
 121
 122   my $conf = new FS::Conf;
 123
 124   local $SIG{HUP} = 'IGNORE';
 125   local $SIG{INT} = 'IGNORE';
 126   local $SIG{QUIT} = 'IGNORE';
 127   local $SIG{TERM} = 'IGNORE';
 128   local $SIG{TSTP} = 'IGNORE';
 129   local $SIG{PIPE} = 'IGNORE';
 130
 131   my $oldAutoCommit = $FS::UID::AutoCommit;
 132   local $FS::UID::AutoCommit = 0;
 133   my $dbh = dbh;
 134
 135   my @open = $self->cust_bill->open_cust_bill_pkg; #FOR UPDATE...?
 136   @open = grep { $_->pkgnum == $self->pkgnum } @open
 137     if $conf->exists('pkg-balances') && $self->pkgnum;
 138   warn "$me ". scalar(@open). " open line items for invoice ".
 139        $self->cust_bill->invnum. ": ". join(', ', @open). "\n"
 140     if $DEBUG;
 141   my $total = 0;
 142   $total += $_->setup + $_->recur foreach @open;
 143   $total = sprintf('%.2f', $total);
 144
 145   if ( $self->amount > $total ) {
 146     $dbh->rollback if $oldAutoCommit;
 147     return "Can't apply a ". $self->_app_source_name. ' of $'. $self->amount.
 148            " greater than the remaining owed on line items (\$$total)";
 149   }
 150
 151   #easy cases:
 152   # - one lineitem (a simple special case of:)
 153   # - amount is for whole invoice (well, all of remaining lineitem links)
 154   if ( $self->amount == $total ) {
 155
 156     warn "$me application amount covers remaining balance of invoice in full;".
 157          "applying to those lineitems\n"
 158       if $DEBUG;
 159
 160     #@apply = map { [ $_, $_->amount ]; } @open;
 161     @apply = map { [ $_, $_->setup || $_->recur ]; } @open;
 162
 163   } else {
 164
 165     #slightly magic case:
 166     # - amount exactly and uniquely matches a single open lineitem
 167     #   (you must be trying to pay or credit that item, then)
 168
 169     my @same = grep {    $_->setup == $self->amount
 170                       || $_->recur == $self->amount
 171                     }
 172                     @open;
 173     if ( scalar(@same) == 1 ) {
 174       warn "$me application amount exactly and uniquely matches one lineitem;".
 175            " applying to that lineitem\n"
 176         if $DEBUG;
 177       @apply = map { [ $_, $self->amount ]; } @same
 178     }
 179
 180   }
 181
 182   unless ( @apply ) {
 183
 184     warn "$me applying amount based on package weights\n"
 185       if $DEBUG;
 186
 187     #and the rest:
 188     # - apply based on weights...
 189
 190     my $weight_col = $self->_app_part_pkg_weight_column;
 191     my @openweight = map {
 192                            my $open = $_;
 193                            my $cust_pkg = $open->cust_pkg;
 194                            my $weight =
 195                              $cust_pkg
 196                                ? ( $cust_pkg->part_pkg->$weight_col() || 0 )
 197                                : 0; #default or per-tax weight?
 198                            [ $open, $weight ]
 199                          }
 200                          @open;
 201
 202     my %saw = ();
 203     my @weights = sort { $b <=> $a }     # highest weight first
 204                   grep { ! $saw{$_}++ }  # want a list of unique weights
 205                   map  { $_->[1] }
 206                        @openweight;
 207
 208     my $remaining_amount = $self->amount;
 209     foreach my $weight ( @weights ) {
 210
 211       #i hate it when my schwartz gets tangled
 212       my @items = map { $_->[0] } grep { $weight == $_->[1] } @openweight;
 213
 214       my $itemtotal = 0;
 215       foreach my $item (@items) { $itemtotal += $item->setup || $item->recur; }
 216       my $applytotal = min( $itemtotal, $remaining_amount );
 217       $remaining_amount -= $applytotal;
 218
 219       warn "$me applying $applytotal ($remaining_amount remaining)".
 220            " to ". scalar(@items). " lineitems with weight $weight\n"
 221         if $DEBUG;
 222
 223       #if some items are less than applytotal/num_items, then apply then in full
 224       my $lessflag;
 225       do {
 226         $lessflag = 0;
 227
 228         #no, not sprintf("%.2f",
 229         # we want this rounded DOWN for purposes of checking for line items
 230         # less than it, we don't want .66666 becoming .67 and causing this
 231         # to trigger when it shouldn't
 232         my $applyeach = int( 100 * $applytotal / scalar(@items) ) / 100;
 233
 234         my @newitems = ();
 235         foreach my $item ( @items ) {
 236           my $itemamount = $item->setup || $item->recur;
 237           if ( $itemamount < $applyeach ) {
 238             warn "$me applying full $itemamount".
 239                  " to small line item (cust_bill_pkg ". $item->billpkgnum. ")\n"
 240               if $DEBUG;
 241             push @apply, [ $item, $itemamount ];
 242             $applytotal -= $itemamount;
 243             $lessflag=1;
 244           } else {
 245             push @newitems, $item;
 246           }
 247         }
 248         @items = @newitems;
 249
 250       } while ( $lessflag );
 251
 252       #and now that we've fallen out of the loop, distribute the rest equally...
 253
 254       # should cust_bill_pay_pkg and cust_credit_bill_pkg amount columns
 255       # become real instead of numeric(10,2) ???  no..
 256       my $applyeach = sprintf("%.2f", $applytotal / scalar(@items) );
 257
 258       my @equi_apply = map { [ $_, $applyeach ] } @items;
 259
 260       # or should we futz with pennies instead?  yes, bah!
 261       my $diff =
 262         sprintf('%.0f', 100 * ( $applytotal - $applyeach * scalar(@items) ) );
 263       $diff = 0 if $diff eq '-0'; #yay ieee fp
 264       if ( abs($diff) > scalar(@items) ) {
 265         #we must have done something really wrong, the difference is more than
 266         #a penny an item
 267         $dbh->rollback if $oldAutoCommit;
 268         return 'Error distributing pennies applying '. $self->_app_source_name.
 269                " - can't distribute difference of $diff pennies".
 270                ' among '. scalar(@items). ' line items';
 271       }
 272
 273       warn "$me futzing with $diff pennies difference\n"
 274         if $DEBUG && $diff;
 275
 276       my $futz = 0;
 277       while ( $diff != 0 && $futz < scalar(@equi_apply) ) {
 278         if ( $diff > 0 ) {
 279           $equi_apply[$futz++]->[1] += .01;
 280           $diff -= 1;
 281         } elsif ( $diff < 0 ) {
 282           $equi_apply[$futz++]->[1] -= .01;
 283           $diff += 1;
 284         } else {
 285           die "guru exception #5 (in fortran tongue the answer)";
 286         }
 287       }
 288
 289       if ( sprintf('%.0f', $diff ) ) {
 290         $dbh->rollback if $oldAutoCommit;
 291         return "couldn't futz with pennies enough: still $diff left";
 292       }
 293
 294       if ( $DEBUG ) {
 295         warn "$me applying ". $_->[1].
 296              " to line item (cust_bill_pkg ". $_->[0]->billpkgnum. ")\n"
 297           foreach @equi_apply;
 298       }
 299
 300
 301       push @apply, @equi_apply;
 302
 303       #$remaining_amount -= $applytotal;
 304       last unless $remaining_amount;
 305
 306     }
 307
 308   }
 309
 310   # do the applicaiton(s)
 311   my $table = $self->lineitem_breakdown_table;
 312   my $source_key = dbdef->table($self->table)->primary_key;
 313   my $applied = 0;
 314   foreach my $apply ( @apply ) {
 315     my ( $cust_bill_pkg, $amount ) = @$apply;
 316     $applied += $amount;
 317     my $application = "FS::$table"->new( {
 318       $source_key  => $self->$source_key(),
 319       'billpkgnum' => $cust_bill_pkg->billpkgnum,
 320       'amount'     => sprintf('%.2f', $amount),
 321       'setuprecur' => ( $cust_bill_pkg->setup > 0 ? 'setup' : 'recur' ),
 322       'sdate'      => $cust_bill_pkg->sdate,
 323       'edate'      => $cust_bill_pkg->edate,
 324     });
 325     my $error = $application->insert;
 326     if ( $error ) {
 327       $dbh->rollback if $oldAutoCommit;
 328       return $error;
 329     }
 330   }
 331
 332   #everything should always be applied to line items in full now... sanity check
 333   $applied = sprintf('%.2f', $applied);
 334   unless ( $applied == $self->amount ) {
 335     $dbh->rollback if $oldAutoCommit;
 336     return 'Error applying '. $self->_app_source_name. ' of $'. $self->amount.
 337            ' to line items - only $'. $applied. ' was applied.';
 338   }
 339
 340   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 341   '';
 342
 343 }
 344
 345 =item lineitem_applications
 346
 347 Returns all the specific line item applications for this invoice application.
 348
 349 =cut
 350
 351 sub lineitem_applications {
 352   my $self = shift;
 353   my $primary_key = dbdef->table($self->table)->primary_key;
 354   qsearch({
 355     'table'   => $self->lineitem_breakdown_table,
 356     'hashref' => { $primary_key => $self->$primary_key() },
 357   });
 358
 359 }
 360
 361 =item cust_bill
 362
 363 Returns the invoice (see L<FS::cust_bill>)
 364
 365 =cut
 366
 367 sub cust_bill {
 368   my $self = shift;
 369   qsearchs( 'cust_bill', { 'invnum' => $self->invnum } );
 370 }
 371
 372 =item applied_to_invoice
 373
 374 Returns a string representing the invoice (see L<FS::cust_bill>), for example:
 375 "applied to Invoice #54 (3/20/2008)"
 376
 377 =cut
 378
 379 sub applied_to_invoice {
 380   my $self = shift;
 381   'applied to '. $self->cust_bill->invnum_date_pretty;
 382 }
 383
 384 =item lineitem_breakdown_table
 385
 386 =cut
 387
 388 sub lineitem_breakdown_table {
 389   my $self = shift;
 390   $self->_load_table($self->_app_lineitem_breakdown_table);
 391 }
 392
 393 sub _load_table {
 394   my( $self, $table ) = @_;
 395   eval "use FS::$table";
 396   die $@ if $@;
 397   $table;
 398 }
 399
 400 =back
 401
 402 =head1 BUGS
 403
 404 =head1 SEE ALSO
 405
 406 L<FS::cust_bill_pay> and L<FS::cust_bill_pay_pkg>,
 407 L<FS::cust_credit_bill> and L<FS::cust_credit_bill_pkg>
 408
 409 =cut
 410
 411 1;
 412