FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319
 320   my $locale = $params{'locale'} || $cust_main->locale;
 321
 322   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 323                      'html'     => [ '<%=', '%>' ],
 324                      'template' => [ '{', '}' ],
 325                    );
 326
 327   warn "$me print_generic creating template\n"
 328     if $DEBUG > 1;
 329
 330   # set the notice name here, and nowhere else.
 331   my $notice_name =  $params{notice_name}
 332                   || $conf->config('notice_name')
 333                   || $self->notice_name;
 334
 335   #create the template
 336   my $template = $params{template} ? $params{template} : $self->_agent_template;
 337   my $templatefile = $self->template_conf. $format;
 338   $templatefile .= "_$template"
 339     if length($template) && $conf->exists($templatefile."_$template");
 340
 341   # the base template
 342   my @invoice_template = map "$_\n", $conf->config($templatefile)
 343     or die "cannot load config data $templatefile";
 344
 345   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 346     #change this to a die when the old code is removed
 347     # it's been almost ten years, changing it to a die
 348     die "old-style invoice template $templatefile; ".
 349          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 350          #$old_latex = 'true';
 351          #@invoice_template = _translate_old_latex_format(@invoice_template);
 352   }
 353
 354   warn "$me print_generic creating T:T object\n"
 355     if $DEBUG > 1;
 356
 357   my $text_template = new Text::Template(
 358     TYPE => 'ARRAY',
 359     SOURCE => \@invoice_template,
 360     DELIMITERS => $delimiters{$format},
 361   );
 362
 363   warn "$me print_generic compiling T:T object\n"
 364     if $DEBUG > 1;
 365
 366   $text_template->compile()
 367     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 368
 369
 370   # additional substitution could possibly cause breakage in existing templates
 371   my %convert_maps = (
 372     'latex' => {
 373                  'notes'         => sub { map "$_", @_ },
 374                  'footer'        => sub { map "$_", @_ },
 375                  'smallfooter'   => sub { map "$_", @_ },
 376                  'returnaddress' => sub { map "$_", @_ },
 377                  'coupon'        => sub { map "$_", @_ },
 378                  'summary'       => sub { map "$_", @_ },
 379                },
 380     'html'  => {
 381                  'notes' =>
 382                    sub {
 383                      map {
 384                        s/%%(.*)$/<!-- $1 -->/g;
 385                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 386                        s/\\begin\{enumerate\}/<ol>/g;
 387                        s/\\item /  <li>/g;
 388                        s/\\end\{enumerate\}/<\/ol>/g;
 389                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 390                        s/\\\\\*/<br>/g;
 391                        s/\\dollar ?/\$/g;
 392                        s/\\#/#/g;
 393                        s/~/&nbsp;/g;
 394                        $_;
 395                      }  @_
 396                    },
 397                  'footer' =>
 398                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 399                  'smallfooter' =>
 400                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 401                  'returnaddress' =>
 402                    sub {
 403                      map {
 404                        s/~/&nbsp;/g;
 405                        s/\\\\\*?\s*$/<BR>/;
 406                        s/\\hyphenation\{[\w\s\-]+}//;
 407                        s/\\([&])/$1/g;
 408                        $_;
 409                      }  @_
 410                    },
 411                  'coupon'        => sub { "" },
 412                  'summary'       => sub { "" },
 413                },
 414     'template' => {
 415                  'notes' =>
 416                    sub {
 417                      map {
 418                        s/%%.*$//g;
 419                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 420                        s/\\begin\{enumerate\}//g;
 421                        s/\\item /  * /g;
 422                        s/\\end\{enumerate\}//g;
 423                        s/\\textbf\{(.*)\}/$1/g;
 424                        s/\\\\\*/ /;
 425                        s/\\dollar ?/\$/g;
 426                        $_;
 427                      }  @_
 428                    },
 429                  'footer' =>
 430                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 431                  'smallfooter' =>
 432                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 433                  'returnaddress' =>
 434                    sub {
 435                      map {
 436                        s/~/ /g;
 437                        s/\\\\\*?\s*$/\n/;             # dubious
 438                        s/\\hyphenation\{[\w\s\-]+}//;
 439                        $_;
 440                      }  @_
 441                    },
 442                  'coupon'        => sub { "" },
 443                  'summary'       => sub { "" },
 444                },
 445   );
 446
 447
 448   # hashes for differing output formats
 449   my %nbsps = ( 'latex'    => '~',
 450                 'html'     => '',    # '&nbps;' would be nice
 451                 'template' => '',    # not used
 452               );
 453   my $nbsp = $nbsps{$format};
 454
 455   my %escape_functions = ( 'latex'    => \&_latex_escape,
 456                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 457                            'template' => sub { shift },
 458                          );
 459   my $escape_function = $escape_functions{$format};
 460   my $escape_function_nonbsp = ($format eq 'html')
 461                                  ? \&_html_escape : $escape_function;
 462
 463   my %newline_tokens = (  'latex'     => '\\\\',
 464                           'html'      => '<br>',
 465                           'template'  => "\n",
 466                         );
 467   my $newline_token = $newline_tokens{$format};
 468
 469   warn "$me generating template variables\n"
 470     if $DEBUG > 1;
 471
 472   # generate template variables
 473   my $returnaddress;
 474
 475   if (
 476          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 477                                         $template
 478                                       )
 479                 )
 480        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 481                                         $template
 482                                       )
 483                 )
 484   ) {
 485
 486     $returnaddress = join("\n",
 487       $conf->config_orbase("invoice_${format}returnaddress", $template)
 488     );
 489
 490   } elsif ( grep /\S/,
 491             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 492
 493     my $convert_map = $convert_maps{$format}{'returnaddress'};
 494     $returnaddress =
 495       join( "\n",
 496             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 497                                                  $template
 498                                                )
 499                          )
 500           );
 501   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 502
 503     my $convert_map = $convert_maps{$format}{'returnaddress'};
 504     $returnaddress = join( "\n", &$convert_map(
 505                                    map { s/( {2,})/'~' x length($1)/eg;
 506                                          s/$/\\\\\*/;
 507                                          $_
 508                                        }
 509                                      ( $conf->config('company_name', $cust_main->agentnum),
 510                                        $conf->config('company_address', $cust_main->agentnum),
 511                                      )
 512                                  )
 513                      );
 514
 515   } else {
 516
 517     my $warning = "Couldn't find a return address; ".
 518                   "do you need to set the company_address configuration value?";
 519     warn "$warning\n";
 520     $returnaddress = $nbsp;
 521     #$returnaddress = $warning;
 522
 523   }
 524
 525   warn "$me generating invoice data\n"
 526     if $DEBUG > 1;
 527
 528   my $agentnum = $cust_main->agentnum;
 529
 530   my %invoice_data = (
 531
 532     #invoice from info
 533     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 534     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 535     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 536     'returnaddress'   => $returnaddress,
 537     'agent'           => &$escape_function($cust_main->agent->agent),
 538
 539     #invoice/quotation info
 540     'no_number'       => $params{'no_number'},
 541     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 542     'quotationnum'    => $self->quotationnum,
 543     'no_date'         => $params{'no_date'},
 544     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 545       # workaround for inconsistent behavior in the early plain text
 546       # templates; see RT#28271
 547     'date'            => ( $params{'no_date'}
 548                              ? ''
 549                              : ($format eq 'template'
 550                                ? $self->_date
 551                                : $self->time2str_local('long', $self->_date, $format)
 552                                )
 553                          ),
 554     'today'           => $self->time2str_local('long', $today, $format),
 555     'terms'           => $self->terms,
 556     'template'        => $template, #params{'template'},
 557     'notice_name'     => $notice_name, # escape?
 558     'current_charges' => sprintf("%.2f", $self->charged),
 559     'duedate'         => $self->due_date2str('rdate'), #date_format?
 560
 561     #customer info
 562     'custnum'         => $cust_main->display_custnum,
 563     'prospectnum'     => $cust_main->prospectnum,
 564     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 565     ( map { $_ => &$escape_function($cust_main->$_()) }
 566         qw( company address1 address2 city state zip fax )
 567     ),
 568     'payname'         => &$escape_function( $cust_main->invoice_attn
 569                                              || $cust_main->contact_firstlast ),
 570
 571     #global config
 572     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 573     'unitprices'      => $conf->exists('invoice-unitprice'),
 574     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 575     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 576     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 577
 578     #layout info -- would be fancy to calc some of this and bury the template
 579     #               here in the code
 580     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 581     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 582     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 583     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 584     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 585     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 586     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 587     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 588     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 589     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 590
 591     # better hang on to conf_dir for a while (for old templates)
 592     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 593
 594     #these are only used when doing paged plaintext
 595     'page'            => 1,
 596     'total_pages'     => 1,
 597
 598   );
 599
 600   #localization
 601   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 602   # prototype here to silence warnings
 603   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 604
 605   my $min_sdate = 999999999999;
 606   my $max_edate = 0;
 607   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 608     next unless $cust_bill_pkg->pkgnum > 0;
 609     $min_sdate = $cust_bill_pkg->sdate
 610       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 611     $max_edate = $cust_bill_pkg->edate
 612       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 613   }
 614
 615   $invoice_data{'bill_period'} = '';
 616   $invoice_data{'bill_period'} =
 617       $self->time2str_local('%e %h', $min_sdate, $format)
 618       . " to " .
 619       $self->time2str_local('%e %h', $max_edate, $format)
 620     if ($max_edate != 0 && $min_sdate != 999999999999);
 621
 622   $invoice_data{finance_section} = '';
 623   if ( $conf->config('finance_pkgclass') ) {
 624     my $pkg_class =
 625       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 626     $invoice_data{finance_section} = $pkg_class->categoryname;
 627   }
 628   $invoice_data{finance_amount} = '0.00';
 629   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 630
 631   my $countrydefault = $conf->config('countrydefault') || 'US';
 632   foreach ( qw( address1 address2 city state zip country fax) ){
 633     my $method = 'ship_'.$_;
 634     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 635   }
 636   if ( length($cust_main->ship_company) ) {
 637     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 638   } else {
 639     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 640   }
 641   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 642   $invoice_data{'ship_country'} = ''
 643     if ( $invoice_data{'ship_country'} eq $countrydefault );
 644
 645   $invoice_data{'cid'} = $params{'cid'}
 646     if $params{'cid'};
 647
 648   if ( $cust_main->country eq $countrydefault ) {
 649     $invoice_data{'country'} = '';
 650   } else {
 651     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 652   }
 653
 654   my @address = ();
 655   $invoice_data{'address'} = \@address;
 656   push @address,
 657     $invoice_data{'payname'}.
 658       ( $cust_main->po_number
 659           ? " (P.O. #". $cust_main->po_number. ")"
 660           : ''
 661       )
 662   ;
 663   push @address, $cust_main->company
 664     if $cust_main->company;
 665   push @address, $cust_main->address1;
 666   push @address, $cust_main->address2
 667     if $cust_main->address2;
 668   push @address,
 669     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 670   push @address, $invoice_data{'country'}
 671     if $invoice_data{'country'};
 672   push @address, ''
 673     while (scalar(@address) < 5);
 674
 675   $invoice_data{'logo_file'} = $params{'logo_file'}
 676     if $params{'logo_file'};
 677   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 678     if $params{'barcode_file'};
 679   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 680     if $params{'barcode_img'};
 681   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 682     if $params{'barcode_cid'};
 683
 684   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 685 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 686   #my $balance_due = $self->owed + $pr_total - $cr_total;
 687   my $balance_due = $self->owed + $pr_total;
 688
 689   # the sum of amount owed on all invoices
 690   # (this is used in the summary & on the payment coupon)
 691   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 692
 693   # flag telling this invoice to have a first-page summary
 694   my $summarypage = '';
 695
 696   if ( $self->custnum && $self->invnum ) {
 697     # XXX should be an FS::cust_bill method to set the defaults, instead
 698     # of checking the type here
 699
 700     # info from customer's last invoice before this one, for some
 701     # summary formats
 702     $invoice_data{'last_bill'} = {};
 703
 704     my $last_bill = $self->previous_bill;
 705     if ( $last_bill ) {
 706
 707       # "balance_date_range" unfortunately is unsuitable for this, since it
 708       # cares about application dates.  We want to know the sum of all
 709       # _top-level transactions_ dated before the last invoice.
 710       my @sql =
 711         map "$_ WHERE _date <= ? AND custnum = ?", (
 712           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 713           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 714           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 715           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 716         );
 717
 718       # the customer's current balance immediately after generating the last
 719       # bill
 720
 721       my $last_bill_balance = $last_bill->charged;
 722       foreach (@sql) {
 723         my $delta = FS::Record->scalar_sql(
 724           $_,
 725           $last_bill->_date - 1,
 726           $self->custnum,
 727         );
 728         $last_bill_balance += $delta;
 729       }
 730
 731       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 732
 733       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 734         $last_bill->invnum,
 735         $self->time2str_local('%D', $last_bill->_date),
 736         $last_bill_balance
 737       ) if $DEBUG > 0;
 738       # ("true_previous_balance" is a terrible name, but at least it's no
 739       # longer stored in the database)
 740       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 741
 742       # the change in balance from immediately after that invoice
 743       # to immediately before this one
 744       my $before_this_bill_balance = 0;
 745       foreach (@sql) {
 746         my $delta = FS::Record->scalar_sql(
 747           $_,
 748           $self->_date - 1,
 749           $self->custnum,
 750         );
 751         $before_this_bill_balance += $delta;
 752       }
 753       $invoice_data{'balance_adjustments'} =
 754         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 755
 756       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 757                    $invoice_data{'balance_adjustments'}
 758       ) if $DEBUG > 0;
 759
 760       # the sum of amount owed on all previous invoices
 761       # ($pr_total is used elsewhere but not as $previous_balance)
 762       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 763
 764       $invoice_data{'last_bill'}{'_date'} = $last_bill->_date; #unformatted
 765       my (@payments, @credits);
 766       # for formats that itemize previous payments
 767       foreach my $cust_pay ( qsearch('cust_pay', {
 768                               'custnum' => $self->custnum,
 769                               '_date'   => { op => '>=',
 770                                              value => $last_bill->_date }
 771                              } ) )
 772       {
 773         next if $cust_pay->_date > $self->_date;
 774         push @payments, {
 775             '_date'       => $cust_pay->_date,
 776             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 777             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 778             'amount'      => sprintf('%.2f', $cust_pay->paid),
 779         };
 780         # not concerned about applications
 781       }
 782       foreach my $cust_credit ( qsearch('cust_credit', {
 783                               'custnum' => $self->custnum,
 784                               '_date'   => { op => '>=',
 785                                              value => $last_bill->_date }
 786                              } ) )
 787       {
 788         next if $cust_credit->_date > $self->_date;
 789         push @credits, {
 790             '_date'       => $cust_credit->_date,
 791             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 792             'creditreason'=> $cust_credit->reason,
 793             'amount'      => sprintf('%.2f', $cust_credit->amount),
 794         };
 795       }
 796       $invoice_data{'previous_payments'} = \@payments;
 797       $invoice_data{'previous_credits'}  = \@credits;
 798     } else {
 799       # there is no $last_bill
 800       $invoice_data{'true_previous_balance'} =
 801       $invoice_data{'balance_adjustments'}   =
 802       $invoice_data{'previous_balance'}      = '0.00';
 803       $invoice_data{'previous_payments'} = [];
 804       $invoice_data{'previous_credits'} = [];
 805     }
 806
 807     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 808       $invoice_data{'summarypage'} = $summarypage = 1;
 809     }
 810
 811   } # if this is an invoice
 812
 813   warn "$me substituting variables in notes, footer, smallfooter\n"
 814     if $DEBUG > 1;
 815
 816   my $tc = $self->template_conf;
 817   my @include = ( [ $tc,        'notes' ],
 818                   [ 'invoice_', 'footer' ],
 819                   [ 'invoice_', 'smallfooter', ],
 820                   [ 'invoice_', 'watermark' ],
 821                 );
 822   push @include, [ $tc,        'coupon', ]
 823     unless $params{'no_coupon'};
 824
 825   foreach my $i (@include) {
 826
 827     # load the configuration for this sub-template
 828
 829     my($base, $include) = @$i;
 830
 831     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 832
 833     my @inc_src = $conf->config($inc_file, $agentnum);
 834     if (!@inc_src) {
 835       my $converter = $convert_maps{$format}{$include};
 836       if ( $converter ) {
 837         # then attempt to convert LaTeX to the requested format
 838         $inc_file = $conf->key_orbase($base.'latex'.$include, $template);
 839         @inc_src = &$converter( $conf->config($inc_file, $agentnum) );
 840         foreach (@inc_src) {
 841           # this isn't included in the convert_maps
 842           my ($open, $close) = @{ $delimiters{$format} };
 843           s/\[\@--/$open/g;
 844           s/--\@\]/$close/g;
 845         }
 846       }
 847     } # else @inc_src is empty and that's fine
 848
 849     # make a Text::Template out of it
 850
 851     my $inc_tt = new Text::Template (
 852       TYPE       => 'ARRAY',
 853       SOURCE     => [ map "$_\n", @inc_src ],
 854       DELIMITERS => $delimiters{$format},
 855     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 856
 857     unless ( $inc_tt->compile() ) {
 858       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 859       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 860       die $error;
 861     }
 862
 863     # fill in variables
 864
 865     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 866
 867     $invoice_data{$include} =~ s/\n+$//
 868       if ($format eq 'latex');
 869   }
 870
 871   # let invoices use either of these as needed
 872   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 873     ? $cust_main->payinfo : '';
 874   $invoice_data{'po_line'} =
 875     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 876       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 877       : $nbsp;
 878
 879   my %money_chars = ( 'latex'    => '',
 880                       'html'     => $conf->config('money_char') || '$',
 881                       'template' => '',
 882                     );
 883   my $money_char = $money_chars{$format};
 884
 885   # extremely dubious
 886   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 887                             'html'     => $conf->config('money_char') || '$',
 888                             'template' => '',
 889                           );
 890   my $other_money_char = $other_money_chars{$format};
 891   $invoice_data{'dollar'} = $other_money_char;
 892
 893   my %minus_signs = ( 'latex'    => '$-$',
 894                       'html'     => '&minus;',
 895                       'template' => '- ' );
 896   my $minus = $minus_signs{$format};
 897
 898   my @detail_items = ();
 899   my @total_items = ();
 900   my @buf = ();
 901   my @sections = ();
 902
 903   $invoice_data{'detail_items'} = \@detail_items;
 904   $invoice_data{'total_items'} = \@total_items;
 905   $invoice_data{'buf'} = \@buf;
 906   $invoice_data{'sections'} = \@sections;
 907
 908   warn "$me generating sections\n"
 909     if $DEBUG > 1;
 910
 911   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 912   my $multisection = $self->has_sections;
 913   $conf->exists($tc.'sections', $cust_main->agentnum) ||
 914                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 915   $invoice_data{'multisection'} = $multisection;
 916   my $late_sections;
 917   my $extra_sections = [];
 918   my $extra_lines = ();
 919
 920   # default section ('Charges')
 921   my $default_section = { 'description' => '',
 922                           'subtotal'    => '',
 923                           'no_subtotal' => 1,
 924                         };
 925
 926   # Previous Charges section
 927   # subtotal is the first return value from $self->previous
 928   my $previous_section;
 929   # if the invoice has major sections, or if we're summarizing previous
 930   # charges with a single line, or if we've been specifically told to put them
 931   # in a section, create a section for previous charges:
 932   if ( $multisection or
 933        $conf->exists('previous_balance-summary_only') or
 934        $conf->exists('previous_balance-section') ) {
 935
 936     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 937                            'subtotal'    => $other_money_char.
 938                                             sprintf('%.2f', $pr_total),
 939                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 940                          };
 941     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 942       join(' / ', map { $cust_main->balance_date_range(@$_) }
 943                   $self->_prior_month30s
 944           )
 945       if $conf->exists('invoice_include_aging');
 946
 947   } else {
 948     # otherwise put them in the main section
 949     $previous_section = $default_section;
 950   }
 951
 952   my $adjust_section = {
 953     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 954     'adjust_section' => 1,
 955     'subtotal'       => 0,   # adjusted below
 956   };
 957   my $adjust_weight = _pkg_category($adjust_section->{description})
 958                         ? _pkg_category($adjust_section->{description})->weight
 959                         : 0;
 960   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 961   # Note: 'sort_weight' here is actually a flag telling whether there is an
 962   # explicit package category for the adjust section. If so, certain behavior
 963   # happens.
 964   $adjust_section->{'sort_weight'} = $adjust_weight;
 965
 966
 967   if ( $multisection ) {
 968     ($extra_sections, $extra_lines) =
 969       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 970       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 971       && $self->can('_items_extra_usage_sections');
 972
 973     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 974
 975     push @detail_items, @$extra_lines if $extra_lines;
 976
 977     # the code is written so that both methods can be used together, but
 978     # we haven't yet changed the template to take advantage of that, so for
 979     # now, treat them as mutually exclusive.
 980     my %section_method = ( by_category => 1 );
 981     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 982       %section_method = ( by_location => 1 );
 983     }
 984     my ($early, $late) =
 985       $self->_items_sections( 'summary' => $summarypage,
 986                               'escape'  => $escape_function_nonbsp,
 987                               'extra_sections' => $extra_sections,
 988                               'format'  => $format,
 989                               %section_method
 990                             );
 991     push @sections, @$early;
 992     $late_sections = $late;
 993
 994     if (    $conf->exists('svc_phone_sections')
 995          && $self->can('_items_svc_phone_sections')
 996        )
 997     {
 998       my ($phone_sections, $phone_lines) =
 999         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1000       push @{$late_sections}, @$phone_sections;
1001       push @detail_items, @$phone_lines;
1002     }
1003     if ( $conf->exists('voip-cust_accountcode_cdr')
1004          && $cust_main->accountcode_cdr
1005          && $self->can('_items_accountcode_cdr')
1006        )
1007     {
1008       my ($accountcode_section, $accountcode_lines) =
1009         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1010       if ( scalar(@$accountcode_lines) ) {
1011           push @{$late_sections}, $accountcode_section;
1012           push @detail_items, @$accountcode_lines;
1013       }
1014     }
1015   } else {# not multisection
1016     # make a default section
1017     push @sections, $default_section;
1018     # and calculate the finance charge total, since it won't get done otherwise.
1019     # and the default section total
1020     # XXX possibly finance_pkgclass should not be used in this manner?
1021     my @finance_charges;
1022     my @charges;
1023     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1024       if ( $invoice_data{finance_section} and
1025         grep { $_->section eq $invoice_data{finance_section} }
1026            $cust_bill_pkg->cust_bill_pkg_display ) {
1027         # I think these are always setup fees, but just to be sure...
1028         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1029       } else {
1030         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1031       }
1032     }
1033     $invoice_data{finance_amount} =
1034       sprintf('%.2f', sum( @finance_charges ) || 0);
1035     $default_section->{subtotal} = $other_money_char.
1036                                     sprintf('%.2f', sum( @charges ) || 0);
1037   }
1038
1039   # start setting up summary subtotals
1040   my @summary_subtotals;
1041   my $method = $conf->config('summary_subtotals_method');
1042   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1043     # then re-section them by the correct method
1044     my %section_method = ( by_category => 1 );
1045     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1046       %section_method = ( by_location => 1 );
1047     }
1048     my ($early, $late) =
1049       $self->_items_sections( 'summary' => $summarypage,
1050                               'escape'  => $escape_function_nonbsp,
1051                               'extra_sections' => $extra_sections,
1052                               'format'  => $format,
1053                               %section_method
1054                             );
1055     foreach ( @$early ) {
1056       next if $_->{subtotal} == 0;
1057       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1058       push @summary_subtotals, $_;
1059     }
1060   } else {
1061     # subtotal sectioning is the same as for the actual invoice sections
1062     @summary_subtotals = @sections;
1063   }
1064
1065   # Hereafter, push sections to both @sections and @summary_subtotals
1066   # if they belong in both places (e.g. tax section).  Late sections are
1067   # never in @summary_subtotals.
1068
1069   # previous invoice balances in the Previous Charges section if there
1070   # is one, otherwise in the main detail section
1071   # (except if summary_only is enabled, don't show them at all)
1072   if ( $self->can('_items_previous') &&
1073        $self->enable_previous &&
1074        ! $conf->exists('previous_balance-summary_only') ) {
1075
1076     warn "$me adding previous balances\n"
1077       if $DEBUG > 1;
1078
1079     foreach my $line_item ( $self->_items_previous ) {
1080
1081       my $detail = {
1082         ref             => $line_item->{'pkgnum'},
1083         pkgpart         => $line_item->{'pkgpart'},
1084         #quantity        => 1, # not really correct
1085         section         => $previous_section, # which might be $default_section
1086         description     => &$escape_function($line_item->{'description'}),
1087         ext_description => [ map { &$escape_function($_) }
1088                              @{ $line_item->{'ext_description'} || [] }
1089                            ],
1090         amount          => $money_char . $line_item->{'amount'},
1091         product_code    => $line_item->{'pkgpart'} || 'N/A',
1092       };
1093
1094       push @detail_items, $detail;
1095       push @buf, [ $detail->{'description'},
1096                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1097                  ];
1098     }
1099
1100   }
1101
1102   if ( @pr_cust_bill && $self->enable_previous ) {
1103     push @buf, ['','-----------'];
1104     push @buf, [ $self->mt('Total Previous Balance'),
1105                  $money_char. sprintf("%10.2f", $pr_total) ];
1106     push @buf, ['',''];
1107   }
1108
1109   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1110       warn "$me adding DID summary\n"
1111         if $DEBUG > 1;
1112
1113       my ($didsummary,$minutes) = $self->_did_summary;
1114       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1115       push @detail_items,
1116        { 'description' => $didsummary_desc,
1117            'ext_description' => [ $didsummary, $minutes ],
1118        };
1119   }
1120
1121   foreach my $section (@sections, @$late_sections) {
1122
1123     # begin some normalization
1124     $section->{'subtotal'} = $section->{'amount'}
1125       if $multisection
1126          && !exists($section->{subtotal})
1127          && exists($section->{amount});
1128
1129     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1130       if ( $invoice_data{finance_section} &&
1131            $section->{'description'} eq $invoice_data{finance_section} );
1132
1133     $section->{'subtotal'} = $other_money_char.
1134                              sprintf('%.2f', $section->{'subtotal'})
1135       if $multisection;
1136
1137     # continue some normalization
1138     $section->{'amount'}   = $section->{'subtotal'}
1139       if $multisection;
1140
1141
1142     if ( $section->{'description'} ) {
1143       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1144                    [ '', '' ],
1145                  );
1146     }
1147
1148     warn "$me   setting options\n"
1149       if $DEBUG > 1;
1150
1151     my %options = ();
1152     $options{'section'} = $section if $multisection;
1153     $options{'format'} = $format;
1154     $options{'escape_function'} = $escape_function;
1155     $options{'no_usage'} = 1 unless $unsquelched;
1156     $options{'unsquelched'} = $unsquelched;
1157     $options{'summary_page'} = $summarypage;
1158     $options{'skip_usage'} =
1159       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1160     $options{'preref_callback'} = $params{'preref_callback'};
1161
1162     warn "$me   searching for line items\n"
1163       if $DEBUG > 1;
1164
1165     foreach my $line_item ( $self->_items_pkg(%options),
1166                             $self->_items_fee(%options) ) {
1167
1168       warn "$me     adding line item ".
1169            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1170         if $DEBUG > 1;
1171
1172       push @buf, ( [ $line_item->{'description'},
1173                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1174                    ],
1175                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1176                  );
1177
1178       $line_item->{'ref'} = $line_item->{'pkgnum'};
1179       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1180       $line_item->{'section'} = $section;
1181       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1182       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1183
1184       if ( length($line_item->{'unit_amount'}) ) {
1185         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1186       }
1187       $line_item->{'ext_description'} ||= [];
1188
1189       push @detail_items, $line_item;
1190     }
1191
1192     if ( $section->{'description'} ) {
1193       push @buf, ( ['','-----------'],
1194                    [ $section->{'description'}. ' sub-total',
1195                       $section->{'subtotal'} # already formatted this
1196                    ],
1197                    [ '', '' ],
1198                    [ '', '' ],
1199                  );
1200     }
1201
1202   }
1203
1204   $invoice_data{current_less_finance} =
1205     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1206
1207   # if there's anything in the Previous Charges section, prepend it to the list
1208   if ( $pr_total and $previous_section ne $default_section ) {
1209     unshift @sections, $previous_section;
1210     # but not @summary_subtotals
1211   }
1212
1213   warn "$me adding taxes\n"
1214     if $DEBUG > 1;
1215
1216   # create a tax section if we don't yet have one
1217   my $tax_description = 'Taxes, Surcharges, and Fees';
1218   my $tax_section =
1219     List::Util::first { $_->{description} eq $tax_description } @sections;
1220   if (!$tax_section) {
1221     $tax_section = { 'description' => $tax_description };
1222   }
1223   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1224   # if this is an existing tax section, we're merging the tax items into it.
1225   # grab the taxtotal that's already there, strip the money symbol if any
1226   my $taxtotal = $tax_section->{'subtotal'} || 0;
1227   $taxtotal =~ s/^\Q$other_money_char\E//;
1228
1229   # this does nothing
1230   #my $tax_weight = _pkg_category($tax_section->{description})
1231   #                      ? _pkg_category($tax_section->{description})->weight
1232   #                      : 0;
1233   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1234   #$tax_section->{'sort_weight'} = $tax_weight;
1235
1236   my @items_tax = $self->_items_tax;
1237   push @sections, $tax_section if $multisection and @items_tax > 0;
1238
1239   foreach my $tax ( @items_tax ) {
1240
1241     $taxtotal += $tax->{'amount'};
1242
1243     my $description = &$escape_function( $tax->{'description'} );
1244     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1245
1246     if ( $multisection ) {
1247
1248       push @detail_items, {
1249         ext_description => [],
1250         ref          => '',
1251         quantity     => '',
1252         description  => $description,
1253         amount       => $money_char. $amount,
1254         product_code => '',
1255         section      => $tax_section,
1256       };
1257
1258     } else {
1259
1260       push @total_items, {
1261         'total_item'   => $description,
1262         'total_amount' => $other_money_char. $amount,
1263       };
1264
1265     }
1266
1267     push @buf,[ $description,
1268                 $money_char. $amount,
1269               ];
1270
1271   }
1272
1273   if ( @items_tax ) {
1274     my $total = {};
1275     $total->{'total_item'} = $self->mt('Sub-total');
1276     $total->{'total_amount'} =
1277       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1278
1279     if ( $multisection ) {
1280       if ( $taxtotal > 0 ) {
1281         # there are taxes, so prepare the section to be displayed.
1282         # $taxtotal already includes any line items that were already in the
1283         # section (fees, taxes that are charged as packages for some reason).
1284         # also set 'summarized' to false so that this isn't a summary-only
1285         # section.
1286         $tax_section->{'subtotal'} = $other_money_char.
1287                                      sprintf('%.2f', $taxtotal);
1288         $tax_section->{'pretotal'} = 'New charges sub-total '.
1289                                      $total->{'total_amount'};
1290         $tax_section->{'description'} = $self->mt($tax_description);
1291         $tax_section->{'summarized'} = '';
1292
1293         # append it if it's not already there
1294         if ( !grep $tax_section, @sections ) {
1295           push @sections, $tax_section;
1296           push @summary_subtotals, $tax_section;
1297         }
1298       }
1299
1300     } else {
1301       unshift @total_items, $total;
1302     }
1303   }
1304   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1305
1306   ###
1307   # Totals
1308   ###
1309
1310   my %embolden_functions = (
1311     'latex'    => sub { return '\textbf{'. shift(). '}' },
1312     'html'     => sub { return '<b>'. shift(). '</b>' },
1313     'template' => sub { shift },
1314   );
1315   my $embolden_function = $embolden_functions{$format};
1316
1317   if ( $multisection ) {
1318
1319     if ( $adjust_section->{'sort_weight'} ) {
1320       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1321         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1322     } else{
1323       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1324         $other_money_char.  sprintf('%.2f', $self->charged );
1325     }
1326
1327   }
1328
1329   if ( $self->can('_items_total') ) { # should always be true now
1330
1331     # even for multisection, need plain text version
1332
1333     my @new_total_items = $self->_items_total;
1334
1335     push @buf,['','-----------'];
1336
1337     foreach ( @new_total_items ) {
1338       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1339       $_->{'total_item'}   = &$embolden_function( $item );
1340       $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1341       # but if it's multisection, don't append to @total_items. the adjust
1342       # section has all this stuff
1343       push @total_items, $_ if !$multisection;
1344       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1345     }
1346
1347     push @buf, [ '', '' ];
1348
1349     # if we're showing previous invoices, also show previous
1350     # credits and payments
1351     if ( $self->enable_previous
1352           and $self->can('_items_credits')
1353           and $self->can('_items_payments') )
1354       {
1355
1356       # credits
1357       my $credittotal = 0;
1358       foreach my $credit (
1359         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1360       ) {
1361
1362         my $total;
1363         $total->{'total_item'} = &$escape_function($credit->{'description'});
1364         $credittotal += $credit->{'amount'};
1365         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1366         if ( $multisection ) {
1367           push @detail_items, {
1368             ext_description => [],
1369             ref          => '',
1370             quantity     => '',
1371             description  => &$escape_function($credit->{'description'}),
1372             amount       => $money_char . $credit->{'amount'},
1373             product_code => '',
1374             section      => $adjust_section,
1375           };
1376         } else {
1377           push @total_items, $total;
1378         }
1379
1380       }
1381       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1382
1383       #credits (again)
1384       foreach my $credit (
1385         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1386       ) {
1387         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1388       }
1389
1390       # payments
1391       my $paymenttotal = 0;
1392       foreach my $payment (
1393         $self->_items_payments( 'template' => $template )
1394       ) {
1395         my $total = {};
1396         $total->{'total_item'} = &$escape_function($payment->{'description'});
1397         $paymenttotal += $payment->{'amount'};
1398         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1399         if ( $multisection ) {
1400           push @detail_items, {
1401             ext_description => [],
1402             ref          => '',
1403             quantity     => '',
1404             description  => &$escape_function($payment->{'description'}),
1405             amount       => $money_char . $payment->{'amount'},
1406             product_code => '',
1407             section      => $adjust_section,
1408           };
1409         }else{
1410           push @total_items, $total;
1411         }
1412         push @buf, [ $payment->{'description'},
1413                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1414                    ];
1415       }
1416       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1417
1418       if ( $multisection ) {
1419         $adjust_section->{'subtotal'} = $other_money_char.
1420                                         sprintf('%.2f', $credittotal + $paymenttotal);
1421
1422         #why this? because {sort_weight} forces the adjust_section to appear
1423         #in @extra_sections instead of @sections. obviously.
1424         push @sections, $adjust_section
1425           unless $adjust_section->{sort_weight};
1426         # do not summarize; adjustments there are shown according to
1427         # different rules
1428       }
1429
1430       # create Balance Due message
1431       {
1432         my $total;
1433         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1434         $total->{'total_amount'} =
1435           &$embolden_function(
1436             $other_money_char. sprintf('%.2f', #why? $summarypage
1437                                                #  ? $self->charged +
1438                                                #    $self->billing_balance
1439                                                #  :
1440                                                    $self->owed + $pr_total
1441                                       )
1442           );
1443         if ( $multisection && !$adjust_section->{sort_weight} ) {
1444           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1445                                            $total->{'total_amount'};
1446         } else {
1447           push @total_items, $total;
1448         }
1449         push @buf,['','-----------'];
1450         push @buf,[$self->balance_due_msg, $money_char.
1451           sprintf("%10.2f", $balance_due ) ];
1452       }
1453
1454       if ( $conf->exists('previous_balance-show_credit')
1455           and $cust_main->balance < 0 ) {
1456         my $credit_total = {
1457           'total_item'    => &$embolden_function($self->credit_balance_msg),
1458           'total_amount'  => &$embolden_function(
1459             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1460           ),
1461         };
1462         if ( $multisection ) {
1463           $adjust_section->{'posttotal'} .= $newline_token .
1464             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1465         }
1466         else {
1467           push @total_items, $credit_total;
1468         }
1469         push @buf,['','-----------'];
1470         push @buf,[$self->credit_balance_msg, $money_char.
1471           sprintf("%10.2f", -$cust_main->balance ) ];
1472       }
1473     }
1474
1475   } #end of default total adding ! can('_items_total')
1476
1477   if ( $multisection ) {
1478     if (    $conf->exists('svc_phone_sections')
1479          && $self->can('_items_svc_phone_sections')
1480        )
1481     {
1482       my $total;
1483       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1484       $total->{'total_amount'} =
1485         &$embolden_function(
1486           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1487         );
1488       my $last_section = pop @sections;
1489       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1490                                      $total->{'total_amount'};
1491       push @sections, $last_section;
1492     }
1493     push @sections, @$late_sections
1494       if $unsquelched;
1495   }
1496
1497   # make a discounts-available section, even without multisection
1498   if ( $conf->exists('discount-show_available')
1499        and my @discounts_avail = $self->_items_discounts_avail ) {
1500     my $discount_section = {
1501       'description' => $self->mt('Discounts Available'),
1502       'subtotal'    => '',
1503       'no_subtotal' => 1,
1504     };
1505
1506     push @sections, $discount_section; # do not summarize
1507     push @detail_items, map { +{
1508         'ref'         => '', #should this be something else?
1509         'section'     => $discount_section,
1510         'description' => &$escape_function( $_->{description} ),
1511         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1512         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1513     } } @discounts_avail;
1514   }
1515
1516   # not adding any more sections after this
1517   $invoice_data{summary_subtotals} = \@summary_subtotals;
1518
1519   # usage subtotals
1520   if ( $conf->exists('usage_class_summary')
1521        and $self->can('_items_usage_class_summary') ) {
1522     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1523     if ( @usage_subtotals ) {
1524       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1525       unshift @detail_items, @usage_subtotals;
1526     }
1527   }
1528
1529   # invoice history "section" (not really a section)
1530   # not to be included in any subtotals, completely independent of
1531   # everything...
1532   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1533     my %history;
1534     my %monthorder;
1535     foreach my $cust_bill ( $cust_main->cust_bill ) {
1536       # XXX hardcoded format, and currently only 'charged'; add other fields
1537       # if they become necessary
1538       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1539       $history{$date} ||= 0;
1540       $history{$date} += $cust_bill->charged;
1541       # just so we have a numeric sort key
1542       $monthorder{$date} ||= $cust_bill->_date;
1543     }
1544     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1545                         keys %history;
1546     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1547     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1548   }
1549
1550   # service locations: another option for template customization
1551   my %location_info;
1552   foreach my $item (@detail_items) {
1553     if ( $item->{locationnum} ) {
1554       $location_info{ $item->{locationnum} } ||= {
1555         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1556       };
1557     }
1558   }
1559   $invoice_data{location_info} = \%location_info;
1560
1561   # debugging hook: call this with 'diag' => 1 to just get a hash of
1562   # the invoice variables
1563   return \%invoice_data if ( $params{'diag'} );
1564
1565   # All sections and items are built; now fill in templates.
1566   my @includelist = ();
1567   push @includelist, 'summary' if $summarypage;
1568   foreach my $include ( @includelist ) {
1569
1570     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1571     my @inc_src;
1572
1573     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1574
1575       @inc_src = $conf->config($inc_file, $agentnum);
1576
1577     } else {
1578
1579       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1580
1581       my $convert_map = $convert_maps{$format}{$include};
1582
1583       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1584                        s/--\@\]/$delimiters{$format}[1]/g;
1585                        $_;
1586                      }
1587                  &$convert_map( $conf->config($inc_file, $agentnum) );
1588
1589     }
1590
1591     my $inc_tt = new Text::Template (
1592       TYPE       => 'ARRAY',
1593       SOURCE     => [ map "$_\n", @inc_src ],
1594       DELIMITERS => $delimiters{$format},
1595     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1596
1597     unless ( $inc_tt->compile() ) {
1598       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1599       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1600       die $error;
1601     }
1602
1603     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1604
1605     $invoice_data{$include} =~ s/\n+$//
1606       if ($format eq 'latex');
1607   }
1608
1609   $invoice_lines = 0;
1610   my $wasfunc = 0;
1611   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1612     /invoice_lines\((\d*)\)/;
1613     $invoice_lines += $1 || scalar(@buf);
1614     $wasfunc=1;
1615   }
1616   die "no invoice_lines() functions in template?"
1617     if ( $format eq 'template' && !$wasfunc );
1618
1619   if ($format eq 'template') {
1620
1621     if ( $invoice_lines ) {
1622       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1623       $invoice_data{'total_pages'}++
1624         if scalar(@buf) % $invoice_lines;
1625     }
1626
1627     #setup subroutine for the template
1628     $invoice_data{invoice_lines} = sub {
1629       my $lines = shift || scalar(@buf);
1630       map {
1631         scalar(@buf)
1632           ? shift @buf
1633           : [ '', '' ];
1634       }
1635       ( 1 .. $lines );
1636     };
1637
1638     my $lines;
1639     my @collect;
1640     while (@buf) {
1641       push @collect, split("\n",
1642         $text_template->fill_in( HASH => \%invoice_data )
1643       );
1644       $invoice_data{'page'}++;
1645     }
1646     map "$_\n", @collect;
1647
1648   } else { # this is where we actually create the invoice
1649
1650     warn "filling in template for invoice ". $self->invnum. "\n"
1651       if $DEBUG;
1652     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1653       if $DEBUG > 1;
1654
1655     $text_template->fill_in(HASH => \%invoice_data);
1656   }
1657 }
1658
1659 sub notice_name { '('.shift->table.')'; }
1660
1661 # this is not supposed to happen
1662 sub template_conf { warn "bare FS::Template_Mixin::template_conf";
1663   'invoice_';
1664 }
1665
1666 # helper routine for generating date ranges
1667 sub _prior_month30s {
1668   my $self = shift;
1669   my @ranges = (
1670    [ 1,       2592000 ], # 0-30 days ago
1671    [ 2592000, 5184000 ], # 30-60 days ago
1672    [ 5184000, 7776000 ], # 60-90 days ago
1673    [ 7776000, 0       ], # 90+   days ago
1674   );
1675
1676   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1677           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1678       ] }
1679   @ranges;
1680 }
1681
1682 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1683
1684 Returns an postscript invoice, as a scalar.
1685
1686 Options can be passed as a hashref (recommended) or as a list of time, template
1687 and then any key/value pairs for any other options.
1688
1689 I<time> an optional value used to control the printing of overdue messages.  The
1690 default is now.  It isn't the date of the invoice; that's the `_date' field.
1691 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1692 L<Time::Local> and L<Date::Parse> for conversion functions.
1693
1694 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1695
1696 =cut
1697
1698 sub print_ps {
1699   my $self = shift;
1700
1701   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1702   my $ps = generate_ps($file);
1703   unlink($logofile);
1704   unlink($barcodefile) if $barcodefile;
1705
1706   $ps;
1707 }
1708
1709 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1710
1711 Returns an PDF invoice, as a scalar.
1712
1713 Options can be passed as a hashref (recommended) or as a list of time, template
1714 and then any key/value pairs for any other options.
1715
1716 I<time> an optional value used to control the printing of overdue messages.  The
1717 default is now.  It isn't the date of the invoice; that's the `_date' field.
1718 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1719 L<Time::Local> and L<Date::Parse> for conversion functions.
1720
1721 I<template>, if specified, is the name of a suffix for alternate invoices.
1722
1723 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1724
1725 =cut
1726
1727 sub print_pdf {
1728   my $self = shift;
1729
1730   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1731   my $pdf = generate_pdf($file);
1732   unlink($logofile);
1733   unlink($barcodefile) if $barcodefile;
1734
1735   $pdf;
1736 }
1737
1738 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1739
1740 Returns an HTML invoice, as a scalar.
1741
1742 I<time> an optional value used to control the printing of overdue messages.  The
1743 default is now.  It isn't the date of the invoice; that's the `_date' field.
1744 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1745 L<Time::Local> and L<Date::Parse> for conversion functions.
1746
1747 I<template>, if specified, is the name of a suffix for alternate invoices.
1748
1749 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1750
1751 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1752 when emailing the invoice as part of a multipart/related MIME email.
1753
1754 =cut
1755
1756 sub print_html {
1757   my $self = shift;
1758   my %params;
1759   if ( ref($_[0]) ) {
1760     %params = %{ shift() };
1761   } else {
1762     %params = @_;
1763   }
1764   $params{'format'} = 'html';
1765
1766   $self->print_generic( %params );
1767 }
1768
1769 # quick subroutine for print_latex
1770 #
1771 # There are ten characters that LaTeX treats as special characters, which
1772 # means that they do not simply typeset themselves:
1773 #      # $ % & ~ _ ^ \ { }
1774 #
1775 # TeX ignores blanks following an escaped character; if you want a blank (as
1776 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1777
1778 sub _latex_escape {
1779   my $value = shift;
1780   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1781   $value =~ s/([<>])/\$$1\$/g;
1782   $value;
1783 }
1784
1785 sub _html_escape {
1786   my $value = shift;
1787   encode_entities($value);
1788   $value;
1789 }
1790
1791 sub _html_escape_nbsp {
1792   my $value = _html_escape(shift);
1793   $value =~ s/ +/&nbsp;/g;
1794   $value;
1795 }
1796
1797 #utility methods for print_*
1798
1799 sub _translate_old_latex_format {
1800   warn "_translate_old_latex_format called\n"
1801     if $DEBUG;
1802
1803   my @template = ();
1804   while ( @_ ) {
1805     my $line = shift;
1806
1807     if ( $line =~ /^%%Detail\s*$/ ) {
1808
1809       push @template, q![@--!,
1810                       q!  foreach my $_tr_line (@detail_items) {!,
1811                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1812                       q!      $_tr_line->{'description'} .= !,
1813                       q!        "\\tabularnewline\n~~".!,
1814                       q!        join( "\\tabularnewline\n~~",!,
1815                       q!          @{$_tr_line->{'ext_description'}}!,
1816                       q!        );!,
1817                       q!    }!;
1818
1819       while ( ( my $line_item_line = shift )
1820               !~ /^%%EndDetail\s*$/                            ) {
1821         $line_item_line =~ s/'/\\'/g;    # nice LTS
1822         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1823         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1824         push @template, "    \$OUT .= '$line_item_line';";
1825       }
1826
1827       push @template, '}',
1828                       '--@]';
1829       #' doh, gvim
1830     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1831
1832       push @template, '[@--',
1833                       '  foreach my $_tr_line (@total_items) {';
1834
1835       while ( ( my $total_item_line = shift )
1836               !~ /^%%EndTotalDetails\s*$/                      ) {
1837         $total_item_line =~ s/'/\\'/g;    # nice LTS
1838         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1839         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1840         push @template, "    \$OUT .= '$total_item_line';";
1841       }
1842
1843       push @template, '}',
1844                       '--@]';
1845
1846     } else {
1847       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1848       push @template, $line;
1849     }
1850
1851   }
1852
1853   if ($DEBUG) {
1854     warn "$_\n" foreach @template;
1855   }
1856
1857   (@template);
1858 }
1859
1860 =item terms
1861
1862 =cut
1863
1864 sub terms {
1865   my $self = shift;
1866   my $conf = $self->conf;
1867
1868   #check for an invoice-specific override
1869   return $self->invoice_terms if $self->invoice_terms;
1870
1871   #check for a customer- specific override
1872   my $cust_main = $self->cust_main;
1873   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1874
1875   my $agentnum = '';
1876   if ( $cust_main ) {
1877     $agentnum = $cust_main->agentnum;
1878   } elsif ( my $prospect_main = $self->prospect_main ) {
1879     $agentnum = $prospect_main->agentnum;
1880   }
1881
1882   #use configured default
1883   $conf->config('invoice_default_terms', $agentnum) || '';
1884 }
1885
1886 =item due_date
1887
1888 =cut
1889
1890 sub due_date {
1891   my $self = shift;
1892   my $duedate = '';
1893   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1894     $duedate = $self->_date() + ( $1 * 86400 );
1895   }
1896   $duedate;
1897 }
1898
1899 =item due_date2str
1900
1901 =cut
1902
1903 sub due_date2str {
1904   my $self = shift;
1905   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1906 }
1907
1908 =item balance_due_msg
1909
1910 =cut
1911
1912 sub balance_due_msg {
1913   my $self = shift;
1914   my $msg = $self->mt('Balance Due');
1915   return $msg unless $self->terms; # huh?
1916   if ( !$self->conf->exists('invoice_show_prior_due_date')
1917        or $self->conf->exists('invoice_sections') ) {
1918     # if enabled, the due date is shown with Total New Charges (see
1919     # _items_total) and not here
1920     # (yes, or if invoice_sections is enabled; this is just for compatibility)
1921     if ( $self->due_date ) {
1922       $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1923         $self->due_date2str('short');
1924     } elsif ( $self->terms ) {
1925       $msg .= ' - '. $self->mt($self->terms);
1926     }
1927   }
1928   $msg;
1929 }
1930
1931 =item balance_due_date
1932
1933 =cut
1934
1935 sub balance_due_date {
1936   my $self = shift;
1937   my $conf = $self->conf;
1938   my $duedate = '';
1939   my $terms = $self->terms;
1940   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1941     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1942   }
1943   $duedate;
1944 }
1945
1946 sub credit_balance_msg {
1947   my $self = shift;
1948   $self->mt('Credit Balance Remaining')
1949 }
1950
1951 =item _date_pretty
1952
1953 Returns a string with the date, for example: "3/20/2008", localized for the
1954 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1955
1956 =cut
1957
1958 sub _date_pretty {
1959   my $self = shift;
1960   $self->time2str_local('short', $self->_date);
1961 }
1962
1963 =item _date_pretty_unlocalized
1964
1965 Returns a string with the date, for example: "3/20/2008", in the format
1966 configured for the back-office.  Use _date_pretty for end-customer display use.
1967
1968 =cut
1969
1970 sub _date_pretty_unlocalized {
1971   my $self = shift;
1972   time2str($date_format, $self->_date);
1973 }
1974
1975 =item email HASHREF
1976
1977 Emails this template.
1978
1979 Options are passed as a hashref.  Available options:
1980
1981 =over 4
1982
1983 =item from
1984
1985 If specified, overrides the default From: address.
1986
1987 =item notice_name
1988
1989 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1990
1991 =item template
1992
1993 (Deprecated) If specified, is the name of a suffix for alternate template files.
1994
1995 =back
1996
1997 Options accepted by generate_email can also be used.
1998
1999 =cut
2000
2001 sub email {
2002   my $self = shift;
2003   my $opt = shift || {};
2004   if ($opt and !ref($opt)) {
2005     die ref($self). '->email called with positional parameters';
2006   }
2007
2008   return if $self->hide;
2009
2010   my $error = send_email(
2011     $self->generate_email(
2012       'subject'     => $self->email_subject($opt->{template}),
2013       %$opt, # template, etc.
2014     )
2015   );
2016
2017   die "can't email: $error\n" if $error;
2018 }
2019
2020 =item generate_email OPTION => VALUE ...
2021
2022 Options:
2023
2024 =over 4
2025
2026 =item from
2027
2028 sender address, required
2029
2030 =item template
2031
2032 alternate template name, optional
2033
2034 =item subject
2035
2036 email subject, optional
2037
2038 =item notice_name
2039
2040 notice name instead of "Invoice", optional
2041
2042 =back
2043
2044 Returns an argument list to be passed to L<FS::Misc::send_email>.
2045
2046 =cut
2047
2048 use MIME::Entity;
2049
2050 sub generate_email {
2051
2052   my $self = shift;
2053   my %args = @_;
2054   my $conf = $self->conf;
2055
2056   my $me = '[FS::Template_Mixin::generate_email]';
2057
2058   my %return = (
2059     'from'      => $args{'from'},
2060     'subject'   => ($args{'subject'} || $self->email_subject),
2061     'custnum'   => $self->custnum,
2062     'msgtype'   => 'invoice',
2063   );
2064
2065   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2066
2067   my $cust_main = $self->cust_main;
2068
2069   if (ref($args{'to'}) eq 'ARRAY') {
2070     $return{'to'} = $args{'to'};
2071   } elsif ( $cust_main ) {
2072     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2073   }
2074
2075   my $tc = $self->template_conf;
2076
2077   my @text; # array of lines
2078   my $html; # a big string
2079   my @related_parts; # will contain the text/HTML alternative, and images
2080   my $related; # will contain the multipart/related object
2081
2082   if ( $conf->exists($tc. 'email_pdf') ) {
2083     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2084
2085       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2086         if $DEBUG;
2087
2088       my $msg_template = FS::msg_template->by_key($msgnum)
2089         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2090       my %prepared = $msg_template->prepare(
2091         cust_main => $self->cust_main,
2092         object    => $self
2093       );
2094
2095       @text = split(/(?=\n)/, $prepared{'text_body'});
2096       $html = $prepared{'html_body'};
2097
2098     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2099
2100       warn "$me using '${tc}email_pdf_note' in multipart message"
2101         if $DEBUG;
2102       @text = $conf->config($tc.'email_pdf_note');
2103       $html = join('<BR>', @text);
2104
2105     } # else use the plain text invoice
2106   }
2107
2108   if (!@text) {
2109
2110     if ( $conf->config($tc.'template') ) {
2111
2112       warn "$me generating plain text invoice"
2113         if $DEBUG;
2114
2115       # 'print_text' argument is no longer used
2116       @text = $self->print_text(\%args);
2117
2118     } else {
2119
2120       warn "$me no plain text version exists; sending empty message body"
2121         if $DEBUG;
2122
2123     }
2124
2125   }
2126
2127   my $text_part = build MIME::Entity (
2128     'Type'        => 'text/plain',
2129     'Encoding'    => 'quoted-printable',
2130     'Charset'     => 'UTF-8',
2131     #'Encoding'    => '7bit',
2132     'Data'        => \@text,
2133     'Disposition' => 'inline',
2134   );
2135
2136   if (!$html) {
2137
2138     if ( $conf->exists($tc.'html') ) {
2139       warn "$me generating HTML invoice"
2140         if $DEBUG;
2141
2142       $args{'from'} =~ /\@([\w\.\-]+)/;
2143       my $from = $1 || 'example.com';
2144       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2145
2146       my $logo;
2147       my $agentnum = $cust_main ? $cust_main->agentnum
2148                                 : $self->prospect_main->agentnum;
2149       if ( defined($args{'template'}) && length($args{'template'})
2150            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2151          )
2152       {
2153         $logo = 'logo_'. $args{'template'}. '.png';
2154       } else {
2155         $logo = "logo.png";
2156       }
2157       my $image_data = $conf->config_binary( $logo, $agentnum);
2158
2159       push @related_parts, build MIME::Entity
2160         'Type'       => 'image/png',
2161         'Encoding'   => 'base64',
2162         'Data'       => $image_data,
2163         'Filename'   => 'logo.png',
2164         'Content-ID' => "<$content_id>",
2165       ;
2166
2167       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2168         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2169         push @related_parts, build MIME::Entity
2170           'Type'       => 'image/png',
2171           'Encoding'   => 'base64',
2172           'Data'       => $self->invoice_barcode(0),
2173           'Filename'   => 'barcode.png',
2174           'Content-ID' => "<$barcode_content_id>",
2175         ;
2176         $args{'barcode_cid'} = $barcode_content_id;
2177       }
2178
2179       $html = $self->print_html({ 'cid'=>$content_id, %args });
2180     }
2181
2182   }
2183
2184   if ( $html ) {
2185
2186     warn "$me creating HTML/text multipart message"
2187       if $DEBUG;
2188
2189     $return{'nobody'} = 1;
2190
2191     my $alternative = build MIME::Entity
2192       'Type'        => 'multipart/alternative',
2193       #'Encoding'    => '7bit',
2194       'Disposition' => 'inline'
2195     ;
2196
2197     if ( @text ) {
2198       $alternative->add_part($text_part);
2199     }
2200
2201     $alternative->attach(
2202       'Type'        => 'text/html',
2203       'Encoding'    => 'quoted-printable',
2204       'Data'        => [ '<html>',
2205                          '  <head>',
2206                          '    <title>',
2207                          '      '. encode_entities($return{'subject'}),
2208                          '    </title>',
2209                          '  </head>',
2210                          '  <body bgcolor="#e8e8e8">',
2211                          $html,
2212                          '  </body>',
2213                          '</html>',
2214                        ],
2215       'Disposition' => 'inline',
2216       #'Filename'    => 'invoice.pdf',
2217     );
2218
2219     unshift @related_parts, $alternative;
2220
2221     $related = build MIME::Entity 'Type'     => 'multipart/related',
2222                                   'Encoding' => '7bit';
2223
2224     #false laziness w/Misc::send_email
2225     $related->head->replace('Content-type',
2226       $related->mime_type.
2227       '; boundary="'. $related->head->multipart_boundary. '"'.
2228       '; type=multipart/alternative'
2229     );
2230
2231     $related->add_part($_) foreach @related_parts;
2232
2233   }
2234
2235   my @otherparts = ();
2236   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2237
2238     push @otherparts, build MIME::Entity
2239       'Type'        => 'text/csv',
2240       'Encoding'    => '7bit',
2241       'Data'        => [ map { "$_\n" }
2242                            $self->call_details('prepend_billed_number' => 1)
2243                        ],
2244       'Disposition' => 'attachment',
2245       'Filename'    => 'usage-'. $self->invnum. '.csv',
2246     ;
2247
2248   }
2249
2250   if ( $conf->exists($tc.'email_pdf') ) {
2251
2252     #attaching pdf too:
2253     # multipart/mixed
2254     #   multipart/related
2255     #     multipart/alternative
2256     #       text/plain
2257     #       text/html
2258     #     image/png
2259     #   application/pdf
2260
2261     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2262     push @otherparts, $pdf;
2263   }
2264
2265   if (@otherparts) {
2266     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2267     if ( $html ) {
2268       $return{'mimeparts'} = [ $related, @otherparts ];
2269       $return{'type'} = 'multipart/related'; # of the first part
2270     } else {
2271       $return{'mimeparts'} = [ $text_part, @otherparts ];
2272       $return{'type'} = 'text/plain';
2273     }
2274   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2275     $return{'mimeparts'} = \@related_parts;
2276     $return{'content-type'} = 'multipart/related';
2277     $return{'type'} = 'multipart/alternative';
2278   } else { # no HTML either
2279     $return{'body'} = \@text;
2280     $return{'content-type'} = 'text/plain';
2281   }
2282
2283   %return;
2284
2285 }
2286
2287 =item mimebuild_pdf
2288
2289 Returns a list suitable for passing to MIME::Entity->build(), representing
2290 this invoice as PDF attachment.
2291
2292 =cut
2293
2294 sub mimebuild_pdf {
2295   my $self = shift;
2296   (
2297     'Type'        => 'application/pdf',
2298     'Encoding'    => 'base64',
2299     'Data'        => [ $self->print_pdf(@_) ],
2300     'Disposition' => 'attachment',
2301     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2302   );
2303 }
2304
2305 =item _items_sections OPTIONS
2306
2307 Generate section information for all items appearing on this invoice.
2308 This will only be called for multi-section invoices.
2309
2310 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2311 related display records (L<FS::cust_bill_pkg_display>) and organize
2312 them into two groups ("early" and "late" according to whether they come
2313 before or after the total), then into sections.  A subtotal is calculated
2314 for each section.
2315
2316 Section descriptions are returned in sort weight order.  Each consists
2317 of a hash containing:
2318
2319 description: the package category name, escaped
2320 subtotal: the total charges in that section
2321 tax_section: a flag indicating that the section contains only tax charges
2322 summarized: same as tax_section, for some reason
2323 sort_weight: the package category's sort weight
2324
2325 If 'condense' is set on the display record, it also contains everything
2326 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2327 coderefs to generate parts of the invoice.  This is not advised.
2328
2329 The method returns two arrayrefs, one of "early" sections and one of "late"
2330 sections.
2331
2332 OPTIONS may include:
2333
2334 by_location: a flag to divide the invoice into sections by location.
2335 Each section hash will have a 'location' element containing a hashref of
2336 the location fields (see L<FS::cust_location>).  The section description
2337 will be the location label, but the template can use any of the location
2338 fields to create a suitable label.
2339
2340 by_category: a flag to divide the invoice into sections using display
2341 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2342 behavior.  Each section hash will have a 'category' element containing
2343 the section name from the display record (which probably equals the
2344 category name of the package, but may not in some cases).
2345
2346 summary: a flag indicating that this is a summary-format invoice.
2347 Turning this on has the following effects:
2348 - Ignores display items with the 'summary' flag.
2349 - Places all sections in the "early" group even if they have post_total.
2350 - Creates sections for all non-disabled package categories, even if they
2351 have no charges on this invoice, as well as a section with no name.
2352
2353 escape: an escape function to use for section titles.
2354
2355 extra_sections: an arrayref of additional sections to return after the
2356 sorted list.  If there are any of these, section subtotals exclude
2357 usage charges.
2358
2359 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2360 passed through to C<_condense_section()>.
2361
2362 =cut
2363
2364 use vars qw(%pkg_category_cache);
2365 sub _items_sections {
2366   my $self = shift;
2367   my %opt = @_;
2368
2369   my $escape = $opt{escape};
2370   my @extra_sections = @{ $opt{extra_sections} || [] };
2371
2372   # $subtotal{$locationnum}{$categoryname} = amount.
2373   # if we're not using by_location, $locationnum is undef.
2374   # if we're not using by_category, you guessed it, $categoryname is undef.
2375   # if we're not using either one, we shouldn't be here in the first place...
2376   my %subtotal = ();
2377   my %late_subtotal = ();
2378   my %not_tax = ();
2379
2380   # About tax items + multisection invoices:
2381   # If either invoice_*summary option is enabled, AND there is a
2382   # package category with the name of the tax, then there will be
2383   # a display record assigning the tax item to that category.
2384   #
2385   # However, the taxes are always placed in the "Taxes, Surcharges,
2386   # and Fees" section regardless of that.  The only effect of the
2387   # display record is to create a subtotal for the summary page.
2388
2389   # cache these
2390   my $pkg_hash = $self->cust_pkg_hash;
2391
2392   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2393   {
2394
2395       my $usage = $cust_bill_pkg->usage;
2396
2397       my $locationnum;
2398       if ( $opt{by_location} ) {
2399         if ( $cust_bill_pkg->pkgnum ) {
2400           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2401         } else {
2402           $locationnum = '';
2403         }
2404       } else {
2405         $locationnum = undef;
2406       }
2407
2408       # as in _items_cust_pkg, if a line item has no display records,
2409       # cust_bill_pkg_display() returns a default record for it
2410
2411       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2412         next if ( $display->summary && $opt{summary} );
2413
2414         my $section = $display->section;
2415         my $type    = $display->type;
2416         # Set $section = undef if we're sectioning by location and this
2417         # line item _has_ a location (i.e. isn't a fee).
2418         $section = undef if $locationnum;
2419
2420         # set this flag if the section is not tax-only
2421         $not_tax{$locationnum}{$section} = 1
2422           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2423
2424         # there's actually a very important piece of logic buried in here:
2425         # incrementing $late_subtotal{$section} CREATES
2426         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2427         # to define the list of late sections, and likewise keys(%subtotal).
2428         # When _items_cust_bill_pkg is called to generate line items for
2429         # real, it will be called with 'section' => $section for each
2430         # of these.
2431         if ( $display->post_total && !$opt{summary} ) {
2432           if (! $type || $type eq 'S') {
2433             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2434               if $cust_bill_pkg->setup != 0
2435               || $cust_bill_pkg->setup_show_zero;
2436           }
2437
2438           if (! $type) {
2439             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2440               if $cust_bill_pkg->recur != 0
2441               || $cust_bill_pkg->recur_show_zero;
2442           }
2443
2444           if ($type && $type eq 'R') {
2445             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2446               if $cust_bill_pkg->recur != 0
2447               || $cust_bill_pkg->recur_show_zero;
2448           }
2449
2450           if ($type && $type eq 'U') {
2451             $late_subtotal{$locationnum}{$section} += $usage
2452               unless scalar(@extra_sections);
2453           }
2454
2455         } else { # it's a pre-total (normal) section
2456
2457           # skip tax items unless they're explicitly included in a section
2458           next if $cust_bill_pkg->pkgnum == 0 and
2459                   ! $cust_bill_pkg->feepart   and
2460                   ! $section;
2461
2462           if ( $type eq 'S' ) {
2463             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2464               if $cust_bill_pkg->setup != 0
2465               || $cust_bill_pkg->setup_show_zero;
2466           } elsif ( $type eq 'R' ) {
2467             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2468               if $cust_bill_pkg->recur != 0
2469               || $cust_bill_pkg->recur_show_zero;
2470           } elsif ( $type eq 'U' ) {
2471             $subtotal{$locationnum}{$section} += $usage
2472               unless scalar(@extra_sections);
2473           } elsif ( !$type ) {
2474             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2475                                                + $cust_bill_pkg->recur;
2476           }
2477
2478         }
2479
2480       }
2481
2482   }
2483
2484   %pkg_category_cache = ();
2485
2486   # summary invoices need subtotals for all non-disabled package categories,
2487   # even if they're zero
2488   # but currently assume that there are no location sections, or at least
2489   # that the summary page doesn't care about them
2490   if ( $opt{summary} ) {
2491     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2492       $subtotal{''}{$category->categoryname} ||= 0;
2493     }
2494     $subtotal{''}{''} ||= 0;
2495   }
2496
2497   my @sections;
2498   foreach my $post_total (0,1) {
2499     my @these;
2500     my $s = $post_total ? \%late_subtotal : \%subtotal;
2501     foreach my $locationnum (keys %$s) {
2502       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2503         my $section = {
2504                         'subtotal'    => $s->{$locationnum}{$sectionname},
2505                         'sort_weight' => 0,
2506                       };
2507         if ( $locationnum ) {
2508           $section->{'locationnum'} = $locationnum;
2509           my $location = FS::cust_location->by_key($locationnum);
2510           $section->{'description'} = &{ $escape }($location->location_label);
2511           # Better ideas? This will roughly group them by proximity,
2512           # which alpha sorting on any of the address fields won't.
2513           # Sorting by locationnum is meaningless.
2514           # We have to sort on _something_ or the order may change
2515           # randomly from one invoice to the next, which will confuse
2516           # people.
2517           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2518                                       $locationnum;
2519           $section->{'location'} = {
2520             label_prefix => &{ $escape }($location->label_prefix),
2521             map { $_ => &{ $escape }($location->get($_)) }
2522               $location->fields
2523           };
2524         } else {
2525           $section->{'category'} = $sectionname;
2526           $section->{'description'} = &{ $escape }($sectionname);
2527           if ( _pkg_category($sectionname) ) {
2528             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2529             if ( _pkg_category($sectionname)->condense ) {
2530               $section = { %$section, $self->_condense_section($opt{format}) };
2531             }
2532           }
2533         }
2534         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2535           # then it's a tax-only section
2536           $section->{'summarized'} = 'Y';
2537           $section->{'tax_section'} = 'Y';
2538         }
2539         push @these, $section;
2540       } # foreach $sectionname
2541     } #foreach $locationnum
2542     push @these, @extra_sections if $post_total == 0;
2543     # need an alpha sort for location sections, because postal codes can
2544     # be non-numeric
2545     $sections[ $post_total ] = [ sort {
2546       $opt{'by_location'} ?
2547         ($a->{sort_weight} cmp $b->{sort_weight}) :
2548         ($a->{sort_weight} <=> $b->{sort_weight})
2549       } @these ];
2550   } #foreach $post_total
2551
2552   return @sections; # early, late
2553 }
2554
2555 #helper subs for above
2556
2557 sub cust_pkg_hash {
2558   my $self = shift;
2559   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2560 }
2561
2562 sub _pkg_category {
2563   my $categoryname = shift;
2564   $pkg_category_cache{$categoryname} ||=
2565     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2566 }
2567
2568 my %condensed_format = (
2569   'label' => [ qw( Description Qty Amount ) ],
2570   'fields' => [
2571                 sub { shift->{description} },
2572                 sub { shift->{quantity} },
2573                 sub { my($href, %opt) = @_;
2574                       ($opt{dollar} || ''). $href->{amount};
2575                     },
2576               ],
2577   'align'  => [ qw( l r r ) ],
2578   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2579   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2580 );
2581
2582 sub _condense_section {
2583   my ( $self, $format ) = ( shift, shift );
2584   ( 'condensed' => 1,
2585     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2586       qw( description_generator
2587           header_generator
2588           total_generator
2589           total_line_generator
2590         )
2591   );
2592 }
2593
2594 sub _condensed_generator_defaults {
2595   my ( $self, $format ) = ( shift, shift );
2596   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2597 }
2598
2599 my %html_align = (
2600   'c' => 'center',
2601   'l' => 'left',
2602   'r' => 'right',
2603 );
2604
2605 sub _condensed_header_generator {
2606   my ( $self, $format ) = ( shift, shift );
2607
2608   my ( $f, $prefix, $suffix, $separator, $column ) =
2609     _condensed_generator_defaults($format);
2610
2611   if ($format eq 'latex') {
2612     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2613     $suffix = "\\\\\n\\hline";
2614     $separator = "&\n";
2615     $column =
2616       sub { my ($d,$a,$s,$w) = @_;
2617             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2618           };
2619   } elsif ( $format eq 'html' ) {
2620     $prefix = '<th></th>';
2621     $suffix = '';
2622     $separator = '';
2623     $column =
2624       sub { my ($d,$a,$s,$w) = @_;
2625             return qq!<th align="$html_align{$a}">$d</th>!;
2626       };
2627   }
2628
2629   sub {
2630     my @args = @_;
2631     my @result = ();
2632
2633     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2634       push @result,
2635         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2636     }
2637
2638     $prefix. join($separator, @result). $suffix;
2639   };
2640
2641 }
2642
2643 sub _condensed_description_generator {
2644   my ( $self, $format ) = ( shift, shift );
2645
2646   my ( $f, $prefix, $suffix, $separator, $column ) =
2647     _condensed_generator_defaults($format);
2648
2649   my $money_char = '$';
2650   if ($format eq 'latex') {
2651     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2652     $suffix = '\\\\';
2653     $separator = " & \n";
2654     $column =
2655       sub { my ($d,$a,$s,$w) = @_;
2656             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2657           };
2658     $money_char = '\\dollar';
2659   }elsif ( $format eq 'html' ) {
2660     $prefix = '"><td align="center"></td>';
2661     $suffix = '';
2662     $separator = '';
2663     $column =
2664       sub { my ($d,$a,$s,$w) = @_;
2665             return qq!<td align="$html_align{$a}">$d</td>!;
2666       };
2667     #$money_char = $conf->config('money_char') || '$';
2668     $money_char = '';  # this is madness
2669   }
2670
2671   sub {
2672     #my @args = @_;
2673     my $href = shift;
2674     my @result = ();
2675
2676     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2677       my $dollar = '';
2678       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2679       push @result,
2680         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2681                     map { $f->{$_}->[$i] } qw(align span width)
2682                   );
2683     }
2684
2685     $prefix. join( $separator, @result ). $suffix;
2686   };
2687
2688 }
2689
2690 sub _condensed_total_generator {
2691   my ( $self, $format ) = ( shift, shift );
2692
2693   my ( $f, $prefix, $suffix, $separator, $column ) =
2694     _condensed_generator_defaults($format);
2695   my $style = '';
2696
2697   if ($format eq 'latex') {
2698     $prefix = "& ";
2699     $suffix = "\\\\\n";
2700     $separator = " & \n";
2701     $column =
2702       sub { my ($d,$a,$s,$w) = @_;
2703             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2704           };
2705   }elsif ( $format eq 'html' ) {
2706     $prefix = '';
2707     $suffix = '';
2708     $separator = '';
2709     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2710     $column =
2711       sub { my ($d,$a,$s,$w) = @_;
2712             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2713       };
2714   }
2715
2716
2717   sub {
2718     my @args = @_;
2719     my @result = ();
2720
2721     #  my $r = &{$f->{fields}->[$i]}(@args);
2722     #  $r .= ' Total' unless $i;
2723
2724     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2725       push @result,
2726         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2727                     map { $f->{$_}->[$i] } qw(align span width)
2728                   );
2729     }
2730
2731     $prefix. join( $separator, @result ). $suffix;
2732   };
2733
2734 }
2735
2736 =item total_line_generator FORMAT
2737
2738 Returns a coderef used for generation of invoice total line items for this
2739 usage_class.  FORMAT is either html or latex
2740
2741 =cut
2742
2743 # should not be used: will have issues with hash element names (description vs
2744 # total_item and amount vs total_amount -- another array of functions?
2745
2746 sub _condensed_total_line_generator {
2747   my ( $self, $format ) = ( shift, shift );
2748
2749   my ( $f, $prefix, $suffix, $separator, $column ) =
2750     _condensed_generator_defaults($format);
2751   my $style = '';
2752
2753   if ($format eq 'latex') {
2754     $prefix = "& ";
2755     $suffix = "\\\\\n";
2756     $separator = " & \n";
2757     $column =
2758       sub { my ($d,$a,$s,$w) = @_;
2759             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2760           };
2761   }elsif ( $format eq 'html' ) {
2762     $prefix = '';
2763     $suffix = '';
2764     $separator = '';
2765     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2766     $column =
2767       sub { my ($d,$a,$s,$w) = @_;
2768             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2769       };
2770   }
2771
2772
2773   sub {
2774     my @args = @_;
2775     my @result = ();
2776
2777     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2778       push @result,
2779         &{$column}( &{$f->{fields}->[$i]}(@args),
2780                     map { $f->{$_}->[$i] } qw(align span width)
2781                   );
2782     }
2783
2784     $prefix. join( $separator, @result ). $suffix;
2785   };
2786
2787 }
2788
2789 =item _items_pkg [ OPTIONS ]
2790
2791 Return line item hashes for each package item on this invoice. Nearly
2792 equivalent to
2793
2794 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2795
2796 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2797 'format' and 'escape_function' at minimum.
2798
2799 To produce items for a specific invoice section, OPTIONS should include
2800 'section', a hashref containing 'category' and/or 'locationnum' keys.
2801
2802 'section' may also contain a key named 'condensed'. If this is present
2803 and has a true value, _items_pkg will try to merge identical items into items
2804 with 'quantity' equal to the number of items (not the sum of their separate
2805 quantities, for some reason).
2806
2807 =cut
2808
2809 sub _items_nontax {
2810   my $self = shift;
2811   # The order of these is important.  Bundled line items will be merged into
2812   # the most recent non-hidden item, so it needs to be the one with:
2813   # - the same pkgnum
2814   # - the same start date
2815   # - no pkgpart_override
2816   #
2817   # So: sort by pkgnum,
2818   # then by sdate
2819   # then sort the base line item before any overrides
2820   # then sort hidden before non-hidden add-ons
2821   # then sort by override pkgpart (for consistency)
2822   sort { $a->pkgnum <=> $b->pkgnum        or
2823          $a->sdate  <=> $b->sdate         or
2824          ($a->pkgpart_override ? 0 : -1)  or
2825          ($b->pkgpart_override ? 0 : 1)   or
2826          $b->hidden cmp $a->hidden        or
2827          $a->pkgpart_override <=> $b->pkgpart_override
2828        }
2829   # and of course exclude taxes and fees
2830   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2831 }
2832
2833 sub _items_fee {
2834   my $self = shift;
2835   my %options = @_;
2836   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2837   my $escape_function = $options{escape_function};
2838
2839   my @items;
2840   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2841     # cache this, so we don't look it up again in every section
2842     my $part_fee = $cust_bill_pkg->get('part_fee')
2843        || $cust_bill_pkg->part_fee;
2844     $cust_bill_pkg->set('part_fee', $part_fee);
2845     if (!$part_fee) {
2846       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2847       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2848       next;
2849     }
2850     if ( exists($options{section}) and exists($options{section}{category}) )
2851     {
2852       my $categoryname = $options{section}{category};
2853       # then filter for items that have that section
2854       if ( $part_fee->categoryname ne $categoryname ) {
2855         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2856         next;
2857       }
2858     } # otherwise include them all in the main section
2859     # XXX what to do when sectioning by location?
2860
2861     my @ext_desc;
2862     my %base_invnums; # invnum => invoice date
2863     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2864       if ($_->base_invnum) {
2865         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2866         my $base_date = $self->time2str_local('short', $base_bill->_date)
2867           if $base_bill;
2868         $base_invnums{$_->base_invnum} = $base_date || '';
2869       }
2870     }
2871     foreach (sort keys(%base_invnums)) {
2872       next if $_ == $self->invnum;
2873       # per convention, we must escape ext_description lines
2874       push @ext_desc,
2875         &{$escape_function}(
2876           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2877         );
2878     }
2879     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2880     # but not escape the base description line
2881
2882     push @items,
2883       { feepart     => $cust_bill_pkg->feepart,
2884         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2885         description => $desc,
2886         ext_description => \@ext_desc
2887         # sdate/edate?
2888       };
2889   }
2890   @items;
2891 }
2892
2893 sub _items_pkg {
2894   my $self = shift;
2895   my %options = @_;
2896
2897   warn "$me _items_pkg searching for all package line items\n"
2898     if $DEBUG > 1;
2899
2900   my @cust_bill_pkg = $self->_items_nontax;
2901
2902   warn "$me _items_pkg filtering line items\n"
2903     if $DEBUG > 1;
2904   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2905
2906   if ($options{section} && $options{section}->{condensed}) {
2907
2908     warn "$me _items_pkg condensing section\n"
2909       if $DEBUG > 1;
2910
2911     my %itemshash = ();
2912     local $Storable::canonical = 1;
2913     foreach ( @items ) {
2914       my $item = { %$_ };
2915       delete $item->{ref};
2916       delete $item->{ext_description};
2917       my $key = freeze($item);
2918       $itemshash{$key} ||= 0;
2919       $itemshash{$key} ++; # += $item->{quantity};
2920     }
2921     @items = sort { $a->{description} cmp $b->{description} }
2922              map { my $i = thaw($_);
2923                    $i->{quantity} = $itemshash{$_};
2924                    $i->{amount} =
2925                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2926                    $i;
2927                  }
2928              keys %itemshash;
2929   }
2930
2931   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2932     if $DEBUG > 1;
2933
2934   @items;
2935 }
2936
2937 sub _taxsort {
2938   return 0 unless $a->itemdesc cmp $b->itemdesc;
2939   return -1 if $b->itemdesc eq 'Tax';
2940   return 1 if $a->itemdesc eq 'Tax';
2941   return -1 if $b->itemdesc eq 'Other surcharges';
2942   return 1 if $a->itemdesc eq 'Other surcharges';
2943   $a->itemdesc cmp $b->itemdesc;
2944 }
2945
2946 sub _items_tax {
2947   my $self = shift;
2948   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2949     $self->cust_bill_pkg;
2950   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2951
2952   if ( $self->conf->exists('always_show_tax') ) {
2953     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2954     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2955       push @items,
2956         { 'description' => $itemdesc,
2957           'amount'      => 0.00 };
2958     }
2959   }
2960   @items;
2961 }
2962
2963 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2964
2965 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2966 list of hashrefs describing the line items they generate on the invoice.
2967
2968 OPTIONS may include:
2969
2970 format: the invoice format.
2971
2972 escape_function: the function used to escape strings.
2973
2974 DEPRECATED? (expensive, mostly unused?)
2975 format_function: the function used to format CDRs.
2976
2977 section: a hashref containing 'category' and/or 'locationnum'; if this
2978 is present, only returns line items that belong to that category and/or
2979 location (whichever is defined).
2980
2981 multisection: a flag indicating that this is a multisection invoice,
2982 which does something complicated.
2983
2984 preref_callback: coderef run for each line item, code should return HTML to be
2985 displayed before that line item (quotations only)
2986
2987 Returns a list of hashrefs, each of which may contain:
2988
2989 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2990 ext_description, which is an arrayref of detail lines to show below
2991 the package line.
2992
2993 =cut
2994
2995 sub _items_cust_bill_pkg {
2996   my $self = shift;
2997   my $conf = $self->conf;
2998   my $cust_bill_pkgs = shift;
2999   my %opt = @_;
3000
3001   my $format = $opt{format} || '';
3002   my $escape_function = $opt{escape_function} || sub { shift };
3003   my $format_function = $opt{format_function} || '';
3004   my $no_usage = $opt{no_usage} || '';
3005   my $unsquelched = $opt{unsquelched} || ''; #unused
3006   my ($section, $locationnum, $category);
3007   if ( $opt{section} ) {
3008     $category = $opt{section}->{category};
3009     $locationnum = $opt{section}->{locationnum};
3010   }
3011   my $summary_page = $opt{summary_page} || ''; #unused
3012   my $multisection = defined($category) || defined($locationnum);
3013   # this variable is the value of the config setting, not whether it applies
3014   # to this particular line item.
3015   my $discount_show_always = $conf->exists('discount-show-always');
3016
3017   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3018
3019   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3020
3021   # for location labels: use default location on the invoice date
3022   my $default_locationnum;
3023   if ( $self->custnum ) {
3024     my $h_cust_main;
3025     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3026     $h_cust_main = qsearchs({
3027         'table'     => 'h_cust_main',
3028         'hashref'   => { custnum => $self->custnum },
3029         'extra_sql' => $h_search[1],
3030         'addl_from' => $h_search[3],
3031     }) || $cust_main;
3032     $default_locationnum = $h_cust_main->ship_locationnum;
3033   } elsif ( $self->prospectnum ) {
3034     my $cust_location = qsearchs('cust_location',
3035       { prospectnum => $self->prospectnum,
3036         disabled => '' });
3037     $default_locationnum = $cust_location->locationnum if $cust_location;
3038   }
3039
3040   my @b = (); # accumulator for the line item hashes that we'll return
3041   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3042             # the 'current' line item hashes for setup, recur, usage, discount
3043   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3044   {
3045     # if the current line item is waiting to go out, and the one we're about
3046     # to start is not bundled, then push out the current one and start a new
3047     # one.
3048     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3049       if ( $_ && !$cust_bill_pkg->hidden ) {
3050         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3051         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3052         if (exists($_->{unit_amount})) {
3053           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3054         }
3055         push @b, { %$_ };
3056         # we already decided to create this display line; don't reconsider it
3057         # now.
3058         #  if $_->{amount} != 0
3059         #  || $discount_show_always
3060         #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3061         #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3062         ;
3063         $_ = undef;
3064       }
3065     }
3066
3067     if ( $locationnum ) {
3068       # this is a location section; skip packages that aren't at this
3069       # service location.
3070       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3071       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3072               != $locationnum;
3073     }
3074
3075     # Consider display records for this item to determine if it belongs
3076     # in this section.  Note that if there are no display records, there
3077     # will be a default pseudo-record that includes all charge types
3078     # and has no section name.
3079     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3080                                   ? $cust_bill_pkg->cust_bill_pkg_display
3081                                   : ( $cust_bill_pkg );
3082
3083     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3084          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3085       if $DEBUG > 1;
3086
3087     if ( defined($category) ) {
3088       # then this is a package category section; process all display records
3089       # that belong to this section.
3090       @cust_bill_pkg_display = grep { $_->section eq $category }
3091                                 @cust_bill_pkg_display;
3092     } else {
3093       # otherwise, process all display records that aren't usage summaries
3094       # (I don't think there should be usage summaries if you aren't using
3095       # category sections, but this is the historical behavior)
3096       @cust_bill_pkg_display = grep { !$_->summary }
3097                                 @cust_bill_pkg_display;
3098     }
3099
3100     my $classname = ''; # package class name, will fill in later
3101
3102     foreach my $display (@cust_bill_pkg_display) {
3103
3104       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3105            $display->billpkgdisplaynum. "\n"
3106         if $DEBUG > 1;
3107
3108       my $type = $display->type;
3109
3110       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3111       $desc = substr($desc, 0, $maxlength). '...'
3112         if $format eq 'latex' && length($desc) > $maxlength;
3113
3114       my %details_opt = ( 'format'          => $format,
3115                           'escape_function' => $escape_function,
3116                           'format_function' => $format_function,
3117                           'no_usage'        => $opt{'no_usage'},
3118                         );
3119
3120       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3121         # XXX this should be pulled out into quotation_pkg
3122
3123         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3124           if $DEBUG > 1;
3125         # quotation_pkgs are never fees, so don't worry about the case where
3126         # part_pkg is undefined
3127
3128         # and I guess they're never bundled either?
3129         if ( $cust_bill_pkg->setup != 0 ) {
3130           my $description = $desc;
3131           $description .= ' Setup'
3132             if $cust_bill_pkg->recur != 0
3133             || $discount_show_always
3134             || $cust_bill_pkg->recur_show_zero;
3135           #push @b, {
3136           # keep it consistent, please
3137           $s = {
3138             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3139             'description' => $description,
3140             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3141             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3142             'quantity'    => $cust_bill_pkg->quantity,
3143             'preref_html' => ( $opt{preref_callback}
3144                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3145                                  : ''
3146                              ),
3147           };
3148         }
3149         if ( $cust_bill_pkg->recur != 0 ) {
3150           #push @b, {
3151           $r = {
3152             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3153             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3154             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3155             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3156             'quantity'    => $cust_bill_pkg->quantity,
3157            'preref_html'  => ( $opt{preref_callback}
3158                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3159                                  : ''
3160                              ),
3161           };
3162         }
3163
3164       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3165         # a "normal" package line item (not a quotation, not a fee, not a tax)
3166
3167         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3168           if $DEBUG > 1;
3169
3170         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3171         my $part_pkg = $cust_pkg->part_pkg;
3172
3173         # which pkgpart to show for display purposes?
3174         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3175
3176         # start/end dates for invoice formats that do nonstandard
3177         # things with them
3178         my %item_dates = ();
3179         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3180           unless $part_pkg->option('disable_line_item_date_ranges',1);
3181
3182         # not normally used, but pass this to the template anyway
3183         $classname = $part_pkg->classname;
3184
3185         if (    (!$type || $type eq 'S')
3186              && (    $cust_bill_pkg->setup != 0
3187                   || $cust_bill_pkg->setup_show_zero
3188                   || ($discount_show_always and $cust_bill_pkg->unitsetup > 0)
3189                 )
3190            )
3191          {
3192
3193           warn "$me _items_cust_bill_pkg adding setup\n"
3194             if $DEBUG > 1;
3195
3196           # append the word 'Setup' to the setup line if there's going to be
3197           # a recur line for the same package (i.e. not a one-time charge)
3198           my $description = $desc;
3199           $description .= ' Setup'
3200             if $cust_bill_pkg->recur != 0
3201             || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3202             || $cust_bill_pkg->recur_show_zero;
3203
3204           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3205                                                               $self->agentnum )
3206             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3207                                      # triggered by the recurring charge freq
3208                                      # (RT#26274)
3209             && $cust_bill_pkg->recur == 0
3210             && ! $cust_bill_pkg->recur_show_zero;
3211
3212           my @d = ();
3213           my $svc_label;
3214
3215           # always pass the svc_label through to the template, even if
3216           # not displaying it as an ext_description
3217           my @svc_labels = map &{$escape_function}($_),
3218                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3219
3220           $svc_label = $svc_labels[0];
3221
3222           unless ( $cust_pkg->part_pkg->hide_svc_detail
3223                 || $cust_bill_pkg->hidden )
3224           {
3225
3226             push @d, @svc_labels
3227               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3228             # show the location label if it's not the customer's default
3229             # location, and we're not grouping items by location already
3230             if ( $cust_pkg->locationnum != $default_locationnum
3231                   and !defined($locationnum) ) {
3232               my $loc = $cust_pkg->location_label;
3233               $loc = substr($loc, 0, $maxlength). '...'
3234                 if $format eq 'latex' && length($loc) > $maxlength;
3235               push @d, &{$escape_function}($loc);
3236             }
3237
3238           } #unless hiding service details
3239
3240           push @d, $cust_bill_pkg->details(%details_opt)
3241             if $cust_bill_pkg->recur == 0;
3242
3243           if ( $cust_bill_pkg->hidden ) {
3244             $s->{amount}      += $cust_bill_pkg->setup;
3245             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3246             push @{ $s->{ext_description} }, @d;
3247           } else {
3248             $s = {
3249               _is_setup       => 1,
3250               description     => $description,
3251               pkgpart         => $pkgpart,
3252               pkgnum          => $cust_bill_pkg->pkgnum,
3253               amount          => $cust_bill_pkg->setup,
3254               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3255               unit_amount     => $cust_bill_pkg->unitsetup,
3256               quantity        => $cust_bill_pkg->quantity,
3257               ext_description => \@d,
3258               svc_label       => ($svc_label || ''),
3259               locationnum     => $cust_pkg->locationnum, # sure, why not?
3260             };
3261           };
3262
3263         }
3264
3265         # should we show a recur line?
3266         # if type eq 'S', then NO, because we've been told not to.
3267         # otherwise, show the recur line if:
3268         # - there's a recurring charge
3269         # - or recur_show_zero is on
3270         # - or there's a positive unitrecur (so it's been discounted to zero)
3271         #   and discount-show-always is on
3272         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3273              && (
3274                      $cust_bill_pkg->recur != 0
3275                   || !defined($s)
3276                   || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3277                   || $cust_bill_pkg->recur_show_zero
3278                 )
3279            )
3280         {
3281
3282           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3283             if $DEBUG > 1;
3284
3285           my $is_summary = $display->summary;
3286           my $description = $desc;
3287           if ( $type eq 'U' and defined($r) ) {
3288             # don't just show the same description as the recur line
3289             $description = $self->mt('Usage charges');
3290           }
3291
3292           my $part_pkg = $cust_pkg->part_pkg;
3293
3294           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3295                                                               $self->agentnum );
3296
3297           my @d = ();
3298           my @seconds = (); # for display of usage info
3299           my $svc_label = '';
3300
3301           #at least until cust_bill_pkg has "past" ranges in addition to
3302           #the "future" sdate/edate ones... see #3032
3303           my @dates = ( $self->_date );
3304           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3305           push @dates, $prev->sdate if $prev;
3306           push @dates, undef if !$prev;
3307
3308           my @svc_labels = map &{$escape_function}($_),
3309                       $cust_pkg->h_labels_short(@dates, 'I');
3310           $svc_label = $svc_labels[0];
3311
3312           # show service labels, unless...
3313                     # the package is set not to display them
3314           unless ( $part_pkg->hide_svc_detail
3315                     # or this is a tax-like line item
3316                 || $cust_bill_pkg->itemdesc
3317                     # or this is a hidden (bundled) line item
3318                 || $cust_bill_pkg->hidden
3319                     # or this is a usage summary line
3320                 || $is_summary && $type && $type eq 'U'
3321                     # or this is a usage line and there's a recurring line
3322                     # for the package in the same section (which will
3323                     # have service labels already)
3324                 || ($type eq 'U' and defined($r))
3325               )
3326           {
3327
3328             warn "$me _items_cust_bill_pkg adding service details\n"
3329               if $DEBUG > 1;
3330
3331             push @d, @svc_labels
3332               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3333             warn "$me _items_cust_bill_pkg done adding service details\n"
3334               if $DEBUG > 1;
3335
3336             # show the location label if it's not the customer's default
3337             # location, and we're not grouping items by location already
3338             if ( $cust_pkg->locationnum != $default_locationnum
3339                   and !defined($locationnum) ) {
3340               my $loc = $cust_pkg->location_label;
3341               $loc = substr($loc, 0, $maxlength). '...'
3342                 if $format eq 'latex' && length($loc) > $maxlength;
3343               push @d, &{$escape_function}($loc);
3344             }
3345
3346             # Display of seconds_since_sqlradacct:
3347             # On the invoice, when processing @detail_items, look for a field
3348             # named 'seconds'.  This will contain total seconds for each
3349             # service, in the same order as @ext_description.  For services
3350             # that don't support this it will show undef.
3351             if ( $conf->exists('svc_acct-usage_seconds')
3352                  and ! $cust_bill_pkg->pkgpart_override ) {
3353               foreach my $cust_svc (
3354                   $cust_pkg->h_cust_svc(@dates, 'I')
3355                 ) {
3356
3357                 # eval because not having any part_export_usage exports
3358                 # is a fatal error, last_bill/_date because that's how
3359                 # sqlradius_hour billing does it
3360                 my $sec = eval {
3361                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3362                 };
3363                 push @seconds, $sec;
3364               }
3365             } #if svc_acct-usage_seconds
3366
3367           } # if we are showing service labels
3368
3369           unless ( $is_summary ) {
3370             warn "$me _items_cust_bill_pkg adding details\n"
3371               if $DEBUG > 1;
3372
3373             #instead of omitting details entirely in this case (unwanted side
3374             # effects), just omit CDRs
3375             $details_opt{'no_usage'} = 1
3376               if $type && $type eq 'R';
3377
3378             push @d, $cust_bill_pkg->details(%details_opt);
3379           }
3380
3381           warn "$me _items_cust_bill_pkg calculating amount\n"
3382             if $DEBUG > 1;
3383
3384           my $amount = 0;
3385           if (!$type) {
3386             $amount = $cust_bill_pkg->recur;
3387           } elsif ($type eq 'R') {
3388             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3389           } elsif ($type eq 'U') {
3390             $amount = $cust_bill_pkg->usage;
3391           }
3392
3393           if ( !$type || $type eq 'R' ) {
3394
3395             warn "$me _items_cust_bill_pkg adding recur\n"
3396               if $DEBUG > 1;
3397
3398             my $unit_amount =
3399               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3400                                                 : $amount;
3401
3402             if ( $cust_bill_pkg->hidden ) {
3403               $r->{amount}      += $amount;
3404               $r->{unit_amount} += $unit_amount;
3405               push @{ $r->{ext_description} }, @d;
3406             } else {
3407               $r = {
3408                 description     => $description,
3409                 pkgpart         => $pkgpart,
3410                 pkgnum          => $cust_bill_pkg->pkgnum,
3411                 amount          => $amount,
3412                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3413                 unit_amount     => $unit_amount,
3414                 quantity        => $cust_bill_pkg->quantity,
3415                 %item_dates,
3416                 ext_description => \@d,
3417                 svc_label       => ($svc_label || ''),
3418                 locationnum     => $cust_pkg->locationnum,
3419               };
3420               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3421             }
3422
3423           } else {  # $type eq 'U'
3424
3425             warn "$me _items_cust_bill_pkg adding usage\n"
3426               if $DEBUG > 1;
3427
3428             if ( $cust_bill_pkg->hidden and defined($u) ) {
3429               # if this is a hidden package and there's already a usage
3430               # line for the bundle, add this package's total amount and
3431               # usage details to it
3432               $u->{amount}      += $amount;
3433               push @{ $u->{ext_description} }, @d;
3434             } elsif ( $amount ) {
3435               # create a new usage line
3436               $u = {
3437                 description     => $description,
3438                 pkgpart         => $pkgpart,
3439                 pkgnum          => $cust_bill_pkg->pkgnum,
3440                 amount          => $amount,
3441                 usage_item      => 1,
3442                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3443                 %item_dates,
3444                 ext_description => \@d,
3445                 locationnum     => $cust_pkg->locationnum,
3446               };
3447             } # else this has no usage, so don't create a usage section
3448           }
3449
3450         } # recurring or usage with recurring charge
3451
3452       } else { # taxes and fees
3453
3454         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3455           if $DEBUG > 1;
3456
3457         # items of this kind should normally not have sdate/edate.
3458         push @b, {
3459           'description' => $desc,
3460           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3461                                            + $cust_bill_pkg->recur)
3462         };
3463
3464       } # if quotation / package line item / other line item
3465
3466       # decide whether to show active discounts here
3467       if (
3468           # case 1: we are showing a single line for the package
3469           ( !$type )
3470           # case 2: we are showing a setup line for a package that has
3471           # no base recurring fee
3472           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3473           # case 3: we are showing a recur line for a package that has
3474           # a base recurring fee
3475           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3476       ) {
3477
3478         my $item_discount = $cust_bill_pkg->_item_discount;
3479         if ( $item_discount ) {
3480           # $item_discount->{amount} is negative
3481
3482           if ( $d and $cust_bill_pkg->hidden ) {
3483             $d->{amount}      += $item_discount->{amount};
3484           } else {
3485             $d = $item_discount;
3486             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3487           }
3488
3489           # update the active line (before the discount) to show the
3490           # original price (whether this is a hidden line or not)
3491           #
3492           # quotation discounts keep track of setup and recur; invoice
3493           # discounts currently don't
3494           if ( exists $item_discount->{setup_amount} ) {
3495
3496             $s->{amount} -= $item_discount->{setup_amount} if $s;
3497             $r->{amount} -= $item_discount->{recur_amount} if $r;
3498
3499           } else {
3500
3501             # $active_line is the line item hashref for the line that will
3502             # show the original price
3503             # (use the recur or single line for the package, unless we're
3504             # showing a setup line for a package with no recurring fee)
3505             my $active_line = $r;
3506             if ( $type eq 'S' ) {
3507               $active_line = $s;
3508             }
3509             $active_line->{amount} -= $item_discount->{amount};
3510
3511           }
3512
3513         } # if there are any discounts
3514       } # if this is an appropriate place to show discounts
3515
3516     } # foreach $display
3517
3518   }
3519
3520   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3521     if ( $_  ) {
3522       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3523         if exists($_->{amount});
3524       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3525       if (exists($_->{unit_amount})) {
3526         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3527       }
3528
3529       push @b, { %$_ };
3530       #if $_->{amount} != 0
3531       #  || $discount_show_always
3532       #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3533       #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3534     }
3535   }
3536
3537   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3538     if $DEBUG > 1;
3539
3540   @b;
3541
3542 }
3543
3544 =item _items_discounts_avail
3545
3546 Returns an array of line item hashrefs representing available term discounts
3547 for this invoice.  This makes the same assumptions that apply to term
3548 discounts in general: that the package is billed monthly, at a flat rate,
3549 with no usage charges.  A prorated first month will be handled, as will
3550 a setup fee if the discount is allowed to apply to setup fees.
3551
3552 =cut
3553
3554 sub _items_discounts_avail {
3555   my $self = shift;
3556
3557   #maybe move this method from cust_bill when quotations support discount_plans
3558   return () unless $self->can('discount_plans');
3559   my %plans = $self->discount_plans;
3560
3561   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3562   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3563
3564   map {
3565     my $months = $_;
3566     my $plan = $plans{$months};
3567
3568     my $term_total = sprintf('%.2f', $plan->discounted_total);
3569     my $percent = sprintf('%.0f',
3570                           100 * (1 - $term_total / $plan->base_total) );
3571     my $permonth = sprintf('%.2f', $term_total / $months);
3572     my $detail = $self->mt('discount on item'). ' '.
3573                  join(', ', map { "#$_" } $plan->pkgnums)
3574       if $list_pkgnums;
3575
3576     # discounts for non-integer months don't work anyway
3577     $months = sprintf("%d", $months);
3578
3579     +{
3580       description => $self->mt('Save [_1]% by paying for [_2] months',
3581                                 $percent, $months),
3582       amount      => $self->mt('[_1] ([_2] per month)',
3583                                 $term_total, $money_char.$permonth),
3584       ext_description => ($detail || ''),
3585     }
3586   } #map
3587   sort { $b <=> $a } keys %plans;
3588
3589 }
3590
3591 1;