FS/FS/svc_cable.pm

   1 package FS::svc_cable;
   2 use base qw( FS::svc_MAC_Mixin
   3              FS::svc_Common
   4            ); #FS::device_Common
   5
   6 use strict;
   7 use Tie::IxHash;
   8 use FS::Record qw( qsearchs ); # qw( qsearch qsearchs );
   9 use FS::cable_provider;
  10 use FS::cable_model;
  11
  12 =head1 NAME
  13
  14 FS::svc_cable - Object methods for svc_cable records
  15
  16 =head1 SYNOPSIS
  17
  18   use FS::svc_cable;
  19
  20   $record = new FS::svc_cable \%hash;
  21   $record = new FS::svc_cable { 'column' => 'value' };
  22
  23   $error = $record->insert;
  24
  25   $error = $new_record->replace($old_record);
  26
  27   $error = $record->delete;
  28
  29   $error = $record->check;
  30
  31 =head1 DESCRIPTION
  32
  33 An FS::svc_cable object represents a cable subscriber.  FS::svc_cable inherits
  34 from FS::Record.  The following fields are currently supported:
  35
  36 =over 4
  37
  38 =item svcnum
  39
  40 primary key
  41
  42 =back
  43
  44 =head1 METHODS
  45
  46 =over 4
  47
  48 =item new HASHREF
  49
  50 Creates a new record.  To add the record to the database, see L<"insert">.
  51
  52 Note that this stores the hash reference, not a distinct copy of the hash it
  53 points to.  You can ask the object for a copy with the I<hash> method.
  54
  55 =cut
  56
  57 sub table { 'svc_cable'; }
  58
  59 sub table_dupcheck_fields { ( 'serialnum', 'mac_addr' ); }
  60
  61 sub search_sql {
  62   my( $class, $string ) = @_;
  63   if ( $string =~ /^([A-F0-9]{12})$/i ) {
  64     $class->search_sql_field('mac_addr', uc($string));
  65   } elsif ( $string =~ /^(([A-F0-9]{2}:){5}([A-F0-9]{2}))$/i ) {
  66     $string =~ s/://g;
  67     $class->search_sql_field('mac_addr', uc($string) );
  68   } elsif ( $string =~ /^(\w+)$/ ) {
  69     $class->search_sql_field('serialnum', $1);
  70   } else {
  71     '1 = 0'; #false
  72   }
  73 }
  74
  75 sub table_info {
  76
  77   tie my %fields, 'Tie::IxHash',
  78     'svcnum'      => 'Service',
  79     'providernum' => { label             => 'Provider',
  80                        type              => 'select-cable_provider',
  81                        disable_inventory => 1,
  82                        disable_select    => 1,
  83                        value_callback    => sub {
  84                                               my $svc = shift;
  85                                               my $p = $svc->cable_provider;
  86                                               $p ? $p->provider : '';
  87                                             },
  88                      },
  89     'ordernum'    => 'Order number', #XXX "Circuit ID/Order number"
  90     'modelnum'    => { label             => 'Model',
  91                        type              => 'select-cable_model',
  92                        disable_inventory => 1,
  93                        disable_select    => 1,
  94                        value_callback    => sub {
  95                                               my $svc = shift;
  96                                               $svc->cable_model->model_name;
  97                                             },
  98                      },
  99     'serialnum'   => 'Serial number',
 100     'mac_addr'    => { label          => 'MAC address',
 101                        type           => 'input-mac_addr',
 102                        value_callback => sub {
 103                                            my $svc = shift;
 104                                            $svc->mac_addr_formatted('U',':');
 105                                          },
 106                      },
 107   ;
 108
 109   {
 110     'name'            => 'Cable Subscriber',
 111     #'name_plural'     => '', #optional,
 112     #'longname_plural' => '', #optional
 113     'fields'          => \%fields,
 114     'sorts'           => [ 'svcnum', 'serialnum', 'mac_addr', ],
 115     'display_weight'  => 54,
 116     'cancel_weight'   => 70, #?  no deps, so
 117   };
 118 }
 119
 120 =item label
 121
 122 Returns the MAC address and serial number.
 123
 124 =cut
 125
 126 sub label {
 127   my $self = shift;
 128   my @label = ();
 129   push @label, 'MAC:'. $self->mac_addr_pretty
 130     if $self->mac_addr;
 131   push @label, 'Serial#'. $self->serialnum
 132     if $self->serialnum;
 133   return join(', ', @label);
 134 }
 135
 136 =item insert
 137
 138 Adds this record to the database.  If there is an error, returns the error,
 139 otherwise returns false.
 140
 141 =item delete
 142
 143 Delete this record from the database.
 144
 145 =item replace OLD_RECORD
 146
 147 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 148 returns the error, otherwise returns false.
 149
 150 =item check
 151
 152 Checks all fields to make sure this is a valid record.  If there is
 153 an error, returns the error, otherwise returns false.  Called by the insert
 154 and replace methods.
 155
 156 =cut
 157
 158 sub check {
 159   my $self = shift;
 160
 161   my $error =
 162        $self->ut_numbern('svcnum')
 163     || $self->ut_foreign_keyn('providernum', 'cable_provider', 'providernum')
 164     || $self->ut_alphan('ordernum')
 165     || $self->ut_foreign_key('modelnum', 'cable_model', 'modelnum')
 166     || $self->ut_alpha('serialnum')
 167     || $self->ut_mac_addr('mac_addr')
 168   ;
 169   return $error if $error;
 170
 171   $self->SUPER::check;
 172 }
 173
 174 sub _check_duplicate {
 175   my $self = shift;
 176
 177   # Not reliable checks because the table isn't locked, but that's why we have
 178   # unique indices.  These are just to give friendlier error messages.
 179
 180   my @dup_mac;
 181   @dup_mac = $self->find_duplicates('global', 'mac_addr');
 182   if ( @dup_mac ) {
 183     return "MAC address in use (svcnum ".$dup_mac[0]->svcnum.")";
 184   }
 185
 186   my @dup_serial;
 187   @dup_serial = $self->find_duplicates('global', 'serialnum');
 188   if ( @dup_serial ) {
 189     return "Serial number in use (svcnum ".$dup_serial[0]->svcnum.")";
 190   }
 191
 192   '';
 193 }
 194
 195 =item cable_provider
 196
 197 Returns the cable_provider object for this record.
 198
 199 =cut
 200
 201 sub cable_provider {
 202   my $self = shift;
 203   qsearchs('cable_provider', { 'providernum'=>$self->providernum } );
 204 }
 205
 206 =item cable_model
 207
 208 Returns the cable_model object for this record.
 209
 210 =cut
 211
 212 sub cable_model {
 213   my $self = shift;
 214   qsearchs('cable_model', { 'modelnum'=>$self->modelnum } );
 215 }
 216
 217 =back
 218
 219 =head1 BUGS
 220
 221 =head1 SEE ALSO
 222
 223 L<FS::Record>, schema.html from the base documentation.
 224
 225 =cut
 226
 227 1;
 228