FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   $conf->touch('payment_receipt')
  51     if $conf->exists('payment_receipt_email')
  52     || $conf->config('payment_receipt_msgnum');
  53
  54   $conf->touch('geocode-require_nw_coordinates')
  55     if $conf->exists('svc_broadband-require-nw-coordinates');
  56
  57   unless ( $conf->config('echeck-country') ) {
  58     if ( $conf->exists('cust_main-require-bank-branch') ) {
  59       $conf->set('echeck-country', 'CA');
  60     } elsif ( $conf->exists('echeck-nonus') ) {
  61       $conf->set('echeck-country', 'XX');
  62     } else {
  63       $conf->set('echeck-country', 'US');
  64     }
  65   }
  66
  67   my @agents = qsearch('agent', {});
  68
  69   upgrade_overlimit_groups($conf);
  70   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  71
  72   upgrade_invoice_from($conf);
  73   foreach my $agent (@agents) {
  74     upgrade_invoice_from($conf,$agent->agentnum,1);
  75   }
  76
  77   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  78   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  79     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  80       qw( quotation_html quotation_latex quotation_latexnotes );
  81
  82   # change 'fslongtable' to 'longtable'
  83   # in invoice and quotation main templates, and also in all secondary
  84   # invoice templates
  85   my @latex_confs =
  86     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  87
  88   foreach my $c (@latex_confs) {
  89     my $value = $c->value;
  90     if (length($value) and $value =~ /fslongtable/) {
  91       $value =~ s/fslongtable/longtable/g;
  92       $conf->set($c->name, $value, $c->agentnum);
  93     }
  94   }
  95
  96   # if there's a USPS tools login, assume that's the standardization method
  97   # you want to use
  98   $conf->set('address_standardize_method', 'usps')
  99     if $conf->exists('usps_webtools-userid')
 100     && length($conf->config('usps_webtools-userid')) > 0
 101     && ! $conf->exists('address_standardize_method');
 102
 103   # this option has been renamed/expanded
 104   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 105     $conf->touch('cust_main-enable_spouse');
 106     $conf->delete('cust_main-enable_spouse_birthdate');
 107   }
 108
 109   # renamed/repurposed
 110   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 111     $conf->touch('part_pkg-show_fcc_options');
 112     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 113     warn "
 114 You have FCC Form 477 package options enabled.
 115
 116 Starting with the October 2014 filing date, the FCC has redesigned
 117 Form 477 and introduced new service categories.  See bin/convert-477-options
 118 to update your package configuration for the new report.
 119
 120 If you need to continue using the old Form 477 report, turn on the
 121 'old_fcc_report' configuration option.
 122 ";
 123   }
 124
 125   # boolean invoice_sections_by_location option is now
 126   # invoice_sections_method = 'location'
 127   my @invoice_sections_confs =
 128     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 129   foreach my $c (@invoice_sections_confs) {
 130     $c->name =~ /^(\w+)sections_by_location$/;
 131     $conf->delete($c->name);
 132     my $newname = $1.'sections_method';
 133     $conf->set($newname, 'location');
 134   }
 135
 136   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 137   if ( $conf->exists('enable_taxproducts') ) {
 138
 139     $conf->delete('enable_taxproducts');
 140     $conf->set('tax_data_vendor', 'cch');
 141
 142   }
 143
 144   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 145   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 146     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 147     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 148   }
 149
 150   # boolean+text previous_balance-exclude_from_total is now two separate options
 151   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 152   if (length($total_new_charges) > 0) {
 153     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 154     $conf->set('previous_balance-exclude_from_total', '');
 155   }
 156
 157   # switch from specifying an email address to boolean check
 158   if ( $conf->exists('batch-errors_to') ) {
 159     $conf->touch('batch-errors_not_fatal');
 160     $conf->delete('batch-errors_to');
 161   }
 162
 163   if ( $conf->exists('voip-cust_email_csv_cdr') ) {
 164     $conf->set('voip_cdr_email_attach', 'csv');
 165     $conf->delete('voip-cust_email_csv_cdr') ;
 166   }
 167
 168   if ( !$conf->config('password-generated-characters') ) {
 169     my $pw_set =
 170       'abcdefghijkmnpqrstuvwxyzABCDEFGHIJKLMNPQRSTUVWXYZ23456789()#.,' ;
 171     $conf->set('password-generated-characters', $pw_set);
 172   }
 173
 174   if ($conf->exists('unsuspendauto') && !$conf->config('unsuspend_balance')) {
 175     $conf->set('unsuspend_balance','Zero');
 176     $conf->delete('unsuspendauto');
 177   }
 178
 179   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 180
 181 }
 182
 183 sub upgrade_overlimit_groups {
 184     my $conf = shift;
 185     my $agentnum = shift;
 186     my @groups = $conf->config('overlimit_groups',$agentnum);
 187     if(scalar(@groups)) {
 188         my $groups = join(',',@groups);
 189         my @groupnums;
 190         my $error = '';
 191         if ( $groups !~ /^[\d,]+$/ ) {
 192             foreach my $groupname ( @groups ) {
 193                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 194                 unless ( $g ) {
 195                     $g = new FS::radius_group {
 196                                     'groupname' => $groupname,
 197                                     'description' => $groupname,
 198                                     };
 199                     $error = $g->insert;
 200                     die $error if $error;
 201                 }
 202                 push @groupnums, $g->groupnum;
 203             }
 204             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 205         }
 206     }
 207 }
 208
 209 sub upgrade_invoice_from {
 210   my ($conf, $agentnum, $agentonly) = @_;
 211   if (
 212       (!$conf->exists('invoice_from_name',$agentnum,$agentonly)) &&
 213       ($conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/)
 214   ) {
 215     my $realemail = $1;
 216     $realemail =~ s/^\s*//; # remove leading spaces
 217     $realemail =~ s/\s*$//; # remove trailing spaces
 218     my $realname = $conf->config('invoice_from',$agentnum);
 219     $realname =~ s/\<.*\>//; # remove email address
 220     $realname =~ s/^\s*//; # remove leading spaces
 221     $realname =~ s/\s*$//; # remove trailing spaces
 222     # properly quote names that contain punctuation
 223     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 224       $realname = '"' . $realname . '"';
 225     }
 226     $conf->set('invoice_from_name', $realname, $agentnum);
 227     $conf->set('invoice_from', $realemail, $agentnum);
 228   }
 229 }
 230
 231 =item upgrade
 232
 233 =cut
 234
 235 sub upgrade {
 236   my %opt = @_;
 237
 238   my $data = upgrade_data(%opt);
 239
 240   my $oldAutoCommit = $FS::UID::AutoCommit;
 241   local $FS::UID::AutoCommit = 0;
 242   local $FS::UID::AutoCommit = 0;
 243
 244   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 245
 246
 247   foreach my $table ( keys %$data ) {
 248
 249     my $class = "FS::$table";
 250     eval "use $class;";
 251     die $@ if $@;
 252
 253     if ( $class->can('_upgrade_data') ) {
 254       warn "Upgrading $table...\n";
 255
 256       my $start = time;
 257
 258       $class->_upgrade_data(%opt);
 259
 260       # New interface for async upgrades: a class can declare a
 261       # "queueable_upgrade" method, which will run as part of the normal
 262       # upgrade, but if the -j option is passed, will instead be run from
 263       # the job queue.
 264       if ( $class->can('queueable_upgrade') ) {
 265         my $jobname = $class . '::queueable_upgrade';
 266         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 267         if ($num_jobs > 0) {
 268           warn "$class upgrade already scheduled.\n";
 269         } else {
 270           if ( $opt{'queue'} ) {
 271             warn "Scheduling $class upgrade.\n";
 272             my $job = FS::queue->new({ job => $jobname });
 273             $job->insert($class, %opt);
 274           } else {
 275             $class->queueable_upgrade(%opt);
 276           }
 277         } #$num_jobs == 0
 278       }
 279
 280       if ( $oldAutoCommit ) {
 281         warn "  committing\n";
 282         dbh->commit or die dbh->errstr;
 283       }
 284
 285       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 286       warn "  done in ". (time-$start). " seconds\n";
 287
 288     } else {
 289       warn "WARNING: asked for upgrade of $table,".
 290            " but FS::$table has no _upgrade_data method\n";
 291     }
 292
 293 #    my @records = @{ $data->{$table} };
 294 #
 295 #    foreach my $record ( @records ) {
 296 #      my $args = delete($record->{'_upgrade_args'}) || [];
 297 #      my $object = $class->new( $record );
 298 #      my $error = $object->insert( @$args );
 299 #      die "error inserting record into $table: $error\n"
 300 #        if $error;
 301 #    }
 302
 303   }
 304
 305   local($FS::cust_main::ignore_expired_card) = 1;
 306   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 307   local($FS::cust_main::ignore_banned_card) = 1;
 308   local($FS::cust_main::skip_fuzzyfiles) = 1;
 309
 310   local($FS::cust_payby::ignore_expired_card) = 1;
 311   local($FS::cust_payby::ignore_banned_card) = 1;
 312
 313   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 314   # kind of a weird spot for this, but it's better than duplicating
 315   # all this code in each class...
 316   my @decrypt_tables = qw( cust_main cust_pay_void cust_pay cust_refund cust_pay_pending );
 317   foreach my $table ( @decrypt_tables ) {
 318       my @objects = qsearch({
 319         'table'     => $table,
 320         'hashref'   => {},
 321         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 322                        " AND LENGTH(payinfo) > 100",
 323       });
 324       foreach my $object ( @objects ) {
 325           my $payinfo = $object->decrypt($object->payinfo);
 326           die "error decrypting payinfo" if $payinfo eq $object->payinfo;
 327           $object->payinfo($payinfo);
 328           my $error = $object->replace;
 329           die $error if $error;
 330       }
 331   }
 332
 333 }
 334
 335 =item upgrade_data
 336
 337 =cut
 338
 339 sub upgrade_data {
 340   my %opt = @_;
 341
 342   tie my %hash, 'Tie::IxHash',
 343
 344     #payby conditions to new ones
 345     'part_event_condition' => [],
 346
 347     #payby actions to new ones
 348     'part_event' => [],
 349
 350     #cust_main (remove paycvv from history, locations, cust_payby, etc)
 351     'cust_main' => [],
 352
 353     #contact -> cust_contact / prospect_contact
 354     'contact' => [],
 355
 356     #msgcat
 357     'msgcat' => [],
 358
 359     #reason type and reasons
 360     'reason_type'     => [],
 361     'cust_pkg_reason' => [],
 362
 363     #need part_pkg before cust_credit...
 364     'part_pkg' => [],
 365
 366     #customer credits
 367     'cust_credit' => [],
 368
 369     # reason / void_reason migration to reasonnum / void_reasonnum
 370     'cust_credit_void' => [],
 371     'cust_bill_void' => [],
 372     'cust_bill_pkg_void' => [],
 373
 374     #duplicate history records
 375     'h_cust_svc'  => [],
 376
 377     #populate cust_pay.otaker
 378     'cust_pay'    => [],
 379
 380     #populate part_pkg_taxclass for starters
 381     'part_pkg_taxclass' => [],
 382
 383     #remove bad pending records
 384     'cust_pay_pending' => [],
 385
 386     #replace invnum and pkgnum with billpkgnum
 387     'cust_bill_pkg_detail' => [],
 388
 389     #usage_classes if we have none
 390     'usage_class' => [],
 391
 392     #phone_type if we have none
 393     'phone_type' => [],
 394
 395     #fixup access rights
 396     'access_right' => [],
 397
 398     #change recur_flat and enable_prorate
 399     'part_pkg_option' => [],
 400
 401     #add weights to pkg_category
 402     'pkg_category' => [],
 403
 404     #cdrbatch fixes
 405     'cdr' => [],
 406
 407     #otaker->usernum
 408     'cust_attachment' => [],
 409     #'cust_credit' => [],
 410     #'cust_main' => [],
 411     'cust_main_note' => [],
 412     #'cust_pay' => [],
 413     'cust_pay_void' => [],
 414     'cust_pkg' => [],
 415     #'cust_pkg_reason' => [],
 416     'cust_pkg_discount' => [],
 417     'cust_refund' => [],
 418     'banned_pay' => [],
 419
 420     #default namespace
 421     'payment_gateway' => [],
 422
 423     #migrate to templates
 424     'msg_template' => [],
 425
 426     #return unprovisioned numbers to availability
 427     'phone_avail' => [],
 428
 429     #insert scripcondition
 430     'TicketSystem' => [],
 431
 432     #insert LATA data if not already present
 433     'lata' => [],
 434
 435     #insert MSA data if not already present
 436     'msa' => [],
 437
 438     # migrate to radius_group and groupnum instead of groupname
 439     'radius_usergroup' => [],
 440     'part_svc'         => [],
 441     'part_export'      => [],
 442
 443     #insert default tower_sector if not present
 444     'tower' => [],
 445
 446     #repair improperly deleted services
 447     'cust_svc' => [],
 448
 449     #routernum/blocknum
 450     'svc_broadband' => [],
 451
 452     #set up payment gateways if needed
 453     'pay_batch' => [],
 454
 455     #flag monthly tax exemptions
 456     'cust_tax_exempt_pkg' => [],
 457
 458     #kick off tax location history upgrade
 459     'cust_bill_pkg' => [],
 460
 461     #fix taxable line item links
 462     'cust_bill_pkg_tax_location' => [],
 463
 464     #populate state FIPS codes if not already done
 465     'state' => [],
 466
 467     #set default locations on quoted packages
 468     'quotation_pkg' => [],
 469
 470     #populate tax statuses
 471     'tax_status' => [],
 472
 473     #mark certain taxes as system-maintained
 474     'cust_main_county' => [],
 475   ;
 476
 477   \%hash;
 478
 479 }
 480
 481 =item upgrade_schema
 482
 483 =cut
 484
 485 sub upgrade_schema {
 486   my %opt = @_;
 487
 488   my $data = upgrade_schema_data(%opt);
 489
 490   my $oldAutoCommit = $FS::UID::AutoCommit;
 491   local $FS::UID::AutoCommit = 0;
 492   local $FS::UID::AutoCommit = 0;
 493
 494   foreach my $table ( keys %$data ) {
 495
 496     my $class = "FS::$table";
 497     eval "use $class;";
 498     die $@ if $@;
 499
 500     if ( $class->can('_upgrade_schema') ) {
 501       warn "Upgrading $table schema...\n";
 502
 503       my $start = time;
 504
 505       $class->_upgrade_schema(%opt);
 506
 507       if ( $oldAutoCommit ) {
 508         warn "  committing\n";
 509         dbh->commit or die dbh->errstr;
 510       }
 511
 512       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 513       warn "  done in ". (time-$start). " seconds\n";
 514
 515     } else {
 516       warn "WARNING: asked for schema upgrade of $table,".
 517            " but FS::$table has no _upgrade_schema method\n";
 518     }
 519
 520   }
 521
 522 }
 523
 524 =item upgrade_schema_data
 525
 526 =cut
 527
 528 sub upgrade_schema_data {
 529   my %opt = @_;
 530
 531   tie my %hash, 'Tie::IxHash',
 532
 533     #fix classnum character(1)
 534     'cust_bill_pkg_detail' => [],
 535     #add necessary columns to RT schema
 536     'TicketSystem' => [],
 537
 538   ;
 539
 540   \%hash;
 541
 542 }
 543
 544 sub upgrade_sqlradius {
 545   #my %opt = @_;
 546
 547   my $conf = new FS::Conf;
 548
 549   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 550
 551   foreach my $part_export ( @part_export ) {
 552
 553     my $errmsg = 'Error adding FreesideStatus to '.
 554                  $part_export->option('datasrc'). ': ';
 555
 556     my $dbh = DBI->connect(
 557       ( map $part_export->option($_), qw ( datasrc username password ) ),
 558       { PrintError => 0, PrintWarn => 0 }
 559     ) or do {
 560       warn $errmsg.$DBI::errstr;
 561       next;
 562     };
 563
 564     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 565     my $group = "UserName";
 566     $group .= ",Realm"
 567       if ref($part_export) =~ /withdomain/
 568       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 569
 570     my $sth_alter = $dbh->prepare(
 571       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 572     );
 573     if ( $sth_alter ) {
 574       if ( $sth_alter->execute ) {
 575         my $sth_update = $dbh->prepare(
 576          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 577         ) or die $errmsg.$dbh->errstr;
 578         $sth_update->execute or die $errmsg.$sth_update->errstr;
 579       } else {
 580         my $error = $sth_alter->errstr;
 581         warn $errmsg.$error
 582           unless $error =~ /Duplicate column name/i  #mysql
 583               || $error =~ /already exists/i;        #Pg
 584 ;
 585       }
 586     } else {
 587       my $error = $dbh->errstr;
 588       warn $errmsg.$error; #unless $error =~ /exists/i;
 589     }
 590
 591     my $sth_index = $dbh->prepare(
 592       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 593     );
 594     if ( $sth_index ) {
 595       unless ( $sth_index->execute ) {
 596         my $error = $sth_index->errstr;
 597         warn $errmsg.$error
 598           unless $error =~ /Duplicate key name/i #mysql
 599               || $error =~ /already exists/i;    #Pg
 600       }
 601     } else {
 602       my $error = $dbh->errstr;
 603       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 604     }
 605
 606     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 607       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 608       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 609
 610     my $sth = $dbh->prepare("SELECT UserName,
 611                                     Realm,
 612                                     $str2time max(AcctStartTime)),
 613                                     $str2time max(AcctStopTime))
 614                               FROM radacct
 615                               WHERE FreesideStatus = 'done'
 616                                 AND $times
 617                               GROUP BY $group
 618                             ")
 619       or die $errmsg.$dbh->errstr;
 620     $sth->execute() or die $errmsg.$sth->errstr;
 621
 622     while (my $row = $sth->fetchrow_arrayref ) {
 623       my ($username, $realm, $start, $stop) = @$row;
 624
 625       $username = lc($username) unless $conf->exists('username-uppercase');
 626
 627       my $exportnum = $part_export->exportnum;
 628       my $extra_sql = " AND exportnum = $exportnum ".
 629                       " AND exportsvcnum IS NOT NULL ";
 630
 631       if ( ref($part_export) =~ /withdomain/ ) {
 632         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 633                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 634       }
 635
 636       my $svc_acct = qsearchs({
 637         'select'    => 'svc_acct.*',
 638         'table'     => 'svc_acct',
 639         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 640                        'LEFT JOIN export_svc USING ( svcpart )',
 641         'hashref'   => { 'username' => $username },
 642         'extra_sql' => $extra_sql,
 643       });
 644
 645       if ($svc_acct) {
 646         $svc_acct->last_login($start)
 647           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 648         $svc_acct->last_logout($stop)
 649           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 650       }
 651     }
 652   }
 653
 654 }
 655
 656 =back
 657
 658 =head1 BUGS
 659
 660 Sure.
 661
 662 =head1 SEE ALSO
 663
 664 =cut
 665
 666 1;
 667