FS/FS/Report/FCC_477.pm

   1 package FS::Report::FCC_477;
   2 use base qw( FS::Report );
   3
   4 use strict;
   5 use vars qw( @upload @download @technology @part2aoption @part2boption
   6              %states
   7            );
   8 use FS::Record qw( dbh );
   9
  10 use Tie::IxHash;
  11 use Storable;
  12
  13 our $DEBUG = 0;
  14
  15 =head1 NAME
  16
  17 FS::Report::FCC_477 - Routines for FCC Form 477 reports
  18
  19 =head1 SYNOPSIS
  20
  21 =head1 BUGS
  22
  23 Documentation.
  24
  25 =head1 SEE ALSO
  26
  27 =cut
  28
  29 @upload = qw(
  30  <200kbps
  31  200-768kbps
  32  768kbps-1.5mbps
  33  1.5-3mpbs
  34  3-6mbps
  35  6-10mbps
  36  10-25mbps
  37  25-100mbps
  38  >100mbps
  39 );
  40
  41 @download = qw(
  42  200-768kbps
  43  768kbps-1.5mbps
  44  1.5-3mbps
  45  3-6mbps
  46  6-10mbps
  47  10-25mbps
  48  25-100mbps
  49  >100mbps
  50 );
  51
  52 @technology = (
  53   'Asymmetric xDSL',
  54   'Symmetric xDSL',
  55   'Other Wireline',
  56   'Cable Modem',
  57   'Optical Carrier',
  58   'Satellite',
  59   'Terrestrial Fixed Wireless',
  60   'Terrestrial Mobile Wireless',
  61   'Electric Power Line',
  62   'Other Technology',
  63 );
  64
  65 @part2aoption = (
  66  'LD carrier',
  67  'owned loops',
  68  'unswitched UNE loops',
  69  'UNE-P',
  70  'UNE-P replacement',
  71  'FTTP',
  72  'coax',
  73  'wireless',
  74 );
  75
  76 @part2boption = (
  77  'nomadic',
  78  'copper',
  79  'FTTP',
  80  'coax',
  81  'wireless',
  82  'other broadband',
  83 );
  84
  85 #from the select at http://www.ffiec.gov/census/default.aspx
  86 #though this is now in the database, also
  87 %states = (
  88   '01' => 'ALABAMA (AL)',
  89   '02' => 'ALASKA (AK)',
  90   '04' => 'ARIZONA (AZ)',
  91   '05' => 'ARKANSAS (AR)',
  92   '06' => 'CALIFORNIA (CA)',
  93   '08' => 'COLORADO (CO)',
  94
  95   '09' => 'CONNECTICUT (CT)',
  96   '10' => 'DELAWARE (DE)',
  97   '11' => 'DISTRICT OF COLUMBIA (DC)',
  98   '12' => 'FLORIDA (FL)',
  99   '13' => 'GEORGIA (GA)',
 100   '15' => 'HAWAII (HI)',
 101
 102   '16' => 'IDAHO (ID)',
 103   '17' => 'ILLINOIS (IL)',
 104   '18' => 'INDIANA (IN)',
 105   '19' => 'IOWA (IA)',
 106   '20' => 'KANSAS (KS)',
 107   '21' => 'KENTUCKY (KY)',
 108
 109   '22' => 'LOUISIANA (LA)',
 110   '23' => 'MAINE (ME)',
 111   '24' => 'MARYLAND (MD)',
 112   '25' => 'MASSACHUSETTS (MA)',
 113   '26' => 'MICHIGAN (MI)',
 114   '27' => 'MINNESOTA (MN)',
 115
 116   '28' => 'MISSISSIPPI (MS)',
 117   '29' => 'MISSOURI (MO)',
 118   '30' => 'MONTANA (MT)',
 119   '31' => 'NEBRASKA (NE)',
 120   '32' => 'NEVADA (NV)',
 121   '33' => 'NEW HAMPSHIRE (NH)',
 122
 123   '34' => 'NEW JERSEY (NJ)',
 124   '35' => 'NEW MEXICO (NM)',
 125   '36' => 'NEW YORK (NY)',
 126   '37' => 'NORTH CAROLINA (NC)',
 127   '38' => 'NORTH DAKOTA (ND)',
 128   '39' => 'OHIO (OH)',
 129
 130   '40' => 'OKLAHOMA (OK)',
 131   '41' => 'OREGON (OR)',
 132   '42' => 'PENNSYLVANIA (PA)',
 133   '44' => 'RHODE ISLAND (RI)',
 134   '45' => 'SOUTH CAROLINA (SC)',
 135   '46' => 'SOUTH DAKOTA (SD)',
 136
 137   '47' => 'TENNESSEE (TN)',
 138   '48' => 'TEXAS (TX)',
 139   '49' => 'UTAH (UT)',
 140   '50' => 'VERMONT (VT)',
 141   '51' => 'VIRGINIA (VA)',
 142   '53' => 'WASHINGTON (WA)',
 143
 144   '54' => 'WEST VIRGINIA (WV)',
 145   '55' => 'WISCONSIN (WI)',
 146   '56' => 'WYOMING (WY)',
 147   '72' => 'PUERTO RICO (PR)',
 148 );
 149
 150 sub restore_fcc477map {
 151   my $key = shift;
 152   FS::Record::scalar_sql('',"select formvalue from fcc477map where formkey = ?",$key);
 153 }
 154
 155 sub save_fcc477map {
 156   my $key = shift;
 157   my $value = shift;
 158
 159   local $SIG{HUP} = 'IGNORE';
 160   local $SIG{INT} = 'IGNORE';
 161   local $SIG{QUIT} = 'IGNORE';
 162   local $SIG{TERM} = 'IGNORE';
 163   local $SIG{TSTP} = 'IGNORE';
 164   local $SIG{PIPE} = 'IGNORE';
 165
 166   my $oldAutoCommit = $FS::UID::AutoCommit;
 167   local $FS::UID::AutoCommit = 0;
 168   my $dbh = dbh;
 169
 170   my $sql = "delete from fcc477map where formkey = ?";
 171   my $sth = dbh->prepare($sql) or die dbh->errstr;
 172   $sth->execute($key) or do {
 173     warn "WARNING: Error removing FCC 477 form defaults: " . $sth->errstr;
 174     $dbh->rollback if $oldAutoCommit;
 175   };
 176
 177   $sql = "insert into fcc477map (formkey,formvalue) values (?,?)";
 178   $sth = dbh->prepare($sql) or die dbh->errstr;
 179   $sth->execute($key,$value) or do {
 180     warn "WARNING: Error setting FCC 477 form defaults: " . $sth->errstr;
 181     $dbh->rollback if $oldAutoCommit;
 182   };
 183
 184   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 185
 186   '';
 187 }
 188
 189 sub parse_technology_option {
 190   my $cgi = shift;
 191   my $save = shift;
 192   my @result = ();
 193   my $i = 0;
 194   for (my $i = 0; $i < scalar(@technology); $i++) {
 195     my $value = $cgi->param("part1_technology_option_$i"); #lame
 196     save_fcc477map("part1_technology_option_$i",$value)
 197         if $save && $value =~ /^\d+$/;
 198     push @result, $value =~ /^\d+$/ ? $value : 0;
 199   }
 200   return (@result);
 201 }
 202
 203 sub statenum2state {
 204   my $num = shift;
 205   $states{$num};
 206 }
 207 ### everything above this point is unmaintained ###
 208
 209
 210 =head1 THE "NEW" REPORT (October 2014 and later)
 211
 212 =head2 METHODS
 213
 214 =over 4
 215
 216 =cut
 217
 218 # functions for internal use
 219
 220 sub join_optionnames {
 221   join(' ', map { join_optionname($_) } @_);
 222 }
 223
 224 sub join_optionnames_int {
 225   join(' ', map { join_optionname_int($_) } @_);
 226 }
 227
 228 sub join_optionname {
 229   # Returns a FROM phrase to join a specific option into the query (via
 230   # part_pkg).  The option value will appear as a field with the same name
 231   # as the option.
 232   my $name = shift;
 233   "LEFT JOIN (SELECT pkgpart, optionvalue AS $name FROM part_pkg_fcc_option".
 234     " WHERE fccoptionname = '$name') AS t_$name".
 235     " ON (part_pkg.pkgpart = t_$name.pkgpart)";
 236 }
 237
 238 sub join_optionname_int {
 239   # Returns a FROM phrase to join a specific option into the query (via
 240   # part_pkg) and cast it to integer..  Note this does not convert nulls
 241   # to zero.
 242   my $name = shift;
 243   "LEFT JOIN (SELECT pkgpart, CAST(optionvalue AS int) AS $name
 244    FROM part_pkg_fcc_option".
 245     " WHERE fccoptionname = '$name') AS t_$name".
 246     " ON (part_pkg.pkgpart = t_$name.pkgpart)";
 247 }
 248
 249 sub dbaname {
 250   # Returns an sql expression for the DBA name
 251   "COALESCE( deploy_zone.dbaname,
 252      (SELECT value FROM conf WHERE conf.name = 'company_name'
 253                              AND (conf.agentnum = deploy_zone.agentnum
 254                                   OR conf.agentnum IS NULL)
 255                              ORDER BY conf.agentnum IS NOT NULL DESC
 256                              LIMIT 1)
 257      ) AS dbaname"
 258 }
 259
 260 sub active_on {
 261   # Returns a condition to limit packages to those that were setup before a
 262   # certain date, and not canceled before that date.
 263   #
 264   # (Strictly speaking this should also exclude suspended packages but
 265   # "suspended as of some past date" is a complicated query.)
 266   my $date = shift;
 267   "cust_pkg.setup <= $date AND ".
 268   "(cust_pkg.cancel IS NULL OR cust_pkg.cancel > $date) AND ".
 269   "(cust_pkg.change_date IS NULL OR cust_pkg.change_date <= $date)"
 270 }
 271
 272 sub is_fixed_broadband {
 273   "is_broadband::int = 1 AND technology::int IN( 10, 11, 12, 20, 30, 40, 41, 42, 50, 60, 70, 90, 0 )"
 274 }
 275
 276 sub is_mobile_broadband {
 277   "is_broadband::int = 1 AND technology::int IN( 80, 81, 82, 83, 84, 85, 86, 87, 88)"
 278 }
 279
 280
 281 =item report SECTION, OPTIONS
 282
 283 Returns the report section SECTION (see the C<parts> method for section
 284 name strings).  OPTIONS may contain the following:
 285
 286 - date: a timestamp value. Packages that were active on that date will be
 287 counted.
 288
 289 - agentnum: limit to packages with this agent.
 290
 291 - ignore_quantity: if true, package quantities will be ignored (only distinct
 292 packages will be counted).
 293
 294 The result will be a hashref containing three parallel arrayrefs:
 295 - "data", the columns required by the FCC.
 296 - "detail", a list of the package numbers included in each row's aggregation
 297 - "error", a hashref containing any error status strings in that row. Keys
 298 are error identifiers, values are the messages to show the user.
 299 as well as an informational item:
 300 - "num_errors", the number of rows that contain errors
 301
 302 =item report_data SECTION, OPTIONS
 303
 304 Returns only the data, not the detail or error columns.  This is the part that
 305 will be submitted to the FCC.
 306
 307 =cut
 308
 309 sub report {
 310   my $class = shift;
 311   my $section = shift;
 312   my %opt = @_;
 313   $opt{detail} = 1;
 314
 315   # add the error column
 316   my $data = $class->report_data($section, %opt);
 317   my $error = [];
 318   my $detail = [];
 319   my $check_method = $section.'_check';
 320   my $num_errors = 0;
 321   foreach my $row (@$data) {
 322     if ( $class->can($check_method) ) { # they don't all have these
 323       my $eh = $class->$check_method( $row );
 324       $num_errors++ if keys(%$eh);
 325       push @$error, $eh
 326     }
 327     push @$detail, pop @$row; # this comes from the query
 328   }
 329
 330   return +{
 331     data => $data,
 332     error => $error,
 333     detail => $detail,
 334     num_errors => $num_errors,
 335   };
 336 }
 337
 338 sub report_data {
 339   my $class = shift;
 340   my $section = shift;
 341   my %opt = @_;
 342
 343   my $method = $section.'_sql';
 344   die "Report section '$section' is not implemented\n"
 345     unless $class->can($method);
 346   my $statement = $class->$method(%opt);
 347
 348   warn $statement if $DEBUG;
 349   my $sth = dbh->prepare($statement);
 350   $sth->execute or die $sth->errstr;
 351   return $sth->fetchall_arrayref;
 352 }
 353
 354 sub fbd_sql {
 355   my $class = shift;
 356   my %opt = @_;
 357   my $date = $opt{date} || time;
 358   my $agentnum = $opt{agentnum};
 359
 360   my @select = (
 361     'censusblock',
 362     dbaname(),
 363     'technology',
 364     'CASE WHEN is_consumer IS NOT NULL THEN 1 ELSE 0 END',
 365     'adv_speed_down',
 366     'adv_speed_up',
 367     'CASE WHEN is_business IS NOT NULL THEN 1 ELSE 0 END',
 368     'cir_speed_down',
 369     'cir_speed_up',
 370   );
 371   push @select, 'blocknum' if $opt{detail};
 372
 373   my $from = 'deploy_zone_block
 374     JOIN deploy_zone USING (zonenum)
 375     JOIN agent USING (agentnum)';
 376   my @where = (
 377     "zonetype = 'B'",
 378     "active_date  < $date",
 379     "(expire_date > $date OR expire_date IS NULL)",
 380   );
 381   push @where, "agentnum = $agentnum" if $agentnum;
 382
 383   my $order_by = 'censusblock, agentnum, technology, is_consumer, is_business';
 384
 385   "SELECT ".join(', ', @select) . "
 386   FROM $from
 387   WHERE ".join(' AND ', @where)."
 388   ORDER BY $order_by
 389   ";
 390 }
 391
 392 sub fbs_sql {
 393   my $class = shift;
 394   my %opt = @_;
 395   my $date = $opt{date} || time;
 396   my $agentnum = $opt{agentnum};
 397   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 398
 399   my $censustract = "replace(cust_location.censustract, '.', '')";
 400
 401   my @select = (
 402     "$censustract AS censustract",
 403     'technology',
 404     'broadband_downstream',
 405     'broadband_upstream',
 406     "SUM($q)",
 407     "SUM(COALESCE(is_consumer,0) * $q)",
 408   );
 409   push @select, "array_to_string(array_agg(pkgnum), ',')" if $opt{detail};
 410
 411   my $from =
 412     'cust_pkg
 413       JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 414       JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 415       JOIN part_pkg USING (pkgpart) '.
 416       join_optionnames_int(qw(
 417         is_broadband technology
 418         is_consumer
 419         )).
 420       join_optionnames(qw(broadband_downstream broadband_upstream))
 421   ;
 422   my @where = (
 423     active_on($date),
 424     is_fixed_broadband()
 425   );
 426   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 427   my $group_by = "$censustract, technology, broadband_downstream, broadband_upstream ";
 428   my $order_by = $group_by;
 429
 430   "SELECT ".join(', ', @select) . "
 431   FROM $from
 432   WHERE ".join(' AND ', @where)."
 433   GROUP BY $group_by
 434   ORDER BY $order_by
 435   ";
 436
 437 }
 438
 439 sub fbs_check {
 440   my $class = shift;
 441   my $row = shift;
 442   my %e;
 443   #censustract
 444   if ( length($row->[0]) == 0 ) {
 445     $e{'censustract_null'} = 'The package location has no census tract.';
 446   } elsif ($row->[0] !~ /^\d{11}$/) {
 447     $e{'censustract_bad'} = 'The census tract must be exactly 11 digits.';
 448   }
 449
 450   #technology
 451   if ( length($row->[1]) == 0 ) {
 452     $e{'technology_null'} = 'The package has no technology type.';
 453   }
 454
 455   #speeds
 456   if ( length($row->[2]) == 0 or length($row->[3]) == 0 ) {
 457     $e{'speed_null'} = 'The package is missing downstream or upstream speeds.';
 458   } elsif ( $row->[2] !~ /^\d*(\.\d+)?$/ or $row->[3] !~ /^\d*(\.\d+)?$/ ) {
 459     $e{'speed_bad'} = 'The downstream and upstream speeds must be decimal numbers in Mbps.';
 460   } elsif ( $row->[2] == 0 or $row->[3] == 0 ) {
 461     $e{'speed_zero'} = 'The downstream and upstream speeds cannot be zero.';
 462   }
 463
 464   return \%e;
 465 }
 466
 467 sub fvs_sql {
 468   my $class = shift;
 469   my %opt = @_;
 470   my $date = $opt{date} || time;
 471   my $agentnum = $opt{agentnum};
 472   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 473   my $censustract = "replace(cust_location.censustract, '.', '')";
 474
 475   my @select = (
 476     "$censustract AS censustract",
 477     # VoIP indicator (0 for non-VoIP, 1 for VoIP)
 478     'COALESCE(is_voip, 0)',
 479     # number of lines/subscriptions
 480     "SUM($q * (CASE WHEN is_voip = 1 THEN 1 ELSE phone_lines END))",
 481     # consumer grade lines/subscriptions
 482     "SUM($q * COALESCE(is_consumer,0) * (CASE WHEN is_voip = 1 THEN voip_sessions ELSE phone_lines END))",
 483   );
 484   push @select, "array_to_string(array_agg(pkgnum), ',')" if $opt{detail};
 485
 486   my $from = 'cust_pkg
 487     JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 488     JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 489     JOIN part_pkg USING (pkgpart) '.
 490     join_optionnames_int(qw(
 491       is_phone is_voip is_consumer phone_lines voip_sessions
 492       ))
 493   ;
 494
 495   my @where = (
 496     active_on($date),
 497     "(is_voip = 1 OR is_phone = 1)",
 498   );
 499   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 500   my $group_by = "$censustract, COALESCE(is_voip, 0)";
 501   my $order_by = $group_by;
 502
 503   "SELECT ".join(', ', @select) . "
 504   FROM $from
 505   WHERE ".join(' AND ', @where)."
 506   GROUP BY $group_by
 507   ORDER BY $order_by
 508   ";
 509
 510 }
 511
 512 sub fvs_check {
 513   my $class = shift;
 514   my $row = shift;
 515   my %e;
 516   #censustract
 517   if ( length($row->[0]) == 0 ) {
 518     $e{'censustract_null'} = 'The package location has no census tract.';
 519   } elsif ($row->[0] !~ /^\d{11}$/) {
 520     $e{'censustract_bad'} = 'The census tract must be exactly 11 digits.';
 521   }
 522   return \%e;
 523 }
 524
 525 sub lts_sql {
 526   my $class = shift;
 527   my %opt = @_;
 528   my $date = $opt{date} || time;
 529   my $agentnum = $opt{agentnum};
 530   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 531
 532   my @select = (
 533     "state.fips",
 534     "SUM($q * phone_vges)",
 535     "SUM($q * phone_circuits)",
 536     "SUM($q * phone_lines)",
 537     "SUM($q * (CASE WHEN is_broadband = 1 THEN phone_lines ELSE 0 END))",
 538     "SUM($q * (CASE WHEN is_consumer = 1 AND phone_longdistance IS NULL THEN phone_lines ELSE 0 END))",
 539     "SUM($q * (CASE WHEN is_consumer = 1 AND phone_longdistance = 1 THEN phone_lines ELSE 0 END))",
 540     "SUM($q * (CASE WHEN is_consumer IS NULL AND phone_longdistance IS NULL THEN phone_lines ELSE 0 END))",
 541     "SUM($q * (CASE WHEN is_consumer IS NULL AND phone_longdistance = 1 THEN phone_lines ELSE 0 END))",
 542     "SUM($q * (CASE WHEN phone_localloop = 'owned' THEN phone_lines ELSE 0 END))",
 543     "SUM($q * (CASE WHEN phone_localloop = 'leased' THEN phone_lines ELSE 0 END))",
 544     "SUM($q * (CASE WHEN phone_localloop = 'resale' THEN phone_lines ELSE 0 END))",
 545     "SUM($q * (CASE WHEN media = 'Fiber' THEN phone_lines ELSE 0 END))",
 546     "SUM($q * (CASE WHEN media = 'Cable Modem' THEN phone_lines ELSE 0 END))",
 547     "SUM($q * (CASE WHEN media = 'Fixed Wireless' THEN phone_lines ELSE 0 END))",
 548   );
 549   push @select, "array_to_string(array_agg(pkgnum),',')" if $opt{detail};
 550
 551   my $from =
 552     'cust_pkg
 553       JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 554       JOIN state USING (country, state)
 555       JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 556       JOIN part_pkg USING (pkgpart) '.
 557       join_optionnames_int(qw(
 558         is_phone is_broadband
 559         phone_vges phone_circuits phone_lines
 560         is_consumer phone_longdistance
 561         )).
 562       join_optionnames('media', 'phone_localloop')
 563   ;
 564   my @where = (
 565     active_on($date),
 566     "is_phone = 1",
 567   );
 568   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 569   my $group_by = 'state.fips';
 570   my $order_by = $group_by;
 571
 572   "SELECT ".join(', ', @select) . "
 573   FROM $from
 574   WHERE ".join(' AND ', @where)."
 575   GROUP BY $group_by
 576   ORDER BY $order_by
 577   ";
 578 }
 579
 580 # voip_sql has a special case: the fifth column, "Voice with Internet",
 581 # must test whether there are _any_ broadband packages at the same location,
 582 # not just whether this package is both VoIP and broadband.
 583
 584 sub voip_sql {
 585   my $class = shift;
 586   my %opt = @_;
 587   my $date = $opt{date} || time;
 588   my $agentnum = $opt{agentnum};
 589   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 590
 591   # subquery to test whether there's an is_broadband package at this location
 592   my $broadband_pkg =
 593     "SELECT 1 FROM cust_pkg AS broadband_pkg
 594     WHERE broadband_pkg.locationnum = cust_pkg.locationnum
 595     AND EXISTS(SELECT 1 FROM part_pkg_fcc_option
 596       WHERE fccoptionname = 'is_broadband'
 597       AND part_pkg_fcc_option.pkgpart = broadband_pkg.pkgpart
 598       AND optionvalue = '1')
 599     AND ".  active_on( $date );
 600
 601   my $has_broadband = "EXISTS($broadband_pkg)";
 602
 603   my @select = (
 604     "state.fips",
 605     # OTT, OTT + consumer
 606     "SUM($q * (CASE WHEN (voip_lastmile IS NULL) THEN 1 ELSE 0 END))",
 607     "SUM($q * (CASE WHEN (voip_lastmile IS NULL AND is_consumer = 1) THEN 1 ELSE 0 END))",
 608     # non-OTT: total, consumer, broadband bundle, media types
 609     "SUM($q * (CASE WHEN (voip_lastmile = 1) THEN 1 ELSE 0 END))",
 610     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND is_consumer = 1) THEN 1 ELSE 0 END))",
 611     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND $has_broadband) THEN 1 ELSE 0 END))",
 612     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND media = 'Copper') THEN 1 ELSE 0 END))",
 613     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND media = 'Fiber') THEN 1 ELSE 0 END))",
 614     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND media = 'Cable Modem') THEN 1 ELSE 0 END))",
 615     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND media = 'Fixed Wireless') THEN 1 ELSE 0 END))",
 616     "SUM($q * (CASE WHEN (voip_lastmile = 1 AND media NOT IN('Copper', 'Fiber', 'Cable Modem', 'Fixed Wireless') ) THEN 1 ELSE 0 END))",
 617   );
 618   push @select, "array_to_string(array_agg(pkgnum),',')" if $opt{detail};
 619
 620   my $from =
 621     'cust_pkg
 622       JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 623       JOIN state USING (country, state)
 624       JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 625       JOIN part_pkg USING (pkgpart) '.
 626       join_optionnames_int(
 627         qw( is_voip is_consumer voip_lastmile)
 628       ).
 629       join_optionnames('media')
 630   ;
 631   my @where = (
 632     active_on($date),
 633     "is_voip = 1",
 634   );
 635   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 636   my $group_by = 'state.fips';
 637   my $order_by = $group_by;
 638
 639   "SELECT ".join(', ', @select) . "
 640   FROM $from
 641   WHERE ".join(' AND ', @where)."
 642   GROUP BY $group_by
 643   ORDER BY $order_by
 644   ";
 645 }
 646
 647 sub mbs_sql {
 648   my $class = shift;
 649   my %opt = @_;
 650   my $date = $opt{date} || time;
 651   my $agentnum = $opt{agentnum};
 652   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 653
 654   my @select = (
 655     'state.fips',
 656     'broadband_downstream',
 657     'broadband_upstream',
 658     "SUM($q)",
 659     "SUM(COALESCE(is_consumer, 0) * $q)",
 660   );
 661   push @select, "array_to_string(array_agg(pkgnum),',')" if $opt{detail};
 662
 663   my $from =
 664     'cust_pkg
 665       JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 666       JOIN state USING (country, state)
 667       JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 668       JOIN part_pkg USING (pkgpart) '.
 669       join_optionnames_int(qw(
 670         is_broadband technology
 671         is_consumer
 672         )).
 673       join_optionnames(qw(broadband_downstream broadband_upstream))
 674   ;
 675   my @where = (
 676     active_on($date),
 677     is_mobile_broadband()
 678   );
 679   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 680   my $group_by = 'state.fips, broadband_downstream, broadband_upstream ';
 681   my $order_by = $group_by;
 682
 683   "SELECT ".join(', ', @select) . "
 684   FROM $from
 685   WHERE ".join(' AND ', @where)."
 686   GROUP BY $group_by
 687   ORDER BY $order_by
 688   ";
 689 }
 690
 691 sub mvs_sql {
 692   my $class = shift;
 693   my %opt = @_;
 694   my $date = $opt{date} || time;
 695   my $agentnum = $opt{agentnum};
 696   my $q = $opt{ignore_quantity} ? '1' : 'COALESCE(cust_pkg.quantity, 1)';
 697
 698   my @select = (
 699     'state.fips',
 700     "SUM($q)",
 701     "SUM($q * COALESCE(mobile_direct,0))",
 702   );
 703   push @select, "array_to_string(array_agg(pkgnum),',')" if $opt{detail};
 704
 705   my $from =
 706     'cust_pkg
 707       JOIN cust_location ON (cust_pkg.locationnum = cust_location.locationnum)
 708       JOIN state USING (country, state)
 709       JOIN cust_main ON (cust_pkg.custnum = cust_main.custnum)
 710       JOIN part_pkg USING (pkgpart) '.
 711       join_optionnames_int(qw( is_mobile mobile_direct) )
 712   ;
 713   my @where = (
 714     active_on($date),
 715     'is_mobile = 1'
 716   );
 717   push @where, "cust_main.agentnum = $agentnum" if $agentnum;
 718   my $group_by = 'state.fips';
 719   my $order_by = $group_by;
 720
 721   "SELECT ".join(', ', @select) . "
 722   FROM $from
 723   WHERE ".join(' AND ', @where)."
 724   GROUP BY $group_by
 725   ORDER BY $order_by
 726   ";
 727 }
 728
 729 =item parts
 730
 731 Returns a Tie::IxHash reference of the internal short names used for the
 732 report sections ('fbd', 'mbs', etc.) to the full names.
 733
 734 =cut
 735
 736 tie our %parts, 'Tie::IxHash', (
 737   fbd   => 'Fixed Broadband Deployment',
 738   fbs   => 'Fixed Broadband Subscription',
 739   fvs   => 'Fixed Voice Subscription',
 740   lts   => 'Local Exchange Telephone Subscription',
 741   voip  => 'Interconnected VoIP Subscription',
 742   mbd   => 'Mobile Broadband Deployment',
 743   mbsa  => 'Mobile Broadband Service Availability',
 744   mbs   => 'Mobile Broadband Subscription',
 745   mvd   => 'Mobile Voice Deployment',
 746   mvs   => 'Mobile Voice Subscription',
 747 );
 748
 749 sub parts {
 750   Storable::dclone(\%parts);
 751 }
 752
 753 =item part_table SECTION
 754
 755 Returns the name of the primary table that's aggregated in the report section
 756 SECTION. The last column of the report returned by the L</report> method is
 757 a comma-separated list of record numbers, in this table, that are included in
 758 the report line item.
 759
 760 =cut
 761
 762 sub part_table {
 763   my ($class, $part) = @_;
 764   if ($part eq 'fbd') {
 765     return 'deploy_zone_block';
 766   } else {
 767     return 'cust_pkg';
 768   } # add other cases as we add more of the deployment/availability reports
 769 }
 770
 771 1;