FS/FS/agent.pm

   1 package FS::agent;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 #use Crypt::YAPassGen;
   6 use Business::CreditCard 0.28;
   7 use FS::Record qw( dbh qsearch qsearchs );
   8 use FS::cust_main;
   9 use FS::cust_pkg;
  10 use FS::agent_type;
  11 use FS::reg_code;
  12 use FS::TicketSystem;
  13 use FS::Conf;
  14
  15 @ISA = qw( FS::m2m_Common FS::Record );
  16
  17 =head1 NAME
  18
  19 FS::agent - Object methods for agent records
  20
  21 =head1 SYNOPSIS
  22
  23   use FS::agent;
  24
  25   $record = new FS::agent \%hash;
  26   $record = new FS::agent { 'column' => 'value' };
  27
  28   $error = $record->insert;
  29
  30   $error = $new_record->replace($old_record);
  31
  32   $error = $record->delete;
  33
  34   $error = $record->check;
  35
  36   $agent_type = $record->agent_type;
  37
  38   $hashref = $record->pkgpart_hashref;
  39   #may purchase $pkgpart if $hashref->{$pkgpart};
  40
  41 =head1 DESCRIPTION
  42
  43 An FS::agent object represents an agent.  Every customer has an agent.  Agents
  44 can be used to track things like resellers or salespeople.  FS::agent inherits
  45 from FS::Record.  The following fields are currently supported:
  46
  47 =over 4
  48
  49 =item agentnum - primary key (assigned automatically for new agents)
  50
  51 =item agent - Text name of this agent
  52
  53 =item typenum - Agent type (see L<FS::agent_type>)
  54
  55 =item ticketing_queueid - Ticketing Queue
  56
  57 =item invoice_template - Invoice template name
  58
  59 =item agent_custnum - Optional agent customer (see L<FS::cust_main>)
  60
  61 =item disabled - Disabled flag, empty or 'Y'
  62
  63 =item prog - Deprecated (never used)
  64
  65 =item freq - Deprecated (never used)
  66
  67 =item username - (Deprecated) Username for the Agent interface
  68
  69 =item _password - (Deprecated) Password for the Agent interface
  70
  71 =back
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item new HASHREF
  78
  79 Creates a new agent.  To add the agent to the database, see L<"insert">.
  80
  81 =cut
  82
  83 sub table { 'agent'; }
  84
  85 =item insert
  86
  87 Adds this agent to the database.  If there is an error, returns the error,
  88 otherwise returns false.
  89
  90 =item delete
  91
  92 Deletes this agent from the database.  Only agents with no customers can be
  93 deleted.  If there is an error, returns the error, otherwise returns false.
  94
  95 =cut
  96
  97 sub delete {
  98   my $self = shift;
  99
 100   return "Can't delete an agent with customers!"
 101     if qsearch( 'cust_main', { 'agentnum' => $self->agentnum } );
 102
 103   $self->SUPER::delete;
 104 }
 105
 106 =item replace OLD_RECORD
 107
 108 Replaces OLD_RECORD with this one in the database.  If there is an error,
 109 returns the error, otherwise returns false.
 110
 111 =item check
 112
 113 Checks all fields to make sure this is a valid agent.  If there is an error,
 114 returns the error, otherwise returns false.  Called by the insert and replace
 115 methods.
 116
 117 =cut
 118
 119 sub check {
 120   my $self = shift;
 121
 122   my $error =
 123     $self->ut_numbern('agentnum')
 124       || $self->ut_text('agent')
 125       || $self->ut_number('typenum')
 126       || $self->ut_numbern('freq')
 127       || $self->ut_textn('prog')
 128       || $self->ut_textn('invoice_template')
 129       || $self->ut_foreign_keyn('agent_custnum', 'cust_main', 'custnum' )
 130   ;
 131   return $error if $error;
 132
 133   if ( $self->dbdef_table->column('disabled') ) {
 134     $error = $self->ut_enum('disabled', [ '', 'Y' ] );
 135     return $error if $error;
 136   }
 137
 138   if ( $self->dbdef_table->column('username') ) {
 139     $error = $self->ut_alphan('username');
 140     return $error if $error;
 141     if ( length($self->username) ) {
 142       my $conflict = qsearchs('agent', { 'username' => $self->username } );
 143       return 'duplicate agent username (with '. $conflict->agent. ')'
 144         if $conflict && $conflict->agentnum != $self->agentnum;
 145       $error = $self->ut_text('password'); # ut_text... arbitrary choice
 146     } else {
 147       $self->_password('');
 148     }
 149   }
 150
 151   return "Unknown typenum!"
 152     unless $self->agent_type;
 153
 154   $self->SUPER::check;
 155 }
 156
 157 =item agent_type
 158
 159 Returns the FS::agent_type object (see L<FS::agent_type>) for this agent.
 160
 161 =cut
 162
 163 sub agent_type {
 164   my $self = shift;
 165   qsearchs( 'agent_type', { 'typenum' => $self->typenum } );
 166 }
 167
 168 =item agent_cust_main
 169
 170 Returns the FS::cust_main object (see L<FS::cust_main>), if any, for this
 171 agent.
 172
 173 =cut
 174
 175 sub agent_cust_main {
 176   my $self = shift;
 177   qsearchs( 'cust_main', { 'custnum' => $self->agent_custnum } );
 178 }
 179
 180 =item pkgpart_hashref
 181
 182 Returns a hash reference.  The keys of the hash are pkgparts.  The value is
 183 true if this agent may purchase the specified package definition.  See
 184 L<FS::part_pkg>.
 185
 186 =cut
 187
 188 sub pkgpart_hashref {
 189   my $self = shift;
 190   $self->agent_type->pkgpart_hashref;
 191 }
 192
 193 =item ticketing_queue
 194
 195 Returns the queue name corresponding with the id from the I<ticketing_queueid>
 196 field, or the empty string.
 197
 198 =cut
 199
 200 sub ticketing_queue {
 201   my $self = shift;
 202   FS::TicketSystem->queue($self->ticketing_queueid);
 203 };
 204
 205 =item payment_gateway [ OPTION => VALUE, ... ]
 206
 207 Returns a payment gateway object (see L<FS::payment_gateway>) for this agent.
 208
 209 Currently available options are I<nofatal>, I<invnum>, I<method>,
 210 I<payinfo>, and I<thirdparty>.
 211
 212 If I<nofatal> is set, and no gateway is available, then the empty string
 213 will be returned instead of throwing a fatal exception.
 214
 215 If I<invnum> is set to the number of an invoice (see L<FS::cust_bill>) then
 216 an attempt will be made to select a gateway suited for the taxes paid on
 217 the invoice.
 218
 219 The I<method> and I<payinfo> options can be used to influence the choice
 220 as well.  Presently only 'CC', 'ECHECK', and 'PAYPAL' methods are meaningful.
 221
 222 When the I<method> is 'CC' then the card number in I<payinfo> can direct
 223 this routine to route to a gateway suited for that type of card.
 224
 225 If I<thirdparty> is set, the defined self-service payment gateway will
 226 be returned.
 227
 228 =cut
 229
 230 sub payment_gateway {
 231   my ( $self, %options ) = @_;
 232
 233   my $conf = new FS::Conf;
 234
 235   if ( $options{thirdparty} ) {
 236     # still a kludge, but it gets the job done
 237     # and the 'cardtype' semantics don't really apply to thirdparty
 238     # gateways because we have to choose a gateway without ever
 239     # seeing the card number
 240     my $gatewaynum =
 241       $conf->config('selfservice-payment_gateway', $self->agentnum);
 242     my $gateway = FS::payment_gateway->by_key($gatewaynum)
 243       if $gatewaynum;
 244
 245     if ( $gateway ) {
 246       return $gateway;
 247     } elsif ( $options{'nofatal'} ) {
 248       return '';
 249     } else {
 250       die "no third-party gateway configured\n";
 251     }
 252   }
 253
 254   my $taxclass = '';
 255   if ( $options{invnum} ) {
 256
 257     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $options{invnum} } );
 258     die "invnum ". $options{'invnum'}. " not found" unless $cust_bill;
 259
 260     my @part_pkg =
 261       map  { $_->part_pkg }
 262       grep { $_ }
 263       map  { $_->cust_pkg }
 264       $cust_bill->cust_bill_pkg;
 265
 266     my @taxclasses = map $_->taxclass, @part_pkg;
 267
 268     $taxclass = $taxclasses[0]
 269       unless grep { $taxclasses[0] ne $_ } @taxclasses; #unless there are
 270                                                         #different taxclasses
 271   }
 272
 273   #look for an agent gateway override first
 274   my $cardtype = '';
 275   if ( $options{method} ) {
 276     if ( $options{method} eq 'CC' && $options{payinfo} ) {
 277       $cardtype = cardtype($options{payinfo});
 278     } elsif ( $options{method} eq 'ECHECK' ) {
 279       $cardtype = 'ACH';
 280     } else {
 281       $cardtype = $options{method}
 282     }
 283   }
 284
 285   my $override =
 286        qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
 287                                            cardtype => $cardtype,
 288                                            taxclass => $taxclass,       } )
 289     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
 290                                            cardtype => '',
 291                                            taxclass => $taxclass,       } )
 292     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
 293                                            cardtype => $cardtype,
 294                                            taxclass => '',              } )
 295     || qsearchs('agent_payment_gateway', { agentnum => $self->agentnum,
 296                                            cardtype => '',
 297                                            taxclass => '',              } );
 298
 299   my $payment_gateway;
 300   if ( $override ) { #use a payment gateway override
 301
 302     $payment_gateway = $override->payment_gateway;
 303
 304     $payment_gateway->gateway_namespace('Business::OnlinePayment')
 305       unless $payment_gateway->gateway_namespace;
 306
 307   } else { #use the standard settings from the config
 308
 309     # the standard settings from the config could be moved to a null agent
 310     # agent_payment_gateway referenced payment_gateway
 311
 312     unless ( $conf->exists('business-onlinepayment') ) {
 313       if ( $options{'nofatal'} ) {
 314         return '';
 315       } else {
 316         die "Real-time processing not enabled\n";
 317       }
 318     }
 319
 320     #load up config
 321     my $bop_config = 'business-onlinepayment';
 322     $bop_config .= '-ach'
 323       if ( $options{method}
 324            && $options{method} =~ /^(ECHECK|CHEK)$/
 325            && $conf->exists($bop_config. '-ach')
 326          );
 327     my ( $processor, $login, $password, $action, @bop_options ) =
 328       $conf->config($bop_config);
 329     $action ||= 'normal authorization';
 330     pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
 331     die "No real-time processor is enabled - ".
 332         "did you set the business-onlinepayment configuration value?\n"
 333       unless $processor;
 334
 335     $payment_gateway = new FS::payment_gateway;
 336
 337     $payment_gateway->gateway_namespace( $conf->config('business-onlinepayment-namespace') ||
 338                                  'Business::OnlinePayment');
 339     $payment_gateway->gateway_module($processor);
 340     $payment_gateway->gateway_username($login);
 341     $payment_gateway->gateway_password($password);
 342     $payment_gateway->gateway_action($action);
 343     $payment_gateway->set('options', [ @bop_options ]);
 344
 345   }
 346
 347   unless ( $payment_gateway->gateway_namespace ) {
 348     $payment_gateway->gateway_namespace(
 349       scalar($conf->config('business-onlinepayment-namespace'))
 350       || 'Business::OnlinePayment'
 351     );
 352   }
 353
 354   $payment_gateway;
 355 }
 356
 357 =item num_prospect_cust_main
 358
 359 Returns the number of prospects (customers with no packages ever ordered) for
 360 this agent.
 361
 362 =cut
 363
 364 sub num_prospect_cust_main {
 365   shift->num_sql(FS::cust_main->prospect_sql);
 366 }
 367
 368 sub num_sql {
 369   my( $self, $sql ) = @_;
 370   my $statement = "SELECT COUNT(*) FROM cust_main WHERE agentnum = ? AND $sql";
 371   my $sth = dbh->prepare($statement) or die dbh->errstr." preparing $statement";
 372   $sth->execute($self->agentnum) or die $sth->errstr. " executing $statement";
 373   $sth->fetchrow_arrayref->[0];
 374 }
 375
 376 =item prospect_cust_main
 377
 378 Returns the prospects (customers with no packages ever ordered) for this agent,
 379 as cust_main objects.
 380
 381 =cut
 382
 383 sub prospect_cust_main {
 384   shift->cust_main_sql(FS::cust_main->prospect_sql);
 385 }
 386
 387 sub cust_main_sql {
 388   my( $self, $sql ) = @_;
 389   qsearch( 'cust_main',
 390            { 'agentnum' => $self->agentnum },
 391            '',
 392            " AND $sql"
 393   );
 394 }
 395
 396 =item num_active_cust_main
 397
 398 Returns the number of active customers for this agent (customers with active
 399 recurring packages).
 400
 401 =cut
 402
 403 sub num_active_cust_main {
 404   shift->num_sql(FS::cust_main->active_sql);
 405 }
 406
 407 =item active_cust_main
 408
 409 Returns the active customers for this agent, as cust_main objects.
 410
 411 =cut
 412
 413 sub active_cust_main {
 414   shift->cust_main_sql(FS::cust_main->active_sql);
 415 }
 416
 417 =item num_inactive_cust_main
 418
 419 Returns the number of inactive customers for this agent (customers with no
 420 active recurring packages, but otherwise unsuspended/uncancelled).
 421
 422 =cut
 423
 424 sub num_inactive_cust_main {
 425   shift->num_sql(FS::cust_main->inactive_sql);
 426 }
 427
 428 =item inactive_cust_main
 429
 430 Returns the inactive customers for this agent, as cust_main objects.
 431
 432 =cut
 433
 434 sub inactive_cust_main {
 435   shift->cust_main_sql(FS::cust_main->inactive_sql);
 436 }
 437
 438
 439 =item num_susp_cust_main
 440
 441 Returns the number of suspended customers for this agent.
 442
 443 =cut
 444
 445 sub num_susp_cust_main {
 446   shift->num_sql(FS::cust_main->susp_sql);
 447 }
 448
 449 =item susp_cust_main
 450
 451 Returns the suspended customers for this agent, as cust_main objects.
 452
 453 =cut
 454
 455 sub susp_cust_main {
 456   shift->cust_main_sql(FS::cust_main->susp_sql);
 457 }
 458
 459 =item num_cancel_cust_main
 460
 461 Returns the number of cancelled customer for this agent.
 462
 463 =cut
 464
 465 sub num_cancel_cust_main {
 466   shift->num_sql(FS::cust_main->cancel_sql);
 467 }
 468
 469 =item cancel_cust_main
 470
 471 Returns the cancelled customers for this agent, as cust_main objects.
 472
 473 =cut
 474
 475 sub cancel_cust_main {
 476   shift->cust_main_sql(FS::cust_main->cancel_sql);
 477 }
 478
 479 =item num_active_cust_pkg
 480
 481 Returns the number of active customer packages for this agent.
 482
 483 =cut
 484
 485 sub num_active_cust_pkg {
 486   shift->num_pkg_sql(FS::cust_pkg->active_sql);
 487 }
 488
 489 sub num_pkg_sql {
 490   my( $self, $sql ) = @_;
 491   my $statement =
 492     "SELECT COUNT(*) FROM cust_pkg LEFT JOIN cust_main USING ( custnum )".
 493     " WHERE agentnum = ? AND $sql";
 494   my $sth = dbh->prepare($statement) or die dbh->errstr." preparing $statement";
 495   $sth->execute($self->agentnum) or die $sth->errstr. "executing $statement";
 496   $sth->fetchrow_arrayref->[0];
 497 }
 498
 499 =item num_inactive_cust_pkg
 500
 501 Returns the number of inactive customer packages (one-time packages otherwise
 502 unsuspended/uncancelled) for this agent.
 503
 504 =cut
 505
 506 sub num_inactive_cust_pkg {
 507   shift->num_pkg_sql(FS::cust_pkg->inactive_sql);
 508 }
 509
 510 =item num_susp_cust_pkg
 511
 512 Returns the number of suspended customer packages for this agent.
 513
 514 =cut
 515
 516 sub num_susp_cust_pkg {
 517   shift->num_pkg_sql(FS::cust_pkg->susp_sql);
 518 }
 519
 520 =item num_cancel_cust_pkg
 521
 522 Returns the number of cancelled customer packages for this agent.
 523
 524 =cut
 525
 526 sub num_cancel_cust_pkg {
 527   shift->num_pkg_sql(FS::cust_pkg->cancel_sql);
 528 }
 529
 530 =item generate_reg_codes NUM PKGPART_ARRAYREF
 531
 532 Generates the specified number of registration codes, allowing purchase of the
 533 specified package definitions.  Returns an array reference of the newly
 534 generated codes, or a scalar error message.
 535
 536 =cut
 537
 538 #false laziness w/prepay_credit::generate
 539 sub generate_reg_codes {
 540   my( $self, $num, $pkgparts ) = @_;
 541
 542   my @codeset = ( 'A'..'Z' );
 543
 544   local $SIG{HUP} = 'IGNORE';
 545   local $SIG{INT} = 'IGNORE';
 546   local $SIG{QUIT} = 'IGNORE';
 547   local $SIG{TERM} = 'IGNORE';
 548   local $SIG{TSTP} = 'IGNORE';
 549   local $SIG{PIPE} = 'IGNORE';
 550
 551   my $oldAutoCommit = $FS::UID::AutoCommit;
 552   local $FS::UID::AutoCommit = 0;
 553   my $dbh = dbh;
 554
 555   my @codes = ();
 556   for ( 1 ... $num ) {
 557     my $reg_code = new FS::reg_code {
 558       'agentnum' => $self->agentnum,
 559       'code'     => join('', map($codeset[int(rand $#codeset)], (0..7) ) ),
 560     };
 561     my $error = $reg_code->insert($pkgparts);
 562     if ( $error ) {
 563       $dbh->rollback if $oldAutoCommit;
 564       return $error;
 565     }
 566     push @codes, $reg_code->code;
 567   }
 568
 569   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 570
 571   \@codes;
 572
 573 }
 574
 575 =item num_reg_code
 576
 577 Returns the number of unused registration codes for this agent.
 578
 579 =cut
 580
 581 sub num_reg_code {
 582   my $self = shift;
 583   my $sth = dbh->prepare(
 584     "SELECT COUNT(*) FROM reg_code WHERE agentnum = ?"
 585   ) or die dbh->errstr;
 586   $sth->execute($self->agentnum) or die $sth->errstr;
 587   $sth->fetchrow_arrayref->[0];
 588 }
 589
 590 =item num_prepay_credit
 591
 592 Returns the number of unused prepaid cards for this agent.
 593
 594 =cut
 595
 596 sub num_prepay_credit {
 597   my $self = shift;
 598   my $sth = dbh->prepare(
 599     "SELECT COUNT(*) FROM prepay_credit WHERE agentnum = ?"
 600   ) or die dbh->errstr;
 601   $sth->execute($self->agentnum) or die $sth->errstr;
 602   $sth->fetchrow_arrayref->[0];
 603 }
 604
 605 =item num_sales
 606
 607 Returns the number of non-disabled sales people for this agent.
 608
 609 =cut
 610
 611 sub num_sales {
 612   my $self = shift;
 613   my $sth = dbh->prepare(
 614     "SELECT COUNT(*) FROM sales WHERE agentnum = ?
 615                                   AND ( disabled = '' OR disabled IS NULL )"
 616   ) or die dbh->errstr;
 617   $sth->execute($self->agentnum) or die $sth->errstr;
 618   $sth->fetchrow_arrayref->[0];
 619 }
 620
 621 =back
 622
 623 =head1 BUGS
 624
 625 =head1 SEE ALSO
 626
 627 L<FS::Record>, L<FS::agent_type>, L<FS::cust_main>, L<FS::part_pkg>,
 628 schema.html from the base documentation.
 629
 630 =cut
 631
 632 1;
 633