FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::UI::Web;
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14 use FS::Record qw(qsearch qsearchs);
  15 use FS::Msgcat qw(gettext);
  16 use FS::Misc qw(card_types);
  17 use FS::ClientAPI_SessionCache;
  18 use FS::svc_acct;
  19 use FS::svc_domain;
  20 use FS::svc_external;
  21 use FS::part_svc;
  22 use FS::cust_main;
  23 use FS::cust_bill;
  24 use FS::cust_main_county;
  25 use FS::cust_pkg;
  26 use FS::payby;
  27 use HTML::Entities;
  28
  29 #false laziness with FS::cust_main
  30 BEGIN {
  31   eval "use Time::Local;";
  32   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  33     if $] < 5.006 && !defined($Time::Local::VERSION);
  34   eval "use Time::Local qw(timelocal_nocheck);";
  35 }
  36
  37 use vars qw( @cust_main_editable_fields );
  38 @cust_main_editable_fields = qw(
  39   first last company address1 address2 city
  40     county state zip country daytime night fax
  41   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  42     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  43   payby payinfo payname paystart_month paystart_year payissue payip
  44 );
  45
  46 use subs qw(_provision);
  47
  48 sub _cache {
  49   $cache ||= new FS::ClientAPI_SessionCache( {
  50                'namespace' => 'FS::ClientAPI::MyAccount',
  51              } );
  52 }
  53
  54 #false laziness w/FS::ClientAPI::passwd::passwd
  55 sub login {
  56   my $p = shift;
  57
  58   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  59     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  60
  61   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  62                                          'domsvc'    => $svc_domain->svcnum, }
  63                          );
  64   return { error => 'User not found.' } unless $svc_acct;
  65
  66   my $conf = new FS::Conf;
  67   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  68   return { error => 'Only primary user may log in.' }
  69     if $conf->exists('selfservice_server-primary_only')
  70        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  71
  72   return { error => 'Incorrect password.' }
  73     unless $svc_acct->check_password($p->{'password'});
  74
  75   my $session = {
  76     'svcnum' => $svc_acct->svcnum,
  77   };
  78
  79   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  80   if ( $cust_pkg ) {
  81     my $cust_main = $cust_pkg->cust_main;
  82     $session->{'custnum'} = $cust_main->custnum;
  83   }
  84
  85   my $session_id;
  86   do {
  87     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  88   } until ( ! defined _cache->get($session_id) ); #just in case
  89
  90   _cache->set( $session_id, $session, '1 hour' );
  91
  92   return { 'error'      => '',
  93            'session_id' => $session_id,
  94          };
  95 }
  96
  97 sub logout {
  98   my $p = shift;
  99   if ( $p->{'session_id'} ) {
 100     _cache->remove($p->{'session_id'});
 101     return { 'error' => '' };
 102   } else {
 103     return { 'error' => "Can't resume session" }; #better error message
 104   }
 105 }
 106
 107 sub customer_info {
 108   my $p = shift;
 109
 110   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 111   return { 'error' => $session } if $context eq 'error';
 112
 113   my %return;
 114   if ( $custnum ) { #customer record
 115
 116     my $search = { 'custnum' => $custnum };
 117     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 118     my $cust_main = qsearchs('cust_main', $search )
 119       or return { 'error' => "unknown custnum $custnum" };
 120
 121     $return{balance} = $cust_main->balance;
 122
 123     my @open = map {
 124                      {
 125                        invnum => $_->invnum,
 126                        date   => time2str("%b %o, %Y", $_->_date),
 127                        owed   => $_->owed,
 128                      };
 129                    } $cust_main->open_cust_bill;
 130     $return{open_invoices} = \@open;
 131
 132     my $conf = new FS::Conf;
 133     $return{small_custview} =
 134       small_custview( $cust_main, $conf->config('countrydefault') );
 135
 136     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 137
 138     for (@cust_main_editable_fields) {
 139       $return{$_} = $cust_main->get($_);
 140     }
 141
 142     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 143       $return{payinfo} = $cust_main->paymask;
 144       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 145     }
 146
 147     $return{'invoicing_list'} =
 148       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 149     $return{'postal_invoicing'} =
 150       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 151
 152   } elsif ( $session->{'svcnum'} ) { #no customer record
 153
 154     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 155       or die "unknown svcnum";
 156     $return{name} = $svc_acct->email;
 157
 158   } else {
 159
 160     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 161
 162   }
 163
 164   return { 'error'          => '',
 165            'custnum'        => $custnum,
 166            %return,
 167          };
 168
 169 }
 170
 171 sub edit_info {
 172   my $p = shift;
 173   my $session = _cache->get($p->{'session_id'})
 174     or return { 'error' => "Can't resume session" }; #better error message
 175
 176   my $custnum = $session->{'custnum'}
 177     or return { 'error' => "no customer record" };
 178
 179   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 180     or return { 'error' => "unknown custnum $custnum" };
 181
 182   my $new = new FS::cust_main { $cust_main->hash };
 183   $new->set( $_ => $p->{$_} )
 184     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 185
 186   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 187     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 188     if ( $new->payinfo eq $cust_main->paymask ) {
 189       $new->payinfo($cust_main->payinfo);
 190     } else {
 191       $new->paycvv($p->{'paycvv'});
 192     }
 193   }
 194
 195   my @invoicing_list;
 196   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 197     #false laziness with httemplate/edit/process/cust_main.cgi
 198     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 199     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 200   } else {
 201     @invoicing_list = $cust_main->invoicing_list;
 202   }
 203
 204   my $error = $new->replace($cust_main, \@invoicing_list);
 205   return { 'error' => $error } if $error;
 206   #$cust_main = $new;
 207
 208   return { 'error' => '' };
 209 }
 210
 211 sub payment_info {
 212   my $p = shift;
 213   my $session = _cache->get($p->{'session_id'})
 214     or return { 'error' => "Can't resume session" }; #better error message
 215
 216   ##
 217   #generic
 218   ##
 219
 220   use vars qw($payment_info); #cache for performance
 221   unless ( $payment_info ) {
 222
 223     my $conf = new FS::Conf;
 224     my %states = map { $_->state => 1 }
 225                    qsearch('cust_main_county', {
 226                      'country' => $conf->config('countrydefault') || 'US'
 227                    } );
 228
 229     $payment_info = {
 230
 231       #list all counties/states/countries
 232       'cust_main_county' =>
 233         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 234
 235       #shortcut for one-country folks
 236       'states' =>
 237         [ sort { $a cmp $b } keys %states ],
 238
 239       'card_types' => card_types(),
 240
 241       'paytypes' => [ @FS::cust_main::paytypes ],
 242
 243       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 244       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 245
 246       'show_ss'  => $conf->exists('show_ss'),
 247       'show_stateid' => $conf->exists('show_stateid'),
 248       'show_paystate' => $conf->exists('show_bankstate'),
 249     };
 250
 251   }
 252
 253   ##
 254   #customer-specific
 255   ##
 256
 257   my %return = %$payment_info;
 258
 259   my $custnum = $session->{'custnum'};
 260
 261   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 262     or return { 'error' => "unknown custnum $custnum" };
 263
 264   $return{balance} = $cust_main->balance;
 265
 266   $return{payname} = $cust_main->payname
 267                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 268
 269   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 270
 271   $return{payby} = $cust_main->payby;
 272   $return{stateid_state} = $cust_main->stateid_state;
 273
 274   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 275     $return{card_type} = cardtype($cust_main->payinfo);
 276     $return{payinfo} = $cust_main->payinfo;
 277
 278     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 279
 280   }
 281
 282   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 283     my ($payinfo1, $payinfo2) = split '@', $cust_main->payinfo;
 284     $return{payinfo1} = $payinfo1;
 285     $return{payinfo2} = $payinfo2;
 286     $return{paytype}  = $cust_main->paytype;
 287     $return{paystate} = $cust_main->paystate;
 288
 289   }
 290
 291   #doubleclick protection
 292   my $_date = time;
 293   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 294
 295   return { 'error' => '',
 296            %return,
 297          };
 298
 299 };
 300
 301 #some false laziness with httemplate/process/payment.cgi - look there for
 302 #ACH and CVV support stuff
 303 sub process_payment {
 304
 305   my $p = shift;
 306
 307   my $session = _cache->get($p->{'session_id'})
 308     or return { 'error' => "Can't resume session" }; #better error message
 309
 310   my %return;
 311
 312   my $custnum = $session->{'custnum'};
 313
 314   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 315     or return { 'error' => "unknown custnum $custnum" };
 316
 317   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 318     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 319   my $payname = $1;
 320
 321   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 322     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 323   my $paybatch = $1;
 324
 325   $p->{'payby'} =~ /^([A-Z]{4})$/
 326     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 327   my $payby = $1;
 328
 329   my $payinfo;
 330   my $paycvv = '';
 331   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 332
 333     $p->{'payinfo1'} =~ /^(\d+)$/
 334       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 335     my $payinfo1 = $1;
 336      $p->{'payinfo2'} =~ /^(\d+)$/
 337       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 338     my $payinfo2 = $1;
 339     $payinfo = $payinfo1. '@'. $payinfo2;
 340
 341   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 342
 343     $payinfo = $p->{'payinfo'};
 344     $payinfo =~ s/\D//g;
 345     $payinfo =~ /^(\d{13,16})$/
 346       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 347     $payinfo = $1;
 348     validate($payinfo)
 349       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 350     return { 'error' => gettext('unknown_card_type') }
 351       if cardtype($payinfo) eq "Unknown";
 352
 353     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 354       if ( cardtype($payinfo) eq 'American Express card' ) {
 355         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 356           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 357         $paycvv = $1;
 358       } else {
 359         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 360           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 361         $paycvv = $1;
 362       }
 363     }
 364
 365   } else {
 366     die "unknown payby $payby";
 367   }
 368
 369   my %payby2fields = (
 370     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 371     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 372   );
 373
 374   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 375     'quiet'    => 1,
 376     'payinfo'  => $payinfo,
 377     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 378     'payname'  => $payname,
 379     'paybatch' => $paybatch,
 380     'paycvv'   => $paycvv,
 381     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 382   );
 383   return { 'error' => $error } if $error;
 384
 385   $cust_main->apply_payments;
 386
 387   if ( $p->{'save'} ) {
 388     my $new = new FS::cust_main { $cust_main->hash };
 389     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 390       $new->set( $_ => $p->{$_} )
 391         foreach qw( payname paystart_month paystart_year payissue payip
 392                     address1 address2 city state zip payinfo );
 393       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 394     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 395       $new->set( $_ => $p->{$_} )
 396         foreach qw( payname payip paytype paystate
 397                     stateid stateid_state );
 398       $new->set( 'payinfo' => $payinfo );
 399       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 400     }
 401     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 402     my $error = $new->replace($cust_main);
 403     return { 'error' => $error } if $error;
 404     $cust_main = $new;
 405   }
 406
 407   return { 'error' => '' };
 408
 409 }
 410
 411 sub process_prepay {
 412
 413   my $p = shift;
 414
 415   my $session = _cache->get($p->{'session_id'})
 416     or return { 'error' => "Can't resume session" }; #better error message
 417
 418   my %return;
 419
 420   my $custnum = $session->{'custnum'};
 421
 422   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 423     or return { 'error' => "unknown custnum $custnum" };
 424
 425   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 426   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 427                                            \$amount,
 428                                            \$seconds,
 429                                            \$upbytes,
 430                                            \$downbytes,
 431                                            \$totalbytes,
 432                                          );
 433
 434   return { 'error' => $error } if $error;
 435
 436   return { 'error'     => '',
 437            'amount'    => $amount,
 438            'seconds'   => $seconds,
 439            'duration'  => duration_exact($seconds),
 440            'upbytes'   => $upbytes,
 441            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 442            'downbytes' => $downbytes,
 443            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 444            'totalbytes'=> $totalbytes,
 445            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 446          };
 447
 448 }
 449
 450 sub invoice {
 451   my $p = shift;
 452   my $session = _cache->get($p->{'session_id'})
 453     or return { 'error' => "Can't resume session" }; #better error message
 454
 455   my $custnum = $session->{'custnum'};
 456
 457   my $invnum = $p->{'invnum'};
 458
 459   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 460                                           'custnum' => $custnum } )
 461     or return { 'error' => "Can't find invnum" };
 462
 463   #my %return;
 464
 465   return { 'error'        => '',
 466            'invnum'       => $invnum,
 467            'invoice_text' => join('', $cust_bill->print_text ),
 468            'invoice_html' => $cust_bill->print_html,
 469          };
 470
 471 }
 472
 473 sub invoice_logo {
 474   my $p = shift;
 475
 476   #sessioning for this?  how do we get the session id to the backend invoice
 477   # template so it can add it to the link, blah
 478
 479   my $templatename = $p->{'templatename'};
 480
 481   #false laziness-ish w/view/cust_bill-logo.cgi
 482
 483   my $conf = new FS::Conf;
 484   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 485     $templatename = "_$1";
 486   } else {
 487     $templatename = '';
 488   }
 489
 490   my $filename = "logo$templatename.png";
 491
 492   return { 'error'        => '',
 493            'logo'         => $conf->config_binary($filename),
 494            'content_type' => 'image/png', #should allow gif, jpg too
 495          };
 496 }
 497
 498
 499 sub list_invoices {
 500   my $p = shift;
 501   my $session = _cache->get($p->{'session_id'})
 502     or return { 'error' => "Can't resume session" }; #better error message
 503
 504   my $custnum = $session->{'custnum'};
 505
 506   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 507     or return { 'error' => "unknown custnum $custnum" };
 508
 509   my @cust_bill = $cust_main->cust_bill;
 510
 511   return  { 'error'       => '',
 512             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 513                                         '_date'  => $_->_date,
 514                                       }
 515                                     } @cust_bill
 516                               ]
 517           };
 518 }
 519
 520 sub cancel {
 521   my $p = shift;
 522   my $session = _cache->get($p->{'session_id'})
 523     or return { 'error' => "Can't resume session" }; #better error message
 524
 525   my $custnum = $session->{'custnum'};
 526
 527   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 528     or return { 'error' => "unknown custnum $custnum" };
 529
 530   my @errors = $cust_main->cancel( 'quiet'=>1 );
 531
 532   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 533
 534   return { 'error' => $error };
 535
 536 }
 537
 538 sub list_pkgs {
 539   my $p = shift;
 540
 541   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 542   return { 'error' => $session } if $context eq 'error';
 543
 544   my $search = { 'custnum' => $custnum };
 545   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 546   my $cust_main = qsearchs('cust_main', $search )
 547     or return { 'error' => "unknown custnum $custnum" };
 548
 549   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 550
 551   my $conf = new FS::Conf;
 552
 553   { 'svcnum'   => $session->{'svcnum'},
 554     'custnum'  => $custnum,
 555     'cust_pkg' => [ map {
 556                           { $_->hash,
 557                             $_->part_pkg->hash,
 558                             part_svc =>
 559                               [ map $_->hashref, $_->available_part_svc ],
 560                             cust_svc =>
 561                               [ map { my $ref = { $_->hash,
 562                                                   label => [ $_->label ],
 563                                                 };
 564                                       $ref->{_password} = $_->svc_x->_password
 565                                         if $context eq 'agent'
 566                                         && $conf->exists('agent-showpasswords')
 567                                         && $_->part_svc->svcdb eq 'svc_acct';
 568                                       $ref;
 569                                     } $_->cust_svc
 570                               ],
 571                           };
 572                         } $cust_main->ncancelled_pkgs
 573                   ],
 574     'small_custview' =>
 575       small_custview( $cust_main, $conf->config('countrydefault') ),
 576   };
 577
 578 }
 579
 580 sub list_svcs {
 581   my $p = shift;
 582
 583   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 584   return { 'error' => $session } if $context eq 'error';
 585
 586   my $search = { 'custnum' => $custnum };
 587   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 588   my $cust_main = qsearchs('cust_main', $search )
 589     or return { 'error' => "unknown custnum $custnum" };
 590
 591   my @cust_svc = ();
 592   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 593   foreach my $cust_pkg ( $p->{'ncancelled'}
 594                          ? $cust_main->ncancelled_pkgs
 595                          : $cust_main->unsuspended_pkgs ) {
 596     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 597   }
 598   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 599     if $p->{'svcdb'};
 600
 601   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 602   #              @svc_x;
 603
 604   {
 605     #no#'svcnum'   => $session->{'svcnum'},
 606     'custnum'  => $custnum,
 607     'svcs'     => [ map {
 608                           my $svc_x = $_->svc_x;
 609                           my($label, $value) = $_->label;
 610                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 611
 612                           { 'svcnum'    => $_->svcnum,
 613                             'label'     => $label,
 614                             'value'     => $value,
 615                             'username'  => $svc_x->username,
 616                             'email'     => $svc_x->email,
 617                             'seconds'   => $svc_x->seconds,
 618                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 619                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 620                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 621                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 622                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 623                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 624                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 625                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 626                             # more...
 627                           };
 628                         }
 629                         @cust_svc
 630                   ],
 631   };
 632
 633 }
 634
 635 sub list_svc_usage {
 636   my $p = shift;
 637
 638   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 639   return { 'error' => $session } if $context eq 'error';
 640
 641   my $search = { 'svcnum' => $p->{'svcnum'} };
 642   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 643   my $svc_acct = qsearchs ( 'svc_acct', $search );
 644   return { 'error' => 'No service selected in list_svc_usage' }
 645     unless $svc_acct;
 646
 647   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 648   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 649   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 650   my $end    = time;
 651
 652   unless($p->{beginning}){
 653     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 654     $p->{ending} = $end;
 655   }
 656   my @usage = ();
 657
 658   foreach my $part_export (
 659     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 660     qw (sqlradius sqlradius_withdomain')
 661   ) {
 662
 663     push @usage, @ { $part_export->usage_sessions($p->{beginning},
 664                                                   $p->{ending},
 665                                                   $svc_acct)
 666                    };
 667   }
 668
 669   #kinda false laziness with FS::cust_main::bill, but perhaps
 670   #we should really change this bit to DateTime and DateTime::Duration
 671   #
 672   #change this bit to use Date::Manip? CAREFUL with timezones (see
 673   # mailing list archive)
 674   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 675     (localtime($p->{ending}) )[0,1,2,3,4,5];
 676   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 677     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 678
 679   if ( $freq =~ /^\d+$/ ) {
 680     $nmon += $freq;
 681     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 682     $pmon -= $freq;
 683     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 684   } elsif ( $freq =~ /^(\d+)w$/ ) {
 685     my $weeks = $1;
 686     $nmday += $weeks * 7;
 687     $pmday -= $weeks * 7;
 688   } elsif ( $freq =~ /^(\d+)d$/ ) {
 689     my $days = $1;
 690     $nmday += $days;
 691     $pmday -= $days;
 692   } elsif ( $freq =~ /^(\d+)h$/ ) {
 693     my $hours = $1;
 694     $nhour += $hours;
 695     $phour -= $hours;
 696   } else {
 697     return { 'error' => "unparsable frequency: ". $freq };
 698   }
 699
 700   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 701   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 702
 703
 704   {
 705     'error'     => '',
 706     'svcnum'    => $p->{svcnum},
 707     'beginning' => $p->{beginning},
 708     'ending'    => $p->{ending},
 709     'previous'  => ($previous > $start) ? $previous : $start,
 710     'next'      => ($next < $end) ? $next : $end,
 711     'usage'     => \@usage,
 712   };
 713 }
 714
 715 sub order_pkg {
 716   my $p = shift;
 717
 718   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 719   return { 'error' => $session } if $context eq 'error';
 720
 721   my $search = { 'custnum' => $custnum };
 722   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 723   my $cust_main = qsearchs('cust_main', $search )
 724     or return { 'error' => "unknown custnum $custnum" };
 725
 726   #false laziness w/ClientAPI/Signup.pm
 727
 728   my $cust_pkg = new FS::cust_pkg ( {
 729     'custnum' => $custnum,
 730     'pkgpart' => $p->{'pkgpart'},
 731   } );
 732   my $error = $cust_pkg->check;
 733   return { 'error' => $error } if $error;
 734
 735   my @svc = ();
 736   unless ( $p->{'svcpart'} eq 'none' ) {
 737
 738     my $svcdb;
 739     my $svcpart = '';
 740     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 741       $svcpart = $1;
 742       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 743       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 744       $svcdb = $part_svc->svcdb;
 745     } else {
 746       $svcdb = 'svc_acct';
 747     }
 748     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 749
 750     my %fields = (
 751       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 752       'svc_domain'   => [ qw( domain ) ],
 753       'svc_external' => [ qw( id title ) ],
 754     );
 755
 756     my $svc_x = "FS::$svcdb"->new( {
 757       'svcpart'   => $svcpart,
 758       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 759     } );
 760
 761     if ( $svcdb eq 'svc_acct' ) {
 762       my @acct_snarf;
 763       my $snarfnum = 1;
 764       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 765         my $acct_snarf = new FS::acct_snarf ( {
 766           'machine'   => $p->{"snarf_machine$snarfnum"},
 767           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 768           'username'  => $p->{"snarf_username$snarfnum"},
 769           '_password' => $p->{"snarf_password$snarfnum"},
 770         } );
 771         $snarfnum++;
 772         push @acct_snarf, $acct_snarf;
 773       }
 774       $svc_x->child_objects( \@acct_snarf );
 775     }
 776
 777     my $y = $svc_x->setdefault; # arguably should be in new method
 778     return { 'error' => $y } if $y && !ref($y);
 779
 780     $error = $svc_x->check;
 781     return { 'error' => $error } if $error;
 782
 783     push @svc, $svc_x;
 784
 785   }
 786
 787   use Tie::RefHash;
 788   tie my %hash, 'Tie::RefHash';
 789   %hash = ( $cust_pkg => \@svc );
 790   #msgcat
 791   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 792   return { 'error' => $error } if $error;
 793
 794   my $conf = new FS::Conf;
 795   if ( $conf->exists('signup_server-realtime') ) {
 796
 797     my $bill_error = _do_bop_realtime( $cust_main );
 798
 799     if ($bill_error) {
 800       $cust_pkg->cancel('quiet'=>1);
 801       return $bill_error;
 802     } else {
 803       $cust_pkg->reexport;
 804     }
 805
 806   } else {
 807     $cust_pkg->reexport;
 808   }
 809
 810   return { error => '', pkgnum => $cust_pkg->pkgnum };
 811
 812 }
 813
 814 sub change_pkg {
 815   my $p = shift;
 816
 817   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 818   return { 'error' => $session } if $context eq 'error';
 819
 820   my $search = { 'custnum' => $custnum };
 821   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 822   my $cust_main = qsearchs('cust_main', $search )
 823     or return { 'error' => "unknown custnum $custnum" };
 824
 825   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 826     or return { 'error' => "unknown package $p->{pkgnum}" };
 827
 828   my @newpkg;
 829   my $error = FS::cust_pkg::order( $custnum,
 830                                    [$p->{pkgpart}],
 831                                    [$p->{pkgnum}],
 832                                    \@newpkg,
 833                                  );
 834
 835   my $conf = new FS::Conf;
 836   if ( $conf->exists('signup_server-realtime') ) {
 837
 838     my $bill_error = _do_bop_realtime( $cust_main );
 839
 840     if ($bill_error) {
 841       $newpkg[0]->suspend;
 842       return $bill_error;
 843     } else {
 844       $newpkg[0]->reexport;
 845     }
 846
 847   } else {
 848     $newpkg[0]->reexport;
 849   }
 850
 851   return { error => '', pkgnum => $cust_pkg->pkgnum };
 852
 853 }
 854
 855 sub order_recharge {
 856   my $p = shift;
 857
 858   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 859   return { 'error' => $session } if $context eq 'error';
 860
 861   my $search = { 'custnum' => $custnum };
 862   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 863   my $cust_main = qsearchs('cust_main', $search )
 864     or return { 'error' => "unknown custnum $custnum" };
 865
 866   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 867     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 868
 869   my $svc_x = $cust_svc->svc_x;
 870   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 871
 872   my %vhash =
 873     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 874     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 875          recharge_totalbytes );
 876   my $amount = $part_pkg->option('recharge_amount', 1);
 877
 878   my ($l, $v, $d) = $cust_svc->label;  # blah
 879   my $pkg = "Recharge $v";
 880
 881   my $bill_error = $cust_main->charge($amount, $pkg,
 882      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 883      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 884      $part_pkg->taxclass); #meh
 885
 886   my $conf = new FS::Conf;
 887   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 888
 889     $bill_error = _do_bop_realtime( $cust_main );
 890
 891     if ($bill_error) {
 892       return $bill_error;
 893     } else {
 894       my $error = $svc_x->recharge (\%vhash);
 895       return { 'error' => $error } if $error;
 896     }
 897
 898   } else {
 899     my $error = $bill_error;
 900     $error ||= $svc_x->recharge (\%vhash);
 901     return { 'error' => $error } if $error;
 902   }
 903
 904   return { error => '', svc => $cust_svc->part_svc->svc };
 905
 906 }
 907
 908 sub _do_bop_realtime {
 909   my ($cust_main) = @_;
 910
 911     my $old_balance = $cust_main->balance;
 912
 913     my $bill_error =    $cust_main->bill
 914                      || $cust_main->apply_payments_and_credits
 915                      || $cust_main->collect('realtime' => 1);
 916
 917     if (    $cust_main->balance > $old_balance
 918          && $cust_main->balance > 0
 919          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 920       #this makes sense.  credit is "un-doing" the invoice
 921       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 922                           'self-service decline' );
 923       $cust_main->apply_credits( 'order' => 'newest' );
 924
 925       return { 'error' => '_decline', 'bill_error' => $bill_error };
 926     }
 927
 928     '';
 929 }
 930
 931 sub cancel_pkg {
 932   my $p = shift;
 933   my $session = _cache->get($p->{'session_id'})
 934     or return { 'error' => "Can't resume session" }; #better error message
 935
 936   my $custnum = $session->{'custnum'};
 937
 938   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 939     or return { 'error' => "unknown custnum $custnum" };
 940
 941   my $pkgnum = $p->{'pkgnum'};
 942
 943   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 944                                         'pkgnum'  => $pkgnum,   } )
 945     or return { 'error' => "unknown pkgnum $pkgnum" };
 946
 947   my $error = $cust_pkg->cancel( 'quiet'=>1 );
 948   return { 'error' => $error };
 949
 950 }
 951
 952 sub provision_acct {
 953   my $p = shift;
 954
 955   return { 'error' => gettext('passwords_dont_match') }
 956     if $p->{'_password'} ne $p->{'_password2'};
 957   return { 'error' => gettext('empty_password') }
 958     unless length($p->{'_password'});
 959
 960   _provision( 'FS::svc_acct',
 961               [qw(username _password)],
 962               [qw(username _password)],
 963               $p,
 964               @_
 965             );
 966 }
 967
 968 sub provision_external {
 969   my $p = shift;
 970   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
 971   _provision( 'FS::svc_external',
 972               [],
 973               [qw(id title)],
 974               $p,
 975               @_
 976             );
 977 }
 978
 979 sub _provision {
 980   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
 981
 982   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 983   return { 'error' => $session } if $context eq 'error';
 984
 985   my $search = { 'custnum' => $custnum };
 986   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 987   my $cust_main = qsearchs('cust_main', $search )
 988     or return { 'error' => "unknown custnum $custnum" };
 989
 990   my $pkgnum = $p->{'pkgnum'};
 991
 992   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 993                                         'pkgnum'  => $pkgnum,
 994                                                                } )
 995     or return { 'error' => "unknown pkgnum $pkgnum" };
 996
 997   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
 998     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
 999
