FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf $money_char );
   5 use vars qw( $invoice_lines @buf ); #yuck
   6 use Fcntl qw(:flock); #for spool_csv
   7 use List::Util qw(min max);
   8 use Date::Format;
   9 use Text::Template 1.20;
  10 use File::Temp 0.14;
  11 use String::ShellQuote;
  12 use HTML::Entities;
  13 use Locale::Country;
  14 use FS::UID qw( datasrc );
  15 use FS::Misc qw( send_email send_fax generate_ps do_print );
  16 use FS::Record qw( qsearch qsearchs dbh );
  17 use FS::cust_main_Mixin;
  18 use FS::cust_main;
  19 use FS::cust_bill_pkg;
  20 use FS::cust_credit;
  21 use FS::cust_pay;
  22 use FS::cust_pkg;
  23 use FS::cust_credit_bill;
  24 use FS::pay_batch;
  25 use FS::cust_pay_batch;
  26 use FS::cust_bill_event;
  27 use FS::cust_event;
  28 use FS::part_pkg;
  29 use FS::cust_bill_pay;
  30 use FS::cust_bill_pay_batch;
  31 use FS::part_bill_event;
  32 use FS::payby;
  33
  34 @ISA = qw( FS::cust_main_Mixin FS::Record );
  35
  36 $DEBUG = 0;
  37 $me = '[FS::cust_bill]';
  38
  39 #ask FS::UID to run this stuff for us later
  40 FS::UID->install_callback( sub {
  41   $conf = new FS::Conf;
  42   $money_char = $conf->config('money_char') || '$';
  43 } );
  44
  45 =head1 NAME
  46
  47 FS::cust_bill - Object methods for cust_bill records
  48
  49 =head1 SYNOPSIS
  50
  51   use FS::cust_bill;
  52
  53   $record = new FS::cust_bill \%hash;
  54   $record = new FS::cust_bill { 'column' => 'value' };
  55
  56   $error = $record->insert;
  57
  58   $error = $new_record->replace($old_record);
  59
  60   $error = $record->delete;
  61
  62   $error = $record->check;
  63
  64   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  65
  66   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  67
  68   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  69
  70   @cust_pay_objects = $cust_bill->cust_pay;
  71
  72   $tax_amount = $record->tax;
  73
  74   @lines = $cust_bill->print_text;
  75   @lines = $cust_bill->print_text $time;
  76
  77 =head1 DESCRIPTION
  78
  79 An FS::cust_bill object represents an invoice; a declaration that a customer
  80 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
  81 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
  82 following fields are currently supported:
  83
  84 =over 4
  85
  86 =item invnum - primary key (assigned automatically for new invoices)
  87
  88 =item custnum - customer (see L<FS::cust_main>)
  89
  90 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  91 L<Time::Local> and L<Date::Parse> for conversion functions.
  92
  93 =item charged - amount of this invoice
  94
  95 =item printed - deprecated
  96
  97 =item closed - books closed flag, empty or `Y'
  98
  99 =back
 100
 101 =head1 METHODS
 102
 103 =over 4
 104
 105 =item new HASHREF
 106
 107 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 108 Invoices are normally created by calling the bill method of a customer object
 109 (see L<FS::cust_main>).
 110
 111 =cut
 112
 113 sub table { 'cust_bill'; }
 114
 115 sub cust_linked { $_[0]->cust_main_custnum; }
 116 sub cust_unlinked_msg {
 117   my $self = shift;
 118   "WARNING: can't find cust_main.custnum ". $self->custnum.
 119   ' (cust_bill.invnum '. $self->invnum. ')';
 120 }
 121
 122 =item insert
 123
 124 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 125 returns the error, otherwise returns false.
 126
 127 =item delete
 128
 129 This method now works but you probably shouldn't use it.  Instead, apply a
 130 credit against the invoice.
 131
 132 Using this method to delete invoices outright is really, really bad.  There
 133 would be no record you ever posted this invoice, and there are no check to
 134 make sure charged = 0 or that there are no associated cust_bill_pkg records.
 135
 136 Really, don't use it.
 137
 138 =cut
 139
 140 sub delete {
 141   my $self = shift;
 142   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 143   $self->SUPER::delete(@_);
 144 }
 145
 146 =item replace OLD_RECORD
 147
 148 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 149 returns the error, otherwise returns false.
 150
 151 Only printed may be changed.  printed is normally updated by calling the
 152 collect method of a customer object (see L<FS::cust_main>).
 153
 154 =cut
 155
 156 #replace can be inherited from Record.pm
 157
 158 # replace_check is now the preferred way to #implement replace data checks
 159 # (so $object->replace() works without an argument)
 160
 161 sub replace_check {
 162   my( $new, $old ) = ( shift, shift );
 163   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 164   #return "Can't change _date!" unless $old->_date eq $new->_date;
 165   return "Can't change _date!" unless $old->_date == $new->_date;
 166   return "Can't change charged!" unless $old->charged == $new->charged
 167                                      || $old->charged == 0;
 168
 169   '';
 170 }
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid invoice.  If there is an error,
 175 returns the error, otherwise returns false.  Called by the insert and replace
 176 methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('invnum')
 185     || $self->ut_number('custnum')
 186     || $self->ut_numbern('_date')
 187     || $self->ut_money('charged')
 188     || $self->ut_numbern('printed')
 189     || $self->ut_enum('closed', [ '', 'Y' ])
 190   ;
 191   return $error if $error;
 192
 193   return "Unknown customer"
 194     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 195
 196   $self->_date(time) unless $self->_date;
 197
 198   $self->printed(0) if $self->printed eq '';
 199
 200   $self->SUPER::check;
 201 }
 202
 203 =item previous
 204
 205 Returns a list consisting of the total previous balance for this customer,
 206 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 207
 208 =cut
 209
 210 sub previous {
 211   my $self = shift;
 212   my $total = 0;
 213   my @cust_bill = sort { $a->_date <=> $b->_date }
 214     grep { $_->owed != 0 && $_->_date < $self->_date }
 215       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 216   ;
 217   foreach ( @cust_bill ) { $total += $_->owed; }
 218   $total, @cust_bill;
 219 }
 220
 221 =item cust_bill_pkg
 222
 223 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 224
 225 =cut
 226
 227 sub cust_bill_pkg {
 228   my $self = shift;
 229   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 230 }
 231
 232 =item cust_pkg
 233
 234 Returns the packages (see L<FS::cust_pkg>) corresponding to the line items for
 235 this invoice.
 236
 237 =cut
 238
 239 sub cust_pkg {
 240   my $self = shift;
 241   my @cust_pkg = map { $_->cust_pkg } $self->cust_bill_pkg;
 242   my %saw = ();
 243   grep { ! $saw{$_->pkgnum}++ } @cust_pkg;
 244 }
 245
 246 =item open_cust_bill_pkg
 247
 248 Returns the open line items for this invoice.
 249
 250 Note that cust_bill_pkg with both setup and recur fees are returned as two
 251 separate line items, each with only one fee.
 252
 253 =cut
 254
 255 # modeled after cust_main::open_cust_bill
 256 sub open_cust_bill_pkg {
 257   my $self = shift;
 258
 259   # grep { $_->owed > 0 } $self->cust_bill_pkg
 260
 261   my %other = ( 'recur' => 'setup',
 262                 'setup' => 'recur', );
 263   my @open = ();
 264   foreach my $field ( qw( recur setup )) {
 265     push @open, map  { $_->set( $other{$field}, 0 ); $_; }
 266                 grep { $_->owed($field) > 0 }
 267                 $self->cust_bill_pkg;
 268   }
 269
 270   @open;
 271 }
 272
 273 =item cust_bill_event
 274
 275 Returns the completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 276
 277 =cut
 278
 279 sub cust_bill_event {
 280   my $self = shift;
 281   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 282 }
 283
 284 =item num_cust_bill_event
 285
 286 Returns the number of completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 287
 288 =cut
 289
 290 sub num_cust_bill_event {
 291   my $self = shift;
 292   my $sql =
 293     "SELECT COUNT(*) FROM cust_bill_event WHERE invnum = ?";
 294   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 295   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 296   $sth->fetchrow_arrayref->[0];
 297 }
 298
 299 =item cust_event
 300
 301 Returns the new-style customer billing events (see L<FS::cust_event>) for this invoice.
 302
 303 =cut
 304
 305 #false laziness w/cust_pkg.pm
 306 sub cust_event {
 307   my $self = shift;
 308   qsearch({
 309     'table'     => 'cust_event',
 310     'addl_from' => 'JOIN part_event USING ( eventpart )',
 311     'hashref'   => { 'tablenum' => $self->invnum },
 312     'extra_sql' => " AND eventtable = 'cust_bill' ",
 313   });
 314 }
 315
 316 =item num_cust_event
 317
 318 Returns the number of new-style customer billing events (see L<FS::cust_event>) for this invoice.
 319
 320 =cut
 321
 322 #false laziness w/cust_pkg.pm
 323 sub num_cust_event {
 324   my $self = shift;
 325   my $sql =
 326     "SELECT COUNT(*) FROM cust_event JOIN part_event USING ( eventpart ) ".
 327     "  WHERE tablenum = ? AND eventtable = 'cust_bill'";
 328   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 329   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 330   $sth->fetchrow_arrayref->[0];
 331 }
 332
 333 =item cust_main
 334
 335 Returns the customer (see L<FS::cust_main>) for this invoice.
 336
 337 =cut
 338
 339 sub cust_main {
 340   my $self = shift;
 341   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 342 }
 343
 344 =item cust_suspend_if_balance_over AMOUNT
 345
 346 Suspends the customer associated with this invoice if the total amount owed on
 347 this invoice and all older invoices is greater than the specified amount.
 348
 349 Returns a list: an empty list on success or a list of errors.
 350
 351 =cut
 352
 353 sub cust_suspend_if_balance_over {
 354   my( $self, $amount ) = ( shift, shift );
 355   my $cust_main = $self->cust_main;
 356   if ( $cust_main->total_owed_date($self->_date) < $amount ) {
 357     return ();
 358   } else {
 359     $cust_main->suspend(@_);
 360   }
 361 }
 362
 363 =item cust_credit
 364
 365 Depreciated.  See the cust_credited method.
 366
 367  #Returns a list consisting of the total previous credited (see
 368  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 369  #outstanding credits (FS::cust_credit objects).
 370
 371 =cut
 372
 373 sub cust_credit {
 374   use Carp;
 375   croak "FS::cust_bill->cust_credit depreciated; see ".
 376         "FS::cust_bill->cust_credit_bill";
 377   #my $self = shift;
 378   #my $total = 0;
 379   #my @cust_credit = sort { $a->_date <=> $b->_date }
 380   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 381   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 382   #;
 383   #foreach (@cust_credit) { $total += $_->credited; }
 384   #$total, @cust_credit;
 385 }
 386
 387 =item cust_pay
 388
 389 Depreciated.  See the cust_bill_pay method.
 390
 391 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 392
 393 =cut
 394
 395 sub cust_pay {
 396   use Carp;
 397   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 398   #my $self = shift;
 399   #sort { $a->_date <=> $b->_date }
 400   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 401   #;
 402 }
 403
 404 =item cust_bill_pay
 405
 406 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 407
 408 =cut
 409
 410 sub cust_bill_pay {
 411   my $self = shift;
 412   sort { $a->_date <=> $b->_date }
 413     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 414 }
 415
 416 =item cust_credited
 417
 418 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 419
 420 =cut
 421
 422 sub cust_credited {
 423   my $self = shift;
 424   sort { $a->_date <=> $b->_date }
 425     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 426   ;
 427 }
 428
 429 =item tax
 430
 431 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 432
 433 =cut
 434
 435 sub tax {
 436   my $self = shift;
 437   my $total = 0;
 438   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 439                                              'pkgnum' => 0 } );
 440   foreach (@taxlines) { $total += $_->setup; }
 441   $total;
 442 }
 443
 444 =item owed
 445
 446 Returns the amount owed (still outstanding) on this invoice, which is charged
 447 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 448 applications (see L<FS::cust_credit_bill>).
 449
 450 =cut
 451
 452 sub owed {
 453   my $self = shift;
 454   my $balance = $self->charged;
 455   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 456   $balance -= $_->amount foreach ( $self->cust_credited );
 457   $balance = sprintf( "%.2f", $balance);
 458   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 459   $balance;
 460 }
 461
 462 =item apply_payments_and_credits
 463
 464 =cut
 465
 466 sub apply_payments_and_credits {
 467   my $self = shift;
 468
 469   local $SIG{HUP} = 'IGNORE';
 470   local $SIG{INT} = 'IGNORE';
 471   local $SIG{QUIT} = 'IGNORE';
 472   local $SIG{TERM} = 'IGNORE';
 473   local $SIG{TSTP} = 'IGNORE';
 474   local $SIG{PIPE} = 'IGNORE';
 475
 476   my $oldAutoCommit = $FS::UID::AutoCommit;
 477   local $FS::UID::AutoCommit = 0;
 478   my $dbh = dbh;
 479
 480   $self->select_for_update; #mutex
 481
 482   my @payments = grep { $_->unapplied > 0 } $self->cust_main->cust_pay;
 483   my @credits  = grep { $_->credited > 0 } $self->cust_main->cust_credit;
 484
 485   while ( $self->owed > 0 and ( @payments || @credits ) ) {
 486
 487     my $app = '';
 488     if ( @payments && @credits ) {
 489
 490       #decide which goes first by weight of top (unapplied) line item
 491
 492       my @open_lineitems = $self->open_cust_bill_pkg;
 493
 494       my $max_pay_weight =
 495         max( map  { $_->part_pkg->pay_weight || 0 }
 496              grep { $_ }
 497              map  { $_->cust_pkg }
 498                   @open_lineitems
 499            );
 500       my $max_credit_weight =
 501         max( map  { $_->part_pkg->credit_weight || 0 }
 502              grep { $_ }
 503              map  { $_->cust_pkg }
 504                   @open_lineitems
 505            );
 506
 507       #if both are the same... payments first?  it has to be something
 508       if ( $max_pay_weight >= $max_credit_weight ) {
 509         $app = 'pay';
 510       } else {
 511         $app = 'credit';
 512       }
 513
 514     } elsif ( @payments ) {
 515       $app = 'pay';
 516     } elsif ( @credits ) {
 517       $app = 'credit';
 518     } else {
 519       die "guru meditation #12 and 35";
 520     }
 521
 522     if ( $app eq 'pay' ) {
 523
 524       my $payment = shift @payments;
 525
 526       $app = new FS::cust_bill_pay {
 527         'paynum'  => $payment->paynum,
 528         'amount'  => sprintf('%.2f', min( $payment->unapplied, $self->owed ) ),
 529       };
 530
 531     } elsif ( $app eq 'credit' ) {
 532
 533       my $credit = shift @credits;
 534
 535       $app = new FS::cust_credit_bill {
 536         'crednum' => $credit->crednum,
 537         'amount'  => sprintf('%.2f', min( $credit->credited, $self->owed ) ),
 538       };
 539
 540     } else {
 541       die "guru meditation #12 and 35";
 542     }
 543
 544     $app->invnum( $self->invnum );
 545
 546     my $error = $app->insert;
 547     if ( $error ) {
 548       $dbh->rollback if $oldAutoCommit;
 549       return "Error inserting ". $app->table. " record: $error";
 550     }
 551     die $error if $error;
 552
 553   }
 554
 555   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 556   ''; #no error
 557
 558 }
 559
 560 =item generate_email PARAMHASH
 561
 562 PARAMHASH can contain the following:
 563
 564 =over 4
 565
 566 =item from       => sender address, required
 567
 568 =item tempate    => alternate template name, optional
 569
 570 =item print_text => text attachment arrayref, optional
 571
 572 =item subject    => email subject, optional
 573
 574 =back
 575
 576 Returns an argument list to be passed to L<FS::Misc::send_email>.
 577
 578 =cut
 579
 580 use MIME::Entity;
 581
 582 sub generate_email {
 583
 584   my $self = shift;
 585   my %args = @_;
 586
 587   my $me = '[FS::cust_bill::generate_email]';
 588
 589   my %return = (
 590     'from'      => $args{'from'},
 591     'subject'   => (($args{'subject'}) ? $args{'subject'} : 'Invoice'),
 592   );
 593
 594   if (ref($args{'to'}) eq 'ARRAY') {
 595     $return{'to'} = $args{'to'};
 596   } else {
 597     $return{'to'} = [ grep { $_ !~ /^(POST|FAX)$/ }
 598                            $self->cust_main->invoicing_list
 599                     ];
 600   }
 601
 602   if ( $conf->exists('invoice_html') ) {
 603
 604     warn "$me creating HTML/text multipart message"
 605       if $DEBUG;
 606
 607     $return{'nobody'} = 1;
 608
 609     my $alternative = build MIME::Entity
 610       'Type'        => 'multipart/alternative',
 611       'Encoding'    => '7bit',
 612       'Disposition' => 'inline'
 613     ;
 614
 615     my $data;
 616     if ( $conf->exists('invoice_email_pdf')
 617          and scalar($conf->config('invoice_email_pdf_note')) ) {
 618
 619       warn "$me using 'invoice_email_pdf_note' in multipart message"
 620         if $DEBUG;
 621       $data = [ map { $_ . "\n" }
 622                     $conf->config('invoice_email_pdf_note')
 623               ];
 624
 625     } else {
 626
 627       warn "$me not using 'invoice_email_pdf_note' in multipart message"
 628         if $DEBUG;
 629       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 630         $data = $args{'print_text'};
 631       } else {
 632         $data = [ $self->print_text('', $args{'template'}) ];
 633       }
 634
 635     }
 636
 637     $alternative->attach(
 638       'Type'        => 'text/plain',
 639       #'Encoding'    => 'quoted-printable',
 640       'Encoding'    => '7bit',
 641       'Data'        => $data,
 642       'Disposition' => 'inline',
 643     );
 644
 645     $args{'from'} =~ /\@([\w\.\-]+)/;
 646     my $from = $1 || 'example.com';
 647     my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
 648
 649     my $path = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
 650     my $file;
 651     if ( defined($args{'template'}) && length($args{'template'})
 652          && -e "$path/logo_". $args{'template'}. ".png"
 653        )
 654     {
 655       $file = "$path/logo_". $args{'template'}. ".png";
 656     } else {
 657       $file = "$path/logo.png";
 658     }
 659
 660     my $image = build MIME::Entity
 661       'Type'       => 'image/png',
 662       'Encoding'   => 'base64',
 663       'Path'       => $file,
 664       'Filename'   => 'logo.png',
 665       'Content-ID' => "<$content_id>",
 666     ;
 667
 668     $alternative->attach(
 669       'Type'        => 'text/html',
 670       'Encoding'    => 'quoted-printable',
 671       'Data'        => [ '<html>',
 672                          '  <head>',
 673                          '    <title>',
 674                          '      '. encode_entities($return{'subject'}),
 675                          '    </title>',
 676                          '  </head>',
 677                          '  <body bgcolor="#e8e8e8">',
 678                          $self->print_html('', $args{'template'}, $content_id),
 679                          '  </body>',
 680                          '</html>',
 681                        ],
 682       'Disposition' => 'inline',
 683       #'Filename'    => 'invoice.pdf',
 684     );
 685
 686     if ( $conf->exists('invoice_email_pdf') ) {
 687
 688       #attaching pdf too:
 689       # multipart/mixed
 690       #   multipart/related
 691       #     multipart/alternative
 692       #       text/plain
 693       #       text/html
 694       #     image/png
 695       #   application/pdf
 696
 697       my $related = build MIME::Entity 'Type'     => 'multipart/related',
 698                                        'Encoding' => '7bit';
 699
 700       #false laziness w/Misc::send_email
 701       $related->head->replace('Content-type',
 702         $related->mime_type.
 703         '; boundary="'. $related->head->multipart_boundary. '"'.
 704         '; type=multipart/alternative'
 705       );
 706
 707       $related->add_part($alternative);
 708
 709       $related->add_part($image);
 710
 711       my $pdf = build MIME::Entity $self->mimebuild_pdf('', $args{'template'});
 712
 713       $return{'mimeparts'} = [ $related, $pdf ];
 714
 715     } else {
 716
 717       #no other attachment:
 718       # multipart/related
 719       #   multipart/alternative
 720       #     text/plain
 721       #     text/html
 722       #   image/png
 723
 724       $return{'content-type'} = 'multipart/related';
 725       $return{'mimeparts'} = [ $alternative, $image ];
 726       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
 727       #$return{'disposition'} = 'inline';
 728
 729     }
 730
 731   } else {
 732
 733     if ( $conf->exists('invoice_email_pdf') ) {
 734       warn "$me creating PDF attachment"
 735         if $DEBUG;
 736
 737       #mime parts arguments a la MIME::Entity->build().
 738       $return{'mimeparts'} = [
 739         { $self->mimebuild_pdf('', $args{'template'}) }
 740       ];
 741     }
 742
 743     if ( $conf->exists('invoice_email_pdf')
 744          and scalar($conf->config('invoice_email_pdf_note')) ) {
 745
 746       warn "$me using 'invoice_email_pdf_note'"
 747         if $DEBUG;
 748       $return{'body'} = [ map { $_ . "\n" }
 749                               $conf->config('invoice_email_pdf_note')
 750                         ];
 751
 752     } else {
 753
 754       warn "$me not using 'invoice_email_pdf_note'"
 755         if $DEBUG;
 756       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 757         $return{'body'} = $args{'print_text'};
 758       } else {
 759         $return{'body'} = [ $self->print_text('', $args{'template'}) ];
 760       }
 761
 762     }
 763
 764   }
 765
 766   %return;
 767
 768 }
 769
 770 =item mimebuild_pdf
 771
 772 Returns a list suitable for passing to MIME::Entity->build(), representing
 773 this invoice as PDF attachment.
 774
 775 =cut
 776
 777 sub mimebuild_pdf {
 778   my $self = shift;
 779   (
 780     'Type'        => 'application/pdf',
 781     'Encoding'    => 'base64',
 782     'Data'        => [ $self->print_pdf(@_) ],
 783     'Disposition' => 'attachment',
 784     'Filename'    => 'invoice.pdf',
 785   );
 786 }
 787
 788 =item send [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 789
 790 Sends this invoice to the destinations configured for this customer: sends
 791 email, prints and/or faxes.  See L<FS::cust_main_invoice>.
 792
 793 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 794
 795 AGENTNUM, if specified, means that this invoice will only be sent for customers
 796 of the specified agent or agent(s).  AGENTNUM can be a scalar agentnum (for a
 797 single agent) or an arrayref of agentnums.
 798
 799 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 800
 801 =cut
 802
 803 sub queueable_send {
 804   my %opt = @_;
 805
 806   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 807     or die "invalid invoice number: " . $opt{invnum};
 808
 809   my @args = ( $opt{template}, $opt{agentnum} );
 810   push @args, $opt{invoice_from}
 811     if exists($opt{invoice_from}) && $opt{invoice_from};
 812
 813   my $error = $self->send( @args );
 814   die $error if $error;
 815
 816 }
 817
 818 sub send {
 819   my $self = shift;
 820   my $template = scalar(@_) ? shift : '';
 821   if ( scalar(@_) && $_[0]  ) {
 822     my $agentnums = ref($_[0]) ? shift : [ shift ];
 823     return 'N/A' unless grep { $_ == $self->cust_main->agentnum } @$agentnums;
 824   }
 825
 826   my $invoice_from =
 827     scalar(@_)
 828       ? shift
 829       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 830
 831   my @invoicing_list = $self->cust_main->invoicing_list;
 832
 833   $self->email($template, $invoice_from)
 834     if grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list or !@invoicing_list;
 835
 836   $self->print($template)
 837     if grep { $_ eq 'POST' } @invoicing_list; #postal
 838
 839   $self->fax($template)
 840     if grep { $_ eq 'FAX' } @invoicing_list; #fax
 841
 842   '';
 843
 844 }
 845
 846 =item email [ TEMPLATENAME  [ , INVOICE_FROM ] ]
 847
 848 Emails this invoice.
 849
 850 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 851
 852 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 853
 854 =cut
 855
 856 sub queueable_email {
 857   my %opt = @_;
 858
 859   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 860     or die "invalid invoice number: " . $opt{invnum};
 861
 862   my @args = ( $opt{template} );
 863   push @args, $opt{invoice_from}
 864     if exists($opt{invoice_from}) && $opt{invoice_from};
 865
 866   my $error = $self->email( @args );
 867   die $error if $error;
 868
 869 }
 870
 871 sub email {
 872   my $self = shift;
 873   my $template = scalar(@_) ? shift : '';
 874   my $invoice_from =
 875     scalar(@_)
 876       ? shift
 877       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 878
 879   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 880                             $self->cust_main->invoicing_list;
 881
 882   #better to notify this person than silence
 883   @invoicing_list = ($invoice_from) unless @invoicing_list;
 884
 885   my $error = send_email(
 886     $self->generate_email(
 887       'from'       => $invoice_from,
 888       'to'         => [ grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list ],
 889       'template'   => $template,
 890     )
 891   );
 892   die "can't email invoice: $error\n" if $error;
 893   #die "$error\n" if $error;
 894
 895 }
 896
 897 =item lpr_data [ TEMPLATENAME ]
 898
 899 Returns the postscript or plaintext for this invoice as an arrayref.
 900
 901 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 902
 903 =cut
 904
 905 sub lpr_data {
 906   my( $self, $template) = @_;
 907   $conf->exists('invoice_latex')
 908     ? [ $self->print_ps('', $template) ]
 909     : [ $self->print_text('', $template) ];
 910 }
 911
 912 =item print [ TEMPLATENAME ]
 913
 914 Prints this invoice.
 915
 916 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 917
 918 =cut
 919
 920 sub print {
 921   my $self = shift;
 922   my $template = scalar(@_) ? shift : '';
 923
 924   do_print $self->lpr_data($template);
 925 }
 926
 927 =item fax [ TEMPLATENAME ]
 928
 929 Faxes this invoice.
 930
 931 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 932
 933 =cut
 934
 935 sub fax {
 936   my $self = shift;
 937   my $template = scalar(@_) ? shift : '';
 938
 939   die 'FAX invoice destination not (yet?) supported with plain text invoices.'
 940     unless $conf->exists('invoice_latex');
 941
 942   my $dialstring = $self->cust_main->getfield('fax');
 943   #Check $dialstring?
 944
 945   my $error = send_fax( 'docdata'    => $self->lpr_data($template),
 946                         'dialstring' => $dialstring,
 947                       );
 948   die $error if $error;
 949
 950 }
 951
 952 =item send_if_newest [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 953
 954 Like B<send>, but only sends the invoice if it is the newest open invoice for
 955 this customer.
 956
 957 =cut
 958
 959 sub send_if_newest {
 960   my $self = shift;
 961
 962   return ''
 963     if scalar(
 964                grep { $_->owed > 0 }
 965                     qsearch('cust_bill', {
 966                       'custnum' => $self->custnum,
 967                       #'_date'   => { op=>'>', value=>$self->_date },
 968                       'invnum'  => { op=>'>', value=>$self->invnum },
 969                     } )
 970              );
 971
 972   $self->send(@_);
 973 }
 974
 975 =item send_csv OPTION => VALUE, ...
 976
 977 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 978
 979 Options are:
 980
 981 protocol - currently only "ftp"
 982 server
 983 username
 984 password
 985 dir
 986
 987 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 988 and YYMMDDHHMMSS is a timestamp.
 989
 990 See L</print_csv> for a description of the output format.
 991
 992 =cut
 993
 994 sub send_csv {
 995   my($self, %opt) = @_;
 996
 997   #create file(s)
 998
 999   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1000   mkdir $spooldir, 0700 unless -d $spooldir;
1001
1002   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1003   my $file = "$spooldir/$tracctnum.csv";
1004
1005   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1006
1007   open(CSV, ">$file") or die "can't open $file: $!";
1008   print CSV $header;
1009
1010   print CSV $detail;
1011
1012   close CSV;
1013
1014   my $net;
1015   if ( $opt{protocol} eq 'ftp' ) {
1016     eval "use Net::FTP;";
1017     die $@ if $@;
1018     $net = Net::FTP->new($opt{server}) or die @$;
1019   } else {
1020     die "unknown protocol: $opt{protocol}";
1021   }
1022
1023   $net->login( $opt{username}, $opt{password} )
1024     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
1025
1026   $net->binary or die "can't set binary mode";
1027
1028   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
1029
1030   $net->put($file) or die "can't put $file: $!";
1031
1032   $net->quit;
1033
1034   unlink $file;
1035
1036 }
1037
1038 =item spool_csv
1039
1040 Spools CSV invoice data.
1041
1042 Options are:
1043
1044 =over 4
1045
1046 =item format - 'default' or 'billco'
1047
1048 =item dest - if set (to POST, EMAIL or FAX), only sends spools invoices if the customer has the corresponding invoice destinations set (see L<FS::cust_main_invoice>).
1049
1050 =item agent_spools - if set to a true value, will spool to per-agent files rather than a single global file
1051
1052 =item balanceover - if set, only spools the invoice if the total amount owed on this invoice and all older invoices is greater than the specified amount.
1053
1054 =back
1055
1056 =cut
1057
1058 sub spool_csv {
1059   my($self, %opt) = @_;
1060
1061   my $cust_main = $self->cust_main;
1062
1063   if ( $opt{'dest'} ) {
1064     my %invoicing_list = map { /^(POST|FAX)$/ or 'EMAIL' =~ /^(.*)$/; $1 => 1 }
1065                              $cust_main->invoicing_list;
1066     return 'N/A' unless $invoicing_list{$opt{'dest'}}
1067                      || ! keys %invoicing_list;
1068   }
1069
1070   if ( $opt{'balanceover'} ) {
1071     return 'N/A'
1072       if $cust_main->total_owed_date($self->_date) < $opt{'balanceover'};
1073   }
1074
1075   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1076   mkdir $spooldir, 0700 unless -d $spooldir;
1077
1078   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1079
1080   my $file =
1081     "$spooldir/".
1082     ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1083     ( lc($opt{'format'}) eq 'billco' ? '-header' : '' ) .
1084     '.csv';
1085
1086   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1087
1088   open(CSV, ">>$file") or die "can't open $file: $!";
1089   flock(CSV, LOCK_EX);
1090   seek(CSV, 0, 2);
1091
1092   print CSV $header;
1093
1094   if ( lc($opt{'format'}) eq 'billco' ) {
1095
1096     flock(CSV, LOCK_UN);
1097     close CSV;
1098
1099     $file =
1100       "$spooldir/".
1101       ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1102       '-detail.csv';
1103
1104     open(CSV,">>$file") or die "can't open $file: $!";
1105     flock(CSV, LOCK_EX);
1106     seek(CSV, 0, 2);
1107   }
1108
1109   print CSV $detail;
1110
1111   flock(CSV, LOCK_UN);
1112   close CSV;
1113
1114   return '';
1115
1116 }
1117
1118 =item print_csv OPTION => VALUE, ...
1119
1120 Returns CSV data for this invoice.
1121
1122 Options are:
1123
1124 format - 'default' or 'billco'
1125
1126 Returns a list consisting of two scalars.  The first is a single line of CSV
1127 header information for this invoice.  The second is one or more lines of CSV
1128 detail information for this invoice.
1129
1130 If I<format> is not specified or "default", the fields of the CSV file are as
1131 follows:
1132
1133 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
1134
1135 =over 4
1136
1137 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
1138
1139 B<record_type> is C<cust_bill> for the initial header line only.  The
1140 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
1141 fields are filled in.
1142
1143 B<record_type> is C<cust_bill_pkg> for detail lines.  Only the first two fields
1144 (B<record_type> and B<invnum>) and the last five fields (B<pkg> through B<edate>)
1145 are filled in.
1146
1147 =item invnum - invoice number
1148
1149 =item custnum - customer number
1150
1151 =item _date - invoice date
1152
1153 =item charged - total invoice amount
1154
1155 =item first - customer first name
1156
1157 =item last - customer first name
1158
1159 =item company - company name
1160
1161 =item address1 - address line 1
1162
1163 =item address2 - address line 1
1164
1165 =item city
1166
1167 =item state
1168
1169 =item zip
1170
1171 =item country
1172
1173 =item pkg - line item description
1174
1175 =item setup - line item setup fee (one or both of B<setup> and B<recur> will be defined)
1176
1177 =item recur - line item recurring fee (one or both of B<setup> and B<recur> will be defined)
1178
1179 =item sdate - start date for recurring fee
1180
1181 =item edate - end date for recurring fee
1182
1183 =back
1184
1185 If I<format> is "billco", the fields of the header CSV file are as follows:
1186
1187   +-------------------------------------------------------------------+
1188   |                        FORMAT HEADER FILE                         |
1189   |-------------------------------------------------------------------|
1190   | Field | Description                   | Name       | Type | Width |
1191   | 1     | N/A-Leave Empty               | RC         | CHAR |     2 |
1192   | 2     | N/A-Leave Empty               | CUSTID     | CHAR |    15 |
1193   | 3     | Transaction Account No        | TRACCTNUM  | CHAR |    15 |
1194   | 4     | Transaction Invoice No        | TRINVOICE  | CHAR |    15 |
1195   | 5     | Transaction Zip Code          | TRZIP      | CHAR |     5 |
1196   | 6     | Transaction Company Bill To   | TRCOMPANY  | CHAR |    30 |
1197   | 7     | Transaction Contact Bill To   | TRNAME     | CHAR |    30 |
1198   | 8     | Additional Address Unit Info  | TRADDR1    | CHAR |    30 |
1199   | 9     | Bill To Street Address        | TRADDR2    | CHAR |    30 |
1200   | 10    | Ancillary Billing Information | TRADDR3    | CHAR |    30 |
1201   | 11    | Transaction City Bill To      | TRCITY     | CHAR |    20 |
1202   | 12    | Transaction State Bill To     | TRSTATE    | CHAR |     2 |
1203   | 13    | Bill Cycle Close Date         | CLOSEDATE  | CHAR |    10 |
1204   | 14    | Bill Due Date                 | DUEDATE    | CHAR |    10 |
1205   | 15    | Previous Balance              | BALFWD     | NUM* |     9 |
1206   | 16    | Pmt/CR Applied                | CREDAPPLY  | NUM* |     9 |
1207   | 17    | Total Current Charges         | CURRENTCHG | NUM* |     9 |
1208   | 18    | Total Amt Due                 | TOTALDUE   | NUM* |     9 |
1209   | 19    | Total Amt Due                 | AMTDUE     | NUM* |     9 |
1210   | 20    | 30 Day Aging                  | AMT30      | NUM* |     9 |
1211   | 21    | 60 Day Aging                  | AMT60      | NUM* |     9 |
1212   | 22    | 90 Day Aging                  | AMT90      | NUM* |     9 |
1213   | 23    | Y/N                           | AGESWITCH  | CHAR |     1 |
1214   | 24    | Remittance automation         | SCANLINE   | CHAR |   100 |
1215   | 25    | Total Taxes & Fees            | TAXTOT     | NUM* |     9 |
1216   | 26    | Customer Reference Number     | CUSTREF    | CHAR |    15 |
1217   | 27    | Federal Tax***                | FEDTAX     | NUM* |     9 |
1218   | 28    | State Tax***                  | STATETAX   | NUM* |     9 |
1219   | 29    | Other Taxes & Fees***         | OTHERTAX   | NUM* |     9 |
1220   +-------+-------------------------------+------------+------+-------+
1221
1222 If I<format> is "billco", the fields of the detail CSV file are as follows:
1223
1224                                   FORMAT FOR DETAIL FILE
1225         |                            |           |      |
1226   Field | Description                | Name      | Type | Width
1227   1     | N/A-Leave Empty            | RC        | CHAR |     2
1228   2     | N/A-Leave Empty            | CUSTID    | CHAR |    15
1229   3     | Account Number             | TRACCTNUM | CHAR |    15
1230   4     | Invoice Number             | TRINVOICE | CHAR |    15
1231   5     | Line Sequence (sort order) | LINESEQ   | NUM  |     6
1232   6     | Transaction Detail         | DETAILS   | CHAR |   100
1233   7     | Amount                     | AMT       | NUM* |     9
1234   8     | Line Format Control**      | LNCTRL    | CHAR |     2
1235   9     | Grouping Code              | GROUP     | CHAR |     2
1236   10    | User Defined               | ACCT CODE | CHAR |    15
1237
1238 =cut
1239
1240 sub print_csv {
1241   my($self, %opt) = @_;
1242
1243   eval "use Text::CSV_XS";
1244   die $@ if $@;
1245
1246   my $cust_main = $self->cust_main;
1247
1248   my $csv = Text::CSV_XS->new({'always_quote'=>1});
1249
1250   if ( lc($opt{'format'}) eq 'billco' ) {
1251
1252     my $taxtotal = 0;
1253     $taxtotal += $_->{'amount'} foreach $self->_items_tax;
1254
1255     my $duedate = $self->due_date2str('%m/%d/%Y'); #date_format?
1256
1257     my( $previous_balance, @unused ) = $self->previous; #previous balance
1258
1259     my $pmt_cr_applied = 0;
1260     $pmt_cr_applied += $_->{'amount'}
1261       foreach ( $self->_items_payments, $self->_items_credits ) ;
1262
1263     my $totaldue = sprintf('%.2f', $self->owed + $previous_balance);
1264
1265     $csv->combine(
1266       '',                         #  1 | N/A-Leave Empty               CHAR   2
1267       '',                         #  2 | N/A-Leave Empty               CHAR  15
1268       $opt{'tracctnum'},          #  3 | Transaction Account No        CHAR  15
1269       $self->invnum,              #  4 | Transaction Invoice No        CHAR  15
1270       $cust_main->zip,            #  5 | Transaction Zip Code          CHAR   5
1271       $cust_main->company,        #  6 | Transaction Company Bill To   CHAR  30
1272       #$cust_main->payname,        #  7 | Transaction Contact Bill To   CHAR  30
1273       $cust_main->contact,        #  7 | Transaction Contact Bill To   CHAR  30
1274       $cust_main->address2,       #  8 | Additional Address Unit Info  CHAR  30
1275       $cust_main->address1,       #  9 | Bill To Street Address        CHAR  30
1276       '',                         # 10 | Ancillary Billing Information CHAR  30
1277       $cust_main->city,           # 11 | Transaction City Bill To      CHAR  20
1278       $cust_main->state,          # 12 | Transaction State Bill To     CHAR   2
1279
1280       # XXX ?
1281       time2str("%m/%d/%Y", $self->_date), # 13 | Bill Cycle Close Date CHAR  10
1282
1283       # XXX ?
1284       $duedate,                   # 14 | Bill Due Date                 CHAR  10
1285
1286       $previous_balance,          # 15 | Previous Balance              NUM*   9
1287       $pmt_cr_applied,            # 16 | Pmt/CR Applied                NUM*   9
1288       sprintf("%.2f", $self->charged), # 17 | Total Current Charges    NUM*   9
1289       $totaldue,                  # 18 | Total Amt Due                 NUM*   9
1290       $totaldue,                  # 19 | Total Amt Due                 NUM*   9
1291       '',                         # 20 | 30 Day Aging                  NUM*   9
1292       '',                         # 21 | 60 Day Aging                  NUM*   9
1293       '',                         # 22 | 90 Day Aging                  NUM*   9
1294       'N',                        # 23 | Y/N                           CHAR   1
1295       '',                         # 24 | Remittance automation         CHAR 100
1296       $taxtotal,                  # 25 | Total Taxes & Fees            NUM*   9
1297       $self->custnum,             # 26 | Customer Reference Number     CHAR  15
1298       '0',                        # 27 | Federal Tax***                NUM*   9
1299       sprintf("%.2f", $taxtotal), # 28 | State Tax***                  NUM*   9
1300       '0',                        # 29 | Other Taxes & Fees***         NUM*   9
1301     );
1302
1303   } else {
1304
1305     $csv->combine(
1306       'cust_bill',
1307       $self->invnum,
1308       $self->custnum,
1309       time2str("%x", $self->_date),
1310       sprintf("%.2f", $self->charged),
1311       ( map { $cust_main->getfield($_) }
1312           qw( first last company address1 address2 city state zip country ) ),
1313       map { '' } (1..5),
1314     ) or die "can't create csv";
1315   }
1316
1317   my $header = $csv->string. "\n";
1318
1319   my $detail = '';
1320   if ( lc($opt{'format'}) eq 'billco' ) {
1321
1322     my $lineseq = 0;
1323     foreach my $item ( $self->_items_pkg ) {
1324
1325       $csv->combine(
1326         '',                     #  1 | N/A-Leave Empty            CHAR   2
1327         '',                     #  2 | N/A-Leave Empty            CHAR  15
1328         $opt{'tracctnum'},      #  3 | Account Number             CHAR  15
1329         $self->invnum,          #  4 | Invoice Number             CHAR  15
1330         $lineseq++,             #  5 | Line Sequence (sort order) NUM    6
1331         $item->{'description'}, #  6 | Transaction Detail         CHAR 100
1332         $item->{'amount'},      #  7 | Amount                     NUM*   9
1333         '',                     #  8 | Line Format Control**      CHAR   2
1334         '',                     #  9 | Grouping Code              CHAR   2
1335         '',                     # 10 | User Defined               CHAR  15
1336       );
1337
1338       $detail .= $csv->string. "\n";
1339
1340     }
1341
1342   } else {
1343
1344     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1345
1346       my($pkg, $setup, $recur, $sdate, $edate);
1347       if ( $cust_bill_pkg->pkgnum ) {
1348
1349         ($pkg, $setup, $recur, $sdate, $edate) = (
1350           $cust_bill_pkg->part_pkg->pkg,
1351           ( $cust_bill_pkg->setup != 0
1352             ? sprintf("%.2f", $cust_bill_pkg->setup )
1353             : '' ),
1354           ( $cust_bill_pkg->recur != 0
1355             ? sprintf("%.2f", $cust_bill_pkg->recur )
1356             : '' ),
1357           ( $cust_bill_pkg->sdate
1358             ? time2str("%x", $cust_bill_pkg->sdate)
1359             : '' ),
1360           ($cust_bill_pkg->edate
1361             ?time2str("%x", $cust_bill_pkg->edate)
1362             : '' ),
1363         );
1364
1365       } else { #pkgnum tax
1366         next unless $cust_bill_pkg->setup != 0;
1367         my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
1368                          ? ( $cust_bill_pkg->itemdesc || 'Tax' )
1369                          : 'Tax';
1370         ($pkg, $setup, $recur, $sdate, $edate) =
1371           ( $itemdesc, sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
1372       }
1373
1374       $csv->combine(
1375         'cust_bill_pkg',
1376         $self->invnum,
1377         ( map { '' } (1..11) ),
1378         ($pkg, $setup, $recur, $sdate, $edate)
1379       ) or die "can't create csv";
1380
1381       $detail .= $csv->string. "\n";
1382
1383     }
1384
1385   }
1386
1387   ( $header, $detail );
1388
1389 }
1390
1391 =item comp
1392
1393 Pays this invoice with a compliemntary payment.  If there is an error,
1394 returns the error, otherwise returns false.
1395
1396 =cut
1397
1398 sub comp {
1399   my $self = shift;
1400   my $cust_pay = new FS::cust_pay ( {
1401     'invnum'   => $self->invnum,
1402     'paid'     => $self->owed,
1403     '_date'    => '',
1404     'payby'    => 'COMP',
1405     'payinfo'  => $self->cust_main->payinfo,
1406     'paybatch' => '',
1407   } );
1408   $cust_pay->insert;
1409 }
1410
1411 =item realtime_card
1412
1413 Attempts to pay this invoice with a credit card payment via a
1414 Business::OnlinePayment realtime gateway.  See
1415 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1416 for supported processors.
1417
1418 =cut
1419
1420 sub realtime_card {
1421   my $self = shift;
1422   $self->realtime_bop( 'CC', @_ );
1423 }
1424
1425 =item realtime_ach
1426
1427 Attempts to pay this invoice with an electronic check (ACH) payment via a
1428 Business::OnlinePayment realtime gateway.  See
1429 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1430 for supported processors.
1431
1432 =cut
1433
1434 sub realtime_ach {
1435   my $self = shift;
1436   $self->realtime_bop( 'ECHECK', @_ );
1437 }
1438
1439 =item realtime_lec
1440
1441 Attempts to pay this invoice with phone bill (LEC) payment via a
1442 Business::OnlinePayment realtime gateway.  See
1443 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1444 for supported processors.
1445
1446 =cut
1447
1448 sub realtime_lec {
1449   my $self = shift;
1450   $self->realtime_bop( 'LEC', @_ );
1451 }
1452
1453 sub realtime_bop {
1454   my( $self, $method ) = @_;
1455
1456   my $cust_main = $self->cust_main;
1457   my $balance = $cust_main->balance;
1458   my $amount = ( $balance < $self->owed ) ? $balance : $self->owed;
1459   $amount = sprintf("%.2f", $amount);
1460   return "not run (balance $balance)" unless $amount > 0;
1461
1462   my $description = 'Internet Services';
1463   if ( $conf->exists('business-onlinepayment-description') ) {
1464     my $dtempl = $conf->config('business-onlinepayment-description');
1465
1466     my $agent_obj = $cust_main->agent
1467       or die "can't retreive agent for $cust_main (agentnum ".
1468              $cust_main->agentnum. ")";
1469     my $agent = $agent_obj->agent;
1470     my $pkgs = join(', ',
1471       map { $_->part_pkg->pkg }
1472         grep { $_->pkgnum } $self->cust_bill_pkg
1473     );
1474     $description = eval qq("$dtempl");
1475   }
1476
1477   $cust_main->realtime_bop($method, $amount,
1478     'description' => $description,
1479     'invnum'      => $self->invnum,
1480   );
1481
1482 }
1483
1484 =item batch_card OPTION => VALUE...
1485
1486 Adds a payment for this invoice to the pending credit card batch (see
1487 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
1488 runs the payment using a realtime gateway.
1489
1490 =cut
1491
1492 sub batch_card {
1493   my ($self, %options) = @_;
1494   my $cust_main = $self->cust_main;
1495
1496   $options{invnum} = $self->invnum;
1497
1498   $cust_main->batch_card(%options);
1499 }
1500
1501 sub _agent_template {
1502   my $self = shift;
1503   $self->cust_main->agent_template;
1504 }
1505
1506 sub _agent_invoice_from {
1507   my $self = shift;
1508   $self->cust_main->agent_invoice_from;
1509 }
1510
1511 =item print_text [ TIME [ , TEMPLATE ] ]
1512
1513 Returns an text invoice, as a list of lines.
1514
1515 TIME an optional value used to control the printing of overdue messages.  The
1516 default is now.  It isn't the date of the invoice; that's the `_date' field.
1517 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1518 L<Time::Local> and L<Date::Parse> for conversion functions.
1519
1520 =cut
1521
1522 sub print_text {
1523   my( $self, $today, $template ) = @_;
1524
1525   my %params = ( 'format' => 'template' );
1526   $params{'time'} = $today if $today;
1527   $params{'template'} = $template if $template;
1528
1529   $self->print_generic( %params );
1530 }
1531
1532 =item print_latex [ TIME [ , TEMPLATE ] ]
1533
1534 Internal method - returns a filename of a filled-in LaTeX template for this
1535 invoice (Note: add ".tex" to get the actual filename), and a filename of
1536 an associated logo (with the .eps extension included).
1537
1538 See print_ps and print_pdf for methods that return PostScript and PDF output.
1539
1540 TIME an optional value used to control the printing of overdue messages.  The
1541 default is now.  It isn't the date of the invoice; that's the `_date' field.
1542 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1543 L<Time::Local> and L<Date::Parse> for conversion functions.
1544
1545 =cut
1546
1547 sub print_latex {
1548
1549   my( $self, $today, $template ) = @_;
1550
1551   my %params = ( 'format' => 'latex' );
1552   $params{'time'} = $today if $today;
1553   $params{'template'} = $template if $template;
1554
1555   $template ||= $self->_agent_template;
1556
1557   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1558   my $lh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1559                            DIR      => $dir,
1560                            SUFFIX   => '.eps',
1561                            UNLINK   => 0,
1562                          ) or die "can't open temp file: $!\n";
1563
1564   if ($template && $conf->exists("logo_${template}.eps")) {
1565     print $lh $conf->config_binary("logo_${template}.eps")
1566       or die "can't write temp file: $!\n";
1567   }else{
1568     print $lh $conf->config_binary('logo.eps')
1569       or die "can't write temp file: $!\n";
1570   }
1571   close $lh;
1572   $params{'logo_file'} = $lh->filename;
1573
1574   my @filled_in = $self->print_generic( %params );
1575
1576   my $fh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1577                            DIR      => $dir,
1578                            SUFFIX   => '.tex',
1579                            UNLINK   => 0,
1580                          ) or die "can't open temp file: $!\n";
1581   print $fh join('', @filled_in );
1582   close $fh;
1583
1584   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
1585   return ($1, $params{'logo_file'});
1586
1587 }
1588
1589 =item print_generic OPTIONS_HASH
1590
1591 Internal method - returns a filled-in template for this invoice as a scalar.
1592
1593 See print_ps and print_pdf for methods that return PostScript and PDF output.
1594
1595 Non optional options include
1596   format - latex, html, template
1597
1598 Optional options include
1599
1600 template - a value used as a suffix for a configuration template
1601
1602 time - a value used to control the printing of overdue messages.  The
1603 default is now.  It isn't the date of the invoice; that's the `_date' field.
1604 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1605 L<Time::Local> and L<Date::Parse> for conversion functions.
1606
1607 cid -
1608
1609 =cut
1610
1611 sub print_generic {
1612
1613   my( $self, %params ) = @_;
1614   my $today = $params{today} ? $params{today} : time;
1615   warn "FS::cust_bill::print_generic called on $self with suffix $params{template}\n"
1616     if $DEBUG;
1617
1618   my $format = $params{format};
1619   die "Unknown format: $format"
1620     unless $format =~ /^(latex|html|template)$/;
1621
1622   my $cust_main = $self->cust_main;
1623   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
1624     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
1625
1626
1627   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
1628                      'html'     => [ '<%=', '%>' ],
1629                      'template' => [ '{', '}' ],
1630                    );
1631
1632   #create the template
1633   my $template = $params{template} ? $params{template} : $self->_agent_template;
1634   my $templatefile = "invoice_$format";
1635   $templatefile .= "_$template"
1636     if length($template);
1637   my @invoice_template = map "$_\n", $conf->config($templatefile)
1638     or die "cannot load config data $templatefile";
1639
1640   my $old_latex = '';
1641   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
1642     #change this to a die when the old code is removed
1643     warn "old-style invoice template $templatefile; ".
1644          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
1645     $old_latex = 'true';
1646     @invoice_template = _translate_old_latex_format(@invoice_template);
1647   }
1648
1649   my $text_template = new Text::Template(
1650     TYPE => 'ARRAY',
1651     SOURCE => \@invoice_template,
1652     DELIMITERS => $delimiters{$format},
1653   );
1654
1655   $text_template->compile()
1656     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
1657
1658
1659   # additional substitution could possibly cause breakage in existing templates
1660   my %convert_maps = (
1661     'latex' => {
1662                  'notes'         => sub { map "$_", @_ },
1663                  'footer'        => sub { map "$_", @_ },
1664                  'smallfooter'   => sub { map "$_", @_ },
1665                  'returnaddress' => sub { map "$_", @_ },
1666                },
1667     'html'  => {
1668                  'notes' =>
1669                    sub {
1670                      map {
1671                        s/%%(.*)$/<!-- $1 -->/g;
1672                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
1673                        s/\\begin\{enumerate\}/<ol>/g;
1674                        s/\\item /  <li>/g;
1675                        s/\\end\{enumerate\}/<\/ol>/g;
1676                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
1677                        s/\\\\\*/<br>/g;
1678                        s/\\dollar ?/\$/g;
1679                        s/\\#/#/g;
1680                        s/~/&nbsp;/g;
1681                        $_;
1682                      }  @_
1683                    },
1684                  'footer' =>
1685                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1686                  'smallfooter' =>
1687                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1688                  'returnaddress' =>
1689                    sub {
1690                      map {
1691                        s/~/&nbsp;/g;
1692                        s/\\\\\*?\s*$/<BR>/;
1693                        s/\\hyphenation\{[\w\s\-]+}//;
1694                        $_;
1695                      }  @_
1696                    },
1697                },
1698     'template' => {
1699                  'notes' =>
1700                    sub {
1701                      map {
1702                        s/%%.*$//g;
1703                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
1704                        s/\\begin\{enumerate\}//g;
1705                        s/\\item /  * /g;
1706                        s/\\end\{enumerate\}//g;
1707                        s/\\textbf\{(.*)\}/$1/g;
1708                        s/\\\\\*/ /;
1709                        s/\\dollar ?/\$/g;
1710                        $_;
1711                      }  @_
1712                    },
1713                  'footer' =>
1714                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1715                  'smallfooter' =>
1716                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1717                  'returnaddress' =>
1718                    sub {
1719                      map {
1720                        s/~/ /g;
1721                        s/\\\\\*?\s*$/\n/;             # dubious
1722                        s/\\hyphenation\{[\w\s\-]+}//;
1723                        $_;
1724                      }  @_
1725                    },
1726                },
1727   );
1728
1729
1730   # hashes for differing output formats
1731   my %nbsps = ( 'latex'    => '~',
1732                 'html'     => '',    # '&nbps;' would be nice
1733                 'template' => '',    # not used
1734               );
1735   my $nbsp = $nbsps{$format};
1736
1737   my %escape_functions = ( 'latex'    => \&_latex_escape,
1738                            'html'     => \&encode_entities,
1739                            'template' => sub { shift },
1740                          );
1741   my $escape_function = $escape_functions{$format};
1742
1743   my %date_formats = ( 'latex'    => '%b %o, %Y',
1744                        'html'     => '%b&nbsp;%o,&nbsp;%Y',
1745                        'template' => '%s',
1746                      );
1747   my $date_format = $date_formats{$format};
1748
1749   my %embolden_functions = ( 'latex'    => sub { return '\textbf{'. shift(). '}'
1750                                                },
1751                              'html'     => sub { return '<b>'. shift(). '</b>'
1752                                                },
1753                              'template' => sub { shift },
1754                            );
1755   my $embolden_function = $embolden_functions{$format};
1756
1757
1758   # generate template variables
1759   my $returnaddress;
1760   if (
1761          defined( $conf->config_orbase( "invoice_${format}returnaddress",
1762                                         $template
1763                                       )
1764                 )
1765        && length( $conf->config_orbase( "invoice_${format}returnaddress",
1766                                         $template
1767                                       )
1768                 )
1769   ) {
1770
1771     $returnaddress = join("\n",
1772       $conf->config_orbase("invoice_${format}returnaddress", $template)
1773     );
1774
1775   } elsif ( grep /\S/,
1776             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
1777
1778     my $convert_map = $convert_maps{$format}{'returnaddress'};
1779     $returnaddress =
1780       join( "\n",
1781             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
1782                                                  $template
1783                                                )
1784                          )
1785           );
1786   } elsif ( grep /\S/, $conf->config('company_address') ) {
1787
1788     my $convert_map = $convert_maps{$format}{'returnaddress'};
1789     $returnaddress = join( "\n", &$convert_map(
1790                                    map { s/( {2,})/'~' x length($1)/eg;
1791                                          s/$/\\\\\*/;
1792                                          $_
1793                                        }
1794                                      ( $conf->config('company_name'),
1795                                        $conf->config('company_address'),
1796                                      )
1797                                  )
1798                      );
1799
1800   } else {
1801
1802     my $warning = "Couldn't find a return address; ".
1803                   "do you need to set the company_address configuration value?";
1804     warn "$warning\n";
1805     $returnaddress = $nbsp;
1806     #$returnaddress = $warning;
1807
1808   }
1809
1810   my %invoice_data = (
1811     'company_name'    => scalar( $conf->config('company_name') ),
1812     'company_address' => join("\n", $conf->config('company_address') ). "\n",
1813     'custnum'         => $self->custnum,
1814     'invnum'          => $self->invnum,
1815     'date'            => time2str($date_format, $self->_date),
1816     'today'           => time2str('%b %o, %Y', $today),
1817     'agent'           => &$escape_function($cust_main->agent->agent),
1818     'payname'         => &$escape_function($cust_main->payname),
1819     'company'         => &$escape_function($cust_main->company),
1820     'address1'        => &$escape_function($cust_main->address1),
1821     'address2'        => &$escape_function($cust_main->address2),
1822     'city'            => &$escape_function($cust_main->city),
1823     'state'           => &$escape_function($cust_main->state),
1824     'zip'             => &$escape_function($cust_main->zip),
1825     'returnaddress'   => $returnaddress,
1826     'quantity'        => 1,
1827     'terms'           => $self->terms,
1828     'template'        => $params{'template'},
1829     #'notes'           => join("\n", $conf->config('invoice_latexnotes') ),
1830     # better hang on to conf_dir for a while
1831     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
1832     'page'            => 1,
1833     'total_pages'     => 1,
1834   );
1835
1836   $invoice_data{'cid'} = $params{'cid'}
1837     if $params{'cid'};
1838
1839   my $countrydefault = $conf->config('countrydefault') || 'US';
1840   if ( $cust_main->country eq $countrydefault ) {
1841     $invoice_data{'country'} = '';
1842   } else {
1843     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
1844   }
1845
1846   my @address = ();
1847   $invoice_data{'address'} = \@address;
1848   push @address,
1849     $cust_main->payname.
1850       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
1851         ? " (P.O. #". $cust_main->payinfo. ")"
1852         : ''
1853       )
1854   ;
1855   push @address, $cust_main->company
1856     if $cust_main->company;
1857   push @address, $cust_main->address1;
1858   push @address, $cust_main->address2
1859     if $cust_main->address2;
1860   push @address,
1861     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
1862   push @address, $invoice_data{'country'}
1863     if $invoice_data{'country'};
1864   push @address, ''
1865     while (scalar(@address) < 5);
1866
1867   #do variable substitution in notes, footer, smallfooter
1868   foreach my $include (qw( notes footer smallfooter )) {
1869
1870     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1871     my @inc_src;
1872
1873     if ( $conf->exists($inc_file) && length( $conf->config($inc_file) ) ) {
1874
1875       @inc_src = $conf->config($inc_file);
1876
1877     } else {
1878
1879       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1880
1881       my $convert_map = $convert_maps{$format}{$include};
1882
1883       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1884                        s/--\@\]/$delimiters{$format}[1]/g;
1885                        $_;
1886                      }
1887                  &$convert_map( $conf->config($inc_file) );
1888
1889     }
1890
1891     my $inc_tt = new Text::Template (
1892       TYPE       => 'ARRAY',
1893       SOURCE     => [ map "$_\n", @inc_src ],
1894       DELIMITERS => $delimiters{$format},
1895     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1896
1897     unless ( $inc_tt->compile() ) {
1898       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1899       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1900       die $error;
1901     }
1902
1903     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1904
1905     $invoice_data{$include} =~ s/\n+$//
1906       if ($format eq 'latex');
1907   }
1908
1909   $invoice_data{'po_line'} =
1910     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
1911       ? &$escape_function("Purchase Order #". $cust_main->payinfo)
1912       : $nbsp;
1913
1914   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1915 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
1916   #my $balance_due = $self->owed + $pr_total - $cr_total;
1917   my $balance_due = $self->owed + $pr_total;
1918
1919   my %money_chars = ( 'latex'    => '',
1920                       'html'     => $conf->config('money_char') || '$',
1921                       'template' => '',
1922                     );
1923   my $money_char = $money_chars{$format};
1924
1925   my %other_money_chars = ( 'latex'    => '\dollar ',
1926                             'html'     => $conf->config('money_char') || '$',
1927                             'template' => '',
1928                           );
1929   my $other_money_char = $other_money_chars{$format};
1930
1931   my @detail_items = ();
1932   my @total_items = ();
1933   my @buf = ();
1934   my @sections = ();
1935
1936   $invoice_data{'detail_items'} = \@detail_items;
1937   $invoice_data{'total_items'} = \@total_items;
1938   $invoice_data{'buf'} = \@buf;
1939   $invoice_data{'sections'} = \@sections;
1940
1941   my $previous_section = { 'description' => 'Previous Charges',
1942                            'subtotal'    => $other_money_char.
1943                                             sprintf('%.2f', $pr_total),
1944                          };
1945
1946   my $multisection = $conf->exists('invoice_sections', $cust_main->agentnum);
1947   if ( $multisection ) {
1948     push @sections, $self->_items_sections;
1949   }else{
1950     push @sections, { 'description' => '', 'subtotal' => '' };
1951   }
1952
1953   foreach my $line_item ( $conf->exists('disable_previous_balance')
1954                             ? ()
1955                             : $self->_items_previous
1956                         )
1957   {
1958     my $detail = {
1959       ext_description => [],
1960     };
1961     $detail->{'ref'} = $line_item->{'pkgnum'};
1962     $detail->{'quantity'} = 1;
1963     $detail->{'section'} = $previous_section;
1964     $detail->{'description'} = &$escape_function($line_item->{'description'});
1965     if ( exists $line_item->{'ext_description'} ) {
1966       @{$detail->{'ext_description'}} = map {
1967         &$escape_function($_);
1968       } @{$line_item->{'ext_description'}};
1969     }
1970     {
1971       my $money = $old_latex ? '' : $money_char;
1972       $detail->{'amount'} = $money. $line_item->{'amount'};
1973     }
1974     $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
1975
1976     push @detail_items, $detail;
1977     push @buf, [ $detail->{'description'},
1978                  $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1979                ];
1980   }
1981
1982   if ( @pr_cust_bill && !$conf->exists('disable_previous_balance') ) {
1983     push @buf, ['','-----------'];
1984     push @buf, [ 'Total Previous Balance',
1985                  $money_char. sprintf("%10.2f", $pr_total) ];
1986     push @buf, ['',''];
1987   }
1988
1989   foreach my $section (@sections) {
1990
1991     $section->{'subtotal'} = $other_money_char.
1992                              sprintf('%.2f', $section->{'subtotal'})
1993       if $multisection;
1994
1995     if ( $section->{'description'} ) {
1996       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1997                    [ '', '' ],
1998                  );
1999     }
2000
2001     my %options = ();
2002     $options{'section'} = $section if $multisection;
2003     $options{'format'} = $format;
2004
2005     foreach my $line_item ( $self->_items_pkg(%options) ) {
2006       my $detail = {
2007         ext_description => [],
2008       };
2009       $detail->{'ref'} = $line_item->{'pkgnum'};
2010       $detail->{'quantity'} = 1;
2011       $detail->{'section'} = $section;
2012       $detail->{'description'} = &$escape_function($line_item->{'description'});
2013       if ( exists $line_item->{'ext_description'} ) {
2014         @{$detail->{'ext_description'}} = @{$line_item->{'ext_description'}};
2015       }
2016       {
2017         my $money = $old_latex ? '' : $money_char;
2018         $detail->{'amount'} = $money. $line_item->{'amount'};
2019       }
2020       $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
2021
2022       push @detail_items, $detail;
2023       push @buf, ( [ $detail->{'description'},
2024                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
2025                    ],
2026                    map { [ " ". $_, '' ] } @{$detail->{'ext_description'}},
2027                  );
2028     }
2029
2030     if ( $section->{'description'} ) {
2031       push @buf, ( ['','-----------'],
2032                    [ $section->{'description'}. ' sub-total',
2033                       $money_char. sprintf("%10.2f", $section->{'subtotal'})
2034                    ],
2035                    [ '', '' ],
2036                    [ '', '' ],
2037                  );
2038     }
2039
2040   }
2041
2042   if ( $multisection && !$conf->exists('disable_previous_balance') ) {
2043     unshift @sections, $previous_section;
2044   }
2045
2046   my $taxtotal = 0;
2047   foreach my $tax ( $self->_items_tax ) {
2048     my $total = {};
2049     $total->{'total_item'} = &$escape_function($tax->{'description'});
2050     $taxtotal += $tax->{'amount'};
2051     $total->{'total_amount'} = $other_money_char. $tax->{'amount'};
2052     push @total_items, $total;
2053     push @buf,[ $total->{'total_item'},
2054                 $money_char. sprintf("%10.2f", $total->{'total_amount'}),
2055               ];
2056
2057   }
2058
2059   if ( $taxtotal ) {
2060     my $total = {};
2061     if ( $multisection ) {
2062       $total->{'total_item'} = 'New charges sub-total';
2063     }else{
2064       $total->{'total_item'} = 'Sub-total';
2065     }
2066     $total->{'total_amount'} =
2067       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
2068     unshift @total_items, $total;
2069   }
2070
2071   push @buf,['','-----------'];
2072   push @buf,[( $conf->exists('disable_previous_balance')
2073                ? 'Total Charges'
2074                : 'Total New Charges'
2075              ),
2076              $money_char. sprintf("%10.2f",$self->charged) ];
2077   push @buf,['',''];
2078
2079   {
2080     my $total = {};
2081     $total->{'total_item'} = &$embolden_function('Total');
2082     $total->{'total_amount'} =
2083       &$embolden_function(
2084         $other_money_char.
2085         sprintf( '%.2f',
2086                  $self->charged + ( $conf->exists('disable_previous_balance')
2087                                     ? 0
2088                                     : $pr_total
2089                                   )
2090                )
2091       );
2092     push @total_items, $total;
2093     push @buf,['','-----------'];
2094     push @buf,['Total Charges',
2095                $money_char.
2096                sprintf( '%10.2f', $self->charged +
2097                                     ( $conf->exists('disable_previous_balance')
2098                                         ? 0
2099                                         : $pr_total
2100                                     )
2101                       )
2102               ];
2103     push @buf,['',''];
2104   }
2105
2106   unless ( $conf->exists('disable_previous_balance') ) {
2107     #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
2108
2109     # credits
2110     foreach my $credit ( $self->_items_credits ) {
2111       my $total;
2112       $total->{'total_item'} = &$escape_function($credit->{'description'});
2113       #$credittotal
2114       $total->{'total_amount'} = '-'. $other_money_char. $credit->{'amount'};
2115       push @total_items, $total;
2116     }
2117
2118     # credits (again)
2119     foreach ( $self->cust_credited ) {
2120
2121       #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2122
2123       my $reason = substr($_->cust_credit->reason,0,32);
2124       $reason .= '...' if length($reason) < length($_->cust_credit->reason);
2125       $reason = " ($reason) " if $reason;
2126       push @buf,[
2127         "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".        $reason,
2128         $money_char. sprintf("%10.2f",$_->amount)
2129       ];
2130     }
2131
2132     # payments
2133     foreach my $payment ( $self->_items_payments ) {
2134       my $total = {};
2135       $total->{'total_item'} = &$escape_function($payment->{'description'});
2136       #$paymenttotal
2137       $total->{'total_amount'} = '-'. $other_money_char. $payment->{'amount'};
2138       push @total_items, $total;
2139       push @buf, [ $payment->{'description'},
2140                    $money_char. sprintf("%10.2f", $payment->{'amount'}),
2141                  ];
2142     }
2143
2144     {
2145       my $total;
2146       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
2147       $total->{'total_amount'} =
2148         &$embolden_function(
2149           $other_money_char. sprintf('%.2f', $self->owed + $pr_total )
2150         );
2151       push @total_items, $total;
2152       push @buf,['','-----------'];
2153       push @buf,[$self->balance_due_msg, $money_char.
2154         sprintf("%10.2f", $balance_due ) ];
2155     }
2156   }
2157
2158   $invoice_data{'logo_file'} = $params{'logo_file'}
2159     if $params{'logo_file'};
2160
2161   $invoice_lines = 0;
2162   my $wasfunc = 0;
2163   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
2164     /invoice_lines\((\d*)\)/;
2165     $invoice_lines += $1 || scalar(@buf);
2166     $wasfunc=1;
2167   }
2168   die "no invoice_lines() functions in template?"
2169     if ( $format eq 'template' && !$wasfunc );
2170
2171   if ($format eq 'template') {
2172
2173     if ( $invoice_lines ) {
2174       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
2175       $invoice_data{'total_pages'}++
2176         if scalar(@buf) % $invoice_lines;
2177     }
2178
2179     #setup subroutine for the template
2180     sub FS::cust_bill::_template::invoice_lines {
2181       my $lines = shift || scalar(@FS::cust_bill::_template::buf);
2182       map {
2183         scalar(@FS::cust_bill::_template::buf)
2184           ? shift @FS::cust_bill::_template::buf
2185           : [ '', '' ];
2186       }
2187       ( 1 .. $lines );
2188     }
2189
2190     my $lines;
2191     my @collect;
2192     while (@buf) {
2193       push @collect, split("\n",
2194         $text_template->fill_in( HASH => \%invoice_data,
2195                                  PACKAGE => 'FS::cust_bill::_template'
2196                                )
2197       );
2198       $FS::cust_bill::_template::page++;
2199     }
2200     map "$_\n", @collect;
2201   }else{
2202     warn "filling in template for invoice ". $self->invnum. "\n"
2203       if $DEBUG;
2204     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
2205       if $DEBUG > 1;
2206
2207     $text_template->fill_in(HASH => \%invoice_data);
2208   }
2209 }
2210
2211 =item print_ps [ TIME [ , TEMPLATE ] ]
2212
2213 Returns an postscript invoice, as a scalar.
2214
2215 TIME an optional value used to control the printing of overdue messages.  The
2216 default is now.  It isn't the date of the invoice; that's the `_date' field.
2217 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2218 L<Time::Local> and L<Date::Parse> for conversion functions.
2219
2220 =cut
2221
2222 sub print_ps {
2223   my $self = shift;
2224
2225   my ($file, $lfile) = $self->print_latex(@_);
2226   my $ps = generate_ps($file);
2227   unlink($lfile);
2228   $ps;
2229
2230 }
2231
2232 =item print_pdf [ TIME [ , TEMPLATE ] ]
2233
2234 Returns an PDF invoice, as a scalar.
2235
2236 TIME an optional value used to control the printing of overdue messages.  The
2237 default is now.  It isn't the date of the invoice; that's the `_date' field.
2238 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2239 L<Time::Local> and L<Date::Parse> for conversion functions.
2240
2241 =cut
2242
2243 sub print_pdf {
2244   my $self = shift;
2245
2246   my ($file, $lfile) = $self->print_latex(@_);
2247
2248   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
2249   chdir($dir);
2250
2251   #system('pdflatex', "$file.tex");
2252   #system('pdflatex', "$file.tex");
2253   #! LaTeX Error: Unknown graphics extension: .eps.
2254
2255   my $sfile = shell_quote $file;
2256
2257   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2258     or die "pslatex $file.tex failed; see $file.log for details?\n";
2259   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2260     or die "pslatex $file.tex failed; see $file.log for details?\n";
2261
2262   #system('dvipdf', "$file.dvi", "$file.pdf" );
2263   system(
2264     "dvips -q -t letter -f $sfile.dvi ".
2265     "| gs -q -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=$sfile.pdf ".
2266     "     -c save pop -"
2267   ) == 0
2268     or die "dvips | gs failed: $!";
2269
2270   open(PDF, "<$file.pdf")
2271     or die "can't open $file.pdf: $! (error in LaTeX template?)\n";
2272
2273   unlink("$file.dvi", "$file.log", "$file.aux", "$file.pdf", "$file.tex");
2274   unlink("$lfile");
2275
2276   my $pdf = '';
2277   while (<PDF>) {
2278     $pdf .= $_;
2279   }
2280
2281   close PDF;
2282
2283   return $pdf;
2284
2285 }
2286
2287 =item print_html [ TIME [ , TEMPLATE [ , CID ] ] ]
2288
2289 Returns an HTML invoice, as a scalar.
2290
2291 TIME an optional value used to control the printing of overdue messages.  The
2292 default is now.  It isn't the date of the invoice; that's the `_date' field.
2293 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2294 L<Time::Local> and L<Date::Parse> for conversion functions.
2295
2296 CID is a MIME Content-ID used to create a "cid:" URL for the logo image, used
2297 when emailing the invoice as part of a multipart/related MIME email.
2298
2299 =cut
2300
2301 sub print_html {
2302   my( $self, $today, $template, $cid ) = @_;
2303
2304   my %params = ( 'format' => 'html' );
2305   $params{'time'} = $today if $today;
2306   $params{'template'} = $template if $template;
2307   $params{'cid'} = $cid if $cid;
2308
2309   $self->print_generic( %params );
2310 }
2311
2312 # quick subroutine for print_latex
2313 #
2314 # There are ten characters that LaTeX treats as special characters, which
2315 # means that they do not simply typeset themselves:
2316 #      # $ % & ~ _ ^ \ { }
2317 #
2318 # TeX ignores blanks following an escaped character; if you want a blank (as
2319 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
2320
2321 sub _latex_escape {
2322   my $value = shift;
2323   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
2324   $value =~ s/([<>])/\$$1\$/g;
2325   $value;
2326 }
2327
2328 #utility methods for print_*
2329
2330 sub _translate_old_latex_format {
2331   warn "_translate_old_latex_format called\n"
2332     if $DEBUG;
2333
2334   my @template = ();
2335   while ( @_ ) {
2336     my $line = shift;
2337
2338     if ( $line =~ /^%%Detail\s*$/ ) {
2339
2340       push @template, q![@--!,
2341                       q!  foreach my $_tr_line (@detail_items) {!,
2342                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
2343                       q!      $_tr_line->{'description'} .= !,
2344                       q!        "\\tabularnewline\n~~".!,
2345                       q!        join( "\\tabularnewline\n~~",!,
2346                       q!          @{$_tr_line->{'ext_description'}}!,
2347                       q!        );!,
2348                       q!    }!;
2349
2350       while ( ( my $line_item_line = shift )
2351               !~ /^%%EndDetail\s*$/                            ) {
2352         $line_item_line =~ s/'/\\'/g;    # nice LTS
2353         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2354         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2355         push @template, "    \$OUT .= '$line_item_line';";
2356       }
2357
2358       push @template, '}',
2359                       '--@]';
2360
2361     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
2362
2363       push @template, '[@--',
2364                       '  foreach my $_tr_line (@total_items) {';
2365
2366       while ( ( my $total_item_line = shift )
2367               !~ /^%%EndTotalDetails\s*$/                      ) {
2368         $total_item_line =~ s/'/\\'/g;    # nice LTS
2369         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2370         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2371         push @template, "    \$OUT .= '$total_item_line';";
2372       }
2373
2374       push @template, '}',
2375                       '--@]';
2376
2377     } else {
2378       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
2379       push @template, $line;
2380     }
2381
2382   }
2383
2384   if ($DEBUG) {
2385     warn "$_\n" foreach @template;
2386   }
2387
2388   (@template);
2389 }
2390
2391 sub terms {
2392   my $self = shift;
2393
2394   #check for an invoice- specific override (eventually)
2395
2396   #check for a customer- specific override
2397   return $self->cust_main->invoice_terms
2398     if $self->cust_main->invoice_terms;
2399
2400   #use configured default or default default
2401   $conf->config('invoice_default_terms') || 'Payable upon receipt';
2402 }
2403
2404 sub due_date {
2405   my $self = shift;
2406   my $duedate = '';
2407   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2408     $duedate = $self->_date() + ( $1 * 86400 );
2409   }
2410   $duedate;
2411 }
2412
2413 sub due_date2str {
2414   my $self = shift;
2415   $self->due_date ? time2str(shift, $self->due_date) : '';
2416 }
2417
2418 sub balance_due_msg {
2419   my $self = shift;
2420   my $msg = 'Balance Due';
2421   return $msg unless $self->terms;
2422   if ( $self->due_date ) {
2423     $msg .= ' - Please pay by '. $self->due_date2str('%x');
2424   } elsif ( $self->terms ) {
2425     $msg .= ' - '. $self->terms;
2426   }
2427   $msg;
2428 }
2429
2430 sub _items_sections {
2431   my $self = shift;
2432
2433   my %s = ();
2434   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
2435
2436     if ( $cust_bill_pkg->pkgnum > 0 ) {
2437
2438       my $desc = $cust_bill_pkg->part_pkg->classname;
2439
2440       $s{$desc} += $cust_bill_pkg->setup
2441         if ( $cust_bill_pkg->setup != 0 );
2442
2443       $s{$desc} += $cust_bill_pkg->recur
2444         if ( $cust_bill_pkg->recur != 0 );
2445
2446     }
2447
2448   }
2449
2450   map { {'description' => $_, 'subtotal' => $s{$_}} } sort keys %s;
2451
2452 }
2453
2454 sub _items {
2455   my $self = shift;
2456   my @display = scalar(@_)
2457                 ? @_
2458                 : qw( _items_previous _items_pkg );
2459                 #: qw( _items_pkg );
2460                 #: qw( _items_previous _items_pkg _items_tax _items_credits _items_payments );
2461   my @b = ();
2462   foreach my $display ( @display ) {
2463     push @b, $self->$display(@_);
2464   }
2465   @b;
2466 }
2467
2468 sub _items_previous {
2469   my $self = shift;
2470   my $cust_main = $self->cust_main;
2471   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
2472   my @b = ();
2473   foreach ( @pr_cust_bill ) {
2474     push @b, {
2475       'description' => 'Previous Balance, Invoice #'. $_->invnum.
2476                        ' ('. time2str('%x',$_->_date). ')',
2477       #'pkgpart'     => 'N/A',
2478       'pkgnum'      => 'N/A',
2479       'amount'      => sprintf("%.2f", $_->owed),
2480     };
2481   }
2482   @b;
2483
2484   #{
2485   #    'description'     => 'Previous Balance',
2486   #    #'pkgpart'         => 'N/A',
2487   #    'pkgnum'          => 'N/A',
2488   #    'amount'          => sprintf("%10.2f", $pr_total ),
2489   #    'ext_description' => [ map {
2490   #                                 "Invoice ". $_->invnum.
2491   #                                 " (". time2str("%x",$_->_date). ") ".
2492   #                                 sprintf("%10.2f", $_->owed)
2493   #                         } @pr_cust_bill ],
2494
2495   #};
2496 }
2497
2498 sub _items_pkg {
2499   my $self = shift;
2500   my %options = @_;
2501   my $section = delete $options{'section'};
2502   my @cust_bill_pkg =
2503     grep { $_->pkgnum &&
2504            ( defined($section)
2505                ? $_->part_pkg->classname eq $section->{'description'}
2506                : 1
2507            )
2508          } $self->cust_bill_pkg;
2509   $self->_items_cust_bill_pkg(\@cust_bill_pkg, %options);
2510 }
2511
2512 sub _taxsort {
2513   return 0 unless $a cmp $b;
2514   return -1 if $b eq 'Tax';
2515   return 1 if $a eq 'Tax';
2516   return -1 if $b eq 'Other surcharges';
2517   return 1 if $a eq 'Other surcharges';
2518   $a cmp $b;
2519 }
2520
2521 sub _items_tax {
2522   my $self = shift;
2523   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum } $self->cust_bill_pkg;
2524   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2525 }
2526
2527 sub _items_cust_bill_pkg {
2528   my $self = shift;
2529   my $cust_bill_pkg = shift;
2530   my %opt = @_;
2531   my $format = $opt{format} || '';
2532   my $escape_function = $opt{escape_function} || sub { shift };
2533
2534   my @b = ();
2535   foreach my $cust_bill_pkg ( @$cust_bill_pkg ) {
2536
2537     my $cust_pkg = $cust_bill_pkg->cust_pkg;
2538
2539     my $desc = $cust_bill_pkg->desc;
2540
2541     if ( $cust_bill_pkg->pkgnum > 0 ) {
2542
2543       if ( $cust_bill_pkg->setup != 0 ) {
2544         my $description = $desc;
2545         $description .= ' Setup' if $cust_bill_pkg->recur != 0;
2546         my @d = $cust_pkg->h_labels_short($self->_date);
2547         push @d, $cust_bill_pkg->details( 'format'          => $format,
2548                                           'escape_function' => $escape_function,
2549                                         )
2550           if $cust_bill_pkg->recur == 0;
2551         push @b, {
2552           description     => $description,
2553           #pkgpart         => $part_pkg->pkgpart,
2554           pkgnum          => $cust_bill_pkg->pkgnum,
2555           amount          => sprintf("%.2f", $cust_bill_pkg->setup),
2556           ext_description => \@d,
2557         };
2558       }
2559
2560       if ( $cust_bill_pkg->recur != 0 ) {
2561         push @b, {
2562           description     => $desc .
2563                              ( $conf->exists('disable_line_item_date_ranges')
2564                                ? ''
2565                                : " (" .time2str("%x", $cust_bill_pkg->sdate).
2566                                  " - ".time2str("%x", $cust_bill_pkg->edate).")"
2567                              ),
2568           #pkgpart         => $part_pkg->pkgpart,
2569           pkgnum          => $cust_bill_pkg->pkgnum,
2570           amount          => sprintf("%.2f", $cust_bill_pkg->recur),
2571           ext_description =>
2572             #at least until cust_bill_pkg has "past" ranges in addition to
2573             #the "future" sdate/edate ones... see #3032
2574             [ $cust_pkg->h_labels_short( $self->_date ),
2575                                          #$cust_bill_pkg->edate,
2576                                          #$cust_bill_pkg->sdate),
2577               $cust_bill_pkg->details( 'format'          => $format,
2578                                        'escape_function' => $escape_function),
2579             ],
2580         };
2581       }
2582
2583     } else { #pkgnum tax or one-shot line item (??)
2584
2585       if ( $cust_bill_pkg->setup != 0 ) {
2586         push @b, {
2587           'description' => $desc,
2588           'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
2589         };
2590       }
2591       if ( $cust_bill_pkg->recur != 0 ) {
2592         push @b, {
2593           'description' => "$desc (".
2594                            time2str("%x", $cust_bill_pkg->sdate). ' - '.
2595                            time2str("%x", $cust_bill_pkg->edate). ')',
2596           'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
2597         };
2598       }
2599
2600     }
2601
2602   }
2603
2604   @b;
2605
2606 }
2607
2608 sub _items_credits {
2609   my $self = shift;
2610
2611   my @b;
2612   #credits
2613   foreach ( $self->cust_credited ) {
2614
2615     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2616
2617     my $reason = $_->cust_credit->reason;
2618     #my $reason = substr($_->cust_credit->reason,0,32);
2619     #$reason .= '...' if length($reason) < length($_->cust_credit->reason);
2620     $reason = " ($reason) " if $reason;
2621     push @b, {
2622       #'description' => 'Credit ref\#'. $_->crednum.
2623       #                 " (". time2str("%x",$_->cust_credit->_date) .")".
2624       #                 $reason,
2625       'description' => 'Credit applied '.
2626                        time2str("%x",$_->cust_credit->_date). $reason,
2627       'amount'      => sprintf("%.2f",$_->amount),
2628     };
2629   }
2630   #foreach ( @cr_cust_credit ) {
2631   #  push @buf,[
2632   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
2633   #    $money_char. sprintf("%10.2f",$_->credited)
2634   #  ];
2635   #}
2636
2637   @b;
2638
2639 }
2640
2641 sub _items_payments {
2642   my $self = shift;
2643
2644   my @b;
2645   #get & print payments
2646   foreach ( $self->cust_bill_pay ) {
2647
2648     #something more elaborate if $_->amount ne ->cust_pay->paid ?
2649
2650     push @b, {
2651       'description' => "Payment received ".
2652                        time2str("%x",$_->cust_pay->_date ),
2653       'amount'      => sprintf("%.2f", $_->amount )
2654     };
2655   }
2656
2657   @b;
2658
2659 }
2660
2661
2662 =back
2663
2664 =head1 SUBROUTINES
2665
2666 =over 4
2667
2668 =item reprint
2669
2670 =cut
2671
2672 sub process_reprint {
2673   process_re_X('print', @_);
2674 }
2675
2676 =item reemail
2677
2678 =cut
2679
2680 sub process_reemail {
2681   process_re_X('email', @_);
2682 }
2683
2684 =item refax
2685
2686 =cut
2687
2688 sub process_refax {
2689   process_re_X('fax', @_);
2690 }
2691
2692 use Storable qw(thaw);
2693 use Data::Dumper;
2694 use MIME::Base64;
2695 sub process_re_X {
2696   my( $method, $job ) = ( shift, shift );
2697   warn "$me process_re_X $method for job $job\n" if $DEBUG;
2698
2699   my $param = thaw(decode_base64(shift));
2700   warn Dumper($param) if $DEBUG;
2701
2702   re_X(
2703     $method,
2704     $job,
2705     %$param,
2706   );
2707
2708 }
2709
2710 sub re_X {
2711   my($method, $job, %param ) = @_;
2712   if ( $DEBUG ) {
2713     warn "re_X $method for job $job with param:\n".
2714          join( '', map { "  $_ => ". $param{$_}. "\n" } keys %param );
2715   }
2716
2717   #some false laziness w/search/cust_bill.html
2718   my $distinct = '';
2719   my $orderby = 'ORDER BY cust_bill._date';
2720
2721   my $extra_sql = ' WHERE '. FS::cust_bill->search_sql(\%param);
2722
2723   my $addl_from = 'LEFT JOIN cust_main USING ( custnum )';
2724
2725   my @cust_bill = qsearch( {
2726     #'select'    => "cust_bill.*",
2727     'table'     => 'cust_bill',
2728     'addl_from' => $addl_from,
2729     'hashref'   => {},
2730     'extra_sql' => $extra_sql,
2731     'order_by'  => $orderby,
2732     'debug' => 1,
2733   } );
2734
2735   warn " $me re_X $method: ". scalar(@cust_bill). " invoices found\n"
2736     if $DEBUG;
2737
2738   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
2739   foreach my $cust_bill ( @cust_bill ) {
2740     $cust_bill->$method();
2741
2742     if ( $job ) { #progressbar foo
2743       $num++;
2744       if ( time - $min_sec > $last ) {
2745         my $error = $job->update_statustext(
2746           int( 100 * $num / scalar(@cust_bill) )
2747         );
2748         die $error if $error;
2749         $last = time;
2750       }
2751     }
2752
2753   }
2754
2755 }
2756
2757 =back
2758
2759 =head1 CLASS METHODS
2760
2761 =over 4
2762
2763 =item owed_sql
2764
2765 Returns an SQL fragment to retreive the amount owed (charged minus credited and paid).
2766
2767 =cut
2768
2769 sub owed_sql {
2770   my $class = shift;
2771   'charged - '. $class->paid_sql. ' - '. $class->credited_sql;
2772 }
2773
2774 =item net_sql
2775
2776 Returns an SQL fragment to retreive the net amount (charged minus credited).
2777
2778 =cut
2779
2780 sub net_sql {
2781   my $class = shift;
2782   'charged - '. $class->credited_sql;
2783 }
2784
2785 =item paid_sql
2786
2787 Returns an SQL fragment to retreive the amount paid against this invoice.
2788
2789 =cut
2790
2791 sub paid_sql {
2792   #my $class = shift;
2793   "( SELECT COALESCE(SUM(amount),0) FROM cust_bill_pay
2794        WHERE cust_bill.invnum = cust_bill_pay.invnum   )";
2795 }
2796
2797 =item credited_sql
2798
2799 Returns an SQL fragment to retreive the amount credited against this invoice.
2800
2801 =cut
2802
2803 sub credited_sql {
2804   #my $class = shift;
2805   "( SELECT COALESCE(SUM(amount),0) FROM cust_credit_bill
2806        WHERE cust_bill.invnum = cust_credit_bill.invnum   )";
2807 }
2808
2809 =item search_sql HASHREF
2810
2811 Class method which returns an SQL WHERE fragment to search for parameters
2812 specified in HASHREF.  Valid parameters are
2813
2814 =over 4
2815
2816 =item begin
2817
2818 Epoch date (UNIX timestamp) setting a lower bound for _date values
2819
2820 =item end
2821
2822 Epoch date (UNIX timestamp) setting an upper bound for _date values
2823
2824 =item invnum_min
2825
2826 =item invnum_max
2827
2828 =item agentnum
2829
2830 =item owed
2831
2832 =item net
2833
2834 =item days
2835
2836 =item newest_percust
2837
2838 =back
2839
2840 Note: validates all passed-in data; i.e. safe to use with unchecked CGI params.
2841
2842 =cut
2843
2844 sub search_sql {
2845   my($class, $param) = @_;
2846   if ( $DEBUG ) {
2847     warn "$me search_sql called with params: \n".
2848          join("\n", map { "  $_: ". $param->{$_} } keys %$param ). "\n";
2849   }
2850
2851   my @search = ();
2852
2853   if ( $param->{'begin'} =~ /^(\d+)$/ ) {
2854     push @search, "cust_bill._date >= $1";
2855   }
2856   if ( $param->{'end'} =~ /^(\d+)$/ ) {
2857     push @search, "cust_bill._date < $1";
2858   }
2859   if ( $param->{'invnum_min'} =~ /^(\d+)$/ ) {
2860     push @search, "cust_bill.invnum >= $1";
2861   }
2862   if ( $param->{'invnum_max'} =~ /^(\d+)$/ ) {
2863     push @search, "cust_bill.invnum <= $1";
2864   }
2865   if ( $param->{'agentnum'} =~ /^(\d+)$/ ) {
2866     push @search, "cust_main.agentnum = $1";
2867   }
2868
2869   push @search, '0 != '. FS::cust_bill->owed_sql
2870     if $param->{'open'};
2871
2872   push @search, '0 != '. FS::cust_bill->net_sql
2873     if $param->{'net'};
2874
2875   push @search, "cust_bill._date < ". (time-86400*$param->{'days'})
2876     if $param->{'days'};
2877
2878   if ( $param->{'newest_percust'} ) {
2879
2880     #$distinct = 'DISTINCT ON ( cust_bill.custnum )';
2881     #$orderby = 'ORDER BY cust_bill.custnum ASC, cust_bill._date DESC';
2882
2883     my @newest_where = map { my $x = $_;
2884                              $x =~ s/\bcust_bill\./newest_cust_bill./g;
2885                              $x;
2886                            }
2887                            grep ! /^cust_main./, @search;
2888     my $newest_where = scalar(@newest_where)
2889                          ? ' AND '. join(' AND ', @newest_where)
2890                          : '';
2891
2892
2893     push @search, "cust_bill._date = (
2894       SELECT(MAX(newest_cust_bill._date)) FROM cust_bill AS newest_cust_bill
2895         WHERE newest_cust_bill.custnum = cust_bill.custnum
2896           $newest_where
2897     )";
2898
2899   }
2900
2901   my $curuser = $FS::CurrentUser::CurrentUser;
2902   if ( $curuser->username eq 'fs_queue'
2903        && $param->{'CurrentUser'} =~ /^(\w+)$/ ) {
2904     my $username = $1;
2905     my $newuser = qsearchs('access_user', {
2906       'username' => $username,
2907       'disabled' => '',
2908     } );
2909     if ( $newuser ) {
2910       $curuser = $newuser;
2911     } else {
2912       warn "$me WARNING: (fs_queue) can't find CurrentUser $username\n";
2913     }
2914   }
2915
2916   push @search, $curuser->agentnums_sql;
2917
2918   join(' AND ', @search );
2919
2920 }
2921
2922 =back
2923
2924 =head1 BUGS
2925
2926 The delete method.
2927
2928 =head1 SEE ALSO
2929
2930 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
2931 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
2932 documentation.
2933
2934 =cut
2935
2936 1;
2937