FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Time::Local qw( timelocal );
  14 use Text::Template 1.20;
  15 use File::Temp 0.14;
  16 use Archive::Zip qw( :ERROR_CODES :CONSTANTS );
  17 use IO::Scalar;
  18 use HTML::Entities;
  19 use Cwd;
  20 use FS::UID;
  21 use FS::Misc qw( send_email );
  22 use FS::Record qw( qsearch qsearchs dbh );
  23 use FS::Conf;
  24 use FS::Misc qw( generate_ps generate_pdf );
  25 use FS::pkg_category;
  26 use FS::pkg_class;
  27 use FS::invoice_mode;
  28 use FS::L10N;
  29
  30 $DEBUG = 0;
  31 $me = '[FS::Template_Mixin]';
  32 FS::UID->install_callback( sub {
  33   my $conf = new FS::Conf; #global
  34   $money_char  = $conf->config('money_char')  || '$';
  35   $date_format = $conf->config('date_format') || '%x'; #/YY
  36 } );
  37
  38 =item conf [ MODE ]
  39
  40 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  41
  42 If the "mode" pseudo-field is set on the object, the configuration handle
  43 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  44 locale).
  45
  46 =cut
  47
  48 sub conf {
  49   my $self = shift;
  50   my $mode = $self->get('mode');
  51   if ($self->{_conf} and !defined($mode)) {
  52     return $self->{_conf};
  53   }
  54
  55   my $cust_main = $self->cust_main;
  56   my $locale = $cust_main ? $cust_main->locale : '';
  57   my $conf;
  58   if ( $mode ) {
  59     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  60       $mode = $mode->modenum;
  61     } elsif ( $mode =~ /\D/ ) {
  62       die "invalid invoice mode $mode";
  63     }
  64     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  65     if (!$conf) {
  66       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  67       # it doesn't have a locale, but system conf still might
  68       $conf->set('locale' => $locale) if $conf;
  69     }
  70   }
  71   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  72   # and locale, then use the system config only (but with the locale)
  73   $conf ||= FS::Conf->new({ 'locale' => $locale });
  74   # cache it
  75   return $self->{_conf} = $conf;
  76 }
  77
  78 =item print_text OPTIONS
  79
  80 Returns an text invoice, as a list of lines.
  81
  82 Options can be passed as a hash.
  83
  84 I<time>, if specified, is used to control the printing of overdue messages.  The
  85 default is now.  It isn't the date of the invoice; that's the `_date' field.
  86 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  87 L<Time::Local> and L<Date::Parse> for conversion functions.
  88
  89 I<template>, if specified, is the name of a suffix for alternate invoices.
  90
  91 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  92
  93 =cut
  94
  95 sub print_text {
  96   my $self = shift;
  97   my %params;
  98   if ( ref($_[0]) ) {
  99     %params = %{ shift() };
 100   } else {
 101     %params = @_;
 102   }
 103
 104   $params{'format'} = 'template'; # for some reason
 105
 106   $self->print_generic( %params );
 107 }
 108
 109 =item print_latex HASHREF
 110
 111 Internal method - returns a filename of a filled-in LaTeX template for this
 112 invoice (Note: add ".tex" to get the actual filename), and a filename of
 113 an associated logo (with the .eps extension included).
 114
 115 See print_ps and print_pdf for methods that return PostScript and PDF output.
 116
 117 Options can be passed as a hash.
 118
 119 I<time>, if specified, is used to control the printing of overdue messages.  The
 120 default is now.  It isn't the date of the invoice; that's the `_date' field.
 121 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 122 L<Time::Local> and L<Date::Parse> for conversion functions.
 123
 124 I<template>, if specified, is the name of a suffix for alternate invoices.
 125 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 126 customize invoice templates for different purposes.
 127
 128 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 129
 130 =cut
 131
 132 sub print_latex {
 133   my $self = shift;
 134   my %params;
 135
 136   if ( ref($_[0]) ) {
 137     %params = %{ shift() };
 138   } else {
 139     %params = @_;
 140   }
 141
 142   $params{'format'} = 'latex';
 143   my $conf = $self->conf;
 144
 145   # this needs to go away
 146   my $template = $params{'template'};
 147   # and this especially
 148   $template ||= $self->_agent_template
 149     if $self->can('_agent_template');
 150
 151   #the new way
 152   $self->set('mode', $params{mode})
 153     if $params{mode};
 154
 155   my $pkey = $self->primary_key;
 156   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 157
 158   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 159   my $lh = new File::Temp(
 160     TEMPLATE => $tmp_template,
 161     DIR      => $dir,
 162     SUFFIX   => '.eps',
 163     UNLINK   => 0,
 164   ) or die "can't open temp file: $!\n";
 165
 166   my $agentnum = $self->agentnum;
 167
 168   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 169     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 170       or die "can't write temp file: $!\n";
 171   } else {
 172     print $lh $conf->config_binary('logo.eps', $agentnum)
 173       or die "can't write temp file: $!\n";
 174   }
 175   close $lh;
 176   $params{'logo_file'} = $lh->filename;
 177
 178   if( $conf->exists('invoice-barcode')
 179         && $self->can('invoice_barcode')
 180         && $self->invnum ) { # don't try to barcode statements
 181       my $png_file = $self->invoice_barcode($dir);
 182       my $eps_file = $png_file;
 183       $eps_file =~ s/\.png$/.eps/g;
 184       $png_file =~ /(barcode.*png)/;
 185       $png_file = $1;
 186       $eps_file =~ /(barcode.*eps)/;
 187       $eps_file = $1;
 188
 189       my $curr_dir = cwd();
 190       chdir($dir);
 191       # after painfuly long experimentation, it was determined that sam2p won't
 192       # accept : and other chars in the path, no matter how hard I tried to
 193       # escape them, hence the chdir (and chdir back, just to be safe)
 194       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 195         or die "sam2p failed: $!\n";
 196       unlink($png_file);
 197       chdir($curr_dir);
 198
 199       $params{'barcode_file'} = $eps_file;
 200   }
 201
 202   my @filled_in = $self->print_generic( %params );
 203
 204   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 205                            DIR      => $dir,
 206                            SUFFIX   => '.tex',
 207                            UNLINK   => 0,
 208                          ) or die "can't open temp file: $!\n";
 209   binmode($fh, ':utf8'); # language support
 210   print $fh join('', @filled_in );
 211   close $fh;
 212
 213   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 214   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 215
 216 }
 217
 218 sub agentnum {
 219   my $self = shift;
 220   my $cust_main = $self->cust_main;
 221   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 222 }
 223
 224 =item print_generic OPTION => VALUE ...
 225
 226 Internal method - returns a filled-in template for this invoice as a scalar.
 227
 228 See print_ps and print_pdf for methods that return PostScript and PDF output.
 229
 230 Required options
 231
 232 =over 4
 233
 234 =item format
 235
 236 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 237
 238 =back
 239
 240 Additional options
 241
 242 =over 4
 243
 244 =item notice_name
 245
 246 Overrides "Invoice" as the name of the sent document.
 247
 248 =item today
 249
 250 Used to control the printing of overdue messages.  The
 251 default is now.  It isn't the date of the invoice; that's the `_date' field.
 252 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 253 L<Time::Local> and L<Date::Parse> for conversion functions.
 254
 255 =item logo_file
 256
 257 Logo file (path to temporary EPS file on the local filesystem)
 258
 259 =item cid
 260
 261 CID for inline (emailed) images (logo)
 262
 263 =item locale
 264
 265 Override customer's locale
 266
 267 =item unsquelch_cdr
 268
 269 Overrides any per customer cdr squelching when true
 270
 271 =item no_number
 272
 273 Supress the (invoice, quotation, statement, etc.) number
 274
 275 =item no_date
 276
 277 Supress the date
 278
 279 =item no_coupon
 280
 281 Supress the payment coupon
 282
 283 =item barcode_file
 284
 285 Barcode file (path to temporary EPS file on the local filesystem)
 286
 287 =item barcode_img
 288
 289 Flag indicating the barcode image should be a link (normal HTML dipaly)
 290
 291 =item barcode_cid
 292
 293 Barcode CID for inline (emailed) images
 294
 295 =item preref_callback
 296
 297 Coderef run for each line item, code should return HTML to be displayed
 298 before that line item (quotations only)
 299
 300 =item template
 301
 302 Deprecated.  Used as a suffix for a configuration template.  Please
 303 don't use this, it deprecated in favor of more flexible alternatives.
 304
 305 =back
 306
 307 =cut
 308
 309 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 310 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 311 # yes: fixed width/plain text printing will be borked
 312 sub print_generic {
 313   my( $self, %params ) = @_;
 314   my $conf = $self->conf;
 315
 316   my $today = $params{today} ? $params{today} : time;
 317   warn "$me print_generic called on $self with suffix $params{template}\n"
 318     if $DEBUG;
 319
 320   my $format = $params{format};
 321   die "Unknown format: $format"
 322     unless $format =~ /^(latex|html|template)$/;
 323
 324   my $cust_main = $self->cust_main || $self->prospect_main;
 325
 326   my $locale = $params{'locale'} || $cust_main->locale;
 327
 328   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 329                      'html'     => [ '<%=', '%>' ],
 330                      'template' => [ '{', '}' ],
 331                    );
 332
 333   warn "$me print_generic creating template\n"
 334     if $DEBUG > 1;
 335
 336   # set the notice name here, and nowhere else.
 337   my $notice_name =  $params{notice_name}
 338                   || $conf->config('notice_name')
 339                   || $self->notice_name;
 340
 341   #create the template
 342   my $template = $params{template} ? $params{template} : $self->_agent_template;
 343   my $templatefile = $self->template_conf. $format;
 344   $templatefile .= "_$template"
 345     if length($template) && $conf->exists($templatefile."_$template");
 346
 347   $self->set('_template',$template);
 348
 349   # the base template
 350   my @invoice_template = map "$_\n", $conf->config($templatefile)
 351     or die "cannot load config data $templatefile";
 352
 353   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 354     #change this to a die when the old code is removed
 355     # it's been almost ten years, changing it to a die
 356     die "old-style invoice template $templatefile; ".
 357          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 358          #$old_latex = 'true';
 359          #@invoice_template = _translate_old_latex_format(@invoice_template);
 360   }
 361
 362   warn "$me print_generic creating T:T object\n"
 363     if $DEBUG > 1;
 364
 365   my $text_template = new Text::Template(
 366     TYPE => 'ARRAY',
 367     SOURCE => \@invoice_template,
 368     DELIMITERS => $delimiters{$format},
 369   );
 370
 371   warn "$me print_generic compiling T:T object\n"
 372     if $DEBUG > 1;
 373
 374   $text_template->compile()
 375     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 376
 377
 378   # additional substitution could possibly cause breakage in existing templates
 379   my %convert_maps = (
 380     'latex' => {
 381                  'notes'         => sub { map "$_", @_ },
 382                  'footer'        => sub { map "$_", @_ },
 383                  'smallfooter'   => sub { map "$_", @_ },
 384                  'returnaddress' => sub { map "$_", @_ },
 385                  'coupon'        => sub { map "$_", @_ },
 386                  'summary'       => sub { map "$_", @_ },
 387                },
 388     'html'  => {
 389                  'notes' =>
 390                    sub {
 391                      map {
 392                        s/%%(.*)$/<!-- $1 -->/g;
 393                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 394                        s/\\begin\{enumerate\}/<ol>/g;
 395                        s/\\item /  <li>/g;
 396                        s/\\end\{enumerate\}/<\/ol>/g;
 397                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 398                        s/\\\\\*/<br>/g;
 399                        s/\\dollar ?/\$/g;
 400                        s/\\#/#/g;
 401                        s/~/&nbsp;/g;
 402                        $_;
 403                      }  @_
 404                    },
 405                  'footer' =>
 406                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 407                  'smallfooter' =>
 408                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 409                  'returnaddress' =>
 410                    sub {
 411                      map {
 412                        s/~/&nbsp;/g;
 413                        s/\\\\\*?\s*$/<BR>/;
 414                        s/\\hyphenation\{[\w\s\-]+}//;
 415                        s/\\([&])/$1/g;
 416                        $_;
 417                      }  @_
 418                    },
 419                  'coupon'        => sub { "" },
 420                  'summary'       => sub { "" },
 421                },
 422     'template' => {
 423                  'notes' =>
 424                    sub {
 425                      map {
 426                        s/%%.*$//g;
 427                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 428                        s/\\begin\{enumerate\}//g;
 429                        s/\\item /  * /g;
 430                        s/\\end\{enumerate\}//g;
 431                        s/\\textbf\{(.*)\}/$1/g;
 432                        s/\\\\\*/ /;
 433                        s/\\dollar ?/\$/g;
 434                        $_;
 435                      }  @_
 436                    },
 437                  'footer' =>
 438                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 439                  'smallfooter' =>
 440                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 441                  'returnaddress' =>
 442                    sub {
 443                      map {
 444                        s/~/ /g;
 445                        s/\\\\\*?\s*$/\n/;             # dubious
 446                        s/\\hyphenation\{[\w\s\-]+}//;
 447                        $_;
 448                      }  @_
 449                    },
 450                  'coupon'        => sub { "" },
 451                  'summary'       => sub { "" },
 452                },
 453   );
 454
 455
 456   # hashes for differing output formats
 457   my %nbsps = ( 'latex'    => '~',
 458                 'html'     => '',    # '&nbps;' would be nice
 459                 'template' => '',    # not used
 460               );
 461   my $nbsp = $nbsps{$format};
 462
 463   my %escape_functions = ( 'latex'    => \&_latex_escape,
 464                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 465                            'template' => sub { shift },
 466                          );
 467   my $escape_function = $escape_functions{$format};
 468   my $escape_function_nonbsp = ($format eq 'html')
 469                                  ? \&_html_escape : $escape_function;
 470
 471   my %newline_tokens = (  'latex'     => '\\\\',
 472                           'html'      => '<br>',
 473                           'template'  => "\n",
 474                         );
 475   my $newline_token = $newline_tokens{$format};
 476
 477   warn "$me generating template variables\n"
 478     if $DEBUG > 1;
 479
 480   # generate template variables
 481   my $returnaddress;
 482
 483   if (
 484          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 485                                         $template
 486                                       )
 487                 )
 488        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 489                                         $template
 490                                       )
 491                 )
 492   ) {
 493
 494     $returnaddress = join("\n",
 495       $conf->config_orbase("invoice_${format}returnaddress", $template)
 496     );
 497
 498   } elsif ( grep /\S/,
 499             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 500
 501     my $convert_map = $convert_maps{$format}{'returnaddress'};
 502     $returnaddress =
 503       join( "\n",
 504             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 505                                                  $template
 506                                                )
 507                          )
 508           );
 509   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 510
 511     my $convert_map = $convert_maps{$format}{'returnaddress'};
 512     $returnaddress = join( "\n", &$convert_map(
 513                                    map { s/( {2,})/'~' x length($1)/eg;
 514                                          s/$/\\\\\*/;
 515                                          $_
 516                                        }
 517                                      ( $conf->config('company_name', $cust_main->agentnum),
 518                                        $conf->config('company_address', $cust_main->agentnum),
 519                                      )
 520                                  )
 521                      );
 522
 523   } else {
 524
 525     my $warning = "Couldn't find a return address; ".
 526                   "do you need to set the company_address configuration value?";
 527     warn "$warning\n";
 528     $returnaddress = $nbsp;
 529     #$returnaddress = $warning;
 530
 531   }
 532
 533   warn "$me generating invoice data\n"
 534     if $DEBUG > 1;
 535
 536   my $agentnum = $cust_main->agentnum;
 537
 538   my %invoice_data = (
 539
 540     #invoice from info
 541     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 542     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 543     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 544     'returnaddress'   => $returnaddress,
 545     'agent'           => &$escape_function($cust_main->agent->agent),
 546
 547     #invoice/quotation info
 548     'no_number'       => $params{'no_number'},
 549     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 550     'quotationnum'    => $self->quotationnum,
 551     'no_date'         => $params{'no_date'},
 552     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 553       # workaround for inconsistent behavior in the early plain text
 554       # templates; see RT#28271
 555     'date'            => ( $params{'no_date'}
 556                              ? ''
 557                              : ($format eq 'template'
 558                                ? $self->_date
 559                                : $self->time2str_local('long', $self->_date, $format)
 560                                )
 561                          ),
 562     'today'           => $self->time2str_local('long', $today, $format),
 563     'terms'           => $self->terms,
 564     'template'        => $template, #params{'template'},
 565     'notice_name'     => $notice_name, # escape?
 566     'current_charges' => sprintf("%.2f", $self->charged),
 567     'duedate'         => $self->due_date2str('rdate'), #date_format?
 568     'duedate_long'    => $self->due_date2str('long'),
 569
 570     #customer info
 571     'custnum'         => $cust_main->display_custnum,
 572     'prospectnum'     => $cust_main->prospectnum,
 573     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 574     ( map { $_ => &$escape_function($cust_main->$_()) }
 575         qw( company address1 address2 city state zip fax )
 576     ),
 577     'payname'         => &$escape_function( $cust_main->invoice_attn
 578                                              || $cust_main->contact_firstlast ),
 579
 580     #global config
 581     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 582     'unitprices'      => $conf->exists('invoice-unitprice'),
 583     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 584     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 585     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 586
 587     #layout info -- would be fancy to calc some of this and bury the template
 588     #               here in the code
 589     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 590     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 591     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 592     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 593     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 594     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 595     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 596     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 597     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 598     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 599
 600     # better hang on to conf_dir for a while (for old templates)
 601     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 602
 603     #these are only used when doing paged plaintext
 604     'page'            => 1,
 605     'total_pages'     => 1,
 606
 607   );
 608
 609   #quotations have $name
 610   $invoice_data{'name'} = $invoice_data{'payname'};
 611
 612   #localization
 613   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 614   # prototype here to silence warnings
 615   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 616
 617   my $min_sdate = 999999999999;
 618   my $max_edate = 0;
 619   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 620     next unless $cust_bill_pkg->pkgnum > 0;
 621     $min_sdate = $cust_bill_pkg->sdate
 622       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 623     $max_edate = $cust_bill_pkg->edate
 624       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 625   }
 626
 627   $invoice_data{'bill_period'} = '';
 628   $invoice_data{'bill_period'} =
 629       $self->time2str_local('%e %h', $min_sdate, $format)
 630       . " to " .
 631       $self->time2str_local('%e %h', $max_edate, $format)
 632     if ($max_edate != 0 && $min_sdate != 999999999999);
 633
 634   $invoice_data{finance_section} = '';
 635   if ( $conf->config('finance_pkgclass') ) {
 636     my $pkg_class =
 637       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 638     $invoice_data{finance_section} = $pkg_class->categoryname;
 639   }
 640   $invoice_data{finance_amount} = '0.00';
 641   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 642
 643   my $countrydefault = $conf->config('countrydefault') || 'US';
 644   foreach ( qw( address1 address2 city state zip country fax) ){
 645     my $method = 'ship_'.$_;
 646     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 647   }
 648   if ( length($cust_main->ship_company) ) {
 649     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 650   } else {
 651     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 652   }
 653   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 654   $invoice_data{'ship_country'} = ''
 655     if ( $invoice_data{'ship_country'} eq $countrydefault );
 656
 657   $invoice_data{'cid'} = $params{'cid'}
 658     if $params{'cid'};
 659
 660   if ( $cust_main->bill_locationnum
 661        && $cust_main->bill_location->country ne $countrydefault ) {
 662     $invoice_data{'country'} = &$escape_function($cust_main->bill_country_full);
 663   } else {
 664     $invoice_data{'country'} = '';
 665   }
 666
 667   my @address = ();
 668   $invoice_data{'address'} = \@address;
 669   push @address,
 670     $invoice_data{'payname'}.
 671       ( $cust_main->po_number
 672           ? " (P.O. #". $cust_main->po_number. ")"
 673           : ''
 674       )
 675   ;
 676   push @address, $cust_main->company
 677     if $cust_main->company;
 678   push @address, $cust_main->address1;
 679   push @address, $cust_main->address2
 680     if $cust_main->address2;
 681   push @address,
 682     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 683   push @address, $invoice_data{'country'}
 684     if $invoice_data{'country'};
 685   push @address, ''
 686     while (scalar(@address) < 5);
 687
 688   $invoice_data{'logo_file'} = $params{'logo_file'}
 689     if $params{'logo_file'};
 690   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 691     if $params{'barcode_file'};
 692   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 693     if $params{'barcode_img'};
 694   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 695     if $params{'barcode_cid'};
 696
 697
 698   # re: rt:78190
 699   #   using owed_on_invoice() instead of owed() here for $balance_due
 700   #   using _items_previous_total() instead of ->previous() for $pr_total
 701   #
 702   #   owed_on_invoice() is aware of configuration flags that affect how an
 703   #     invoice is rendered.  May not return actual current balance. Will
 704   #     return balance appropriate for the invoice being rendered, based
 705   #     on which past due items, current charges, and future payments are
 706   #     displayed.
 707   #
 708   #   Going forward, usage of owed(), or bypassing cust_bill helper methods
 709   #     when generating invoice lines may lead to incorrect or misleading
 710   #     math on invoices.
 711   #
 712   #   Helper methods that are aware of invoicing conf flags:
 713   #   - owed_on_invoice          # use instead of owed()
 714   #   - _items_previous()        # use instead of previous()
 715   #   - _items_credits()         # use instead of cust_credit()
 716   #   - _items_payments()
 717   #   - _items_total()
 718   #   - _items_previous_total()  # use instead of previous()
 719   #   - _items_payments_total()
 720   #   - _items_credits_total()   # use instead of cust_credit()
 721
 722   my $pr_total    = $self->_items_previous_total();
 723
 724   my $balance_due = $self->owed_on_invoice();
 725   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 726
 727   # flag telling this invoice to have a first-page summary
 728   my $summarypage = '';
 729
 730   if ( $self->custnum && $self->invnum ) {
 731     # XXX should be an FS::cust_bill method to set the defaults, instead
 732     # of checking the type here
 733
 734     # info from customer's last invoice before this one, for some
 735     # summary formats
 736     $invoice_data{'last_bill'} = {};
 737
 738     #    my $last_bill = $self->previous_bill;
 739     # if ( $last_bill ) {
 740
 741     # Populate template stash for previous balance and payments
 742     if ($pr_total) {
 743       # Used on summary page as "Previous Balance"
 744       $invoice_data{'true_previous_balance'} = sprintf("%.2f", $pr_total);
 745
 746       # Used on summary page as "Payments"
 747       $invoice_data{'balance_adjustments'} = sprintf("%.2f",
 748         $self->_items_payments_total() + $self->_items_credits_total()
 749       );
 750
 751       # Used in invoice template as "Previous Balance"
 752       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 753
 754       # $invoice_data{last_bill}{_date}:
 755       # Not used in default templates, but may be in use by someone
 756       #
 757       # ! May be a problem field if they are using it... this field
 758       #   stores the date of the previous invoice... it is possible to
 759       #   carry a balance, but have the immediately previous invoice paid off.
 760       #   In this case, this field might be presenting bad data?  Not
 761       #   altering the problematic behavior, because someone might be
 762       #   expecting this bad behavior in their templates for some other
 763       #   purpose, such as a "your last bill was dated %_date%"
 764       my $last_bill = $self->previous_bill;
 765       $invoice_data{'last_bill'}{'_date'}
 766         = ref $last_bill
 767         ? $last_bill->_date()
 768         : undef;
 769
 770       # $invoice_data{previous_payments}
 771       # Not used in default templates, but may be in use by someone
 772       #
 773       # Returns an array of hrefs representing payments, each with keys:
 774       #  - _date:       epoch timestamp
 775       #  - date:        text formatted date
 776       #  - amount:      money formatted amount string
 777       #  - payinfo:     string from payby_payinfo_pretty()
 778       #  - paynum:      id for cust_pay
 779       #  - description: Text description for bill line item
 780       #
 781       my @payments = $self->_items_payments();
 782       $invoice_data{previous_payments} = \@payments;
 783
 784       # $invoice_data{previous_credits}
 785       # Not used in default templates, but may be in use by someone
 786       #
 787       # Returns an array of hrefs representing credits, each with keys:
 788       #  - _date:        epoch timestamp
 789       #  - date:         text formatted date
 790       #  - amount:       money formatted amount string
 791       #  - crednum:      id for cust_credit
 792       #  - description:  Text description for bill line item
 793       #  - creditreason: reason() from cust_credit
 794       #
 795       my @credits = $self->_items_credits();
 796       $invoice_data{previous_credits} = \@credits;
 797
 798       # Populate formatted date field
 799       for my $pmt_href (@payments, @credits) {
 800         $pmt_href->{date} = $self->time2str_local(
 801           'long',
 802           $pmt_href->{_date},
 803           $format
 804         );
 805       }
 806
 807     } else {
 808       # There are no outstanding invoices    = YAPH
 809       $invoice_data{'true_previous_balance'} =
 810       $invoice_data{'balance_adjustments'}   =
 811       $invoice_data{'previous_balance'}      = '0.00';
 812       $invoice_data{'previous_payments'}     =
 813       $invoice_data{'previous_credits'}      = [];
 814     }
 815
 816     # Condencing a lot of debug staements here
 817     if ($DEBUG) {
 818       warn "\$invoice_data{$_}: $invoice_data{$_}"
 819         for qw(
 820           true_previous_balance
 821           balance_adjustments
 822           previous_balance
 823           previous_payments
 824           previous_credits
 825         );
 826     }
 827
 828     if ( $conf->config_bool('invoice_usesummary', $agentnum) ) {
 829       $invoice_data{'summarypage'} = $summarypage = 1;
 830     }
 831
 832   } # if this is an invoice
 833
 834   warn "$me substituting variables in notes, footer, smallfooter\n"
 835     if $DEBUG > 1;
 836
 837   my $tc = $self->template_conf;
 838   my @include = ( [ $tc,        'notes' ],
 839                   [ 'invoice_', 'footer' ],
 840                   [ 'invoice_', 'smallfooter', ],
 841                   [ 'invoice_', 'watermark' ],
 842                 );
 843   push @include, [ $tc,        'coupon', ]
 844     unless $params{'no_coupon'};
 845
 846   foreach my $i (@include) {
 847
 848     # load the configuration for this sub-template
 849
 850     my($base, $include) = @$i;
 851
 852     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 853
 854     my @inc_src = $conf->config($inc_file, $agentnum);
 855     if (!@inc_src) {
 856       my $converter = $convert_maps{$format}{$include};
 857       if ( $converter ) {
 858         # then attempt to convert LaTeX to the requested format
 859         $inc_file = $conf->key_orbase($base.'latex'.$include, $template);
 860         @inc_src = &$converter( $conf->config($inc_file, $agentnum) );
 861         foreach (@inc_src) {
 862           # this isn't included in the convert_maps
 863           my ($open, $close) = @{ $delimiters{$format} };
 864           s/\[\@--/$open/g;
 865           s/--\@\]/$close/g;
 866         }
 867       }
 868     } # else @inc_src is empty and that's fine
 869
 870     # make a Text::Template out of it
 871
 872     my $inc_tt = new Text::Template (
 873       TYPE       => 'ARRAY',
 874       SOURCE     => [ map "$_\n", @inc_src ],
 875       DELIMITERS => $delimiters{$format},
 876     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 877
 878     unless ( $inc_tt->compile() ) {
 879       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 880       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 881       die $error;
 882     }
 883
 884     # fill in variables
 885
 886     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 887
 888     $invoice_data{$include} =~ s/\n+$//
 889       if ($format eq 'latex');
 890   }
 891
 892 # if (well, probably when) we still need PO numbers in the brave new world of
 893 # 4.x, then we'll have to add them back as their own customer fields
 894 #  # let invoices use either of these as needed
 895 #  $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 896 #    ? $cust_main->payinfo : '';
 897 #  $invoice_data{'po_line'} =
 898 #    (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 899 #      ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 900 #      : $nbsp;
 901
 902   my %money_chars = ( 'latex'    => '',
 903                       'html'     => $conf->config('money_char') || '$',
 904                       'template' => '',
 905                     );
 906   my $money_char = $money_chars{$format};
 907
 908   # extremely dubious
 909   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 910                             'html'     => $conf->config('money_char') || '$',
 911                             'template' => '',
 912                           );
 913   my $other_money_char = $other_money_chars{$format};
 914   $invoice_data{'dollar'} = $other_money_char;
 915
 916   my %minus_signs = ( 'latex'    => '$-$',
 917                       'html'     => '&minus;',
 918                       'template' => '- ' );
 919   my $minus = $minus_signs{$format};
 920
 921   my @detail_items = ();
 922   my @total_items = ();
 923   my @buf = ();
 924   my @sections = ();
 925
 926   $invoice_data{'detail_items'} = \@detail_items;
 927   $invoice_data{'total_items'} = \@total_items;
 928   $invoice_data{'buf'} = \@buf;
 929   $invoice_data{'sections'} = \@sections;
 930
 931   warn "$me generating sections\n"
 932     if $DEBUG > 1;
 933
 934   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 935   my $multisection = $self->has_sections;
 936   $invoice_data{'multisection'} = $multisection;
 937   my $late_sections;
 938   my $extra_sections = [];
 939   my $extra_lines = ();
 940
 941   # default section ('Charges')
 942   my $default_section = { 'description' => '',
 943                           'subtotal'    => '',
 944                           'no_subtotal' => 1,
 945                         };
 946
 947   # Previous Charges section
 948   # subtotal is the first return value from $self->previous
 949   my $previous_section;
 950   # if the invoice has major sections, or if we're summarizing previous
 951   # charges with a single line, or if we've been specifically told to put them
 952   # in a section, create a section for previous charges:
 953   if ( $multisection or
 954        $conf->exists('previous_balance-summary_only') or
 955        $conf->exists('previous_balance-section') ) {
 956
 957     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 958                            'subtotal'    => $other_money_char.
 959                                             sprintf('%.2f', $pr_total),
 960                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 961                          };
 962
 963     # Include balance aging line and template variables
 964     my @aged_balances = $self->_items_aging_balances();
 965     ( $invoice_data{aged_balance_current},
 966       $invoice_data{aged_balance_30d},
 967       $invoice_data{aged_balance_60d},
 968       $invoice_data{aged_balance_90d}
 969     ) = @aged_balances;
 970
 971     if ($conf->exists('invoice_include_aging')) {
 972       $previous_section->{posttotal} = sprintf(
 973         '0 / 30 / 60 / 90 days overdue %.2f / %.2f / %.2f / %.2f',
 974         @aged_balances,
 975       );
 976     }
 977
 978   } else {
 979     # otherwise put them in the main section
 980     $previous_section = $default_section;
 981   }
 982
 983   my $adjust_section = {
 984     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 985     'adjust_section' => 1,
 986     'subtotal'       => 0,   # adjusted below
 987   };
 988   my $adjust_weight = _pkg_category($adjust_section->{description})
 989                         ? _pkg_category($adjust_section->{description})->weight
 990                         : 0;
 991   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 992   # Note: 'sort_weight' here is actually a flag telling whether there is an
 993   # explicit package category for the adjust section. If so, certain behavior
 994   # happens.
 995   $adjust_section->{'sort_weight'} = $adjust_weight;
 996
 997
 998   if ( $multisection ) {
 999     ($extra_sections, $extra_lines) =
1000       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
1001       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
1002       && $self->can('_items_extra_usage_sections');
1003
1004     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
1005
1006     push @detail_items, @$extra_lines if $extra_lines;
1007
1008     # the code is written so that both methods can be used together, but
1009     # we haven't yet changed the template to take advantage of that, so for
1010     # now, treat them as mutually exclusive.
1011     my %section_method = ( by_category => 1 );
1012     if ( $conf->config($tc.'sections_method') eq 'location' ) {
1013       %section_method = ( by_location => 1 );
1014     }
1015     my ($early, $late) =
1016       $self->_items_sections( 'summary' => $summarypage,
1017                               'escape'  => $escape_function_nonbsp,
1018                               'extra_sections' => $extra_sections,
1019                               'format'  => $format,
1020                               %section_method
1021                             );
1022     push @sections, @$early;
1023     $late_sections = $late;
1024
1025     if (    $conf->exists('svc_phone_sections')
1026          && $self->can('_items_svc_phone_sections')
1027        )
1028     {
1029       my ($phone_sections, $phone_lines) =
1030         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1031       push @{$late_sections}, @$phone_sections;
1032       push @detail_items, @$phone_lines;
1033     }
1034     if ( $conf->exists('voip-cust_accountcode_cdr')
1035          && $cust_main->accountcode_cdr
1036          && $self->can('_items_accountcode_cdr')
1037        )
1038     {
1039       my ($accountcode_section, $accountcode_lines) =
1040         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1041       if ( scalar(@$accountcode_lines) ) {
1042           push @{$late_sections}, $accountcode_section;
1043           push @detail_items, @$accountcode_lines;
1044       }
1045     }
1046   } else {# not multisection
1047     # make a default section
1048     push @sections, $default_section;
1049     # and calculate the finance charge total, since it won't get done otherwise.
1050     # and the default section total
1051     # XXX possibly finance_pkgclass should not be used in this manner?
1052     my @finance_charges;
1053     my @charges;
1054     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1055       if ( $invoice_data{finance_section} and
1056         grep { $_->section eq $invoice_data{finance_section} }
1057            $cust_bill_pkg->cust_bill_pkg_display ) {
1058         # I think these are always setup fees, but just to be sure...
1059         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1060       } else {
1061         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1062       }
1063     }
1064     $invoice_data{finance_amount} =
1065       sprintf('%.2f', sum( @finance_charges ) || 0);
1066     $default_section->{subtotal} = $other_money_char.
1067                                     sprintf('%.2f', sum( @charges ) || 0);
1068   }
1069
1070   # start setting up summary subtotals
1071   my @summary_subtotals;
1072   my $method = $conf->config('summary_subtotals_method');
1073   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1074     # then re-section them by the correct method
1075     my %section_method = ( by_category => 1 );
1076     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1077       %section_method = ( by_location => 1 );
1078     }
1079     my ($early, $late) =
1080       $self->_items_sections( 'summary' => $summarypage,
1081                               'escape'  => $escape_function_nonbsp,
1082                               'extra_sections' => $extra_sections,
1083                               'format'  => $format,
1084                               %section_method
1085                             );
1086     foreach ( @$early ) {
1087       next if $_->{subtotal} == 0;
1088       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1089       push @summary_subtotals, $_;
1090     }
1091   } else {
1092     # subtotal sectioning is the same as for the actual invoice sections
1093     @summary_subtotals = grep $_->{subtotal}, @sections;
1094   }
1095
1096   # Hereafter, push sections to both @sections and @summary_subtotals
1097   # if they belong in both places (e.g. tax section).  Late sections are
1098   # never in @summary_subtotals.
1099
1100   # previous invoice balances in the Previous Charges section if there
1101   # is one, otherwise in the main detail section
1102   # (except if summary_only is enabled, don't show them at all)
1103   if ( $self->can('_items_previous') &&
1104        $self->enable_previous &&
1105        ! $conf->exists('previous_balance-summary_only') ) {
1106
1107     warn "$me adding previous balances\n"
1108       if $DEBUG > 1;
1109
1110     foreach my $line_item ( $self->_items_previous ) {
1111
1112       my $detail = {
1113         ref             => $line_item->{'pkgnum'},
1114         pkgpart         => $line_item->{'pkgpart'},
1115         #quantity        => 1, # not really correct
1116         section         => $previous_section, # which might be $default_section
1117         description     => &$escape_function($line_item->{'description'}),
1118         ext_description => [ map { &$escape_function($_) }
1119                              @{ $line_item->{'ext_description'} || [] }
1120                            ],
1121         amount          => $money_char . $line_item->{'amount'},
1122         product_code    => $line_item->{'pkgpart'} || 'N/A',
1123       };
1124
1125       push @detail_items, $detail;
1126       push @buf, [ $detail->{'description'},
1127                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1128                  ];
1129     }
1130
1131   }
1132
1133   if ( $pr_total && $self->enable_previous ) {
1134     push @buf, ['','-----------'];
1135     push @buf, [ $self->mt('Total Previous Balance'),
1136                  $money_char. sprintf("%10.2f", $pr_total) ];
1137     push @buf, ['',''];
1138   }
1139
1140   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1141       warn "$me adding DID summary\n"
1142         if $DEBUG > 1;
1143
1144       my ($didsummary,$minutes) = $self->_did_summary;
1145       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1146       push @detail_items,
1147        { 'description' => $didsummary_desc,
1148            'ext_description' => [ $didsummary, $minutes ],
1149        };
1150   }
1151
1152   foreach my $section (@sections, @$late_sections) {
1153
1154     # begin some normalization
1155     $section->{'subtotal'} = $section->{'amount'}
1156       if $multisection
1157          && !exists($section->{subtotal})
1158          && exists($section->{amount});
1159
1160     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1161       if ( $invoice_data{finance_section} &&
1162            $section->{'description'} eq $invoice_data{finance_section} );
1163
1164     if ( $multisection ) {
1165
1166       if ( ref($section->{'subtotal'}) ) {
1167
1168         $section->{'subtotal'} =
1169           sprintf("$other_money_char%.2f to $other_money_char%.2f",
1170                     $section->{'subtotal'}[0],
1171                     $section->{'subtotal'}[1]
1172                  );
1173
1174       } else {
1175
1176         $section->{'subtotal'} = $other_money_char.
1177                                  sprintf('%.2f', $section->{'subtotal'})
1178
1179       }
1180
1181       # continue some normalization
1182       $section->{'amount'}   = $section->{'subtotal'}
1183
1184     }
1185
1186     if ( $section->{'description'} ) {
1187       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1188                    [ '', '' ],
1189                  );
1190     }
1191
1192     warn "$me   setting options\n"
1193       if $DEBUG > 1;
1194
1195     my %options = ();
1196     $options{'section'} = $section if $multisection;
1197     $options{'section_with_taxes'} = 1
1198       if $multisection
1199       && $conf->config_bool('invoice_sections_with_taxes', $cust_main->agentnum);
1200     $options{'format'} = $format;
1201     $options{'escape_function'} = $escape_function;
1202     $options{'no_usage'} = 1 unless $unsquelched;
1203     $options{'unsquelched'} = $unsquelched;
1204     $options{'summary_page'} = $summarypage;
1205     $options{'skip_usage'} =
1206       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1207     $options{'preref_callback'} = $params{'preref_callback'};
1208     $options{'disable_line_item_date_ranges'} =
1209       $conf->exists('disable_line_item_date_ranges');
1210
1211     warn "$me   searching for line items\n"
1212       if $DEBUG > 1;
1213
1214     my %section_tax_lines;
1215     my %seen_tax_lines;
1216     foreach my $line_item ( $self->_items_pkg(%options),
1217                             $self->_items_fee(%options) ) {
1218
1219       warn "$me     adding line item ".
1220            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1221         if $DEBUG > 1;
1222
1223       push @buf, ( [ $line_item->{'description'},
1224                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1225                    ],
1226                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1227                  );
1228
1229       $line_item->{'ref'} = $line_item->{'pkgnum'};
1230       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1231       $line_item->{'section'} = $section;
1232       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1233       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1234
1235       if ( length($line_item->{'unit_amount'}) ) {
1236         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1237       }
1238       $line_item->{'ext_description'} ||= [];
1239
1240       if ( $options{section_with_taxes} && ref $line_item->{pkg_tax} ) {
1241         for my $line_tax ( @{$ line_item->{pkg_tax} } ) {
1242
1243           # It is rarely possible for the same tax record to be presented here
1244           # multiple times.  See cust_bill_pkg::_pkg_tax_list for more info
1245           next if $seen_tax_lines{ $line_tax->{billpkgtaxlocationnum} };
1246           $seen_tax_lines{ $line_tax->{billpkgtaxlocationnum} } = 1;
1247
1248           $section_tax_lines{ $line_tax->{taxname} } += $line_tax->{amount};
1249         }
1250       }
1251
1252       push @detail_items, $line_item;
1253     }
1254
1255     # If conf flag invoice_sections_with_taxes:
1256     # - Add @detail_items for taxes into each section
1257     # - Update section subtotal to include taxes
1258     if ( $options{section_with_taxes} && %section_tax_lines ) {
1259       for my $taxname ( keys %section_tax_lines ) {
1260
1261         push @detail_items, {
1262           section => $section,
1263           amount  => sprintf($money_char."%.2f",$section_tax_lines{$taxname}),
1264           description => &$escape_function($taxname),
1265         };
1266
1267         # Append taxes to total.  If line format resembles "$5.00 to $12.00"
1268         # append to the second value.
1269
1270         # $section->{subtotal} = '$5.00 to 12.00'; # for testing:
1271         if ($section->{subtotal} =~ /to/) {
1272           my @subtotal = split /\s/, $section->{subtotal};
1273           $subtotal[2] =~ s/[^\d\.]//g;
1274           $subtotal[2] = sprintf(
1275             $money_char."%.2f",
1276             ( $subtotal[2] + $section_tax_lines{$taxname} )
1277           );
1278           $section->{subtotal} = join ' ', @subtotal;
1279         } else {
1280           $section->{subtotal} =~ s/[^\d\.]//g;
1281           $section->{subtotal} = sprintf(
1282             $money_char . "%.2f",
1283             ( $section->{subtotal} + $section_tax_lines{$taxname} )
1284           );
1285         }
1286
1287       }
1288     }
1289
1290     if ( $section->{'description'} ) {
1291       push @buf, ( ['','-----------'],
1292                    [ $section->{'description'}. ' sub-total',
1293                       $section->{'subtotal'} # already formatted this
1294                    ],
1295                    [ '', '' ],
1296                    [ '', '' ],
1297                  );
1298     }
1299
1300   }
1301
1302   $invoice_data{current_less_finance} =
1303     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1304
1305   # if there's anything in the Previous Charges section, prepend it to the list
1306   if ( $pr_total and $previous_section ne $default_section ) {
1307     unshift @sections, $previous_section;
1308     # but not @summary_subtotals
1309   }
1310
1311   warn "$me adding taxes\n"
1312     if $DEBUG > 1;
1313
1314   # create a tax section if we don't yet have one
1315   my @items_tax = $self->_items_tax;
1316   my $tax_description = 'Taxes, Surcharges, and Fees';
1317   my $tax_section =
1318     List::Util::first { $_->{description} eq $tax_description } @sections;
1319   if (!$tax_section) {
1320     $tax_section = { 'description' => $tax_description };
1321     push @sections, $tax_section if $multisection and @items_tax > 0;
1322   }
1323   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1324   # if this is an existing tax section, we're merging the tax items into it.
1325   # grab the taxtotal that's already there, strip the money symbol if any
1326   my $taxtotal = $tax_section->{'subtotal'} || 0;
1327   $taxtotal =~ s/^\Q$other_money_char\E//;
1328
1329   # this does nothing
1330   #my $tax_weight = _pkg_category($tax_section->{description})
1331   #                      ? _pkg_category($tax_section->{description})->weight
1332   #                      : 0;
1333   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1334   #$tax_section->{'sort_weight'} = $tax_weight;
1335
1336   foreach my $tax ( @items_tax ) {
1337
1338     $taxtotal += $tax->{'amount'};
1339
1340     my $description = &$escape_function( $tax->{'description'} );
1341     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1342
1343     if ( $multisection ) {
1344
1345       push @detail_items, {
1346         ext_description => [],
1347         ref          => '',
1348         quantity     => '',
1349         description  => $description,
1350         amount       => $money_char. $amount,
1351         product_code => '',
1352         section      => $tax_section,
1353       };
1354
1355     } else {
1356
1357       push @total_items, {
1358         'total_item'   => $description,
1359         'total_amount' => $other_money_char. $amount,
1360       };
1361
1362     }
1363
1364     push @buf,[ $description,
1365                 $money_char. $amount,
1366               ];
1367
1368   }
1369
1370   if ( @items_tax ) {
1371     my $total = {};
1372     $total->{'total_item'} = $self->mt('Sub-total');
1373     $total->{'total_amount'} =
1374       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1375
1376     if ( $multisection ) {
1377       if ( $taxtotal > 0 ) {
1378         # there are taxes, so prepare the section to be displayed.
1379         # $taxtotal already includes any line items that were already in the
1380         # section (fees, taxes that are charged as packages for some reason).
1381         # also set 'summarized' to false so that this isn't a summary-only
1382         # section.
1383         $tax_section->{'subtotal'} = $other_money_char.
1384                                      sprintf('%.2f', $taxtotal);
1385         $tax_section->{'pretotal'} = 'New charges sub-total '.
1386                                      $total->{'total_amount'};
1387         $tax_section->{'description'} = $self->mt($tax_description);
1388         $tax_section->{'summarized'} = '';
1389
1390         if ( $conf->config_bool('invoice_sections_with_taxes', $cust_main->agentnum) ) {
1391
1392           # remove tax section if taxes are itemized within other sections
1393           @sections = grep{ $_ ne $tax_section } @sections;
1394
1395         } elsif ( !grep $tax_section, @sections ) {
1396
1397           # append it if it's not already there
1398           push @sections, $tax_section;
1399           push @summary_subtotals, $tax_section;
1400
1401         }
1402
1403       }
1404     } else {
1405       unshift @total_items, $total;
1406     }
1407   }
1408   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1409
1410   ###
1411   # Totals
1412   ###
1413
1414   my %embolden_functions = (
1415     'latex'    => sub { return '\textbf{'. shift(). '}' },
1416     'html'     => sub { return '<b>'. shift(). '</b>' },
1417     'template' => sub { shift },
1418   );
1419   my $embolden_function = $embolden_functions{$format};
1420
1421   if ( $multisection ) {
1422
1423     if ( $adjust_section->{'sort_weight'} ) {
1424       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1425         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1426     } else{
1427       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1428         $other_money_char.  sprintf('%.2f', $self->charged );
1429     }
1430
1431   }
1432
1433   if ( $self->can('_items_total') ) { # should always be true now
1434
1435     # even for multisection, need plain text version
1436
1437     my @new_total_items = $self->_items_total;
1438
1439     push @buf,['','-----------'];
1440
1441     foreach ( @new_total_items ) {
1442       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1443       $_->{'total_item'}   = &$embolden_function( $item );
1444
1445       if ( ref($amount) ) {
1446         $_->{'total_amount'} = &$embolden_function(
1447                                  $other_money_char.$amount->[0]. ' to '.
1448                                  $other_money_char.$amount->[1]
1449                                );
1450       } else {
1451         $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1452       }
1453
1454       # but if it's multisection, don't append to @total_items. the adjust
1455       # section has all this stuff
1456       push @total_items, $_ if !$multisection;
1457       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1458     }
1459
1460     push @buf, [ '', '' ];
1461
1462     # if we're showing previous invoices, also show previous
1463     # credits and payments
1464     if ( $self->enable_previous
1465           and $self->can('_items_credits')
1466           and $self->can('_items_payments') )
1467       {
1468
1469       # credits
1470       my $credittotal = 0;
1471       foreach my $credit (
1472         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1473       ) {
1474
1475         my $total;
1476         $total->{'total_item'} = &$escape_function($credit->{'description'});
1477         $credittotal += $credit->{'amount'};
1478         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1479         if ( $multisection ) {
1480           push @detail_items, {
1481             ext_description => [],
1482             ref          => '',
1483             quantity     => '',
1484             description  => &$escape_function($credit->{'description'}),
1485             amount       => $money_char . $credit->{'amount'},
1486             product_code => '',
1487             section      => $adjust_section,
1488           };
1489         } else {
1490           push @total_items, $total;
1491         }
1492
1493       }
1494       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1495
1496       #credits (again)
1497       foreach my $credit (
1498         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1499       ) {
1500         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1501       }
1502
1503       # payments
1504       my $paymenttotal = 0;
1505       foreach my $payment (
1506         $self->_items_payments( 'template' => $template )
1507       ) {
1508         my $total = {};
1509         $total->{'total_item'} = &$escape_function($payment->{'description'});
1510         $paymenttotal += $payment->{'amount'};
1511         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1512         if ( $multisection ) {
1513           push @detail_items, {
1514             ext_description => [],
1515             ref          => '',
1516             quantity     => '',
1517             description  => &$escape_function($payment->{'description'}),
1518             amount       => $money_char . $payment->{'amount'},
1519             product_code => '',
1520             section      => $adjust_section,
1521           };
1522         }else{
1523           push @total_items, $total;
1524         }
1525         push @buf, [ $payment->{'description'},
1526                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1527                    ];
1528       }
1529       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1530
1531       if ( $multisection ) {
1532         $adjust_section->{'subtotal'} = $other_money_char.
1533                                         sprintf('%.2f', $credittotal + $paymenttotal);
1534
1535         #why this? because {sort_weight} forces the adjust_section to appear
1536         #in @extra_sections instead of @sections. obviously.
1537         push @sections, $adjust_section
1538           unless $adjust_section->{sort_weight};
1539         # do not summarize; adjustments there are shown according to
1540         # different rules
1541       }
1542
1543       # create Balance Due message
1544       {
1545         my $total;
1546         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1547         $total->{'total_amount'} =
1548           &$embolden_function(
1549             $other_money_char. sprintf('%.2f', #why? $summarypage
1550                                                #  ? $self->charged +
1551                                                #    $self->billing_balance
1552                                                #  :
1553                                                    $balance_due
1554                                       )
1555           );
1556         if ( $multisection && !$adjust_section->{sort_weight} ) {
1557           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1558                                            $total->{'total_amount'};
1559         } else {
1560           push @total_items, $total;
1561         }
1562         push @buf,['','-----------'];
1563         push @buf,[$self->balance_due_msg, $money_char.
1564           sprintf("%10.2f", $balance_due ) ];
1565       }
1566
1567       if ( $conf->exists('previous_balance-show_credit')
1568           and $cust_main->balance < 0 ) {
1569         my $credit_total = {
1570           'total_item'    => &$embolden_function($self->credit_balance_msg),
1571           'total_amount'  => &$embolden_function(
1572             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1573           ),
1574         };
1575         if ( $multisection ) {
1576           $adjust_section->{'posttotal'} .= $newline_token .
1577             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1578         }
1579         else {
1580           push @total_items, $credit_total;
1581         }
1582         push @buf,['','-----------'];
1583         push @buf,[$self->credit_balance_msg, $money_char.
1584           sprintf("%10.2f", -$cust_main->balance ) ];
1585       }
1586     }
1587
1588   } #end of default total adding ! can('_items_total')
1589
1590   if ( $multisection ) {
1591     if (    $conf->exists('svc_phone_sections')
1592          && $self->can('_items_svc_phone_sections')
1593        )
1594     {
1595       my $total;
1596       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1597       $total->{'total_amount'} =
1598         &$embolden_function(
1599           $other_money_char. sprintf('%.2f', $balance_due)
1600         );
1601       my $last_section = pop @sections;
1602       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1603                                      $total->{'total_amount'};
1604       push @sections, $last_section;
1605     }
1606     push @sections, @$late_sections
1607       if $unsquelched;
1608   }
1609
1610   # make a discounts-available section, even without multisection
1611   if ( $conf->exists('discount-show_available')
1612        and my @discounts_avail = $self->_items_discounts_avail ) {
1613     my $discount_section = {
1614       'description' => $self->mt('Discounts Available'),
1615       'subtotal'    => '',
1616       'no_subtotal' => 1,
1617     };
1618
1619     push @sections, $discount_section; # do not summarize
1620     push @detail_items, map { +{
1621         'ref'         => '', #should this be something else?
1622         'section'     => $discount_section,
1623         'description' => &$escape_function( $_->{description} ),
1624         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1625         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1626     } } @discounts_avail;
1627   }
1628
1629   # not adding any more sections after this
1630   $invoice_data{summary_subtotals} = \@summary_subtotals;
1631
1632   # usage subtotals
1633   if ( $conf->exists('usage_class_summary')
1634        and $self->can('_items_usage_class_summary') ) {
1635     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function, 'money_char' => $other_money_char);
1636     if ( @usage_subtotals ) {
1637       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1638       unshift @detail_items, @usage_subtotals;
1639     }
1640   }
1641
1642   # invoice history "section" (not really a section)
1643   # not to be included in any subtotals, completely independent of
1644   # everything...
1645   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1646     my %history;
1647     my %monthorder;
1648     foreach my $cust_bill ( $cust_main->cust_bill ) {
1649       # XXX hardcoded format, and currently only 'charged'; add other fields
1650       # if they become necessary
1651       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1652       $history{$date} ||= 0;
1653       $history{$date} += $cust_bill->charged;
1654       # just so we have a numeric sort key
1655       $monthorder{$date} ||= $cust_bill->_date;
1656     }
1657     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1658                         keys %history;
1659     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1660     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1661   }
1662
1663   # service locations: another option for template customization
1664   my %location_info;
1665   foreach my $item (@detail_items) {
1666     if ( $item->{locationnum} ) {
1667       $location_info{ $item->{locationnum} } ||= {
1668         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1669       };
1670     }
1671   }
1672   $invoice_data{location_info} = \%location_info;
1673
1674   # debugging hook: call this with 'diag' => 1 to just get a hash of
1675   # the invoice variables
1676   return \%invoice_data if ( $params{'diag'} );
1677
1678   # All sections and items are built; now fill in templates.
1679   my @includelist = ();
1680   push @includelist, 'summary' if $summarypage;
1681   foreach my $include ( @includelist ) {
1682
1683     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1684     my @inc_src;
1685
1686     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1687
1688       @inc_src = $conf->config($inc_file, $agentnum);
1689
1690     } else {
1691
1692       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1693
1694       my $convert_map = $convert_maps{$format}{$include};
1695
1696       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1697                        s/--\@\]/$delimiters{$format}[1]/g;
1698                        $_;
1699                      }
1700                  &$convert_map( $conf->config($inc_file, $agentnum) );
1701
1702     }
1703
1704     my $inc_tt = new Text::Template (
1705       TYPE       => 'ARRAY',
1706       SOURCE     => [ map "$_\n", @inc_src ],
1707       DELIMITERS => $delimiters{$format},
1708     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1709
1710     unless ( $inc_tt->compile() ) {
1711       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1712       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1713       die $error;
1714     }
1715
1716     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1717
1718     $invoice_data{$include} =~ s/\n+$//
1719       if ($format eq 'latex');
1720   }
1721
1722   $invoice_lines = 0;
1723   my $wasfunc = 0;
1724   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1725     /invoice_lines\((\d*)\)/;
1726     $invoice_lines += $1 || scalar(@buf);
1727     $wasfunc=1;
1728   }
1729   die "no invoice_lines() functions in template?"
1730     if ( $format eq 'template' && !$wasfunc );
1731
1732   if ( $invoice_lines ) {
1733     $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1734     $invoice_data{'total_pages'}++
1735       if scalar(@buf) % $invoice_lines;
1736   }
1737
1738   #setup subroutine for the template
1739   $invoice_data{invoice_lines} = sub {
1740     my $lines = shift || scalar(@buf);
1741     map {
1742       scalar(@buf)
1743         ? shift @buf
1744         : [ '', '' ];
1745     }
1746     ( 1 .. $lines );
1747   };
1748
1749   if ($format eq 'template') {
1750
1751     my $lines;
1752     my @collect;
1753     while (@buf) {
1754       push @collect, split("\n",
1755         $text_template->fill_in( HASH => \%invoice_data )
1756       );
1757       $invoice_data{'page'}++;
1758     }
1759     map "$_\n", @collect;
1760
1761   } else { # this is where we actually create the invoice
1762
1763     if ( $params{no_addresses} ) {
1764       delete $invoice_data{$_} foreach qw(
1765         payname company address1 address2 city state zip country
1766       );
1767       $invoice_data{returnaddress} = '~';
1768     }
1769
1770     warn "filling in template for invoice ". $self->invnum. "\n"
1771       if $DEBUG;
1772     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1773       if $DEBUG > 1;
1774
1775     $text_template->fill_in(HASH => \%invoice_data);
1776   }
1777 }
1778
1779 sub notice_name { '('.shift->table.')'; }
1780
1781 # this is not supposed to happen
1782 sub template_conf { warn "bare FS::Template_Mixin::template_conf";
1783   'invoice_';
1784 }
1785
1786 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1787
1788 Returns an postscript invoice, as a scalar.
1789
1790 Options can be passed as a hashref (recommended) or as a list of time, template
1791 and then any key/value pairs for any other options.
1792
1793 I<time> an optional value used to control the printing of overdue messages.  The
1794 default is now.  It isn't the date of the invoice; that's the `_date' field.
1795 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1796 L<Time::Local> and L<Date::Parse> for conversion functions.
1797
1798 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1799
1800 =cut
1801
1802 sub print_ps {
1803   my $self = shift;
1804
1805   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1806   my $ps = generate_ps($file);
1807   unlink($logofile);
1808   unlink($barcodefile) if $barcodefile;
1809
1810   $ps;
1811 }
1812
1813 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1814
1815 Returns an PDF invoice, as a scalar.
1816
1817 Options can be passed as a hashref (recommended) or as a list of time, template
1818 and then any key/value pairs for any other options.
1819
1820 I<time> an optional value used to control the printing of overdue messages.  The
1821 default is now.  It isn't the date of the invoice; that's the `_date' field.
1822 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1823 L<Time::Local> and L<Date::Parse> for conversion functions.
1824
1825 I<template>, if specified, is the name of a suffix for alternate invoices.
1826
1827 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1828
1829 =cut
1830
1831 sub print_pdf {
1832   my $self = shift;
1833
1834   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1835   my $pdf = generate_pdf($file);
1836   unlink($logofile);
1837   unlink($barcodefile) if $barcodefile;
1838
1839   $pdf;
1840 }
1841
1842 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1843
1844 Returns an HTML invoice, as a scalar.
1845
1846 I<time> an optional value used to control the printing of overdue messages.  The
1847 default is now.  It isn't the date of the invoice; that's the `_date' field.
1848 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1849 L<Time::Local> and L<Date::Parse> for conversion functions.
1850
1851 I<template>, if specified, is the name of a suffix for alternate invoices.
1852
1853 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1854
1855 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1856 when emailing the invoice as part of a multipart/related MIME email.
1857
1858 =cut
1859
1860 sub print_html {
1861   my $self = shift;
1862   my %params;
1863   if ( ref($_[0]) ) {
1864     %params = %{ shift() };
1865   } else {
1866     %params = @_;
1867   }
1868   $params{'format'} = 'html';
1869
1870   $self->print_generic( %params );
1871 }
1872
1873 # quick subroutine for print_latex
1874 #
1875 # There are ten characters that LaTeX treats as special characters, which
1876 # means that they do not simply typeset themselves:
1877 #      # $ % & ~ _ ^ \ { }
1878 #
1879 # TeX ignores blanks following an escaped character; if you want a blank (as
1880 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1881
1882 sub _latex_escape {
1883   my $value = shift;
1884   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1885   $value =~ s/([<>])/\$$1\$/g;
1886   $value;
1887 }
1888
1889 sub _html_escape {
1890   my $value = shift;
1891   encode_entities($value);
1892   $value;
1893 }
1894
1895 sub _html_escape_nbsp {
1896   my $value = _html_escape(shift);
1897   $value =~ s/ +/&nbsp;/g;
1898   $value;
1899 }
1900
1901 #utility methods for print_*
1902
1903 sub _translate_old_latex_format {
1904   warn "_translate_old_latex_format called\n"
1905     if $DEBUG;
1906
1907   my @template = ();
1908   while ( @_ ) {
1909     my $line = shift;
1910
1911     if ( $line =~ /^%%Detail\s*$/ ) {
1912
1913       push @template, q![@--!,
1914                       q!  foreach my $_tr_line (@detail_items) {!,
1915                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1916                       q!      $_tr_line->{'description'} .= !,
1917                       q!        "\\tabularnewline\n~~".!,
1918                       q!        join( "\\tabularnewline\n~~",!,
1919                       q!          @{$_tr_line->{'ext_description'}}!,
1920                       q!        );!,
1921                       q!    }!;
1922
1923       while ( ( my $line_item_line = shift )
1924               !~ /^%%EndDetail\s*$/                            ) {
1925         $line_item_line =~ s/'/\\'/g;    # nice LTS
1926         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1927         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1928         push @template, "    \$OUT .= '$line_item_line';";
1929       }
1930
1931       push @template, '}',
1932                       '--@]';
1933       #' doh, gvim
1934     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1935
1936       push @template, '[@--',
1937                       '  foreach my $_tr_line (@total_items) {';
1938
1939       while ( ( my $total_item_line = shift )
1940               !~ /^%%EndTotalDetails\s*$/                      ) {
1941         $total_item_line =~ s/'/\\'/g;    # nice LTS
1942         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1943         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1944         push @template, "    \$OUT .= '$total_item_line';";
1945       }
1946
1947       push @template, '}',
1948                       '--@]';
1949
1950     } else {
1951       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1952       push @template, $line;
1953     }
1954
1955   }
1956
1957   if ($DEBUG) {
1958     warn "$_\n" foreach @template;
1959   }
1960
1961   (@template);
1962 }
1963
1964 =item terms
1965
1966 =cut
1967
1968 sub terms {
1969   my $self = shift;
1970   my $conf = $self->conf;
1971
1972   #check for an invoice-specific override
1973   return $self->invoice_terms if $self->invoice_terms;
1974
1975   #check for a customer- specific override
1976   my $cust_main = $self->cust_main;
1977   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1978
1979   my $agentnum = '';
1980   if ( $cust_main ) {
1981     $agentnum = $cust_main->agentnum;
1982   } elsif ( my $prospect_main = $self->prospect_main ) {
1983     $agentnum = $prospect_main->agentnum;
1984   }
1985
1986   #use configured default
1987   $conf->config('invoice_default_terms', $agentnum) || '';
1988 }
1989
1990 =item due_date
1991
1992 =cut
1993
1994 sub due_date {
1995   my $self = shift;
1996   my $duedate = '';
1997   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1998     $duedate = $self->_date() + ( $1 * 86400 );
1999   } elsif ( $self->terms =~ /^End of Month$/ ) {
2000     my ($mon,$year) = (localtime($self->_date) )[4,5];
2001     $mon++;
2002     until ( $mon < 12 ) { $mon -= 12; $year++; }
2003     my $nextmonth_first = timelocal(0,0,0,1,$mon,$year);
2004     $duedate = $nextmonth_first - 86400;
2005   }
2006   $duedate;
2007 }
2008
2009 =item due_date2str
2010
2011 =cut
2012
2013 sub due_date2str {
2014   my $self = shift;
2015   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
2016 }
2017
2018 =item invoice_pay_by_msg
2019
2020   displays the invoice_pay_by_msg or default Please pay by [_1] if empty.
2021
2022 =cut
2023
2024 sub invoice_pay_by_msg {
2025   my $self = shift;
2026   my $msg = '';
2027   my $please_pay_by =
2028         $self->conf->config('invoice_pay_by_msg', $self->agentnum)
2029         || 'Please pay by [_1]';
2030   $msg .= ' - ' . $self->mt($please_pay_by, $self->due_date2str('short')) . ' ';
2031
2032   $msg;
2033 }
2034
2035 =item balance_due_msg
2036
2037 =cut
2038
2039 sub balance_due_msg {
2040   my $self = shift;
2041   my $msg = $self->mt('Balance Due');
2042   return $msg unless $self->terms; # huh?
2043   if ( !$self->conf->exists('invoice_show_prior_due_date')
2044        || $self->has_sections ) {
2045     # if enabled, the due date is shown with Total New Charges (see
2046     # _items_total) and not here
2047     # (yes, or if invoice_sections is enabled; this is just for compatibility)
2048     if ( $self->due_date ) {
2049       $msg .= $self->invoice_pay_by_msg
2050        unless $self->conf->config_bool('invoice_omit_due_date',$self->agentnum);
2051     } elsif ( $self->terms ) {
2052       $msg .= ' - '. $self->mt($self->terms);
2053     }
2054   }
2055   $msg;
2056 }
2057
2058 =item balance_due_date
2059
2060 =cut
2061
2062 sub balance_due_date {
2063   my $self = shift;
2064   my $conf = $self->conf;
2065   my $duedate = '';
2066   my $terms = $self->terms;
2067   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2068     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
2069   }
2070   $duedate;
2071 }
2072
2073 sub credit_balance_msg {
2074   my $self = shift;
2075   $self->mt('Credit Balance Remaining')
2076 }
2077
2078 =item _date_pretty
2079
2080 Returns a string with the date, for example: "3/20/2008", localized for the
2081 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
2082
2083 =cut
2084
2085 sub _date_pretty {
2086   my $self = shift;
2087   $self->time2str_local('short', $self->_date);
2088 }
2089
2090 =item _date_pretty_unlocalized
2091
2092 Returns a string with the date, for example: "3/20/2008", in the format
2093 configured for the back-office.  Use _date_pretty for end-customer display use.
2094
2095 =cut
2096
2097 sub _date_pretty_unlocalized {
2098   my $self = shift;
2099   time2str($date_format, $self->_date);
2100 }
2101
2102 =item email HASHREF
2103
2104 Emails this template.
2105
2106 Options are passed as a hashref.  Available options:
2107
2108 =over 4
2109
2110 =item from
2111
2112 If specified, overrides the default From: address.
2113
2114 =item notice_name
2115
2116 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
2117
2118 =item template
2119
2120 (Deprecated) If specified, is the name of a suffix for alternate template files.
2121
2122 =back
2123
2124 Options accepted by generate_email can also be used.
2125
2126 =cut
2127
2128 sub email {
2129   my $self = shift;
2130   my $opt = shift || {};
2131   if ($opt and !ref($opt)) {
2132     die ref($self). '->email called with positional parameters';
2133   }
2134
2135   return if $self->hide;
2136
2137   my $error = send_email(
2138     $self->generate_email(
2139       'subject'     => $self->email_subject($opt->{template}),
2140       %$opt, # template, etc.
2141     )
2142   );
2143
2144   die "can't email: $error\n" if $error;
2145 }
2146
2147 =item generate_email OPTION => VALUE ...
2148
2149 Options:
2150
2151 =over 4
2152
2153 =item from
2154
2155 sender address, required
2156
2157 =item template
2158
2159 alternate template name, optional
2160
2161 =item subject
2162
2163 email subject, optional
2164
2165 =item notice_name
2166
2167 notice name instead of "Invoice", optional
2168
2169 =back
2170
2171 Returns an argument list to be passed to L<FS::Misc::send_email>.
2172
2173 =cut
2174
2175 use MIME::Entity;
2176 use Encode;
2177
2178 sub generate_email {
2179
2180   my $self = shift;
2181   my %args = @_;
2182   my $conf = $self->conf;
2183
2184   my $me = '[FS::Template_Mixin::generate_email]';
2185
2186   my %return = (
2187     'from'      => $args{'from'},
2188     'subject'   => ($args{'subject'} || $self->email_subject),
2189     'custnum'   => $self->custnum,
2190     'msgtype'   => 'invoice',
2191   );
2192
2193   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2194
2195   my $cust_main = $self->cust_main;
2196
2197   if (ref($args{'to'}) eq 'ARRAY') {
2198     $return{'to'} = $args{'to'};
2199   } elsif ( $cust_main ) {
2200     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2201   }
2202
2203   my $tc = $self->template_conf;
2204
2205   my @text; # array of lines
2206   my $html; # a big string
2207   my @related_parts; # will contain the text/HTML alternative, and images
2208   my $related; # will contain the multipart/related object
2209
2210   if ( $conf->exists($tc. 'email_pdf') ) {
2211     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2212
2213       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2214         if $DEBUG;
2215
2216       my $msg_template = FS::msg_template->by_key($msgnum)
2217         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2218       my $cust_msg = $msg_template->prepare(
2219         cust_main => $self->cust_main,
2220         object    => $self,
2221         msgtype   => 'invoice',
2222       );
2223
2224       # XXX hack to make this work in the new cust_msg era; consider replacing
2225       # with cust_bill_send_with_notice events.
2226       my @parts = $cust_msg->parts;
2227       foreach my $part (@parts) { # will only have two parts, normally
2228         if ( $part->mime_type eq 'text/plain' ) {
2229           @text = @{ $part->body };
2230         } elsif ( $part->mime_type eq 'text/html' ) {
2231           $html = $part->bodyhandle->as_string;
2232         }
2233       }
2234
2235     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2236
2237       warn "$me using '${tc}email_pdf_note' in multipart message"
2238         if $DEBUG;
2239       @text = $conf->config($tc.'email_pdf_note');
2240       $html = join('<BR>', @text);
2241
2242     } # else use the plain text invoice
2243   }
2244
2245   if (!@text) {
2246
2247     if ( $conf->config($tc.'template') ) {
2248
2249       warn "$me generating plain text invoice"
2250         if $DEBUG;
2251
2252       # 'print_text' argument is no longer used
2253       @text = map Encode::encode_utf8($_), $self->print_text(\%args);
2254
2255     } else {
2256
2257       warn "$me no plain text version exists; sending empty message body"
2258         if $DEBUG;
2259
2260     }
2261
2262   }
2263
2264   my $text_part = build MIME::Entity (
2265     'Type'        => 'text/plain',
2266     'Encoding'    => 'quoted-printable',
2267     'Charset'     => 'UTF-8',
2268     #'Encoding'    => '7bit',
2269     'Data'        => \@text,
2270     'Disposition' => 'inline',
2271   );
2272
2273   if (!$html) {
2274
2275     if ( $conf->exists($tc.'html') ) {
2276       warn "$me generating HTML invoice"
2277         if $DEBUG;
2278
2279       $args{'from'} =~ /\@([\w\.\-]+)/;
2280       my $from = $1 || 'example.com';
2281       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2282
2283       my $logo;
2284       my $agentnum = $cust_main ? $cust_main->agentnum
2285                                 : $self->prospect_main->agentnum;
2286       if ( defined($args{'template'}) && length($args{'template'})
2287            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2288          )
2289       {
2290         $logo = 'logo_'. $args{'template'}. '.png';
2291       } else {
2292         $logo = "logo.png";
2293       }
2294       my $image_data = $conf->config_binary( $logo, $agentnum);
2295
2296       push @related_parts, build MIME::Entity
2297         'Type'       => 'image/png',
2298         'Encoding'   => 'base64',
2299         'Data'       => $image_data,
2300         'Filename'   => 'logo.png',
2301         'Content-ID' => "<$content_id>",
2302       ;
2303
2304       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2305         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2306         push @related_parts, build MIME::Entity
2307           'Type'       => 'image/png',
2308           'Encoding'   => 'base64',
2309           'Data'       => $self->invoice_barcode(0),
2310           'Filename'   => 'barcode.png',
2311           'Content-ID' => "<$barcode_content_id>",
2312         ;
2313         $args{'barcode_cid'} = $barcode_content_id;
2314       }
2315
2316       $html = $self->print_html({ 'cid'=>$content_id, %args });
2317     }
2318
2319   }
2320
2321   if ( $html ) {
2322
2323     warn "$me creating HTML/text multipart message"
2324       if $DEBUG;
2325
2326     $return{'nobody'} = 1;
2327
2328     my $alternative = build MIME::Entity
2329       'Type'        => 'multipart/alternative',
2330       #'Encoding'    => '7bit',
2331       'Disposition' => 'inline'
2332     ;
2333
2334     if ( @text ) {
2335       $alternative->add_part($text_part);
2336     }
2337
2338     $alternative->attach(
2339       'Type'        => 'text/html',
2340       'Encoding'    => 'quoted-printable',
2341       'Data'        => [ '<html>',
2342                          '  <head>',
2343                          '    <title>',
2344                          '      '. encode_entities($return{'subject'}),
2345                          '    </title>',
2346                          '  </head>',
2347                          '  <body bgcolor="#e8e8e8">',
2348                          Encode::encode_utf8($html),
2349                          '  </body>',
2350                          '</html>',
2351                        ],
2352       'Disposition' => 'inline',
2353       #'Filename'    => 'invoice.pdf',
2354     );
2355
2356     unshift @related_parts, $alternative;
2357
2358     $related = build MIME::Entity 'Type'     => 'multipart/related',
2359                                   'Encoding' => '7bit';
2360
2361     #false laziness w/Misc::send_email
2362     $related->head->replace('Content-type',
2363       $related->mime_type.
2364       '; boundary="'. $related->head->multipart_boundary. '"'.
2365       '; type=multipart/alternative'
2366     );
2367
2368     $related->add_part($_) foreach @related_parts;
2369
2370   }
2371
2372   my @otherparts = ();
2373   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2374
2375     if ( $conf->config('voip-cdr_email_attach') eq 'zip' ) {
2376
2377       my $data = join('', map "$_\n",
2378                    $self->call_details(prepend_billed_number=>1)
2379                  );
2380
2381       my $zip = new Archive::Zip;
2382       my $file = $zip->addString( $data, 'usage-'.$self->invnum.'.csv' );
2383       $file->desiredCompressionMethod( COMPRESSION_DEFLATED );
2384
2385       my $zipdata = '';
2386       my $SH = IO::Scalar->new(\$zipdata);
2387       my $status = $zip->writeToFileHandle($SH);
2388       die "Error zipping CDR attachment: $!" unless $status == AZ_OK;
2389
2390       push @otherparts, build MIME::Entity
2391         'Type'        => 'application/zip',
2392         'Encoding'    => 'base64',
2393         'Data'        => $zipdata,
2394         'Disposition' => 'attachment',
2395         'Filename'    => 'usage-'. $self->invnum. '.zip',
2396       ;
2397
2398     } else { # } elsif ( $conf->config('voip-cdr_email_attach') eq 'csv' ) {
2399
2400       push @otherparts, build MIME::Entity
2401         'Type'        => 'text/csv',
2402         'Encoding'    => '7bit',
2403         'Data'        => [ map { "$_\n" }
2404                              $self->call_details('prepend_billed_number' => 1)
2405                          ],
2406         'Disposition' => 'attachment',
2407         'Filename'    => 'usage-'. $self->invnum. '.csv',
2408       ;
2409
2410     }
2411
2412   }
2413
2414   if ( $conf->exists($tc.'email_pdf') ) {
2415
2416     #attaching pdf too:
2417     # multipart/mixed
2418     #   multipart/related
2419     #     multipart/alternative
2420     #       text/plain
2421     #       text/html
2422     #     image/png
2423     #   application/pdf
2424
2425     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2426     push @otherparts, $pdf;
2427   }
2428
2429   if (@otherparts) {
2430     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2431     if ( $html ) {
2432       $return{'mimeparts'} = [ $related, @otherparts ];
2433       $return{'type'} = 'multipart/related'; # of the first part
2434     } else {
2435       $return{'mimeparts'} = [ $text_part, @otherparts ];
2436       $return{'type'} = 'text/plain';
2437     }
2438   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2439     $return{'mimeparts'} = \@related_parts;
2440     $return{'content-type'} = 'multipart/related';
2441     $return{'type'} = 'multipart/alternative';
2442   } else { # no HTML either
2443     $return{'body'} = \@text;
2444     $return{'content-type'} = 'text/plain';
2445   }
2446
2447   %return;
2448
2449 }
2450
2451 =item mimebuild_pdf
2452
2453 Returns a list suitable for passing to MIME::Entity->build(), representing
2454 this quotation or invoice as PDF attachment.
2455
2456 =cut
2457
2458 sub mimebuild_pdf {
2459   my $self = shift;
2460   (
2461     'Type'        => 'application/pdf',
2462     'Encoding'    => 'base64',
2463     'Data'        => [ $self->print_pdf(@_) ],
2464     'Disposition' => 'attachment',
2465     'Filename'    => $self->pdf_filename,
2466   );
2467 }
2468
2469 =item postal_mail_fsinc
2470
2471 Sends this invoice to the Freeside Internet Services, Inc. print and mail
2472 service.
2473
2474 =cut
2475
2476 use CAM::PDF;
2477 use IO::Socket::SSL;
2478 use LWP::UserAgent;
2479 use HTTP::Request::Common qw( POST );
2480 use Cpanel::JSON::XS;
2481 use MIME::Base64;
2482 sub postal_mail_fsinc {
2483   my ( $self, %opt ) = @_;
2484
2485   my $url = 'https://ws.freeside.biz/print';
2486
2487   my $cust_main = $self->cust_main;
2488   my $agentnum = $cust_main->agentnum;
2489   my $bill_location = $cust_main->bill_location;
2490
2491   die "Extra charges for international mailing; contact support\@freeside.biz to enable\n"
2492     if $bill_location->country ne 'US';
2493
2494   my $conf = new FS::Conf;
2495
2496   my @company_address = $conf->config('company_address', $agentnum);
2497   my ( $company_address1, $company_address2, $company_city, $company_state, $company_zip );
2498   if ( $company_address[2] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2499     $company_address1 = $company_address[0];
2500     $company_address2 = $company_address[1];
2501     $company_city  = $1;
2502     $company_state = $2;
2503     $company_zip   = $3;
2504   } elsif ( $company_address[1] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2505     $company_address1 = $company_address[0];
2506     $company_address2 = '';
2507     $company_city  = $1;
2508     $company_state = $2;
2509     $company_zip   = $3;
2510   } else {
2511     die "Unparsable company_address; contact support\@freeside.biz\n";
2512   }
2513   $company_city =~ s/,$//;
2514
2515   my $file = $self->print_pdf(%opt, 'no_addresses' => 1);
2516   my $pages = CAM::PDF->new($file)->numPages;
2517
2518   my $ua = LWP::UserAgent->new(
2519     'ssl_opts' => {
2520       verify_hostname => 0,
2521       SSL_verify_mode => IO::Socket::SSL::SSL_VERIFY_NONE,
2522       SSL_version     => 'SSLv3',
2523     }
2524   );
2525   my $response = $ua->request( POST $url, [
2526     'support-key'      => scalar($conf->config('support-key')),
2527     'file'             => encode_base64($file),
2528     'pages'            => $pages,
2529
2530     #from:
2531     'company_name'     => scalar( $conf->config('company_name', $agentnum) ),
2532     'company_address1' => $company_address1,
2533     'company_address2' => $company_address2,
2534     'company_city'     => $company_city,
2535     'company_state'    => $company_state,
2536     'company_zip'      => $company_zip,
2537     'company_country'  => 'US',
2538     'company_phonenum' => scalar($conf->config('company_phonenum', $agentnum)),
2539     'company_email'    => scalar($conf->config('invoice_from', $agentnum)),
2540
2541     #to:
2542     'name'             => $cust_main->invoice_attn
2543                             || $cust_main->contact_firstlast,
2544     'company'          => $cust_main->company,
2545     'address1'         => $bill_location->address1,
2546     'address2'         => $bill_location->address2,
2547     'city'             => $bill_location->city,
2548     'state'            => $bill_location->state,
2549     'zip'              => $bill_location->zip,
2550     'country'          => $bill_location->country,
2551   ]);
2552
2553   die "Print connection error: ". $response->message.
2554       ' ('. $response->as_string. ")\n"
2555     unless $response->is_success;
2556
2557   local $@;
2558   my $content = eval { decode_json($response->content) };
2559   die "Print JSON error : $@\n" if $@;
2560
2561   die $content->{error}."\n"
2562     if $content->{error};
2563
2564   #TODO: store this so we can query for a status later
2565   warn "Invoice printed, ID ". $content->{id}. "\n";
2566
2567   $content->{id};
2568
2569 }
2570
2571 =item _items_sections OPTIONS
2572
2573 Generate section information for all items appearing on this invoice.
2574 This will only be called for multi-section invoices.
2575
2576 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2577 related display records (L<FS::cust_bill_pkg_display>) and organize
2578 them into two groups ("early" and "late" according to whether they come
2579 before or after the total), then into sections.  A subtotal is calculated
2580 for each section.
2581
2582 Section descriptions are returned in sort weight order.  Each consists
2583 of a hash containing:
2584
2585 description: the package category name, escaped
2586 subtotal: the total charges in that section
2587 tax_section: a flag indicating that the section contains only tax charges
2588 summarized: same as tax_section, for some reason
2589 sort_weight: the package category's sort weight
2590
2591 If 'condense' is set on the display record, it also contains everything
2592 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2593 coderefs to generate parts of the invoice.  This is not advised.
2594
2595 The method returns two arrayrefs, one of "early" sections and one of "late"
2596 sections.
2597
2598 OPTIONS may include:
2599
2600 by_location: a flag to divide the invoice into sections by location.
2601 Each section hash will have a 'location' element containing a hashref of
2602 the location fields (see L<FS::cust_location>).  The section description
2603 will be the location label, but the template can use any of the location
2604 fields to create a suitable label.
2605
2606 by_category: a flag to divide the invoice into sections using display
2607 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2608 behavior.  Each section hash will have a 'category' element containing
2609 the section name from the display record (which probably equals the
2610 category name of the package, but may not in some cases).
2611
2612 summary: a flag indicating that this is a summary-format invoice.
2613 Turning this on has the following effects:
2614 - Ignores display items with the 'summary' flag.
2615 - Places all sections in the "early" group even if they have post_total.
2616 - Creates sections for all non-disabled package categories, even if they
2617 have no charges on this invoice, as well as a section with no name.
2618
2619 escape: an escape function to use for section titles.
2620
2621 extra_sections: an arrayref of additional sections to return after the
2622 sorted list.  If there are any of these, section subtotals exclude
2623 usage charges.
2624
2625 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2626 passed through to C<_condense_section()>.
2627
2628 =cut
2629
2630 use vars qw(%pkg_category_cache);
2631 sub _items_sections {
2632   my $self = shift;
2633   my %opt = @_;
2634
2635   my $escape = $opt{escape};
2636   my @extra_sections = @{ $opt{extra_sections} || [] };
2637
2638   # $subtotal{$locationnum}{$categoryname} = amount.
2639   # if we're not using by_location, $locationnum is undef.
2640   # if we're not using by_category, you guessed it, $categoryname is undef.
2641   # if we're not using either one, we shouldn't be here in the first place...
2642   my %subtotal = ();
2643   my %late_subtotal = ();
2644   my %not_tax = ();
2645
2646   # About tax items + multisection invoices:
2647   # If either invoice_*summary option is enabled, AND there is a
2648   # package category with the name of the tax, then there will be
2649   # a display record assigning the tax item to that category.
2650   #
2651   # However, the taxes are always placed in the "Taxes, Surcharges,
2652   # and Fees" section regardless of that.  The only effect of the
2653   # display record is to create a subtotal for the summary page.
2654
2655   # cache these
2656   my $pkg_hash = $self->cust_pkg_hash;
2657
2658   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2659   {
2660
2661       my $usage = $cust_bill_pkg->usage;
2662
2663       my $locationnum;
2664       if ( $opt{by_location} ) {
2665         if ( $cust_bill_pkg->pkgnum ) {
2666           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2667         } else {
2668           $locationnum = '';
2669         }
2670       } else {
2671         $locationnum = undef;
2672       }
2673
2674       # as in _items_cust_pkg, if a line item has no display records,
2675       # cust_bill_pkg_display() returns a default record for it
2676
2677       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2678         next if ( $display->summary && $opt{summary} );
2679
2680         #my $section = $display->section;
2681         #false laziness with the method, but for efficiency inside this loop
2682         my $section = $display->get('section');
2683         if ( !$section && !$cust_bill_pkg->hidden ) {
2684           $section = $cust_bill_pkg->get('categoryname'); #cust_bill->cust_bill_pkg added it (XXX quotations / quotation_section)
2685         }
2686
2687         my $type    = $display->type;
2688         # Set $section = undef if we're sectioning by location and this
2689         # line item _has_ a location (i.e. isn't a fee).
2690         $section = undef if $locationnum;
2691
2692         # set this flag if the section is not tax-only
2693         $not_tax{$locationnum}{$section} = 1
2694           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2695
2696         # there's actually a very important piece of logic buried in here:
2697         # incrementing $late_subtotal{$section} CREATES
2698         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2699         # to define the list of late sections, and likewise keys(%subtotal).
2700         # When _items_cust_bill_pkg is called to generate line items for
2701         # real, it will be called with 'section' => $section for each
2702         # of these.
2703         if ( $display->post_total && !$opt{summary} ) {
2704           if (! $type || $type eq 'S') {
2705             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2706               if $cust_bill_pkg->setup != 0
2707               || $cust_bill_pkg->setup_show_zero;
2708           }
2709
2710           if (! $type) {
2711             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2712               if $cust_bill_pkg->recur != 0
2713               || $cust_bill_pkg->recur_show_zero;
2714           }
2715
2716           if ($type && $type eq 'R') {
2717             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2718               if $cust_bill_pkg->recur != 0
2719               || $cust_bill_pkg->recur_show_zero;
2720           }
2721
2722           if ($type && $type eq 'U') {
2723             $late_subtotal{$locationnum}{$section} += $usage
2724               unless scalar(@extra_sections);
2725           }
2726
2727         } else { # it's a pre-total (normal) section
2728
2729           # skip tax items unless they're explicitly included in a section
2730           next if $cust_bill_pkg->pkgnum == 0 and
2731                   ! $cust_bill_pkg->feepart   and
2732                   ! $section;
2733
2734           if ( $type eq 'S' ) {
2735             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2736               if $cust_bill_pkg->setup != 0
2737               || $cust_bill_pkg->setup_show_zero;
2738           } elsif ( $type eq 'R' ) {
2739             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2740               if $cust_bill_pkg->recur != 0
2741               || $cust_bill_pkg->recur_show_zero;
2742           } elsif ( $type eq 'U' ) {
2743             $subtotal{$locationnum}{$section} += $usage
2744               unless scalar(@extra_sections);
2745           } elsif ( !$type ) {
2746             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2747                                                + $cust_bill_pkg->recur;
2748           }
2749
2750         }
2751
2752       }
2753
2754   }
2755
2756   %pkg_category_cache = ();
2757
2758   # summary invoices need subtotals for all non-disabled package categories,
2759   # even if they're zero
2760   # but currently assume that there are no location sections, or at least
2761   # that the summary page doesn't care about them
2762   if ( $opt{summary} ) {
2763     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2764       $subtotal{''}{$category->categoryname} ||= 0;
2765     }
2766     $subtotal{''}{''} ||= 0;
2767   }
2768
2769   my @sections;
2770   foreach my $post_total (0,1) {
2771     my @these;
2772     my $s = $post_total ? \%late_subtotal : \%subtotal;
2773     foreach my $locationnum (keys %$s) {
2774       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2775         my $section = {
2776                         'subtotal'    => $s->{$locationnum}{$sectionname},
2777                         'sort_weight' => 0,
2778                       };
2779         if ( $locationnum ) {
2780           $section->{'locationnum'} = $locationnum;
2781           my $location = FS::cust_location->by_key($locationnum);
2782           $section->{'description'} = &{ $escape }($location->location_label);
2783           # Better ideas? This will roughly group them by proximity,
2784           # which alpha sorting on any of the address fields won't.
2785           # Sorting by locationnum is meaningless.
2786           # We have to sort on _something_ or the order may change
2787           # randomly from one invoice to the next, which will confuse
2788           # people.
2789           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2790                                       $locationnum;
2791           $section->{'location'} = {
2792             label_prefix => &{ $escape }($location->label_prefix),
2793             map { $_ => &{ $escape }($location->get($_)) }
2794               $location->fields
2795           };
2796         } else {
2797           $section->{'category'} = $sectionname;
2798           $section->{'description'} = &{ $escape }($sectionname);
2799           if ( _pkg_category($sectionname) ) {
2800             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2801             if ( _pkg_category($sectionname)->condense ) {
2802               $section = { %$section, $self->_condense_section($opt{format}) };
2803             }
2804           }
2805         }
2806         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2807           # then it's a tax-only section
2808           $section->{'summarized'} = 'Y';
2809           $section->{'tax_section'} = 'Y';
2810         }
2811         push @these, $section;
2812       } # foreach $sectionname
2813     } #foreach $locationnum
2814     push @these, @extra_sections if $post_total == 0;
2815     # need an alpha sort for location sections, because postal codes can
2816     # be non-numeric
2817     $sections[ $post_total ] = [ sort {
2818       $opt{'by_location'} ?
2819         ($a->{sort_weight} cmp $b->{sort_weight}) :
2820         ($a->{sort_weight} <=> $b->{sort_weight})
2821       } @these ];
2822   } #foreach $post_total
2823
2824   return @sections; # early, late
2825 }
2826
2827 #helper subs for above
2828
2829 sub cust_pkg_hash {
2830   my $self = shift;
2831   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2832 }
2833
2834 sub _pkg_category {
2835   my $categoryname = shift;
2836   $pkg_category_cache{$categoryname} ||=
2837     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2838 }
2839
2840 my %condensed_format = (
2841   'label' => [ qw( Description Qty Amount ) ],
2842   'fields' => [
2843                 sub { shift->{description} },
2844                 sub { shift->{quantity} },
2845                 sub { my($href, %opt) = @_;
2846                       ($opt{dollar} || ''). $href->{amount};
2847                     },
2848               ],
2849   'align'  => [ qw( l r r ) ],
2850   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2851   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2852 );
2853
2854 sub _condense_section {
2855   my ( $self, $format ) = ( shift, shift );
2856   ( 'condensed' => 1,
2857     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2858       qw( description_generator
2859           header_generator
2860           total_generator
2861           total_line_generator
2862         )
2863   );
2864 }
2865
2866 sub _condensed_generator_defaults {
2867   my ( $self, $format ) = ( shift, shift );
2868   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2869 }
2870
2871 my %html_align = (
2872   'c' => 'center',
2873   'l' => 'left',
2874   'r' => 'right',
2875 );
2876
2877 sub _condensed_header_generator {
2878   my ( $self, $format ) = ( shift, shift );
2879
2880   my ( $f, $prefix, $suffix, $separator, $column ) =
2881     _condensed_generator_defaults($format);
2882
2883   if ($format eq 'latex') {
2884     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2885     $suffix = "\\\\\n\\hline";
2886     $separator = "&\n";
2887     $column =
2888       sub { my ($d,$a,$s,$w) = @_;
2889             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2890           };
2891   } elsif ( $format eq 'html' ) {
2892     $prefix = '<th></th>';
2893     $suffix = '';
2894     $separator = '';
2895     $column =
2896       sub { my ($d,$a,$s,$w) = @_;
2897             return qq!<th align="$html_align{$a}">$d</th>!;
2898       };
2899   }
2900
2901   sub {
2902     my @args = @_;
2903     my @result = ();
2904
2905     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2906       push @result,
2907         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2908     }
2909
2910     $prefix. join($separator, @result). $suffix;
2911   };
2912
2913 }
2914
2915 sub _condensed_description_generator {
2916   my ( $self, $format ) = ( shift, shift );
2917
2918   my ( $f, $prefix, $suffix, $separator, $column ) =
2919     _condensed_generator_defaults($format);
2920
2921   my $money_char = '$';
2922   if ($format eq 'latex') {
2923     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2924     $suffix = '\\\\';
2925     $separator = " & \n";
2926     $column =
2927       sub { my ($d,$a,$s,$w) = @_;
2928             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2929           };
2930     $money_char = '\\dollar';
2931   }elsif ( $format eq 'html' ) {
2932     $prefix = '"><td align="center"></td>';
2933     $suffix = '';
2934     $separator = '';
2935     $column =
2936       sub { my ($d,$a,$s,$w) = @_;
2937             return qq!<td align="$html_align{$a}">$d</td>!;
2938       };
2939     #$money_char = $conf->config('money_char') || '$';
2940     $money_char = '';  # this is madness
2941   }
2942
2943   sub {
2944     #my @args = @_;
2945     my $href = shift;
2946     my @result = ();
2947
2948     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2949       my $dollar = '';
2950       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2951       push @result,
2952         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2953                     map { $f->{$_}->[$i] } qw(align span width)
2954                   );
2955     }
2956
2957     $prefix. join( $separator, @result ). $suffix;
2958   };
2959
2960 }
2961
2962 sub _condensed_total_generator {
2963   my ( $self, $format ) = ( shift, shift );
2964
2965   my ( $f, $prefix, $suffix, $separator, $column ) =
2966     _condensed_generator_defaults($format);
2967   my $style = '';
2968
2969   if ($format eq 'latex') {
2970     $prefix = "& ";
2971     $suffix = "\\\\\n";
2972     $separator = " & \n";
2973     $column =
2974       sub { my ($d,$a,$s,$w) = @_;
2975             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2976           };
2977   }elsif ( $format eq 'html' ) {
2978     $prefix = '';
2979     $suffix = '';
2980     $separator = '';
2981     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2982     $column =
2983       sub { my ($d,$a,$s,$w) = @_;
2984             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2985       };
2986   }
2987
2988
2989   sub {
2990     my @args = @_;
2991     my @result = ();
2992
2993     #  my $r = &{$f->{fields}->[$i]}(@args);
2994     #  $r .= ' Total' unless $i;
2995
2996     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2997       push @result,
2998         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2999                     map { $f->{$_}->[$i] } qw(align span width)
3000                   );
3001     }
3002
3003     $prefix. join( $separator, @result ). $suffix;
3004   };
3005
3006 }
3007
3008 =item total_line_generator FORMAT
3009
3010 Returns a coderef used for generation of invoice total line items for this
3011 usage_class.  FORMAT is either html or latex
3012
3013 =cut
3014
3015 # should not be used: will have issues with hash element names (description vs
3016 # total_item and amount vs total_amount -- another array of functions?
3017
3018 sub _condensed_total_line_generator {
3019   my ( $self, $format ) = ( shift, shift );
3020
3021   my ( $f, $prefix, $suffix, $separator, $column ) =
3022     _condensed_generator_defaults($format);
3023   my $style = '';
3024
3025   if ($format eq 'latex') {
3026     $prefix = "& ";
3027     $suffix = "\\\\\n";
3028     $separator = " & \n";
3029     $column =
3030       sub { my ($d,$a,$s,$w) = @_;
3031             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
3032           };
3033   }elsif ( $format eq 'html' ) {
3034     $prefix = '';
3035     $suffix = '';
3036     $separator = '';
3037     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
3038     $column =
3039       sub { my ($d,$a,$s,$w) = @_;
3040             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
3041       };
3042   }
3043
3044
3045   sub {
3046     my @args = @_;
3047     my @result = ();
3048
3049     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
3050       push @result,
3051         &{$column}( &{$f->{fields}->[$i]}(@args),
3052                     map { $f->{$_}->[$i] } qw(align span width)
3053                   );
3054     }
3055
3056     $prefix. join( $separator, @result ). $suffix;
3057   };
3058
3059 }
3060
3061 =item _items_pkg [ OPTIONS ]
3062
3063 Return line item hashes for each package item on this invoice. Nearly
3064 equivalent to
3065
3066 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
3067
3068 OPTIONS are passed through to _items_cust_bill_pkg, and should include
3069 'format' and 'escape_function' at minimum.
3070
3071 To produce items for a specific invoice section, OPTIONS should include
3072 'section', a hashref containing 'category' and/or 'locationnum' keys.
3073
3074 'section' may also contain a key named 'condensed'. If this is present
3075 and has a true value, _items_pkg will try to merge identical items into items
3076 with 'quantity' equal to the number of items (not the sum of their separate
3077 quantities, for some reason).
3078
3079 =cut
3080
3081 sub _items_nontax {
3082   my $self = shift;
3083   # The order of these is important.  Bundled line items will be merged into
3084   # the most recent non-hidden item, so it needs to be the one with:
3085   # - the same pkgnum
3086   # - the same start date
3087   # - no pkgpart_override
3088   #
3089   # So: sort by pkgnum,
3090   # then by sdate
3091   # then sort the base line item before any overrides
3092   # then sort hidden before non-hidden add-ons
3093   # then sort by override pkgpart (for consistency)
3094   sort { $a->pkgnum <=> $b->pkgnum        or
3095          $a->sdate  <=> $b->sdate         or
3096          ($a->pkgpart_override ? 0 : -1)  or
3097          ($b->pkgpart_override ? 0 : 1)   or
3098          $b->hidden cmp $a->hidden        or
3099          $a->pkgpart_override <=> $b->pkgpart_override
3100        }
3101   # and of course exclude taxes and fees
3102   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
3103 }
3104
3105 sub _items_fee {
3106   my $self = shift;
3107   my %options = @_;
3108   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
3109   my $escape_function = $options{escape_function};
3110
3111   my $locale = $self->cust_main->locale;
3112
3113   my @items;
3114   foreach my $cust_bill_pkg (@cust_bill_pkg) {
3115     # cache this, so we don't look it up again in every section
3116     my $part_fee = $cust_bill_pkg->get('part_fee')
3117        || $cust_bill_pkg->part_fee;
3118     $cust_bill_pkg->set('part_fee', $part_fee);
3119     if (!$part_fee) {
3120       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
3121       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
3122       next;
3123     }
3124     if ( exists($options{section}) and exists($options{section}{category}) )
3125     {
3126       my $categoryname = $options{section}{category};
3127       # then filter for items that have that section
3128       if ( $part_fee->categoryname ne $categoryname ) {
3129         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
3130         next;
3131       }
3132     } # otherwise include them all in the main section
3133     # XXX what to do when sectioning by location?
3134
3135     my @ext_desc;
3136     my %base_invnums; # invnum => invoice date
3137     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
3138       if ($_->base_invnum) {
3139         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
3140         my $base_date = $self->time2str_local('short', $base_bill->_date)
3141           if $base_bill;
3142         $base_invnums{$_->base_invnum} = $base_date || '';
3143       }
3144     }
3145     foreach (sort keys(%base_invnums)) {
3146       next if $_ == $self->invnum;
3147       # per convention, we must escape ext_description lines
3148       push @ext_desc,
3149         &{$escape_function}(
3150           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
3151         );
3152     }
3153     my $desc = $part_fee->itemdesc_locale($locale);
3154     # but not escape the base description line
3155
3156     my @pkg_tax = $cust_bill_pkg->_pkg_tax_list
3157       if $options{section_with_taxes};
3158
3159     push @items,
3160       { feepart     => $cust_bill_pkg->feepart,
3161         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
3162         description => $desc,
3163         pkg_tax     => \@pkg_tax,
3164         ext_description => \@ext_desc,
3165         # sdate/edate?
3166       };
3167   }
3168   @items;
3169 }
3170
3171 sub _items_pkg {
3172   my $self = shift;
3173   my %options = @_;
3174
3175   warn "$me _items_pkg searching for all package line items\n"
3176     if $DEBUG > 1;
3177
3178   my @cust_bill_pkg = $self->_items_nontax;
3179
3180   warn "$me _items_pkg filtering line items\n"
3181     if $DEBUG > 1;
3182   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3183
3184   if ($options{section} && $options{section}->{condensed}) {
3185
3186     warn "$me _items_pkg condensing section\n"
3187       if $DEBUG > 1;
3188
3189     my %itemshash = ();
3190     local $Storable::canonical = 1;
3191     foreach ( @items ) {
3192       my $item = { %$_ };
3193       delete $item->{ref};
3194       delete $item->{ext_description};
3195       my $key = freeze($item);
3196       $itemshash{$key} ||= 0;
3197       $itemshash{$key} ++; # += $item->{quantity};
3198     }
3199     @items = sort { $a->{description} cmp $b->{description} }
3200              map { my $i = thaw($_);
3201                    $i->{quantity} = $itemshash{$_};
3202                    $i->{amount} =
3203                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
3204                    $i;
3205                  }
3206              keys %itemshash;
3207   }
3208
3209   warn "$me _items_pkg returning ". scalar(@items). " items\n"
3210     if $DEBUG > 1;
3211
3212   @items;
3213 }
3214
3215 sub _taxsort {
3216   return 0 unless $a->itemdesc cmp $b->itemdesc;
3217   return -1 if $b->itemdesc eq 'Tax';
3218   return 1 if $a->itemdesc eq 'Tax';
3219   return -1 if $b->itemdesc eq 'Other surcharges';
3220   return 1 if $a->itemdesc eq 'Other surcharges';
3221   $a->itemdesc cmp $b->itemdesc;
3222 }
3223
3224 sub _items_tax {
3225   my $self = shift;
3226   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
3227     $self->cust_bill_pkg;
3228   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3229
3230   if ( $self->conf->exists('always_show_tax') ) {
3231     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
3232     if (0 == grep { $_->{description} eq $itemdesc } @items) {
3233       push @items,
3234         { 'description' => $itemdesc,
3235           'amount'      => 0.00 };
3236     }
3237   }
3238   @items;
3239 }
3240
3241 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
3242
3243 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
3244 list of hashrefs describing the line items they generate on the invoice.
3245
3246 OPTIONS may include:
3247
3248 format: the invoice format.
3249
3250 escape_function: the function used to escape strings.
3251
3252 DEPRECATED? (expensive, mostly unused?)
3253 format_function: the function used to format CDRs.
3254
3255 section: a hashref containing 'category' and/or 'locationnum'; if this
3256 is present, only returns line items that belong to that category and/or
3257 location (whichever is defined).
3258
3259 multisection: a flag indicating that this is a multisection invoice,
3260 which does something complicated.
3261
3262 section_with_taxes:  Look up and include applied taxes for each record
3263
3264 Returns a list of hashrefs, each of which may contain:
3265
3266 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
3267 ext_description, which is an arrayref of detail lines to show below
3268 the package line.
3269
3270 =cut
3271
3272 sub _items_cust_bill_pkg {
3273   my $self = shift;
3274   my $conf = $self->conf;
3275   my $cust_bill_pkgs = shift;
3276   my %opt = @_;
3277
3278   my $format = $opt{format} || '';
3279   my $escape_function = $opt{escape_function} || sub { shift };
3280   my $format_function = $opt{format_function} || '';
3281   my $no_usage = $opt{no_usage} || '';
3282   my $unsquelched = $opt{unsquelched} || ''; #unused
3283   my ($section, $locationnum, $category);
3284   if ( $opt{section} ) {
3285     $category = $opt{section}->{category};
3286     $locationnum = $opt{section}->{locationnum};
3287   }
3288   my $summary_page = $opt{summary_page} || ''; #unused
3289   my $multisection = defined($category) || defined($locationnum);
3290   # this variable is the value of the config setting, not whether it applies
3291   # to this particular line item.
3292   my $discount_show_always = $conf->exists('discount-show-always');
3293
3294   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3295
3296   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3297
3298   my $agentnum = $self->agentnum;
3299
3300   # for location labels: use default location on the invoice date
3301   my $default_locationnum;
3302   if ( $conf->exists('invoice-all_pkg_addresses') ) {
3303     $default_locationnum = 0; # treat them all as non-default
3304   } elsif ( $self->custnum ) {
3305     my $h_cust_main;
3306     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3307     $h_cust_main = qsearchs({
3308         'table'     => 'h_cust_main',
3309         'hashref'   => { custnum => $self->custnum },
3310         'extra_sql' => $h_search[1],
3311         'addl_from' => $h_search[3],
3312     }) || $cust_main;
3313     $default_locationnum = $h_cust_main->ship_locationnum;
3314   } elsif ( $self->prospectnum ) {
3315     my $cust_location = qsearchs('cust_location',
3316       { prospectnum => $self->prospectnum,
3317         disabled => '' });
3318     $default_locationnum = $cust_location->locationnum if $cust_location;
3319   }
3320
3321   my @b = (); # accumulator for the line item hashes that we'll return
3322   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3323             # the 'current' line item hashes for setup, recur, usage, discount
3324   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3325   {
3326     # if the current line item is waiting to go out, and the one we're about
3327     # to start is not bundled, then push out the current one and start a new
3328     # one.
3329     if ( $d ) {
3330       $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3331     }
3332     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3333       if ( $_ && !$cust_bill_pkg->hidden ) {
3334         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3335         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3336         if (exists($_->{unit_amount})) {
3337           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3338         }
3339         push @b, { %$_ };
3340         # we already decided to create this display line; don't reconsider it
3341         # now.
3342         #  if $_->{amount} != 0
3343         #  || $discount_show_always
3344         #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3345         #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3346         ;
3347         $_ = undef;
3348       }
3349     }
3350
3351     if ( $locationnum ) {
3352       # this is a location section; skip packages that aren't at this
3353       # service location.
3354       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3355       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3356               != $locationnum;
3357     }
3358
3359     # Consider display records for this item to determine if it belongs
3360     # in this section.  Note that if there are no display records, there
3361     # will be a default pseudo-record that includes all charge types
3362     # and has no section name.
3363     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3364                                   ? $cust_bill_pkg->cust_bill_pkg_display
3365                                   : ( $cust_bill_pkg );
3366
3367     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3368          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3369       if $DEBUG > 1;
3370
3371     if ( defined($category) ) {
3372       # then this is a package category section; process all display records
3373       # that belong to this section.
3374       @cust_bill_pkg_display = grep { $_->section eq $category }
3375                                 @cust_bill_pkg_display;
3376     } else {
3377       # otherwise, process all display records that aren't usage summaries
3378       # (I don't think there should be usage summaries if you aren't using
3379       # category sections, but this is the historical behavior)
3380       @cust_bill_pkg_display = grep { !$_->summary }
3381                                 @cust_bill_pkg_display;
3382     }
3383
3384     my $classname = ''; # package class name, will fill in later
3385
3386     foreach my $display (@cust_bill_pkg_display) {
3387
3388       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3389            $display->billpkgdisplaynum. "\n"
3390         if $DEBUG > 1;
3391
3392       my $type = $display->type;
3393
3394       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3395       $desc = substr($desc, 0, $maxlength). '...'
3396         if $format eq 'latex' && length($desc) > $maxlength;
3397
3398       my %details_opt = ( 'format'          => $format,
3399                           'escape_function' => $escape_function,
3400                           'format_function' => $format_function,
3401                           'no_usage'        => $opt{'no_usage'},
3402                         );
3403
3404       if ( $cust_bill_pkg->pkgnum > 0 ) {
3405         # a "normal" package line item (not a quotation, not a fee, not a tax)
3406
3407         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3408           if $DEBUG > 1;
3409
3410         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3411         my $part_pkg = $cust_pkg->part_pkg;
3412
3413         # which pkgpart to show for display purposes?
3414         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3415
3416         # start/end dates for invoice formats that do nonstandard
3417         # things with them
3418         my %item_dates = ();
3419         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3420           unless $part_pkg->option('disable_line_item_date_ranges',1);
3421
3422         # not normally used, but pass this to the template anyway
3423         $classname = $part_pkg->classname;
3424
3425         my @pkg_tax = $cust_bill_pkg->_pkg_tax_list
3426           if $opt{section_with_taxes};
3427
3428         if (    (!$type || $type eq 'S')
3429              && (    $cust_bill_pkg->setup != 0
3430                   || $cust_bill_pkg->setup_show_zero
3431                   || ($discount_show_always and $cust_bill_pkg->unitsetup > 0)
3432                 )
3433            )
3434          {
3435
3436           warn "$me _items_cust_bill_pkg adding setup\n"
3437             if $DEBUG > 1;
3438
3439           # append the word 'Setup' to the setup line if there's going to be
3440           # a recur line for the same package (i.e. not a one-time charge)
3441           # XXX localization
3442           my $description = $desc;
3443           $description .= ' Setup'
3444             if $cust_bill_pkg->recur != 0
3445             || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3446             || $cust_bill_pkg->recur_show_zero;
3447
3448           my $disable_date_ranges =
3449                $opt{disable_line_item_date_ranges}
3450             || $part_pkg->option('disable_line_item_date_ranges', 1);
3451
3452           $description .= $cust_bill_pkg->time_period_pretty(
3453                             $part_pkg,
3454                             $agentnum,
3455                             disable_date_ranges => $disable_date_ranges,
3456                           )
3457             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3458                                      # triggered by the recurring charge freq
3459                                      # (RT#26274)
3460             && $cust_bill_pkg->recur == 0
3461             && ! $cust_bill_pkg->recur_show_zero;
3462
3463           my @d = ();
3464           my @svc_labels = ();
3465           my $svc_label = '';
3466
3467           unless ( $part_pkg->hide_svc_detail ) {
3468
3469             # still pass the svc_label through to the template, even if
3470             # not displaying it as an ext_description
3471             @svc_labels = map &{$escape_function}($_),
3472               $cust_pkg->h_labels_short($self->_date,
3473                                         undef,
3474                                         'I',
3475                                         $self->conf->{locale},
3476                                        );
3477             $svc_label = $svc_labels[0];
3478
3479           }
3480
3481           unless ( $part_pkg->hide_svc_detail
3482                 || $cust_bill_pkg->hidden )
3483           {
3484
3485             push @d, @svc_labels
3486               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3487             # show the location label if it's not the customer's default
3488             # location, and we're not grouping items by location already
3489             if ( $cust_pkg->locationnum != $default_locationnum
3490                   and !defined($locationnum) ) {
3491               my $loc = $cust_pkg->location_label;
3492               $loc = substr($loc, 0, $maxlength). '...'
3493                 if $format eq 'latex' && length($loc) > $maxlength;
3494               push @d, &{$escape_function}($loc);
3495             }
3496
3497           } #unless hiding service details
3498
3499           push @d, $cust_bill_pkg->details(%details_opt)
3500             if $cust_bill_pkg->recur == 0;
3501
3502           if ( $cust_bill_pkg->hidden ) {
3503             $s->{amount}      += $cust_bill_pkg->setup;
3504             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3505             push @{ $s->{ext_description} }, @d;
3506           } else {
3507             $s = {
3508               billpkgnum      => $cust_bill_pkg->billpkgnum,
3509               _is_setup       => 1,
3510               description     => $description,
3511               pkgpart         => $pkgpart,
3512               pkgnum          => $cust_bill_pkg->pkgnum,
3513               amount          => $cust_bill_pkg->setup,
3514               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3515               unit_amount     => $cust_bill_pkg->unitsetup,
3516               quantity        => $cust_bill_pkg->quantity,
3517               ext_description => \@d,
3518               svc_label       => ($svc_label || ''),
3519               locationnum     => $cust_pkg->locationnum, # sure, why not?
3520               pkg_tax         => \@pkg_tax,
3521             };
3522           };
3523
3524         }
3525
3526         # should we show a recur line?
3527         # if type eq 'S', then NO, because we've been told not to.
3528         # otherwise, show the recur line if:
3529         # - there's a recurring charge
3530         # - or recur_show_zero is on
3531         # - or there's a positive unitrecur (so it's been discounted to zero)
3532         #   and discount-show-always is on
3533         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3534              && (
3535                      $cust_bill_pkg->recur != 0
3536                   || !defined($s)
3537                   || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3538                   || $cust_bill_pkg->recur_show_zero
3539                 )
3540            )
3541         {
3542
3543           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3544             if $DEBUG > 1;
3545
3546           my $is_summary = $display->summary;
3547           my $description = $desc;
3548           if ( $type eq 'U' and defined($r) ) {
3549             # don't just show the same description as the recur line
3550             $description = $self->mt('Usage charges');
3551           }
3552
3553           my $disable_date_ranges =
3554                $opt{disable_line_item_date_ranges}
3555             || $part_pkg->option('disable_line_item_date_ranges', 1);
3556
3557           $description .= $cust_bill_pkg->time_period_pretty(
3558                                     $part_pkg,
3559                                     $agentnum,
3560                                     disable_date_ranges => $disable_date_ranges,
3561                           );
3562
3563           my @d = ();
3564           my @seconds = (); # for display of usage info
3565           my @svc_labels = ();
3566           my $svc_label = '';
3567
3568           #at least until cust_bill_pkg has "past" ranges in addition to
3569           #the "future" sdate/edate ones... see #3032
3570           my @dates = ( $self->_date );
3571           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3572           push @dates, $prev->sdate if $prev;
3573           push @dates, undef if !$prev;
3574
3575           unless ( $part_pkg->hide_svc_detail ) {
3576             @svc_labels = map &{$escape_function}($_),
3577               $cust_pkg->h_labels_short(@dates,
3578                                         'I',
3579                                         $self->conf->{locale});
3580             $svc_label = $svc_labels[0];
3581           }
3582
3583           # show service labels, unless...
3584                     # the package is set not to display them
3585           unless ( $part_pkg->hide_svc_detail
3586                     # or this is a tax-like line item
3587                 || $cust_bill_pkg->itemdesc
3588                     # or this is a hidden (bundled) line item
3589                 || $cust_bill_pkg->hidden
3590                     # or this is a usage summary line
3591                 || $is_summary && $type && $type eq 'U'
3592                     # or this is a usage line and there's a recurring line
3593                     # for the package in the same section (which will
3594                     # have service labels already)
3595                 || ($type eq 'U' and defined($r))
3596               )
3597           {
3598
3599             warn "$me _items_cust_bill_pkg adding service details\n"
3600               if $DEBUG > 1;
3601
3602             push @d, @svc_labels
3603               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3604             warn "$me _items_cust_bill_pkg done adding service details\n"
3605               if $DEBUG > 1;
3606
3607             # show the location label if it's not the customer's default
3608             # location, and we're not grouping items by location already
3609             if ( $cust_pkg->locationnum != $default_locationnum
3610                   and !defined($locationnum) ) {
3611               my $loc = $cust_pkg->location_label;
3612               $loc = substr($loc, 0, $maxlength). '...'
3613                 if $format eq 'latex' && length($loc) > $maxlength;
3614               push @d, &{$escape_function}($loc);
3615             }
3616
3617             # Display of seconds_since_sqlradacct:
3618             # On the invoice, when processing @detail_items, look for a field
3619             # named 'seconds'.  This will contain total seconds for each
3620             # service, in the same order as @ext_description.  For services
3621             # that don't support this it will show undef.
3622             if ( $conf->exists('svc_acct-usage_seconds')
3623                  and ! $cust_bill_pkg->pkgpart_override ) {
3624               foreach my $cust_svc (
3625                   $cust_pkg->h_cust_svc(@dates, 'I')
3626                 ) {
3627
3628                 # eval because not having any part_export_usage exports
3629                 # is a fatal error, last_bill/_date because that's how
3630                 # sqlradius_hour billing does it
3631                 my $sec = eval {
3632                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3633                 };
3634                 push @seconds, $sec;
3635               }
3636             } #if svc_acct-usage_seconds
3637
3638           } # if we are showing service labels
3639
3640           unless ( $is_summary ) {
3641             warn "$me _items_cust_bill_pkg adding details\n"
3642               if $DEBUG > 1;
3643
3644             #instead of omitting details entirely in this case (unwanted side
3645             # effects), just omit CDRs
3646             $details_opt{'no_usage'} = 1
3647               if $type && $type eq 'R';
3648
3649             push @d, $cust_bill_pkg->details(%details_opt);
3650           }
3651
3652           warn "$me _items_cust_bill_pkg calculating amount\n"
3653             if $DEBUG > 1;
3654
3655           my $amount = 0;
3656           if (!$type) {
3657             $amount = $cust_bill_pkg->recur;
3658           } elsif ($type eq 'R') {
3659             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3660           } elsif ($type eq 'U') {
3661             $amount = $cust_bill_pkg->usage;
3662           }
3663
3664           if ( !$type || $type eq 'R' ) {
3665
3666             warn "$me _items_cust_bill_pkg adding recur\n"
3667               if $DEBUG > 1;
3668
3669             my $unit_amount =
3670               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3671                                                 : $amount;
3672
3673             if ( $cust_bill_pkg->hidden ) {
3674               $r->{amount}      += $amount;
3675               $r->{unit_amount} += $unit_amount;
3676               push @{ $r->{ext_description} }, @d;
3677             } else {
3678               $r = {
3679                 billpkgnum      => $cust_bill_pkg->billpkgnum,
3680                 description     => $description,
3681                 pkgpart         => $pkgpart,
3682                 pkgnum          => $cust_bill_pkg->pkgnum,
3683                 amount          => $amount,
3684                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3685                 unit_amount     => $unit_amount,
3686                 quantity        => $cust_bill_pkg->quantity,
3687                 %item_dates,
3688                 ext_description => \@d,
3689                 svc_label       => ($svc_label || ''),
3690                 locationnum     => $cust_pkg->locationnum,
3691                 pkg_tax         => \@pkg_tax,
3692               };
3693               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3694             }
3695
3696           } else {  # $type eq 'U'
3697
3698             warn "$me _items_cust_bill_pkg adding usage\n"
3699               if $DEBUG > 1;
3700
3701             if ( $cust_bill_pkg->hidden and defined($u) ) {
3702               # if this is a hidden package and there's already a usage
3703               # line for the bundle, add this package's total amount and
3704               # usage details to it
3705               $u->{amount}      += $amount;
3706               push @{ $u->{ext_description} }, @d;
3707             } elsif ( $amount ) {
3708               # create a new usage line
3709               $u = {
3710                 billpkgnum      => $cust_bill_pkg->billpkgnum,
3711                 description     => $description,
3712                 pkgpart         => $pkgpart,
3713                 pkgnum          => $cust_bill_pkg->pkgnum,
3714                 amount          => $amount,
3715                 usage_item      => 1,
3716                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3717                 %item_dates,
3718                 ext_description => \@d,
3719                 locationnum     => $cust_pkg->locationnum,
3720                 pkg_tax         => \@pkg_tax,
3721               };
3722             } # else this has no usage, so don't create a usage section
3723           }
3724
3725         } # recurring or usage with recurring charge
3726
3727       } else { # taxes and fees
3728
3729         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3730           if $DEBUG > 1;
3731
3732         # items of this kind should normally not have sdate/edate.
3733         push @b, {
3734           'description' => $desc,
3735           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3736                                            + $cust_bill_pkg->recur)
3737         };
3738
3739       } # if package line item / other line item
3740
3741       # decide whether to show active discounts here
3742       if (
3743           # case 1: we are showing a single line for the package
3744           ( !$type )
3745           # case 2: we are showing a setup line for a package that has
3746           # no base recurring fee
3747           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3748           # case 3: we are showing a recur line for a package that has
3749           # a base recurring fee
3750           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3751       ) {
3752
3753         my $item_discount = $cust_bill_pkg->_item_discount;
3754         if ( $item_discount ) {
3755           # $item_discount->{amount} is negative
3756
3757           if ( $d and $cust_bill_pkg->hidden ) {
3758             $d->{setup_amount} += $item_discount->{setup_amount};
3759             $d->{recur_amount} += $item_discount->{recur_amount};
3760           } else {
3761             $d = $item_discount;
3762             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3763           }
3764
3765           # update the active line (before the discount) to show the
3766           # original price (whether this is a hidden line or not)
3767
3768           $s->{amount} -= $item_discount->{setup_amount} if $s;
3769           $r->{amount} -= $item_discount->{recur_amount} if $r;
3770
3771         } # if there are any discounts
3772       } # if this is an appropriate place to show discounts
3773
3774     } # foreach $display
3775
3776   }
3777
3778   # discount amount is internally split up
3779   if ( $d ) {
3780     $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3781   }
3782
3783   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3784     if ( $_  ) {
3785       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3786         if exists($_->{amount});
3787       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3788       if (exists($_->{unit_amount})) {
3789         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3790       }
3791
3792       push @b, { %$_ };
3793       #if $_->{amount} != 0
3794       #  || $discount_show_always
3795       #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3796       #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3797     }
3798   }
3799
3800   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3801     if $DEBUG > 1;
3802
3803   @b;
3804
3805 }
3806
3807 =item _items_discounts_avail
3808
3809 Returns an array of line item hashrefs representing available term discounts
3810 for this invoice.  This makes the same assumptions that apply to term
3811 discounts in general: that the package is billed monthly, at a flat rate,
3812 with no usage charges.  A prorated first month will be handled, as will
3813 a setup fee if the discount is allowed to apply to setup fees.
3814
3815 =cut
3816
3817 sub _items_discounts_avail {
3818   my $self = shift;
3819
3820   #maybe move this method from cust_bill when quotations support discount_plans
3821   return () unless $self->can('discount_plans');
3822   my %plans = $self->discount_plans;
3823
3824   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3825   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3826
3827   map {
3828     my $months = $_;
3829     my $plan = $plans{$months};
3830
3831     my $term_total = sprintf('%.2f', $plan->discounted_total);
3832     my $percent = sprintf('%.0f',
3833                           100 * (1 - $term_total / $plan->base_total) );
3834     my $permonth = sprintf('%.2f', $term_total / $months);
3835     my $detail = $self->mt('discount on item'). ' '.
3836                  join(', ', map { "#$_" } $plan->pkgnums)
3837       if $list_pkgnums;
3838
3839     # discounts for non-integer months don't work anyway
3840     $months = sprintf("%d", $months);
3841
3842     +{
3843       description => $self->mt('Save [_1]% by paying for [_2] months',
3844                                 $percent, $months),
3845       amount      => $self->mt('[_1] ([_2] per month)',
3846                                 $term_total, $money_char.$permonth),
3847       ext_description => ($detail || ''),
3848     }
3849   } #map
3850   sort { $b <=> $a } keys %plans;
3851
3852 }
3853
3854 =item has_sections AGENTNUM
3855
3856 Return true if invoice_sections should be enabled for this bill.
3857  (Inherited by both cust_bill and cust_bill_void)
3858
3859 Determination:
3860 * False if not an invoice
3861 * True always if conf invoice_sections is enabled
3862 * True always if sections_by_location is enabled
3863 * True if conf invoice_sections_multilocation > 1,
3864   and location_count >= invoice_sections_multilocation
3865 * Else, False
3866
3867 =cut
3868
3869 sub has_sections {
3870   my ($self, $agentnum) = @_;
3871
3872   return 0 unless $self->invnum > 0;
3873
3874   $agentnum ||= $self->agentnum;
3875   return 1 if $self->conf->config_bool('invoice_sections', $agentnum);
3876   return 1 if $self->conf->exists('sections_by_location', $agentnum);
3877
3878   my $location_min = $self->conf->config(
3879     'invoice_sections_multilocation', $agentnum,
3880   );
3881
3882   return 1
3883     if $location_min
3884     && $self->location_count >= $location_min;
3885
3886   0;
3887 }
3888
3889
3890 =item location_count
3891
3892 Return the number of locations billed on this invoice
3893
3894 =cut
3895
3896 sub location_count {
3897   my ($self) = @_;
3898   return 0 unless $self->invnum;
3899
3900   # SELECT COUNT( DISTINCT cust_pkg.locationnum )
3901   # FROM cust_bill_pkg
3902   # LEFT JOIN cust_pkg USING (pkgnum)
3903   # WHERE invnum = 278
3904   #   AND cust_bill_pkg.pkgnum > 0
3905
3906   my $result = qsearchs({
3907     select    => 'COUNT(DISTINCT cust_pkg.locationnum) as location_count',
3908     table     => 'cust_bill_pkg',
3909     addl_from => 'LEFT JOIN cust_pkg USING (pkgnum)',
3910     extra_sql => 'WHERE invnum = '.dbh->quote( $self->invnum )
3911                . '  AND cust_bill_pkg.pkgnum > 0'
3912   });
3913   ref $result ? $result->location_count : 0;
3914 }
3915
3916
3917
3918 1;