FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw( $cache $DEBUG );
   5 use subs qw( _cache _provision );
   6 use Data::Dumper;
   7 use Digest::MD5 qw(md5_hex);
   8 use Date::Format;
   9 use Business::CreditCard;
  10 use Time::Duration;
  11 use FS::UI::Web::small_custview qw(small_custview); #less doh
  12 use FS::UI::Web;
  13 use FS::UI::bytecount;
  14 use FS::Conf;
  15 use FS::Record qw(qsearch qsearchs);
  16 use FS::Msgcat qw(gettext);
  17 use FS::Misc qw(card_types);
  18 use FS::ClientAPI_SessionCache;
  19 use FS::svc_acct;
  20 use FS::svc_domain;
  21 use FS::svc_external;
  22 use FS::part_svc;
  23 use FS::cust_main;
  24 use FS::cust_bill;
  25 use FS::cust_main_county;
  26 use FS::cust_pkg;
  27 use FS::payby;
  28 use HTML::Entities;
  29
  30 $DEBUG = 0;
  31
  32 #false laziness with FS::cust_main
  33 BEGIN {
  34   eval "use Time::Local;";
  35   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  36     if $] < 5.006 && !defined($Time::Local::VERSION);
  37   eval "use Time::Local qw(timelocal_nocheck);";
  38 }
  39
  40 use vars qw( @cust_main_editable_fields );
  41 @cust_main_editable_fields = qw(
  42   first last company address1 address2 city
  43     county state zip country daytime night fax
  44   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  45     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  46   payby payinfo payname paystart_month paystart_year payissue payip
  47   ss paytype paystate stateid stateid_state
  48 );
  49
  50 sub _cache {
  51   $cache ||= new FS::ClientAPI_SessionCache( {
  52                'namespace' => 'FS::ClientAPI::MyAccount',
  53              } );
  54 }
  55
  56 #false laziness w/FS::ClientAPI::passwd::passwd
  57 sub login {
  58   my $p = shift;
  59
  60   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  61     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  62
  63   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  64                                          'domsvc'    => $svc_domain->svcnum, }
  65                          );
  66   return { error => 'User not found.' } unless $svc_acct;
  67
  68   my $conf = new FS::Conf;
  69
  70   #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  71   #return { error => 'Only primary user may log in.' }
  72   #  if $conf->exists('selfservice_server-primary_only')
  73   #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  74   my $cust_svc = $svc_acct->cust_svc;
  75   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
  76   return { error => 'Only primary user may log in.' }
  77     if $conf->exists('selfservice_server-primary_only')
  78       && $cust_svc->svcpart != $part_pkg->svcpart('svc_acct');
  79
  80   return { error => 'Incorrect password.' }
  81     unless $svc_acct->check_password($p->{'password'});
  82
  83   my $session = {
  84     'svcnum' => $svc_acct->svcnum,
  85   };
  86
  87   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  88   if ( $cust_pkg ) {
  89     my $cust_main = $cust_pkg->cust_main;
  90     $session->{'custnum'} = $cust_main->custnum;
  91   }
  92
  93   my $session_id;
  94   do {
  95     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  96   } until ( ! defined _cache->get($session_id) ); #just in case
  97
  98   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
  99   _cache->set( $session_id, $session, $timeout );
 100
 101   return { 'error'      => '',
 102            'session_id' => $session_id,
 103          };
 104 }
 105
 106 sub logout {
 107   my $p = shift;
 108   if ( $p->{'session_id'} ) {
 109     _cache->remove($p->{'session_id'});
 110     return { 'error' => '' };
 111   } else {
 112     return { 'error' => "Can't resume session" }; #better error message
 113   }
 114 }
 115
 116 sub customer_info {
 117   my $p = shift;
 118
 119   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 120   return { 'error' => $session } if $context eq 'error';
 121
 122   my %return;
 123
 124   my $conf = new FS::Conf;
 125   if ($conf->exists('cust_main-require_address2')) {
 126     $return{'require_address2'} = '1';
 127   }else{
 128     $return{'require_address2'} = '';
 129   }
 130
 131   if ( $custnum ) { #customer record
 132
 133     my $search = { 'custnum' => $custnum };
 134     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 135     my $cust_main = qsearchs('cust_main', $search )
 136       or return { 'error' => "unknown custnum $custnum" };
 137
 138     $return{balance} = $cust_main->balance;
 139
 140     my @open = map {
 141                      {
 142                        invnum => $_->invnum,
 143                        date   => time2str("%b %o, %Y", $_->_date),
 144                        owed   => $_->owed,
 145                      };
 146                    } $cust_main->open_cust_bill;
 147     $return{open_invoices} = \@open;
 148
 149     $return{small_custview} =
 150       small_custview( $cust_main, $conf->config('countrydefault') );
 151
 152     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 153
 154     for (@cust_main_editable_fields) {
 155       $return{$_} = $cust_main->get($_);
 156     }
 157
 158     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 159       $return{payinfo} = $cust_main->paymask;
 160       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 161     }
 162
 163     $return{'invoicing_list'} =
 164       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 165     $return{'postal_invoicing'} =
 166       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 167
 168   } elsif ( $session->{'svcnum'} ) { #no customer record
 169
 170     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 171       or die "unknown svcnum";
 172     $return{name} = $svc_acct->email;
 173
 174   } else {
 175
 176     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 177
 178   }
 179
 180   return { 'error'          => '',
 181            'custnum'        => $custnum,
 182            %return,
 183          };
 184
 185 }
 186
 187 sub edit_info {
 188   my $p = shift;
 189   my $session = _cache->get($p->{'session_id'})
 190     or return { 'error' => "Can't resume session" }; #better error message
 191
 192   my $custnum = $session->{'custnum'}
 193     or return { 'error' => "no customer record" };
 194
 195   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 196     or return { 'error' => "unknown custnum $custnum" };
 197
 198   my $new = new FS::cust_main { $cust_main->hash };
 199   $new->set( $_ => $p->{$_} )
 200     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 201
 202   my $payby = '';
 203   if (exists($p->{'payby'})) {
 204     $p->{'payby'} =~ /^([A-Z]{4})$/
 205       or return { 'error' => "illegal_payby " . $p->{'payby'} };
 206     $payby = $1;
 207   }
 208
 209   if ( $payby =~ /^(CARD|DCRD)$/ ) {
 210
 211     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 212
 213     if ( $new->payinfo eq $cust_main->paymask ) {
 214       $new->payinfo($cust_main->payinfo);
 215     } else {
 216       $new->payinfo($p->{'payinfo'});
 217     }
 218
 219     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 220
 221   }elsif ( $payby =~ /^(CHEK|DCHK)$/ ) {
 222     my $payinfo;
 223     $p->{'payinfo1'} =~ /^([\dx]+)$/
 224       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 225     my $payinfo1 = $1;
 226      $p->{'payinfo2'} =~ /^([\dx]+)$/
 227       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 228     my $payinfo2 = $1;
 229     $payinfo = $payinfo1. '@'. $payinfo2;
 230
 231     if ( $payinfo eq $cust_main->paymask ) {
 232       $new->payinfo($cust_main->payinfo);
 233     } else {
 234       $new->payinfo($payinfo);
 235     }
 236
 237     $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 238
 239   }elsif ( $payby =~ /^(BILL)$/ ) {
 240   } elsif ( $payby ) {  #notyet ready
 241     return { 'error' => "unknown payby $payby" };
 242   }
 243
 244   my @invoicing_list;
 245   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 246     #false laziness with httemplate/edit/process/cust_main.cgi
 247     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 248     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 249   } else {
 250     @invoicing_list = $cust_main->invoicing_list;
 251   }
 252
 253   my $error = $new->replace($cust_main, \@invoicing_list);
 254   return { 'error' => $error } if $error;
 255   #$cust_main = $new;
 256
 257   return { 'error' => '' };
 258 }
 259
 260 sub payment_info {
 261   my $p = shift;
 262   my $session = _cache->get($p->{'session_id'})
 263     or return { 'error' => "Can't resume session" }; #better error message
 264
 265   ##
 266   #generic
 267   ##
 268
 269   use vars qw($payment_info); #cache for performance
 270   unless ( $payment_info ) {
 271
 272     my $conf = new FS::Conf;
 273     my %states = map { $_->state => 1 }
 274                    qsearch('cust_main_county', {
 275                      'country' => $conf->config('countrydefault') || 'US'
 276                    } );
 277
 278     $payment_info = {
 279
 280       #list all counties/states/countries
 281       'cust_main_county' =>
 282         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 283
 284       #shortcut for one-country folks
 285       'states' =>
 286         [ sort { $a cmp $b } keys %states ],
 287
 288       'card_types' => card_types(),
 289
 290       'paytypes' => [ @FS::cust_main::paytypes ],
 291
 292       'paybys' => [ $conf->config('signup_server-payby') ],
 293
 294       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 295       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 296
 297       'show_ss'  => $conf->exists('show_ss'),
 298       'show_stateid' => $conf->exists('show_stateid'),
 299       'show_paystate' => $conf->exists('show_bankstate'),
 300     };
 301
 302   }
 303
 304   ##
 305   #customer-specific
 306   ##
 307
 308   my %return = %$payment_info;
 309
 310   my $custnum = $session->{'custnum'};
 311
 312   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 313     or return { 'error' => "unknown custnum $custnum" };
 314
 315   $return{balance} = $cust_main->balance;
 316
 317   $return{payname} = $cust_main->payname
 318                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 319
 320   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 321
 322   $return{payby} = $cust_main->payby;
 323   $return{stateid_state} = $cust_main->stateid_state;
 324
 325   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 326     $return{card_type} = cardtype($cust_main->payinfo);
 327     $return{payinfo} = $cust_main->paymask;
 328
 329     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 330
 331   }
 332
 333   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 334     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 335     $return{payinfo1} = $payinfo1;
 336     $return{payinfo2} = $payinfo2;
 337     $return{paytype}  = $cust_main->paytype;
 338     $return{paystate} = $cust_main->paystate;
 339
 340   }
 341
 342   #doubleclick protection
 343   my $_date = time;
 344   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 345
 346   return { 'error' => '',
 347            %return,
 348          };
 349
 350 };
 351
 352 #some false laziness with httemplate/process/payment.cgi - look there for
 353 #ACH and CVV support stuff
 354 sub process_payment {
 355
 356   my $p = shift;
 357
 358   my $session = _cache->get($p->{'session_id'})
 359     or return { 'error' => "Can't resume session" }; #better error message
 360
 361   my %return;
 362
 363   my $custnum = $session->{'custnum'};
 364
 365   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 366     or return { 'error' => "unknown custnum $custnum" };
 367
 368   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 369     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 370   my $payname = $1;
 371
 372   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 373     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 374   my $paybatch = $1;
 375
 376   $p->{'payby'} = 'CARD' unless exists($p->{'payby'});
 377   $p->{'payby'} =~ /^([A-Z]{4})$/
 378     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 379   my $payby = $1;
 380
 381   #false laziness w/process/payment.cgi
 382   my $payinfo;
 383   my $paycvv = '';
 384   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 385
 386     $p->{'payinfo1'} =~ /^([\dx]+)$/
 387       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 388     my $payinfo1 = $1;
 389      $p->{'payinfo2'} =~ /^([\dx]+)$/
 390       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 391     my $payinfo2 = $1;
 392     $payinfo = $payinfo1. '@'. $payinfo2;
 393
 394     $payinfo = $cust_main->payinfo
 395       if $cust_main->paymask eq $payinfo;
 396
 397   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 398
 399     $payinfo = $p->{'payinfo'};
 400
 401     $payinfo = $cust_main->payinfo
 402       if $cust_main->paymask eq $payinfo;
 403
 404     $payinfo =~ s/\D//g;
 405     $payinfo =~ /^(\d{13,16})$/
 406       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 407     $payinfo = $1;
 408
 409     validate($payinfo)
 410       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 411     return { 'error' => gettext('unknown_card_type') }
 412       if cardtype($payinfo) eq "Unknown";
 413
 414     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 415       if ( cardtype($payinfo) eq 'American Express card' ) {
 416         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 417           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 418         $paycvv = $1;
 419       } else {
 420         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 421           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 422         $paycvv = $1;
 423       }
 424     }
 425
 426   } else {
 427     die "unknown payby $payby";
 428   }
 429
 430   my %payby2fields = (
 431     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 432     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 433   );
 434
 435   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 436     'quiet'    => 1,
 437     'payinfo'  => $payinfo,
 438     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 439     'payname'  => $payname,
 440     'paybatch' => $paybatch,
 441     'paycvv'   => $paycvv,
 442     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 443   );
 444   return { 'error' => $error } if $error;
 445
 446   $cust_main->apply_payments;
 447
 448   if ( $p->{'save'} ) {
 449     my $new = new FS::cust_main { $cust_main->hash };
 450     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 451       $new->set( $_ => $p->{$_} )
 452         foreach qw( payname paystart_month paystart_year payissue payip
 453                     address1 address2 city state zip payinfo );
 454       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 455     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 456       $new->set( $_ => $p->{$_} )
 457         foreach qw( payname payip paytype paystate
 458                     stateid stateid_state );
 459       $new->set( 'payinfo' => $payinfo );
 460       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 461     }
 462     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 463     my $error = $new->replace($cust_main);
 464     return { 'error' => $error } if $error;
 465     $cust_main = $new;
 466   }
 467
 468   return { 'error' => '' };
 469
 470 }
 471
 472 sub process_payment_order_pkg {
 473   my $p = shift;
 474
 475   my $hr = process_payment($p);
 476   return $hr if $hr->{'error'};
 477
 478   order_pkg($p);
 479 }
 480
 481 sub process_payment_order_renew {
 482   my $p = shift;
 483
 484   my $hr = process_payment($p);
 485   return $hr if $hr->{'error'};
 486
 487   order_renew($p);
 488 }
 489
 490 sub process_prepay {
 491
 492   my $p = shift;
 493
 494   my $session = _cache->get($p->{'session_id'})
 495     or return { 'error' => "Can't resume session" }; #better error message
 496
 497   my %return;
 498
 499   my $custnum = $session->{'custnum'};
 500
 501   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 502     or return { 'error' => "unknown custnum $custnum" };
 503
 504   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 505   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 506                                            \$amount,
 507                                            \$seconds,
 508                                            \$upbytes,
 509                                            \$downbytes,
 510                                            \$totalbytes,
 511                                          );
 512
 513   return { 'error' => $error } if $error;
 514
 515   return { 'error'     => '',
 516            'amount'    => $amount,
 517            'seconds'   => $seconds,
 518            'duration'  => duration_exact($seconds),
 519            'upbytes'   => $upbytes,
 520            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 521            'downbytes' => $downbytes,
 522            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 523            'totalbytes'=> $totalbytes,
 524            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 525          };
 526
 527 }
 528
 529 sub invoice {
 530   my $p = shift;
 531   my $session = _cache->get($p->{'session_id'})
 532     or return { 'error' => "Can't resume session" }; #better error message
 533
 534   my $custnum = $session->{'custnum'};
 535
 536   my $invnum = $p->{'invnum'};
 537
 538   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 539                                           'custnum' => $custnum } )
 540     or return { 'error' => "Can't find invnum" };
 541
 542   #my %return;
 543
 544   return { 'error'        => '',
 545            'invnum'       => $invnum,
 546            'invoice_text' => join('', $cust_bill->print_text ),
 547            'invoice_html' => $cust_bill->print_html,
 548          };
 549
 550 }
 551
 552 sub invoice_logo {
 553   my $p = shift;
 554
 555   #sessioning for this?  how do we get the session id to the backend invoice
 556   # template so it can add it to the link, blah
 557
 558   my $agentnum = '';
 559   if ( $p->{'invnum'} ) {
 560     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $p->{'invnum'} } )
 561       or return { 'error' => 'unknown invnum' };
 562     $agentnum = $cust_bill->cust_main->agentnum;
 563   }
 564
 565   my $templatename = $p->{'template'} || $p->{'templatename'};
 566
 567   #false laziness-ish w/view/cust_bill-logo.cgi
 568
 569   my $conf = new FS::Conf;
 570   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 571     $templatename = "_$1";
 572   } else {
 573     $templatename = '';
 574   }
 575
 576   my $filename = "logo$templatename.png";
 577
 578   return { 'error'        => '',
 579            'logo'         => $conf->config_binary($filename, $agentnum),
 580            'content_type' => 'image/png', #should allow gif, jpg too
 581          };
 582 }
 583
 584
 585 sub list_invoices {
 586   my $p = shift;
 587   my $session = _cache->get($p->{'session_id'})
 588     or return { 'error' => "Can't resume session" }; #better error message
 589
 590   my $custnum = $session->{'custnum'};
 591
 592   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 593     or return { 'error' => "unknown custnum $custnum" };
 594
 595   my @cust_bill = $cust_main->cust_bill;
 596
 597   return  { 'error'       => '',
 598             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 599                                         '_date'  => $_->_date,
 600                                       }
 601                                     } @cust_bill
 602                               ]
 603           };
 604 }
 605
 606 sub cancel {
 607   my $p = shift;
 608   my $session = _cache->get($p->{'session_id'})
 609     or return { 'error' => "Can't resume session" }; #better error message
 610
 611   my $custnum = $session->{'custnum'};
 612
 613   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 614     or return { 'error' => "unknown custnum $custnum" };
 615
 616   my @errors = $cust_main->cancel( 'quiet'=>1 );
 617
 618   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 619
 620   return { 'error' => $error };
 621
 622 }
 623
 624 sub list_pkgs {
 625   my $p = shift;
 626
 627   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 628   return { 'error' => $session } if $context eq 'error';
 629
 630   my $search = { 'custnum' => $custnum };
 631   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 632   my $cust_main = qsearchs('cust_main', $search )
 633     or return { 'error' => "unknown custnum $custnum" };
 634
 635   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 636
 637   my $conf = new FS::Conf;
 638
 639   { 'svcnum'   => $session->{'svcnum'},
 640     'custnum'  => $custnum,
 641     'cust_pkg' => [ map {
 642                           { $_->hash,
 643                             $_->part_pkg->hash,
 644                             part_svc =>
 645                               [ map $_->hashref, $_->available_part_svc ],
 646                             cust_svc =>
 647                               [ map { my $ref = { $_->hash,
 648                                                   label => [ $_->label ],
 649                                                 };
 650                                       $ref->{_password} = $_->svc_x->_password
 651                                         if $context eq 'agent'
 652                                         && $conf->exists('agent-showpasswords')
 653                                         && $_->part_svc->svcdb eq 'svc_acct';
 654                                       $ref;
 655                                     } $_->cust_svc
 656                               ],
 657                           };
 658                         } $cust_main->ncancelled_pkgs
 659                   ],
 660     'small_custview' =>
 661       small_custview( $cust_main, $conf->config('countrydefault') ),
 662   };
 663
 664 }
 665
 666 sub list_svcs {
 667   my $p = shift;
 668
 669   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 670   return { 'error' => $session } if $context eq 'error';
 671
 672   my $search = { 'custnum' => $custnum };
 673   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 674   my $cust_main = qsearchs('cust_main', $search )
 675     or return { 'error' => "unknown custnum $custnum" };
 676
 677   my @cust_svc = ();
 678   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 679   foreach my $cust_pkg ( $p->{'ncancelled'}
 680                          ? $cust_main->ncancelled_pkgs
 681                          : $cust_main->unsuspended_pkgs ) {
 682     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 683   }
 684   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 685     if $p->{'svcdb'};
 686
 687   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 688   #              @svc_x;
 689
 690   {
 691     #no#'svcnum'   => $session->{'svcnum'},
 692     'custnum'  => $custnum,
 693     'svcs'     => [ map {
 694                           my $svc_x = $_->svc_x;
 695                           my($label, $value) = $_->label;
 696                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 697
 698                           { 'svcnum'    => $_->svcnum,
 699                             'label'     => $label,
 700                             'value'     => $value,
 701                             'username'  => $svc_x->username,
 702                             'email'     => $svc_x->email,
 703                             'seconds'   => $svc_x->seconds,
 704                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 705                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 706                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 707                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 708                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 709                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 710                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 711                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 712                             # more...
 713                           };
 714                         }
 715                         @cust_svc
 716                   ],
 717   };
 718
 719 }
 720
 721 sub list_svc_usage {
 722   my $p = shift;
 723
 724   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 725   return { 'error' => $session } if $context eq 'error';
 726
 727   my $search = { 'svcnum' => $p->{'svcnum'} };
 728   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 729   my $svc_acct = qsearchs ( 'svc_acct', $search );
 730   return { 'error' => 'No service selected in list_svc_usage' }
 731     unless $svc_acct;
 732
 733   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 734   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 735   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 736   my $end    = time;
 737
 738   unless($p->{beginning}){
 739     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 740     $p->{ending} = $end;
 741   }
 742   my @usage = ();
 743
 744   foreach my $part_export (
 745     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 746     qw (sqlradius sqlradius_withdomain')
 747   ) {
 748
 749     push @usage, @ { $part_export->usage_sessions($p->{beginning},
 750                                                   $p->{ending},
 751                                                   $svc_acct)
 752                    };
 753   }
 754
 755   #kinda false laziness with FS::cust_main::bill, but perhaps
 756   #we should really change this bit to DateTime and DateTime::Duration
 757   #
 758   #change this bit to use Date::Manip? CAREFUL with timezones (see
 759   # mailing list archive)
 760   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 761     (localtime($p->{ending}) )[0,1,2,3,4,5];
 762   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 763     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 764
 765   if ( $freq =~ /^\d+$/ ) {
 766     $nmon += $freq;
 767     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 768     $pmon -= $freq;
 769     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 770   } elsif ( $freq =~ /^(\d+)w$/ ) {
 771     my $weeks = $1;
 772     $nmday += $weeks * 7;
 773     $pmday -= $weeks * 7;
 774   } elsif ( $freq =~ /^(\d+)d$/ ) {
 775     my $days = $1;
 776     $nmday += $days;
 777     $pmday -= $days;
 778   } elsif ( $freq =~ /^(\d+)h$/ ) {
 779     my $hours = $1;
 780     $nhour += $hours;
 781     $phour -= $hours;
 782   } else {
 783     return { 'error' => "unparsable frequency: ". $freq };
 784   }
 785
 786   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 787   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 788
 789
 790   {
 791     'error'     => '',
 792     'svcnum'    => $p->{svcnum},
 793     'beginning' => $p->{beginning},
 794     'ending'    => $p->{ending},
 795     'previous'  => ($previous > $start) ? $previous : $start,
 796     'next'      => ($next < $end) ? $next : $end,
 797     'usage'     => \@usage,
 798   };
 799 }
 800
 801 sub order_pkg {
 802   my $p = shift;
 803
 804   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 805   return { 'error' => $session } if $context eq 'error';
 806
 807   my $search = { 'custnum' => $custnum };
 808   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 809   my $cust_main = qsearchs('cust_main', $search )
 810     or return { 'error' => "unknown custnum $custnum" };
 811
 812   my $status = $cust_main->status;
 813   #false laziness w/ClientAPI/Signup.pm
 814
 815   my $cust_pkg = new FS::cust_pkg ( {
 816     'custnum' => $custnum,
 817     'pkgpart' => $p->{'pkgpart'},
 818   } );
 819   my $error = $cust_pkg->check;
 820   return { 'error' => $error } if $error;
 821
 822   my @svc = ();
 823   unless ( $p->{'svcpart'} eq 'none' ) {
 824
 825     my $svcdb;
 826     my $svcpart = '';
 827     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 828       $svcpart = $1;
 829       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 830       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 831       $svcdb = $part_svc->svcdb;
 832     } else {
 833       $svcdb = 'svc_acct';
 834     }
 835     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 836
 837     my %fields = (
 838       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 839       'svc_domain'   => [ qw( domain ) ],
 840       'svc_external' => [ qw( id title ) ],
 841     );
 842
 843     my $svc_x = "FS::$svcdb"->new( {
 844       'svcpart'   => $svcpart,
 845       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 846     } );
 847
 848     if ( $svcdb eq 'svc_acct' ) {
 849       my @acct_snarf;
 850       my $snarfnum = 1;
 851       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 852         my $acct_snarf = new FS::acct_snarf ( {
 853           'machine'   => $p->{"snarf_machine$snarfnum"},
 854           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 855           'username'  => $p->{"snarf_username$snarfnum"},
 856           '_password' => $p->{"snarf_password$snarfnum"},
 857         } );
 858         $snarfnum++;
 859         push @acct_snarf, $acct_snarf;
 860       }
 861       $svc_x->child_objects( \@acct_snarf );
 862     }
 863
 864     my $y = $svc_x->setdefault; # arguably should be in new method
 865     return { 'error' => $y } if $y && !ref($y);
 866
 867     $error = $svc_x->check;
 868     return { 'error' => $error } if $error;
 869
 870     push @svc, $svc_x;
 871
 872   }
 873
 874   use Tie::RefHash;
 875   tie my %hash, 'Tie::RefHash';
 876   %hash = ( $cust_pkg => \@svc );
 877   #msgcat
 878   $error = $cust_main->order_pkgs( \%hash, 'noexport' => 1 );
 879   return { 'error' => $error } if $error;
 880
 881   my $conf = new FS::Conf;
 882   if ( $conf->exists('signup_server-realtime') ) {
 883
 884     my $bill_error = _do_bop_realtime( $cust_main, $status );
 885
 886     if ($bill_error) {
 887       $cust_pkg->cancel('quiet'=>1);
 888       return $bill_error;
 889     } else {
 890       $cust_pkg->reexport;
 891     }
 892
 893   } else {
 894     $cust_pkg->reexport;
 895   }
 896
 897   return { error => '', pkgnum => $cust_pkg->pkgnum };
 898
 899 }
 900
 901 sub change_pkg {
 902   my $p = shift;
 903
 904   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 905   return { 'error' => $session } if $context eq 'error';
 906
 907   my $search = { 'custnum' => $custnum };
 908   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 909   my $cust_main = qsearchs('cust_main', $search )
 910     or return { 'error' => "unknown custnum $custnum" };
 911
 912   my $status = $cust_main->status;
 913   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 914     or return { 'error' => "unknown package $p->{pkgnum}" };
 915
 916   my @newpkg;
 917   my $error = FS::cust_pkg::order( $custnum,
 918                                    [$p->{pkgpart}],
 919                                    [$p->{pkgnum}],
 920                                    \@newpkg,
 921                                  );
 922
 923   my $conf = new FS::Conf;
 924   if ( $conf->exists('signup_server-realtime') ) {
 925
 926     my $bill_error = _do_bop_realtime( $cust_main, $status );
 927
 928     if ($bill_error) {
 929       $newpkg[0]->suspend;
 930       return $bill_error;
 931     } else {
 932       $newpkg[0]->reexport;
 933     }
 934
 935   } else {
 936     $newpkg[0]->reexport;
 937   }
 938
 939   return { error => '', pkgnum => $cust_pkg->pkgnum };
 940
 941 }
 942
 943 sub order_recharge {
 944   my $p = shift;
 945
 946   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 947   return { 'error' => $session } if $context eq 'error';
 948
 949   my $search = { 'custnum' => $custnum };
 950   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 951   my $cust_main = qsearchs('cust_main', $search )
 952     or return { 'error' => "unknown custnum $custnum" };
 953
 954   my $status = $cust_main->status;
 955   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 956     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 957
 958   my $svc_x = $cust_svc->svc_x;
 959   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 960
 961   my %vhash =
 962     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 963     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 964          recharge_totalbytes );
 965   my $amount = $part_pkg->option('recharge_amount', 1);
 966
 967   my ($l, $v, $d) = $cust_svc->label;  # blah
 968   my $pkg = "Recharge $v";
 969
 970   my $bill_error = $cust_main->charge($amount, $pkg,
 971      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 972      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 973      $part_pkg->taxclass); #meh
 974
 975   my $conf = new FS::Conf;
 976   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 977
 978     $bill_error = _do_bop_realtime( $cust_main, $status );
 979
 980     if ($bill_error) {
 981       return $bill_error;
 982     } else {
 983       my $error = $svc_x->recharge (\%vhash);
 984       return { 'error' => $error } if $error;
 985     }
 986
 987   } else {
 988     my $error = $bill_error;
 989     $error ||= $svc_x->recharge (\%vhash);
 990     return { 'error' => $error } if $error;
 991   }
 992
 993   return { error => '', svc => $cust_svc->part_svc->svc };
 994
 995 }
 996
 997 sub _do_bop_realtime {
 998   my ($cust_main, $status) = (shift, shift);
 999
1000     my $old_balance = $cust_main->balance;
1001
1002     my $bill_error = $cust_main->bill;
1003
1004     $cust_main->apply_payments_and_credits;
1005     $bill_error = $cust_main->collect('realtime' => 1);
1006
1007     if (    $cust_main->balance > $old_balance
1008          && $cust_main->balance > 0
1009          && ( $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ?
1010               1 : $status eq 'suspended' ) ) {
1011       #this makes sense.  credit is "un-doing" the invoice
1012       my $conf = new FS::Conf;
1013       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
1014                           'self-service decline',
1015                           'reason_type' => $conf->config('signup_credit_type'),
1016                         );
1017       $cust_main->apply_credits( 'order' => 'newest' );
1018
1019       return { 'error' => '_decline', 'bill_error' => $bill_error };
1020     }
1021
1022     '';
1023 }
1024
1025 sub renew_info {
1026   my $p = shift;
1027
1028   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1029   return { 'error' => $session } if $context eq 'error';
1030
1031   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1032     or return { 'error' => "unknown custnum $custnum" };
1033
1034   my @cust_pkg = sort { $a->bill <=> $b->bill }
1035                  grep { $_->part_pkg->freq ne '0' }
1036                  $cust_main->ncancelled_pkgs;
1037
1038   #return { 'error' => 'No active packages to renew.' } unless @cust_pkg;
1039
1040   my $total = $cust_main->balance;
1041
1042   my @array = map {
1043                     my $bill = $_->bill;
1044                     $total += $_->part_pkg->base_recur($_, \$bill);
1045                     my $renew_date = $_->part_pkg->add_freq($_->bill);
1046                     {
1047                       'pkgnum'             => $_->pkgnum,
1048                       'amount'             => sprintf('%.2f', $total),
1049                       'bill_date'          => $_->bill,
1050                       'bill_date_pretty'   => time2str('%x', $_->bill),
1051                       'renew_date'         => $renew_date,
1052                       'renew_date_pretty'  => time2str('%x', $renew_date),
1053                       'expire_date'        => $_->expire,
1054                       'expire_date_pretty' => time2str('%x', $_->expire),
1055                     };
1056                   }
1057                   @cust_pkg;
1058
1059   return { 'dates' => \@array };
1060
1061 }
1062
1063 sub payment_info_renew_info {
1064   my $p = shift;
1065   my $renew_info   = renew_info($p);
1066   my $payment_info = payment_info($p);
1067   return { %$renew_info,
1068            %$payment_info,
1069          };
1070 }
1071
1072 sub order_renew {
1073   my $p = shift;
1074
1075   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1076   return { 'error' => $session } if $context eq 'error';
1077
1078   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1079     or return { 'error' => "unknown custnum $custnum" };
1080
1081   my $date = $p->{'date'};
1082
1083   my $now = time;
1084
1085   #freeside-daily -n -d $date fs_daily $custnum
1086   $cust_main->bill_and_collect( 'time'         => $date,
1087                                 'invoice_time' => $now,
1088                                 'actual_time'  => $now,
1089                                 'check_freq'   => '1d',
1090                               );
1091
1092   return { 'error' => '' };
1093
1094 }
1095
1096 sub cancel_pkg {
1097   my $p = shift;
1098   my $session = _cache->get($p->{'session_id'})
1099     or return { 'error' => "Can't resume session" }; #better error message
1100
1101   my $custnum = $session->{'custnum'};
1102
1103   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1104     or return { 'error' => "unknown custnum $custnum" };
1105
1106   my $pkgnum = $p->{'pkgnum'};
1107
1108   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1109                                         'pkgnum'  => $pkgnum,   } )
1110     or return { 'error' => "unknown pkgnum $pkgnum" };
1111
1112   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1113   return { 'error' => $error };
1114
1115 }
1116
1117 sub provision_acct {
1118   my $p = shift;
1119   warn "provision_acct called\n"
1120     if $DEBUG;
1121
1122   return { 'error' => gettext('passwords_dont_match') }
1123     if $p->{'_password'} ne $p->{'_password2'};
1124   return { 'error' => gettext('empty_password') }
1125     unless length($p->{'_password'});
1126
1127   if ($p->{'domsvc'}) {
1128     my %domains = domain_select_hash FS::svc_acct(map { $_ => $p->{$_} }
1129                                                   qw ( svcpart pkgnum ) );
1130     return { 'error' => gettext('invalid_domain') }
1131       unless ($domains{$p->{'domsvc'}});
1132   }
1133
1134   warn "provision_acct calling _provision\n"
1135     if $DEBUG;
1136   _provision( 'FS::svc_acct',
1137               [qw(username _password domsvc)],
1138               [qw(username _password domsvc)],
1139               $p,
1140               @_
1141             );
1142 }
1143
1144 sub provision_external {
1145   my $p = shift;
1146   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1147   _provision( 'FS::svc_external',
1148               [],
1149               [qw(id title)],
1150               $p,
1151               @_
1152             );
1153 }
1154
1155 sub _provision {
1156   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1157   warn "_provision called for $class\n"
1158     if $DEBUG;
1159
1160   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1161   return { 'error' => $session } if $context eq 'error';
1162
1163   my $search = { 'custnum' => $custnum };
1164   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1165   my $cust_main = qsearchs('cust_main', $search )
1166     or return { 'error' => "unknown custnum $custnum" };
1167
1168   my $pkgnum = $p->{'pkgnum'};
1169
1170   warn "searching for custnum $custnum pkgnum $pkgnum\n"
1171     if $DEBUG;
1172   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1173                                         'pkgnum'  => $pkgnum,
1174                                                                } )
1175     or return { 'error' => "unknown pkgnum $pkgnum" };
1176
1177   warn "searching for svcpart ". $p->{'svcpart'}. "\n"
1178     if $DEBUG;
1179   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1180     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1181
1182   warn "creating $class record\n"
1183     if $DEBUG;
1184   my $svc_x = $class->new( {
1185     'pkgnum'  => $p->{'pkgnum'},
1186     'svcpart' => $p->{'svcpart'},
1187     map { $_ => $p->{$_} } @$fields
1188   } );
1189   warn "inserting $class record\n"
1190     if $DEBUG;
1191   my $error = $svc_x->insert;
1192
1193   unless ( $error ) {
1194     warn "finding inserted record for svcnum ". $svc_x->svcnum. "\n"
1195       if $DEBUG;
1196     $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1197   }
1198
1199   my $return = { 'svc'   => $part_svc->svc,
1200                  'error' => $error,
1201                  map { $_ => $svc_x->get($_) } @$return_fields
1202                };
1203   warn "_provision returning ". Dumper($return). "\n"
1204     if $DEBUG;
1205   return $return;
1206
1207 }
1208
1209 sub part_svc_info {
1210   my $p = shift;
1211
1212   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1213   return { 'error' => $session } if $context eq 'error';
1214
1215   my $search = { 'custnum' => $custnum };
1216   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1217   my $cust_main = qsearchs('cust_main', $search )
1218     or return { 'error' => "unknown custnum $custnum" };
1219
1220   my $pkgnum = $p->{'pkgnum'};
1221
1222   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1223                                         'pkgnum'  => $pkgnum,
1224                                                                } )
1225     or return { 'error' => "unknown pkgnum $pkgnum" };
1226
1227   my $svcpart = $p->{'svcpart'};
1228
1229   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1230                                       'svcpart' => $svcpart,           } )
1231     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1232   my $part_svc = $pkg_svc->part_svc;
1233
1234   my $conf = new FS::Conf;
1235
1236   return {
1237     'svc'     => $part_svc->svc,
1238     'svcdb'   => $part_svc->svcdb,
1239     'pkgnum'  => $pkgnum,
1240     'svcpart' => $svcpart,
1241     'custnum' => $custnum,
1242
1243     'security_phrase' => 0, #XXX !
1244     'svc_acct_pop'    => [], #XXX !
1245     'popnum'          => '',
1246     'init_popstate'   => '',
1247     'popac'           => '',
1248     'acstate'         => '',
1249
1250     'small_custview' =>
1251       small_custview( $cust_main, $conf->config('countrydefault') ),
1252
1253   };
1254
1255 }
1256
1257 sub unprovision_svc {
1258   my $p = shift;
1259
1260   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1261   return { 'error' => $session } if $context eq 'error';
1262
1263   my $search = { 'custnum' => $custnum };
1264   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1265   my $cust_main = qsearchs('cust_main', $search )
1266     or return { 'error' => "unknown custnum $custnum" };
1267
1268   my $svcnum = $p->{'svcnum'};
1269
1270   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1271     or return { 'error' => "unknown svcnum $svcnum" };
1272
1273   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1274     unless $cust_svc->cust_pkg->custnum == $custnum;
1275
1276   my $conf = new FS::Conf;
1277
1278   return { 'svc'   => $cust_svc->part_svc->svc,
1279            'error' => $cust_svc->cancel,
1280            'small_custview' =>
1281              small_custview( $cust_main, $conf->config('countrydefault') ),
1282          };
1283
1284 }
1285
1286 sub myaccount_passwd {
1287   my $p = shift;
1288   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1289   return { 'error' => $session } if $context eq 'error';
1290
1291   return { 'error' => "New passwords don't match." }
1292     if $p->{'new_password'} ne $p->{'new_password2'};
1293
1294   return { 'error' => 'Enter new password' }
1295     unless length($p->{'new_password'});
1296
1297   #my $search = { 'custnum' => $custnum };
1298   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1299   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1300   my $search = " AND custnum = $1";
1301   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1302
1303   my $svc_acct = qsearchs( {
1304     'table'     => 'svc_acct',
1305     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1306                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1307                    'LEFT JOIN cust_main USING ( custnum ) ',
1308     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1309     'extra_sql' => $search, #important
1310   } )
1311     or return { 'error' => "Service not found" };
1312
1313   $svc_acct->_password($p->{'new_password'});
1314   my $error = $svc_acct->replace();
1315
1316   my($label, $value) = $svc_acct->cust_svc->label;
1317
1318   return { 'error' => $error,
1319            'label' => $label,
1320            'value' => $value,
1321          };
1322
1323 }
1324
1325 #--
1326
1327 sub _custoragent_session_custnum {
1328   my $p = shift;
1329
1330   my($context, $session, $custnum);
1331   if ( $p->{'session_id'} ) {
1332
1333     $context = 'customer';
1334     $session = _cache->get($p->{'session_id'})
1335       or return ( 'error' => "Can't resume session" ); #better error message
1336     $custnum = $session->{'custnum'};
1337
1338   } elsif ( $p->{'agent_session_id'} ) {
1339
1340     $context = 'agent';
1341     my $agent_cache = new FS::ClientAPI_SessionCache( {
1342       'namespace' => 'FS::ClientAPI::Agent',
1343     } );
1344     $session = $agent_cache->get($p->{'agent_session_id'})
1345       or return ( 'error' => "Can't resume session" ); #better error message
1346     $custnum = $p->{'custnum'};
1347
1348   } else {
1349     return ( 'error' => "Can't resume session" ); #better error message
1350   }
1351
1352   ($context, $session, $custnum);
1353
1354 }
1355
1356 1;
1357