FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Time::Local qw( timelocal );
  14 use Text::Template 1.20;
  15 use File::Temp 0.14;
  16 use Archive::Zip qw( :ERROR_CODES :CONSTANTS );
  17 use IO::Scalar;
  18 use HTML::Entities;
  19 use Cwd;
  20 use FS::UID;
  21 use FS::Misc qw( send_email );
  22 use FS::Record qw( qsearch qsearchs dbh );
  23 use FS::Conf;
  24 use FS::Misc qw( generate_ps generate_pdf );
  25 use FS::pkg_category;
  26 use FS::pkg_class;
  27 use FS::invoice_mode;
  28 use FS::L10N;
  29
  30 $DEBUG = 0;
  31 $me = '[FS::Template_Mixin]';
  32 FS::UID->install_callback( sub {
  33   my $conf = new FS::Conf; #global
  34   $money_char  = $conf->config('money_char')  || '$';
  35   $date_format = $conf->config('date_format') || '%x'; #/YY
  36 } );
  37
  38 =item conf [ MODE ]
  39
  40 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  41
  42 If the "mode" pseudo-field is set on the object, the configuration handle
  43 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  44 locale).
  45
  46 =cut
  47
  48 sub conf {
  49   my $self = shift;
  50   my $mode = $self->get('mode');
  51   if ($self->{_conf} and !defined($mode)) {
  52     return $self->{_conf};
  53   }
  54
  55   my $cust_main = $self->cust_main;
  56   my $locale = $cust_main ? $cust_main->locale : '';
  57   my $conf;
  58   if ( $mode ) {
  59     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  60       $mode = $mode->modenum;
  61     } elsif ( $mode =~ /\D/ ) {
  62       die "invalid invoice mode $mode";
  63     }
  64     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  65     if (!$conf) {
  66       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  67       # it doesn't have a locale, but system conf still might
  68       $conf->set('locale' => $locale) if $conf;
  69     }
  70   }
  71   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  72   # and locale, then use the system config only (but with the locale)
  73   $conf ||= FS::Conf->new({ 'locale' => $locale });
  74   # cache it
  75   return $self->{_conf} = $conf;
  76 }
  77
  78 =item print_text OPTIONS
  79
  80 Returns an text invoice, as a list of lines.
  81
  82 Options can be passed as a hash.
  83
  84 I<time>, if specified, is used to control the printing of overdue messages.  The
  85 default is now.  It isn't the date of the invoice; that's the `_date' field.
  86 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  87 L<Time::Local> and L<Date::Parse> for conversion functions.
  88
  89 I<template>, if specified, is the name of a suffix for alternate invoices.
  90
  91 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  92
  93 =cut
  94
  95 sub print_text {
  96   my $self = shift;
  97   my %params;
  98   if ( ref($_[0]) ) {
  99     %params = %{ shift() };
 100   } else {
 101     %params = @_;
 102   }
 103
 104   $params{'format'} = 'template'; # for some reason
 105
 106   $self->print_generic( %params );
 107 }
 108
 109 =item print_latex HASHREF
 110
 111 Internal method - returns a filename of a filled-in LaTeX template for this
 112 invoice (Note: add ".tex" to get the actual filename), and a filename of
 113 an associated logo (with the .eps extension included).
 114
 115 See print_ps and print_pdf for methods that return PostScript and PDF output.
 116
 117 Options can be passed as a hash.
 118
 119 I<time>, if specified, is used to control the printing of overdue messages.  The
 120 default is now.  It isn't the date of the invoice; that's the `_date' field.
 121 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 122 L<Time::Local> and L<Date::Parse> for conversion functions.
 123
 124 I<template>, if specified, is the name of a suffix for alternate invoices.
 125 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 126 customize invoice templates for different purposes.
 127
 128 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 129
 130 =cut
 131
 132 sub print_latex {
 133   my $self = shift;
 134   my %params;
 135
 136   if ( ref($_[0]) ) {
 137     %params = %{ shift() };
 138   } else {
 139     %params = @_;
 140   }
 141
 142   $params{'format'} = 'latex';
 143   my $conf = $self->conf;
 144
 145   # this needs to go away
 146   my $template = $params{'template'};
 147   # and this especially
 148   $template ||= $self->_agent_template
 149     if $self->can('_agent_template');
 150
 151   #the new way
 152   $self->set('mode', $params{mode})
 153     if $params{mode};
 154
 155   my $pkey = $self->primary_key;
 156   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 157
 158   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 159   my $lh = new File::Temp(
 160     TEMPLATE => $tmp_template,
 161     DIR      => $dir,
 162     SUFFIX   => '.eps',
 163     UNLINK   => 0,
 164   ) or die "can't open temp file: $!\n";
 165
 166   my $agentnum = $self->agentnum;
 167
 168   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 169     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 170       or die "can't write temp file: $!\n";
 171   } else {
 172     print $lh $conf->config_binary('logo.eps', $agentnum)
 173       or die "can't write temp file: $!\n";
 174   }
 175   close $lh;
 176   $params{'logo_file'} = $lh->filename;
 177
 178   if( $conf->exists('invoice-barcode')
 179         && $self->can('invoice_barcode')
 180         && $self->invnum ) { # don't try to barcode statements
 181       my $png_file = $self->invoice_barcode($dir);
 182       my $eps_file = $png_file;
 183       $eps_file =~ s/\.png$/.eps/g;
 184       $png_file =~ /(barcode.*png)/;
 185       $png_file = $1;
 186       $eps_file =~ /(barcode.*eps)/;
 187       $eps_file = $1;
 188
 189       my $curr_dir = cwd();
 190       chdir($dir);
 191       # after painfuly long experimentation, it was determined that sam2p won't
 192       # accept : and other chars in the path, no matter how hard I tried to
 193       # escape them, hence the chdir (and chdir back, just to be safe)
 194       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 195         or die "sam2p failed: $!\n";
 196       unlink($png_file);
 197       chdir($curr_dir);
 198
 199       $params{'barcode_file'} = $eps_file;
 200   }
 201
 202   my @filled_in = $self->print_generic( %params );
 203
 204   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 205                            DIR      => $dir,
 206                            SUFFIX   => '.tex',
 207                            UNLINK   => 0,
 208                          ) or die "can't open temp file: $!\n";
 209   binmode($fh, ':utf8'); # language support
 210   print $fh join('', @filled_in );
 211   close $fh;
 212
 213   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 214   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 215
 216 }
 217
 218 sub agentnum {
 219   my $self = shift;
 220   my $cust_main = $self->cust_main;
 221   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 222 }
 223
 224 =item print_generic OPTION => VALUE ...
 225
 226 Internal method - returns a filled-in template for this invoice as a scalar.
 227
 228 See print_ps and print_pdf for methods that return PostScript and PDF output.
 229
 230 Required options
 231
 232 =over 4
 233
 234 =item format
 235
 236 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 237
 238 =back
 239
 240 Additional options
 241
 242 =over 4
 243
 244 =item notice_name
 245
 246 Overrides "Invoice" as the name of the sent document.
 247
 248 =item today
 249
 250 Used to control the printing of overdue messages.  The
 251 default is now.  It isn't the date of the invoice; that's the `_date' field.
 252 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 253 L<Time::Local> and L<Date::Parse> for conversion functions.
 254
 255 =item logo_file
 256
 257 Logo file (path to temporary EPS file on the local filesystem)
 258
 259 =item cid
 260
 261 CID for inline (emailed) images (logo)
 262
 263 =item locale
 264
 265 Override customer's locale
 266
 267 =item unsquelch_cdr
 268
 269 Overrides any per customer cdr squelching when true
 270
 271 =item no_number
 272
 273 Supress the (invoice, quotation, statement, etc.) number
 274
 275 =item no_date
 276
 277 Supress the date
 278
 279 =item no_coupon
 280
 281 Supress the payment coupon
 282
 283 =item barcode_file
 284
 285 Barcode file (path to temporary EPS file on the local filesystem)
 286
 287 =item barcode_img
 288
 289 Flag indicating the barcode image should be a link (normal HTML dipaly)
 290
 291 =item barcode_cid
 292
 293 Barcode CID for inline (emailed) images
 294
 295 =item preref_callback
 296
 297 Coderef run for each line item, code should return HTML to be displayed
 298 before that line item (quotations only)
 299
 300 =item template
 301
 302 Dprecated.  Used as a suffix for a configuration template.  Please
 303 don't use this, it deprecated in favor of more flexible alternatives.
 304
 305 =back
 306
 307 =cut
 308
 309 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 310 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 311 # yes: fixed width/plain text printing will be borked
 312 sub print_generic {
 313   my( $self, %params ) = @_;
 314   my $conf = $self->conf;
 315
 316   my $today = $params{today} ? $params{today} : time;
 317   warn "$me print_generic called on $self with suffix $params{template}\n"
 318     if $DEBUG;
 319
 320   my $format = $params{format};
 321   die "Unknown format: $format"
 322     unless $format =~ /^(latex|html|template)$/;
 323
 324   my $cust_main = $self->cust_main || $self->prospect_main;
 325
 326   my $locale = $params{'locale'} || $cust_main->locale;
 327
 328   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 329                      'html'     => [ '<%=', '%>' ],
 330                      'template' => [ '{', '}' ],
 331                    );
 332
 333   warn "$me print_generic creating template\n"
 334     if $DEBUG > 1;
 335
 336   # set the notice name here, and nowhere else.
 337   my $notice_name =  $params{notice_name}
 338                   || $conf->config('notice_name')
 339                   || $self->notice_name;
 340
 341   #create the template
 342   my $template = $params{template} ? $params{template} : $self->_agent_template;
 343   my $templatefile = $self->template_conf. $format;
 344   $templatefile .= "_$template"
 345     if length($template) && $conf->exists($templatefile."_$template");
 346
 347   # the base template
 348   my @invoice_template = map "$_\n", $conf->config($templatefile)
 349     or die "cannot load config data $templatefile";
 350
 351   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 352     #change this to a die when the old code is removed
 353     # it's been almost ten years, changing it to a die
 354     die "old-style invoice template $templatefile; ".
 355          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 356          #$old_latex = 'true';
 357          #@invoice_template = _translate_old_latex_format(@invoice_template);
 358   }
 359
 360   warn "$me print_generic creating T:T object\n"
 361     if $DEBUG > 1;
 362
 363   my $text_template = new Text::Template(
 364     TYPE => 'ARRAY',
 365     SOURCE => \@invoice_template,
 366     DELIMITERS => $delimiters{$format},
 367   );
 368
 369   warn "$me print_generic compiling T:T object\n"
 370     if $DEBUG > 1;
 371
 372   $text_template->compile()
 373     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 374
 375
 376   # additional substitution could possibly cause breakage in existing templates
 377   my %convert_maps = (
 378     'latex' => {
 379                  'notes'         => sub { map "$_", @_ },
 380                  'footer'        => sub { map "$_", @_ },
 381                  'smallfooter'   => sub { map "$_", @_ },
 382                  'returnaddress' => sub { map "$_", @_ },
 383                  'coupon'        => sub { map "$_", @_ },
 384                  'summary'       => sub { map "$_", @_ },
 385                },
 386     'html'  => {
 387                  'notes' =>
 388                    sub {
 389                      map {
 390                        s/%%(.*)$/<!-- $1 -->/g;
 391                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 392                        s/\\begin\{enumerate\}/<ol>/g;
 393                        s/\\item /  <li>/g;
 394                        s/\\end\{enumerate\}/<\/ol>/g;
 395                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 396                        s/\\\\\*/<br>/g;
 397                        s/\\dollar ?/\$/g;
 398                        s/\\#/#/g;
 399                        s/~/&nbsp;/g;
 400                        $_;
 401                      }  @_
 402                    },
 403                  'footer' =>
 404                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 405                  'smallfooter' =>
 406                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 407                  'returnaddress' =>
 408                    sub {
 409                      map {
 410                        s/~/&nbsp;/g;
 411                        s/\\\\\*?\s*$/<BR>/;
 412                        s/\\hyphenation\{[\w\s\-]+}//;
 413                        s/\\([&])/$1/g;
 414                        $_;
 415                      }  @_
 416                    },
 417                  'coupon'        => sub { "" },
 418                  'summary'       => sub { "" },
 419                },
 420     'template' => {
 421                  'notes' =>
 422                    sub {
 423                      map {
 424                        s/%%.*$//g;
 425                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 426                        s/\\begin\{enumerate\}//g;
 427                        s/\\item /  * /g;
 428                        s/\\end\{enumerate\}//g;
 429                        s/\\textbf\{(.*)\}/$1/g;
 430                        s/\\\\\*/ /;
 431                        s/\\dollar ?/\$/g;
 432                        $_;
 433                      }  @_
 434                    },
 435                  'footer' =>
 436                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 437                  'smallfooter' =>
 438                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 439                  'returnaddress' =>
 440                    sub {
 441                      map {
 442                        s/~/ /g;
 443                        s/\\\\\*?\s*$/\n/;             # dubious
 444                        s/\\hyphenation\{[\w\s\-]+}//;
 445                        $_;
 446                      }  @_
 447                    },
 448                  'coupon'        => sub { "" },
 449                  'summary'       => sub { "" },
 450                },
 451   );
 452
 453
 454   # hashes for differing output formats
 455   my %nbsps = ( 'latex'    => '~',
 456                 'html'     => '',    # '&nbps;' would be nice
 457                 'template' => '',    # not used
 458               );
 459   my $nbsp = $nbsps{$format};
 460
 461   my %escape_functions = ( 'latex'    => \&_latex_escape,
 462                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 463                            'template' => sub { shift },
 464                          );
 465   my $escape_function = $escape_functions{$format};
 466   my $escape_function_nonbsp = ($format eq 'html')
 467                                  ? \&_html_escape : $escape_function;
 468
 469   my %newline_tokens = (  'latex'     => '\\\\',
 470                           'html'      => '<br>',
 471                           'template'  => "\n",
 472                         );
 473   my $newline_token = $newline_tokens{$format};
 474
 475   warn "$me generating template variables\n"
 476     if $DEBUG > 1;
 477
 478   # generate template variables
 479   my $returnaddress;
 480
 481   if (
 482          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 483                                         $template
 484                                       )
 485                 )
 486        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 487                                         $template
 488                                       )
 489                 )
 490   ) {
 491
 492     $returnaddress = join("\n",
 493       $conf->config_orbase("invoice_${format}returnaddress", $template)
 494     );
 495
 496   } elsif ( grep /\S/,
 497             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 498
 499     my $convert_map = $convert_maps{$format}{'returnaddress'};
 500     $returnaddress =
 501       join( "\n",
 502             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 503                                                  $template
 504                                                )
 505                          )
 506           );
 507   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 508
 509     my $convert_map = $convert_maps{$format}{'returnaddress'};
 510     $returnaddress = join( "\n", &$convert_map(
 511                                    map { s/( {2,})/'~' x length($1)/eg;
 512                                          s/$/\\\\\*/;
 513                                          $_
 514                                        }
 515                                      ( $conf->config('company_name', $cust_main->agentnum),
 516                                        $conf->config('company_address', $cust_main->agentnum),
 517                                      )
 518                                  )
 519                      );
 520
 521   } else {
 522
 523     my $warning = "Couldn't find a return address; ".
 524                   "do you need to set the company_address configuration value?";
 525     warn "$warning\n";
 526     $returnaddress = $nbsp;
 527     #$returnaddress = $warning;
 528
 529   }
 530
 531   warn "$me generating invoice data\n"
 532     if $DEBUG > 1;
 533
 534   my $agentnum = $cust_main->agentnum;
 535
 536   my %invoice_data = (
 537
 538     #invoice from info
 539     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 540     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 541     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 542     'returnaddress'   => $returnaddress,
 543     'agent'           => &$escape_function($cust_main->agent->agent),
 544
 545     #invoice/quotation info
 546     'no_number'       => $params{'no_number'},
 547     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 548     'quotationnum'    => $self->quotationnum,
 549     'no_date'         => $params{'no_date'},
 550     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 551       # workaround for inconsistent behavior in the early plain text
 552       # templates; see RT#28271
 553     'date'            => ( $params{'no_date'}
 554                              ? ''
 555                              : ($format eq 'template'
 556                                ? $self->_date
 557                                : $self->time2str_local('long', $self->_date, $format)
 558                                )
 559                          ),
 560     'today'           => $self->time2str_local('long', $today, $format),
 561     'terms'           => $self->terms,
 562     'template'        => $template, #params{'template'},
 563     'notice_name'     => $notice_name, # escape?
 564     'current_charges' => sprintf("%.2f", $self->charged),
 565     'duedate'         => $self->due_date2str('rdate'), #date_format?
 566     'duedate_long'    => $self->due_date2str('long'),
 567
 568     #customer info
 569     'custnum'         => $cust_main->display_custnum,
 570     'prospectnum'     => $cust_main->prospectnum,
 571     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 572     ( map { $_ => &$escape_function($cust_main->$_()) }
 573         qw( company address1 address2 city state zip fax )
 574     ),
 575     'payname'         => &$escape_function( $cust_main->invoice_attn
 576                                              || $cust_main->contact_firstlast ),
 577
 578     #global config
 579     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 580     'unitprices'      => $conf->exists('invoice-unitprice'),
 581     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 582     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 583     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 584
 585     #layout info -- would be fancy to calc some of this and bury the template
 586     #               here in the code
 587     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 588     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 589     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 590     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 591     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 592     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 593     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 594     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 595     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 596     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 597
 598     # better hang on to conf_dir for a while (for old templates)
 599     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 600
 601     #these are only used when doing paged plaintext
 602     'page'            => 1,
 603     'total_pages'     => 1,
 604
 605   );
 606
 607   #quotations have $name
 608   $invoice_data{'name'} = $invoice_data{'payname'};
 609
 610   #localization
 611   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 612   # prototype here to silence warnings
 613   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 614
 615   my $min_sdate = 999999999999;
 616   my $max_edate = 0;
 617   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 618     next unless $cust_bill_pkg->pkgnum > 0;
 619     $min_sdate = $cust_bill_pkg->sdate
 620       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 621     $max_edate = $cust_bill_pkg->edate
 622       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 623   }
 624
 625   $invoice_data{'bill_period'} = '';
 626   $invoice_data{'bill_period'} =
 627       $self->time2str_local('%e %h', $min_sdate, $format)
 628       . " to " .
 629       $self->time2str_local('%e %h', $max_edate, $format)
 630     if ($max_edate != 0 && $min_sdate != 999999999999);
 631
 632   $invoice_data{finance_section} = '';
 633   if ( $conf->config('finance_pkgclass') ) {
 634     my $pkg_class =
 635       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 636     $invoice_data{finance_section} = $pkg_class->categoryname;
 637   }
 638   $invoice_data{finance_amount} = '0.00';
 639   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 640
 641   my $countrydefault = $conf->config('countrydefault') || 'US';
 642   foreach ( qw( address1 address2 city state zip country fax) ){
 643     my $method = 'ship_'.$_;
 644     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 645   }
 646   if ( length($cust_main->ship_company) ) {
 647     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 648   } else {
 649     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 650   }
 651   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 652   $invoice_data{'ship_country'} = ''
 653     if ( $invoice_data{'ship_country'} eq $countrydefault );
 654
 655   $invoice_data{'cid'} = $params{'cid'}
 656     if $params{'cid'};
 657
 658   if ( $cust_main->bill_locationnum
 659        && $cust_main->bill_location->country ne $countrydefault ) {
 660     $invoice_data{'country'} = &$escape_function($cust_main->bill_country_full);
 661   } else {
 662     $invoice_data{'country'} = '';
 663   }
 664
 665   my @address = ();
 666   $invoice_data{'address'} = \@address;
 667   push @address,
 668     $invoice_data{'payname'}.
 669       ( $cust_main->po_number
 670           ? " (P.O. #". $cust_main->po_number. ")"
 671           : ''
 672       )
 673   ;
 674   push @address, $cust_main->company
 675     if $cust_main->company;
 676   push @address, $cust_main->address1;
 677   push @address, $cust_main->address2
 678     if $cust_main->address2;
 679   push @address,
 680     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 681   push @address, $invoice_data{'country'}
 682     if $invoice_data{'country'};
 683   push @address, ''
 684     while (scalar(@address) < 5);
 685
 686   $invoice_data{'logo_file'} = $params{'logo_file'}
 687     if $params{'logo_file'};
 688   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 689     if $params{'barcode_file'};
 690   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 691     if $params{'barcode_img'};
 692   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 693     if $params{'barcode_cid'};
 694
 695   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 696 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 697   #my $balance_due = $self->owed + $pr_total - $cr_total;
 698   my $balance_due = $self->owed;
 699   if ( $self->enable_previous ) {
 700     $balance_due += $pr_total;
 701   }
 702   # otherwise the previous balance is not shown, so including it in the
 703   # balance due is just confusing
 704
 705   # the sum of amount owed on all invoices
 706   # (this is used in the summary & on the payment coupon)
 707   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 708
 709   # flag telling this invoice to have a first-page summary
 710   my $summarypage = '';
 711
 712   if ( $self->custnum && $self->invnum ) {
 713     # XXX should be an FS::cust_bill method to set the defaults, instead
 714     # of checking the type here
 715
 716     # info from customer's last invoice before this one, for some
 717     # summary formats
 718     $invoice_data{'last_bill'} = {};
 719
 720     my $last_bill = $self->previous_bill;
 721     if ( $last_bill ) {
 722
 723       # "balance_date_range" unfortunately is unsuitable for this, since it
 724       # cares about application dates.  We want to know the sum of all
 725       # _top-level transactions_ dated before the last invoice.
 726       #
 727       # still do this for the "Previous Balance" line of the summary block
 728       my @sql =
 729         map "$_ WHERE _date <= ? AND custnum = ?", (
 730           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 731           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 732           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 733           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 734         );
 735
 736       # the customer's current balance immediately after generating the last
 737       # bill
 738
 739       my $last_bill_balance = $last_bill->charged;
 740       foreach (@sql) {
 741         my $delta = FS::Record->scalar_sql(
 742           $_,
 743           $last_bill->_date - 1,
 744           $self->custnum,
 745         );
 746         $last_bill_balance += $delta;
 747       }
 748
 749       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 750
 751       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 752         $last_bill->invnum,
 753         $self->time2str_local('%D', $last_bill->_date),
 754         $last_bill_balance
 755       ) if $DEBUG > 0;
 756       # ("true_previous_balance" is a terrible name, but at least it's no
 757       # longer stored in the database)
 758       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 759
 760       # Now, get all applications of credits/payments dated on or after the
 761       # previous bill, to invoices before the current bill. (The
 762       # credit/payment date restriction prevents these from intersecting
 763       # the "Previous Balance" set.)
 764       # These are "adjustments". The past due balance will be shown as
 765       # Previous Balance - Adjustments.
 766       my $adjustments = 0;
 767       @sql = map {
 768         "SELECT COALESCE(SUM(y.amount),0) FROM $_ JOIN cust_bill USING (invnum)
 769          WHERE cust_bill._date < ?
 770            AND x._date >= ?
 771            AND cust_bill.custnum = ?"
 772         } "cust_credit AS x JOIN cust_credit_bill y USING (crednum)",
 773           "cust_pay    AS x JOIN cust_bill_pay    y USING (paynum)"
 774       ;
 775       foreach (@sql) {
 776         my $delta = FS::Record->scalar_sql(
 777           $_,
 778           $self->_date,
 779           $last_bill->_date,
 780           $self->custnum,
 781         );
 782         $adjustments += $delta;
 783       }
 784       $invoice_data{'balance_adjustments'} = sprintf("%.2f", $adjustments);
 785
 786       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 787                    $invoice_data{'balance_adjustments'}
 788       ) if $DEBUG > 0;
 789
 790       # the sum of amount owed on all previous invoices
 791       # ($pr_total is used elsewhere but not as $previous_balance)
 792       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 793
 794       $invoice_data{'last_bill'}{'_date'} = $last_bill->_date; #unformatted
 795       my (@payments, @credits);
 796       # for formats that itemize previous payments
 797       foreach my $cust_pay ( qsearch('cust_pay', {
 798                               'custnum' => $self->custnum,
 799                               '_date'   => { op => '>=',
 800                                              value => $last_bill->_date }
 801                              } ) )
 802       {
 803         next if $cust_pay->_date > $self->_date;
 804         push @payments, {
 805             '_date'       => $cust_pay->_date,
 806             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 807             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 808             'amount'      => sprintf('%.2f', $cust_pay->paid),
 809         };
 810         # not concerned about applications
 811       }
 812       foreach my $cust_credit ( qsearch('cust_credit', {
 813                               'custnum' => $self->custnum,
 814                               '_date'   => { op => '>=',
 815                                              value => $last_bill->_date }
 816                              } ) )
 817       {
 818         next if $cust_credit->_date > $self->_date;
 819         push @credits, {
 820             '_date'       => $cust_credit->_date,
 821             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 822             'creditreason'=> $cust_credit->reason,
 823             'amount'      => sprintf('%.2f', $cust_credit->amount),
 824         };
 825       }
 826       $invoice_data{'previous_payments'} = \@payments;
 827       $invoice_data{'previous_credits'}  = \@credits;
 828     } else {
 829       # there is no $last_bill
 830       $invoice_data{'true_previous_balance'} =
 831       $invoice_data{'balance_adjustments'}   =
 832       $invoice_data{'previous_balance'}      = '0.00';
 833       $invoice_data{'previous_payments'} = [];
 834       $invoice_data{'previous_credits'} = [];
 835     }
 836
 837     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 838       $invoice_data{'summarypage'} = $summarypage = 1;
 839     }
 840
 841   } # if this is an invoice
 842
 843   warn "$me substituting variables in notes, footer, smallfooter\n"
 844     if $DEBUG > 1;
 845
 846   my $tc = $self->template_conf;
 847   my @include = ( [ $tc,        'notes' ],
 848                   [ 'invoice_', 'footer' ],
 849                   [ 'invoice_', 'smallfooter', ],
 850                   [ 'invoice_', 'watermark' ],
 851                 );
 852   push @include, [ $tc,        'coupon', ]
 853     unless $params{'no_coupon'};
 854
 855   foreach my $i (@include) {
 856
 857     # load the configuration for this sub-template
 858
 859     my($base, $include) = @$i;
 860
 861     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 862
 863     my @inc_src = $conf->config($inc_file, $agentnum);
 864     if (!@inc_src) {
 865       my $converter = $convert_maps{$format}{$include};
 866       if ( $converter ) {
 867         # then attempt to convert LaTeX to the requested format
 868         $inc_file = $conf->key_orbase($base.'latex'.$include, $template);
 869         @inc_src = &$converter( $conf->config($inc_file, $agentnum) );
 870         foreach (@inc_src) {
 871           # this isn't included in the convert_maps
 872           my ($open, $close) = @{ $delimiters{$format} };
 873           s/\[\@--/$open/g;
 874           s/--\@\]/$close/g;
 875         }
 876       }
 877     } # else @inc_src is empty and that's fine
 878
 879     # make a Text::Template out of it
 880
 881     my $inc_tt = new Text::Template (
 882       TYPE       => 'ARRAY',
 883       SOURCE     => [ map "$_\n", @inc_src ],
 884       DELIMITERS => $delimiters{$format},
 885     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 886
 887     unless ( $inc_tt->compile() ) {
 888       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 889       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 890       die $error;
 891     }
 892
 893     # fill in variables
 894
 895     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 896
 897     $invoice_data{$include} =~ s/\n+$//
 898       if ($format eq 'latex');
 899   }
 900
 901 # if (well, probably when) we still need PO numbers in the brave new world of
 902 # 4.x, then we'll have to add them back as their own customer fields
 903 #  # let invoices use either of these as needed
 904 #  $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 905 #    ? $cust_main->payinfo : '';
 906 #  $invoice_data{'po_line'} =
 907 #    (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 908 #      ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 909 #      : $nbsp;
 910
 911   my %money_chars = ( 'latex'    => '',
 912                       'html'     => $conf->config('money_char') || '$',
 913                       'template' => '',
 914                     );
 915   my $money_char = $money_chars{$format};
 916
 917   # extremely dubious
 918   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 919                             'html'     => $conf->config('money_char') || '$',
 920                             'template' => '',
 921                           );
 922   my $other_money_char = $other_money_chars{$format};
 923   $invoice_data{'dollar'} = $other_money_char;
 924
 925   my %minus_signs = ( 'latex'    => '$-$',
 926                       'html'     => '&minus;',
 927                       'template' => '- ' );
 928   my $minus = $minus_signs{$format};
 929
 930   my @detail_items = ();
 931   my @total_items = ();
 932   my @buf = ();
 933   my @sections = ();
 934
 935   $invoice_data{'detail_items'} = \@detail_items;
 936   $invoice_data{'total_items'} = \@total_items;
 937   $invoice_data{'buf'} = \@buf;
 938   $invoice_data{'sections'} = \@sections;
 939
 940   warn "$me generating sections\n"
 941     if $DEBUG > 1;
 942
 943   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 944   my $multisection = $self->has_sections;
 945   $invoice_data{'multisection'} = $multisection;
 946   my $late_sections;
 947   my $extra_sections = [];
 948   my $extra_lines = ();
 949
 950   # default section ('Charges')
 951   my $default_section = { 'description' => '',
 952                           'subtotal'    => '',
 953                           'no_subtotal' => 1,
 954                         };
 955
 956   # Previous Charges section
 957   # subtotal is the first return value from $self->previous
 958   my $previous_section;
 959   # if the invoice has major sections, or if we're summarizing previous
 960   # charges with a single line, or if we've been specifically told to put them
 961   # in a section, create a section for previous charges:
 962   if ( $multisection or
 963        $conf->exists('previous_balance-summary_only') or
 964        $conf->exists('previous_balance-section') ) {
 965
 966     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 967                            'subtotal'    => $other_money_char.
 968                                             sprintf('%.2f', $pr_total),
 969                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 970                          };
 971     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 972       join(' / ', map { $cust_main->balance_date_range(@$_) }
 973                   $self->_prior_month30s
 974           )
 975       if $conf->exists('invoice_include_aging');
 976
 977   } else {
 978     # otherwise put them in the main section
 979     $previous_section = $default_section;
 980   }
 981
 982   my $adjust_section = {
 983     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 984     'adjust_section' => 1,
 985     'subtotal'       => 0,   # adjusted below
 986   };
 987   my $adjust_weight = _pkg_category($adjust_section->{description})
 988                         ? _pkg_category($adjust_section->{description})->weight
 989                         : 0;
 990   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 991   # Note: 'sort_weight' here is actually a flag telling whether there is an
 992   # explicit package category for the adjust section. If so, certain behavior
 993   # happens.
 994   $adjust_section->{'sort_weight'} = $adjust_weight;
 995
 996
 997   if ( $multisection ) {
 998     ($extra_sections, $extra_lines) =
 999       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
1000       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
1001       && $self->can('_items_extra_usage_sections');
1002
1003     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
1004
1005     push @detail_items, @$extra_lines if $extra_lines;
1006
1007     # the code is written so that both methods can be used together, but
1008     # we haven't yet changed the template to take advantage of that, so for
1009     # now, treat them as mutually exclusive.
1010     my %section_method = ( by_category => 1 );
1011     if ( $conf->config($tc.'sections_method') eq 'location' ) {
1012       %section_method = ( by_location => 1 );
1013     }
1014     my ($early, $late) =
1015       $self->_items_sections( 'summary' => $summarypage,
1016                               'escape'  => $escape_function_nonbsp,
1017                               'extra_sections' => $extra_sections,
1018                               'format'  => $format,
1019                               %section_method
1020                             );
1021     push @sections, @$early;
1022     $late_sections = $late;
1023
1024     if (    $conf->exists('svc_phone_sections')
1025          && $self->can('_items_svc_phone_sections')
1026        )
1027     {
1028       my ($phone_sections, $phone_lines) =
1029         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1030       push @{$late_sections}, @$phone_sections;
1031       push @detail_items, @$phone_lines;
1032     }
1033     if ( $conf->exists('voip-cust_accountcode_cdr')
1034          && $cust_main->accountcode_cdr
1035          && $self->can('_items_accountcode_cdr')
1036        )
1037     {
1038       my ($accountcode_section, $accountcode_lines) =
1039         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1040       if ( scalar(@$accountcode_lines) ) {
1041           push @{$late_sections}, $accountcode_section;
1042           push @detail_items, @$accountcode_lines;
1043       }
1044     }
1045   } else {# not multisection
1046     # make a default section
1047     push @sections, $default_section;
1048     # and calculate the finance charge total, since it won't get done otherwise.
1049     # and the default section total
1050     # XXX possibly finance_pkgclass should not be used in this manner?
1051     my @finance_charges;
1052     my @charges;
1053     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1054       if ( $invoice_data{finance_section} and
1055         grep { $_->section eq $invoice_data{finance_section} }
1056            $cust_bill_pkg->cust_bill_pkg_display ) {
1057         # I think these are always setup fees, but just to be sure...
1058         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1059       } else {
1060         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1061       }
1062     }
1063     $invoice_data{finance_amount} =
1064       sprintf('%.2f', sum( @finance_charges ) || 0);
1065     $default_section->{subtotal} = $other_money_char.
1066                                     sprintf('%.2f', sum( @charges ) || 0);
1067   }
1068
1069   # start setting up summary subtotals
1070   my @summary_subtotals;
1071   my $method = $conf->config('summary_subtotals_method');
1072   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1073     # then re-section them by the correct method
1074     my %section_method = ( by_category => 1 );
1075     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1076       %section_method = ( by_location => 1 );
1077     }
1078     my ($early, $late) =
1079       $self->_items_sections( 'summary' => $summarypage,
1080                               'escape'  => $escape_function_nonbsp,
1081                               'extra_sections' => $extra_sections,
1082                               'format'  => $format,
1083                               %section_method
1084                             );
1085     foreach ( @$early ) {
1086       next if $_->{subtotal} == 0;
1087       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1088       push @summary_subtotals, $_;
1089     }
1090   } else {
1091     # subtotal sectioning is the same as for the actual invoice sections
1092     @summary_subtotals = @sections;
1093   }
1094
1095   # Hereafter, push sections to both @sections and @summary_subtotals
1096   # if they belong in both places (e.g. tax section).  Late sections are
1097   # never in @summary_subtotals.
1098
1099   # previous invoice balances in the Previous Charges section if there
1100   # is one, otherwise in the main detail section
1101   # (except if summary_only is enabled, don't show them at all)
1102   if ( $self->can('_items_previous') &&
1103        $self->enable_previous &&
1104        ! $conf->exists('previous_balance-summary_only') ) {
1105
1106     warn "$me adding previous balances\n"
1107       if $DEBUG > 1;
1108
1109     foreach my $line_item ( $self->_items_previous ) {
1110
1111       my $detail = {
1112         ref             => $line_item->{'pkgnum'},
1113         pkgpart         => $line_item->{'pkgpart'},
1114         #quantity        => 1, # not really correct
1115         section         => $previous_section, # which might be $default_section
1116         description     => &$escape_function($line_item->{'description'}),
1117         ext_description => [ map { &$escape_function($_) }
1118                              @{ $line_item->{'ext_description'} || [] }
1119                            ],
1120         amount          => $money_char . $line_item->{'amount'},
1121         product_code    => $line_item->{'pkgpart'} || 'N/A',
1122       };
1123
1124       push @detail_items, $detail;
1125       push @buf, [ $detail->{'description'},
1126                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1127                  ];
1128     }
1129
1130   }
1131
1132   if ( @pr_cust_bill && $self->enable_previous ) {
1133     push @buf, ['','-----------'];
1134     push @buf, [ $self->mt('Total Previous Balance'),
1135                  $money_char. sprintf("%10.2f", $pr_total) ];
1136     push @buf, ['',''];
1137   }
1138
1139   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1140       warn "$me adding DID summary\n"
1141         if $DEBUG > 1;
1142
1143       my ($didsummary,$minutes) = $self->_did_summary;
1144       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1145       push @detail_items,
1146        { 'description' => $didsummary_desc,
1147            'ext_description' => [ $didsummary, $minutes ],
1148        };
1149   }
1150
1151   foreach my $section (@sections, @$late_sections) {
1152
1153     # begin some normalization
1154     $section->{'subtotal'} = $section->{'amount'}
1155       if $multisection
1156          && !exists($section->{subtotal})
1157          && exists($section->{amount});
1158
1159     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1160       if ( $invoice_data{finance_section} &&
1161            $section->{'description'} eq $invoice_data{finance_section} );
1162
1163     if ( $multisection ) {
1164
1165       if ( ref($section->{'subtotal'}) ) {
1166
1167         $section->{'subtotal'} =
1168           sprintf("$other_money_char%.2f to $other_money_char%.2f",
1169                     $section->{'subtotal'}[0],
1170                     $section->{'subtotal'}[1]
1171                  );
1172
1173       } else {
1174
1175         $section->{'subtotal'} = $other_money_char.
1176                                  sprintf('%.2f', $section->{'subtotal'})
1177
1178       }
1179
1180       # continue some normalization
1181       $section->{'amount'}   = $section->{'subtotal'}
1182
1183     }
1184
1185     if ( $section->{'description'} ) {
1186       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1187                    [ '', '' ],
1188                  );
1189     }
1190
1191     warn "$me   setting options\n"
1192       if $DEBUG > 1;
1193
1194     my %options = ();
1195     $options{'section'} = $section if $multisection;
1196     $options{'format'} = $format;
1197     $options{'escape_function'} = $escape_function;
1198     $options{'no_usage'} = 1 unless $unsquelched;
1199     $options{'unsquelched'} = $unsquelched;
1200     $options{'summary_page'} = $summarypage;
1201     $options{'skip_usage'} =
1202       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1203     $options{'preref_callback'} = $params{'preref_callback'};
1204
1205     warn "$me   searching for line items\n"
1206       if $DEBUG > 1;
1207
1208     foreach my $line_item ( $self->_items_pkg(%options),
1209                             $self->_items_fee(%options) ) {
1210
1211       warn "$me     adding line item ".
1212            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1213         if $DEBUG > 1;
1214
1215       push @buf, ( [ $line_item->{'description'},
1216                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1217                    ],
1218                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1219                  );
1220
1221       $line_item->{'ref'} = $line_item->{'pkgnum'};
1222       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1223       $line_item->{'section'} = $section;
1224       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1225       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1226
1227       if ( length($line_item->{'unit_amount'}) ) {
1228         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1229       }
1230       $line_item->{'ext_description'} ||= [];
1231
1232       push @detail_items, $line_item;
1233     }
1234
1235     if ( $section->{'description'} ) {
1236       push @buf, ( ['','-----------'],
1237                    [ $section->{'description'}. ' sub-total',
1238                       $section->{'subtotal'} # already formatted this
1239                    ],
1240                    [ '', '' ],
1241                    [ '', '' ],
1242                  );
1243     }
1244
1245   }
1246
1247   $invoice_data{current_less_finance} =
1248     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1249
1250   # if there's anything in the Previous Charges section, prepend it to the list
1251   if ( $pr_total and $previous_section ne $default_section ) {
1252     unshift @sections, $previous_section;
1253     # but not @summary_subtotals
1254   }
1255
1256   warn "$me adding taxes\n"
1257     if $DEBUG > 1;
1258
1259   # create a tax section if we don't yet have one
1260   my @items_tax = $self->_items_tax;
1261   my $tax_description = 'Taxes, Surcharges, and Fees';
1262   my $tax_section =
1263     List::Util::first { $_->{description} eq $tax_description } @sections;
1264   if (!$tax_section) {
1265     $tax_section = { 'description' => $tax_description };
1266     push @sections, $tax_section if $multisection and @items_tax > 0;
1267   }
1268   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1269   # if this is an existing tax section, we're merging the tax items into it.
1270   # grab the taxtotal that's already there, strip the money symbol if any
1271   my $taxtotal = $tax_section->{'subtotal'} || 0;
1272   $taxtotal =~ s/^\Q$other_money_char\E//;
1273
1274   # this does nothing
1275   #my $tax_weight = _pkg_category($tax_section->{description})
1276   #                      ? _pkg_category($tax_section->{description})->weight
1277   #                      : 0;
1278   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1279   #$tax_section->{'sort_weight'} = $tax_weight;
1280
1281   foreach my $tax ( @items_tax ) {
1282
1283     $taxtotal += $tax->{'amount'};
1284
1285     my $description = &$escape_function( $tax->{'description'} );
1286     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1287
1288     if ( $multisection ) {
1289
1290       push @detail_items, {
1291         ext_description => [],
1292         ref          => '',
1293         quantity     => '',
1294         description  => $description,
1295         amount       => $money_char. $amount,
1296         product_code => '',
1297         section      => $tax_section,
1298       };
1299
1300     } else {
1301
1302       push @total_items, {
1303         'total_item'   => $description,
1304         'total_amount' => $other_money_char. $amount,
1305       };
1306
1307     }
1308
1309     push @buf,[ $description,
1310                 $money_char. $amount,
1311               ];
1312
1313   }
1314
1315   if ( @items_tax ) {
1316     my $total = {};
1317     $total->{'total_item'} = $self->mt('Sub-total');
1318     $total->{'total_amount'} =
1319       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1320
1321     if ( $multisection ) {
1322       if ( $taxtotal > 0 ) {
1323         # there are taxes, so prepare the section to be displayed.
1324         # $taxtotal already includes any line items that were already in the
1325         # section (fees, taxes that are charged as packages for some reason).
1326         # also set 'summarized' to false so that this isn't a summary-only
1327         # section.
1328         $tax_section->{'subtotal'} = $other_money_char.
1329                                      sprintf('%.2f', $taxtotal);
1330         $tax_section->{'pretotal'} = 'New charges sub-total '.
1331                                      $total->{'total_amount'};
1332         $tax_section->{'description'} = $self->mt($tax_description);
1333         $tax_section->{'summarized'} = '';
1334
1335         # append it if it's not already there
1336         if ( !grep $tax_section, @sections ) {
1337           push @sections, $tax_section;
1338           push @summary_subtotals, $tax_section;
1339         }
1340       }
1341
1342     } else {
1343       unshift @total_items, $total;
1344     }
1345   }
1346   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1347
1348   ###
1349   # Totals
1350   ###
1351
1352   my %embolden_functions = (
1353     'latex'    => sub { return '\textbf{'. shift(). '}' },
1354     'html'     => sub { return '<b>'. shift(). '</b>' },
1355     'template' => sub { shift },
1356   );
1357   my $embolden_function = $embolden_functions{$format};
1358
1359   if ( $multisection ) {
1360
1361     if ( $adjust_section->{'sort_weight'} ) {
1362       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1363         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1364     } else{
1365       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1366         $other_money_char.  sprintf('%.2f', $self->charged );
1367     }
1368
1369   }
1370
1371   if ( $self->can('_items_total') ) { # should always be true now
1372
1373     # even for multisection, need plain text version
1374
1375     my @new_total_items = $self->_items_total;
1376
1377     push @buf,['','-----------'];
1378
1379     foreach ( @new_total_items ) {
1380       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1381       $_->{'total_item'}   = &$embolden_function( $item );
1382
1383       if ( ref($amount) ) {
1384         $_->{'total_amount'} = &$embolden_function(
1385                                  $other_money_char.$amount->[0]. ' to '.
1386                                  $other_money_char.$amount->[1]
1387                                );
1388       } else {
1389       $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1390       }
1391
1392       # but if it's multisection, don't append to @total_items. the adjust
1393       # section has all this stuff
1394       push @total_items, $_ if !$multisection;
1395       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1396     }
1397
1398     push @buf, [ '', '' ];
1399
1400     # if we're showing previous invoices, also show previous
1401     # credits and payments
1402     if ( $self->enable_previous
1403           and $self->can('_items_credits')
1404           and $self->can('_items_payments') )
1405       {
1406
1407       # credits
1408       my $credittotal = 0;
1409       foreach my $credit (
1410         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1411       ) {
1412
1413         my $total;
1414         $total->{'total_item'} = &$escape_function($credit->{'description'});
1415         $credittotal += $credit->{'amount'};
1416         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1417         if ( $multisection ) {
1418           push @detail_items, {
1419             ext_description => [],
1420             ref          => '',
1421             quantity     => '',
1422             description  => &$escape_function($credit->{'description'}),
1423             amount       => $money_char . $credit->{'amount'},
1424             product_code => '',
1425             section      => $adjust_section,
1426           };
1427         } else {
1428           push @total_items, $total;
1429         }
1430
1431       }
1432       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1433
1434       #credits (again)
1435       foreach my $credit (
1436         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1437       ) {
1438         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1439       }
1440
1441       # payments
1442       my $paymenttotal = 0;
1443       foreach my $payment (
1444         $self->_items_payments( 'template' => $template )
1445       ) {
1446         my $total = {};
1447         $total->{'total_item'} = &$escape_function($payment->{'description'});
1448         $paymenttotal += $payment->{'amount'};
1449         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1450         if ( $multisection ) {
1451           push @detail_items, {
1452             ext_description => [],
1453             ref          => '',
1454             quantity     => '',
1455             description  => &$escape_function($payment->{'description'}),
1456             amount       => $money_char . $payment->{'amount'},
1457             product_code => '',
1458             section      => $adjust_section,
1459           };
1460         }else{
1461           push @total_items, $total;
1462         }
1463         push @buf, [ $payment->{'description'},
1464                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1465                    ];
1466       }
1467       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1468
1469       if ( $multisection ) {
1470         $adjust_section->{'subtotal'} = $other_money_char.
1471                                         sprintf('%.2f', $credittotal + $paymenttotal);
1472
1473         #why this? because {sort_weight} forces the adjust_section to appear
1474         #in @extra_sections instead of @sections. obviously.
1475         push @sections, $adjust_section
1476           unless $adjust_section->{sort_weight};
1477         # do not summarize; adjustments there are shown according to
1478         # different rules
1479       }
1480
1481       # create Balance Due message
1482       {
1483         my $total;
1484         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1485         $total->{'total_amount'} =
1486           &$embolden_function(
1487             $other_money_char. sprintf('%.2f', #why? $summarypage
1488                                                #  ? $self->charged +
1489                                                #    $self->billing_balance
1490                                                #  :
1491                                                    $self->owed + $pr_total
1492                                       )
1493           );
1494         if ( $multisection && !$adjust_section->{sort_weight} ) {
1495           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1496                                            $total->{'total_amount'};
1497         } else {
1498           push @total_items, $total;
1499         }
1500         push @buf,['','-----------'];
1501         push @buf,[$self->balance_due_msg, $money_char.
1502           sprintf("%10.2f", $balance_due ) ];
1503       }
1504
1505       if ( $conf->exists('previous_balance-show_credit')
1506           and $cust_main->balance < 0 ) {
1507         my $credit_total = {
1508           'total_item'    => &$embolden_function($self->credit_balance_msg),
1509           'total_amount'  => &$embolden_function(
1510             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1511           ),
1512         };
1513         if ( $multisection ) {
1514           $adjust_section->{'posttotal'} .= $newline_token .
1515             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1516         }
1517         else {
1518           push @total_items, $credit_total;
1519         }
1520         push @buf,['','-----------'];
1521         push @buf,[$self->credit_balance_msg, $money_char.
1522           sprintf("%10.2f", -$cust_main->balance ) ];
1523       }
1524     }
1525
1526   } #end of default total adding ! can('_items_total')
1527
1528   if ( $multisection ) {
1529     if (    $conf->exists('svc_phone_sections')
1530          && $self->can('_items_svc_phone_sections')
1531        )
1532     {
1533       my $total;
1534       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1535       $total->{'total_amount'} =
1536         &$embolden_function(
1537           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1538         );
1539       my $last_section = pop @sections;
1540       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1541                                      $total->{'total_amount'};
1542       push @sections, $last_section;
1543     }
1544     push @sections, @$late_sections
1545       if $unsquelched;
1546   }
1547
1548   # make a discounts-available section, even without multisection
1549   if ( $conf->exists('discount-show_available')
1550        and my @discounts_avail = $self->_items_discounts_avail ) {
1551     my $discount_section = {
1552       'description' => $self->mt('Discounts Available'),
1553       'subtotal'    => '',
1554       'no_subtotal' => 1,
1555     };
1556
1557     push @sections, $discount_section; # do not summarize
1558     push @detail_items, map { +{
1559         'ref'         => '', #should this be something else?
1560         'section'     => $discount_section,
1561         'description' => &$escape_function( $_->{description} ),
1562         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1563         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1564     } } @discounts_avail;
1565   }
1566
1567   # not adding any more sections after this
1568   $invoice_data{summary_subtotals} = \@summary_subtotals;
1569
1570   # usage subtotals
1571   if ( $conf->exists('usage_class_summary')
1572        and $self->can('_items_usage_class_summary') ) {
1573     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function, 'money_char' => $other_money_char);
1574     if ( @usage_subtotals ) {
1575       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1576       unshift @detail_items, @usage_subtotals;
1577     }
1578   }
1579
1580   # invoice history "section" (not really a section)
1581   # not to be included in any subtotals, completely independent of
1582   # everything...
1583   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1584     my %history;
1585     my %monthorder;
1586     foreach my $cust_bill ( $cust_main->cust_bill ) {
1587       # XXX hardcoded format, and currently only 'charged'; add other fields
1588       # if they become necessary
1589       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1590       $history{$date} ||= 0;
1591       $history{$date} += $cust_bill->charged;
1592       # just so we have a numeric sort key
1593       $monthorder{$date} ||= $cust_bill->_date;
1594     }
1595     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1596                         keys %history;
1597     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1598     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1599   }
1600
1601   # service locations: another option for template customization
1602   my %location_info;
1603   foreach my $item (@detail_items) {
1604     if ( $item->{locationnum} ) {
1605       $location_info{ $item->{locationnum} } ||= {
1606         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1607       };
1608     }
1609   }
1610   $invoice_data{location_info} = \%location_info;
1611
1612   # debugging hook: call this with 'diag' => 1 to just get a hash of
1613   # the invoice variables
1614   return \%invoice_data if ( $params{'diag'} );
1615
1616   # All sections and items are built; now fill in templates.
1617   my @includelist = ();
1618   push @includelist, 'summary' if $summarypage;
1619   foreach my $include ( @includelist ) {
1620
1621     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1622     my @inc_src;
1623
1624     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1625
1626       @inc_src = $conf->config($inc_file, $agentnum);
1627
1628     } else {
1629
1630       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1631
1632       my $convert_map = $convert_maps{$format}{$include};
1633
1634       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1635                        s/--\@\]/$delimiters{$format}[1]/g;
1636                        $_;
1637                      }
1638                  &$convert_map( $conf->config($inc_file, $agentnum) );
1639
1640     }
1641
1642     my $inc_tt = new Text::Template (
1643       TYPE       => 'ARRAY',
1644       SOURCE     => [ map "$_\n", @inc_src ],
1645       DELIMITERS => $delimiters{$format},
1646     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1647
1648     unless ( $inc_tt->compile() ) {
1649       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1650       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1651       die $error;
1652     }
1653
1654     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1655
1656     $invoice_data{$include} =~ s/\n+$//
1657       if ($format eq 'latex');
1658   }
1659
1660   $invoice_lines = 0;
1661   my $wasfunc = 0;
1662   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1663     /invoice_lines\((\d*)\)/;
1664     $invoice_lines += $1 || scalar(@buf);
1665     $wasfunc=1;
1666   }
1667   die "no invoice_lines() functions in template?"
1668     if ( $format eq 'template' && !$wasfunc );
1669
1670   if ( $invoice_lines ) {
1671     $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1672     $invoice_data{'total_pages'}++
1673       if scalar(@buf) % $invoice_lines;
1674   }
1675
1676   #setup subroutine for the template
1677   $invoice_data{invoice_lines} = sub {
1678     my $lines = shift || scalar(@buf);
1679     map {
1680       scalar(@buf)
1681         ? shift @buf
1682         : [ '', '' ];
1683     }
1684     ( 1 .. $lines );
1685   };
1686
1687   if ($format eq 'template') {
1688
1689     my $lines;
1690     my @collect;
1691     while (@buf) {
1692       push @collect, split("\n",
1693         $text_template->fill_in( HASH => \%invoice_data )
1694       );
1695       $invoice_data{'page'}++;
1696     }
1697     map "$_\n", @collect;
1698
1699   } else { # this is where we actually create the invoice
1700
1701     if ( $params{no_addresses} ) {
1702       delete $invoice_data{$_} foreach qw(
1703         payname company address1 address2 city state zip country
1704       );
1705       $invoice_data{returnaddress} = '~';
1706     }
1707
1708     warn "filling in template for invoice ". $self->invnum. "\n"
1709       if $DEBUG;
1710     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1711       if $DEBUG > 1;
1712
1713     $text_template->fill_in(HASH => \%invoice_data);
1714   }
1715 }
1716
1717 sub notice_name { '('.shift->table.')'; }
1718
1719 # this is not supposed to happen
1720 sub template_conf { warn "bare FS::Template_Mixin::template_conf";
1721   'invoice_';
1722 }
1723
1724 # helper routine for generating date ranges
1725 sub _prior_month30s {
1726   my $self = shift;
1727   my @ranges = (
1728    [ 1,       2592000 ], # 0-30 days ago
1729    [ 2592000, 5184000 ], # 30-60 days ago
1730    [ 5184000, 7776000 ], # 60-90 days ago
1731    [ 7776000, 0       ], # 90+   days ago
1732   );
1733
1734   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1735           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1736       ] }
1737   @ranges;
1738 }
1739
1740 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1741
1742 Returns an postscript invoice, as a scalar.
1743
1744 Options can be passed as a hashref (recommended) or as a list of time, template
1745 and then any key/value pairs for any other options.
1746
1747 I<time> an optional value used to control the printing of overdue messages.  The
1748 default is now.  It isn't the date of the invoice; that's the `_date' field.
1749 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1750 L<Time::Local> and L<Date::Parse> for conversion functions.
1751
1752 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1753
1754 =cut
1755
1756 sub print_ps {
1757   my $self = shift;
1758
1759   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1760   my $ps = generate_ps($file);
1761   unlink($logofile);
1762   unlink($barcodefile) if $barcodefile;
1763
1764   $ps;
1765 }
1766
1767 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1768
1769 Returns an PDF invoice, as a scalar.
1770
1771 Options can be passed as a hashref (recommended) or as a list of time, template
1772 and then any key/value pairs for any other options.
1773
1774 I<time> an optional value used to control the printing of overdue messages.  The
1775 default is now.  It isn't the date of the invoice; that's the `_date' field.
1776 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1777 L<Time::Local> and L<Date::Parse> for conversion functions.
1778
1779 I<template>, if specified, is the name of a suffix for alternate invoices.
1780
1781 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1782
1783 =cut
1784
1785 sub print_pdf {
1786   my $self = shift;
1787
1788   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1789   my $pdf = generate_pdf($file);
1790   unlink($logofile);
1791   unlink($barcodefile) if $barcodefile;
1792
1793   $pdf;
1794 }
1795
1796 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1797
1798 Returns an HTML invoice, as a scalar.
1799
1800 I<time> an optional value used to control the printing of overdue messages.  The
1801 default is now.  It isn't the date of the invoice; that's the `_date' field.
1802 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1803 L<Time::Local> and L<Date::Parse> for conversion functions.
1804
1805 I<template>, if specified, is the name of a suffix for alternate invoices.
1806
1807 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1808
1809 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1810 when emailing the invoice as part of a multipart/related MIME email.
1811
1812 =cut
1813
1814 sub print_html {
1815   my $self = shift;
1816   my %params;
1817   if ( ref($_[0]) ) {
1818     %params = %{ shift() };
1819   } else {
1820     %params = @_;
1821   }
1822   $params{'format'} = 'html';
1823
1824   $self->print_generic( %params );
1825 }
1826
1827 # quick subroutine for print_latex
1828 #
1829 # There are ten characters that LaTeX treats as special characters, which
1830 # means that they do not simply typeset themselves:
1831 #      # $ % & ~ _ ^ \ { }
1832 #
1833 # TeX ignores blanks following an escaped character; if you want a blank (as
1834 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1835
1836 sub _latex_escape {
1837   my $value = shift;
1838   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1839   $value =~ s/([<>])/\$$1\$/g;
1840   $value;
1841 }
1842
1843 sub _html_escape {
1844   my $value = shift;
1845   encode_entities($value);
1846   $value;
1847 }
1848
1849 sub _html_escape_nbsp {
1850   my $value = _html_escape(shift);
1851   $value =~ s/ +/&nbsp;/g;
1852   $value;
1853 }
1854
1855 #utility methods for print_*
1856
1857 sub _translate_old_latex_format {
1858   warn "_translate_old_latex_format called\n"
1859     if $DEBUG;
1860
1861   my @template = ();
1862   while ( @_ ) {
1863     my $line = shift;
1864
1865     if ( $line =~ /^%%Detail\s*$/ ) {
1866
1867       push @template, q![@--!,
1868                       q!  foreach my $_tr_line (@detail_items) {!,
1869                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1870                       q!      $_tr_line->{'description'} .= !,
1871                       q!        "\\tabularnewline\n~~".!,
1872                       q!        join( "\\tabularnewline\n~~",!,
1873                       q!          @{$_tr_line->{'ext_description'}}!,
1874                       q!        );!,
1875                       q!    }!;
1876
1877       while ( ( my $line_item_line = shift )
1878               !~ /^%%EndDetail\s*$/                            ) {
1879         $line_item_line =~ s/'/\\'/g;    # nice LTS
1880         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1881         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1882         push @template, "    \$OUT .= '$line_item_line';";
1883       }
1884
1885       push @template, '}',
1886                       '--@]';
1887       #' doh, gvim
1888     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1889
1890       push @template, '[@--',
1891                       '  foreach my $_tr_line (@total_items) {';
1892
1893       while ( ( my $total_item_line = shift )
1894               !~ /^%%EndTotalDetails\s*$/                      ) {
1895         $total_item_line =~ s/'/\\'/g;    # nice LTS
1896         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1897         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1898         push @template, "    \$OUT .= '$total_item_line';";
1899       }
1900
1901       push @template, '}',
1902                       '--@]';
1903
1904     } else {
1905       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1906       push @template, $line;
1907     }
1908
1909   }
1910
1911   if ($DEBUG) {
1912     warn "$_\n" foreach @template;
1913   }
1914
1915   (@template);
1916 }
1917
1918 =item terms
1919
1920 =cut
1921
1922 sub terms {
1923   my $self = shift;
1924   my $conf = $self->conf;
1925
1926   #check for an invoice-specific override
1927   return $self->invoice_terms if $self->invoice_terms;
1928
1929   #check for a customer- specific override
1930   my $cust_main = $self->cust_main;
1931   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1932
1933   my $agentnum = '';
1934   if ( $cust_main ) {
1935     $agentnum = $cust_main->agentnum;
1936   } elsif ( my $prospect_main = $self->prospect_main ) {
1937     $agentnum = $prospect_main->agentnum;
1938   }
1939
1940   #use configured default
1941   $conf->config('invoice_default_terms', $agentnum) || '';
1942 }
1943
1944 =item due_date
1945
1946 =cut
1947
1948 sub due_date {
1949   my $self = shift;
1950   my $duedate = '';
1951   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1952     $duedate = $self->_date() + ( $1 * 86400 );
1953   } elsif ( $self->terms =~ /^End of Month$/ ) {
1954     my ($mon,$year) = (localtime($self->_date) )[4,5];
1955     $mon++;
1956     until ( $mon < 12 ) { $mon -= 12; $year++; }
1957     my $nextmonth_first = timelocal(0,0,0,1,$mon,$year);
1958     $duedate = $nextmonth_first - 86400;
1959   }
1960   $duedate;
1961 }
1962
1963 =item due_date2str
1964
1965 =cut
1966
1967 sub due_date2str {
1968   my $self = shift;
1969   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1970 }
1971
1972 =item balance_due_msg
1973
1974 =cut
1975
1976 sub balance_due_msg {
1977   my $self = shift;
1978   my $msg = $self->mt('Balance Due');
1979   return $msg unless $self->terms; # huh?
1980   if ( !$self->conf->exists('invoice_show_prior_due_date')
1981        or $self->conf->exists('invoice_sections') ) {
1982     # if enabled, the due date is shown with Total New Charges (see
1983     # _items_total) and not here
1984     # (yes, or if invoice_sections is enabled; this is just for compatibility)
1985     if ( $self->due_date ) {
1986       my $please_pay_by =
1987         $self->conf->config('invoice_pay_by_msg', $self->agentnum)
1988         || 'Please pay by [_1]';
1989       $msg .= ' - ' . $self->mt($please_pay_by, $self->due_date2str('short')).
1990               ' '
1991        unless $self->conf->config_bool('invoice_omit_due_date',$self->agentnum);
1992     } elsif ( $self->terms ) {
1993       $msg .= ' - '. $self->mt($self->terms);
1994     }
1995   }
1996   $msg;
1997 }
1998
1999 =item balance_due_date
2000
2001 =cut
2002
2003 sub balance_due_date {
2004   my $self = shift;
2005   my $conf = $self->conf;
2006   my $duedate = '';
2007   my $terms = $self->terms;
2008   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2009     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
2010   }
2011   $duedate;
2012 }
2013
2014 sub credit_balance_msg {
2015   my $self = shift;
2016   $self->mt('Credit Balance Remaining')
2017 }
2018
2019 =item _date_pretty
2020
2021 Returns a string with the date, for example: "3/20/2008", localized for the
2022 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
2023
2024 =cut
2025
2026 sub _date_pretty {
2027   my $self = shift;
2028   $self->time2str_local('short', $self->_date);
2029 }
2030
2031 =item _date_pretty_unlocalized
2032
2033 Returns a string with the date, for example: "3/20/2008", in the format
2034 configured for the back-office.  Use _date_pretty for end-customer display use.
2035
2036 =cut
2037
2038 sub _date_pretty_unlocalized {
2039   my $self = shift;
2040   time2str($date_format, $self->_date);
2041 }
2042
2043 =item email HASHREF
2044
2045 Emails this template.
2046
2047 Options are passed as a hashref.  Available options:
2048
2049 =over 4
2050
2051 =item from
2052
2053 If specified, overrides the default From: address.
2054
2055 =item notice_name
2056
2057 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
2058
2059 =item template
2060
2061 (Deprecated) If specified, is the name of a suffix for alternate template files.
2062
2063 =back
2064
2065 Options accepted by generate_email can also be used.
2066
2067 =cut
2068
2069 sub email {
2070   my $self = shift;
2071   my $opt = shift || {};
2072   if ($opt and !ref($opt)) {
2073     die ref($self). '->email called with positional parameters';
2074   }
2075
2076   return if $self->hide;
2077
2078   my $error = send_email(
2079     $self->generate_email(
2080       'subject'     => $self->email_subject($opt->{template}),
2081       %$opt, # template, etc.
2082     )
2083   );
2084
2085   die "can't email: $error\n" if $error;
2086 }
2087
2088 =item generate_email OPTION => VALUE ...
2089
2090 Options:
2091
2092 =over 4
2093
2094 =item from
2095
2096 sender address, required
2097
2098 =item template
2099
2100 alternate template name, optional
2101
2102 =item subject
2103
2104 email subject, optional
2105
2106 =item notice_name
2107
2108 notice name instead of "Invoice", optional
2109
2110 =back
2111
2112 Returns an argument list to be passed to L<FS::Misc::send_email>.
2113
2114 =cut
2115
2116 use MIME::Entity;
2117 use Encode;
2118
2119 sub generate_email {
2120
2121   my $self = shift;
2122   my %args = @_;
2123   my $conf = $self->conf;
2124
2125   my $me = '[FS::Template_Mixin::generate_email]';
2126
2127   my %return = (
2128     'from'      => $args{'from'},
2129     'subject'   => ($args{'subject'} || $self->email_subject),
2130     'custnum'   => $self->custnum,
2131     'msgtype'   => 'invoice',
2132   );
2133
2134   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2135
2136   my $cust_main = $self->cust_main;
2137
2138   if (ref($args{'to'}) eq 'ARRAY') {
2139     $return{'to'} = $args{'to'};
2140   } elsif ( $cust_main ) {
2141     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2142   }
2143
2144   my $tc = $self->template_conf;
2145
2146   my @text; # array of lines
2147   my $html; # a big string
2148   my @related_parts; # will contain the text/HTML alternative, and images
2149   my $related; # will contain the multipart/related object
2150
2151   if ( $conf->exists($tc. 'email_pdf') ) {
2152     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2153
2154       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2155         if $DEBUG;
2156
2157       my $msg_template = FS::msg_template->by_key($msgnum)
2158         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2159       my $cust_msg = $msg_template->prepare(
2160         cust_main => $self->cust_main,
2161         object    => $self,
2162         msgtype   => 'invoice',
2163       );
2164
2165       # XXX hack to make this work in the new cust_msg era; consider replacing
2166       # with cust_bill_send_with_notice events.
2167       my @parts = $cust_msg->parts;
2168       foreach my $part (@parts) { # will only have two parts, normally
2169         if ( $part->mime_type eq 'text/plain' ) {
2170           @text = @{ $part->body };
2171         } elsif ( $part->mime_type eq 'text/html' ) {
2172           $html = $part->bodyhandle->as_string;
2173         }
2174       }
2175
2176     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2177
2178       warn "$me using '${tc}email_pdf_note' in multipart message"
2179         if $DEBUG;
2180       @text = $conf->config($tc.'email_pdf_note');
2181       $html = join('<BR>', @text);
2182
2183     } # else use the plain text invoice
2184   }
2185
2186   if (!@text) {
2187
2188     if ( $conf->config($tc.'template') ) {
2189
2190       warn "$me generating plain text invoice"
2191         if $DEBUG;
2192
2193       # 'print_text' argument is no longer used
2194       @text = map Encode::encode_utf8($_), $self->print_text(\%args);
2195
2196     } else {
2197
2198       warn "$me no plain text version exists; sending empty message body"
2199         if $DEBUG;
2200
2201     }
2202
2203   }
2204
2205   my $text_part = build MIME::Entity (
2206     'Type'        => 'text/plain',
2207     'Encoding'    => 'quoted-printable',
2208     'Charset'     => 'UTF-8',
2209     #'Encoding'    => '7bit',
2210     'Data'        => \@text,
2211     'Disposition' => 'inline',
2212   );
2213
2214   if (!$html) {
2215
2216     if ( $conf->exists($tc.'html') ) {
2217       warn "$me generating HTML invoice"
2218         if $DEBUG;
2219
2220       $args{'from'} =~ /\@([\w\.\-]+)/;
2221       my $from = $1 || 'example.com';
2222       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2223
2224       my $logo;
2225       my $agentnum = $cust_main ? $cust_main->agentnum
2226                                 : $self->prospect_main->agentnum;
2227       if ( defined($args{'template'}) && length($args{'template'})
2228            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2229          )
2230       {
2231         $logo = 'logo_'. $args{'template'}. '.png';
2232       } else {
2233         $logo = "logo.png";
2234       }
2235       my $image_data = $conf->config_binary( $logo, $agentnum);
2236
2237       push @related_parts, build MIME::Entity
2238         'Type'       => 'image/png',
2239         'Encoding'   => 'base64',
2240         'Data'       => $image_data,
2241         'Filename'   => 'logo.png',
2242         'Content-ID' => "<$content_id>",
2243       ;
2244
2245       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2246         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2247         push @related_parts, build MIME::Entity
2248           'Type'       => 'image/png',
2249           'Encoding'   => 'base64',
2250           'Data'       => $self->invoice_barcode(0),
2251           'Filename'   => 'barcode.png',
2252           'Content-ID' => "<$barcode_content_id>",
2253         ;
2254         $args{'barcode_cid'} = $barcode_content_id;
2255       }
2256
2257       $html = $self->print_html({ 'cid'=>$content_id, %args });
2258     }
2259
2260   }
2261
2262   if ( $html ) {
2263
2264     warn "$me creating HTML/text multipart message"
2265       if $DEBUG;
2266
2267     $return{'nobody'} = 1;
2268
2269     my $alternative = build MIME::Entity
2270       'Type'        => 'multipart/alternative',
2271       #'Encoding'    => '7bit',
2272       'Disposition' => 'inline'
2273     ;
2274
2275     if ( @text ) {
2276       $alternative->add_part($text_part);
2277     }
2278
2279     $alternative->attach(
2280       'Type'        => 'text/html',
2281       'Encoding'    => 'quoted-printable',
2282       'Data'        => [ '<html>',
2283                          '  <head>',
2284                          '    <title>',
2285                          '      '. encode_entities($return{'subject'}),
2286                          '    </title>',
2287                          '  </head>',
2288                          '  <body bgcolor="#e8e8e8">',
2289                          Encode::encode_utf8($html),
2290                          '  </body>',
2291                          '</html>',
2292                        ],
2293       'Disposition' => 'inline',
2294       #'Filename'    => 'invoice.pdf',
2295     );
2296
2297     unshift @related_parts, $alternative;
2298
2299     $related = build MIME::Entity 'Type'     => 'multipart/related',
2300                                   'Encoding' => '7bit';
2301
2302     #false laziness w/Misc::send_email
2303     $related->head->replace('Content-type',
2304       $related->mime_type.
2305       '; boundary="'. $related->head->multipart_boundary. '"'.
2306       '; type=multipart/alternative'
2307     );
2308
2309     $related->add_part($_) foreach @related_parts;
2310
2311   }
2312
2313   my @otherparts = ();
2314   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2315
2316     if ( $conf->config('voip-cdr_email_attach') eq 'zip' ) {
2317
2318       my $data = join('', map "$_\n",
2319                    $self->call_details(prepend_billed_number=>1)
2320                  );
2321
2322       my $zip = new Archive::Zip;
2323       my $file = $zip->addString( $data, 'usage-'.$self->invnum.'.csv' );
2324       $file->desiredCompressionMethod( COMPRESSION_DEFLATED );
2325
2326       my $zipdata = '';
2327       my $SH = IO::Scalar->new(\$zipdata);
2328       my $status = $zip->writeToFileHandle($SH);
2329       die "Error zipping CDR attachment: $!" unless $status == AZ_OK;
2330
2331       push @otherparts, build MIME::Entity
2332         'Type'        => 'application/zip',
2333         'Encoding'    => 'base64',
2334         'Data'        => $zipdata,
2335         'Disposition' => 'attachment',
2336         'Filename'    => 'usage-'. $self->invnum. '.zip',
2337       ;
2338
2339     } else { # } elsif ( $conf->config('voip-cdr_email_attach') eq 'csv' ) {
2340
2341       push @otherparts, build MIME::Entity
2342         'Type'        => 'text/csv',
2343         'Encoding'    => '7bit',
2344         'Data'        => [ map { "$_\n" }
2345                              $self->call_details('prepend_billed_number' => 1)
2346                          ],
2347         'Disposition' => 'attachment',
2348         'Filename'    => 'usage-'. $self->invnum. '.csv',
2349       ;
2350
2351     }
2352
2353   }
2354
2355   if ( $conf->exists($tc.'email_pdf') ) {
2356
2357     #attaching pdf too:
2358     # multipart/mixed
2359     #   multipart/related
2360     #     multipart/alternative
2361     #       text/plain
2362     #       text/html
2363     #     image/png
2364     #   application/pdf
2365
2366     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2367     push @otherparts, $pdf;
2368   }
2369
2370   if (@otherparts) {
2371     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2372     if ( $html ) {
2373       $return{'mimeparts'} = [ $related, @otherparts ];
2374       $return{'type'} = 'multipart/related'; # of the first part
2375     } else {
2376       $return{'mimeparts'} = [ $text_part, @otherparts ];
2377       $return{'type'} = 'text/plain';
2378     }
2379   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2380     $return{'mimeparts'} = \@related_parts;
2381     $return{'content-type'} = 'multipart/related';
2382     $return{'type'} = 'multipart/alternative';
2383   } else { # no HTML either
2384     $return{'body'} = \@text;
2385     $return{'content-type'} = 'text/plain';
2386   }
2387
2388   %return;
2389
2390 }
2391
2392 =item mimebuild_pdf
2393
2394 Returns a list suitable for passing to MIME::Entity->build(), representing
2395 this quotation or invoice as PDF attachment.
2396
2397 =cut
2398
2399 sub mimebuild_pdf {
2400   my $self = shift;
2401   (
2402     'Type'        => 'application/pdf',
2403     'Encoding'    => 'base64',
2404     'Data'        => [ $self->print_pdf(@_) ],
2405     'Disposition' => 'attachment',
2406     'Filename'    => $self->pdf_filename,
2407   );
2408 }
2409
2410 =item postal_mail_fsinc
2411
2412 Sends this invoice to the Freeside Internet Services, Inc. print and mail
2413 service.
2414
2415 =cut
2416
2417 use CAM::PDF;
2418 use IO::Socket::SSL;
2419 use LWP::UserAgent;
2420 use HTTP::Request::Common qw( POST );
2421 use Cpanel::JSON::XS;
2422 use MIME::Base64;
2423 sub postal_mail_fsinc {
2424   my ( $self, %opt ) = @_;
2425
2426   my $url = 'https://ws.freeside.biz/print';
2427
2428   my $cust_main = $self->cust_main;
2429   my $agentnum = $cust_main->agentnum;
2430   my $bill_location = $cust_main->bill_location;
2431
2432   die "Extra charges for international mailing; contact support\@freeside.biz to enable\n"
2433     if $bill_location->country ne 'US';
2434
2435   my $conf = new FS::Conf;
2436
2437   my @company_address = $conf->config('company_address', $agentnum);
2438   my ( $company_address1, $company_address2, $company_city, $company_state, $company_zip );
2439   if ( $company_address[2] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2440     $company_address1 = $company_address[0];
2441     $company_address2 = $company_address[1];
2442     $company_city  = $1;
2443     $company_state = $2;
2444     $company_zip   = $3;
2445   } elsif ( $company_address[1] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2446     $company_address1 = $company_address[0];
2447     $company_address2 = '';
2448     $company_city  = $1;
2449     $company_state = $2;
2450     $company_zip   = $3;
2451   } else {
2452     die "Unparsable company_address; contact support\@freeside.biz\n";
2453   }
2454   $company_city =~ s/,$//;
2455
2456   my $file = $self->print_pdf(%opt, 'no_addresses' => 1);
2457   my $pages = CAM::PDF->new($file)->numPages;
2458
2459   my $ua = LWP::UserAgent->new(
2460     'ssl_opts' => {
2461       verify_hostname => 0,
2462       SSL_verify_mode => IO::Socket::SSL::SSL_VERIFY_NONE,
2463       SSL_version     => 'SSLv3',
2464     }
2465   );
2466   my $response = $ua->request( POST $url, [
2467     'support-key'      => scalar($conf->config('support-key')),
2468     'file'             => encode_base64($file),
2469     'pages'            => $pages,
2470
2471     #from:
2472     'company_name'     => scalar( $conf->config('company_name', $agentnum) ),
2473     'company_address1' => $company_address1,
2474     'company_address2' => $company_address2,
2475     'company_city'     => $company_city,
2476     'company_state'    => $company_state,
2477     'company_zip'      => $company_zip,
2478     'company_country'  => 'US',
2479     'company_phonenum' => scalar($conf->config('company_phonenum', $agentnum)),
2480     'company_email'    => scalar($conf->config('invoice_from', $agentnum)),
2481
2482     #to:
2483     'name'             => $cust_main->invoice_attn
2484                             || $cust_main->contact_firstlast,
2485     'company'          => $cust_main->company,
2486     'address1'         => $bill_location->address1,
2487     'address2'         => $bill_location->address2,
2488     'city'             => $bill_location->city,
2489     'state'            => $bill_location->state,
2490     'zip'              => $bill_location->zip,
2491     'country'          => $bill_location->country,
2492   ]);
2493
2494   die "Print connection error: ". $response->message.
2495       ' ('. $response->as_string. ")\n"
2496     unless $response->is_success;
2497
2498   local $@;
2499   my $content = eval { decode_json($response->content) };
2500   die "Print JSON error : $@\n" if $@;
2501
2502   die $content->{error}."\n"
2503     if $content->{error};
2504
2505   #TODO: store this so we can query for a status later
2506   warn "Invoice printed, ID ". $content->{id}. "\n";
2507
2508   $content->{id};
2509
2510 }
2511
2512 =item _items_sections OPTIONS
2513
2514 Generate section information for all items appearing on this invoice.
2515 This will only be called for multi-section invoices.
2516
2517 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2518 related display records (L<FS::cust_bill_pkg_display>) and organize
2519 them into two groups ("early" and "late" according to whether they come
2520 before or after the total), then into sections.  A subtotal is calculated
2521 for each section.
2522
2523 Section descriptions are returned in sort weight order.  Each consists
2524 of a hash containing:
2525
2526 description: the package category name, escaped
2527 subtotal: the total charges in that section
2528 tax_section: a flag indicating that the section contains only tax charges
2529 summarized: same as tax_section, for some reason
2530 sort_weight: the package category's sort weight
2531
2532 If 'condense' is set on the display record, it also contains everything
2533 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2534 coderefs to generate parts of the invoice.  This is not advised.
2535
2536 The method returns two arrayrefs, one of "early" sections and one of "late"
2537 sections.
2538
2539 OPTIONS may include:
2540
2541 by_location: a flag to divide the invoice into sections by location.
2542 Each section hash will have a 'location' element containing a hashref of
2543 the location fields (see L<FS::cust_location>).  The section description
2544 will be the location label, but the template can use any of the location
2545 fields to create a suitable label.
2546
2547 by_category: a flag to divide the invoice into sections using display
2548 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2549 behavior.  Each section hash will have a 'category' element containing
2550 the section name from the display record (which probably equals the
2551 category name of the package, but may not in some cases).
2552
2553 summary: a flag indicating that this is a summary-format invoice.
2554 Turning this on has the following effects:
2555 - Ignores display items with the 'summary' flag.
2556 - Places all sections in the "early" group even if they have post_total.
2557 - Creates sections for all non-disabled package categories, even if they
2558 have no charges on this invoice, as well as a section with no name.
2559
2560 escape: an escape function to use for section titles.
2561
2562 extra_sections: an arrayref of additional sections to return after the
2563 sorted list.  If there are any of these, section subtotals exclude
2564 usage charges.
2565
2566 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2567 passed through to C<_condense_section()>.
2568
2569 =cut
2570
2571 use vars qw(%pkg_category_cache);
2572 sub _items_sections {
2573   my $self = shift;
2574   my %opt = @_;
2575
2576   my $escape = $opt{escape};
2577   my @extra_sections = @{ $opt{extra_sections} || [] };
2578
2579   # $subtotal{$locationnum}{$categoryname} = amount.
2580   # if we're not using by_location, $locationnum is undef.
2581   # if we're not using by_category, you guessed it, $categoryname is undef.
2582   # if we're not using either one, we shouldn't be here in the first place...
2583   my %subtotal = ();
2584   my %late_subtotal = ();
2585   my %not_tax = ();
2586
2587   # About tax items + multisection invoices:
2588   # If either invoice_*summary option is enabled, AND there is a
2589   # package category with the name of the tax, then there will be
2590   # a display record assigning the tax item to that category.
2591   #
2592   # However, the taxes are always placed in the "Taxes, Surcharges,
2593   # and Fees" section regardless of that.  The only effect of the
2594   # display record is to create a subtotal for the summary page.
2595
2596   # cache these
2597   my $pkg_hash = $self->cust_pkg_hash;
2598
2599   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2600   {
2601
2602       my $usage = $cust_bill_pkg->usage;
2603
2604       my $locationnum;
2605       if ( $opt{by_location} ) {
2606         if ( $cust_bill_pkg->pkgnum ) {
2607           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2608         } else {
2609           $locationnum = '';
2610         }
2611       } else {
2612         $locationnum = undef;
2613       }
2614
2615       # as in _items_cust_pkg, if a line item has no display records,
2616       # cust_bill_pkg_display() returns a default record for it
2617
2618       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2619         next if ( $display->summary && $opt{summary} );
2620
2621         my $section = $display->section;
2622         my $type    = $display->type;
2623         # Set $section = undef if we're sectioning by location and this
2624         # line item _has_ a location (i.e. isn't a fee).
2625         $section = undef if $locationnum;
2626
2627         # set this flag if the section is not tax-only
2628         $not_tax{$locationnum}{$section} = 1
2629           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2630
2631         # there's actually a very important piece of logic buried in here:
2632         # incrementing $late_subtotal{$section} CREATES
2633         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2634         # to define the list of late sections, and likewise keys(%subtotal).
2635         # When _items_cust_bill_pkg is called to generate line items for
2636         # real, it will be called with 'section' => $section for each
2637         # of these.
2638         if ( $display->post_total && !$opt{summary} ) {
2639           if (! $type || $type eq 'S') {
2640             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2641               if $cust_bill_pkg->setup != 0
2642               || $cust_bill_pkg->setup_show_zero;
2643           }
2644
2645           if (! $type) {
2646             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2647               if $cust_bill_pkg->recur != 0
2648               || $cust_bill_pkg->recur_show_zero;
2649           }
2650
2651           if ($type && $type eq 'R') {
2652             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2653               if $cust_bill_pkg->recur != 0
2654               || $cust_bill_pkg->recur_show_zero;
2655           }
2656
2657           if ($type && $type eq 'U') {
2658             $late_subtotal{$locationnum}{$section} += $usage
2659               unless scalar(@extra_sections);
2660           }
2661
2662         } else { # it's a pre-total (normal) section
2663
2664           # skip tax items unless they're explicitly included in a section
2665           next if $cust_bill_pkg->pkgnum == 0 and
2666                   ! $cust_bill_pkg->feepart   and
2667                   ! $section;
2668
2669           if ( $type eq 'S' ) {
2670             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2671               if $cust_bill_pkg->setup != 0
2672               || $cust_bill_pkg->setup_show_zero;
2673           } elsif ( $type eq 'R' ) {
2674             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2675               if $cust_bill_pkg->recur != 0
2676               || $cust_bill_pkg->recur_show_zero;
2677           } elsif ( $type eq 'U' ) {
2678             $subtotal{$locationnum}{$section} += $usage
2679               unless scalar(@extra_sections);
2680           } elsif ( !$type ) {
2681             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2682                                                + $cust_bill_pkg->recur;
2683           }
2684
2685         }
2686
2687       }
2688
2689   }
2690
2691   %pkg_category_cache = ();
2692
2693   # summary invoices need subtotals for all non-disabled package categories,
2694   # even if they're zero
2695   # but currently assume that there are no location sections, or at least
2696   # that the summary page doesn't care about them
2697   if ( $opt{summary} ) {
2698     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2699       $subtotal{''}{$category->categoryname} ||= 0;
2700     }
2701     $subtotal{''}{''} ||= 0;
2702   }
2703
2704   my @sections;
2705   foreach my $post_total (0,1) {
2706     my @these;
2707     my $s = $post_total ? \%late_subtotal : \%subtotal;
2708     foreach my $locationnum (keys %$s) {
2709       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2710         my $section = {
2711                         'subtotal'    => $s->{$locationnum}{$sectionname},
2712                         'sort_weight' => 0,
2713                       };
2714         if ( $locationnum ) {
2715           $section->{'locationnum'} = $locationnum;
2716           my $location = FS::cust_location->by_key($locationnum);
2717           $section->{'description'} = &{ $escape }($location->location_label);
2718           # Better ideas? This will roughly group them by proximity,
2719           # which alpha sorting on any of the address fields won't.
2720           # Sorting by locationnum is meaningless.
2721           # We have to sort on _something_ or the order may change
2722           # randomly from one invoice to the next, which will confuse
2723           # people.
2724           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2725                                       $locationnum;
2726           $section->{'location'} = {
2727             label_prefix => &{ $escape }($location->label_prefix),
2728             map { $_ => &{ $escape }($location->get($_)) }
2729               $location->fields
2730           };
2731         } else {
2732           $section->{'category'} = $sectionname;
2733           $section->{'description'} = &{ $escape }($sectionname);
2734           if ( _pkg_category($sectionname) ) {
2735             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2736             if ( _pkg_category($sectionname)->condense ) {
2737               $section = { %$section, $self->_condense_section($opt{format}) };
2738             }
2739           }
2740         }
2741         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2742           # then it's a tax-only section
2743           $section->{'summarized'} = 'Y';
2744           $section->{'tax_section'} = 'Y';
2745         }
2746         push @these, $section;
2747       } # foreach $sectionname
2748     } #foreach $locationnum
2749     push @these, @extra_sections if $post_total == 0;
2750     # need an alpha sort for location sections, because postal codes can
2751     # be non-numeric
2752     $sections[ $post_total ] = [ sort {
2753       $opt{'by_location'} ?
2754         ($a->{sort_weight} cmp $b->{sort_weight}) :
2755         ($a->{sort_weight} <=> $b->{sort_weight})
2756       } @these ];
2757   } #foreach $post_total
2758
2759   return @sections; # early, late
2760 }
2761
2762 #helper subs for above
2763
2764 sub cust_pkg_hash {
2765   my $self = shift;
2766   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2767 }
2768
2769 sub _pkg_category {
2770   my $categoryname = shift;
2771   $pkg_category_cache{$categoryname} ||=
2772     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2773 }
2774
2775 my %condensed_format = (
2776   'label' => [ qw( Description Qty Amount ) ],
2777   'fields' => [
2778                 sub { shift->{description} },
2779                 sub { shift->{quantity} },
2780                 sub { my($href, %opt) = @_;
2781                       ($opt{dollar} || ''). $href->{amount};
2782                     },
2783               ],
2784   'align'  => [ qw( l r r ) ],
2785   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2786   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2787 );
2788
2789 sub _condense_section {
2790   my ( $self, $format ) = ( shift, shift );
2791   ( 'condensed' => 1,
2792     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2793       qw( description_generator
2794           header_generator
2795           total_generator
2796           total_line_generator
2797         )
2798   );
2799 }
2800
2801 sub _condensed_generator_defaults {
2802   my ( $self, $format ) = ( shift, shift );
2803   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2804 }
2805
2806 my %html_align = (
2807   'c' => 'center',
2808   'l' => 'left',
2809   'r' => 'right',
2810 );
2811
2812 sub _condensed_header_generator {
2813   my ( $self, $format ) = ( shift, shift );
2814
2815   my ( $f, $prefix, $suffix, $separator, $column ) =
2816     _condensed_generator_defaults($format);
2817
2818   if ($format eq 'latex') {
2819     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2820     $suffix = "\\\\\n\\hline";
2821     $separator = "&\n";
2822     $column =
2823       sub { my ($d,$a,$s,$w) = @_;
2824             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2825           };
2826   } elsif ( $format eq 'html' ) {
2827     $prefix = '<th></th>';
2828     $suffix = '';
2829     $separator = '';
2830     $column =
2831       sub { my ($d,$a,$s,$w) = @_;
2832             return qq!<th align="$html_align{$a}">$d</th>!;
2833       };
2834   }
2835
2836   sub {
2837     my @args = @_;
2838     my @result = ();
2839
2840     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2841       push @result,
2842         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2843     }
2844
2845     $prefix. join($separator, @result). $suffix;
2846   };
2847
2848 }
2849
2850 sub _condensed_description_generator {
2851   my ( $self, $format ) = ( shift, shift );
2852
2853   my ( $f, $prefix, $suffix, $separator, $column ) =
2854     _condensed_generator_defaults($format);
2855
2856   my $money_char = '$';
2857   if ($format eq 'latex') {
2858     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2859     $suffix = '\\\\';
2860     $separator = " & \n";
2861     $column =
2862       sub { my ($d,$a,$s,$w) = @_;
2863             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2864           };
2865     $money_char = '\\dollar';
2866   }elsif ( $format eq 'html' ) {
2867     $prefix = '"><td align="center"></td>';
2868     $suffix = '';
2869     $separator = '';
2870     $column =
2871       sub { my ($d,$a,$s,$w) = @_;
2872             return qq!<td align="$html_align{$a}">$d</td>!;
2873       };
2874     #$money_char = $conf->config('money_char') || '$';
2875     $money_char = '';  # this is madness
2876   }
2877
2878   sub {
2879     #my @args = @_;
2880     my $href = shift;
2881     my @result = ();
2882
2883     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2884       my $dollar = '';
2885       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2886       push @result,
2887         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2888                     map { $f->{$_}->[$i] } qw(align span width)
2889                   );
2890     }
2891
2892     $prefix. join( $separator, @result ). $suffix;
2893   };
2894
2895 }
2896
2897 sub _condensed_total_generator {
2898   my ( $self, $format ) = ( shift, shift );
2899
2900   my ( $f, $prefix, $suffix, $separator, $column ) =
2901     _condensed_generator_defaults($format);
2902   my $style = '';
2903
2904   if ($format eq 'latex') {
2905     $prefix = "& ";
2906     $suffix = "\\\\\n";
2907     $separator = " & \n";
2908     $column =
2909       sub { my ($d,$a,$s,$w) = @_;
2910             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2911           };
2912   }elsif ( $format eq 'html' ) {
2913     $prefix = '';
2914     $suffix = '';
2915     $separator = '';
2916     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2917     $column =
2918       sub { my ($d,$a,$s,$w) = @_;
2919             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2920       };
2921   }
2922
2923
2924   sub {
2925     my @args = @_;
2926     my @result = ();
2927
2928     #  my $r = &{$f->{fields}->[$i]}(@args);
2929     #  $r .= ' Total' unless $i;
2930
2931     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2932       push @result,
2933         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2934                     map { $f->{$_}->[$i] } qw(align span width)
2935                   );
2936     }
2937
2938     $prefix. join( $separator, @result ). $suffix;
2939   };
2940
2941 }
2942
2943 =item total_line_generator FORMAT
2944
2945 Returns a coderef used for generation of invoice total line items for this
2946 usage_class.  FORMAT is either html or latex
2947
2948 =cut
2949
2950 # should not be used: will have issues with hash element names (description vs
2951 # total_item and amount vs total_amount -- another array of functions?
2952
2953 sub _condensed_total_line_generator {
2954   my ( $self, $format ) = ( shift, shift );
2955
2956   my ( $f, $prefix, $suffix, $separator, $column ) =
2957     _condensed_generator_defaults($format);
2958   my $style = '';
2959
2960   if ($format eq 'latex') {
2961     $prefix = "& ";
2962     $suffix = "\\\\\n";
2963     $separator = " & \n";
2964     $column =
2965       sub { my ($d,$a,$s,$w) = @_;
2966             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2967           };
2968   }elsif ( $format eq 'html' ) {
2969     $prefix = '';
2970     $suffix = '';
2971     $separator = '';
2972     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2973     $column =
2974       sub { my ($d,$a,$s,$w) = @_;
2975             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2976       };
2977   }
2978
2979
2980   sub {
2981     my @args = @_;
2982     my @result = ();
2983
2984     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2985       push @result,
2986         &{$column}( &{$f->{fields}->[$i]}(@args),
2987                     map { $f->{$_}->[$i] } qw(align span width)
2988                   );
2989     }
2990
2991     $prefix. join( $separator, @result ). $suffix;
2992   };
2993
2994 }
2995
2996 =item _items_pkg [ OPTIONS ]
2997
2998 Return line item hashes for each package item on this invoice. Nearly
2999 equivalent to
3000
3001 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
3002
3003 OPTIONS are passed through to _items_cust_bill_pkg, and should include
3004 'format' and 'escape_function' at minimum.
3005
3006 To produce items for a specific invoice section, OPTIONS should include
3007 'section', a hashref containing 'category' and/or 'locationnum' keys.
3008
3009 'section' may also contain a key named 'condensed'. If this is present
3010 and has a true value, _items_pkg will try to merge identical items into items
3011 with 'quantity' equal to the number of items (not the sum of their separate
3012 quantities, for some reason).
3013
3014 =cut
3015
3016 sub _items_nontax {
3017   my $self = shift;
3018   # The order of these is important.  Bundled line items will be merged into
3019   # the most recent non-hidden item, so it needs to be the one with:
3020   # - the same pkgnum
3021   # - the same start date
3022   # - no pkgpart_override
3023   #
3024   # So: sort by pkgnum,
3025   # then by sdate
3026   # then sort the base line item before any overrides
3027   # then sort hidden before non-hidden add-ons
3028   # then sort by override pkgpart (for consistency)
3029   sort { $a->pkgnum <=> $b->pkgnum        or
3030          $a->sdate  <=> $b->sdate         or
3031          ($a->pkgpart_override ? 0 : -1)  or
3032          ($b->pkgpart_override ? 0 : 1)   or
3033          $b->hidden cmp $a->hidden        or
3034          $a->pkgpart_override <=> $b->pkgpart_override
3035        }
3036   # and of course exclude taxes and fees
3037   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
3038 }
3039
3040 sub _items_fee {
3041   my $self = shift;
3042   my %options = @_;
3043   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
3044   my $escape_function = $options{escape_function};
3045
3046   my @items;
3047   foreach my $cust_bill_pkg (@cust_bill_pkg) {
3048     # cache this, so we don't look it up again in every section
3049     my $part_fee = $cust_bill_pkg->get('part_fee')
3050        || $cust_bill_pkg->part_fee;
3051     $cust_bill_pkg->set('part_fee', $part_fee);
3052     if (!$part_fee) {
3053       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
3054       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
3055       next;
3056     }
3057     if ( exists($options{section}) and exists($options{section}{category}) )
3058     {
3059       my $categoryname = $options{section}{category};
3060       # then filter for items that have that section
3061       if ( $part_fee->categoryname ne $categoryname ) {
3062         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
3063         next;
3064       }
3065     } # otherwise include them all in the main section
3066     # XXX what to do when sectioning by location?
3067
3068     my @ext_desc;
3069     my %base_invnums; # invnum => invoice date
3070     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
3071       if ($_->base_invnum) {
3072         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
3073         my $base_date = $self->time2str_local('short', $base_bill->_date)
3074           if $base_bill;
3075         $base_invnums{$_->base_invnum} = $base_date || '';
3076       }
3077     }
3078     foreach (sort keys(%base_invnums)) {
3079       next if $_ == $self->invnum;
3080       # per convention, we must escape ext_description lines
3081       push @ext_desc,
3082         &{$escape_function}(
3083           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
3084         );
3085     }
3086     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
3087     # but not escape the base description line
3088
3089     push @items,
3090       { feepart     => $cust_bill_pkg->feepart,
3091         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
3092         description => $desc,
3093         ext_description => \@ext_desc
3094         # sdate/edate?
3095       };
3096   }
3097   @items;
3098 }
3099
3100 sub _items_pkg {
3101   my $self = shift;
3102   my %options = @_;
3103
3104   warn "$me _items_pkg searching for all package line items\n"
3105     if $DEBUG > 1;
3106
3107   my @cust_bill_pkg = $self->_items_nontax;
3108
3109   warn "$me _items_pkg filtering line items\n"
3110     if $DEBUG > 1;
3111   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3112
3113   if ($options{section} && $options{section}->{condensed}) {
3114
3115     warn "$me _items_pkg condensing section\n"
3116       if $DEBUG > 1;
3117
3118     my %itemshash = ();
3119     local $Storable::canonical = 1;
3120     foreach ( @items ) {
3121       my $item = { %$_ };
3122       delete $item->{ref};
3123       delete $item->{ext_description};
3124       my $key = freeze($item);
3125       $itemshash{$key} ||= 0;
3126       $itemshash{$key} ++; # += $item->{quantity};
3127     }
3128     @items = sort { $a->{description} cmp $b->{description} }
3129              map { my $i = thaw($_);
3130                    $i->{quantity} = $itemshash{$_};
3131                    $i->{amount} =
3132                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
3133                    $i;
3134                  }
3135              keys %itemshash;
3136   }
3137
3138   warn "$me _items_pkg returning ". scalar(@items). " items\n"
3139     if $DEBUG > 1;
3140
3141   @items;
3142 }
3143
3144 sub _taxsort {
3145   return 0 unless $a->itemdesc cmp $b->itemdesc;
3146   return -1 if $b->itemdesc eq 'Tax';
3147   return 1 if $a->itemdesc eq 'Tax';
3148   return -1 if $b->itemdesc eq 'Other surcharges';
3149   return 1 if $a->itemdesc eq 'Other surcharges';
3150   $a->itemdesc cmp $b->itemdesc;
3151 }
3152
3153 sub _items_tax {
3154   my $self = shift;
3155   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
3156     $self->cust_bill_pkg;
3157   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3158
3159   if ( $self->conf->exists('always_show_tax') ) {
3160     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
3161     if (0 == grep { $_->{description} eq $itemdesc } @items) {
3162       push @items,
3163         { 'description' => $itemdesc,
3164           'amount'      => 0.00 };
3165     }
3166   }
3167   @items;
3168 }
3169
3170 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
3171
3172 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
3173 list of hashrefs describing the line items they generate on the invoice.
3174
3175 OPTIONS may include:
3176
3177 format: the invoice format.
3178
3179 escape_function: the function used to escape strings.
3180
3181 DEPRECATED? (expensive, mostly unused?)
3182 format_function: the function used to format CDRs.
3183
3184 section: a hashref containing 'category' and/or 'locationnum'; if this
3185 is present, only returns line items that belong to that category and/or
3186 location (whichever is defined).
3187
3188 multisection: a flag indicating that this is a multisection invoice,
3189 which does something complicated.
3190
3191 Returns a list of hashrefs, each of which may contain:
3192
3193 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
3194 ext_description, which is an arrayref of detail lines to show below
3195 the package line.
3196
3197 =cut
3198
3199 sub _items_cust_bill_pkg {
3200   my $self = shift;
3201   my $conf = $self->conf;
3202   my $cust_bill_pkgs = shift;
3203   my %opt = @_;
3204
3205   my $format = $opt{format} || '';
3206   my $escape_function = $opt{escape_function} || sub { shift };
3207   my $format_function = $opt{format_function} || '';
3208   my $no_usage = $opt{no_usage} || '';
3209   my $unsquelched = $opt{unsquelched} || ''; #unused
3210   my ($section, $locationnum, $category);
3211   if ( $opt{section} ) {
3212     $category = $opt{section}->{category};
3213     $locationnum = $opt{section}->{locationnum};
3214   }
3215   my $summary_page = $opt{summary_page} || ''; #unused
3216   my $multisection = defined($category) || defined($locationnum);
3217   # this variable is the value of the config setting, not whether it applies
3218   # to this particular line item.
3219   my $discount_show_always = $conf->exists('discount-show-always');
3220
3221   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3222
3223   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3224
3225   # for location labels: use default location on the invoice date
3226   my $default_locationnum;
3227   if ( $conf->exists('invoice-all_pkg_addresses') ) {
3228     $default_locationnum = 0; # treat them all as non-default
3229   } elsif ( $self->custnum ) {
3230     my $h_cust_main;
3231     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3232     $h_cust_main = qsearchs({
3233         'table'     => 'h_cust_main',
3234         'hashref'   => { custnum => $self->custnum },
3235         'extra_sql' => $h_search[1],
3236         'addl_from' => $h_search[3],
3237     }) || $cust_main;
3238     $default_locationnum = $h_cust_main->ship_locationnum;
3239   } elsif ( $self->prospectnum ) {
3240     my $cust_location = qsearchs('cust_location',
3241       { prospectnum => $self->prospectnum,
3242         disabled => '' });
3243     $default_locationnum = $cust_location->locationnum if $cust_location;
3244   }
3245
3246   my @b = (); # accumulator for the line item hashes that we'll return
3247   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3248             # the 'current' line item hashes for setup, recur, usage, discount
3249   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3250   {
3251     # if the current line item is waiting to go out, and the one we're about
3252     # to start is not bundled, then push out the current one and start a new
3253     # one.
3254     if ( $d ) {
3255       $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3256     }
3257     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3258       if ( $_ && !$cust_bill_pkg->hidden ) {
3259         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3260         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3261         if (exists($_->{unit_amount})) {
3262           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3263         }
3264         push @b, { %$_ };
3265         # we already decided to create this display line; don't reconsider it
3266         # now.
3267         #  if $_->{amount} != 0
3268         #  || $discount_show_always
3269         #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3270         #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3271         ;
3272         $_ = undef;
3273       }
3274     }
3275
3276     if ( $locationnum ) {
3277       # this is a location section; skip packages that aren't at this
3278       # service location.
3279       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3280       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3281               != $locationnum;
3282     }
3283
3284     # Consider display records for this item to determine if it belongs
3285     # in this section.  Note that if there are no display records, there
3286     # will be a default pseudo-record that includes all charge types
3287     # and has no section name.
3288     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3289                                   ? $cust_bill_pkg->cust_bill_pkg_display
3290                                   : ( $cust_bill_pkg );
3291
3292     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3293          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3294       if $DEBUG > 1;
3295
3296     if ( defined($category) ) {
3297       # then this is a package category section; process all display records
3298       # that belong to this section.
3299       @cust_bill_pkg_display = grep { $_->section eq $category }
3300                                 @cust_bill_pkg_display;
3301     } else {
3302       # otherwise, process all display records that aren't usage summaries
3303       # (I don't think there should be usage summaries if you aren't using
3304       # category sections, but this is the historical behavior)
3305       @cust_bill_pkg_display = grep { !$_->summary }
3306                                 @cust_bill_pkg_display;
3307     }
3308
3309     my $classname = ''; # package class name, will fill in later
3310
3311     foreach my $display (@cust_bill_pkg_display) {
3312
3313       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3314            $display->billpkgdisplaynum. "\n"
3315         if $DEBUG > 1;
3316
3317       my $type = $display->type;
3318
3319       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3320       $desc = substr($desc, 0, $maxlength). '...'
3321         if $format eq 'latex' && length($desc) > $maxlength;
3322
3323       my %details_opt = ( 'format'          => $format,
3324                           'escape_function' => $escape_function,
3325                           'format_function' => $format_function,
3326                           'no_usage'        => $opt{'no_usage'},
3327                         );
3328
3329       if ( $cust_bill_pkg->pkgnum > 0 ) {
3330         # a "normal" package line item (not a quotation, not a fee, not a tax)
3331
3332         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3333           if $DEBUG > 1;
3334
3335         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3336         my $part_pkg = $cust_pkg->part_pkg;
3337
3338         # which pkgpart to show for display purposes?
3339         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3340
3341         # start/end dates for invoice formats that do nonstandard
3342         # things with them
3343         my %item_dates = ();
3344         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3345           unless $part_pkg->option('disable_line_item_date_ranges',1);
3346
3347         # not normally used, but pass this to the template anyway
3348         $classname = $part_pkg->classname;
3349
3350         if (    (!$type || $type eq 'S')
3351              && (    $cust_bill_pkg->setup != 0
3352                   || $cust_bill_pkg->setup_show_zero
3353                   || ($discount_show_always and $cust_bill_pkg->unitsetup > 0)
3354                 )
3355            )
3356          {
3357
3358           warn "$me _items_cust_bill_pkg adding setup\n"
3359             if $DEBUG > 1;
3360
3361           # append the word 'Setup' to the setup line if there's going to be
3362           # a recur line for the same package (i.e. not a one-time charge)
3363           # XXX localization
3364           my $description = $desc;
3365           $description .= ' Setup'
3366             if $cust_bill_pkg->recur != 0
3367             || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3368             || $cust_bill_pkg->recur_show_zero;
3369
3370           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3371                                                               $self->agentnum )
3372             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3373                                      # triggered by the recurring charge freq
3374                                      # (RT#26274)
3375             && $cust_bill_pkg->recur == 0
3376             && ! $cust_bill_pkg->recur_show_zero;
3377
3378           my @d = ();
3379           my $svc_label;
3380
3381           # always pass the svc_label through to the template, even if
3382           # not displaying it as an ext_description
3383           my @svc_labels = map &{$escape_function}($_),
3384             $cust_pkg->h_labels_short($self->_date,
3385                                       undef,
3386                                       'I',
3387                                       $self->conf->{locale},
3388                                      );
3389           $svc_label = $svc_labels[0];
3390
3391           unless ( $cust_pkg->part_pkg->hide_svc_detail
3392                 || $cust_bill_pkg->hidden )
3393           {
3394
3395             push @d, @svc_labels
3396               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3397             # show the location label if it's not the customer's default
3398             # location, and we're not grouping items by location already
3399             if ( $cust_pkg->locationnum != $default_locationnum
3400                   and !defined($locationnum) ) {
3401               my $loc = $cust_pkg->location_label;
3402               $loc = substr($loc, 0, $maxlength). '...'
3403                 if $format eq 'latex' && length($loc) > $maxlength;
3404               push @d, &{$escape_function}($loc);
3405             }
3406
3407           } #unless hiding service details
3408
3409           push @d, $cust_bill_pkg->details(%details_opt)
3410             if $cust_bill_pkg->recur == 0;
3411
3412           if ( $cust_bill_pkg->hidden ) {
3413             $s->{amount}      += $cust_bill_pkg->setup;
3414             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3415             push @{ $s->{ext_description} }, @d;
3416           } else {
3417             $s = {
3418               _is_setup       => 1,
3419               description     => $description,
3420               pkgpart         => $pkgpart,
3421               pkgnum          => $cust_bill_pkg->pkgnum,
3422               amount          => $cust_bill_pkg->setup,
3423               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3424               unit_amount     => $cust_bill_pkg->unitsetup,
3425               quantity        => $cust_bill_pkg->quantity,
3426               ext_description => \@d,
3427               svc_label       => ($svc_label || ''),
3428               locationnum     => $cust_pkg->locationnum, # sure, why not?
3429             };
3430           };
3431
3432         }
3433
3434         # should we show a recur line?
3435         # if type eq 'S', then NO, because we've been told not to.
3436         # otherwise, show the recur line if:
3437         # - there's a recurring charge
3438         # - or recur_show_zero is on
3439         # - or there's a positive unitrecur (so it's been discounted to zero)
3440         #   and discount-show-always is on
3441         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3442              && (
3443                      $cust_bill_pkg->recur != 0
3444                   || !defined($s)
3445                   || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3446                   || $cust_bill_pkg->recur_show_zero
3447                 )
3448            )
3449         {
3450
3451           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3452             if $DEBUG > 1;
3453
3454           my $is_summary = $display->summary;
3455           my $description = $desc;
3456           if ( $type eq 'U' and defined($r) ) {
3457             # don't just show the same description as the recur line
3458             $description = $self->mt('Usage charges');
3459           }
3460
3461           my $part_pkg = $cust_pkg->part_pkg;
3462
3463           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3464                                                               $self->agentnum );
3465
3466           my @d = ();
3467           my @seconds = (); # for display of usage info
3468           my $svc_label = '';
3469
3470           #at least until cust_bill_pkg has "past" ranges in addition to
3471           #the "future" sdate/edate ones... see #3032
3472           my @dates = ( $self->_date );
3473           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3474           push @dates, $prev->sdate if $prev;
3475           push @dates, undef if !$prev;
3476
3477           my @svc_labels = map &{$escape_function}($_),
3478             $cust_pkg->h_labels_short(@dates,
3479                                       'I',
3480                                       $self->conf->{locale});
3481           $svc_label = $svc_labels[0];
3482
3483           # show service labels, unless...
3484                     # the package is set not to display them
3485           unless ( $part_pkg->hide_svc_detail
3486                     # or this is a tax-like line item
3487                 || $cust_bill_pkg->itemdesc
3488                     # or this is a hidden (bundled) line item
3489                 || $cust_bill_pkg->hidden
3490                     # or this is a usage summary line
3491                 || $is_summary && $type && $type eq 'U'
3492                     # or this is a usage line and there's a recurring line
3493                     # for the package in the same section (which will
3494                     # have service labels already)
3495                 || ($type eq 'U' and defined($r))
3496               )
3497           {
3498
3499             warn "$me _items_cust_bill_pkg adding service details\n"
3500               if $DEBUG > 1;
3501
3502             push @d, @svc_labels
3503               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3504             warn "$me _items_cust_bill_pkg done adding service details\n"
3505               if $DEBUG > 1;
3506
3507             # show the location label if it's not the customer's default
3508             # location, and we're not grouping items by location already
3509             if ( $cust_pkg->locationnum != $default_locationnum
3510                   and !defined($locationnum) ) {
3511               my $loc = $cust_pkg->location_label;
3512               $loc = substr($loc, 0, $maxlength). '...'
3513                 if $format eq 'latex' && length($loc) > $maxlength;
3514               push @d, &{$escape_function}($loc);
3515             }
3516
3517             # Display of seconds_since_sqlradacct:
3518             # On the invoice, when processing @detail_items, look for a field
3519             # named 'seconds'.  This will contain total seconds for each
3520             # service, in the same order as @ext_description.  For services
3521             # that don't support this it will show undef.
3522             if ( $conf->exists('svc_acct-usage_seconds')
3523                  and ! $cust_bill_pkg->pkgpart_override ) {
3524               foreach my $cust_svc (
3525                   $cust_pkg->h_cust_svc(@dates, 'I')
3526                 ) {
3527
3528                 # eval because not having any part_export_usage exports
3529                 # is a fatal error, last_bill/_date because that's how
3530                 # sqlradius_hour billing does it
3531                 my $sec = eval {
3532                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3533                 };
3534                 push @seconds, $sec;
3535               }
3536             } #if svc_acct-usage_seconds
3537
3538           } # if we are showing service labels
3539
3540           unless ( $is_summary ) {
3541             warn "$me _items_cust_bill_pkg adding details\n"
3542               if $DEBUG > 1;
3543
3544             #instead of omitting details entirely in this case (unwanted side
3545             # effects), just omit CDRs
3546             $details_opt{'no_usage'} = 1
3547               if $type && $type eq 'R';
3548
3549             push @d, $cust_bill_pkg->details(%details_opt);
3550           }
3551
3552           warn "$me _items_cust_bill_pkg calculating amount\n"
3553             if $DEBUG > 1;
3554
3555           my $amount = 0;
3556           if (!$type) {
3557             $amount = $cust_bill_pkg->recur;
3558           } elsif ($type eq 'R') {
3559             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3560           } elsif ($type eq 'U') {
3561             $amount = $cust_bill_pkg->usage;
3562           }
3563
3564           if ( !$type || $type eq 'R' ) {
3565
3566             warn "$me _items_cust_bill_pkg adding recur\n"
3567               if $DEBUG > 1;
3568
3569             my $unit_amount =
3570               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3571                                                 : $amount;
3572
3573             if ( $cust_bill_pkg->hidden ) {
3574               $r->{amount}      += $amount;
3575               $r->{unit_amount} += $unit_amount;
3576               push @{ $r->{ext_description} }, @d;
3577             } else {
3578               $r = {
3579                 description     => $description,
3580                 pkgpart         => $pkgpart,
3581                 pkgnum          => $cust_bill_pkg->pkgnum,
3582                 amount          => $amount,
3583                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3584                 unit_amount     => $unit_amount,
3585                 quantity        => $cust_bill_pkg->quantity,
3586                 %item_dates,
3587                 ext_description => \@d,
3588                 svc_label       => ($svc_label || ''),
3589                 locationnum     => $cust_pkg->locationnum,
3590               };
3591               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3592             }
3593
3594           } else {  # $type eq 'U'
3595
3596             warn "$me _items_cust_bill_pkg adding usage\n"
3597               if $DEBUG > 1;
3598
3599             if ( $cust_bill_pkg->hidden and defined($u) ) {
3600               # if this is a hidden package and there's already a usage
3601               # line for the bundle, add this package's total amount and
3602               # usage details to it
3603               $u->{amount}      += $amount;
3604               push @{ $u->{ext_description} }, @d;
3605             } elsif ( $amount ) {
3606               # create a new usage line
3607               $u = {
3608                 description     => $description,
3609                 pkgpart         => $pkgpart,
3610                 pkgnum          => $cust_bill_pkg->pkgnum,
3611                 amount          => $amount,
3612                 usage_item      => 1,
3613                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3614                 %item_dates,
3615                 ext_description => \@d,
3616                 locationnum     => $cust_pkg->locationnum,
3617               };
3618             } # else this has no usage, so don't create a usage section
3619           }
3620
3621         } # recurring or usage with recurring charge
3622
3623       } else { # taxes and fees
3624
3625         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3626           if $DEBUG > 1;
3627
3628         # items of this kind should normally not have sdate/edate.
3629         push @b, {
3630           'description' => $desc,
3631           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3632                                            + $cust_bill_pkg->recur)
3633         };
3634
3635       } # if package line item / other line item
3636
3637       # decide whether to show active discounts here
3638       if (
3639           # case 1: we are showing a single line for the package
3640           ( !$type )
3641           # case 2: we are showing a setup line for a package that has
3642           # no base recurring fee
3643           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3644           # case 3: we are showing a recur line for a package that has
3645           # a base recurring fee
3646           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3647       ) {
3648
3649         my $item_discount = $cust_bill_pkg->_item_discount;
3650         if ( $item_discount ) {
3651           # $item_discount->{amount} is negative
3652
3653           if ( $d and $cust_bill_pkg->hidden ) {
3654             $d->{setup_amount} += $item_discount->{setup_amount};
3655             $d->{recur_amount} += $item_discount->{recur_amount};
3656           } else {
3657             $d = $item_discount;
3658             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3659           }
3660
3661           # update the active line (before the discount) to show the
3662           # original price (whether this is a hidden line or not)
3663
3664           $s->{amount} -= $item_discount->{setup_amount} if $s;
3665           $r->{amount} -= $item_discount->{recur_amount} if $r;
3666
3667         } # if there are any discounts
3668       } # if this is an appropriate place to show discounts
3669
3670     } # foreach $display
3671
3672   }
3673
3674   # discount amount is internally split up
3675   if ( $d ) {
3676     $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3677   }
3678
3679   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3680     if ( $_  ) {
3681       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3682         if exists($_->{amount});
3683       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3684       if (exists($_->{unit_amount})) {
3685         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3686       }
3687
3688       push @b, { %$_ };
3689       #if $_->{amount} != 0
3690       #  || $discount_show_always
3691       #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3692       #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3693     }
3694   }
3695
3696   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3697     if $DEBUG > 1;
3698
3699   @b;
3700
3701 }
3702
3703 =item _items_discounts_avail
3704
3705 Returns an array of line item hashrefs representing available term discounts
3706 for this invoice.  This makes the same assumptions that apply to term
3707 discounts in general: that the package is billed monthly, at a flat rate,
3708 with no usage charges.  A prorated first month will be handled, as will
3709 a setup fee if the discount is allowed to apply to setup fees.
3710
3711 =cut
3712
3713 sub _items_discounts_avail {
3714   my $self = shift;
3715
3716   #maybe move this method from cust_bill when quotations support discount_plans
3717   return () unless $self->can('discount_plans');
3718   my %plans = $self->discount_plans;
3719
3720   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3721   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3722
3723   map {
3724     my $months = $_;
3725     my $plan = $plans{$months};
3726
3727     my $term_total = sprintf('%.2f', $plan->discounted_total);
3728     my $percent = sprintf('%.0f',
3729                           100 * (1 - $term_total / $plan->base_total) );
3730     my $permonth = sprintf('%.2f', $term_total / $months);
3731     my $detail = $self->mt('discount on item'). ' '.
3732                  join(', ', map { "#$_" } $plan->pkgnums)
3733       if $list_pkgnums;
3734
3735     # discounts for non-integer months don't work anyway
3736     $months = sprintf("%d", $months);
3737
3738     +{
3739       description => $self->mt('Save [_1]% by paying for [_2] months',
3740                                 $percent, $months),
3741       amount      => $self->mt('[_1] ([_2] per month)',
3742                                 $term_total, $money_char.$permonth),
3743       ext_description => ($detail || ''),
3744     }
3745   } #map
3746   sort { $b <=> $a } keys %plans;
3747
3748 }
3749
3750 =item has_sections AGENTNUM
3751
3752 Return true if invoice_sections should be enabled for this bill.
3753  (Inherited by both cust_bill and cust_bill_void)
3754
3755 Determination:
3756 * False if not an invoice
3757 * True always if conf invoice_sections is enabled
3758 * True always if sections_by_location is enabled
3759 * True if conf invoice_sections_multilocation > 1,
3760   and location_count >= invoice_sections_multilocation
3761 * Else, False
3762
3763 =cut
3764
3765 sub has_sections {
3766   my ($self, $agentnum) = @_;
3767
3768   return 0 unless $self->invnum > 0;
3769
3770   $agentnum ||= $self->cust_main->agentnum;
3771   return 1 if $self->conf->exists('invoice_sections', $agentnum);
3772   return 1 if $self->conf->exists('sections_by_location', $agentnum);
3773
3774   my $location_min = $self->conf->config(
3775     'invoice_sections_multilocation', $agentnum,
3776   );
3777
3778   return 1
3779     if $location_min
3780     && $self->location_count >= $location_min;
3781
3782   0;
3783 }
3784
3785
3786 =item location_count
3787
3788 Return the number of locations billed on this invoice
3789
3790 =cut
3791
3792 sub location_count {
3793   my ($self) = @_;
3794   return 0 unless $self->invnum;
3795
3796   # SELECT COUNT( DISTINCT cust_pkg.locationnum )
3797   # FROM cust_bill_pkg
3798   # LEFT JOIN cust_pkg USING (pkgnum)
3799   # WHERE invnum = 278
3800   #   AND cust_bill_pkg.pkgnum > 0
3801
3802   my $result = qsearchs({
3803     select    => 'COUNT(DISTINCT cust_pkg.locationnum) as location_count',
3804     table     => 'cust_bill_pkg',
3805     addl_from => 'LEFT JOIN cust_pkg USING (pkgnum)',
3806     extra_sql => 'WHERE invnum = '.dbh->quote( $self->invnum )
3807                . '  AND cust_bill_pkg.pkgnum > 0'
3808   });
3809   ref $result ? $result->location_count : 0;
3810 }
3811
3812 1;