FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 320     unless $cust_main->payname
 321         && $cust_main->payby !~ /^(CARD|DCRD|CHEK|DCHK)$/;
 322
 323   my $locale = $params{'locale'} || $cust_main->locale;
 324
 325   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 326                      'html'     => [ '<%=', '%>' ],
 327                      'template' => [ '{', '}' ],
 328                    );
 329
 330   warn "$me print_generic creating template\n"
 331     if $DEBUG > 1;
 332
 333   # set the notice name here, and nowhere else.
 334   my $notice_name =  $params{notice_name}
 335                   || $conf->config('notice_name')
 336                   || $self->notice_name;
 337
 338   #create the template
 339   my $template = $params{template} ? $params{template} : $self->_agent_template;
 340   my $templatefile = $self->template_conf. $format;
 341   $templatefile .= "_$template"
 342     if length($template) && $conf->exists($templatefile."_$template");
 343
 344   # the base template
 345   my @invoice_template = map "$_\n", $conf->config($templatefile)
 346     or die "cannot load config data $templatefile";
 347
 348   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 349     #change this to a die when the old code is removed
 350     # it's been almost ten years, changing it to a die on the next release.
 351     warn "old-style invoice template $templatefile; ".
 352          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 353          #$old_latex = 'true';
 354          #@invoice_template = _translate_old_latex_format(@invoice_template);
 355   }
 356
 357   warn "$me print_generic creating T:T object\n"
 358     if $DEBUG > 1;
 359
 360   my $text_template = new Text::Template(
 361     TYPE => 'ARRAY',
 362     SOURCE => \@invoice_template,
 363     DELIMITERS => $delimiters{$format},
 364   );
 365
 366   warn "$me print_generic compiling T:T object\n"
 367     if $DEBUG > 1;
 368
 369   $text_template->compile()
 370     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 371
 372
 373   # additional substitution could possibly cause breakage in existing templates
 374   my %convert_maps = (
 375     'latex' => {
 376                  'notes'         => sub { map "$_", @_ },
 377                  'footer'        => sub { map "$_", @_ },
 378                  'smallfooter'   => sub { map "$_", @_ },
 379                  'returnaddress' => sub { map "$_", @_ },
 380                  'coupon'        => sub { map "$_", @_ },
 381                  'summary'       => sub { map "$_", @_ },
 382                },
 383     'html'  => {
 384                  'notes' =>
 385                    sub {
 386                      map {
 387                        s/%%(.*)$/<!-- $1 -->/g;
 388                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 389                        s/\\begin\{enumerate\}/<ol>/g;
 390                        s/\\item /  <li>/g;
 391                        s/\\end\{enumerate\}/<\/ol>/g;
 392                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 393                        s/\\\\\*/<br>/g;
 394                        s/\\dollar ?/\$/g;
 395                        s/\\#/#/g;
 396                        s/~/&nbsp;/g;
 397                        $_;
 398                      }  @_
 399                    },
 400                  'footer' =>
 401                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 402                  'smallfooter' =>
 403                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 404                  'returnaddress' =>
 405                    sub {
 406                      map {
 407                        s/~/&nbsp;/g;
 408                        s/\\\\\*?\s*$/<BR>/;
 409                        s/\\hyphenation\{[\w\s\-]+}//;
 410                        s/\\([&])/$1/g;
 411                        $_;
 412                      }  @_
 413                    },
 414                  'coupon'        => sub { "" },
 415                  'summary'       => sub { "" },
 416                },
 417     'template' => {
 418                  'notes' =>
 419                    sub {
 420                      map {
 421                        s/%%.*$//g;
 422                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 423                        s/\\begin\{enumerate\}//g;
 424                        s/\\item /  * /g;
 425                        s/\\end\{enumerate\}//g;
 426                        s/\\textbf\{(.*)\}/$1/g;
 427                        s/\\\\\*/ /;
 428                        s/\\dollar ?/\$/g;
 429                        $_;
 430                      }  @_
 431                    },
 432                  'footer' =>
 433                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 434                  'smallfooter' =>
 435                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 436                  'returnaddress' =>
 437                    sub {
 438                      map {
 439                        s/~/ /g;
 440                        s/\\\\\*?\s*$/\n/;             # dubious
 441                        s/\\hyphenation\{[\w\s\-]+}//;
 442                        $_;
 443                      }  @_
 444                    },
 445                  'coupon'        => sub { "" },
 446                  'summary'       => sub { "" },
 447                },
 448   );
 449
 450
 451   # hashes for differing output formats
 452   my %nbsps = ( 'latex'    => '~',
 453                 'html'     => '',    # '&nbps;' would be nice
 454                 'template' => '',    # not used
 455               );
 456   my $nbsp = $nbsps{$format};
 457
 458   my %escape_functions = ( 'latex'    => \&_latex_escape,
 459                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 460                            'template' => sub { shift },
 461                          );
 462   my $escape_function = $escape_functions{$format};
 463   my $escape_function_nonbsp = ($format eq 'html')
 464                                  ? \&_html_escape : $escape_function;
 465
 466   my %newline_tokens = (  'latex'     => '\\\\',
 467                           'html'      => '<br>',
 468                           'template'  => "\n",
 469                         );
 470   my $newline_token = $newline_tokens{$format};
 471
 472   warn "$me generating template variables\n"
 473     if $DEBUG > 1;
 474
 475   # generate template variables
 476   my $returnaddress;
 477
 478   if (
 479          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 480                                         $template
 481                                       )
 482                 )
 483        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 484                                         $template
 485                                       )
 486                 )
 487   ) {
 488
 489     $returnaddress = join("\n",
 490       $conf->config_orbase("invoice_${format}returnaddress", $template)
 491     );
 492
 493   } elsif ( grep /\S/,
 494             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 495
 496     my $convert_map = $convert_maps{$format}{'returnaddress'};
 497     $returnaddress =
 498       join( "\n",
 499             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 500                                                  $template
 501                                                )
 502                          )
 503           );
 504   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 505
 506     my $convert_map = $convert_maps{$format}{'returnaddress'};
 507     $returnaddress = join( "\n", &$convert_map(
 508                                    map { s/( {2,})/'~' x length($1)/eg;
 509                                          s/$/\\\\\*/;
 510                                          $_
 511                                        }
 512                                      ( $conf->config('company_name', $cust_main->agentnum),
 513                                        $conf->config('company_address', $cust_main->agentnum),
 514                                      )
 515                                  )
 516                      );
 517
 518   } else {
 519
 520     my $warning = "Couldn't find a return address; ".
 521                   "do you need to set the company_address configuration value?";
 522     warn "$warning\n";
 523     $returnaddress = $nbsp;
 524     #$returnaddress = $warning;
 525
 526   }
 527
 528   warn "$me generating invoice data\n"
 529     if $DEBUG > 1;
 530
 531   my $agentnum = $cust_main->agentnum;
 532
 533   my %invoice_data = (
 534
 535     #invoice from info
 536     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 537     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 538     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 539     'returnaddress'   => $returnaddress,
 540     'agent'           => &$escape_function($cust_main->agent->agent),
 541
 542     #invoice/quotation info
 543     'no_number'       => $params{'no_number'},
 544     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 545     'quotationnum'    => $self->quotationnum,
 546     'no_date'         => $params{'no_date'},
 547     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 548       # workaround for inconsistent behavior in the early plain text
 549       # templates; see RT#28271
 550     'date'            => ( $params{'no_date'}
 551                              ? ''
 552                              : ($format eq 'template'
 553                                ? $self->_date
 554                                : $self->time2str_local('long', $self->_date, $format)
 555                                )
 556                          ),
 557     'today'           => $self->time2str_local('long', $today, $format),
 558     'terms'           => $self->terms,
 559     'template'        => $template, #params{'template'},
 560     'notice_name'     => $notice_name, # escape?
 561     'current_charges' => sprintf("%.2f", $self->charged),
 562     'duedate'         => $self->due_date2str('rdate'), #date_format?
 563
 564     #customer info
 565     'custnum'         => $cust_main->display_custnum,
 566     'prospectnum'     => $cust_main->prospectnum,
 567     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 568     ( map { $_ => &$escape_function($cust_main->$_()) } qw(
 569       payname company address1 address2 city state zip fax
 570     )),
 571
 572     #global config
 573     'ship_enable'     => $conf->exists('invoice-ship_address'),
 574     'unitprices'      => $conf->exists('invoice-unitprice'),
 575     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 576     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 577     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 578
 579     #layout info -- would be fancy to calc some of this and bury the template
 580     #               here in the code
 581     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 582     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 583     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 584     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 585     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 586     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 587     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 588     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 589     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 590     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 591
 592     # better hang on to conf_dir for a while (for old templates)
 593     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 594
 595     #these are only used when doing paged plaintext
 596     'page'            => 1,
 597     'total_pages'     => 1,
 598
 599   );
 600
 601   #localization
 602   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 603   # prototype here to silence warnings
 604   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 605
 606   my $min_sdate = 999999999999;
 607   my $max_edate = 0;
 608   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 609     next unless $cust_bill_pkg->pkgnum > 0;
 610     $min_sdate = $cust_bill_pkg->sdate
 611       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 612     $max_edate = $cust_bill_pkg->edate
 613       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 614   }
 615
 616   $invoice_data{'bill_period'} = '';
 617   $invoice_data{'bill_period'} =
 618       $self->time2str_local('%e %h', $min_sdate, $format)
 619       . " to " .
 620       $self->time2str_local('%e %h', $max_edate, $format)
 621     if ($max_edate != 0 && $min_sdate != 999999999999);
 622
 623   $invoice_data{finance_section} = '';
 624   if ( $conf->config('finance_pkgclass') ) {
 625     my $pkg_class =
 626       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 627     $invoice_data{finance_section} = $pkg_class->categoryname;
 628   }
 629   $invoice_data{finance_amount} = '0.00';
 630   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 631
 632   my $countrydefault = $conf->config('countrydefault') || 'US';
 633   foreach ( qw( address1 address2 city state zip country fax) ){
 634     my $method = 'ship_'.$_;
 635     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 636   }
 637   if ( length($cust_main->ship_company) ) {
 638     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 639   } else {
 640     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 641   }
 642   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 643   $invoice_data{'ship_country'} = ''
 644     if ( $invoice_data{'ship_country'} eq $countrydefault );
 645
 646   $invoice_data{'cid'} = $params{'cid'}
 647     if $params{'cid'};
 648
 649   if ( $cust_main->country eq $countrydefault ) {
 650     $invoice_data{'country'} = '';
 651   } else {
 652     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 653   }
 654
 655   my @address = ();
 656   $invoice_data{'address'} = \@address;
 657   push @address,
 658     $cust_main->payname.
 659       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 660         ? " (P.O. #". $cust_main->payinfo. ")"
 661         : ''
 662       )
 663   ;
 664   push @address, $cust_main->company
 665     if $cust_main->company;
 666   push @address, $cust_main->address1;
 667   push @address, $cust_main->address2
 668     if $cust_main->address2;
 669   push @address,
 670     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 671   push @address, $invoice_data{'country'}
 672     if $invoice_data{'country'};
 673   push @address, ''
 674     while (scalar(@address) < 5);
 675
 676   $invoice_data{'logo_file'} = $params{'logo_file'}
 677     if $params{'logo_file'};
 678   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 679     if $params{'barcode_file'};
 680   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 681     if $params{'barcode_img'};
 682   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 683     if $params{'barcode_cid'};
 684
 685   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 686 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 687   #my $balance_due = $self->owed + $pr_total - $cr_total;
 688   my $balance_due = $self->owed + $pr_total;
 689
 690   # the sum of amount owed on all invoices
 691   # (this is used in the summary & on the payment coupon)
 692   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 693
 694   # flag telling this invoice to have a first-page summary
 695   my $summarypage = '';
 696
 697   if ( $self->custnum && $self->invnum ) {
 698     # XXX should be an FS::cust_bill method to set the defaults, instead
 699     # of checking the type here
 700
 701     my $last_bill = $self->previous_bill;
 702     if ( $last_bill ) {
 703
 704       # "balance_date_range" unfortunately is unsuitable for this, since it
 705       # cares about application dates.  We want to know the sum of all
 706       # _top-level transactions_ dated before the last invoice.
 707       my @sql =
 708         map "$_ WHERE _date <= ? AND custnum = ?", (
 709           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 710           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 711           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 712           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 713         );
 714
 715       # the customer's current balance immediately after generating the last
 716       # bill
 717
 718       my $last_bill_balance = $last_bill->charged;
 719       foreach (@sql) {
 720         my $delta = FS::Record->scalar_sql(
 721           $_,
 722           $last_bill->_date - 1,
 723           $self->custnum,
 724         );
 725         $last_bill_balance += $delta;
 726       }
 727
 728       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 729
 730       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 731         $last_bill->invnum,
 732         $self->time2str_local('%D', $last_bill->_date),
 733         $last_bill_balance
 734       ) if $DEBUG > 0;
 735       # ("true_previous_balance" is a terrible name, but at least it's no
 736       # longer stored in the database)
 737       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 738
 739       # the change in balance from immediately after that invoice
 740       # to immediately before this one
 741       my $before_this_bill_balance = 0;
 742       foreach (@sql) {
 743         my $delta = FS::Record->scalar_sql(
 744           $_,
 745           $self->_date - 1,
 746           $self->custnum,
 747         );
 748         $before_this_bill_balance += $delta;
 749       }
 750       $invoice_data{'balance_adjustments'} =
 751         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 752
 753       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 754                    $invoice_data{'balance_adjustments'}
 755       ) if $DEBUG > 0;
 756
 757       # the sum of amount owed on all previous invoices
 758       # ($pr_total is used elsewhere but not as $previous_balance)
 759       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 760
 761       $invoice_data{'last_bill'} = {
 762         '_date'     => $last_bill->_date, #unformatted
 763       };
 764       my (@payments, @credits);
 765       # for formats that itemize previous payments
 766       foreach my $cust_pay ( qsearch('cust_pay', {
 767                               'custnum' => $self->custnum,
 768                               '_date'   => { op => '>=',
 769                                              value => $last_bill->_date }
 770                              } ) )
 771       {
 772         next if $cust_pay->_date > $self->_date;
 773         push @payments, {
 774             '_date'       => $cust_pay->_date,
 775             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 776             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 777             'amount'      => sprintf('%.2f', $cust_pay->paid),
 778         };
 779         # not concerned about applications
 780       }
 781       foreach my $cust_credit ( qsearch('cust_credit', {
 782                               'custnum' => $self->custnum,
 783                               '_date'   => { op => '>=',
 784                                              value => $last_bill->_date }
 785                              } ) )
 786       {
 787         next if $cust_credit->_date > $self->_date;
 788         push @credits, {
 789             '_date'       => $cust_credit->_date,
 790             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 791             'creditreason'=> $cust_credit->reason,
 792             'amount'      => sprintf('%.2f', $cust_credit->amount),
 793         };
 794       }
 795       $invoice_data{'previous_payments'} = \@payments;
 796       $invoice_data{'previous_credits'}  = \@credits;
 797     } else {
 798       # there is no $last_bill
 799       $invoice_data{'true_previous_balance'} =
 800       $invoice_data{'balance_adjustments'}   =
 801       $invoice_data{'previous_balance'}      = '0.00';
 802       $invoice_data{'previous_payments'} = [];
 803       $invoice_data{'previous_credits'} = [];
 804     }
 805
 806     # info from customer's last invoice before this one, for some
 807     # summary formats
 808     $invoice_data{'last_bill'} = {};
 809
 810     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 811       $invoice_data{'summarypage'} = $summarypage = 1;
 812     }
 813
 814   } # if this is an invoice
 815
 816   warn "$me substituting variables in notes, footer, smallfooter\n"
 817     if $DEBUG > 1;
 818
 819   my $tc = $self->template_conf;
 820   my @include = ( [ $tc,        'notes' ],
 821                   [ 'invoice_', 'footer' ],
 822                   [ 'invoice_', 'smallfooter', ],
 823                 );
 824   push @include, [ $tc,        'coupon', ]
 825     unless $params{'no_coupon'};
 826
 827   foreach my $i (@include) {
 828
 829     my($base, $include) = @$i;
 830
 831     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 832     my @inc_src;
 833
 834     if ( $conf->exists($inc_file, $agentnum)
 835          && length( $conf->config($inc_file, $agentnum) ) ) {
 836
 837       @inc_src = $conf->config($inc_file, $agentnum);
 838
 839     } else {
 840
 841       $inc_file = $conf->key_orbase("${base}latex$include", $template);
 842
 843       my $convert_map = $convert_maps{$format}{$include};
 844
 845       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
 846                        s/--\@\]/$delimiters{$format}[1]/g;
 847                        $_;
 848                      }
 849                  &$convert_map( $conf->config($inc_file, $agentnum) );
 850
 851     }
 852
 853     my $inc_tt = new Text::Template (
 854       TYPE       => 'ARRAY',
 855       SOURCE     => [ map "$_\n", @inc_src ],
 856       DELIMITERS => $delimiters{$format},
 857     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 858
 859     unless ( $inc_tt->compile() ) {
 860       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 861       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 862       die $error;
 863     }
 864
 865     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 866
 867     $invoice_data{$include} =~ s/\n+$//
 868       if ($format eq 'latex');
 869   }
 870
 871   # let invoices use either of these as needed
 872   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 873     ? $cust_main->payinfo : '';
 874   $invoice_data{'po_line'} =
 875     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 876       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 877       : $nbsp;
 878
 879   my %money_chars = ( 'latex'    => '',
 880                       'html'     => $conf->config('money_char') || '$',
 881                       'template' => '',
 882                     );
 883   my $money_char = $money_chars{$format};
 884
 885   # extremely dubious
 886   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 887                             'html'     => $conf->config('money_char') || '$',
 888                             'template' => '',
 889                           );
 890   my $other_money_char = $other_money_chars{$format};
 891   $invoice_data{'dollar'} = $other_money_char;
 892
 893   my %minus_signs = ( 'latex'    => '$-$',
 894                       'html'     => '&minus;',
 895                       'template' => '- ' );
 896   my $minus = $minus_signs{$format};
 897
 898   my @detail_items = ();
 899   my @total_items = ();
 900   my @buf = ();
 901   my @sections = ();
 902
 903   $invoice_data{'detail_items'} = \@detail_items;
 904   $invoice_data{'total_items'} = \@total_items;
 905   $invoice_data{'buf'} = \@buf;
 906   $invoice_data{'sections'} = \@sections;
 907
 908   warn "$me generating sections\n"
 909     if $DEBUG > 1;
 910
 911   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 912   my $multisection = $conf->exists($tc.'sections', $cust_main->agentnum) ||
 913                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 914   $invoice_data{'multisection'} = $multisection;
 915   my $late_sections;
 916   my $extra_sections = [];
 917   my $extra_lines = ();
 918
 919   # default section ('Charges')
 920   my $default_section = { 'description' => '',
 921                           'subtotal'    => '',
 922                           'no_subtotal' => 1,
 923                         };
 924
 925   # Previous Charges section
 926   # subtotal is the first return value from $self->previous
 927   my $previous_section;
 928   # if the invoice has major sections, or if we're summarizing previous
 929   # charges with a single line, or if we've been specifically told to put them
 930   # in a section, create a section for previous charges:
 931   if ( $multisection or
 932        $conf->exists('previous_balance-summary_only') or
 933        $conf->exists('previous_balance-section') ) {
 934
 935     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 936                            'subtotal'    => $other_money_char.
 937                                             sprintf('%.2f', $pr_total),
 938                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 939                          };
 940     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 941       join(' / ', map { $cust_main->balance_date_range(@$_) }
 942                   $self->_prior_month30s
 943           )
 944       if $conf->exists('invoice_include_aging');
 945
 946   } else {
 947     # otherwise put them in the main section
 948     $previous_section = $default_section;
 949   }
 950
 951   my $adjust_section = {
 952     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 953     'adjust_section' => 1,
 954     'subtotal'       => 0,   # adjusted below
 955   };
 956   my $adjust_weight = _pkg_category($adjust_section->{description})
 957                         ? _pkg_category($adjust_section->{description})->weight
 958                         : 0;
 959   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 960   # Note: 'sort_weight' here is actually a flag telling whether there is an
 961   # explicit package category for the adjust section. If so, certain behavior
 962   # happens.
 963   $adjust_section->{'sort_weight'} = $adjust_weight;
 964
 965
 966   if ( $multisection ) {
 967     ($extra_sections, $extra_lines) =
 968       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 969       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 970       && $self->can('_items_extra_usage_sections');
 971
 972     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 973
 974     push @detail_items, @$extra_lines if $extra_lines;
 975
 976     # the code is written so that both methods can be used together, but
 977     # we haven't yet changed the template to take advantage of that, so for
 978     # now, treat them as mutually exclusive.
 979     my %section_method = ( by_category => 1 );
 980     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 981       %section_method = ( by_location => 1 );
 982     }
 983     my ($early, $late) =
 984       $self->_items_sections( 'summary' => $summarypage,
 985                               'escape'  => $escape_function_nonbsp,
 986                               'extra_sections' => $extra_sections,
 987                               'format'  => $format,
 988                               %section_method
 989                             );
 990     push @sections, @$early;
 991     $late_sections = $late;
 992
 993     if (    $conf->exists('svc_phone_sections')
 994          && $self->can('_items_svc_phone_sections')
 995        )
 996     {
 997       my ($phone_sections, $phone_lines) =
 998         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
 999       push @{$late_sections}, @$phone_sections;
1000       push @detail_items, @$phone_lines;
1001     }
1002     if ( $conf->exists('voip-cust_accountcode_cdr')
1003          && $cust_main->accountcode_cdr
1004          && $self->can('_items_accountcode_cdr')
1005        )
1006     {
1007       my ($accountcode_section, $accountcode_lines) =
1008         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1009       if ( scalar(@$accountcode_lines) ) {
1010           push @{$late_sections}, $accountcode_section;
1011           push @detail_items, @$accountcode_lines;
1012       }
1013     }
1014   } else {# not multisection
1015     # make a default section
1016     push @sections, $default_section;
1017     # and calculate the finance charge total, since it won't get done otherwise.
1018     # and the default section total
1019     # XXX possibly finance_pkgclass should not be used in this manner?
1020     my @finance_charges;
1021     my @charges;
1022     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1023       if ( $invoice_data{finance_section} and
1024         grep { $_->section eq $invoice_data{finance_section} }
1025            $cust_bill_pkg->cust_bill_pkg_display ) {
1026         # I think these are always setup fees, but just to be sure...
1027         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1028       } else {
1029         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1030       }
1031     }
1032     $invoice_data{finance_amount} =
1033       sprintf('%.2f', sum( @finance_charges ) || 0);
1034     $default_section->{subtotal} = $other_money_char.
1035                                     sprintf('%.2f', sum( @charges ) || 0);
1036   }
1037
1038   # start setting up summary subtotals
1039   my @summary_subtotals;
1040   my $method = $conf->config('summary_subtotals_method');
1041   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1042     # then re-section them by the correct method
1043     my %section_method = ( by_category => 1 );
1044     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1045       %section_method = ( by_location => 1 );
1046     }
1047     my ($early, $late) =
1048       $self->_items_sections( 'summary' => $summarypage,
1049                               'escape'  => $escape_function_nonbsp,
1050                               'extra_sections' => $extra_sections,
1051                               'format'  => $format,
1052                               %section_method
1053                             );
1054     foreach ( @$early ) {
1055       next if $_->{subtotal} == 0;
1056       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1057       push @summary_subtotals, $_;
1058     }
1059   } else {
1060     # subtotal sectioning is the same as for the actual invoice sections
1061     @summary_subtotals = @sections;
1062   }
1063
1064   # Hereafter, push sections to both @sections and @summary_subtotals
1065   # if they belong in both places (e.g. tax section).  Late sections are
1066   # never in @summary_subtotals.
1067
1068   # previous invoice balances in the Previous Charges section if there
1069   # is one, otherwise in the main detail section
1070   # (except if summary_only is enabled, don't show them at all)
1071   if ( $self->can('_items_previous') &&
1072        $self->enable_previous &&
1073        ! $conf->exists('previous_balance-summary_only') ) {
1074
1075     warn "$me adding previous balances\n"
1076       if $DEBUG > 1;
1077
1078     foreach my $line_item ( $self->_items_previous ) {
1079
1080       my $detail = {
1081         ref             => $line_item->{'pkgnum'},
1082         pkgpart         => $line_item->{'pkgpart'},
1083         #quantity        => 1, # not really correct
1084         section         => $previous_section, # which might be $default_section
1085         description     => &$escape_function($line_item->{'description'}),
1086         ext_description => [ map { &$escape_function($_) }
1087                              @{ $line_item->{'ext_description'} || [] }
1088                            ],
1089         amount          => $money_char . $line_item->{'amount'},
1090         product_code    => $line_item->{'pkgpart'} || 'N/A',
1091       };
1092
1093       push @detail_items, $detail;
1094       push @buf, [ $detail->{'description'},
1095                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1096                  ];
1097     }
1098
1099   }
1100
1101   if ( @pr_cust_bill && $self->enable_previous ) {
1102     push @buf, ['','-----------'];
1103     push @buf, [ $self->mt('Total Previous Balance'),
1104                  $money_char. sprintf("%10.2f", $pr_total) ];
1105     push @buf, ['',''];
1106   }
1107
1108   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1109       warn "$me adding DID summary\n"
1110         if $DEBUG > 1;
1111
1112       my ($didsummary,$minutes) = $self->_did_summary;
1113       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1114       push @detail_items,
1115        { 'description' => $didsummary_desc,
1116            'ext_description' => [ $didsummary, $minutes ],
1117        };
1118   }
1119
1120   foreach my $section (@sections, @$late_sections) {
1121
1122     # begin some normalization
1123     $section->{'subtotal'} = $section->{'amount'}
1124       if $multisection
1125          && !exists($section->{subtotal})
1126          && exists($section->{amount});
1127
1128     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1129       if ( $invoice_data{finance_section} &&
1130            $section->{'description'} eq $invoice_data{finance_section} );
1131
1132     $section->{'subtotal'} = $other_money_char.
1133                              sprintf('%.2f', $section->{'subtotal'})
1134       if $multisection;
1135
1136     # continue some normalization
1137     $section->{'amount'}   = $section->{'subtotal'}
1138       if $multisection;
1139
1140
1141     if ( $section->{'description'} ) {
1142       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1143                    [ '', '' ],
1144                  );
1145     }
1146
1147     warn "$me   setting options\n"
1148       if $DEBUG > 1;
1149
1150     my %options = ();
1151     $options{'section'} = $section if $multisection;
1152     $options{'format'} = $format;
1153     $options{'escape_function'} = $escape_function;
1154     $options{'no_usage'} = 1 unless $unsquelched;
1155     $options{'unsquelched'} = $unsquelched;
1156     $options{'summary_page'} = $summarypage;
1157     $options{'skip_usage'} =
1158       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1159     $options{'preref_callback'} = $params{'preref_callback'};
1160
1161     warn "$me   searching for line items\n"
1162       if $DEBUG > 1;
1163
1164     foreach my $line_item ( $self->_items_pkg(%options),
1165                             $self->_items_fee(%options) ) {
1166
1167       warn "$me     adding line item ".
1168            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1169         if $DEBUG > 1;
1170
1171       push @buf, ( [ $line_item->{'description'},
1172                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1173                    ],
1174                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1175                  );
1176
1177       $line_item->{'ref'} = $line_item->{'pkgnum'};
1178       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1179       $line_item->{'section'} = $section;
1180       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1181       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1182
1183       if ( length($line_item->{'unit_amount'}) ) {
1184         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1185       }
1186       $line_item->{'ext_description'} ||= [];
1187
1188       push @detail_items, $line_item;
1189     }
1190
1191     if ( $section->{'description'} ) {
1192       push @buf, ( ['','-----------'],
1193                    [ $section->{'description'}. ' sub-total',
1194                       $section->{'subtotal'} # already formatted this
1195                    ],
1196                    [ '', '' ],
1197                    [ '', '' ],
1198                  );
1199     }
1200
1201   }
1202
1203   $invoice_data{current_less_finance} =
1204     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1205
1206   # if there's anything in the Previous Charges section, prepend it to the list
1207   if ( $pr_total and $previous_section ne $default_section ) {
1208     unshift @sections, $previous_section;
1209     # but not @summary_subtotals
1210   }
1211
1212   warn "$me adding taxes\n"
1213     if $DEBUG > 1;
1214
1215   # create a tax section if we don't yet have one
1216   my $tax_description = 'Taxes, Surcharges, and Fees';
1217   my $tax_section =
1218     List::Util::first { $_->{description} eq $tax_description } @sections;
1219   if (!$tax_section) {
1220     $tax_section = { 'description' => $tax_description };
1221     push @sections, $tax_section if $multisection;
1222   }
1223   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1224   # if this is an existing tax section, we're merging the tax items into it.
1225   # grab the taxtotal that's already there, strip the money symbol if any
1226   my $taxtotal = $tax_section->{'subtotal'} || 0;
1227   $taxtotal =~ s/^\Q$other_money_char\E//;
1228
1229   # this does nothing
1230   #my $tax_weight = _pkg_category($tax_section->{description})
1231   #                      ? _pkg_category($tax_section->{description})->weight
1232   #                      : 0;
1233   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1234   #$tax_section->{'sort_weight'} = $tax_weight;
1235
1236   my @items_tax = $self->_items_tax;
1237   foreach my $tax ( @items_tax ) {
1238
1239     $taxtotal += $tax->{'amount'};
1240
1241     my $description = &$escape_function( $tax->{'description'} );
1242     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1243
1244     if ( $multisection ) {
1245
1246       push @detail_items, {
1247         ext_description => [],
1248         ref          => '',
1249         quantity     => '',
1250         description  => $description,
1251         amount       => $money_char. $amount,
1252         product_code => '',
1253         section      => $tax_section,
1254       };
1255
1256     } else {
1257
1258       push @total_items, {
1259         'total_item'   => $description,
1260         'total_amount' => $other_money_char. $amount,
1261       };
1262
1263     }
1264
1265     push @buf,[ $description,
1266                 $money_char. $amount,
1267               ];
1268
1269   }
1270
1271   if ( @items_tax ) {
1272     my $total = {};
1273     $total->{'total_item'} = $self->mt('Sub-total');
1274     $total->{'total_amount'} =
1275       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1276
1277     if ( $multisection ) {
1278       if ( $taxtotal > 0 ) {
1279         $tax_section->{'subtotal'} = $other_money_char.
1280                                      sprintf('%.2f', $taxtotal);
1281         $tax_section->{'pretotal'} = 'New charges sub-total '.
1282                                      $total->{'total_amount'};
1283         $tax_section->{'description'} = $self->mt($tax_description);
1284
1285         # append it if it's not already there
1286         if ( !grep $tax_section, @sections ) {
1287           push @sections, $tax_section;
1288           push @summary_subtotals, $tax_section;
1289         }
1290       }
1291
1292     } else {
1293       unshift @total_items, $total;
1294     }
1295   }
1296   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1297
1298   push @buf,['','-----------'];
1299   push @buf,[$self->mt(
1300               (!$self->enable_previous)
1301                ? 'Total Charges'
1302                : 'Total New Charges'
1303              ),
1304              $money_char. sprintf("%10.2f",$self->charged) ];
1305   push @buf,['',''];
1306
1307   ###
1308   # Totals
1309   ###
1310
1311   my %embolden_functions = (
1312     'latex'    => sub { return '\textbf{'. shift(). '}' },
1313     'html'     => sub { return '<b>'. shift(). '</b>' },
1314     'template' => sub { shift },
1315   );
1316   my $embolden_function = $embolden_functions{$format};
1317
1318   if ( $self->can('_items_total') ) { # quotations
1319
1320     $self->_items_total(\@total_items);
1321
1322     foreach ( @total_items ) {
1323       $_->{'total_item'}   = &$embolden_function( $_->{'total_item'} );
1324       $_->{'total_amount'} = &$embolden_function( $other_money_char.
1325                                                    $_->{'total_amount'}
1326                                                 );
1327     }
1328
1329   } else { #normal invoice case
1330
1331     # calculate total, possibly including total owed on previous
1332     # invoices
1333     my $total = {};
1334     my $item = 'Total';
1335     $item = $conf->config('previous_balance-exclude_from_total')
1336          || 'Total New Charges'
1337       if $conf->exists('previous_balance-exclude_from_total');
1338     my $amount = $self->charged;
1339     if ( $self->enable_previous and !$conf->exists('previous_balance-exclude_from_total') ) {
1340       $amount += $pr_total;
1341     }
1342
1343     $total->{'total_item'} = &$embolden_function($self->mt($item));
1344     $total->{'total_amount'} =
1345       &$embolden_function( $other_money_char.  sprintf( '%.2f', $amount ) );
1346     if ( $multisection ) {
1347       if ( $adjust_section->{'sort_weight'} ) {
1348         $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1349           $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1350       } else {
1351         $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1352           $other_money_char.  sprintf('%.2f', $self->charged );
1353       }
1354     } else {
1355       push @total_items, $total;
1356     }
1357     push @buf,['','-----------'];
1358     push @buf,[$item,
1359                $money_char.
1360                sprintf( '%10.2f', $amount )
1361               ];
1362     push @buf,['',''];
1363
1364     # if we're showing previous invoices, also show previous
1365     # credits and payments
1366     if ( $self->enable_previous
1367           and $self->can('_items_credits')
1368           and $self->can('_items_payments') )
1369       {
1370       #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
1371
1372       # credits
1373       my $credittotal = 0;
1374       foreach my $credit (
1375         $self->_items_credits( 'template' => $template, 'trim_len' => 60 )
1376       ) {
1377
1378         my $total;
1379         $total->{'total_item'} = &$escape_function($credit->{'description'});
1380         $credittotal += $credit->{'amount'};
1381         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1382         if ( $multisection ) {
1383           push @detail_items, {
1384             ext_description => [],
1385             ref          => '',
1386             quantity     => '',
1387             description  => &$escape_function($credit->{'description'}),
1388             amount       => $money_char . $credit->{'amount'},
1389             product_code => '',
1390             section      => $adjust_section,
1391           };
1392         } else {
1393           push @total_items, $total;
1394         }
1395
1396       }
1397       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1398
1399       #credits (again)
1400       foreach my $credit (
1401         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1402       ) {
1403         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1404       }
1405
1406       # payments
1407       my $paymenttotal = 0;
1408       foreach my $payment (
1409         $self->_items_payments( 'template' => $template )
1410       ) {
1411         my $total = {};
1412         $total->{'total_item'} = &$escape_function($payment->{'description'});
1413         $paymenttotal += $payment->{'amount'};
1414         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1415         if ( $multisection ) {
1416           push @detail_items, {
1417             ext_description => [],
1418             ref          => '',
1419             quantity     => '',
1420             description  => &$escape_function($payment->{'description'}),
1421             amount       => $money_char . $payment->{'amount'},
1422             product_code => '',
1423             section      => $adjust_section,
1424           };
1425         }else{
1426           push @total_items, $total;
1427         }
1428         push @buf, [ $payment->{'description'},
1429                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1430                    ];
1431       }
1432       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1433
1434       if ( $multisection ) {
1435         $adjust_section->{'subtotal'} = $other_money_char.
1436                                         sprintf('%.2f', $credittotal + $paymenttotal);
1437
1438         #why this? because {sort_weight} forces the adjust_section to appear
1439         #in @extra_sections instead of @sections. obviously.
1440         push @sections, $adjust_section
1441           unless $adjust_section->{sort_weight};
1442         # do not summarize; adjustments there are shown according to
1443         # different rules
1444       }
1445
1446       # create Balance Due message
1447       {
1448         my $total;
1449         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1450         $total->{'total_amount'} =
1451           &$embolden_function(
1452             $other_money_char. sprintf('%.2f', #why? $summarypage
1453                                                #  ? $self->charged +
1454                                                #    $self->billing_balance
1455                                                #  :
1456                                                    $self->owed + $pr_total
1457                                       )
1458           );
1459         if ( $multisection && !$adjust_section->{sort_weight} ) {
1460           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1461                                            $total->{'total_amount'};
1462         }else{
1463           push @total_items, $total;
1464         }
1465         push @buf,['','-----------'];
1466         push @buf,[$self->balance_due_msg, $money_char.
1467           sprintf("%10.2f", $balance_due ) ];
1468       }
1469
1470       if ( $conf->exists('previous_balance-show_credit')
1471           and $cust_main->balance < 0 ) {
1472         my $credit_total = {
1473           'total_item'    => &$embolden_function($self->credit_balance_msg),
1474           'total_amount'  => &$embolden_function(
1475             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1476           ),
1477         };
1478         if ( $multisection ) {
1479           $adjust_section->{'posttotal'} .= $newline_token .
1480             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1481         }
1482         else {
1483           push @total_items, $credit_total;
1484         }
1485         push @buf,['','-----------'];
1486         push @buf,[$self->credit_balance_msg, $money_char.
1487           sprintf("%10.2f", -$cust_main->balance ) ];
1488       }
1489     }
1490
1491   } #end of default total adding ! can('_items_total')
1492
1493   if ( $multisection ) {
1494     if (    $conf->exists('svc_phone_sections')
1495          && $self->can('_items_svc_phone_sections')
1496        )
1497     {
1498       my $total;
1499       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1500       $total->{'total_amount'} =
1501         &$embolden_function(
1502           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1503         );
1504       my $last_section = pop @sections;
1505       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1506                                      $total->{'total_amount'};
1507       push @sections, $last_section;
1508     }
1509     push @sections, @$late_sections
1510       if $unsquelched;
1511   }
1512
1513   # make a discounts-available section, even without multisection
1514   if ( $conf->exists('discount-show_available')
1515        and my @discounts_avail = $self->_items_discounts_avail ) {
1516     my $discount_section = {
1517       'description' => $self->mt('Discounts Available'),
1518       'subtotal'    => '',
1519       'no_subtotal' => 1,
1520     };
1521
1522     push @sections, $discount_section; # do not summarize
1523     push @detail_items, map { +{
1524         'ref'         => '', #should this be something else?
1525         'section'     => $discount_section,
1526         'description' => &$escape_function( $_->{description} ),
1527         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1528         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1529     } } @discounts_avail;
1530   }
1531
1532   # not adding any more sections after this
1533   $invoice_data{summary_subtotals} = \@summary_subtotals;
1534
1535   # usage subtotals
1536   if ( $conf->exists('usage_class_summary')
1537        and $self->can('_items_usage_class_summary') ) {
1538     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1539     if ( @usage_subtotals ) {
1540       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1541       unshift @detail_items, @usage_subtotals;
1542     }
1543   }
1544
1545   # invoice history "section" (not really a section)
1546   # not to be included in any subtotals, completely independent of
1547   # everything...
1548   if ( $conf->exists('previous_invoice_history') ) {
1549     my %history;
1550     my %monthorder;
1551     foreach my $cust_bill ( $cust_main->cust_bill ) {
1552       # XXX hardcoded format, and currently only 'charged'; add other fields
1553       # if they become necessary
1554       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1555       $history{$date} ||= 0;
1556       $history{$date} += $cust_bill->charged;
1557       # just so we have a numeric sort key
1558       $monthorder{$date} ||= $cust_bill->_date;
1559     }
1560     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1561                         keys %history;
1562     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1563     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1564   }
1565
1566   # service locations: another option for template customization
1567   my %location_info;
1568   foreach my $item (@detail_items) {
1569     if ( $item->{locationnum} ) {
1570       $location_info{ $item->{locationnum} } ||= {
1571         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1572       };
1573     }
1574   }
1575   $invoice_data{location_info} = \%location_info;
1576
1577   # debugging hook: call this with 'diag' => 1 to just get a hash of
1578   # the invoice variables
1579   return \%invoice_data if ( $params{'diag'} );
1580
1581   # All sections and items are built; now fill in templates.
1582   my @includelist = ();
1583   push @includelist, 'summary' if $summarypage;
1584   foreach my $include ( @includelist ) {
1585
1586     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1587     my @inc_src;
1588
1589     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1590
1591       @inc_src = $conf->config($inc_file, $agentnum);
1592
1593     } else {
1594
1595       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1596
1597       my $convert_map = $convert_maps{$format}{$include};
1598
1599       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1600                        s/--\@\]/$delimiters{$format}[1]/g;
1601                        $_;
1602                      }
1603                  &$convert_map( $conf->config($inc_file, $agentnum) );
1604
1605     }
1606
1607     my $inc_tt = new Text::Template (
1608       TYPE       => 'ARRAY',
1609       SOURCE     => [ map "$_\n", @inc_src ],
1610       DELIMITERS => $delimiters{$format},
1611     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1612
1613     unless ( $inc_tt->compile() ) {
1614       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1615       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1616       die $error;
1617     }
1618
1619     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1620
1621     $invoice_data{$include} =~ s/\n+$//
1622       if ($format eq 'latex');
1623   }
1624
1625   $invoice_lines = 0;
1626   my $wasfunc = 0;
1627   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1628     /invoice_lines\((\d*)\)/;
1629     $invoice_lines += $1 || scalar(@buf);
1630     $wasfunc=1;
1631   }
1632   die "no invoice_lines() functions in template?"
1633     if ( $format eq 'template' && !$wasfunc );
1634
1635   if ($format eq 'template') {
1636
1637     if ( $invoice_lines ) {
1638       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1639       $invoice_data{'total_pages'}++
1640         if scalar(@buf) % $invoice_lines;
1641     }
1642
1643     #setup subroutine for the template
1644     $invoice_data{invoice_lines} = sub {
1645       my $lines = shift || scalar(@buf);
1646       map {
1647         scalar(@buf)
1648           ? shift @buf
1649           : [ '', '' ];
1650       }
1651       ( 1 .. $lines );
1652     };
1653
1654     my $lines;
1655     my @collect;
1656     while (@buf) {
1657       push @collect, split("\n",
1658         $text_template->fill_in( HASH => \%invoice_data )
1659       );
1660       $invoice_data{'page'}++;
1661     }
1662     map "$_\n", @collect;
1663
1664   } else { # this is where we actually create the invoice
1665
1666     warn "filling in template for invoice ". $self->invnum. "\n"
1667       if $DEBUG;
1668     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1669       if $DEBUG > 1;
1670
1671     $text_template->fill_in(HASH => \%invoice_data);
1672   }
1673 }
1674
1675 sub notice_name { '('.shift->table.')'; }
1676
1677 sub template_conf { 'invoice_'; }
1678
1679 # helper routine for generating date ranges
1680 sub _prior_month30s {
1681   my $self = shift;
1682   my @ranges = (
1683    [ 1,       2592000 ], # 0-30 days ago
1684    [ 2592000, 5184000 ], # 30-60 days ago
1685    [ 5184000, 7776000 ], # 60-90 days ago
1686    [ 7776000, 0       ], # 90+   days ago
1687   );
1688
1689   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1690           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1691       ] }
1692   @ranges;
1693 }
1694
1695 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1696
1697 Returns an postscript invoice, as a scalar.
1698
1699 Options can be passed as a hashref (recommended) or as a list of time, template
1700 and then any key/value pairs for any other options.
1701
1702 I<time> an optional value used to control the printing of overdue messages.  The
1703 default is now.  It isn't the date of the invoice; that's the `_date' field.
1704 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1705 L<Time::Local> and L<Date::Parse> for conversion functions.
1706
1707 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1708
1709 =cut
1710
1711 sub print_ps {
1712   my $self = shift;
1713
1714   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1715   my $ps = generate_ps($file);
1716   unlink($logofile);
1717   unlink($barcodefile) if $barcodefile;
1718
1719   $ps;
1720 }
1721
1722 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1723
1724 Returns an PDF invoice, as a scalar.
1725
1726 Options can be passed as a hashref (recommended) or as a list of time, template
1727 and then any key/value pairs for any other options.
1728
1729 I<time> an optional value used to control the printing of overdue messages.  The
1730 default is now.  It isn't the date of the invoice; that's the `_date' field.
1731 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1732 L<Time::Local> and L<Date::Parse> for conversion functions.
1733
1734 I<template>, if specified, is the name of a suffix for alternate invoices.
1735
1736 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1737
1738 =cut
1739
1740 sub print_pdf {
1741   my $self = shift;
1742
1743   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1744   my $pdf = generate_pdf($file);
1745   unlink($logofile);
1746   unlink($barcodefile) if $barcodefile;
1747
1748   $pdf;
1749 }
1750
1751 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1752
1753 Returns an HTML invoice, as a scalar.
1754
1755 I<time> an optional value used to control the printing of overdue messages.  The
1756 default is now.  It isn't the date of the invoice; that's the `_date' field.
1757 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1758 L<Time::Local> and L<Date::Parse> for conversion functions.
1759
1760 I<template>, if specified, is the name of a suffix for alternate invoices.
1761
1762 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1763
1764 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1765 when emailing the invoice as part of a multipart/related MIME email.
1766
1767 =cut
1768
1769 sub print_html {
1770   my $self = shift;
1771   my %params;
1772   if ( ref($_[0]) ) {
1773     %params = %{ shift() };
1774   } else {
1775     %params = @_;
1776   }
1777   $params{'format'} = 'html';
1778
1779   $self->print_generic( %params );
1780 }
1781
1782 # quick subroutine for print_latex
1783 #
1784 # There are ten characters that LaTeX treats as special characters, which
1785 # means that they do not simply typeset themselves:
1786 #      # $ % & ~ _ ^ \ { }
1787 #
1788 # TeX ignores blanks following an escaped character; if you want a blank (as
1789 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1790
1791 sub _latex_escape {
1792   my $value = shift;
1793   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1794   $value =~ s/([<>])/\$$1\$/g;
1795   $value;
1796 }
1797
1798 sub _html_escape {
1799   my $value = shift;
1800   encode_entities($value);
1801   $value;
1802 }
1803
1804 sub _html_escape_nbsp {
1805   my $value = _html_escape(shift);
1806   $value =~ s/ +/&nbsp;/g;
1807   $value;
1808 }
1809
1810 #utility methods for print_*
1811
1812 sub _translate_old_latex_format {
1813   warn "_translate_old_latex_format called\n"
1814     if $DEBUG;
1815
1816   my @template = ();
1817   while ( @_ ) {
1818     my $line = shift;
1819
1820     if ( $line =~ /^%%Detail\s*$/ ) {
1821
1822       push @template, q![@--!,
1823                       q!  foreach my $_tr_line (@detail_items) {!,
1824                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1825                       q!      $_tr_line->{'description'} .= !,
1826                       q!        "\\tabularnewline\n~~".!,
1827                       q!        join( "\\tabularnewline\n~~",!,
1828                       q!          @{$_tr_line->{'ext_description'}}!,
1829                       q!        );!,
1830                       q!    }!;
1831
1832       while ( ( my $line_item_line = shift )
1833               !~ /^%%EndDetail\s*$/                            ) {
1834         $line_item_line =~ s/'/\\'/g;    # nice LTS
1835         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1836         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1837         push @template, "    \$OUT .= '$line_item_line';";
1838       }
1839
1840       push @template, '}',
1841                       '--@]';
1842       #' doh, gvim
1843     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1844
1845       push @template, '[@--',
1846                       '  foreach my $_tr_line (@total_items) {';
1847
1848       while ( ( my $total_item_line = shift )
1849               !~ /^%%EndTotalDetails\s*$/                      ) {
1850         $total_item_line =~ s/'/\\'/g;    # nice LTS
1851         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1852         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1853         push @template, "    \$OUT .= '$total_item_line';";
1854       }
1855
1856       push @template, '}',
1857                       '--@]';
1858
1859     } else {
1860       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1861       push @template, $line;
1862     }
1863
1864   }
1865
1866   if ($DEBUG) {
1867     warn "$_\n" foreach @template;
1868   }
1869
1870   (@template);
1871 }
1872
1873 =item terms
1874
1875 =cut
1876
1877 sub terms {
1878   my $self = shift;
1879   my $conf = $self->conf;
1880
1881   #check for an invoice-specific override
1882   return $self->invoice_terms if $self->invoice_terms;
1883
1884   #check for a customer- specific override
1885   my $cust_main = $self->cust_main;
1886   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1887
1888   my $agentnum = '';
1889   if ( $cust_main ) {
1890     $agentnum = $cust_main->agentnum;
1891   } elsif ( my $prospect_main = $self->prospect_main ) {
1892     $agentnum = $prospect_main->agentnum;
1893   }
1894
1895   #use configured default
1896   $conf->config('invoice_default_terms', $agentnum) || '';
1897 }
1898
1899 =item due_date
1900
1901 =cut
1902
1903 sub due_date {
1904   my $self = shift;
1905   my $duedate = '';
1906   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1907     $duedate = $self->_date() + ( $1 * 86400 );
1908   }
1909   $duedate;
1910 }
1911
1912 =item due_date2str
1913
1914 =cut
1915
1916 sub due_date2str {
1917   my $self = shift;
1918   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1919 }
1920
1921 =item balance_due_msg
1922
1923 =cut
1924
1925 sub balance_due_msg {
1926   my $self = shift;
1927   my $msg = $self->mt('Balance Due');
1928   return $msg unless $self->terms;
1929   if ( $self->due_date ) {
1930     $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1931       $self->due_date2str('short');
1932   } elsif ( $self->terms ) {
1933     $msg .= ' - '. $self->terms;
1934   }
1935   $msg;
1936 }
1937
1938 =item balance_due_date
1939
1940 =cut
1941
1942 sub balance_due_date {
1943   my $self = shift;
1944   my $conf = $self->conf;
1945   my $duedate = '';
1946   my $terms = $self->terms;
1947   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1948     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1949   }
1950   $duedate;
1951 }
1952
1953 sub credit_balance_msg {
1954   my $self = shift;
1955   $self->mt('Credit Balance Remaining')
1956 }
1957
1958 =item _date_pretty
1959
1960 Returns a string with the date, for example: "3/20/2008", localized for the
1961 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1962
1963 =cut
1964
1965 sub _date_pretty {
1966   my $self = shift;
1967   $self->time2str_local('short', $self->_date);
1968 }
1969
1970 =item _date_pretty_unlocalized
1971
1972 Returns a string with the date, for example: "3/20/2008", in the format
1973 configured for the back-office.  Use _date_pretty for end-customer display use.
1974
1975 =cut
1976
1977 sub _date_pretty_unlocalized {
1978   my $self = shift;
1979   time2str($date_format, $self->_date);
1980 }
1981
1982 =item email HASHREF
1983
1984 Emails this template.
1985
1986 Options are passed as a hashref.  Available options:
1987
1988 =over 4
1989
1990 =item from
1991
1992 If specified, overrides the default From: address.
1993
1994 =item notice_name
1995
1996 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1997
1998 =item template
1999
2000 (Deprecated) If specified, is the name of a suffix for alternate template files.
2001
2002 =back
2003
2004 Options accepted by generate_email can also be used.
2005
2006 =cut
2007
2008 sub email {
2009   my $self = shift;
2010   my $opt = shift || {};
2011   if ($opt and !ref($opt)) {
2012     die ref($self). '->email called with positional parameters';
2013   }
2014
2015   return if $self->hide;
2016
2017   my $error = send_email(
2018     $self->generate_email(
2019       'subject'     => $self->email_subject($opt->{template}),
2020       %$opt, # template, etc.
2021     )
2022   );
2023
2024   die "can't email: $error\n" if $error;
2025 }
2026
2027 =item generate_email OPTION => VALUE ...
2028
2029 Options:
2030
2031 =over 4
2032
2033 =item from
2034
2035 sender address, required
2036
2037 =item template
2038
2039 alternate template name, optional
2040
2041 =item subject
2042
2043 email subject, optional
2044
2045 =item notice_name
2046
2047 notice name instead of "Invoice", optional
2048
2049 =back
2050
2051 Returns an argument list to be passed to L<FS::Misc::send_email>.
2052
2053 =cut
2054
2055 use MIME::Entity;
2056
2057 sub generate_email {
2058
2059   my $self = shift;
2060   my %args = @_;
2061   my $conf = $self->conf;
2062
2063   my $me = '[FS::Template_Mixin::generate_email]';
2064
2065   my %return = (
2066     'from'      => $args{'from'},
2067     'subject'   => ($args{'subject'} || $self->email_subject),
2068     'custnum'   => $self->custnum,
2069     'msgtype'   => 'invoice',
2070   );
2071
2072   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2073
2074   my $cust_main = $self->cust_main;
2075
2076   if (ref($args{'to'}) eq 'ARRAY') {
2077     $return{'to'} = $args{'to'};
2078   } elsif ( $cust_main ) {
2079     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2080   }
2081
2082   my $tc = $self->template_conf;
2083
2084   my @text; # array of lines
2085   my $html; # a big string
2086   my @related_parts; # will contain the text/HTML alternative, and images
2087   my $related; # will contain the multipart/related object
2088
2089   if ( $conf->exists($tc. 'email_pdf') ) {
2090     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2091
2092       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2093         if $DEBUG;
2094
2095       my $msg_template = FS::msg_template->by_key($msgnum)
2096         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2097       my %prepared = $msg_template->prepare(
2098         cust_main => $self->cust_main,
2099         object    => $self
2100       );
2101
2102       @text = split(/(?=\n)/, $prepared{'text_body'});
2103       $html = $prepared{'html_body'};
2104
2105     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2106
2107       warn "$me using '${tc}email_pdf_note' in multipart message"
2108         if $DEBUG;
2109       @text = $conf->config($tc.'email_pdf_note');
2110       $html = join('<BR>', @text);
2111
2112     } # else use the plain text invoice
2113   }
2114
2115   if (!@text) {
2116
2117     warn "$me generating plain text invoice"
2118       if $DEBUG;
2119
2120     # 'print_text' argument is no longer used
2121     @text = $self->print_text(\%args);
2122
2123   }
2124
2125   my $text_part = build MIME::Entity (
2126     'Type'        => 'text/plain',
2127     'Encoding'    => 'quoted-printable',
2128     'Charset'     => 'UTF-8',
2129     #'Encoding'    => '7bit',
2130     'Data'        => \@text,
2131     'Disposition' => 'inline',
2132   );
2133
2134   if (!$html) {
2135
2136     if ( $conf->exists($tc.'html') ) {
2137       warn "$me generating HTML invoice"
2138         if $DEBUG;
2139
2140       $args{'from'} =~ /\@([\w\.\-]+)/;
2141       my $from = $1 || 'example.com';
2142       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2143
2144       my $logo;
2145       my $agentnum = $cust_main ? $cust_main->agentnum
2146                                 : $self->prospect_main->agentnum;
2147       if ( defined($args{'template'}) && length($args{'template'})
2148            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2149          )
2150       {
2151         $logo = 'logo_'. $args{'template'}. '.png';
2152       } else {
2153         $logo = "logo.png";
2154       }
2155       my $image_data = $conf->config_binary( $logo, $agentnum);
2156
2157       push @related_parts, build MIME::Entity
2158         'Type'       => 'image/png',
2159         'Encoding'   => 'base64',
2160         'Data'       => $image_data,
2161         'Filename'   => 'logo.png',
2162         'Content-ID' => "<$content_id>",
2163       ;
2164
2165       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2166         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2167         push @related_parts, build MIME::Entity
2168           'Type'       => 'image/png',
2169           'Encoding'   => 'base64',
2170           'Data'       => $self->invoice_barcode(0),
2171           'Filename'   => 'barcode.png',
2172           'Content-ID' => "<$barcode_content_id>",
2173         ;
2174         $args{'barcode_cid'} = $barcode_content_id;
2175       }
2176
2177       $html = $self->print_html({ 'cid'=>$content_id, %args });
2178     }
2179
2180   }
2181
2182   if ( $html ) {
2183
2184     warn "$me creating HTML/text multipart message"
2185       if $DEBUG;
2186
2187     $return{'nobody'} = 1;
2188
2189     my $alternative = build MIME::Entity
2190       'Type'        => 'multipart/alternative',
2191       #'Encoding'    => '7bit',
2192       'Disposition' => 'inline'
2193     ;
2194
2195     if ( @text ) {
2196       $alternative->add_part($text_part);
2197     }
2198
2199     $alternative->attach(
2200       'Type'        => 'text/html',
2201       'Encoding'    => 'quoted-printable',
2202       'Data'        => [ '<html>',
2203                          '  <head>',
2204                          '    <title>',
2205                          '      '. encode_entities($return{'subject'}),
2206                          '    </title>',
2207                          '  </head>',
2208                          '  <body bgcolor="#e8e8e8">',
2209                          $html,
2210                          '  </body>',
2211                          '</html>',
2212                        ],
2213       'Disposition' => 'inline',
2214       #'Filename'    => 'invoice.pdf',
2215     );
2216
2217     unshift @related_parts, $alternative;
2218
2219     $related = build MIME::Entity 'Type'     => 'multipart/related',
2220                                   'Encoding' => '7bit';
2221
2222     #false laziness w/Misc::send_email
2223     $related->head->replace('Content-type',
2224       $related->mime_type.
2225       '; boundary="'. $related->head->multipart_boundary. '"'.
2226       '; type=multipart/alternative'
2227     );
2228
2229     $related->add_part($_) foreach @related_parts;
2230
2231   }
2232
2233   my @otherparts = ();
2234   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2235
2236     push @otherparts, build MIME::Entity
2237       'Type'        => 'text/csv',
2238       'Encoding'    => '7bit',
2239       'Data'        => [ map { "$_\n" }
2240                            $self->call_details('prepend_billed_number' => 1)
2241                        ],
2242       'Disposition' => 'attachment',
2243       'Filename'    => 'usage-'. $self->invnum. '.csv',
2244     ;
2245
2246   }
2247
2248   if ( $conf->exists($tc.'email_pdf') ) {
2249
2250     #attaching pdf too:
2251     # multipart/mixed
2252     #   multipart/related
2253     #     multipart/alternative
2254     #       text/plain
2255     #       text/html
2256     #     image/png
2257     #   application/pdf
2258
2259     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2260     push @otherparts, $pdf;
2261   }
2262
2263   if (@otherparts) {
2264     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2265     if ( $html ) {
2266       $return{'mimeparts'} = [ $related, @otherparts ];
2267       $return{'type'} = 'multipart/related'; # of the first part
2268     } else {
2269       $return{'mimeparts'} = [ $text_part, @otherparts ];
2270       $return{'type'} = 'text/plain';
2271     }
2272   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2273     $return{'mimeparts'} = \@related_parts;
2274     $return{'content-type'} = 'multipart/related';
2275     $return{'type'} = 'multipart/alternative';
2276   } else { # no HTML either
2277     $return{'body'} = \@text;
2278     $return{'content-type'} = 'text/plain';
2279   }
2280
2281   %return;
2282
2283 }
2284
2285 =item mimebuild_pdf
2286
2287 Returns a list suitable for passing to MIME::Entity->build(), representing
2288 this invoice as PDF attachment.
2289
2290 =cut
2291
2292 sub mimebuild_pdf {
2293   my $self = shift;
2294   (
2295     'Type'        => 'application/pdf',
2296     'Encoding'    => 'base64',
2297     'Data'        => [ $self->print_pdf(@_) ],
2298     'Disposition' => 'attachment',
2299     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2300   );
2301 }
2302
2303 =item _items_sections OPTIONS
2304
2305 Generate section information for all items appearing on this invoice.
2306 This will only be called for multi-section invoices.
2307
2308 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2309 related display records (L<FS::cust_bill_pkg_display>) and organize
2310 them into two groups ("early" and "late" according to whether they come
2311 before or after the total), then into sections.  A subtotal is calculated
2312 for each section.
2313
2314 Section descriptions are returned in sort weight order.  Each consists
2315 of a hash containing:
2316
2317 description: the package category name, escaped
2318 subtotal: the total charges in that section
2319 tax_section: a flag indicating that the section contains only tax charges
2320 summarized: same as tax_section, for some reason
2321 sort_weight: the package category's sort weight
2322
2323 If 'condense' is set on the display record, it also contains everything
2324 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2325 coderefs to generate parts of the invoice.  This is not advised.
2326
2327 The method returns two arrayrefs, one of "early" sections and one of "late"
2328 sections.
2329
2330 OPTIONS may include:
2331
2332 by_location: a flag to divide the invoice into sections by location.
2333 Each section hash will have a 'location' element containing a hashref of
2334 the location fields (see L<FS::cust_location>).  The section description
2335 will be the location label, but the template can use any of the location
2336 fields to create a suitable label.
2337
2338 by_category: a flag to divide the invoice into sections using display
2339 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2340 behavior.  Each section hash will have a 'category' element containing
2341 the section name from the display record (which probably equals the
2342 category name of the package, but may not in some cases).
2343
2344 summary: a flag indicating that this is a summary-format invoice.
2345 Turning this on has the following effects:
2346 - Ignores display items with the 'summary' flag.
2347 - Places all sections in the "early" group even if they have post_total.
2348 - Creates sections for all non-disabled package categories, even if they
2349 have no charges on this invoice, as well as a section with no name.
2350
2351 escape: an escape function to use for section titles.
2352
2353 extra_sections: an arrayref of additional sections to return after the
2354 sorted list.  If there are any of these, section subtotals exclude
2355 usage charges.
2356
2357 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2358 passed through to C<_condense_section()>.
2359
2360 =cut
2361
2362 use vars qw(%pkg_category_cache);
2363 sub _items_sections {
2364   my $self = shift;
2365   my %opt = @_;
2366
2367   my $escape = $opt{escape};
2368   my @extra_sections = @{ $opt{extra_sections} || [] };
2369
2370   # $subtotal{$locationnum}{$categoryname} = amount.
2371   # if we're not using by_location, $locationnum is undef.
2372   # if we're not using by_category, you guessed it, $categoryname is undef.
2373   # if we're not using either one, we shouldn't be here in the first place...
2374   my %subtotal = ();
2375   my %late_subtotal = ();
2376   my %not_tax = ();
2377
2378   # About tax items + multisection invoices:
2379   # If either invoice_*summary option is enabled, AND there is a
2380   # package category with the name of the tax, then there will be
2381   # a display record assigning the tax item to that category.
2382   #
2383   # However, the taxes are always placed in the "Taxes, Surcharges,
2384   # and Fees" section regardless of that.  The only effect of the
2385   # display record is to create a subtotal for the summary page.
2386
2387   # cache these
2388   my $pkg_hash = $self->cust_pkg_hash;
2389
2390   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2391   {
2392
2393       my $usage = $cust_bill_pkg->usage;
2394
2395       my $locationnum;
2396       if ( $opt{by_location} ) {
2397         if ( $cust_bill_pkg->pkgnum ) {
2398           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2399         } else {
2400           $locationnum = '';
2401         }
2402       } else {
2403         $locationnum = undef;
2404       }
2405
2406       # as in _items_cust_pkg, if a line item has no display records,
2407       # cust_bill_pkg_display() returns a default record for it
2408
2409       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2410         next if ( $display->summary && $opt{summary} );
2411
2412         my $section = $display->section;
2413         my $type    = $display->type;
2414         # Set $section = undef if we're sectioning by location and this
2415         # line item _has_ a location (i.e. isn't a fee).
2416         $section = undef if $locationnum;
2417
2418         # set this flag if the section is not tax-only
2419         $not_tax{$locationnum}{$section} = 1
2420           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2421
2422         # there's actually a very important piece of logic buried in here:
2423         # incrementing $late_subtotal{$section} CREATES
2424         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2425         # to define the list of late sections, and likewise keys(%subtotal).
2426         # When _items_cust_bill_pkg is called to generate line items for
2427         # real, it will be called with 'section' => $section for each
2428         # of these.
2429         if ( $display->post_total && !$opt{summary} ) {
2430           if (! $type || $type eq 'S') {
2431             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2432               if $cust_bill_pkg->setup != 0
2433               || $cust_bill_pkg->setup_show_zero;
2434           }
2435
2436           if (! $type) {
2437             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2438               if $cust_bill_pkg->recur != 0
2439               || $cust_bill_pkg->recur_show_zero;
2440           }
2441
2442           if ($type && $type eq 'R') {
2443             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2444               if $cust_bill_pkg->recur != 0
2445               || $cust_bill_pkg->recur_show_zero;
2446           }
2447
2448           if ($type && $type eq 'U') {
2449             $late_subtotal{$locationnum}{$section} += $usage
2450               unless scalar(@extra_sections);
2451           }
2452
2453         } else { # it's a pre-total (normal) section
2454
2455           # skip tax items unless they're explicitly included in a section
2456           next if $cust_bill_pkg->pkgnum == 0 and
2457                   ! $cust_bill_pkg->feepart   and
2458                   ! $section;
2459
2460           if ( $type eq 'S' ) {
2461             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2462               if $cust_bill_pkg->setup != 0
2463               || $cust_bill_pkg->setup_show_zero;
2464           } elsif ( $type eq 'R' ) {
2465             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2466               if $cust_bill_pkg->recur != 0
2467               || $cust_bill_pkg->recur_show_zero;
2468           } elsif ( $type eq 'U' ) {
2469             $subtotal{$locationnum}{$section} += $usage
2470               unless scalar(@extra_sections);
2471           } elsif ( !$type ) {
2472             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2473                                                + $cust_bill_pkg->recur;
2474           }
2475
2476         }
2477
2478       }
2479
2480   }
2481
2482   %pkg_category_cache = ();
2483
2484   # summary invoices need subtotals for all non-disabled package categories,
2485   # even if they're zero
2486   # but currently assume that there are no location sections, or at least
2487   # that the summary page doesn't care about them
2488   if ( $opt{summary} ) {
2489     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2490       $subtotal{''}{$category->categoryname} ||= 0;
2491     }
2492     $subtotal{''}{''} ||= 0;
2493   }
2494
2495   my @sections;
2496   foreach my $post_total (0,1) {
2497     my @these;
2498     my $s = $post_total ? \%late_subtotal : \%subtotal;
2499     foreach my $locationnum (keys %$s) {
2500       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2501         my $section = {
2502                         'subtotal'    => $s->{$locationnum}{$sectionname},
2503                         'post_total'  => $post_total,
2504                         'sort_weight' => 0,
2505                       };
2506         if ( $locationnum ) {
2507           $section->{'locationnum'} = $locationnum;
2508           my $location = FS::cust_location->by_key($locationnum);
2509           $section->{'description'} = &{ $escape }($location->location_label);
2510           # Better ideas? This will roughly group them by proximity,
2511           # which alpha sorting on any of the address fields won't.
2512           # Sorting by locationnum is meaningless.
2513           # We have to sort on _something_ or the order may change
2514           # randomly from one invoice to the next, which will confuse
2515           # people.
2516           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2517                                       $locationnum;
2518           $section->{'location'} = {
2519             label_prefix => &{ $escape }($location->label_prefix),
2520             map { $_ => &{ $escape }($location->get($_)) }
2521               $location->fields
2522           };
2523         } else {
2524           $section->{'category'} = $sectionname;
2525           $section->{'description'} = &{ $escape }($sectionname);
2526           if ( _pkg_category($sectionname) ) {
2527             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2528             if ( _pkg_category($sectionname)->condense ) {
2529               $section = { %$section, $self->_condense_section($opt{format}) };
2530             }
2531           }
2532         }
2533         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2534           # then it's a tax-only section
2535           $section->{'summarized'} = 'Y';
2536           $section->{'tax_section'} = 'Y';
2537         }
2538         push @these, $section;
2539       } # foreach $sectionname
2540     } #foreach $locationnum
2541     push @these, @extra_sections if $post_total == 0;
2542     # need an alpha sort for location sections, because postal codes can
2543     # be non-numeric
2544     $sections[ $post_total ] = [ sort {
2545       $opt{'by_location'} ?
2546         ($a->{sort_weight} cmp $b->{sort_weight}) :
2547         ($a->{sort_weight} <=> $b->{sort_weight})
2548       } @these ];
2549   } #foreach $post_total
2550
2551   return @sections; # early, late
2552 }
2553
2554 #helper subs for above
2555
2556 sub cust_pkg_hash {
2557   my $self = shift;
2558   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2559 }
2560
2561 sub _pkg_category {
2562   my $categoryname = shift;
2563   $pkg_category_cache{$categoryname} ||=
2564     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2565 }
2566
2567 my %condensed_format = (
2568   'label' => [ qw( Description Qty Amount ) ],
2569   'fields' => [
2570                 sub { shift->{description} },
2571                 sub { shift->{quantity} },
2572                 sub { my($href, %opt) = @_;
2573                       ($opt{dollar} || ''). $href->{amount};
2574                     },
2575               ],
2576   'align'  => [ qw( l r r ) ],
2577   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2578   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2579 );
2580
2581 sub _condense_section {
2582   my ( $self, $format ) = ( shift, shift );
2583   ( 'condensed' => 1,
2584     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2585       qw( description_generator
2586           header_generator
2587           total_generator
2588           total_line_generator
2589         )
2590   );
2591 }
2592
2593 sub _condensed_generator_defaults {
2594   my ( $self, $format ) = ( shift, shift );
2595   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2596 }
2597
2598 my %html_align = (
2599   'c' => 'center',
2600   'l' => 'left',
2601   'r' => 'right',
2602 );
2603
2604 sub _condensed_header_generator {
2605   my ( $self, $format ) = ( shift, shift );
2606
2607   my ( $f, $prefix, $suffix, $separator, $column ) =
2608     _condensed_generator_defaults($format);
2609
2610   if ($format eq 'latex') {
2611     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2612     $suffix = "\\\\\n\\hline";
2613     $separator = "&\n";
2614     $column =
2615       sub { my ($d,$a,$s,$w) = @_;
2616             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2617           };
2618   } elsif ( $format eq 'html' ) {
2619     $prefix = '<th></th>';
2620     $suffix = '';
2621     $separator = '';
2622     $column =
2623       sub { my ($d,$a,$s,$w) = @_;
2624             return qq!<th align="$html_align{$a}">$d</th>!;
2625       };
2626   }
2627
2628   sub {
2629     my @args = @_;
2630     my @result = ();
2631
2632     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2633       push @result,
2634         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2635     }
2636
2637     $prefix. join($separator, @result). $suffix;
2638   };
2639
2640 }
2641
2642 sub _condensed_description_generator {
2643   my ( $self, $format ) = ( shift, shift );
2644
2645   my ( $f, $prefix, $suffix, $separator, $column ) =
2646     _condensed_generator_defaults($format);
2647
2648   my $money_char = '$';
2649   if ($format eq 'latex') {
2650     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2651     $suffix = '\\\\';
2652     $separator = " & \n";
2653     $column =
2654       sub { my ($d,$a,$s,$w) = @_;
2655             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2656           };
2657     $money_char = '\\dollar';
2658   }elsif ( $format eq 'html' ) {
2659     $prefix = '"><td align="center"></td>';
2660     $suffix = '';
2661     $separator = '';
2662     $column =
2663       sub { my ($d,$a,$s,$w) = @_;
2664             return qq!<td align="$html_align{$a}">$d</td>!;
2665       };
2666     #$money_char = $conf->config('money_char') || '$';
2667     $money_char = '';  # this is madness
2668   }
2669
2670   sub {
2671     #my @args = @_;
2672     my $href = shift;
2673     my @result = ();
2674
2675     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2676       my $dollar = '';
2677       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2678       push @result,
2679         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2680                     map { $f->{$_}->[$i] } qw(align span width)
2681                   );
2682     }
2683
2684     $prefix. join( $separator, @result ). $suffix;
2685   };
2686
2687 }
2688
2689 sub _condensed_total_generator {
2690   my ( $self, $format ) = ( shift, shift );
2691
2692   my ( $f, $prefix, $suffix, $separator, $column ) =
2693     _condensed_generator_defaults($format);
2694   my $style = '';
2695
2696   if ($format eq 'latex') {
2697     $prefix = "& ";
2698     $suffix = "\\\\\n";
2699     $separator = " & \n";
2700     $column =
2701       sub { my ($d,$a,$s,$w) = @_;
2702             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2703           };
2704   }elsif ( $format eq 'html' ) {
2705     $prefix = '';
2706     $suffix = '';
2707     $separator = '';
2708     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2709     $column =
2710       sub { my ($d,$a,$s,$w) = @_;
2711             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2712       };
2713   }
2714
2715
2716   sub {
2717     my @args = @_;
2718     my @result = ();
2719
2720     #  my $r = &{$f->{fields}->[$i]}(@args);
2721     #  $r .= ' Total' unless $i;
2722
2723     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2724       push @result,
2725         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2726                     map { $f->{$_}->[$i] } qw(align span width)
2727                   );
2728     }
2729
2730     $prefix. join( $separator, @result ). $suffix;
2731   };
2732
2733 }
2734
2735 =item total_line_generator FORMAT
2736
2737 Returns a coderef used for generation of invoice total line items for this
2738 usage_class.  FORMAT is either html or latex
2739
2740 =cut
2741
2742 # should not be used: will have issues with hash element names (description vs
2743 # total_item and amount vs total_amount -- another array of functions?
2744
2745 sub _condensed_total_line_generator {
2746   my ( $self, $format ) = ( shift, shift );
2747
2748   my ( $f, $prefix, $suffix, $separator, $column ) =
2749     _condensed_generator_defaults($format);
2750   my $style = '';
2751
2752   if ($format eq 'latex') {
2753     $prefix = "& ";
2754     $suffix = "\\\\\n";
2755     $separator = " & \n";
2756     $column =
2757       sub { my ($d,$a,$s,$w) = @_;
2758             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2759           };
2760   }elsif ( $format eq 'html' ) {
2761     $prefix = '';
2762     $suffix = '';
2763     $separator = '';
2764     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2765     $column =
2766       sub { my ($d,$a,$s,$w) = @_;
2767             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2768       };
2769   }
2770
2771
2772   sub {
2773     my @args = @_;
2774     my @result = ();
2775
2776     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2777       push @result,
2778         &{$column}( &{$f->{fields}->[$i]}(@args),
2779                     map { $f->{$_}->[$i] } qw(align span width)
2780                   );
2781     }
2782
2783     $prefix. join( $separator, @result ). $suffix;
2784   };
2785
2786 }
2787
2788 =item _items_pkg [ OPTIONS ]
2789
2790 Return line item hashes for each package item on this invoice. Nearly
2791 equivalent to
2792
2793 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2794
2795 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2796 'format' and 'escape_function' at minimum.
2797
2798 To produce items for a specific invoice section, OPTIONS should include
2799 'section', a hashref containing 'category' and/or 'locationnum' keys.
2800
2801 'section' may also contain a key named 'condensed'. If this is present
2802 and has a true value, _items_pkg will try to merge identical items into items
2803 with 'quantity' equal to the number of items (not the sum of their separate
2804 quantities, for some reason).
2805
2806 =cut
2807
2808 sub _items_nontax {
2809   my $self = shift;
2810   # The order of these is important.  Bundled line items will be merged into
2811   # the most recent non-hidden item, so it needs to be the one with:
2812   # - the same pkgnum
2813   # - the same start date
2814   # - no pkgpart_override
2815   #
2816   # So: sort by pkgnum,
2817   # then by sdate
2818   # then sort the base line item before any overrides
2819   # then sort hidden before non-hidden add-ons
2820   # then sort by override pkgpart (for consistency)
2821   sort { $a->pkgnum <=> $b->pkgnum        or
2822          $a->sdate  <=> $b->sdate         or
2823          ($a->pkgpart_override ? 0 : -1)  or
2824          ($b->pkgpart_override ? 0 : 1)   or
2825          $b->hidden cmp $a->hidden        or
2826          $a->pkgpart_override <=> $b->pkgpart_override
2827        }
2828   # and of course exclude taxes and fees
2829   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2830 }
2831
2832 sub _items_fee {
2833   my $self = shift;
2834   my %options = @_;
2835   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2836   my $escape_function = $options{escape_function};
2837
2838   my @items;
2839   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2840     # cache this, so we don't look it up again in every section
2841     my $part_fee = $cust_bill_pkg->get('part_fee')
2842        || $cust_bill_pkg->part_fee;
2843     $cust_bill_pkg->set('part_fee', $part_fee);
2844     if (!$part_fee) {
2845       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2846       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2847       next;
2848     }
2849     if ( exists($options{section}) and exists($options{section}{category}) )
2850     {
2851       my $categoryname = $options{section}{category};
2852       # then filter for items that have that section
2853       if ( $part_fee->categoryname ne $categoryname ) {
2854         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2855         next;
2856       }
2857     } # otherwise include them all in the main section
2858     # XXX what to do when sectioning by location?
2859
2860     my @ext_desc;
2861     my %base_invnums; # invnum => invoice date
2862     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2863       if ($_->base_invnum) {
2864         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2865         my $base_date = $self->time2str_local('short', $base_bill->_date)
2866           if $base_bill;
2867         $base_invnums{$_->base_invnum} = $base_date || '';
2868       }
2869     }
2870     foreach (sort keys(%base_invnums)) {
2871       next if $_ == $self->invnum;
2872       # per convention, we must escape ext_description lines
2873       push @ext_desc,
2874         &{$escape_function}(
2875           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2876         );
2877     }
2878     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2879     # but not escape the base description line
2880
2881     push @items,
2882       { feepart     => $cust_bill_pkg->feepart,
2883         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2884         description => $desc,
2885         ext_description => \@ext_desc
2886         # sdate/edate?
2887       };
2888   }
2889   @items;
2890 }
2891
2892 sub _items_pkg {
2893   my $self = shift;
2894   my %options = @_;
2895
2896   warn "$me _items_pkg searching for all package line items\n"
2897     if $DEBUG > 1;
2898
2899   my @cust_bill_pkg = $self->_items_nontax;
2900
2901   warn "$me _items_pkg filtering line items\n"
2902     if $DEBUG > 1;
2903   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2904
2905   if ($options{section} && $options{section}->{condensed}) {
2906
2907     warn "$me _items_pkg condensing section\n"
2908       if $DEBUG > 1;
2909
2910     my %itemshash = ();
2911     local $Storable::canonical = 1;
2912     foreach ( @items ) {
2913       my $item = { %$_ };
2914       delete $item->{ref};
2915       delete $item->{ext_description};
2916       my $key = freeze($item);
2917       $itemshash{$key} ||= 0;
2918       $itemshash{$key} ++; # += $item->{quantity};
2919     }
2920     @items = sort { $a->{description} cmp $b->{description} }
2921              map { my $i = thaw($_);
2922                    $i->{quantity} = $itemshash{$_};
2923                    $i->{amount} =
2924                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2925                    $i;
2926                  }
2927              keys %itemshash;
2928   }
2929
2930   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2931     if $DEBUG > 1;
2932
2933   @items;
2934 }
2935
2936 sub _taxsort {
2937   return 0 unless $a->itemdesc cmp $b->itemdesc;
2938   return -1 if $b->itemdesc eq 'Tax';
2939   return 1 if $a->itemdesc eq 'Tax';
2940   return -1 if $b->itemdesc eq 'Other surcharges';
2941   return 1 if $a->itemdesc eq 'Other surcharges';
2942   $a->itemdesc cmp $b->itemdesc;
2943 }
2944
2945 sub _items_tax {
2946   my $self = shift;
2947   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2948     $self->cust_bill_pkg;
2949   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2950
2951   if ( $self->conf->exists('always_show_tax') ) {
2952     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2953     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2954       push @items,
2955         { 'description' => $itemdesc,
2956           'amount'      => 0.00 };
2957     }
2958   }
2959   @items;
2960 }
2961
2962 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2963
2964 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2965 list of hashrefs describing the line items they generate on the invoice.
2966
2967 OPTIONS may include:
2968
2969 format: the invoice format.
2970
2971 escape_function: the function used to escape strings.
2972
2973 DEPRECATED? (expensive, mostly unused?)
2974 format_function: the function used to format CDRs.
2975
2976 section: a hashref containing 'category' and/or 'locationnum'; if this
2977 is present, only returns line items that belong to that category and/or
2978 location (whichever is defined).
2979
2980 multisection: a flag indicating that this is a multisection invoice,
2981 which does something complicated.
2982
2983 preref_callback: coderef run for each line item, code should return HTML to be
2984 displayed before that line item (quotations only)
2985
2986 Returns a list of hashrefs, each of which may contain:
2987
2988 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2989 ext_description, which is an arrayref of detail lines to show below
2990 the package line.
2991
2992 =cut
2993
2994 sub _items_cust_bill_pkg {
2995   my $self = shift;
2996   my $conf = $self->conf;
2997   my $cust_bill_pkgs = shift;
2998   my %opt = @_;
2999
3000   my $format = $opt{format} || '';
3001   my $escape_function = $opt{escape_function} || sub { shift };
3002   my $format_function = $opt{format_function} || '';
3003   my $no_usage = $opt{no_usage} || '';
3004   my $unsquelched = $opt{unsquelched} || ''; #unused
3005   my ($section, $locationnum, $category);
3006   if ( $opt{section} ) {
3007     $category = $opt{section}->{category};
3008     $locationnum = $opt{section}->{locationnum};
3009   }
3010   my $summary_page = $opt{summary_page} || ''; #unused
3011   my $multisection = defined($category) || defined($locationnum);
3012   my $discount_show_always = 0;
3013
3014   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 50;
3015
3016   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3017                                    # and location labels
3018
3019   my @b = (); # accumulator for the line item hashes that we'll return
3020   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3021             # the 'current' line item hashes for setup, recur, usage, discount
3022   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3023   {
3024     # if the current line item is waiting to go out, and the one we're about
3025     # to start is not bundled, then push out the current one and start a new
3026     # one.
3027     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3028       if ( $_ && !$cust_bill_pkg->hidden ) {
3029         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3030         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3031         if (exists($_->{unit_amount})) {
3032           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3033         }
3034         push @b, { %$_ }
3035           if $_->{amount} != 0
3036           || $discount_show_always
3037           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3038           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3039         ;
3040         $_ = undef;
3041       }
3042     }
3043
3044     if ( $locationnum ) {
3045       # this is a location section; skip packages that aren't at this
3046       # service location.
3047       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3048       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3049               != $locationnum;
3050     }
3051
3052     # Consider display records for this item to determine if it belongs
3053     # in this section.  Note that if there are no display records, there
3054     # will be a default pseudo-record that includes all charge types
3055     # and has no section name.
3056     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3057                                   ? $cust_bill_pkg->cust_bill_pkg_display
3058                                   : ( $cust_bill_pkg );
3059
3060     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3061          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3062       if $DEBUG > 1;
3063
3064     if ( defined($category) ) {
3065       # then this is a package category section; process all display records
3066       # that belong to this section.
3067       @cust_bill_pkg_display = grep { $_->section eq $category }
3068                                 @cust_bill_pkg_display;
3069     } else {
3070       # otherwise, process all display records that aren't usage summaries
3071       # (I don't think there should be usage summaries if you aren't using
3072       # category sections, but this is the historical behavior)
3073       @cust_bill_pkg_display = grep { !$_->summary }
3074                                 @cust_bill_pkg_display;
3075     }
3076
3077     my $classname = ''; # package class name, will fill in later
3078
3079     foreach my $display (@cust_bill_pkg_display) {
3080
3081       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3082            $display->billpkgdisplaynum. "\n"
3083         if $DEBUG > 1;
3084
3085       my $type = $display->type;
3086
3087       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3088       $desc = substr($desc, 0, $maxlength). '...'
3089         if $format eq 'latex' && length($desc) > $maxlength;
3090
3091       my %details_opt = ( 'format'          => $format,
3092                           'escape_function' => $escape_function,
3093                           'format_function' => $format_function,
3094                           'no_usage'        => $opt{'no_usage'},
3095                         );
3096
3097       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3098
3099         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3100           if $DEBUG > 1;
3101         # quotation_pkgs are never fees, so don't worry about the case where
3102         # part_pkg is undefined
3103
3104         # and I guess they're never bundled either?
3105         if ( $cust_bill_pkg->setup != 0 ) {
3106           my $description = $desc;
3107           $description .= ' Setup'
3108             if $cust_bill_pkg->recur != 0
3109             || $discount_show_always
3110             || $cust_bill_pkg->recur_show_zero;
3111           #push @b, {
3112           # keep it consistent, please
3113           $s = {
3114             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3115             'description' => $description,
3116             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3117             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3118             'quantity'    => $cust_bill_pkg->quantity,
3119             'preref_html' => ( $opt{preref_callback}
3120                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3121                                  : ''
3122                              ),
3123           };
3124         }
3125         if ( $cust_bill_pkg->recur != 0 ) {
3126           #push @b, {
3127           $r = {
3128             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3129             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3130             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3131             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3132             'quantity'    => $cust_bill_pkg->quantity,
3133            'preref_html'  => ( $opt{preref_callback}
3134                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3135                                  : ''
3136                              ),
3137           };
3138         }
3139
3140       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3141         # a "normal" package line item (not a quotation, not a fee, not a tax)
3142
3143         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3144           if $DEBUG > 1;
3145
3146         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3147         my $part_pkg = $cust_pkg->part_pkg;
3148
3149         # which pkgpart to show for display purposes?
3150         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3151
3152         # start/end dates for invoice formats that do nonstandard
3153         # things with them
3154         my %item_dates = ();
3155         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3156           unless $part_pkg->option('disable_line_item_date_ranges',1);
3157
3158         # not normally used, but pass this to the template anyway
3159         $classname = $part_pkg->classname;
3160
3161         if (    (!$type || $type eq 'S')
3162              && (    $cust_bill_pkg->setup != 0
3163                   || $cust_bill_pkg->setup_show_zero
3164                 )
3165            )
3166          {
3167
3168           warn "$me _items_cust_bill_pkg adding setup\n"
3169             if $DEBUG > 1;
3170
3171           my $description = $desc;
3172           $description .= ' Setup'
3173             if $cust_bill_pkg->recur != 0
3174             || $discount_show_always
3175             || $cust_bill_pkg->recur_show_zero;
3176
3177           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3178                                                               $self->agentnum )
3179             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3180                                      # triggered by the recurring charge freq
3181                                      # (RT#26274)
3182             && $cust_bill_pkg->recur == 0
3183             && ! $cust_bill_pkg->recur_show_zero;
3184
3185           my @d = ();
3186           my $svc_label;
3187
3188           # always pass the svc_label through to the template, even if
3189           # not displaying it as an ext_description
3190           my @svc_labels = map &{$escape_function}($_),
3191                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3192
3193           $svc_label = $svc_labels[0];
3194
3195           unless ( $cust_pkg->part_pkg->hide_svc_detail
3196                 || $cust_bill_pkg->hidden )
3197           {
3198
3199             push @d, @svc_labels
3200               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3201             my $lnum = $cust_main ? $cust_main->ship_locationnum
3202                                   : $self->prospect_main->locationnum;
3203             # show the location label if it's not the customer's default
3204             # location, and we're not grouping items by location already
3205             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3206               my $loc = $cust_pkg->location_label;
3207               $loc = substr($loc, 0, $maxlength). '...'
3208                 if $format eq 'latex' && length($loc) > $maxlength;
3209               push @d, &{$escape_function}($loc);
3210             }
3211
3212           } #unless hiding service details
3213
3214           push @d, $cust_bill_pkg->details(%details_opt)
3215             if $cust_bill_pkg->recur == 0;
3216
3217           if ( $cust_bill_pkg->hidden ) {
3218             $s->{amount}      += $cust_bill_pkg->setup;
3219             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3220             push @{ $s->{ext_description} }, @d;
3221           } else {
3222             $s = {
3223               _is_setup       => 1,
3224               description     => $description,
3225               pkgpart         => $pkgpart,
3226               pkgnum          => $cust_bill_pkg->pkgnum,
3227               amount          => $cust_bill_pkg->setup,
3228               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3229               unit_amount     => $cust_bill_pkg->unitsetup,
3230               quantity        => $cust_bill_pkg->quantity,
3231               ext_description => \@d,
3232               svc_label       => ($svc_label || ''),
3233               locationnum     => $cust_pkg->locationnum, # sure, why not?
3234             };
3235           };
3236
3237         }
3238
3239         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3240              && (
3241                      $cust_bill_pkg->recur != 0
3242                   || $cust_bill_pkg->setup == 0
3243                   || $discount_show_always
3244                   || $cust_bill_pkg->recur_show_zero
3245                 )
3246            )
3247         {
3248
3249           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3250             if $DEBUG > 1;
3251
3252           my $is_summary = $display->summary;
3253           my $description = $desc;
3254           if ( $type eq 'U' and defined($r) ) {
3255             # don't just show the same description as the recur line
3256             $description = $self->mt('Usage charges');
3257           }
3258
3259           my $part_pkg = $cust_pkg->part_pkg;
3260
3261           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3262                                                               $self->agentnum );
3263
3264           my @d = ();
3265           my @seconds = (); # for display of usage info
3266           my $svc_label = '';
3267
3268           #at least until cust_bill_pkg has "past" ranges in addition to
3269           #the "future" sdate/edate ones... see #3032
3270           my @dates = ( $self->_date );
3271           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3272           push @dates, $prev->sdate if $prev;
3273           push @dates, undef if !$prev;
3274
3275           my @svc_labels = map &{$escape_function}($_),
3276                       $cust_pkg->h_labels_short(@dates, 'I');
3277           $svc_label = $svc_labels[0];
3278
3279           # show service labels, unless...
3280                     # the package is set not to display them
3281           unless ( $part_pkg->hide_svc_detail
3282                     # or this is a tax-like line item
3283                 || $cust_bill_pkg->itemdesc
3284                     # or this is a hidden (bundled) line item
3285                 || $cust_bill_pkg->hidden
3286                     # or this is a usage summary line
3287                 || $is_summary && $type && $type eq 'U'
3288                     # or this is a usage line and there's a recurring line
3289                     # for the package in the same section (which will
3290                     # have service labels already)
3291                 || ($type eq 'U' and defined($r))
3292               )
3293           {
3294
3295             warn "$me _items_cust_bill_pkg adding service details\n"
3296               if $DEBUG > 1;
3297
3298             push @d, @svc_labels
3299               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3300             warn "$me _items_cust_bill_pkg done adding service details\n"
3301               if $DEBUG > 1;
3302
3303             my $lnum = $cust_main ? $cust_main->ship_locationnum
3304                                   : $self->prospect_main->locationnum;
3305             # show the location label if it's not the customer's default
3306             # location, and we're not grouping items by location already
3307             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3308               my $loc = $cust_pkg->location_label;
3309               $loc = substr($loc, 0, $maxlength). '...'
3310                 if $format eq 'latex' && length($loc) > $maxlength;
3311               push @d, &{$escape_function}($loc);
3312             }
3313
3314             # Display of seconds_since_sqlradacct:
3315             # On the invoice, when processing @detail_items, look for a field
3316             # named 'seconds'.  This will contain total seconds for each
3317             # service, in the same order as @ext_description.  For services
3318             # that don't support this it will show undef.
3319             if ( $conf->exists('svc_acct-usage_seconds')
3320                  and ! $cust_bill_pkg->pkgpart_override ) {
3321               foreach my $cust_svc (
3322                   $cust_pkg->h_cust_svc(@dates, 'I')
3323                 ) {
3324
3325                 # eval because not having any part_export_usage exports
3326                 # is a fatal error, last_bill/_date because that's how
3327                 # sqlradius_hour billing does it
3328                 my $sec = eval {
3329                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3330                 };
3331                 push @seconds, $sec;
3332               }
3333             } #if svc_acct-usage_seconds
3334
3335           } # if we are showing service labels
3336
3337           unless ( $is_summary ) {
3338             warn "$me _items_cust_bill_pkg adding details\n"
3339               if $DEBUG > 1;
3340
3341             #instead of omitting details entirely in this case (unwanted side
3342             # effects), just omit CDRs
3343             $details_opt{'no_usage'} = 1
3344               if $type && $type eq 'R';
3345
3346             push @d, $cust_bill_pkg->details(%details_opt);
3347           }
3348
3349           warn "$me _items_cust_bill_pkg calculating amount\n"
3350             if $DEBUG > 1;
3351
3352           my $amount = 0;
3353           if (!$type) {
3354             $amount = $cust_bill_pkg->recur;
3355           } elsif ($type eq 'R') {
3356             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3357           } elsif ($type eq 'U') {
3358             $amount = $cust_bill_pkg->usage;
3359           }
3360
3361           if ( !$type || $type eq 'R' ) {
3362
3363             warn "$me _items_cust_bill_pkg adding recur\n"
3364               if $DEBUG > 1;
3365
3366             my $unit_amount =
3367               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3368                                                 : $amount;
3369
3370             if ( $cust_bill_pkg->hidden ) {
3371               $r->{amount}      += $amount;
3372               $r->{unit_amount} += $unit_amount;
3373               push @{ $r->{ext_description} }, @d;
3374             } else {
3375               $r = {
3376                 description     => $description,
3377                 pkgpart         => $pkgpart,
3378                 pkgnum          => $cust_bill_pkg->pkgnum,
3379                 amount          => $amount,
3380                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3381                 unit_amount     => $unit_amount,
3382                 quantity        => $cust_bill_pkg->quantity,
3383                 %item_dates,
3384                 ext_description => \@d,
3385                 svc_label       => ($svc_label || ''),
3386                 locationnum     => $cust_pkg->locationnum,
3387               };
3388               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3389             }
3390
3391           } else {  # $type eq 'U'
3392
3393             warn "$me _items_cust_bill_pkg adding usage\n"
3394               if $DEBUG > 1;
3395
3396             if ( $cust_bill_pkg->hidden and defined($u) ) {
3397               # if this is a hidden package and there's already a usage
3398               # line for the bundle, add this package's total amount and
3399               # usage details to it
3400               $u->{amount}      += $amount;
3401               push @{ $u->{ext_description} }, @d;
3402             } elsif ( $amount ) {
3403               # create a new usage line
3404               $u = {
3405                 description     => $description,
3406                 pkgpart         => $pkgpart,
3407                 pkgnum          => $cust_bill_pkg->pkgnum,
3408                 amount          => $amount,
3409                 usage_item      => 1,
3410                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3411                 %item_dates,
3412                 ext_description => \@d,
3413                 locationnum     => $cust_pkg->locationnum,
3414               };
3415             } # else this has no usage, so don't create a usage section
3416           }
3417
3418         } # recurring or usage with recurring charge
3419
3420       } else { # taxes and fees
3421
3422         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3423           if $DEBUG > 1;
3424
3425         # items of this kind should normally not have sdate/edate.
3426         push @b, {
3427           'description' => $desc,
3428           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3429                                            + $cust_bill_pkg->recur)
3430         };
3431
3432       } # if quotation / package line item / other line item
3433
3434       # decide whether to show active discounts here
3435       if (
3436           # case 1: we are showing a single line for the package
3437           ( !$type )
3438           # case 2: we are showing a setup line for a package that has
3439           # no base recurring fee
3440           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3441           # case 3: we are showing a recur line for a package that has
3442           # a base recurring fee
3443           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3444       ) {
3445
3446         my $item_discount = $cust_bill_pkg->_item_discount;
3447         if ( $item_discount ) {
3448           # $item_discount->{amount} is negative
3449
3450           if ( $d and $cust_bill_pkg->hidden ) {
3451             $d->{amount}      += $item_discount->{amount};
3452           } else {
3453             $d = $item_discount;
3454             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3455           }
3456
3457           # update the active line (before the discount) to show the
3458           # original price (whether this is a hidden line or not)
3459           #
3460           # quotation discounts keep track of setup and recur; invoice
3461           # discounts currently don't
3462           if ( exists $item_discount->{setup_amount} ) {
3463
3464             $s->{amount} -= $item_discount->{setup_amount} if $s;
3465             $r->{amount} -= $item_discount->{recur_amount} if $r;
3466
3467           } else {
3468
3469             # $active_line is the line item hashref for the line that will
3470             # show the original price
3471             # (use the recur or single line for the package, unless we're
3472             # showing a setup line for a package with no recurring fee)
3473             my $active_line = $r;
3474             if ( $type eq 'S' ) {
3475               $active_line = $s;
3476             }
3477             $active_line->{amount} -= $item_discount->{amount};
3478
3479           }
3480
3481         } # if there are any discounts
3482       } # if this is an appropriate place to show discounts
3483
3484     } # foreach $display
3485
3486     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3487                                 && $conf->exists('discount-show-always'));
3488
3489   }
3490
3491   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3492     if ( $_  ) {
3493       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3494         if exists($_->{amount});
3495       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3496       if (exists($_->{unit_amount})) {
3497         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3498       }
3499
3500       push @b, { %$_ }
3501         if $_->{amount} != 0
3502         || $discount_show_always
3503         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3504         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3505     }
3506   }
3507
3508   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3509     if $DEBUG > 1;
3510
3511   @b;
3512
3513 }
3514
3515 =item _items_discounts_avail
3516
3517 Returns an array of line item hashrefs representing available term discounts
3518 for this invoice.  This makes the same assumptions that apply to term
3519 discounts in general: that the package is billed monthly, at a flat rate,
3520 with no usage charges.  A prorated first month will be handled, as will
3521 a setup fee if the discount is allowed to apply to setup fees.
3522
3523 =cut
3524
3525 sub _items_discounts_avail {
3526   my $self = shift;
3527
3528   #maybe move this method from cust_bill when quotations support discount_plans
3529   return () unless $self->can('discount_plans');
3530   my %plans = $self->discount_plans;
3531
3532   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3533   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3534
3535   map {
3536     my $months = $_;
3537     my $plan = $plans{$months};
3538
3539     my $term_total = sprintf('%.2f', $plan->discounted_total);
3540     my $percent = sprintf('%.0f',
3541                           100 * (1 - $term_total / $plan->base_total) );
3542     my $permonth = sprintf('%.2f', $term_total / $months);
3543     my $detail = $self->mt('discount on item'). ' '.
3544                  join(', ', map { "#$_" } $plan->pkgnums)
3545       if $list_pkgnums;
3546
3547     # discounts for non-integer months don't work anyway
3548     $months = sprintf("%d", $months);
3549
3550     +{
3551       description => $self->mt('Save [_1]% by paying for [_2] months',
3552                                 $percent, $months),
3553       amount      => $self->mt('[_1] ([_2] per month)',
3554                                 $term_total, $money_char.$permonth),
3555       ext_description => ($detail || ''),
3556     }
3557   } #map
3558   sort { $b <=> $a } keys %plans;
3559
3560 }
3561
3562 1;