FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf $money_char );
   5 use vars qw( $invoice_lines @buf ); #yuck
   6 use Fcntl qw(:flock); #for spool_csv
   7 use List::Util qw(min max);
   8 use Date::Format;
   9 use Text::Template 1.20;
  10 use File::Temp 0.14;
  11 use String::ShellQuote;
  12 use HTML::Entities;
  13 use Locale::Country;
  14 use FS::UID qw( datasrc );
  15 use FS::Misc qw( send_email send_fax generate_ps do_print );
  16 use FS::Record qw( qsearch qsearchs dbh );
  17 use FS::cust_main_Mixin;
  18 use FS::cust_main;
  19 use FS::cust_bill_pkg;
  20 use FS::cust_credit;
  21 use FS::cust_pay;
  22 use FS::cust_pkg;
  23 use FS::cust_credit_bill;
  24 use FS::pay_batch;
  25 use FS::cust_pay_batch;
  26 use FS::cust_bill_event;
  27 use FS::cust_event;
  28 use FS::part_pkg;
  29 use FS::cust_bill_pay;
  30 use FS::cust_bill_pay_batch;
  31 use FS::part_bill_event;
  32 use FS::payby;
  33
  34 @ISA = qw( FS::cust_main_Mixin FS::Record );
  35
  36 $DEBUG = 0;
  37 $me = '[FS::cust_bill]';
  38
  39 #ask FS::UID to run this stuff for us later
  40 FS::UID->install_callback( sub {
  41   $conf = new FS::Conf;
  42   $money_char = $conf->config('money_char') || '$';
  43 } );
  44
  45 =head1 NAME
  46
  47 FS::cust_bill - Object methods for cust_bill records
  48
  49 =head1 SYNOPSIS
  50
  51   use FS::cust_bill;
  52
  53   $record = new FS::cust_bill \%hash;
  54   $record = new FS::cust_bill { 'column' => 'value' };
  55
  56   $error = $record->insert;
  57
  58   $error = $new_record->replace($old_record);
  59
  60   $error = $record->delete;
  61
  62   $error = $record->check;
  63
  64   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  65
  66   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  67
  68   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  69
  70   @cust_pay_objects = $cust_bill->cust_pay;
  71
  72   $tax_amount = $record->tax;
  73
  74   @lines = $cust_bill->print_text;
  75   @lines = $cust_bill->print_text $time;
  76
  77 =head1 DESCRIPTION
  78
  79 An FS::cust_bill object represents an invoice; a declaration that a customer
  80 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
  81 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
  82 following fields are currently supported:
  83
  84 =over 4
  85
  86 =item invnum - primary key (assigned automatically for new invoices)
  87
  88 =item custnum - customer (see L<FS::cust_main>)
  89
  90 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  91 L<Time::Local> and L<Date::Parse> for conversion functions.
  92
  93 =item charged - amount of this invoice
  94
  95 =item printed - deprecated
  96
  97 =item closed - books closed flag, empty or `Y'
  98
  99 =back
 100
 101 =head1 METHODS
 102
 103 =over 4
 104
 105 =item new HASHREF
 106
 107 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 108 Invoices are normally created by calling the bill method of a customer object
 109 (see L<FS::cust_main>).
 110
 111 =cut
 112
 113 sub table { 'cust_bill'; }
 114
 115 sub cust_linked { $_[0]->cust_main_custnum; }
 116 sub cust_unlinked_msg {
 117   my $self = shift;
 118   "WARNING: can't find cust_main.custnum ". $self->custnum.
 119   ' (cust_bill.invnum '. $self->invnum. ')';
 120 }
 121
 122 =item insert
 123
 124 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 125 returns the error, otherwise returns false.
 126
 127 =item delete
 128
 129 This method now works but you probably shouldn't use it.  Instead, apply a
 130 credit against the invoice.
 131
 132 Using this method to delete invoices outright is really, really bad.  There
 133 would be no record you ever posted this invoice, and there are no check to
 134 make sure charged = 0 or that there are no associated cust_bill_pkg records.
 135
 136 Really, don't use it.
 137
 138 =cut
 139
 140 sub delete {
 141   my $self = shift;
 142   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 143   $self->SUPER::delete(@_);
 144 }
 145
 146 =item replace OLD_RECORD
 147
 148 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 149 returns the error, otherwise returns false.
 150
 151 Only printed may be changed.  printed is normally updated by calling the
 152 collect method of a customer object (see L<FS::cust_main>).
 153
 154 =cut
 155
 156 #replace can be inherited from Record.pm
 157
 158 # replace_check is now the preferred way to #implement replace data checks
 159 # (so $object->replace() works without an argument)
 160
 161 sub replace_check {
 162   my( $new, $old ) = ( shift, shift );
 163   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 164   #return "Can't change _date!" unless $old->_date eq $new->_date;
 165   return "Can't change _date!" unless $old->_date == $new->_date;
 166   return "Can't change charged!" unless $old->charged == $new->charged
 167                                      || $old->charged == 0;
 168
 169   '';
 170 }
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid invoice.  If there is an error,
 175 returns the error, otherwise returns false.  Called by the insert and replace
 176 methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('invnum')
 185     || $self->ut_number('custnum')
 186     || $self->ut_numbern('_date')
 187     || $self->ut_money('charged')
 188     || $self->ut_numbern('printed')
 189     || $self->ut_enum('closed', [ '', 'Y' ])
 190   ;
 191   return $error if $error;
 192
 193   return "Unknown customer"
 194     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 195
 196   $self->_date(time) unless $self->_date;
 197
 198   $self->printed(0) if $self->printed eq '';
 199
 200   $self->SUPER::check;
 201 }
 202
 203 =item previous
 204
 205 Returns a list consisting of the total previous balance for this customer,
 206 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 207
 208 =cut
 209
 210 sub previous {
 211   my $self = shift;
 212   my $total = 0;
 213   my @cust_bill = sort { $a->_date <=> $b->_date }
 214     grep { $_->owed != 0 && $_->_date < $self->_date }
 215       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 216   ;
 217   foreach ( @cust_bill ) { $total += $_->owed; }
 218   $total, @cust_bill;
 219 }
 220
 221 =item cust_bill_pkg
 222
 223 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 224
 225 =cut
 226
 227 sub cust_bill_pkg {
 228   my $self = shift;
 229   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 230 }
 231
 232 =item cust_pkg
 233
 234 Returns the packages (see L<FS::cust_pkg>) corresponding to the line items for
 235 this invoice.
 236
 237 =cut
 238
 239 sub cust_pkg {
 240   my $self = shift;
 241   my @cust_pkg = map { $_->cust_pkg } $self->cust_bill_pkg;
 242   my %saw = ();
 243   grep { ! $saw{$_->pkgnum}++ } @cust_pkg;
 244 }
 245
 246 =item open_cust_bill_pkg
 247
 248 Returns the open line items for this invoice.
 249
 250 Note that cust_bill_pkg with both setup and recur fees are returned as two
 251 separate line items, each with only one fee.
 252
 253 =cut
 254
 255 # modeled after cust_main::open_cust_bill
 256 sub open_cust_bill_pkg {
 257   my $self = shift;
 258
 259   # grep { $_->owed > 0 } $self->cust_bill_pkg
 260
 261   my %other = ( 'recur' => 'setup',
 262                 'setup' => 'recur', );
 263   my @open = ();
 264   foreach my $field ( qw( recur setup )) {
 265     push @open, map  { $_->set( $other{$field}, 0 ); $_; }
 266                 grep { $_->owed($field) > 0 }
 267                 $self->cust_bill_pkg;
 268   }
 269
 270   @open;
 271 }
 272
 273 =item cust_bill_event
 274
 275 Returns the completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 276
 277 =cut
 278
 279 sub cust_bill_event {
 280   my $self = shift;
 281   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 282 }
 283
 284 =item num_cust_bill_event
 285
 286 Returns the number of completed invoice events (deprecated, old-style events - see L<FS::cust_bill_event>) for this invoice.
 287
 288 =cut
 289
 290 sub num_cust_bill_event {
 291   my $self = shift;
 292   my $sql =
 293     "SELECT COUNT(*) FROM cust_bill_event WHERE invnum = ?";
 294   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 295   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 296   $sth->fetchrow_arrayref->[0];
 297 }
 298
 299 =item cust_event
 300
 301 Returns the new-style customer billing events (see L<FS::cust_event>) for this invoice.
 302
 303 =cut
 304
 305 #false laziness w/cust_pkg.pm
 306 sub cust_event {
 307   my $self = shift;
 308   qsearch({
 309     'table'     => 'cust_event',
 310     'addl_from' => 'JOIN part_event USING ( eventpart )',
 311     'hashref'   => { 'tablenum' => $self->invnum },
 312     'extra_sql' => " AND eventtable = 'cust_bill' ",
 313   });
 314 }
 315
 316 =item num_cust_event
 317
 318 Returns the number of new-style customer billing events (see L<FS::cust_event>) for this invoice.
 319
 320 =cut
 321
 322 #false laziness w/cust_pkg.pm
 323 sub num_cust_event {
 324   my $self = shift;
 325   my $sql =
 326     "SELECT COUNT(*) FROM cust_event JOIN part_event USING ( eventpart ) ".
 327     "  WHERE tablenum = ? AND eventtable = 'cust_bill'";
 328   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
 329   $sth->execute($self->invnum) or die $sth->errstr. " executing $sql";
 330   $sth->fetchrow_arrayref->[0];
 331 }
 332
 333 =item cust_main
 334
 335 Returns the customer (see L<FS::cust_main>) for this invoice.
 336
 337 =cut
 338
 339 sub cust_main {
 340   my $self = shift;
 341   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 342 }
 343
 344 =item cust_suspend_if_balance_over AMOUNT
 345
 346 Suspends the customer associated with this invoice if the total amount owed on
 347 this invoice and all older invoices is greater than the specified amount.
 348
 349 Returns a list: an empty list on success or a list of errors.
 350
 351 =cut
 352
 353 sub cust_suspend_if_balance_over {
 354   my( $self, $amount ) = ( shift, shift );
 355   my $cust_main = $self->cust_main;
 356   if ( $cust_main->total_owed_date($self->_date) < $amount ) {
 357     return ();
 358   } else {
 359     $cust_main->suspend(@_);
 360   }
 361 }
 362
 363 =item cust_credit
 364
 365 Depreciated.  See the cust_credited method.
 366
 367  #Returns a list consisting of the total previous credited (see
 368  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 369  #outstanding credits (FS::cust_credit objects).
 370
 371 =cut
 372
 373 sub cust_credit {
 374   use Carp;
 375   croak "FS::cust_bill->cust_credit depreciated; see ".
 376         "FS::cust_bill->cust_credit_bill";
 377   #my $self = shift;
 378   #my $total = 0;
 379   #my @cust_credit = sort { $a->_date <=> $b->_date }
 380   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 381   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 382   #;
 383   #foreach (@cust_credit) { $total += $_->credited; }
 384   #$total, @cust_credit;
 385 }
 386
 387 =item cust_pay
 388
 389 Depreciated.  See the cust_bill_pay method.
 390
 391 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 392
 393 =cut
 394
 395 sub cust_pay {
 396   use Carp;
 397   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 398   #my $self = shift;
 399   #sort { $a->_date <=> $b->_date }
 400   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 401   #;
 402 }
 403
 404 =item cust_bill_pay
 405
 406 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 407
 408 =cut
 409
 410 sub cust_bill_pay {
 411   my $self = shift;
 412   sort { $a->_date <=> $b->_date }
 413     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 414 }
 415
 416 =item cust_credited
 417
 418 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 419
 420 =cut
 421
 422 sub cust_credited {
 423   my $self = shift;
 424   sort { $a->_date <=> $b->_date }
 425     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 426   ;
 427 }
 428
 429 =item tax
 430
 431 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 432
 433 =cut
 434
 435 sub tax {
 436   my $self = shift;
 437   my $total = 0;
 438   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 439                                              'pkgnum' => 0 } );
 440   foreach (@taxlines) { $total += $_->setup; }
 441   $total;
 442 }
 443
 444 =item owed
 445
 446 Returns the amount owed (still outstanding) on this invoice, which is charged
 447 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 448 applications (see L<FS::cust_credit_bill>).
 449
 450 =cut
 451
 452 sub owed {
 453   my $self = shift;
 454   my $balance = $self->charged;
 455   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 456   $balance -= $_->amount foreach ( $self->cust_credited );
 457   $balance = sprintf( "%.2f", $balance);
 458   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 459   $balance;
 460 }
 461
 462 =item apply_payments_and_credits
 463
 464 =cut
 465
 466 sub apply_payments_and_credits {
 467   my $self = shift;
 468
 469   local $SIG{HUP} = 'IGNORE';
 470   local $SIG{INT} = 'IGNORE';
 471   local $SIG{QUIT} = 'IGNORE';
 472   local $SIG{TERM} = 'IGNORE';
 473   local $SIG{TSTP} = 'IGNORE';
 474   local $SIG{PIPE} = 'IGNORE';
 475
 476   my $oldAutoCommit = $FS::UID::AutoCommit;
 477   local $FS::UID::AutoCommit = 0;
 478   my $dbh = dbh;
 479
 480   $self->select_for_update; #mutex
 481
 482   my @payments = grep { $_->unapplied > 0 } $self->cust_main->cust_pay;
 483   my @credits  = grep { $_->credited > 0 } $self->cust_main->cust_credit;
 484
 485   while ( $self->owed > 0 and ( @payments || @credits ) ) {
 486
 487     my $app = '';
 488     if ( @payments && @credits ) {
 489
 490       #decide which goes first by weight of top (unapplied) line item
 491
 492       my @open_lineitems = $self->open_cust_bill_pkg;
 493
 494       my $max_pay_weight =
 495         max( map  { $_->part_pkg->pay_weight || 0 }
 496              grep { $_ }
 497              map  { $_->cust_pkg }
 498                   @open_lineitems
 499            );
 500       my $max_credit_weight =
 501         max( map  { $_->part_pkg->credit_weight || 0 }
 502              grep { $_ }
 503              map  { $_->cust_pkg }
 504                   @open_lineitems
 505            );
 506
 507       #if both are the same... payments first?  it has to be something
 508       if ( $max_pay_weight >= $max_credit_weight ) {
 509         $app = 'pay';
 510       } else {
 511         $app = 'credit';
 512       }
 513
 514     } elsif ( @payments ) {
 515       $app = 'pay';
 516     } elsif ( @credits ) {
 517       $app = 'credit';
 518     } else {
 519       die "guru meditation #12 and 35";
 520     }
 521
 522     if ( $app eq 'pay' ) {
 523
 524       my $payment = shift @payments;
 525
 526       $app = new FS::cust_bill_pay {
 527         'paynum'  => $payment->paynum,
 528         'amount'  => sprintf('%.2f', min( $payment->unapplied, $self->owed ) ),
 529       };
 530
 531     } elsif ( $app eq 'credit' ) {
 532
 533       my $credit = shift @credits;
 534
 535       $app = new FS::cust_credit_bill {
 536         'crednum' => $credit->crednum,
 537         'amount'  => sprintf('%.2f', min( $credit->credited, $self->owed ) ),
 538       };
 539
 540     } else {
 541       die "guru meditation #12 and 35";
 542     }
 543
 544     $app->invnum( $self->invnum );
 545
 546     my $error = $app->insert;
 547     if ( $error ) {
 548       $dbh->rollback if $oldAutoCommit;
 549       return "Error inserting ". $app->table. " record: $error";
 550     }
 551     die $error if $error;
 552
 553   }
 554
 555   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 556   ''; #no error
 557
 558 }
 559
 560 =item generate_email PARAMHASH
 561
 562 PARAMHASH can contain the following:
 563
 564 =over 4
 565
 566 =item from       => sender address, required
 567
 568 =item tempate    => alternate template name, optional
 569
 570 =item print_text => text attachment arrayref, optional
 571
 572 =item subject    => email subject, optional
 573
 574 =back
 575
 576 Returns an argument list to be passed to L<FS::Misc::send_email>.
 577
 578 =cut
 579
 580 use MIME::Entity;
 581
 582 sub generate_email {
 583
 584   my $self = shift;
 585   my %args = @_;
 586
 587   my $me = '[FS::cust_bill::generate_email]';
 588
 589   my %return = (
 590     'from'      => $args{'from'},
 591     'subject'   => (($args{'subject'}) ? $args{'subject'} : 'Invoice'),
 592   );
 593
 594   if (ref($args{'to'}) eq 'ARRAY') {
 595     $return{'to'} = $args{'to'};
 596   } else {
 597     $return{'to'} = [ grep { $_ !~ /^(POST|FAX)$/ }
 598                            $self->cust_main->invoicing_list
 599                     ];
 600   }
 601
 602   if ( $conf->exists('invoice_html') ) {
 603
 604     warn "$me creating HTML/text multipart message"
 605       if $DEBUG;
 606
 607     $return{'nobody'} = 1;
 608
 609     my $alternative = build MIME::Entity
 610       'Type'        => 'multipart/alternative',
 611       'Encoding'    => '7bit',
 612       'Disposition' => 'inline'
 613     ;
 614
 615     my $data;
 616     if ( $conf->exists('invoice_email_pdf')
 617          and scalar($conf->config('invoice_email_pdf_note')) ) {
 618
 619       warn "$me using 'invoice_email_pdf_note' in multipart message"
 620         if $DEBUG;
 621       $data = [ map { $_ . "\n" }
 622                     $conf->config('invoice_email_pdf_note')
 623               ];
 624
 625     } else {
 626
 627       warn "$me not using 'invoice_email_pdf_note' in multipart message"
 628         if $DEBUG;
 629       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 630         $data = $args{'print_text'};
 631       } else {
 632         $data = [ $self->print_text('', $args{'template'}) ];
 633       }
 634
 635     }
 636
 637     $alternative->attach(
 638       'Type'        => 'text/plain',
 639       #'Encoding'    => 'quoted-printable',
 640       'Encoding'    => '7bit',
 641       'Data'        => $data,
 642       'Disposition' => 'inline',
 643     );
 644
 645     $args{'from'} =~ /\@([\w\.\-]+)/;
 646     my $from = $1 || 'example.com';
 647     my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
 648
 649     my $path = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
 650     my $file;
 651     if ( defined($args{'template'}) && length($args{'template'})
 652          && -e "$path/logo_". $args{'template'}. ".png"
 653        )
 654     {
 655       $file = "$path/logo_". $args{'template'}. ".png";
 656     } else {
 657       $file = "$path/logo.png";
 658     }
 659
 660     my $image = build MIME::Entity
 661       'Type'       => 'image/png',
 662       'Encoding'   => 'base64',
 663       'Path'       => $file,
 664       'Filename'   => 'logo.png',
 665       'Content-ID' => "<$content_id>",
 666     ;
 667
 668     $alternative->attach(
 669       'Type'        => 'text/html',
 670       'Encoding'    => 'quoted-printable',
 671       'Data'        => [ '<html>',
 672                          '  <head>',
 673                          '    <title>',
 674                          '      '. encode_entities($return{'subject'}),
 675                          '    </title>',
 676                          '  </head>',
 677                          '  <body bgcolor="#e8e8e8">',
 678                          $self->print_html('', $args{'template'}, $content_id),
 679                          '  </body>',
 680                          '</html>',
 681                        ],
 682       'Disposition' => 'inline',
 683       #'Filename'    => 'invoice.pdf',
 684     );
 685
 686     if ( $conf->exists('invoice_email_pdf') ) {
 687
 688       #attaching pdf too:
 689       # multipart/mixed
 690       #   multipart/related
 691       #     multipart/alternative
 692       #       text/plain
 693       #       text/html
 694       #     image/png
 695       #   application/pdf
 696
 697       my $related = build MIME::Entity 'Type'     => 'multipart/related',
 698                                        'Encoding' => '7bit';
 699
 700       #false laziness w/Misc::send_email
 701       $related->head->replace('Content-type',
 702         $related->mime_type.
 703         '; boundary="'. $related->head->multipart_boundary. '"'.
 704         '; type=multipart/alternative'
 705       );
 706
 707       $related->add_part($alternative);
 708
 709       $related->add_part($image);
 710
 711       my $pdf = build MIME::Entity $self->mimebuild_pdf('', $args{'template'});
 712
 713       $return{'mimeparts'} = [ $related, $pdf ];
 714
 715     } else {
 716
 717       #no other attachment:
 718       # multipart/related
 719       #   multipart/alternative
 720       #     text/plain
 721       #     text/html
 722       #   image/png
 723
 724       $return{'content-type'} = 'multipart/related';
 725       $return{'mimeparts'} = [ $alternative, $image ];
 726       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
 727       #$return{'disposition'} = 'inline';
 728
 729     }
 730
 731   } else {
 732
 733     if ( $conf->exists('invoice_email_pdf') ) {
 734       warn "$me creating PDF attachment"
 735         if $DEBUG;
 736
 737       #mime parts arguments a la MIME::Entity->build().
 738       $return{'mimeparts'} = [
 739         { $self->mimebuild_pdf('', $args{'template'}) }
 740       ];
 741     }
 742
 743     if ( $conf->exists('invoice_email_pdf')
 744          and scalar($conf->config('invoice_email_pdf_note')) ) {
 745
 746       warn "$me using 'invoice_email_pdf_note'"
 747         if $DEBUG;
 748       $return{'body'} = [ map { $_ . "\n" }
 749                               $conf->config('invoice_email_pdf_note')
 750                         ];
 751
 752     } else {
 753
 754       warn "$me not using 'invoice_email_pdf_note'"
 755         if $DEBUG;
 756       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 757         $return{'body'} = $args{'print_text'};
 758       } else {
 759         $return{'body'} = [ $self->print_text('', $args{'template'}) ];
 760       }
 761
 762     }
 763
 764   }
 765
 766   %return;
 767
 768 }
 769
 770 =item mimebuild_pdf
 771
 772 Returns a list suitable for passing to MIME::Entity->build(), representing
 773 this invoice as PDF attachment.
 774
 775 =cut
 776
 777 sub mimebuild_pdf {
 778   my $self = shift;
 779   (
 780     'Type'        => 'application/pdf',
 781     'Encoding'    => 'base64',
 782     'Data'        => [ $self->print_pdf(@_) ],
 783     'Disposition' => 'attachment',
 784     'Filename'    => 'invoice.pdf',
 785   );
 786 }
 787
 788 =item send [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 789
 790 Sends this invoice to the destinations configured for this customer: sends
 791 email, prints and/or faxes.  See L<FS::cust_main_invoice>.
 792
 793 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 794
 795 AGENTNUM, if specified, means that this invoice will only be sent for customers
 796 of the specified agent or agent(s).  AGENTNUM can be a scalar agentnum (for a
 797 single agent) or an arrayref of agentnums.
 798
 799 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 800
 801 =cut
 802
 803 sub queueable_send {
 804   my %opt = @_;
 805
 806   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 807     or die "invalid invoice number: " . $opt{invnum};
 808
 809   my @args = ( $opt{template}, $opt{agentnum} );
 810   push @args, $opt{invoice_from}
 811     if exists($opt{invoice_from}) && $opt{invoice_from};
 812
 813   my $error = $self->send( @args );
 814   die $error if $error;
 815
 816 }
 817
 818 sub send {
 819   my $self = shift;
 820   my $template = scalar(@_) ? shift : '';
 821   if ( scalar(@_) && $_[0]  ) {
 822     my $agentnums = ref($_[0]) ? shift : [ shift ];
 823     return 'N/A' unless grep { $_ == $self->cust_main->agentnum } @$agentnums;
 824   }
 825
 826   my $invoice_from =
 827     scalar(@_)
 828       ? shift
 829       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 830
 831   my @invoicing_list = $self->cust_main->invoicing_list;
 832
 833   $self->email($template, $invoice_from)
 834     if grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list or !@invoicing_list;
 835
 836   $self->print($template)
 837     if grep { $_ eq 'POST' } @invoicing_list; #postal
 838
 839   $self->fax($template)
 840     if grep { $_ eq 'FAX' } @invoicing_list; #fax
 841
 842   '';
 843
 844 }
 845
 846 =item email [ TEMPLATENAME  [ , INVOICE_FROM ] ]
 847
 848 Emails this invoice.
 849
 850 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 851
 852 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 853
 854 =cut
 855
 856 sub queueable_email {
 857   my %opt = @_;
 858
 859   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 860     or die "invalid invoice number: " . $opt{invnum};
 861
 862   my @args = ( $opt{template} );
 863   push @args, $opt{invoice_from}
 864     if exists($opt{invoice_from}) && $opt{invoice_from};
 865
 866   my $error = $self->email( @args );
 867   die $error if $error;
 868
 869 }
 870
 871 sub email {
 872   my $self = shift;
 873   my $template = scalar(@_) ? shift : '';
 874   my $invoice_from =
 875     scalar(@_)
 876       ? shift
 877       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 878
 879   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 880                             $self->cust_main->invoicing_list;
 881
 882   #better to notify this person than silence
 883   @invoicing_list = ($invoice_from) unless @invoicing_list;
 884
 885   my $error = send_email(
 886     $self->generate_email(
 887       'from'       => $invoice_from,
 888       'to'         => [ grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list ],
 889       'template'   => $template,
 890     )
 891   );
 892   die "can't email invoice: $error\n" if $error;
 893   #die "$error\n" if $error;
 894
 895 }
 896
 897 =item lpr_data [ TEMPLATENAME ]
 898
 899 Returns the postscript or plaintext for this invoice as an arrayref.
 900
 901 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 902
 903 =cut
 904
 905 sub lpr_data {
 906   my( $self, $template) = @_;
 907   $conf->exists('invoice_latex')
 908     ? [ $self->print_ps('', $template) ]
 909     : [ $self->print_text('', $template) ];
 910 }
 911
 912 =item print [ TEMPLATENAME ]
 913
 914 Prints this invoice.
 915
 916 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 917
 918 =cut
 919
 920 sub print {
 921   my $self = shift;
 922   my $template = scalar(@_) ? shift : '';
 923
 924   do_print $self->lpr_data($template);
 925 }
 926
 927 =item fax [ TEMPLATENAME ]
 928
 929 Faxes this invoice.
 930
 931 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 932
 933 =cut
 934
 935 sub fax {
 936   my $self = shift;
 937   my $template = scalar(@_) ? shift : '';
 938
 939   die 'FAX invoice destination not (yet?) supported with plain text invoices.'
 940     unless $conf->exists('invoice_latex');
 941
 942   my $dialstring = $self->cust_main->getfield('fax');
 943   #Check $dialstring?
 944
 945   my $error = send_fax( 'docdata'    => $self->lpr_data($template),
 946                         'dialstring' => $dialstring,
 947                       );
 948   die $error if $error;
 949
 950 }
 951
 952 =item send_if_newest [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 953
 954 Like B<send>, but only sends the invoice if it is the newest open invoice for
 955 this customer.
 956
 957 =cut
 958
 959 sub send_if_newest {
 960   my $self = shift;
 961
 962   return ''
 963     if scalar(
 964                grep { $_->owed > 0 }
 965                     qsearch('cust_bill', {
 966                       'custnum' => $self->custnum,
 967                       #'_date'   => { op=>'>', value=>$self->_date },
 968                       'invnum'  => { op=>'>', value=>$self->invnum },
 969                     } )
 970              );
 971
 972   $self->send(@_);
 973 }
 974
 975 =item send_csv OPTION => VALUE, ...
 976
 977 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 978
 979 Options are:
 980
 981 protocol - currently only "ftp"
 982 server
 983 username
 984 password
 985 dir
 986
 987 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 988 and YYMMDDHHMMSS is a timestamp.
 989
 990 See L</print_csv> for a description of the output format.
 991
 992 =cut
 993
 994 sub send_csv {
 995   my($self, %opt) = @_;
 996
 997   #create file(s)
 998
 999   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1000   mkdir $spooldir, 0700 unless -d $spooldir;
1001
1002   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1003   my $file = "$spooldir/$tracctnum.csv";
1004
1005   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1006
1007   open(CSV, ">$file") or die "can't open $file: $!";
1008   print CSV $header;
1009
1010   print CSV $detail;
1011
1012   close CSV;
1013
1014   my $net;
1015   if ( $opt{protocol} eq 'ftp' ) {
1016     eval "use Net::FTP;";
1017     die $@ if $@;
1018     $net = Net::FTP->new($opt{server}) or die @$;
1019   } else {
1020     die "unknown protocol: $opt{protocol}";
1021   }
1022
1023   $net->login( $opt{username}, $opt{password} )
1024     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
1025
1026   $net->binary or die "can't set binary mode";
1027
1028   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
1029
1030   $net->put($file) or die "can't put $file: $!";
1031
1032   $net->quit;
1033
1034   unlink $file;
1035
1036 }
1037
1038 =item spool_csv
1039
1040 Spools CSV invoice data.
1041
1042 Options are:
1043
1044 =over 4
1045
1046 =item format - 'default' or 'billco'
1047
1048 =item dest - if set (to POST, EMAIL or FAX), only sends spools invoices if the customer has the corresponding invoice destinations set (see L<FS::cust_main_invoice>).
1049
1050 =item agent_spools - if set to a true value, will spool to per-agent files rather than a single global file
1051
1052 =item balanceover - if set, only spools the invoice if the total amount owed on this invoice and all older invoices is greater than the specified amount.
1053
1054 =back
1055
1056 =cut
1057
1058 sub spool_csv {
1059   my($self, %opt) = @_;
1060
1061   my $cust_main = $self->cust_main;
1062
1063   if ( $opt{'dest'} ) {
1064     my %invoicing_list = map { /^(POST|FAX)$/ or 'EMAIL' =~ /^(.*)$/; $1 => 1 }
1065                              $cust_main->invoicing_list;
1066     return 'N/A' unless $invoicing_list{$opt{'dest'}}
1067                      || ! keys %invoicing_list;
1068   }
1069
1070   if ( $opt{'balanceover'} ) {
1071     return 'N/A'
1072       if $cust_main->total_owed_date($self->_date) < $opt{'balanceover'};
1073   }
1074
1075   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1076   mkdir $spooldir, 0700 unless -d $spooldir;
1077
1078   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1079
1080   my $file =
1081     "$spooldir/".
1082     ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1083     ( lc($opt{'format'}) eq 'billco' ? '-header' : '' ) .
1084     '.csv';
1085
1086   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1087
1088   open(CSV, ">>$file") or die "can't open $file: $!";
1089   flock(CSV, LOCK_EX);
1090   seek(CSV, 0, 2);
1091
1092   print CSV $header;
1093
1094   if ( lc($opt{'format'}) eq 'billco' ) {
1095
1096     flock(CSV, LOCK_UN);
1097     close CSV;
1098
1099     $file =
1100       "$spooldir/".
1101       ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1102       '-detail.csv';
1103
1104     open(CSV,">>$file") or die "can't open $file: $!";
1105     flock(CSV, LOCK_EX);
1106     seek(CSV, 0, 2);
1107   }
1108
1109   print CSV $detail;
1110
1111   flock(CSV, LOCK_UN);
1112   close CSV;
1113
1114   return '';
1115
1116 }
1117
1118 =item print_csv OPTION => VALUE, ...
1119
1120 Returns CSV data for this invoice.
1121
1122 Options are:
1123
1124 format - 'default' or 'billco'
1125
1126 Returns a list consisting of two scalars.  The first is a single line of CSV
1127 header information for this invoice.  The second is one or more lines of CSV
1128 detail information for this invoice.
1129
1130 If I<format> is not specified or "default", the fields of the CSV file are as
1131 follows:
1132
1133 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
1134
1135 =over 4
1136
1137 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
1138
1139 B<record_type> is C<cust_bill> for the initial header line only.  The
1140 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
1141 fields are filled in.
1142
1143 B<record_type> is C<cust_bill_pkg> for detail lines.  Only the first two fields
1144 (B<record_type> and B<invnum>) and the last five fields (B<pkg> through B<edate>)
1145 are filled in.
1146
1147 =item invnum - invoice number
1148
1149 =item custnum - customer number
1150
1151 =item _date - invoice date
1152
1153 =item charged - total invoice amount
1154
1155 =item first - customer first name
1156
1157 =item last - customer first name
1158
1159 =item company - company name
1160
1161 =item address1 - address line 1
1162
1163 =item address2 - address line 1
1164
1165 =item city
1166
1167 =item state
1168
1169 =item zip
1170
1171 =item country
1172
1173 =item pkg - line item description
1174
1175 =item setup - line item setup fee (one or both of B<setup> and B<recur> will be defined)
1176
1177 =item recur - line item recurring fee (one or both of B<setup> and B<recur> will be defined)
1178
1179 =item sdate - start date for recurring fee
1180
1181 =item edate - end date for recurring fee
1182
1183 =back
1184
1185 If I<format> is "billco", the fields of the header CSV file are as follows:
1186
1187   +-------------------------------------------------------------------+
1188   |                        FORMAT HEADER FILE                         |
1189   |-------------------------------------------------------------------|
1190   | Field | Description                   | Name       | Type | Width |
1191   | 1     | N/A-Leave Empty               | RC         | CHAR |     2 |
1192   | 2     | N/A-Leave Empty               | CUSTID     | CHAR |    15 |
1193   | 3     | Transaction Account No        | TRACCTNUM  | CHAR |    15 |
1194   | 4     | Transaction Invoice No        | TRINVOICE  | CHAR |    15 |
1195   | 5     | Transaction Zip Code          | TRZIP      | CHAR |     5 |
1196   | 6     | Transaction Company Bill To   | TRCOMPANY  | CHAR |    30 |
1197   | 7     | Transaction Contact Bill To   | TRNAME     | CHAR |    30 |
1198   | 8     | Additional Address Unit Info  | TRADDR1    | CHAR |    30 |
1199   | 9     | Bill To Street Address        | TRADDR2    | CHAR |    30 |
1200   | 10    | Ancillary Billing Information | TRADDR3    | CHAR |    30 |
1201   | 11    | Transaction City Bill To      | TRCITY     | CHAR |    20 |
1202   | 12    | Transaction State Bill To     | TRSTATE    | CHAR |     2 |
1203   | 13    | Bill Cycle Close Date         | CLOSEDATE  | CHAR |    10 |
1204   | 14    | Bill Due Date                 | DUEDATE    | CHAR |    10 |
1205   | 15    | Previous Balance              | BALFWD     | NUM* |     9 |
1206   | 16    | Pmt/CR Applied                | CREDAPPLY  | NUM* |     9 |
1207   | 17    | Total Current Charges         | CURRENTCHG | NUM* |     9 |
1208   | 18    | Total Amt Due                 | TOTALDUE   | NUM* |     9 |
1209   | 19    | Total Amt Due                 | AMTDUE     | NUM* |     9 |
1210   | 20    | 30 Day Aging                  | AMT30      | NUM* |     9 |
1211   | 21    | 60 Day Aging                  | AMT60      | NUM* |     9 |
1212   | 22    | 90 Day Aging                  | AMT90      | NUM* |     9 |
1213   | 23    | Y/N                           | AGESWITCH  | CHAR |     1 |
1214   | 24    | Remittance automation         | SCANLINE   | CHAR |   100 |
1215   | 25    | Total Taxes & Fees            | TAXTOT     | NUM* |     9 |
1216   | 26    | Customer Reference Number     | CUSTREF    | CHAR |    15 |
1217   | 27    | Federal Tax***                | FEDTAX     | NUM* |     9 |
1218   | 28    | State Tax***                  | STATETAX   | NUM* |     9 |
1219   | 29    | Other Taxes & Fees***         | OTHERTAX   | NUM* |     9 |
1220   +-------+-------------------------------+------------+------+-------+
1221
1222 If I<format> is "billco", the fields of the detail CSV file are as follows:
1223
1224                                   FORMAT FOR DETAIL FILE
1225         |                            |           |      |
1226   Field | Description                | Name      | Type | Width
1227   1     | N/A-Leave Empty            | RC        | CHAR |     2
1228   2     | N/A-Leave Empty            | CUSTID    | CHAR |    15
1229   3     | Account Number             | TRACCTNUM | CHAR |    15
1230   4     | Invoice Number             | TRINVOICE | CHAR |    15
1231   5     | Line Sequence (sort order) | LINESEQ   | NUM  |     6
1232   6     | Transaction Detail         | DETAILS   | CHAR |   100
1233   7     | Amount                     | AMT       | NUM* |     9
1234   8     | Line Format Control**      | LNCTRL    | CHAR |     2
1235   9     | Grouping Code              | GROUP     | CHAR |     2
1236   10    | User Defined               | ACCT CODE | CHAR |    15
1237
1238 =cut
1239
1240 sub print_csv {
1241   my($self, %opt) = @_;
1242
1243   eval "use Text::CSV_XS";
1244   die $@ if $@;
1245
1246   my $cust_main = $self->cust_main;
1247
1248   my $csv = Text::CSV_XS->new({'always_quote'=>1});
1249
1250   if ( lc($opt{'format'}) eq 'billco' ) {
1251
1252     my $taxtotal = 0;
1253     $taxtotal += $_->{'amount'} foreach $self->_items_tax;
1254
1255     my $duedate = $self->due_date2str('%m/%d/%Y'); #date_format?
1256
1257     my( $previous_balance, @unused ) = $self->previous; #previous balance
1258
1259     my $pmt_cr_applied = 0;
1260     $pmt_cr_applied += $_->{'amount'}
1261       foreach ( $self->_items_payments, $self->_items_credits ) ;
1262
1263     my $totaldue = sprintf('%.2f', $self->owed + $previous_balance);
1264
1265     $csv->combine(
1266       '',                         #  1 | N/A-Leave Empty               CHAR   2
1267       '',                         #  2 | N/A-Leave Empty               CHAR  15
1268       $opt{'tracctnum'},          #  3 | Transaction Account No        CHAR  15
1269       $self->invnum,              #  4 | Transaction Invoice No        CHAR  15
1270       $cust_main->zip,            #  5 | Transaction Zip Code          CHAR   5
1271       $cust_main->company,        #  6 | Transaction Company Bill To   CHAR  30
1272       #$cust_main->payname,        #  7 | Transaction Contact Bill To   CHAR  30
1273       $cust_main->contact,        #  7 | Transaction Contact Bill To   CHAR  30
1274       $cust_main->address2,       #  8 | Additional Address Unit Info  CHAR  30
1275       $cust_main->address1,       #  9 | Bill To Street Address        CHAR  30
1276       '',                         # 10 | Ancillary Billing Information CHAR  30
1277       $cust_main->city,           # 11 | Transaction City Bill To      CHAR  20
1278       $cust_main->state,          # 12 | Transaction State Bill To     CHAR   2
1279
1280       # XXX ?
1281       time2str("%m/%d/%Y", $self->_date), # 13 | Bill Cycle Close Date CHAR  10
1282
1283       # XXX ?
1284       $duedate,                   # 14 | Bill Due Date                 CHAR  10
1285
1286       $previous_balance,          # 15 | Previous Balance              NUM*   9
1287       $pmt_cr_applied,            # 16 | Pmt/CR Applied                NUM*   9
1288       sprintf("%.2f", $self->charged), # 17 | Total Current Charges    NUM*   9
1289       $totaldue,                  # 18 | Total Amt Due                 NUM*   9
1290       $totaldue,                  # 19 | Total Amt Due                 NUM*   9
1291       '',                         # 20 | 30 Day Aging                  NUM*   9
1292       '',                         # 21 | 60 Day Aging                  NUM*   9
1293       '',                         # 22 | 90 Day Aging                  NUM*   9
1294       'N',                        # 23 | Y/N                           CHAR   1
1295       '',                         # 24 | Remittance automation         CHAR 100
1296       $taxtotal,                  # 25 | Total Taxes & Fees            NUM*   9
1297       $self->custnum,             # 26 | Customer Reference Number     CHAR  15
1298       '0',                        # 27 | Federal Tax***                NUM*   9
1299       sprintf("%.2f", $taxtotal), # 28 | State Tax***                  NUM*   9
1300       '0',                        # 29 | Other Taxes & Fees***         NUM*   9
1301     );
1302
1303   } else {
1304
1305     $csv->combine(
1306       'cust_bill',
1307       $self->invnum,
1308       $self->custnum,
1309       time2str("%x", $self->_date),
1310       sprintf("%.2f", $self->charged),
1311       ( map { $cust_main->getfield($_) }
1312           qw( first last company address1 address2 city state zip country ) ),
1313       map { '' } (1..5),
1314     ) or die "can't create csv";
1315   }
1316
1317   my $header = $csv->string. "\n";
1318
1319   my $detail = '';
1320   if ( lc($opt{'format'}) eq 'billco' ) {
1321
1322     my $lineseq = 0;
1323     foreach my $item ( $self->_items_pkg ) {
1324
1325       $csv->combine(
1326         '',                     #  1 | N/A-Leave Empty            CHAR   2
1327         '',                     #  2 | N/A-Leave Empty            CHAR  15
1328         $opt{'tracctnum'},      #  3 | Account Number             CHAR  15
1329         $self->invnum,          #  4 | Invoice Number             CHAR  15
1330         $lineseq++,             #  5 | Line Sequence (sort order) NUM    6
1331         $item->{'description'}, #  6 | Transaction Detail         CHAR 100
1332         $item->{'amount'},      #  7 | Amount                     NUM*   9
1333         '',                     #  8 | Line Format Control**      CHAR   2
1334         '',                     #  9 | Grouping Code              CHAR   2
1335         '',                     # 10 | User Defined               CHAR  15
1336       );
1337
1338       $detail .= $csv->string. "\n";
1339
1340     }
1341
1342   } else {
1343
1344     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1345
1346       my($pkg, $setup, $recur, $sdate, $edate);
1347       if ( $cust_bill_pkg->pkgnum ) {
1348
1349         ($pkg, $setup, $recur, $sdate, $edate) = (
1350           $cust_bill_pkg->part_pkg->pkg,
1351           ( $cust_bill_pkg->setup != 0
1352             ? sprintf("%.2f", $cust_bill_pkg->setup )
1353             : '' ),
1354           ( $cust_bill_pkg->recur != 0
1355             ? sprintf("%.2f", $cust_bill_pkg->recur )
1356             : '' ),
1357           ( $cust_bill_pkg->sdate
1358             ? time2str("%x", $cust_bill_pkg->sdate)
1359             : '' ),
1360           ($cust_bill_pkg->edate
1361             ?time2str("%x", $cust_bill_pkg->edate)
1362             : '' ),
1363         );
1364
1365       } else { #pkgnum tax
1366         next unless $cust_bill_pkg->setup != 0;
1367         my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
1368                          ? ( $cust_bill_pkg->itemdesc || 'Tax' )
1369                          : 'Tax';
1370         ($pkg, $setup, $recur, $sdate, $edate) =
1371           ( $itemdesc, sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
1372       }
1373
1374       $csv->combine(
1375         'cust_bill_pkg',
1376         $self->invnum,
1377         ( map { '' } (1..11) ),
1378         ($pkg, $setup, $recur, $sdate, $edate)
1379       ) or die "can't create csv";
1380
1381       $detail .= $csv->string. "\n";
1382
1383     }
1384
1385   }
1386
1387   ( $header, $detail );
1388
1389 }
1390
1391 =item comp
1392
1393 Pays this invoice with a compliemntary payment.  If there is an error,
1394 returns the error, otherwise returns false.
1395
1396 =cut
1397
1398 sub comp {
1399   my $self = shift;
1400   my $cust_pay = new FS::cust_pay ( {
1401     'invnum'   => $self->invnum,
1402     'paid'     => $self->owed,
1403     '_date'    => '',
1404     'payby'    => 'COMP',
1405     'payinfo'  => $self->cust_main->payinfo,
1406     'paybatch' => '',
1407   } );
1408   $cust_pay->insert;
1409 }
1410
1411 =item realtime_card
1412
1413 Attempts to pay this invoice with a credit card payment via a
1414 Business::OnlinePayment realtime gateway.  See
1415 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1416 for supported processors.
1417
1418 =cut
1419
1420 sub realtime_card {
1421   my $self = shift;
1422   $self->realtime_bop( 'CC', @_ );
1423 }
1424
1425 =item realtime_ach
1426
1427 Attempts to pay this invoice with an electronic check (ACH) payment via a
1428 Business::OnlinePayment realtime gateway.  See
1429 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1430 for supported processors.
1431
1432 =cut
1433
1434 sub realtime_ach {
1435   my $self = shift;
1436   $self->realtime_bop( 'ECHECK', @_ );
1437 }
1438
1439 =item realtime_lec
1440
1441 Attempts to pay this invoice with phone bill (LEC) payment via a
1442 Business::OnlinePayment realtime gateway.  See
1443 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1444 for supported processors.
1445
1446 =cut
1447
1448 sub realtime_lec {
1449   my $self = shift;
1450   $self->realtime_bop( 'LEC', @_ );
1451 }
1452
1453 sub realtime_bop {
1454   my( $self, $method ) = @_;
1455
1456   my $cust_main = $self->cust_main;
1457   my $balance = $cust_main->balance;
1458   my $amount = ( $balance < $self->owed ) ? $balance : $self->owed;
1459   $amount = sprintf("%.2f", $amount);
1460   return "not run (balance $balance)" unless $amount > 0;
1461
1462   my $description = 'Internet Services';
1463   if ( $conf->exists('business-onlinepayment-description') ) {
1464     my $dtempl = $conf->config('business-onlinepayment-description');
1465
1466     my $agent_obj = $cust_main->agent
1467       or die "can't retreive agent for $cust_main (agentnum ".
1468              $cust_main->agentnum. ")";
1469     my $agent = $agent_obj->agent;
1470     my $pkgs = join(', ',
1471       map { $_->part_pkg->pkg }
1472         grep { $_->pkgnum } $self->cust_bill_pkg
1473     );
1474     $description = eval qq("$dtempl");
1475   }
1476
1477   $cust_main->realtime_bop($method, $amount,
1478     'description' => $description,
1479     'invnum'      => $self->invnum,
1480   );
1481
1482 }
1483
1484 =item batch_card OPTION => VALUE...
1485
1486 Adds a payment for this invoice to the pending credit card batch (see
1487 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
1488 runs the payment using a realtime gateway.
1489
1490 =cut
1491
1492 sub batch_card {
1493   my ($self, %options) = @_;
1494   my $cust_main = $self->cust_main;
1495
1496   $options{invnum} = $self->invnum;
1497
1498   $cust_main->batch_card(%options);
1499 }
1500
1501 sub _agent_template {
1502   my $self = shift;
1503   $self->cust_main->agent_template;
1504 }
1505
1506 sub _agent_invoice_from {
1507   my $self = shift;
1508   $self->cust_main->agent_invoice_from;
1509 }
1510
1511 =item print_text [ TIME [ , TEMPLATE ] ]
1512
1513 Returns an text invoice, as a list of lines.
1514
1515 TIME an optional value used to control the printing of overdue messages.  The
1516 default is now.  It isn't the date of the invoice; that's the `_date' field.
1517 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1518 L<Time::Local> and L<Date::Parse> for conversion functions.
1519
1520 =cut
1521
1522 sub print_text {
1523   my( $self, $today, $template ) = @_;
1524
1525   my %params = ( 'format' => 'template' );
1526   $params{'time'} = $today if $today;
1527   $params{'template'} = $template if $template;
1528
1529   $self->print_generic( %params );
1530 }
1531
1532 =item print_latex [ TIME [ , TEMPLATE ] ]
1533
1534 Internal method - returns a filename of a filled-in LaTeX template for this
1535 invoice (Note: add ".tex" to get the actual filename), and a filename of
1536 an associated logo (with the .eps extension included).
1537
1538 See print_ps and print_pdf for methods that return PostScript and PDF output.
1539
1540 TIME an optional value used to control the printing of overdue messages.  The
1541 default is now.  It isn't the date of the invoice; that's the `_date' field.
1542 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1543 L<Time::Local> and L<Date::Parse> for conversion functions.
1544
1545 =cut
1546
1547 sub print_latex {
1548
1549   my( $self, $today, $template ) = @_;
1550
1551   my %params = ( 'format' => 'latex' );
1552   $params{'time'} = $today if $today;
1553   $params{'template'} = $template if $template;
1554
1555   $template ||= $self->_agent_template;
1556
1557   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1558   my $lh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1559                            DIR      => $dir,
1560                            SUFFIX   => '.eps',
1561                            UNLINK   => 0,
1562                          ) or die "can't open temp file: $!\n";
1563
1564   if ($template && $conf->exists("logo_${template}.eps")) {
1565     print $lh $conf->config_binary("logo_${template}.eps")
1566       or die "can't write temp file: $!\n";
1567   }else{
1568     print $lh $conf->config_binary('logo.eps')
1569       or die "can't write temp file: $!\n";
1570   }
1571   close $lh;
1572   $params{'logo_file'} = $lh->filename;
1573
1574   my @filled_in = $self->print_generic( %params );
1575
1576   my $fh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
1577                            DIR      => $dir,
1578                            SUFFIX   => '.tex',
1579                            UNLINK   => 0,
1580                          ) or die "can't open temp file: $!\n";
1581   print $fh join('', @filled_in );
1582   close $fh;
1583
1584   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
1585   return ($1, $params{'logo_file'});
1586
1587 }
1588
1589 =item print_generic OPTIONS_HASH
1590
1591 Internal method - returns a filled-in template for this invoice as a scalar.
1592
1593 See print_ps and print_pdf for methods that return PostScript and PDF output.
1594
1595 Non optional options include
1596   format - latex, html, template
1597
1598 Optional options include
1599
1600 template - a value used as a suffix for a configuration template
1601
1602 time - a value used to control the printing of overdue messages.  The
1603 default is now.  It isn't the date of the invoice; that's the `_date' field.
1604 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1605 L<Time::Local> and L<Date::Parse> for conversion functions.
1606
1607 cid -
1608
1609 =cut
1610
1611 sub print_generic {
1612
1613   my( $self, %params ) = @_;
1614   my $today = $params{today} ? $params{today} : time;
1615   warn "FS::cust_bill::print_generic called on $self with suffix $params{template}\n"
1616     if $DEBUG;
1617
1618   my $format = $params{format};
1619   die "Unknown format: $format"
1620     unless $format =~ /^(latex|html|template)$/;
1621
1622   my $cust_main = $self->cust_main;
1623   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
1624     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
1625
1626
1627   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
1628                      'html'     => [ '<%=', '%>' ],
1629                      'template' => [ '{', '}' ],
1630                    );
1631
1632   #create the template
1633   my $template = $params{template} ? $params{template} : $self->_agent_template;
1634   my $templatefile = "invoice_$format";
1635   $templatefile .= "_$template"
1636     if length($template);
1637   my @invoice_template = map "$_\n", $conf->config($templatefile)
1638     or die "cannot load config data $templatefile";
1639
1640   my $old_latex = '';
1641   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
1642     #change this to a die when the old code is removed
1643     warn "old-style invoice template $templatefile; ".
1644          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
1645     $old_latex = 'true';
1646     @invoice_template = _translate_old_latex_format(@invoice_template);
1647   }
1648
1649   my $text_template = new Text::Template(
1650     TYPE => 'ARRAY',
1651     SOURCE => \@invoice_template,
1652     DELIMITERS => $delimiters{$format},
1653   );
1654
1655   $text_template->compile()
1656     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
1657
1658
1659   # additional substitution could possibly cause breakage in existing templates
1660   my %convert_maps = (
1661     'latex' => {
1662                  'notes'         => sub { map "$_", @_ },
1663                  'footer'        => sub { map "$_", @_ },
1664                  'smallfooter'   => sub { map "$_", @_ },
1665                  'returnaddress' => sub { map "$_", @_ },
1666                },
1667     'html'  => {
1668                  'notes' =>
1669                    sub {
1670                      map {
1671                        s/%%(.*)$/<!-- $1 -->/g;
1672                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
1673                        s/\\begin\{enumerate\}/<ol>/g;
1674                        s/\\item /  <li>/g;
1675                        s/\\end\{enumerate\}/<\/ol>/g;
1676                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
1677                        s/\\\\\*/<br>/g;
1678                        s/\\dollar ?/\$/g;
1679                        s/\\#/#/g;
1680                        s/~/&nbsp;/g;
1681                        $_;
1682                      }  @_
1683                    },
1684                  'footer' =>
1685                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1686                  'smallfooter' =>
1687                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
1688                  'returnaddress' =>
1689                    sub {
1690                      map {
1691                        s/~/&nbsp;/g;
1692                        s/\\\\\*?\s*$/<BR>/;
1693                        s/\\hyphenation\{[\w\s\-]+}//;
1694                        $_;
1695                      }  @_
1696                    },
1697                },
1698     'template' => {
1699                  'notes' =>
1700                    sub {
1701                      map {
1702                        s/%%.*$//g;
1703                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
1704                        s/\\begin\{enumerate\}//g;
1705                        s/\\item /  * /g;
1706                        s/\\end\{enumerate\}//g;
1707                        s/\\textbf\{(.*)\}/$1/g;
1708                        s/\\\\\*/ /;
1709                        s/\\dollar ?/\$/g;
1710                        $_;
1711                      }  @_
1712                    },
1713                  'footer' =>
1714                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1715                  'smallfooter' =>
1716                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
1717                  'returnaddress' =>
1718                    sub {
1719                      map {
1720                        s/~/ /g;
1721                        s/\\\\\*?\s*$/\n/;             # dubious
1722                        s/\\hyphenation\{[\w\s\-]+}//;
1723                        $_;
1724                      }  @_
1725                    },
1726                },
1727   );
1728
1729
1730   # hashes for differing output formats
1731   my %nbsps = ( 'latex'    => '~',
1732                 'html'     => '',    # '&nbps;' would be nice
1733                 'template' => '',    # not used
1734               );
1735   my $nbsp = $nbsps{$format};
1736
1737   my %escape_functions = ( 'latex'    => \&_latex_escape,
1738                            'html'     => \&encode_entities,
1739                            'template' => sub { shift },
1740                          );
1741   my $escape_function = $escape_functions{$format};
1742
1743   my %date_formats = ( 'latex'    => '%b %o, %Y',
1744                        'html'     => '%b&nbsp;%o,&nbsp;%Y',
1745                        'template' => '%s',
1746                      );
1747   my $date_format = $date_formats{$format};
1748
1749   my %embolden_functions = ( 'latex'    => sub { return '\textbf{'. shift(). '}'
1750                                                },
1751                              'html'     => sub { return '<b>'. shift(). '</b>'
1752                                                },
1753                              'template' => sub { shift },
1754                            );
1755   my $embolden_function = $embolden_functions{$format};
1756
1757
1758   # generate template variables
1759   my $returnaddress;
1760   if (
1761          defined( $conf->config_orbase( "invoice_${format}returnaddress",
1762                                         $template
1763                                       )
1764                 )
1765        && length( $conf->config_orbase( "invoice_${format}returnaddress",
1766                                         $template
1767                                       )
1768                 )
1769   ) {
1770
1771     $returnaddress = join("\n",
1772       $conf->config_orbase("invoice_${format}returnaddress", $template)
1773     );
1774
1775   } elsif ( grep /\S/,
1776             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
1777
1778     my $convert_map = $convert_maps{$format}{'returnaddress'};
1779     $returnaddress =
1780       join( "\n",
1781             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
1782                                                  $template
1783                                                )
1784                          )
1785           );
1786   } elsif ( grep /\S/, $conf->config('company_address') ) {
1787
1788     my $convert_map = $convert_maps{$format}{'returnaddress'};
1789     $returnaddress = join( "\n", &$convert_map(
1790                                    map { s/( {2,})/'~' x length($1)/eg;
1791                                          s/$/\\\\\*/;
1792                                          $_
1793                                        }
1794                                      ( $conf->config('company_name'),
1795                                        $conf->config('company_address'),
1796                                      )
1797                                  )
1798                      );
1799
1800   } else {
1801
1802     my $warning = "Couldn't find a return address; ".
1803                   "do you need to set the company_address configuration value?";
1804     warn "$warning\n";
1805     $returnaddress = $nbsp;
1806     #$returnaddress = $warning;
1807
1808   }
1809
1810   my %invoice_data = (
1811     'company_name'    => scalar( $conf->config('company_name') ),
1812     'company_address' => join("\n", $conf->config('company_address') ). "\n",
1813     'custnum'         => $self->custnum,
1814     'invnum'          => $self->invnum,
1815     'date'            => time2str($date_format, $self->_date),
1816     'today'           => time2str('%b %o, %Y', $today),
1817     'agent'           => &$escape_function($cust_main->agent->agent),
1818     'payname'         => &$escape_function($cust_main->payname),
1819     'company'         => &$escape_function($cust_main->company),
1820     'address1'        => &$escape_function($cust_main->address1),
1821     'address2'        => &$escape_function($cust_main->address2),
1822     'city'            => &$escape_function($cust_main->city),
1823     'state'           => &$escape_function($cust_main->state),
1824     'zip'             => &$escape_function($cust_main->zip),
1825     'returnaddress'   => $returnaddress,
1826     'quantity'        => 1,
1827     'terms'           => $self->terms,
1828     'template'        => $params{'template'},
1829     #'notes'           => join("\n", $conf->config('invoice_latexnotes') ),
1830     # better hang on to conf_dir for a while
1831     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
1832     'page'            => 1,
1833     'total_pages'     => 1,
1834   );
1835
1836   $invoice_data{'cid'} = $params{'cid'}
1837     if $params{'cid'};
1838
1839   my $countrydefault = $conf->config('countrydefault') || 'US';
1840   if ( $cust_main->country eq $countrydefault ) {
1841     $invoice_data{'country'} = '';
1842   } else {
1843     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
1844   }
1845
1846   my @address = ();
1847   $invoice_data{'address'} = \@address;
1848   push @address,
1849     $cust_main->payname.
1850       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
1851         ? " (P.O. #". $cust_main->payinfo. ")"
1852         : ''
1853       )
1854   ;
1855   push @address, $cust_main->company
1856     if $cust_main->company;
1857   push @address, $cust_main->address1;
1858   push @address, $cust_main->address2
1859     if $cust_main->address2;
1860   push @address,
1861     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
1862   push @address, $invoice_data{'country'}
1863     if $invoice_data{'country'};
1864   push @address, ''
1865     while (scalar(@address) < 5);
1866
1867   #do variable substitution in notes, footer, smallfooter
1868   foreach my $include (qw( notes footer smallfooter )) {
1869
1870     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1871     my @inc_src;
1872
1873     if ( $conf->exists($inc_file) && length( $conf->config($inc_file) ) ) {
1874
1875       @inc_src = $conf->config($inc_file);
1876
1877     } else {
1878
1879       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1880
1881       my $convert_map = $convert_maps{$format}{$include};
1882
1883       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1884                        s/--\@\]/$delimiters{$format}[1]/g;
1885                        $_;
1886                      }
1887                  &$convert_map( $conf->config($inc_file) );
1888
1889     }
1890
1891     my $inc_tt = new Text::Template (
1892       TYPE       => 'ARRAY',
1893       SOURCE     => [ map "$_\n", @inc_src ],
1894       DELIMITERS => $delimiters{$format},
1895     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1896
1897     unless ( $inc_tt->compile() ) {
1898       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1899       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1900       die $error;
1901     }
1902
1903     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1904
1905     $invoice_data{$include} =~ s/\n+$//
1906       if ($format eq 'latex');
1907   }
1908
1909   $invoice_data{'po_line'} =
1910     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
1911       ? &$escape_function("Purchase Order #". $cust_main->payinfo)
1912       : $nbsp;
1913
1914   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1915 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
1916   #my $balance_due = $self->owed + $pr_total - $cr_total;
1917   my $balance_due = $self->owed + $pr_total;
1918
1919   my %money_chars = ( 'latex'    => '',
1920                       'html'     => $conf->config('money_char') || '$',
1921                       'template' => '',
1922                     );
1923   my $money_char = $money_chars{$format};
1924
1925   my %other_money_chars = ( 'latex'    => '\dollar ',
1926                             'html'     => $conf->config('money_char') || '$',
1927                             'template' => '',
1928                           );
1929   my $other_money_char = $other_money_chars{$format};
1930
1931   my @detail_items = ();
1932   my @total_items = ();
1933   my @buf = ();
1934   my @sections = ();
1935
1936   $invoice_data{'detail_items'} = \@detail_items;
1937   $invoice_data{'total_items'} = \@total_items;
1938   $invoice_data{'buf'} = \@buf;
1939   $invoice_data{'sections'} = \@sections;
1940
1941   my $previous_section = { 'description' => 'Previous Charges',
1942                            'subtotal'    => $other_money_char.
1943                                             sprintf('%.2f', $pr_total),
1944                          };
1945
1946   my $multisection = $conf->exists('invoice_sections', $cust_main->agentnum);
1947   if ( $multisection ) {
1948     push @sections, $self->_items_sections;
1949   }else{
1950     push @sections, { 'description' => '', 'subtotal' => '' };
1951   }
1952
1953   foreach my $line_item ( $self->_items_previous ) {
1954     my $detail = {
1955       ext_description => [],
1956     };
1957     $detail->{'ref'} = $line_item->{'pkgnum'};
1958     $detail->{'quantity'} = 1;
1959     $detail->{'section'} = $previous_section;
1960     $detail->{'description'} = &$escape_function($line_item->{'description'});
1961     if ( exists $line_item->{'ext_description'} ) {
1962       @{$detail->{'ext_description'}} = map {
1963         &$escape_function($_);
1964       } @{$line_item->{'ext_description'}};
1965     }
1966     {
1967       my $money = $old_latex ? '' : $money_char;
1968       $detail->{'amount'} = $money. $line_item->{'amount'};
1969     }
1970     $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
1971
1972     push @detail_items, $detail;
1973     push @buf, [ $detail->{'description'},
1974                  $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1975                ];
1976   }
1977
1978   if (@pr_cust_bill) {
1979     push @buf, ['','-----------'];
1980     push @buf, [ 'Total Previous Balance',
1981                  $money_char. sprintf("%10.2f", $pr_total) ];
1982     push @buf, ['',''];
1983   }
1984
1985   foreach my $section (@sections) {
1986
1987     $section->{'subtotal'} = $other_money_char.
1988                              sprintf('%.2f', $section->{'subtotal'})
1989       if $multisection;
1990
1991     if ( $section->{'description'} ) {
1992       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1993                    [ '', '' ],
1994                  );
1995     }
1996
1997     my %options = ();
1998     $options{'section'} = $section if $multisection;
1999
2000     foreach my $line_item ( $self->_items_pkg(%options) ) {
2001       my $detail = {
2002         ext_description => [],
2003       };
2004       $detail->{'ref'} = $line_item->{'pkgnum'};
2005       $detail->{'quantity'} = 1;
2006       $detail->{'section'} = $section;
2007       $detail->{'description'} = &$escape_function($line_item->{'description'});
2008       if ( exists $line_item->{'ext_description'} ) {
2009         @{$detail->{'ext_description'}} = map {
2010           &$escape_function($_);
2011         } @{$line_item->{'ext_description'}};
2012       }
2013       {
2014         my $money = $old_latex ? '' : $money_char;
2015         $detail->{'amount'} = $money. $line_item->{'amount'};
2016       }
2017       $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
2018
2019       push @detail_items, $detail;
2020       push @buf, ( [ $detail->{'description'},
2021                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
2022                    ],
2023                    map { [ " ". $_, '' ] } @{$detail->{'ext_description'}},
2024                  );
2025     }
2026
2027     if ( $section->{'description'} ) {
2028       push @buf, ( ['','-----------'],
2029                    [ $section->{'description'}. ' sub-total',
2030                       $money_char. sprintf("%10.2f", $section->{'subtotal'})
2031                    ],
2032                    [ '', '' ],
2033                    [ '', '' ],
2034                  );
2035     }
2036
2037   }
2038
2039   if ( $multisection ) {
2040     unshift @sections, $previous_section;
2041   }
2042
2043   my $taxtotal = 0;
2044   foreach my $tax ( $self->_items_tax ) {
2045     my $total = {};
2046     $total->{'total_item'} = &$escape_function($tax->{'description'});
2047     $taxtotal += $tax->{'amount'};
2048     $total->{'total_amount'} = $other_money_char. $tax->{'amount'};
2049     push @total_items, $total;
2050     push @buf,[ $total->{'total_item'},
2051                 $money_char. sprintf("%10.2f", $total->{'total_amount'}),
2052               ];
2053
2054   }
2055
2056   if ( $taxtotal ) {
2057     my $total = {};
2058     if ( $multisection ) {
2059       $total->{'total_item'} = 'New charges sub-total';
2060     }else{
2061       $total->{'total_item'} = 'Sub-total';
2062     }
2063     $total->{'total_amount'} =
2064       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
2065     unshift @total_items, $total;
2066   }
2067
2068   push @buf,['','-----------'];
2069   push @buf,['Total New Charges',
2070              $money_char. sprintf("%10.2f",$self->charged) ];
2071   push @buf,['',''];
2072
2073   {
2074     my $total = {};
2075     $total->{'total_item'} = &$embolden_function('Total');
2076     $total->{'total_amount'} =
2077     $total->{'total_amount'} =
2078       &$embolden_function(
2079         $other_money_char.  sprintf('%.2f', $self->charged + $pr_total )
2080       );
2081     push @total_items, $total;
2082     push @buf,['','-----------'];
2083     push @buf,['Total Charges',
2084                $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
2085     push @buf,['',''];
2086   }
2087
2088
2089   #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
2090
2091   # credits
2092   foreach my $credit ( $self->_items_credits ) {
2093     my $total;
2094     $total->{'total_item'} = &$escape_function($credit->{'description'});
2095     #$credittotal
2096     $total->{'total_amount'} = '-'. $other_money_char. $credit->{'amount'};
2097     push @total_items, $total;
2098   }
2099
2100   # credits (again)
2101   foreach ( $self->cust_credited ) {
2102
2103     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2104
2105     my $reason = substr($_->cust_credit->reason,0,32);
2106     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
2107     $reason = " ($reason) " if $reason;
2108     push @buf,[
2109       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".        $reason,
2110       $money_char. sprintf("%10.2f",$_->amount)
2111     ];
2112   }
2113
2114   # payments
2115   foreach my $payment ( $self->_items_payments ) {
2116     my $total = {};
2117     $total->{'total_item'} = &$escape_function($payment->{'description'});
2118     #$paymenttotal
2119     $total->{'total_amount'} = '-'. $other_money_char. $payment->{'amount'};
2120     push @total_items, $total;
2121     push @buf, [ $payment->{'description'},
2122                  $money_char. sprintf("%10.2f", $payment->{'amount'}),
2123                ];
2124   }
2125
2126   {
2127     my $total;
2128     $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
2129     $total->{'total_amount'} =
2130       &$embolden_function(
2131         $other_money_char. sprintf('%.2f', $self->owed + $pr_total )
2132       );
2133     push @total_items, $total;
2134     push @buf,['','-----------'];
2135     push @buf,[$self->balance_due_msg, $money_char.
2136       sprintf("%10.2f", $balance_due ) ];
2137   }
2138
2139   $invoice_data{'logo_file'} = $params{'logo_file'}
2140     if $params{'logo_file'};
2141
2142   $invoice_lines = 0;
2143   my $wasfunc = 0;
2144   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
2145     /invoice_lines\((\d*)\)/;
2146     $invoice_lines += $1 || scalar(@buf);
2147     $wasfunc=1;
2148   }
2149   die "no invoice_lines() functions in template?"
2150     if ( $format eq 'template' && !$wasfunc );
2151
2152   if ($format eq 'template') {
2153
2154     if ( $invoice_lines ) {
2155       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
2156       $invoice_data{'total_pages'}++
2157         if scalar(@buf) % $invoice_lines;
2158     }
2159
2160     #setup subroutine for the template
2161     sub FS::cust_bill::_template::invoice_lines {
2162       my $lines = shift || scalar(@FS::cust_bill::_template::buf);
2163       map {
2164         scalar(@FS::cust_bill::_template::buf)
2165           ? shift @FS::cust_bill::_template::buf
2166           : [ '', '' ];
2167       }
2168       ( 1 .. $lines );
2169     }
2170
2171     my $lines;
2172     my @collect;
2173     while (@buf) {
2174       push @collect, split("\n",
2175         $text_template->fill_in( HASH => \%invoice_data,
2176                                  PACKAGE => 'FS::cust_bill::_template'
2177                                )
2178       );
2179       $FS::cust_bill::_template::page++;
2180     }
2181     map "$_\n", @collect;
2182   }else{
2183     warn "filling in template for invoice ". $self->invnum. "\n"
2184       if $DEBUG;
2185     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
2186       if $DEBUG > 1;
2187
2188     $text_template->fill_in(HASH => \%invoice_data);
2189   }
2190 }
2191
2192 =item print_ps [ TIME [ , TEMPLATE ] ]
2193
2194 Returns an postscript invoice, as a scalar.
2195
2196 TIME an optional value used to control the printing of overdue messages.  The
2197 default is now.  It isn't the date of the invoice; that's the `_date' field.
2198 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2199 L<Time::Local> and L<Date::Parse> for conversion functions.
2200
2201 =cut
2202
2203 sub print_ps {
2204   my $self = shift;
2205
2206   my ($file, $lfile) = $self->print_latex(@_);
2207   my $ps = generate_ps($file);
2208   unlink($lfile);
2209   $ps;
2210
2211 }
2212
2213 =item print_pdf [ TIME [ , TEMPLATE ] ]
2214
2215 Returns an PDF invoice, as a scalar.
2216
2217 TIME an optional value used to control the printing of overdue messages.  The
2218 default is now.  It isn't the date of the invoice; that's the `_date' field.
2219 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2220 L<Time::Local> and L<Date::Parse> for conversion functions.
2221
2222 =cut
2223
2224 sub print_pdf {
2225   my $self = shift;
2226
2227   my ($file, $lfile) = $self->print_latex(@_);
2228
2229   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
2230   chdir($dir);
2231
2232   #system('pdflatex', "$file.tex");
2233   #system('pdflatex', "$file.tex");
2234   #! LaTeX Error: Unknown graphics extension: .eps.
2235
2236   my $sfile = shell_quote $file;
2237
2238   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2239     or die "pslatex $file.tex failed; see $file.log for details?\n";
2240   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2241     or die "pslatex $file.tex failed; see $file.log for details?\n";
2242
2243   #system('dvipdf', "$file.dvi", "$file.pdf" );
2244   system(
2245     "dvips -q -t letter -f $sfile.dvi ".
2246     "| gs -q -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=$sfile.pdf ".
2247     "     -c save pop -"
2248   ) == 0
2249     or die "dvips | gs failed: $!";
2250
2251   open(PDF, "<$file.pdf")
2252     or die "can't open $file.pdf: $! (error in LaTeX template?)\n";
2253
2254   unlink("$file.dvi", "$file.log", "$file.aux", "$file.pdf", "$file.tex");
2255   unlink("$lfile");
2256
2257   my $pdf = '';
2258   while (<PDF>) {
2259     $pdf .= $_;
2260   }
2261
2262   close PDF;
2263
2264   return $pdf;
2265
2266 }
2267
2268 =item print_html [ TIME [ , TEMPLATE [ , CID ] ] ]
2269
2270 Returns an HTML invoice, as a scalar.
2271
2272 TIME an optional value used to control the printing of overdue messages.  The
2273 default is now.  It isn't the date of the invoice; that's the `_date' field.
2274 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2275 L<Time::Local> and L<Date::Parse> for conversion functions.
2276
2277 CID is a MIME Content-ID used to create a "cid:" URL for the logo image, used
2278 when emailing the invoice as part of a multipart/related MIME email.
2279
2280 =cut
2281
2282 sub print_html {
2283   my( $self, $today, $template, $cid ) = @_;
2284
2285   my %params = ( 'format' => 'html' );
2286   $params{'time'} = $today if $today;
2287   $params{'template'} = $template if $template;
2288   $params{'cid'} = $cid if $cid;
2289
2290   $self->print_generic( %params );
2291 }
2292
2293 # quick subroutine for print_latex
2294 #
2295 # There are ten characters that LaTeX treats as special characters, which
2296 # means that they do not simply typeset themselves:
2297 #      # $ % & ~ _ ^ \ { }
2298 #
2299 # TeX ignores blanks following an escaped character; if you want a blank (as
2300 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
2301
2302 sub _latex_escape {
2303   my $value = shift;
2304   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
2305   $value =~ s/([<>])/\$$1\$/g;
2306   $value;
2307 }
2308
2309 #utility methods for print_*
2310
2311 sub _translate_old_latex_format {
2312   warn "_translate_old_latex_format called\n"
2313     if $DEBUG;
2314
2315   my @template = ();
2316   while ( @_ ) {
2317     my $line = shift;
2318
2319     if ( $line =~ /^%%Detail\s*$/ ) {
2320
2321       push @template, q![@--!,
2322                       q!  foreach my $_tr_line (@detail_items) {!,
2323                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
2324                       q!      $_tr_line->{'description'} .= !,
2325                       q!        "\\tabularnewline\n~~".!,
2326                       q!        join( "\\tabularnewline\n~~",!,
2327                       q!          @{$_tr_line->{'ext_description'}}!,
2328                       q!        );!,
2329                       q!    }!;
2330
2331       while ( ( my $line_item_line = shift )
2332               !~ /^%%EndDetail\s*$/                            ) {
2333         $line_item_line =~ s/'/\\'/g;    # nice LTS
2334         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2335         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2336         push @template, "    \$OUT .= '$line_item_line';";
2337       }
2338
2339       push @template, '}',
2340                       '--@]';
2341
2342     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
2343
2344       push @template, '[@--',
2345                       '  foreach my $_tr_line (@total_items) {';
2346
2347       while ( ( my $total_item_line = shift )
2348               !~ /^%%EndTotalDetails\s*$/                      ) {
2349         $total_item_line =~ s/'/\\'/g;    # nice LTS
2350         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
2351         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
2352         push @template, "    \$OUT .= '$total_item_line';";
2353       }
2354
2355       push @template, '}',
2356                       '--@]';
2357
2358     } else {
2359       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
2360       push @template, $line;
2361     }
2362
2363   }
2364
2365   if ($DEBUG) {
2366     warn "$_\n" foreach @template;
2367   }
2368
2369   (@template);
2370 }
2371
2372 sub terms {
2373   my $self = shift;
2374
2375   #check for an invoice- specific override (eventually)
2376
2377   #check for a customer- specific override
2378   return $self->cust_main->invoice_terms
2379     if $self->cust_main->invoice_terms;
2380
2381   #use configured default or default default
2382   $conf->config('invoice_default_terms') || 'Payable upon receipt';
2383 }
2384
2385 sub due_date {
2386   my $self = shift;
2387   my $duedate = '';
2388   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2389     $duedate = $self->_date() + ( $1 * 86400 );
2390   }
2391   $duedate;
2392 }
2393
2394 sub due_date2str {
2395   my $self = shift;
2396   $self->due_date ? time2str(shift, $self->due_date) : '';
2397 }
2398
2399 sub balance_due_msg {
2400   my $self = shift;
2401   my $msg = 'Balance Due';
2402   return $msg unless $self->terms;
2403   if ( $self->due_date ) {
2404     $msg .= ' - Please pay by '. $self->due_date2str('%x');
2405   } elsif ( $self->terms ) {
2406     $msg .= ' - '. $self->terms;
2407   }
2408   $msg;
2409 }
2410
2411 sub _items_sections {
2412   my $self = shift;
2413
2414   my %s = ();
2415   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
2416
2417     if ( $cust_bill_pkg->pkgnum > 0 ) {
2418
2419       my $desc = $cust_bill_pkg->part_pkg->classname;
2420
2421       $s{$desc} += $cust_bill_pkg->setup
2422         if ( $cust_bill_pkg->setup != 0 );
2423
2424       $s{$desc} += $cust_bill_pkg->recur
2425         if ( $cust_bill_pkg->recur != 0 );
2426
2427     }
2428
2429   }
2430
2431   map { {'description' => $_, 'subtotal' => $s{$_}} } sort keys %s;
2432
2433 }
2434
2435 sub _items {
2436   my $self = shift;
2437   my @display = scalar(@_)
2438                 ? @_
2439                 : qw( _items_previous _items_pkg );
2440                 #: qw( _items_pkg );
2441                 #: qw( _items_previous _items_pkg _items_tax _items_credits _items_payments );
2442   my @b = ();
2443   foreach my $display ( @display ) {
2444     push @b, $self->$display(@_);
2445   }
2446   @b;
2447 }
2448
2449 sub _items_previous {
2450   my $self = shift;
2451   my $cust_main = $self->cust_main;
2452   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
2453   my @b = ();
2454   foreach ( @pr_cust_bill ) {
2455     push @b, {
2456       'description' => 'Previous Balance, Invoice #'. $_->invnum.
2457                        ' ('. time2str('%x',$_->_date). ')',
2458       #'pkgpart'     => 'N/A',
2459       'pkgnum'      => 'N/A',
2460       'amount'      => sprintf("%.2f", $_->owed),
2461     };
2462   }
2463   @b;
2464
2465   #{
2466   #    'description'     => 'Previous Balance',
2467   #    #'pkgpart'         => 'N/A',
2468   #    'pkgnum'          => 'N/A',
2469   #    'amount'          => sprintf("%10.2f", $pr_total ),
2470   #    'ext_description' => [ map {
2471   #                                 "Invoice ". $_->invnum.
2472   #                                 " (". time2str("%x",$_->_date). ") ".
2473   #                                 sprintf("%10.2f", $_->owed)
2474   #                         } @pr_cust_bill ],
2475
2476   #};
2477 }
2478
2479 sub _items_pkg {
2480   my $self = shift;
2481   my %options = @_;
2482   my $section = delete $options{'section'};
2483   my @cust_bill_pkg =
2484     grep { $_->pkgnum &&
2485            ( defined($section)
2486                ? $_->part_pkg->classname eq $section->{'description'}
2487                : 1
2488            )
2489          } $self->cust_bill_pkg;
2490   $self->_items_cust_bill_pkg(\@cust_bill_pkg, %options);
2491 }
2492
2493 sub _taxsort {
2494   return 0 unless $a cmp $b;
2495   return -1 if $b eq 'Tax';
2496   return 1 if $a eq 'Tax';
2497   return -1 if $b eq 'Other surcharges';
2498   return 1 if $a eq 'Other surcharges';
2499   $a cmp $b;
2500 }
2501
2502 sub _items_tax {
2503   my $self = shift;
2504   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum } $self->cust_bill_pkg;
2505   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2506 }
2507
2508 sub _items_cust_bill_pkg {
2509   my $self = shift;
2510   my $cust_bill_pkg = shift;
2511
2512   my @b = ();
2513   foreach my $cust_bill_pkg ( @$cust_bill_pkg ) {
2514
2515     my $cust_pkg = $cust_bill_pkg->cust_pkg;
2516
2517     my $desc = $cust_bill_pkg->desc;
2518
2519     if ( $cust_bill_pkg->pkgnum > 0 ) {
2520
2521       if ( $cust_bill_pkg->setup != 0 ) {
2522         my $description = $desc;
2523         $description .= ' Setup' if $cust_bill_pkg->recur != 0;
2524         my @d = $cust_pkg->h_labels_short($self->_date);
2525         push @d, $cust_bill_pkg->details if $cust_bill_pkg->recur == 0;
2526         push @b, {
2527           description     => $description,
2528           #pkgpart         => $part_pkg->pkgpart,
2529           pkgnum          => $cust_bill_pkg->pkgnum,
2530           amount          => sprintf("%.2f", $cust_bill_pkg->setup),
2531           ext_description => \@d,
2532         };
2533       }
2534
2535       if ( $cust_bill_pkg->recur != 0 ) {
2536         push @b, {
2537           description     => $desc .
2538                              ( $conf->exists('disable_line_item_date_ranges')
2539                                ? ''
2540                                : " (" .time2str("%x", $cust_bill_pkg->sdate).
2541                                  " - ".time2str("%x", $cust_bill_pkg->edate).")"
2542                              ),
2543           #pkgpart         => $part_pkg->pkgpart,
2544           pkgnum          => $cust_bill_pkg->pkgnum,
2545           amount          => sprintf("%.2f", $cust_bill_pkg->recur),
2546           ext_description =>
2547             #at least until cust_bill_pkg has "past" ranges in addition to
2548             #the "future" sdate/edate ones... see #3032
2549             [ $cust_pkg->h_labels_short( $self->_date ),
2550                                          #$cust_bill_pkg->edate,
2551                                          #$cust_bill_pkg->sdate),
2552               $cust_bill_pkg->details,
2553             ],
2554         };
2555       }
2556
2557     } else { #pkgnum tax or one-shot line item (??)
2558
2559       if ( $cust_bill_pkg->setup != 0 ) {
2560         push @b, {
2561           'description' => $desc,
2562           'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
2563         };
2564       }
2565       if ( $cust_bill_pkg->recur != 0 ) {
2566         push @b, {
2567           'description' => "$desc (".
2568                            time2str("%x", $cust_bill_pkg->sdate). ' - '.
2569                            time2str("%x", $cust_bill_pkg->edate). ')',
2570           'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
2571         };
2572       }
2573
2574     }
2575
2576   }
2577
2578   @b;
2579
2580 }
2581
2582 sub _items_credits {
2583   my $self = shift;
2584
2585   my @b;
2586   #credits
2587   foreach ( $self->cust_credited ) {
2588
2589     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2590
2591     my $reason = $_->cust_credit->reason;
2592     #my $reason = substr($_->cust_credit->reason,0,32);
2593     #$reason .= '...' if length($reason) < length($_->cust_credit->reason);
2594     $reason = " ($reason) " if $reason;
2595     push @b, {
2596       #'description' => 'Credit ref\#'. $_->crednum.
2597       #                 " (". time2str("%x",$_->cust_credit->_date) .")".
2598       #                 $reason,
2599       'description' => 'Credit applied '.
2600                        time2str("%x",$_->cust_credit->_date). $reason,
2601       'amount'      => sprintf("%.2f",$_->amount),
2602     };
2603   }
2604   #foreach ( @cr_cust_credit ) {
2605   #  push @buf,[
2606   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
2607   #    $money_char. sprintf("%10.2f",$_->credited)
2608   #  ];
2609   #}
2610
2611   @b;
2612
2613 }
2614
2615 sub _items_payments {
2616   my $self = shift;
2617
2618   my @b;
2619   #get & print payments
2620   foreach ( $self->cust_bill_pay ) {
2621
2622     #something more elaborate if $_->amount ne ->cust_pay->paid ?
2623
2624     push @b, {
2625       'description' => "Payment received ".
2626                        time2str("%x",$_->cust_pay->_date ),
2627       'amount'      => sprintf("%.2f", $_->amount )
2628     };
2629   }
2630
2631   @b;
2632
2633 }
2634
2635
2636 =back
2637
2638 =head1 SUBROUTINES
2639
2640 =over 4
2641
2642 =item reprint
2643
2644 =cut
2645
2646 sub process_reprint {
2647   process_re_X('print', @_);
2648 }
2649
2650 =item reemail
2651
2652 =cut
2653
2654 sub process_reemail {
2655   process_re_X('email', @_);
2656 }
2657
2658 =item refax
2659
2660 =cut
2661
2662 sub process_refax {
2663   process_re_X('fax', @_);
2664 }
2665
2666 use Storable qw(thaw);
2667 use Data::Dumper;
2668 use MIME::Base64;
2669 sub process_re_X {
2670   my( $method, $job ) = ( shift, shift );
2671   warn "$me process_re_X $method for job $job\n" if $DEBUG;
2672
2673   my $param = thaw(decode_base64(shift));
2674   warn Dumper($param) if $DEBUG;
2675
2676   re_X(
2677     $method,
2678     $job,
2679     %$param,
2680   );
2681
2682 }
2683
2684 sub re_X {
2685   my($method, $job, %param ) = @_;
2686   if ( $DEBUG ) {
2687     warn "re_X $method for job $job with param:\n".
2688          join( '', map { "  $_ => ". $param{$_}. "\n" } keys %param );
2689   }
2690
2691   #some false laziness w/search/cust_bill.html
2692   my $distinct = '';
2693   my $orderby = 'ORDER BY cust_bill._date';
2694
2695   my $extra_sql = ' WHERE '. FS::cust_bill->search_sql(\%param);
2696
2697   my $addl_from = 'LEFT JOIN cust_main USING ( custnum )';
2698
2699   my @cust_bill = qsearch( {
2700     #'select'    => "cust_bill.*",
2701     'table'     => 'cust_bill',
2702     'addl_from' => $addl_from,
2703     'hashref'   => {},
2704     'extra_sql' => $extra_sql,
2705     'order_by'  => $orderby,
2706     'debug' => 1,
2707   } );
2708
2709   warn " $me re_X $method: ". scalar(@cust_bill). " invoices found\n"
2710     if $DEBUG;
2711
2712   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
2713   foreach my $cust_bill ( @cust_bill ) {
2714     $cust_bill->$method();
2715
2716     if ( $job ) { #progressbar foo
2717       $num++;
2718       if ( time - $min_sec > $last ) {
2719         my $error = $job->update_statustext(
2720           int( 100 * $num / scalar(@cust_bill) )
2721         );
2722         die $error if $error;
2723         $last = time;
2724       }
2725     }
2726
2727   }
2728
2729 }
2730
2731 =back
2732
2733 =head1 CLASS METHODS
2734
2735 =over 4
2736
2737 =item owed_sql
2738
2739 Returns an SQL fragment to retreive the amount owed (charged minus credited and paid).
2740
2741 =cut
2742
2743 sub owed_sql {
2744   my $class = shift;
2745   'charged - '. $class->paid_sql. ' - '. $class->credited_sql;
2746 }
2747
2748 =item net_sql
2749
2750 Returns an SQL fragment to retreive the net amount (charged minus credited).
2751
2752 =cut
2753
2754 sub net_sql {
2755   my $class = shift;
2756   'charged - '. $class->credited_sql;
2757 }
2758
2759 =item paid_sql
2760
2761 Returns an SQL fragment to retreive the amount paid against this invoice.
2762
2763 =cut
2764
2765 sub paid_sql {
2766   #my $class = shift;
2767   "( SELECT COALESCE(SUM(amount),0) FROM cust_bill_pay
2768        WHERE cust_bill.invnum = cust_bill_pay.invnum   )";
2769 }
2770
2771 =item credited_sql
2772
2773 Returns an SQL fragment to retreive the amount credited against this invoice.
2774
2775 =cut
2776
2777 sub credited_sql {
2778   #my $class = shift;
2779   "( SELECT COALESCE(SUM(amount),0) FROM cust_credit_bill
2780        WHERE cust_bill.invnum = cust_credit_bill.invnum   )";
2781 }
2782
2783 =item search_sql HASHREF
2784
2785 Class method which returns an SQL WHERE fragment to search for parameters
2786 specified in HASHREF.  Valid parameters are
2787
2788 =over 4
2789
2790 =item begin
2791
2792 Epoch date (UNIX timestamp) setting a lower bound for _date values
2793
2794 =item end
2795
2796 Epoch date (UNIX timestamp) setting an upper bound for _date values
2797
2798 =item invnum_min
2799
2800 =item invnum_max
2801
2802 =item agentnum
2803
2804 =item owed
2805
2806 =item net
2807
2808 =item days
2809
2810 =item newest_percust
2811
2812 =back
2813
2814 Note: validates all passed-in data; i.e. safe to use with unchecked CGI params.
2815
2816 =cut
2817
2818 sub search_sql {
2819   my($class, $param) = @_;
2820   if ( $DEBUG ) {
2821     warn "$me search_sql called with params: \n".
2822          join("\n", map { "  $_: ". $param->{$_} } keys %$param ). "\n";
2823   }
2824
2825   my @search = ();
2826
2827   if ( $param->{'begin'} =~ /^(\d+)$/ ) {
2828     push @search, "cust_bill._date >= $1";
2829   }
2830   if ( $param->{'end'} =~ /^(\d+)$/ ) {
2831     push @search, "cust_bill._date < $1";
2832   }
2833   if ( $param->{'invnum_min'} =~ /^(\d+)$/ ) {
2834     push @search, "cust_bill.invnum >= $1";
2835   }
2836   if ( $param->{'invnum_max'} =~ /^(\d+)$/ ) {
2837     push @search, "cust_bill.invnum <= $1";
2838   }
2839   if ( $param->{'agentnum'} =~ /^(\d+)$/ ) {
2840     push @search, "cust_main.agentnum = $1";
2841   }
2842
2843   push @search, '0 != '. FS::cust_bill->owed_sql
2844     if $param->{'open'};
2845
2846   push @search, '0 != '. FS::cust_bill->net_sql
2847     if $param->{'net'};
2848
2849   push @search, "cust_bill._date < ". (time-86400*$param->{'days'})
2850     if $param->{'days'};
2851
2852   if ( $param->{'newest_percust'} ) {
2853
2854     #$distinct = 'DISTINCT ON ( cust_bill.custnum )';
2855     #$orderby = 'ORDER BY cust_bill.custnum ASC, cust_bill._date DESC';
2856
2857     my @newest_where = map { my $x = $_;
2858                              $x =~ s/\bcust_bill\./newest_cust_bill./g;
2859                              $x;
2860                            }
2861                            grep ! /^cust_main./, @search;
2862     my $newest_where = scalar(@newest_where)
2863                          ? ' AND '. join(' AND ', @newest_where)
2864                          : '';
2865
2866
2867     push @search, "cust_bill._date = (
2868       SELECT(MAX(newest_cust_bill._date)) FROM cust_bill AS newest_cust_bill
2869         WHERE newest_cust_bill.custnum = cust_bill.custnum
2870           $newest_where
2871     )";
2872
2873   }
2874
2875   my $curuser = $FS::CurrentUser::CurrentUser;
2876   if ( $curuser->username eq 'fs_queue'
2877        && $param->{'CurrentUser'} =~ /^(\w+)$/ ) {
2878     my $username = $1;
2879     my $newuser = qsearchs('access_user', {
2880       'username' => $username,
2881       'disabled' => '',
2882     } );
2883     if ( $newuser ) {
2884       $curuser = $newuser;
2885     } else {
2886       warn "$me WARNING: (fs_queue) can't find CurrentUser $username\n";
2887     }
2888   }
2889
2890   push @search, $curuser->agentnums_sql;
2891
2892   join(' AND ', @search );
2893
2894 }
2895
2896 =back
2897
2898 =head1 BUGS
2899
2900 The delete method.
2901
2902 =head1 SEE ALSO
2903
2904 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
2905 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
2906 documentation.
2907
2908 =cut
2909
2910 1;
2911