+=head3 RFC2822 (MIME)
+
+Returns the object's date and time in RFC2822 format,
+for example C<Sun, 06 Nov 1994 08:49:37 +0000>.
+Format is locale independand as required by RFC. Time
+part always has timezone offset in digits with sign prefix.
+
+Supports arguments: C<Timezone>, C<Date>, C<Time>, C<DayOfWeek>
+and C<Seconds>. See </Output formatters> for description of
+arguments.
+
+=cut
+
+sub RFC2822 {
+ my $self = shift;
+ my %args = ( Date => 1,
+ Time => 1,
+ Timezone => '',
+ DayOfWeek => 1,
+ Seconds => 1,
+ @_,
+ );
+
+ # 0 1 2 3 4 5 6 7 8 9
+ my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
+ $self->Localtime($args{'Timezone'});
+
+ my ($date, $time) = ('','');
+ $date .= "$DAYS_OF_WEEK[$wday], " if $args{'DayOfWeek'} && $args{'Date'};
+ $date .= "$mday $MONTHS[$mon] $year" if $args{'Date'};
+
+ if ( $args{'Time'} ) {
+ $time .= sprintf("%02d:%02d", $hour, $min);
+ $time .= sprintf(":%02d", $sec) if $args{'Seconds'};
+ $time .= sprintf " %s%02d%02d", $self->_SplitOffset( $offset );
+ }
+
+ return join ' ', grep $_, ($date, $time);
+}
+
+=head3 RFC2616 (HTTP)
+
+Returns the object's date and time in RFC2616 (HTTP/1.1) format,
+for example C<Sun, 06 Nov 1994 08:49:37 GMT>. While the RFC describes
+version 1.1 of HTTP, but the same form date can be used in version 1.0.
+
+Format is fixed length, locale independand and always represented in GMT
+what makes it quite useless for users, but any date in HTTP transfers
+must be presented using this format.
+
+ HTTP-date = rfc1123 | ...
+ rfc1123 = wkday "," SP date SP time SP "GMT"
+ date = 2DIGIT SP month SP 4DIGIT
+ ; day month year (e.g., 02 Jun 1982)
+ time = 2DIGIT ":" 2DIGIT ":" 2DIGIT
+ ; 00:00:00 - 23:59:59
+ wkday = "Mon" | "Tue" | "Wed" | "Thu" | "Fri" | "Sat" | "Sun"
+ month = "Jan" | "Feb" | "Mar" | "Apr" | "May" | "Jun"
+ | "Jul" | "Aug" | "Sep" | "Oct" | "Nov" | "Dec"
+
+Supports arguments: C<Date> and C<Time>, but you should use them only for
+some personal reasons, RFC2616 doesn't define any optional parts.
+See </Output formatters> for description of arguments.
+
+=cut
+
+sub RFC2616 {
+ my $self = shift;
+ my %args = ( Date => 1, Time => 1,
+ @_,
+ Timezone => 'utc',
+ Seconds => 1, DayOfWeek => 1,
+ );
+
+ my $res = $self->RFC2822( %args );
+ $res =~ s/\s*[+-]\d\d\d\d$/ GMT/ if $args{'Time'};
+ return $res;
+}
+
+=head4 iCal
+
+Returns the object's date and time in iCalendar format,
+
+Supports arguments: C<Date> and C<Time>.
+See </Output formatters> for description of arguments.
+
+=cut
+
+sub iCal {
+ my $self = shift;
+ my %args = (
+ Date => 1, Time => 1,
+ @_,
+ );
+ my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
+ $self->Localtime( 'utc' );
+
+ #the month needs incrementing, as gmtime returns 0-11
+ $mon++;
+
+ my $res;
+ if ( $args{'Date'} && !$args{'Time'} ) {
+ $res = sprintf( '%04d%02d%02d', $year, $mon, $mday );
+ }
+ elsif ( !$args{'Date'} && $args{'Time'} ) {
+ $res = sprintf( 'T%02d%02d%02dZ', $hour, $min, $sec );
+ }
+ else {
+ $res = sprintf( '%04d%02d%02dT%02d%02d%02dZ', $year, $mon, $mday, $hour, $min, $sec );
+ }
+ return $res;
+}
+
+# it's been added by mistake in 3.8.0
+sub iCalDate { return (shift)->iCal( Time => 0, @_ ) }
+
+sub _SplitOffset {
+ my ($self, $offset) = @_;
+ my $sign = $offset < 0? '-': '+';
+ $offset = int( (abs $offset) / 60 + 0.001 );
+ my $mins = $offset % 60;
+ my $hours = int( $offset/60 + 0.001 );
+ return $sign, $hours, $mins;
+}
+
+=head2 Timezones handling
+
+=head3 Localtime $context [$time]
+
+Takes one mandatory argument C<$context>, which determines whether
+we want "user local", "system" or "UTC" time. Also, takes optional
+argument unix C<$time>, default value is the current unix time.
+
+Returns object's date and time in the format provided by perl's
+builtin functions C<localtime> and C<gmtime> with two exceptions:
+
+1) "Year" is a four-digit year, rather than "years since 1900"
+
+2) The last element of the array returned is C<offset>, which
+represents timezone offset against C<UTC> in seconds.
+
+=cut
+
+sub Localtime
+{
+ my $self = shift;
+ my $tz = $self->Timezone(shift);
+
+ my $unix = shift || $self->Unix;
+ $unix = 0 unless $unix >= 0;
+
+ my @local;
+ if ($tz eq 'UTC') {
+ @local = gmtime($unix);
+ } else {
+ {
+ local $ENV{'TZ'} = $tz;
+ ## Using POSIX::tzset fixes a bug where the TZ environment variable
+ ## is cached.
+ POSIX::tzset();
+ @local = localtime($unix);
+ }
+ POSIX::tzset(); # return back previouse value
+ }
+ $local[5] += 1900; # change year to 4+ digits format
+ my $offset = Time::Local::timegm_nocheck(@local) - $unix;
+ return @local, $offset;
+}
+
+=head3 Timelocal $context @time
+
+Takes argument C<$context>, which determines whether we should
+treat C<@time> as "user local", "system" or "UTC" time.
+
+C<@time> is array returned by L<Localtime> functions. Only first
+six elements are mandatory - $sec, $min, $hour, $mday, $mon and $year.
+You may pass $wday, $yday and $isdst, these are ignored.
+
+If you pass C<$offset> as ninth argument, it's used instead of
+C<$context>. It's done such way as code
+C<$self->Timelocal('utc', $self->Localtime('server'))> doesn't
+makes much sense and most probably would produce unexpected
+result, so the method ignore 'utc' context and uses offset
+returned by L<Localtime> method.
+
+=cut
+
+sub Timelocal {
+ my $self = shift;
+ my $tz = shift;
+ if ( defined $_[9] ) {
+ return timegm(@_[0..5]) - $_[9];
+ } else {
+ $tz = $self->Timezone( $tz );
+ if ( $tz eq 'UTC' ) {
+ return Time::Local::timegm(@_[0..5]);
+ } else {
+ my $rv;
+ {
+ local $ENV{'TZ'} = $tz;
+ ## Using POSIX::tzset fixes a bug where the TZ environment variable
+ ## is cached.
+ POSIX::tzset();
+ $rv = Time::Local::timelocal(@_[0..5]);
+ };
+ POSIX::tzset(); # switch back to previouse value
+ return $rv;
+ }
+ }
+}
+
+
+=head3 Timezone $context
+
+Returns the timezone name.
+
+Takes one argument, C<$context> argument which could be C<user>, C<server> or C<utc>.
+
+=over