DBSchema/Column.pm

   1 package DBIx::DBSchema::Column;
   2
   3 use strict;
   4 use vars qw(@ISA $VERSION);
   5 #use Carp;
   6 #use Exporter;
   7 use DBIx::DBSchema::_util qw(_load_driver _dbh);
   8
   9 #@ISA = qw(Exporter);
  10 @ISA = qw();
  11
  12 $VERSION = '0.08';
  13
  14 =head1 NAME
  15
  16 DBIx::DBSchema::Column - Column objects
  17
  18 =head1 SYNOPSIS
  19
  20   use DBIx::DBSchema::Column;
  21
  22   #named params with a hashref (preferred)
  23   $column = new DBIx::DBSchema::Column ( {
  24     'name'    => 'column_name',
  25     'type'    => 'varchar'
  26     'null'    => 'NOT NULL',
  27     'length'  => 64,
  28     'default' => '',
  29     'local'   => '',
  30   } );
  31
  32   #list
  33   $column = new DBIx::DBSchema::Column ( $name, $sql_type, $nullability, $length, $default, $local );
  34
  35   $name = $column->name;
  36   $column->name( 'name' );
  37
  38   $sql_type = $column->type;
  39   $column->type( 'sql_type' );
  40
  41   $null = $column->null;
  42   $column->null( 'NULL' );
  43   $column->null( 'NOT NULL' );
  44   $column->null( '' );
  45
  46   $length = $column->length;
  47   $column->length( '10' );
  48   $column->length( '8,2' );
  49
  50   $default = $column->default;
  51   $column->default( 'Roo' );
  52
  53   $sql_line = $column->line;
  54   $sql_line = $column->line($datasrc);
  55
  56   $sql_add_column = $column->sql_add_column;
  57   $sql_add_column = $column->sql_add_column($datasrc);
  58
  59 =head1 DESCRIPTION
  60
  61 DBIx::DBSchema::Column objects represent columns in tables (see
  62 L<DBIx::DBSchema::Table>).
  63
  64 =head1 METHODS
  65
  66 =over 4
  67
  68 =item new HASHREF
  69
  70 =item new [ name [ , type [ , null [ , length  [ , default [ , local ] ] ] ] ] ]
  71
  72 Creates a new DBIx::DBSchema::Column object.  Takes a hashref of named
  73 parameters, or a list.  B<name> is the name of the column.  B<type> is the SQL
  74 data type.  B<null> is the nullability of the column (intrepreted using Perl's
  75 rules for truth, with one exception: `NOT NULL' is false).  B<length> is the
  76 SQL length of the column.  B<default> is the default value of the column.
  77 B<local> is reserved for database-specific information.
  78
  79 Note: If you pass a scalar reference as the B<default> rather than a scalar value, it will be dereferenced and quoting will be forced off.  This can be used to pass SQL functions such as C<$now()> or explicit empty strings as C<''> as
  80 defaults.
  81
  82 =cut
  83
  84 sub new {
  85   my $proto = shift;
  86   my $class = ref($proto) || $proto;
  87
  88   my $self;
  89   if ( ref($_[0]) ) {
  90     $self = shift;
  91   } else {
  92     $self = { map { $_ => shift } qw(name type null length default local) };
  93   }
  94
  95   #croak "Illegal name: ". $self->{'name'}
  96   #  if grep $self->{'name'} eq $_, @reserved_words;
  97
  98   $self->{'null'} =~ s/^NOT NULL$//i;
  99   $self->{'null'} = 'NULL' if $self->{'null'};
 100
 101   bless ($self, $class);
 102
 103 }
 104
 105 =item name [ NAME ]
 106
 107 Returns or sets the column name.
 108
 109 =cut
 110
 111 sub name {
 112   my($self,$value)=@_;
 113   if ( defined($value) ) {
 114   #croak "Illegal name: $name" if grep $name eq $_, @reserved_words;
 115     $self->{'name'} = $value;
 116   } else {
 117     $self->{'name'};
 118   }
 119 }
 120
 121 =item type [ TYPE ]
 122
 123 Returns or sets the column type.
 124
 125 =cut
 126
 127 sub type {
 128   my($self,$value)=@_;
 129   if ( defined($value) ) {
 130     $self->{'type'} = $value;
 131   } else {
 132     $self->{'type'};
 133   }
 134 }
 135
 136 =item null [ NULL ]
 137
 138 Returns or sets the column null flag (the empty string is equivalent to
 139 `NOT NULL')
 140
 141 =cut
 142
 143 sub null {
 144   my($self,$value)=@_;
 145   if ( defined($value) ) {
 146     $value =~ s/^NOT NULL$//i;
 147     $value = 'NULL' if $value;
 148     $self->{'null'} = $value;
 149   } else {
 150     $self->{'null'};
 151   }
 152 }
 153
 154 =item length [ LENGTH ]
 155
 156 Returns or sets the column length.
 157
 158 =cut
 159
 160 sub length {
 161   my($self,$value)=@_;
 162   if ( defined($value) ) {
 163     $self->{'length'} = $value;
 164   } else {
 165     $self->{'length'};
 166   }
 167 }
 168
 169 =item default [ LOCAL ]
 170
 171 Returns or sets the default value.
 172
 173 =cut
 174
 175 sub default {
 176   my($self,$value)=@_;
 177   if ( defined($value) ) {
 178     $self->{'default'} = $value;
 179   } else {
 180     $self->{'default'};
 181   }
 182 }
 183
 184
 185 =item local [ LOCAL ]
 186
 187 Returns or sets the database-specific field.
 188
 189 =cut
 190
 191 sub local {
 192   my($self,$value)=@_;
 193   if ( defined($value) ) {
 194     $self->{'local'} = $value;
 195   } else {
 196     $self->{'local'};
 197   }
 198 }
 199
 200 =item table_obj [ TABLE_OBJ ]
 201
 202 Returns or sets the table object (see L<DBIx::DBSchema::Table>).  Typically
 203 set internally when a column object is added to a table object.
 204
 205 =cut
 206
 207 sub table_obj {
 208   my($self,$value)=@_;
 209   if ( defined($value) ) {
 210     $self->{'table_obj'} = $value;
 211   } else {
 212     $self->{'table_obj'};
 213   }
 214 }
 215
 216 =item table_name
 217
 218 Returns the table name, or the empty string if this column has not yet been
 219 assigned to a table.
 220
 221 =cut
 222
 223 sub table_name {
 224   my $self = shift;
 225   $self->{'table_obj'} ? $self->{'table_obj'}->name : '';
 226 }
 227
 228 =item line [ DATABASE_HANDLE | DATA_SOURCE [ USERNAME PASSWORD [ ATTR ] ] ]
 229
 230 Returns an SQL column definition.
 231
 232 The data source can be specified by passing an open DBI database handle, or by
 233 passing the DBI data source name, username and password.
 234
 235 Although the username and password are optional, it is best to call this method
 236 with a database handle or data source including a valid username and password -
 237 a DBI connection will be opened and the quoting and type mapping will be more
 238 reliable.
 239
 240 If passed a DBI data source (or handle) such as `DBI:mysql:database' or
 241 `DBI:Pg:dbname=database', will use syntax specific to that database engine.
 242 Currently supported databases are MySQL and PostgreSQL.  Non-standard syntax
 243 for other engines (if applicable) may also be supported in the future.
 244
 245 =cut
 246
 247 sub line {
 248   my($self, $dbh) = ( shift, _dbh(@_) );
 249
 250   my $driver = $dbh ? _load_driver($dbh) : '';
 251
 252   my %typemap;
 253   %typemap = eval "\%DBIx::DBSchema::DBD::${driver}::typemap" if $driver;
 254   my $type = defined( $typemap{uc($self->type)} )
 255     ? $typemap{uc($self->type)}
 256     : $self->type;
 257
 258   my $null = $self->null;
 259
 260   my $default;
 261   if ( defined($self->default) && !ref($self->default) && $self->default ne ''
 262        && ref($dbh)
 263        # false laziness: nicked from FS::Record::_quote
 264        && ( $self->default !~ /^\-?\d+(\.\d+)?$/
 265             || $type =~ /(char|binary|blob|text)$/i
 266           )
 267   ) {
 268     $default = $dbh->quote($self->default);
 269   } else {
 270     $default = ref($self->default) ? ${$self->default} : $self->default;
 271   }
 272
 273   #this should be a callback into the driver
 274   if ( $driver eq 'mysql' ) { #yucky mysql hack
 275     $null ||= "NOT NULL";
 276     $self->local('AUTO_INCREMENT') if uc($self->type) eq 'SERIAL';
 277   } elsif ( $driver =~ /^(?:Pg|SQLite)$/ ) { #yucky Pg/SQLite hack
 278     $null ||= "NOT NULL";
 279     $null =~ s/^NULL$//;
 280   }
 281
 282   join(' ',
 283     $self->name,
 284     $type. ( ( defined($self->length) && $self->length )
 285              ? '('.$self->length.')'
 286              : ''
 287            ),
 288     $null,
 289     ( ( defined($default) && $default ne '' )
 290       ? 'DEFAULT '. $default
 291       : ''
 292     ),
 293     ( ( $driver eq 'mysql' && defined($self->local) )
 294       ? $self->local
 295       : ''
 296     ),
 297   );
 298
 299 }
 300
 301 =item sql_add_column [ DBH ]
 302
 303 Returns a list of SQL statements to add this column to an existing table.  (To
 304 create a new table, see L<DBIx::DBSchema::Table/sql_create_table> instead.)
 305
 306 The data source can be specified by passing an open DBI database handle, or by
 307 passing the DBI data source name, username and password.
 308
 309 Although the username and password are optional, it is best to call this method
 310 with a database handle or data source including a valid username and password -
 311 a DBI connection will be opened and the quoting and type mapping will be more
 312 reliable.
 313
 314 If passed a DBI data source (or handle) such as `DBI:Pg:dbname=database', will
 315 use PostgreSQL-specific syntax.  Non-standard syntax for other engines (if
 316 applicable) may also be supported in the future.
 317
 318 =cut
 319
 320 sub sql_add_column {
 321   my($self, $dbh) = ( shift, _dbh(@_) );
 322
 323   die "$self: this column is not assigned to a table"
 324     unless $self->table_name;
 325
 326   my $driver = $dbh ? _load_driver($dbh) : '';
 327
 328   my @after_add = ();
 329
 330   my $real_type = '';
 331   if (  $driver eq 'Pg' && $self->type eq 'serial' ) {
 332     $real_type = 'serial';
 333     $self->type('int');
 334
 335     push @after_add, sub {
 336       my($table, $column) = @_;
 337
 338       #needs more work for old Pg
 339
 340       my $nextval;
 341       if ( $dbh->{'pg_server_version'} > 70300 ) {
 342         $nextval = "nextval('public.${table}_${column}_seq'::text)";
 343       } else {
 344         $nextval = "nextval('${table}_${column}_seq'::text)";
 345       }
 346
 347       (
 348         "ALTER TABLE $table ALTER COLUMN $column SET DEFAULT $nextval",
 349         "CREATE SEQUENCE ${table}_${column}_seq",
 350         "UPDATE $table SET $column = $nextval WHERE $column IS NULL",
 351         #"ALTER TABLE $table ALTER $column SET NOT NULL",
 352       );
 353
 354     };
 355
 356   }
 357
 358   my $real_null = undef;
 359   if ( $driver eq 'Pg' && ! $self->null ) {
 360     $real_null = $self->null;
 361     $self->null('NULL');
 362
 363     #if ( $dbh->{'pg_server_version'} > 70300 ) { #this seemed to work on 7.3
 364     if ( $dbh->{'pg_server_version'} > 70400 ) {  #after all...
 365
 366       push @after_add, sub {
 367         my($table, $column) = @_;
 368         "ALTER TABLE $table ALTER $column SET NOT NULL";
 369       };
 370
 371     } else {
 372
 373       push @after_add, sub {
 374         my($table, $column) = @_;
 375         "UPDATE pg_attribute SET attnotnull = TRUE ".
 376         " WHERE attname = '$column' ".
 377         " AND attrelid = ( SELECT oid FROM pg_class WHERE relname = '$table' )";
 378       };
 379
 380     }
 381
 382   }
 383
 384   my @r = ();
 385   my $table = $self->table_name;
 386   my $column = $self->name;
 387
 388   push @r, "ALTER TABLE $table ADD COLUMN ". $self->line($dbh);
 389
 390   push @r, &{$_}($table, $column) foreach @after_add;
 391
 392   push @r, "ALTER TABLE $table ADD PRIMARY KEY ( ".
 393              $self->table_obj->primary_key. " )"
 394     if $self->name eq $self->table_obj->primary_key;
 395
 396   $self->type($real_type) if $real_type;
 397   $self->null($real_null) if defined $real_null;
 398
 399   @r;
 400
 401 }
 402
 403 =item sql_alter_column PROTOTYPE_COLUMN  [ DATABASE_HANDLE | DATA_SOURCE [ USERNAME PASSWORD [ ATTR ] ] ]
 404
 405 Returns a list of SQL statements to alter this column so that it is identical
 406 to the provided prototype column, also a DBIx::DBSchema::Column object.
 407
 408  #Optionally, the data source can be specified by passing an open DBI database
 409  #handle, or by passing the DBI data source name, username and password.
 410  #
 411  #If passed a DBI data source (or handle) such as `DBI:Pg:dbname=database', will
 412  #use PostgreSQL-specific syntax.  Non-standard syntax for other engines (if
 413  #applicable) may also be supported in the future.
 414  #
 415  #If not passed a data source (or handle), or if there is no driver for the
 416  #specified database, will attempt to use generic SQL syntax.
 417
 418
 419 Or should, someday.  Right now it knows how to change NOT NULL into NULL and
 420 vice-versa.
 421
 422 =cut
 423
 424 sub sql_alter_column {
 425   my( $self, $new, $dbh ) = ( shift, shift, _dbh(@_) );
 426
 427   my $table = $self->table_name;
 428   die "$self: this column is not assigned to a table"
 429     unless $table;
 430
 431   my $name = $self->name;
 432
 433   my $driver = $dbh ? _load_driver($dbh) : '';
 434
 435   my @r = ();
 436
 437   # change the name...
 438
 439   # change the type...
 440
 441   # change nullability from NOT NULL to NULL
 442   if ( ! $self->null && $new->null ) {
 443
 444     if ( $driver eq 'Pg' && $dbh->{'pg_server_version'} < 70300 ) {
 445       push @r, "UPDATE pg_attribute SET attnotnull = FALSE
 446                   WHERE attname = '$name'
 447                     AND attrelid = ( SELECT oid FROM pg_class
 448                                        WHERE relname = '$table'
 449                                    )";
 450     } else {
 451       push @r, "ALTER TABLE $table ALTER COLUMN $name DROP NOT NULL";
 452     }
 453   }
 454
 455   # change nullability from NULL to NOT NULL...
 456   # this one could be more complicated, need to set a DEFAULT value and update
 457   # the table first...
 458   if ( $self->null && ! $new->null ) {
 459
 460     if ( $driver eq 'Pg' && $dbh->{'pg_server_version'} < 70300 ) {
 461       push @r, "UPDATE pg_attribute SET attnotnull = TRUE
 462                   WHERE attname = '$name'
 463                     AND attrelid = ( SELECT oid FROM pg_class
 464                                        WHERE relname = '$table'
 465                                    )";
 466     } else {
 467       push @r, "ALTER TABLE $table ALTER COLUMN $name SET NOT NULL";
 468     }
 469   }
 470
 471   # change other stuff...
 472
 473   @r;
 474
 475 }
 476
 477 =back
 478
 479 =head1 AUTHOR
 480
 481 Ivan Kohler <ivan-dbix-dbschema@420.am>
 482
 483 =head1 COPYRIGHT
 484
 485 Copyright (c) 2000-2006 Ivan Kohler
 486 All rights reserved.
 487 This program is free software; you can redistribute it and/or modify it under
 488 the same terms as Perl itself.
 489
 490 =head1 BUGS
 491
 492 Better documentation is needed for sql_add_column
 493
 494 line() and sql_add_column() hav database-specific foo that should be abstracted
 495 into the DBIx::DBSchema:DBD:: modules.
 496
 497 =head1 SEE ALSO
 498
 499 L<DBIx::DBSchema::Table>, L<DBIx::DBSchema>, L<DBIx::DBSchema::DBD>, L<DBI>
 500
 501 =cut
 502
 503 1;
 504