FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $conf $me
   6              %virtual_fields_cache
   7              $nowarn_identical $no_update_diff $no_check_foreign
   8            );
   9 use Exporter;
  10 use Carp qw(carp cluck croak confess);
  11 use Scalar::Util qw( blessed );
  12 use File::CounterFile;
  13 use Locale::Country;
  14 use Text::CSV_XS;
  15 use File::Slurp qw( slurp );
  16 use DBI qw(:sql_types);
  17 use DBIx::DBSchema 0.33;
  18 use FS::UID qw(dbh getotaker datasrc driver_name);
  19 use FS::CurrentUser;
  20 use FS::Schema qw(dbdef);
  21 use FS::SearchCache;
  22 use FS::Msgcat qw(gettext);
  23 #use FS::Conf; #dependency loop bs, in install_callback below instead
  24
  25 use FS::part_virtual_field;
  26
  27 use Tie::IxHash;
  28
  29 @ISA = qw(Exporter);
  30
  31 #export dbdef for now... everything else expects to find it here
  32 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch
  33                 str2time_sql str2time_sql_closing );
  34
  35 $DEBUG = 0;
  36 $me = '[FS::Record]';
  37
  38 $nowarn_identical = 0;
  39 $no_update_diff = 0;
  40 $no_check_foreign = 0;
  41
  42 my $rsa_module;
  43 my $rsa_loaded;
  44 my $rsa_encrypt;
  45 my $rsa_decrypt;
  46
  47 FS::UID->install_callback( sub {
  48   eval "use FS::Conf;";
  49   die $@ if $@;
  50   $conf = FS::Conf->new;
  51   $File::CounterFile::DEFAULT_DIR = $conf->base_dir . "/counters.". datasrc;
  52 } );
  53
  54
  55 =head1 NAME
  56
  57 FS::Record - Database record objects
  58
  59 =head1 SYNOPSIS
  60
  61     use FS::Record;
  62     use FS::Record qw(dbh fields qsearch qsearchs);
  63
  64     $record = new FS::Record 'table', \%hash;
  65     $record = new FS::Record 'table', { 'column' => 'value', ... };
  66
  67     $record  = qsearchs FS::Record 'table', \%hash;
  68     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  69     @records = qsearch  FS::Record 'table', \%hash;
  70     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  71
  72     $table = $record->table;
  73     $dbdef_table = $record->dbdef_table;
  74
  75     $value = $record->get('column');
  76     $value = $record->getfield('column');
  77     $value = $record->column;
  78
  79     $record->set( 'column' => 'value' );
  80     $record->setfield( 'column' => 'value' );
  81     $record->column('value');
  82
  83     %hash = $record->hash;
  84
  85     $hashref = $record->hashref;
  86
  87     $error = $record->insert;
  88
  89     $error = $record->delete;
  90
  91     $error = $new_record->replace($old_record);
  92
  93     # external use deprecated - handled by the database (at least for Pg, mysql)
  94     $value = $record->unique('column');
  95
  96     $error = $record->ut_float('column');
  97     $error = $record->ut_floatn('column');
  98     $error = $record->ut_number('column');
  99     $error = $record->ut_numbern('column');
 100     $error = $record->ut_snumber('column');
 101     $error = $record->ut_snumbern('column');
 102     $error = $record->ut_money('column');
 103     $error = $record->ut_text('column');
 104     $error = $record->ut_textn('column');
 105     $error = $record->ut_alpha('column');
 106     $error = $record->ut_alphan('column');
 107     $error = $record->ut_phonen('column');
 108     $error = $record->ut_anything('column');
 109     $error = $record->ut_name('column');
 110
 111     $quoted_value = _quote($value,'table','field');
 112
 113     #deprecated
 114     $fields = hfields('table');
 115     if ( $fields->{Field} ) { # etc.
 116
 117     @fields = fields 'table'; #as a subroutine
 118     @fields = $record->fields; #as a method call
 119
 120
 121 =head1 DESCRIPTION
 122
 123 (Mostly) object-oriented interface to database records.  Records are currently
 124 implemented on top of DBI.  FS::Record is intended as a base class for
 125 table-specific classes to inherit from, i.e. FS::cust_main.
 126
 127 =head1 CONSTRUCTORS
 128
 129 =over 4
 130
 131 =item new [ TABLE, ] HASHREF
 132
 133 Creates a new record.  It doesn't store it in the database, though.  See
 134 L<"insert"> for that.
 135
 136 Note that the object stores this hash reference, not a distinct copy of the
 137 hash it points to.  You can ask the object for a copy with the I<hash>
 138 method.
 139
 140 TABLE can only be omitted when a dervived class overrides the table method.
 141
 142 =cut
 143
 144 sub new {
 145   my $proto = shift;
 146   my $class = ref($proto) || $proto;
 147   my $self = {};
 148   bless ($self, $class);
 149
 150   unless ( defined ( $self->table ) ) {
 151     $self->{'Table'} = shift;
 152     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 153   }
 154
 155   $self->{'Hash'} = shift;
 156
 157   foreach my $field ( grep !defined($self->{'Hash'}{$_}), $self->fields ) {
 158     $self->{'Hash'}{$field}='';
 159   }
 160
 161   $self->_rebless if $self->can('_rebless');
 162
 163   $self->{'modified'} = 0;
 164
 165   $self->_cache($self->{'Hash'}, shift) if $self->can('_cache') && @_;
 166
 167   $self;
 168 }
 169
 170 sub new_or_cached {
 171   my $proto = shift;
 172   my $class = ref($proto) || $proto;
 173   my $self = {};
 174   bless ($self, $class);
 175
 176   $self->{'Table'} = shift unless defined ( $self->table );
 177
 178   my $hashref = $self->{'Hash'} = shift;
 179   my $cache = shift;
 180   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 181     my $obj = $cache->cache->{$hashref->{$cache->key}};
 182     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 183     $obj;
 184   } else {
 185     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 186   }
 187
 188 }
 189
 190 sub create {
 191   my $proto = shift;
 192   my $class = ref($proto) || $proto;
 193   my $self = {};
 194   bless ($self, $class);
 195   if ( defined $self->table ) {
 196     cluck "create constructor is deprecated, use new!";
 197     $self->new(@_);
 198   } else {
 199     croak "FS::Record::create called (not from a subclass)!";
 200   }
 201 }
 202
 203 =item qsearch PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 204
 205 Searches the database for all records matching (at least) the key/value pairs
 206 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 207 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 208 objects.
 209
 210 The preferred usage is to pass a hash reference of named parameters:
 211
 212   my @records = qsearch( {
 213                            'table'     => 'table_name',
 214                            'hashref'   => { 'field' => 'value'
 215                                             'field' => { 'op'    => '<',
 216                                                          'value' => '420',
 217                                                        },
 218                                           },
 219
 220                            #these are optional...
 221                            'select'    => '*',
 222                            'extra_sql' => 'AND field ',
 223                            'order_by'  => 'ORDER BY something',
 224                            #'cache_obj' => '', #optional
 225                            'addl_from' => 'LEFT JOIN othtable USING ( field )',
 226                            'debug'     => 1,
 227                          }
 228                        );
 229
 230 Much code still uses old-style positional parameters, this is also probably
 231 fine in the common case where there are only two parameters:
 232
 233   my @records = qsearch( 'table', { 'field' => 'value' } );
 234
 235 ###oops, argh, FS::Record::new only lets us create database fields.
 236 #Normal behaviour if SELECT is not specified is `*', as in
 237 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 238 #feature where you can specify SELECT - remember, the objects returned,
 239 #although blessed into the appropriate `FS::TABLE' package, will only have the
 240 #fields you specify.  This might have unwanted results if you then go calling
 241 #regular FS::TABLE methods
 242 #on it.
 243
 244 =cut
 245
 246 my %TYPE = (); #for debugging
 247
 248 sub qsearch {
 249   my($stable, $record, $select, $extra_sql, $order_by, $cache, $addl_from );
 250   my $debug = '';
 251   if ( ref($_[0]) ) { #hashref for now, eventually maybe accept a list too
 252     my $opt = shift;
 253     $stable    = $opt->{'table'}     or die "table name is required";
 254     $record    = $opt->{'hashref'}   || {};
 255     $select    = $opt->{'select'}    || '*';
 256     $extra_sql = $opt->{'extra_sql'} || '';
 257     $order_by  = $opt->{'order_by'}  || '';
 258     $cache     = $opt->{'cache_obj'} || '';
 259     $addl_from = $opt->{'addl_from'} || '';
 260     $debug     = $opt->{'debug'}     || '';
 261   } else {
 262     ($stable, $record, $select, $extra_sql, $cache, $addl_from ) = @_;
 263     $select ||= '*';
 264   }
 265
 266   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 267   #for jsearch
 268   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 269   $stable = $1;
 270   my $dbh = dbh;
 271
 272   my $table = $cache ? $cache->table : $stable;
 273   my $dbdef_table = dbdef->table($table)
 274     or die "No schema for table $table found - ".
 275            "do you need to run freeside-upgrade?";
 276   my $pkey = $dbdef_table->primary_key;
 277
 278   my @real_fields = grep exists($record->{$_}), real_fields($table);
 279   my @virtual_fields;
 280   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 281     @virtual_fields = grep exists($record->{$_}), "FS::$table"->virtual_fields;
 282   } else {
 283     cluck "warning: FS::$table not loaded; virtual fields not searchable";
 284     @virtual_fields = ();
 285   }
 286
 287   my $statement = "SELECT $select FROM $stable";
 288   $statement .= " $addl_from" if $addl_from;
 289   if ( @real_fields or @virtual_fields ) {
 290     $statement .= ' WHERE '. join(' AND ',
 291       get_real_fields($table, $record, \@real_fields) ,
 292       get_virtual_fields($table, $pkey, $record, \@virtual_fields),
 293       );
 294   }
 295
 296   $statement .= " $extra_sql" if defined($extra_sql);
 297   $statement .= " $order_by"  if defined($order_by);
 298
 299   warn "[debug]$me $statement\n" if $DEBUG > 1 || $debug;
 300   my $sth = $dbh->prepare($statement)
 301     or croak "$dbh->errstr doing $statement";
 302
 303   my $bind = 1;
 304
 305   foreach my $field (
 306     grep defined( $record->{$_} ) && $record->{$_} ne '', @real_fields
 307   ) {
 308
 309     my $value = $record->{$field};
 310     $value = $value->{'value'} if ref($value);
 311     my $type = dbdef->table($table)->column($field)->type;
 312
 313     my $TYPE = SQL_VARCHAR;
 314     if ( $type =~ /(int|(big)?serial)/i && $value =~ /^\d+(\.\d+)?$/ ) {
 315       $TYPE = SQL_INTEGER;
 316
 317     #DBD::Pg 1.49: Cannot bind ... unknown sql_type 6 with SQL_FLOAT
 318     } elsif (    ( $type =~ /(numeric)/i     && $value =~ /^[+-]?\d+(\.\d+)?$/)
 319               || ( $type =~ /(real|float4)/i
 320                      && $value =~ /[-+]?\d*\.?\d+([eE][-+]?\d+)?/
 321                  )
 322             ) {
 323       $TYPE = SQL_DECIMAL;
 324     }
 325
 326     if ( $DEBUG > 2 ) {
 327       no strict 'refs';
 328       %TYPE = map { &{"DBI::$_"}() => $_ } @{ $DBI::EXPORT_TAGS{sql_types} }
 329         unless keys %TYPE;
 330       warn "  bind_param $bind (for field $field), $value, TYPE $TYPE{$TYPE}\n";
 331     }
 332
 333     $sth->bind_param($bind++, $value, { TYPE => $TYPE } );
 334
 335   }
 336
 337 #  $sth->execute( map $record->{$_},
 338 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 339 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 340
 341   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 342
 343   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 344     @virtual_fields = "FS::$table"->virtual_fields;
 345   } else {
 346     cluck "warning: FS::$table not loaded; virtual fields not returned either";
 347     @virtual_fields = ();
 348   }
 349
 350   my %result;
 351   tie %result, "Tie::IxHash";
 352   my @stuff = @{ $sth->fetchall_arrayref( {} ) };
 353   if ( $pkey && scalar(@stuff) && $stuff[0]->{$pkey} ) {
 354     %result = map { $_->{$pkey}, $_ } @stuff;
 355   } else {
 356     @result{@stuff} = @stuff;
 357   }
 358
 359   $sth->finish;
 360
 361   if ( keys(%result) and @virtual_fields ) {
 362     $statement =
 363       "SELECT virtual_field.recnum, part_virtual_field.name, ".
 364              "virtual_field.value ".
 365       "FROM part_virtual_field JOIN virtual_field USING (vfieldpart) ".
 366       "WHERE part_virtual_field.dbtable = '$table' AND ".
 367       "virtual_field.recnum IN (".
 368       join(',', keys(%result)). ") AND part_virtual_field.name IN ('".
 369       join(q!', '!, @virtual_fields) . "')";
 370     warn "[debug]$me $statement\n" if $DEBUG > 1;
 371     $sth = $dbh->prepare($statement) or croak "$dbh->errstr doing $statement";
 372     $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 373
 374     foreach (@{ $sth->fetchall_arrayref({}) }) {
 375       my $recnum = $_->{recnum};
 376       my $name = $_->{name};
 377       my $value = $_->{value};
 378       if (exists($result{$recnum})) {
 379         $result{$recnum}->{$name} = $value;
 380       }
 381     }
 382   }
 383   my @return;
 384   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 385     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 386       #derivied class didn't override new method, so this optimization is safe
 387       if ( $cache ) {
 388         @return = map {
 389           new_or_cached( "FS::$table", { %{$_} }, $cache )
 390         } values(%result);
 391       } else {
 392         @return = map {
 393           new( "FS::$table", { %{$_} } )
 394         } values(%result);
 395       }
 396     } else {
 397       #okay, its been tested
 398       # warn "untested code (class FS::$table uses custom new method)";
 399       @return = map {
 400         eval 'FS::'. $table. '->new( { %{$_} } )';
 401       } values(%result);
 402     }
 403
 404     # Check for encrypted fields and decrypt them.
 405    ## only in the local copy, not the cached object
 406     if ( $conf && $conf->exists('encryption') # $conf doesn't exist when doing
 407                                               # the initial search for
 408                                               # access_user
 409          && eval 'defined(@FS::'. $table . '::encrypted_fields)') {
 410       foreach my $record (@return) {
 411         foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 412           # Set it directly... This may cause a problem in the future...
 413           $record->setfield($field, $record->decrypt($record->getfield($field)));
 414         }
 415       }
 416     }
 417   } else {
 418     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 419     @return = map {
 420       FS::Record->new( $table, { %{$_} } );
 421     } values(%result);
 422   }
 423   return @return;
 424 }
 425
 426 ## makes this easier to read
 427
 428 sub get_virtual_fields {
 429    my $table = shift;
 430    my $pkey = shift;
 431    my $record = shift;
 432    my $virtual_fields = shift;
 433
 434    return
 435     ( map {
 436       my $op = '=';
 437       my $column = $_;
 438       if ( ref($record->{$_}) ) {
 439         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 440         if ( uc($op) eq 'ILIKE' ) {
 441           $op = 'LIKE';
 442           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 443           $column = "LOWER($_)";
 444         }
 445         $record->{$_} = $record->{$_}{'value'};
 446       }
 447
 448       # ... EXISTS ( SELECT name, value FROM part_virtual_field
 449       #              JOIN virtual_field
 450       #              ON part_virtual_field.vfieldpart = virtual_field.vfieldpart
 451       #              WHERE recnum = svc_acct.svcnum
 452       #              AND (name, value) = ('egad', 'brain') )
 453
 454       my $value = $record->{$_};
 455
 456       my $subq;
 457
 458       $subq = ($value ? 'EXISTS ' : 'NOT EXISTS ') .
 459       "( SELECT part_virtual_field.name, virtual_field.value ".
 460       "FROM part_virtual_field JOIN virtual_field ".
 461       "ON part_virtual_field.vfieldpart = virtual_field.vfieldpart ".
 462       "WHERE virtual_field.recnum = ${table}.${pkey} ".
 463       "AND part_virtual_field.name = '${column}'".
 464       ($value ?
 465         " AND virtual_field.value ${op} '${value}'"
 466       : "") . ")";
 467       $subq;
 468
 469     } @{ $virtual_fields } ) ;
 470 }
 471
 472 sub get_real_fields {
 473   my $table = shift;
 474   my $record = shift;
 475   my $real_fields = shift;
 476
 477    ## this huge map was previously inline, just broke it out to help read the qsearch method, should be optimized for readability
 478       return (
 479       map {
 480
 481       my $op = '=';
 482       my $column = $_;
 483       if ( ref($record->{$_}) ) {
 484         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 485         #$op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name ne 'Pg';
 486         if ( uc($op) eq 'ILIKE' ) {
 487           $op = 'LIKE';
 488           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 489           $column = "LOWER($_)";
 490         }
 491         $record->{$_} = $record->{$_}{'value'}
 492       }
 493
 494       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 495         if ( $op eq '=' ) {
 496           if ( driver_name eq 'Pg' ) {
 497             my $type = dbdef->table($table)->column($column)->type;
 498             if ( $type =~ /(int|(big)?serial)/i ) {
 499               qq-( $column IS NULL )-;
 500             } else {
 501               qq-( $column IS NULL OR $column = '' )-;
 502             }
 503           } else {
 504             qq-( $column IS NULL OR $column = "" )-;
 505           }
 506         } elsif ( $op eq '!=' ) {
 507           if ( driver_name eq 'Pg' ) {
 508             my $type = dbdef->table($table)->column($column)->type;
 509             if ( $type =~ /(int|(big)?serial)/i ) {
 510               qq-( $column IS NOT NULL )-;
 511             } else {
 512               qq-( $column IS NOT NULL AND $column != '' )-;
 513             }
 514           } else {
 515             qq-( $column IS NOT NULL AND $column != "" )-;
 516           }
 517         } else {
 518           if ( driver_name eq 'Pg' ) {
 519             qq-( $column $op '' )-;
 520           } else {
 521             qq-( $column $op "" )-;
 522           }
 523         }
 524       } else {
 525         "$column $op ?";
 526       }
 527     } @{ $real_fields } );
 528 }
 529
 530 =item by_key PRIMARY_KEY_VALUE
 531
 532 This is a class method that returns the record with the given primary key
 533 value.  This method is only useful in FS::Record subclasses.  For example:
 534
 535   my $cust_main = FS::cust_main->by_key(1); # retrieve customer with custnum 1
 536
 537 is equivalent to:
 538
 539   my $cust_main = qsearchs('cust_main', { 'custnum' => 1 } );
 540
 541 =cut
 542
 543 sub by_key {
 544   my ($class, $pkey_value) = @_;
 545
 546   my $table = $class->table
 547     or croak "No table for $class found";
 548
 549   my $dbdef_table = dbdef->table($table)
 550     or die "No schema for table $table found - ".
 551            "do you need to create it or run dbdef-create?";
 552   my $pkey = $dbdef_table->primary_key
 553     or die "No primary key for table $table";
 554
 555   return qsearchs($table, { $pkey => $pkey_value });
 556 }
 557
 558 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 559
 560 Experimental JOINed search method.  Using this method, you can execute a
 561 single SELECT spanning multiple tables, and cache the results for subsequent
 562 method calls.  Interface will almost definately change in an incompatible
 563 fashion.
 564
 565 Arguments:
 566
 567 =cut
 568
 569 sub jsearch {
 570   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 571   my $cache = FS::SearchCache->new( $ptable, $pkey );
 572   my %saw;
 573   ( $cache,
 574     grep { !$saw{$_->getfield($pkey)}++ }
 575       qsearch($table, $record, $select, $extra_sql, $cache )
 576   );
 577 }
 578
 579 =item qsearchs PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 580
 581 Same as qsearch, except that if more than one record matches, it B<carp>s but
 582 returns the first.  If this happens, you either made a logic error in asking
 583 for a single item, or your data is corrupted.
 584
 585 =cut
 586
 587 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 588   my $table = $_[0];
 589   my(@result) = qsearch(@_);
 590   cluck "warning: Multiple records in scalar search ($table)"
 591     if scalar(@result) > 1;
 592   #should warn more vehemently if the search was on a primary key?
 593   scalar(@result) ? ($result[0]) : ();
 594 }
 595
 596 =back
 597
 598 =head1 METHODS
 599
 600 =over 4
 601
 602 =item table
 603
 604 Returns the table name.
 605
 606 =cut
 607
 608 sub table {
 609 #  cluck "warning: FS::Record::table deprecated; supply one in subclass!";
 610   my $self = shift;
 611   $self -> {'Table'};
 612 }
 613
 614 =item dbdef_table
 615
 616 Returns the DBIx::DBSchema::Table object for the table.
 617
 618 =cut
 619
 620 sub dbdef_table {
 621   my($self)=@_;
 622   my($table)=$self->table;
 623   dbdef->table($table);
 624 }
 625
 626 =item primary_key
 627
 628 Returns the primary key for the table.
 629
 630 =cut
 631
 632 sub primary_key {
 633   my $self = shift;
 634   my $pkey = $self->dbdef_table->primary_key;
 635 }
 636
 637 =item get, getfield COLUMN
 638
 639 Returns the value of the column/field/key COLUMN.
 640
 641 =cut
 642
 643 sub get {
 644   my($self,$field) = @_;
 645   # to avoid "Use of unitialized value" errors
 646   if ( defined ( $self->{Hash}->{$field} ) ) {
 647     $self->{Hash}->{$field};
 648   } else {
 649     '';
 650   }
 651 }
 652 sub getfield {
 653   my $self = shift;
 654   $self->get(@_);
 655 }
 656
 657 =item set, setfield COLUMN, VALUE
 658
 659 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 660
 661 =cut
 662
 663 sub set {
 664   my($self,$field,$value) = @_;
 665   $self->{'modified'} = 1;
 666   $self->{'Hash'}->{$field} = $value;
 667 }
 668 sub setfield {
 669   my $self = shift;
 670   $self->set(@_);
 671 }
 672
 673 =item AUTLOADED METHODS
 674
 675 $record->column is a synonym for $record->get('column');
 676
 677 $record->column('value') is a synonym for $record->set('column','value');
 678
 679 =cut
 680
 681 # readable/safe
 682 sub AUTOLOAD {
 683   my($self,$value)=@_;
 684   my($field)=$AUTOLOAD;
 685   $field =~ s/.*://;
 686   if ( defined($value) ) {
 687     confess "errant AUTOLOAD $field for $self (arg $value)"
 688       unless blessed($self) && $self->can('setfield');
 689     $self->setfield($field,$value);
 690   } else {
 691     confess "errant AUTOLOAD $field for $self (no args)"
 692       unless blessed($self) && $self->can('getfield');
 693     $self->getfield($field);
 694   }
 695 }
 696
 697 # efficient
 698 #sub AUTOLOAD {
 699 #  my $field = $AUTOLOAD;
 700 #  $field =~ s/.*://;
 701 #  if ( defined($_[1]) ) {
 702 #    $_[0]->setfield($field, $_[1]);
 703 #  } else {
 704 #    $_[0]->getfield($field);
 705 #  }
 706 #}
 707
 708 =item hash
 709
 710 Returns a list of the column/value pairs, usually for assigning to a new hash.
 711
 712 To make a distinct duplicate of an FS::Record object, you can do:
 713
 714     $new = new FS::Record ( $old->table, { $old->hash } );
 715
 716 =cut
 717
 718 sub hash {
 719   my($self) = @_;
 720   confess $self. ' -> hash: Hash attribute is undefined'
 721     unless defined($self->{'Hash'});
 722   %{ $self->{'Hash'} };
 723 }
 724
 725 =item hashref
 726
 727 Returns a reference to the column/value hash.  This may be deprecated in the
 728 future; if there's a reason you can't just use the autoloaded or get/set
 729 methods, speak up.
 730
 731 =cut
 732
 733 sub hashref {
 734   my($self) = @_;
 735   $self->{'Hash'};
 736 }
 737
 738 =item modified
 739
 740 Returns true if any of this object's values have been modified with set (or via
 741 an autoloaded method).  Doesn't yet recognize when you retreive a hashref and
 742 modify that.
 743
 744 =cut
 745
 746 sub modified {
 747   my $self = shift;
 748   $self->{'modified'};
 749 }
 750
 751 =item select_for_update
 752
 753 Selects this record with the SQL "FOR UPDATE" command.  This can be useful as
 754 a mutex.
 755
 756 =cut
 757
 758 sub select_for_update {
 759   my $self = shift;
 760   my $primary_key = $self->primary_key;
 761   qsearchs( {
 762     'select'    => '*',
 763     'table'     => $self->table,
 764     'hashref'   => { $primary_key => $self->$primary_key() },
 765     'extra_sql' => 'FOR UPDATE',
 766   } );
 767 }
 768
 769 =item lock_table
 770
 771 Locks this table with a database-driver specific lock method.  This is used
 772 as a mutex in order to do a duplicate search.
 773
 774 For PostgreSQL, does "LOCK TABLE tablename IN SHARE ROW EXCLUSIVE MODE".
 775
 776 For MySQL, does a SELECT FOR UPDATE on the duplicate_lock table.
 777
 778 Errors are fatal; no useful return value.
 779
 780 Note: To use this method for new tables other than svc_acct and svc_phone,
 781 edit freeside-upgrade and add those tables to the duplicate_lock list.
 782
 783 =cut
 784
 785 sub lock_table {
 786   my $self = shift;
 787   my $table = $self->table;
 788
 789   warn "$me locking $table table\n" if $DEBUG;
 790
 791   if ( driver_name =~ /^Pg/i ) {
 792
 793     dbh->do("LOCK TABLE $table IN SHARE ROW EXCLUSIVE MODE")
 794       or die dbh->errstr;
 795
 796   } elsif ( driver_name =~ /^mysql/i ) {
 797
 798     dbh->do("SELECT * FROM duplicate_lock
 799                WHERE lockname = '$table'
 800                FOR UPDATE"
 801            ) or die dbh->errstr;
 802
 803   } else {
 804
 805     die "unknown database ". driver_name. "; don't know how to lock table";
 806
 807   }
 808
 809   warn "$me acquired $table table lock\n" if $DEBUG;
 810
 811 }
 812
 813 =item insert
 814
 815 Inserts this record to the database.  If there is an error, returns the error,
 816 otherwise returns false.
 817
 818 =cut
 819
 820 sub insert {
 821   my $self = shift;
 822   my $saved = {};
 823
 824   warn "$self -> insert" if $DEBUG;
 825
 826   my $error = $self->check;
 827   return $error if $error;
 828
 829   #single-field unique keys are given a value if false
 830   #(like MySQL's AUTO_INCREMENT or Pg SERIAL)
 831   foreach ( $self->dbdef_table->unique_singles) {
 832     $self->unique($_) unless $self->getfield($_);
 833   }
 834
 835   #and also the primary key, if the database isn't going to
 836   my $primary_key = $self->dbdef_table->primary_key;
 837   my $db_seq = 0;
 838   if ( $primary_key ) {
 839     my $col = $self->dbdef_table->column($primary_key);
 840
 841     $db_seq =
 842       uc($col->type) =~ /^(BIG)?SERIAL\d?/
 843       || ( driver_name eq 'Pg'
 844              && defined($col->default)
 845              && $col->default =~ /^nextval\(/i
 846          )
 847       || ( driver_name eq 'mysql'
 848              && defined($col->local)
 849              && $col->local =~ /AUTO_INCREMENT/i
 850          );
 851     $self->unique($primary_key) unless $self->getfield($primary_key) || $db_seq;
 852   }
 853
 854   my $table = $self->table;
 855
 856   # Encrypt before the database
 857   if (    defined(eval '@FS::'. $table . '::encrypted_fields')
 858        && scalar( eval '@FS::'. $table . '::encrypted_fields')
 859        && $conf->exists('encryption')
 860   ) {
 861     foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 862       $self->{'saved'} = $self->getfield($field);
 863       $self->setfield($field, $self->encrypt($self->getfield($field)));
 864     }
 865   }
 866
 867   #false laziness w/delete
 868   my @real_fields =
 869     grep { defined($self->getfield($_)) && $self->getfield($_) ne "" }
 870     real_fields($table)
 871   ;
 872   my @values = map { _quote( $self->getfield($_), $table, $_) } @real_fields;
 873   #eslaf
 874
 875   my $statement = "INSERT INTO $table ";
 876   if ( @real_fields ) {
 877     $statement .=
 878       "( ".
 879         join( ', ', @real_fields ).
 880       ") VALUES (".
 881         join( ', ', @values ).
 882        ")"
 883     ;
 884   } else {
 885     $statement .= 'DEFAULT VALUES';
 886   }
 887   warn "[debug]$me $statement\n" if $DEBUG > 1;
 888   my $sth = dbh->prepare($statement) or return dbh->errstr;
 889
 890   local $SIG{HUP} = 'IGNORE';
 891   local $SIG{INT} = 'IGNORE';
 892   local $SIG{QUIT} = 'IGNORE';
 893   local $SIG{TERM} = 'IGNORE';
 894   local $SIG{TSTP} = 'IGNORE';
 895   local $SIG{PIPE} = 'IGNORE';
 896
 897   $sth->execute or return $sth->errstr;
 898
 899   # get inserted id from the database, if applicable & needed
 900   if ( $db_seq && ! $self->getfield($primary_key) ) {
 901     warn "[debug]$me retreiving sequence from database\n" if $DEBUG;
 902
 903     my $insertid = '';
 904
 905     if ( driver_name eq 'Pg' ) {
 906
 907       #my $oid = $sth->{'pg_oid_status'};
 908       #my $i_sql = "SELECT $primary_key FROM $table WHERE oid = ?";
 909
 910       my $default = $self->dbdef_table->column($primary_key)->default;
 911       unless ( $default =~ /^nextval\(\(?'"?([\w\.]+)"?'/i ) {
 912         dbh->rollback if $FS::UID::AutoCommit;
 913         return "can't parse $table.$primary_key default value".
 914                " for sequence name: $default";
 915       }
 916       my $sequence = $1;
 917
 918       my $i_sql = "SELECT currval('$sequence')";
 919       my $i_sth = dbh->prepare($i_sql) or do {
 920         dbh->rollback if $FS::UID::AutoCommit;
 921         return dbh->errstr;
 922       };
 923       $i_sth->execute() or do { #$i_sth->execute($oid)
 924         dbh->rollback if $FS::UID::AutoCommit;
 925         return $i_sth->errstr;
 926       };
 927       $insertid = $i_sth->fetchrow_arrayref->[0];
 928
 929     } elsif ( driver_name eq 'mysql' ) {
 930
 931       $insertid = dbh->{'mysql_insertid'};
 932       # work around mysql_insertid being null some of the time, ala RT :/
 933       unless ( $insertid ) {
 934         warn "WARNING: DBD::mysql didn't return mysql_insertid; ".
 935              "using SELECT LAST_INSERT_ID();";
 936         my $i_sql = "SELECT LAST_INSERT_ID()";
 937         my $i_sth = dbh->prepare($i_sql) or do {
 938           dbh->rollback if $FS::UID::AutoCommit;
 939           return dbh->errstr;
 940         };
 941         $i_sth->execute or do {
 942           dbh->rollback if $FS::UID::AutoCommit;
 943           return $i_sth->errstr;
 944         };
 945         $insertid = $i_sth->fetchrow_arrayref->[0];
 946       }
 947
 948     } else {
 949
 950       dbh->rollback if $FS::UID::AutoCommit;
 951       return "don't know how to retreive inserted ids from ". driver_name.
 952              ", try using counterfiles (maybe run dbdef-create?)";
 953
 954     }
 955
 956     $self->setfield($primary_key, $insertid);
 957
 958   }
 959
 960   my @virtual_fields =
 961       grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 962           $self->virtual_fields;
 963   if (@virtual_fields) {
 964     my %v_values = map { $_, $self->getfield($_) } @virtual_fields;
 965
 966     my $vfieldpart = $self->vfieldpart_hashref;
 967
 968     my $v_statement = "INSERT INTO virtual_field(recnum, vfieldpart, value) ".
 969                     "VALUES (?, ?, ?)";
 970
 971     my $v_sth = dbh->prepare($v_statement) or do {
 972       dbh->rollback if $FS::UID::AutoCommit;
 973       return dbh->errstr;
 974     };
 975
 976     foreach (keys(%v_values)) {
 977       $v_sth->execute($self->getfield($primary_key),
 978                       $vfieldpart->{$_},
 979                       $v_values{$_})
 980       or do {
 981         dbh->rollback if $FS::UID::AutoCommit;
 982         return $v_sth->errstr;
 983       };
 984     }
 985   }
 986
 987
 988   my $h_sth;
 989   if ( defined dbdef->table('h_'. $table) ) {
 990     my $h_statement = $self->_h_statement('insert');
 991     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 992     $h_sth = dbh->prepare($h_statement) or do {
 993       dbh->rollback if $FS::UID::AutoCommit;
 994       return dbh->errstr;
 995     };
 996   } else {
 997     $h_sth = '';
 998   }
 999   $h_sth->execute or return $h_sth->errstr if $h_sth;
1000
1001   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1002
1003   # Now that it has been saved, reset the encrypted fields so that $new
1004   # can still be used.
1005   foreach my $field (keys %{$saved}) {
1006     $self->setfield($field, $saved->{$field});
1007   }
1008
1009   '';
1010 }
1011
1012 =item add
1013
1014 Depriciated (use insert instead).
1015
1016 =cut
1017
1018 sub add {
1019   cluck "warning: FS::Record::add deprecated!";
1020   insert @_; #call method in this scope
1021 }
1022
1023 =item delete
1024
1025 Delete this record from the database.  If there is an error, returns the error,
1026 otherwise returns false.
1027
1028 =cut
1029
1030 sub delete {
1031   my $self = shift;
1032
1033   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
1034     map {
1035       $self->getfield($_) eq ''
1036         #? "( $_ IS NULL OR $_ = \"\" )"
1037         ? ( driver_name eq 'Pg'
1038               ? "$_ IS NULL"
1039               : "( $_ IS NULL OR $_ = \"\" )"
1040           )
1041         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
1042     } ( $self->dbdef_table->primary_key )
1043           ? ( $self->dbdef_table->primary_key)
1044           : real_fields($self->table)
1045   );
1046   warn "[debug]$me $statement\n" if $DEBUG > 1;
1047   my $sth = dbh->prepare($statement) or return dbh->errstr;
1048
1049   my $h_sth;
1050   if ( defined dbdef->table('h_'. $self->table) ) {
1051     my $h_statement = $self->_h_statement('delete');
1052     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
1053     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
1054   } else {
1055     $h_sth = '';
1056   }
1057
1058   my $primary_key = $self->dbdef_table->primary_key;
1059   my $v_sth;
1060   my @del_vfields;
1061   my $vfp = $self->vfieldpart_hashref;
1062   foreach($self->virtual_fields) {
1063     next if $self->getfield($_) eq '';
1064     unless(@del_vfields) {
1065       my $st = "DELETE FROM virtual_field WHERE recnum = ? AND vfieldpart = ?";
1066       $v_sth = dbh->prepare($st) or return dbh->errstr;
1067     }
1068     push @del_vfields, $_;
1069   }
1070
1071   local $SIG{HUP} = 'IGNORE';
1072   local $SIG{INT} = 'IGNORE';
1073   local $SIG{QUIT} = 'IGNORE';
1074   local $SIG{TERM} = 'IGNORE';
1075   local $SIG{TSTP} = 'IGNORE';
1076   local $SIG{PIPE} = 'IGNORE';
1077
1078   my $rc = $sth->execute or return $sth->errstr;
1079   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
1080   $h_sth->execute or return $h_sth->errstr if $h_sth;
1081   $v_sth->execute($self->getfield($primary_key), $vfp->{$_})
1082     or return $v_sth->errstr
1083         foreach (@del_vfields);
1084
1085   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1086
1087   #no need to needlessly destoy the data either (causes problems actually)
1088   #undef $self; #no need to keep object!
1089
1090   '';
1091 }
1092
1093 =item del
1094
1095 Depriciated (use delete instead).
1096
1097 =cut
1098
1099 sub del {
1100   cluck "warning: FS::Record::del deprecated!";
1101   &delete(@_); #call method in this scope
1102 }
1103
1104 =item replace OLD_RECORD
1105
1106 Replace the OLD_RECORD with this one in the database.  If there is an error,
1107 returns the error, otherwise returns false.
1108
1109 =cut
1110
1111 sub replace {
1112   my ($new, $old) = (shift, shift);
1113
1114   $old = $new->replace_old unless defined($old);
1115
1116   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
1117
1118   if ( $new->can('replace_check') ) {
1119     my $error = $new->replace_check($old);
1120     return $error if $error;
1121   }
1122
1123   return "Records not in same table!" unless $new->table eq $old->table;
1124
1125   my $primary_key = $old->dbdef_table->primary_key;
1126   return "Can't change primary key $primary_key ".
1127          'from '. $old->getfield($primary_key).
1128          ' to ' . $new->getfield($primary_key)
1129     if $primary_key
1130        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
1131
1132   my $error = $new->check;
1133   return $error if $error;
1134
1135   # Encrypt for replace
1136   my $saved = {};
1137   if ($conf->exists('encryption') && defined(eval '@FS::'. $new->table . '::encrypted_fields')) {
1138     foreach my $field (eval '@FS::'. $new->table . '::encrypted_fields') {
1139       $saved->{$field} = $new->getfield($field);
1140       $new->setfield($field, $new->encrypt($new->getfield($field)));
1141     }
1142   }
1143
1144   #my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
1145   my %diff = map { ($new->getfield($_) ne $old->getfield($_))
1146                    ? ($_, $new->getfield($_)) : () } $old->fields;
1147
1148   unless (keys(%diff) || $no_update_diff ) {
1149     carp "[warning]$me $new -> replace $old: records identical"
1150       unless $nowarn_identical;
1151     return '';
1152   }
1153
1154   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
1155     map {
1156       "$_ = ". _quote($new->getfield($_),$old->table,$_)
1157     } real_fields($old->table)
1158   ). ' WHERE '.
1159     join(' AND ',
1160       map {
1161
1162         if ( $old->getfield($_) eq '' ) {
1163
1164          #false laziness w/qsearch
1165          if ( driver_name eq 'Pg' ) {
1166             my $type = $old->dbdef_table->column($_)->type;
1167             if ( $type =~ /(int|(big)?serial)/i ) {
1168               qq-( $_ IS NULL )-;
1169             } else {
1170               qq-( $_ IS NULL OR $_ = '' )-;
1171             }
1172           } else {
1173             qq-( $_ IS NULL OR $_ = "" )-;
1174           }
1175
1176         } else {
1177           "$_ = ". _quote($old->getfield($_),$old->table,$_);
1178         }
1179
1180       } ( $primary_key ? ( $primary_key ) : real_fields($old->table) )
1181     )
1182   ;
1183   warn "[debug]$me $statement\n" if $DEBUG > 1;
1184   my $sth = dbh->prepare($statement) or return dbh->errstr;
1185
1186   my $h_old_sth;
1187   if ( defined dbdef->table('h_'. $old->table) ) {
1188     my $h_old_statement = $old->_h_statement('replace_old');
1189     warn "[debug]$me $h_old_statement\n" if $DEBUG > 2;
1190     $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
1191   } else {
1192     $h_old_sth = '';
1193   }
1194
1195   my $h_new_sth;
1196   if ( defined dbdef->table('h_'. $new->table) ) {
1197     my $h_new_statement = $new->_h_statement('replace_new');
1198     warn "[debug]$me $h_new_statement\n" if $DEBUG > 2;
1199     $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
1200   } else {
1201     $h_new_sth = '';
1202   }
1203
1204   # For virtual fields we have three cases with different SQL
1205   # statements: add, replace, delete
1206   my $v_add_sth;
1207   my $v_rep_sth;
1208   my $v_del_sth;
1209   my (@add_vfields, @rep_vfields, @del_vfields);
1210   my $vfp = $old->vfieldpart_hashref;
1211   foreach(grep { exists($diff{$_}) } $new->virtual_fields) {
1212     if($diff{$_} eq '') {
1213       # Delete
1214       unless(@del_vfields) {
1215         my $st = "DELETE FROM virtual_field WHERE recnum = ? ".
1216                  "AND vfieldpart = ?";
1217         warn "[debug]$me $st\n" if $DEBUG > 2;
1218         $v_del_sth = dbh->prepare($st) or return dbh->errstr;
1219       }
1220       push @del_vfields, $_;
1221     } elsif($old->getfield($_) eq '') {
1222       # Add
1223       unless(@add_vfields) {
1224         my $st = "INSERT INTO virtual_field (value, recnum, vfieldpart) ".
1225                  "VALUES (?, ?, ?)";
1226         warn "[debug]$me $st\n" if $DEBUG > 2;
1227         $v_add_sth = dbh->prepare($st) or return dbh->errstr;
1228       }
1229       push @add_vfields, $_;
1230     } else {
1231       # Replace
1232       unless(@rep_vfields) {
1233         my $st = "UPDATE virtual_field SET value = ? ".
1234                  "WHERE recnum = ? AND vfieldpart = ?";
1235         warn "[debug]$me $st\n" if $DEBUG > 2;
1236         $v_rep_sth = dbh->prepare($st) or return dbh->errstr;
1237       }
1238       push @rep_vfields, $_;
1239     }
1240   }
1241
1242   local $SIG{HUP} = 'IGNORE';
1243   local $SIG{INT} = 'IGNORE';
1244   local $SIG{QUIT} = 'IGNORE';
1245   local $SIG{TERM} = 'IGNORE';
1246   local $SIG{TSTP} = 'IGNORE';
1247   local $SIG{PIPE} = 'IGNORE';
1248
1249   my $rc = $sth->execute or return $sth->errstr;
1250   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
1251   $h_old_sth->execute or return $h_old_sth->errstr if $h_old_sth;
1252   $h_new_sth->execute or return $h_new_sth->errstr if $h_new_sth;
1253
1254   $v_del_sth->execute($old->getfield($primary_key),
1255                       $vfp->{$_})
1256         or return $v_del_sth->errstr
1257       foreach(@del_vfields);
1258
1259   $v_add_sth->execute($new->getfield($_),
1260                       $old->getfield($primary_key),
1261                       $vfp->{$_})
1262         or return $v_add_sth->errstr
1263       foreach(@add_vfields);
1264
1265   $v_rep_sth->execute($new->getfield($_),
1266                       $old->getfield($primary_key),
1267                       $vfp->{$_})
1268         or return $v_rep_sth->errstr
1269       foreach(@rep_vfields);
1270
1271   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1272
1273   # Now that it has been saved, reset the encrypted fields so that $new
1274   # can still be used.
1275   foreach my $field (keys %{$saved}) {
1276     $new->setfield($field, $saved->{$field});
1277   }
1278
1279   '';
1280
1281 }
1282
1283 sub replace_old {
1284   my( $self ) = shift;
1285   warn "[$me] replace called with no arguments; autoloading old record\n"
1286     if $DEBUG;
1287
1288   my $primary_key = $self->dbdef_table->primary_key;
1289   if ( $primary_key ) {
1290     $self->by_key( $self->$primary_key() ) #this is what's returned
1291       or croak "can't find ". $self->table. ".$primary_key ".
1292         $self->$primary_key();
1293   } else {
1294     croak $self->table. " has no primary key; pass old record as argument";
1295   }
1296
1297 }
1298
1299 =item rep
1300
1301 Depriciated (use replace instead).
1302
1303 =cut
1304
1305 sub rep {
1306   cluck "warning: FS::Record::rep deprecated!";
1307   replace @_; #call method in this scope
1308 }
1309
1310 =item check
1311
1312 Checks virtual fields (using check_blocks).  Subclasses should still provide
1313 a check method to validate real fields, foreign keys, etc., and call this
1314 method via $self->SUPER::check.
1315
1316 (FIXME: Should this method try to make sure that it I<is> being called from
1317 a subclass's check method, to keep the current semantics as far as possible?)
1318
1319 =cut
1320
1321 sub check {
1322   #confess "FS::Record::check not implemented; supply one in subclass!";
1323   my $self = shift;
1324
1325   foreach my $field ($self->virtual_fields) {
1326     for ($self->getfield($field)) {
1327       # See notes on check_block in FS::part_virtual_field.
1328       eval $self->pvf($field)->check_block;
1329       if ( $@ ) {
1330         #this is bad, probably want to follow the stack backtrace up and see
1331         #wtf happened
1332         my $err = "Fatal error checking $field for $self";
1333         cluck "$err: $@";
1334         return "$err (see log for backtrace): $@";
1335
1336       }
1337       $self->setfield($field, $_);
1338     }
1339   }
1340   '';
1341 }
1342
1343 =item batch_import PARAM_HASHREF
1344
1345 Class method for batch imports.  Available params:
1346
1347 =over 4
1348
1349 =item job
1350
1351 FS::queue object, will be updated with progress
1352
1353 =back
1354
1355 =cut
1356
1357 use Storable qw(thaw);
1358 use Data::Dumper;
1359 use MIME::Base64;
1360 sub process_batch_import {
1361   my($job, $opt) = ( shift, shift );
1362
1363   my $table = $opt->{table};
1364   my @pass_params = @{ $opt->{params} };
1365   my %formats = %{ $opt->{formats} };
1366
1367   my $param = thaw(decode_base64(shift));
1368   warn Dumper($param) if $DEBUG;
1369
1370   my $files = $param->{'uploaded_files'}
1371     or die "No files provided.\n";
1372
1373   my (%files) = map { /^(\w+):([\.\w]+)$/ ? ($1,$2):() } split /,/, $files;
1374
1375   my $dir = '%%%FREESIDE_CACHE%%%/cache.'. $FS::UID::datasrc. '/';
1376   my $file = $dir. $files{'file'};
1377
1378   my $type;
1379   if ( $file =~ /\.(\w+)$/i ) {
1380     $type = lc($1);
1381   } else {
1382     #or error out???
1383     warn "can't parse file type from filename $file; defaulting to CSV";
1384     $type = 'csv';
1385   }
1386   $type = 'csv'
1387     if $opt->{'default_csv'} && $type ne 'xls';
1388
1389   my $error =
1390     FS::Record::batch_import( {
1391       table     => $table,
1392       formats   => \%formats,
1393       job       => $job,
1394       file      => $file,
1395       type      => $type,
1396       format    => $param->{format},
1397       params    => { map { $_ => $param->{$_} } @pass_params },
1398     } );
1399
1400   unlink $file;
1401
1402   die "$error\n" if $error;
1403 }
1404
1405 sub batch_import {
1406   my $param = shift;
1407
1408   my $table     = $param->{table};
1409   my $formats   = $param->{formats};
1410   my $params    = $param->{params};
1411
1412   my $job       = $param->{job};
1413
1414   my $filename  = $param->{file};
1415   my $type      = $param->{type} || 'csv';
1416
1417   my $format = $param->{'format'};
1418
1419   die "unknown format $format" unless exists $formats->{ $format };
1420   my @fields    = @{ $formats->{ $format } };
1421
1422   my $count;
1423   my $parser;
1424   my @buffer = ();
1425   if ( $type eq 'csv' ) {
1426
1427     $parser = new Text::CSV_XS;
1428
1429     @buffer = split(/\r?\n/, slurp($filename) );
1430     $count = scalar(@buffer);
1431
1432   } elsif ( $type eq 'xls' ) {
1433
1434     eval "use Spreadsheet::ParseExcel;";
1435     die $@ if $@;
1436
1437     my $excel = Spreadsheet::ParseExcel::Workbook->new->Parse($filename);
1438
1439     $parser = $excel->{Worksheet}[0]; #first sheet
1440
1441     $count = $parser->{MaxRow} || $parser->{MinRow};
1442     $count++;
1443
1444   } else {
1445     die "Unknown file type $type\n";
1446   }
1447
1448   #my $columns;
1449
1450   local $SIG{HUP} = 'IGNORE';
1451   local $SIG{INT} = 'IGNORE';
1452   local $SIG{QUIT} = 'IGNORE';
1453   local $SIG{TERM} = 'IGNORE';
1454   local $SIG{TSTP} = 'IGNORE';
1455   local $SIG{PIPE} = 'IGNORE';
1456
1457   my $oldAutoCommit = $FS::UID::AutoCommit;
1458   local $FS::UID::AutoCommit = 0;
1459   my $dbh = dbh;
1460
1461   my $line;
1462   my $row = 0;
1463   my( $last, $min_sec ) = ( time, 5 ); #progressbar foo
1464   while (1) {
1465
1466     my @columns = ();
1467     if ( $type eq 'csv' ) {
1468
1469       last unless scalar(@buffer);
1470       $line = shift(@buffer);
1471
1472       $parser->parse($line) or do {
1473         $dbh->rollback if $oldAutoCommit;
1474         return "can't parse: ". $parser->error_input();
1475       };
1476       @columns = $parser->fields();
1477
1478     } elsif ( $type eq 'xls' ) {
1479
1480       last if $row > ($parser->{MaxRow} || $parser->{MinRow})
1481            || ! $parser->{Cells}[$row];
1482
1483       my @row = @{ $parser->{Cells}[$row] };
1484       @columns = map $_->{Val}, @row;
1485
1486       #my $z = 'A';
1487       #warn $z++. ": $_\n" for @columns;
1488
1489     } else {
1490       die "Unknown file type $type\n";
1491     }
1492
1493     my %hash = %$params;
1494
1495     foreach my $field ( @fields ) {
1496
1497       my $value = shift @columns;
1498
1499       if ( ref($field) eq 'CODE' ) {
1500         &{$field}(\%hash, $value);
1501       } else {
1502         $hash{$field} = $value if length($value);
1503       }
1504
1505     }
1506
1507     my $class = "FS::$table";
1508
1509     my $record = $class->new( \%hash );
1510
1511     my $error = $record->insert;
1512
1513     if ( $error ) {
1514       $dbh->rollback if $oldAutoCommit;
1515       return "can't insert record". ( $line ? " for $line" : '' ). ": $error";
1516     }
1517
1518     $row++;
1519
1520     if ( $job && time - $min_sec > $last ) { #progress bar
1521       $job->update_statustext( int(100 * $row / $count) );
1522       $last = time;
1523     }
1524
1525   }
1526
1527   $dbh->commit or die $dbh->errstr if $oldAutoCommit;;
1528
1529   return "Empty file!" unless $row;
1530
1531   ''; #no error
1532
1533 }
1534
1535 sub _h_statement {
1536   my( $self, $action, $time ) = @_;
1537
1538   $time ||= time;
1539
1540   my @fields =
1541     grep { defined($self->getfield($_)) && $self->getfield($_) ne "" }
1542     real_fields($self->table);
1543   ;
1544
1545   # If we're encrypting then don't ever store the payinfo or CVV2 in the history....
1546   # You can see if it changed by the paymask...
1547   if ($conf && $conf->exists('encryption') ) {
1548     @fields = grep  $_ ne 'payinfo' && $_ ne 'cvv2', @fields;
1549   }
1550   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
1551
1552   "INSERT INTO h_". $self->table. " ( ".
1553       join(', ', qw(history_date history_user history_action), @fields ).
1554     ") VALUES (".
1555       join(', ', $time, dbh->quote(getotaker()), dbh->quote($action), @values).
1556     ")"
1557   ;
1558 }
1559
1560 =item unique COLUMN
1561
1562 B<Warning>: External use is B<deprecated>.
1563
1564 Replaces COLUMN in record with a unique number, using counters in the
1565 filesystem.  Used by the B<insert> method on single-field unique columns
1566 (see L<DBIx::DBSchema::Table>) and also as a fallback for primary keys
1567 that aren't SERIAL (Pg) or AUTO_INCREMENT (mysql).
1568
1569 Returns the new value.
1570
1571 =cut
1572
1573 sub unique {
1574   my($self,$field) = @_;
1575   my($table)=$self->table;
1576
1577   croak "Unique called on field $field, but it is ",
1578         $self->getfield($field),
1579         ", not null!"
1580     if $self->getfield($field);
1581
1582   #warn "table $table is tainted" if is_tainted($table);
1583   #warn "field $field is tainted" if is_tainted($field);
1584
1585   my($counter) = new File::CounterFile "$table.$field",0;
1586 # hack for web demo
1587 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
1588 #  my($user)=$1;
1589 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
1590 # endhack
1591
1592   my $index = $counter->inc;
1593   $index = $counter->inc while qsearchs($table, { $field=>$index } );
1594
1595   $index =~ /^(\d*)$/;
1596   $index=$1;
1597
1598   $self->setfield($field,$index);
1599
1600 }
1601
1602 =item ut_float COLUMN
1603
1604 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
1605 null.  If there is an error, returns the error, otherwise returns false.
1606
1607 =cut
1608
1609 sub ut_float {
1610   my($self,$field)=@_ ;
1611   ($self->getfield($field) =~ /^\s*(\d+\.\d+)\s*$/ ||
1612    $self->getfield($field) =~ /^\s*(\d+)\s*$/ ||
1613    $self->getfield($field) =~ /^\s*(\d+\.\d+e\d+)\s*$/ ||
1614    $self->getfield($field) =~ /^\s*(\d+e\d+)\s*$/)
1615     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1616   $self->setfield($field,$1);
1617   '';
1618 }
1619 =item ut_floatn COLUMN
1620
1621 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May be
1622 null.  If there is an error, returns the error, otherwise returns false.
1623
1624 =cut
1625
1626 #false laziness w/ut_ipn
1627 sub ut_floatn {
1628   my( $self, $field ) = @_;
1629   if ( $self->getfield($field) =~ /^()$/ ) {
1630     $self->setfield($field,'');
1631     '';
1632   } else {
1633     $self->ut_float($field);
1634   }
1635 }
1636
1637 =item ut_sfloat COLUMN
1638
1639 Check/untaint signed floating point numeric data: 1.1, 1, 1.1e10, 1e10.
1640 May not be null.  If there is an error, returns the error, otherwise returns
1641 false.
1642
1643 =cut
1644
1645 sub ut_sfloat {
1646   my($self,$field)=@_ ;
1647   ($self->getfield($field) =~ /^\s*(-?\d+\.\d+)\s*$/ ||
1648    $self->getfield($field) =~ /^\s*(-?\d+)\s*$/ ||
1649    $self->getfield($field) =~ /^\s*(-?\d+\.\d+[eE]-?\d+)\s*$/ ||
1650    $self->getfield($field) =~ /^\s*(-?\d+[eE]-?\d+)\s*$/)
1651     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1652   $self->setfield($field,$1);
1653   '';
1654 }
1655 =item ut_sfloatn COLUMN
1656
1657 Check/untaint signed floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May be
1658 null.  If there is an error, returns the error, otherwise returns false.
1659
1660 =cut
1661
1662 sub ut_sfloatn {
1663   my( $self, $field ) = @_;
1664   if ( $self->getfield($field) =~ /^()$/ ) {
1665     $self->setfield($field,'');
1666     '';
1667   } else {
1668     $self->ut_sfloat($field);
1669   }
1670 }
1671
1672 =item ut_snumber COLUMN
1673
1674 Check/untaint signed numeric data (whole numbers).  If there is an error,
1675 returns the error, otherwise returns false.
1676
1677 =cut
1678
1679 sub ut_snumber {
1680   my($self, $field) = @_;
1681   $self->getfield($field) =~ /^\s*(-?)\s*(\d+)\s*$/
1682     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1683   $self->setfield($field, "$1$2");
1684   '';
1685 }
1686
1687 =item ut_snumbern COLUMN
1688
1689 Check/untaint signed numeric data (whole numbers).  If there is an error,
1690 returns the error, otherwise returns false.
1691
1692 =cut
1693
1694 sub ut_snumbern {
1695   my($self, $field) = @_;
1696   $self->getfield($field) =~ /^\s*(-?)\s*(\d*)\s*$/
1697     or return "Illegal (numeric) $field: ". $self->getfield($field);
1698   if ($1) {
1699     return "Illegal (numeric) $field: ". $self->getfield($field)
1700       unless $2;
1701   }
1702   $self->setfield($field, "$1$2");
1703   '';
1704 }
1705
1706 =item ut_number COLUMN
1707
1708 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
1709 is an error, returns the error, otherwise returns false.
1710
1711 =cut
1712
1713 sub ut_number {
1714   my($self,$field)=@_;
1715   $self->getfield($field) =~ /^\s*(\d+)\s*$/
1716     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1717   $self->setfield($field,$1);
1718   '';
1719 }
1720
1721 =item ut_numbern COLUMN
1722
1723 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
1724 an error, returns the error, otherwise returns false.
1725
1726 =cut
1727
1728 sub ut_numbern {
1729   my($self,$field)=@_;
1730   $self->getfield($field) =~ /^\s*(\d*)\s*$/
1731     or return "Illegal (numeric) $field: ". $self->getfield($field);
1732   $self->setfield($field,$1);
1733   '';
1734 }
1735
1736 =item ut_money COLUMN
1737
1738 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
1739 is an error, returns the error, otherwise returns false.
1740
1741 =cut
1742
1743 sub ut_money {
1744   my($self,$field)=@_;
1745   $self->setfield($field, 0) if $self->getfield($field) eq '';
1746   $self->getfield($field) =~ /^\s*(\-)?\s*(\d*)(\.\d{2})?\s*$/
1747     or return "Illegal (money) $field: ". $self->getfield($field);
1748   #$self->setfield($field, "$1$2$3" || 0);
1749   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
1750   '';
1751 }
1752
1753 =item ut_text COLUMN
1754
1755 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1756 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / = [ ]
1757 May not be null.  If there is an error, returns the error, otherwise returns
1758 false.
1759
1760 =cut
1761
1762 sub ut_text {
1763   my($self,$field)=@_;
1764   #warn "msgcat ". \&msgcat. "\n";
1765   #warn "notexist ". \&notexist. "\n";
1766   #warn "AUTOLOAD ". \&AUTOLOAD. "\n";
1767   $self->getfield($field)
1768     =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=\[\]]+)$/
1769       or return gettext('illegal_or_empty_text'). " $field: ".
1770                  $self->getfield($field);
1771   $self->setfield($field,$1);
1772   '';
1773 }
1774
1775 =item ut_textn COLUMN
1776
1777 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1778 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
1779 May be null.  If there is an error, returns the error, otherwise returns false.
1780
1781 =cut
1782
1783 sub ut_textn {
1784   my($self,$field)=@_;
1785   $self->getfield($field)
1786     =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=\[\]]*)$/
1787       or return gettext('illegal_text'). " $field: ". $self->getfield($field);
1788   $self->setfield($field,$1);
1789   '';
1790 }
1791
1792 =item ut_alpha COLUMN
1793
1794 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
1795 an error, returns the error, otherwise returns false.
1796
1797 =cut
1798
1799 sub ut_alpha {
1800   my($self,$field)=@_;
1801   $self->getfield($field) =~ /^(\w+)$/
1802     or return "Illegal or empty (alphanumeric) $field: ".
1803               $self->getfield($field);
1804   $self->setfield($field,$1);
1805   '';
1806 }
1807
1808 =item ut_alpha COLUMN
1809
1810 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
1811 error, returns the error, otherwise returns false.
1812
1813 =cut
1814
1815 sub ut_alphan {
1816   my($self,$field)=@_;
1817   $self->getfield($field) =~ /^(\w*)$/
1818     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
1819   $self->setfield($field,$1);
1820   '';
1821 }
1822
1823 =item ut_alpha_lower COLUMN
1824
1825 Check/untaint lowercase alphanumeric strings (no spaces).  May not be null.  If
1826 there is an error, returns the error, otherwise returns false.
1827
1828 =cut
1829
1830 sub ut_alpha_lower {
1831   my($self,$field)=@_;
1832   $self->getfield($field) =~ /[[:upper:]]/
1833     and return "Uppercase characters are not permitted in $field";
1834   $self->ut_alpha($field);
1835 }
1836
1837 =item ut_phonen COLUMN [ COUNTRY ]
1838
1839 Check/untaint phone numbers.  May be null.  If there is an error, returns
1840 the error, otherwise returns false.
1841
1842 Takes an optional two-letter ISO country code; without it or with unsupported
1843 countries, ut_phonen simply calls ut_alphan.
1844
1845 =cut
1846
1847 sub ut_phonen {
1848   my( $self, $field, $country ) = @_;
1849   return $self->ut_alphan($field) unless defined $country;
1850   my $phonen = $self->getfield($field);
1851   if ( $phonen eq '' ) {
1852     $self->setfield($field,'');
1853   } elsif ( $country eq 'US' || $country eq 'CA' ) {
1854     $phonen =~ s/\D//g;
1855     $phonen = $conf->config('cust_main-default_areacode').$phonen
1856       if length($phonen)==7 && $conf->config('cust_main-default_areacode');
1857     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
1858       or return gettext('illegal_phone'). " $field: ". $self->getfield($field);
1859     $phonen = "$1-$2-$3";
1860     $phonen .= " x$4" if $4;
1861     $self->setfield($field,$phonen);
1862   } else {
1863     warn "warning: don't know how to check phone numbers for country $country";
1864     return $self->ut_textn($field);
1865   }
1866   '';
1867 }
1868
1869 =item ut_hex COLUMN
1870
1871 Check/untaint hexadecimal values.
1872
1873 =cut
1874
1875 sub ut_hex {
1876   my($self, $field) = @_;
1877   $self->getfield($field) =~ /^([\da-fA-F]+)$/
1878     or return "Illegal (hex) $field: ". $self->getfield($field);
1879   $self->setfield($field, uc($1));
1880   '';
1881 }
1882
1883 =item ut_hexn COLUMN
1884
1885 Check/untaint hexadecimal values.  May be null.
1886
1887 =cut
1888
1889 sub ut_hexn {
1890   my($self, $field) = @_;
1891   $self->getfield($field) =~ /^([\da-fA-F]*)$/
1892     or return "Illegal (hex) $field: ". $self->getfield($field);
1893   $self->setfield($field, uc($1));
1894   '';
1895 }
1896 =item ut_ip COLUMN
1897
1898 Check/untaint ip addresses.  IPv4 only for now.
1899
1900 =cut
1901
1902 sub ut_ip {
1903   my( $self, $field ) = @_;
1904   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
1905     or return "Illegal (IP address) $field: ". $self->getfield($field);
1906   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
1907   $self->setfield($field, "$1.$2.$3.$4");
1908   '';
1909 }
1910
1911 =item ut_ipn COLUMN
1912
1913 Check/untaint ip addresses.  IPv4 only for now.  May be null.
1914
1915 =cut
1916
1917 sub ut_ipn {
1918   my( $self, $field ) = @_;
1919   if ( $self->getfield($field) =~ /^()$/ ) {
1920     $self->setfield($field,'');
1921     '';
1922   } else {
1923     $self->ut_ip($field);
1924   }
1925 }
1926
1927 =item ut_coord COLUMN [ LOWER [ UPPER ] ]
1928
1929 Check/untaint coordinates.
1930 Accepts the following forms:
1931 DDD.DDDDD
1932 -DDD.DDDDD
1933 DDD MM.MMM
1934 -DDD MM.MMM
1935 DDD MM SS
1936 -DDD MM SS
1937 DDD MM MMM
1938 -DDD MM MMM
1939
1940 The "DDD MM SS" and "DDD MM MMM" are potentially ambiguous.
1941 The latter form (that is, the MMM are thousands of minutes) is
1942 assumed if the "MMM" is exactly three digits or two digits > 59.
1943
1944 To be safe, just use the DDD.DDDDD form.
1945
1946 If LOWER or UPPER are specified, then the coordinate is checked
1947 for lower and upper bounds, respectively.
1948
1949 =cut
1950
1951 sub ut_coord {
1952
1953   my ($self, $field) = (shift, shift);
1954
1955   my $lower = shift if scalar(@_);
1956   my $upper = shift if scalar(@_);
1957   my $coord = $self->getfield($field);
1958   my $neg = $coord =~ s/^(-)//;
1959
1960   my ($d, $m, $s) = (0, 0, 0);
1961
1962   if (
1963     (($d) = ($coord =~ /^(\s*\d{1,3}(?:\.\d+)?)\s*$/)) ||
1964     (($d, $m) = ($coord =~ /^(\s*\d{1,3})\s+(\d{1,2}(?:\.\d+))\s*$/)) ||
1965     (($d, $m, $s) = ($coord =~ /^(\s*\d{1,3})\s+(\d{1,2})\s+(\d{1,3})\s*$/))
1966   ) {
1967     $s = (((($s =~ /^\d{3}$/) or $s > 59) ? ($s / 1000) : ($s / 60)) / 60);
1968     $m = $m / 60;
1969     if ($m > 59) {
1970       return "Invalid (coordinate with minutes > 59) $field: "
1971              . $self->getfield($field);
1972     }
1973
1974     $coord = ($neg ? -1 : 1) * sprintf('%.8f', $d + $m + $s);
1975
1976     if (defined($lower) and ($coord < $lower)) {
1977       return "Invalid (coordinate < $lower) $field: "
1978              . $self->getfield($field);;
1979     }
1980
1981     if (defined($upper) and ($coord > $upper)) {
1982       return "Invalid (coordinate > $upper) $field: "
1983              . $self->getfield($field);;
1984     }
1985
1986     $self->setfield($field, $coord);
1987     return '';
1988   }
1989
1990   return "Invalid (coordinate) $field: " . $self->getfield($field);
1991
1992 }
1993
1994 =item ut_coordn COLUMN [ LOWER [ UPPER ] ]
1995
1996 Same as ut_coord, except optionally null.
1997
1998 =cut
1999
2000 sub ut_coordn {
2001
2002   my ($self, $field) = (shift, shift);
2003
2004   if ($self->getfield($field) =~ /^$/) {
2005     return '';
2006   } else {
2007     return $self->ut_coord($field, @_);
2008   }
2009
2010 }
2011
2012
2013 =item ut_domain COLUMN
2014
2015 Check/untaint host and domain names.
2016
2017 =cut
2018
2019 sub ut_domain {
2020   my( $self, $field ) = @_;
2021   #$self->getfield($field) =~/^(\w+\.)*\w+$/
2022   $self->getfield($field) =~/^(([\w\-]+\.)*\w+)$/
2023     or return "Illegal (domain) $field: ". $self->getfield($field);
2024   $self->setfield($field,$1);
2025   '';
2026 }
2027
2028 =item ut_name COLUMN
2029
2030 Check/untaint proper names; allows alphanumerics, spaces and the following
2031 punctuation: , . - '
2032
2033 May not be null.
2034
2035 =cut
2036
2037 sub ut_name {
2038   my( $self, $field ) = @_;
2039   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
2040     or return gettext('illegal_name'). " $field: ". $self->getfield($field);
2041   $self->setfield($field,$1);
2042   '';
2043 }
2044
2045 =item ut_zip COLUMN
2046
2047 Check/untaint zip codes.
2048
2049 =cut
2050
2051 my @zip_reqd_countries = qw( AU CA US ); #CA, US implicit...
2052
2053 sub ut_zip {
2054   my( $self, $field, $country ) = @_;
2055
2056   if ( $country eq 'US' ) {
2057
2058     $self->getfield($field) =~ /^\s*(\d{5}(\-\d{4})?)\s*$/
2059       or return gettext('illegal_zip'). " $field for country $country: ".
2060                 $self->getfield($field);
2061     $self->setfield($field, $1);
2062
2063   } elsif ( $country eq 'CA' ) {
2064
2065     $self->getfield($field) =~ /^\s*([A-Z]\d[A-Z])\s*(\d[A-Z]\d)\s*$/i
2066       or return gettext('illegal_zip'). " $field for country $country: ".
2067                 $self->getfield($field);
2068     $self->setfield($field, "$1 $2");
2069
2070   } else {
2071
2072     if ( $self->getfield($field) =~ /^\s*$/
2073          && ( !$country || ! grep { $_ eq $country } @zip_reqd_countries )
2074        )
2075     {
2076       $self->setfield($field,'');
2077     } else {
2078       $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
2079         or return gettext('illegal_zip'). " $field: ". $self->getfield($field);
2080       $self->setfield($field,$1);
2081     }
2082
2083   }
2084
2085   '';
2086 }
2087
2088 =item ut_country COLUMN
2089
2090 Check/untaint country codes.  Country names are changed to codes, if possible -
2091 see L<Locale::Country>.
2092
2093 =cut
2094
2095 sub ut_country {
2096   my( $self, $field ) = @_;
2097   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
2098     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
2099          && country2code($1) ) {
2100       $self->setfield($field,uc(country2code($1)));
2101     }
2102   }
2103   $self->getfield($field) =~ /^(\w\w)$/
2104     or return "Illegal (country) $field: ". $self->getfield($field);
2105   $self->setfield($field,uc($1));
2106   '';
2107 }
2108
2109 =item ut_anything COLUMN
2110
2111 Untaints arbitrary data.  Be careful.
2112
2113 =cut
2114
2115 sub ut_anything {
2116   my( $self, $field ) = @_;
2117   $self->getfield($field) =~ /^(.*)$/s
2118     or return "Illegal $field: ". $self->getfield($field);
2119   $self->setfield($field,$1);
2120   '';
2121 }
2122
2123 =item ut_enum COLUMN CHOICES_ARRAYREF
2124
2125 Check/untaint a column, supplying all possible choices, like the "enum" type.
2126
2127 =cut
2128
2129 sub ut_enum {
2130   my( $self, $field, $choices ) = @_;
2131   foreach my $choice ( @$choices ) {
2132     if ( $self->getfield($field) eq $choice ) {
2133       $self->setfield($choice);
2134       return '';
2135     }
2136   }
2137   return "Illegal (enum) field $field: ". $self->getfield($field);
2138 }
2139
2140 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
2141
2142 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
2143 on the column first.
2144
2145 =cut
2146
2147 sub ut_foreign_key {
2148   my( $self, $field, $table, $foreign ) = @_;
2149   return '' if $no_check_foreign;
2150   qsearchs($table, { $foreign => $self->getfield($field) })
2151     or return "Can't find ". $self->table. ".$field ". $self->getfield($field).
2152               " in $table.$foreign";
2153   '';
2154 }
2155
2156 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
2157
2158 Like ut_foreign_key, except the null value is also allowed.
2159
2160 =cut
2161
2162 sub ut_foreign_keyn {
2163   my( $self, $field, $table, $foreign ) = @_;
2164   $self->getfield($field)
2165     ? $self->ut_foreign_key($field, $table, $foreign)
2166     : '';
2167 }
2168
2169 =item ut_agentnum_acl
2170
2171 Checks this column as an agentnum, taking into account the current users's
2172 ACLs.
2173
2174 =cut
2175
2176 sub ut_agentnum_acl {
2177   my( $self, $field, $null_acl ) = @_;
2178
2179   my $error = $self->ut_foreign_keyn($field, 'agent', 'agentnum');
2180   return "Illegal agentnum: $error" if $error;
2181
2182   my $curuser = $FS::CurrentUser::CurrentUser;
2183
2184   if ( $self->$field() ) {
2185
2186     return "Access denied"
2187       unless $curuser->agentnum($self->$field());
2188
2189   } else {
2190
2191     return "Access denied"
2192       unless $curuser->access_right($null_acl);
2193
2194   }
2195
2196   '';
2197
2198 }
2199
2200 =item virtual_fields [ TABLE ]
2201
2202 Returns a list of virtual fields defined for the table.  This should not
2203 be exported, and should only be called as an instance or class method.
2204
2205 =cut
2206
2207 sub virtual_fields {
2208   my $self = shift;
2209   my $table;
2210   $table = $self->table or confess "virtual_fields called on non-table";
2211
2212   confess "Unknown table $table" unless dbdef->table($table);
2213
2214   return () unless dbdef->table('part_virtual_field');
2215
2216   unless ( $virtual_fields_cache{$table} ) {
2217     my $query = 'SELECT name from part_virtual_field ' .
2218                 "WHERE dbtable = '$table'";
2219     my $dbh = dbh;
2220     my $result = $dbh->selectcol_arrayref($query);
2221     confess "Error executing virtual fields query: $query: ". $dbh->errstr
2222       if $dbh->err;
2223     $virtual_fields_cache{$table} = $result;
2224   }
2225
2226   @{$virtual_fields_cache{$table}};
2227
2228 }
2229
2230
2231 =item fields [ TABLE ]
2232
2233 This is a wrapper for real_fields and virtual_fields.  Code that called
2234 fields before should probably continue to call fields.
2235
2236 =cut
2237
2238 sub fields {
2239   my $something = shift;
2240   my $table;
2241   if($something->isa('FS::Record')) {
2242     $table = $something->table;
2243   } else {
2244     $table = $something;
2245     $something = "FS::$table";
2246   }
2247   return (real_fields($table), $something->virtual_fields());
2248 }
2249
2250 =item pvf FIELD_NAME
2251
2252 Returns the FS::part_virtual_field object corresponding to a field in the
2253 record (specified by FIELD_NAME).
2254
2255 =cut
2256
2257 sub pvf {
2258   my ($self, $name) = (shift, shift);
2259
2260   if(grep /^$name$/, $self->virtual_fields) {
2261     return qsearchs('part_virtual_field', { dbtable => $self->table,
2262                                             name    => $name } );
2263   }
2264   ''
2265 }
2266
2267 =item vfieldpart_hashref TABLE
2268
2269 Returns a hashref of virtual field names and vfieldparts applicable to the given
2270 TABLE.
2271
2272 =cut
2273
2274 sub vfieldpart_hashref {
2275   my $self = shift;
2276   my $table = $self->table;
2277
2278   return {} unless dbdef->table('part_virtual_field');
2279
2280   my $dbh = dbh;
2281   my $statement = "SELECT vfieldpart, name FROM part_virtual_field WHERE ".
2282                   "dbtable = '$table'";
2283   my $sth = $dbh->prepare($statement);
2284   $sth->execute or croak "Execution of '$statement' failed: ".$dbh->errstr;
2285   return { map { $_->{name}, $_->{vfieldpart} }
2286     @{$sth->fetchall_arrayref({})} };
2287
2288 }
2289
2290 =item encrypt($value)
2291
2292 Encrypts the credit card using a combination of PK to encrypt and uuencode to armour.
2293
2294 Returns the encrypted string.
2295
2296 You should generally not have to worry about calling this, as the system handles this for you.
2297
2298 =cut
2299
2300 sub encrypt {
2301   my ($self, $value) = @_;
2302   my $encrypted;
2303
2304   if ($conf->exists('encryption')) {
2305     if ($self->is_encrypted($value)) {
2306       # Return the original value if it isn't plaintext.
2307       $encrypted = $value;
2308     } else {
2309       $self->loadRSA;
2310       if (ref($rsa_encrypt) =~ /::RSA/) { # We Can Encrypt
2311         # RSA doesn't like the empty string so let's pack it up
2312         # The database doesn't like the RSA data so uuencode it
2313         my $length = length($value)+1;
2314         $encrypted = pack("u*",$rsa_encrypt->encrypt(pack("Z$length",$value)));
2315       } else {
2316         die ("You can't encrypt w/o a valid RSA engine - Check your installation or disable encryption");
2317       }
2318     }
2319   }
2320   return $encrypted;
2321 }
2322
2323 =item is_encrypted($value)
2324
2325 Checks to see if the string is encrypted and returns true or false (1/0) to indicate it's status.
2326
2327 =cut
2328
2329
2330 sub is_encrypted {
2331   my ($self, $value) = @_;
2332   # Possible Bug - Some work may be required here....
2333
2334   if ($value =~ /^M/ && length($value) > 80) {
2335     return 1;
2336   } else {
2337     return 0;
2338   }
2339 }
2340
2341 =item decrypt($value)
2342
2343 Uses the private key to decrypt the string. Returns the decryoted string or undef on failure.
2344
2345 You should generally not have to worry about calling this, as the system handles this for you.
2346
2347 =cut
2348
2349 sub decrypt {
2350   my ($self,$value) = @_;
2351   my $decrypted = $value; # Will return the original value if it isn't encrypted or can't be decrypted.
2352   if ($conf->exists('encryption') && $self->is_encrypted($value)) {
2353     $self->loadRSA;
2354     if (ref($rsa_decrypt) =~ /::RSA/) {
2355       my $encrypted = unpack ("u*", $value);
2356       $decrypted =  unpack("Z*", eval{$rsa_decrypt->decrypt($encrypted)});
2357       if ($@) {warn "Decryption Failed"};
2358     }
2359   }
2360   return $decrypted;
2361 }
2362
2363 sub loadRSA {
2364     my $self = shift;
2365     #Initialize the Module
2366     $rsa_module = 'Crypt::OpenSSL::RSA'; # The Default
2367
2368     if ($conf->exists('encryptionmodule') && $conf->config_binary('encryptionmodule') ne '') {
2369       $rsa_module = $conf->config('encryptionmodule');
2370     }
2371
2372     if (!$rsa_loaded) {
2373         eval ("require $rsa_module"); # No need to import the namespace
2374         $rsa_loaded++;
2375     }
2376     # Initialize Encryption
2377     if ($conf->exists('encryptionpublickey') && $conf->config_binary('encryptionpublickey') ne '') {
2378       my $public_key = join("\n",$conf->config('encryptionpublickey'));
2379       $rsa_encrypt = $rsa_module->new_public_key($public_key);
2380     }
2381
2382     # Intitalize Decryption
2383     if ($conf->exists('encryptionprivatekey') && $conf->config_binary('encryptionprivatekey') ne '') {
2384       my $private_key = join("\n",$conf->config('encryptionprivatekey'));
2385       $rsa_decrypt = $rsa_module->new_private_key($private_key);
2386     }
2387 }
2388
2389 =item h_search ACTION
2390
2391 Given an ACTION, either "insert", or "delete", returns the appropriate history
2392 record corresponding to this record, if any.
2393
2394 =cut
2395
2396 sub h_search {
2397   my( $self, $action ) = @_;
2398
2399   my $table = $self->table;
2400   $table =~ s/^h_//;
2401
2402   my $primary_key = dbdef->table($table)->primary_key;
2403
2404   qsearchs({
2405     'table'   => "h_$table",
2406     'hashref' => { $primary_key     => $self->$primary_key(),
2407                    'history_action' => $action,
2408                  },
2409   });
2410
2411 }
2412
2413 =item h_date ACTION
2414
2415 Given an ACTION, either "insert", or "delete", returns the timestamp of the
2416 appropriate history record corresponding to this record, if any.
2417
2418 =cut
2419
2420 sub h_date {
2421   my($self, $action) = @_;
2422   my $h = $self->h_search($action);
2423   $h ? $h->history_date : '';
2424 }
2425
2426 =back
2427
2428 =head1 SUBROUTINES
2429
2430 =over 4
2431
2432 =item real_fields [ TABLE ]
2433
2434 Returns a list of the real columns in the specified table.  Called only by
2435 fields() and other subroutines elsewhere in FS::Record.
2436
2437 =cut
2438
2439 sub real_fields {
2440   my $table = shift;
2441
2442   my($table_obj) = dbdef->table($table);
2443   confess "Unknown table $table" unless $table_obj;
2444   $table_obj->columns;
2445 }
2446
2447 =item _quote VALUE, TABLE, COLUMN
2448
2449 This is an internal function used to construct SQL statements.  It returns
2450 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
2451 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
2452
2453 =cut
2454
2455 sub _quote {
2456   my($value, $table, $column) = @_;
2457   my $column_obj = dbdef->table($table)->column($column);
2458   my $column_type = $column_obj->type;
2459   my $nullable = $column_obj->null;
2460
2461   warn "  $table.$column: $value ($column_type".
2462        ( $nullable ? ' NULL' : ' NOT NULL' ).
2463        ")\n" if $DEBUG > 2;
2464
2465   if ( $value eq '' && $nullable ) {
2466     'NULL'
2467   } elsif ( $value eq '' && $column_type =~ /^(int|numeric)/ ) {
2468     cluck "WARNING: Attempting to set non-null integer $table.$column null; ".
2469           "using 0 instead";
2470     0;
2471   } elsif ( $value =~ /^\d+(\.\d+)?$/ &&
2472             ! $column_type =~ /(char|binary|text)$/i ) {
2473     $value;
2474   } else {
2475     dbh->quote($value);
2476   }
2477 }
2478
2479 =item hfields TABLE
2480
2481 This is deprecated.  Don't use it.
2482
2483 It returns a hash-type list with the fields of this record's table set true.
2484
2485 =cut
2486
2487 sub hfields {
2488   carp "warning: hfields is deprecated";
2489   my($table)=@_;
2490   my(%hash);
2491   foreach (fields($table)) {
2492     $hash{$_}=1;
2493   }
2494   \%hash;
2495 }
2496
2497 sub _dump {
2498   my($self)=@_;
2499   join("\n", map {
2500     "$_: ". $self->getfield($_). "|"
2501   } (fields($self->table)) );
2502 }
2503
2504 sub DESTROY { return; }
2505
2506 #sub DESTROY {
2507 #  my $self = shift;
2508 #  #use Carp qw(cluck);
2509 #  #cluck "DESTROYING $self";
2510 #  warn "DESTROYING $self";
2511 #}
2512
2513 #sub is_tainted {
2514 #             return ! eval { join('',@_), kill 0; 1; };
2515 #         }
2516
2517 =item str2time_sql [ DRIVER_NAME ]
2518
2519 Returns a function to convert to unix time based on database type, such as
2520 "EXTRACT( EPOCH FROM" for Pg or "UNIX_TIMESTAMP(" for mysql.  See
2521 the str2time_sql_closing method to return a closing string rather than just
2522 using a closing parenthesis as previously suggested.
2523
2524 You can pass an optional driver name such as "Pg", "mysql" or
2525 $dbh->{Driver}->{Name} to return a function for that database instead of
2526 the current database.
2527
2528 =cut
2529
2530 sub str2time_sql {
2531   my $driver = shift || driver_name;
2532
2533   return 'UNIX_TIMESTAMP('      if $driver =~ /^mysql/i;
2534   return 'EXTRACT( EPOCH FROM ' if $driver =~ /^Pg/i;
2535
2536   warn "warning: unknown database type $driver; guessing how to convert ".
2537        "dates to UNIX timestamps";
2538   return 'EXTRACT(EPOCH FROM ';
2539
2540 }
2541
2542 =item str2time_sql_closing [ DRIVER_NAME ]
2543
2544 Returns the closing suffix of a function to convert to unix time based on
2545 database type, such as ")::integer" for Pg or ")" for mysql.
2546
2547 You can pass an optional driver name such as "Pg", "mysql" or
2548 $dbh->{Driver}->{Name} to return a function for that database instead of
2549 the current database.
2550
2551 =cut
2552
2553 sub str2time_sql_closing {
2554   my $driver = shift || driver_name;
2555
2556   return ' )::INTEGER ' if $driver =~ /^Pg/i;
2557   return ' ) ';
2558 }
2559
2560 =back
2561
2562 =head1 BUGS
2563
2564 This module should probably be renamed, since much of the functionality is
2565 of general use.  It is not completely unlike Adapter::DBI (see below).
2566
2567 Exported qsearch and qsearchs should be deprecated in favor of method calls
2568 (against an FS::Record object like the old search and searchs that qsearch
2569 and qsearchs were on top of.)
2570
2571 The whole fields / hfields mess should be removed.
2572
2573 The various WHERE clauses should be subroutined.
2574
2575 table string should be deprecated in favor of DBIx::DBSchema::Table.
2576
2577 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
2578 true maps to the database (and WHERE clauses) would also help.
2579
2580 The ut_ methods should ask the dbdef for a default length.
2581
2582 ut_sqltype (like ut_varchar) should all be defined
2583
2584 A fallback check method should be provided which uses the dbdef.
2585
2586 The ut_money method assumes money has two decimal digits.
2587
2588 The Pg money kludge in the new method only strips `$'.
2589
2590 The ut_phonen method only checks US-style phone numbers.
2591
2592 The _quote function should probably use ut_float instead of a regex.
2593
2594 All the subroutines probably should be methods, here or elsewhere.
2595
2596 Probably should borrow/use some dbdef methods where appropriate (like sub
2597 fields)
2598
2599 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
2600 or allow it to be set.  Working around it is ugly any way around - DBI should
2601 be fixed.  (only affects RDBMS which return uppercase column names)
2602
2603 ut_zip should take an optional country like ut_phone.
2604
2605 =head1 SEE ALSO
2606
2607 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
2608
2609 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
2610
2611 http://poop.sf.net/
2612
2613 =cut
2614
2615 1;
2616