BusinessOnlinePayment.pm

   1 # Vend::Payment::BusinessOnlinePayment - Interchange wrapper for
   2 #                                        Business::OnlinePayment modules
   3 #
   4 # Copyright (C) 2004 Ivan Kohler.  All rights reserved.
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the same terms as Perl itself.
   8 #
   9 # Ivan Kohler <ivan-interchange@420.am>
  10
  11 package Vend::Payment::BusinessOnlinePayment;
  12
  13 =head1 NAME
  14
  15 Vend::Payment::BusinessOnlinePayment - Interchange wrapper for Business::OnlinePayment
  16
  17 =head1 SYNOPSIS
  18
  19     &charge=onlinepayment
  20
  21         or
  22
  23     [charge mode=onlinepayment param1=value1 param2=value2]
  24
  25 =head1 PREREQUISITES
  26
  27   Business::OnlinePayment
  28   Business::OnlinePayment:: gateway module
  29
  30   See L<http://www.420.am/business-onlinepayment/> or
  31   L<http://search.cpan.org/search?query=Business%3A%3AOnlinePayment&mode=module>
  32
  33 =head1 DESCRIPTION
  34
  35 This is a wrapper around Business::OnlinePayment for Interchange.
  36
  37 The Vend::Payment::BusinessOnlinePayment module implements the onlinepayment()
  38 routine for use with Interchange.  It is compatible on a call level with the
  39 other Interchange payment modules.  In theory (and even usually in practice)
  40 you could switch from another gateway to a Business::OnlinePayment supported
  41 gateway (or between different Business::OnlinePayment gateways) with a few
  42 configuration file changes.
  43
  44 Business::OnlinePayment is a set of related Perl modules for processing online
  45 payments (credit cards, electronic checks, and other payment systems).  It
  46 provides a consistant interface for processing online payments, regardless of
  47 the gateway backend being used, in the same way that DBI provides an consistant
  48 interface to different databases.
  49
  50 See L<http://www.420.am/business-onlinepayment/> for more information and
  51 supported gateways.
  52
  53 It is hoped that a future version of Interchange will do all credit card
  54 processing through Business::OnlinePayment, but this is my no means
  55 guaranteed and the timeframe is unknown.  Think ALSA somewhere around
  56 Linux 2.2 and you've got the general idea.
  57
  58 Currently this module is recommended for people with gateway processors
  59 unsupported by a native Interchange Vend::Payment:: module and for the
  60 adventurous.
  61
  62 =head1 USAGE
  63
  64 To enable this module, place this directive in C<interchange.cfg>:
  65
  66     Require module Vend::Payment::BusinessOnlinePayment
  67
  68 This I<must> be in interchange.cfg or a file included from it.
  69
  70 The mode can be named anything, but the C<gateway> parameter must be set
  71 to C<onlinepayment>. To make it the default payment gateway for all credit
  72 card transactions in a specific catalog, you can set in C<catalog.cfg>:
  73
  74     Variable   MV_PAYMENT_MODE  onlinepayment
  75
  76 It uses several of the standard settings from Interchange payment. Any time
  77 we speak of a setting, it is obtained either first from the tag/call options,
  78 then from an Interchange order Route named for the mode, then finally a
  79 default global payment variable, For example, the C<setting> parameter would
  80 be specified by:
  81
  82     [charge mode=onlinepayment setting=value]
  83
  84 or
  85
  86     Route onlinepayment setting value
  87
  88 or
  89
  90     Variable MV_PAYMENT_SETTING      value
  91
  92 The following settings are available:
  93
  94 =over 4
  95
  96 =item processor
  97
  98 Your Business::OnlinePayment processor.
  99
 100 =item id
 101
 102 Your Business::OnlinePayment login.
 103
 104 =item secret
 105
 106 Your Busienss::OnlinePayment password.
 107
 108 =item transaction
 109
 110 The type of transaction to be run. Valid values are:
 111
 112     Interchange         Business::OnlinePayment
 113     ----------------    -----------------------
 114         auth            Authorization Only
 115         return          Credit
 116         reverse
 117         sale            Normal Authorization
 118         settle          Post Authorization
 119         void            Void
 120
 121 =item test
 122
 123 Set this true if you wish to operate in test mode.  Make sure to verify
 124 that your specific Business::OnlinePayment:: gateway module supports a
 125 test mode.
 126
 127 =back
 128
 129 In addition, any other processor options are passed to your gateway.  See
 130 the documentation for your specific Business::OnlinePayment:: gateway module
 131 for details on what options are required, if any.
 132
 133 =head1 AUTHOR
 134
 135 Ivan Kohler <ivan-interchange@420.am>
 136
 137 =cut
 138
 139 package Vend::Payment;
 140 use strict;
 141 use vars qw( $VERSION );
 142 use Business::OnlinePayment;
 143
 144 $VERSION = '0.01';
 145
 146 my $default_avs = q{You must enter the correct billing address of your credit }.
 147                   q{card.  The bank returned the following error: %s};
 148
 149 my $default_declined = "error: %s. Please call in your order or try again.";
 150
 151 sub onlinepayment {
 152   my ($user, $amount) = @_;
 153
 154   my $opt = {};
 155   my $secret;
 156
 157   if ( ref($user) ) {
 158     $opt = $user;
 159     $user = $opt->{id};
 160     $secret = $opt->{secret};
 161   }
 162
 163   my $actual = $opt->{actual} || { map_actual() };
 164
 165   $user ||= charge_param('id')
 166     or return ( MStatus => 'failure-hard',
 167                 MErrMsg => errmsg('No account id'),
 168               );
 169
 170   $secret ||= charge_param('secret');
 171
 172   my $precision = $opt->{precision} || 2;
 173
 174   my $referer = $opt->{referer} || charge_param('referer');
 175
 176   $actual->{$_} = $opt->{$_}
 177     foreach grep defined($opt->{$_}), qw(
 178       order_id
 179       auth_code
 180       mv_credit_card_exp_month
 181       mv_credit_card_exp_year
 182       mv_credit_card_number
 183     );
 184
 185   $actual->{mv_credit_card_exp_month} =~ s/\D//g;
 186   $actual->{mv_credit_card_exp_year} =~ s/\D//g;
 187   $actual->{mv_credit_card_exp_year} =~ s/\d\d(\d\d)/$1/;
 188   $actual->{mv_credit_card_number} =~ s/\D//g;
 189
 190   my $exp = sprintf '%02d/%02d', $actual->{mv_credit_card_exp_month},
 191                                  $actual->{mv_credit_card_exp_year};
 192
 193   my %ic2bop = (
 194     'auth'    =>  'Authorization Only',
 195     'return'  =>  'Credit',
 196     #'reverse' =>
 197     'sale'    =>  'Normal Authorization',
 198     'settle'  =>  'Post Authorization',
 199     'void'    =>  'Void',
 200   );
 201
 202   my $action = $ic2bop{$opt->{transaction} || 'sale'};
 203
 204   $amount = $opt->{total_cost} if $opt->{total_cost};
 205
 206   if ( ! $amount ) {
 207     $amount = Vend::Interpolate::total_cost();
 208     $amount = Vend::Util::round_to_frac_digits($amount, $precision);
 209   }
 210
 211   my $order_id = gen_order_id($opt);
 212
 213   my $processor = charge_param('processor');
 214
 215   #processor options!
 216   my %ignore = map { $_=>1 } qw(gateway processor id secret transaction );
 217   my %options = map  { $_=>1 }
 218                 grep { !$ignore{$_} } (
 219                                         keys(%$opt),
 220                                         map { s/^MV_PAYMENT_//; lc($_); }
 221                                           grep { /^MV_PAYMENT_/ }
 222                                             keys %$main::Variable
 223                                       );
 224
 225   my $transaction =
 226     new Business::OnlinePayment ( $processor, %options );
 227
 228   $transaction->test_transaction($opt->{test} || charge_param('test'));
 229
 230   $actual->{$_} =~ s/[\n\r]//g foreach keys %$actual;
 231
 232   $transaction->content(
 233     'type'            => 'CC',
 234     'login'           => $user,
 235     'password'        => $secret,
 236     'action'          => $action,
 237     #'description'
 238     'amount'          => $amount,
 239     'card_number'     => $actual->{mv_credit_card_number},
 240     'expiration'      => $exp,
 241     'cvv2'            => $actual->{cvv2},
 242     'order_number'    => $actual->{order_id},
 243     'auth_code'       => $actual->{auth_code},
 244     #'recurring_billing'
 245     'invoice_number'  => $actual->{mv_order_number},
 246     #'customer_id'
 247     'last_name'       => $actual->{b_lname},
 248     'first_name'      => $actual->{b_fname},
 249     'name'            => $actual->{b_fname}. ' '. $actual->{b_lname},
 250     'company'         => $actual->{b_company},
 251     'address'         => $actual->{b_address},
 252     'city'            => $actual->{b_city},
 253     'state'           => $actual->{b_state},
 254     'zip'             => $actual->{b_zip},
 255     'country'         => $actual->{b_country},
 256     'ship_last_name'  => $actual->{lname},
 257     'ship_first_name' => $actual->{fname},
 258     'ship_name'       => $actual->{fname}. ' '. $actual->{lname},
 259     'ship_company'    => $actual->{company},
 260     'ship_address'    => $actual->{address},
 261     'ship_city'       => $actual->{city},
 262     'ship_state'      => $actual->{state},
 263     'ship_zip'        => $actual->{zip},
 264     'ship_country'    => $actual->{country},
 265     'referer'         => $referer,
 266     'email'           => $actual->{email},
 267     'phone'           => $actual->{phone_day},
 268   );
 269
 270   $transaction->submit();
 271
 272   my %result;
 273   if ( $transaction->is_success() ) {
 274
 275     $result{MStatus} = 'success';
 276     $result{'order-id'} = $transaction->order_number || $opt->{'order_id'};
 277
 278   } else {
 279
 280     $result{MStatus} = 'failure';
 281     delete $result{'order-id'};
 282
 283     if ( 0 ) { #need a standard Business::OnlinePayment way to ask about AVS
 284       $result{MErrMsg} = errmsg(
 285         $opt->{'message_avs'} || $default_avs,
 286         $transaction->error_message
 287       )
 288     } else {
 289       $result{MErrMsg} = errmsg(
 290         $opt->{'message_declined'} || "$processor $default_declined",
 291          $transaction->error_message
 292       );
 293     }
 294
 295   }
 296
 297   return %result;
 298
 299 }
 300
 301 1;
 302