+sub _merge_into {
+ # For internal use:
+ #
+ # When given two cust_main_county row objects, rewrite all database foreign
+ # key references referring to $row_to_merge->taxnum as references to
+ # $row_to_keep->taxnum, so $row_to_merge can be safely deleted from
+ # cust_main_county
+ #
+ # Usage (class method):
+ # $row_to_merge->_merge_into( $row_to_keep )
+ #
+ # Usage (package function):
+ # FS::cust_main_county::_merge_into( $row_to_merge, $row_to_keep )
+ #
+ # Optionally, allow merge when records don't match
+ # (useful during tax table update routines)
+ # $row_to_merge->_merge_info(
+ # $row_to_keep,
+ # { identical_record_check => 0 }
+ # );
+
+ my $row_to_merge = shift;
+ my $row_to_keep = shift
+ or croak 'record to merge into must be provided';
+
+ my $args = shift || { identical_record_check => 1 };
+ croak 'invalid arguments hashref' unless ref $args;
+
+ my $log = FS::Log->new('FS::cust_main_county');
+
+ my $keep_taxnum = $row_to_keep->taxnum;
+ my $merge_taxnum = $row_to_merge->taxnum;
+
+ if (
+ $args->{identical_record_check}
+ && (
+ $row_to_keep->tax != $row_to_merge->tax
+ || $row_to_keep->exempt_amount != $row_to_merge->exempt_amount
+ )
+ ) {
+ my $msg = "Found duplicate taxes (#$keep_taxnum and #$merge_taxnum) "
+ . "but they have different rates and can't be merged.";
+ $log->warn( $msg );
+ warn "$msg\n";
+ return;
+ }
+
+ my $msg = "Merging tax #$merge_taxnum into #$keep_taxnum";
+ $log->warn( $msg );
+ warn "$msg\n";
+
+ foreach my $table (qw(
+ cust_bill_pkg_tax_location
+ cust_bill_pkg_tax_location_void
+ cust_tax_exempt_pkg
+ cust_tax_exempt_pkg_void
+ )) {
+ foreach my $row (qsearch($table, { 'taxnum' => $merge_taxnum })) {
+ $row->set('taxnum' => $keep_taxnum);
+ if ( my $error = $row->replace ) {
+ $log->error( $error );
+ die $error;
+ }
+ }
+ }
+
+ if ( my $error = $row_to_merge->delete ) {
+ $log->error( $error );
+ die $error;
+ }
+}
+
+sub _upgrade_data {
+ my $class = shift;
+ # assume taxes in Washington with district numbers, and null name, or
+ # named 'sales tax', are looked up via the wa_sales method. mark them.
+ my $journal = 'cust_main_county__source_wa_sales_201611';
+ if (!FS::upgrade_journal->is_done($journal)) {
+ my @taxes = qsearch({
+ 'table' => 'cust_main_county',
+ 'extra_sql' => " WHERE tax > 0 AND country = 'US' AND state = 'WA'".
+ " AND district IS NOT NULL AND ( taxname IS NULL OR ".
+ " taxname ~* 'sales tax' )",
+ });
+ if ( @taxes ) {
+ warn "Flagging Washington state sales taxes: ".scalar(@taxes)." records.\n";
+ foreach (@taxes) {
+ $_->set('source', 'wa_sales');
+ my $error = $_->replace;
+ die $error if $error;
+ }
+ }
+ FS::upgrade_journal->set_done($journal);
+ }
+ my @key_fields = (qw(city county state country district taxname taxclass));
+
+ # trim whitespace and convert to uppercase in the 'city' field.
+ foreach my $record (qsearch({
+ table => 'cust_main_county',
+ extra_sql => " WHERE city LIKE ' %' OR city LIKE '% ' OR city != UPPER(city)",
+ })) {
+ # any with-trailing-space records probably duplicate other records
+ # from the same city, and if we just fix the record in place, we'll
+ # create an exact duplicate.
+ # so find the record this one would duplicate, and merge them.
+ $record->check; # trims whitespace
+ my %match = map { $_ => $record->get($_) } @key_fields;
+ my $other = qsearchs('cust_main_county', \%match);
+ if ($other) {
+ $record->_merge_into($other);
+ } else {
+ # else there is no record this one duplicates, so just fix it
+ my $error = $record->replace;
+ die $error if $error;
+ }
+ } # foreach $record
+
+ # separate wa_sales taxes by tax class as needed
+ my $district_taxname = $conf->config('tax_district_taxname');
+ $journal = 'cust_main_county__district_taxclass';
+ if (!FS::upgrade_journal->is_done($journal)
+ and $conf->exists('enable_taxclasses')) {
+ eval "use FS::part_pkg_taxclass";
+ my @taxes = qsearch({
+ 'table' => 'cust_main_county',
+ 'extra_sql' => " WHERE tax > 0 AND country = 'US' AND state = 'WA'".
+ " AND district IS NOT NULL AND source = 'wa_sales'".
+ " AND taxclass IS NULL"
+ });
+ my @classes = FS::part_pkg_taxclass->taxclass_names;
+ if ( @taxes ) {
+ warn "Separating WA sales taxes: ".scalar(@taxes)." records.\n";
+ foreach my $oldtax (@taxes) {
+ my $error;
+ my $taxnum = $oldtax->taxnum;
+ warn "Separating tax #$taxnum into classes\n";
+ foreach my $taxclass (@classes) {
+ # ensure that we end up with a single copy of the tax in this
+ # jurisdiction+class. there may already be one (or more) there.
+ # if so, they all represent the same tax; merge them together.
+ my %newtax_hash = (
+ 'country' => 'US',
+ 'state' => 'WA',
+ 'city' => $oldtax->city,
+ 'district' => $oldtax->district,
+ 'taxclass' => $taxclass,
+ 'source' => 'wa_sales',
+ );
+ my @taxes_in_class = qsearch('cust_main_county', {
+ %newtax_hash,
+ 'tax' => { op => '>', value => 0 },
+ 'setuptax' => '',
+ 'recurtax' => '',
+ });
+ my $newtax = shift @taxes_in_class;
+ if ($newtax) {
+ foreach (@taxes_in_class) {
+ # allow the merge, even if this somehow differs.
+ $_->set('tax', $newtax->tax);
+ $_->_merge_into($newtax);
+ }
+ }
+ $newtax ||= FS::cust_main_county->new(\%newtax_hash);
+ # copy properties from the pre-split tax
+ $newtax->set('tax', $oldtax->tax);
+ $newtax->set('setuptax', $oldtax->setuptax);
+ $newtax->set('recurtax', $oldtax->recurtax);
+ # and assign the defined tax name
+ $newtax->set('taxname', $district_taxname);
+ $error = ($newtax->taxnum ? $newtax->replace : $newtax->insert);
+ die "splitting taxnum ".$oldtax->taxnum.": $error\n" if $error;
+ } # foreach $taxclass
+ $oldtax->set('tax', 0);
+ $error = $oldtax->replace;
+ die "splitting taxnum ".$oldtax->taxnum.": $error\n" if $error;
+ }
+ }
+ FS::upgrade_journal->set_done($journal);
+ }
+
+ # also ensure they all have the chosen taxname now
+ if ($district_taxname) {
+ my @taxes = qsearch('cust_main_county', {
+ 'source' => 'wa_sales',
+ 'taxname' => { op => '!=', value => $district_taxname }
+ });
+ if (@taxes) {
+ warn "Renaming WA sales taxes: ".scalar(@taxes)." records.\n";
+ foreach my $tax (@taxes) {
+ $tax->set('taxname', $district_taxname);
+ my $error = $tax->replace;
+ die "renaming taxnum ".$tax->taxnum.": $error\n" if $error;
+ }
+ }
+ }
+
+ # remove duplicates (except disabled records)
+ my @duplicate_sets = qsearch({
+ table => 'cust_main_county',
+ select => FS::Record::group_concat_sql('taxnum', ',') . ' AS taxnums, ' .
+ join(',', @key_fields),
+ extra_sql => ' WHERE tax > 0
+ GROUP BY city, county, state, country, district, taxname, taxclass
+ HAVING COUNT(*) > 1'
+ });
+ warn "Found ".scalar(@duplicate_sets)." set(s) of duplicate tax definitions\n"
+ if @duplicate_sets;
+ foreach my $set (@duplicate_sets) {
+ my @taxnums = split(',', $set->get('taxnums'));
+ my $first = FS::cust_main_county->by_key(shift @taxnums);
+ foreach my $taxnum (@taxnums) {
+ my $record = FS::cust_main_county->by_key($taxnum);
+ $record->_merge_into($first);
+ }
+ }
+
+
+ '';
+}
+