FS/FS/cust_bill_ApplicationCommon.pm

   1 package FS::cust_bill_ApplicationCommon;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $skip_apply_to_lineitems_hack );
   5 use List::Util qw(min);
   6 use FS::Schema qw( dbdef );
   7 use FS::Record qw( qsearch qsearchs dbh );
   8
   9 @ISA = qw( FS::Record );
  10
  11 $DEBUG = 0;
  12 $me = '[FS::cust_bill_ApplicationCommon]';
  13
  14 $skip_apply_to_lineitems_hack = 0;
  15
  16 =head1 NAME
  17
  18 FS::cust_bill_ApplicationCommon - Base class for bill application classes
  19
  20 =head1 SYNOPSIS
  21
  22 use FS::cust_bill_ApplicationCommon;
  23
  24 @ISA = qw( FS::cust_bill_ApplicationCommon );
  25
  26 sub _app_source_name  { 'payment'; }
  27 sub _app_source_table { 'cust_pay'; }
  28 sub _app_lineitem_breakdown_table { 'cust_bill_pay_pkg'; }
  29
  30 =head1 DESCRIPTION
  31
  32 FS::cust_bill_ApplicationCommon is intended as a base class for classes which
  33 represent application of things to invoices, currently payments
  34 (see L<FS::cust_bill_pay>) or credits (see L<FS::cust_credit_bill>).
  35
  36 =head1 METHODS
  37
  38 =over 4
  39
  40 =item insert
  41
  42 =cut
  43
  44 sub insert {
  45   my $self = shift;
  46
  47   local $SIG{HUP} = 'IGNORE';
  48   local $SIG{INT} = 'IGNORE';
  49   local $SIG{QUIT} = 'IGNORE';
  50   local $SIG{TERM} = 'IGNORE';
  51   local $SIG{TSTP} = 'IGNORE';
  52   local $SIG{PIPE} = 'IGNORE';
  53
  54   my $oldAutoCommit = $FS::UID::AutoCommit;
  55   local $FS::UID::AutoCommit = 0;
  56   my $dbh = dbh;
  57
  58   my $error =    $self->SUPER::insert(@_)
  59               || $self->apply_to_lineitems(@_);
  60   if ( $error ) {
  61     $dbh->rollback if $oldAutoCommit;
  62     return $error;
  63   }
  64
  65   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
  66
  67   '';
  68
  69 }
  70
  71 =item delete
  72
  73 =cut
  74
  75 sub delete {
  76   my $self = shift;
  77
  78   local $SIG{HUP} = 'IGNORE';
  79   local $SIG{INT} = 'IGNORE';
  80   local $SIG{QUIT} = 'IGNORE';
  81   local $SIG{TERM} = 'IGNORE';
  82   local $SIG{TSTP} = 'IGNORE';
  83   local $SIG{PIPE} = 'IGNORE';
  84
  85   my $oldAutoCommit = $FS::UID::AutoCommit;
  86   local $FS::UID::AutoCommit = 0;
  87   my $dbh = dbh;
  88
  89   foreach my $app ( $self->lineitem_applications ) {
  90     my $error = $app->delete;
  91     if ( $error ) {
  92       $dbh->rollback if $oldAutoCommit;
  93       return $error;
  94     }
  95   }
  96
  97   my $error = $self->SUPER::delete(@_);
  98   if ( $error ) {
  99     $dbh->rollback if $oldAutoCommit;
 100     return $error;
 101   }
 102
 103   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 104
 105   '';
 106
 107 }
 108
 109 =item apply_to_lineitems
 110
 111 Auto-applies this invoice application to specific line items, if possible.
 112
 113 =cut
 114
 115 sub calculate_applications {
 116   my( $self, %options ) = @_;
 117
 118   return '' if $skip_apply_to_lineitems_hack;
 119
 120   my @apply = ();
 121
 122   my $conf = new FS::Conf;
 123
 124   my @open = $self->cust_bill->open_cust_bill_pkg; #FOR UPDATE...?
 125
 126   if ( exists($options{subitems}) ) {
 127     my $i = 0;
 128     my %open = ();
 129     $open{$_->billpkgnum} = $i++ foreach @open;
 130
 131     foreach my $listref ( @{$options{subitems}} ) {
 132       my ($billpkgnum, $itemamount, $taxlocationnum) = @$listref;
 133       return "Can't apply a ". $self->_app_source_name. ' of $'. $listref->[1].
 134              " to line item $billpkgnum which is not open"
 135         unless exists($open{$billpkgnum});
 136       my $itemindex = $open{$billpkgnum};
 137       my %taxhash = ();
 138       if ($taxlocationnum) {
 139         %taxhash = map { ($_->primary_key => $_->get($_->primary_key)) }
 140                    grep { $_->get($_->primary_key) == $taxlocationnum }
 141                    $open[$itemindex]->cust_bill_pkg_tax_Xlocation;
 142
 143         return "No tax line item with a key value of $taxlocationnum exists"
 144           unless scalar(%taxhash);
 145       }
 146       push @apply, [ $open[$itemindex], $itemamount, { %taxhash } ];
 147     }
 148     return \@apply;
 149   }
 150
 151   @open = grep { $_->pkgnum == $self->pkgnum } @open
 152     if $conf->exists('pkg-balances') && $self->pkgnum;
 153   warn "$me ". scalar(@open). " open line items for invoice ".
 154        $self->cust_bill->invnum. ": ". join(', ', @open). "\n"
 155     if $DEBUG;
 156   my $total = 0;
 157   $total += $_->owed_setup + $_->owed_recur foreach @open;
 158   $total = sprintf('%.2f', $total);
 159
 160   if ( $self->amount > $total ) {
 161     return "Can't apply a ". $self->_app_source_name. ' of $'. $self->amount.
 162            " greater than the remaining owed on line items (\$$total)";
 163   }
 164
 165   #easy cases:
 166   # - one lineitem (a simple special case of:)
 167   # - amount is for whole invoice (well, all of remaining lineitem links)
 168   if ( $self->amount == $total ) {
 169
 170     warn "$me application amount covers remaining balance of invoice in full;".
 171          "applying to those lineitems\n"
 172       if $DEBUG;
 173
 174     #@apply = map { [ $_, $_->amount ]; } @open;
 175     @apply = map { [ $_, $_->owed_setup + 0 || $_->owed_recur + 0 ]; } @open;
 176
 177   } else {
 178
 179     #slightly magic case:
 180     # - amount exactly and uniquely matches a single open lineitem
 181     #   (you must be trying to pay or credit that item, then)
 182
 183     my @same = grep {    $_->owed_setup == $self->amount
 184                       || $_->owed_recur == $self->amount
 185                     }
 186                     @open;
 187     if ( scalar(@same) == 1 ) {
 188       warn "$me application amount exactly and uniquely matches one lineitem;".
 189            " applying to that lineitem\n"
 190         if $DEBUG;
 191       @apply = map { [ $_, $self->amount ]; } @same
 192     }
 193
 194   }
 195
 196   unless ( @apply ) {
 197
 198     warn "$me applying amount based on package weights\n"
 199       if $DEBUG;
 200
 201     #and the rest:
 202     # - apply based on weights...
 203
 204     my $weight_col = $self->_app_part_pkg_weight_column;
 205     my @openweight = map {
 206                            my $open = $_;
 207                            my $cust_pkg = $open->cust_pkg;
 208                            my $weight =
 209                              $cust_pkg
 210                                ? ( $cust_pkg->part_pkg->$weight_col() || 0 )
 211                                : -1; #default or per-tax weight?
 212                            [ $open, $weight ]
 213                          }
 214                          @open;
 215
 216     my %saw = ();
 217     my @weights = sort { $b <=> $a }     # highest weight first
 218                   grep { ! $saw{$_}++ }  # want a list of unique weights
 219                   map  { $_->[1] }
 220                        @openweight;
 221
 222     my $remaining_amount = $self->amount;
 223     foreach my $weight ( @weights ) {
 224
 225       #i hate it when my schwartz gets tangled
 226       my @items = map { $_->[0] } grep { $weight == $_->[1] } @openweight;
 227
 228       my $itemtotal = 0;
 229       foreach my $item (@items) { $itemtotal += $item->owed_setup + 0 || $item->owed_recur + 0; }
 230       my $applytotal = min( $itemtotal, $remaining_amount );
 231       $remaining_amount -= $applytotal;
 232
 233       warn "$me applying $applytotal ($remaining_amount remaining)".
 234            " to ". scalar(@items). " lineitems with weight $weight\n"
 235         if $DEBUG;
 236
 237       #if some items are less than applytotal/num_items, then apply then in full
 238       my $lessflag;
 239       do {
 240         $lessflag = 0;
 241
 242         #no, not sprintf("%.2f",
 243         # we want this rounded DOWN for purposes of checking for line items
 244         # less than it, we don't want .66666 becoming .67 and causing this
 245         # to trigger when it shouldn't
 246         my $applyeach = int( 100 * $applytotal / scalar(@items) ) / 100;
 247
 248         my @newitems = ();
 249         foreach my $item ( @items ) {
 250           my $itemamount = $item->owed_setup + 0 || $item->owed_recur + 0;
 251           if ( $itemamount < $applyeach ) {
 252             warn "$me applying full $itemamount".
 253                  " to small line item (cust_bill_pkg ". $item->billpkgnum. ")\n"
 254               if $DEBUG;
 255             push @apply, [ $item, $itemamount ];
 256             $applytotal -= $itemamount;
 257             $lessflag=1;
 258           } else {
 259             push @newitems, $item;
 260           }
 261         }
 262         @items = @newitems;
 263
 264       } while ( $lessflag );
 265
 266       #and now that we've fallen out of the loop, distribute the rest equally...
 267
 268       # should cust_bill_pay_pkg and cust_credit_bill_pkg amount columns
 269       # become real instead of numeric(10,2) ???  no..
 270       my $applyeach = sprintf("%.2f", $applytotal / scalar(@items) );
 271
 272       my @equi_apply = map { [ $_, $applyeach ] } @items;
 273
 274       # or should we futz with pennies instead?  yes, bah!
 275       my $diff =
 276         sprintf('%.0f', 100 * ( $applytotal - $applyeach * scalar(@items) ) );
 277       $diff = 0 if $diff eq '-0'; #yay ieee fp
 278       if ( abs($diff) > scalar(@items) ) {
 279         #we must have done something really wrong, the difference is more than
 280         #a penny an item
 281         return 'Error distributing pennies applying '. $self->_app_source_name.
 282                " - can't distribute difference of $diff pennies".
 283                ' among '. scalar(@items). ' line items';
 284       }
 285
 286       warn "$me futzing with $diff pennies difference\n"
 287         if $DEBUG && $diff;
 288
 289       my $futz = 0;
 290       while ( $diff != 0 && $futz < scalar(@equi_apply) ) {
 291         if ( $diff > 0 ) {
 292           $equi_apply[$futz++]->[1] += .01;
 293           $diff -= 1;
 294         } elsif ( $diff < 0 ) {
 295           $equi_apply[$futz++]->[1] -= .01;
 296           $diff += 1;
 297         } else {
 298           die "guru exception #5 (in fortran tongue the answer)";
 299         }
 300       }
 301
 302       if ( sprintf('%.0f', $diff ) ) {
 303         return "couldn't futz with pennies enough: still $diff left";
 304       }
 305
 306       if ( $DEBUG ) {
 307         warn "$me applying ". $_->[1].
 308              " to line item (cust_bill_pkg ". $_->[0]->billpkgnum. ")\n"
 309           foreach @equi_apply;
 310       }
 311
 312
 313       push @apply, @equi_apply;
 314
 315       #$remaining_amount -= $applytotal;
 316       last unless $remaining_amount;
 317
 318     }
 319
 320   }
 321
 322   # break down lineitem amounts for tax lines
 323   # could expand @open above, instead, for a slightly different magic effect
 324   my @result = ();
 325   foreach my $apply ( @apply ) {
 326     my @sub_lines = $apply->[0]->cust_bill_pkg_tax_Xlocation;
 327     my $amount = $apply->[1];
 328     warn "applying ". $apply->[1]. " to ". $apply->[0]->desc
 329       if $DEBUG;
 330
 331     foreach my $subline ( @sub_lines ) {
 332       my $owed = $subline->owed;
 333       push @result, [ $apply->[0],
 334                       sprintf('%.2f', min($amount, $owed) ),
 335                       { $subline->primary_key => $subline->get($subline->primary_key) },
 336                     ];
 337       $amount -= $owed;
 338       $amount = 0 if $amount < 0;
 339       last unless $amount;
 340     }
 341     if ( $amount > 0 ) {
 342       push @result, [ $apply->[0], sprintf('%.2f', $amount), {} ];
 343     }
 344   }
 345
 346   \@result;
 347
 348 }
 349
 350 sub apply_to_lineitems {
 351   #my $self = shift;
 352   my( $self, %options ) = @_;
 353
 354   return '' if $skip_apply_to_lineitems_hack;
 355
 356
 357
 358   my $conf = new FS::Conf;
 359
 360   local $SIG{HUP} = 'IGNORE';
 361   local $SIG{INT} = 'IGNORE';
 362   local $SIG{QUIT} = 'IGNORE';
 363   local $SIG{TERM} = 'IGNORE';
 364   local $SIG{TSTP} = 'IGNORE';
 365   local $SIG{PIPE} = 'IGNORE';
 366
 367   my $oldAutoCommit = $FS::UID::AutoCommit;
 368   local $FS::UID::AutoCommit = 0;
 369   my $dbh = dbh;
 370
 371   my $listref_or_error = $self->calculate_applications(%options);
 372   unless (ref($listref_or_error)) {
 373     $dbh->rollback if $oldAutoCommit;
 374     return $listref_or_error;
 375   }
 376
 377   my @apply = @$listref_or_error;
 378
 379   # do the applicaiton(s)
 380   my $table = $self->lineitem_breakdown_table;
 381   my $source_key = dbdef->table($self->table)->primary_key;
 382   my $applied = 0;
 383   foreach my $apply ( @apply ) {
 384     my ( $cust_bill_pkg, $amount, $taxcreditref ) = @$apply;
 385     $applied += $amount;
 386     my $application = "FS::$table"->new( {
 387       $source_key  => $self->$source_key(),
 388       'billpkgnum' => $cust_bill_pkg->billpkgnum,
 389       'amount'     => sprintf('%.2f', $amount),
 390       'setuprecur' => ( $cust_bill_pkg->setup > 0 ? 'setup' : 'recur' ),
 391       'sdate'      => $cust_bill_pkg->sdate,
 392       'edate'      => $cust_bill_pkg->edate,
 393       %$taxcreditref,
 394     });
 395     my $error = $application->insert(%options);
 396     if ( $error ) {
 397       $dbh->rollback if $oldAutoCommit;
 398       return $error;
 399     }
 400   }
 401
 402   #everything should always be applied to line items in full now... sanity check
 403   $applied = sprintf('%.2f', $applied);
 404   unless ( $applied == $self->amount ) {
 405     $dbh->rollback if $oldAutoCommit;
 406     return 'Error applying '. $self->_app_source_name. ' of $'. $self->amount.
 407            ' to line items - only $'. $applied. ' was applied.';
 408   }
 409
 410   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 411   '';
 412
 413 }
 414
 415 =item lineitem_applications
 416
 417 Returns all the specific line item applications for this invoice application.
 418
 419 =cut
 420
 421 sub lineitem_applications {
 422   my $self = shift;
 423   my $primary_key = dbdef->table($self->table)->primary_key;
 424   qsearch({
 425     'table'   => $self->lineitem_breakdown_table,
 426     'hashref' => { $primary_key => $self->$primary_key() },
 427   });
 428
 429 }
 430
 431 =item cust_bill
 432
 433 Returns the invoice (see L<FS::cust_bill>)
 434
 435 =cut
 436
 437 sub cust_bill {
 438   my $self = shift;
 439   qsearchs( 'cust_bill', { 'invnum' => $self->invnum } );
 440 }
 441
 442 =item applied_to_invoice
 443
 444 Returns a string representing the invoice (see L<FS::cust_bill>), for example:
 445 "applied to Invoice #54 (3/20/2008)"
 446
 447 =cut
 448
 449 sub applied_to_invoice {
 450   my $self = shift;
 451   'applied to '. $self->cust_bill->invnum_date_pretty;
 452 }
 453
 454 =item lineitem_breakdown_table
 455
 456 =cut
 457
 458 sub lineitem_breakdown_table {
 459   my $self = shift;
 460   $self->_load_table($self->_app_lineitem_breakdown_table);
 461 }
 462
 463 sub _load_table {
 464   my( $self, $table ) = @_;
 465   eval "use FS::$table";
 466   die $@ if $@;
 467   $table;
 468 }
 469
 470 =back
 471
 472 =head1 BUGS
 473
 474 =head1 SEE ALSO
 475
 476 L<FS::cust_bill_pay> and L<FS::cust_bill_pay_pkg>,
 477 L<FS::cust_credit_bill> and L<FS::cust_credit_bill_pkg>
 478
 479 =cut
 480
 481 1;
 482