FS/FS/TicketSystem.pm

   1 package FS::TicketSystem;
   2
   3 use strict;
   4 use vars qw( $conf $system $AUTOLOAD );
   5 use FS::Conf;
   6 use FS::UID qw( dbh driver_name );
   7
   8 FS::UID->install_callback( sub {
   9   $conf = new FS::Conf;
  10   $system = $conf->config('ticket_system');
  11 } );
  12
  13 sub AUTOLOAD {
  14   my $self = shift;
  15
  16   my($sub)=$AUTOLOAD;
  17   $sub =~ s/.*://;
  18
  19   my $conf = new FS::Conf;
  20   die "FS::TicketSystem::$AUTOLOAD called, but no ticket system configured\n"
  21     unless $system;
  22
  23   eval "use FS::TicketSystem::$system;";
  24   die $@ if $@;
  25
  26   $self .= "::$system";
  27   $self->$sub(@_);
  28 }
  29
  30 sub _upgrade_data {
  31   return if !defined($system) || $system ne 'RT_Internal';
  32   my ($class, %opts) = @_;
  33
  34   # go ahead and use the RT API for this
  35
  36   FS::TicketSystem->init;
  37   my $session = FS::TicketSystem->session();
  38   my $CurrentUser = $session->{'CurrentUser'}
  39     or die 'freeside-upgrade must run as a valid RT user';
  40
  41   # EscalateQueue custom field and friends
  42   my $CF = RT::CustomField->new($CurrentUser);
  43   $CF->Load('EscalateQueue');
  44   if (!defined($CF->Id)) {
  45     my ($val, $msg) = $CF->Create(
  46       'Name' => 'EscalateQueue',
  47       'Type' => 'Select',
  48       'MaxValues' => 1,
  49       'LookupType' => 'RT::Queue',
  50       'Description' => 'Escalate to Queue',
  51       'ValuesClass' => 'RT::CustomFieldValues::Queues', #magic!
  52     );
  53     die $msg if !$val;
  54     my $OCF = RT::ObjectCustomField->new($CurrentUser);
  55     ($val, $msg) = $OCF->Create(
  56       'CustomField' => $CF->Id,
  57       'ObjectId' => 0,
  58     );
  59     die $msg if !$val;
  60   }
  61
  62   # Load from RT data file
  63   our (@Groups, @Users, @ACL, @Queues, @ScripActions, @ScripConditions,
  64        @Templates, @CustomFields, @Scrips, @Attributes, @Initial, @Final);
  65   my $datafile = '%%%RT_PATH%%%/etc/initialdata';
  66   eval { require $datafile };
  67   if ( $@ ) {
  68     warn "Couldn't load RT data from '$datafile': $@\n(skipping)\n";
  69     return;
  70   }
  71
  72   # Cache existing ScripCondition, ScripAction, and Template IDs
  73   my $search = RT::ScripConditions->new($CurrentUser);
  74   $search->UnLimit;
  75   my %condition = map { lc($_->Name), $_->Id } @{ $search->ItemsArrayRef };
  76
  77   $search = RT::ScripActions->new($CurrentUser);
  78   $search->UnLimit;
  79   my %action = map { lc($_->Name), $_->Id } @{ $search->ItemsArrayRef };
  80
  81   $search = RT::Templates->new($CurrentUser);
  82   $search->UnLimit;
  83   my %template = map { lc($_->Name), $_->Id } @{ $search->ItemsArrayRef };
  84
  85   # ScripConditions
  86   my $ScripCondition = RT::ScripCondition->new($CurrentUser);
  87   foreach my $sc (@ScripConditions) {
  88     # $sc: Name, Description, ApplicableTransTypes, ExecModule, Argument
  89     next if exists( $condition{ lc($sc->{Name}) } );
  90     my ($val, $msg) = $ScripCondition->Create( %$sc );
  91     die $msg if !$val;
  92     $condition{ lc($ScripCondition->Name) } = $ScripCondition->Id;
  93   }
  94
  95   # ScripActions
  96   my $ScripAction = RT::ScripAction->new($CurrentUser);
  97   foreach my $sa (@ScripActions) {
  98     # $sa: Name, Description, ExecModule, Argument
  99     next if exists( $action{ lc($sa->{Name}) } );
 100     my ($val, $msg) = $ScripAction->Create( %$sa );
 101     die $msg if !$val;
 102     $action{ lc($ScripAction->Name) } = $ScripAction->Id;
 103   }
 104
 105   # Templates
 106   my $Template = RT::Template->new($CurrentUser);
 107   foreach my $t (@Templates) {
 108     # $t: Queue, Name, Description, Content
 109     next if exists( $template{ lc($t->{Name}) } );
 110     my ($val, $msg) = $Template->Create( %$t );
 111     die $msg if !$val;
 112     $template{ lc($Template->Name) } = $Template->Id;
 113   }
 114
 115   # Scrips
 116   my $Scrip = RT::Scrip->new($CurrentUser);
 117   foreach my $s ( @Scrips ) {
 118     my $desc = $s->{'Description'};
 119     my ($c, $a, $t) = map lc,
 120       @{ $s }{'ScripCondition', 'ScripAction', 'Template'};
 121     if ( !$condition{$c} ) {
 122       warn "ScripCondition '$c' not found.\n";
 123       next;
 124     }
 125     if ( !$action{$a} ) {
 126       warn "ScripAction '$a' not found.\n";
 127       next;
 128     }
 129     if ( !$template{$t} ) {
 130       warn "Template '$t' not found.\n";
 131       next;
 132     }
 133     my %param = (
 134       ScripCondition => $condition{$c},
 135       ScripAction => $action{$a},
 136       Template => $template{$t},
 137       Queue => 0,
 138     );
 139     $Scrip->LoadByCols(%param);
 140     if (!defined($Scrip->Id)) {
 141       my ($val, $msg) = $Scrip->Create(%param, Description => $desc);
 142       die $msg if !$val;
 143     }
 144   } #foreach (@Scrips)
 145
 146   return;
 147 }
 148
 149 1;