FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf $money_char );
   5 use vars qw( $invoice_lines @buf ); #yuck
   6 use Fcntl qw(:flock); #for spool_csv
   7 use List::Util qw(min max);
   8 use Date::Format;
   9 use Text::Template 1.20;
  10 use File::Temp 0.14;
  11 use String::ShellQuote;
  12 use HTML::Entities;
  13 use Locale::Country;
  14 use FS::UID qw( datasrc );
  15 use FS::Misc qw( send_email send_fax generate_ps do_print );
  16 use FS::Record qw( qsearch qsearchs dbh );
  17 use FS::cust_main_Mixin;
  18 use FS::cust_main;
  19 use FS::cust_bill_pkg;
  20 use FS::cust_credit;
  21 use FS::cust_pay;
  22 use FS::cust_pkg;
  23 use FS::cust_credit_bill;
  24 use FS::pay_batch;
  25 use FS::cust_pay_batch;
  26 use FS::cust_bill_event;
  27 use FS::cust_event;
  28 use FS::part_pkg;
  29 use FS::cust_bill_pay;
  30 use FS::cust_bill_pay_batch;
  31 use FS::part_bill_event;
  32 use FS::payby;
  33
  34 @ISA = qw( FS::cust_main_Mixin FS::Record );
  35
  36 $DEBUG = 0;
  37 $me = '[FS::cust_bill]';
  38
  39 #ask FS::UID to run this stuff for us later
  40 FS::UID->install_callback( sub {
  41   $conf = new FS::Conf;
  42   $money_char = $conf->config('money_char') || '$';
  43 } );
  44
  45 =head1 NAME
  46
  47 FS::cust_bill - Object methods for cust_bill records
  48
  49 =head1 SYNOPSIS
  50
  51   use FS::cust_bill;
  52
  53   $record = new FS::cust_bill \%hash;
  54   $record = new FS::cust_bill { 'column' => 'value' };
  55
  56   $error = $record->insert;
  57
  58   $error = $new_record->replace($old_record);
  59
  60   $error = $record->delete;
  61
  62   $error = $record->check;
  63
  64   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  65
  66   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  67
  68   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  69
  70   @cust_pay_objects = $cust_bill->cust_pay;
  71
  72   $tax_amount = $record->tax;
  73
  74   @lines = $cust_bill->print_text;
  75   @lines = $cust_bill->print_text $time;
  76
  77 =head1 DESCRIPTION
  78
  79 An FS::cust_bill object represents an invoice; a declaration that a customer
  80 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
  81 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
  82 following fields are currently supported:
  83
  84 =over 4
  85
  86 =item invnum - primary key (assigned automatically for new invoices)
  87
  88 =item custnum - customer (see L<FS::cust_main>)
  89
  90 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  91 L<Time::Local> and L<Date::Parse> for conversion functions.
  92
  93 =item charged - amount of this invoice
  94
  95 =item printed - deprecated
  96
  97 =item closed - books closed flag, empty or `Y'
  98
  99 =back
 100
 101 =head1 METHODS
 102
 103 =over 4
 104
 105 =item new HASHREF
 106
 107 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 108 Invoices are normally created by calling the bill method of a customer object
 109 (see L<FS::cust_main>).
 110
 111 =cut
 112
 113 sub table { 'cust_bill'; }
 114
 115 sub cust_linked { $_[0]->cust_main_custnum; }
 116 sub cust_unlinked_msg {
 117   my $self = shift;
 118   "WARNING: can't find cust_main.custnum ". $self->custnum.
 119   ' (cust_bill.invnum '. $self->invnum. ')';
 120 }
 121
 122 =item insert
 123
 124 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 125 returns the error, otherwise returns false.
 126
 127 =item delete
 128
 129 This method now works but you probably shouldn't use it.  Instead, apply a
 130 credit against the invoice.
 131
 132 Using this method to delete invoices outright is really, really bad.  There
 133 would be no record you ever posted this invoice, and there are no check to
 134 make sure charged = 0 or that there are no associated cust_bill_pkg records.
 135
 136 Really, don't use it.
 137
 138 =cut
 139
 140 sub delete {
 141   my $self = shift;
 142   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 143   $self->SUPER::delete(@_);
 144 }
 145
 146 =item replace OLD_RECORD
 147
 148 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 149 returns the error, otherwise returns false.
 150
 151 Only printed may be changed.  printed is normally updated by calling the
 152 collect method of a customer object (see L<FS::cust_main>).
 153
 154 =cut
 155
 156 #replace can be inherited from Record.pm
 157
 158 # replace_check is now the preferred way to #implement replace data checks
 159 # (so $object->replace() works without an argument)
 160
 161 sub replace_check {
 162   my( $new, $old ) = ( shift, shift );
 163   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 164   #return "Can't change _date!" unless $old->_date eq $new->_date;
 165   return "Can't change _date!" unless $old->_date == $new->_date;
 166   return "Can't change charged!" unless $old->charged == $new->charged
 167                                      || $old->charged == 0;
 168
 169   '';
 170 }
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid invoice.  If there is an error,
 175 returns the error, otherwise returns false.  Called by the insert and replace
 176 methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('invnum')
 185     || $self->ut_number('custnum')
 186     || $self->ut_numbern('_date')
 187     || $self->ut_money('charged')
 188     || $self->ut_numbern('printed')
 189     || $self->ut_enum('closed', [ '', 'Y' ])
 190   ;
 191   return $error if $error;
 192
 193   return "Unknown customer"
 194     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 195
 196   $self->_date(time) unless $self->_date;
 197
 198   $self->printed(0) if $self->printed eq '';
 199
 200   $self->SUPER::check;
 201 }
 202
 203 =item previous
 204
 205 Returns a list consisting of the total previous balance for this customer,
 206 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 207
 208 =cut
 209
 210 sub previous {
 211   my $self = shift;
 212   my $total = 0;
 213   my @cust_bill = sort { $a->_date <=> $b->_date }
 214     grep { $_->owed != 0 && $_->_date < $self->_date }
 215       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 216   ;
 217   foreach ( @cust_bill ) { $total += $_->owed; }
 218   $total, @cust_bill;
 219 }
 220
 221 =item cust_bill_pkg
 222
 223 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 224
 225 =cut
 226
 227 sub cust_bill_pkg {
 228   my $self = shift;
 229   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 230 }
 231
 232 =item cust_pkg
 233
 234 Returns the packages (see L<FS::cust_pkg>) corresponding to the line items for
 235 this invoice.
 236
 237 =cut
 238
 239 sub cust_pkg {
 240   my $self = shift;
 241   my @cust_pkg = map { $_->cust_pkg } $self->cust_bill_pkg;
 242   my %saw = ();
 243   grep { ! $saw{$_->pkgnum}++ } @cust_pkg;
 244 }
 245
 246 =item open_cust_bill_pkg
 247
 248 Returns the open line items for this invoice.
 249
 250 Note that cust_bill_pkg with both setup and recur fees are returned as two
 251 separate line items, each with only one fee.
 252
 253 =cut
 254
 255 # modeled after cust_main::open_cust_bill
 256 sub open_cust_bill_pkg {
 257   my $self = shift;
 258
 259   # grep { $_->owed > 0 } $self->cust_bill_pkg
 260
 261   my %other = ( 'recur' => 'setup',
 262                 'setup' => 'recur', );
 263   my @open = ();
 264   foreach my $field ( qw( recur setup )) {
 265     push @open, map  { $_->set( $other{$field}, 0 ); $_; }
 266                 grep { $_->owed($field) > 0 }
 267                 $self->cust_bill_pkg;
 268   }
 269
 270   @open;
 271 }
 272
 273 =item cust_bill_event
 274
 275 Returns the completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 276
 277 =cut
 278
 279 sub cust_bill_event {
 280   my $self = shift;
 281   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 282 }
 283
 284 =item num_cust_bill_event
 285
 286 Returns the number of completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 287
 288 =cut
 289
 290 sub num_cust_bill_event {
 291   my $self = shift;
 292   my $sql =
 293     "SELECT COUNT(*) FROM cust_bill_event WHERE invnum = ?";
 294   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 295   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 296   $sth->fetchrow_arrayref->[0];
 297 }
 298
 299 =item cust_event
 300
 301 Returns the new-style customer billing events (see L<FS::cust_event>) for this invoice.
 302
 303 =cut
 304
 305 #false laziness w/cust_pkg.pm
 306 sub cust_event {
 307   my $self = shift;
 308   qsearch({
 309     'table'     => 'cust_event',
 310     'addl_from' => 'JOIN part_event USING ( eventpart )',
 311     'hashref'   => { 'tablenum' => $self->invnum },
 312     'extra_sql' => " AND eventtable = 'cust_bill' ",
 313   });
 314 }
 315
 316 =item num_cust_event
 317
 318 Returns the number of new-style customer billing events (see L<FS::cust_event>) for this invoice.
 319
 320 =cut
 321
 322 #false laziness w/cust_pkg.pm
 323 sub num_cust_event {
 324   my $self = shift;
 325   my $sql =
 326     "SELECT COUNT(*) FROM cust_event JOIN part_event USING ( eventpart ) ".
 327     "  WHERE tablenum = ? AND eventtable = 'cust_bill'";
 328   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 329   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 330   $sth->fetchrow_arrayref->[0];
 331 }
 332
 333 =item cust_main
 334
 335 Returns the customer (see L<FS::cust_main>) for this invoice.
 336
 337 =cut
 338
 339 sub cust_main {
 340   my $self = shift;
 341   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 342 }
 343
 344 =item cust_suspend_if_balance_over AMOUNT
 345
 346 Suspends the customer associated with this invoice if the total amount owed on
 347 this invoice and all older invoices is greater than the specified amount.
 348
 349 Returns a list: an empty list on success or a list of errors.
 350
 351 =cut
 352
 353 sub cust_suspend_if_balance_over {
 354   my( $self, $amount ) = ( shift, shift );
 355   my $cust_main = $self->cust_main;
 356   if ( $cust_main->total_owed_date($self->_date) < $amount ) {
 357     return ();
 358   } else {
 359     $cust_main->suspend(@_);
 360   }
 361 }
 362
 363 =item cust_credit
 364
 365 Depreciated.  See the cust_credited method.
 366
 367  #Returns a list consisting of the total previous credited (see
 368  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 369  #outstanding credits (FS::cust_credit objects).
 370
 371 =cut
 372
 373 sub cust_credit {
 374   use Carp;
 375   croak "FS::cust_bill->cust_credit depreciated; see ".
 376         "FS::cust_bill->cust_credit_bill";
 377   #my $self = shift;
 378   #my $total = 0;
 379   #my @cust_credit = sort { $a->_date <=> $b->_date }
 380   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 381   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 382   #;
 383   #foreach (@cust_credit) { $total += $_->credited; }
 384   #$total, @cust_credit;
 385 }
 386
 387 =item cust_pay
 388
 389 Depreciated.  See the cust_bill_pay method.
 390
 391 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 392
 393 =cut
 394
 395 sub cust_pay {
 396   use Carp;
 397   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 398   #my $self = shift;
 399   #sort { $a->_date <=> $b->_date }
 400   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 401   #;
 402 }
 403
 404 =item cust_bill_pay
 405
 406 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 407
 408 =cut
 409
 410 sub cust_bill_pay {
 411   my $self = shift;
 412   sort { $a->_date <=> $b->_date }
 413     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 414 }
 415
 416 =item cust_credited
 417
 418 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 419
 420 =cut
 421
 422 sub cust_credited {
 423   my $self = shift;
 424   sort { $a->_date <=> $b->_date }
 425     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 426   ;
 427 }
 428
 429 =item tax
 430
 431 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 432
 433 =cut
 434
 435 sub tax {
 436   my $self = shift;
 437   my $total = 0;
 438   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 439                                              'pkgnum' => 0 } );
 440   foreach (@taxlines) { $total += $_->setup; }
 441   $total;
 442 }
 443
 444 =item owed
 445
 446 Returns the amount owed (still outstanding) on this invoice, which is charged
 447 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 448 applications (see L<FS::cust_credit_bill>).
 449
 450 =cut
 451
 452 sub owed {
 453   my $self = shift;
 454   my $balance = $self->charged;
 455   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 456   $balance -= $_->amount foreach ( $self->cust_credited );
 457   $balance = sprintf( "%.2f", $balance);
 458   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 459   $balance;
 460 }
 461
 462 =item apply_payments_and_credits
 463
 464 =cut
 465
 466 sub apply_payments_and_credits {
 467   my $self = shift;
 468
 469   local $SIG{HUP} = 'IGNORE';
 470   local $SIG{INT} = 'IGNORE';
 471   local $SIG{QUIT} = 'IGNORE';
 472   local $SIG{TERM} = 'IGNORE';
 473   local $SIG{TSTP} = 'IGNORE';
 474   local $SIG{PIPE} = 'IGNORE';
 475
 476   my $oldAutoCommit = $FS::UID::AutoCommit;
 477   local $FS::UID::AutoCommit = 0;
 478   my $dbh = dbh;
 479
 480   $self->select_for_update; #mutex
 481
 482   my @payments = grep { $_->unapplied > 0 } $self->cust_main->cust_pay;
 483   my @credits  = grep { $_->credited > 0 } $self->cust_main->cust_credit;
 484
 485   while ( $self->owed > 0 and ( @payments || @credits ) ) {
 486
 487     my $app = '';
 488     if ( @payments && @credits ) {
 489
 490       #decide which goes first by weight of top (unapplied) line item
 491
 492       my @open_lineitems = $self->open_cust_bill_pkg;
 493
 494       my $max_pay_weight =
 495         max( map  { $_->part_pkg->pay_weight || 0 }
 496              grep { $_ }
 497              map  { $_->cust_pkg }
 498                   @open_lineitems
 499            );
 500       my $max_credit_weight =
 501         max( map  { $_->part_pkg->credit_weight || 0 }
 502              grep { $_ }
 503              map  { $_->cust_pkg }
 504                   @open_lineitems
 505            );
 506
 507       #if both are the same... payments first?  it has to be something
 508       if ( $max_pay_weight >= $max_credit_weight ) {
 509         $app = 'pay';
 510       } else {
 511         $app = 'credit';
 512       }
 513
 514     } elsif ( @payments ) {
 515       $app = 'pay';
 516     } elsif ( @credits ) {
 517       $app = 'credit';
 518     } else {
 519       die "guru meditation #12 and 35";
 520     }
 521
 522     if ( $app eq 'pay' ) {
 523
 524       my $payment = shift @payments;
 525
 526       $app = new FS::cust_bill_pay {
 527         'paynum'  => $payment->paynum,
 528         'amount'  => sprintf('%.2f', min( $payment->unapplied, $self->owed ) ),
 529       };
 530
 531     } elsif ( $app eq 'credit' ) {
 532
 533       my $credit = shift @credits;
 534
 535       $app = new FS::cust_credit_bill {
 536         'crednum' => $credit->crednum,
 537         'amount'  => sprintf('%.2f', min( $credit->credited, $self->owed ) ),
 538       };
 539
 540     } else {
 541       die "guru meditation #12 and 35";
 542     }
 543
 544     $app->invnum( $self->invnum );
 545
 546     my $error = $app->insert;
 547     if ( $error ) {
 548       $dbh->rollback if $oldAutoCommit;
 549       return "Error inserting ". $app->table. " record: $error";
 550     }
 551     die $error if $error;
 552
 553   }
 554
 555   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 556   ''; #no error
 557
 558 }
 559
 560 =item generate_email PARAMHASH
 561
 562 PARAMHASH can contain the following:
 563
 564 =over 4
 565
 566 =item from       => sender address, required
 567
 568 =item tempate    => alternate template name, optional
 569
 570 =item print_text => text attachment arrayref, optional
 571
 572 =item subject    => email subject, optional
 573
 574 =back
 575
 576 Returns an argument list to be passed to L<FS::Misc::send_email>.
 577
 578 =cut
 579
 580 use MIME::Entity;
 581
 582 sub generate_email {
 583
 584   my $self = shift;
 585   my %args = @_;
 586
 587   my $me = '[FS::cust_bill::generate_email]';
 588
 589   my %return = (
 590     'from'      => $args{'from'},
 591     'subject'   => (($args{'subject'}) ? $args{'subject'} : 'Invoice'),
 592   );
 593
 594   if (ref($args{'to'}) eq 'ARRAY') {
 595     $return{'to'} = $args{'to'};
 596   } else {
 597     $return{'to'} = [ grep { $_ !~ /^(POST|FAX)$/ }
 598                            $self->cust_main->invoicing_list
 599                     ];
 600   }
 601
 602   if ( $conf->exists('invoice_html') ) {
 603
 604     warn "$me creating HTML/text multipart message"
 605       if $DEBUG;
 606
 607     $return{'nobody'} = 1;
 608
 609     my $alternative = build MIME::Entity
 610       'Type'        => 'multipart/alternative',
 611       'Encoding'    => '7bit',
 612       'Disposition' => 'inline'
 613     ;
 614
 615     my $data;
 616     if ( $conf->exists('invoice_email_pdf')
 617          and scalar($conf->config('invoice_email_pdf_note')) ) {
 618
 619       warn "$me using 'invoice_email_pdf_note' in multipart message"
 620         if $DEBUG;
 621       $data = [ map { $_ . "\n" }
 622                     $conf->config('invoice_email_pdf_note')
 623               ];
 624
 625     } else {
 626
 627       warn "$me not using 'invoice_email_pdf_note' in multipart message"
 628         if $DEBUG;
 629       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 630         $data = $args{'print_text'};
 631       } else {
 632         $data = [ $self->print_text('', $args{'template'}) ];
 633       }
 634
 635     }
 636
 637     $alternative->attach(
 638       'Type'        => 'text/plain',
 639       #'Encoding'    => 'quoted-printable',
 640       'Encoding'    => '7bit',
 641       'Data'        => $data,
 642       'Disposition' => 'inline',
 643     );
 644
 645     $args{'from'} =~ /\@([\w\.\-]+)/;
 646     my $from = $1 || 'example.com';
 647     my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
 648
 649     my $path = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
 650     my $file;
 651     if ( defined($args{'template'}) && length($args{'template'})
 652          && -e "$path/logo_". $args{'template'}. ".png"
 653        )
 654     {
 655       $file = "$path/logo_". $args{'template'}. ".png";
 656     } else {
 657       $file = "$path/logo.png";
 658     }
 659
 660     my $image = build MIME::Entity
 661       'Type'       => 'image/png',
 662       'Encoding'   => 'base64',
 663       'Path'       => $file,
 664       'Filename'   => 'logo.png',
 665       'Content-ID' => "<$content_id>",
 666     ;
 667
 668     $alternative->attach(
 669       'Type'        => 'text/html',
 670       'Encoding'    => 'quoted-printable',
 671       'Data'        => [ '<html>',
 672                          '  <head>',
 673                          '    <title>',
 674                          '      '. encode_entities($return{'subject'}),
 675                          '    </title>',
 676                          '  </head>',
 677                          '  <body bgcolor="#e8e8e8">',
 678                          $self->print_html('', $args{'template'}, $content_id),
 679                          '  </body>',
 680                          '</html>',
 681                        ],
 682       'Disposition' => 'inline',
 683       #'Filename'    => 'invoice.pdf',
 684     );
 685
 686     if ( $conf->exists('invoice_email_pdf') ) {
 687
 688       #attaching pdf too:
 689       # multipart/mixed
 690       #   multipart/related
 691       #     multipart/alternative
 692       #       text/plain
 693       #       text/html
 694       #     image/png
 695       #   application/pdf
 696
 697       my $related = build MIME::Entity 'Type'     => 'multipart/related',
 698                                        'Encoding' => '7bit';
 699
 700       #false laziness w/Misc::send_email
 701       $related->head->replace('Content-type',
 702         $related->mime_type.
 703         '; boundary="'. $related->head->multipart_boundary. '"'.
 704         '; type=multipart/alternative'
 705       );
 706
 707       $related->add_part($alternative);
 708
 709       $related->add_part($image);
 710
 711       my $pdf = build MIME::Entity $self->mimebuild_pdf('', $args{'template'});
 712
 713       $return{'mimeparts'} = [ $related, $pdf ];
 714
 715     } else {
 716
 717       #no other attachment:
 718       # multipart/related
 719       #   multipart/alternative
 720       #     text/plain
 721       #     text/html
 722       #   image/png
 723
 724       $return{'content-type'} = 'multipart/related';
 725       $return{'mimeparts'} = [ $alternative, $image ];
 726       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
 727       #$return{'disposition'} = 'inline';
 728
 729     }
 730
 731   } else {
 732
 733     if ( $conf->exists('invoice_email_pdf') ) {
 734       warn "$me creating PDF attachment"
 735         if $DEBUG;
 736
 737       #mime parts arguments a la MIME::Entity->build().
 738       $return{'mimeparts'} = [
 739         { $self->mimebuild_pdf('', $args{'template'}) }
 740       ];
 741     }
 742
 743     if ( $conf->exists('invoice_email_pdf')
 744          and scalar($conf->config('invoice_email_pdf_note')) ) {
 745
 746       warn "$me using 'invoice_email_pdf_note'"
 747         if $DEBUG;
 748       $return{'body'} = [ map { $_ . "\n" }
 749                               $conf->config('invoice_email_pdf_note')
 750                         ];
 751
 752     } else {
 753
 754       warn "$me not using 'invoice_email_pdf_note'"
 755         if $DEBUG;
 756       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 757         $return{'body'} = $args{'print_text'};
 758       } else {
 759         $return{'body'} = [ $self->print_text('', $args{'template'}) ];
 760       }
 761
 762     }
 763
 764   }
 765
 766   %return;
 767
 768 }
 769
 770 =item mimebuild_pdf
 771
 772 Returns a list suitable for passing to MIME::Entity->build(), representing
 773 this invoice as PDF attachment.
 774
 775 =cut
 776
 777 sub mimebuild_pdf {
 778   my $self = shift;
 779   (
 780     'Type'        => 'application/pdf',
 781     'Encoding'    => 'base64',
 782     'Data'        => [ $self->print_pdf(@_) ],
 783     'Disposition' => 'attachment',
 784     'Filename'    => 'invoice.pdf',
 785   );
 786 }
 787
 788 =item send [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 789
 790 Sends this invoice to the destinations configured for this customer: sends
 791 email, prints and/or faxes.  See L<FS::cust_main_invoice>.
 792
 793 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 794
 795 AGENTNUM, if specified, means that this invoice will only be sent for customers
 796 of the specified agent or agent(s).  AGENTNUM can be a scalar agentnum (for a
 797 single agent) or an arrayref of agentnums.
 798
 799 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 800
 801 =cut
 802
 803 sub queueable_send {
 804   my %opt = @_;
 805
 806   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 807     or die "invalid invoice number: " . $opt{invnum};
 808
 809   my @args = ( $opt{template}, $opt{agentnum} );
 810   push @args, $opt{invoice_from}
 811     if exists($opt{invoice_from}) && $opt{invoice_from};
 812
 813   my $error = $self->send( @args );
 814   die $error if $error;
 815
 816 }
 817
 818 sub send {
 819   my $self = shift;
 820   my $template = scalar(@_) ? shift : '';
 821   if ( scalar(@_) && $_[0]  ) {
 822     my $agentnums = ref($_[0]) ? shift : [ shift ];
 823     return 'N/A' unless grep { $_ == $self->cust_main->agentnum } @$agentnums;
 824   }
 825
 826   my $invoice_from =
 827     scalar(@_)
 828       ? shift
 829       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 830
 831   my @invoicing_list = $self->cust_main->invoicing_list;
 832
 833   $self->email($template, $invoice_from)
 834     if grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list or !@invoicing_list;
 835
 836   $self->print($template)
 837     if grep { $_ eq 'POST' } @invoicing_list; #postal
 838
 839   $self->fax($template)
 840     if grep { $_ eq 'FAX' } @invoicing_list; #fax
 841
 842   '';
 843
 844 }
 845
 846 =item email [ TEMPLATENAME  [ , INVOICE_FROM ] ]
 847
 848 Emails this invoice.
 849
 850 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 851
 852 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 853
 854 =cut
 855
 856 sub queueable_email {
 857   my %opt = @_;
 858
 859   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 860     or die "invalid invoice number: " . $opt{invnum};
 861
 862   my @args = ( $opt{template} );
 863   push @args, $opt{invoice_from}
 864     if exists($opt{invoice_from}) && $opt{invoice_from};
 865
 866   my $error = $self->email( @args );
 867   die $error if $error;
 868
 869 }
 870
 871 sub email {
 872   my $self = shift;
 873   my $template = scalar(@_) ? shift : '';
 874   my $invoice_from =
 875     scalar(@_)
 876       ? shift
 877       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 878
 879   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 880                             $self->cust_main->invoicing_list;
 881
 882   #better to notify this person than silence
 883   @invoicing_list = ($invoice_from) unless @invoicing_list;
 884
 885   my $error = send_email(
 886     $self->generate_email(
 887       'from'       => $invoice_from,
 888       'to'         => [ grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list ],
 889       'template'   => $template,
 890     )
 891   );
 892   die "can't email invoice: $error\n" if $error;
 893   #die "$error\n" if $error;
 894
 895 }
 896
 897 =item lpr_data [ TEMPLATENAME ]
 898
 899 Returns the postscript or plaintext for this invoice as an arrayref.
 900
 901 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 902
 903 =cut
 904
 905 sub lpr_data {
 906   my( $self, $template) = @_;
 907   $conf->exists('invoice_latex')
 908     ? [ $self->print_ps('', $template) ]
 909     : [ $self->print_text('', $template) ];
 910 }
 911
 912 =item print [ TEMPLATENAME ]
 913
 914 Prints this invoice.
 915
 916 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 917
 918 =cut
 919
 920 sub print {
 921   my $self = shift;
 922   my $template = scalar(@_) ? shift : '';
 923
 924   do_print $self->lpr_data($template);
 925 }
 926
 927 =item fax [ TEMPLATENAME ]
 928
 929 Faxes this invoice.
 930
 931 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 932
 933 =cut
 934
 935 sub fax {
 936   my $self = shift;
 937   my $template = scalar(@_) ? shift : '';
 938
 939   die 'FAX invoice destination not (yet?) supported with plain text invoices.'
 940     unless $conf->exists('invoice_latex');
 941
 942   my $dialstring = $self->cust_main->getfield('fax');
 943   #Check $dialstring?
 944
 945   my $error = send_fax( 'docdata'    => $self->lpr_data($template),
 946                         'dialstring' => $dialstring,
 947                       );
 948   die $error if $error;
 949
 950 }
 951
 952 =item send_if_newest [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 953
 954 Like B<send>, but only sends the invoice if it is the newest open invoice for
 955 this customer.
 956
 957 =cut
 958
 959 sub send_if_newest {
 960   my $self = shift;
 961
 962   return ''
 963     if scalar(
 964                grep { $_->owed > 0 }
 965                     qsearch('cust_bill', {
 966                       'custnum' => $self->custnum,
 967                       #'_date'   => { op=>'>', value=>$self->_date },
 968                       'invnum'  => { op=>'>', value=>$self->invnum },
 969                     } )
 970              );
 971
 972   $self->send(@_);
 973 }
 974
 975 =item send_csv OPTION => VALUE, ...
 976
 977 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 978
 979 Options are:
 980
 981 protocol - currently only "ftp"
 982 server
 983 username
 984 password
 985 dir
 986
 987 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 988 and YYMMDDHHMMSS is a timestamp.
 989
 990 See L</print_csv> for a description of the output format.
 991
 992 =cut
 993
 994 sub send_csv {
 995   my($self, %opt) = @_;
 996
 997   #create file(s)
 998
 999   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1000   mkdir $spooldir, 0700 unless -d $spooldir;
1001
1002   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1003   my $file = "$spooldir/$tracctnum.csv";
1004
1005   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1006
1007   open(CSV, ">$file") or die "can't open $file: $!";
1008   print CSV $header;
1009
1010   print CSV $detail;
1011
1012   close CSV;
1013
1014   my $net;
1015   if ( $opt{protocol} eq 'ftp' ) {
1016     eval "use Net::FTP;";
1017     die $@ if $@;
1018     $net = Net::FTP->new($opt{server}) or die @$;
1019   } else {
1020     die "unknown protocol: $opt{protocol}";
1021   }
1022
1023   $net->login( $opt{username}, $opt{password} )
1024     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
1025
1026   $net->binary or die "can't set binary mode";
1027
1028   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
1029
1030   $net->put($file) or die "can't put $file: $!";
1031
1032   $net->quit;
1033
1034   unlink $file;
1035
1036 }
1037
1038 =item spool_csv
1039
1040 Spools CSV invoice data.
1041
1042 Options are:
1043
1044 =over 4
1045
1046 =item format - 'default' or 'billco'
1047
1048 =item dest - if set (to POST, EMAIL or FAX), only sends spools invoices if the customer has the corresponding invoice destinations set (see L<FS::cust_main_invoice>).
1049
1050 =item agent_spools - if set to a true value, will spool to per-agent files rather than a single global file
1051
1052 =item balanceover - if set, only spools the invoice if the total amount owed on this invoice and all older invoices is greater than the specified amount.
1053
1054 =back
1055
1056 =cut
1057
1058 sub spool_csv {
1059   my($self, %opt) = @_;
1060
1061   my $cust_main = $self->cust_main;
1062
1063   if ( $opt{'dest'} ) {
1064     my %invoicing_list = map { /^(POST|FAX)$/ or 'EMAIL' =~ /^(.*)$/; $1 => 1 }
1065                              $cust_main->invoicing_list;
1066     return 'N/A' unless $invoicing_list{$opt{'dest'}}
1067                      || ! keys %invoicing_list;
1068   }
1069
1070   if ( $opt{'balanceover'} ) {
1071     return 'N/A'
1072       if $cust_main->total_owed_date($self->_date) < $opt{'balanceover'};
1073   }
1074
1075   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1076   mkdir $spooldir, 0700 unless -d $spooldir;
1077
1078   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1079
1080   my $file =
1081     "$spooldir/".
1082     ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1083     ( lc($opt{'format'}) eq 'billco' ? '-header' : '' ) .
1084     '.csv';
1085
1086   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1087
1088   open(CSV, ">>$file") or die "can't open $file: $!";
1089   flock(CSV, LOCK_EX);
1090   seek(CSV, 0, 2);
1091
1092   print CSV $header;
1093
1094   if ( lc($opt{'format'}) eq 'billco' ) {
1095
1096     flock(CSV, LOCK_UN);
1097     close CSV;
1098
1099     $file =
1100       "$spooldir/".
1101       ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1102       '-detail.csv';
1103
1104     open(CSV,">>$file") or die "can't open $file: $!";
1105     flock(CSV, LOCK_EX);
1106     seek(CSV, 0, 2);
1107   }
1108
1109   print CSV $detail;
1110
1111   flock(CSV, LOCK_UN);
1112   close CSV;
1113
1114   return '';
1115
1116 }
1117
1118 =item print_csv OPTION => VALUE, ...
1119
1120 Returns CSV data for this invoice.
1121
1122 Options are:
1123
1124 format - 'default' or 'billco'
1125
1126 Returns a list consisting of two scalars.  The first is a single line of CSV
1127 header information for this invoice.  The second is one or more lines of CSV
1128 detail information for this invoice.
1129
1130 If I<format> is not specified or "default", the fields of the CSV file are as
1131 follows:
1132
1133 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
1134
1135 =over 4
1136
1137 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
1138
1139 B<record_type> is C<cust_bill> for the initial header line only.  The
1140 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
1141 fields are filled in.
1142
1143 B<record_type> is C<cust_bill_pkg> for detail lines.  Only the first two fields
1144 (B<record_type> and B<invnum>) and the last five fields (B<pkg> through B<edate>)
1145 are filled in.
1146
1147 =item invnum - invoice number
1148
1149 =item custnum - customer number
1150
1151 =item _date - invoice date
1152
1153 =item charged - total invoice amount
1154
1155 =item first - customer first name
1156
1157 =item last - customer first name
1158
1159 =item company - company name
1160
1161 =item address1 - address line 1
1162
1163 =item address2 - address line 1
1164
1165 =item city
1166
1167 =item state
1168
1169 =item zip
1170
1171 =item country
1172
1173 =item pkg - line item description
1174
1175 =item setup - line item setup fee (one or both of B<setup> and B<recur> will be defined)
1176
1177 =item recur - line item recurring fee (one or both of B<setup> and B<recur> will be defined)
1178
1179 =item sdate - start date for recurring fee
1180
1181 =item edate - end date for recurring fee
1182
1183 =back
1184
1185 If I<format> is "billco", the fields of the header CSV file are as follows:
1186
1187   +-------------------------------------------------------------------+
1188   |                        FORMAT HEADER FILE                         |
1189   |-------------------------------------------------------------------|
1190   | Field | Description                   | Name       | Type | Width |
1191   | 1     | N/A-Leave Empty               | RC         | CHAR |     2 |
1192   | 2     | N/A-Leave Empty               | CUSTID     | CHAR |    15 |
1193   | 3     | Transaction Account No        | TRACCTNUM  | CHAR |    15 |
1194   | 4     | Transaction Invoice No        | TRINVOICE  | CHAR |    15 |
1195   | 5     | Transaction Zip Code          | TRZIP      | CHAR |     5 |
1196   | 6     | Transaction Company Bill To   | TRCOMPANY  | CHAR |    30 |
1197   | 7     | Transaction Contact Bill To   | TRNAME     | CHAR |    30 |
1198   | 8     | Additional Address Unit Info  | TRADDR1    | CHAR |    30 |
1199   | 9     | Bill To Street Address        | TRADDR2    | CHAR |    30 |
1200   | 10    | Ancillary Billing Information | TRADDR3    | CHAR |    30 |
1201   | 11    | Transaction City Bill To      | TRCITY     | CHAR |    20 |
1202   | 12    | Transaction State Bill To     | TRSTATE    | CHAR |     2 |
1203   | 13    | Bill Cycle Close Date         | CLOSEDATE  | CHAR |    10 |
1204   | 14    | Bill Due Date                 | DUEDATE    | CHAR |    10 |
1205   | 15    | Previous Balance              | BALFWD     | NUM* |     9 |
1206   | 16    | Pmt/CR Applied                | CREDAPPLY  | NUM* |     9 |
1207   | 17    | Total Current Charges         | CURRENTCHG | NUM* |     9 |
1208   | 18    | Total Amt Due                 | TOTALDUE   | NUM* |     9 |
1209   | 19    | Total Amt Due                 | AMTDUE     | NUM* |     9 |
1210   | 20    | 30 Day Aging                  | AMT30      | NUM* |     9 |
1211   | 21    | 60 Day Aging                  | AMT60      | NUM* |     9 |
1212   | 22    | 90 Day Aging                  | AMT90      | NUM* |     9 |
1213   | 23    | Y/N                           | AGESWITCH  | CHAR |     1 |
1214   | 24    | Remittance automation         | SCANLINE   | CHAR |   100 |
1215   | 25    | Total Taxes & Fees            | TAXTOT     | NUM* |     9 |
1216   | 26    | Customer Reference Number     | CUSTREF    | CHAR |    15 |
1217   | 27    | Federal Tax***                | FEDTAX     | NUM* |     9 |
1218   | 28    | State Tax***                  | STATETAX   | NUM* |     9 |
1219   | 29    | Other Taxes & Fees***         | OTHERTAX   | NUM* |     9 |
1220   +-------+-------------------------------+------------+------+-------+
1221
1222 If I<format> is "billco", the fields of the detail CSV file are as follows:
1223
1224                                   FORMAT FOR DETAIL FILE
1225         |                            |           |      |
1226   Field | Description                | Name      | Type | Width
1227   1     | N/A-Leave Empty            | RC        | CHAR |     2
1228   2     | N/A-Leave Empty            | CUSTID    | CHAR |    15
1229   3     | Account Number             | TRACCTNUM | CHAR |    15
1230   4     | Invoice Number             | TRINVOICE | CHAR |    15
1231   5     | Line Sequence (sort order) | LINESEQ   | NUM  |     6
1232   6     | Transaction Detail         | DETAILS   | CHAR |   100
1233   7     | Amount                     | AMT       | NUM* |     9
1234   8     | Line Format Control**      | LNCTRL    | CHAR |     2
1235   9     | Grouping Code              | GROUP     | CHAR |     2
1236   10    | User Defined               | ACCT CODE | CHAR |    15
1237
1238 =cut
1239
1240 sub print_csv {
1241   my($self, %opt) = @_;
1242
1243   eval "use Text::CSV_XS";
1244   die $@ if $@;
1245
1246   my $cust_main = $self->cust_main;
1247
1248   my $csv = Text::CSV_XS->new({'always_quote'=>1});
1249
1250   if ( lc($opt{'format'}) eq 'billco' ) {
1251
1252     my $taxtotal = 0;
1253     $taxtotal += $_->{'amount'} foreach $self->_items_tax;
1254
1255     my $duedate = $self->due_date2str('%m/%d/%Y'); #date_format?
1256
1257     my( $previous_balance, @unused ) = $self->previous; #previous balance
1258
1259     my $pmt_cr_applied = 0;
1260     $pmt_cr_applied += $_->{'amount'}
1261       foreach ( $self->_items_payments, $self->_items_credits ) ;
1262
1263     my $totaldue = sprintf('%.2f', $self->owed + $previous_balance);
1264
1265     $csv->combine(
1266       '',                         #  1 | N/A-Leave Empty               CHAR   2
1267       '',                         #  2 | N/A-Leave Empty               CHAR  15
1268       $opt{'tracctnum'},          #  3 | Transaction Account No        CHAR  15
1269       $self->invnum,              #  4 | Transaction Invoice No        CHAR  15
1270       $cust_main->zip,            #  5 | Transaction Zip Code          CHAR   5
1271       $cust_main->company,        #  6 | Transaction Company Bill To   CHAR  30
1272       #$cust_main->payname,        #  7 | Transaction Contact Bill To   CHAR  30
1273       $cust_main->contact,        #  7 | Transaction Contact Bill To   CHAR  30
1274       $cust_main->address2,       #  8 | Additional Address Unit Info  CHAR  30
1275       $cust_main->address1,       #  9 | Bill To Street Address        CHAR  30
1276       '',                         # 10 | Ancillary Billing Information CHAR  30
1277       $cust_main->city,           # 11 | Transaction City Bill To      CHAR  20
1278       $cust_main->state,          # 12 | Transaction State Bill To     CHAR   2
1279
1280       # XXX ?
1281       time2str("%m/%d/%Y", $self->_date), # 13 | Bill Cycle Close Date CHAR  10
1282
1283       # XXX ?
1284       $duedate,                   # 14 | Bill Due Date                 CHAR  10
1285
1286       $previous_balance,          # 15 | Previous Balance              NUM*   9
1287       $pmt_cr_applied,            # 16 | Pmt/CR Applied                NUM*   9
1288       sprintf("%.2f", $self->charged), # 17 | Total Current Charges    NUM*   9
1289       $totaldue,                  # 18 | Total Amt Due                 NUM*   9
1290       $totaldue,                  # 19 | Total Amt Due                 NUM*   9
1291       '',                         # 20 | 30 Day Aging                  NUM*   9
1292       '',                         # 21 | 60 Day Aging                  NUM*   9
1293       '',                         # 22 | 90 Day Aging                  NUM*   9
1294       'N',                        # 23 | Y/N                           CHAR   1
1295       '',                         # 24 | Remittance automation         CHAR 100
1296       $taxtotal,                  # 25 | Total Taxes & Fees            NUM*   9
1297       $self->custnum,             # 26 | Customer Reference Number     CHAR  15
1298       '0',                        # 27 | Federal Tax***                NUM*   9
1299       sprintf("%.2f", $taxtotal), # 28 | State Tax***                  NUM*   9
1300       '0',                        # 29 | Other Taxes & Fees***         NUM*   9
1301     );
1302
1303   } else {
1304
1305     $csv->combine(
1306       'cust_bill',
1307       $self->invnum,
1308       $self->custnum,
1309       time2str("%x", $self->_date),
1310       sprintf("%.2f", $self->charged),
1311       ( map { $cust_main->getfield($_) }
1312           qw( first last company address1 address2 city state zip country ) ),
1313       map { '' } (1..5),
1314     ) or die "can't create csv";
1315   }
1316
1317   my $header = $csv->string. "\n";
1318
1319   my $detail = '';
1320   if ( lc($opt{'format'}) eq 'billco' ) {
1321
1322     my $lineseq = 0;
1323     foreach my $item ( $self->_items_pkg ) {
1324
1325       $csv->combine(
1326         '',                     #  1 | N/A-Leave Empty            CHAR   2
1327         '',                     #  2 | N/A-Leave Empty            CHAR  15
1328         $opt{'tracctnum'},      #  3 | Account Number             CHAR  15
1329         $self->invnum,          #  4 | Invoice Number             CHAR  15
1330         $lineseq++,             #  5 | Line Sequence (sort order) NUM    6
1331         $item->{'description'}, #  6 | Transaction Detail         CHAR 100
1332         $item->{'amount'},      #  7 | Amount                     NUM*   9
1333         '',                     #  8 | Line Format Control**      CHAR   2
1334         '',                     #  9 | Grouping Code              CHAR   2
1335         '',                     # 10 | User Defined               CHAR  15
1336       );
1337
1338       $detail .= $csv->string. "\n";
1339
1340     }
1341
1342   } else {
1343
1344     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1345
1346       my($pkg, $setup, $recur, $sdate, $edate);
1347       if ( $cust_bill_pkg->pkgnum ) {
1348
1349         ($pkg, $setup, $recur, $sdate, $edate) = (
1350           $cust_bill_pkg->cust_pkg->part_pkg->pkg,
1351           ( $cust_bill_pkg->setup != 0
1352             ? sprintf("%.2f", $cust_bill_pkg->setup )
1353             : '' ),
1354           ( $cust_bill_pkg->recur != 0
1355             ? sprintf("%.2f", $cust_bill_pkg->recur )
1356             : '' ),
1357           ( $cust_bill_pkg->sdate
1358             ? time2str("%x", $cust_bill_pkg->sdate)
1359             : '' ),
1360           ($cust_bill_pkg->edate
1361             ?time2str("%x", $cust_bill_pkg->edate)
1362             : '' ),
1363         );
1364
1365       } else { #pkgnum tax
1366         next unless $cust_bill_pkg->setup != 0;
1367         my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
1368                          ? ( $cust_bill_pkg->itemdesc || 'Tax' )
1369                          : 'Tax';
1370         ($pkg, $setup, $recur, $sdate, $edate) =
1371           ( $itemdesc, sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
1372       }
1373
1374       $csv->combine(
1375         'cust_bill_pkg',
1376         $self->invnum,
1377         ( map { '' } (1..11) ),
1378         ($pkg, $setup, $recur, $sdate, $edate)
1379       ) or die "can't create csv";
1380
1381       $detail .= $csv->string. "\n";
1382
1383     }
1384
1385   }
1386
1387   ( $header, $detail );
1388
1389 }
1390
1391 =item comp
1392
1393 Pays this invoice with a compliemntary payment.  If there is an error,
1394 returns the error, otherwise returns false.
1395
1396 =cut
1397
1398 sub comp {
1399   my $self = shift;
1400   my $cust_pay = new FS::cust_pay ( {
1401     'invnum'   => $self->invnum,
1402     'paid'     => $self->owed,
1403     '_date'    => '',
1404     'payby'    => 'COMP',
1405     'payinfo'  => $self->cust_main->payinfo,
1406     'paybatch' => '',
1407   } );
1408   $cust_pay->insert;
1409 }
1410
1411 =item realtime_card
1412
1413 Attempts to pay this invoice with a credit card payment via a
1414 Business::OnlinePayment realtime gateway.  See
1415 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1416 for supported processors.
1417
1418 =cut
1419
1420 sub realtime_card {
1421   my $self = shift;
1422   $self->realtime_bop( 'CC', @_ );
1423 }
1424
1425 =item realtime_ach
1426
1427 Attempts to pay this invoice with an electronic check (ACH) payment via a
1428 Business::OnlinePayment realtime gateway.  See
1429 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1430 for supported processors.
1431
1432 =cut
1433
1434 sub realtime_ach {
1435   my $self = shift;
1436   $self->realtime_bop( 'ECHECK', @_ );
1437 }
1438
1439 =item realtime_lec
1440
1441 Attempts to pay this invoice with phone bill (LEC) payment via a
1442 Business::OnlinePayment realtime gateway.  See
1443 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1444 for supported processors.
1445
1446 =cut
1447
1448 sub realtime_lec {
1449   my $self = shift;
1450   $self->realtime_bop( 'LEC', @_ );
1451 }
1452
1453 sub realtime_bop {
1454   my( $self, $method ) = @_;
1455
1456   my $cust_main = $self->cust_main;
1457   my $balance = $cust_main->balance;
1458   my $amount = ( $balance < $self->owed ) ? $balance : $self->owed;
1459   $amount = sprintf("%.2f", $amount);
1460   return "not run (balance $balance)" unless $amount > 0;
1461
1462   my $description = 'Internet Services';
1463   if ( $conf->exists('business-onlinepayment-description') ) {
1464     my $dtempl = $conf->config('business-onlinepayment-description');
1465
1466     my $agent_obj = $cust_main->agent
1467       or die "can't retreive agent for $cust_main (agentnum ".
1468              $cust_main->agentnum. ")";
1469     my $agent = $agent_obj->agent;
1470     my $pkgs = join(', ',
1471       map { $_->cust_pkg->part_pkg->pkg }
1472         grep { $_->pkgnum } $self->cust_bill_pkg
1473     );
1474     $description = eval qq("$dtempl");
1475   }
1476
1477   $cust_main->realtime_bop($method, $amount,
1478     'description' => $description,
1479     'invnum'      => $self->invnum,
1480   );
1481
1482 }
1483
1484 =item batch_card OPTION => VALUE...
1485
1486 Adds a payment for this invoice to the pending credit card batch (see
1487 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
1488 runs the payment using a realtime gateway.
1489
1490 =cut
1491
1492 sub batch_card {
1493   my ($self, %options) = @_;
1494   my $cust_main = $self->cust_main;
1495
1496   $options{invnum} = $self->invnum;
1497
1498   $cust_main->batch_card(%options);
1499 }
1500
1501 sub _agent_template {
1502   my $self = shift;
1503   $self->cust_main->agent_template;
1504 }
1505
1506 sub _agent_invoice_from {
1507   my $self = shift;
1508   $self->cust_main->agent_invoice_from;
1509 }
1510
1511 =item print_text [ TIME [ , TEMPLATE ] ]
1512
1513 Returns an text invoice, as a list of lines.
1514
1515 TIME an optional value used to control the printing of overdue messages.  The
1516 default is now.  It isn't the date of the invoice; that's the `_date' field.
1517 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1518 L<Time::Local> and L<Date::Parse> for conversion functions.
1519
1520 =cut
1521
1522 sub print_text {
1523   my( $self, $today, $template ) = @_;
1524
1525   my %params = ( 'format' => 'template' );
1526   $params{'time'} = $today if $today;
1527   $params{'template'} = $template if $template;
1528
1529   $self->print_generic( %params );
1530 }
1531
1532 =item print_latex [ TIME [ , TEMPLATE ] ]
1533
1534 Internal method - returns a filename of a filled-in LaTeX template for this
1535 invoice (Note: add ".tex" to get the actual filename), and a filename of
1536 an associated logo (with the .eps extension included).
1537
1538 See print_ps and print_pdf for methods that return PostScript and PDF output.
1539
1540 TIME an optional value used to control the printing of overdue messages.  The
1541 default is now.  It isn't the date of the invoice; that's the `_date' field.
1542 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1543 L<Time::Local> and L<Date::Parse> for conversion functions.
1544
1545 =cut
1546
1547 sub print_latex {
1548
1549   my( $self, $today, $template ) = @_;
1550
1551   my %params = ( 'format' => 'latex' );
1552   $params{'time'} = $today if $today;
1553   $params{'template'} = $template if $template;
1554
1555   $template ||= $self->_agent_template;
1556
1557   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1558   my $lh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1559                            DIR      => $dir,
1560                            SUFFIX   => '.eps',
1561                            UNLINK   => 0,
1562                          ) or die "can't open temp file: $!\n";
1563
1564   if ($template && $conf->exists("logo_${template}.eps")) {
1565     print $lh $conf->config_binary("logo_${template}.eps")
1566       or die "can't write temp file: $!\n";
1567   }else{
1568     print $lh $conf->config_binary('logo.eps')
1569       or die "can't write temp file: $!\n";
1570   }
1571   close $lh;
1572   $params{'logo_file'} = $lh->filename;
1573
1574   my @filled_in = $self->print_generic( %params );
1575
1576   my $fh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1577                            DIR      => $dir,
1578                            SUFFIX   => '.tex',
1579                            UNLINK   => 0,
1580                          ) or die "can't open temp file: $!\n";
1581   print $fh join('', @filled_in );
1582   close $fh;
1583
1584   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
1585   return ($1, $params{'logo_file'});
1586
1587 }
1588
1589 =item print_generic OPTIONS_HASH
1590
1591 Internal method - returns a filled-in template for this invoice as a scalar.
1592
1593 See print_ps and print_pdf for methods that return PostScript and PDF output.
1594
1595 Non optional options include
1596   format - latex, html, template
1597
1598 Optional options include
1599
1600 template - a value used as a suffix for a configuration template
1601
1602 time - a value used to control the printing of overdue messages.  The
1603 default is now.  It isn't the date of the invoice; that's the `_date' field.
1604 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1605 L<Time::Local> and L<Date::Parse> for conversion functions.
1606
1607 cid -
1608
1609 =cut
1610
1611 sub print_generic {
1612
1613   my( $self, %params ) = @_;
1614   my $today = $params{today} ? $params{today} : time;
1615   warn "FS::cust_bill::print_generic called on $self with suffix $params{template}\n"
1616     if $DEBUG;
1617
1618   my $format = $params{format};
1619   die "Unknown format: $format"
1620     unless $format =~ /^(latex|html|template)$/;
1621
1622   my $cust_main = $self->cust_main;
1623   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
1624     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
1625
1626
1627   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
1628                      'html'     => [ '<%=', '%>' ],
1629                      'template' => [ '{', '}' ],
1630                    );
1631
1632   #create the template
1633   my $template = $params{template} ? $params{template} : $self->_agent_template;
1634   my $templatefile = "invoice_$format";
1635   $templatefile .= "_$template"
1636     if length($template);
1637   my @invoice_template = map "$_\n", $conf->config($templatefile)
1638     or die "cannot load config file $templatefile";
1639
1640   my $old_latex = '';
1641   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
1642     #change this to a die when the old code is removed
1643     warn "old-style invoice template $templatefile; ".
1644          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
1645     $old_latex = 'true';
1646     @invoice_template = _translate_old_latex_format(@invoice_template);
1647   }
1648
1649   my $text_template = new Text::Template(
1650     TYPE => 'ARRAY',
1651     SOURCE => \@invoice_template,
1652     DELIMITERS => $delimiters{$format},
1653   );
1654
1655   $text_template->compile()
1656     or die 'While compiling ' . $templatefile . ': ' . $Text::Template::ERROR;
1657
1658
1659   # additional substitution could possibly cause breakage in existing templates
1660   my %convert_maps = (
1661     'latex' => {
1662                  'notes'         => sub { map "$_", @_ },
1663                  'footer'        => sub { map "$_", @_ },
1664                  'smallfooter'   => sub { map "$_", @_ },
1665                  'returnaddress' => sub { map "$_", @_ },
1666                },
1667     'html'  => {
1668                  'notes' =>
1669                    sub {
1670                      map {
1671                        s/%%(.*)$/<!-- $1 -->/g;
1672                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
1673                        s/\\begin\{enumerate\}/<ol>/g;
1674                        s/\\item /  <li>/g;
1675                        s/\\end\{enumerate\}/<\/ol>/g;
1676                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
1677                        s/\\\\\*/<br>/g;
1678                        s/\\dollar ?/\$/g;
1679                        s/\\#/#/g;
1680                        $_;
1681                      }  @_
1682                    },
1683                  'footer' =>
1684                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1685                  'smallfooter' =>
1686                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1687                  'returnaddress' =>
1688                    sub {
1689                      map {
1690                        s/~/&nbsp;/g;
1691                        s/\\\\\*?\s*$/<BR>/;
1692                        s/\\hyphenation\{[\w\s\-]+}//;
1693                        $_;
1694                      }  @_
1695                    },
1696                },
1697     'template' => {
1698                  'notes' =>
1699                    sub {
1700                      map {
1701                        s/%%.*$//g;
1702                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
1703                        s/\\begin\{enumerate\}//g;
1704                        s/\\item /  * /g;
1705                        s/\\end\{enumerate\}//g;
1706                        s/\\textbf\{(.*)\}/$1/g;
1707                        s/\\\\\*/ /;
1708                        s/\\dollar ?/\$/g;
1709                        $_;
1710                      }  @_
1711                    },
1712                  'footer' =>
1713                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1714                  'smallfooter' =>
1715                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1716                  'returnaddress' =>
1717                    sub {
1718                      map {
1719                        s/~/ /g;
1720                        s/\\\\\*?\s*$/\n/;             # dubious
1721                        s/\\hyphenation\{[\w\s\-]+}//;
1722                        $_;
1723                      }  @_
1724                    },
1725                },
1726   );
1727
1728
1729   # hashes for differing output formats
1730   my %nbsps = ( 'latex'    => '~',
1731                 'html'     => '',    # '&nbps;' would be nice
1732                 'template' => '',    # not used
1733               );
1734   my $nbsp = $nbsps{$format};
1735
1736   my %escape_functions = ( 'latex'    => \&_latex_escape,
1737                            'html'     => \&encode_entities,
1738                            'template' => sub { shift },
1739                          );
1740   my $escape_function = $escape_functions{$format};
1741
1742   my %date_formats = ( 'latex'    => '%b, %o, %Y',
1743                        'html'     => '%b&nbsp;%o,&nbsp;%Y',
1744                        'template' => '%s',
1745                      );
1746   my $date_format = $date_formats{$format};
1747
1748   my %embolden_functions = ( 'latex'    => sub { return '\textbf{'. shift(). '}'
1749                                                },
1750                              'html'     => sub { return '<b>'. shift(). '</b>'
1751                                                },
1752                              'template' => sub { shift },
1753                            );
1754   my $embolden_function = $embolden_functions{$format};
1755
1756
1757   # generate template variables
1758   my $returnaddress;
1759   if (
1760          defined( $conf->config_orbase( "invoice_${format}returnaddress",
1761                                         $template
1762                                       )
1763                 )
1764        && length( $conf->config_orbase( "invoice_${format}returnaddress",
1765                                         $template
1766                                       )
1767                 )
1768   ) {
1769
1770     $returnaddress = join("\n",
1771       $conf->config_orbase("invoice_${format}returnaddress", $template)
1772     );
1773
1774   } elsif ( grep /\S/,
1775             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
1776
1777     my $convert_map = $convert_maps{$format}{'returnaddress'};
1778     $returnaddress =
1779       join( "\n",
1780             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
1781                                                  $template
1782                                                )
1783                          )
1784           );
1785   } elsif ( grep /\S/, $conf->config('company_address') ) {
1786
1787     $returnaddress = join( "\n", $conf->config('company_address') );
1788
1789     $returnaddress =
1790       join( '\\*'."\n", map s/( {2,})/'~' x length($1)/eg,
1791                             $conf->config('company_address')
1792           )
1793         if $format eq 'latex';
1794
1795   } else {
1796
1797     my $warning = "Couldn't find a return address; ".
1798                   "do you need to set the company_address configuration value?";
1799     warn "$warning\n";
1800     $returnaddress = $nbsp;
1801     #$returnaddress = $warning;
1802
1803   }
1804
1805   my %invoice_data = (
1806     'company_name'    => scalar( $conf->config('company_name') ),
1807     'company_address' => join("\n", $conf->config('company_address') ). "\n",
1808     'custnum'         => $self->custnum,
1809     'invnum'          => $self->invnum,
1810     'date'            => time2str($date_format, $self->_date),
1811     'today'           => time2str('%b %o, %Y', $today),
1812     'agent'           => &$escape_function($cust_main->agent->agent),
1813     'payname'         => &$escape_function($cust_main->payname),
1814     'company'         => &$escape_function($cust_main->company),
1815     'address1'        => &$escape_function($cust_main->address1),
1816     'address2'        => &$escape_function($cust_main->address2),
1817     'city'            => &$escape_function($cust_main->city),
1818     'state'           => &$escape_function($cust_main->state),
1819     'zip'             => &$escape_function($cust_main->zip),
1820     'returnaddress'   => $returnaddress,
1821     'quantity'        => 1,
1822     'terms'           => $self->terms,
1823     'template'        => $params{'template'},
1824     #'notes'           => join("\n", $conf->config('invoice_latexnotes') ),
1825     # better hang on to conf_dir for a while
1826     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
1827     'page'            => 1,
1828     'total_pages'     => 1,
1829   );
1830
1831   $invoice_data{'cid'} = $params{'cid'}
1832     if $params{'cid'};
1833
1834   my $countrydefault = $conf->config('countrydefault') || 'US';
1835   if ( $cust_main->country eq $countrydefault ) {
1836     $invoice_data{'country'} = '';
1837   } else {
1838     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
1839   }
1840
1841   my @address = ();
1842   $invoice_data{'address'} = \@address;
1843   push @address,
1844     $cust_main->payname.
1845       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
1846         ? " (P.O. #". $cust_main->payinfo. ")"
1847         : ''
1848       )
1849   ;
1850   push @address, $cust_main->company
1851     if $cust_main->company;
1852   push @address, $cust_main->address1;
1853   push @address, $cust_main->address2
1854     if $cust_main->address2;
1855   push @address,
1856     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
1857   push @address, $invoice_data{'country'}
1858     if $invoice_data{'country'};
1859   push @address, ''
1860     while (scalar(@address) < 5);
1861
1862   #do variable substitution in notes, footer, smallfooter
1863   foreach my $include (qw( notes footer smallfooter )) {
1864
1865     my @inc_src = $conf->config_orbase("invoice_latex$include", $template );
1866     my $convert_map = $convert_maps{$format}{$include};
1867
1868     if (
1869            defined( $conf->config_orbase("invoice_${format}$include", $template) )
1870         && length(  $conf->config_orbase('invoice_${format}$include', $template) )
1871     ) {
1872       @inc_src = $conf->config_orbase("invoice_${format}$include", $template );
1873     } else {
1874       @inc_src =
1875         map { s/\[@--/$delimiters{$format}[0]/g;
1876               s/--@]/$delimiters{$format}[1]/g;
1877               $_;
1878             }
1879         &$convert_map(
1880                        $conf->config_orbase("invoice_latex$include", $template )
1881                      );
1882     }
1883
1884     my $inc_tt = new Text::Template (
1885       TYPE       => 'ARRAY',
1886       SOURCE     => [ map "$_\n", @inc_src ],
1887       DELIMITERS => $delimiters{$format},
1888     ) or die "can't create new Text::Template object: $Text::Template::ERROR";
1889
1890     $inc_tt->compile()
1891       or die "can't compile template: $Text::Template::ERROR";
1892
1893     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1894
1895     $invoice_data{$include} =~ s/\n+$//
1896       if ($format eq 'latex');
1897   }
1898
1899   $invoice_data{'po_line'} =
1900     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
1901       ? &$escape_function("Purchase Order #". $cust_main->payinfo)
1902       : $nbsp;
1903
1904   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1905 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
1906   #my $balance_due = $self->owed + $pr_total - $cr_total;
1907   my $balance_due = $self->owed + $pr_total;
1908
1909   my %money_chars = ( 'latex'    => '',
1910                       'html'     => $conf->config('money_char') || '$',
1911                       'template' => '',
1912                     );
1913   my $money_char = $money_chars{$format};
1914
1915   my %other_money_chars = ( 'latex'    => '\dollar ',
1916                             'html'     => $conf->config('money_char') || '$',
1917                             'template' => '',
1918                           );
1919   my $other_money_char = $other_money_chars{$format};
1920
1921   my @detail_items = ();
1922   my @total_items = ();
1923   my @buf = ();
1924   my @sections = ();
1925
1926   $invoice_data{'detail_items'} = \@detail_items;
1927   $invoice_data{'total_items'} = \@total_items;
1928   $invoice_data{'buf'} = \@buf;
1929   $invoice_data{'sections'} = \@sections;
1930
1931   my $previous_section = { 'description' => 'Previous Charges',
1932                            'subtotal'    => $other_money_char.
1933                                             sprintf('%.2f', $pr_total),
1934                          };
1935
1936   my $multisection = $conf->exists('invoice_sections', $cust_main->agentnum);
1937   if ( $multisection ) {
1938     push @sections, $self->_items_sections;
1939   }else{
1940     push @sections, { 'description' => '', 'subtotal' => '' };
1941   }
1942
1943   foreach my $line_item ( $self->_items_previous ) {
1944     my $detail = {
1945       ext_description => [],
1946     };
1947     $detail->{'ref'} = $line_item->{'pkgnum'};
1948     $detail->{'quantity'} = 1;
1949     $detail->{'section'} = $previous_section;
1950     $detail->{'description'} = &$escape_function($line_item->{'description'});
1951     if ( exists $line_item->{'ext_description'} ) {
1952       @{$detail->{'ext_description'}} = map {
1953         &$escape_function($_);
1954       } @{$line_item->{'ext_description'}};
1955     }
1956     {
1957       my $money = $old_latex ? '' : $money_char;
1958       $detail->{'amount'} = $money. $line_item->{'amount'};
1959     }
1960     $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
1961
1962     push @detail_items, $detail;
1963     push @buf, [ $detail->{'description'},
1964                  $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1965                ];
1966   }
1967
1968   if (@pr_cust_bill) {
1969     push @buf, ['','-----------'];
1970     push @buf, [ 'Total Previous Balance',
1971                  $money_char. sprintf("%10.2f", $pr_total) ];
1972     push @buf, ['',''];
1973   }
1974
1975   foreach my $section (@sections) {
1976
1977     $section->{'subtotal'} = $other_money_char.
1978                              sprintf('%.2f', $section->{'subtotal'})
1979       if $multisection;
1980
1981     if ( $section->{'description'} ) {
1982       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1983                    [ '', '' ],
1984                  );
1985     }
1986
1987     my %options = ();
1988     $options{'section'} = $section if $multisection;
1989
1990     foreach my $line_item ( $self->_items_pkg(%options) ) {
1991       my $detail = {
1992         ext_description => [],
1993       };
1994       $detail->{'ref'} = $line_item->{'pkgnum'};
1995       $detail->{'quantity'} = 1;
1996       $detail->{'section'} = $section;
1997       $detail->{'description'} = &$escape_function($line_item->{'description'});
1998       if ( exists $line_item->{'ext_description'} ) {
1999         @{$detail->{'ext_description'}} = map {
2000           &$escape_function($_);
2001         } @{$line_item->{'ext_description'}};
2002       }
2003       {
2004         my $money = $old_latex ? '' : $money_char;
2005         $detail->{'amount'} = $money. $line_item->{'amount'};
2006       }
2007       $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
2008
2009       push @detail_items, $detail;
2010       push @buf, ( [ $detail->{'description'},
2011                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
2012                    ],
2013                    map { [ " ". $_, '' ] } @{$detail->{'ext_description'}},
2014                  );
2015     }
2016
2017     if ( $section->{'description'} ) {
2018       push @buf, ( ['','-----------'],
2019                    [ $section->{'description'}. ' sub-total',
2020                       $money_char. sprintf("%10.2f", $section->{'subtotal'})
2021                    ],
2022                    [ '', '' ],
2023                    [ '', '' ],
2024                  );
2025     }
2026
2027   }
2028
2029   if ( $multisection ) {
2030     unshift @sections, $previous_section;
2031   }
2032
2033   my $taxtotal = 0;
2034   foreach my $tax ( $self->_items_tax ) {
2035     my $total = {};
2036     $total->{'total_item'} = &$escape_function($tax->{'description'});
2037     $taxtotal += $tax->{'amount'};
2038     $total->{'total_amount'} = $other_money_char. $tax->{'amount'};
2039     push @total_items, $total;
2040     push @buf,[ $total->{'total_item'},
2041                 $money_char. sprintf("%10.2f", $total->{'total_amount'}),
2042               ];
2043
2044   }
2045
2046   if ( $taxtotal ) {
2047     my $total = {};
2048     if ( $multisection ) {
2049       $total->{'total_item'} = 'New charges sub-total';
2050     }else{
2051       $total->{'total_item'} = 'Sub-total';
2052     }
2053     $total->{'total_amount'} =
2054       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
2055     unshift @total_items, $total;
2056   }
2057
2058   push @buf,['','-----------'];
2059   push @buf,['Total New Charges',
2060              $money_char. sprintf("%10.2f",$self->charged) ];
2061   push @buf,['',''];
2062
2063   {
2064     my $total = {};
2065     $total->{'total_item'} = &$embolden_function('Total');
2066     $total->{'total_amount'} =
2067     $total->{'total_amount'} =
2068       &$embolden_function(
2069         $other_money_char.  sprintf('%.2f', $self->charged + $pr_total )
2070       );
2071     push @total_items, $total;
2072     push @buf,['','-----------'];
2073     push @buf,['Total Charges',
2074                $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
2075     push @buf,['',''];
2076   }
2077
2078
2079   #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
2080
2081   # credits
2082   foreach my $credit ( $self->_items_credits ) {
2083     my $total;
2084     $total->{'total_item'} = &$escape_function($credit->{'description'});
2085     #$credittotal
2086     $total->{'total_amount'} = '-'. $other_money_char. $credit->{'amount'};
2087     push @total_items, $total;
2088   }
2089
2090   # credits (again)
2091   foreach ( $self->cust_credited ) {
2092
2093     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2094
2095     my $reason = substr($_->cust_credit->reason,0,32);
2096     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
2097     $reason = " ($reason) " if $reason;
2098     push @buf,[
2099       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".        $reason,
2100       $money_char. sprintf("%10.2f",$_->amount)
2101     ];
2102   }
2103
2104   # payments
2105   foreach my $payment ( $self->_items_payments ) {
2106     my $total = {};
2107     $total->{'total_item'} = &$escape_function($payment->{'description'});
2108     #$paymenttotal
2109     $total->{'total_amount'} = '-'. $other_money_char. $payment->{'amount'};
2110     push @total_items, $total;
2111     push @buf, [ $payment->{'description'},
2112                  $money_char. sprintf("%10.2f", $payment->{'amount'}),
2113                ];
2114   }
2115
2116   {
2117     my $total;
2118     $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
2119     $total->{'total_amount'} =
2120       &$embolden_function(
2121         $other_money_char. sprintf('%.2f', $self->owed + $pr_total )
2122       );
2123     push @total_items, $total;
2124     push @buf,['','-----------'];
2125     push @buf,[$self->balance_due_msg, $money_char.
2126       sprintf("%10.2f", $balance_due ) ];
2127   }
2128
2129   $invoice_data{'logo_file'} = $params{'logo_file'}
2130     if $params{'logo_file'};
2131
2132   $invoice_lines = 0;
2133   my $wasfunc = 0;
2134   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
2135     /invoice_lines\((\d*)\)/;
2136     $invoice_lines += $1 || scalar(@buf);
2137     $wasfunc=1;
2138   }
2139   die "no invoice_lines() functions in template?"
2140     if ( $format eq 'template' && !$wasfunc );
2141
2142   if ($format eq 'template') {
2143
2144     if ( $invoice_lines ) {
2145       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
2146       $invoice_data{'total_pages'}++
2147         if scalar(@buf) % $invoice_lines;
2148     }
2149
2150     #setup subroutine for the template
2151     sub FS::cust_bill::_template::invoice_lines {
2152       my $lines = shift || scalar(@FS::cust_bill::_template::buf);
2153       map {
2154         scalar(@FS::cust_bill::_template::buf)
2155           ? shift @FS::cust_bill::_template::buf
2156           : [ '', '' ];
2157       }
2158       ( 1 .. $lines );
2159     }
2160
2161     my $lines;
2162     my @collect;
2163     while (@buf) {
2164       push @collect, split("\n",
2165         $text_template->fill_in( HASH => \%invoice_data,
2166                                  PACKAGE => 'FS::cust_bill::_template'
2167                                )
2168       );
2169       $FS::cust_bill::_template::page++;
2170     }
2171     map "$_\n", @collect;
2172   }else{
2173     warn "filling in template for invoice ". $self->invnum. "\n"
2174       if $DEBUG;
2175     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
2176       if $DEBUG > 1;
2177
2178     $text_template->fill_in(HASH => \%invoice_data);
2179   }
2180 }
2181
2182 =item print_ps [ TIME [ , TEMPLATE ] ]
2183
2184 Returns an postscript invoice, as a scalar.
2185
2186 TIME an optional value used to control the printing of overdue messages.  The
2187 default is now.  It isn't the date of the invoice; that's the `_date' field.
2188 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2189 L<Time::Local> and L<Date::Parse> for conversion functions.
2190
2191 =cut
2192
2193 sub print_ps {
2194   my $self = shift;
2195
2196   my ($file, $lfile) = $self->print_latex(@_);
2197   my $ps = generate_ps($file);
2198   unlink($lfile);
2199   $ps;
2200
2201 }
2202
2203 =item print_pdf [ TIME [ , TEMPLATE ] ]
2204
2205 Returns an PDF invoice, as a scalar.
2206
2207 TIME an optional value used to control the printing of overdue messages.  The
2208 default is now.  It isn't the date of the invoice; that's the `_date' field.
2209 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2210 L<Time::Local> and L<Date::Parse> for conversion functions.
2211
2212 =cut
2213
2214 sub print_pdf {
2215   my $self = shift;
2216
2217   my ($file, $lfile) = $self->print_latex(@_);
2218
2219   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
2220   chdir($dir);
2221
2222   #system('pdflatex', "$file.tex");
2223   #system('pdflatex', "$file.tex");
2224   #! LaTeX Error: Unknown graphics extension: .eps.
2225
2226   my $sfile = shell_quote $file;
2227
2228   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2229     or die "pslatex $file.tex failed; see $file.log for details?\n";
2230   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2231     or die "pslatex $file.tex failed; see $file.log for details?\n";
2232
2233   #system('dvipdf', "$file.dvi", "$file.pdf" );
2234   system(
2235     "dvips -q -t letter -f $sfile.dvi ".
2236     "| gs -q -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=$sfile.pdf ".
2237     "     -c save pop -"
2238   ) == 0
2239     or die "dvips | gs failed: $!";
2240
2241   open(PDF, "<$file.pdf")
2242     or die "can't open $file.pdf: $! (error in LaTeX template?)\n";
2243
2244   unlink("$file.dvi", "$file.log", "$file.aux", "$file.pdf", "$file.tex");
2245   unlink("$lfile");
2246
2247   my $pdf = '';
2248   while (<PDF>) {
2249     $pdf .= $_;
2250   }
2251
2252   close PDF;
2253
2254   return $pdf;
2255
2256 }
2257
2258 =item print_html [ TIME [ , TEMPLATE [ , CID ] ] ]
2259
2260 Returns an HTML invoice, as a scalar.
2261
2262 TIME an optional value used to control the printing of overdue messages.  The
2263 default is now.  It isn't the date of the invoice; that's the `_date' field.
2264 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2265 L<Time::Local> and L<Date::Parse> for conversion functions.
2266
2267 CID is a MIME Content-ID used to create a "cid:" URL for the logo image, used
2268 when emailing the invoice as part of a multipart/related MIME email.
2269
2270 =cut
2271
2272 sub print_html {
2273   my( $self, $today, $template, $cid ) = @_;
2274
2275   my %params = ( 'format' => 'html' );
2276   $params{'time'} = $today if $today;
2277   $params{'template'} = $template if $template;
2278   $params{'cid'} = $cid if $cid;
2279
2280   $self->print_generic( %params );
2281 }
2282
2283 # quick subroutine for print_latex
2284 #
2285 # There are ten characters that LaTeX treats as special characters, which
2286 # means that they do not simply typeset themselves:
2287 #      # $ % & ~ _ ^ \ { }
2288 #
2289 # TeX ignores blanks following an escaped character; if you want a blank (as
2290 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
2291
2292 sub _latex_escape {
2293   my $value = shift;
2294   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
2295   $value =~ s/([<>])/\$$1\$/g;
2296   $value;
2297 }
2298
2299 #utility methods for print_*
2300
2301 sub _translate_old_latex_format {
2302   warn "_translate_old_latex_format called\n"
2303     if $DEBUG;
2304
2305   my @template = ();
2306   while ( @_ ) {
2307     my $line = shift;
2308
2309     if ( $line =~ /^%%Detail\s*$/ ) {
2310
2311       push @template, q![@--!,
2312                       q!  foreach my $_tr_line (@detail_items) {!,
2313                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
2314                       q!      $_tr_line->{'description'} .= !,
2315                       q!        "\\tabularnewline\n~~".!,
2316                       q!        join( "\\tabularnewline\n~~",!,
2317                       q!          @{$_tr_line->{'ext_description'}}!,
2318                       q!        );!,
2319                       q!    }!;
2320
2321       while ( ( my $line_item_line = shift )
2322               !~ /^%%EndDetail\s*$/                            ) {
2323         $line_item_line =~ s/'/\\'/g;    # nice LTS
2324         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2325         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2326         push @template, "    \$OUT .= '$line_item_line';";
2327       }
2328
2329       push @template, '}',
2330                       '--@]';
2331
2332     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
2333
2334       push @template, '[@--',
2335                       '  foreach my $_tr_line (@total_items) {';
2336
2337       while ( ( my $total_item_line = shift )
2338               !~ /^%%EndTotalDetails\s*$/                      ) {
2339         $total_item_line =~ s/'/\\'/g;    # nice LTS
2340         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2341         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2342         push @template, "    \$OUT .= '$total_item_line';";
2343       }
2344
2345       push @template, '}',
2346                       '--@]';
2347
2348     } else {
2349       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
2350       push @template, $line;
2351     }
2352
2353   }
2354
2355   if ($DEBUG) {
2356     warn "$_\n" foreach @template;
2357   }
2358
2359   (@template);
2360 }
2361
2362 sub terms {
2363   my $self = shift;
2364
2365   #check for an invoice- specific override (eventually)
2366
2367   #check for a customer- specific override
2368   return $self->cust_main->invoice_terms
2369     if $self->cust_main->invoice_terms;
2370
2371   #use configured default or default default
2372   $conf->config('invoice_default_terms') || 'Payable upon receipt';
2373 }
2374
2375 sub due_date {
2376   my $self = shift;
2377   my $duedate = '';
2378   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2379     $duedate = $self->_date() + ( $1 * 86400 );
2380   }
2381   $duedate;
2382 }
2383
2384 sub due_date2str {
2385   my $self = shift;
2386   $self->due_date ? time2str(shift, $self->due_date) : '';
2387 }
2388
2389 sub balance_due_msg {
2390   my $self = shift;
2391   my $msg = 'Balance Due';
2392   return $msg unless $self->terms;
2393   if ( $self->due_date ) {
2394     $msg .= ' - Please pay by '. $self->due_date2str('%x');
2395   } elsif ( $self->terms ) {
2396     $msg .= ' - '. $self->terms;
2397   }
2398   $msg;
2399 }
2400
2401 sub _items_sections {
2402   my $self = shift;
2403
2404   my %s = ();
2405   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
2406
2407     if ( $cust_bill_pkg->pkgnum > 0 ) {
2408
2409       my $desc = $cust_bill_pkg->cust_pkg->part_pkg->classname;
2410
2411       $s{$desc} += $cust_bill_pkg->setup
2412         if ( $cust_bill_pkg->setup != 0 );
2413
2414       $s{$desc} += $cust_bill_pkg->recur
2415         if ( $cust_bill_pkg->recur != 0 );
2416
2417     }
2418
2419   }
2420
2421   map { {'description' => $_, 'subtotal' => $s{$_}} } sort keys %s;
2422
2423 }
2424
2425 sub _items {
2426   my $self = shift;
2427   my @display = scalar(@_)
2428                 ? @_
2429                 : qw( _items_previous _items_pkg );
2430                 #: qw( _items_pkg );
2431                 #: qw( _items_previous _items_pkg _items_tax _items_credits _items_payments );
2432   my @b = ();
2433   foreach my $display ( @display ) {
2434     push @b, $self->$display(@_);
2435   }
2436   @b;
2437 }
2438
2439 sub _items_previous {
2440   my $self = shift;
2441   my $cust_main = $self->cust_main;
2442   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
2443   my @b = ();
2444   foreach ( @pr_cust_bill ) {
2445     push @b, {
2446       'description' => 'Previous Balance, Invoice #'. $_->invnum.
2447                        ' ('. time2str('%x',$_->_date). ')',
2448       #'pkgpart'     => 'N/A',
2449       'pkgnum'      => 'N/A',
2450       'amount'      => sprintf("%.2f", $_->owed),
2451     };
2452   }
2453   @b;
2454
2455   #{
2456   #    'description'     => 'Previous Balance',
2457   #    #'pkgpart'         => 'N/A',
2458   #    'pkgnum'          => 'N/A',
2459   #    'amount'          => sprintf("%10.2f", $pr_total ),
2460   #    'ext_description' => [ map {
2461   #                                 "Invoice ". $_->invnum.
2462   #                                 " (". time2str("%x",$_->_date). ") ".
2463   #                                 sprintf("%10.2f", $_->owed)
2464   #                         } @pr_cust_bill ],
2465
2466   #};
2467 }
2468
2469 sub _items_pkg {
2470   my $self = shift;
2471   my %options = @_;
2472   my $section = delete $options{'section'};
2473   my @cust_bill_pkg =
2474     grep { $_->pkgnum &&
2475            ( defined($section)
2476                ? $_->cust_pkg->part_pkg->classname eq $section->{'description'}
2477                : 1
2478            )
2479          } $self->cust_bill_pkg;
2480   $self->_items_cust_bill_pkg(\@cust_bill_pkg, %options);
2481 }
2482
2483 sub _items_tax {
2484   my $self = shift;
2485   my @cust_bill_pkg = grep { ! $_->pkgnum } $self->cust_bill_pkg;
2486   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2487 }
2488
2489 sub _items_cust_bill_pkg {
2490   my $self = shift;
2491   my $cust_bill_pkg = shift;
2492
2493   my @b = ();
2494   foreach my $cust_bill_pkg ( @$cust_bill_pkg ) {
2495
2496     my $desc = $cust_bill_pkg->desc;
2497
2498     if ( $cust_bill_pkg->pkgnum > 0 ) {
2499
2500       if ( $cust_bill_pkg->setup != 0 ) {
2501         my $description = $desc;
2502         $description .= ' Setup' if $cust_bill_pkg->recur != 0;
2503         my @d = $cust_bill_pkg->cust_pkg->h_labels_short($self->_date);
2504         push @d, $cust_bill_pkg->details if $cust_bill_pkg->recur == 0;
2505         push @b, {
2506           description     => $description,
2507           #pkgpart         => $part_pkg->pkgpart,
2508           pkgnum          => $cust_bill_pkg->pkgnum,
2509           amount          => sprintf("%.2f", $cust_bill_pkg->setup),
2510           ext_description => \@d,
2511         };
2512       }
2513
2514       if ( $cust_bill_pkg->recur != 0 ) {
2515         push @b, {
2516           description     => $desc .
2517                              ( $conf->exists('disable_line_item_date_ranges')
2518                                ? ''
2519                                : " (" .time2str("%x", $cust_bill_pkg->sdate).
2520                                  " - ".time2str("%x", $cust_bill_pkg->edate).")"
2521                              ),
2522           #pkgpart         => $part_pkg->pkgpart,
2523           pkgnum          => $cust_bill_pkg->pkgnum,
2524           amount          => sprintf("%.2f", $cust_bill_pkg->recur),
2525           ext_description =>
2526             [ $cust_bill_pkg->cust_pkg->h_labels_short( $cust_bill_pkg->edate,
2527                                                         $cust_bill_pkg->sdate),
2528               $cust_bill_pkg->details,
2529             ],
2530         };
2531       }
2532
2533     } else { #pkgnum tax or one-shot line item (??)
2534
2535       if ( $cust_bill_pkg->setup != 0 ) {
2536         push @b, {
2537           'description' => $desc,
2538           'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
2539         };
2540       }
2541       if ( $cust_bill_pkg->recur != 0 ) {
2542         push @b, {
2543           'description' => "$desc (".
2544                            time2str("%x", $cust_bill_pkg->sdate). ' - '.
2545                            time2str("%x", $cust_bill_pkg->edate). ')',
2546           'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
2547         };
2548       }
2549
2550     }
2551
2552   }
2553
2554   @b;
2555
2556 }
2557
2558 sub _items_credits {
2559   my $self = shift;
2560
2561   my @b;
2562   #credits
2563   foreach ( $self->cust_credited ) {
2564
2565     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2566
2567     my $reason = $_->cust_credit->reason;
2568     #my $reason = substr($_->cust_credit->reason,0,32);
2569     #$reason .= '...' if length($reason) < length($_->cust_credit->reason);
2570     $reason = " ($reason) " if $reason;
2571     push @b, {
2572       #'description' => 'Credit ref\#'. $_->crednum.
2573       #                 " (". time2str("%x",$_->cust_credit->_date) .")".
2574       #                 $reason,
2575       'description' => 'Credit applied '.
2576                        time2str("%x",$_->cust_credit->_date). $reason,
2577       'amount'      => sprintf("%.2f",$_->amount),
2578     };
2579   }
2580   #foreach ( @cr_cust_credit ) {
2581   #  push @buf,[
2582   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
2583   #    $money_char. sprintf("%10.2f",$_->credited)
2584   #  ];
2585   #}
2586
2587   @b;
2588
2589 }
2590
2591 sub _items_payments {
2592   my $self = shift;
2593
2594   my @b;
2595   #get & print payments
2596   foreach ( $self->cust_bill_pay ) {
2597
2598     #something more elaborate if $_->amount ne ->cust_pay->paid ?
2599
2600     push @b, {
2601       'description' => "Payment received ".
2602                        time2str("%x",$_->cust_pay->_date ),
2603       'amount'      => sprintf("%.2f", $_->amount )
2604     };
2605   }
2606
2607   @b;
2608
2609 }
2610
2611
2612 =back
2613
2614 =head1 SUBROUTINES
2615
2616 =over 4
2617
2618 =item reprint
2619
2620 =cut
2621
2622 sub process_reprint {
2623   process_re_X('print', @_);
2624 }
2625
2626 =item reemail
2627
2628 =cut
2629
2630 sub process_reemail {
2631   process_re_X('email', @_);
2632 }
2633
2634 =item refax
2635
2636 =cut
2637
2638 sub process_refax {
2639   process_re_X('fax', @_);
2640 }
2641
2642 use Storable qw(thaw);
2643 use Data::Dumper;
2644 use MIME::Base64;
2645 sub process_re_X {
2646   my( $method, $job ) = ( shift, shift );
2647   warn "process_re_X $method for job $job\n" if $DEBUG;
2648
2649   my $param = thaw(decode_base64(shift));
2650   warn Dumper($param) if $DEBUG;
2651
2652   re_X(
2653     $method,
2654     $job,
2655     %$param,
2656   );
2657
2658 }
2659
2660 sub re_X {
2661   my($method, $job, %param ) = @_;
2662   if ( $DEBUG ) {
2663     warn "re_X $method for job $job with param:\n".
2664          join( '', map { "  $_ => ". $param{$_}. "\n" } keys %param );
2665   }
2666
2667   #some false laziness w/search/cust_bill.html
2668   my $distinct = '';
2669   my $orderby = 'ORDER BY cust_bill._date';
2670
2671   my $extra_sql = ' WHERE '. FS::cust_bill->search_sql(\%param);
2672
2673   my $addl_from = 'left join cust_main using ( custnum )';
2674
2675   my @cust_bill = qsearch( 'cust_bill',
2676                            {},
2677                            #"$distinct cust_bill.*",
2678                            "cust_bill.*",
2679                            $extra_sql,
2680                            '',
2681                            $addl_from
2682                          );
2683
2684   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
2685   foreach my $cust_bill ( @cust_bill ) {
2686     $cust_bill->$method();
2687
2688     if ( $job ) { #progressbar foo
2689       $num++;
2690       if ( time - $min_sec > $last ) {
2691         my $error = $job->update_statustext(
2692           int( 100 * $num / scalar(@cust_bill) )
2693         );
2694         die $error if $error;
2695         $last = time;
2696       }
2697     }
2698
2699   }
2700
2701 }
2702
2703 =back
2704
2705 =head1 CLASS METHODS
2706
2707 =over 4
2708
2709 =item owed_sql
2710
2711 Returns an SQL fragment to retreive the amount owed (charged minus credited and paid).
2712
2713 =cut
2714
2715 sub owed_sql {
2716   my $class = shift;
2717   'charged - '. $class->paid_sql. ' - '. $class->credited_sql;
2718 }
2719
2720 =item net_sql
2721
2722 Returns an SQL fragment to retreive the net amount (charged minus credited).
2723
2724 =cut
2725
2726 sub net_sql {
2727   my $class = shift;
2728   'charged - '. $class->credited_sql;
2729 }
2730
2731 =item paid_sql
2732
2733 Returns an SQL fragment to retreive the amount paid against this invoice.
2734
2735 =cut
2736
2737 sub paid_sql {
2738   #my $class = shift;
2739   "( SELECT COALESCE(SUM(amount),0) FROM cust_bill_pay
2740        WHERE cust_bill.invnum = cust_bill_pay.invnum   )";
2741 }
2742
2743 =item credited_sql
2744
2745 Returns an SQL fragment to retreive the amount credited against this invoice.
2746
2747 =cut
2748
2749 sub credited_sql {
2750   #my $class = shift;
2751   "( SELECT COALESCE(SUM(amount),0) FROM cust_credit_bill
2752        WHERE cust_bill.invnum = cust_credit_bill.invnum   )";
2753 }
2754
2755 =item search_sql HASHREF
2756
2757 Class method which returns an SQL WHERE fragment to search for parameters
2758 specified in HASHREF.  Valid parameters are
2759
2760 =over 4
2761
2762 =item begin
2763
2764 Epoch date (UNIX timestamp) setting a lower bound for _date values
2765
2766 =item end
2767
2768 Epoch date (UNIX timestamp) setting an upper bound for _date values
2769
2770 =item invnum_min
2771
2772 =item invnum_max
2773
2774 =item agentnum
2775
2776 =item owed
2777
2778 =item net
2779
2780 =item days
2781
2782 =item newest_percust
2783
2784 =back
2785
2786 Note: validates all passed-in data; i.e. safe to use with unchecked CGI params.
2787
2788 =cut
2789
2790 sub search_sql {
2791   my($class, $param) = @_;
2792   my @search = ();
2793
2794   if ( $param->{'begin'} =~ /^(\d+)$/ ) {
2795     push @search, "cust_bill._date >= $1";
2796   }
2797   if ( $param->{'end'} =~ /^(\d+)$/ ) {
2798     push @search, "cust_bill._date < $1";
2799   }
2800   if ( $param->{'invnum_min'} =~ /^(\d+)$/ ) {
2801     push @search, "cust_bill.invnum >= $1";
2802   }
2803   if ( $param->{'invnum_max'} =~ /^(\d+)$/ ) {
2804     push @search, "cust_bill.invnum <= $1";
2805   }
2806   if ( $param->{'agentnum'} =~ /^(\d+)$/ ) {
2807     push @search, "cust_main.agentnum = $1";
2808   }
2809
2810   push @search, '0 != '. FS::cust_bill->owed_sql
2811     if $param->{'open'};
2812
2813   push @search, '0 != '. FS::cust_bill->net_sql
2814     if $param->{'net'};
2815
2816   push @search, "cust_bill._date < ". (time-86400*$param->{'days'})
2817     if $param->{'days'};
2818
2819   if ( $param->{'newest_percust'} ) {
2820
2821     #$distinct = 'DISTINCT ON ( cust_bill.custnum )';
2822     #$orderby = 'ORDER BY cust_bill.custnum ASC, cust_bill._date DESC';
2823
2824     my @newest_where = map { my $x = $_;
2825                              $x =~ s/\bcust_bill\./newest_cust_bill./g;
2826                              $x;
2827                            }
2828                            grep ! /^cust_main./, @search;
2829     my $newest_where = scalar(@newest_where)
2830                          ? ' AND '. join(' AND ', @newest_where)
2831                          : '';
2832
2833
2834     push @search, "cust_bill._date = (
2835       SELECT(MAX(newest_cust_bill._date)) FROM cust_bill AS newest_cust_bill
2836         WHERE newest_cust_bill.custnum = cust_bill.custnum
2837           $newest_where
2838     )";
2839
2840   }
2841
2842   push @search, $FS::CurrentUser::CurrentUser->agentnums_sql;
2843
2844   join(' AND ', @search );
2845
2846 }
2847
2848 =back
2849
2850 =head1 BUGS
2851
2852 The delete method.
2853
2854 =head1 SEE ALSO
2855
2856 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
2857 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
2858 documentation.
2859
2860 =cut
2861
2862 1;
2863