FS/FS/UI/Web.pm

   1 package FS::UI::Web;
   2
   3 use strict;
   4 use vars qw($DEBUG @ISA @EXPORT_OK $me);
   5 use Exporter;
   6 use Carp qw( confess );
   7 use HTML::Entities;
   8 use FS::Conf;
   9 use FS::Misc::DateTime qw( parse_datetime day_end );
  10 use FS::Record qw(dbdef qsearch);
  11 use FS::cust_main;  # are sql_balance and sql_date_balance in the right module?
  12
  13 #use vars qw(@ISA);
  14 #use FS::UI
  15 #@ISA = qw( FS::UI );
  16 @ISA = qw( Exporter );
  17
  18 @EXPORT_OK = qw( get_page_pref set_page_pref svc_url random_id );
  19
  20 $DEBUG = 0;
  21 $me = '[FS::UID::Web]';
  22
  23 our $NO_RANDOM_IDS;
  24
  25 ###
  26 # user prefs
  27 ###
  28
  29 =item get_page_pref NAME, TABLENUM
  30
  31 Returns the user's page preference named NAME for the current page. If the
  32 page is a view or edit page or otherwise shows a single record at a time,
  33 it should use TABLENUM to link the preference to that record.
  34
  35 =cut
  36
  37 sub get_page_pref {
  38   my ($prefname, $tablenum) = @_;
  39
  40   my $m = $HTML::Mason::Commands::m
  41     or die "can't get page pref when running outside the UI";
  42   # what's more useful: to tie prefs to the base_comp (usually where
  43   # code is executing right now), or to the request_comp (approximately the
  44   # one in the URL)? not sure.
  45   $FS::CurrentUser::CurrentUser->get_page_pref( $m->request_comp->path,
  46                                                 $prefname,
  47                                                 $tablenum
  48                                               );
  49 }
  50
  51 =item set_page_pref NAME, TABLENUM, VALUE
  52
  53 Sets the user's page preference named NAME for the current page. Use TABLENUM
  54 as for get_page_pref.
  55
  56 If VALUE is an empty string, the preference will be deleted (and
  57 C<get_page_pref> will return an empty string).
  58
  59   my $mypref = set_page_pref('mypref', '', 100);
  60
  61 =cut
  62
  63 sub set_page_pref {
  64   my ($prefname, $tablenum, $prefvalue) = @_;
  65
  66   my $m = $HTML::Mason::Commands::m
  67     or die "can't set page pref when running outside the UI";
  68   $FS::CurrentUser::CurrentUser->set_page_pref( $m->request_comp->path,
  69                                                 $prefname,
  70                                                 $tablenum,
  71                                                 $prefvalue );
  72 }
  73
  74 ###
  75 # date parsing
  76 ###
  77
  78 =item parse_beginning_ending CGI [, PREFIX ]
  79
  80 Parses a beginning/ending date range, as used on many reports. This function
  81 recognizes two sets of CGI params: "begin" and "end", the integer timestamp
  82 values, and "beginning" and "ending", the user-readable date fields.
  83
  84 If "begin" contains an integer, that's passed through as the beginning date.
  85 Otherwise, "beginning" is passed to L<DateTime::Format::Natural> and turned
  86 into an integer. If this fails or it doesn't have a value, zero is used as the
  87 beginning date.
  88
  89 The same happens for "end" and "ending", except that if "ending" contains a
  90 date without a time, it gets moved to the end of that day, and if there's no
  91 value, the value returned is the highest unsigned 32-bit time value (some time
  92 in 2037).
  93
  94 PREFIX is optionally a string to prepend (with '_' as a delimiter) to the form
  95 field names.
  96
  97 =cut
  98
  99 use Date::Parse;
 100 sub parse_beginning_ending {
 101   my($cgi, $prefix) = @_;
 102   $prefix .= '_' if $prefix;
 103
 104   my $beginning = 0;
 105   if ( $cgi->param($prefix.'begin') =~ /^(\d+)$/ ) {
 106     $beginning = $1;
 107   } elsif ( $cgi->param($prefix.'beginning') =~ /^([ 0-9\-\/\:]{1,64})$/ ) {
 108     $beginning = parse_datetime($1) || 0;
 109   }
 110
 111   my $ending = 4294967295; #2^32-1
 112   if ( $cgi->param($prefix.'end') =~ /^(\d+)$/ ) {
 113     $ending = $1 - 1;
 114   } elsif ( $cgi->param($prefix.'ending') =~ /^([ 0-9\-\/\:]{1,64})$/ ) {
 115     $ending = parse_datetime($1);
 116     $ending = day_end($ending) unless $ending =~ /:/;
 117   }
 118
 119   ( $beginning, $ending );
 120 }
 121
 122 =item svc_url
 123
 124 Returns a service URL, first checking to see if there is a service-specific
 125 page to link to, otherwise to a generic service handling page.  Options are
 126 passed as a list of name-value pairs, and include:
 127
 128 =over 4
 129
 130 =item * m - Mason request object ($m)
 131
 132 =item * action - The action for which to construct "edit", "view", or "search"
 133
 134 =item ** part_svc - Service definition (see L<FS::part_svc>)
 135
 136 =item ** svcdb - Service table
 137
 138 =item *** query - Query string
 139
 140 =item *** svc   - FS::cust_svc or FS::svc_* object
 141
 142 =item ahref - Optional flag, if set true returns <A HREF="$url"> instead of just the URL.
 143
 144 =back
 145
 146 * Required fields
 147
 148 ** part_svc OR svcdb is required
 149
 150 *** query OR svc is required
 151
 152 =cut
 153
 154   # ##
 155   # #required
 156   # ##
 157   #  'm'        => $m, #mason request object
 158   #  'action'   => 'edit', #or 'view'
 159   #
 160   #  'part_svc' => $part_svc, #usual
 161   #   #OR
 162   #  'svcdb'    => 'svc_table',
 163   #
 164   #  'query'    => #optional query string
 165   #                # (pass a blank string if you want a "raw" URL to add your
 166   #                #  own svcnum to)
 167   #   #OR
 168   #  'svc'      => $svc_x, #or $cust_svc, it just needs a svcnum
 169   #
 170   # ##
 171   # #optional
 172   # ##
 173   #  'ahref'    => 1, # if set true, returns <A HREF="$url">
 174
 175 use FS::CGI qw(rooturl);
 176 sub svc_url {
 177   my %opt = @_;
 178
 179   #? return '' unless ref($opt{part_svc});
 180
 181   my $svcdb = $opt{svcdb} || $opt{part_svc}->svcdb;
 182   my $query = exists($opt{query}) ? $opt{query} : $opt{svc}->svcnum;
 183   my $url;
 184   warn "$me [svc_url] checking for /$opt{action}/$svcdb.cgi component"
 185     if $DEBUG;
 186   if ( $opt{m}->interp->comp_exists("/$opt{action}/$svcdb.cgi") ) {
 187     $url = "$svcdb.cgi?";
 188   } elsif ( $opt{m}->interp->comp_exists("/$opt{action}/$svcdb.html") ) {
 189     $url = "$svcdb.html?";
 190   } else {
 191     my $generic = $opt{action} eq 'search' ? 'cust_svc' : 'svc_Common';
 192
 193     $url = "$generic.html?svcdb=$svcdb;";
 194     $url .= 'svcnum=' if $query =~ /^\d+(;|$)/ or $query eq '';
 195   }
 196
 197   my $return = FS::CGI::rooturl(). "$opt{action}/$url$query";
 198
 199   $return = qq!<A HREF="$return">! if $opt{ahref};
 200
 201   $return;
 202 }
 203
 204 sub svc_link {
 205   my($m, $part_svc, $cust_svc) = @_ or return '';
 206   svc_X_link( $part_svc->svc, @_ );
 207 }
 208
 209 sub svc_label_link {
 210   my($m, $part_svc, $cust_svc) = @_ or return '';
 211   my($svc, $label, $svcdb) = $cust_svc->label;
 212   svc_X_link( $label, @_ );
 213 }
 214
 215 sub svc_X_link {
 216   my ($x, $m, $part_svc, $cust_svc) = @_ or return '';
 217
 218   return $x
 219    unless $FS::CurrentUser::CurrentUser->access_right('View customer services');
 220
 221   confess "svc_X_link called without a service ($x, $m, $part_svc, $cust_svc)\n"
 222     unless $cust_svc;
 223
 224   my $ahref = svc_url(
 225     'ahref'    => 1,
 226     'm'        => $m,
 227     'action'   => 'view',
 228     'part_svc' => $part_svc,
 229     'svc'      => $cust_svc,
 230   );
 231
 232   "$ahref$x</A>";
 233 }
 234
 235 #this probably needs an ACL too...
 236 sub svc_export_links {
 237   my ($m, $part_svc, $cust_svc) = @_ or return '';
 238
 239   my $ahref = $cust_svc->export_links;
 240
 241   join('', @$ahref);
 242 }
 243
 244 sub parse_lt_gt {
 245   my($cgi, $field) = (shift, shift);
 246   my $table = ( @_ && length($_[0]) ) ? shift.'.' : '';
 247
 248   my @search = ();
 249
 250   my %op = (
 251     'lt' => '<',
 252     'gt' => '>',
 253   );
 254
 255   foreach my $op (keys %op) {
 256
 257     warn "checking for ${field}_$op field\n"
 258       if $DEBUG;
 259
 260     if ( $cgi->param($field."_$op") =~ /^\s*\$?\s*(-?[\d\,\s]+(\.\d\d)?)\s*$/ ) {
 261
 262       my $num = $1;
 263       $num =~ s/[\,\s]+//g;
 264       my $search = "$table$field $op{$op} $num";
 265       push @search, $search;
 266
 267       warn "found ${field}_$op field; adding search element $search\n"
 268         if $DEBUG;
 269     }
 270
 271   }
 272
 273   @search;
 274
 275 }
 276
 277 ###
 278 # cust_main report subroutines
 279 ###
 280
 281 =over 4
 282
 283 =item cust_header [ CUST_FIELDS_VALUE ]
 284
 285 Returns an array of customer information headers according to the supplied
 286 customer fields value, or if no value is supplied, the B<cust-fields>
 287 configuration value.
 288
 289 =cut
 290
 291 use vars qw( @cust_fields @cust_colors @cust_styles @cust_aligns );
 292
 293 sub cust_header {
 294
 295   warn "FS::UI:Web::cust_header called"
 296     if $DEBUG;
 297
 298   my $conf = new FS::Conf;
 299
 300   my %header2method = (
 301     'Customer'                 => 'name',
 302     'Cust. Status'             => 'cust_status_label',
 303     'Cust#'                    => 'display_custnum',
 304     'Name'                     => 'contact',
 305     'Company'                  => 'company',
 306
 307     # obsolete but might still be referenced in configuration
 308     '(bill) Customer'          => 'name',
 309     '(service) Customer'       => 'ship_name',
 310     '(bill) Name'              => 'contact',
 311     '(service) Name'           => 'ship_contact',
 312     '(bill) Company'           => 'company',
 313     '(service) Company'        => 'ship_company',
 314     '(bill) Day phone'         => 'daytime',
 315     '(bill) Night phone'       => 'night',
 316     '(bill) Fax number'        => 'fax',
 317
 318     'Customer'                 => 'name',
 319     'Address 1'                => 'bill_address1',
 320     'Address 2'                => 'bill_address2',
 321     'City'                     => 'bill_city',
 322     'State'                    => 'bill_state',
 323     'Zip'                      => 'bill_zip',
 324     'Country'                  => 'bill_country_full',
 325     'Day phone'                => 'daytime', # XXX should use msgcat, but how?
 326     'Night phone'              => 'night',   # XXX should use msgcat, but how?
 327     'Mobile phone'             => 'mobile',  # XXX should use msgcat, but how?
 328     'Fax number'               => 'fax',
 329     '(bill) Address 1'         => 'bill_address1',
 330     '(bill) Address 2'         => 'bill_address2',
 331     '(bill) City'              => 'bill_city',
 332     '(bill) State'             => 'bill_state',
 333     '(bill) Zip'               => 'bill_zip',
 334     '(bill) Country'           => 'bill_country_full',
 335     '(bill) Latitude'          => 'bill_latitude',
 336     '(bill) Longitude'         => 'bill_longitude',
 337     '(service) Address 1'      => 'ship_address1',
 338     '(service) Address 2'      => 'ship_address2',
 339     '(service) City'           => 'ship_city',
 340     '(service) State'          => 'ship_state',
 341     '(service) Zip'            => 'ship_zip',
 342     '(service) Country'        => 'ship_country_full',
 343     '(service) Latitude'       => 'ship_latitude',
 344     '(service) Longitude'      => 'ship_longitude',
 345     'Invoicing email(s)'       => 'invoicing_list_emailonly_scalar',
 346 # FS::Upgrade::upgrade_config removes this from existing cust-fields settings
 347 #    'Payment Type'             => 'cust_payby',
 348     'Current Balance'          => 'current_balance',
 349     'Agent Cust#'              => 'agent_custid',
 350     'Agent'                    => 'agent_name',
 351     'Agent Cust# or Cust#'     => 'display_custnum',
 352     'Advertising Source'       => 'referral',
 353   );
 354   $header2method{'Cust#'} = 'display_custnum'
 355     if $conf->exists('cust_main-default_agent_custid');
 356
 357 foreach my $phone_type ( FS::phone_type->get_phone_types() ) {
 358   $header2method{'Contact '.$phone_type->typename.' phone(s)'} = sub {
 359     my $self = shift;
 360     my $num = $phone_type->phonetypenum;
 361
 362     my @phones;
 363     foreach ($self->contact_list_name_phones) {
 364       my $data = [
 365         {
 366           'data'  => $_->first.' '.$_->last.' '.FS::contact_phone::phonenum_pretty($_),
 367         },
 368       ];
 369       push @phones, $data if $_->phonetypenum eq $phone_type->phonetypenum;
 370     }
 371   return \@phones;
 372   };
 373 }
 374
 375   my %header2colormethod = (
 376     'Cust. Status' => 'cust_statuscolor',
 377   );
 378   my %header2style = (
 379     'Cust. Status' => 'b',
 380   );
 381   my %header2align = (
 382     'Cust. Status' => 'c',
 383     'Cust#'        => 'r',
 384   );
 385
 386   my $cust_fields;
 387   my @cust_header;
 388   if ( @_ && $_[0] ) {
 389
 390     warn "  using supplied cust-fields override".
 391           " (ignoring cust-fields config file)"
 392       if $DEBUG;
 393     $cust_fields = shift;
 394
 395   } else {
 396
 397     if (    $conf->exists('cust-fields')
 398          && $conf->config('cust-fields') =~ /^([\w\. \|\#\(\)]+):?/
 399        )
 400     {
 401       warn "  found cust-fields configuration value"
 402         if $DEBUG;
 403       $cust_fields = $1;
 404     } else {
 405       warn "  no cust-fields configuration value found; using default 'Cust. Status | Customer'"
 406         if $DEBUG;
 407       $cust_fields = 'Cust. Status | Customer';
 408     }
 409
 410   }
 411
 412   @cust_header = split(/ \| /, $cust_fields);
 413   @cust_fields = map { $header2method{$_} || $_ } @cust_header;
 414   @cust_colors = map { exists $header2colormethod{$_}
 415                          ? $header2colormethod{$_}
 416                          : ''
 417                      }
 418                      @cust_header;
 419   @cust_styles = map { exists $header2style{$_} ? $header2style{$_} : '' }
 420                      @cust_header;
 421   @cust_aligns = map { exists $header2align{$_} ? $header2align{$_} : 'l' }
 422                      @cust_header;
 423
 424   #my $svc_x = shift;
 425   @cust_header;
 426 }
 427
 428 sub cust_sort_fields {
 429   cust_header(@_) if( @_ or !@cust_fields );
 430   #inefficientish, but tiny lists and only run once per page
 431
 432   my @sort_fields;
 433   foreach (@cust_fields) {
 434     if ($_ eq "custnum") { push @sort_fields, 'custnum'; }
 435     elsif ($_ eq "contact" || $_ eq "name") { push @sort_fields, '(last, first)'; }
 436     elsif ($_ eq "company") { push @sort_fields, 'company'; }
 437     else { push @sort_fields, ''; }
 438   }
 439   return @sort_fields;
 440
 441 }
 442
 443 =item cust_sql_fields [ CUST_FIELDS_VALUE ]
 444
 445 Returns a list of fields for the SELECT portion of an SQL query.
 446
 447 As with L<the cust_header subroutine|/cust_header>, the fields returned are
 448 defined by the supplied customer fields setting, or if no customer fields
 449 setting is supplied, the <B>cust-fields</B> configuration value.
 450
 451 =cut
 452
 453 sub cust_sql_fields {
 454
 455   my @fields = qw( last first company );
 456 #  push @fields, map "ship_$_", @fields;
 457
 458   cust_header(@_) if( @_ or !@cust_fields );
 459   #inefficientish, but tiny lists and only run once per page
 460
 461   my @location_fields;
 462   foreach my $field (qw( address1 address2 city state zip latitude longitude )) {
 463     foreach my $pre ('bill_','ship_') {
 464       if ( grep { $_ eq $pre.$field } @cust_fields ) {
 465         push @location_fields, $pre.'location.'.$field.' AS '.$pre.$field;
 466       }
 467     }
 468   }
 469   foreach my $pre ('bill_','ship_') {
 470     if ( grep { $_ eq $pre.'country_full' } @cust_fields ) {
 471       push @location_fields, $pre.'locationnum';
 472     }
 473   }
 474
 475   foreach my $field (qw(daytime night mobile fax )) {
 476     push @fields, $field if (grep { $_ eq $field } @cust_fields);
 477   }
 478   push @fields, 'agent_custid';
 479
 480   push @fields, 'agentnum' if grep { $_ eq 'agent_name' } @cust_fields;
 481
 482   my @extra_fields = ();
 483   if (grep { $_ eq 'current_balance' } @cust_fields) {
 484     push @extra_fields, FS::cust_main->balance_sql . " AS current_balance";
 485   }
 486
 487   push @extra_fields, 'part_referral_x.referral AS referral'
 488     if grep { $_ eq 'referral' } @cust_fields;
 489
 490   map("cust_main.$_", @fields), @location_fields, @extra_fields;
 491 }
 492
 493 =item join_cust_main [ TABLE[.CUSTNUM] ] [ LOCATION_TABLE[.LOCATIONNUM] ]
 494
 495 Returns an SQL join phrase for the FROM clause so that the fields listed
 496 in L</cust_sql_fields> will be available.  Currently joins to cust_main
 497 itself, as well as cust_location (under the aliases 'bill_location' and
 498 'ship_location') if address fields are needed.  L</cust_header> should have
 499 been called already.
 500
 501 All of these will be left joins; if you want to exclude rows with no linked
 502 cust_main record (or bill_location/ship_location), you can do so in the
 503 WHERE clause.
 504
 505 TABLE is the table containing the custnum field.  If CUSTNUM (a field name
 506 in that table) is specified, that field will be joined to cust_main.custnum.
 507 Otherwise, this function will assume the field is named "custnum".  If the
 508 argument isn't present at all, the join will just say "USING (custnum)",
 509 which might work.
 510
 511 As a special case, if TABLE is 'cust_main', only the joins to cust_location
 512 will be returned.
 513
 514 LOCATION_TABLE is an optional table name to use for joining ship_location,
 515 in case your query also includes package information and you want the
 516 "service address" columns to reflect package addresses.
 517
 518 =cut
 519
 520 sub join_cust_main {
 521   my ($cust_table, $location_table) = @_;
 522   my ($custnum, $locationnum);
 523   ($cust_table, $custnum) = split(/\./, $cust_table);
 524   $custnum ||= 'custnum';
 525   ($location_table, $locationnum) = split(/\./, $location_table);
 526   $locationnum ||= 'locationnum';
 527
 528   my $sql = '';
 529   if ( $cust_table ) {
 530     $sql = " LEFT JOIN cust_main ON (cust_main.custnum = $cust_table.$custnum)"
 531       unless $cust_table eq 'cust_main';
 532   } else {
 533     $sql = " LEFT JOIN cust_main USING (custnum)";
 534   }
 535
 536   if ( !@cust_fields or grep /^bill_/, @cust_fields ) {
 537
 538     $sql .= ' LEFT JOIN cust_location bill_location'.
 539             ' ON (bill_location.locationnum = cust_main.bill_locationnum)';
 540
 541   }
 542
 543   if ( !@cust_fields or grep /^ship_/, @cust_fields ) {
 544
 545     if (!$location_table) {
 546       $location_table = 'cust_main';
 547       $locationnum = 'ship_locationnum';
 548     }
 549
 550     $sql .= ' LEFT JOIN cust_location ship_location'.
 551             " ON (ship_location.locationnum = $location_table.$locationnum) ";
 552   }
 553
 554   if ( !@cust_fields or grep { $_ eq 'referral' } @cust_fields ) {
 555     $sql .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
 556   }
 557
 558   $sql;
 559 }
 560
 561 =item cust_fields OBJECT [ CUST_FIELDS_VALUE ]
 562
 563 Given an object that contains fields from cust_main (say, from a
 564 JOINed search.  See httemplate/search/svc_* for examples), returns an array
 565 of customer information, or "(unlinked)" if this service is not linked to a
 566 customer.
 567
 568 As with L<the cust_header subroutine|/cust_header>, the fields returned are
 569 defined by the supplied customer fields setting, or if no customer fields
 570 setting is supplied, the <B>cust-fields</B> configuration value.
 571
 572 =cut
 573
 574
 575 sub cust_fields {
 576   my $record = shift;
 577   warn "FS::UI::Web::cust_fields called for $record ".
 578        "(cust_fields: @cust_fields)"
 579     if $DEBUG > 1;
 580
 581   #cust_header(@_) unless @cust_fields; #now need to cache to keep cust_fields
 582   #                                     #override incase we were passed as a sub
 583
 584   my $seen_unlinked = 0;
 585
 586   map {
 587     if ( $record->custnum ) {
 588       warn "  $record -> $_" if $DEBUG > 1;
 589       encode_entities( $record->$_(@_) );
 590     } else {
 591       warn "  ($record unlinked)" if $DEBUG > 1;
 592       $seen_unlinked++ ? '' : '(unlinked)';
 593     }
 594   } @cust_fields;
 595 }
 596
 597 =item cust_fields_subs
 598
 599 Returns an array of subroutine references for returning customer field values.
 600 This is similar to cust_fields, but returns each field's sub as a distinct
 601 element.
 602
 603 =cut
 604
 605 sub cust_fields_subs {
 606   my $unlinked_warn = 0;
 607
 608   return map {
 609     my $f = $_;
 610     if ( $unlinked_warn++ ) {
 611
 612       sub {
 613         my $record = shift;
 614         if ( $record->custnum ) {
 615           encode_entities( $record->$f(@_) );
 616         } else {
 617           '(unlinked)'
 618         };
 619       };
 620
 621     } else {
 622
 623       sub {
 624         my $record = shift;
 625         $record->custnum ? encode_entities( $record->$f(@_) ) : '';
 626       };
 627
 628     }
 629
 630   } @cust_fields;
 631 }
 632
 633 =item cust_colors
 634
 635 Returns an array of subroutine references (or empty strings) for returning
 636 customer information colors.
 637
 638 As with L<the cust_header subroutine|/cust_header>, the fields returned are
 639 defined by the supplied customer fields setting, or if no customer fields
 640 setting is supplied, the <B>cust-fields</B> configuration value.
 641
 642 =cut
 643
 644 sub cust_colors {
 645   map {
 646     my $method = $_;
 647     if ( $method ) {
 648       sub { shift->$method(@_) };
 649     } else {
 650       '';
 651     }
 652   } @cust_colors;
 653 }
 654
 655 =item cust_styles
 656
 657 Returns an array of customer information styles.
 658
 659 As with L<the cust_header subroutine|/cust_header>, the fields returned are
 660 defined by the supplied customer fields setting, or if no customer fields
 661 setting is supplied, the <B>cust-fields</B> configuration value.
 662
 663 =cut
 664
 665 sub cust_styles {
 666   map {
 667     if ( $_ ) {
 668       $_;
 669     } else {
 670       '';
 671     }
 672   } @cust_styles;
 673 }
 674
 675 =item cust_aligns
 676
 677 Returns an array or scalar (depending on context) of customer information
 678 alignments.
 679
 680 As with L<the cust_header subroutine|/cust_header>, the fields returned are
 681 defined by the supplied customer fields setting, or if no customer fields
 682 setting is supplied, the <B>cust-fields</B> configuration value.
 683
 684 =cut
 685
 686 sub cust_aligns {
 687   if ( wantarray ) {
 688     @cust_aligns;
 689   } else {
 690     join('', @cust_aligns);
 691   }
 692 }
 693
 694 =item cust_links
 695
 696 Returns an array of links to view/cust_main.cgi, for use with cust_fields.
 697
 698 =cut
 699
 700 sub cust_links {
 701   my $link = [ FS::CGI::rooturl().'view/cust_main.cgi?', 'custnum' ];
 702
 703   return map { $_ eq 'cust_status_label' ? '' : $link }
 704     @cust_fields;
 705 }
 706
 707 =item is_mobile
 708
 709 Utility function to determine if the client is a mobile browser.
 710
 711 =cut
 712
 713 sub is_mobile {
 714   my $ua = $ENV{'HTTP_USER_AGENT'} || '';
 715   if ( $ua =~ /(?:hiptop|Blazer|Novarra|Vagabond|SonyEricsson|Symbian|NetFront|UP.Browser|UP.Link|Windows CE|MIDP|J2ME|DoCoMo|J-PHONE|PalmOS|PalmSource|iPhone|iPod|AvantGo|Nokia|Android|WebOS|S60|Opera Mini|Opera Mobi)/io ) {
 716     return 1;
 717   }
 718   return 0;
 719 }
 720
 721 =item random_id [ DIGITS ]
 722
 723 Returns a random number of length DIGITS, or if unspecified, a long random
 724 identifier consisting of the timestamp, process ID, and a random number.
 725 Anything in the UI that needs a random identifier should use this.
 726
 727 =cut
 728
 729 sub random_id {
 730   my $digits = shift;
 731   if (!defined $NO_RANDOM_IDS) {
 732     my $conf = FS::Conf->new;
 733     $NO_RANDOM_IDS = $conf->exists('no_random_ids') ? 1 : 0;
 734     warn "TEST MODE--RANDOM ID NUMBERS DISABLED\n" if $NO_RANDOM_IDS;
 735   }
 736   if ( $NO_RANDOM_IDS ) {
 737     if ( $digits > 0 ) {
 738       return 0;
 739     } else {
 740       return '0000000000-0000-000000000.000000';
 741     }
 742   } else {
 743     if ($digits > 0) {
 744       return int(rand(10 ** $digits));
 745     } else {
 746       return time . "-$$-" . rand() * 2**32;
 747     }
 748   }
 749 }
 750
 751 =back
 752
 753 =cut
 754
 755 ###
 756 # begin JSRPC code...
 757 ###
 758
 759 package FS::UI::Web::JSRPC;
 760
 761 use strict;
 762 use vars qw($DEBUG);
 763 use Carp;
 764 use Storable qw(nfreeze);
 765 use MIME::Base64;
 766 use Cpanel::JSON::XS;
 767 use FS::CurrentUser;
 768 use FS::Record qw(qsearchs);
 769 use FS::queue;
 770 use FS::CGI qw(rooturl);
 771 use FS::Report::Queued::FutureAutobill;
 772
 773 $DEBUG = 0;
 774
 775 sub new {
 776         my $class = shift;
 777         my $self  = {
 778                 env => {},
 779                 job => shift,
 780                 cgi => shift,
 781         };
 782
 783         bless $self, $class;
 784
 785         croak "CGI object required as second argument" unless $self->{'cgi'};
 786
 787         return $self;
 788 }
 789
 790 sub process {
 791
 792   my $self = shift;
 793
 794   my $cgi = $self->{'cgi'};
 795
 796   # XXX this should parse JSON foo and build a proper data structure
 797   my @args = $cgi->param('arg');
 798
 799   #work around konqueror bug!
 800   @args = map { s/\x00$//; $_; } @args;
 801
 802   my $sub = $cgi->param('sub'); #????
 803
 804   warn "FS::UI::Web::JSRPC::process:\n".
 805        "  cgi=$cgi\n".
 806        "  sub=$sub\n".
 807        "  args=".join(', ',@args)."\n"
 808     if $DEBUG;
 809
 810   if ( $sub eq 'start_job' ) {
 811
 812     $self->start_job(@args);
 813
 814   } elsif ( $sub eq 'job_status' ) {
 815
 816     $self->job_status(@args);
 817
 818   } else {
 819
 820     die "unknown sub $sub";
 821
 822   }
 823
 824 }
 825
 826 sub start_job {
 827   my $self = shift;
 828
 829   warn "FS::UI::Web::start_job: ". join(', ', @_) if $DEBUG;
 830 #  my %param = @_;
 831   my %param = ();
 832   while ( @_ ) {
 833     my( $field, $value ) = splice(@_, 0, 2);
 834     unless ( exists( $param{$field} ) ) {
 835       $param{$field} = $value;
 836     } elsif ( ! ref($param{$field}) ) {
 837       $param{$field} = [ $param{$field}, $value ];
 838     } else {
 839       push @{$param{$field}}, $value;
 840     }
 841   }
 842   $param{CurrentUser} = $FS::CurrentUser::CurrentUser->username;
 843   $param{RootURL} = rooturl($self->{cgi}->self_url);
 844   warn "FS::UI::Web::start_job\n".
 845        join('', map {
 846                       if ( ref($param{$_}) ) {
 847                         "  $_ => [ ". join(', ', @{$param{$_}}). " ]\n";
 848                       } else {
 849                         "  $_ => $param{$_}\n";
 850                       }
 851                     } keys %param )
 852     if $DEBUG;
 853
 854   #first get the CGI params shipped off to a job ASAP so an id can be returned
 855   #to the caller
 856
 857   my $job = new FS::queue { 'job' => $self->{'job'} };
 858
 859   #too slow to insert all the cgi params as individual args..,?
 860   #my $error = $queue->insert('_JOB', $cgi->Vars);
 861
 862   #rely on FS::queue smartness to freeze/encode the param hash
 863
 864   my $error = $job->insert( '_JOB', \%param );
 865
 866   if ( $error ) {
 867
 868     warn "job not inserted: $error\n"
 869       if $DEBUG;
 870
 871     $error;  #this doesn't seem to be handled well,
 872              # will trigger "illegal jobnum" below?
 873              # (should never be an error inserting the job, though, only thing
 874              #  would be Pg f%*kage)
 875   } else {
 876
 877     warn "job inserted successfully with jobnum ". $job->jobnum. "\n"
 878       if $DEBUG;
 879
 880     $job->jobnum;
 881   }
 882
 883 }
 884
 885 sub job_status {
 886   my( $self, $jobnum ) = @_; #$url ???
 887
 888   sleep 1; # XXX could use something better...
 889
 890   my $job;
 891   if ( $jobnum =~ /^(\d+)$/ ) {
 892     $job = qsearchs('queue', { 'jobnum' => $jobnum } );
 893   } else {
 894     die "FS::UI::Web::job_status: illegal jobnum $jobnum\n";
 895   }
 896
 897   my @return;
 898   if ( $job && $job->status ne 'failed' && $job->status ne 'done' ) {
 899     my ($progress, $action) = split ',', $job->statustext, 2;
 900     $action ||= 'Server processing job';
 901     @return = ( 'progress', $progress, $action );
 902   } elsif ( !$job ) { #handle job gone case : job successful
 903                       # so close popup, redirect parent window...
 904     @return = ( 'complete' );
 905   } elsif ( $job->status eq 'done' ) {
 906     @return = ( 'done', $job->statustext, '' );
 907   } else {
 908     @return = ( 'error', $job ? $job->statustext : $jobnum );
 909   }
 910
 911   encode_json \@return;
 912
 913 }
 914
 915 1;
 916