FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319
 320   my $locale = $params{'locale'} || $cust_main->locale;
 321
 322   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 323                      'html'     => [ '<%=', '%>' ],
 324                      'template' => [ '{', '}' ],
 325                    );
 326
 327   warn "$me print_generic creating template\n"
 328     if $DEBUG > 1;
 329
 330   # set the notice name here, and nowhere else.
 331   my $notice_name =  $params{notice_name}
 332                   || $conf->config('notice_name')
 333                   || $self->notice_name;
 334
 335   #create the template
 336   my $template = $params{template} ? $params{template} : $self->_agent_template;
 337   my $templatefile = $self->template_conf. $format;
 338   $templatefile .= "_$template"
 339     if length($template) && $conf->exists($templatefile."_$template");
 340
 341   # the base template
 342   my @invoice_template = map "$_\n", $conf->config($templatefile)
 343     or die "cannot load config data $templatefile";
 344
 345   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 346     #change this to a die when the old code is removed
 347     # it's been almost ten years, changing it to a die
 348     die "old-style invoice template $templatefile; ".
 349          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 350          #$old_latex = 'true';
 351          #@invoice_template = _translate_old_latex_format(@invoice_template);
 352   }
 353
 354   warn "$me print_generic creating T:T object\n"
 355     if $DEBUG > 1;
 356
 357   my $text_template = new Text::Template(
 358     TYPE => 'ARRAY',
 359     SOURCE => \@invoice_template,
 360     DELIMITERS => $delimiters{$format},
 361   );
 362
 363   warn "$me print_generic compiling T:T object\n"
 364     if $DEBUG > 1;
 365
 366   $text_template->compile()
 367     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 368
 369
 370   # additional substitution could possibly cause breakage in existing templates
 371   my %convert_maps = (
 372     'latex' => {
 373                  'notes'         => sub { map "$_", @_ },
 374                  'footer'        => sub { map "$_", @_ },
 375                  'smallfooter'   => sub { map "$_", @_ },
 376                  'returnaddress' => sub { map "$_", @_ },
 377                  'coupon'        => sub { map "$_", @_ },
 378                  'summary'       => sub { map "$_", @_ },
 379                },
 380     'html'  => {
 381                  'notes' =>
 382                    sub {
 383                      map {
 384                        s/%%(.*)$/<!-- $1 -->/g;
 385                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 386                        s/\\begin\{enumerate\}/<ol>/g;
 387                        s/\\item /  <li>/g;
 388                        s/\\end\{enumerate\}/<\/ol>/g;
 389                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 390                        s/\\\\\*/<br>/g;
 391                        s/\\dollar ?/\$/g;
 392                        s/\\#/#/g;
 393                        s/~/&nbsp;/g;
 394                        $_;
 395                      }  @_
 396                    },
 397                  'footer' =>
 398                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 399                  'smallfooter' =>
 400                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 401                  'returnaddress' =>
 402                    sub {
 403                      map {
 404                        s/~/&nbsp;/g;
 405                        s/\\\\\*?\s*$/<BR>/;
 406                        s/\\hyphenation\{[\w\s\-]+}//;
 407                        s/\\([&])/$1/g;
 408                        $_;
 409                      }  @_
 410                    },
 411                  'coupon'        => sub { "" },
 412                  'summary'       => sub { "" },
 413                },
 414     'template' => {
 415                  'notes' =>
 416                    sub {
 417                      map {
 418                        s/%%.*$//g;
 419                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 420                        s/\\begin\{enumerate\}//g;
 421                        s/\\item /  * /g;
 422                        s/\\end\{enumerate\}//g;
 423                        s/\\textbf\{(.*)\}/$1/g;
 424                        s/\\\\\*/ /;
 425                        s/\\dollar ?/\$/g;
 426                        $_;
 427                      }  @_
 428                    },
 429                  'footer' =>
 430                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 431                  'smallfooter' =>
 432                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 433                  'returnaddress' =>
 434                    sub {
 435                      map {
 436                        s/~/ /g;
 437                        s/\\\\\*?\s*$/\n/;             # dubious
 438                        s/\\hyphenation\{[\w\s\-]+}//;
 439                        $_;
 440                      }  @_
 441                    },
 442                  'coupon'        => sub { "" },
 443                  'summary'       => sub { "" },
 444                },
 445   );
 446
 447
 448   # hashes for differing output formats
 449   my %nbsps = ( 'latex'    => '~',
 450                 'html'     => '',    # '&nbps;' would be nice
 451                 'template' => '',    # not used
 452               );
 453   my $nbsp = $nbsps{$format};
 454
 455   my %escape_functions = ( 'latex'    => \&_latex_escape,
 456                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 457                            'template' => sub { shift },
 458                          );
 459   my $escape_function = $escape_functions{$format};
 460   my $escape_function_nonbsp = ($format eq 'html')
 461                                  ? \&_html_escape : $escape_function;
 462
 463   my %newline_tokens = (  'latex'     => '\\\\',
 464                           'html'      => '<br>',
 465                           'template'  => "\n",
 466                         );
 467   my $newline_token = $newline_tokens{$format};
 468
 469   warn "$me generating template variables\n"
 470     if $DEBUG > 1;
 471
 472   # generate template variables
 473   my $returnaddress;
 474
 475   if (
 476          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 477                                         $template
 478                                       )
 479                 )
 480        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 481                                         $template
 482                                       )
 483                 )
 484   ) {
 485
 486     $returnaddress = join("\n",
 487       $conf->config_orbase("invoice_${format}returnaddress", $template)
 488     );
 489
 490   } elsif ( grep /\S/,
 491             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 492
 493     my $convert_map = $convert_maps{$format}{'returnaddress'};
 494     $returnaddress =
 495       join( "\n",
 496             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 497                                                  $template
 498                                                )
 499                          )
 500           );
 501   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 502
 503     my $convert_map = $convert_maps{$format}{'returnaddress'};
 504     $returnaddress = join( "\n", &$convert_map(
 505                                    map { s/( {2,})/'~' x length($1)/eg;
 506                                          s/$/\\\\\*/;
 507                                          $_
 508                                        }
 509                                      ( $conf->config('company_name', $cust_main->agentnum),
 510                                        $conf->config('company_address', $cust_main->agentnum),
 511                                      )
 512                                  )
 513                      );
 514
 515   } else {
 516
 517     my $warning = "Couldn't find a return address; ".
 518                   "do you need to set the company_address configuration value?";
 519     warn "$warning\n";
 520     $returnaddress = $nbsp;
 521     #$returnaddress = $warning;
 522
 523   }
 524
 525   warn "$me generating invoice data\n"
 526     if $DEBUG > 1;
 527
 528   my $agentnum = $cust_main->agentnum;
 529
 530   my %invoice_data = (
 531
 532     #invoice from info
 533     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 534     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 535     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 536     'returnaddress'   => $returnaddress,
 537     'agent'           => &$escape_function($cust_main->agent->agent),
 538
 539     #invoice/quotation info
 540     'no_number'       => $params{'no_number'},
 541     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 542     'quotationnum'    => $self->quotationnum,
 543     'no_date'         => $params{'no_date'},
 544     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 545       # workaround for inconsistent behavior in the early plain text
 546       # templates; see RT#28271
 547     'date'            => ( $params{'no_date'}
 548                              ? ''
 549                              : ($format eq 'template'
 550                                ? $self->_date
 551                                : $self->time2str_local('long', $self->_date, $format)
 552                                )
 553                          ),
 554     'today'           => $self->time2str_local('long', $today, $format),
 555     'terms'           => $self->terms,
 556     'template'        => $template, #params{'template'},
 557     'notice_name'     => $notice_name, # escape?
 558     'current_charges' => sprintf("%.2f", $self->charged),
 559     'duedate'         => $self->due_date2str('rdate'), #date_format?
 560
 561     #customer info
 562     'custnum'         => $cust_main->display_custnum,
 563     'prospectnum'     => $cust_main->prospectnum,
 564     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 565     ( map { $_ => &$escape_function($cust_main->$_()) }
 566         qw( company address1 address2 city state zip fax )
 567     ),
 568     'payname'         => &$escape_function( $cust_main->invoice_attn
 569                                              || $cust_main->contact_firstlast ),
 570
 571     #global config
 572     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 573     'unitprices'      => $conf->exists('invoice-unitprice'),
 574     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 575     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 576     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 577
 578     #layout info -- would be fancy to calc some of this and bury the template
 579     #               here in the code
 580     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 581     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 582     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 583     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 584     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 585     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 586     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 587     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 588     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 589     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 590
 591     # better hang on to conf_dir for a while (for old templates)
 592     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 593
 594     #these are only used when doing paged plaintext
 595     'page'            => 1,
 596     'total_pages'     => 1,
 597
 598   );
 599
 600   #localization
 601   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 602   # prototype here to silence warnings
 603   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 604
 605   my $min_sdate = 999999999999;
 606   my $max_edate = 0;
 607   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 608     next unless $cust_bill_pkg->pkgnum > 0;
 609     $min_sdate = $cust_bill_pkg->sdate
 610       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 611     $max_edate = $cust_bill_pkg->edate
 612       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 613   }
 614
 615   $invoice_data{'bill_period'} = '';
 616   $invoice_data{'bill_period'} =
 617       $self->time2str_local('%e %h', $min_sdate, $format)
 618       . " to " .
 619       $self->time2str_local('%e %h', $max_edate, $format)
 620     if ($max_edate != 0 && $min_sdate != 999999999999);
 621
 622   $invoice_data{finance_section} = '';
 623   if ( $conf->config('finance_pkgclass') ) {
 624     my $pkg_class =
 625       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 626     $invoice_data{finance_section} = $pkg_class->categoryname;
 627   }
 628   $invoice_data{finance_amount} = '0.00';
 629   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 630
 631   my $countrydefault = $conf->config('countrydefault') || 'US';
 632   foreach ( qw( address1 address2 city state zip country fax) ){
 633     my $method = 'ship_'.$_;
 634     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 635   }
 636   if ( length($cust_main->ship_company) ) {
 637     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 638   } else {
 639     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 640   }
 641   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 642   $invoice_data{'ship_country'} = ''
 643     if ( $invoice_data{'ship_country'} eq $countrydefault );
 644
 645   $invoice_data{'cid'} = $params{'cid'}
 646     if $params{'cid'};
 647
 648   if ( $cust_main->country eq $countrydefault ) {
 649     $invoice_data{'country'} = '';
 650   } else {
 651     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 652   }
 653
 654   my @address = ();
 655   $invoice_data{'address'} = \@address;
 656   push @address,
 657     $invoice_data{'payname'}.
 658       ( $cust_main->po_number
 659           ? " (P.O. #". $cust_main->po_number. ")"
 660           : ''
 661       )
 662   ;
 663   push @address, $cust_main->company
 664     if $cust_main->company;
 665   push @address, $cust_main->address1;
 666   push @address, $cust_main->address2
 667     if $cust_main->address2;
 668   push @address,
 669     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 670   push @address, $invoice_data{'country'}
 671     if $invoice_data{'country'};
 672   push @address, ''
 673     while (scalar(@address) < 5);
 674
 675   $invoice_data{'logo_file'} = $params{'logo_file'}
 676     if $params{'logo_file'};
 677   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 678     if $params{'barcode_file'};
 679   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 680     if $params{'barcode_img'};
 681   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 682     if $params{'barcode_cid'};
 683
 684   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 685 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 686   #my $balance_due = $self->owed + $pr_total - $cr_total;
 687   my $balance_due = $self->owed + $pr_total;
 688
 689   # the sum of amount owed on all invoices
 690   # (this is used in the summary & on the payment coupon)
 691   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 692
 693   # flag telling this invoice to have a first-page summary
 694   my $summarypage = '';
 695
 696   if ( $self->custnum && $self->invnum ) {
 697     # XXX should be an FS::cust_bill method to set the defaults, instead
 698     # of checking the type here
 699
 700     # info from customer's last invoice before this one, for some
 701     # summary formats
 702     $invoice_data{'last_bill'} = {};
 703
 704     my $last_bill = $self->previous_bill;
 705     if ( $last_bill ) {
 706
 707       # "balance_date_range" unfortunately is unsuitable for this, since it
 708       # cares about application dates.  We want to know the sum of all
 709       # _top-level transactions_ dated before the last invoice.
 710       my @sql =
 711         map "$_ WHERE _date <= ? AND custnum = ?", (
 712           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 713           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 714           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 715           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 716         );
 717
 718       # the customer's current balance immediately after generating the last
 719       # bill
 720
 721       my $last_bill_balance = $last_bill->charged;
 722       foreach (@sql) {
 723         my $delta = FS::Record->scalar_sql(
 724           $_,
 725           $last_bill->_date - 1,
 726           $self->custnum,
 727         );
 728         $last_bill_balance += $delta;
 729       }
 730
 731       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 732
 733       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 734         $last_bill->invnum,
 735         $self->time2str_local('%D', $last_bill->_date),
 736         $last_bill_balance
 737       ) if $DEBUG > 0;
 738       # ("true_previous_balance" is a terrible name, but at least it's no
 739       # longer stored in the database)
 740       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 741
 742       # the change in balance from immediately after that invoice
 743       # to immediately before this one
 744       my $before_this_bill_balance = 0;
 745       foreach (@sql) {
 746         my $delta = FS::Record->scalar_sql(
 747           $_,
 748           $self->_date - 1,
 749           $self->custnum,
 750         );
 751         $before_this_bill_balance += $delta;
 752       }
 753       $invoice_data{'balance_adjustments'} =
 754         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 755
 756       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 757                    $invoice_data{'balance_adjustments'}
 758       ) if $DEBUG > 0;
 759
 760       # the sum of amount owed on all previous invoices
 761       # ($pr_total is used elsewhere but not as $previous_balance)
 762       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 763
 764       $invoice_data{'last_bill'}{'_date'} = $last_bill->_date; #unformatted
 765       my (@payments, @credits);
 766       # for formats that itemize previous payments
 767       foreach my $cust_pay ( qsearch('cust_pay', {
 768                               'custnum' => $self->custnum,
 769                               '_date'   => { op => '>=',
 770                                              value => $last_bill->_date }
 771                              } ) )
 772       {
 773         next if $cust_pay->_date > $self->_date;
 774         push @payments, {
 775             '_date'       => $cust_pay->_date,
 776             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 777             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 778             'amount'      => sprintf('%.2f', $cust_pay->paid),
 779         };
 780         # not concerned about applications
 781       }
 782       foreach my $cust_credit ( qsearch('cust_credit', {
 783                               'custnum' => $self->custnum,
 784                               '_date'   => { op => '>=',
 785                                              value => $last_bill->_date }
 786                              } ) )
 787       {
 788         next if $cust_credit->_date > $self->_date;
 789         push @credits, {
 790             '_date'       => $cust_credit->_date,
 791             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 792             'creditreason'=> $cust_credit->reason,
 793             'amount'      => sprintf('%.2f', $cust_credit->amount),
 794         };
 795       }
 796       $invoice_data{'previous_payments'} = \@payments;
 797       $invoice_data{'previous_credits'}  = \@credits;
 798     } else {
 799       # there is no $last_bill
 800       $invoice_data{'true_previous_balance'} =
 801       $invoice_data{'balance_adjustments'}   =
 802       $invoice_data{'previous_balance'}      = '0.00';
 803       $invoice_data{'previous_payments'} = [];
 804       $invoice_data{'previous_credits'} = [];
 805     }
 806
 807     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 808       $invoice_data{'summarypage'} = $summarypage = 1;
 809     }
 810
 811   } # if this is an invoice
 812
 813   warn "$me substituting variables in notes, footer, smallfooter\n"
 814     if $DEBUG > 1;
 815
 816   my $tc = $self->template_conf;
 817   my @include = ( [ $tc,        'notes' ],
 818                   [ 'invoice_', 'footer' ],
 819                   [ 'invoice_', 'smallfooter', ],
 820                 );
 821   push @include, [ $tc,        'coupon', ]
 822     unless $params{'no_coupon'};
 823
 824   foreach my $i (@include) {
 825
 826     my($base, $include) = @$i;
 827
 828     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 829     my @inc_src;
 830
 831     if ( $conf->exists($inc_file, $agentnum)
 832          && length( $conf->config($inc_file, $agentnum) ) ) {
 833
 834       @inc_src = $conf->config($inc_file, $agentnum);
 835
 836     } else {
 837
 838       $inc_file = $conf->key_orbase("${base}latex$include", $template);
 839
 840       my $convert_map = $convert_maps{$format}{$include};
 841
 842       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
 843                        s/--\@\]/$delimiters{$format}[1]/g;
 844                        $_;
 845                      }
 846                  &$convert_map( $conf->config($inc_file, $agentnum) );
 847
 848     }
 849
 850     my $inc_tt = new Text::Template (
 851       TYPE       => 'ARRAY',
 852       SOURCE     => [ map "$_\n", @inc_src ],
 853       DELIMITERS => $delimiters{$format},
 854     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 855
 856     unless ( $inc_tt->compile() ) {
 857       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 858       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 859       die $error;
 860     }
 861
 862     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 863
 864     $invoice_data{$include} =~ s/\n+$//
 865       if ($format eq 'latex');
 866   }
 867
 868   # let invoices use either of these as needed
 869   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 870     ? $cust_main->payinfo : '';
 871   $invoice_data{'po_line'} =
 872     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 873       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 874       : $nbsp;
 875
 876   my %money_chars = ( 'latex'    => '',
 877                       'html'     => $conf->config('money_char') || '$',
 878                       'template' => '',
 879                     );
 880   my $money_char = $money_chars{$format};
 881
 882   # extremely dubious
 883   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 884                             'html'     => $conf->config('money_char') || '$',
 885                             'template' => '',
 886                           );
 887   my $other_money_char = $other_money_chars{$format};
 888   $invoice_data{'dollar'} = $other_money_char;
 889
 890   my %minus_signs = ( 'latex'    => '$-$',
 891                       'html'     => '&minus;',
 892                       'template' => '- ' );
 893   my $minus = $minus_signs{$format};
 894
 895   my @detail_items = ();
 896   my @total_items = ();
 897   my @buf = ();
 898   my @sections = ();
 899
 900   $invoice_data{'detail_items'} = \@detail_items;
 901   $invoice_data{'total_items'} = \@total_items;
 902   $invoice_data{'buf'} = \@buf;
 903   $invoice_data{'sections'} = \@sections;
 904
 905   warn "$me generating sections\n"
 906     if $DEBUG > 1;
 907
 908   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 909   my $multisection = $self->has_sections;
 910   $conf->exists($tc.'sections', $cust_main->agentnum) ||
 911                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 912   $invoice_data{'multisection'} = $multisection;
 913   my $late_sections;
 914   my $extra_sections = [];
 915   my $extra_lines = ();
 916
 917   # default section ('Charges')
 918   my $default_section = { 'description' => '',
 919                           'subtotal'    => '',
 920                           'no_subtotal' => 1,
 921                         };
 922
 923   # Previous Charges section
 924   # subtotal is the first return value from $self->previous
 925   my $previous_section;
 926   # if the invoice has major sections, or if we're summarizing previous
 927   # charges with a single line, or if we've been specifically told to put them
 928   # in a section, create a section for previous charges:
 929   if ( $multisection or
 930        $conf->exists('previous_balance-summary_only') or
 931        $conf->exists('previous_balance-section') ) {
 932
 933     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 934                            'subtotal'    => $other_money_char.
 935                                             sprintf('%.2f', $pr_total),
 936                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 937                          };
 938     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 939       join(' / ', map { $cust_main->balance_date_range(@$_) }
 940                   $self->_prior_month30s
 941           )
 942       if $conf->exists('invoice_include_aging');
 943
 944   } else {
 945     # otherwise put them in the main section
 946     $previous_section = $default_section;
 947   }
 948
 949   my $adjust_section = {
 950     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 951     'adjust_section' => 1,
 952     'subtotal'       => 0,   # adjusted below
 953   };
 954   my $adjust_weight = _pkg_category($adjust_section->{description})
 955                         ? _pkg_category($adjust_section->{description})->weight
 956                         : 0;
 957   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 958   # Note: 'sort_weight' here is actually a flag telling whether there is an
 959   # explicit package category for the adjust section. If so, certain behavior
 960   # happens.
 961   $adjust_section->{'sort_weight'} = $adjust_weight;
 962
 963
 964   if ( $multisection ) {
 965     ($extra_sections, $extra_lines) =
 966       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 967       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 968       && $self->can('_items_extra_usage_sections');
 969
 970     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 971
 972     push @detail_items, @$extra_lines if $extra_lines;
 973
 974     # the code is written so that both methods can be used together, but
 975     # we haven't yet changed the template to take advantage of that, so for
 976     # now, treat them as mutually exclusive.
 977     my %section_method = ( by_category => 1 );
 978     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 979       %section_method = ( by_location => 1 );
 980     }
 981     my ($early, $late) =
 982       $self->_items_sections( 'summary' => $summarypage,
 983                               'escape'  => $escape_function_nonbsp,
 984                               'extra_sections' => $extra_sections,
 985                               'format'  => $format,
 986                               %section_method
 987                             );
 988     push @sections, @$early;
 989     $late_sections = $late;
 990
 991     if (    $conf->exists('svc_phone_sections')
 992          && $self->can('_items_svc_phone_sections')
 993        )
 994     {
 995       my ($phone_sections, $phone_lines) =
 996         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
 997       push @{$late_sections}, @$phone_sections;
 998       push @detail_items, @$phone_lines;
 999     }
