t/bop.t

   1 #!/usr/bin/perl
   2 # $Id: bop.t,v 1.8 2006-11-20 05:29:14 plobbes Exp $
   3
   4 use strict;
   5 use warnings;
   6 use Test::More tests => 60;
   7
   8 BEGIN { use_ok("Business::OnlinePayment") or exit; }
   9
  10 {    # fake test driver 1 (no submit method)
  11
  12     package Business::OnlinePayment::MOCK1;
  13     use strict;
  14     use warnings;
  15     use base qw(Business::OnlinePayment);
  16 }
  17
  18 {    # fake test driver 2 (with submit method that dies)
  19
  20     package Business::OnlinePayment::MOCK2;
  21     use strict;
  22     use warnings;
  23     use base qw(Business::OnlinePayment);
  24     sub submit { die("in processor submit\n"); }
  25 }
  26
  27 {    # fake test driver 3 (with submit method)
  28
  29     package Business::OnlinePayment::MOCK3;
  30     use strict;
  31     use warnings;
  32     use base qw(Business::OnlinePayment);
  33     sub submit { return (1); }
  34 }
  35
  36 my $package = "Business::OnlinePayment";
  37 my @drivers = qw(MOCK1 MOCK2 MOCK3);
  38 my $driver  = $drivers[0];
  39
  40 # trick to make use() happy (called in Business::OnlinePayment->new)
  41 foreach my $drv (@drivers) {
  42     $INC{"Business/OnlinePayment/${drv}.pm"} = "testing";
  43 }
  44
  45 {    # new
  46     can_ok( $package, qw(new) );
  47     my $obj;
  48
  49     eval { $obj = $package->new(); };
  50     like( $@, qr/^unspecified processor/, "new() without a processor croaks" );
  51
  52     eval { $obj = $package->new("__BOP BOGUS PROCESSOR__"); };
  53     like( $@, qr/^unknown processor/,
  54         "new() with an unknown processor croaks" );
  55
  56     $obj = $package->new($driver);
  57     isa_ok( $obj, $package );
  58     isa_ok( $obj, $package . "::" . $driver );
  59
  60     # build_subs(%fields)
  61     can_ok(
  62         $obj, qw(
  63           authorization
  64           error_message
  65           failure_status
  66           fraud_detect
  67           is_success
  68           maximum_risk
  69           path
  70           port
  71           require_avs
  72           result_code
  73           server
  74           server_response
  75           test_transaction
  76           transaction_type
  77           )
  78     );
  79
  80     # new (via build_subs) automatically creates accessors for arguments
  81     $obj = $package->new( $driver, "proc1" => "value1" );
  82     can_ok( $package, "proc1" );
  83     can_ok( $obj,     "proc1" );
  84
  85     # new (via build_subs) automatically creates accessors for arguments
  86     $obj = $package->new( $driver, qw(key1 v1 Key2 v2 -Key3 v3 --KEY4 v4) );
  87     can_ok( $package, qw(key1 key2 key3 key4) );
  88     can_ok( $obj,     qw(key1 key2 key3 key4) );
  89
  90     # new makes all accessors lowercase and removes leading dash(es)
  91     is( $obj->key1, "v1", "value of key1   (method key1) is v1" );
  92     is( $obj->key2, "v2", "value of Key2   (method key2) is v2" );
  93     is( $obj->key3, "v3", "value of -Key3  (method key3) is v3" );
  94     is( $obj->key4, "v4", "value of --KEY4 (method key4) is v4" );
  95 }
  96
  97 # XXX
  98 # {    # _risk_detect }
  99
 100 {    # _pre_submit
 101
 102     my $s_orig = Business::OnlinePayment::MOCK3->can("submit");
 103     is( ref $s_orig, "CODE", "MOCK3 submit code ref $s_orig" );
 104
 105     # test to ensure we do not go recursive when wrapping submit
 106     my $obj1   = $package->new("MOCK3");
 107     my $s_new1 = $obj1->can("submit");
 108
 109     isnt( $s_new1, $s_orig, "MOCK3 submit code ref $s_new1 (wrapped)" );
 110     is( $obj1->submit, "1", "MOCK3(obj1) submit returns 1" );
 111
 112     my $obj2   = $package->new("MOCK3");
 113     my $s_new2 = $obj2->can("submit");
 114     is( $obj2->submit, "1", "MOCK3(obj2) submit returns 1" );
 115
 116     # fraud detection failure modes
 117     my $obj  = $package->new("MOCK3");
 118     my $proc = "__BOGUS_PROCESSOR";
 119
 120     is( $obj->fraud_detect($proc), $proc, "fraud_detect set to '$proc'" );
 121     eval { $obj->submit; };
 122     is( $@, "", "fraud_detect ignores non-existant processors" );
 123
 124     # XXX: need more test cases for when fraud detection is enabled
 125 }
 126
 127 {    # content
 128     my $obj;
 129
 130     $obj = $package->new($driver);
 131     can_ok( $package, qw(content) );
 132     can_ok( $obj,     qw(content) );
 133
 134     is( $obj->content, (), "default content is empty" );
 135
 136     my %data = qw(k1 v1 type test -k2 v2 K3 v3);
 137     is_deeply( { $obj->content(%data) }, \%data, "content is set properly" );
 138     is( $obj->transaction_type, "test", "content sets transaction_type" );
 139
 140     %data = ( type => undef );
 141     is_deeply( { $obj->content(%data) }, \%data, "content with type=>undef" );
 142     is( $obj->transaction_type, "test", "transaction_type not reset" );
 143 }
 144
 145 {    # required_fields
 146     my $obj = $package->new($driver);
 147     can_ok( $package, qw(required_fields) );
 148     can_ok( $obj,     qw(required_fields) );
 149
 150     is( $obj->required_fields, 0, "no required fields" );
 151
 152     eval { $obj->required_fields("field1"); };
 153     like( $@, qr/^missing required field/, "missing required_fields croaks" );
 154 }
 155
 156 {    # get_fields
 157     my $obj = $package->new($driver);
 158     can_ok( $package, qw(get_fields) );
 159     can_ok( $obj,     qw(get_fields) );
 160
 161     my %data = ( a => 1, b => 2, c => undef, d => 4 );
 162     $obj->content(%data);
 163
 164     my ( @want, %get );
 165
 166     @want = qw(a b);
 167     %get = map { $_ => $data{$_} } @want;
 168     is_deeply( { $obj->get_fields(@want) },
 169         \%get, "get_fields with defined vals" );
 170
 171     @want = qw(a c d);
 172     %get = map { defined $data{$_} ? ( $_ => $data{$_} ) : () } @want;
 173
 174     is_deeply( { $obj->get_fields(@want) },
 175         \%get, "get_fields does not get fields with undef values" );
 176 }
 177
 178 {    # remap_fields
 179     my $obj = $package->new($driver);
 180     can_ok( $package, qw(remap_fields) );
 181     can_ok( $obj,     qw(remap_fields) );
 182
 183     my %data = ( a => 1, b => 2, c => undef, d => 4 );
 184     $obj->content(%data);
 185
 186     my %map = ( a => "Aa", d => "Dd" );
 187     my %get = ( a => 1, Aa => 1, b => 2, c => undef, d => 4, Dd => 4 );
 188
 189     $obj->remap_fields(%map);
 190     is_deeply( { $obj->content }, \%get, "remap_fields" );
 191 }
 192
 193 {    # submit
 194     my $obj = $package->new($driver);
 195     can_ok( $package, qw(submit) );
 196     can_ok( $obj,     qw(submit) );
 197
 198     eval { $obj->submit; };
 199     like( $@, qr/^Processor subclass did not /, "missing submit() croaks" );
 200     is( $obj->can("submit"), $package->can("submit"), "submit unchanged" );
 201
 202     my $mock2 = $package->new("MOCK2");
 203     can_ok( $mock2, qw(submit) );
 204
 205     isnt( $mock2->can("submit"), $package->can("submit"), "submit changed" );
 206     eval { $mock2->submit; };
 207     like( $@, qr/^in processor submit/, "processor submit() is called" );
 208 }
 209
 210 {    # dump_contents
 211     my $obj = $package->new($driver);
 212     can_ok( $package, qw(dump_contents) );
 213     can_ok( $obj,     qw(dump_contents) );
 214 }
 215
 216 {    # build_subs
 217     my $obj;
 218
 219     $obj = $package->new($driver);
 220     can_ok( $package, qw(build_subs) );
 221     can_ok( $obj,     qw(build_subs) );
 222
 223     # build_subs creates accessors for arguments
 224     my %data = qw(key1 v1 Key2 v2 -Key3 v3 --KEY4 v4);
 225     my @subs =
 226       sort { lc( ( $a =~ /(\w+)/ )[0] ) cmp lc( ( $b =~ /(\w+)/ )[0] ) }
 227       keys %data;
 228
 229     $obj->build_subs(@subs);
 230
 231     # perl does not allow dashes ("-") in subroutine names
 232     foreach my $sub (@subs) {
 233         if ( $sub !~ /^\w+/ ) {
 234             is( ref $package->can($sub), "", "$package can NOT $sub" );
 235             is( ref $obj->can($sub),     "", ref($obj) . " can NOT $sub" );
 236         }
 237         else {
 238             can_ok( $package, $sub );
 239             can_ok( $obj,     $sub );
 240             $obj->$sub( $data{$sub} );
 241             is( $obj->$sub, $data{$sub}, "$sub accessor returns $data{$sub}" );
 242         }
 243     }
 244 }