FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::UI::Web;
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14 use FS::Record qw(qsearch qsearchs);
  15 use FS::Msgcat qw(gettext);
  16 use FS::Misc qw(card_types);
  17 use FS::ClientAPI_SessionCache;
  18 use FS::svc_acct;
  19 use FS::svc_domain;
  20 use FS::svc_external;
  21 use FS::part_svc;
  22 use FS::cust_main;
  23 use FS::cust_bill;
  24 use FS::cust_main_county;
  25 use FS::cust_pkg;
  26 use FS::payby;
  27 use FS::acct_rt_transaction;
  28 use HTML::Entities;
  29
  30 #false laziness with FS::cust_main
  31 BEGIN {
  32   eval "use Time::Local;";
  33   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  34     if $] < 5.006 && !defined($Time::Local::VERSION);
  35   eval "use Time::Local qw(timelocal_nocheck);";
  36 }
  37
  38 use vars qw( @cust_main_editable_fields );
  39 @cust_main_editable_fields = qw(
  40   first last company address1 address2 city
  41     county state zip country daytime night fax
  42   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  43     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  44   payby payinfo payname paystart_month paystart_year payissue payip
  45 );
  46
  47 use subs qw(_provision);
  48
  49 sub _cache {
  50   $cache ||= new FS::ClientAPI_SessionCache( {
  51                'namespace' => 'FS::ClientAPI::MyAccount',
  52              } );
  53 }
  54
  55 #false laziness w/FS::ClientAPI::passwd::passwd
  56 sub login {
  57   my $p = shift;
  58
  59   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  60     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  61
  62   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  63                                          'domsvc'    => $svc_domain->svcnum, }
  64                          );
  65   return { error => 'User not found.' } unless $svc_acct;
  66
  67   my $conf = new FS::Conf;
  68   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  69   return { error => 'Only primary user may log in.' }
  70     if $conf->exists('selfservice_server-primary_only')
  71        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  72
  73   return { error => 'Incorrect password.' }
  74     unless $svc_acct->check_password($p->{'password'});
  75
  76   my $session = {
  77     'svcnum' => $svc_acct->svcnum,
  78   };
  79
  80   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  81   if ( $cust_pkg ) {
  82     my $cust_main = $cust_pkg->cust_main;
  83     $session->{'custnum'} = $cust_main->custnum;
  84   }
  85
  86   my $session_id;
  87   do {
  88     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  89   } until ( ! defined _cache->get($session_id) ); #just in case
  90
  91   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
  92   _cache->set( $session_id, $session, $timeout );
  93
  94   return { 'error'      => '',
  95            'session_id' => $session_id,
  96          };
  97 }
  98
  99 sub logout {
 100   my $p = shift;
 101   if ( $p->{'session_id'} ) {
 102     _cache->remove($p->{'session_id'});
 103     return { 'error' => '' };
 104   } else {
 105     return { 'error' => "Can't resume session" }; #better error message
 106   }
 107 }
 108
 109 sub customer_info {
 110   my $p = shift;
 111
 112   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 113   return { 'error' => $session } if $context eq 'error';
 114
 115   my %return;
 116   if ( $custnum ) { #customer record
 117
 118     my $search = { 'custnum' => $custnum };
 119     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 120     my $cust_main = qsearchs('cust_main', $search )
 121       or return { 'error' => "unknown custnum $custnum" };
 122
 123     $return{balance} = $cust_main->balance;
 124
 125     $return{tickets} = [ ($cust_main->tickets) ];
 126
 127     my @open = map {
 128                      {
 129                        invnum => $_->invnum,
 130                        date   => time2str("%b %o, %Y", $_->_date),
 131                        owed   => $_->owed,
 132                      };
 133                    } $cust_main->open_cust_bill;
 134     $return{open_invoices} = \@open;
 135
 136     my $conf = new FS::Conf;
 137     $return{small_custview} =
 138       small_custview( $cust_main, $conf->config('countrydefault') );
 139
 140     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 141
 142     for (@cust_main_editable_fields) {
 143       $return{$_} = $cust_main->get($_);
 144     }
 145
 146     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 147       $return{payinfo} = $cust_main->paymask;
 148       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 149     }
 150
 151     $return{'invoicing_list'} =
 152       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 153     $return{'postal_invoicing'} =
 154       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 155
 156     if (scalar($conf->config('support_packages'))) {
 157       my @support_services = ();
 158       foreach ($cust_main->support_services) {
 159         my $seconds = $_->svc_x->seconds;
 160         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 161                              int(abs($seconds)/3600)."h".
 162                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 163         my $cust_pkg = $_->cust_pkg;
 164         my $pkgnum = '';
 165         my $pkg = '';
 166         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 167         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 168         push @support_services, { svcnum => $_->svcnum,
 169                                   time => $time_remaining,
 170                                   pkgnum => $pkgnum,
 171                                   pkg => $pkg,
 172                                 };
 173       }
 174       $return{support_services} = \@support_services;
 175     }
 176
 177   } elsif ( $session->{'svcnum'} ) { #no customer record
 178
 179     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 180       or die "unknown svcnum";
 181     $return{name} = $svc_acct->email;
 182
 183   } else {
 184
 185     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 186
 187   }
 188
 189   return { 'error'          => '',
 190            'custnum'        => $custnum,
 191            %return,
 192          };
 193
 194 }
 195
 196 sub edit_info {
 197   my $p = shift;
 198   my $session = _cache->get($p->{'session_id'})
 199     or return { 'error' => "Can't resume session" }; #better error message
 200
 201   my $custnum = $session->{'custnum'}
 202     or return { 'error' => "no customer record" };
 203
 204   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 205     or return { 'error' => "unknown custnum $custnum" };
 206
 207   my $new = new FS::cust_main { $cust_main->hash };
 208   $new->set( $_ => $p->{$_} )
 209     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 210
 211   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 212     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 213     if ( $new->payinfo eq $cust_main->paymask ) {
 214       $new->payinfo($cust_main->payinfo);
 215     } else {
 216       $new->paycvv($p->{'paycvv'});
 217     }
 218   }
 219
 220   my @invoicing_list;
 221   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 222     #false laziness with httemplate/edit/process/cust_main.cgi
 223     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 224     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 225   } else {
 226     @invoicing_list = $cust_main->invoicing_list;
 227   }
 228
 229   my $error = $new->replace($cust_main, \@invoicing_list);
 230   return { 'error' => $error } if $error;
 231   #$cust_main = $new;
 232
 233   return { 'error' => '' };
 234 }
 235
 236 sub payment_info {
 237   my $p = shift;
 238   my $session = _cache->get($p->{'session_id'})
 239     or return { 'error' => "Can't resume session" }; #better error message
 240
 241   ##
 242   #generic
 243   ##
 244
 245   use vars qw($payment_info); #cache for performance
 246   unless ( $payment_info ) {
 247
 248     my $conf = new FS::Conf;
 249     my %states = map { $_->state => 1 }
 250                    qsearch('cust_main_county', {
 251                      'country' => $conf->config('countrydefault') || 'US'
 252                    } );
 253
 254     $payment_info = {
 255
 256       #list all counties/states/countries
 257       'cust_main_county' =>
 258         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 259
 260       #shortcut for one-country folks
 261       'states' =>
 262         [ sort { $a cmp $b } keys %states ],
 263
 264       'card_types' => card_types(),
 265
 266       'paytypes' => [ @FS::cust_main::paytypes ],
 267
 268       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 269       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 270
 271       'show_ss'  => $conf->exists('show_ss'),
 272       'show_stateid' => $conf->exists('show_stateid'),
 273       'show_paystate' => $conf->exists('show_bankstate'),
 274     };
 275
 276   }
 277
 278   ##
 279   #customer-specific
 280   ##
 281
 282   my %return = %$payment_info;
 283
 284   my $custnum = $session->{'custnum'};
 285
 286   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 287     or return { 'error' => "unknown custnum $custnum" };
 288
 289   $return{balance} = $cust_main->balance;
 290
 291   $return{payname} = $cust_main->payname
 292                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 293
 294   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 295
 296   $return{payby} = $cust_main->payby;
 297   $return{stateid_state} = $cust_main->stateid_state;
 298
 299   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 300     $return{card_type} = cardtype($cust_main->payinfo);
 301     $return{payinfo} = $cust_main->paymask;
 302
 303     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 304
 305   }
 306
 307   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 308     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 309     $return{payinfo1} = $payinfo1;
 310     $return{payinfo2} = $payinfo2;
 311     $return{paytype}  = $cust_main->paytype;
 312     $return{paystate} = $cust_main->paystate;
 313
 314   }
 315
 316   #doubleclick protection
 317   my $_date = time;
 318   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 319
 320   return { 'error' => '',
 321            %return,
 322          };
 323
 324 };
 325
 326 #some false laziness with httemplate/process/payment.cgi - look there for
 327 #ACH and CVV support stuff
 328 sub process_payment {
 329
 330   my $p = shift;
 331
 332   my $session = _cache->get($p->{'session_id'})
 333     or return { 'error' => "Can't resume session" }; #better error message
 334
 335   my %return;
 336
 337   my $custnum = $session->{'custnum'};
 338
 339   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 340     or return { 'error' => "unknown custnum $custnum" };
 341
 342   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 343     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 344   my $payname = $1;
 345
 346   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 347     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 348   my $paybatch = $1;
 349
 350   $p->{'payby'} =~ /^([A-Z]{4})$/
 351     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 352   my $payby = $1;
 353
 354   my $payinfo;
 355   my $paycvv = '';
 356   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 357
 358     $p->{'payinfo1'} =~ /^([\dx]+)$/
 359       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 360     my $payinfo1 = $1;
 361      $p->{'payinfo2'} =~ /^([\dx]+)$/
 362       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 363     my $payinfo2 = $1;
 364     $payinfo = $payinfo1. '@'. $payinfo2;
 365
 366     $payinfo = $cust_main->payinfo
 367       if $cust_main->paymask eq $payinfo;
 368
 369   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 370
 371     $payinfo = $p->{'payinfo'};
 372     $payinfo =~ s/[^\dx]//g;
 373     $payinfo =~ /^(\d{13,16})$/
 374       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 375     $payinfo = $1;
 376
 377     $payinfo = $cust_main->payinfo
 378       if $cust_main->paymask eq $payinfo;
 379
 380     validate($payinfo)
 381       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 382     return { 'error' => gettext('unknown_card_type') }
 383       if cardtype($payinfo) eq "Unknown";
 384
 385     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 386       if ( cardtype($payinfo) eq 'American Express card' ) {
 387         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 388           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 389         $paycvv = $1;
 390       } else {
 391         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 392           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 393         $paycvv = $1;
 394       }
 395     }
 396
 397   } else {
 398     die "unknown payby $payby";
 399   }
 400
 401   my %payby2fields = (
 402     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 403     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 404   );
 405
 406   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 407     'quiet'    => 1,
 408     'payinfo'  => $payinfo,
 409     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 410     'payname'  => $payname,
 411     'paybatch' => $paybatch,
 412     'paycvv'   => $paycvv,
 413     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 414   );
 415   return { 'error' => $error } if $error;
 416
 417   $cust_main->apply_payments;
 418
 419   if ( $p->{'save'} ) {
 420     my $new = new FS::cust_main { $cust_main->hash };
 421     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 422       $new->set( $_ => $p->{$_} )
 423         foreach qw( payname paystart_month paystart_year payissue payip
 424                     address1 address2 city state zip payinfo );
 425       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 426     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 427       $new->set( $_ => $p->{$_} )
 428         foreach qw( payname payip paytype paystate
 429                     stateid stateid_state );
 430       $new->set( 'payinfo' => $payinfo );
 431       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 432     }
 433     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 434     my $error = $new->replace($cust_main);
 435     return { 'error' => $error } if $error;
 436     $cust_main = $new;
 437   }
 438
 439   return { 'error' => '' };
 440
 441 }
 442
 443 sub process_payment_order_pkg {
 444   my $p = shift;
 445
 446   my $hr = process_payment($p);
 447   return $hr if $hr->{'error'};
 448
 449   order_pkg($p);
 450 }
 451
 452 sub process_prepay {
 453
 454   my $p = shift;
 455
 456   my $session = _cache->get($p->{'session_id'})
 457     or return { 'error' => "Can't resume session" }; #better error message
 458
 459   my %return;
 460
 461   my $custnum = $session->{'custnum'};
 462
 463   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 464     or return { 'error' => "unknown custnum $custnum" };
 465
 466   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 467   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 468                                            \$amount,
 469                                            \$seconds,
 470                                            \$upbytes,
 471                                            \$downbytes,
 472                                            \$totalbytes,
 473                                          );
 474
 475   return { 'error' => $error } if $error;
 476
 477   return { 'error'     => '',
 478            'amount'    => $amount,
 479            'seconds'   => $seconds,
 480            'duration'  => duration_exact($seconds),
 481            'upbytes'   => $upbytes,
 482            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 483            'downbytes' => $downbytes,
 484            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 485            'totalbytes'=> $totalbytes,
 486            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 487          };
 488
 489 }
 490
 491 sub invoice {
 492   my $p = shift;
 493   my $session = _cache->get($p->{'session_id'})
 494     or return { 'error' => "Can't resume session" }; #better error message
 495
 496   my $custnum = $session->{'custnum'};
 497
 498   my $invnum = $p->{'invnum'};
 499
 500   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 501                                           'custnum' => $custnum } )
 502     or return { 'error' => "Can't find invnum" };
 503
 504   #my %return;
 505
 506   return { 'error'        => '',
 507            'invnum'       => $invnum,
 508            'invoice_text' => join('', $cust_bill->print_text ),
 509            'invoice_html' => $cust_bill->print_html,
 510          };
 511
 512 }
 513
 514 sub invoice_logo {
 515   my $p = shift;
 516
 517   #sessioning for this?  how do we get the session id to the backend invoice
 518   # template so it can add it to the link, blah
 519
 520   my $templatename = $p->{'templatename'};
 521
 522   #false laziness-ish w/view/cust_bill-logo.cgi
 523
 524   my $conf = new FS::Conf;
 525   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 526     $templatename = "_$1";
 527   } else {
 528     $templatename = '';
 529   }
 530
 531   my $filename = "logo$templatename.png";
 532
 533   return { 'error'        => '',
 534            'logo'         => $conf->config_binary($filename),
 535            'content_type' => 'image/png', #should allow gif, jpg too
 536          };
 537 }
 538
 539
 540 sub list_invoices {
 541   my $p = shift;
 542   my $session = _cache->get($p->{'session_id'})
 543     or return { 'error' => "Can't resume session" }; #better error message
 544
 545   my $custnum = $session->{'custnum'};
 546
 547   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 548     or return { 'error' => "unknown custnum $custnum" };
 549
 550   my @cust_bill = $cust_main->cust_bill;
 551
 552   return  { 'error'       => '',
 553             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 554                                         '_date'  => $_->_date,
 555                                       }
 556                                     } @cust_bill
 557                               ]
 558           };
 559 }
 560
 561 sub cancel {
 562   my $p = shift;
 563   my $session = _cache->get($p->{'session_id'})
 564     or return { 'error' => "Can't resume session" }; #better error message
 565
 566   my $custnum = $session->{'custnum'};
 567
 568   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 569     or return { 'error' => "unknown custnum $custnum" };
 570
 571   my @errors = $cust_main->cancel( 'quiet'=>1 );
 572
 573   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 574
 575   return { 'error' => $error };
 576
 577 }
 578
 579 sub list_pkgs {
 580   my $p = shift;
 581
 582   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 583   return { 'error' => $session } if $context eq 'error';
 584
 585   my $search = { 'custnum' => $custnum };
 586   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 587   my $cust_main = qsearchs('cust_main', $search )
 588     or return { 'error' => "unknown custnum $custnum" };
 589
 590   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 591
 592   my $conf = new FS::Conf;
 593
 594   { 'svcnum'   => $session->{'svcnum'},
 595     'custnum'  => $custnum,
 596     'cust_pkg' => [ map {
 597                           { $_->hash,
 598                             $_->part_pkg->hash,
 599                             part_svc =>
 600                               [ map $_->hashref, $_->available_part_svc ],
 601                             cust_svc =>
 602                               [ map { my $ref = { $_->hash,
 603                                                   label => [ $_->label ],
 604                                                 };
 605                                       $ref->{_password} = $_->svc_x->_password
 606                                         if $context eq 'agent'
 607                                         && $conf->exists('agent-showpasswords')
 608                                         && $_->part_svc->svcdb eq 'svc_acct';
 609                                       $ref;
 610                                     } $_->cust_svc
 611                               ],
 612                           };
 613                         } $cust_main->ncancelled_pkgs
 614                   ],
 615     'small_custview' =>
 616       small_custview( $cust_main, $conf->config('countrydefault') ),
 617   };
 618
 619 }
 620
 621 sub list_svcs {
 622   my $p = shift;
 623
 624   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 625   return { 'error' => $session } if $context eq 'error';
 626
 627   my $search = { 'custnum' => $custnum };
 628   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 629   my $cust_main = qsearchs('cust_main', $search )
 630     or return { 'error' => "unknown custnum $custnum" };
 631
 632   my @cust_svc = ();
 633   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 634   foreach my $cust_pkg ( $p->{'ncancelled'}
 635                          ? $cust_main->ncancelled_pkgs
 636                          : $cust_main->unsuspended_pkgs ) {
 637     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 638   }
 639   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 640     if $p->{'svcdb'};
 641
 642   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 643   #              @svc_x;
 644
 645   {
 646     #no#'svcnum'   => $session->{'svcnum'},
 647     'custnum'  => $custnum,
 648     'svcs'     => [ map {
 649                           my $svc_x = $_->svc_x;
 650                           my($label, $value) = $_->label;
 651                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 652
 653                           { 'svcnum'    => $_->svcnum,
 654                             'label'     => $label,
 655                             'value'     => $value,
 656                             'username'  => $svc_x->username,
 657                             'email'     => $svc_x->email,
 658                             'seconds'   => $svc_x->seconds,
 659                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 660                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 661                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 662                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 663                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 664                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 665                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 666                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 667                             # more...
 668                           };
 669                         }
 670                         @cust_svc
 671                   ],
 672   };
 673
 674 }
 675
 676 sub _list_svc_usage {
 677   my($svc_acct, $begin, $end) = @_;
 678   my @usage = ();
 679   foreach my $part_export (
 680     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 681     qw (sqlradius sqlradius_withdomain')
 682   ) {
 683
 684     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
 685   }
 686   (@usage);
 687 }
 688
 689 sub list_svc_usage {
 690   _usage_details(\&_list_svc_usage, @_);
 691 }
 692
 693 sub _list_support_usage {
 694   my($svc_acct, $begin, $end) = @_;
 695   my @usage = ();
 696   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
 697             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
 698           ) {
 699     push @usage, { 'seconds'  => $_->seconds,
 700                    'support'  => $_->support,
 701                    '_date'    => $_->_date,
 702                    'id'       => $_->transaction_id,
 703                    'creator'  => $_->creator,
 704                    'subject'  => $_->subject,
 705                    'status'   => $_->status,
 706                    'ticketid' => $_->ticketid,
 707                  };
 708   }
 709   (@usage);
 710 }
 711
 712 sub list_support_usage {
 713   _usage_details(\&_list_support_usage, @_);
 714 }
 715
 716 sub _usage_details {
 717   my ($callback, $p) = (shift,shift);
 718
 719   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 720   return { 'error' => $session } if $context eq 'error';
 721
 722   my $search = { 'svcnum' => $p->{'svcnum'} };
 723   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 724   my $svc_acct = qsearchs ( 'svc_acct', $search );
 725   return { 'error' => 'No service selected in list_svc_usage' }
 726     unless $svc_acct;
 727
 728   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 729   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 730   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 731   my $end    = time;
 732
 733   unless($p->{beginning}){
 734     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 735     $p->{ending} = $end;
 736   }
 737
 738   my (@usage) = &$callback($svc_acct,$p->{beginning},$p->{ending});
 739
 740   #kinda false laziness with FS::cust_main::bill, but perhaps
 741   #we should really change this bit to DateTime and DateTime::Duration
 742   #
 743   #change this bit to use Date::Manip? CAREFUL with timezones (see
 744   # mailing list archive)
 745   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 746     (localtime($p->{ending}) )[0,1,2,3,4,5];
 747   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 748     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 749
 750   if ( $freq =~ /^\d+$/ ) {
 751     $nmon += $freq;
 752     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 753     $pmon -= $freq;
 754     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 755   } elsif ( $freq =~ /^(\d+)w$/ ) {
 756     my $weeks = $1;
 757     $nmday += $weeks * 7;
 758     $pmday -= $weeks * 7;
 759   } elsif ( $freq =~ /^(\d+)d$/ ) {
 760     my $days = $1;
 761     $nmday += $days;
 762     $pmday -= $days;
 763   } elsif ( $freq =~ /^(\d+)h$/ ) {
 764     my $hours = $1;
 765     $nhour += $hours;
 766     $phour -= $hours;
 767   } else {
 768     return { 'error' => "unparsable frequency: ". $freq };
 769   }
 770
 771   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 772   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 773
 774   {
 775     'error'     => '',
 776     'svcnum'    => $p->{svcnum},
 777     'beginning' => $p->{beginning},
 778     'ending'    => $p->{ending},
 779     'previous'  => ($previous > $start) ? $previous : $start,
 780     'next'      => ($next < $end) ? $next : $end,
 781     'usage'     => \@usage,
 782   };
 783 }
 784
 785 sub order_pkg {
 786   my $p = shift;
 787
 788   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 789   return { 'error' => $session } if $context eq 'error';
 790
 791   my $search = { 'custnum' => $custnum };
 792   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 793   my $cust_main = qsearchs('cust_main', $search )
 794     or return { 'error' => "unknown custnum $custnum" };
 795
 796   #false laziness w/ClientAPI/Signup.pm
 797
 798   my $cust_pkg = new FS::cust_pkg ( {
 799     'custnum' => $custnum,
 800     'pkgpart' => $p->{'pkgpart'},
 801   } );
 802   my $error = $cust_pkg->check;
 803   return { 'error' => $error } if $error;
 804
 805   my @svc = ();
 806   unless ( $p->{'svcpart'} eq 'none' ) {
 807
 808     my $svcdb;
 809     my $svcpart = '';
 810     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 811       $svcpart = $1;
 812       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 813       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 814       $svcdb = $part_svc->svcdb;
 815     } else {
 816       $svcdb = 'svc_acct';
 817     }
 818     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 819
 820     my %fields = (
 821       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 822       'svc_domain'   => [ qw( domain ) ],
 823       'svc_external' => [ qw( id title ) ],
 824     );
 825
 826     my $svc_x = "FS::$svcdb"->new( {
 827       'svcpart'   => $svcpart,
 828       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 829     } );
 830
 831     if ( $svcdb eq 'svc_acct' ) {
 832       my @acct_snarf;
 833       my $snarfnum = 1;
 834       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 835         my $acct_snarf = new FS::acct_snarf ( {
 836           'machine'   => $p->{"snarf_machine$snarfnum"},
 837           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 838           'username'  => $p->{"snarf_username$snarfnum"},
 839           '_password' => $p->{"snarf_password$snarfnum"},
 840         } );
 841         $snarfnum++;
 842         push @acct_snarf, $acct_snarf;
 843       }
 844       $svc_x->child_objects( \@acct_snarf );
 845     }
 846
 847     my $y = $svc_x->setdefault; # arguably should be in new method
 848     return { 'error' => $y } if $y && !ref($y);
 849
 850     $error = $svc_x->check;
 851     return { 'error' => $error } if $error;
 852
 853     push @svc, $svc_x;
 854
 855   }
 856
 857   use Tie::RefHash;
 858   tie my %hash, 'Tie::RefHash';
 859   %hash = ( $cust_pkg => \@svc );
 860   #msgcat
 861   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 862   return { 'error' => $error } if $error;
 863
 864   my $conf = new FS::Conf;
 865   if ( $conf->exists('signup_server-realtime') ) {
 866
 867     my $bill_error = _do_bop_realtime( $cust_main );
 868
 869     if ($bill_error) {
 870       $cust_pkg->cancel('quiet'=>1);
 871       return $bill_error;
 872     } else {
 873       $cust_pkg->reexport;
 874     }
 875
 876   } else {
 877     $cust_pkg->reexport;
 878   }
 879
 880   return { error => '', pkgnum => $cust_pkg->pkgnum };
 881
 882 }
 883
 884 sub change_pkg {
 885   my $p = shift;
 886
 887   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 888   return { 'error' => $session } if $context eq 'error';
 889
 890   my $search = { 'custnum' => $custnum };
 891   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 892   my $cust_main = qsearchs('cust_main', $search )
 893     or return { 'error' => "unknown custnum $custnum" };
 894
 895   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 896     or return { 'error' => "unknown package $p->{pkgnum}" };
 897
 898   my @newpkg;
 899   my $error = FS::cust_pkg::order( $custnum,
 900                                    [$p->{pkgpart}],
 901                                    [$p->{pkgnum}],
 902                                    \@newpkg,
 903                                  );
 904
 905   my $conf = new FS::Conf;
 906   if ( $conf->exists('signup_server-realtime') ) {
 907
 908     my $bill_error = _do_bop_realtime( $cust_main );
 909
 910     if ($bill_error) {
 911       $newpkg[0]->suspend;
 912       return $bill_error;
 913     } else {
 914       $newpkg[0]->reexport;
 915     }
 916
 917   } else {
 918     $newpkg[0]->reexport;
 919   }
 920
 921   return { error => '', pkgnum => $cust_pkg->pkgnum };
 922
 923 }
 924
 925 sub order_recharge {
 926   my $p = shift;
 927
 928   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 929   return { 'error' => $session } if $context eq 'error';
 930
 931   my $search = { 'custnum' => $custnum };
 932   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 933   my $cust_main = qsearchs('cust_main', $search )
 934     or return { 'error' => "unknown custnum $custnum" };
 935
 936   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 937     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 938
 939   my $svc_x = $cust_svc->svc_x;
 940   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 941
 942   my %vhash =
 943     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 944     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 945          recharge_totalbytes );
 946   my $amount = $part_pkg->option('recharge_amount', 1);
 947
 948   my ($l, $v, $d) = $cust_svc->label;  # blah
 949   my $pkg = "Recharge $v";
 950
 951   my $bill_error = $cust_main->charge($amount, $pkg,
 952      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 953      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 954      $part_pkg->taxclass); #meh
 955
 956   my $conf = new FS::Conf;
 957   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 958
 959     $bill_error = _do_bop_realtime( $cust_main );
 960
 961     if ($bill_error) {
 962       return $bill_error;
 963     } else {
 964       my $error = $svc_x->recharge (\%vhash);
 965       return { 'error' => $error } if $error;
 966     }
 967
 968   } else {
 969     my $error = $bill_error;
 970     $error ||= $svc_x->recharge (\%vhash);
 971     return { 'error' => $error } if $error;
 972   }
 973
 974   return { error => '', svc => $cust_svc->part_svc->svc };
 975
 976 }
 977
 978 sub _do_bop_realtime {
 979   my ($cust_main) = @_;
 980
 981     my $old_balance = $cust_main->balance;
 982
 983     my $bill_error =    $cust_main->bill
 984                      || $cust_main->apply_payments_and_credits
 985                      || $cust_main->collect('realtime' => 1);
 986
 987     if (    $cust_main->balance > $old_balance
 988          && $cust_main->balance > 0
 989          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 990       #this makes sense.  credit is "un-doing" the invoice
 991       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 992                           'self-service decline' );
 993       $cust_main->apply_credits( 'order' => 'newest' );
 994
 995       return { 'error' => '_decline', 'bill_error' => $bill_error };
 996     }
 997
 998     '';
 999 }
