+ #carp "cust_credit->credited deprecated; use ->unapplied";
+ $self->unapplied(@_);
+}
+
+=item cust_main
+
+Returns the customer (see L<FS::cust_main>) for this credit.
+
+=cut
+
+# _upgrade_data
+#
+# Used by FS::Upgrade to migrate to a new database.
+
+sub _upgrade_data { # class method
+ my ($class, %opts) = @_;
+
+ warn "$me upgrading $class\n" if $DEBUG;
+
+ $class->_upgrade_reasonnum(%opts);
+
+ if (defined dbdef->table($class->table)->column('reason')) {
+
+ warn "$me Ensuring existance of auto reasons\n" if $DEBUG;
+
+ foreach ( keys %reasontype_map ) {
+ unless ($conf->config($_)) { # hmmmm
+# warn "$me Found $_ reason type lacking\n" if $DEBUG;
+# my $hashref = { 'class' => 'R', 'type' => $reasontype_map{$_} };
+ my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
+ my $reason_type = qsearchs( 'reason_type', $hashref );
+ unless ($reason_type) {
+ $reason_type = new FS::reason_type( $hashref );
+ my $error = $reason_type->insert();
+ die "$class had error inserting FS::reason_type into database: $error\n"
+ if $error;
+ }
+ $conf->set($_, $reason_type->typenum);
+ }
+ }
+
+ warn "$me Ensuring commission packages have a reason type\n" if $DEBUG;
+
+ my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
+ my $reason_type = qsearchs( 'reason_type', $hashref );
+ unless ($reason_type) {
+ $reason_type = new FS::reason_type( $hashref );
+ my $error = $reason_type->insert();
+ die "$class had error inserting FS::reason_type into database: $error\n"
+ if $error;
+ }
+
+ my @plans = qw( flat_comission flat_comission_cust flat_comission_pkg );
+ foreach my $plan ( @plans ) {
+ foreach my $pkg ( qsearch('part_pkg', { 'plan' => $plan } ) ) {
+ unless ($pkg->option('reason_type', 1) ) {
+ my $plandata = $pkg->plandata.
+ "reason_type=". $reason_type->typenum. "\n";
+ $pkg->plandata($plandata);
+ my $error =
+ $pkg->replace( undef,
+ 'pkg_svc' => { map { $_->svcpart => $_->quantity }
+ $pkg->pkg_svc
+ },
+ 'primary_svc' => $pkg->svcpart,
+ );
+ die "failed setting reason_type option: $error"
+ if $error;
+ }
+ }
+ }
+ }
+
+ local($otaker_upgrade_kludge) = 1;
+ local($ignore_empty_reasonnum) = 1;
+ $class->_upgrade_otaker(%opts);
+
+ if ( !FS::upgrade_journal->is_done('cust_credit__tax_link')
+ and !$conf->config('tax_data_vendor') ) {
+ # RT#25458: fix credit line item applications that should refer to a
+ # specific tax allocation
+ my @cust_credit_bill_pkg = qsearch({
+ table => 'cust_credit_bill_pkg',
+ select => 'cust_credit_bill_pkg.*',
+ addl_from => ' LEFT JOIN cust_bill_pkg USING (billpkgnum)',
+ extra_sql =>
+ 'WHERE cust_credit_bill_pkg.billpkgtaxlocationnum IS NULL '.
+ 'AND cust_bill_pkg.pkgnum = 0', # is a tax
+ });
+ my %tax_items;
+ my %credits;
+ foreach (@cust_credit_bill_pkg) {
+ my $billpkgnum = $_->billpkgnum;
+ $tax_items{$billpkgnum} ||= FS::cust_bill_pkg->by_key($billpkgnum);
+ $credits{$billpkgnum} ||= [];
+ push @{ $credits{$billpkgnum} }, $_;
+ }
+ TAX_ITEM: foreach my $tax_item (values %tax_items) {
+ my $billpkgnum = $tax_item->billpkgnum;
+ # get all pkg/location/taxrate allocations of this tax line item
+ my @allocations = sort {$b->amount <=> $a->amount}
+ qsearch('cust_bill_pkg_tax_location', {
+ billpkgnum => $billpkgnum
+ });
+ # and these are all credit applications to it
+ my @credits = sort {$b->amount <=> $a->amount}
+ @{ $credits{$billpkgnum} };
+ my $c = shift @credits;
+ my $a = shift @allocations; # we will NOT modify these
+ while ($c and $a) {
+ if ( abs($c->amount - $a->amount) < 0.005 ) {
+ # by far the most common case: the tax line item is for a single
+ # tax, so we just fill in the billpkgtaxlocationnum
+ $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
+ my $error = $c->replace;
+ if ($error) {
+ warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
+ next TAX_ITEM;
+ }
+ $c = shift @credits;
+ $a = shift @allocations;
+ } elsif ( $c->amount > $a->amount ) {
+ # fairly common: the tax line contains tax for multiple packages
+ # (or multiple taxes) but the credit isn't divided up
+ my $new_link = FS::cust_credit_bill_pkg->new({
+ creditbillnum => $c->creditbillnum,
+ billpkgnum => $c->billpkgnum,
+ billpkgtaxlocationnum => $a->billpkgtaxlocationnum,
+ amount => $a->amount,
+ setuprecur => 'setup',
+ });
+ my $error = $new_link->insert;
+ if ($error) {
+ warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
+ next TAX_ITEM;
+ }
+ $c->set(amount => sprintf('%.2f', $c->amount - $a->amount));
+ $a = shift @allocations;
+ } elsif ( $c->amount < 0.005 ) {
+ # also fairly common; we can delete these with no harm
+ my $error = $c->delete;
+ warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
+ $c = shift @credits;
+ } elsif ( $c->amount < $a->amount ) {
+ # should never happen, but if it does, handle it gracefully
+ $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
+ my $error = $c->replace;
+ if ($error) {
+ warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
+ next TAX_ITEM;
+ }
+ $a->set(amount => $a->amount - $c->amount);
+ $c = shift @credits;
+ }
+ } # while $c and $a
+ if ( $c ) {
+ if ( $c->amount < 0.005 ) {
+ my $error = $c->delete;
+ warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
+ } elsif ( $c->modified ) {
+ # then we've allocated part of it, so reduce the nonspecific
+ # application by that much
+ my $error = $c->replace;
+ warn "error fixing credit application to tax item #$billpkgnum:\n$error\n" if $error;
+ }
+ # else there are probably no allocations, i.e. this is a pre-3.x
+ # record that was never migrated over, so leave it alone
+ } # if $c
+ } # foreach $tax_item
+ FS::upgrade_journal->set_done('cust_credit__tax_link');
+ }
+}
+
+=back
+
+=head1 CLASS METHODS
+
+=over 4
+
+=item unapplied_sql
+
+Returns an SQL fragment to retreive the unapplied amount.
+
+=cut
+
+sub unapplied_sql {
+ my ($class, $start, $end) = @_;
+
+ my $bill_start = $start ? "AND cust_credit_bill._date <= $start" : '';
+ my $bill_end = $end ? "AND cust_credit_bill._date > $end" : '';
+ my $refund_start = $start ? "AND cust_credit_refund._date <= $start" : '';
+ my $refund_end = $end ? "AND cust_credit_refund._date > $end" : '';
+
+ "amount
+ - COALESCE(
+ ( SELECT SUM(amount) FROM cust_credit_refund
+ WHERE cust_credit.crednum = cust_credit_refund.crednum
+ $refund_start $refund_end )
+ ,0
+ )
+ - COALESCE(
+ ( SELECT SUM(amount) FROM cust_credit_bill
+ WHERE cust_credit.crednum = cust_credit_bill.crednum
+ $bill_start $bill_end )
+ ,0
+ )
+ ";
+
+}
+
+=item credited_sql
+
+Deprecated name for the unapplied_sql method.
+
+=cut
+
+sub credited_sql {
+ #my $class = shift;
+
+ #carp "cust_credit->credited_sql deprecated; use ->unapplied_sql";
+
+ #$class->unapplied_sql(@_);
+ unapplied_sql();
+}
+
+=item calculate_tax_adjustment PARAMS
+
+Calculate the amount of tax that needs to be credited as part of a lineitem
+credit.
+
+PARAMS must include:
+
+- billpkgnums: arrayref identifying the line items to credit
+- setuprecurs: arrayref of 'setup' or 'recur', indicating which part of
+ the lineitem charge is being credited
+- amounts: arrayref of the amounts to credit on each line item
+- custnum: the customer all of these invoices belong to, for error checking
+
+Returns a hash containing:
+- subtotal: the total non-tax amount to be credited (the sum of the 'amounts')
+- taxtotal: the total tax amount to be credited
+- taxlines: an arrayref of hashrefs for each tax line to be credited, each with:
+ - table: "cust_bill_pkg_tax_location" or "cust_bill_pkg_tax_rate_location"
+ - num: the key within that table
+ - credit: the credit amount to apply to that line
+
+=cut
+
+sub calculate_tax_adjustment {
+ my ($class, %arg) = @_;
+
+ my $error;
+ my @taxlines;
+ my $subtotal = 0;
+ my $taxtotal = 0;
+
+ my (%cust_bill_pkg, %cust_bill);
+
+ for (my $i = 0; ; $i++) {
+ my $billpkgnum = $arg{billpkgnums}[$i]
+ or last;
+ my $setuprecur = $arg{setuprecurs}[$i];
+ my $amount = $arg{amounts}[$i];
+ next if $amount == 0;
+ $subtotal += $amount;
+ my $cust_bill_pkg = $cust_bill_pkg{$billpkgnum}
+ ||= FS::cust_bill_pkg->by_key($billpkgnum)
+ or die "lineitem #$billpkgnum not found\n";
+
+ my $invnum = $cust_bill_pkg->invnum;
+ $cust_bill{ $invnum } ||= FS::cust_bill->by_key($invnum);
+ $cust_bill{ $invnum}->custnum == $arg{custnum}
+ or die "lineitem #$billpkgnum not found\n";
+
+ # tax_Xlocation records don't distinguish setup and recur, so calculate
+ # the fraction of setup+recur (after deducting credits) that's setup. This
+ # will also be the fraction of tax (after deducting credits) that's tax on
+ # setup.
+ my ($setup, $recur);
+ $setup = $cust_bill_pkg->get('setup') || 0;
+ if ($setup) {
+ $setup -= $cust_bill_pkg->credited('', '', setuprecur => 'setup') || 0;
+ }
+ $recur = $cust_bill_pkg->get('recur') || 0;
+ if ($recur) {
+ $recur -= $cust_bill_pkg->credited('', '', setuprecur => 'recur') || 0;
+ }
+ # Skip line items that have been completely credited.
+ next if ($setup + $recur) == 0;
+ my $setup_ratio = $setup / ($setup + $recur);
+
+ # Calculate the fraction of tax to credit: it's the fraction of this
+ # charge (either setup or recur) that's being credited.
+ my $charged = ($setuprecur eq 'setup') ? $setup : $recur;
+ next if $charged == 0; # shouldn't happen, but still...
+
+ if ($charged < $amount) {
+ $error = "invoice #$invnum: tried to credit $amount, but only $charged was charged";
+ last;
+ }
+ my $credit_ratio = $amount / $charged;
+
+ # gather taxes that apply to the selected item
+ foreach my $table (
+ qw(cust_bill_pkg_tax_location cust_bill_pkg_tax_rate_location)
+ ) {
+ foreach my $tax_link (
+ qsearch($table, { taxable_billpkgnum => $billpkgnum })
+ ) {
+ my $tax_amount = $tax_link->amount;
+ # deduct existing credits applied to the tax, for the same reason as
+ # above
+ foreach ($tax_link->cust_credit_bill_pkg) {
+ $tax_amount -= $_->amount;
+ }
+ # split tax amount based on setuprecur
+ # (this method ensures that, if you credit both setup and recur tax,
+ # it always equals the entire tax despite any rounding)
+ my $setup_tax = sprintf('%.2f', $tax_amount * $setup_ratio);
+ if ( $setuprecur eq 'setup' ) {
+ $tax_amount = $setup_tax;
+ } else {
+ $tax_amount = $tax_amount - $setup_tax;
+ }
+ my $tax_credit = sprintf('%.2f', $tax_amount * $credit_ratio);
+ my $pkey = $tax_link->get($tax_link->primary_key);
+ push @taxlines, {
+ table => $table,
+ num => $pkey,
+ credit => $tax_credit,
+ };
+ $taxtotal += $tax_credit;
+
+ } #foreach cust_bill_pkg_tax_(rate_)?location
+ }
+ } # foreach $billpkgnum
+
+ return (
+ subtotal => sprintf('%.2f', $subtotal),
+ taxtotal => sprintf('%.2f', $taxtotal),
+ taxlines => \@taxlines,
+ );
+}
+
+=item credit_lineitems OPTIONS
+
+Creates a credit to a group of line items, with a specified amount applied
+to each. This will also calculate the tax adjustments for those amounts and
+credit the appropriate tax line items.
+
+Example:
+
+ my $error = FS::cust_credit->credit_lineitems(
+
+ #the lineitems to credit
+ 'billpkgnums' => \@billpkgnums,
+ 'setuprecurs' => \@setuprecurs,
+ 'amounts' => \@amounts,
+ 'apply' => 1, #0 leaves the credit unapplied
+ 'set_source' => 1, #creates credit source records for the line items
+
+ #the credit
+ map { $_ => scalar($cgi->param($_)) }
+ #fields('cust_credit')
+ qw( custnum _date amount reasonnum addlinfo ), #pkgnum eventnum
+
+ );
+
+C<billpkgnums>, C<setuprecurs>, C<amounts> are required and are parallel
+arrays. Each one indicates an amount of credit to be applied to either the
+setup or recur portion of a (non-tax) line item.
+
+C<custnum>, C<_date>, C<reasonnum>, and C<addlinfo> will be set on the
+credit before it's inserted.
+
+C<amount> is the total amount. If unspecified, the credit will be the sum
+of the per-line-item amounts and their tax adjustments.
+
+=cut
+
+#maybe i should just be an insert with extra args instead of a class method
+sub credit_lineitems {
+ my( $class, %arg ) = @_;
+ my $curuser = $FS::CurrentUser::CurrentUser;
+
+ #some false laziness w/misc/xmlhttp-cust_bill_pkg-calculate_taxes.html
+
+ my $cust_main = qsearchs({
+ 'table' => 'cust_main',
+ 'hashref' => { 'custnum' => $arg{custnum} },
+ 'extra_sql' => ' AND '. $curuser->agentnums_sql,
+ }) or return 'unknown customer';
+
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+ local $SIG{PIPE} = 'IGNORE';
+
+ my $oldAutoCommit = $FS::UID::AutoCommit;
+ local $FS::UID::AutoCommit = 0;
+ my $dbh = dbh;
+
+ #my @cust_bill_pkg = qsearch({
+ # 'select' => 'cust_bill_pkg.*',
+ # 'table' => 'cust_bill_pkg',
+ # 'addl_from' => ' LEFT JOIN cust_bill USING (invnum) '.
+ # ' LEFT JOIN cust_main USING (custnum) ',
+ # 'extra_sql' => ' WHERE custnum = $custnum AND billpkgnum IN ('.
+ # join( ',', @{$arg{billpkgnums}} ). ')',
+ # 'order_by' => 'ORDER BY invnum ASC, billpkgnum ASC',
+ #});
+
+ my $error = '';
+
+ # first, determine the tax adjustments
+ my %tax_adjust = $class->calculate_tax_adjustment(%arg);
+ # and determine the amount automatically if it wasn't specified
+ if ( !exists( $arg{amount} ) ) {
+ $arg{amount} = sprintf('%.2f', $tax_adjust{subtotal} + $tax_adjust{taxtotal});
+ }
+
+ my $set_source = $arg{set_source};
+
+ # create the credit
+ my $cust_credit = new FS::cust_credit ( {
+ map { $_ => $arg{$_} }
+ #fields('cust_credit')
+ qw( custnum _date amount reason reasonnum addlinfo ), #pkgnum eventnum
+ } );
+ $error = $cust_credit->insert;
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error inserting credit: $error";
+ }
+
+ unless ( $arg{'apply'} ) {
+ $dbh->commit or die $dbh->errstr if $oldAutoCommit;
+ return '';
+ }
+
+ #my $subtotal = 0;
+ # keys in all of these are invoice numbers
+ my %cust_credit_bill = ();
+ my %cust_bill_pkg = ();
+ my %cust_credit_bill_pkg = ();
+ my %unapplied_payments = (); #invoice numbers, and then billpaynums
+ my %currency;
+
+ # little private function to unapply payments from a cust_bill_pkg until
+ # there's a specified amount of unpaid balance on it.
+ # it's a separate sub because we do it for both tax and nontax items. it's
+ # private because it needs access to some local data structures.
+ my $unapply_sub = sub {
+ my ($cust_bill_pkg, $setuprecur, $need_to_unapply) = @_;
+
+ my $invnum = $cust_bill_pkg->invnum;
+
+ $need_to_unapply -= $cust_bill_pkg->owed($setuprecur);
+ return if $need_to_unapply < 0.005;
+
+ my $error;
+ # then unapply payments one at a time (partially if need be) until the
+ # unpaid balance = the credit amount.
+ foreach my $cust_bill_pay_pkg (
+ $cust_bill_pkg->cust_bill_pay_pkg($setuprecur)
+ ) {
+ my $this_amount = $cust_bill_pay_pkg->amount;
+ if ( $this_amount > $need_to_unapply ) {
+ # unapply the needed amount
+ $cust_bill_pay_pkg->set('amount',
+ sprintf('%.2f', $this_amount - $need_to_unapply));
+ $error = $cust_bill_pay_pkg->replace;
+ $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum} += $need_to_unapply;
+ last; # and we're done
+
+ } else {
+ # unapply it all
+ $error = $cust_bill_pay_pkg->delete;
+ $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum} += $this_amount;
+
+ $need_to_unapply -= $this_amount;
+ }
+
+ } # foreach $cust_bill_pay_pkg
+
+ # return an error if we somehow still have leftover $need_to_unapply?
+
+ return $error;
+ };
+
+
+ foreach my $billpkgnum ( @{$arg{billpkgnums}} ) {
+ my $setuprecur = shift @{$arg{setuprecurs}};
+ my $amount = shift @{$arg{amounts}};
+
+ my $cust_bill_pkg = qsearchs({
+ 'table' => 'cust_bill_pkg',
+ 'hashref' => { 'billpkgnum' => $billpkgnum },
+ 'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
+ 'extra_sql' => 'AND custnum = '. $cust_main->custnum,
+ }) or die "unknown billpkgnum $billpkgnum";
+
+ my $invnum = $cust_bill_pkg->invnum;
+
+ push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
+
+ $cust_credit_bill{$invnum} += $amount;
+ push @{ $cust_credit_bill_pkg{$invnum} },
+ new FS::cust_credit_bill_pkg {
+ 'billpkgnum' => $billpkgnum,
+ 'amount' => sprintf('%.2f',$amount),
+ 'setuprecur' => $setuprecur,
+ 'sdate' => $cust_bill_pkg->sdate,
+ 'edate' => $cust_bill_pkg->edate,
+ };
+
+ # unapply payments if necessary
+ $error = &{$unapply_sub}($cust_bill_pkg, $setuprecur, $amount);
+
+ if ( $set_source ) {
+ $currency{$invnum} ||= $cust_bill_pkg->cust_bill->currency;
+ my $source = FS::cust_credit_source_bill_pkg->new({
+ 'crednum' => $cust_credit->crednum,
+ 'billpkgnum' => $billpkgnum,
+ 'amount' => $amount,
+ 'currency' => $currency{invnum},
+ });
+ $error ||= $source->insert;
+ }
+
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error unapplying payment: $error";
+ }
+ }
+
+ # do the same for taxes
+ foreach my $tax_credit ( @{ $tax_adjust{taxlines} } ) {
+ my $table = $tax_credit->{table};
+ my $tax_link = "FS::$table"->by_key( $tax_credit->{num} )
+ or die "tried to credit $table #$tax_credit->{num} but it doesn't exist";
+
+ my $billpkgnum = $tax_link->billpkgnum;
+ my $cust_bill_pkg = qsearchs({
+ 'table' => 'cust_bill_pkg',
+ 'hashref' => { 'billpkgnum' => $billpkgnum },
+ 'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
+ 'extra_sql' => 'AND custnum = '. $cust_main->custnum,
+ }) or die "unknown billpkgnum $billpkgnum";
+
+ my $invnum = $cust_bill_pkg->invnum;
+ push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
+
+ my $amount = $tax_credit->{credit};
+ $cust_credit_bill{$invnum} += $amount;
+
+ # create a credit application record to the tax line item, earmarked
+ # to the specific cust_bill_pkg_Xlocation
+ push @{ $cust_credit_bill_pkg{$invnum} },
+ new FS::cust_credit_bill_pkg {
+ 'billpkgnum' => $billpkgnum,
+ 'amount' => sprintf('%.2f', $amount),
+ 'setuprecur' => 'setup',
+ $tax_link->primary_key, $tax_credit->{num}
+ };
+
+ $error = &{$unapply_sub}($cust_bill_pkg, 'setup', $amount);
+
+ # I guess it's correct to do this for taxes also?
+ if ( $set_source ) {
+ $currency{$invnum} ||= $cust_bill_pkg->cust_bill->currency;
+ my $source = FS::cust_credit_source_bill_pkg->new({
+ 'crednum' => $cust_credit->crednum,
+ 'billpkgnum' => $billpkgnum,
+ 'amount' => $amount,
+ 'currency' => $currency{invnum},
+ });
+ $error ||= $source->insert;
+ }
+
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error unapplying payment: $error";
+ }
+ }
+
+ ###
+ # now loop through %cust_credit_bill and insert those
+ ###
+
+ # (hack to prevent cust_credit_bill_pkg insertion)
+ local($FS::cust_bill_ApplicationCommon::skip_apply_to_lineitems_hack) = 1;
+
+ foreach my $invnum ( sort { $a <=> $b } keys %cust_credit_bill ) {
+
+ # if we unapplied any payments from line items, also unapply that
+ # amount from the invoice
+ foreach my $billpaynum (keys %{$unapplied_payments{$invnum}}) {
+ my $cust_bill_pay = FS::cust_bill_pay->by_key($billpaynum)
+ or die "broken payment application $billpaynum";
+ my @subapps = $cust_bill_pay->lineitem_applications;
+ $error = $cust_bill_pay->delete; # can't replace
+
+ my $new_cust_bill_pay = FS::cust_bill_pay->new({
+ $cust_bill_pay->hash,
+ billpaynum => '',
+ amount => sprintf('%.2f',
+ $cust_bill_pay->amount
+ - $unapplied_payments{$invnum}{$billpaynum}),
+ });
+
+ if ( $new_cust_bill_pay->amount > 0 ) {
+ $error ||= $new_cust_bill_pay->insert;
+ # Also reapply it to everything it was applied to before.
+ # Note that we've already deleted cust_bill_pay_pkg records for the
+ # items we're crediting, so they aren't on this list.
+ foreach my $cust_bill_pay_pkg (@subapps) {
+ $cust_bill_pay_pkg->billpaypkgnum('');
+ $cust_bill_pay_pkg->billpaynum($new_cust_bill_pay->billpaynum);
+ $error ||= $cust_bill_pay_pkg->insert;
+ }
+ }
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error unapplying payment: $error";
+ }
+ }
+ #insert cust_credit_bill
+
+ my $cust_credit_bill = new FS::cust_credit_bill {
+ 'crednum' => $cust_credit->crednum,
+ 'invnum' => $invnum,
+ 'amount' => sprintf('%.2f', $cust_credit_bill{$invnum}),
+ };
+ $error = $cust_credit_bill->insert;
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error applying credit of $cust_credit_bill{$invnum} ".
+ " to invoice $invnum: $error";
+ }
+
+ #and then insert cust_credit_bill_pkg for each cust_bill_pkg
+ foreach my $cust_credit_bill_pkg ( @{$cust_credit_bill_pkg{$invnum}} ) {
+ $cust_credit_bill_pkg->creditbillnum( $cust_credit_bill->creditbillnum );
+ $error = $cust_credit_bill_pkg->insert;
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return "Error applying credit to line item: $error";
+ }
+ }
+
+ }
+
+ $dbh->commit or die $dbh->errstr if $oldAutoCommit;
+ '';
+
+}
+
+### refund_to_unapply/unapply_refund false laziness with FS::cust_pay
+
+=item refund_to_unapply
+
+Returns L<FS::cust_credit_refund> objects that will be deleted by L</unapply_refund>
+(all currently applied refunds that aren't closed.)
+Returns empty list if credit itself is closed.
+
+=cut
+
+sub refund_to_unapply {
+ my $self = shift;
+ return () if $self->closed;
+ qsearch({
+ 'table' => 'cust_credit_refund',
+ 'hashref' => { 'crednum' => $self->crednum },
+ 'addl_from' => 'LEFT JOIN cust_refund USING (refundnum)',
+ 'extra_sql' => "AND cust_refund.closed IS NULL AND cust_refund.source_paynum IS NULL",
+ });
+}
+
+=item unapply_refund
+
+Deletes all objects returned by L</refund_to_unapply>.
+
+=cut
+
+sub unapply_refund {
+ my $self = shift;
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+ local $SIG{PIPE} = 'IGNORE';
+
+ my $oldAutoCommit = $FS::UID::AutoCommit;
+ local $FS::UID::AutoCommit = 0;
+
+ foreach my $cust_credit_refund ($self->refund_to_unapply) {
+ my $error = $cust_credit_refund->delete;
+ if ($error) {
+ dbh->rollback if $oldAutoCommit;
+ return $error;
+ }
+ }
+
+ dbh->commit or die dbh->errstr if $oldAutoCommit;
+ return '';