FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $me %virtual_fields_cache $nowarn_identical );
   6 use Exporter;
   7 use Carp qw(carp cluck croak confess);
   8 use File::CounterFile;
   9 use Locale::Country;
  10 use DBI qw(:sql_types);
  11 use DBIx::DBSchema 0.25;
  12 use FS::UID qw(dbh getotaker datasrc driver_name);
  13 use FS::Schema qw(dbdef);
  14 use FS::SearchCache;
  15 use FS::Msgcat qw(gettext);
  16 use FS::Conf;
  17
  18 use FS::part_virtual_field;
  19
  20 use Tie::IxHash;
  21
  22 @ISA = qw(Exporter);
  23
  24 #export dbdef for now... everything else expects to find it here
  25 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch);
  26
  27 $DEBUG = 0;
  28 $me = '[FS::Record]';
  29
  30 $nowarn_identical = 0;
  31
  32 my $conf;
  33 my $rsa_module;
  34 my $rsa_loaded;
  35 my $rsa_encrypt;
  36 my $rsa_decrypt;
  37
  38 FS::UID->install_callback( sub {
  39   $conf = new FS::Conf;
  40   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  41 } );
  42
  43 =head1 NAME
  44
  45 FS::Record - Database record objects
  46
  47 =head1 SYNOPSIS
  48
  49     use FS::Record;
  50     use FS::Record qw(dbh fields qsearch qsearchs);
  51
  52     $record = new FS::Record 'table', \%hash;
  53     $record = new FS::Record 'table', { 'column' => 'value', ... };
  54
  55     $record  = qsearchs FS::Record 'table', \%hash;
  56     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  57     @records = qsearch  FS::Record 'table', \%hash;
  58     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  59
  60     $table = $record->table;
  61     $dbdef_table = $record->dbdef_table;
  62
  63     $value = $record->get('column');
  64     $value = $record->getfield('column');
  65     $value = $record->column;
  66
  67     $record->set( 'column' => 'value' );
  68     $record->setfield( 'column' => 'value' );
  69     $record->column('value');
  70
  71     %hash = $record->hash;
  72
  73     $hashref = $record->hashref;
  74
  75     $error = $record->insert;
  76
  77     $error = $record->delete;
  78
  79     $error = $new_record->replace($old_record);
  80
  81     # external use deprecated - handled by the database (at least for Pg, mysql)
  82     $value = $record->unique('column');
  83
  84     $error = $record->ut_float('column');
  85     $error = $record->ut_number('column');
  86     $error = $record->ut_numbern('column');
  87     $error = $record->ut_money('column');
  88     $error = $record->ut_text('column');
  89     $error = $record->ut_textn('column');
  90     $error = $record->ut_alpha('column');
  91     $error = $record->ut_alphan('column');
  92     $error = $record->ut_phonen('column');
  93     $error = $record->ut_anything('column');
  94     $error = $record->ut_name('column');
  95
  96     $quoted_value = _quote($value,'table','field');
  97
  98     #deprecated
  99     $fields = hfields('table');
 100     if ( $fields->{Field} ) { # etc.
 101
 102     @fields = fields 'table'; #as a subroutine
 103     @fields = $record->fields; #as a method call
 104
 105
 106 =head1 DESCRIPTION
 107
 108 (Mostly) object-oriented interface to database records.  Records are currently
 109 implemented on top of DBI.  FS::Record is intended as a base class for
 110 table-specific classes to inherit from, i.e. FS::cust_main.
 111
 112 =head1 CONSTRUCTORS
 113
 114 =over 4
 115
 116 =item new [ TABLE, ] HASHREF
 117
 118 Creates a new record.  It doesn't store it in the database, though.  See
 119 L<"insert"> for that.
 120
 121 Note that the object stores this hash reference, not a distinct copy of the
 122 hash it points to.  You can ask the object for a copy with the I<hash>
 123 method.
 124
 125 TABLE can only be omitted when a dervived class overrides the table method.
 126
 127 =cut
 128
 129 sub new {
 130   my $proto = shift;
 131   my $class = ref($proto) || $proto;
 132   my $self = {};
 133   bless ($self, $class);
 134
 135   unless ( defined ( $self->table ) ) {
 136     $self->{'Table'} = shift;
 137     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 138   }
 139
 140   $self->{'Hash'} = shift;
 141
 142   foreach my $field ( grep !defined($self->{'Hash'}{$_}), $self->fields ) {
 143     $self->{'Hash'}{$field}='';
 144   }
 145
 146   $self->_rebless if $self->can('_rebless');
 147
 148   $self->{'modified'} = 0;
 149
 150   $self->_cache($self->{'Hash'}, shift) if $self->can('_cache') && @_;
 151
 152   $self;
 153 }
 154
 155 sub new_or_cached {
 156   my $proto = shift;
 157   my $class = ref($proto) || $proto;
 158   my $self = {};
 159   bless ($self, $class);
 160
 161   $self->{'Table'} = shift unless defined ( $self->table );
 162
 163   my $hashref = $self->{'Hash'} = shift;
 164   my $cache = shift;
 165   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 166     my $obj = $cache->cache->{$hashref->{$cache->key}};
 167     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 168     $obj;
 169   } else {
 170     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 171   }
 172
 173 }
 174
 175 sub create {
 176   my $proto = shift;
 177   my $class = ref($proto) || $proto;
 178   my $self = {};
 179   bless ($self, $class);
 180   if ( defined $self->table ) {
 181     cluck "create constructor is deprecated, use new!";
 182     $self->new(@_);
 183   } else {
 184     croak "FS::Record::create called (not from a subclass)!";
 185   }
 186 }
 187
 188 =item qsearch PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 189
 190 Searches the database for all records matching (at least) the key/value pairs
 191 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 192 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 193 objects.
 194
 195 The preferred usage is to pass a hash reference of named parameters:
 196
 197   my @records = qsearch( {
 198                            'table'     => 'table_name',
 199                            'hashref'   => { 'field' => 'value'
 200                                             'field' => { 'op'    => '<',
 201                                                          'value' => '420',
 202                                                        },
 203                                           },
 204
 205                            #these are optional...
 206                            'select'    => '*',
 207                            'extra_sql' => 'AND field ',
 208                            #'cache_obj' => '', #optional
 209                            'addl_from' => 'LEFT JOIN othtable USING ( field )',
 210                          }
 211                        );
 212
 213 Much code still uses old-style positional parameters, this is also probably
 214 fine in the common case where there are only two parameters:
 215
 216   my @records = qsearch( 'table', { 'field' => 'value' } );
 217
 218 ###oops, argh, FS::Record::new only lets us create database fields.
 219 #Normal behaviour if SELECT is not specified is `*', as in
 220 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 221 #feature where you can specify SELECT - remember, the objects returned,
 222 #although blessed into the appropriate `FS::TABLE' package, will only have the
 223 #fields you specify.  This might have unwanted results if you then go calling
 224 #regular FS::TABLE methods
 225 #on it.
 226
 227 =cut
 228
 229 sub qsearch {
 230   my($stable, $record, $select, $extra_sql, $cache, $addl_from );
 231   if ( ref($_[0]) ) { #hashref for now, eventually maybe accept a list too
 232     my $opt = shift;
 233     $stable    = $opt->{'table'}     or die "table name is required";
 234     $record    = $opt->{'hashref'}   || {};
 235     $select    = $opt->{'select'}    || '*';
 236     $extra_sql = $opt->{'extra_sql'} || '';
 237     $cache     = $opt->{'cache_obj'} || '';
 238     $addl_from = $opt->{'addl_from'} || '';
 239   } else {
 240     ($stable, $record, $select, $extra_sql, $cache, $addl_from ) = @_;
 241     $select ||= '*';
 242   }
 243
 244   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 245   #for jsearch
 246   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 247   $stable = $1;
 248   my $dbh = dbh;
 249
 250   my $table = $cache ? $cache->table : $stable;
 251   my $dbdef_table = dbdef->table($table)
 252     or die "No schema for table $table found - ".
 253            "do you need to create it or run dbdef-create?";
 254   my $pkey = $dbdef_table->primary_key;
 255
 256   my @real_fields = grep exists($record->{$_}), real_fields($table);
 257   my @virtual_fields;
 258   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 259     @virtual_fields = grep exists($record->{$_}), "FS::$table"->virtual_fields;
 260   } else {
 261     cluck "warning: FS::$table not loaded; virtual fields not searchable";
 262     @virtual_fields = ();
 263   }
 264
 265   my $statement = "SELECT $select FROM $stable";
 266   $statement .= " $addl_from" if $addl_from;
 267   if ( @real_fields or @virtual_fields ) {
 268     $statement .= ' WHERE '. join(' AND ',
 269       ( map {
 270
 271       my $op = '=';
 272       my $column = $_;
 273       if ( ref($record->{$_}) ) {
 274         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 275         #$op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name ne 'Pg';
 276         if ( uc($op) eq 'ILIKE' ) {
 277           $op = 'LIKE';
 278           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 279           $column = "LOWER($_)";
 280         }
 281         $record->{$_} = $record->{$_}{'value'}
 282       }
 283
 284       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 285         if ( $op eq '=' ) {
 286           if ( driver_name eq 'Pg' ) {
 287             my $type = dbdef->table($table)->column($column)->type;
 288             if ( $type =~ /(int|serial)/i ) {
 289               qq-( $column IS NULL )-;
 290             } else {
 291               qq-( $column IS NULL OR $column = '' )-;
 292             }
 293           } else {
 294             qq-( $column IS NULL OR $column = "" )-;
 295           }
 296         } elsif ( $op eq '!=' ) {
 297           if ( driver_name eq 'Pg' ) {
 298             my $type = dbdef->table($table)->column($column)->type;
 299             if ( $type =~ /(int|serial)/i ) {
 300               qq-( $column IS NOT NULL )-;
 301             } else {
 302               qq-( $column IS NOT NULL AND $column != '' )-;
 303             }
 304           } else {
 305             qq-( $column IS NOT NULL AND $column != "" )-;
 306           }
 307         } else {
 308           if ( driver_name eq 'Pg' ) {
 309             qq-( $column $op '' )-;
 310           } else {
 311             qq-( $column $op "" )-;
 312           }
 313         }
 314       } else {
 315         "$column $op ?";
 316       }
 317     } @real_fields ),
 318     ( map {
 319       my $op = '=';
 320       my $column = $_;
 321       if ( ref($record->{$_}) ) {
 322         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 323         if ( uc($op) eq 'ILIKE' ) {
 324           $op = 'LIKE';
 325           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 326           $column = "LOWER($_)";
 327         }
 328         $record->{$_} = $record->{$_}{'value'};
 329       }
 330
 331       # ... EXISTS ( SELECT name, value FROM part_virtual_field
 332       #              JOIN virtual_field
 333       #              ON part_virtual_field.vfieldpart = virtual_field.vfieldpart
 334       #              WHERE recnum = svc_acct.svcnum
 335       #              AND (name, value) = ('egad', 'brain') )
 336
 337       my $value = $record->{$_};
 338
 339       my $subq;
 340
 341       $subq = ($value ? 'EXISTS ' : 'NOT EXISTS ') .
 342       "( SELECT part_virtual_field.name, virtual_field.value ".
 343       "FROM part_virtual_field JOIN virtual_field ".
 344       "ON part_virtual_field.vfieldpart = virtual_field.vfieldpart ".
 345       "WHERE virtual_field.recnum = ${table}.${pkey} ".
 346       "AND part_virtual_field.name = '${column}'".
 347       ($value ?
 348         " AND virtual_field.value ${op} '${value}'"
 349       : "") . ")";
 350       $subq;
 351
 352     } @virtual_fields ) );
 353
 354   }
 355
 356   $statement .= " $extra_sql" if defined($extra_sql);
 357
 358   warn "[debug]$me $statement\n" if $DEBUG > 1;
 359   my $sth = $dbh->prepare($statement)
 360     or croak "$dbh->errstr doing $statement";
 361
 362   my $bind = 1;
 363
 364   foreach my $field (
 365     grep defined( $record->{$_} ) && $record->{$_} ne '', @real_fields
 366   ) {
 367     if ( $record->{$field} =~ /^\d+(\.\d+)?$/
 368          && dbdef->table($table)->column($field)->type =~ /(int|serial)/i
 369     ) {
 370       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_INTEGER } );
 371     } else {
 372       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_VARCHAR } );
 373     }
 374   }
 375
 376 #  $sth->execute( map $record->{$_},
 377 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 378 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 379
 380   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 381
 382   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 383     @virtual_fields = "FS::$table"->virtual_fields;
 384   } else {
 385     cluck "warning: FS::$table not loaded; virtual fields not returned either";
 386     @virtual_fields = ();
 387   }
 388
 389   my %result;
 390   tie %result, "Tie::IxHash";
 391   my @stuff = @{ $sth->fetchall_arrayref( {} ) };
 392   if($pkey) {
 393     %result = map { $_->{$pkey}, $_ } @stuff;
 394   } else {
 395     @result{@stuff} = @stuff;
 396   }
 397
 398   $sth->finish;
 399
 400   if ( keys(%result) and @virtual_fields ) {
 401     $statement =
 402       "SELECT virtual_field.recnum, part_virtual_field.name, ".
 403              "virtual_field.value ".
 404       "FROM part_virtual_field JOIN virtual_field USING (vfieldpart) ".
 405       "WHERE part_virtual_field.dbtable = '$table' AND ".
 406       "virtual_field.recnum IN (".
 407       join(',', keys(%result)). ") AND part_virtual_field.name IN ('".
 408       join(q!', '!, @virtual_fields) . "')";
 409     warn "[debug]$me $statement\n" if $DEBUG > 1;
 410     $sth = $dbh->prepare($statement) or croak "$dbh->errstr doing $statement";
 411     $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 412
 413     foreach (@{ $sth->fetchall_arrayref({}) }) {
 414       my $recnum = $_->{recnum};
 415       my $name = $_->{name};
 416       my $value = $_->{value};
 417       if (exists($result{$recnum})) {
 418         $result{$recnum}->{$name} = $value;
 419       }
 420     }
 421   }
 422   my @return;
 423   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 424     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 425       #derivied class didn't override new method, so this optimization is safe
 426       if ( $cache ) {
 427         @return = map {
 428           new_or_cached( "FS::$table", { %{$_} }, $cache )
 429         } values(%result);
 430       } else {
 431         @return = map {
 432           new( "FS::$table", { %{$_} } )
 433         } values(%result);
 434       }
 435     } else {
 436       #okay, its been tested
 437       # warn "untested code (class FS::$table uses custom new method)";
 438       @return = map {
 439         eval 'FS::'. $table. '->new( { %{$_} } )';
 440       } values(%result);
 441     }
 442
 443     # Check for encrypted fields and decrypt them.
 444     if ($conf->exists('encryption') && eval 'defined(@FS::'. $table . '::encrypted_fields)') {
 445       foreach my $record (@return) {
 446         foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 447           # Set it directly... This may cause a problem in the future...
 448           $record->setfield($field, $record->decrypt($record->getfield($field)));
 449         }
 450       }
 451     }
 452   } else {
 453     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 454     @return = map {
 455       FS::Record->new( $table, { %{$_} } );
 456     } values(%result);
 457   }
 458   return @return;
 459 }
 460
 461 =item by_key PRIMARY_KEY_VALUE
 462
 463 This is a class method that returns the record with the given primary key
 464 value.  This method is only useful in FS::Record subclasses.  For example:
 465
 466   my $cust_main = FS::cust_main->by_key(1); # retrieve customer with custnum 1
 467
 468 is equivalent to:
 469
 470   my $cust_main = qsearchs('cust_main', { 'custnum' => 1 } );
 471
 472 =cut
 473
 474 sub by_key {
 475   my ($class, $pkey_value) = @_;
 476
 477   my $table = $class->table
 478     or croak "No table for $class found";
 479
 480   my $dbdef_table = dbdef->table($table)
 481     or die "No schema for table $table found - ".
 482            "do you need to create it or run dbdef-create?";
 483   my $pkey = $dbdef_table->primary_key
 484     or die "No primary key for table $table";
 485
 486   return qsearchs($table, { $pkey => $pkey_value });
 487 }
 488
 489 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 490
 491 Experimental JOINed search method.  Using this method, you can execute a
 492 single SELECT spanning multiple tables, and cache the results for subsequent
 493 method calls.  Interface will almost definately change in an incompatible
 494 fashion.
 495
 496 Arguments:
 497
 498 =cut
 499
 500 sub jsearch {
 501   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 502   my $cache = FS::SearchCache->new( $ptable, $pkey );
 503   my %saw;
 504   ( $cache,
 505     grep { !$saw{$_->getfield($pkey)}++ }
 506       qsearch($table, $record, $select, $extra_sql, $cache )
 507   );
 508 }
 509
 510 =item qsearchs PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 511
 512 Same as qsearch, except that if more than one record matches, it B<carp>s but
 513 returns the first.  If this happens, you either made a logic error in asking
 514 for a single item, or your data is corrupted.
 515
 516 =cut
 517
 518 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 519   my $table = $_[0];
 520   my(@result) = qsearch(@_);
 521   cluck "warning: Multiple records in scalar search ($table)"
 522     if scalar(@result) > 1;
 523   #should warn more vehemently if the search was on a primary key?
 524   scalar(@result) ? ($result[0]) : ();
 525 }
 526
 527 =back
 528
 529 =head1 METHODS
 530
 531 =over 4
 532
 533 =item table
 534
 535 Returns the table name.
 536
 537 =cut
 538
 539 sub table {
 540 #  cluck "warning: FS::Record::table deprecated; supply one in subclass!";
 541   my $self = shift;
 542   $self -> {'Table'};
 543 }
 544
 545 =item dbdef_table
 546
 547 Returns the DBIx::DBSchema::Table object for the table.
 548
 549 =cut
 550
 551 sub dbdef_table {
 552   my($self)=@_;
 553   my($table)=$self->table;
 554   dbdef->table($table);
 555 }
 556
 557 =item get, getfield COLUMN
 558
 559 Returns the value of the column/field/key COLUMN.
 560
 561 =cut
 562
 563 sub get {
 564   my($self,$field) = @_;
 565   # to avoid "Use of unitialized value" errors
 566   if ( defined ( $self->{Hash}->{$field} ) ) {
 567     $self->{Hash}->{$field};
 568   } else {
 569     '';
 570   }
 571 }
 572 sub getfield {
 573   my $self = shift;
 574   $self->get(@_);
 575 }
 576
 577 =item set, setfield COLUMN, VALUE
 578
 579 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 580
 581 =cut
 582
 583 sub set {
 584   my($self,$field,$value) = @_;
 585   $self->{'modified'} = 1;
 586   $self->{'Hash'}->{$field} = $value;
 587 }
 588 sub setfield {
 589   my $self = shift;
 590   $self->set(@_);
 591 }
 592
 593 =item AUTLOADED METHODS
 594
 595 $record->column is a synonym for $record->get('column');
 596
 597 $record->column('value') is a synonym for $record->set('column','value');
 598
 599 =cut
 600
 601 # readable/safe
 602 sub AUTOLOAD {
 603   my($self,$value)=@_;
 604   my($field)=$AUTOLOAD;
 605   $field =~ s/.*://;
 606   if ( defined($value) ) {
 607     confess "errant AUTOLOAD $field for $self (arg $value)"
 608       unless ref($self) && $self->can('setfield');
 609     $self->setfield($field,$value);
 610   } else {
 611     confess "errant AUTOLOAD $field for $self (no args)"
 612       unless ref($self) && $self->can('getfield');
 613     $self->getfield($field);
 614   }
 615 }
 616
 617 # efficient
 618 #sub AUTOLOAD {
 619 #  my $field = $AUTOLOAD;
 620 #  $field =~ s/.*://;
 621 #  if ( defined($_[1]) ) {
 622 #    $_[0]->setfield($field, $_[1]);
 623 #  } else {
 624 #    $_[0]->getfield($field);
 625 #  }
 626 #}
 627
 628 =item hash
 629
 630 Returns a list of the column/value pairs, usually for assigning to a new hash.
 631
 632 To make a distinct duplicate of an FS::Record object, you can do:
 633
 634     $new = new FS::Record ( $old->table, { $old->hash } );
 635
 636 =cut
 637
 638 sub hash {
 639   my($self) = @_;
 640   confess $self. ' -> hash: Hash attribute is undefined'
 641     unless defined($self->{'Hash'});
 642   %{ $self->{'Hash'} };
 643 }
 644
 645 =item hashref
 646
 647 Returns a reference to the column/value hash.  This may be deprecated in the
 648 future; if there's a reason you can't just use the autoloaded or get/set
 649 methods, speak up.
 650
 651 =cut
 652
 653 sub hashref {
 654   my($self) = @_;
 655   $self->{'Hash'};
 656 }
 657
 658 =item modified
 659
 660 Returns true if any of this object's values have been modified with set (or via
 661 an autoloaded method).  Doesn't yet recognize when you retreive a hashref and
 662 modify that.
 663
 664 =cut
 665
 666 sub modified {
 667   my $self = shift;
 668   $self->{'modified'};
 669 }
 670
 671 =item insert
 672
 673 Inserts this record to the database.  If there is an error, returns the error,
 674 otherwise returns false.
 675
 676 =cut
 677
 678 sub insert {
 679   my $self = shift;
 680   my $saved = {};
 681
 682   my $error = $self->check;
 683   return $error if $error;
 684
 685   #single-field unique keys are given a value if false
 686   #(like MySQL's AUTO_INCREMENT or Pg SERIAL)
 687   foreach ( $self->dbdef_table->unique->singles ) {
 688     $self->unique($_) unless $self->getfield($_);
 689   }
 690
 691   #and also the primary key, if the database isn't going to
 692   my $primary_key = $self->dbdef_table->primary_key;
 693   my $db_seq = 0;
 694   if ( $primary_key ) {
 695     my $col = $self->dbdef_table->column($primary_key);
 696
 697     $db_seq =
 698       uc($col->type) eq 'SERIAL'
 699       || ( driver_name eq 'Pg'
 700              && defined($col->default)
 701              && $col->default =~ /^nextval\(/i
 702          )
 703       || ( driver_name eq 'mysql'
 704              && defined($col->local)
 705              && $col->local =~ /AUTO_INCREMENT/i
 706          );
 707     $self->unique($primary_key) unless $self->getfield($primary_key) || $db_seq;
 708   }
 709
 710   my $table = $self->table;
 711
 712
 713   # Encrypt before the database
 714   if ($conf->exists('encryption') && defined(eval '@FS::'. $table . 'encrypted_fields')) {
 715     foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 716       $self->{'saved'} = $self->getfield($field);
 717       $self->setfield($field, $self->enrypt($self->getfield($field)));
 718     }
 719   }
 720
 721
 722   #false laziness w/delete
 723   my @real_fields =
 724     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 725     real_fields($table)
 726   ;
 727   my @values = map { _quote( $self->getfield($_), $table, $_) } @real_fields;
 728   #eslaf
 729
 730   my $statement = "INSERT INTO $table ( ".
 731       join( ', ', @real_fields ).
 732     ") VALUES (".
 733       join( ', ', @values ).
 734     ")"
 735   ;
 736   warn "[debug]$me $statement\n" if $DEBUG > 1;
 737   my $sth = dbh->prepare($statement) or return dbh->errstr;
 738
 739   local $SIG{HUP} = 'IGNORE';
 740   local $SIG{INT} = 'IGNORE';
 741   local $SIG{QUIT} = 'IGNORE';
 742   local $SIG{TERM} = 'IGNORE';
 743   local $SIG{TSTP} = 'IGNORE';
 744   local $SIG{PIPE} = 'IGNORE';
 745
 746   $sth->execute or return $sth->errstr;
 747
 748   my $insertid = '';
 749   if ( $db_seq ) { # get inserted id from the database, if applicable
 750     warn "[debug]$me retreiving sequence from database\n" if $DEBUG;
 751     if ( driver_name eq 'Pg' ) {
 752
 753       my $oid = $sth->{'pg_oid_status'};
 754       my $i_sql = "SELECT $primary_key FROM $table WHERE oid = ?";
 755       my $i_sth = dbh->prepare($i_sql) or do {
 756         dbh->rollback if $FS::UID::AutoCommit;
 757         return dbh->errstr;
 758       };
 759       $i_sth->execute($oid) or do {
 760         dbh->rollback if $FS::UID::AutoCommit;
 761         return $i_sth->errstr;
 762       };
 763       $insertid = $i_sth->fetchrow_arrayref->[0];
 764
 765     } elsif ( driver_name eq 'mysql' ) {
 766
 767       $insertid = dbh->{'mysql_insertid'};
 768       # work around mysql_insertid being null some of the time, ala RT :/
 769       unless ( $insertid ) {
 770         warn "WARNING: DBD::mysql didn't return mysql_insertid; ".
 771              "using SELECT LAST_INSERT_ID();";
 772         my $i_sql = "SELECT LAST_INSERT_ID()";
 773         my $i_sth = dbh->prepare($i_sql) or do {
 774           dbh->rollback if $FS::UID::AutoCommit;
 775           return dbh->errstr;
 776         };
 777         $i_sth->execute or do {
 778           dbh->rollback if $FS::UID::AutoCommit;
 779           return $i_sth->errstr;
 780         };
 781         $insertid = $i_sth->fetchrow_arrayref->[0];
 782       }
 783
 784     } else {
 785       dbh->rollback if $FS::UID::AutoCommit;
 786       return "don't know how to retreive inserted ids from ". driver_name.
 787              ", try using counterfiles (maybe run dbdef-create?)";
 788     }
 789     $self->setfield($primary_key, $insertid);
 790   }
 791
 792   my @virtual_fields =
 793       grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 794           $self->virtual_fields;
 795   if (@virtual_fields) {
 796     my %v_values = map { $_, $self->getfield($_) } @virtual_fields;
 797
 798     my $vfieldpart = $self->vfieldpart_hashref;
 799
 800     my $v_statement = "INSERT INTO virtual_field(recnum, vfieldpart, value) ".
 801                     "VALUES (?, ?, ?)";
 802
 803     my $v_sth = dbh->prepare($v_statement) or do {
 804       dbh->rollback if $FS::UID::AutoCommit;
 805       return dbh->errstr;
 806     };
 807
 808     foreach (keys(%v_values)) {
 809       $v_sth->execute($self->getfield($primary_key),
 810                       $vfieldpart->{$_},
 811                       $v_values{$_})
 812       or do {
 813         dbh->rollback if $FS::UID::AutoCommit;
 814         return $v_sth->errstr;
 815       };
 816     }
 817   }
 818
 819
 820   my $h_sth;
 821   if ( defined dbdef->table('h_'. $table) ) {
 822     my $h_statement = $self->_h_statement('insert');
 823     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 824     $h_sth = dbh->prepare($h_statement) or do {
 825       dbh->rollback if $FS::UID::AutoCommit;
 826       return dbh->errstr;
 827     };
 828   } else {
 829     $h_sth = '';
 830   }
 831   $h_sth->execute or return $h_sth->errstr if $h_sth;
 832
 833   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 834
 835   # Now that it has been saved, reset the encrypted fields so that $new
 836   # can still be used.
 837   foreach my $field (keys %{$saved}) {
 838     $self->setfield($field, $saved->{$field});
 839   }
 840
 841   '';
 842 }
 843
 844 =item add
 845
 846 Depriciated (use insert instead).
 847
 848 =cut
 849
 850 sub add {
 851   cluck "warning: FS::Record::add deprecated!";
 852   insert @_; #call method in this scope
 853 }
 854
 855 =item delete
 856
 857 Delete this record from the database.  If there is an error, returns the error,
 858 otherwise returns false.
 859
 860 =cut
 861
 862 sub delete {
 863   my $self = shift;
 864
 865   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 866     map {
 867       $self->getfield($_) eq ''
 868         #? "( $_ IS NULL OR $_ = \"\" )"
 869         ? ( driver_name eq 'Pg'
 870               ? "$_ IS NULL"
 871               : "( $_ IS NULL OR $_ = \"\" )"
 872           )
 873         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 874     } ( $self->dbdef_table->primary_key )
 875           ? ( $self->dbdef_table->primary_key)
 876           : real_fields($self->table)
 877   );
 878   warn "[debug]$me $statement\n" if $DEBUG > 1;
 879   my $sth = dbh->prepare($statement) or return dbh->errstr;
 880
 881   my $h_sth;
 882   if ( defined dbdef->table('h_'. $self->table) ) {
 883     my $h_statement = $self->_h_statement('delete');
 884     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 885     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 886   } else {
 887     $h_sth = '';
 888   }
 889
 890   my $primary_key = $self->dbdef_table->primary_key;
 891   my $v_sth;
 892   my @del_vfields;
 893   my $vfp = $self->vfieldpart_hashref;
 894   foreach($self->virtual_fields) {
 895     next if $self->getfield($_) eq '';
 896     unless(@del_vfields) {
 897       my $st = "DELETE FROM virtual_field WHERE recnum = ? AND vfieldpart = ?";
 898       $v_sth = dbh->prepare($st) or return dbh->errstr;
 899     }
 900     push @del_vfields, $_;
 901   }
 902
 903   local $SIG{HUP} = 'IGNORE';
 904   local $SIG{INT} = 'IGNORE';
 905   local $SIG{QUIT} = 'IGNORE';
 906   local $SIG{TERM} = 'IGNORE';
 907   local $SIG{TSTP} = 'IGNORE';
 908   local $SIG{PIPE} = 'IGNORE';
 909
 910   my $rc = $sth->execute or return $sth->errstr;
 911   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 912   $h_sth->execute or return $h_sth->errstr if $h_sth;
 913   $v_sth->execute($self->getfield($primary_key), $vfp->{$_})
 914     or return $v_sth->errstr
 915         foreach (@del_vfields);
 916
 917   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 918
 919   #no need to needlessly destoy the data either (causes problems actually)
 920   #undef $self; #no need to keep object!
 921
 922   '';
 923 }
 924
 925 =item del
 926
 927 Depriciated (use delete instead).
 928
 929 =cut
 930
 931 sub del {
 932   cluck "warning: FS::Record::del deprecated!";
 933   &delete(@_); #call method in this scope
 934 }
 935
 936 =item replace OLD_RECORD
 937
 938 Replace the OLD_RECORD with this one in the database.  If there is an error,
 939 returns the error, otherwise returns false.
 940
 941 =cut
 942
 943 sub replace {
 944   my $new = shift;
 945   my $old = shift;
 946
 947   if (!defined($old)) {
 948     warn "[debug]$me replace called with no arguments; autoloading old record\n"
 949      if $DEBUG;
 950     my $primary_key = $new->dbdef_table->primary_key;
 951     if ( $primary_key ) {
 952       $old = qsearchs($new->table, { $primary_key => $new->$primary_key() } )
 953         or croak "can't find ". $new->table. ".$primary_key ".
 954                  $new->$primary_key();
 955     } else {
 956       croak $new->table. " has no primary key; pass old record as argument";
 957     }
 958   }
 959
 960   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
 961
 962   return "Records not in same table!" unless $new->table eq $old->table;
 963
 964   my $primary_key = $old->dbdef_table->primary_key;
 965   return "Can't change primary key $primary_key ".
 966          'from '. $old->getfield($primary_key).
 967          ' to ' . $new->getfield($primary_key)
 968     if $primary_key
 969        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 970
 971   my $error = $new->check;
 972   return $error if $error;
 973
 974   # Encrypt for replace
 975   my $saved = {};
 976   if ($conf->exists('encryption') && defined(eval '@FS::'. $new->table . 'encrypted_fields')) {
 977     foreach my $field (eval '@FS::'. $new->table . '::encrypted_fields') {
 978       $saved->{$field} = $new->getfield($field);
 979       $new->setfield($field, $new->encrypt($new->getfield($field)));
 980     }
 981   }
 982
 983   #my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 984   my %diff = map { ($new->getfield($_) ne $old->getfield($_))
 985                    ? ($_, $new->getfield($_)) : () } $old->fields;
 986
 987   unless ( keys(%diff) ) {
 988     carp "[warning]$me $new -> replace $old: records identical"
 989       unless $nowarn_identical;
 990     return '';
 991   }
 992
 993   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 994     map {
 995       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 996     } real_fields($old->table)
 997   ). ' WHERE '.
 998     join(' AND ',
 999       map {
1000
1001         if ( $old->getfield($_) eq '' ) {
1002
1003          #false laziness w/qsearch
1004          if ( driver_name eq 'Pg' ) {
1005             my $type = $old->dbdef_table->column($_)->type;
1006             if ( $type =~ /(int|serial)/i ) {
1007               qq-( $_ IS NULL )-;
1008             } else {
1009               qq-( $_ IS NULL OR $_ = '' )-;
1010             }
1011           } else {
1012             qq-( $_ IS NULL OR $_ = "" )-;
1013           }
1014
1015         } else {
1016           "$_ = ". _quote($old->getfield($_),$old->table,$_);
1017         }
1018
1019       } ( $primary_key ? ( $primary_key ) : real_fields($old->table) )
1020     )
1021   ;
1022   warn "[debug]$me $statement\n" if $DEBUG > 1;
1023   my $sth = dbh->prepare($statement) or return dbh->errstr;
1024
1025   my $h_old_sth;
1026   if ( defined dbdef->table('h_'. $old->table) ) {
1027     my $h_old_statement = $old->_h_statement('replace_old');
1028     warn "[debug]$me $h_old_statement\n" if $DEBUG > 2;
1029     $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
1030   } else {
1031     $h_old_sth = '';
1032   }
1033
1034   my $h_new_sth;
1035   if ( defined dbdef->table('h_'. $new->table) ) {
1036     my $h_new_statement = $new->_h_statement('replace_new');
1037     warn "[debug]$me $h_new_statement\n" if $DEBUG > 2;
1038     $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
1039   } else {
1040     $h_new_sth = '';
1041   }
1042
1043   # For virtual fields we have three cases with different SQL
1044   # statements: add, replace, delete
1045   my $v_add_sth;
1046   my $v_rep_sth;
1047   my $v_del_sth;
1048   my (@add_vfields, @rep_vfields, @del_vfields);
1049   my $vfp = $old->vfieldpart_hashref;
1050   foreach(grep { exists($diff{$_}) } $new->virtual_fields) {
1051     if($diff{$_} eq '') {
1052       # Delete
1053       unless(@del_vfields) {
1054         my $st = "DELETE FROM virtual_field WHERE recnum = ? ".
1055                  "AND vfieldpart = ?";
1056         warn "[debug]$me $st\n" if $DEBUG > 2;
1057         $v_del_sth = dbh->prepare($st) or return dbh->errstr;
1058       }
1059       push @del_vfields, $_;
1060     } elsif($old->getfield($_) eq '') {
1061       # Add
1062       unless(@add_vfields) {
1063         my $st = "INSERT INTO virtual_field (value, recnum, vfieldpart) ".
1064                  "VALUES (?, ?, ?)";
1065         warn "[debug]$me $st\n" if $DEBUG > 2;
1066         $v_add_sth = dbh->prepare($st) or return dbh->errstr;
1067       }
1068       push @add_vfields, $_;
1069     } else {
1070       # Replace
1071       unless(@rep_vfields) {
1072         my $st = "UPDATE virtual_field SET value = ? ".
1073                  "WHERE recnum = ? AND vfieldpart = ?";
1074         warn "[debug]$me $st\n" if $DEBUG > 2;
1075         $v_rep_sth = dbh->prepare($st) or return dbh->errstr;
1076       }
1077       push @rep_vfields, $_;
1078     }
1079   }
1080
1081   local $SIG{HUP} = 'IGNORE';
1082   local $SIG{INT} = 'IGNORE';
1083   local $SIG{QUIT} = 'IGNORE';
1084   local $SIG{TERM} = 'IGNORE';
1085   local $SIG{TSTP} = 'IGNORE';
1086   local $SIG{PIPE} = 'IGNORE';
1087
1088   my $rc = $sth->execute or return $sth->errstr;
1089   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
1090   $h_old_sth->execute or return $h_old_sth->errstr if $h_old_sth;
1091   $h_new_sth->execute or return $h_new_sth->errstr if $h_new_sth;
1092
1093   $v_del_sth->execute($old->getfield($primary_key),
1094                       $vfp->{$_})
1095         or return $v_del_sth->errstr
1096       foreach(@del_vfields);
1097
1098   $v_add_sth->execute($new->getfield($_),
1099                       $old->getfield($primary_key),
1100                       $vfp->{$_})
1101         or return $v_add_sth->errstr
1102       foreach(@add_vfields);
1103
1104   $v_rep_sth->execute($new->getfield($_),
1105                       $old->getfield($primary_key),
1106                       $vfp->{$_})
1107         or return $v_rep_sth->errstr
1108       foreach(@rep_vfields);
1109
1110   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1111
1112   # Now that it has been saved, reset the encrypted fields so that $new
1113   # can still be used.
1114   foreach my $field (keys %{$saved}) {
1115     $new->setfield($field, $saved->{$field});
1116   }
1117
1118   '';
1119
1120 }
1121
1122 =item rep
1123
1124 Depriciated (use replace instead).
1125
1126 =cut
1127
1128 sub rep {
1129   cluck "warning: FS::Record::rep deprecated!";
1130   replace @_; #call method in this scope
1131 }
1132
1133 =item check
1134
1135 Checks virtual fields (using check_blocks).  Subclasses should still provide
1136 a check method to validate real fields, foreign keys, etc., and call this
1137 method via $self->SUPER::check.
1138
1139 (FIXME: Should this method try to make sure that it I<is> being called from
1140 a subclass's check method, to keep the current semantics as far as possible?)
1141
1142 =cut
1143
1144 sub check {
1145   #confess "FS::Record::check not implemented; supply one in subclass!";
1146   my $self = shift;
1147
1148   foreach my $field ($self->virtual_fields) {
1149     for ($self->getfield($field)) {
1150       # See notes on check_block in FS::part_virtual_field.
1151       eval $self->pvf($field)->check_block;
1152       if ( $@ ) {
1153         #this is bad, probably want to follow the stack backtrace up and see
1154         #wtf happened
1155         my $err = "Fatal error checking $field for $self";
1156         cluck "$err: $@";
1157         return "$err (see log for backtrace): $@";
1158
1159       }
1160       $self->setfield($field, $_);
1161     }
1162   }
1163   '';
1164 }
1165
1166 sub _h_statement {
1167   my( $self, $action, $time ) = @_;
1168
1169   $time ||= time;
1170
1171   my @fields =
1172     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
1173     real_fields($self->table);
1174   ;
1175   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
1176
1177   "INSERT INTO h_". $self->table. " ( ".
1178       join(', ', qw(history_date history_user history_action), @fields ).
1179     ") VALUES (".
1180       join(', ', $time, dbh->quote(getotaker()), dbh->quote($action), @values).
1181     ")"
1182   ;
1183 }
1184
1185 =item unique COLUMN
1186
1187 B<Warning>: External use is B<deprecated>.
1188
1189 Replaces COLUMN in record with a unique number, using counters in the
1190 filesystem.  Used by the B<insert> method on single-field unique columns
1191 (see L<DBIx::DBSchema::Table>) and also as a fallback for primary keys
1192 that aren't SERIAL (Pg) or AUTO_INCREMENT (mysql).
1193
1194 Returns the new value.
1195
1196 =cut
1197
1198 sub unique {
1199   my($self,$field) = @_;
1200   my($table)=$self->table;
1201
1202   croak "Unique called on field $field, but it is ",
1203         $self->getfield($field),
1204         ", not null!"
1205     if $self->getfield($field);
1206
1207   #warn "table $table is tainted" if is_tainted($table);
1208   #warn "field $field is tainted" if is_tainted($field);
1209
1210   my($counter) = new File::CounterFile "$table.$field",0;
1211 # hack for web demo
1212 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
1213 #  my($user)=$1;
1214 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
1215 # endhack
1216
1217   my $index = $counter->inc;
1218   $index = $counter->inc while qsearchs($table, { $field=>$index } );
1219
1220   $index =~ /^(\d*)$/;
1221   $index=$1;
1222
1223   $self->setfield($field,$index);
1224
1225 }
1226
1227 =item ut_float COLUMN
1228
1229 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
1230 null.  If there is an error, returns the error, otherwise returns false.
1231
1232 =cut
1233
1234 sub ut_float {
1235   my($self,$field)=@_ ;
1236   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
1237    $self->getfield($field) =~ /^(\d+)$/ ||
1238    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
1239    $self->getfield($field) =~ /^(\d+e\d+)$/)
1240     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1241   $self->setfield($field,$1);
1242   '';
1243 }
1244
1245 =item ut_snumber COLUMN
1246
1247 Check/untaint signed numeric data (whole numbers).  May not be null.  If there
1248 is an error, returns the error, otherwise returns false.
1249
1250 =cut
1251
1252 sub ut_snumber {
1253   my($self, $field) = @_;
1254   $self->getfield($field) =~ /^(-?)\s*(\d+)$/
1255     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1256   $self->setfield($field, "$1$2");
1257   '';
1258 }
1259
1260 =item ut_number COLUMN
1261
1262 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
1263 is an error, returns the error, otherwise returns false.
1264
1265 =cut
1266
1267 sub ut_number {
1268   my($self,$field)=@_;
1269   $self->getfield($field) =~ /^(\d+)$/
1270     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1271   $self->setfield($field,$1);
1272   '';
1273 }
1274
1275 =item ut_numbern COLUMN
1276
1277 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
1278 an error, returns the error, otherwise returns false.
1279
1280 =cut
1281
1282 sub ut_numbern {
1283   my($self,$field)=@_;
1284   $self->getfield($field) =~ /^(\d*)$/
1285     or return "Illegal (numeric) $field: ". $self->getfield($field);
1286   $self->setfield($field,$1);
1287   '';
1288 }
1289
1290 =item ut_money COLUMN
1291
1292 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
1293 is an error, returns the error, otherwise returns false.
1294
1295 =cut
1296
1297 sub ut_money {
1298   my($self,$field)=@_;
1299   $self->setfield($field, 0) if $self->getfield($field) eq '';
1300   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
1301     or return "Illegal (money) $field: ". $self->getfield($field);
1302   #$self->setfield($field, "$1$2$3" || 0);
1303   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
1304   '';
1305 }
1306
1307 =item ut_text COLUMN
1308
1309 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1310 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / =
1311 May not be null.  If there is an error, returns the error, otherwise returns
1312 false.
1313
1314 =cut
1315
1316 sub ut_text {
1317   my($self,$field)=@_;
1318   #warn "msgcat ". \&msgcat. "\n";
1319   #warn "notexist ". \&notexist. "\n";
1320   #warn "AUTOLOAD ". \&AUTOLOAD. "\n";
1321   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]+)$/
1322     or return gettext('illegal_or_empty_text'). " $field: ".
1323                $self->getfield($field);
1324   $self->setfield($field,$1);
1325   '';
1326 }
1327
1328 =item ut_textn COLUMN
1329
1330 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1331 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
1332 May be null.  If there is an error, returns the error, otherwise returns false.
1333
1334 =cut
1335
1336 sub ut_textn {
1337   my($self,$field)=@_;
1338   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
1339     or return gettext('illegal_text'). " $field: ". $self->getfield($field);
1340   $self->setfield($field,$1);
1341   '';
1342 }
1343
1344 =item ut_alpha COLUMN
1345
1346 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
1347 an error, returns the error, otherwise returns false.
1348
1349 =cut
1350
1351 sub ut_alpha {
1352   my($self,$field)=@_;
1353   $self->getfield($field) =~ /^(\w+)$/
1354     or return "Illegal or empty (alphanumeric) $field: ".
1355               $self->getfield($field);
1356   $self->setfield($field,$1);
1357   '';
1358 }
1359
1360 =item ut_alpha COLUMN
1361
1362 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
1363 error, returns the error, otherwise returns false.
1364
1365 =cut
1366
1367 sub ut_alphan {
1368   my($self,$field)=@_;
1369   $self->getfield($field) =~ /^(\w*)$/
1370     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
1371   $self->setfield($field,$1);
1372   '';
1373 }
1374
1375 =item ut_phonen COLUMN [ COUNTRY ]
1376
1377 Check/untaint phone numbers.  May be null.  If there is an error, returns
1378 the error, otherwise returns false.
1379
1380 Takes an optional two-letter ISO country code; without it or with unsupported
1381 countries, ut_phonen simply calls ut_alphan.
1382
1383 =cut
1384
1385 sub ut_phonen {
1386   my( $self, $field, $country ) = @_;
1387   return $self->ut_alphan($field) unless defined $country;
1388   my $phonen = $self->getfield($field);
1389   if ( $phonen eq '' ) {
1390     $self->setfield($field,'');
1391   } elsif ( $country eq 'US' || $country eq 'CA' ) {
1392     $phonen =~ s/\D//g;
1393     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
1394       or return gettext('illegal_phone'). " $field: ". $self->getfield($field);
1395     $phonen = "$1-$2-$3";
1396     $phonen .= " x$4" if $4;
1397     $self->setfield($field,$phonen);
1398   } else {
1399     warn "warning: don't know how to check phone numbers for country $country";
1400     return $self->ut_textn($field);
1401   }
1402   '';
1403 }
1404
1405 =item ut_ip COLUMN
1406
1407 Check/untaint ip addresses.  IPv4 only for now.
1408
1409 =cut
1410
1411 sub ut_ip {
1412   my( $self, $field ) = @_;
1413   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
1414     or return "Illegal (IP address) $field: ". $self->getfield($field);
1415   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
1416   $self->setfield($field, "$1.$2.$3.$4");
1417   '';
1418 }
1419
1420 =item ut_ipn COLUMN
1421
1422 Check/untaint ip addresses.  IPv4 only for now.  May be null.
1423
1424 =cut
1425
1426 sub ut_ipn {
1427   my( $self, $field ) = @_;
1428   if ( $self->getfield($field) =~ /^()$/ ) {
1429     $self->setfield($field,'');
1430     '';
1431   } else {
1432     $self->ut_ip($field);
1433   }
1434 }
1435
1436 =item ut_domain COLUMN
1437
1438 Check/untaint host and domain names.
1439
1440 =cut
1441
1442 sub ut_domain {
1443   my( $self, $field ) = @_;
1444   #$self->getfield($field) =~/^(\w+\.)*\w+$/
1445   $self->getfield($field) =~/^(([\w\-]+\.)*\w+)$/
1446     or return "Illegal (domain) $field: ". $self->getfield($field);
1447   $self->setfield($field,$1);
1448   '';
1449 }
1450
1451 =item ut_name COLUMN
1452
1453 Check/untaint proper names; allows alphanumerics, spaces and the following
1454 punctuation: , . - '
1455
1456 May not be null.
1457
1458 =cut
1459
1460 sub ut_name {
1461   my( $self, $field ) = @_;
1462   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
1463     or return gettext('illegal_name'). " $field: ". $self->getfield($field);
1464   $self->setfield($field,$1);
1465   '';
1466 }
1467
1468 =item ut_zip COLUMN
1469
1470 Check/untaint zip codes.
1471
1472 =cut
1473
1474 sub ut_zip {
1475   my( $self, $field, $country ) = @_;
1476   if ( $country eq 'US' ) {
1477     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
1478       or return gettext('illegal_zip'). " $field for country $country: ".
1479                 $self->getfield($field);
1480     $self->setfield($field,$1);
1481   } else {
1482     if ( $self->getfield($field) =~ /^\s*$/ ) {
1483       $self->setfield($field,'');
1484     } else {
1485       $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
1486         or return gettext('illegal_zip'). " $field: ". $self->getfield($field);
1487       $self->setfield($field,$1);
1488     }
1489   }
1490   '';
1491 }
1492
1493 =item ut_country COLUMN
1494
1495 Check/untaint country codes.  Country names are changed to codes, if possible -
1496 see L<Locale::Country>.
1497
1498 =cut
1499
1500 sub ut_country {
1501   my( $self, $field ) = @_;
1502   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
1503     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
1504          && country2code($1) ) {
1505       $self->setfield($field,uc(country2code($1)));
1506     }
1507   }
1508   $self->getfield($field) =~ /^(\w\w)$/
1509     or return "Illegal (country) $field: ". $self->getfield($field);
1510   $self->setfield($field,uc($1));
1511   '';
1512 }
1513
1514 =item ut_anything COLUMN
1515
1516 Untaints arbitrary data.  Be careful.
1517
1518 =cut
1519
1520 sub ut_anything {
1521   my( $self, $field ) = @_;
1522   $self->getfield($field) =~ /^(.*)$/s
1523     or return "Illegal $field: ". $self->getfield($field);
1524   $self->setfield($field,$1);
1525   '';
1526 }
1527
1528 =item ut_enum COLUMN CHOICES_ARRAYREF
1529
1530 Check/untaint a column, supplying all possible choices, like the "enum" type.
1531
1532 =cut
1533
1534 sub ut_enum {
1535   my( $self, $field, $choices ) = @_;
1536   foreach my $choice ( @$choices ) {
1537     if ( $self->getfield($field) eq $choice ) {
1538       $self->setfield($choice);
1539       return '';
1540     }
1541   }
1542   return "Illegal (enum) field $field: ". $self->getfield($field);
1543 }
1544
1545 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1546
1547 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
1548 on the column first.
1549
1550 =cut
1551
1552 sub ut_foreign_key {
1553   my( $self, $field, $table, $foreign ) = @_;
1554   qsearchs($table, { $foreign => $self->getfield($field) })
1555     or return "Can't find ". $self->table. ".$field ". $self->getfield($field).
1556               " in $table.$foreign";
1557   '';
1558 }
1559
1560 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1561
1562 Like ut_foreign_key, except the null value is also allowed.
1563
1564 =cut
1565
1566 sub ut_foreign_keyn {
1567   my( $self, $field, $table, $foreign ) = @_;
1568   $self->getfield($field)
1569     ? $self->ut_foreign_key($field, $table, $foreign)
1570     : '';
1571 }
1572
1573
1574 =item virtual_fields [ TABLE ]
1575
1576 Returns a list of virtual fields defined for the table.  This should not
1577 be exported, and should only be called as an instance or class method.
1578
1579 =cut
1580
1581 sub virtual_fields {
1582   my $self = shift;
1583   my $table;
1584   $table = $self->table or confess "virtual_fields called on non-table";
1585
1586   confess "Unknown table $table" unless dbdef->table($table);
1587
1588   return () unless dbdef->table('part_virtual_field');
1589
1590   unless ( $virtual_fields_cache{$table} ) {
1591     my $query = 'SELECT name from part_virtual_field ' .
1592                 "WHERE dbtable = '$table'";
1593     my $dbh = dbh;
1594     my $result = $dbh->selectcol_arrayref($query);
1595     confess $dbh->errstr if $dbh->err;
1596     $virtual_fields_cache{$table} = $result;
1597   }
1598
1599   @{$virtual_fields_cache{$table}};
1600
1601 }
1602
1603
1604 =item fields [ TABLE ]
1605
1606 This is a wrapper for real_fields and virtual_fields.  Code that called
1607 fields before should probably continue to call fields.
1608
1609 =cut
1610
1611 sub fields {
1612   my $something = shift;
1613   my $table;
1614   if($something->isa('FS::Record')) {
1615     $table = $something->table;
1616   } else {
1617     $table = $something;
1618     $something = "FS::$table";
1619   }
1620   return (real_fields($table), $something->virtual_fields());
1621 }
1622
1623 =back
1624
1625 =item pvf FIELD_NAME
1626
1627 Returns the FS::part_virtual_field object corresponding to a field in the
1628 record (specified by FIELD_NAME).
1629
1630 =cut
1631
1632 sub pvf {
1633   my ($self, $name) = (shift, shift);
1634
1635   if(grep /^$name$/, $self->virtual_fields) {
1636     return qsearchs('part_virtual_field', { dbtable => $self->table,
1637                                             name    => $name } );
1638   }
1639   ''
1640 }
1641
1642 =head1 SUBROUTINES
1643
1644 =over 4
1645
1646 =item real_fields [ TABLE ]
1647
1648 Returns a list of the real columns in the specified table.  Called only by
1649 fields() and other subroutines elsewhere in FS::Record.
1650
1651 =cut
1652
1653 sub real_fields {
1654   my $table = shift;
1655
1656   my($table_obj) = dbdef->table($table);
1657   confess "Unknown table $table" unless $table_obj;
1658   $table_obj->columns;
1659 }
1660
1661 =item _quote VALUE, TABLE, COLUMN
1662
1663 This is an internal function used to construct SQL statements.  It returns
1664 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
1665 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
1666
1667 =cut
1668
1669 sub _quote {
1670   my($value, $table, $column) = @_;
1671   my $column_obj = dbdef->table($table)->column($column);
1672   my $column_type = $column_obj->type;
1673   my $nullable = $column_obj->null;
1674
1675   warn "  $table.$column: $value ($column_type".
1676        ( $nullable ? ' NULL' : ' NOT NULL' ).
1677        ")\n" if $DEBUG > 2;
1678
1679   if ( $value eq '' && $column_type =~ /^int/ ) {
1680     if ( $nullable ) {
1681       'NULL';
1682     } else {
1683       cluck "WARNING: Attempting to set non-null integer $table.$column null; ".
1684             "using 0 instead";
1685       0;
1686     }
1687   } elsif ( $value =~ /^\d+(\.\d+)?$/ &&
1688             ! $column_type =~ /(char|binary|text)$/i ) {
1689     $value;
1690   } else {
1691     dbh->quote($value);
1692   }
1693 }
1694
1695 =item vfieldpart_hashref TABLE
1696
1697 Returns a hashref of virtual field names and vfieldparts applicable to the given
1698 TABLE.
1699
1700 =cut
1701
1702 sub vfieldpart_hashref {
1703   my $self = shift;
1704   my $table = $self->table;
1705
1706   return {} unless dbdef->table('part_virtual_field');
1707
1708   my $dbh = dbh;
1709   my $statement = "SELECT vfieldpart, name FROM part_virtual_field WHERE ".
1710                   "dbtable = '$table'";
1711   my $sth = $dbh->prepare($statement);
1712   $sth->execute or croak "Execution of '$statement' failed: ".$dbh->errstr;
1713   return { map { $_->{name}, $_->{vfieldpart} }
1714     @{$sth->fetchall_arrayref({})} };
1715
1716 }
1717
1718
1719 =item hfields TABLE
1720
1721 This is deprecated.  Don't use it.
1722
1723 It returns a hash-type list with the fields of this record's table set true.
1724
1725 =cut
1726
1727 sub hfields {
1728   carp "warning: hfields is deprecated";
1729   my($table)=@_;
1730   my(%hash);
1731   foreach (fields($table)) {
1732     $hash{$_}=1;
1733   }
1734   \%hash;
1735 }
1736
1737 sub _dump {
1738   my($self)=@_;
1739   join("\n", map {
1740     "$_: ". $self->getfield($_). "|"
1741   } (fields($self->table)) );
1742 }
1743
1744 sub encrypt {
1745   my ($self, $value) = @_;
1746   my $encrypted;
1747
1748   if ($conf->exists('encryption')) {
1749     if ($self->is_encrypted($value)) {
1750       # Return the original value if it isn't plaintext.
1751       $encrypted = $value;
1752     } else {
1753       $self->loadRSA;
1754       if (ref($rsa_encrypt) =~ /::RSA/) { # We Can Encrypt
1755         # RSA doesn't like the empty string so let's pack it up
1756         # The database doesn't like the RSA data so uuencode it
1757         my $length = length($value)+1;
1758         $encrypted = pack("u*",$rsa_encrypt->encrypt(pack("Z$length",$value)));
1759       } else {
1760         die ("You can't encrypt w/o a valid RSA engine - Check your installation or disable encryption");
1761       }
1762     }
1763   }
1764   return $encrypted;
1765 }
1766
1767 sub is_encrypted {
1768   my ($self, $value) = @_;
1769   # Possible Bug - Some work may be required here....
1770
1771   if (length($value) > 80) {
1772     return 1;
1773   } else {
1774     return 0;
1775   }
1776 }
1777
1778 sub decrypt {
1779   my ($self,$value) = @_;
1780   my $decrypted = $value; # Will return the original value if it isn't encrypted or can't be decrypted.
1781   if ($conf->exists('encryption') && $self->is_encrypted($value)) {
1782     $self->loadRSA;
1783     if (ref($rsa_decrypt) =~ /::RSA/) {
1784       my $encrypted = unpack ("u*", $value);
1785       $decrypted =  unpack("Z*", $rsa_decrypt->decrypt($encrypted));
1786     }
1787   }
1788   return $decrypted;
1789 }
1790
1791 sub loadRSA {
1792     my $self = shift;
1793     #Initialize the Module
1794     $rsa_module = 'Crypt::OpenSSL::RSA'; # The Default
1795
1796     if ($conf->exists('encryptionmodule') && $conf->config('encryptionmodule') ne '') {
1797       $rsa_module = $conf->config('encryptionmodule');
1798     }
1799
1800     if (!$rsa_loaded) {
1801         eval ("require $rsa_module"); # No need to import the namespace
1802         $rsa_loaded++;
1803     }
1804     # Initialize Encryption
1805     if ($conf->exists('encryptionpublickey') && $conf->config('encryptionpublickey') ne '') {
1806       my $public_key = join("\n",$conf->config('encryptionpublickey'));
1807       $rsa_encrypt = $rsa_module->new_public_key($public_key);
1808     }
1809
1810     # Intitalize Decryption
1811     if ($conf->exists('encryptionprivatekey') && $conf->config('encryptionprivatekey') ne '') {
1812       my $private_key = join("\n",$conf->config('encryptionprivatekey'));
1813       $rsa_decrypt = $rsa_module->new_private_key($private_key);
1814     }
1815 }
1816
1817 sub DESTROY { return; }
1818
1819 #sub DESTROY {
1820 #  my $self = shift;
1821 #  #use Carp qw(cluck);
1822 #  #cluck "DESTROYING $self";
1823 #  warn "DESTROYING $self";
1824 #}
1825
1826 #sub is_tainted {
1827 #             return ! eval { join('',@_), kill 0; 1; };
1828 #         }
1829
1830 =back
1831
1832 =head1 BUGS
1833
1834 This module should probably be renamed, since much of the functionality is
1835 of general use.  It is not completely unlike Adapter::DBI (see below).
1836
1837 Exported qsearch and qsearchs should be deprecated in favor of method calls
1838 (against an FS::Record object like the old search and searchs that qsearch
1839 and qsearchs were on top of.)
1840
1841 The whole fields / hfields mess should be removed.
1842
1843 The various WHERE clauses should be subroutined.
1844
1845 table string should be deprecated in favor of DBIx::DBSchema::Table.
1846
1847 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1848 true maps to the database (and WHERE clauses) would also help.
1849
1850 The ut_ methods should ask the dbdef for a default length.
1851
1852 ut_sqltype (like ut_varchar) should all be defined
1853
1854 A fallback check method should be provided which uses the dbdef.
1855
1856 The ut_money method assumes money has two decimal digits.
1857
1858 The Pg money kludge in the new method only strips `$'.
1859
1860 The ut_phonen method only checks US-style phone numbers.
1861
1862 The _quote function should probably use ut_float instead of a regex.
1863
1864 All the subroutines probably should be methods, here or elsewhere.
1865
1866 Probably should borrow/use some dbdef methods where appropriate (like sub
1867 fields)
1868
1869 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1870 or allow it to be set.  Working around it is ugly any way around - DBI should
1871 be fixed.  (only affects RDBMS which return uppercase column names)
1872
1873 ut_zip should take an optional country like ut_phone.
1874
1875 =head1 SEE ALSO
1876
1877 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1878
1879 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1880
1881 http://poop.sf.net/
1882
1883 =cut
1884
1885 1;
1886