1000   my $svc_x = $class->new( {
1001     'pkgnum'  => $p->{'pkgnum'},
1002     'svcpart' => $p->{'svcpart'},
1003     map { $_ => $p->{$_} } @$fields
1004   } );
1005   my $error = $svc_x->insert;
1006   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1007     unless $error;
1008
1009   return { 'svc'   => $part_svc->svc,
1010            'error' => $error,
1011            map { $_ => $svc_x->get($_) } @$return_fields
1012          };
1013
1014 }
1015
1016 sub part_svc_info {
1017   my $p = shift;
1018
1019   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1020   return { 'error' => $session } if $context eq 'error';
1021
1022   my $search = { 'custnum' => $custnum };
1023   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1024   my $cust_main = qsearchs('cust_main', $search )
1025     or return { 'error' => "unknown custnum $custnum" };
1026
1027   my $pkgnum = $p->{'pkgnum'};
1028
1029   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1030                                         'pkgnum'  => $pkgnum,
1031                                                                } )
1032     or return { 'error' => "unknown pkgnum $pkgnum" };
1033
1034   my $svcpart = $p->{'svcpart'};
1035
1036   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1037                                       'svcpart' => $svcpart,           } )
1038     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1039   my $part_svc = $pkg_svc->part_svc;
1040
1041   my $conf = new FS::Conf;
1042
1043   return {
1044     'svc'     => $part_svc->svc,
1045     'svcdb'   => $part_svc->svcdb,
1046     'pkgnum'  => $pkgnum,
1047     'svcpart' => $svcpart,
1048     'custnum' => $custnum,
1049
1050     'security_phrase' => 0, #XXX !
1051     'svc_acct_pop'    => [], #XXX !
1052     'popnum'          => '',
1053     'init_popstate'   => '',
1054     'popac'           => '',
1055     'acstate'         => '',
1056
1057     'small_custview' =>
1058       small_custview( $cust_main, $conf->config('countrydefault') ),
1059
1060   };
1061
1062 }
1063
1064 sub unprovision_svc {
1065   my $p = shift;
1066
1067   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1068   return { 'error' => $session } if $context eq 'error';
1069
1070   my $search = { 'custnum' => $custnum };
1071   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1072   my $cust_main = qsearchs('cust_main', $search )
1073     or return { 'error' => "unknown custnum $custnum" };
1074
1075   my $svcnum = $p->{'svcnum'};
1076
1077   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1078     or return { 'error' => "unknown svcnum $svcnum" };
1079
1080   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1081     unless $cust_svc->cust_pkg->custnum == $custnum;
1082
1083   my $conf = new FS::Conf;
1084
1085   return { 'svc'   => $cust_svc->part_svc->svc,
1086            'error' => $cust_svc->cancel,
1087            'small_custview' =>
1088              small_custview( $cust_main, $conf->config('countrydefault') ),
1089          };
1090
1091 }
1092
1093 sub myaccount_passwd {
1094   my $p = shift;
1095   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1096   return { 'error' => $session } if $context eq 'error';
1097
1098   return { 'error' => "New passwords don't match." }
1099     if $p->{'new_password'} ne $p->{'new_password2'};
1100
1101   return { 'error' => 'Enter new password' }
1102     unless length($p->{'new_password'});
1103
1104   #my $search = { 'custnum' => $custnum };
1105   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1106   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1107   my $search = " AND custnum = $1";
1108   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1109
1110   my $svc_acct = qsearchs( {
1111     'table'     => 'svc_acct',
1112     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1113                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1114                    'LEFT JOIN cust_main USING ( custnum ) ',
1115     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1116     'extra_sql' => $search, #important
1117   } )
1118     or return { 'error' => "Service not found" };
1119
1120   $svc_acct->_password($p->{'new_password'});
1121   my $error = $svc_acct->replace();
1122
1123   my($label, $value) = $svc_acct->cust_svc->label;
1124
1125   return { 'error' => $error,
1126            'label' => $label,
1127            'value' => $value,
1128          };
1129
1130 }
1131
1132 #--
1133
1134 sub _custoragent_session_custnum {
1135   my $p = shift;
1136
1137   my($context, $session, $custnum);
1138   if ( $p->{'session_id'} ) {
1139
1140     $context = 'customer';
1141     $session = _cache->get($p->{'session_id'})
1142       or return ( 'error' => "Can't resume session" ); #better error message
1143     $custnum = $session->{'custnum'};
1144
1145   } elsif ( $p->{'agent_session_id'} ) {
1146
1147     $context = 'agent';
1148     my $agent_cache = new FS::ClientAPI_SessionCache( {
1149       'namespace' => 'FS::ClientAPI::Agent',
1150     } );
1151     $session = $agent_cache->get($p->{'agent_session_id'})
1152       or return ( 'error' => "Can't resume session" ); #better error message
1153     $custnum = $p->{'custnum'};
1154
1155   } else {
1156     return ( 'error' => "Can't resume session" ); #better error message
1157   }
1158
1159   ($context, $session, $custnum);
1160
1161 }
1162
1163 1;
1164