1000     if ( $conf->exists('voip-cust_accountcode_cdr')
1001          && $cust_main->accountcode_cdr
1002          && $self->can('_items_accountcode_cdr')
1003        )
1004     {
1005       my ($accountcode_section, $accountcode_lines) =
1006         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1007       if ( scalar(@$accountcode_lines) ) {
1008           push @{$late_sections}, $accountcode_section;
1009           push @detail_items, @$accountcode_lines;
1010       }
1011     }
1012   } else {# not multisection
1013     # make a default section
1014     push @sections, $default_section;
1015     # and calculate the finance charge total, since it won't get done otherwise.
1016     # and the default section total
1017     # XXX possibly finance_pkgclass should not be used in this manner?
1018     my @finance_charges;
1019     my @charges;
1020     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1021       if ( $invoice_data{finance_section} and
1022         grep { $_->section eq $invoice_data{finance_section} }
1023            $cust_bill_pkg->cust_bill_pkg_display ) {
1024         # I think these are always setup fees, but just to be sure...
1025         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1026       } else {
1027         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1028       }
1029     }
1030     $invoice_data{finance_amount} =
1031       sprintf('%.2f', sum( @finance_charges ) || 0);
1032     $default_section->{subtotal} = $other_money_char.
1033                                     sprintf('%.2f', sum( @charges ) || 0);
1034   }
1035
1036   # start setting up summary subtotals
1037   my @summary_subtotals;
1038   my $method = $conf->config('summary_subtotals_method');
1039   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1040     # then re-section them by the correct method
1041     my %section_method = ( by_category => 1 );
1042     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1043       %section_method = ( by_location => 1 );
1044     }
1045     my ($early, $late) =
1046       $self->_items_sections( 'summary' => $summarypage,
1047                               'escape'  => $escape_function_nonbsp,
1048                               'extra_sections' => $extra_sections,
1049                               'format'  => $format,
1050                               %section_method
1051                             );
1052     foreach ( @$early ) {
1053       next if $_->{subtotal} == 0;
1054       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1055       push @summary_subtotals, $_;
1056     }
1057   } else {
1058     # subtotal sectioning is the same as for the actual invoice sections
1059     @summary_subtotals = @sections;
1060   }
1061
1062   # Hereafter, push sections to both @sections and @summary_subtotals
1063   # if they belong in both places (e.g. tax section).  Late sections are
1064   # never in @summary_subtotals.
1065
1066   # previous invoice balances in the Previous Charges section if there
1067   # is one, otherwise in the main detail section
1068   # (except if summary_only is enabled, don't show them at all)
1069   if ( $self->can('_items_previous') &&
1070        $self->enable_previous &&
1071        ! $conf->exists('previous_balance-summary_only') ) {
1072
1073     warn "$me adding previous balances\n"
1074       if $DEBUG > 1;
1075
1076     foreach my $line_item ( $self->_items_previous ) {
1077
1078       my $detail = {
1079         ref             => $line_item->{'pkgnum'},
1080         pkgpart         => $line_item->{'pkgpart'},
1081         #quantity        => 1, # not really correct
1082         section         => $previous_section, # which might be $default_section
1083         description     => &$escape_function($line_item->{'description'}),
1084         ext_description => [ map { &$escape_function($_) }
1085                              @{ $line_item->{'ext_description'} || [] }
1086                            ],
1087         amount          => $money_char . $line_item->{'amount'},
1088         product_code    => $line_item->{'pkgpart'} || 'N/A',
1089       };
1090
1091       push @detail_items, $detail;
1092       push @buf, [ $detail->{'description'},
1093                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1094                  ];
1095     }
1096
1097   }
1098
1099   if ( @pr_cust_bill && $self->enable_previous ) {
1100     push @buf, ['','-----------'];
1101     push @buf, [ $self->mt('Total Previous Balance'),
1102                  $money_char. sprintf("%10.2f", $pr_total) ];
1103     push @buf, ['',''];
1104   }
1105
1106   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1107       warn "$me adding DID summary\n"
1108         if $DEBUG > 1;
1109
1110       my ($didsummary,$minutes) = $self->_did_summary;
1111       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1112       push @detail_items,
1113        { 'description' => $didsummary_desc,
1114            'ext_description' => [ $didsummary, $minutes ],
1115        };
1116   }
1117
1118   foreach my $section (@sections, @$late_sections) {
1119
1120     # begin some normalization
1121     $section->{'subtotal'} = $section->{'amount'}
1122       if $multisection
1123          && !exists($section->{subtotal})
1124          && exists($section->{amount});
1125
1126     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1127       if ( $invoice_data{finance_section} &&
1128            $section->{'description'} eq $invoice_data{finance_section} );
1129
1130     $section->{'subtotal'} = $other_money_char.
1131                              sprintf('%.2f', $section->{'subtotal'})
1132       if $multisection;
1133
1134     # continue some normalization
1135     $section->{'amount'}   = $section->{'subtotal'}
1136       if $multisection;
1137
1138
1139     if ( $section->{'description'} ) {
1140       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1141                    [ '', '' ],
1142                  );
1143     }
1144
1145     warn "$me   setting options\n"
1146       if $DEBUG > 1;
1147
1148     my %options = ();
1149     $options{'section'} = $section if $multisection;
1150     $options{'format'} = $format;
1151     $options{'escape_function'} = $escape_function;
1152     $options{'no_usage'} = 1 unless $unsquelched;
1153     $options{'unsquelched'} = $unsquelched;
1154     $options{'summary_page'} = $summarypage;
1155     $options{'skip_usage'} =
1156       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1157     $options{'preref_callback'} = $params{'preref_callback'};
1158
1159     warn "$me   searching for line items\n"
1160       if $DEBUG > 1;
1161
1162     foreach my $line_item ( $self->_items_pkg(%options),
1163                             $self->_items_fee(%options) ) {
1164
1165       warn "$me     adding line item ".
1166            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1167         if $DEBUG > 1;
1168
1169       push @buf, ( [ $line_item->{'description'},
1170                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1171                    ],
1172                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1173                  );
1174
1175       $line_item->{'ref'} = $line_item->{'pkgnum'};
1176       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1177       $line_item->{'section'} = $section;
1178       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1179       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1180
1181       if ( length($line_item->{'unit_amount'}) ) {
1182         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1183       }
1184       $line_item->{'ext_description'} ||= [];
1185
1186       push @detail_items, $line_item;
1187     }
1188
1189     if ( $section->{'description'} ) {
1190       push @buf, ( ['','-----------'],
1191                    [ $section->{'description'}. ' sub-total',
1192                       $section->{'subtotal'} # already formatted this
1193                    ],
1194                    [ '', '' ],
1195                    [ '', '' ],
1196                  );
1197     }
1198
1199   }
1200
1201   $invoice_data{current_less_finance} =
1202     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1203
1204   # if there's anything in the Previous Charges section, prepend it to the list
1205   if ( $pr_total and $previous_section ne $default_section ) {
1206     unshift @sections, $previous_section;
1207     # but not @summary_subtotals
1208   }
1209
1210   warn "$me adding taxes\n"
1211     if $DEBUG > 1;
1212
1213   # create a tax section if we don't yet have one
1214   my $tax_description = 'Taxes, Surcharges, and Fees';
1215   my $tax_section =
1216     List::Util::first { $_->{description} eq $tax_description } @sections;
1217   if (!$tax_section) {
1218     $tax_section = { 'description' => $tax_description };
1219   }
1220   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1221   # if this is an existing tax section, we're merging the tax items into it.
1222   # grab the taxtotal that's already there, strip the money symbol if any
1223   my $taxtotal = $tax_section->{'subtotal'} || 0;
1224   $taxtotal =~ s/^\Q$other_money_char\E//;
1225
1226   # this does nothing
1227   #my $tax_weight = _pkg_category($tax_section->{description})
1228   #                      ? _pkg_category($tax_section->{description})->weight
1229   #                      : 0;
1230   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1231   #$tax_section->{'sort_weight'} = $tax_weight;
1232
1233   my @items_tax = $self->_items_tax;
1234   push @sections, $tax_section if $multisection and @items_tax > 0;
1235
1236   foreach my $tax ( @items_tax ) {
1237
1238     $taxtotal += $tax->{'amount'};
1239
1240     my $description = &$escape_function( $tax->{'description'} );
1241     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1242
1243     if ( $multisection ) {
1244
1245       push @detail_items, {
1246         ext_description => [],
1247         ref          => '',
1248         quantity     => '',
1249         description  => $description,
1250         amount       => $money_char. $amount,
1251         product_code => '',
1252         section      => $tax_section,
1253       };
1254
1255     } else {
1256
1257       push @total_items, {
1258         'total_item'   => $description,
1259         'total_amount' => $other_money_char. $amount,
1260       };
1261
1262     }
1263
1264     push @buf,[ $description,
1265                 $money_char. $amount,
1266               ];
1267
1268   }
1269
1270   if ( @items_tax ) {
1271     my $total = {};
1272     $total->{'total_item'} = $self->mt('Sub-total');
1273     $total->{'total_amount'} =
1274       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1275
1276     if ( $multisection ) {
1277       if ( $taxtotal > 0 ) {
1278         $tax_section->{'subtotal'} = $other_money_char.
1279                                      sprintf('%.2f', $taxtotal);
1280         $tax_section->{'pretotal'} = 'New charges sub-total '.
1281                                      $total->{'total_amount'};
1282         $tax_section->{'description'} = $self->mt($tax_description);
1283
1284         # append it if it's not already there
1285         if ( !grep $tax_section, @sections ) {
1286           push @sections, $tax_section;
1287           push @summary_subtotals, $tax_section;
1288         }
1289       }
1290
1291     } else {
1292       unshift @total_items, $total;
1293     }
1294   }
1295   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1296
1297   ###
1298   # Totals
1299   ###
1300
1301   my %embolden_functions = (
1302     'latex'    => sub { return '\textbf{'. shift(). '}' },
1303     'html'     => sub { return '<b>'. shift(). '</b>' },
1304     'template' => sub { shift },
1305   );
1306   my $embolden_function = $embolden_functions{$format};
1307
1308   if ( $multisection ) {
1309
1310     if ( $adjust_section->{'sort_weight'} ) {
1311       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1312         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1313     } else{
1314       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1315         $other_money_char.  sprintf('%.2f', $self->charged );
1316     }
1317
1318   }
1319
1320   if ( $self->can('_items_total') ) { # should always be true now
1321
1322     # even for multisection, need plain text version
1323
1324     my @new_total_items = $self->_items_total;
1325
1326     push @buf,['','-----------'];
1327
1328     foreach ( @new_total_items ) {
1329       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1330       $_->{'total_item'}   = &$embolden_function( $item );
1331       $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1332       # but if it's multisection, don't append to @total_items. the adjust
1333       # section has all this stuff
1334       push @total_items, $_ if !$multisection;
1335       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1336     }
1337
1338     push @buf, [ '', '' ];
1339
1340     # if we're showing previous invoices, also show previous
1341     # credits and payments
1342     if ( $self->enable_previous
1343           and $self->can('_items_credits')
1344           and $self->can('_items_payments') )
1345       {
1346
1347       # credits
1348       my $credittotal = 0;
1349       foreach my $credit (
1350         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1351       ) {
1352
1353         my $total;
1354         $total->{'total_item'} = &$escape_function($credit->{'description'});
1355         $credittotal += $credit->{'amount'};
1356         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1357         if ( $multisection ) {
1358           push @detail_items, {
1359             ext_description => [],
1360             ref          => '',
1361             quantity     => '',
1362             description  => &$escape_function($credit->{'description'}),
1363             amount       => $money_char . $credit->{'amount'},
1364             product_code => '',
1365             section      => $adjust_section,
1366           };
1367         } else {
1368           push @total_items, $total;
1369         }
1370
1371       }
1372       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1373
1374       #credits (again)
1375       foreach my $credit (
1376         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1377       ) {
1378         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1379       }
1380
1381       # payments
1382       my $paymenttotal = 0;
1383       foreach my $payment (
1384         $self->_items_payments( 'template' => $template )
1385       ) {
1386         my $total = {};
1387         $total->{'total_item'} = &$escape_function($payment->{'description'});
1388         $paymenttotal += $payment->{'amount'};
1389         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1390         if ( $multisection ) {
1391           push @detail_items, {
1392             ext_description => [],
1393             ref          => '',
1394             quantity     => '',
1395             description  => &$escape_function($payment->{'description'}),
1396             amount       => $money_char . $payment->{'amount'},
1397             product_code => '',
1398             section      => $adjust_section,
1399           };
1400         }else{
1401           push @total_items, $total;
1402         }
1403         push @buf, [ $payment->{'description'},
1404                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1405                    ];
1406       }
1407       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1408
1409       if ( $multisection ) {
1410         $adjust_section->{'subtotal'} = $other_money_char.
1411                                         sprintf('%.2f', $credittotal + $paymenttotal);
1412
1413         #why this? because {sort_weight} forces the adjust_section to appear
1414         #in @extra_sections instead of @sections. obviously.
1415         push @sections, $adjust_section
1416           unless $adjust_section->{sort_weight};
1417         # do not summarize; adjustments there are shown according to
1418         # different rules
1419       }
1420
1421       # create Balance Due message
1422       {
1423         my $total;
1424         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1425         $total->{'total_amount'} =
1426           &$embolden_function(
1427             $other_money_char. sprintf('%.2f', #why? $summarypage
1428                                                #  ? $self->charged +
1429                                                #    $self->billing_balance
1430                                                #  :
1431                                                    $self->owed + $pr_total
1432                                       )
1433           );
1434         if ( $multisection && !$adjust_section->{sort_weight} ) {
1435           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1436                                            $total->{'total_amount'};
1437         } else {
1438           push @total_items, $total;
1439         }
1440         push @buf,['','-----------'];
1441         push @buf,[$self->balance_due_msg, $money_char.
1442           sprintf("%10.2f", $balance_due ) ];
1443       }
1444
1445       if ( $conf->exists('previous_balance-show_credit')
1446           and $cust_main->balance < 0 ) {
1447         my $credit_total = {
1448           'total_item'    => &$embolden_function($self->credit_balance_msg),
1449           'total_amount'  => &$embolden_function(
1450             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1451           ),
1452         };
1453         if ( $multisection ) {
1454           $adjust_section->{'posttotal'} .= $newline_token .
1455             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1456         }
1457         else {
1458           push @total_items, $credit_total;
1459         }
1460         push @buf,['','-----------'];
1461         push @buf,[$self->credit_balance_msg, $money_char.
1462           sprintf("%10.2f", -$cust_main->balance ) ];
1463       }
1464     }
1465
1466   } #end of default total adding ! can('_items_total')
1467
1468   if ( $multisection ) {
1469     if (    $conf->exists('svc_phone_sections')
1470          && $self->can('_items_svc_phone_sections')
1471        )
1472     {
1473       my $total;
1474       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1475       $total->{'total_amount'} =
1476         &$embolden_function(
1477           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1478         );
1479       my $last_section = pop @sections;
1480       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1481                                      $total->{'total_amount'};
1482       push @sections, $last_section;
1483     }
1484     push @sections, @$late_sections
1485       if $unsquelched;
1486   }
1487
1488   # make a discounts-available section, even without multisection
1489   if ( $conf->exists('discount-show_available')
1490        and my @discounts_avail = $self->_items_discounts_avail ) {
1491     my $discount_section = {
1492       'description' => $self->mt('Discounts Available'),
1493       'subtotal'    => '',
1494       'no_subtotal' => 1,
1495     };
1496
1497     push @sections, $discount_section; # do not summarize
1498     push @detail_items, map { +{
1499         'ref'         => '', #should this be something else?
1500         'section'     => $discount_section,
1501         'description' => &$escape_function( $_->{description} ),
1502         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1503         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1504     } } @discounts_avail;
1505   }
1506
1507   # not adding any more sections after this
1508   $invoice_data{summary_subtotals} = \@summary_subtotals;
1509
1510   # usage subtotals
1511   if ( $conf->exists('usage_class_summary')
1512        and $self->can('_items_usage_class_summary') ) {
1513     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1514     if ( @usage_subtotals ) {
1515       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1516       unshift @detail_items, @usage_subtotals;
1517     }
1518   }
1519
1520   # invoice history "section" (not really a section)
1521   # not to be included in any subtotals, completely independent of
1522   # everything...
1523   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1524     my %history;
1525     my %monthorder;
1526     foreach my $cust_bill ( $cust_main->cust_bill ) {
1527       # XXX hardcoded format, and currently only 'charged'; add other fields
1528       # if they become necessary
1529       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1530       $history{$date} ||= 0;
1531       $history{$date} += $cust_bill->charged;
1532       # just so we have a numeric sort key
1533       $monthorder{$date} ||= $cust_bill->_date;
1534     }
1535     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1536                         keys %history;
1537     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1538     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1539   }
1540
1541   # service locations: another option for template customization
1542   my %location_info;
1543   foreach my $item (@detail_items) {
1544     if ( $item->{locationnum} ) {
1545       $location_info{ $item->{locationnum} } ||= {
1546         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1547       };
1548     }
1549   }
1550   $invoice_data{location_info} = \%location_info;
1551
1552   # debugging hook: call this with 'diag' => 1 to just get a hash of
1553   # the invoice variables
1554   return \%invoice_data if ( $params{'diag'} );
1555
1556   # All sections and items are built; now fill in templates.
1557   my @includelist = ();
1558   push @includelist, 'summary' if $summarypage;
1559   foreach my $include ( @includelist ) {
1560
1561     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1562     my @inc_src;
1563
1564     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1565
1566       @inc_src = $conf->config($inc_file, $agentnum);
1567
1568     } else {
1569
1570       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1571
1572       my $convert_map = $convert_maps{$format}{$include};
1573
1574       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1575                        s/--\@\]/$delimiters{$format}[1]/g;
1576                        $_;
1577                      }
1578                  &$convert_map( $conf->config($inc_file, $agentnum) );
1579
1580     }
1581
1582     my $inc_tt = new Text::Template (
1583       TYPE       => 'ARRAY',
1584       SOURCE     => [ map "$_\n", @inc_src ],
1585       DELIMITERS => $delimiters{$format},
1586     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1587
1588     unless ( $inc_tt->compile() ) {
1589       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1590       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1591       die $error;
1592     }
1593
1594     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1595
1596     $invoice_data{$include} =~ s/\n+$//
1597       if ($format eq 'latex');
1598   }
1599
1600   $invoice_lines = 0;
1601   my $wasfunc = 0;
1602   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1603     /invoice_lines\((\d*)\)/;
1604     $invoice_lines += $1 || scalar(@buf);
1605     $wasfunc=1;
1606   }
1607   die "no invoice_lines() functions in template?"
1608     if ( $format eq 'template' && !$wasfunc );
1609
1610   if ($format eq 'template') {
1611
1612     if ( $invoice_lines ) {
1613       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1614       $invoice_data{'total_pages'}++
1615         if scalar(@buf) % $invoice_lines;
1616     }
1617
1618     #setup subroutine for the template
1619     $invoice_data{invoice_lines} = sub {
1620       my $lines = shift || scalar(@buf);
1621       map {
1622         scalar(@buf)
1623           ? shift @buf
1624           : [ '', '' ];
1625       }
1626       ( 1 .. $lines );
1627     };
1628
1629     my $lines;
1630     my @collect;
1631     while (@buf) {
1632       push @collect, split("\n",
1633         $text_template->fill_in( HASH => \%invoice_data )
1634       );
1635       $invoice_data{'page'}++;
1636     }
1637     map "$_\n", @collect;
1638
1639   } else { # this is where we actually create the invoice
1640
1641     warn "filling in template for invoice ". $self->invnum. "\n"
1642       if $DEBUG;
1643     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1644       if $DEBUG > 1;
1645
1646     $text_template->fill_in(HASH => \%invoice_data);
1647   }
1648 }
1649
1650 sub notice_name { '('.shift->table.')'; }
1651
1652 # this is not supposed to happen
1653 sub template_conf { warn "bare FS::Template_Mixin::template_conf";
1654   'invoice_';
1655 }
1656
1657 # helper routine for generating date ranges
1658 sub _prior_month30s {
1659   my $self = shift;
1660   my @ranges = (
1661    [ 1,       2592000 ], # 0-30 days ago
1662    [ 2592000, 5184000 ], # 30-60 days ago
1663    [ 5184000, 7776000 ], # 60-90 days ago
1664    [ 7776000, 0       ], # 90+   days ago
1665   );
1666
1667   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1668           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1669       ] }
1670   @ranges;
1671 }
1672
1673 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1674
1675 Returns an postscript invoice, as a scalar.
1676
1677 Options can be passed as a hashref (recommended) or as a list of time, template
1678 and then any key/value pairs for any other options.
1679
1680 I<time> an optional value used to control the printing of overdue messages.  The
1681 default is now.  It isn't the date of the invoice; that's the `_date' field.
1682 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1683 L<Time::Local> and L<Date::Parse> for conversion functions.
1684
1685 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1686
1687 =cut
1688
1689 sub print_ps {
1690   my $self = shift;
1691
1692   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1693   my $ps = generate_ps($file);
1694   unlink($logofile);
1695   unlink($barcodefile) if $barcodefile;
1696
1697   $ps;
1698 }
1699
1700 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1701
1702 Returns an PDF invoice, as a scalar.
1703
1704 Options can be passed as a hashref (recommended) or as a list of time, template
1705 and then any key/value pairs for any other options.
1706
1707 I<time> an optional value used to control the printing of overdue messages.  The
1708 default is now.  It isn't the date of the invoice; that's the `_date' field.
1709 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1710 L<Time::Local> and L<Date::Parse> for conversion functions.
1711
1712 I<template>, if specified, is the name of a suffix for alternate invoices.
1713
1714 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1715
1716 =cut
1717
1718 sub print_pdf {
1719   my $self = shift;
1720
1721   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1722   my $pdf = generate_pdf($file);
1723   unlink($logofile);
1724   unlink($barcodefile) if $barcodefile;
1725
1726   $pdf;
1727 }
1728
1729 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1730
1731 Returns an HTML invoice, as a scalar.
1732
1733 I<time> an optional value used to control the printing of overdue messages.  The
1734 default is now.  It isn't the date of the invoice; that's the `_date' field.
1735 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1736 L<Time::Local> and L<Date::Parse> for conversion functions.
1737
1738 I<template>, if specified, is the name of a suffix for alternate invoices.
1739
1740 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1741
1742 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1743 when emailing the invoice as part of a multipart/related MIME email.
1744
1745 =cut
1746
1747 sub print_html {
1748   my $self = shift;
1749   my %params;
1750   if ( ref($_[0]) ) {
1751     %params = %{ shift() };
1752   } else {
1753     %params = @_;
1754   }
1755   $params{'format'} = 'html';
1756
1757   $self->print_generic( %params );
1758 }
1759
1760 # quick subroutine for print_latex
1761 #
1762 # There are ten characters that LaTeX treats as special characters, which
1763 # means that they do not simply typeset themselves:
1764 #      # $ % & ~ _ ^ \ { }
1765 #
1766 # TeX ignores blanks following an escaped character; if you want a blank (as
1767 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1768
1769 sub _latex_escape {
1770   my $value = shift;
1771   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1772   $value =~ s/([<>])/\$$1\$/g;
1773   $value;
1774 }
1775
1776 sub _html_escape {
1777   my $value = shift;
1778   encode_entities($value);
1779   $value;
1780 }
1781
1782 sub _html_escape_nbsp {
1783   my $value = _html_escape(shift);
1784   $value =~ s/ +/&nbsp;/g;
1785   $value;
1786 }
1787
1788 #utility methods for print_*
1789
1790 sub _translate_old_latex_format {
1791   warn "_translate_old_latex_format called\n"
1792     if $DEBUG;
1793
1794   my @template = ();
1795   while ( @_ ) {
1796     my $line = shift;
1797
1798     if ( $line =~ /^%%Detail\s*$/ ) {
1799
1800       push @template, q![@--!,
1801                       q!  foreach my $_tr_line (@detail_items) {!,
1802                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1803                       q!      $_tr_line->{'description'} .= !,
1804                       q!        "\\tabularnewline\n~~".!,
1805                       q!        join( "\\tabularnewline\n~~",!,
1806                       q!          @{$_tr_line->{'ext_description'}}!,
1807                       q!        );!,
1808                       q!    }!;
1809
1810       while ( ( my $line_item_line = shift )
1811               !~ /^%%EndDetail\s*$/                            ) {
1812         $line_item_line =~ s/'/\\'/g;    # nice LTS
1813         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1814         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1815         push @template, "    \$OUT .= '$line_item_line';";
1816       }
1817
1818       push @template, '}',
1819                       '--@]';
1820       #' doh, gvim
1821     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1822
1823       push @template, '[@--',
1824                       '  foreach my $_tr_line (@total_items) {';
1825
1826       while ( ( my $total_item_line = shift )
1827               !~ /^%%EndTotalDetails\s*$/                      ) {
1828         $total_item_line =~ s/'/\\'/g;    # nice LTS
1829         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1830         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1831         push @template, "    \$OUT .= '$total_item_line';";
1832       }
1833
1834       push @template, '}',
1835                       '--@]';
1836
1837     } else {
1838       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1839       push @template, $line;
1840     }
1841
1842   }
1843
1844   if ($DEBUG) {
1845     warn "$_\n" foreach @template;
1846   }
1847
1848   (@template);
1849 }
1850
1851 =item terms
1852
1853 =cut
1854
1855 sub terms {
1856   my $self = shift;
1857   my $conf = $self->conf;
1858
1859   #check for an invoice-specific override
1860   return $self->invoice_terms if $self->invoice_terms;
1861
1862   #check for a customer- specific override
1863   my $cust_main = $self->cust_main;
1864   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1865
1866   my $agentnum = '';
1867   if ( $cust_main ) {
1868     $agentnum = $cust_main->agentnum;
1869   } elsif ( my $prospect_main = $self->prospect_main ) {
1870     $agentnum = $prospect_main->agentnum;
1871   }
1872
1873   #use configured default
1874   $conf->config('invoice_default_terms', $agentnum) || '';
1875 }
1876
1877 =item due_date
1878
1879 =cut
1880
1881 sub due_date {
1882   my $self = shift;
1883   my $duedate = '';
1884   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1885     $duedate = $self->_date() + ( $1 * 86400 );
1886   }
1887   $duedate;
1888 }
1889
1890 =item due_date2str
1891
1892 =cut
1893
1894 sub due_date2str {
1895   my $self = shift;
1896   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1897 }
1898
1899 =item balance_due_msg
1900
1901 =cut
1902
1903 sub balance_due_msg {
1904   my $self = shift;
1905   my $msg = $self->mt('Balance Due');
1906   return $msg unless $self->terms; # huh?
1907   if ( !$self->conf->exists('invoice_show_prior_due_date')
1908        or $self->conf->exists('invoice_sections') ) {
1909     # if enabled, the due date is shown with Total New Charges (see
1910     # _items_total) and not here
1911     # (yes, or if invoice_sections is enabled; this is just for compatibility)
1912     if ( $self->due_date ) {
1913       $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1914         $self->due_date2str('short');
1915     } elsif ( $self->terms ) {
1916       $msg .= ' - '. $self->mt($self->terms);
1917     }
1918   }
1919   $msg;
1920 }
1921
1922 =item balance_due_date
1923
1924 =cut
1925
1926 sub balance_due_date {
1927   my $self = shift;
1928   my $conf = $self->conf;
1929   my $duedate = '';
1930   my $terms = $self->terms;
1931   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1932     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1933   }
1934   $duedate;
1935 }
1936
1937 sub credit_balance_msg {
1938   my $self = shift;
1939   $self->mt('Credit Balance Remaining')
1940 }
1941
1942 =item _date_pretty
1943
1944 Returns a string with the date, for example: "3/20/2008", localized for the
1945 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1946
1947 =cut
1948
1949 sub _date_pretty {
1950   my $self = shift;
1951   $self->time2str_local('short', $self->_date);
1952 }
1953
1954 =item _date_pretty_unlocalized
1955
1956 Returns a string with the date, for example: "3/20/2008", in the format
1957 configured for the back-office.  Use _date_pretty for end-customer display use.
1958
1959 =cut
1960
1961 sub _date_pretty_unlocalized {
1962   my $self = shift;
1963   time2str($date_format, $self->_date);
1964 }
1965
1966 =item email HASHREF
1967
1968 Emails this template.
1969
1970 Options are passed as a hashref.  Available options:
1971
1972 =over 4
1973
1974 =item from
1975
1976 If specified, overrides the default From: address.
1977
1978 =item notice_name
1979
1980 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1981
1982 =item template
1983
1984 (Deprecated) If specified, is the name of a suffix for alternate template files.
1985
1986 =back
1987
1988 Options accepted by generate_email can also be used.
1989
1990 =cut
1991
1992 sub email {
1993   my $self = shift;
1994   my $opt = shift || {};
1995   if ($opt and !ref($opt)) {
1996     die ref($self). '->email called with positional parameters';
1997   }
1998
1999   return if $self->hide;
2000
2001   my $error = send_email(
2002     $self->generate_email(
2003       'subject'     => $self->email_subject($opt->{template}),
2004       %$opt, # template, etc.
2005     )
2006   );
2007
2008   die "can't email: $error\n" if $error;
2009 }
2010
2011 =item generate_email OPTION => VALUE ...
2012
2013 Options:
2014
2015 =over 4
2016
2017 =item from
2018
2019 sender address, required
2020
2021 =item template
2022
2023 alternate template name, optional
2024
2025 =item subject
2026
2027 email subject, optional
2028
2029 =item notice_name
2030
2031 notice name instead of "Invoice", optional
2032
2033 =back
2034
2035 Returns an argument list to be passed to L<FS::Misc::send_email>.
2036
2037 =cut
2038
2039 use MIME::Entity;
2040
2041 sub generate_email {
2042
2043   my $self = shift;
2044   my %args = @_;
2045   my $conf = $self->conf;
2046
2047   my $me = '[FS::Template_Mixin::generate_email]';
2048
2049   my %return = (
2050     'from'      => $args{'from'},
2051     'subject'   => ($args{'subject'} || $self->email_subject),
2052     'custnum'   => $self->custnum,
2053     'msgtype'   => 'invoice',
2054   );
2055
2056   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2057
2058   my $cust_main = $self->cust_main;
2059
2060   if (ref($args{'to'}) eq 'ARRAY') {
2061     $return{'to'} = $args{'to'};
2062   } elsif ( $cust_main ) {
2063     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2064   }
2065
2066   my $tc = $self->template_conf;
2067
2068   my @text; # array of lines
2069   my $html; # a big string
2070   my @related_parts; # will contain the text/HTML alternative, and images
2071   my $related; # will contain the multipart/related object
2072
2073   if ( $conf->exists($tc. 'email_pdf') ) {
2074     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2075
2076       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2077         if $DEBUG;
2078
2079       my $msg_template = FS::msg_template->by_key($msgnum)
2080         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2081       my %prepared = $msg_template->prepare(
2082         cust_main => $self->cust_main,
2083         object    => $self
2084       );
2085
2086       @text = split(/(?=\n)/, $prepared{'text_body'});
2087       $html = $prepared{'html_body'};
2088
2089     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2090
2091       warn "$me using '${tc}email_pdf_note' in multipart message"
2092         if $DEBUG;
2093       @text = $conf->config($tc.'email_pdf_note');
2094       $html = join('<BR>', @text);
2095
2096     } # else use the plain text invoice
2097   }
2098
2099   if (!@text) {
2100
2101     if ( $conf->config($tc.'template') ) {
2102
2103       warn "$me generating plain text invoice"
2104         if $DEBUG;
2105
2106       # 'print_text' argument is no longer used
2107       @text = $self->print_text(\%args);
2108
2109     } else {
2110
2111       warn "$me no plain text version exists; sending empty message body"
2112         if $DEBUG;
2113
2114     }
2115
2116   }
2117
2118   my $text_part = build MIME::Entity (
2119     'Type'        => 'text/plain',
2120     'Encoding'    => 'quoted-printable',
2121     'Charset'     => 'UTF-8',
2122     #'Encoding'    => '7bit',
2123     'Data'        => \@text,
2124     'Disposition' => 'inline',
2125   );
2126
2127   if (!$html) {
2128
2129     if ( $conf->exists($tc.'html') ) {
2130       warn "$me generating HTML invoice"
2131         if $DEBUG;
2132
2133       $args{'from'} =~ /\@([\w\.\-]+)/;
2134       my $from = $1 || 'example.com';
2135       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2136
2137       my $logo;
2138       my $agentnum = $cust_main ? $cust_main->agentnum
2139                                 : $self->prospect_main->agentnum;
2140       if ( defined($args{'template'}) && length($args{'template'})
2141            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2142          )
2143       {
2144         $logo = 'logo_'. $args{'template'}. '.png';
2145       } else {
2146         $logo = "logo.png";
2147       }
2148       my $image_data = $conf->config_binary( $logo, $agentnum);
2149
2150       push @related_parts, build MIME::Entity
2151         'Type'       => 'image/png',
2152         'Encoding'   => 'base64',
2153         'Data'       => $image_data,
2154         'Filename'   => 'logo.png',
2155         'Content-ID' => "<$content_id>",
2156       ;
2157
2158       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2159         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2160         push @related_parts, build MIME::Entity
2161           'Type'       => 'image/png',
2162           'Encoding'   => 'base64',
2163           'Data'       => $self->invoice_barcode(0),
2164           'Filename'   => 'barcode.png',
2165           'Content-ID' => "<$barcode_content_id>",
2166         ;
2167         $args{'barcode_cid'} = $barcode_content_id;
2168       }
2169
2170       $html = $self->print_html({ 'cid'=>$content_id, %args });
2171     }
2172
2173   }
2174
2175   if ( $html ) {
2176
2177     warn "$me creating HTML/text multipart message"
2178       if $DEBUG;
2179
2180     $return{'nobody'} = 1;
2181
2182     my $alternative = build MIME::Entity
2183       'Type'        => 'multipart/alternative',
2184       #'Encoding'    => '7bit',
2185       'Disposition' => 'inline'
2186     ;
2187
2188     if ( @text ) {
2189       $alternative->add_part($text_part);
2190     }
2191
2192     $alternative->attach(
2193       'Type'        => 'text/html',
2194       'Encoding'    => 'quoted-printable',
2195       'Data'        => [ '<html>',
2196                          '  <head>',
2197                          '    <title>',
2198                          '      '. encode_entities($return{'subject'}),
2199                          '    </title>',
2200                          '  </head>',
2201                          '  <body bgcolor="#e8e8e8">',
2202                          $html,
2203                          '  </body>',
2204                          '</html>',
2205                        ],
2206       'Disposition' => 'inline',
2207       #'Filename'    => 'invoice.pdf',
2208     );
2209
2210     unshift @related_parts, $alternative;
2211
2212     $related = build MIME::Entity 'Type'     => 'multipart/related',
2213                                   'Encoding' => '7bit';
2214
2215     #false laziness w/Misc::send_email
2216     $related->head->replace('Content-type',
2217       $related->mime_type.
2218       '; boundary="'. $related->head->multipart_boundary. '"'.
2219       '; type=multipart/alternative'
2220     );
2221
2222     $related->add_part($_) foreach @related_parts;
2223
2224   }
2225
2226   my @otherparts = ();
2227   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2228
2229     push @otherparts, build MIME::Entity
2230       'Type'        => 'text/csv',
2231       'Encoding'    => '7bit',
2232       'Data'        => [ map { "$_\n" }
2233                            $self->call_details('prepend_billed_number' => 1)
2234                        ],
2235       'Disposition' => 'attachment',
2236       'Filename'    => 'usage-'. $self->invnum. '.csv',
2237     ;
2238
2239   }
2240
2241   if ( $conf->exists($tc.'email_pdf') ) {
2242
2243     #attaching pdf too:
2244     # multipart/mixed
2245     #   multipart/related
2246     #     multipart/alternative
2247     #       text/plain
2248     #       text/html
2249     #     image/png
2250     #   application/pdf
2251
2252     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2253     push @otherparts, $pdf;
2254   }
2255
2256   if (@otherparts) {
2257     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2258     if ( $html ) {
2259       $return{'mimeparts'} = [ $related, @otherparts ];
2260       $return{'type'} = 'multipart/related'; # of the first part
2261     } else {
2262       $return{'mimeparts'} = [ $text_part, @otherparts ];
2263       $return{'type'} = 'text/plain';
2264     }
2265   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2266     $return{'mimeparts'} = \@related_parts;
2267     $return{'content-type'} = 'multipart/related';
2268     $return{'type'} = 'multipart/alternative';
2269   } else { # no HTML either
2270     $return{'body'} = \@text;
2271     $return{'content-type'} = 'text/plain';
2272   }
2273
2274   %return;
2275
2276 }
2277
2278 =item mimebuild_pdf
2279
2280 Returns a list suitable for passing to MIME::Entity->build(), representing
2281 this invoice as PDF attachment.
2282
2283 =cut
2284
2285 sub mimebuild_pdf {
2286   my $self = shift;
2287   (
2288     'Type'        => 'application/pdf',
2289     'Encoding'    => 'base64',
2290     'Data'        => [ $self->print_pdf(@_) ],
2291     'Disposition' => 'attachment',
2292     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2293   );
2294 }
2295
2296 =item _items_sections OPTIONS
2297
2298 Generate section information for all items appearing on this invoice.
2299 This will only be called for multi-section invoices.
2300
2301 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2302 related display records (L<FS::cust_bill_pkg_display>) and organize
2303 them into two groups ("early" and "late" according to whether they come
2304 before or after the total), then into sections.  A subtotal is calculated
2305 for each section.
2306
2307 Section descriptions are returned in sort weight order.  Each consists
2308 of a hash containing:
2309
2310 description: the package category name, escaped
2311 subtotal: the total charges in that section
2312 tax_section: a flag indicating that the section contains only tax charges
2313 summarized: same as tax_section, for some reason
2314 sort_weight: the package category's sort weight
2315
2316 If 'condense' is set on the display record, it also contains everything
2317 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2318 coderefs to generate parts of the invoice.  This is not advised.
2319
2320 The method returns two arrayrefs, one of "early" sections and one of "late"
2321 sections.
2322
2323 OPTIONS may include:
2324
2325 by_location: a flag to divide the invoice into sections by location.
2326 Each section hash will have a 'location' element containing a hashref of
2327 the location fields (see L<FS::cust_location>).  The section description
2328 will be the location label, but the template can use any of the location
2329 fields to create a suitable label.
2330
2331 by_category: a flag to divide the invoice into sections using display
2332 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2333 behavior.  Each section hash will have a 'category' element containing
2334 the section name from the display record (which probably equals the
2335 category name of the package, but may not in some cases).
2336
2337 summary: a flag indicating that this is a summary-format invoice.
2338 Turning this on has the following effects:
2339 - Ignores display items with the 'summary' flag.
2340 - Places all sections in the "early" group even if they have post_total.
2341 - Creates sections for all non-disabled package categories, even if they
2342 have no charges on this invoice, as well as a section with no name.
2343
2344 escape: an escape function to use for section titles.
2345
2346 extra_sections: an arrayref of additional sections to return after the
2347 sorted list.  If there are any of these, section subtotals exclude
2348 usage charges.
2349
2350 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2351 passed through to C<_condense_section()>.
2352
2353 =cut
2354
2355 use vars qw(%pkg_category_cache);
2356 sub _items_sections {
2357   my $self = shift;
2358   my %opt = @_;
2359
2360   my $escape = $opt{escape};
2361   my @extra_sections = @{ $opt{extra_sections} || [] };
2362
2363   # $subtotal{$locationnum}{$categoryname} = amount.
2364   # if we're not using by_location, $locationnum is undef.
2365   # if we're not using by_category, you guessed it, $categoryname is undef.
2366   # if we're not using either one, we shouldn't be here in the first place...
2367   my %subtotal = ();
2368   my %late_subtotal = ();
2369   my %not_tax = ();
2370
2371   # About tax items + multisection invoices:
2372   # If either invoice_*summary option is enabled, AND there is a
2373   # package category with the name of the tax, then there will be
2374   # a display record assigning the tax item to that category.
2375   #
2376   # However, the taxes are always placed in the "Taxes, Surcharges,
2377   # and Fees" section regardless of that.  The only effect of the
2378   # display record is to create a subtotal for the summary page.
2379
2380   # cache these
2381   my $pkg_hash = $self->cust_pkg_hash;
2382
2383   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2384   {
2385
2386       my $usage = $cust_bill_pkg->usage;
2387
2388       my $locationnum;
2389       if ( $opt{by_location} ) {
2390         if ( $cust_bill_pkg->pkgnum ) {
2391           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2392         } else {
2393           $locationnum = '';
2394         }
2395       } else {
2396         $locationnum = undef;
2397       }
2398
2399       # as in _items_cust_pkg, if a line item has no display records,
2400       # cust_bill_pkg_display() returns a default record for it
2401
2402       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2403         next if ( $display->summary && $opt{summary} );
2404
2405         my $section = $display->section;
2406         my $type    = $display->type;
2407         # Set $section = undef if we're sectioning by location and this
2408         # line item _has_ a location (i.e. isn't a fee).
2409         $section = undef if $locationnum;
2410
2411         # set this flag if the section is not tax-only
2412         $not_tax{$locationnum}{$section} = 1
2413           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2414
2415         # there's actually a very important piece of logic buried in here:
2416         # incrementing $late_subtotal{$section} CREATES
2417         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2418         # to define the list of late sections, and likewise keys(%subtotal).
2419         # When _items_cust_bill_pkg is called to generate line items for
2420         # real, it will be called with 'section' => $section for each
2421         # of these.
2422         if ( $display->post_total && !$opt{summary} ) {
2423           if (! $type || $type eq 'S') {
2424             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2425               if $cust_bill_pkg->setup != 0
2426               || $cust_bill_pkg->setup_show_zero;
2427           }
2428
2429           if (! $type) {
2430             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2431               if $cust_bill_pkg->recur != 0
2432               || $cust_bill_pkg->recur_show_zero;
2433           }
2434
2435           if ($type && $type eq 'R') {
2436             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2437               if $cust_bill_pkg->recur != 0
2438               || $cust_bill_pkg->recur_show_zero;
2439           }
2440
2441           if ($type && $type eq 'U') {
2442             $late_subtotal{$locationnum}{$section} += $usage
2443               unless scalar(@extra_sections);
2444           }
2445
2446         } else { # it's a pre-total (normal) section
2447
2448           # skip tax items unless they're explicitly included in a section
2449           next if $cust_bill_pkg->pkgnum == 0 and
2450                   ! $cust_bill_pkg->feepart   and
2451                   ! $section;
2452
2453           if ( $type eq 'S' ) {
2454             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2455               if $cust_bill_pkg->setup != 0
2456               || $cust_bill_pkg->setup_show_zero;
2457           } elsif ( $type eq 'R' ) {
2458             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2459               if $cust_bill_pkg->recur != 0
2460               || $cust_bill_pkg->recur_show_zero;
2461           } elsif ( $type eq 'U' ) {
2462             $subtotal{$locationnum}{$section} += $usage
2463               unless scalar(@extra_sections);
2464           } elsif ( !$type ) {
2465             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2466                                                + $cust_bill_pkg->recur;
2467           }
2468
2469         }
2470
2471       }
2472
2473   }
2474
2475   %pkg_category_cache = ();
2476
2477   # summary invoices need subtotals for all non-disabled package categories,
2478   # even if they're zero
2479   # but currently assume that there are no location sections, or at least
2480   # that the summary page doesn't care about them
2481   if ( $opt{summary} ) {
2482     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2483       $subtotal{''}{$category->categoryname} ||= 0;
2484     }
2485     $subtotal{''}{''} ||= 0;
2486   }
2487
2488   my @sections;
2489   foreach my $post_total (0,1) {
2490     my @these;
2491     my $s = $post_total ? \%late_subtotal : \%subtotal;
2492     foreach my $locationnum (keys %$s) {
2493       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2494         my $section = {
2495                         'subtotal'    => $s->{$locationnum}{$sectionname},
2496                         'post_total'  => $post_total,
2497                         'sort_weight' => 0,
2498                       };
2499         if ( $locationnum ) {
2500           $section->{'locationnum'} = $locationnum;
2501           my $location = FS::cust_location->by_key($locationnum);
2502           $section->{'description'} = &{ $escape }($location->location_label);
2503           # Better ideas? This will roughly group them by proximity,
2504           # which alpha sorting on any of the address fields won't.
2505           # Sorting by locationnum is meaningless.
2506           # We have to sort on _something_ or the order may change
2507           # randomly from one invoice to the next, which will confuse
2508           # people.
2509           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2510                                       $locationnum;
2511           $section->{'location'} = {
2512             label_prefix => &{ $escape }($location->label_prefix),
2513             map { $_ => &{ $escape }($location->get($_)) }
2514               $location->fields
2515           };
2516         } else {
2517           $section->{'category'} = $sectionname;
2518           $section->{'description'} = &{ $escape }($sectionname);
2519           if ( _pkg_category($sectionname) ) {
2520             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2521             if ( _pkg_category($sectionname)->condense ) {
2522               $section = { %$section, $self->_condense_section($opt{format}) };
2523             }
2524           }
2525         }
2526         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2527           # then it's a tax-only section
2528           $section->{'summarized'} = 'Y';
2529           $section->{'tax_section'} = 'Y';
2530         }
2531         push @these, $section;
2532       } # foreach $sectionname
2533     } #foreach $locationnum
2534     push @these, @extra_sections if $post_total == 0;
2535     # need an alpha sort for location sections, because postal codes can
2536     # be non-numeric
2537     $sections[ $post_total ] = [ sort {
2538       $opt{'by_location'} ?
2539         ($a->{sort_weight} cmp $b->{sort_weight}) :
2540         ($a->{sort_weight} <=> $b->{sort_weight})
2541       } @these ];
2542   } #foreach $post_total
2543
2544   return @sections; # early, late
2545 }
2546
2547 #helper subs for above
2548
2549 sub cust_pkg_hash {
2550   my $self = shift;
2551   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2552 }
2553
2554 sub _pkg_category {
2555   my $categoryname = shift;
2556   $pkg_category_cache{$categoryname} ||=
2557     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2558 }
2559
2560 my %condensed_format = (
2561   'label' => [ qw( Description Qty Amount ) ],
2562   'fields' => [
2563                 sub { shift->{description} },
2564                 sub { shift->{quantity} },
2565                 sub { my($href, %opt) = @_;
2566                       ($opt{dollar} || ''). $href->{amount};
2567                     },
2568               ],
2569   'align'  => [ qw( l r r ) ],
2570   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2571   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2572 );
2573
2574 sub _condense_section {
2575   my ( $self, $format ) = ( shift, shift );
2576   ( 'condensed' => 1,
2577     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2578       qw( description_generator
2579           header_generator
2580           total_generator
2581           total_line_generator
2582         )
2583   );
2584 }
2585
2586 sub _condensed_generator_defaults {
2587   my ( $self, $format ) = ( shift, shift );
2588   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2589 }
2590
2591 my %html_align = (
2592   'c' => 'center',
2593   'l' => 'left',
2594   'r' => 'right',
2595 );
2596
2597 sub _condensed_header_generator {
2598   my ( $self, $format ) = ( shift, shift );
2599
2600   my ( $f, $prefix, $suffix, $separator, $column ) =
2601     _condensed_generator_defaults($format);
2602
2603   if ($format eq 'latex') {
2604     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2605     $suffix = "\\\\\n\\hline";
2606     $separator = "&\n";
2607     $column =
2608       sub { my ($d,$a,$s,$w) = @_;
2609             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2610           };
2611   } elsif ( $format eq 'html' ) {
2612     $prefix = '<th></th>';
2613     $suffix = '';
2614     $separator = '';
2615     $column =
2616       sub { my ($d,$a,$s,$w) = @_;
2617             return qq!<th align="$html_align{$a}">$d</th>!;
2618       };
2619   }
2620
2621   sub {
2622     my @args = @_;
2623     my @result = ();
2624
2625     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2626       push @result,
2627         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2628     }
2629
2630     $prefix. join($separator, @result). $suffix;
2631   };
2632
2633 }
2634
2635 sub _condensed_description_generator {
2636   my ( $self, $format ) = ( shift, shift );
2637
2638   my ( $f, $prefix, $suffix, $separator, $column ) =
2639     _condensed_generator_defaults($format);
2640
2641   my $money_char = '$';
2642   if ($format eq 'latex') {
2643     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2644     $suffix = '\\\\';
2645     $separator = " & \n";
2646     $column =
2647       sub { my ($d,$a,$s,$w) = @_;
2648             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2649           };
2650     $money_char = '\\dollar';
2651   }elsif ( $format eq 'html' ) {
2652     $prefix = '"><td align="center"></td>';
2653     $suffix = '';
2654     $separator = '';
2655     $column =
2656       sub { my ($d,$a,$s,$w) = @_;
2657             return qq!<td align="$html_align{$a}">$d</td>!;
2658       };
2659     #$money_char = $conf->config('money_char') || '$';
2660     $money_char = '';  # this is madness
2661   }
2662
2663   sub {
2664     #my @args = @_;
2665     my $href = shift;
2666     my @result = ();
2667
2668     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2669       my $dollar = '';
2670       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2671       push @result,
2672         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2673                     map { $f->{$_}->[$i] } qw(align span width)
2674                   );
2675     }
2676
2677     $prefix. join( $separator, @result ). $suffix;
2678   };
2679
2680 }
2681
2682 sub _condensed_total_generator {
2683   my ( $self, $format ) = ( shift, shift );
2684
2685   my ( $f, $prefix, $suffix, $separator, $column ) =
2686     _condensed_generator_defaults($format);
2687   my $style = '';
2688
2689   if ($format eq 'latex') {
2690     $prefix = "& ";
2691     $suffix = "\\\\\n";
2692     $separator = " & \n";
2693     $column =
2694       sub { my ($d,$a,$s,$w) = @_;
2695             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2696           };
2697   }elsif ( $format eq 'html' ) {
2698     $prefix = '';
2699     $suffix = '';
2700     $separator = '';
2701     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2702     $column =
2703       sub { my ($d,$a,$s,$w) = @_;
2704             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2705       };
2706   }
2707
2708
2709   sub {
2710     my @args = @_;
2711     my @result = ();
2712
2713     #  my $r = &{$f->{fields}->[$i]}(@args);
2714     #  $r .= ' Total' unless $i;
2715
2716     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2717       push @result,
2718         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2719                     map { $f->{$_}->[$i] } qw(align span width)
2720                   );
2721     }
2722
2723     $prefix. join( $separator, @result ). $suffix;
2724   };
2725
2726 }
2727
2728 =item total_line_generator FORMAT
2729
2730 Returns a coderef used for generation of invoice total line items for this
2731 usage_class.  FORMAT is either html or latex
2732
2733 =cut
2734
2735 # should not be used: will have issues with hash element names (description vs
2736 # total_item and amount vs total_amount -- another array of functions?
2737
2738 sub _condensed_total_line_generator {
2739   my ( $self, $format ) = ( shift, shift );
2740
2741   my ( $f, $prefix, $suffix, $separator, $column ) =
2742     _condensed_generator_defaults($format);
2743   my $style = '';
2744
2745   if ($format eq 'latex') {
2746     $prefix = "& ";
2747     $suffix = "\\\\\n";
2748     $separator = " & \n";
2749     $column =
2750       sub { my ($d,$a,$s,$w) = @_;
2751             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2752           };
2753   }elsif ( $format eq 'html' ) {
2754     $prefix = '';
2755     $suffix = '';
2756     $separator = '';
2757     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2758     $column =
2759       sub { my ($d,$a,$s,$w) = @_;
2760             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2761       };
2762   }
2763
2764
2765   sub {
2766     my @args = @_;
2767     my @result = ();
2768
2769     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2770       push @result,
2771         &{$column}( &{$f->{fields}->[$i]}(@args),
2772                     map { $f->{$_}->[$i] } qw(align span width)
2773                   );
2774     }
2775
2776     $prefix. join( $separator, @result ). $suffix;
2777   };
2778
2779 }
2780
2781 =item _items_pkg [ OPTIONS ]
2782
2783 Return line item hashes for each package item on this invoice. Nearly
2784 equivalent to
2785
2786 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2787
2788 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2789 'format' and 'escape_function' at minimum.
2790
2791 To produce items for a specific invoice section, OPTIONS should include
2792 'section', a hashref containing 'category' and/or 'locationnum' keys.
2793
2794 'section' may also contain a key named 'condensed'. If this is present
2795 and has a true value, _items_pkg will try to merge identical items into items
2796 with 'quantity' equal to the number of items (not the sum of their separate
2797 quantities, for some reason).
2798
2799 =cut
2800
2801 sub _items_nontax {
2802   my $self = shift;
2803   # The order of these is important.  Bundled line items will be merged into
2804   # the most recent non-hidden item, so it needs to be the one with:
2805   # - the same pkgnum
2806   # - the same start date
2807   # - no pkgpart_override
2808   #
2809   # So: sort by pkgnum,
2810   # then by sdate
2811   # then sort the base line item before any overrides
2812   # then sort hidden before non-hidden add-ons
2813   # then sort by override pkgpart (for consistency)
2814   sort { $a->pkgnum <=> $b->pkgnum        or
2815          $a->sdate  <=> $b->sdate         or
2816          ($a->pkgpart_override ? 0 : -1)  or
2817          ($b->pkgpart_override ? 0 : 1)   or
2818          $b->hidden cmp $a->hidden        or
2819          $a->pkgpart_override <=> $b->pkgpart_override
2820        }
2821   # and of course exclude taxes and fees
2822   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2823 }
2824
2825 sub _items_fee {
2826   my $self = shift;
2827   my %options = @_;
2828   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2829   my $escape_function = $options{escape_function};
2830
2831   my @items;
2832   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2833     # cache this, so we don't look it up again in every section
2834     my $part_fee = $cust_bill_pkg->get('part_fee')
2835        || $cust_bill_pkg->part_fee;
2836     $cust_bill_pkg->set('part_fee', $part_fee);
2837     if (!$part_fee) {
2838       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2839       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2840       next;
2841     }
2842     if ( exists($options{section}) and exists($options{section}{category}) )
2843     {
2844       my $categoryname = $options{section}{category};
2845       # then filter for items that have that section
2846       if ( $part_fee->categoryname ne $categoryname ) {
2847         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2848         next;
2849       }
2850     } # otherwise include them all in the main section
2851     # XXX what to do when sectioning by location?
2852
2853     my @ext_desc;
2854     my %base_invnums; # invnum => invoice date
2855     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2856       if ($_->base_invnum) {
2857         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2858         my $base_date = $self->time2str_local('short', $base_bill->_date)
2859           if $base_bill;
2860         $base_invnums{$_->base_invnum} = $base_date || '';
2861       }
2862     }
2863     foreach (sort keys(%base_invnums)) {
2864       next if $_ == $self->invnum;
2865       # per convention, we must escape ext_description lines
2866       push @ext_desc,
2867         &{$escape_function}(
2868           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2869         );
2870     }
2871     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2872     # but not escape the base description line
2873
2874     push @items,
2875       { feepart     => $cust_bill_pkg->feepart,
2876         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2877         description => $desc,
2878         ext_description => \@ext_desc
2879         # sdate/edate?
2880       };
2881   }
2882   @items;
2883 }
2884
2885 sub _items_pkg {
2886   my $self = shift;
2887   my %options = @_;
2888
2889   warn "$me _items_pkg searching for all package line items\n"
2890     if $DEBUG > 1;
2891
2892   my @cust_bill_pkg = $self->_items_nontax;
2893
2894   warn "$me _items_pkg filtering line items\n"
2895     if $DEBUG > 1;
2896   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2897
2898   if ($options{section} && $options{section}->{condensed}) {
2899
2900     warn "$me _items_pkg condensing section\n"
2901       if $DEBUG > 1;
2902
2903     my %itemshash = ();
2904     local $Storable::canonical = 1;
2905     foreach ( @items ) {
2906       my $item = { %$_ };
2907       delete $item->{ref};
2908       delete $item->{ext_description};
2909       my $key = freeze($item);
2910       $itemshash{$key} ||= 0;
2911       $itemshash{$key} ++; # += $item->{quantity};
2912     }
2913     @items = sort { $a->{description} cmp $b->{description} }
2914              map { my $i = thaw($_);
2915                    $i->{quantity} = $itemshash{$_};
2916                    $i->{amount} =
2917                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2918                    $i;
2919                  }
2920              keys %itemshash;
2921   }
2922
2923   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2924     if $DEBUG > 1;
2925
2926   @items;
2927 }
2928
2929 sub _taxsort {
2930   return 0 unless $a->itemdesc cmp $b->itemdesc;
2931   return -1 if $b->itemdesc eq 'Tax';
2932   return 1 if $a->itemdesc eq 'Tax';
2933   return -1 if $b->itemdesc eq 'Other surcharges';
2934   return 1 if $a->itemdesc eq 'Other surcharges';
2935   $a->itemdesc cmp $b->itemdesc;
2936 }
2937
2938 sub _items_tax {
2939   my $self = shift;
2940   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2941     $self->cust_bill_pkg;
2942   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2943
2944   if ( $self->conf->exists('always_show_tax') ) {
2945     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2946     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2947       push @items,
2948         { 'description' => $itemdesc,
2949           'amount'      => 0.00 };
2950     }
2951   }
2952   @items;
2953 }
2954
2955 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2956
2957 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2958 list of hashrefs describing the line items they generate on the invoice.
2959
2960 OPTIONS may include:
2961
2962 format: the invoice format.
2963
2964 escape_function: the function used to escape strings.
2965
2966 DEPRECATED? (expensive, mostly unused?)
2967 format_function: the function used to format CDRs.
2968
2969 section: a hashref containing 'category' and/or 'locationnum'; if this
2970 is present, only returns line items that belong to that category and/or
2971 location (whichever is defined).
2972
2973 multisection: a flag indicating that this is a multisection invoice,
2974 which does something complicated.
2975
2976 preref_callback: coderef run for each line item, code should return HTML to be
2977 displayed before that line item (quotations only)
2978
2979 Returns a list of hashrefs, each of which may contain:
2980
2981 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2982 ext_description, which is an arrayref of detail lines to show below
2983 the package line.
2984
2985 =cut
2986
2987 sub _items_cust_bill_pkg {
2988   my $self = shift;
2989   my $conf = $self->conf;
2990   my $cust_bill_pkgs = shift;
2991   my %opt = @_;
2992
2993   my $format = $opt{format} || '';
2994   my $escape_function = $opt{escape_function} || sub { shift };
2995   my $format_function = $opt{format_function} || '';
2996   my $no_usage = $opt{no_usage} || '';
2997   my $unsquelched = $opt{unsquelched} || ''; #unused
2998   my ($section, $locationnum, $category);
2999   if ( $opt{section} ) {
3000     $category = $opt{section}->{category};
3001     $locationnum = $opt{section}->{locationnum};
3002   }
3003   my $summary_page = $opt{summary_page} || ''; #unused
3004   my $multisection = defined($category) || defined($locationnum);
3005   my $discount_show_always = 0;
3006
3007   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3008
3009   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3010
3011   # for location labels: use default location on the invoice date
3012   my $default_locationnum;
3013   if ( $self->custnum ) {
3014     my $h_cust_main;
3015     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3016     $h_cust_main = qsearchs({
3017         'table'     => 'h_cust_main',
3018         'hashref'   => { custnum => $self->custnum },
3019         'extra_sql' => $h_search[1],
3020         'addl_from' => $h_search[3],
3021     }) || $cust_main;
3022     $default_locationnum = $h_cust_main->ship_locationnum;
3023   } elsif ( $self->prospectnum ) {
3024     my $cust_location = qsearchs('cust_location',
3025       { prospectnum => $self->prospectnum,
3026         disabled => '' });
3027     $default_locationnum = $cust_location->locationnum if $cust_location;
3028   }
3029
3030   my @b = (); # accumulator for the line item hashes that we'll return
3031   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3032             # the 'current' line item hashes for setup, recur, usage, discount
3033   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3034   {
3035     # if the current line item is waiting to go out, and the one we're about
3036     # to start is not bundled, then push out the current one and start a new
3037     # one.
3038     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3039       if ( $_ && !$cust_bill_pkg->hidden ) {
3040         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3041         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3042         if (exists($_->{unit_amount})) {
3043           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3044         }
3045         push @b, { %$_ }
3046           if $_->{amount} != 0
3047           || $discount_show_always
3048           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3049           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3050         ;
3051         $_ = undef;
3052       }
3053     }
3054
3055     if ( $locationnum ) {
3056       # this is a location section; skip packages that aren't at this
3057       # service location.
3058       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3059       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3060               != $locationnum;
3061     }
3062
3063     # Consider display records for this item to determine if it belongs
3064     # in this section.  Note that if there are no display records, there
3065     # will be a default pseudo-record that includes all charge types
3066     # and has no section name.
3067     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3068                                   ? $cust_bill_pkg->cust_bill_pkg_display
3069                                   : ( $cust_bill_pkg );
3070
3071     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3072          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3073       if $DEBUG > 1;
3074
3075     if ( defined($category) ) {
3076       # then this is a package category section; process all display records
3077       # that belong to this section.
3078       @cust_bill_pkg_display = grep { $_->section eq $category }
3079                                 @cust_bill_pkg_display;
3080     } else {
3081       # otherwise, process all display records that aren't usage summaries
3082       # (I don't think there should be usage summaries if you aren't using
3083       # category sections, but this is the historical behavior)
3084       @cust_bill_pkg_display = grep { !$_->summary }
3085                                 @cust_bill_pkg_display;
3086     }
3087
3088     my $classname = ''; # package class name, will fill in later
3089
3090     foreach my $display (@cust_bill_pkg_display) {
3091
3092       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3093            $display->billpkgdisplaynum. "\n"
3094         if $DEBUG > 1;
3095
3096       my $type = $display->type;
3097
3098       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3099       $desc = substr($desc, 0, $maxlength). '...'
3100         if $format eq 'latex' && length($desc) > $maxlength;
3101
3102       my %details_opt = ( 'format'          => $format,
3103                           'escape_function' => $escape_function,
3104                           'format_function' => $format_function,
3105                           'no_usage'        => $opt{'no_usage'},
3106                         );
3107
3108       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3109         # XXX this should be pulled out into quotation_pkg
3110
3111         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3112           if $DEBUG > 1;
3113         # quotation_pkgs are never fees, so don't worry about the case where
3114         # part_pkg is undefined
3115
3116         # and I guess they're never bundled either?
3117         if ( $cust_bill_pkg->setup != 0 ) {
3118           my $description = $desc;
3119           $description .= ' Setup'
3120             if $cust_bill_pkg->recur != 0
3121             || $discount_show_always
3122             || $cust_bill_pkg->recur_show_zero;
3123           #push @b, {
3124           # keep it consistent, please
3125           $s = {
3126             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3127             'description' => $description,
3128             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3129             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3130             'quantity'    => $cust_bill_pkg->quantity,
3131             'preref_html' => ( $opt{preref_callback}
3132                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3133                                  : ''
3134                              ),
3135           };
3136         }
3137         if ( $cust_bill_pkg->recur != 0 ) {
3138           #push @b, {
3139           $r = {
3140             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3141             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3142             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3143             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3144             'quantity'    => $cust_bill_pkg->quantity,
3145            'preref_html'  => ( $opt{preref_callback}
3146                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3147                                  : ''
3148                              ),
3149           };
3150         }
3151
3152       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3153         # a "normal" package line item (not a quotation, not a fee, not a tax)
3154
3155         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3156           if $DEBUG > 1;
3157
3158         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3159         my $part_pkg = $cust_pkg->part_pkg;
3160
3161         # which pkgpart to show for display purposes?
3162         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3163
3164         # start/end dates for invoice formats that do nonstandard
3165         # things with them
3166         my %item_dates = ();
3167         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3168           unless $part_pkg->option('disable_line_item_date_ranges',1);
3169
3170         # not normally used, but pass this to the template anyway
3171         $classname = $part_pkg->classname;
3172
3173         if (    (!$type || $type eq 'S')
3174              && (    $cust_bill_pkg->setup != 0
3175                   || $cust_bill_pkg->setup_show_zero
3176                 )
3177            )
3178          {
3179
3180           warn "$me _items_cust_bill_pkg adding setup\n"
3181             if $DEBUG > 1;
3182
3183           my $description = $desc;
3184           $description .= ' Setup'
3185             if $cust_bill_pkg->recur != 0
3186             || $discount_show_always
3187             || $cust_bill_pkg->recur_show_zero;
3188
3189           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3190                                                               $self->agentnum )
3191             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3192                                      # triggered by the recurring charge freq
3193                                      # (RT#26274)
3194             && $cust_bill_pkg->recur == 0
3195             && ! $cust_bill_pkg->recur_show_zero;
3196
3197           my @d = ();
3198           my $svc_label;
3199
3200           # always pass the svc_label through to the template, even if
3201           # not displaying it as an ext_description
3202           my @svc_labels = map &{$escape_function}($_),
3203                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3204
3205           $svc_label = $svc_labels[0];
3206
3207           unless ( $cust_pkg->part_pkg->hide_svc_detail
3208                 || $cust_bill_pkg->hidden )
3209           {
3210
3211             push @d, @svc_labels
3212               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3213             # show the location label if it's not the customer's default
3214             # location, and we're not grouping items by location already
3215             if ( $cust_pkg->locationnum != $default_locationnum
3216                   and !defined($locationnum) ) {
3217               my $loc = $cust_pkg->location_label;
3218               $loc = substr($loc, 0, $maxlength). '...'
3219                 if $format eq 'latex' && length($loc) > $maxlength;
3220               push @d, &{$escape_function}($loc);
3221             }
3222
3223           } #unless hiding service details
3224
3225           push @d, $cust_bill_pkg->details(%details_opt)
3226             if $cust_bill_pkg->recur == 0;
3227
3228           if ( $cust_bill_pkg->hidden ) {
3229             $s->{amount}      += $cust_bill_pkg->setup;
3230             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3231             push @{ $s->{ext_description} }, @d;
3232           } else {
3233             $s = {
3234               _is_setup       => 1,
3235               description     => $description,
3236               pkgpart         => $pkgpart,
3237               pkgnum          => $cust_bill_pkg->pkgnum,
3238               amount          => $cust_bill_pkg->setup,
3239               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3240               unit_amount     => $cust_bill_pkg->unitsetup,
3241               quantity        => $cust_bill_pkg->quantity,
3242               ext_description => \@d,
3243               svc_label       => ($svc_label || ''),
3244               locationnum     => $cust_pkg->locationnum, # sure, why not?
3245             };
3246           };
3247
3248         }
3249
3250         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3251              && (
3252                      $cust_bill_pkg->recur != 0
3253                   || $cust_bill_pkg->setup == 0
3254                   || $discount_show_always
3255                   || $cust_bill_pkg->recur_show_zero
3256                 )
3257            )
3258         {
3259
3260           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3261             if $DEBUG > 1;
3262
3263           my $is_summary = $display->summary;
3264           my $description = $desc;
3265           if ( $type eq 'U' and defined($r) ) {
3266             # don't just show the same description as the recur line
3267             $description = $self->mt('Usage charges');
3268           }
3269
3270           my $part_pkg = $cust_pkg->part_pkg;
3271
3272           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3273                                                               $self->agentnum );
3274
3275           my @d = ();
3276           my @seconds = (); # for display of usage info
3277           my $svc_label = '';
3278
3279           #at least until cust_bill_pkg has "past" ranges in addition to
3280           #the "future" sdate/edate ones... see #3032
3281           my @dates = ( $self->_date );
3282           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3283           push @dates, $prev->sdate if $prev;
3284           push @dates, undef if !$prev;
3285
3286           my @svc_labels = map &{$escape_function}($_),
3287                       $cust_pkg->h_labels_short(@dates, 'I');
3288           $svc_label = $svc_labels[0];
3289
3290           # show service labels, unless...
3291                     # the package is set not to display them
3292           unless ( $part_pkg->hide_svc_detail
3293                     # or this is a tax-like line item
3294                 || $cust_bill_pkg->itemdesc
3295                     # or this is a hidden (bundled) line item
3296                 || $cust_bill_pkg->hidden
3297                     # or this is a usage summary line
3298                 || $is_summary && $type && $type eq 'U'
3299                     # or this is a usage line and there's a recurring line
3300                     # for the package in the same section (which will
3301                     # have service labels already)
3302                 || ($type eq 'U' and defined($r))
3303               )
3304           {
3305
3306             warn "$me _items_cust_bill_pkg adding service details\n"
3307               if $DEBUG > 1;
3308
3309             push @d, @svc_labels
3310               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3311             warn "$me _items_cust_bill_pkg done adding service details\n"
3312               if $DEBUG > 1;
3313
3314             # show the location label if it's not the customer's default
3315             # location, and we're not grouping items by location already
3316             if ( $cust_pkg->locationnum != $default_locationnum
3317                   and !defined($locationnum) ) {
3318               my $loc = $cust_pkg->location_label;
3319               $loc = substr($loc, 0, $maxlength). '...'
3320                 if $format eq 'latex' && length($loc) > $maxlength;
3321               push @d, &{$escape_function}($loc);
3322             }
3323
3324             # Display of seconds_since_sqlradacct:
3325             # On the invoice, when processing @detail_items, look for a field
3326             # named 'seconds'.  This will contain total seconds for each
3327             # service, in the same order as @ext_description.  For services
3328             # that don't support this it will show undef.
3329             if ( $conf->exists('svc_acct-usage_seconds')
3330                  and ! $cust_bill_pkg->pkgpart_override ) {
3331               foreach my $cust_svc (
3332                   $cust_pkg->h_cust_svc(@dates, 'I')
3333                 ) {
3334
3335                 # eval because not having any part_export_usage exports
3336                 # is a fatal error, last_bill/_date because that's how
3337                 # sqlradius_hour billing does it
3338                 my $sec = eval {
3339                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3340                 };
3341                 push @seconds, $sec;
3342               }
3343             } #if svc_acct-usage_seconds
3344
3345           } # if we are showing service labels
3346
3347           unless ( $is_summary ) {
3348             warn "$me _items_cust_bill_pkg adding details\n"
3349               if $DEBUG > 1;
3350
3351             #instead of omitting details entirely in this case (unwanted side
3352             # effects), just omit CDRs
3353             $details_opt{'no_usage'} = 1
3354               if $type && $type eq 'R';
3355
3356             push @d, $cust_bill_pkg->details(%details_opt);
3357           }
3358
3359           warn "$me _items_cust_bill_pkg calculating amount\n"
3360             if $DEBUG > 1;
3361
3362           my $amount = 0;
3363           if (!$type) {
3364             $amount = $cust_bill_pkg->recur;
3365           } elsif ($type eq 'R') {
3366             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3367           } elsif ($type eq 'U') {
3368             $amount = $cust_bill_pkg->usage;
3369           }
3370
3371           if ( !$type || $type eq 'R' ) {
3372
3373             warn "$me _items_cust_bill_pkg adding recur\n"
3374               if $DEBUG > 1;
3375
3376             my $unit_amount =
3377               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3378                                                 : $amount;
3379
3380             if ( $cust_bill_pkg->hidden ) {
3381               $r->{amount}      += $amount;
3382               $r->{unit_amount} += $unit_amount;
3383               push @{ $r->{ext_description} }, @d;
3384             } else {
3385               $r = {
3386                 description     => $description,
3387                 pkgpart         => $pkgpart,
3388                 pkgnum          => $cust_bill_pkg->pkgnum,
3389                 amount          => $amount,
3390                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3391                 unit_amount     => $unit_amount,
3392                 quantity        => $cust_bill_pkg->quantity,
3393                 %item_dates,
3394                 ext_description => \@d,
3395                 svc_label       => ($svc_label || ''),
3396                 locationnum     => $cust_pkg->locationnum,
3397               };
3398               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3399             }
3400
3401           } else {  # $type eq 'U'
3402
3403             warn "$me _items_cust_bill_pkg adding usage\n"
3404               if $DEBUG > 1;
3405
3406             if ( $cust_bill_pkg->hidden and defined($u) ) {
3407               # if this is a hidden package and there's already a usage
3408               # line for the bundle, add this package's total amount and
3409               # usage details to it
3410               $u->{amount}      += $amount;
3411               push @{ $u->{ext_description} }, @d;
3412             } elsif ( $amount ) {
3413               # create a new usage line
3414               $u = {
3415                 description     => $description,
3416                 pkgpart         => $pkgpart,
3417                 pkgnum          => $cust_bill_pkg->pkgnum,
3418                 amount          => $amount,
3419                 usage_item      => 1,
3420                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3421                 %item_dates,
3422                 ext_description => \@d,
3423                 locationnum     => $cust_pkg->locationnum,
3424               };
3425             } # else this has no usage, so don't create a usage section
3426           }
3427
3428         } # recurring or usage with recurring charge
3429
3430       } else { # taxes and fees
3431
3432         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3433           if $DEBUG > 1;
3434
3435         # items of this kind should normally not have sdate/edate.
3436         push @b, {
3437           'description' => $desc,
3438           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3439                                            + $cust_bill_pkg->recur)
3440         };
3441
3442       } # if quotation / package line item / other line item
3443
3444       # decide whether to show active discounts here
3445       if (
3446           # case 1: we are showing a single line for the package
3447           ( !$type )
3448           # case 2: we are showing a setup line for a package that has
3449           # no base recurring fee
3450           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3451           # case 3: we are showing a recur line for a package that has
3452           # a base recurring fee
3453           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3454       ) {
3455
3456         my $item_discount = $cust_bill_pkg->_item_discount;
3457         if ( $item_discount ) {
3458           # $item_discount->{amount} is negative
3459
3460           if ( $d and $cust_bill_pkg->hidden ) {
3461             $d->{amount}      += $item_discount->{amount};
3462           } else {
3463             $d = $item_discount;
3464             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3465           }
3466
3467           # update the active line (before the discount) to show the
3468           # original price (whether this is a hidden line or not)
3469           #
3470           # quotation discounts keep track of setup and recur; invoice
3471           # discounts currently don't
3472           if ( exists $item_discount->{setup_amount} ) {
3473
3474             $s->{amount} -= $item_discount->{setup_amount} if $s;
3475             $r->{amount} -= $item_discount->{recur_amount} if $r;
3476
3477           } else {
3478
3479             # $active_line is the line item hashref for the line that will
3480             # show the original price
3481             # (use the recur or single line for the package, unless we're
3482             # showing a setup line for a package with no recurring fee)
3483             my $active_line = $r;
3484             if ( $type eq 'S' ) {
3485               $active_line = $s;
3486             }
3487             $active_line->{amount} -= $item_discount->{amount};
3488
3489           }
3490
3491         } # if there are any discounts
3492       } # if this is an appropriate place to show discounts
3493
3494     } # foreach $display
3495
3496     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3497                                 && $conf->exists('discount-show-always'));
3498
3499   }
3500
3501   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3502     if ( $_  ) {
3503       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3504         if exists($_->{amount});
3505       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3506       if (exists($_->{unit_amount})) {
3507         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3508       }
3509
3510       push @b, { %$_ }
3511         if $_->{amount} != 0
3512         || $discount_show_always
3513         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3514         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3515     }
3516   }
3517
3518   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3519     if $DEBUG > 1;
3520
3521   @b;
3522
3523 }
3524
3525 =item _items_discounts_avail
3526
3527 Returns an array of line item hashrefs representing available term discounts
3528 for this invoice.  This makes the same assumptions that apply to term
3529 discounts in general: that the package is billed monthly, at a flat rate,
3530 with no usage charges.  A prorated first month will be handled, as will
3531 a setup fee if the discount is allowed to apply to setup fees.
3532
3533 =cut
3534
3535 sub _items_discounts_avail {
3536   my $self = shift;
3537
3538   #maybe move this method from cust_bill when quotations support discount_plans
3539   return () unless $self->can('discount_plans');
3540   my %plans = $self->discount_plans;
3541
3542   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3543   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3544
3545   map {
3546     my $months = $_;
3547     my $plan = $plans{$months};
3548
3549     my $term_total = sprintf('%.2f', $plan->discounted_total);
3550     my $percent = sprintf('%.0f',
3551                           100 * (1 - $term_total / $plan->base_total) );
3552     my $permonth = sprintf('%.2f', $term_total / $months);
3553     my $detail = $self->mt('discount on item'). ' '.
3554                  join(', ', map { "#$_" } $plan->pkgnums)
3555       if $list_pkgnums;
3556
3557     # discounts for non-integer months don't work anyway
3558     $months = sprintf("%d", $months);
3559
3560     +{
3561       description => $self->mt('Save [_1]% by paying for [_2] months',
3562                                 $percent, $months),
3563       amount      => $self->mt('[_1] ([_2] per month)',
3564                                 $term_total, $money_char.$permonth),
3565       ext_description => ($detail || ''),
3566     }
3567   } #map
3568   sort { $b <=> $a } keys %plans;
3569
3570 }
3571
3572 1;