FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   $conf->touch('payment_receipt')
  51     if $conf->exists('payment_receipt_email')
  52     || $conf->config('payment_receipt_msgnum');
  53
  54   $conf->touch('geocode-require_nw_coordinates')
  55     if $conf->exists('svc_broadband-require-nw-coordinates');
  56
  57   unless ( $conf->config('echeck-country') ) {
  58     if ( $conf->exists('cust_main-require-bank-branch') ) {
  59       $conf->set('echeck-country', 'CA');
  60     } elsif ( $conf->exists('echeck-nonus') ) {
  61       $conf->set('echeck-country', 'XX');
  62     } else {
  63       $conf->set('echeck-country', 'US');
  64     }
  65   }
  66
  67   my @agents = qsearch('agent', {});
  68
  69   upgrade_overlimit_groups($conf);
  70   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  71
  72   upgrade_invoice_from($conf);
  73   foreach my $agent (@agents) {
  74     upgrade_invoice_from($conf,$agent->agentnum,1);
  75   }
  76
  77   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  78   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  79     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  80       qw( quotation_html quotation_latex quotation_latexnotes );
  81
  82   # change 'fslongtable' to 'longtable'
  83   # in invoice and quotation main templates, and also in all secondary
  84   # invoice templates
  85   my @latex_confs =
  86     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  87
  88   foreach my $c (@latex_confs) {
  89     my $value = $c->value;
  90     if (length($value) and $value =~ /fslongtable/) {
  91       $value =~ s/fslongtable/longtable/g;
  92       $conf->set($c->name, $value, $c->agentnum);
  93     }
  94   }
  95
  96   # if there's a USPS tools login, assume that's the standardization method
  97   # you want to use
  98   $conf->set('address_standardize_method', 'usps')
  99     if $conf->exists('usps_webtools-userid')
 100     && length($conf->config('usps_webtools-userid')) > 0
 101     && ! $conf->exists('address_standardize_method');
 102
 103   # this option has been renamed/expanded
 104   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 105     $conf->touch('cust_main-enable_spouse');
 106     $conf->delete('cust_main-enable_spouse_birthdate');
 107   }
 108
 109   # renamed/repurposed
 110   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 111     $conf->touch('part_pkg-show_fcc_options');
 112     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 113     warn "
 114 You have FCC Form 477 package options enabled.
 115
 116 Starting with the October 2014 filing date, the FCC has redesigned
 117 Form 477 and introduced new service categories.  See bin/convert-477-options
 118 to update your package configuration for the new report.
 119
 120 If you need to continue using the old Form 477 report, turn on the
 121 'old_fcc_report' configuration option.
 122 ";
 123   }
 124
 125   # boolean invoice_sections_by_location option is now
 126   # invoice_sections_method = 'location'
 127   my @invoice_sections_confs =
 128     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 129   foreach my $c (@invoice_sections_confs) {
 130     $c->name =~ /^(\w+)sections_by_location$/;
 131     $conf->delete($c->name);
 132     my $newname = $1.'sections_method';
 133     $conf->set($newname, 'location');
 134   }
 135
 136   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 137   if ( $conf->exists('enable_taxproducts') ) {
 138
 139     $conf->delete('enable_taxproducts');
 140     $conf->set('tax_data_vendor', 'cch');
 141
 142   }
 143
 144   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 145   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 146     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 147     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 148   }
 149
 150   # boolean+text previous_balance-exclude_from_total is now two separate options
 151   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 152   if (length($total_new_charges) > 0) {
 153     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 154     $conf->set('previous_balance-exclude_from_total', '');
 155   }
 156
 157   # switch from specifying an email address to boolean check
 158   if ( $conf->exists('batch-errors_to') ) {
 159     $conf->touch('batch-errors_not_fatal');
 160     $conf->delete('batch-errors_to');
 161   }
 162
 163   if ( $conf->exists('voip-cust_email_csv_cdr') ) {
 164     $conf->set('voip_cdr_email_attach', 'csv');
 165     $conf->delete('voip-cust_email_csv_cdr') ;
 166   }
 167
 168   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 169
 170 }
 171
 172 sub upgrade_overlimit_groups {
 173     my $conf = shift;
 174     my $agentnum = shift;
 175     my @groups = $conf->config('overlimit_groups',$agentnum);
 176     if(scalar(@groups)) {
 177         my $groups = join(',',@groups);
 178         my @groupnums;
 179         my $error = '';
 180         if ( $groups !~ /^[\d,]+$/ ) {
 181             foreach my $groupname ( @groups ) {
 182                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 183                 unless ( $g ) {
 184                     $g = new FS::radius_group {
 185                                     'groupname' => $groupname,
 186                                     'description' => $groupname,
 187                                     };
 188                     $error = $g->insert;
 189                     die $error if $error;
 190                 }
 191                 push @groupnums, $g->groupnum;
 192             }
 193             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 194         }
 195     }
 196 }
 197
 198 sub upgrade_invoice_from {
 199   my ($conf, $agentnum, $agentonly) = @_;
 200   if (
 201       (!$conf->exists('invoice_from_name',$agentnum,$agentonly)) &&
 202       ($conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/)
 203   ) {
 204     my $realemail = $1;
 205     $realemail =~ s/^\s*//; # remove leading spaces
 206     $realemail =~ s/\s*$//; # remove trailing spaces
 207     my $realname = $conf->config('invoice_from',$agentnum);
 208     $realname =~ s/\<.*\>//; # remove email address
 209     $realname =~ s/^\s*//; # remove leading spaces
 210     $realname =~ s/\s*$//; # remove trailing spaces
 211     # properly quote names that contain punctuation
 212     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 213       $realname = '"' . $realname . '"';
 214     }
 215     $conf->set('invoice_from_name', $realname, $agentnum);
 216     $conf->set('invoice_from', $realemail, $agentnum);
 217   }
 218 }
 219
 220 =item upgrade
 221
 222 =cut
 223
 224 sub upgrade {
 225   my %opt = @_;
 226
 227   my $data = upgrade_data(%opt);
 228
 229   my $oldAutoCommit = $FS::UID::AutoCommit;
 230   local $FS::UID::AutoCommit = 0;
 231   local $FS::UID::AutoCommit = 0;
 232
 233   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 234
 235
 236   foreach my $table ( keys %$data ) {
 237
 238     my $class = "FS::$table";
 239     eval "use $class;";
 240     die $@ if $@;
 241
 242     if ( $class->can('_upgrade_data') ) {
 243       warn "Upgrading $table...\n";
 244
 245       my $start = time;
 246
 247       $class->_upgrade_data(%opt);
 248
 249       # New interface for async upgrades: a class can declare a
 250       # "queueable_upgrade" method, which will run as part of the normal
 251       # upgrade, but if the -j option is passed, will instead be run from
 252       # the job queue.
 253       if ( $class->can('queueable_upgrade') ) {
 254         my $jobname = $class . '::queueable_upgrade';
 255         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 256         if ($num_jobs > 0) {
 257           warn "$class upgrade already scheduled.\n";
 258         } else {
 259           if ( $opt{'queue'} ) {
 260             warn "Scheduling $class upgrade.\n";
 261             my $job = FS::queue->new({ job => $jobname });
 262             $job->insert($class, %opt);
 263           } else {
 264             $class->queueable_upgrade(%opt);
 265           }
 266         } #$num_jobs == 0
 267       }
 268
 269       if ( $oldAutoCommit ) {
 270         warn "  committing\n";
 271         dbh->commit or die dbh->errstr;
 272       }
 273
 274       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 275       warn "  done in ". (time-$start). " seconds\n";
 276
 277     } else {
 278       warn "WARNING: asked for upgrade of $table,".
 279            " but FS::$table has no _upgrade_data method\n";
 280     }
 281
 282 #    my @records = @{ $data->{$table} };
 283 #
 284 #    foreach my $record ( @records ) {
 285 #      my $args = delete($record->{'_upgrade_args'}) || [];
 286 #      my $object = $class->new( $record );
 287 #      my $error = $object->insert( @$args );
 288 #      die "error inserting record into $table: $error\n"
 289 #        if $error;
 290 #    }
 291
 292   }
 293
 294   local($FS::cust_main::ignore_expired_card) = 1;
 295   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 296   local($FS::cust_main::ignore_banned_card) = 1;
 297   local($FS::cust_main::skip_fuzzyfiles) = 1;
 298
 299   local($FS::cust_payby::ignore_expired_card) = 1;
 300   local($FS::cust_payby::ignore_banned_card) = 1;
 301
 302   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 303   # kind of a weird spot for this, but it's better than duplicating
 304   # all this code in each class...
 305   my @decrypt_tables = qw( cust_payby cust_pay_void cust_pay cust_refund cust_pay_pending );
 306   foreach my $table ( @decrypt_tables ) {
 307       my @objects = qsearch({
 308         'table'     => $table,
 309         'hashref'   => {},
 310         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 311                        " AND LENGTH(payinfo) > 100",
 312       });
 313       foreach my $object ( @objects ) {
 314           my $payinfo = $object->decrypt($object->payinfo);
 315           die "error decrypting payinfo" if $payinfo eq $object->payinfo;
 316           $object->payinfo($payinfo);
 317           my $error = $object->replace;
 318           die $error if $error;
 319       }
 320   }
 321
 322 }
 323
 324 =item upgrade_data
 325
 326 =cut
 327
 328 sub upgrade_data {
 329   my %opt = @_;
 330
 331   tie my %hash, 'Tie::IxHash',
 332
 333     #payby conditions to new ones
 334     'part_event_condition' => [],
 335
 336     #payby actions to new ones
 337     'part_event' => [],
 338
 339     #cust_main (remove paycvv from history, locations, cust_payby, etc)
 340     'cust_main' => [],
 341
 342     #contact -> cust_contact / prospect_contact
 343     'contact' => [],
 344
 345     #msgcat
 346     'msgcat' => [],
 347
 348     #reason type and reasons
 349     'reason_type'     => [],
 350     'cust_pkg_reason' => [],
 351
 352     #need part_pkg before cust_credit...
 353     'part_pkg' => [],
 354
 355     #customer credits
 356     'cust_credit' => [],
 357
 358     # reason / void_reason migration to reasonnum / void_reasonnum
 359     'cust_credit_void' => [],
 360     'cust_bill_void' => [],
 361     'cust_bill_pkg_void' => [],
 362
 363     #duplicate history records
 364     'h_cust_svc'  => [],
 365
 366     #populate cust_pay.otaker
 367     'cust_pay'    => [],
 368
 369     #populate part_pkg_taxclass for starters
 370     'part_pkg_taxclass' => [],
 371
 372     #remove bad pending records
 373     'cust_pay_pending' => [],
 374
 375     #replace invnum and pkgnum with billpkgnum
 376     'cust_bill_pkg_detail' => [],
 377
 378     #usage_classes if we have none
 379     'usage_class' => [],
 380
 381     #phone_type if we have none
 382     'phone_type' => [],
 383
 384     #fixup access rights
 385     'access_right' => [],
 386
 387     #change recur_flat and enable_prorate
 388     'part_pkg_option' => [],
 389
 390     #add weights to pkg_category
 391     'pkg_category' => [],
 392
 393     #cdrbatch fixes
 394     'cdr' => [],
 395
 396     #otaker->usernum
 397     'cust_attachment' => [],
 398     #'cust_credit' => [],
 399     #'cust_main' => [],
 400     'cust_main_note' => [],
 401     #'cust_pay' => [],
 402     'cust_pay_void' => [],
 403     'cust_pkg' => [],
 404     #'cust_pkg_reason' => [],
 405     'cust_pkg_discount' => [],
 406     'cust_refund' => [],
 407     'banned_pay' => [],
 408
 409     #default namespace
 410     'payment_gateway' => [],
 411
 412     #migrate to templates
 413     'msg_template' => [],
 414
 415     #return unprovisioned numbers to availability
 416     'phone_avail' => [],
 417
 418     #insert scripcondition
 419     'TicketSystem' => [],
 420
 421     #insert LATA data if not already present
 422     'lata' => [],
 423
 424     #insert MSA data if not already present
 425     'msa' => [],
 426
 427     # migrate to radius_group and groupnum instead of groupname
 428     'radius_usergroup' => [],
 429     'part_svc'         => [],
 430     'part_export'      => [],
 431
 432     #insert default tower_sector if not present
 433     'tower' => [],
 434
 435     #repair improperly deleted services
 436     'cust_svc' => [],
 437
 438     #routernum/blocknum
 439     'svc_broadband' => [],
 440
 441     #set up payment gateways if needed
 442     'pay_batch' => [],
 443
 444     #flag monthly tax exemptions
 445     'cust_tax_exempt_pkg' => [],
 446
 447     #kick off tax location history upgrade
 448     'cust_bill_pkg' => [],
 449
 450     #fix taxable line item links
 451     'cust_bill_pkg_tax_location' => [],
 452
 453     #populate state FIPS codes if not already done
 454     'state' => [],
 455
 456     #set default locations on quoted packages
 457     'quotation_pkg' => [],
 458
 459     #populate tax statuses
 460     'tax_status' => [],
 461   ;
 462
 463   \%hash;
 464
 465 }
 466
 467 =item upgrade_schema
 468
 469 =cut
 470
 471 sub upgrade_schema {
 472   my %opt = @_;
 473
 474   my $data = upgrade_schema_data(%opt);
 475
 476   my $oldAutoCommit = $FS::UID::AutoCommit;
 477   local $FS::UID::AutoCommit = 0;
 478   local $FS::UID::AutoCommit = 0;
 479
 480   foreach my $table ( keys %$data ) {
 481
 482     my $class = "FS::$table";
 483     eval "use $class;";
 484     die $@ if $@;
 485
 486     if ( $class->can('_upgrade_schema') ) {
 487       warn "Upgrading $table schema...\n";
 488
 489       my $start = time;
 490
 491       $class->_upgrade_schema(%opt);
 492
 493       if ( $oldAutoCommit ) {
 494         warn "  committing\n";
 495         dbh->commit or die dbh->errstr;
 496       }
 497
 498       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 499       warn "  done in ". (time-$start). " seconds\n";
 500
 501     } else {
 502       warn "WARNING: asked for schema upgrade of $table,".
 503            " but FS::$table has no _upgrade_schema method\n";
 504     }
 505
 506   }
 507
 508 }
 509
 510 =item upgrade_schema_data
 511
 512 =cut
 513
 514 sub upgrade_schema_data {
 515   my %opt = @_;
 516
 517   tie my %hash, 'Tie::IxHash',
 518
 519     #fix classnum character(1)
 520     'cust_bill_pkg_detail' => [],
 521     #add necessary columns to RT schema
 522     'TicketSystem' => [],
 523
 524   ;
 525
 526   \%hash;
 527
 528 }
 529
 530 sub upgrade_sqlradius {
 531   #my %opt = @_;
 532
 533   my $conf = new FS::Conf;
 534
 535   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 536
 537   foreach my $part_export ( @part_export ) {
 538
 539     my $errmsg = 'Error adding FreesideStatus to '.
 540                  $part_export->option('datasrc'). ': ';
 541
 542     my $dbh = DBI->connect(
 543       ( map $part_export->option($_), qw ( datasrc username password ) ),
 544       { PrintError => 0, PrintWarn => 0 }
 545     ) or do {
 546       warn $errmsg.$DBI::errstr;
 547       next;
 548     };
 549
 550     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 551     my $group = "UserName";
 552     $group .= ",Realm"
 553       if ref($part_export) =~ /withdomain/
 554       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 555
 556     my $sth_alter = $dbh->prepare(
 557       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 558     );
 559     if ( $sth_alter ) {
 560       if ( $sth_alter->execute ) {
 561         my $sth_update = $dbh->prepare(
 562          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 563         ) or die $errmsg.$dbh->errstr;
 564         $sth_update->execute or die $errmsg.$sth_update->errstr;
 565       } else {
 566         my $error = $sth_alter->errstr;
 567         warn $errmsg.$error
 568           unless $error =~ /Duplicate column name/i  #mysql
 569               || $error =~ /already exists/i;        #Pg
 570 ;
 571       }
 572     } else {
 573       my $error = $dbh->errstr;
 574       warn $errmsg.$error; #unless $error =~ /exists/i;
 575     }
 576
 577     my $sth_index = $dbh->prepare(
 578       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 579     );
 580     if ( $sth_index ) {
 581       unless ( $sth_index->execute ) {
 582         my $error = $sth_index->errstr;
 583         warn $errmsg.$error
 584           unless $error =~ /Duplicate key name/i #mysql
 585               || $error =~ /already exists/i;    #Pg
 586       }
 587     } else {
 588       my $error = $dbh->errstr;
 589       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 590     }
 591
 592     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 593       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 594       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 595
 596     my $sth = $dbh->prepare("SELECT UserName,
 597                                     Realm,
 598                                     $str2time max(AcctStartTime)),
 599                                     $str2time max(AcctStopTime))
 600                               FROM radacct
 601                               WHERE FreesideStatus = 'done'
 602                                 AND $times
 603                               GROUP BY $group
 604                             ")
 605       or die $errmsg.$dbh->errstr;
 606     $sth->execute() or die $errmsg.$sth->errstr;
 607
 608     while (my $row = $sth->fetchrow_arrayref ) {
 609       my ($username, $realm, $start, $stop) = @$row;
 610
 611       $username = lc($username) unless $conf->exists('username-uppercase');
 612
 613       my $exportnum = $part_export->exportnum;
 614       my $extra_sql = " AND exportnum = $exportnum ".
 615                       " AND exportsvcnum IS NOT NULL ";
 616
 617       if ( ref($part_export) =~ /withdomain/ ) {
 618         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 619                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 620       }
 621
 622       my $svc_acct = qsearchs({
 623         'select'    => 'svc_acct.*',
 624         'table'     => 'svc_acct',
 625         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 626                        'LEFT JOIN export_svc USING ( svcpart )',
 627         'hashref'   => { 'username' => $username },
 628         'extra_sql' => $extra_sql,
 629       });
 630
 631       if ($svc_acct) {
 632         $svc_acct->last_login($start)
 633           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 634         $svc_acct->last_logout($stop)
 635           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 636       }
 637     }
 638   }
 639
 640 }
 641
 642 =back
 643
 644 =head1 BUGS
 645
 646 Sure.
 647
 648 =head1 SEE ALSO
 649
 650 =cut
 651
 652 1;
 653