FS/bin/freeside-cdr-asterisk_sql

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use Date::Parse 'str2time';
   6 use Date::Format 'time2str';
   7 use FS::UID qw(adminsuidsetup dbh);
   8 use FS::cdr;
   9 use DBI;
  10 use Getopt::Std;
  11
  12 $DEBUG = 0;
  13
  14 my %opt;
  15 getopts('e:H:U:P:D:T:V:', \%opt);
  16 my $user = shift or die &usage;
  17
  18 my $engine = $opt{e} || 'mysql';
  19
  20 my $dsn = "dbi:$engine";
  21 $dsn .= ":database=$opt{D}"; # if $opt{D};
  22 $dsn .= ";host=$opt{H}" if $opt{H};
  23
  24 my $dbi = DBI->connect($dsn, $opt{U}, $opt{P})
  25   or die $DBI::errstr;
  26
  27 adminsuidsetup $user;
  28
  29 my $fsdbh = FS::UID::dbh;
  30
  31 my $table = $opt{T} || 'cdr';
  32
  33 # check for existence of freesidestatus
  34 if ( $engine =~ /^mysql/ ) {
  35   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'freesidestatus'");
  36   if( ! @$status ) {
  37     warn "Adding freesidestatus column...\n" if $DEBUG;
  38     $dbi->do("ALTER TABLE $table ADD COLUMN freesidestatus varchar(32)")
  39       or die $dbi->errstr;
  40   } else {
  41     warn "freesidestatus column present\n" if $DEBUG;
  42   }
  43 }
  44
  45 my @cols = ();
  46 if ( $opt{V} >= 12 ) {
  47   push @cols, qw( id start answer end );
  48 } else {
  49   push @cols, qw( calldate );
  50 }
  51
  52 push @cols,  qw(
  53   clid src dst dcontext channel lastapp lastdata duration
  54   billsec disposition amaflags accountcode userfield
  55 );
  56
  57 # check for existence of uniqueid
  58 if ( $engine =~ /^mysql/ ) {
  59   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'uniqueid'");
  60   if( @$status ) {
  61     push @cols, 'uniqueid';
  62   }
  63 } else {
  64   #assume there's a uniqueid
  65   push @cols, 'uniqueid';
  66 }
  67
  68 my $sql =
  69   'SELECT '.join(',', @cols). " FROM $table WHERE freesidestatus IS NULL";
  70 my $sth = $dbi->prepare($sql);
  71 $sth->execute;
  72 warn "Importing ".$sth->rows." records...\n" if $DEBUG;
  73
  74 my $cdr_batch = new FS::cdr_batch({
  75     'cdrbatch' => 'sql-import-'. time2str('%Y/%m/%d-%T',time),
  76   });
  77 my $error = $cdr_batch->insert;
  78 die $error if $error;
  79 my $cdrbatchnum = $cdr_batch->cdrbatchnum;
  80
  81 my $imports = 0;
  82 my $updates = 0;
  83
  84 while ( my $row = $sth->fetchrow_hashref ) {
  85
  86   my $cdr = FS::cdr->new($row);
  87
  88   if ( $opt{V} >= 12 ) {
  89     $cdr->calldate($cdr->start);
  90     $cdr->startdate(str2time($cdr->start));
  91     $cdr->answerdate(str2time($cdr->answer));
  92     $cdr->enddate(str2time($cdr->end));
  93     $cdr->cdrid($cdr->id);
  94   } else {
  95     $cdr->startdate(str2time($cdr->calldate));
  96   }
  97
  98   $cdr->cdrbatchnum($cdrbatchnum);
  99
 100   my $error = $cdr->insert;
 101   if ($error) {
 102     warn "failed import: $error\n";
 103   } else {
 104
 105     $imports++;
 106
 107     my $usql = "UPDATE $table SET freesidestatus = 'done' WHERE ";
 108     my @args = ();
 109     if ( $opt{V} >= 12 ) {
 110       $usql .= ' id = '. $row->{'id'};
 111       @args = ( undef );
 112     } else {
 113       $usql .= ' calldate = ? AND src = ? AND dst = ?';
 114       @args = ( undef, $row->{'calldate'}, $row->{'src'}, $row->{'dst'}, );
 115     }
 116
 117     if ( $dbi->do($usql, @args) ) {
 118       $updates++;
 119     } else {
 120       warn "failed to set status: ".$dbi->errstr."\n";
 121     }
 122
 123   }
 124
 125 }
 126
 127 warn "Done.\nImported $imports CDRs, marked $updates CDRs as done.\n";
 128 $dbi->disconnect;
 129
 130 sub usage {
 131   "Usage: \n  freeside-cdr-asterisk_sql\n\t-e mysql|Pg|... [ -H host ]n\t-D database\n\t[ -T table ]\n\t[ -V asterisk_version]\n\t-U user\n\t-P password\n\tfreesideuser\n";
 132 }
 133
 134 =head1 NAME
 135
 136 freeside-cdr-asterisk_sql - Import CDRs from an Asterisk SQL database
 137
 138 =head1 SYNOPSIS
 139
 140   freeside-cdr-asterisk_sql -e mysql|Pg|... [ -H host ] -D database [ -T table ][ -V asterisk_version ] -U user -P password freesideuser
 141
 142 =head1 DESCRIPTION
 143
 144 Imports CDR records from an Asterisk SQL database.
 145
 146 -H: hostname
 147
 148 -e: Database engine (default mysql)
 149
 150 -D: database name
 151
 152 -T: table name (default cdr)
 153
 154 -U: username
 155
 156 -P: password
 157
 158 -V: Asterisk version.  Values of 12 or higher have a new database schema which no longer includes calldate.  Currently defaults to 11, but may default to 12+ or be required in a future, so best to always specify the version.
 159
 160 =cut
 161
 162 1;