FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::UI::Web;
  12 use FS::Conf;
  13 use FS::Record qw(qsearch qsearchs);
  14 use FS::Msgcat qw(gettext);
  15 use FS::Misc qw(card_types);
  16 use FS::ClientAPI_SessionCache;
  17 use FS::svc_acct;
  18 use FS::svc_domain;
  19 use FS::svc_external;
  20 use FS::part_svc;
  21 use FS::cust_main;
  22 use FS::cust_bill;
  23 use FS::cust_main_county;
  24 use FS::cust_pkg;
  25 use HTML::Entities;
  26
  27 #false laziness with FS::cust_main
  28 BEGIN {
  29   eval "use Time::Local;";
  30   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  31     if $] < 5.006 && !defined($Time::Local::VERSION);
  32   eval "use Time::Local qw(timelocal_nocheck);";
  33 }
  34
  35 use vars qw( @cust_main_editable_fields );
  36 @cust_main_editable_fields = qw(
  37   first last company address1 address2 city
  38     county state zip country daytime night fax
  39   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  40     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  41   payby payinfo payname paystart_month paystart_year payissue payip
  42 );
  43
  44 use subs qw(_provision);
  45
  46 sub _cache {
  47   $cache ||= new FS::ClientAPI_SessionCache( {
  48                'namespace' => 'FS::ClientAPI::MyAccount',
  49              } );
  50 }
  51
  52 #false laziness w/FS::ClientAPI::passwd::passwd
  53 sub login {
  54   my $p = shift;
  55
  56   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  57     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  58
  59   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  60                                          'domsvc'    => $svc_domain->svcnum, }
  61                          );
  62   return { error => 'User not found.' } unless $svc_acct;
  63
  64   my $conf = new FS::Conf;
  65   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  66   return { error => 'Only primary user may log in.' }
  67     if $conf->exists('selfservice_server-primary_only')
  68        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  69
  70   return { error => 'Incorrect password.' }
  71     unless $svc_acct->check_password($p->{'password'});
  72
  73   my $session = {
  74     'svcnum' => $svc_acct->svcnum,
  75   };
  76
  77   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  78   if ( $cust_pkg ) {
  79     my $cust_main = $cust_pkg->cust_main;
  80     $session->{'custnum'} = $cust_main->custnum;
  81   }
  82
  83   my $session_id;
  84   do {
  85     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  86   } until ( ! defined _cache->get($session_id) ); #just in case
  87
  88   _cache->set( $session_id, $session, '1 hour' );
  89
  90   return { 'error'      => '',
  91            'session_id' => $session_id,
  92          };
  93 }
  94
  95 sub logout {
  96   my $p = shift;
  97   if ( $p->{'session_id'} ) {
  98     _cache->remove($p->{'session_id'});
  99     return { 'error' => '' };
 100   } else {
 101     return { 'error' => "Can't resume session" }; #better error message
 102   }
 103 }
 104
 105 sub customer_info {
 106   my $p = shift;
 107
 108   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 109   return { 'error' => $session } if $context eq 'error';
 110
 111   my %return;
 112   if ( $custnum ) { #customer record
 113
 114     my $search = { 'custnum' => $custnum };
 115     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 116     my $cust_main = qsearchs('cust_main', $search )
 117       or return { 'error' => "unknown custnum $custnum" };
 118
 119     $return{balance} = $cust_main->balance;
 120
 121     my @open = map {
 122                      {
 123                        invnum => $_->invnum,
 124                        date   => time2str("%b %o, %Y", $_->_date),
 125                        owed   => $_->owed,
 126                      };
 127                    } $cust_main->open_cust_bill;
 128     $return{open_invoices} = \@open;
 129
 130     my $conf = new FS::Conf;
 131     $return{small_custview} =
 132       small_custview( $cust_main, $conf->config('countrydefault') );
 133
 134     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 135
 136     for (@cust_main_editable_fields) {
 137       $return{$_} = $cust_main->get($_);
 138     }
 139
 140     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 141       $return{payinfo} = $cust_main->paymask;
 142       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 143     }
 144
 145     $return{'invoicing_list'} =
 146       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 147     $return{'postal_invoicing'} =
 148       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 149
 150   } elsif ( $session->{'svcnum'} ) { #no customer record
 151
 152     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 153       or die "unknown svcnum";
 154     $return{name} = $svc_acct->email;
 155
 156   } else {
 157
 158     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 159
 160   }
 161
 162   return { 'error'          => '',
 163            'custnum'        => $custnum,
 164            %return,
 165          };
 166
 167 }
 168
 169 sub edit_info {
 170   my $p = shift;
 171   my $session = _cache->get($p->{'session_id'})
 172     or return { 'error' => "Can't resume session" }; #better error message
 173
 174   my $custnum = $session->{'custnum'}
 175     or return { 'error' => "no customer record" };
 176
 177   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 178     or return { 'error' => "unknown custnum $custnum" };
 179
 180   my $new = new FS::cust_main { $cust_main->hash };
 181   $new->set( $_ => $p->{$_} )
 182     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 183
 184   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 185     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 186     if ( $new->payinfo eq $cust_main->paymask ) {
 187       $new->payinfo($cust_main->payinfo);
 188     } else {
 189       $new->paycvv($p->{'paycvv'});
 190     }
 191   }
 192
 193   my @invoicing_list;
 194   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 195     #false laziness with httemplate/edit/process/cust_main.cgi
 196     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 197     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 198   } else {
 199     @invoicing_list = $cust_main->invoicing_list;
 200   }
 201
 202   my $error = $new->replace($cust_main, \@invoicing_list);
 203   return { 'error' => $error } if $error;
 204   #$cust_main = $new;
 205
 206   return { 'error' => '' };
 207 }
 208
 209 sub payment_info {
 210   my $p = shift;
 211   my $session = _cache->get($p->{'session_id'})
 212     or return { 'error' => "Can't resume session" }; #better error message
 213
 214   ##
 215   #generic
 216   ##
 217
 218   use vars qw($payment_info); #cache for performance
 219   unless ( $payment_info ) {
 220
 221     my $conf = new FS::Conf;
 222     my %states = map { $_->state => 1 }
 223                    qsearch('cust_main_county', {
 224                      'country' => $conf->config('countrydefault') || 'US'
 225                    } );
 226
 227     $payment_info = {
 228
 229       #list all counties/states/countries
 230       'cust_main_county' =>
 231         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 232
 233       #shortcut for one-country folks
 234       'states' =>
 235         [ sort { $a cmp $b } keys %states ],
 236
 237       'card_types' => card_types(),
 238
 239     };
 240
 241   }
 242
 243   ##
 244   #customer-specific
 245   ##
 246
 247   my %return = %$payment_info;
 248
 249   my $custnum = $session->{'custnum'};
 250
 251   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 252     or return { 'error' => "unknown custnum $custnum" };
 253
 254   $return{balance} = $cust_main->balance;
 255
 256   $return{payname} = $cust_main->payname
 257                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 258
 259   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 260
 261   $return{payby} = $cust_main->payby;
 262
 263   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 264     $return{card_type} = cardtype($cust_main->payinfo);
 265     $return{payinfo} = $cust_main->payinfo;
 266
 267     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 268
 269   }
 270
 271   #doubleclick protection
 272   my $_date = time;
 273   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 274
 275   return { 'error' => '',
 276            %return,
 277          };
 278
 279 };
 280
 281 #some false laziness with httemplate/process/payment.cgi - look there for
 282 #ACH and CVV support stuff
 283 sub process_payment {
 284
 285   my $p = shift;
 286
 287   my $session = _cache->get($p->{'session_id'})
 288     or return { 'error' => "Can't resume session" }; #better error message
 289
 290   my %return;
 291
 292   my $custnum = $session->{'custnum'};
 293
 294   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 295     or return { 'error' => "unknown custnum $custnum" };
 296
 297   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 298     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 299   my $payname = $1;
 300
 301   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 302     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 303   my $paybatch = $1;
 304
 305   my $payinfo;
 306   my $paycvv = '';
 307   #if ( $payby eq 'CHEK' ) {
 308   #
 309   #  $p->{'payinfo1'} =~ /^(\d+)$/
 310   #    or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 311   #  my $payinfo1 = $1;
 312   #   $p->{'payinfo2'} =~ /^(\d+)$/
 313   #    or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 314   #  my $payinfo2 = $1;
 315   #  $payinfo = $payinfo1. '@'. $payinfo2;
 316   #
 317   #} elsif ( $payby eq 'CARD' ) {
 318
 319     $payinfo = $p->{'payinfo'};
 320     $payinfo =~ s/\D//g;
 321     $payinfo =~ /^(\d{13,16})$/
 322       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 323     $payinfo = $1;
 324     validate($payinfo)
 325       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 326     return { 'error' => gettext('unknown_card_type') }
 327       if cardtype($payinfo) eq "Unknown";
 328
 329     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 330       if ( cardtype($payinfo) eq 'American Express card' ) {
 331         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 332           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 333         $paycvv = $1;
 334       } else {
 335         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 336           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 337         $paycvv = $1;
 338       }
 339     }
 340
 341   #} else {
 342   #  die "unknown payby $payby";
 343   #}
 344
 345   my $error = $cust_main->realtime_bop( 'CC', $p->{'amount'},
 346     'quiet'    => 1,
 347     'payinfo'  => $payinfo,
 348     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 349     'payname'  => $payname,
 350     'paybatch' => $paybatch,
 351     'paycvv'   => $paycvv,
 352     map { $_ => $p->{$_} } qw( paystart_month paystart_year payissue payip
 353                                address1 address2 city state zip )
 354   );
 355   return { 'error' => $error } if $error;
 356
 357   $cust_main->apply_payments;
 358
 359   if ( $p->{'save'} ) {
 360     my $new = new FS::cust_main { $cust_main->hash };
 361     $new->set( $_ => $p->{$_} )
 362       foreach qw( payname paystart_month paystart_year payissue payip
 363                   address1 address2 city state zip payinfo );
 364     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 365     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 366     my $error = $new->replace($cust_main);
 367     return { 'error' => $error } if $error;
 368     $cust_main = $new;
 369   }
 370
 371   return { 'error' => '' };
 372
 373 }
 374
 375 sub process_prepay {
 376
 377   my $p = shift;
 378
 379   my $session = _cache->get($p->{'session_id'})
 380     or return { 'error' => "Can't resume session" }; #better error message
 381
 382   my %return;
 383
 384   my $custnum = $session->{'custnum'};
 385
 386   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 387     or return { 'error' => "unknown custnum $custnum" };
 388
 389   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 390   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 391                                            \$amount,
 392                                            \$seconds,
 393                                            \$upbytes,
 394                                            \$downbytes,
 395                                            \$totalbytes,
 396                                          );
 397
 398   return { 'error' => $error } if $error;
 399
 400   return { 'error'     => '',
 401            'amount'    => $amount,
 402            'seconds'   => $seconds,
 403            'duration'  => duration_exact($seconds),
 404            'upbytes'   => $upbytes,
 405            'upload'    => FS::UI::Web::bytecount_unexact($upbytes),
 406            'downbytes' => $downbytes,
 407            'download'  => FS::UI::Web::bytecount_unexact($downbytes),
 408            'totalbytes'=> $totalbytes,
 409            'totalload' => FS::UI::Web::bytecount_unexact($totalbytes),
 410          };
 411
 412 }
 413
 414 sub invoice {
 415   my $p = shift;
 416   my $session = _cache->get($p->{'session_id'})
 417     or return { 'error' => "Can't resume session" }; #better error message
 418
 419   my $custnum = $session->{'custnum'};
 420
 421   my $invnum = $p->{'invnum'};
 422
 423   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 424                                           'custnum' => $custnum } )
 425     or return { 'error' => "Can't find invnum" };
 426
 427   #my %return;
 428
 429   return { 'error'        => '',
 430            'invnum'       => $invnum,
 431            'invoice_text' => join('', $cust_bill->print_text ),
 432            'invoice_html' => $cust_bill->print_html,
 433          };
 434
 435 }
 436
 437 sub invoice_logo {
 438   my $p = shift;
 439
 440   #sessioning for this?  how do we get the session id to the backend invoice
 441   # template so it can add it to the link, blah
 442
 443   my $templatename = $p->{'templatename'};
 444
 445   #false laziness-ish w/view/cust_bill-logo.cgi
 446
 447   my $conf = new FS::Conf;
 448   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 449     $templatename = "_$1";
 450   } else {
 451     $templatename = '';
 452   }
 453
 454   my $filename = "logo$templatename.png";
 455
 456   return { 'error'        => '',
 457            'logo'         => $conf->config_binary($filename),
 458            'content_type' => 'image/png', #should allow gif, jpg too
 459          };
 460 }
 461
 462
 463 sub list_invoices {
 464   my $p = shift;
 465   my $session = _cache->get($p->{'session_id'})
 466     or return { 'error' => "Can't resume session" }; #better error message
 467
 468   my $custnum = $session->{'custnum'};
 469
 470   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 471     or return { 'error' => "unknown custnum $custnum" };
 472
 473   my @cust_bill = $cust_main->cust_bill;
 474
 475   return  { 'error'       => '',
 476             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 477                                         '_date'  => $_->_date,
 478                                       }
 479                                     } @cust_bill
 480                               ]
 481           };
 482 }
 483
 484 sub cancel {
 485   my $p = shift;
 486   my $session = _cache->get($p->{'session_id'})
 487     or return { 'error' => "Can't resume session" }; #better error message
 488
 489   my $custnum = $session->{'custnum'};
 490
 491   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 492     or return { 'error' => "unknown custnum $custnum" };
 493
 494   my @errors = $cust_main->cancel( 'quiet'=>1 );
 495
 496   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 497
 498   return { 'error' => $error };
 499
 500 }
 501
 502 sub list_pkgs {
 503   my $p = shift;
 504
 505   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 506   return { 'error' => $session } if $context eq 'error';
 507
 508   my $search = { 'custnum' => $custnum };
 509   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 510   my $cust_main = qsearchs('cust_main', $search )
 511     or return { 'error' => "unknown custnum $custnum" };
 512
 513   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 514
 515   my $conf = new FS::Conf;
 516
 517   { 'svcnum'   => $session->{'svcnum'},
 518     'custnum'  => $custnum,
 519     'cust_pkg' => [ map {
 520                           { $_->hash,
 521                             $_->part_pkg->hash,
 522                             part_svc =>
 523                               [ map $_->hashref, $_->available_part_svc ],
 524                             cust_svc =>
 525                               [ map { my $ref = { $_->hash,
 526                                                   label => [ $_->label ],
 527                                                 };
 528                                       $ref->{_password} = $_->svc_x->_password
 529                                         if $context eq 'agent'
 530                                         && $conf->exists('agent-showpasswords')
 531                                         && $_->part_svc->svcdb eq 'svc_acct';
 532                                       $ref;
 533                                     } $_->cust_svc
 534                               ],
 535                           };
 536                         } $cust_main->ncancelled_pkgs
 537                   ],
 538     'small_custview' =>
 539       small_custview( $cust_main, $conf->config('countrydefault') ),
 540   };
 541
 542 }
 543
 544 sub list_svcs {
 545   my $p = shift;
 546
 547   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 548   return { 'error' => $session } if $context eq 'error';
 549
 550   my $search = { 'custnum' => $custnum };
 551   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 552   my $cust_main = qsearchs('cust_main', $search )
 553     or return { 'error' => "unknown custnum $custnum" };
 554
 555   my @cust_svc = ();
 556   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 557   foreach my $cust_pkg ( $p->{'ncancelled'}
 558                          ? $cust_main->ncancelled_pkgs
 559                          : $cust_main->unsuspended_pkgs ) {
 560     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 561   }
 562   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 563     if $p->{'svcdb'};
 564
 565   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 566   #              @svc_x;
 567
 568   {
 569     #no#'svcnum'   => $session->{'svcnum'},
 570     'custnum'  => $custnum,
 571     'svcs'     => [ map {
 572                           my $svc_x = $_->svc_x;
 573                           my($label, $value) = $_->label;
 574                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 575
 576                           { 'svcnum'    => $_->svcnum,
 577                             'label'     => $label,
 578                             'value'     => $value,
 579                             'username'  => $svc_x->username,
 580                             'email'     => $svc_x->email,
 581                             'seconds'   => $svc_x->seconds,
 582                             'upbytes'   => $svc_x->upbytes,
 583                             'downbytes' => $svc_x->downbytes,
 584                             'totalbytes'=> $svc_x->totalbytes,
 585                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 586                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 587                             'recharge_upbytes' => $part_pkg->option('recharge_upbytes', 1),
 588                             'recharge_downbytes' => $part_pkg->option('recharge_downbytes', 1),
 589                             'recharge_totalbytes' => $part_pkg->option('recharge_totalbytes', 1),
 590                             # more...
 591                           };
 592                         }
 593                         @cust_svc
 594                   ],
 595   };
 596
 597 }
 598
 599 sub list_svc_usage {
 600   my $p = shift;
 601
 602   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 603   return { 'error' => $session } if $context eq 'error';
 604
 605   my $search = { 'svcnum' => $p->{'svcnum'} };
 606   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 607   my $svc_acct = qsearchs ( 'svc_acct', $search );
 608   return { 'error' => 'No service selected in list_svc_usage' }
 609     unless $svc_acct;
 610
 611   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 612   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 613   my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 614
 615   unless($p->{beginning}){
 616     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 617     $p->{ending} = $end;
 618   }
 619   my @usage = ();
 620
 621   foreach my $part_export (
 622     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 623     qw (sqlradius sqlradius_withdomain')
 624   ) {
 625
 626     push @usage, @ { $part_export->usage_sessions($p->{beginning},
 627                                                   $p->{ending},
 628                                                   $svc_acct)
 629                    };
 630   }
 631
 632   #kinda false laziness with FS::cust_main::bill, but perhaps
 633   #we should really change this bit to DateTime and DateTime::Duration
 634   #
 635   #change this bit to use Date::Manip? CAREFUL with timezones (see
 636   # mailing list archive)
 637   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 638     (localtime($p->{ending}) )[0,1,2,3,4,5];
 639   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 640     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 641
 642   if ( $freq =~ /^\d+$/ ) {
 643     $nmon += $freq;
 644     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 645     $pmon -= $freq;
 646     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 647   } elsif ( $freq =~ /^(\d+)w$/ ) {
 648     my $weeks = $1;
 649     $nmday += $weeks * 7;
 650     $pmday -= $weeks * 7;
 651   } elsif ( $freq =~ /^(\d+)d$/ ) {
 652     my $days = $1;
 653     $nmday += $days;
 654     $pmday -= $days;
 655   } elsif ( $freq =~ /^(\d+)h$/ ) {
 656     my $hours = $1;
 657     $nhour += $hours;
 658     $phour -= $hours;
 659   } else {
 660     return { 'error' => "unparsable frequency: ". $freq };
 661   }
 662
 663   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 664   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 665
 666
 667   {
 668     'error'     => '',
 669     'svcnum'    => $p->{svcnum},
 670     'beginning' => $p->{beginning},
 671     'ending'    => $p->{ending},
 672     'previous'  => ($previous > $start) ? $previous : $start,
 673     'next'      => ($next < $end) ? $next : $end,
 674     'usage'     => \@usage,
 675   };
 676 }
 677
 678 sub order_pkg {
 679   my $p = shift;
 680
 681   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 682   return { 'error' => $session } if $context eq 'error';
 683
 684   my $search = { 'custnum' => $custnum };
 685   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 686   my $cust_main = qsearchs('cust_main', $search )
 687     or return { 'error' => "unknown custnum $custnum" };
 688
 689   #false laziness w/ClientAPI/Signup.pm
 690
 691   my $cust_pkg = new FS::cust_pkg ( {
 692     'custnum' => $custnum,
 693     'pkgpart' => $p->{'pkgpart'},
 694   } );
 695   my $error = $cust_pkg->check;
 696   return { 'error' => $error } if $error;
 697
 698   my @svc = ();
 699   unless ( $p->{'svcpart'} eq 'none' ) {
 700
 701     my $svcdb;
 702     my $svcpart = '';
 703     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 704       $svcpart = $1;
 705       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 706       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 707       $svcdb = $part_svc->svcdb;
 708     } else {
 709       $svcdb = 'svc_acct';
 710     }
 711     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 712
 713     my %fields = (
 714       'svc_acct'     => [ qw( username _password sec_phrase popnum ) ],
 715       'svc_domain'   => [ qw( domain ) ],
 716       'svc_external' => [ qw( id title ) ],
 717     );
 718
 719     my $svc_x = "FS::$svcdb"->new( {
 720       'svcpart'   => $svcpart,
 721       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 722     } );
 723
 724     if ( $svcdb eq 'svc_acct' ) {
 725       my @acct_snarf;
 726       my $snarfnum = 1;
 727       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 728         my $acct_snarf = new FS::acct_snarf ( {
 729           'machine'   => $p->{"snarf_machine$snarfnum"},
 730           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 731           'username'  => $p->{"snarf_username$snarfnum"},
 732           '_password' => $p->{"snarf_password$snarfnum"},
 733         } );
 734         $snarfnum++;
 735         push @acct_snarf, $acct_snarf;
 736       }
 737       $svc_x->child_objects( \@acct_snarf );
 738     }
 739
 740     my $y = $svc_x->setdefault; # arguably should be in new method
 741     return { 'error' => $y } if $y && !ref($y);
 742
 743     $error = $svc_x->check;
 744     return { 'error' => $error } if $error;
 745
 746     push @svc, $svc_x;
 747
 748   }
 749
 750   use Tie::RefHash;
 751   tie my %hash, 'Tie::RefHash';
 752   %hash = ( $cust_pkg => \@svc );
 753   #msgcat
 754   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 755   return { 'error' => $error } if $error;
 756
 757   my $conf = new FS::Conf;
 758   if ( $conf->exists('signup_server-realtime') ) {
 759
 760     my $bill_error = _do_bop_realtime( $cust_main );
 761
 762     if ($bill_error) {
 763       $cust_pkg->cancel('quiet'=>1);
 764       return $bill_error;
 765     } else {
 766       $cust_pkg->reexport;
 767     }
 768
 769   } else {
 770     $cust_pkg->reexport;
 771   }
 772
 773   return { error => '', pkgnum => $cust_pkg->pkgnum };
 774
 775 }
 776
 777 sub change_pkg {
 778   my $p = shift;
 779
 780   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 781   return { 'error' => $session } if $context eq 'error';
 782
 783   my $search = { 'custnum' => $custnum };
 784   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 785   my $cust_main = qsearchs('cust_main', $search )
 786     or return { 'error' => "unknown custnum $custnum" };
 787
 788   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 789     or return { 'error' => "unknown package $p->{pkgnum}" };
 790
 791   my @newpkg;
 792   my $error = FS::cust_pkg::order( $custnum,
 793                                    [$p->{pkgpart}],
 794                                    [$p->{pkgnum}],
 795                                    \@newpkg,
 796                                  );
 797
 798   my $conf = new FS::Conf;
 799   if ( $conf->exists('signup_server-realtime') ) {
 800
 801     my $bill_error = _do_bop_realtime( $cust_main );
 802
 803     if ($bill_error) {
 804       $newpkg[0]->suspend;
 805       return $bill_error;
 806     } else {
 807       $newpkg[0]->reexport;
 808     }
 809
 810   } else {
 811     $newpkg[0]->reexport;
 812   }
 813
 814   return { error => '', pkgnum => $cust_pkg->pkgnum };
 815
 816 }
 817
 818 sub order_recharge {
 819   my $p = shift;
 820
 821   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 822   return { 'error' => $session } if $context eq 'error';
 823
 824   my $search = { 'custnum' => $custnum };
 825   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 826   my $cust_main = qsearchs('cust_main', $search )
 827     or return { 'error' => "unknown custnum $custnum" };
 828
 829   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 830     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 831
 832   my $svc_x = $cust_svc->svc_x;
 833   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 834
 835   my %vhash =
 836     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 837     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 838          recharge_totalbytes );
 839   my $amount = $part_pkg->option('recharge_amount', 1);
 840
 841   my ($l, $v, $d) = $cust_svc->label;  # blah
 842   my $pkg = "Recharge $v";
 843
 844   my $bill_error = $cust_main->charge($amount, $pkg,
 845      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 846      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 847      $part_pkg->taxclass); #meh
 848
 849   my $conf = new FS::Conf;
 850   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 851
 852     $bill_error = _do_bop_realtime( $cust_main );
 853
 854     if ('bill_error') {
 855       return $bill_error;
 856     } else {
 857       my $error = $svc_x->recharge (\%vhash);
 858       return { 'error' => $error } if $error;
 859     }
 860
 861   } else {
 862     my $error = $bill_error;
 863     $error ||= $svc_x->recharge (\%vhash);
 864     return { 'error' => $error } if $error;
 865   }
 866
 867   return { error => '', svc => $cust_svc->part_svc->svc };
 868
 869 }
 870
 871 sub _do_bop_realtime {
 872   my ($cust_main) = @_;
 873
 874     my $old_balance = $cust_main->balance;
 875
 876     my $bill_error = $cust_main->bill;
 877
 878     $cust_main->apply_payments_and_credits;
 879     $bill_error = $cust_main->collect('realtime' => 1);
 880
 881     if (    $cust_main->balance > $old_balance
 882          && $cust_main->balance > 0
 883          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 884       #this makes sense.  credit is "un-doing" the invoice
 885       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 886                           'self-service decline' );
 887       $cust_main->apply_credits( 'order' => 'newest' );
 888
 889       return { 'error' => '_decline', 'bill_error' => $bill_error };
 890     }
 891
 892     '';
 893 }
 894
 895 sub cancel_pkg {
 896   my $p = shift;
 897   my $session = _cache->get($p->{'session_id'})
 898     or return { 'error' => "Can't resume session" }; #better error message
 899
 900   my $custnum = $session->{'custnum'};
 901
 902   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 903     or return { 'error' => "unknown custnum $custnum" };
 904
 905   my $pkgnum = $p->{'pkgnum'};
 906
 907   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 908                                         'pkgnum'  => $pkgnum,   } )
 909     or return { 'error' => "unknown pkgnum $pkgnum" };
 910
 911   my $error = $cust_pkg->cancel( 'quiet'=>1 );
 912   return { 'error' => $error };
 913
 914 }
 915
 916 sub provision_acct {
 917   my $p = shift;
 918
 919   return { 'error' => gettext('passwords_dont_match') }
 920     if $p->{'_password'} ne $p->{'_password2'};
 921   return { 'error' => gettext('empty_password') }
 922     unless length($p->{'_password'});
 923
 924   _provision( 'FS::svc_acct',
 925               [qw(username _password)],
 926               [qw(username _password)],
 927               $p,
 928               @_
 929             );
 930 }
 931
 932 sub provision_external {
 933   my $p = shift;
 934   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
 935   _provision( 'FS::svc_external',
 936               [],
 937               [qw(id title)],
 938               $p,
 939               @_
 940             );
 941 }
 942
 943 sub _provision {
 944   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
 945
 946   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 947   return { 'error' => $session } if $context eq 'error';
 948
 949   my $search = { 'custnum' => $custnum };
 950   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 951   my $cust_main = qsearchs('cust_main', $search )
 952     or return { 'error' => "unknown custnum $custnum" };
 953
 954   my $pkgnum = $p->{'pkgnum'};
 955
 956   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 957                                         'pkgnum'  => $pkgnum,
 958                                                                } )
 959     or return { 'error' => "unknown pkgnum $pkgnum" };
 960
 961   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
 962     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
 963
 964   my $svc_x = $class->new( {
 965     'pkgnum'  => $p->{'pkgnum'},
 966     'svcpart' => $p->{'svcpart'},
 967     map { $_ => $p->{$_} } @$fields
 968   } );
 969   my $error = $svc_x->insert;
 970   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
 971     unless $error;
 972
 973   return { 'svc'   => $part_svc->svc,
 974            'error' => $error,
 975            map { $_ => $svc_x->get($_) } @$return_fields
 976          };
 977
 978 }
 979
 980 sub part_svc_info {
 981   my $p = shift;
 982
 983   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 984   return { 'error' => $session } if $context eq 'error';
 985
 986   my $search = { 'custnum' => $custnum };
 987   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 988   my $cust_main = qsearchs('cust_main', $search )
 989     or return { 'error' => "unknown custnum $custnum" };
 990
 991   my $pkgnum = $p->{'pkgnum'};
 992
 993   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 994                                         'pkgnum'  => $pkgnum,
 995                                                                } )
 996     or return { 'error' => "unknown pkgnum $pkgnum" };
 997
 998   my $svcpart = $p->{'svcpart'};
 999
