FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $money_char );
   5 use vars qw( $lpr $invoice_from $smtpmachine );
   6 use vars qw( $processor );
   7 use vars qw( $xaction $E_NoErr );
   8 use vars qw( $bop_processor $bop_login $bop_password $bop_action @bop_options );
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use Date::Format;
  11 use Mail::Internet;
  12 use Mail::Header;
  13 use Text::Template;
  14 use FS::Record qw( qsearch qsearchs );
  15 use FS::cust_main;
  16 use FS::cust_bill_pkg;
  17 use FS::cust_credit;
  18 use FS::cust_pay;
  19 use FS::cust_pkg;
  20 use FS::cust_credit_bill;
  21 use FS::cust_pay_batch;
  22 use FS::cust_bill_event;
  23
  24 @ISA = qw( FS::Record );
  25
  26 #ask FS::UID to run this stuff for us later
  27 $FS::UID::callback{'FS::cust_bill'} = sub {
  28
  29   $conf = new FS::Conf;
  30
  31   $money_char = $conf->config('money_char') || '$';
  32
  33   $lpr = $conf->config('lpr');
  34   $invoice_from = $conf->config('invoice_from');
  35   $smtpmachine = $conf->config('smtpmachine');
  36
  37   if ( $conf->exists('cybercash3.2') ) {
  38     require CCMckLib3_2;
  39       #qw($MCKversion %Config InitConfig CCError CCDebug CCDebug2);
  40     require CCMckDirectLib3_2;
  41       #qw(SendCC2_1Server);
  42     require CCMckErrno3_2;
  43       #qw(MCKGetErrorMessage $E_NoErr);
  44     import CCMckErrno3_2 qw($E_NoErr);
  45
  46     my $merchant_conf;
  47     ($merchant_conf,$xaction)= $conf->config('cybercash3.2');
  48     my $status = &CCMckLib3_2::InitConfig($merchant_conf);
  49     if ( $status != $E_NoErr ) {
  50       warn "CCMckLib3_2::InitConfig error:\n";
  51       foreach my $key (keys %CCMckLib3_2::Config) {
  52         warn "  $key => $CCMckLib3_2::Config{$key}\n"
  53       }
  54       my($errmsg) = &CCMckErrno3_2::MCKGetErrorMessage($status);
  55       die "CCMckLib3_2::InitConfig fatal error: $errmsg\n";
  56     }
  57     $processor='cybercash3.2';
  58   } elsif ( $conf->exists('business-onlinepayment') ) {
  59     ( $bop_processor,
  60       $bop_login,
  61       $bop_password,
  62       $bop_action,
  63       @bop_options
  64     ) = $conf->config('business-onlinepayment');
  65     $bop_action ||= 'normal authorization';
  66     eval "use Business::OnlinePayment";
  67     $processor="Business::OnlinePayment::$bop_processor";
  68   }
  69
  70 };
  71
  72 =head1 NAME
  73
  74 FS::cust_bill - Object methods for cust_bill records
  75
  76 =head1 SYNOPSIS
  77
  78   use FS::cust_bill;
  79
  80   $record = new FS::cust_bill \%hash;
  81   $record = new FS::cust_bill { 'column' => 'value' };
  82
  83   $error = $record->insert;
  84
  85   $error = $new_record->replace($old_record);
  86
  87   $error = $record->delete;
  88
  89   $error = $record->check;
  90
  91   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  92
  93   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  94
  95   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  96
  97   @cust_pay_objects = $cust_bill->cust_pay;
  98
  99   $tax_amount = $record->tax;
 100
 101   @lines = $cust_bill->print_text;
 102   @lines = $cust_bill->print_text $time;
 103
 104 =head1 DESCRIPTION
 105
 106 An FS::cust_bill object represents an invoice; a declaration that a customer
 107 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
 108 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
 109 following fields are currently supported:
 110
 111 =over 4
 112
 113 =item invnum - primary key (assigned automatically for new invoices)
 114
 115 =item custnum - customer (see L<FS::cust_main>)
 116
 117 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 118 L<Time::Local> and L<Date::Parse> for conversion functions.
 119
 120 =item charged - amount of this invoice
 121
 122 =item printed - deprecated
 123
 124 =item closed - books closed flag, empty or `Y'
 125
 126 =back
 127
 128 =head1 METHODS
 129
 130 =over 4
 131
 132 =item new HASHREF
 133
 134 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 135 Invoices are normally created by calling the bill method of a customer object
 136 (see L<FS::cust_main>).
 137
 138 =cut
 139
 140 sub table { 'cust_bill'; }
 141
 142 =item insert
 143
 144 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 145 returns the error, otherwise returns false.
 146
 147 =item delete
 148
 149 Currently unimplemented.  I don't remove invoices because there would then be
 150 no record you ever posted this invoice (which is bad, no?)
 151
 152 =cut
 153
 154 sub delete {
 155   my $self = shift;
 156   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 157   $self->SUPER::delete(@_);
 158 }
 159
 160 =item replace OLD_RECORD
 161
 162 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 163 returns the error, otherwise returns false.
 164
 165 Only printed may be changed.  printed is normally updated by calling the
 166 collect method of a customer object (see L<FS::cust_main>).
 167
 168 =cut
 169
 170 sub replace {
 171   my( $new, $old ) = ( shift, shift );
 172   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 173   #return "Can't change _date!" unless $old->_date eq $new->_date;
 174   return "Can't change _date!" unless $old->_date == $new->_date;
 175   return "Can't change charged!" unless $old->charged == $new->charged;
 176
 177   $new->SUPER::replace($old);
 178 }
 179
 180 =item check
 181
 182 Checks all fields to make sure this is a valid invoice.  If there is an error,
 183 returns the error, otherwise returns false.  Called by the insert and replace
 184 methods.
 185
 186 =cut
 187
 188 sub check {
 189   my $self = shift;
 190
 191   my $error =
 192     $self->ut_numbern('invnum')
 193     || $self->ut_number('custnum')
 194     || $self->ut_numbern('_date')
 195     || $self->ut_money('charged')
 196     || $self->ut_numbern('printed')
 197     || $self->ut_enum('closed', [ '', 'Y' ])
 198   ;
 199   return $error if $error;
 200
 201   return "Unknown customer"
 202     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 203
 204   $self->_date(time) unless $self->_date;
 205
 206   $self->printed(0) if $self->printed eq '';
 207
 208   ''; #no error
 209 }
 210
 211 =item previous
 212
 213 Returns a list consisting of the total previous balance for this customer,
 214 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 215
 216 =cut
 217
 218 sub previous {
 219   my $self = shift;
 220   my $total = 0;
 221   my @cust_bill = sort { $a->_date <=> $b->_date }
 222     grep { $_->owed != 0 && $_->_date < $self->_date }
 223       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 224   ;
 225   foreach ( @cust_bill ) { $total += $_->owed; }
 226   $total, @cust_bill;
 227 }
 228
 229 =item cust_bill_pkg
 230
 231 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 232
 233 =cut
 234
 235 sub cust_bill_pkg {
 236   my $self = shift;
 237   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 238 }
 239
 240 =item cust_bill_event
 241
 242 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 243 invoice.
 244
 245 =cut
 246
 247 sub cust_bill_event {
 248   my $self = shift;
 249   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 250 }
 251
 252
 253 =item cust_main
 254
 255 Returns the customer (see L<FS::cust_main>) for this invoice.
 256
 257 =cut
 258
 259 sub cust_main {
 260   my $self = shift;
 261   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 262 }
 263
 264 =item cust_credit
 265
 266 Depreciated.  See the cust_credited method.
 267
 268  #Returns a list consisting of the total previous credited (see
 269  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 270  #outstanding credits (FS::cust_credit objects).
 271
 272 =cut
 273
 274 sub cust_credit {
 275   use Carp;
 276   croak "FS::cust_bill->cust_credit depreciated; see ".
 277         "FS::cust_bill->cust_credit_bill";
 278   #my $self = shift;
 279   #my $total = 0;
 280   #my @cust_credit = sort { $a->_date <=> $b->_date }
 281   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 282   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 283   #;
 284   #foreach (@cust_credit) { $total += $_->credited; }
 285   #$total, @cust_credit;
 286 }
 287
 288 =item cust_pay
 289
 290 Depreciated.  See the cust_bill_pay method.
 291
 292 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 293
 294 =cut
 295
 296 sub cust_pay {
 297   use Carp;
 298   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 299   #my $self = shift;
 300   #sort { $a->_date <=> $b->_date }
 301   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 302   #;
 303 }
 304
 305 =item cust_bill_pay
 306
 307 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 308
 309 =cut
 310
 311 sub cust_bill_pay {
 312   my $self = shift;
 313   sort { $a->_date <=> $b->_date }
 314     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 315 }
 316
 317 =item cust_credited
 318
 319 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 320
 321 =cut
 322
 323 sub cust_credited {
 324   my $self = shift;
 325   sort { $a->_date <=> $b->_date }
 326     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 327   ;
 328 }
 329
 330 =item tax
 331
 332 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 333
 334 =cut
 335
 336 sub tax {
 337   my $self = shift;
 338   my $total = 0;
 339   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 340                                              'pkgnum' => 0 } );
 341   foreach (@taxlines) { $total += $_->setup; }
 342   $total;
 343 }
 344
 345 =item owed
 346
 347 Returns the amount owed (still outstanding) on this invoice, which is charged
 348 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 349 applications (see L<FS::cust_credit_bill>).
 350
 351 =cut
 352
 353 sub owed {
 354   my $self = shift;
 355   my $balance = $self->charged;
 356   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 357   $balance -= $_->amount foreach ( $self->cust_credited );
 358   $balance = sprintf( "%.2f", $balance);
 359   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 360   $balance;
 361 }
 362
 363 =item send
 364
 365 Sends this invoice to the destinations configured for this customer: send
 366 emails or print.  See L<FS::cust_main_invoice>.
 367
 368 =cut
 369
 370 sub send {
 371   my($self,$template) = @_;
 372
 373   #my @print_text = $cust_bill->print_text; #( date )
 374   my @invoicing_list = $self->cust_main->invoicing_list;
 375   if ( grep { $_ ne 'POST' } @invoicing_list ) { #email invoice
 376     #false laziness w/FS::cust_pay::delete & fs_signup_server && ::realtime_card
 377     #$ENV{SMTPHOSTS} = $smtpmachine;
 378     $ENV{MAILADDRESS} = $invoice_from;
 379     my $header = new Mail::Header ( [
 380       "From: $invoice_from",
 381       "To: ". join(', ', grep { $_ ne 'POST' } @invoicing_list ),
 382       "Sender: $invoice_from",
 383       "Reply-To: $invoice_from",
 384       "Date: ". time2str("%a, %d %b %Y %X %z", time),
 385       "Subject: Invoice",
 386     ] );
 387     my $message = new Mail::Internet (
 388       'Header' => $header,
 389       'Body' => [ $self->print_text('', $template) ], #( date)
 390     );
 391     $!=0;
 392     $message->smtpsend( Host => $smtpmachine )
 393       or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 394         or return "(customer # ". $self->custnum. ") can't send invoice email".
 395                   " to ". join(', ', grep { $_ ne 'POST' } @invoicing_list ).
 396                   " via server $smtpmachine with SMTP: $!";
 397
 398   #} elsif ( grep { $_ eq 'POST' } @invoicing_list ) {
 399   } elsif ( ! @invoicing_list || grep { $_ eq 'POST' } @invoicing_list ) {
 400     open(LPR, "|$lpr")
 401       or return "Can't open pipe to $lpr: $!";
 402     print LPR $self->print_text; #( date )
 403     close LPR
 404       or return $! ? "Error closing $lpr: $!"
 405                    : "Exit status $? from $lpr";
 406   }
 407
 408   '';
 409
 410 }
 411
 412 =item comp
 413
 414 Pays this invoice with a compliemntary payment.  If there is an error,
 415 returns the error, otherwise returns false.
 416
 417 =cut
 418
 419 sub comp {
 420   my $self = shift;
 421   my $cust_pay = new FS::cust_pay ( {
 422     'invnum'   => $self->invnum,
 423     'paid'     => $self->owed,
 424     '_date'    => '',
 425     'payby'    => 'COMP',
 426     'payinfo'  => $self->cust_main->payinfo,
 427     'paybatch' => '',
 428   } );
 429   $cust_pay->insert;
 430 }
 431
 432 =item realtime_card
 433
 434 Attempts to pay this invoice with a Business::OnlinePayment realtime gateway.
 435 See http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 436 for supproted processors.
 437
 438 =cut
 439
 440 sub realtime_card {
 441   my $self = shift;
 442   my $cust_main = $self->cust_main;
 443   my $amount = $self->owed;
 444
 445   unless ( $processor =~ /^Business::OnlinePayment::(.*)$/ ) {
 446     return "Real-time card processing not enabled (processor $processor)";
 447   }
 448   my $bop_processor = $1; #hmm?
 449
 450   my $address = $cust_main->address1;
 451   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 452
 453   #fix exp. date
 454   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 455   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 456   my $exp = "$2/$1";
 457
 458   my($payname, $payfirst, $paylast);
 459   if ( $cust_main->payname ) {
 460     $payname = $cust_main->payname;
 461     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)$/
 462       or do {
 463               #$dbh->rollback if $oldAutoCommit;
 464               return "Illegal payname $payname";
 465             };
 466     ($payfirst, $paylast) = ($1, $2);
 467   } else {
 468     $payfirst = $cust_main->getfield('first');
 469     $paylast = $cust_main->getfield('first');
 470     $payname =  "$payfirst $paylast";
 471   }
 472
 473   my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 474   if ( $conf->exists('emailinvoiceauto')
 475        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 476     push @invoicing_list, $cust_main->default_invoicing_list;
 477   }
 478   my $email = $invoicing_list[0];
 479
 480   my( $action1, $action2 ) = split(/\s*\,\s*/, $bop_action );
 481
 482   my $description = 'Internet Services';
 483   if ( $conf->exists('business-onlinepayment-description') ) {
 484     my $dtempl = $conf->config('business-onlinepayment-description');
 485
 486     my $agent_obj = $cust_main->agent;
 487     my $agent = $agent_obj->agent;
 488     my $pkgs = join(', ',
 489       map { $_->cust_pkg->part_pkg->pkg }
 490         grep { $_->pkgnum } $self->cust_bill_pkg
 491     );
 492     $description = eval qq("$dtempl");
 493
 494   }
 495
 496   my $transaction =
 497     new Business::OnlinePayment( $bop_processor, @bop_options );
 498   $transaction->content(
 499     'type'           => 'CC',
 500     'login'          => $bop_login,
 501     'password'       => $bop_password,
 502     'action'         => $action1,
 503     'description'    => $description,
 504     'amount'         => $amount,
 505     'invoice_number' => $self->invnum,
 506     'customer_id'    => $self->custnum,
 507     'last_name'      => $paylast,
 508     'first_name'     => $payfirst,
 509     'name'           => $payname,
 510     'address'        => $address,
 511     'city'           => $cust_main->city,
 512     'state'          => $cust_main->state,
 513     'zip'            => $cust_main->zip,
 514     'country'        => $cust_main->country,
 515     'card_number'    => $cust_main->payinfo,
 516     'expiration'     => $exp,
 517     'referer'        => 'http://cleanwhisker.420.am/',
 518     'email'          => $email,
 519   );
 520   $transaction->submit();
 521
 522   if ( $transaction->is_success() && $action2 ) {
 523     my $auth = $transaction->authorization;
 524     my $ordernum = $transaction->order_number;
 525     #warn "********* $auth ***********\n";
 526     #warn "********* $ordernum ***********\n";
 527     my $capture =
 528       new Business::OnlinePayment( $bop_processor, @bop_options );
 529
 530     $capture->content(
 531       action         => $action2,
 532       login          => $bop_login,
 533       password       => $bop_password,
 534       order_number   => $ordernum,
 535       amount         => $amount,
 536       authorization  => $auth,
 537       description    => $description,
 538     );
 539
 540     $capture->submit();
 541
 542     unless ( $capture->is_success ) {
 543       my $e = "Authorization sucessful but capture failed, invnum #".
 544               $self->invnum. ': '.  $capture->result_code.
 545               ": ". $capture->error_message;
 546       warn $e;
 547       return $e;
 548     }
 549
 550   }
 551
 552   if ( $transaction->is_success() ) {
 553
 554     my $cust_pay = new FS::cust_pay ( {
 555        'invnum'   => $self->invnum,
 556        'paid'     => $amount,
 557        '_date'     => '',
 558        'payby'    => 'CARD',
 559        'payinfo'  => $cust_main->payinfo,
 560        'paybatch' => "$processor:". $transaction->authorization,
 561     } );
 562     my $error = $cust_pay->insert;
 563     if ( $error ) {
 564       # gah, even with transactions.
 565       my $e = 'WARNING: Card debited but database not updated - '.
 566               'error applying payment, invnum #' . $self->invnum.
 567               " ($processor): $error";
 568       warn $e;
 569       return $e;
 570     } else {
 571       return '';
 572     }
 573   #} elsif ( $options{'report_badcard'} ) {
 574   } else {
 575
 576     my $perror = "$processor error, invnum #". $self->invnum. ': '.
 577                  $transaction->result_code. ": ". $transaction->error_message;
 578
 579     if ( $conf->exists('emaildecline')
 580          && grep { $_ ne 'POST' } $cust_main->invoicing_list
 581     ) {
 582       my @templ = $conf->config('declinetemplate');
 583       my $template = new Text::Template (
 584         TYPE   => 'ARRAY',
 585         SOURCE => [ map "$_\n", @templ ],
 586       ) or return "($perror) can't create template: $Text::Template::ERROR";
 587       $template->compile()
 588         or return "($perror) can't compile template: $Text::Template::ERROR";
 589
 590       my $error = $transaction->error_message;
 591
 592       #false laziness w/FS::cust_pay::delete & fs_signup_server && ::send
 593       $ENV{MAILADDRESS} = $invoice_from;
 594       my $header = new Mail::Header ( [
 595         "From: $invoice_from",
 596         "To: ". join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ),
 597         "Sender: $invoice_from",
 598         "Reply-To: $invoice_from",
 599         "Date: ". time2str("%a, %d %b %Y %X %z", time),
 600         "Subject: Your credit card could not be processed",
 601       ] );
 602       my $message = new Mail::Internet (
 603         'Header' => $header,
 604         'Body' => [ $template->fill_in() ],
 605       );
 606       $!=0;
 607       $message->smtpsend( Host => $smtpmachine )
 608         or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 609           or return "($perror) (customer # ". $self->custnum.
 610             ") can't send card decline email to ".
 611             join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ).
 612             " via server $smtpmachine with SMTP: $!";
 613     }
 614
 615     return $perror;
 616   }
 617
 618 }
 619
 620 =item realtime_card_cybercash
 621
 622 Attempts to pay this invoice with the CyberCash CashRegister realtime gateway.
 623
 624 =cut
 625
 626 sub realtime_card_cybercash {
 627   my $self = shift;
 628   my $cust_main = $self->cust_main;
 629   my $amount = $self->owed;
 630
 631   return "CyberCash CashRegister real-time card processing not enabled!"
 632     unless $processor eq 'cybercash3.2';
 633
 634   my $address = $cust_main->address1;
 635   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 636
 637   #fix exp. date
 638   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 639   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 640   my $exp = "$2/$1";
 641
 642   #
 643
 644   my $paybatch = $self->invnum.
 645                   '-' . time2str("%y%m%d%H%M%S", time);
 646
 647   my $payname = $cust_main->payname ||
 648                 $cust_main->getfield('first').' '.$cust_main->getfield('last');
 649
 650   my $country = $cust_main->country eq 'US' ? 'USA' : $cust_main->country;
 651
 652   my @full_xaction = ( $xaction,
 653     'Order-ID'     => $paybatch,
 654     'Amount'       => "usd $amount",
 655     'Card-Number'  => $cust_main->getfield('payinfo'),
 656     'Card-Name'    => $payname,
 657     'Card-Address' => $address,
 658     'Card-City'    => $cust_main->getfield('city'),
 659     'Card-State'   => $cust_main->getfield('state'),
 660     'Card-Zip'     => $cust_main->getfield('zip'),
 661     'Card-Country' => $country,
 662     'Card-Exp'     => $exp,
 663   );
 664
 665   my %result;
 666   %result = &CCMckDirectLib3_2::SendCC2_1Server(@full_xaction);
 667
 668   if ( $result{'MStatus'} eq 'success' ) { #cybercash smps v.2 or 3
 669     my $cust_pay = new FS::cust_pay ( {
 670        'invnum'   => $self->invnum,
 671        'paid'     => $amount,
 672        '_date'     => '',
 673        'payby'    => 'CARD',
 674        'payinfo'  => $cust_main->payinfo,
 675        'paybatch' => "$processor:$paybatch",
 676     } );
 677     my $error = $cust_pay->insert;
 678     if ( $error ) {
 679       # gah, even with transactions.
 680       my $e = 'WARNING: Card debited but database not updated - '.
 681               'error applying payment, invnum #' . $self->invnum.
 682               " (CyberCash Order-ID $paybatch): $error";
 683       warn $e;
 684       return $e;
 685     } else {
 686       return '';
 687     }
 688 #  } elsif ( $result{'Mstatus'} ne 'failure-bad-money'
 689 #            || $options{'report_badcard'}
 690 #          ) {
 691   } else {
 692      return 'Cybercash error, invnum #' .
 693        $self->invnum. ':'. $result{'MErrMsg'};
 694   }
 695
 696 }
 697
 698 =item batch_card
 699
 700 Adds a payment for this invoice to the pending credit card batch (see
 701 L<FS::cust_pay_batch>).
 702
 703 =cut
 704
 705 sub batch_card {
 706   my $self = shift;
 707   my $cust_main = $self->cust_main;
 708
 709   my $cust_pay_batch = new FS::cust_pay_batch ( {
 710     'invnum'   => $self->getfield('invnum'),
 711     'custnum'  => $cust_main->getfield('custnum'),
 712     'last'     => $cust_main->getfield('last'),
 713     'first'    => $cust_main->getfield('first'),
 714     'address1' => $cust_main->getfield('address1'),
 715     'address2' => $cust_main->getfield('address2'),
 716     'city'     => $cust_main->getfield('city'),
 717     'state'    => $cust_main->getfield('state'),
 718     'zip'      => $cust_main->getfield('zip'),
 719     'country'  => $cust_main->getfield('country'),
 720     'trancode' => 77,
 721     'cardnum'  => $cust_main->getfield('payinfo'),
 722     'exp'      => $cust_main->getfield('paydate'),
 723     'payname'  => $cust_main->getfield('payname'),
 724     'amount'   => $self->owed,
 725   } );
 726   $cust_pay_batch->insert;
 727
 728 }
 729
 730 =item print_text [TIME];
 731
 732 Returns an text invoice, as a list of lines.
 733
 734 TIME an optional value used to control the printing of overdue messages.  The
 735 default is now.  It isn't the date of the invoice; that's the `_date' field.
 736 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 737 L<Time::Local> and L<Date::Parse> for conversion functions.
 738
 739 =cut
 740
 741 sub print_text {
 742
 743   my( $self, $today, $template ) = @_;
 744   $today ||= time;
 745 #  my $invnum = $self->invnum;
 746   my $cust_main = qsearchs('cust_main', { 'custnum', $self->custnum } );
 747   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 748     unless $cust_main->payname;
 749
 750   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 751 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 752   #my $balance_due = $self->owed + $pr_total - $cr_total;
 753   my $balance_due = $self->owed + $pr_total;
 754
 755   #my @collect = ();
 756   #my($description,$amount);
 757   @buf = ();
 758
 759   #previous balance
 760   foreach ( @pr_cust_bill ) {
 761     push @buf, [
 762       "Previous Balance, Invoice #". $_->invnum.
 763                  " (". time2str("%x",$_->_date). ")",
 764       $money_char. sprintf("%10.2f",$_->owed)
 765     ];
 766   }
 767   if (@pr_cust_bill) {
 768     push @buf,['','-----------'];
 769     push @buf,[ 'Total Previous Balance',
 770                 $money_char. sprintf("%10.2f",$pr_total ) ];
 771     push @buf,['',''];
 772   }
 773
 774   #new charges
 775   foreach ( $self->cust_bill_pkg ) {
 776
 777     if ( $_->pkgnum ) {
 778
 779       my($cust_pkg)=qsearchs('cust_pkg', { 'pkgnum', $_->pkgnum } );
 780       my($part_pkg)=qsearchs('part_pkg',{'pkgpart'=>$cust_pkg->pkgpart});
 781       my($pkg)=$part_pkg->pkg;
 782
 783       if ( $_->setup != 0 ) {
 784         push @buf, [ "$pkg Setup", $money_char. sprintf("%10.2f",$_->setup) ];
 785         push @buf,
 786           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 787       }
 788
 789       if ( $_->recur != 0 ) {
 790         push @buf, [
 791           "$pkg (" . time2str("%x",$_->sdate) . " - " .
 792                                 time2str("%x",$_->edate) . ")",
 793           $money_char. sprintf("%10.2f",$_->recur)
 794         ];
 795         push @buf,
 796           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 797       }
 798
 799     } else { #pkgnum Tax
 800       push @buf,["Tax", $money_char. sprintf("%10.2f",$_->setup) ]
 801         if $_->setup != 0;
 802     }
 803   }
 804
 805   push @buf,['','-----------'];
 806   push @buf,['Total New Charges',
 807              $money_char. sprintf("%10.2f",$self->charged) ];
 808   push @buf,['',''];
 809
 810   push @buf,['','-----------'];
 811   push @buf,['Total Charges',
 812              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
 813   push @buf,['',''];
 814
 815   #credits
 816   foreach ( $self->cust_credited ) {
 817
 818     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
 819
 820     my $reason = substr($_->cust_credit->reason,0,32);
 821     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
 822     $reason = " ($reason) " if $reason;
 823     push @buf,[
 824       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
 825         $reason,
 826       $money_char. sprintf("%10.2f",$_->amount)
 827     ];
 828   }
 829   #foreach ( @cr_cust_credit ) {
 830   #  push @buf,[
 831   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
 832   #    $money_char. sprintf("%10.2f",$_->credited)
 833   #  ];
 834   #}
 835
 836   #get & print payments
 837   foreach ( $self->cust_bill_pay ) {
 838
 839     #something more elaborate if $_->amount ne ->cust_pay->paid ?
 840
 841     push @buf,[
 842       "Payment received ". time2str("%x",$_->cust_pay->_date ),
 843       $money_char. sprintf("%10.2f",$_->amount )
 844     ];
 845   }
 846
 847   #balance due
 848   push @buf,['','-----------'];
 849   push @buf,['Balance Due', $money_char.
 850     sprintf("%10.2f", $balance_due ) ];
 851
 852   #create the template
 853   my $templatefile = 'invoice_template';
 854   $templatefile .= "_$template" if $template;
 855   my @invoice_template = $conf->config($templatefile)
 856   or die "cannot load config file $templatefile";
 857   $invoice_lines = 0;
 858   my $wasfunc = 0;
 859   foreach ( grep /invoice_lines\(\d+\)/, @invoice_template ) { #kludgy
 860     /invoice_lines\((\d+)\)/;
 861     $invoice_lines += $1;
 862     $wasfunc=1;
 863   }
 864   die "no invoice_lines() functions in template?" unless $wasfunc;
 865   my $invoice_template = new Text::Template (
 866     TYPE   => 'ARRAY',
 867     SOURCE => [ map "$_\n", @invoice_template ],
 868   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
 869   $invoice_template->compile()
 870     or die "can't compile template: $Text::Template::ERROR";
 871
 872   #setup template variables
 873   package FS::cust_bill::_template; #!
 874   use vars qw( $invnum $date $page $total_pages @address $overdue @buf );
 875
 876   $invnum = $self->invnum;
 877   $date = $self->_date;
 878   $page = 1;
 879
 880   if ( $FS::cust_bill::invoice_lines ) {
 881     $total_pages =
 882       int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
 883     $total_pages++
 884       if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
 885   } else {
 886     $total_pages = 1;
 887   }
 888
 889   #format address (variable for the template)
 890   my $l = 0;
 891   @address = ( '', '', '', '', '', '' );
 892   package FS::cust_bill; #!
 893   $FS::cust_bill::_template::address[$l++] =
 894     $cust_main->payname.
 895       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 896         ? " (P.O. #". $cust_main->payinfo. ")"
 897         : ''
 898       )
 899   ;
 900   $FS::cust_bill::_template::address[$l++] = $cust_main->company
 901     if $cust_main->company;
 902   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
 903   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
 904     if $cust_main->address2;
 905   $FS::cust_bill::_template::address[$l++] =
 906     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 907   $FS::cust_bill::_template::address[$l++] = $cust_main->country
 908     unless $cust_main->country eq 'US';
 909
 910         #  #overdue? (variable for the template)
 911         #  $FS::cust_bill::_template::overdue = (
 912         #    $balance_due > 0
 913         #    && $today > $self->_date
 914         ##    && $self->printed > 1
 915         #    && $self->printed > 0
 916         #  );
 917
 918   #and subroutine for the template
 919
 920   sub FS::cust_bill::_template::invoice_lines {
 921     my $lines = shift or return @buf;
 922     map {
 923       scalar(@buf) ? shift @buf : [ '', '' ];
 924     }
 925     ( 1 .. $lines );
 926   }
 927
 928
 929   #and fill it in
 930   $FS::cust_bill::_template::page = 1;
 931   my $lines;
 932   my @collect;
 933   while (@buf) {
 934     push @collect, split("\n",
 935       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
 936     );
 937     $FS::cust_bill::_template::page++;
 938   }
 939
 940   map "$_\n", @collect;
 941
 942 }
 943
 944 =back
 945
 946 =head1 VERSION
 947
 948 $Id: cust_bill.pm,v 1.31 2002-04-16 22:52:14 ivan Exp $
 949
 950 =head1 BUGS
 951
 952 The delete method.
 953
 954 print_text formatting (and some logic :/) is in source, but needs to be
 955 slurped in from a file.  Also number of lines ($=).
 956
 957 missing print_ps for a nice postscript copy (maybe HylaFAX-cover-page-style
 958 or something similar so the look can be completely customized?)
 959
 960 =head1 SEE ALSO
 961
 962 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
 963 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
 964 documentation.
 965
 966 =cut
 967
 968 1;
 969