1000
1001 sub cancel_pkg {
1002   my $p = shift;
1003   my $session = _cache->get($p->{'session_id'})
1004     or return { 'error' => "Can't resume session" }; #better error message
1005
1006   my $custnum = $session->{'custnum'};
1007
1008   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1009     or return { 'error' => "unknown custnum $custnum" };
1010
1011   my $pkgnum = $p->{'pkgnum'};
1012
1013   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1014                                         'pkgnum'  => $pkgnum,   } )
1015     or return { 'error' => "unknown pkgnum $pkgnum" };
1016
1017   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1018   return { 'error' => $error };
1019
1020 }
1021
1022 sub provision_acct {
1023   my $p = shift;
1024
1025   return { 'error' => gettext('passwords_dont_match') }
1026     if $p->{'_password'} ne $p->{'_password2'};
1027   return { 'error' => gettext('empty_password') }
1028     unless length($p->{'_password'});
1029
1030   _provision( 'FS::svc_acct',
1031               [qw(username _password)],
1032               [qw(username _password)],
1033               $p,
1034               @_
1035             );
1036 }
1037
1038 sub provision_external {
1039   my $p = shift;
1040   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1041   _provision( 'FS::svc_external',
1042               [],
1043               [qw(id title)],
1044               $p,
1045               @_
1046             );
1047 }
1048
1049 sub _provision {
1050   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1051
1052   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1053   return { 'error' => $session } if $context eq 'error';
1054
1055   my $search = { 'custnum' => $custnum };
1056   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1057   my $cust_main = qsearchs('cust_main', $search )
1058     or return { 'error' => "unknown custnum $custnum" };
1059
1060   my $pkgnum = $p->{'pkgnum'};
1061
1062   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1063                                         'pkgnum'  => $pkgnum,
1064                                                                } )
1065     or return { 'error' => "unknown pkgnum $pkgnum" };
1066
1067   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1068     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1069
1070   my $svc_x = $class->new( {
1071     'pkgnum'  => $p->{'pkgnum'},
1072     'svcpart' => $p->{'svcpart'},
1073     map { $_ => $p->{$_} } @$fields
1074   } );
1075   my $error = $svc_x->insert;
1076   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1077     unless $error;
1078
1079   return { 'svc'   => $part_svc->svc,
1080            'error' => $error,
1081            map { $_ => $svc_x->get($_) } @$return_fields
1082          };
1083
1084 }
1085
1086 sub part_svc_info {
1087   my $p = shift;
1088
1089   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1090   return { 'error' => $session } if $context eq 'error';
1091
1092   my $search = { 'custnum' => $custnum };
1093   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1094   my $cust_main = qsearchs('cust_main', $search )
1095     or return { 'error' => "unknown custnum $custnum" };
1096
1097   my $pkgnum = $p->{'pkgnum'};
1098
1099   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1100                                         'pkgnum'  => $pkgnum,
1101                                                                } )
1102     or return { 'error' => "unknown pkgnum $pkgnum" };
1103
1104   my $svcpart = $p->{'svcpart'};
1105
1106   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1107                                       'svcpart' => $svcpart,           } )
1108     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1109   my $part_svc = $pkg_svc->part_svc;
1110
1111   my $conf = new FS::Conf;
1112
1113   return {
1114     'svc'     => $part_svc->svc,
1115     'svcdb'   => $part_svc->svcdb,
1116     'pkgnum'  => $pkgnum,
1117     'svcpart' => $svcpart,
1118     'custnum' => $custnum,
1119
1120     'security_phrase' => 0, #XXX !
1121     'svc_acct_pop'    => [], #XXX !
1122     'popnum'          => '',
1123     'init_popstate'   => '',
1124     'popac'           => '',
1125     'acstate'         => '',
1126
1127     'small_custview' =>
1128       small_custview( $cust_main, $conf->config('countrydefault') ),
1129
1130   };
1131
1132 }
1133
1134 sub unprovision_svc {
1135   my $p = shift;
1136
1137   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1138   return { 'error' => $session } if $context eq 'error';
1139
1140   my $search = { 'custnum' => $custnum };
1141   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1142   my $cust_main = qsearchs('cust_main', $search )
1143     or return { 'error' => "unknown custnum $custnum" };
1144
1145   my $svcnum = $p->{'svcnum'};
1146
1147   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1148     or return { 'error' => "unknown svcnum $svcnum" };
1149
1150   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1151     unless $cust_svc->cust_pkg->custnum == $custnum;
1152
1153   my $conf = new FS::Conf;
1154
1155   return { 'svc'   => $cust_svc->part_svc->svc,
1156            'error' => $cust_svc->cancel,
1157            'small_custview' =>
1158              small_custview( $cust_main, $conf->config('countrydefault') ),
1159          };
1160
1161 }
1162
1163 sub myaccount_passwd {
1164   my $p = shift;
1165   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1166   return { 'error' => $session } if $context eq 'error';
1167
1168   return { 'error' => "New passwords don't match." }
1169     if $p->{'new_password'} ne $p->{'new_password2'};
1170
1171   return { 'error' => 'Enter new password' }
1172     unless length($p->{'new_password'});
1173
1174   #my $search = { 'custnum' => $custnum };
1175   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1176   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1177   my $search = " AND custnum = $1";
1178   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1179
1180   my $svc_acct = qsearchs( {
1181     'table'     => 'svc_acct',
1182     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1183                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1184                    'LEFT JOIN cust_main USING ( custnum ) ',
1185     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1186     'extra_sql' => $search, #important
1187   } )
1188     or return { 'error' => "Service not found" };
1189
1190   $svc_acct->_password($p->{'new_password'});
1191   my $error = $svc_acct->replace();
1192
1193   my($label, $value) = $svc_acct->cust_svc->label;
1194
1195   return { 'error' => $error,
1196            'label' => $label,
1197            'value' => $value,
1198          };
1199
1200 }
1201
1202 #--
1203
1204 sub _custoragent_session_custnum {
1205   my $p = shift;
1206
1207   my($context, $session, $custnum);
1208   if ( $p->{'session_id'} ) {
1209
1210     $context = 'customer';
1211     $session = _cache->get($p->{'session_id'})
1212       or return ( 'error' => "Can't resume session" ); #better error message
1213     $custnum = $session->{'custnum'};
1214
1215   } elsif ( $p->{'agent_session_id'} ) {
1216
1217     $context = 'agent';
1218     my $agent_cache = new FS::ClientAPI_SessionCache( {
1219       'namespace' => 'FS::ClientAPI::Agent',
1220     } );
1221     $session = $agent_cache->get($p->{'agent_session_id'})
1222       or return ( 'error' => "Can't resume session" ); #better error message
1223     $custnum = $p->{'custnum'};
1224
1225   } else {
1226     return ( 'error' => "Can't resume session" ); #better error message
1227   }
1228
1229   ($context, $session, $custnum);
1230
1231 }
1232
1233 1;
1234