FS/FS/cdr.pm

   1 package FS::cdr;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use Date::Parse;
   8 use Date::Format;
   9 use Time::Local;
  10 use FS::UID qw( dbh );
  11 use FS::Conf;
  12 use FS::Record qw( qsearch qsearchs );
  13 use FS::cdr_type;
  14 use FS::cdr_calltype;
  15 use FS::cdr_carrier;
  16
  17 @ISA = qw(FS::Record);
  18 @EXPORT_OK = qw( _cdr_date_parser_maker _cdr_min_parser_maker );
  19
  20 $DEBUG = 0;
  21
  22 =head1 NAME
  23
  24 FS::cdr - Object methods for cdr records
  25
  26 =head1 SYNOPSIS
  27
  28   use FS::cdr;
  29
  30   $record = new FS::cdr \%hash;
  31   $record = new FS::cdr { 'column' => 'value' };
  32
  33   $error = $record->insert;
  34
  35   $error = $new_record->replace($old_record);
  36
  37   $error = $record->delete;
  38
  39   $error = $record->check;
  40
  41 =head1 DESCRIPTION
  42
  43 An FS::cdr object represents an Call Data Record, typically from a telephony
  44 system or provider of some sort.  FS::cdr inherits from FS::Record.  The
  45 following fields are currently supported:
  46
  47 =over 4
  48
  49 =item acctid - primary key
  50
  51 =item calldate - Call timestamp (SQL timestamp)
  52
  53 =item clid - Caller*ID with text
  54
  55 =item src - Caller*ID number / Source number
  56
  57 =item dst - Destination extension
  58
  59 =item dcontext - Destination context
  60
  61 =item channel - Channel used
  62
  63 =item dstchannel - Destination channel if appropriate
  64
  65 =item lastapp - Last application if appropriate
  66
  67 =item lastdata - Last application data
  68
  69 =item startdate - Start of call (UNIX-style integer timestamp)
  70
  71 =item answerdate - Answer time of call (UNIX-style integer timestamp)
  72
  73 =item enddate - End time of call (UNIX-style integer timestamp)
  74
  75 =item duration - Total time in system, in seconds
  76
  77 =item billsec - Total time call is up, in seconds
  78
  79 =item disposition - What happened to the call: ANSWERED, NO ANSWER, BUSY
  80
  81 =item amaflags - What flags to use: BILL, IGNORE etc, specified on a per channel basis like accountcode.
  82
  83 =cut
  84
  85   #ignore the "omit" and "documentation" AMAs??
  86   #AMA = Automated Message Accounting.
  87   #default: Sets the system default.
  88   #omit: Do not record calls.
  89   #billing: Mark the entry for billing
  90   #documentation: Mark the entry for documentation.
  91
  92 =item accountcode - CDR account number to use: account
  93
  94 =item uniqueid - Unique channel identifier (Unitel/RSLCOM Event ID)
  95
  96 =item userfield - CDR user-defined field
  97
  98 =item cdr_type - CDR type - see L<FS::cdr_type> (Usage = 1, S&E = 7, OC&C = 8)
  99
 100 =item charged_party - Service number to be billed
 101
 102 =item upstream_currency - Wholesale currency from upstream
 103
 104 =item upstream_price - Wholesale price from upstream
 105
 106 =item upstream_rateplanid - Upstream rate plan ID
 107
 108 =item rated_price - Rated (or re-rated) price
 109
 110 =item distance - km (need units field?)
 111
 112 =item islocal - Local - 1, Non Local = 0
 113
 114 =item calltypenum - Type of call - see L<FS::cdr_calltype>
 115
 116 =item description - Description (cdr_type 7&8 only) (used for cust_bill_pkg.itemdesc)
 117
 118 =item quantity - Number of items (cdr_type 7&8 only)
 119
 120 =item carrierid - Upstream Carrier ID (see L<FS::cdr_carrier>)
 121
 122 =cut
 123
 124 #Telstra =1, Optus = 2, RSL COM = 3
 125
 126 =item upstream_rateid - Upstream Rate ID
 127
 128 =item svcnum - Link to customer service (see L<FS::cust_svc>)
 129
 130 =item freesidestatus - NULL, done (or something)
 131
 132 =item freesiderewritestatus - NULL, done (or something)
 133
 134 =item cdrbatch
 135
 136 =back
 137
 138 =head1 METHODS
 139
 140 =over 4
 141
 142 =item new HASHREF
 143
 144 Creates a new CDR.  To add the CDR to the database, see L<"insert">.
 145
 146 Note that this stores the hash reference, not a distinct copy of the hash it
 147 points to.  You can ask the object for a copy with the I<hash> method.
 148
 149 =cut
 150
 151 # the new method can be inherited from FS::Record, if a table method is defined
 152
 153 sub table { 'cdr'; }
 154
 155 sub table_info {
 156   {
 157     'fields' => {
 158 #XXX fill in some (more) nice names
 159         #'acctid'                => '',
 160         'calldate'              => 'Call date',
 161         'clid'                  => 'Caller ID',
 162         'src'                   => 'Source',
 163         'dst'                   => 'Destination',
 164         'dcontext'              => 'Dest. context',
 165         'channel'               => 'Channel',
 166         'dstchannel'            => 'Destination channel',
 167         #'lastapp'               => '',
 168         #'lastdata'              => '',
 169         'startdate'             => 'Start date',
 170         'answerdate'            => 'Answer date',
 171         'enddate'               => 'End date',
 172         'duration'              => 'Duration',
 173         'billsec'               => 'Billable seconds',
 174         'disposition'           => 'Disposition',
 175         'amaflags'              => 'AMA flags',
 176         'accountcode'           => 'Account code',
 177         #'uniqueid'              => '',
 178         'userfield'             => 'User field',
 179         #'cdrtypenum'            => '',
 180         'charged_party'         => 'Charged party',
 181         #'upstream_currency'     => '',
 182         'upstream_price'        => 'Upstream price',
 183         #'upstream_rateplanid'   => '',
 184         #'ratedetailnum'         => '',
 185         'rated_price'           => 'Rated price',
 186         #'distance'              => '',
 187         #'islocal'               => '',
 188         #'calltypenum'           => '',
 189         #'description'           => '',
 190         #'quantity'              => '',
 191         'carrierid'             => 'Carrier ID',
 192         #'upstream_rateid'       => '',
 193         'svcnum'                => 'Freeside service',
 194         'freesidestatus'        => 'Freeside status',
 195         'freesiderewritestatus' => 'Freeside rewrite status',
 196         'cdrbatch'              => 'Batch',
 197     },
 198
 199   };
 200
 201 }
 202
 203 =item insert
 204
 205 Adds this record to the database.  If there is an error, returns the error,
 206 otherwise returns false.
 207
 208 =cut
 209
 210 # the insert method can be inherited from FS::Record
 211
 212 =item delete
 213
 214 Delete this record from the database.
 215
 216 =cut
 217
 218 # the delete method can be inherited from FS::Record
 219
 220 =item replace OLD_RECORD
 221
 222 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 223 returns the error, otherwise returns false.
 224
 225 =cut
 226
 227 # the replace method can be inherited from FS::Record
 228
 229 =item check
 230
 231 Checks all fields to make sure this is a valid CDR.  If there is
 232 an error, returns the error, otherwise returns false.  Called by the insert
 233 and replace methods.
 234
 235 Note: Unlike most types of records, we don't want to "reject" a CDR and we want
 236 to process them as quickly as possible, so we allow the database to check most
 237 of the data.
 238
 239 =cut
 240
 241 sub check {
 242   my $self = shift;
 243
 244 # we don't want to "reject" a CDR like other sorts of input...
 245 #  my $error =
 246 #    $self->ut_numbern('acctid')
 247 ##    || $self->ut_('calldate')
 248 #    || $self->ut_text('clid')
 249 #    || $self->ut_text('src')
 250 #    || $self->ut_text('dst')
 251 #    || $self->ut_text('dcontext')
 252 #    || $self->ut_text('channel')
 253 #    || $self->ut_text('dstchannel')
 254 #    || $self->ut_text('lastapp')
 255 #    || $self->ut_text('lastdata')
 256 #    || $self->ut_numbern('startdate')
 257 #    || $self->ut_numbern('answerdate')
 258 #    || $self->ut_numbern('enddate')
 259 #    || $self->ut_number('duration')
 260 #    || $self->ut_number('billsec')
 261 #    || $self->ut_text('disposition')
 262 #    || $self->ut_number('amaflags')
 263 #    || $self->ut_text('accountcode')
 264 #    || $self->ut_text('uniqueid')
 265 #    || $self->ut_text('userfield')
 266 #    || $self->ut_numbern('cdrtypenum')
 267 #    || $self->ut_textn('charged_party')
 268 ##    || $self->ut_n('upstream_currency')
 269 ##    || $self->ut_n('upstream_price')
 270 #    || $self->ut_numbern('upstream_rateplanid')
 271 ##    || $self->ut_n('distance')
 272 #    || $self->ut_numbern('islocal')
 273 #    || $self->ut_numbern('calltypenum')
 274 #    || $self->ut_textn('description')
 275 #    || $self->ut_numbern('quantity')
 276 #    || $self->ut_numbern('carrierid')
 277 #    || $self->ut_numbern('upstream_rateid')
 278 #    || $self->ut_numbern('svcnum')
 279 #    || $self->ut_textn('freesidestatus')
 280 #    || $self->ut_textn('freesiderewritestatus')
 281 #  ;
 282 #  return $error if $error;
 283
 284   $self->calldate( $self->startdate_sql )
 285     if !$self->calldate && $self->startdate;
 286
 287   #was just for $format eq 'taqua' but can't see the harm... add something to
 288   #disable if it becomes a problem
 289   if ( $self->duration eq '' && $self->enddate && $self->startdate ) {
 290     $self->duration( $self->enddate - $self->startdate  );
 291   }
 292   if ( $self->billsec eq '' && $self->enddate && $self->answerdate ) {
 293     $self->billsec(  $self->enddate - $self->answerdate );
 294   }
 295
 296   $self->set_charged_party;
 297
 298   #check the foreign keys even?
 299   #do we want to outright *reject* the CDR?
 300   my $error =
 301        $self->ut_numbern('acctid')
 302
 303   #add a config option to turn these back on if someone needs 'em
 304   #
 305   #  #Usage = 1, S&E = 7, OC&C = 8
 306   #  || $self->ut_foreign_keyn('cdrtypenum',  'cdr_type',     'cdrtypenum' )
 307   #
 308   #  #the big list in appendix 2
 309   #  || $self->ut_foreign_keyn('calltypenum', 'cdr_calltype', 'calltypenum' )
 310   #
 311   #  # Telstra =1, Optus = 2, RSL COM = 3
 312   #  || $self->ut_foreign_keyn('carrierid', 'cdr_carrier', 'carrierid' )
 313   ;
 314   return $error if $error;
 315
 316   $self->SUPER::check;
 317 }
 318
 319 =item is_tollfree
 320
 321   Returns true when the cdr represents a toll free number and false otherwise.
 322
 323 =cut
 324
 325 sub is_tollfree {
 326   my $self = shift;
 327   ( $self->dst =~ /^(\+?1)?8(8|([02-7])\3)/ ) ? 1 : 0;
 328 }
 329
 330 =item set_charged_party
 331
 332 If the charged_party field is already set, does nothing.  Otherwise:
 333
 334 If the cdr-charged_party-accountcode config option is enabled, sets the
 335 charged_party to the accountcode.
 336
 337 Otherwise sets the charged_party normally: to the src field in most cases,
 338 or to the dst field if it is a toll free number.
 339
 340 =cut
 341
 342 sub set_charged_party {
 343   my $self = shift;
 344
 345   my $conf = new FS::Conf;
 346
 347   unless ( $self->charged_party ) {
 348
 349     if ( $conf->exists('cdr-charged_party-accountcode') && $self->accountcode ){
 350
 351       my $charged_party = $self->accountcode;
 352       $charged_party =~ s/^0+//
 353         if $conf->exists('cdr-charged_party-accountcode-trim_leading_0s');
 354       $self->charged_party( $charged_party );
 355
 356     } else {
 357
 358       if ( $self->is_tollfree ) {
 359         $self->charged_party($self->dst);
 360       } else {
 361         $self->charged_party($self->src);
 362       }
 363
 364     }
 365
 366   }
 367
 368 #  my $prefix = $conf->config('cdr-charged_party-truncate_prefix');
 369 #  my $prefix_len = length($prefix);
 370 #  my $trunc_len = $conf->config('cdr-charged_party-truncate_length');
 371 #
 372 #  $self->charged_party( substr($self->charged_party, 0, $trunc_len) )
 373 #    if $prefix_len && $trunc_len
 374 #    && substr($self->charged_party, 0, $prefix_len) eq $prefix;
 375
 376 }
 377
 378 =item set_status_and_rated_price STATUS [ RATED_PRICE [ SVCNUM ] ]
 379
 380 Sets the status to the provided string.  If there is an error, returns the
 381 error, otherwise returns false.
 382
 383 =cut
 384
 385 sub set_status_and_rated_price {
 386   my($self, $status, $rated_price, $svcnum) = @_;
 387   $self->freesidestatus($status);
 388   $self->rated_price($rated_price);
 389   $self->svcnum($svcnum) if $svcnum;
 390   $self->replace();
 391 }
 392
 393 =item calldate_unix
 394
 395 Parses the calldate in SQL string format and returns a UNIX timestamp.
 396
 397 =cut
 398
 399 sub calldate_unix {
 400   str2time(shift->calldate);
 401 }
 402
 403 =item startdate_sql
 404
 405 Parses the startdate in UNIX timestamp format and returns a string in SQL
 406 format.
 407
 408 =cut
 409
 410 sub startdate_sql {
 411   my($sec,$min,$hour,$mday,$mon,$year) = localtime(shift->startdate);
 412   $mon++;
 413   $year += 1900;
 414   "$year-$mon-$mday $hour:$min:$sec";
 415 }
 416
 417 =item cdr_carrier
 418
 419 Returns the FS::cdr_carrier object associated with this CDR, or false if no
 420 carrierid is defined.
 421
 422 =cut
 423
 424 my %carrier_cache = ();
 425
 426 sub cdr_carrier {
 427   my $self = shift;
 428   return '' unless $self->carrierid;
 429   $carrier_cache{$self->carrierid} ||=
 430     qsearchs('cdr_carrier', { 'carrierid' => $self->carrierid } );
 431 }
 432
 433 =item carriername
 434
 435 Returns the carrier name (see L<FS::cdr_carrier>), or the empty string if
 436 no FS::cdr_carrier object is assocated with this CDR.
 437
 438 =cut
 439
 440 sub carriername {
 441   my $self = shift;
 442   my $cdr_carrier = $self->cdr_carrier;
 443   $cdr_carrier ? $cdr_carrier->carriername : '';
 444 }
 445
 446 =item cdr_calltype
 447
 448 Returns the FS::cdr_calltype object associated with this CDR, or false if no
 449 calltypenum is defined.
 450
 451 =cut
 452
 453 my %calltype_cache = ();
 454
 455 sub cdr_calltype {
 456   my $self = shift;
 457   return '' unless $self->calltypenum;
 458   $calltype_cache{$self->calltypenum} ||=
 459     qsearchs('cdr_calltype', { 'calltypenum' => $self->calltypenum } );
 460 }
 461
 462 =item calltypename
 463
 464 Returns the call type name (see L<FS::cdr_calltype>), or the empty string if
 465 no FS::cdr_calltype object is assocated with this CDR.
 466
 467 =cut
 468
 469 sub calltypename {
 470   my $self = shift;
 471   my $cdr_calltype = $self->cdr_calltype;
 472   $cdr_calltype ? $cdr_calltype->calltypename : '';
 473 }
 474
 475 =item downstream_csv [ OPTION => VALUE, ... ]
 476
 477 =cut
 478
 479 my %export_names = (
 480   'simple'  => {
 481     'name'           => 'Simple',
 482     'invoice_header' => "Date,Time,Name,Destination,Duration,Price",
 483   },
 484   'simple2' => {
 485     'name'           => 'Simple with source',
 486     'invoice_header' => "Date,Time,Called From,Destination,Duration,Price",
 487                        #"Date,Time,Name,Called From,Destination,Duration,Price",
 488   },
 489   'default' => {
 490     'name'           => 'Default',
 491     'invoice_header' => 'Date,Time,Number,Destination,Duration,Price',
 492   },
 493   'source_default' => {
 494     'name'           => 'Default with source',
 495     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 496   },
 497   'accountcode_default' => {
 498     'name'           => 'Default plus accountcode',
 499     'invoice_header' => 'Date,Time,Account,Number,Destination,Duration,Price',
 500   },
 501 );
 502
 503 my $duration_sub = sub {
 504   my($cdr, %opt) = @_;
 505   if ( $opt{minutes} ) {
 506     $opt{minutes}. ( $opt{granularity} ? 'm' : ' call' );
 507   } else {
 508     sprintf('%.2fm', $cdr->billsec / 60 );
 509   }
 510 };
 511
 512 my %export_formats = (
 513   'simple' => [
 514     sub { time2str('%D', shift->calldate_unix ) },   #DATE
 515     sub { time2str('%r', shift->calldate_unix ) },   #TIME
 516     'userfield',                                     #USER
 517     'dst',                                           #NUMBER_DIALED
 518     $duration_sub,                                   #DURATION
 519     #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 520     sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 521   ],
 522   'simple2' => [
 523     sub { time2str('%D', shift->calldate_unix ) },   #DATE
 524     sub { time2str('%r', shift->calldate_unix ) },   #TIME
 525     #'userfield',                                     #USER
 526     'src',                                           #called from
 527     'dst',                                           #NUMBER_DIALED
 528     $duration_sub,                                   #DURATION
 529     #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 530     sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 531   ],
 532   'default' => [
 533
 534     #DATE
 535     sub { time2str('%D', shift->calldate_unix ) },
 536           # #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 537
 538     #TIME
 539     sub { time2str('%r', shift->calldate_unix ) },
 540           # time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 541
 542     #DEST ("Number")
 543     sub { my($cdr, %opt) = @_; $opt{pretty_dst} || $cdr->dst; },
 544
 545     #REGIONNAME ("Destination")
 546     sub { my($cdr, %opt) = @_; $opt{dst_regionname}; },
 547
 548     #DURATION
 549     $duration_sub,
 550
 551     #PRICE
 552     sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; },
 553
 554   ],
 555 );
 556 $export_formats{'source_default'} = [ 'src', @{ $export_formats{'default'} }, ];
 557 $export_formats{'accountcode_default'} =
 558   [ @{ $export_formats{'default'} }[0,1],
 559     'accountcode',
 560     @{ $export_formats{'default'} }[2..5],
 561   ];
 562
 563 sub downstream_csv {
 564   my( $self, %opt ) = @_;
 565
 566   my $format = $opt{'format'};
 567   return "Unknown format $format" unless exists $export_formats{$format};
 568
 569   #my $conf = new FS::Conf;
 570   #$opt{'money_char'} ||= $conf->config('money_char') || '$';
 571   $opt{'money_char'} ||= FS::Conf->new->config('money_char') || '$';
 572
 573   eval "use Text::CSV_XS;";
 574   die $@ if $@;
 575   my $csv = new Text::CSV_XS;
 576
 577   my @columns =
 578     map {
 579           ref($_) ? &{$_}($self, %opt) : $self->$_();
 580         }
 581     @{ $export_formats{$format} };
 582
 583   my $status = $csv->combine(@columns);
 584   die "FS::CDR: error combining ". $csv->error_input(). "into downstream CSV"
 585     unless $status;
 586
 587   $csv->string;
 588
 589 }
 590
 591 =back
 592
 593 =head1 CLASS METHODS
 594
 595 =over 4
 596
 597 =item invoice_formats
 598
 599 Returns an ordered list of key value pairs containing invoice format names
 600 as keys (for use with part_pkg::voip_cdr) and "pretty" format names as values.
 601
 602 =cut
 603
 604 sub invoice_formats {
 605   map { ($_ => $export_names{$_}->{'name'}) }
 606     grep { $export_names{$_}->{'invoice_header'} }
 607     keys %export_names;
 608 }
 609
 610 =item invoice_header FORMAT
 611
 612 Returns a scalar containing the CSV column header for invoice format FORMAT.
 613
 614 =cut
 615
 616 sub invoice_header {
 617   my $format = shift;
 618   $export_names{$format}->{'invoice_header'};
 619 }
 620
 621 =item import_formats
 622
 623 Returns an ordered list of key value pairs containing import format names
 624 as keys (for use with batch_import) and "pretty" format names as values.
 625
 626 =cut
 627
 628 #false laziness w/part_pkg & part_export
 629
 630 my %cdr_info;
 631 foreach my $INC ( @INC ) {
 632   warn "globbing $INC/FS/cdr/*.pm\n" if $DEBUG;
 633   foreach my $file ( glob("$INC/FS/cdr/*.pm") ) {
 634     warn "attempting to load CDR format info from $file\n" if $DEBUG;
 635     $file =~ /\/(\w+)\.pm$/ or do {
 636       warn "unrecognized file in $INC/FS/cdr/: $file\n";
 637       next;
 638     };
 639     my $mod = $1;
 640     my $info = eval "use FS::cdr::$mod; ".
 641                     "\\%FS::cdr::$mod\::info;";
 642     if ( $@ ) {
 643       die "error using FS::cdr::$mod (skipping): $@\n" if $@;
 644       next;
 645     }
 646     unless ( keys %$info ) {
 647       warn "no %info hash found in FS::cdr::$mod, skipping\n";
 648       next;
 649     }
 650     warn "got CDR format info from FS::cdr::$mod: $info\n" if $DEBUG;
 651     if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 652       warn "skipping disabled CDR format FS::cdr::$mod" if $DEBUG;
 653       next;
 654     }
 655     $cdr_info{$mod} = $info;
 656   }
 657 }
 658
 659 tie my %import_formats, 'Tie::IxHash',
 660   map  { $_ => $cdr_info{$_}->{'name'} }
 661   sort { $cdr_info{$a}->{'weight'} <=> $cdr_info{$b}->{'weight'} }
 662   grep { exists($cdr_info{$_}->{'import_fields'}) }
 663   keys %cdr_info;
 664
 665 sub import_formats {
 666   %import_formats;
 667 }
 668
 669 sub _cdr_min_parser_maker {
 670   my $field = shift;
 671   my @fields = ref($field) ? @$field : ($field);
 672   @fields = qw( billsec duration ) unless scalar(@fields) && $fields[0];
 673   return sub {
 674     my( $cdr, $min ) = @_;
 675     my $sec = eval { _cdr_min_parse($min) };
 676     die "error parsing seconds for @fields from $min minutes: $@\n" if $@;
 677     $cdr->$_($sec) foreach @fields;
 678   };
 679 }
 680
 681 sub _cdr_min_parse {
 682   my $min = shift;
 683   sprintf('%.0f', $min * 60 );
 684 }
 685
 686 sub _cdr_date_parser_maker {
 687   my $field = shift;
 688   my %options = @_;
 689   my @fields = ref($field) ? @$field : ($field);
 690   return sub {
 691     my( $cdr, $datestring ) = @_;
 692     my $unixdate = eval { _cdr_date_parse($datestring, %options) };
 693     die "error parsing date for @fields from $datestring: $@\n" if $@;
 694     $cdr->$_($unixdate) foreach @fields;
 695   };
 696 }
 697
 698 sub _cdr_date_parse {
 699   my $date = shift;
 700   my %options = @_;
 701
 702   return '' unless length($date); #that's okay, it becomes NULL
 703   return '' if $date eq 'NA'; #sansay
 704
 705   if ( $date =~ /^([a-z]{3})\s+([a-z]{3})\s+(\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s+(\d{4})$/i && $7 > 1970 ) {
 706     my $time = str2time($date);
 707     return $time if $time > 100000; #just in case
 708   }
 709
 710   my($year, $mon, $day, $hour, $min, $sec);
 711
 712   #$date =~ /^\s*(\d{4})[\-\/]\(\d{1,2})[\-\/](\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s*$/
 713   #taqua  #2007-10-31 08:57:24.113000000
 714
 715   if ( $date =~ /^\s*(\d{4})\D(\d{1,2})\D(\d{1,2})\D+(\d{1,2})\D(\d{1,2})\D(\d{1,2})(\D|$)/ ) {
 716     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 717   } elsif ( $date  =~ /^\s*(\d{1,2})\D(\d{1,2})\D(\d{4})\s+(\d{1,2})\D(\d{1,2})\D(\d{1,2})(\D|$)/ ) {
 718     ($mon, $day, $year, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 719   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d+\.\d+)(\D|$)/ ) {
 720     # broadsoft: 20081223201938.314
 721     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6);
 722   } else {
 723      die "unparsable date: $date"; #maybe we shouldn't die...
 724   }
 725
 726   return '' if ( $year == 1900 || $year == 1970 ) && $mon == 1 && $day == 1
 727             && $hour == 0 && $min == 0 && $sec == 0;
 728
 729   if ($options{gmt}) {
 730     timegm($sec, $min, $hour, $day, $mon-1, $year);
 731   } else {
 732     timelocal($sec, $min, $hour, $day, $mon-1, $year);
 733   }
 734 }
 735
 736 =item batch_import HASHREF
 737
 738 Imports CDR records.  Available options are:
 739
 740 =over 4
 741
 742 =item file
 743
 744 Filename
 745
 746 =item format
 747
 748 =item params
 749
 750 Hash reference of preset fields, typically cdrbatch
 751
 752 =item empty_ok
 753
 754 Set true to prevent throwing an error on empty imports
 755
 756 =back
 757
 758 =cut
 759
 760 my %import_options = (
 761   'table'   => 'cdr',
 762
 763   'formats' => { map { $_ => $cdr_info{$_}->{'import_fields'}; }
 764                      keys %cdr_info
 765                },
 766
 767                           #drop the || 'csv' to allow auto xls for csv types?
 768   'format_types' => { map { $_ => ( lc($cdr_info{$_}->{'type'}) || 'csv' ); }
 769                           keys %cdr_info
 770                     },
 771
 772   'format_headers' => { map { $_ => ( $cdr_info{$_}->{'header'} || 0 ); }
 773                             keys %cdr_info
 774                       },
 775
 776   'format_sep_chars' => { map { $_ => $cdr_info{$_}->{'sep_char'}; }
 777                               keys %cdr_info
 778                         },
 779
 780   'format_fixedlength_formats' =>
 781     { map { $_ => $cdr_info{$_}->{'fixedlength_format'}; }
 782           keys %cdr_info
 783     },
 784 );
 785
 786 sub _import_options {
 787   \%import_options;
 788 }
 789
 790 sub batch_import {
 791   my $opt = shift;
 792
 793   my $iopt = _import_options;
 794   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
 795
 796   FS::Record::batch_import( $opt );
 797
 798 }
 799
 800 =item process_batch_import
 801
 802 =cut
 803
 804 sub process_batch_import {
 805   my $job = shift;
 806
 807   my $opt = _import_options;
 808   $opt->{'params'} = [ 'format', 'cdrbatch' ];
 809
 810   FS::Record::process_batch_import( $job, $opt, @_ );
 811
 812 }
 813 #  if ( $format eq 'simple' ) { #should be a callback or opt in FS::cdr::simple
 814 #    @columns = map { s/^ +//; $_; } @columns;
 815 #  }
 816
 817 =back
 818
 819 =head1 BUGS
 820
 821 =head1 SEE ALSO
 822
 823 L<FS::Record>, schema.html from the base documentation.
 824
 825 =cut
 826
 827 1;
 828