FS/FS/ClientAPI/Signup.pm

   1 package FS::ClientAPI::Signup;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use Data::Dumper;
   6 use Tie::RefHash;
   7 use Digest::SHA qw(sha512_hex);
   8 use FS::Conf;
   9 use FS::Record qw(qsearch qsearchs dbdef);
  10 use FS::CGI qw(popurl);
  11 use FS::Msgcat qw(gettext);
  12 use FS::Misc qw(card_types);
  13 use FS::ClientAPI_SessionCache;
  14 use FS::agent;
  15 use FS::cust_main_county;
  16 use FS::part_pkg;
  17 use FS::svc_acct_pop;
  18 use FS::cust_main;
  19 use FS::cust_pkg;
  20 use FS::svc_acct;
  21 use FS::svc_phone;
  22 use FS::acct_snarf;
  23 use FS::queue;
  24 use FS::reg_code;
  25 use FS::payby;
  26 use FS::banned_pay;
  27
  28 $DEBUG = 1;
  29 $me = '[FS::ClientAPI::Signup]';
  30
  31 sub clear_cache {
  32   warn "$me clear_cache called\n" if $DEBUG;
  33   my $cache = new FS::ClientAPI_SessionCache( {
  34       'namespace' => 'FS::ClientAPI::Signup',
  35   } );
  36   $cache->clear();
  37   return {};
  38 }
  39
  40 sub signup_info {
  41   my $packet = shift;
  42
  43   warn "$me signup_info called on $packet\n" if $DEBUG;
  44
  45   my $conf = new FS::Conf;
  46   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
  47
  48   my $cache = new FS::ClientAPI_SessionCache( {
  49     'namespace' => 'FS::ClientAPI::Signup',
  50   } );
  51   my $signup_info_cache = $cache->get('signup_info_cache');
  52
  53   if ( $signup_info_cache ) {
  54
  55     warn "$me loading cached signup info\n" if $DEBUG > 1;
  56
  57   } else {
  58
  59     warn "$me populating signup info cache\n" if $DEBUG > 1;
  60
  61     my $agentnum2part_pkg =
  62       {
  63         map {
  64           my $agent = $_;
  65           my $href = $agent->pkgpart_hashref;
  66           $agent->agentnum =>
  67             [
  68               map { { 'payby'       => [ $_->payby ],
  69                       'freq_pretty' => $_->freq_pretty,
  70                       'options'     => { $_->options },
  71                       %{$_->hashref}
  72                   } }
  73                 grep { $_->svcpart($svc_x)
  74                        && ( $href->{ $_->pkgpart }
  75                             || ( $_->agentnum
  76                                  && $_->agentnum == $agent->agentnum
  77                                )
  78                           )
  79                      }
  80                   qsearch( 'part_pkg', { 'disabled' => '' } )
  81             ];
  82         } qsearch('agent', { 'disabled' => '' })
  83       };
  84
  85     my $msgcat = { map { $_=>gettext($_) }
  86                        qw( passwords_dont_match invalid_card unknown_card_type
  87                            not_a empty_password illegal_or_empty_text )
  88                  };
  89     warn "msgcat: ". Dumper($msgcat). "\n" if $DEBUG > 2;
  90
  91     my $label = { map { $_ => FS::Msgcat::_gettext($_) }
  92                       qw( stateid stateid_state )
  93                 };
  94     warn "label: ". Dumper($label). "\n" if $DEBUG > 2;
  95
  96     my @agent_fields = qw( agentnum agent );
  97
  98     my @bools = qw( emailinvoiceonly security_phrase );
  99
 100     my @signup_bools = qw( no_company recommend_daytime recommend_email );
 101
 102     my @signup_server_scalars = qw( default_pkgpart default_svcpart default_domsvc );
 103
 104     my @selfservice_textareas = qw( head body_header body_footer );
 105
 106     my @selfservice_scalars = qw(
 107       body_bgcolor box_bgcolor
 108       text_color link_color vlink_color hlink_color alink_color
 109       font title_color title_align title_size menu_bgcolor menu_fontsize
 110     );
 111
 112     #XXX my @selfservice_bools = qw(
 113     #  menu_skipblanks menu_skipheadings menu_nounderline
 114     #);
 115
 116     #my $selfservice_binaries = qw(
 117     #  title_left_image title_right_image
 118     #  menu_top_image menu_body_image menu_bottom_image
 119     #);
 120
 121     $signup_info_cache = {
 122
 123       'cust_main_county' => [ map $_->hashref,
 124                                   qsearch('cust_main_county', {} )
 125                             ],
 126
 127       'agent' => [ map { my $agent = $_;
 128                          +{ map { $_ => $agent->get($_) } @agent_fields }
 129                        }
 130                        qsearch('agent', { 'disabled' => '' } )
 131                  ],
 132
 133       'part_referral' => [ map $_->hashref,
 134                                qsearch('part_referral', { 'disabled' => '' } )
 135                          ],
 136
 137       'agentnum2part_pkg' => $agentnum2part_pkg,
 138
 139       'svc_acct_pop' => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 140
 141       'emailinvoiceonly' => $conf->exists('emailinvoiceonly'),
 142
 143       'security_phrase' => $conf->exists('security_phrase'),
 144
 145       'nomadix' => $conf->exists('signup_server-nomadix'),
 146
 147       'payby' => [ $conf->config('signup_server-payby') ],
 148
 149       'payby_longname' => [ map { FS::payby->longname($_) }
 150                             $conf->config('signup_server-payby') ],
 151
 152       'card_types' => card_types(),
 153
 154       ( map { $_ => $conf->exists("signup-$_") } @signup_bools ),
 155
 156       ( map { $_ => scalar($conf->config("signup_server-$_")) }
 157             @signup_server_scalars
 158       ),
 159
 160       ( map { $_ => join("\n", $conf->config("selfservice-$_")) }
 161             @selfservice_textareas
 162       ),
 163       ( map { $_ => scalar($conf->config("selfservice-$_")) }
 164             @selfservice_scalars
 165       ),
 166
 167       #( map { $_ => scalar($conf->config_binary("selfservice-$_")) }
 168       #      @selfservice_binaries
 169       #),
 170
 171       'agentnum2part_pkg'  => $agentnum2part_pkg,
 172       'svc_acct_pop'       => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 173       'nomadix'            => $conf->exists('signup_server-nomadix'),
 174       'payby'              => [ $conf->config('signup_server-payby') ],
 175       'card_types'         => card_types(),
 176       'paytypes'           => [ @FS::cust_main::paytypes ],
 177       'cvv_enabled'        => 1,
 178       'stateid_enabled'    => $conf->exists('show_stateid'),
 179       'paystate_enabled'   => $conf->exists('show_bankstate'),
 180       'ship_enabled'       => 1,
 181       'msgcat'             => $msgcat,
 182       'label'              => $label,
 183       'statedefault'       => scalar($conf->config('statedefault')) || 'CA',
 184       'countrydefault'     => scalar($conf->config('countrydefault')) || 'US',
 185       'refnum'             => scalar($conf->config('signup_server-default_refnum')),
 186       'signup_service'     => $svc_x,
 187       'company_name'       => scalar($conf->config('company_name')),
 188       #per-agent?
 189       'logo'               => scalar($conf->config_binary('logo.png')),
 190       'prepaid_template_custnum' => $conf->exists('signup_server-prepaid-template-custnum'),
 191     };
 192
 193     $cache->set('signup_info_cache', $signup_info_cache);
 194
 195   }
 196
 197   my $signup_info = { %$signup_info_cache };
 198   warn "$me signup info loaded\n" if $DEBUG > 1;
 199   warn Dumper($signup_info). "\n" if $DEBUG > 2;
 200
 201   my @addl = qw( signup_server-classnum2 signup_server-classnum3 );
 202
 203   if ( grep { $conf->exists($_) } @addl ) {
 204
 205     $signup_info->{optional_packages} = [];
 206
 207     foreach my $addl ( @addl ) {
 208
 209       warn "$me adding optional package info\n" if $DEBUG > 1;
 210
 211       my $classnum = $conf->config($addl) or next;
 212
 213       my @pkgs = map { {
 214                          'freq_pretty' => $_->freq_pretty,
 215                          'options'     => { $_->options },
 216                          %{ $_->hashref }
 217                        };
 218                      }
 219                      qsearch( 'part_pkg', { classnum => $classnum } );
 220
 221       push @{$signup_info->{optional_packages}}, \@pkgs;
 222
 223       warn "$me done adding opt. package info for $classnum\n" if $DEBUG > 1;
 224
 225     }
 226
 227   }
 228
 229   my $agentnum = $packet->{'agentnum'}
 230                  || $conf->config('signup_server-default_agentnum');
 231   $agentnum =~ /^(\d*)$/ or die "illegal agentnum";
 232   $agentnum = $1;
 233
 234   my $session = '';
 235   if ( exists $packet->{'session_id'} ) {
 236
 237     warn "$me loading agent session\n" if $DEBUG > 1;
 238     my $cache = new FS::ClientAPI_SessionCache( {
 239       'namespace' => 'FS::ClientAPI::Agent',
 240     } );
 241     $session = $cache->get($packet->{'session_id'});
 242     if ( $session ) {
 243       $agentnum = $session->{'agentnum'};
 244     } else {
 245       return { 'error' => "Can't resume session" }; #better error message
 246     }
 247     warn "$me done loading agent session\n" if $DEBUG > 1;
 248
 249   } elsif ( exists $packet->{'customer_session_id'} ) {
 250
 251     warn "$me loading customer session\n" if $DEBUG > 1;
 252     my $cache = new FS::ClientAPI_SessionCache( {
 253       'namespace' => 'FS::ClientAPI::MyAccount',
 254     } );
 255     $session = $cache->get($packet->{'customer_session_id'});
 256     if ( $session ) {
 257       my $custnum = $session->{'custnum'};
 258       my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum });
 259       return { 'error' => "Can't find your customer record" } unless $cust_main;
 260       $agentnum = $cust_main->agentnum;
 261     } else {
 262       return { 'error' => "Can't resume session" }; #better error message
 263     }
 264     warn "$me done loading customer session\n" if $DEBUG > 1;
 265
 266   }
 267
 268   $signup_info->{'part_pkg'} = [];
 269
 270   if ( $packet->{'reg_code'} ) {
 271
 272     warn "$me setting package list via reg_code\n" if $DEBUG > 1;
 273
 274     $signup_info->{'part_pkg'} =
 275       [ map { { 'payby'       => [ $_->payby ],
 276                 'freq_pretty' => $_->freq_pretty,
 277                 'options'     => { $_->options },
 278                 %{$_->hashref}
 279               };
 280             }
 281           grep { $_->svcpart($svc_x) }
 282           map { $_->part_pkg }
 283             qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 284                                     'agentnum' => $agentnum,              } )
 285
 286       ];
 287
 288     $signup_info->{'error'} = 'Unknown registration code'
 289       unless @{ $signup_info->{'part_pkg'} };
 290
 291     warn "$me done setting package list via reg_code\n" if $DEBUG > 1;
 292
 293   } elsif ( $packet->{'promo_code'} ) {
 294
 295     warn "$me setting package list via promo_code\n" if $DEBUG > 1;
 296
 297     $signup_info->{'part_pkg'} =
 298       [ map { { 'payby'   => [ $_->payby ],
 299                 'freq_pretty' => $_->freq_pretty,
 300                 'options'     => { $_->options },
 301                 %{$_->hashref}
 302             } }
 303           grep { $_->svcpart($svc_x) }
 304             qsearch( 'part_pkg', { 'promo_code' => {
 305                                      op=>'ILIKE',
 306                                      value=>$packet->{'promo_code'}
 307                                    },
 308                                    'disabled'   => '',                  } )
 309       ];
 310
 311     $signup_info->{'error'} = 'Unknown promotional code'
 312       unless @{ $signup_info->{'part_pkg'} };
 313
 314     warn "$me done setting package list via promo_code\n" if $DEBUG > 1;
 315   }
 316
 317   if ( $agentnum ) {
 318
 319     warn "$me setting agent-specific payment flag\n" if $DEBUG > 1;
 320     my $agent = qsearchs('agent', { 'agentnum' => $agentnum } )
 321       or return { 'error' => "Self-service agent #$agentnum does not exist" };
 322     warn "$me has agent $agent\n" if $DEBUG > 1;
 323     my @paybys = @{ $signup_info->{'payby'} };
 324     $signup_info->{'hide_payment_fields'} = [];
 325
 326     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 327     my $force_gateway;
 328     if ( $gatewaynum ) {
 329       $force_gateway = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 330       warn "using forced gateway #$gatewaynum - " .
 331         $force_gateway->gateway_username . '@' . $force_gateway->gateway_module
 332         if $DEBUG > 1;
 333       die "configured gatewaynum $gatewaynum not found!" if !$force_gateway;
 334     }
 335     foreach my $payby (@paybys) {
 336       warn "$me checking $payby payment fields\n" if $DEBUG > 1;
 337       my $hide = 0;
 338       if ( FS::payby->realtime($payby) ) {
 339         my $gateway = $force_gateway ||
 340           $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 341                                    'nofatal' => 1,
 342                                  );
 343         if ( $gateway && $gateway->gateway_namespace
 344                     eq 'Business::OnlineThirdPartyPayment'
 345            ) {
 346           warn "$me hiding $payby payment fields\n" if $DEBUG > 1;
 347           $hide = 1;
 348         }
 349       }
 350       push @{$signup_info->{'hide_payment_fields'}}, $hide;
 351     } # foreach $payby
 352     warn "$me done setting agent-specific payment flag\n" if $DEBUG > 1;
 353
 354     warn "$me setting agent-specific package list\n" if $DEBUG > 1;
 355     $signup_info->{'part_pkg'} = $signup_info->{'agentnum2part_pkg'}{$agentnum}
 356       unless @{ $signup_info->{'part_pkg'} };
 357     warn "$me done setting agent-specific package list\n" if $DEBUG > 1;
 358
 359     warn "$me setting agent-specific adv. source list\n" if $DEBUG > 1;
 360     $signup_info->{'part_referral'} =
 361       [
 362         map { $_->hashref }
 363           qsearch( {
 364                      'table'     => 'part_referral',
 365                      'hashref'   => { 'disabled' => '' },
 366                      'extra_sql' => "AND (    agentnum = $agentnum  ".
 367                                     "      OR agentnum IS NULL    ) ",
 368                    },
 369                  )
 370       ];
 371     warn "$me done setting agent-specific adv. source list\n" if $DEBUG > 1;
 372
 373     $signup_info->{'agent_name'} = $agent->agent;
 374
 375     $signup_info->{'company_name'} = $conf->config('company_name', $agentnum);
 376
 377     #some of the above could probably be cached, too
 378
 379     my $signup_info_cache_agent = $cache->get("signup_info_cache_agent$agentnum");
 380
 381     if ( $signup_info_cache_agent ) {
 382
 383       warn "$me loading cached signup info for agentnum $agentnum\n"
 384         if $DEBUG > 1;
 385
 386     } else {
 387
 388       warn "$me populating signup info cache for agentnum $agentnum\n"
 389         if $DEBUG > 1;
 390
 391       $signup_info_cache_agent = {
 392         #( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 393         #  qw( company_name ) ),
 394         ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 395           qw( body_bgcolor box_bgcolor menu_bgcolor ) ),
 396         ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 397           qw( head body_header body_footer ) ),
 398         ( map { $_ => join("\n", $conf->config("signup_server-$_", $agentnum ) ) }
 399           qw( terms_of_service ) ),
 400
 401         ( map { $_ => scalar($conf->exists($_, $agentnum)) }
 402           qw(cust_main-require_phone agent-ship_address) ),
 403       };
 404
 405       if ( $signup_info_cache_agent->{'agent-ship_address'}
 406            && $agent->agent_cust_main ) {
 407
 408         my $cust_main = $agent->agent_cust_main;
 409         my $location = $cust_main->ship_location;
 410         $signup_info_cache_agent->{"ship_$_"} = $location->get($_)
 411           foreach qw( address1 city county state zip country );
 412
 413       }
 414
 415       $cache->set("signup_info_cache_agent$agentnum", $signup_info_cache_agent);
 416
 417     }
 418
 419     $signup_info->{$_} = $signup_info_cache_agent->{$_}
 420       foreach keys %$signup_info_cache_agent;
 421
 422   }
 423   # else {
 424   # delete $signup_info->{'part_pkg'};
 425   #}
 426
 427   warn "$me sorting package list\n" if $DEBUG > 1;
 428   $signup_info->{'part_pkg'} = [ sort { $a->{pkg} cmp $b->{pkg} }  # case?
 429                                       @{ $signup_info->{'part_pkg'} }
 430                                ];
 431   warn "$me done sorting package list\n" if $DEBUG > 1;
 432
 433   if ( exists $packet->{'session_id'} ) {
 434     my $agent_signup_info = { %$signup_info };
 435     delete $agent_signup_info->{agentnum2part_pkg};
 436     $agent_signup_info->{'agent'} = $session->{'agent'};
 437     return $agent_signup_info;
 438   }
 439   elsif ( exists $packet->{'keys'} ) {
 440     my @keys = @{ $packet->{'keys'} };
 441     return { map { $_ => $signup_info->{$_} } @keys };
 442   }
 443   else {
 444     return $signup_info;
 445   }
 446
 447 }
 448
 449 sub domain_select_hash {
 450   my $packet = shift;
 451
 452   my $response = {};
 453
 454   if ($packet->{pkgpart}) {
 455     my $part_pkg = qsearchs('part_pkg' => { 'pkgpart' => $packet->{pkgpart} } );
 456     #$packet->{svcpart} = $part_pkg->svcpart('svc_acct')
 457     $packet->{svcpart} = $part_pkg->svcpart
 458       if $part_pkg;
 459   }
 460
 461   if ($packet->{svcpart}) {
 462     my $part_svc = qsearchs('part_svc' => { 'svcpart' => $packet->{svcpart} } );
 463     $response->{'domsvc'} = $part_svc->part_svc_column('domsvc')->columnvalue
 464       if ($part_svc && $part_svc->part_svc_column('domsvc')->columnflag  eq 'D');
 465   }
 466
 467   $response->{'domains'}
 468     = { domain_select_hash FS::svc_acct( map { $_ => $packet->{$_} }
 469                                                  qw(svcpart pkgnum)
 470                                        ) };
 471
 472   $response;
 473 }
 474
 475 sub new_customer {
 476   my $packet = shift;
 477
 478   my $conf = new FS::Conf;
 479   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 480
 481   if ( $svc_x eq 'svc_acct' ) {
 482
 483     #things that aren't necessary in base class, but are for signup server
 484       #return "Passwords don't match"
 485       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 486     return { 'error' => gettext('empty_password') }
 487       unless length($packet->{'_password'});
 488     # a bit inefficient for large numbers of pops
 489     return { 'error' => gettext('no_access_number_selected') }
 490       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 491
 492   }
 493   elsif ( $svc_x eq 'svc_pbx' ) {
 494     #possibly some validation will be needed
 495   }
 496
 497   my $agentnum;
 498   if ( exists $packet->{'session_id'} ) {
 499     my $cache = new FS::ClientAPI_SessionCache( {
 500       'namespace' => 'FS::ClientAPI::Agent',
 501     } );
 502     my $session = $cache->get($packet->{'session_id'});
 503     if ( $session ) {
 504       $agentnum = $session->{'agentnum'};
 505     } else {
 506       return { 'error' => "Can't resume session" }; #better error message
 507     }
 508   } else {
 509     $agentnum = $packet->{agentnum}
 510                 || $conf->config('signup_server-default_agentnum');
 511   }
 512
 513   my ($bill_hash, $ship_hash);
 514   foreach my $f (FS::cust_main->location_fields) {
 515     # avoid having to change this in front-end code
 516     $bill_hash->{$f} = $packet->{"bill_$f"} || $packet->{$f};
 517     $ship_hash->{$f} = $packet->{"ship_$f"};
 518   }
 519
 520   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 521   # common that are still here and library them.
 522   my $template_custnum = $conf->config('signup_server-prepaid-template-custnum');
 523   my $cust_main;
 524   if ( $template_custnum && $packet->{prepaid_shortform} ) {
 525
 526     my $template_cust = qsearchs('cust_main', { 'custnum' => $template_custnum } );
 527     return { 'error' => 'Configuration error' } unless $template_cust;
 528     $cust_main = new FS::cust_main ( {
 529       'agentnum'      => $agentnum,
 530       'refnum'        => $packet->{refnum}
 531                          || $conf->config('signup_server-default_refnum'),
 532
 533       ( map { $_ => $template_cust->$_ } qw(
 534               last first company daytime night fax
 535             )
 536       ),
 537
 538       ( map { $_ => $packet->{$_} } qw(
 539               ss stateid stateid_state
 540
 541               payby
 542               payinfo paycvv paydate payname paystate paytype
 543               paystart_month paystart_year payissue
 544               payip
 545
 546               referral_custnum comments
 547             )
 548       ),
 549
 550     } );
 551
 552     $bill_hash = { $template_cust->bill_location->location_hash };
 553     $ship_hash = { $template_cust->ship_location->location_hash };
 554
 555   } else {
 556
 557     $cust_main = new FS::cust_main ( {
 558       #'custnum'          => '',
 559       'agentnum'      => $agentnum,
 560       'refnum'        => $packet->{refnum}
 561                          || $conf->config('signup_server-default_refnum'),
 562
 563       map { $_ => $packet->{$_} } qw(
 564         last first ss company
 565         daytime night fax stateid stateid_state
 566         payby
 567         payinfo paycvv paydate payname paystate paytype
 568         paystart_month paystart_year payissue
 569         payip
 570         override_ban_warn
 571         referral_custnum comments
 572       ),
 573
 574     } );
 575   }
 576
 577   my $bill_location = FS::cust_location->new($bill_hash);
 578   my $ship_location;
 579   my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 580   if ( $conf->exists('agent-ship_address', $agentnum)
 581     && $agent->agent_custnum ) {
 582
 583     my $agent_cust_main = $agent->agent_cust_main;
 584     my $prefix = length($agent_cust_main->ship_last) ? 'ship_' : '';
 585     $ship_location = FS::cust_location->new({
 586         $agent_cust_main->ship_location->location_hash
 587     });
 588
 589   }
 590   # we don't have an equivalent of the "same" checkbox in selfservice
 591   # so is there a ship address, and if so, is it different from the billing
 592   # address?
 593   elsif ( length($ship_hash->{address1}) > 0 and
 594           grep { $bill_hash->{$_} ne $ship_hash->{$_} } keys(%$ship_hash)
 595          ) {
 596
 597     $ship_location = FS::cust_location->new( $ship_hash );
 598
 599   }
 600   else {
 601     $ship_location = $bill_location;
 602   }
 603
 604   $cust_main->set('bill_location' => $bill_location);
 605   $cust_main->set('ship_location' => $ship_location);
 606
 607   return { 'error' => "Illegal payment type" }
 608     unless grep { $_ eq $packet->{'payby'} }
 609                 $conf->config('signup_server-payby');
 610
 611   if (FS::payby->realtime($packet->{payby})
 612     and not $conf->exists('signup_server-third_party_as_card')) {
 613     my $payby = $packet->{payby};
 614
 615     my $agent = qsearchs('agent', { 'agentnum' => $agentnum });
 616     return { 'error' => "Unknown reseller" }
 617       unless $agent;
 618
 619     my $gw;
 620     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 621     if ( $gatewaynum ) {
 622       $gw = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 623       die "configured gatewaynum $gatewaynum not found!" if !$gw;
 624     }
 625     else {
 626       $gw = $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 627                                      'nofatal' => 1,
 628                                     );
 629     }
 630
 631     $cust_main->payby('BILL')   # MCRD better?
 632       if $gw && $gw->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 633   }
 634
 635   $cust_main->payinfo($cust_main->daytime)
 636     if $cust_main->payby eq 'LECB' && ! $cust_main->payinfo;
 637
 638   my @invoicing_list = $packet->{'invoicing_list'}
 639                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 640                          : ();
 641
 642   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 643   my $pkgpart = $1;
 644   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 645
 646   my $part_pkg =
 647     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 648       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 649   my $svcpart = $part_pkg->svcpart($svc_x);
 650
 651   my $reg_code = '';
 652   if ( $packet->{'reg_code'} ) {
 653     $reg_code = qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 654                                         'agentnum' => $agentnum,             } )
 655       or return { 'error' => 'Unknown registration code' };
 656   }
 657
 658   my $cust_pkg = new FS::cust_pkg ( {
 659     #later#'custnum' => $custnum,
 660     'pkgpart'    => $packet->{'pkgpart'},
 661     'promo_code' => $packet->{'promo_code'},
 662     'reg_code'   => $packet->{'reg_code'},
 663   } );
 664   #my $error = $cust_pkg->check;
 665   #return { 'error' => $error } if $error;
 666
 667   #should be all auto-magic and shit
 668   my @svc = ();
 669   if ( $svc_x eq 'svc_acct' ) {
 670
 671     my $svc = new FS::svc_acct {
 672       'svcpart'   => $svcpart,
 673       map { $_ => $packet->{$_} }
 674         qw( username _password sec_phrase popnum domsvc ),
 675     };
 676
 677     my @acct_snarf;
 678     my $snarfnum = 1;
 679     while (    exists($packet->{"snarf_machine$snarfnum"})
 680             && length($packet->{"snarf_machine$snarfnum"}) ) {
 681       my $acct_snarf = new FS::acct_snarf ( {
 682         'machine'   => $packet->{"snarf_machine$snarfnum"},
 683         'protocol'  => $packet->{"snarf_protocol$snarfnum"},
 684         'username'  => $packet->{"snarf_username$snarfnum"},
 685         '_password' => $packet->{"snarf_password$snarfnum"},
 686       } );
 687       $snarfnum++;
 688       push @acct_snarf, $acct_snarf;
 689     }
 690     $svc->child_objects( \@acct_snarf );
 691     push @svc, $svc;
 692
 693   } elsif ( $svc_x eq 'svc_phone' ) {
 694
 695     push @svc, new FS::svc_phone ( {
 696       'svcpart' => $svcpart,
 697        map { $_ => $packet->{$_} }
 698          qw( countrycode phonenum sip_password pin ),
 699     } );
 700
 701   } elsif ( $svc_x eq 'svc_pbx' ) {
 702
 703     push @svc, new FS::svc_pbx ( {
 704         'svcpart' => $svcpart,
 705         map { $_ => $packet->{$_} }
 706           qw( id title ),
 707         } );
 708
 709   } else {
 710     die "unknown signup service $svc_x";
 711   }
 712
 713   if ($packet->{'mac_addr'} && $conf->exists('signup_server-mac_addr_svcparts'))
 714   {
 715
 716     my %mac_addr_svcparts = map { $_ => 1 }
 717                             $conf->config('signup_server-mac_addr_svcparts');
 718     my @pkg_svc = grep { $_->quantity && $mac_addr_svcparts{$_->svcpart} }
 719                   $cust_pkg->part_pkg->pkg_svc;
 720
 721     return { 'error' => 'No service defined to assign mac address' }
 722       unless @pkg_svc;
 723
 724     my $svc = new FS::svc_acct {
 725       'svcpart'   => $pkg_svc[0]->svcpart, #multiple matches? alas..
 726       'username'  => $packet->{'mac_addr'},
 727       '_password' => '', #blank as requested (set passwordmin to 0)
 728     };
 729
 730     push @svc, $svc;
 731
 732   }
 733
 734   foreach my $svc ( @svc ) {
 735     my $y = $svc->setdefault; # arguably should be in new method
 736     return { 'error' => $y } if $y && !ref($y);
 737     #$error = $svc->check;
 738     #return { 'error' => $error } if $error;
 739   }
 740
 741   #setup a job dependancy to delay provisioning
 742   my $placeholder = new FS::queue ( {
 743     'job'    => 'FS::ClientAPI::Signup::__placeholder',
 744     'status' => 'locked',
 745   } );
 746   my $error = $placeholder->insert;
 747   return { 'error' => $error } if $error;
 748
 749   use Tie::RefHash;
 750   tie my %hash, 'Tie::RefHash';
 751   %hash = ( $cust_pkg => \@svc );
 752   #msgcat
 753   $error = $cust_main->insert(
 754     \%hash,
 755     \@invoicing_list,
 756     'depend_jobnum' => $placeholder->jobnum,
 757   );
 758   if ( $error ) {
 759     my $perror = $placeholder->delete;
 760     $error .= " (Additionally, error removing placeholder: $perror)" if $perror;
 761     return { 'error' => $error };
 762   }
 763
 764   if ( $conf->exists('signup_server-realtime') ) {
 765
 766     #warn "$me Billing customer...\n" if $Debug;
 767
 768     my $bill_error = $cust_main->bill( 'depend_jobnum'=>$placeholder->jobnum );
 769     #warn "$me error billing new customer: $bill_error"
 770     #  if $bill_error;
 771
 772     $bill_error = $cust_main->apply_payments_and_credits;
 773     #warn "$me error applying payments and credits for".
 774     #     " new customer: $bill_error"
 775     #  if $bill_error;
 776
 777     unless ( $packet->{payby} eq 'PREPAY' ) {
 778       $bill_error = $cust_main->realtime_collect(
 779          method        => FS::payby->payby2bop( $packet->{payby} ),
 780          depend_jobnum => $placeholder->jobnum,
 781          selfservice   => 1,
 782       );
 783       #warn "$me error collecting from new customer: $bill_error"
 784       #  if $bill_error;
 785     }
 786
 787     if ($bill_error && ref($bill_error) eq 'HASH') {
 788       return { 'error' => '_collect',
 789                ( map { $_ => $bill_error->{$_} }
 790                  qw(popup_url reference collectitems)
 791                ),
 792                amount => $cust_main->balance,
 793              };
 794     }
 795
 796     $bill_error = $cust_main->apply_payments_and_credits;
 797     #warn "$me error applying payments and credits for".
 798     #     " new customer: $bill_error"
 799     #  if $bill_error;
 800
 801     if ( $cust_main->balance > 0 ) {
 802
 803       #this makes sense.  credit is "un-doing" the invoice
 804       $cust_main->credit( $cust_main->balance, 'signup server decline',
 805                           'reason_type' => $conf->config('signup_credit_type'),
 806                         );
 807       $cust_main->apply_credits;
 808
 809       #should check list for errors...
 810       #$cust_main->suspend;
 811       local $FS::svc_Common::noexport_hack = 1;
 812       $cust_main->cancel('quiet'=>1);
 813
 814       my $perror = $placeholder->depended_delete;
 815       warn "error removing provisioning jobs after decline: $perror" if $perror;
 816       unless ( $perror ) {
 817         $perror = $placeholder->delete;
 818         warn "error removing placeholder after decline: $perror" if $perror;
 819       }
 820
 821       return { 'error' => '_decline' };
 822     }
 823
 824   }
 825
 826   if ( $reg_code ) {
 827     $error = $reg_code->delete;
 828     return { 'error' => $error } if $error;
 829   }
 830
 831   $error = $placeholder->delete;
 832   return { 'error' => $error } if $error;
 833
 834   if ( $conf->exists('signup-duplicate_cc-warn_hours') ) {
 835     my $hours = $conf->config('signup-duplicate_cc-warn_hours');
 836     my $ban = new FS::banned_pay $cust_main->_new_banned_pay_hashref;
 837     $ban->end_date( int( time + $hours*3600 ) );
 838     $ban->bantype('warn');
 839     $ban->reason('signup-duplicate_cc-warn_hours');
 840     $error = $ban->insert;
 841     warn "WARNING: error inserting temporary banned_pay for ".
 842          " signup-duplicate_cc-warn_hours (proceeding anyway): $error"
 843       if $error;
 844   }
 845
 846   my %return = ( 'error'          => '',
 847                  'signup_service' => $svc_x,
 848                  'custnum'        => $cust_main->custnum,
 849                );
 850
 851   if ( $svc[0] ) {
 852
 853     $return{'svcnum'} = $svc[0]->svcnum;
 854
 855     if ( $svc_x eq 'svc_acct' ) {
 856       $return{$_} = $svc[0]->$_() for qw( username _password );
 857     } elsif ( $svc_x eq 'svc_phone' ) {
 858       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
 859     } elsif ( $svc_x eq 'svc_pbx' ) {
 860       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
 861      } else {
 862       return {'error' => "configuration error: unknown signup service $svc_x"};
 863       #die "unknown signup service $svc_x";
 864       # return an error that's visible to someone somewhere
 865     }
 866
 867   }
 868
 869   return \%return;
 870
 871 }
 872
 873 #false laziness w/ above
 874 # fresh restart to support "free account" portals with 3.x/4.x-style
 875 #  addressless accounts
 876 sub new_customer_minimal {
 877   my $packet = shift;
 878
 879   my $conf = new FS::Conf;
 880   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 881
 882   if ( $svc_x eq 'svc_acct' ) {
 883
 884     #things that aren't necessary in base class, but are for signup server
 885       #return "Passwords don't match"
 886       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 887     return { 'error' => gettext('empty_password') }
 888       unless length($packet->{'_password'});
 889     # a bit inefficient for large numbers of pops
 890     return { 'error' => gettext('no_access_number_selected') }
 891       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 892
 893   }
 894   elsif ( $svc_x eq 'svc_pbx' ) {
 895     #possibly some validation will be needed
 896   }
 897
 898   my $agentnum;
 899   if ( exists $packet->{'session_id'} ) {
 900     my $cache = new FS::ClientAPI_SessionCache( {
 901       'namespace' => 'FS::ClientAPI::Agent',
 902     } );
 903     my $session = $cache->get($packet->{'session_id'});
 904     if ( $session ) {
 905       $agentnum = $session->{'agentnum'};
 906     } else {
 907       return { 'error' => "Can't resume session" }; #better error message
 908     }
 909   } else {
 910     $agentnum = $packet->{agentnum}
 911                 || $conf->config('signup_server-default_agentnum');
 912   }
 913
 914   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 915   # common that are still here and library them.
 916
 917   my $cust_main = new FS::cust_main ( {
 918       #'custnum'          => '',
 919       'agentnum'      => $agentnum,
 920       'refnum'        => $packet->{refnum}
 921                          || $conf->config('signup_server-default_refnum'),
 922       'payby'         => 'BILL',
 923
 924       map { $_ => $packet->{$_} } qw(
 925         last first ss company
 926         daytime night fax
 927       ),
 928
 929   } );
 930
 931   my @invoicing_list = $packet->{'invoicing_list'}
 932                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 933                          : ();
 934
 935   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 936   my $pkgpart = $1;
 937   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 938
 939   my $part_pkg =
 940     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 941       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 942   my $svcpart = $part_pkg->svcpart($svc_x);
 943
 944   my $cust_pkg = new FS::cust_pkg ( {
 945     #later#'custnum' => $custnum,
 946     'pkgpart'    => $packet->{'pkgpart'},
 947   } );
 948   #my $error = $cust_pkg->check;
 949   #return { 'error' => $error } if $error;
 950
 951   #should be all auto-magic and shit
 952   my @svc = ();
 953   if ( $svc_x eq 'svc_acct' ) {
 954
 955     my $svc = new FS::svc_acct {
 956       'svcpart'   => $svcpart,
 957       map { $_ => $packet->{$_} }
 958         qw( username _password sec_phrase popnum domsvc ),
 959     };
 960
 961     push @svc, $svc;
 962
 963   } elsif ( $svc_x eq 'svc_phone' ) {
 964
 965     push @svc, new FS::svc_phone ( {
 966       'svcpart' => $svcpart,
 967        map { $_ => $packet->{$_} }
 968          qw( countrycode phonenum sip_password pin ),
 969     } );
 970
 971   } elsif ( $svc_x eq 'svc_pbx' ) {
 972
 973     push @svc, new FS::svc_pbx ( {
 974         'svcpart' => $svcpart,
 975         map { $_ => $packet->{$_} }
 976           qw( id title ),
 977         } );
 978
 979   } else {
 980     die "unknown signup service $svc_x";
 981   }
 982
 983   foreach my $svc ( @svc ) {
 984     my $y = $svc->setdefault; # arguably should be in new method
 985     return { 'error' => $y } if $y && !ref($y);
 986     #$error = $svc->check;
 987     #return { 'error' => $error } if $error;
 988   }
 989
 990   use Tie::RefHash;
 991   tie my %hash, 'Tie::RefHash';
 992   %hash = ( $cust_pkg => \@svc );
 993   #msgcat
 994   my $error = $cust_main->insert(
 995     \%hash,
 996     \@invoicing_list,
 997   );
 998   return { 'error' => $error } if $error;
 999
1000   my $session = { 'custnum' => $cust_main->custnum };
1001
1002   my $session_id;
1003   do {
1004     $session_id = sha1_hex(time(). {}. rand(). $$)
1005   } until ( ! defined _myaccount_cache->get($session_id) ); #just in case
1006
1007   _cache->set( $session_id, $session, '1 hour' ); # 1 hour?
1008
1009   my %return = ( 'error'          => '',
1010                  'signup_service' => $svc_x,
1011                  'custnum'        => $cust_main->custnum,
1012                  'session_id'     => $session_id,
1013                );
1014
1015   if ( $svc[0] ) {
1016
1017     $return{'svcnum'} = $svc[0]->svcnum;
1018
1019     if ( $svc_x eq 'svc_acct' ) {
1020       $return{$_} = $svc[0]->$_() for qw( username _password );
1021     } elsif ( $svc_x eq 'svc_phone' ) {
1022       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
1023     } elsif ( $svc_x eq 'svc_pbx' ) {
1024       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
1025      } else {
1026       return {'error' => "configuration error: unknown signup service $svc_x"};
1027       #die "unknown signup service $svc_x";
1028       # return an error that's visible to someone somewhere
1029     }
1030
1031   }
1032
1033   return \%return;
1034
1035 }
1036
1037 use vars qw( $myaccount_cache );
1038 sub _myaccount_cache {
1039   $myaccount_cache ||= new FS::ClientAPI_SessionCache( {
1040                          'namespace' => 'FS::ClientAPI::MyAccount',
1041                        } );
1042 }
1043
1044 sub capture_payment {
1045   my $packet = shift;
1046
1047   warn "$me capture_payment called on $packet\n" if $DEBUG;
1048
1049   ###
1050   # identify processor/gateway from called back URL
1051   ###
1052
1053   my $conf = new FS::Conf;
1054
1055   my $payment_gateway;
1056   if ( my $gwnum = $conf->config('selfservice-payment_gateway') ) {
1057     $payment_gateway = qsearchs('payment_gateway', { 'gatewaynum' => $gwnum })
1058       or die "configured gatewaynum $gwnum not found!";
1059   }
1060   else {
1061     my $url = $packet->{url};
1062
1063     $payment_gateway = qsearchs('payment_gateway',
1064         { 'gateway_callback_url' => popurl(0, $url) }
1065       );
1066     if (!$payment_gateway) {
1067
1068       my ( $processor, $login, $password, $action, @bop_options ) =
1069         $conf->config('business-onlinepayment');
1070       $action ||= 'normal authorization';
1071       pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
1072       die "No real-time processor is enabled - ".
1073           "did you set the business-onlinepayment configuration value?\n"
1074         unless $processor;
1075
1076       $payment_gateway = new FS::payment_gateway( {
1077         gateway_namespace => $conf->config('business-onlinepayment-namespace'),
1078         gateway_module    => $processor,
1079         gateway_username  => $login,
1080         gateway_password  => $password,
1081         gateway_action    => $action,
1082         options   => [ ( @bop_options ) ],
1083       });
1084     }
1085   }
1086
1087   die "No real-time third party processor is enabled - ".
1088       "did you set the business-onlinepayment configuration value?\n*"
1089     unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
1090
1091   ###
1092   # locate pending transaction
1093   ###
1094
1095   eval "use Business::OnlineThirdPartyPayment";
1096   die $@ if $@;
1097
1098   my $transaction =
1099     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
1100                                            @{ [ $payment_gateway->options ] },
1101                                          );
1102
1103   my $paypendingnum = $transaction->reference($packet->{data});
1104
1105   my $cust_pay_pending =
1106     qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
1107
1108   unless ($cust_pay_pending) {
1109     my $bill_error = "No payment is being processed with id $paypendingnum".
1110                      "; Transaction aborted.";
1111     return { error => '_decline', bill_error => $bill_error };
1112   }
1113
1114   if ($cust_pay_pending->status ne 'thirdparty') {
1115     my $bill_error = "Payment with id $paypendingnum is not thirdparty, but ".
1116                      $cust_pay_pending->status.  "; Transaction aborted.";
1117     return { error => '_decline', bill_error => $bill_error };
1118   }
1119
1120   my $cust_main = $cust_pay_pending->cust_main;
1121   if ( $packet->{cancel} ) {
1122     # the user has chosen not to make this payment
1123     # (probably should be a separate API call, but I don't want to duplicate
1124     # all of the above...which should eventually go away)
1125     my $error = $cust_pay_pending->delete;
1126     # don't show any errors related to this; they're not meaningful
1127     warn "error canceling pending payment $paypendingnum: $error\n" if $error;
1128     return { 'error'      => '_cancel',
1129              'session_id' => $cust_pay_pending->session_id };
1130   } else {
1131     # create the payment
1132     my $bill_error =
1133       $cust_main->realtime_botpp_capture( $cust_pay_pending,
1134         %{$packet->{data}},
1135         apply => 1,
1136     );
1137
1138     return { 'error'      => ( $bill_error->{bill_error} ? '_decline' : '' ),
1139              %$bill_error,
1140            };
1141   }
1142
1143 }
1144
1145 1;