1000   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1001                                       'svcpart' => $svcpart,           } )
1002     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1003   my $part_svc = $pkg_svc->part_svc;
1004
1005   my $conf = new FS::Conf;
1006
1007   return {
1008     'svc'     => $part_svc->svc,
1009     'svcdb'   => $part_svc->svcdb,
1010     'pkgnum'  => $pkgnum,
1011     'svcpart' => $svcpart,
1012     'custnum' => $custnum,
1013
1014     'security_phrase' => 0, #XXX !
1015     'svc_acct_pop'    => [], #XXX !
1016     'popnum'          => '',
1017     'init_popstate'   => '',
1018     'popac'           => '',
1019     'acstate'         => '',
1020
1021     'small_custview' =>
1022       small_custview( $cust_main, $conf->config('countrydefault') ),
1023
1024   };
1025
1026 }
1027
1028 sub unprovision_svc {
1029   my $p = shift;
1030
1031   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1032   return { 'error' => $session } if $context eq 'error';
1033
1034   my $search = { 'custnum' => $custnum };
1035   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1036   my $cust_main = qsearchs('cust_main', $search )
1037     or return { 'error' => "unknown custnum $custnum" };
1038
1039   my $svcnum = $p->{'svcnum'};
1040
1041   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1042     or return { 'error' => "unknown svcnum $svcnum" };
1043
1044   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1045     unless $cust_svc->cust_pkg->custnum == $custnum;
1046
1047   my $conf = new FS::Conf;
1048
1049   return { 'svc'   => $cust_svc->part_svc->svc,
1050            'error' => $cust_svc->cancel,
1051            'small_custview' =>
1052              small_custview( $cust_main, $conf->config('countrydefault') ),
1053          };
1054
1055 }
1056
1057 sub myaccount_passwd {
1058   my $p = shift;
1059   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1060   return { 'error' => $session } if $context eq 'error';
1061
1062   return { 'error' => "New passwords don't match." }
1063     if $p->{'new_password'} ne $p->{'new_password2'};
1064
1065   return { 'error' => 'Enter new password' }
1066     unless length($p->{'new_password'});
1067
1068   #my $search = { 'custnum' => $custnum };
1069   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1070   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1071   my $search = " AND custnum = $1";
1072   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1073
1074   my $svc_acct = qsearchs( {
1075     'table'     => 'svc_acct',
1076     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1077                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1078                    'LEFT JOIN cust_main USING ( custnum ) ',
1079     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1080     'extra_sql' => $search, #important
1081   } )
1082     or return { 'error' => "Service not found" };
1083
1084   $svc_acct->_password($p->{'new_password'});
1085   my $error = $svc_acct->replace();
1086
1087   my($label, $value) = $svc_acct->cust_svc->label;
1088
1089   return { 'error' => $error,
1090            'label' => $label,
1091            'value' => $value,
1092          };
1093
1094 }
1095
1096 #--
1097
1098 sub _custoragent_session_custnum {
1099   my $p = shift;
1100
1101   my($context, $session, $custnum);
1102   if ( $p->{'session_id'} ) {
1103
1104     $context = 'customer';
1105     $session = _cache->get($p->{'session_id'})
1106       or return ( 'error' => "Can't resume session" ); #better error message
1107     $custnum = $session->{'custnum'};
1108
1109   } elsif ( $p->{'agent_session_id'} ) {
1110
1111     $context = 'agent';
1112     my $agent_cache = new FS::ClientAPI_SessionCache( {
1113       'namespace' => 'FS::ClientAPI::Agent',
1114     } );
1115     $session = $agent_cache->get($p->{'agent_session_id'})
1116       or return ( 'error' => "Can't resume session" ); #better error message
1117     $custnum = $p->{'custnum'};
1118
1119   } else {
1120     return ( 'error' => "Can't resume session" ); #better error message
1121   }
1122
1123   ($context, $session, $custnum);
1124
1125 }
1126
1127 1;
1128