FS/FS/cdr.pm

   1 package FS::cdr;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG $me );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use Date::Parse;
   8 use Date::Format;
   9 use Time::Local;
  10 use FS::UID qw( dbh );
  11 use FS::Conf;
  12 use FS::Record qw( qsearch qsearchs );
  13 use FS::cdr_type;
  14 use FS::cdr_calltype;
  15 use FS::cdr_carrier;
  16 use FS::cdr_batch;
  17 use FS::cdr_termination;
  18
  19 @ISA = qw(FS::Record);
  20 @EXPORT_OK = qw( _cdr_date_parser_maker _cdr_min_parser_maker );
  21
  22 $DEBUG = 0;
  23 $me = '[FS::cdr]';
  24
  25 =head1 NAME
  26
  27 FS::cdr - Object methods for cdr records
  28
  29 =head1 SYNOPSIS
  30
  31   use FS::cdr;
  32
  33   $record = new FS::cdr \%hash;
  34   $record = new FS::cdr { 'column' => 'value' };
  35
  36   $error = $record->insert;
  37
  38   $error = $new_record->replace($old_record);
  39
  40   $error = $record->delete;
  41
  42   $error = $record->check;
  43
  44 =head1 DESCRIPTION
  45
  46 An FS::cdr object represents an Call Data Record, typically from a telephony
  47 system or provider of some sort.  FS::cdr inherits from FS::Record.  The
  48 following fields are currently supported:
  49
  50 =over 4
  51
  52 =item acctid - primary key
  53
  54 =item calldate - Call timestamp (SQL timestamp)
  55
  56 =item clid - Caller*ID with text
  57
  58 =item src - Caller*ID number / Source number
  59
  60 =item dst - Destination extension
  61
  62 =item dcontext - Destination context
  63
  64 =item channel - Channel used
  65
  66 =item dstchannel - Destination channel if appropriate
  67
  68 =item lastapp - Last application if appropriate
  69
  70 =item lastdata - Last application data
  71
  72 =item startdate - Start of call (UNIX-style integer timestamp)
  73
  74 =item answerdate - Answer time of call (UNIX-style integer timestamp)
  75
  76 =item enddate - End time of call (UNIX-style integer timestamp)
  77
  78 =item duration - Total time in system, in seconds
  79
  80 =item billsec - Total time call is up, in seconds
  81
  82 =item disposition - What happened to the call: ANSWERED, NO ANSWER, BUSY
  83
  84 =item amaflags - What flags to use: BILL, IGNORE etc, specified on a per channel basis like accountcode.
  85
  86 =cut
  87
  88   #ignore the "omit" and "documentation" AMAs??
  89   #AMA = Automated Message Accounting.
  90   #default: Sets the system default.
  91   #omit: Do not record calls.
  92   #billing: Mark the entry for billing
  93   #documentation: Mark the entry for documentation.
  94
  95 =item accountcode - CDR account number to use: account
  96
  97 =item uniqueid - Unique channel identifier (Unitel/RSLCOM Event ID)
  98
  99 =item userfield - CDR user-defined field
 100
 101 =item cdr_type - CDR type - see L<FS::cdr_type> (Usage = 1, S&E = 7, OC&C = 8)
 102
 103 =item charged_party - Service number to be billed
 104
 105 =item upstream_currency - Wholesale currency from upstream
 106
 107 =item upstream_price - Wholesale price from upstream
 108
 109 =item upstream_rateplanid - Upstream rate plan ID
 110
 111 =item rated_price - Rated (or re-rated) price
 112
 113 =item distance - km (need units field?)
 114
 115 =item islocal - Local - 1, Non Local = 0
 116
 117 =item calltypenum - Type of call - see L<FS::cdr_calltype>
 118
 119 =item description - Description (cdr_type 7&8 only) (used for cust_bill_pkg.itemdesc)
 120
 121 =item quantity - Number of items (cdr_type 7&8 only)
 122
 123 =item carrierid - Upstream Carrier ID (see L<FS::cdr_carrier>)
 124
 125 =cut
 126
 127 #Telstra =1, Optus = 2, RSL COM = 3
 128
 129 =item upstream_rateid - Upstream Rate ID
 130
 131 =item svcnum - Link to customer service (see L<FS::cust_svc>)
 132
 133 =item freesidestatus - NULL, processing-tiered, done
 134
 135 =item freesiderewritestatus - NULL, done, skipped
 136
 137 =item cdrbatch
 138
 139 =back
 140
 141 =head1 METHODS
 142
 143 =over 4
 144
 145 =item new HASHREF
 146
 147 Creates a new CDR.  To add the CDR to the database, see L<"insert">.
 148
 149 Note that this stores the hash reference, not a distinct copy of the hash it
 150 points to.  You can ask the object for a copy with the I<hash> method.
 151
 152 =cut
 153
 154 # the new method can be inherited from FS::Record, if a table method is defined
 155
 156 sub table { 'cdr'; }
 157
 158 sub table_info {
 159   {
 160     'fields' => {
 161 #XXX fill in some (more) nice names
 162         #'acctid'                => '',
 163         'calldate'              => 'Call date',
 164         'clid'                  => 'Caller ID',
 165         'src'                   => 'Source',
 166         'dst'                   => 'Destination',
 167         'dcontext'              => 'Dest. context',
 168         'channel'               => 'Channel',
 169         'dstchannel'            => 'Destination channel',
 170         #'lastapp'               => '',
 171         #'lastdata'              => '',
 172         'startdate'             => 'Start date',
 173         'answerdate'            => 'Answer date',
 174         'enddate'               => 'End date',
 175         'duration'              => 'Duration',
 176         'billsec'               => 'Billable seconds',
 177         'disposition'           => 'Disposition',
 178         'amaflags'              => 'AMA flags',
 179         'accountcode'           => 'Account code',
 180         #'uniqueid'              => '',
 181         'userfield'             => 'User field',
 182         #'cdrtypenum'            => '',
 183         'charged_party'         => 'Charged party',
 184         #'upstream_currency'     => '',
 185         'upstream_price'        => 'Upstream price',
 186         #'upstream_rateplanid'   => '',
 187         #'ratedetailnum'         => '',
 188         'rated_price'           => 'Rated price',
 189         #'distance'              => '',
 190         #'islocal'               => '',
 191         #'calltypenum'           => '',
 192         #'description'           => '',
 193         #'quantity'              => '',
 194         'carrierid'             => 'Carrier ID',
 195         #'upstream_rateid'       => '',
 196         'svcnum'                => 'Freeside service',
 197         'freesidestatus'        => 'Freeside status',
 198         'freesiderewritestatus' => 'Freeside rewrite status',
 199         'cdrbatch'              => 'Legacy batch',
 200         'cdrbatchnum'           => 'Batch',
 201     },
 202
 203   };
 204
 205 }
 206
 207 =item insert
 208
 209 Adds this record to the database.  If there is an error, returns the error,
 210 otherwise returns false.
 211
 212 =cut
 213
 214 # the insert method can be inherited from FS::Record
 215
 216 =item delete
 217
 218 Delete this record from the database.
 219
 220 =cut
 221
 222 # the delete method can be inherited from FS::Record
 223
 224 =item replace OLD_RECORD
 225
 226 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 227 returns the error, otherwise returns false.
 228
 229 =cut
 230
 231 # the replace method can be inherited from FS::Record
 232
 233 =item check
 234
 235 Checks all fields to make sure this is a valid CDR.  If there is
 236 an error, returns the error, otherwise returns false.  Called by the insert
 237 and replace methods.
 238
 239 Note: Unlike most types of records, we don't want to "reject" a CDR and we want
 240 to process them as quickly as possible, so we allow the database to check most
 241 of the data.
 242
 243 =cut
 244
 245 sub check {
 246   my $self = shift;
 247
 248 # we don't want to "reject" a CDR like other sorts of input...
 249 #  my $error =
 250 #    $self->ut_numbern('acctid')
 251 ##    || $self->ut_('calldate')
 252 #    || $self->ut_text('clid')
 253 #    || $self->ut_text('src')
 254 #    || $self->ut_text('dst')
 255 #    || $self->ut_text('dcontext')
 256 #    || $self->ut_text('channel')
 257 #    || $self->ut_text('dstchannel')
 258 #    || $self->ut_text('lastapp')
 259 #    || $self->ut_text('lastdata')
 260 #    || $self->ut_numbern('startdate')
 261 #    || $self->ut_numbern('answerdate')
 262 #    || $self->ut_numbern('enddate')
 263 #    || $self->ut_number('duration')
 264 #    || $self->ut_number('billsec')
 265 #    || $self->ut_text('disposition')
 266 #    || $self->ut_number('amaflags')
 267 #    || $self->ut_text('accountcode')
 268 #    || $self->ut_text('uniqueid')
 269 #    || $self->ut_text('userfield')
 270 #    || $self->ut_numbern('cdrtypenum')
 271 #    || $self->ut_textn('charged_party')
 272 ##    || $self->ut_n('upstream_currency')
 273 ##    || $self->ut_n('upstream_price')
 274 #    || $self->ut_numbern('upstream_rateplanid')
 275 ##    || $self->ut_n('distance')
 276 #    || $self->ut_numbern('islocal')
 277 #    || $self->ut_numbern('calltypenum')
 278 #    || $self->ut_textn('description')
 279 #    || $self->ut_numbern('quantity')
 280 #    || $self->ut_numbern('carrierid')
 281 #    || $self->ut_numbern('upstream_rateid')
 282 #    || $self->ut_numbern('svcnum')
 283 #    || $self->ut_textn('freesidestatus')
 284 #    || $self->ut_textn('freesiderewritestatus')
 285 #  ;
 286 #  return $error if $error;
 287
 288   for my $f ( grep { $self->$_ =~ /\D/ } qw(startdate answerdate enddate)){
 289     $self->$f( str2time($self->$f) );
 290   }
 291
 292   $self->calldate( $self->startdate_sql )
 293     if !$self->calldate && $self->startdate;
 294
 295   #was just for $format eq 'taqua' but can't see the harm... add something to
 296   #disable if it becomes a problem
 297   if ( $self->duration eq '' && $self->enddate && $self->startdate ) {
 298     $self->duration( $self->enddate - $self->startdate  );
 299   }
 300   if ( $self->billsec eq '' && $self->enddate && $self->answerdate ) {
 301     $self->billsec(  $self->enddate - $self->answerdate );
 302   }
 303
 304   $self->set_charged_party;
 305
 306   #check the foreign keys even?
 307   #do we want to outright *reject* the CDR?
 308   my $error =
 309        $self->ut_numbern('acctid')
 310
 311   #add a config option to turn these back on if someone needs 'em
 312   #
 313   #  #Usage = 1, S&E = 7, OC&C = 8
 314   #  || $self->ut_foreign_keyn('cdrtypenum',  'cdr_type',     'cdrtypenum' )
 315   #
 316   #  #the big list in appendix 2
 317   #  || $self->ut_foreign_keyn('calltypenum', 'cdr_calltype', 'calltypenum' )
 318   #
 319   #  # Telstra =1, Optus = 2, RSL COM = 3
 320   #  || $self->ut_foreign_keyn('carrierid', 'cdr_carrier', 'carrierid' )
 321   ;
 322   return $error if $error;
 323
 324   $self->SUPER::check;
 325 }
 326
 327 =item is_tollfree [ COLUMN ]
 328
 329 Returns true when the cdr represents a toll free number and false otherwise.
 330
 331 By default, inspects the dst field, but an optional column name can be passed
 332 to inspect other field.
 333
 334 =cut
 335
 336 sub is_tollfree {
 337   my $self = shift;
 338   my $field = scalar(@_) ? shift : 'dst';
 339   ( $self->$field() =~ /^(\+?1)?8(8|([02-7])\3)/ ) ? 1 : 0;
 340 }
 341
 342 =item set_charged_party
 343
 344 If the charged_party field is already set, does nothing.  Otherwise:
 345
 346 If the cdr-charged_party-accountcode config option is enabled, sets the
 347 charged_party to the accountcode.
 348
 349 Otherwise sets the charged_party normally: to the src field in most cases,
 350 or to the dst field if it is a toll free number.
 351
 352 =cut
 353
 354 sub set_charged_party {
 355   my $self = shift;
 356
 357   my $conf = new FS::Conf;
 358
 359   unless ( $self->charged_party ) {
 360
 361     if ( $conf->exists('cdr-charged_party-accountcode') && $self->accountcode ){
 362
 363       my $charged_party = $self->accountcode;
 364       $charged_party =~ s/^0+//
 365         if $conf->exists('cdr-charged_party-accountcode-trim_leading_0s');
 366       $self->charged_party( $charged_party );
 367
 368     } elsif ( $conf->exists('cdr-charged_party-field') ) {
 369
 370       my $field = $conf->config('cdr-charged_party-field');
 371       $self->charged_party( $self->$field() );
 372
 373     } else {
 374
 375       if ( $self->is_tollfree ) {
 376         $self->charged_party($self->dst);
 377       } else {
 378         $self->charged_party($self->src);
 379       }
 380
 381     }
 382
 383   }
 384
 385 #  my $prefix = $conf->config('cdr-charged_party-truncate_prefix');
 386 #  my $prefix_len = length($prefix);
 387 #  my $trunc_len = $conf->config('cdr-charged_party-truncate_length');
 388 #
 389 #  $self->charged_party( substr($self->charged_party, 0, $trunc_len) )
 390 #    if $prefix_len && $trunc_len
 391 #    && substr($self->charged_party, 0, $prefix_len) eq $prefix;
 392
 393 }
 394
 395 =item set_status_and_rated_price STATUS [ RATED_PRICE [ SVCNUM ] ]
 396
 397 Sets the status to the provided string.  If there is an error, returns the
 398 error, otherwise returns false.
 399
 400 =cut
 401
 402 sub set_status_and_rated_price {
 403   my($self, $status, $rated_price, $svcnum, %opt) = @_;
 404
 405   if ($opt{'inbound'}) {
 406
 407     my $term = $self->cdr_termination( 1 ); #1: inbound
 408     my $error;
 409     if ( $term ) {
 410       warn "replacing existing cdr status (".$self->acctid.")\n" if $term;
 411       $error = $term->delete;
 412       return $error if $error;
 413     }
 414     $term = FS::cdr_termination->new({
 415         acctid      => $self->acctid,
 416         termpart    => 1,
 417         rated_price => $rated_price,
 418         status      => $status,
 419     });
 420     $term->rated_seconds($opt{rated_seconds}) if exists($opt{rated_seconds});
 421     $term->rated_minutes($opt{rated_minutes}) if exists($opt{rated_minutes});
 422     $term->svcnum($svcnum) if $svcnum;
 423     return $term->insert;
 424
 425   } else {
 426
 427     $self->freesidestatus($status);
 428     $self->rated_price($rated_price);
 429     $self->rated_seconds($opt{rated_seconds}) if exists($opt{rated_seconds});
 430     $self->rated_minutes($opt{rated_minutes}) if exists($opt{rated_minutes});
 431     $self->svcnum($svcnum) if $svcnum;
 432     return $self->replace();
 433
 434   }
 435 }
 436
 437 =item cdr_termination [ TERMPART ]
 438
 439 =cut
 440
 441 sub cdr_termination {
 442   my $self = shift;
 443
 444   if ( scalar(@_) && $_[0] ) {
 445     my $termpart = shift;
 446
 447     qsearchs('cdr_termination', { acctid   => $self->acctid,
 448                                   termpart => $termpart,
 449                                 }
 450             );
 451
 452   } else {
 453
 454     qsearch('cdr_termination', { acctid => $self->acctid, } );
 455
 456   }
 457
 458 }
 459
 460 =item calldate_unix
 461
 462 Parses the calldate in SQL string format and returns a UNIX timestamp.
 463
 464 =cut
 465
 466 sub calldate_unix {
 467   str2time(shift->calldate);
 468 }
 469
 470 =item startdate_sql
 471
 472 Parses the startdate in UNIX timestamp format and returns a string in SQL
 473 format.
 474
 475 =cut
 476
 477 sub startdate_sql {
 478   my($sec,$min,$hour,$mday,$mon,$year) = localtime(shift->startdate);
 479   $mon++;
 480   $year += 1900;
 481   "$year-$mon-$mday $hour:$min:$sec";
 482 }
 483
 484 =item cdr_carrier
 485
 486 Returns the FS::cdr_carrier object associated with this CDR, or false if no
 487 carrierid is defined.
 488
 489 =cut
 490
 491 my %carrier_cache = ();
 492
 493 sub cdr_carrier {
 494   my $self = shift;
 495   return '' unless $self->carrierid;
 496   $carrier_cache{$self->carrierid} ||=
 497     qsearchs('cdr_carrier', { 'carrierid' => $self->carrierid } );
 498 }
 499
 500 =item carriername
 501
 502 Returns the carrier name (see L<FS::cdr_carrier>), or the empty string if
 503 no FS::cdr_carrier object is assocated with this CDR.
 504
 505 =cut
 506
 507 sub carriername {
 508   my $self = shift;
 509   my $cdr_carrier = $self->cdr_carrier;
 510   $cdr_carrier ? $cdr_carrier->carriername : '';
 511 }
 512
 513 =item cdr_calltype
 514
 515 Returns the FS::cdr_calltype object associated with this CDR, or false if no
 516 calltypenum is defined.
 517
 518 =cut
 519
 520 my %calltype_cache = ();
 521
 522 sub cdr_calltype {
 523   my $self = shift;
 524   return '' unless $self->calltypenum;
 525   $calltype_cache{$self->calltypenum} ||=
 526     qsearchs('cdr_calltype', { 'calltypenum' => $self->calltypenum } );
 527 }
 528
 529 =item calltypename
 530
 531 Returns the call type name (see L<FS::cdr_calltype>), or the empty string if
 532 no FS::cdr_calltype object is assocated with this CDR.
 533
 534 =cut
 535
 536 sub calltypename {
 537   my $self = shift;
 538   my $cdr_calltype = $self->cdr_calltype;
 539   $cdr_calltype ? $cdr_calltype->calltypename : '';
 540 }
 541
 542 =item downstream_csv [ OPTION => VALUE, ... ]
 543
 544 =cut
 545
 546 my %export_names = (
 547   'simple'  => {
 548     'name'           => 'Simple',
 549     'invoice_header' => "Date,Time,Name,Destination,Duration,Price",
 550   },
 551   'simple2' => {
 552     'name'           => 'Simple with source',
 553     'invoice_header' => "Date,Time,Called From,Destination,Duration,Price",
 554                        #"Date,Time,Name,Called From,Destination,Duration,Price",
 555   },
 556   'basic' => {
 557     'name'           => 'Basic',
 558     'invoice_header' => "Date/Time,Called Number,Min/Sec,Price",
 559   },
 560   'default' => {
 561     'name'           => 'Default',
 562     'invoice_header' => 'Date,Time,Number,Destination,Duration,Price',
 563   },
 564   'source_default' => {
 565     'name'           => 'Default with source',
 566     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 567   },
 568   'accountcode_default' => {
 569     'name'           => 'Default plus accountcode',
 570     'invoice_header' => 'Date,Time,Account,Number,Destination,Duration,Price',
 571   },
 572   'description_default' => {
 573     'name'           => 'Default with description field as destination',
 574     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 575   },
 576   'sum_duration' => {
 577     'name'           => 'Summary (one line per service, with duration)',
 578     'invoice_header' => 'Caller,Calls,Minutes,Price',
 579   },
 580   'sum_count' => {
 581     'name'           => 'Summary (one line per service, with count)',
 582     'invoice_header' => 'Caller,Messages,Price',
 583   },
 584 );
 585
 586 my %export_formats = ();
 587 sub export_formats {
 588   #my $self = shift;
 589
 590   return %export_formats if keys %export_formats;
 591
 592   my $conf = new FS::Conf;
 593   my $date_format = $conf->config('date_format') || '%m/%d/%Y';
 594
 595   # call duration in the largest units that accurately reflect the  granularity
 596   my $duration_sub = sub {
 597     my($cdr, %opt) = @_;
 598     my $sec = $opt{seconds} || $cdr->billsec;
 599     if ( defined $opt{granularity} &&
 600          $opt{granularity} == 0 ) { #per call
 601       return '1 call';
 602     }
 603     elsif ( defined $opt{granularity} && $opt{granularity} == 60 ) {#full minutes
 604       my $min = int($sec/60);
 605       $min++ if $sec%60;
 606       return $min.'m';
 607     }
 608     else { #anything else
 609       return sprintf("%dm %ds", $sec/60, $sec%60);
 610     }
 611   };
 612
 613   %export_formats = (
 614     'simple' => [
 615       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 616       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 617       'userfield',                                     #USER
 618       'dst',                                           #NUMBER_DIALED
 619       $duration_sub,                                   #DURATION
 620       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 621       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 622     ],
 623     'simple2' => [
 624       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 625       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 626       #'userfield',                                     #USER
 627       'src',                                           #called from
 628       'dst',                                           #NUMBER_DIALED
 629       $duration_sub,                                   #DURATION
 630       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 631       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 632     ],
 633     'sum_duration' => [
 634       # for summary formats, the CDR is a fictitious object containing the
 635       # total billsec and the phone number of the service
 636       'src',
 637       sub { my($cdr, %opt) = @_; $opt{count} },
 638       sub { my($cdr, %opt) = @_; int($opt{seconds}/60).'m' },
 639       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; },
 640     ],
 641     'sum_count' => [
 642       'src',
 643       sub { my($cdr, %opt) = @_; $opt{count} },
 644       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; },
 645     ],
 646     'basic' => [
 647       sub { time2str('%d %b - %I:%M %p', shift->calldate_unix) },
 648       'dst',
 649       $duration_sub,
 650       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 651     ],
 652     'default' => [
 653
 654       #DATE
 655       sub { time2str($date_format, shift->calldate_unix ) },
 656             # #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 657
 658       #TIME
 659       sub { time2str('%r', shift->calldate_unix ) },
 660             # time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 661
 662       #DEST ("Number")
 663       sub { my($cdr, %opt) = @_; $opt{pretty_dst} || $cdr->dst; },
 664
 665       #REGIONNAME ("Destination")
 666       sub { my($cdr, %opt) = @_; $opt{dst_regionname}; },
 667
 668       #DURATION
 669       $duration_sub,
 670
 671       #PRICE
 672       sub { my($cdr, %opt) = @_;
 673         $opt{charge} = '0.00' unless defined $opt{charge};
 674         $opt{money_char}.$opt{charge};
 675       },
 676
 677     ],
 678   );
 679   $export_formats{'source_default'} = [ 'src', @{ $export_formats{'default'} }, ];
 680   $export_formats{'accountcode_default'} =
 681     [ @{ $export_formats{'default'} }[0,1],
 682       'accountcode',
 683       @{ $export_formats{'default'} }[2..5],
 684     ];
 685   my @default = @{ $export_formats{'default'} };
 686   $export_formats{'description_default'} =
 687     [ 'src', @default[0..2],
 688       sub { my($cdr, %opt) = @_; $cdr->description },
 689       @default[4,5] ];
 690
 691   return %export_formats;
 692 }
 693
 694 =item downstream_csv OPTION => VALUE ...
 695
 696 Returns a string of formatted call details for display on an invoice.
 697
 698 Options:
 699
 700 format
 701
 702 charge
 703
 704 seconds
 705
 706 granularity
 707
 708 =cut
 709
 710 sub downstream_csv {
 711   my( $self, %opt ) = @_;
 712
 713   my $format = $opt{'format'};
 714   my %formats = $self->export_formats;
 715   return "Unknown format $format" unless exists $formats{$format};
 716
 717   #my $conf = new FS::Conf;
 718   #$opt{'money_char'} ||= $conf->config('money_char') || '$';
 719   $opt{'money_char'} ||= FS::Conf->new->config('money_char') || '$';
 720
 721   eval "use Text::CSV_XS;";
 722   die $@ if $@;
 723   my $csv = new Text::CSV_XS;
 724
 725   my @columns =
 726     map {
 727           ref($_) ? &{$_}($self, %opt) : $self->$_();
 728         }
 729     @{ $formats{$format} };
 730
 731   return @columns if defined $opt{'keeparray'};
 732
 733   my $status = $csv->combine(@columns);
 734   die "FS::CDR: error combining ". $csv->error_input(). "into downstream CSV"
 735     unless $status;
 736
 737   $csv->string;
 738
 739 }
 740
 741 =back
 742
 743 =head1 CLASS METHODS
 744
 745 =over 4
 746
 747 =item invoice_formats
 748
 749 Returns an ordered list of key value pairs containing invoice format names
 750 as keys (for use with part_pkg::voip_cdr) and "pretty" format names as values.
 751
 752 =cut
 753
 754 sub invoice_formats {
 755   map { ($_ => $export_names{$_}->{'name'}) }
 756     grep { $export_names{$_}->{'invoice_header'} }
 757     keys %export_names;
 758 }
 759
 760 =item invoice_header FORMAT
 761
 762 Returns a scalar containing the CSV column header for invoice format FORMAT.
 763
 764 =cut
 765
 766 sub invoice_header {
 767   my $format = shift;
 768   $export_names{$format}->{'invoice_header'};
 769 }
 770
 771 =item clear_status
 772
 773 Clears cdr and any associated cdr_termination statuses - used for
 774 CDR reprocessing.
 775
 776 =cut
 777
 778 sub clear_status {
 779   my $self = shift;
 780
 781   local $SIG{HUP} = 'IGNORE';
 782   local $SIG{INT} = 'IGNORE';
 783   local $SIG{QUIT} = 'IGNORE';
 784   local $SIG{TERM} = 'IGNORE';
 785   local $SIG{TSTP} = 'IGNORE';
 786   local $SIG{PIPE} = 'IGNORE';
 787
 788   my $oldAutoCommit = $FS::UID::AutoCommit;
 789   local $FS::UID::AutoCommit = 0;
 790   my $dbh = dbh;
 791
 792   $self->freesidestatus('');
 793   my $error = $self->replace;
 794   if ( $error ) {
 795     $dbh->rollback if $oldAutoCommit;
 796     return $error;
 797   }
 798
 799   foreach my $cdr_termination ( $self->cdr_termination ) {
 800       #$cdr_termination->status('');
 801       #$error = $cdr_termination->replace;
 802       $error = $cdr_termination->delete;
 803       if ( $error ) {
 804         $dbh->rollback if $oldAutoCommit;
 805         return $error;
 806       }
 807   }
 808
 809   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 810
 811   '';
 812 }
 813
 814 =item import_formats
 815
 816 Returns an ordered list of key value pairs containing import format names
 817 as keys (for use with batch_import) and "pretty" format names as values.
 818
 819 =cut
 820
 821 #false laziness w/part_pkg & part_export
 822
 823 my %cdr_info;
 824 foreach my $INC ( @INC ) {
 825   warn "globbing $INC/FS/cdr/*.pm\n" if $DEBUG;
 826   foreach my $file ( glob("$INC/FS/cdr/*.pm") ) {
 827     warn "attempting to load CDR format info from $file\n" if $DEBUG;
 828     $file =~ /\/(\w+)\.pm$/ or do {
 829       warn "unrecognized file in $INC/FS/cdr/: $file\n";
 830       next;
 831     };
 832     my $mod = $1;
 833     my $info = eval "use FS::cdr::$mod; ".
 834                     "\\%FS::cdr::$mod\::info;";
 835     if ( $@ ) {
 836       die "error using FS::cdr::$mod (skipping): $@\n" if $@;
 837       next;
 838     }
 839     unless ( keys %$info ) {
 840       warn "no %info hash found in FS::cdr::$mod, skipping\n";
 841       next;
 842     }
 843     warn "got CDR format info from FS::cdr::$mod: $info\n" if $DEBUG;
 844     if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 845       warn "skipping disabled CDR format FS::cdr::$mod" if $DEBUG;
 846       next;
 847     }
 848     $cdr_info{$mod} = $info;
 849   }
 850 }
 851
 852 tie my %import_formats, 'Tie::IxHash',
 853   map  { $_ => $cdr_info{$_}->{'name'} }
 854   sort { $cdr_info{$a}->{'weight'} <=> $cdr_info{$b}->{'weight'} }
 855   grep { exists($cdr_info{$_}->{'import_fields'}) }
 856   keys %cdr_info;
 857
 858 sub import_formats {
 859   %import_formats;
 860 }
 861
 862 sub _cdr_min_parser_maker {
 863   my $field = shift;
 864   my @fields = ref($field) ? @$field : ($field);
 865   @fields = qw( billsec duration ) unless scalar(@fields) && $fields[0];
 866   return sub {
 867     my( $cdr, $min ) = @_;
 868     my $sec = eval { _cdr_min_parse($min) };
 869     die "error parsing seconds for @fields from $min minutes: $@\n" if $@;
 870     $cdr->$_($sec) foreach @fields;
 871   };
 872 }
 873
 874 sub _cdr_min_parse {
 875   my $min = shift;
 876   sprintf('%.0f', $min * 60 );
 877 }
 878
 879 sub _cdr_date_parser_maker {
 880   my $field = shift;
 881   my %options = @_;
 882   my @fields = ref($field) ? @$field : ($field);
 883   return sub {
 884     my( $cdr, $datestring ) = @_;
 885     my $unixdate = eval { _cdr_date_parse($datestring, %options) };
 886     die "error parsing date for @fields from $datestring: $@\n" if $@;
 887     $cdr->$_($unixdate) foreach @fields;
 888   };
 889 }
 890
 891 sub _cdr_date_parse {
 892   my $date = shift;
 893   my %options = @_;
 894
 895   return '' unless length($date); #that's okay, it becomes NULL
 896   return '' if $date eq 'NA'; #sansay
 897
 898   if ( $date =~ /^([a-z]{3})\s+([a-z]{3})\s+(\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s+(\d{4})$/i && $7 > 1970 ) {
 899     my $time = str2time($date);
 900     return $time if $time > 100000; #just in case
 901   }
 902
 903   my($year, $mon, $day, $hour, $min, $sec);
 904
 905   #$date =~ /^\s*(\d{4})[\-\/]\(\d{1,2})[\-\/](\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s*$/
 906   #taqua  #2007-10-31 08:57:24.113000000
 907
 908   if ( $date =~ /^\s*(\d{4})\D(\d{1,2})\D(\d{1,2})\D+(\d{1,2})\D(\d{1,2})\D(\d{1,2})(\D|$)/ ) {
 909     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 910   } elsif ( $date  =~ /^\s*(\d{1,2})\D(\d{1,2})\D(\d{4})\s+(\d{1,2})\D(\d{1,2})(?:\D(\d{1,2}))?(\D|$)/ ) {
 911     # 8/26/2010 12:20:01
 912     # optionally without seconds
 913     ($mon, $day, $year, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 914     $sec = 0 if !defined($sec);
 915   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d+\.\d+)(\D|$)/ ) {
 916     # broadsoft: 20081223201938.314
 917     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 918   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\d+(\D|$)/ ) {
 919     # Taqua OM:  20050422203450943
 920     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 921   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})$/ ) {
 922     # WIP: 20100329121420
 923     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 924   } elsif ( $date =~ /^(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})Z$/) {
 925     # Telos
 926     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 927     $options{gmt} = 1;
 928   } else {
 929      die "unparsable date: $date"; #maybe we shouldn't die...
 930   }
 931
 932   return '' if ( $year == 1900 || $year == 1970 ) && $mon == 1 && $day == 1
 933             && $hour == 0 && $min == 0 && $sec == 0;
 934
 935   if ($options{gmt}) {
 936     timegm($sec, $min, $hour, $day, $mon-1, $year);
 937   } else {
 938     timelocal($sec, $min, $hour, $day, $mon-1, $year);
 939   }
 940 }
 941
 942 =item batch_import HASHREF
 943
 944 Imports CDR records.  Available options are:
 945
 946 =over 4
 947
 948 =item file
 949
 950 Filename
 951
 952 =item format
 953
 954 =item params
 955
 956 Hash reference of preset fields, typically cdrbatch
 957
 958 =item empty_ok
 959
 960 Set true to prevent throwing an error on empty imports
 961
 962 =back
 963
 964 =cut
 965
 966 my %import_options = (
 967   'table'         => 'cdr',
 968
 969   'batch_keycol'  => 'cdrbatchnum',
 970   'batch_table'   => 'cdr_batch',
 971   'batch_namecol' => 'cdrbatch',
 972
 973   'formats' => { map { $_ => $cdr_info{$_}->{'import_fields'}; }
 974                      keys %cdr_info
 975                },
 976
 977                           #drop the || 'csv' to allow auto xls for csv types?
 978   'format_types' => { map { $_ => lc($cdr_info{$_}->{'type'} || 'csv'); }
 979                           keys %cdr_info
 980                     },
 981
 982   'format_headers' => { map { $_ => ( $cdr_info{$_}->{'header'} || 0 ); }
 983                             keys %cdr_info
 984                       },
 985
 986   'format_sep_chars' => { map { $_ => $cdr_info{$_}->{'sep_char'}; }
 987                               keys %cdr_info
 988                         },
 989
 990   'format_fixedlength_formats' =>
 991     { map { $_ => $cdr_info{$_}->{'fixedlength_format'}; }
 992           keys %cdr_info
 993     },
 994
 995   'format_xml_formats' =>
 996     { map { $_ => $cdr_info{$_}->{'xml_format'}; }
 997           keys %cdr_info
 998     },
 999
1000   'format_row_callbacks' => { map { $_ => $cdr_info{$_}->{'row_callback'}; }
1001                                   keys %cdr_info
1002                             },
1003 );
1004
1005 sub _import_options {
1006   \%import_options;
1007 }
1008
1009 sub batch_import {
1010   my $opt = shift;
1011
1012   my $iopt = _import_options;
1013   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
1014
1015   if ( defined $opt->{'cdrtypenum'} ) {
1016         $opt->{'preinsert_callback'} = sub {
1017                 my($record,$param) = (shift,shift);
1018                 $record->cdrtypenum($opt->{'cdrtypenum'});
1019                 '';
1020         };
1021   }
1022
1023   FS::Record::batch_import( $opt );
1024
1025 }
1026
1027 =item process_batch_import
1028
1029 =cut
1030
1031 sub process_batch_import {
1032   my $job = shift;
1033
1034   my $opt = _import_options;
1035 #  $opt->{'params'} = [ 'format', 'cdrbatch' ];
1036
1037   FS::Record::process_batch_import( $job, $opt, @_ );
1038
1039 }
1040 #  if ( $format eq 'simple' ) { #should be a callback or opt in FS::cdr::simple
1041 #    @columns = map { s/^ +//; $_; } @columns;
1042 #  }
1043
1044 # _ upgrade_data
1045 #
1046 # Used by FS::Upgrade to migrate to a new database.
1047
1048 sub _upgrade_data {
1049   my ($class, %opts) = @_;
1050
1051   warn "$me upgrading $class\n" if $DEBUG;
1052
1053   my $sth = dbh->prepare(
1054     'SELECT DISTINCT(cdrbatch) FROM cdr WHERE cdrbatch IS NOT NULL'
1055   ) or die dbh->errstr;
1056
1057   $sth->execute or die $sth->errstr;
1058
1059   my %cdrbatchnum = ();
1060   while (my $row = $sth->fetchrow_arrayref) {
1061
1062     my $cdr_batch = qsearchs( 'cdr_batch', { 'cdrbatch' => $row->[0] } );
1063     unless ( $cdr_batch ) {
1064       $cdr_batch = new FS::cdr_batch { 'cdrbatch' => $row->[0] };
1065       my $error = $cdr_batch->insert;
1066       die $error if $error;
1067     }
1068
1069     $cdrbatchnum{$row->[0]} = $cdr_batch->cdrbatchnum;
1070   }
1071
1072   $sth = dbh->prepare('UPDATE cdr SET cdrbatch = NULL, cdrbatchnum = ? WHERE cdrbatch IS NOT NULL AND cdrbatch = ?') or die dbh->errstr;
1073
1074   foreach my $cdrbatch (keys %cdrbatchnum) {
1075     $sth->execute($cdrbatchnum{$cdrbatch}, $cdrbatch) or die $sth->errstr;
1076   }
1077
1078 }
1079
1080 =back
1081
1082 =head1 BUGS
1083
1084 =head1 SEE ALSO
1085
1086 L<FS::Record>, schema.html from the base documentation.
1087
1088 =cut
1089
1090 1;
1091