FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   $conf->touch('payment_receipt')
  51     if $conf->exists('payment_receipt_email')
  52     || $conf->config('payment_receipt_msgnum');
  53
  54   $conf->touch('geocode-require_nw_coordinates')
  55     if $conf->exists('svc_broadband-require-nw-coordinates');
  56
  57   unless ( $conf->config('echeck-country') ) {
  58     if ( $conf->exists('cust_main-require-bank-branch') ) {
  59       $conf->set('echeck-country', 'CA');
  60     } elsif ( $conf->exists('echeck-nonus') ) {
  61       $conf->set('echeck-country', 'XX');
  62     } else {
  63       $conf->set('echeck-country', 'US');
  64     }
  65   }
  66
  67   my @agents = qsearch('agent', {});
  68
  69   upgrade_overlimit_groups($conf);
  70   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  71
  72   upgrade_invoice_from($conf);
  73   foreach my $agent (@agents) {
  74     upgrade_invoice_from($conf,$agent->agentnum,1);
  75   }
  76
  77   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  78   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  79     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  80       qw( quotation_html quotation_latex quotation_latexnotes );
  81
  82   # change 'fslongtable' to 'longtable'
  83   # in invoice and quotation main templates, and also in all secondary
  84   # invoice templates
  85   my @latex_confs =
  86     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  87
  88   foreach my $c (@latex_confs) {
  89     my $value = $c->value;
  90     if (length($value) and $value =~ /fslongtable/) {
  91       $value =~ s/fslongtable/longtable/g;
  92       $conf->set($c->name, $value, $c->agentnum);
  93     }
  94   }
  95
  96   # if there's a USPS tools login, assume that's the standardization method
  97   # you want to use
  98   $conf->set('address_standardize_method', 'usps')
  99     if $conf->exists('usps_webtools-userid')
 100     && length($conf->config('usps_webtools-userid')) > 0
 101     && ! $conf->exists('address_standardize_method');
 102
 103   # this option has been renamed/expanded
 104   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 105     $conf->touch('cust_main-enable_spouse');
 106     $conf->delete('cust_main-enable_spouse_birthdate');
 107   }
 108
 109   # renamed/repurposed
 110   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 111     $conf->touch('part_pkg-show_fcc_options');
 112     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 113     warn "
 114 You have FCC Form 477 package options enabled.
 115
 116 Starting with the October 2014 filing date, the FCC has redesigned
 117 Form 477 and introduced new service categories.  See bin/convert-477-options
 118 to update your package configuration for the new report.
 119
 120 If you need to continue using the old Form 477 report, turn on the
 121 'old_fcc_report' configuration option.
 122 ";
 123   }
 124
 125   # boolean invoice_sections_by_location option is now
 126   # invoice_sections_method = 'location'
 127   my @invoice_sections_confs =
 128     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 129   foreach my $c (@invoice_sections_confs) {
 130     $c->name =~ /^(\w+)sections_by_location$/;
 131     $conf->delete($c->name);
 132     my $newname = $1.'sections_method';
 133     $conf->set($newname, 'location');
 134   }
 135
 136   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 137   if ( $conf->exists('enable_taxproducts') ) {
 138
 139     $conf->delete('enable_taxproducts');
 140     $conf->set('tax_data_vendor', 'cch');
 141
 142   }
 143
 144   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 145   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 146     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 147     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 148   }
 149
 150   # boolean+text previous_balance-exclude_from_total is now two separate options
 151   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 152   if (length($total_new_charges) > 0) {
 153     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 154     $conf->set('previous_balance-exclude_from_total', '');
 155   }
 156
 157   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 158
 159 }
 160
 161 sub upgrade_overlimit_groups {
 162     my $conf = shift;
 163     my $agentnum = shift;
 164     my @groups = $conf->config('overlimit_groups',$agentnum);
 165     if(scalar(@groups)) {
 166         my $groups = join(',',@groups);
 167         my @groupnums;
 168         my $error = '';
 169         if ( $groups !~ /^[\d,]+$/ ) {
 170             foreach my $groupname ( @groups ) {
 171                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 172                 unless ( $g ) {
 173                     $g = new FS::radius_group {
 174                                     'groupname' => $groupname,
 175                                     'description' => $groupname,
 176                                     };
 177                     $error = $g->insert;
 178                     die $error if $error;
 179                 }
 180                 push @groupnums, $g->groupnum;
 181             }
 182             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 183         }
 184     }
 185 }
 186
 187 sub upgrade_invoice_from {
 188   my ($conf, $agentnum, $agentonly) = @_;
 189   if (
 190       (!$conf->exists('invoice_from_name',$agentnum,$agentonly)) &&
 191       ($conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/)
 192   ) {
 193     my $realemail = $1;
 194     $realemail =~ s/^\s*//; # remove leading spaces
 195     $realemail =~ s/\s*$//; # remove trailing spaces
 196     my $realname = $conf->config('invoice_from',$agentnum);
 197     $realname =~ s/\<.*\>//; # remove email address
 198     $realname =~ s/^\s*//; # remove leading spaces
 199     $realname =~ s/\s*$//; # remove trailing spaces
 200     # properly quote names that contain punctuation
 201     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 202       $realname = '"' . $realname . '"';
 203     }
 204     $conf->set('invoice_from_name', $realname, $agentnum);
 205     $conf->set('invoice_from', $realemail, $agentnum);
 206   }
 207 }
 208
 209 =item upgrade
 210
 211 =cut
 212
 213 sub upgrade {
 214   my %opt = @_;
 215
 216   my $data = upgrade_data(%opt);
 217
 218   my $oldAutoCommit = $FS::UID::AutoCommit;
 219   local $FS::UID::AutoCommit = 0;
 220   local $FS::UID::AutoCommit = 0;
 221
 222   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 223
 224
 225   foreach my $table ( keys %$data ) {
 226
 227     my $class = "FS::$table";
 228     eval "use $class;";
 229     die $@ if $@;
 230
 231     if ( $class->can('_upgrade_data') ) {
 232       warn "Upgrading $table...\n";
 233
 234       my $start = time;
 235
 236       $class->_upgrade_data(%opt);
 237
 238       # New interface for async upgrades: a class can declare a
 239       # "queueable_upgrade" method, which will run as part of the normal
 240       # upgrade, but if the -j option is passed, will instead be run from
 241       # the job queue.
 242       if ( $class->can('queueable_upgrade') ) {
 243         my $jobname = $class . '::queueable_upgrade';
 244         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 245         if ($num_jobs > 0) {
 246           warn "$class upgrade already scheduled.\n";
 247         } else {
 248           if ( $opt{'queue'} ) {
 249             warn "Scheduling $class upgrade.\n";
 250             my $job = FS::queue->new({ job => $jobname });
 251             $job->insert($class, %opt);
 252           } else {
 253             $class->queueable_upgrade(%opt);
 254           }
 255         } #$num_jobs == 0
 256       }
 257
 258       if ( $oldAutoCommit ) {
 259         warn "  committing\n";
 260         dbh->commit or die dbh->errstr;
 261       }
 262
 263       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 264       warn "  done in ". (time-$start). " seconds\n";
 265
 266     } else {
 267       warn "WARNING: asked for upgrade of $table,".
 268            " but FS::$table has no _upgrade_data method\n";
 269     }
 270
 271 #    my @records = @{ $data->{$table} };
 272 #
 273 #    foreach my $record ( @records ) {
 274 #      my $args = delete($record->{'_upgrade_args'}) || [];
 275 #      my $object = $class->new( $record );
 276 #      my $error = $object->insert( @$args );
 277 #      die "error inserting record into $table: $error\n"
 278 #        if $error;
 279 #    }
 280
 281   }
 282
 283   local($FS::cust_main::ignore_expired_card) = 1;
 284   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 285   local($FS::cust_main::ignore_banned_card) = 1;
 286   local($FS::cust_main::skip_fuzzyfiles) = 1;
 287
 288   local($FS::cust_payby::ignore_expired_card) = 1;
 289   local($FS::cust_payby::ignore_banned_card) = 1;
 290
 291   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 292   # kind of a weird spot for this, but it's better than duplicating
 293   # all this code in each class...
 294   my @decrypt_tables = qw( cust_main cust_pay_void cust_pay cust_refund cust_pay_pending );
 295   foreach my $table ( @decrypt_tables ) {
 296       my @objects = qsearch({
 297         'table'     => $table,
 298         'hashref'   => {},
 299         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 300                        " AND LENGTH(payinfo) > 100",
 301       });
 302       foreach my $object ( @objects ) {
 303           my $payinfo = $object->decrypt($object->payinfo);
 304           die "error decrypting payinfo" if $payinfo eq $object->payinfo;
 305           $object->payinfo($payinfo);
 306           my $error = $object->replace;
 307           die $error if $error;
 308       }
 309   }
 310
 311 }
 312
 313 =item upgrade_data
 314
 315 =cut
 316
 317 sub upgrade_data {
 318   my %opt = @_;
 319
 320   tie my %hash, 'Tie::IxHash',
 321
 322     #payby conditions to new ones
 323     'part_event_condition' => [],
 324
 325     #payby actions to new ones
 326     'part_event' => [],
 327
 328     #cust_main (remove paycvv from history, locations, cust_payby, etc)
 329     'cust_main' => [],
 330
 331     #contact -> cust_contact / prospect_contact
 332     'contact' => [],
 333
 334     #msgcat
 335     'msgcat' => [],
 336
 337     #reason type and reasons
 338     'reason_type'     => [],
 339     'cust_pkg_reason' => [],
 340
 341     #need part_pkg before cust_credit...
 342     'part_pkg' => [],
 343
 344     #customer credits
 345     'cust_credit' => [],
 346
 347     # reason / void_reason migration to reasonnum / void_reasonnum
 348     'cust_credit_void' => [],
 349     'cust_bill_void' => [],
 350     'cust_bill_pkg_void' => [],
 351
 352     #duplicate history records
 353     'h_cust_svc'  => [],
 354
 355     #populate cust_pay.otaker
 356     'cust_pay'    => [],
 357
 358     #populate part_pkg_taxclass for starters
 359     'part_pkg_taxclass' => [],
 360
 361     #remove bad pending records
 362     'cust_pay_pending' => [],
 363
 364     #replace invnum and pkgnum with billpkgnum
 365     'cust_bill_pkg_detail' => [],
 366
 367     #usage_classes if we have none
 368     'usage_class' => [],
 369
 370     #phone_type if we have none
 371     'phone_type' => [],
 372
 373     #fixup access rights
 374     'access_right' => [],
 375
 376     #change recur_flat and enable_prorate
 377     'part_pkg_option' => [],
 378
 379     #add weights to pkg_category
 380     'pkg_category' => [],
 381
 382     #cdrbatch fixes
 383     'cdr' => [],
 384
 385     #otaker->usernum
 386     'cust_attachment' => [],
 387     #'cust_credit' => [],
 388     #'cust_main' => [],
 389     'cust_main_note' => [],
 390     #'cust_pay' => [],
 391     'cust_pay_void' => [],
 392     'cust_pkg' => [],
 393     #'cust_pkg_reason' => [],
 394     'cust_pkg_discount' => [],
 395     'cust_refund' => [],
 396     'banned_pay' => [],
 397
 398     #default namespace
 399     'payment_gateway' => [],
 400
 401     #migrate to templates
 402     'msg_template' => [],
 403
 404     #return unprovisioned numbers to availability
 405     'phone_avail' => [],
 406
 407     #insert scripcondition
 408     'TicketSystem' => [],
 409
 410     #insert LATA data if not already present
 411     'lata' => [],
 412
 413     #insert MSA data if not already present
 414     'msa' => [],
 415
 416     # migrate to radius_group and groupnum instead of groupname
 417     'radius_usergroup' => [],
 418     'part_svc'         => [],
 419     'part_export'      => [],
 420
 421     #insert default tower_sector if not present
 422     'tower' => [],
 423
 424     #repair improperly deleted services
 425     'cust_svc' => [],
 426
 427     #routernum/blocknum
 428     'svc_broadband' => [],
 429
 430     #set up payment gateways if needed
 431     'pay_batch' => [],
 432
 433     #flag monthly tax exemptions
 434     'cust_tax_exempt_pkg' => [],
 435
 436     #kick off tax location history upgrade
 437     'cust_bill_pkg' => [],
 438
 439     #fix taxable line item links
 440     'cust_bill_pkg_tax_location' => [],
 441
 442     #populate state FIPS codes if not already done
 443     'state' => [],
 444
 445     #set default locations on quoted packages
 446     'quotation_pkg' => [],
 447
 448     #populate tax statuses
 449     'tax_status' => [],
 450   ;
 451
 452   \%hash;
 453
 454 }
 455
 456 =item upgrade_schema
 457
 458 =cut
 459
 460 sub upgrade_schema {
 461   my %opt = @_;
 462
 463   my $data = upgrade_schema_data(%opt);
 464
 465   my $oldAutoCommit = $FS::UID::AutoCommit;
 466   local $FS::UID::AutoCommit = 0;
 467   local $FS::UID::AutoCommit = 0;
 468
 469   foreach my $table ( keys %$data ) {
 470
 471     my $class = "FS::$table";
 472     eval "use $class;";
 473     die $@ if $@;
 474
 475     if ( $class->can('_upgrade_schema') ) {
 476       warn "Upgrading $table schema...\n";
 477
 478       my $start = time;
 479
 480       $class->_upgrade_schema(%opt);
 481
 482       if ( $oldAutoCommit ) {
 483         warn "  committing\n";
 484         dbh->commit or die dbh->errstr;
 485       }
 486
 487       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 488       warn "  done in ". (time-$start). " seconds\n";
 489
 490     } else {
 491       warn "WARNING: asked for schema upgrade of $table,".
 492            " but FS::$table has no _upgrade_schema method\n";
 493     }
 494
 495   }
 496
 497 }
 498
 499 =item upgrade_schema_data
 500
 501 =cut
 502
 503 sub upgrade_schema_data {
 504   my %opt = @_;
 505
 506   tie my %hash, 'Tie::IxHash',
 507
 508     #fix classnum character(1)
 509     'cust_bill_pkg_detail' => [],
 510     #add necessary columns to RT schema
 511     'TicketSystem' => [],
 512
 513   ;
 514
 515   \%hash;
 516
 517 }
 518
 519 sub upgrade_sqlradius {
 520   #my %opt = @_;
 521
 522   my $conf = new FS::Conf;
 523
 524   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 525
 526   foreach my $part_export ( @part_export ) {
 527
 528     my $errmsg = 'Error adding FreesideStatus to '.
 529                  $part_export->option('datasrc'). ': ';
 530
 531     my $dbh = DBI->connect(
 532       ( map $part_export->option($_), qw ( datasrc username password ) ),
 533       { PrintError => 0, PrintWarn => 0 }
 534     ) or do {
 535       warn $errmsg.$DBI::errstr;
 536       next;
 537     };
 538
 539     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 540     my $group = "UserName";
 541     $group .= ",Realm"
 542       if ref($part_export) =~ /withdomain/
 543       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 544
 545     my $sth_alter = $dbh->prepare(
 546       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 547     );
 548     if ( $sth_alter ) {
 549       if ( $sth_alter->execute ) {
 550         my $sth_update = $dbh->prepare(
 551          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 552         ) or die $errmsg.$dbh->errstr;
 553         $sth_update->execute or die $errmsg.$sth_update->errstr;
 554       } else {
 555         my $error = $sth_alter->errstr;
 556         warn $errmsg.$error
 557           unless $error =~ /Duplicate column name/i  #mysql
 558               || $error =~ /already exists/i;        #Pg
 559 ;
 560       }
 561     } else {
 562       my $error = $dbh->errstr;
 563       warn $errmsg.$error; #unless $error =~ /exists/i;
 564     }
 565
 566     my $sth_index = $dbh->prepare(
 567       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 568     );
 569     if ( $sth_index ) {
 570       unless ( $sth_index->execute ) {
 571         my $error = $sth_index->errstr;
 572         warn $errmsg.$error
 573           unless $error =~ /Duplicate key name/i #mysql
 574               || $error =~ /already exists/i;    #Pg
 575       }
 576     } else {
 577       my $error = $dbh->errstr;
 578       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 579     }
 580
 581     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 582       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 583       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 584
 585     my $sth = $dbh->prepare("SELECT UserName,
 586                                     Realm,
 587                                     $str2time max(AcctStartTime)),
 588                                     $str2time max(AcctStopTime))
 589                               FROM radacct
 590                               WHERE FreesideStatus = 'done'
 591                                 AND $times
 592                               GROUP BY $group
 593                             ")
 594       or die $errmsg.$dbh->errstr;
 595     $sth->execute() or die $errmsg.$sth->errstr;
 596
 597     while (my $row = $sth->fetchrow_arrayref ) {
 598       my ($username, $realm, $start, $stop) = @$row;
 599
 600       $username = lc($username) unless $conf->exists('username-uppercase');
 601
 602       my $exportnum = $part_export->exportnum;
 603       my $extra_sql = " AND exportnum = $exportnum ".
 604                       " AND exportsvcnum IS NOT NULL ";
 605
 606       if ( ref($part_export) =~ /withdomain/ ) {
 607         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 608                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 609       }
 610
 611       my $svc_acct = qsearchs({
 612         'select'    => 'svc_acct.*',
 613         'table'     => 'svc_acct',
 614         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 615                        'LEFT JOIN export_svc USING ( svcpart )',
 616         'hashref'   => { 'username' => $username },
 617         'extra_sql' => $extra_sql,
 618       });
 619
 620       if ($svc_acct) {
 621         $svc_acct->last_login($start)
 622           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 623         $svc_acct->last_logout($stop)
 624           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 625       }
 626     }
 627   }
 628
 629 }
 630
 631 =back
 632
 633 =head1 BUGS
 634
 635 Sure.
 636
 637 =head1 SEE ALSO
 638
 639 =cut
 640
 641 1;
 642