FS/FS/sales.pm

   1 package FS::sales;
   2 use base qw( FS::Commission_Mixin FS::Agent_Mixin FS::Record );
   3
   4 use strict;
   5 use FS::Record qw( qsearch qsearchs );
   6 use FS::agent;
   7 use FS::cust_main;
   8 use FS::cust_bill_pkg;
   9 use FS::cust_credit;
  10
  11 =head1 NAME
  12
  13 FS::sales - Object methods for sales records
  14
  15 =head1 SYNOPSIS
  16
  17   use FS::sales;
  18
  19   $record = new FS::sales \%hash;
  20   $record = new FS::sales { 'column' => 'value' };
  21
  22   $error = $record->insert;
  23
  24   $error = $new_record->replace($old_record);
  25
  26   $error = $record->delete;
  27
  28   $error = $record->check;
  29
  30 =head1 DESCRIPTION
  31
  32 An FS::sales object represents a sales person.  FS::sales inherits from
  33 FS::Record.  The following fields are currently supported:
  34
  35 =over 4
  36
  37 =item salesnum
  38
  39 primary key
  40
  41 =item agentnum
  42
  43 agentnum
  44
  45 =item disabled
  46
  47 disabled
  48
  49
  50 =back
  51
  52 =head1 METHODS
  53
  54 =over 4
  55
  56 =item new HASHREF
  57
  58 Creates a new sales person.  To add the sales person to the database, see
  59 L<"insert">.
  60
  61 Note that this stores the hash reference, not a distinct copy of the hash it
  62 points to.  You can ask the object for a copy with the I<hash> method.
  63
  64 =cut
  65
  66 # the new method can be inherited from FS::Record, if a table method is defined
  67
  68 sub table { 'sales'; }
  69
  70 =item insert
  71
  72 Adds this record to the database.  If there is an error, returns the error,
  73 otherwise returns false.
  74
  75 =cut
  76
  77 # the insert method can be inherited from FS::Record
  78
  79 =item delete
  80
  81 Delete this record from the database.
  82
  83 =cut
  84
  85 # the delete method can be inherited from FS::Record
  86
  87 =item replace OLD_RECORD
  88
  89 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  90 returns the error, otherwise returns false.
  91
  92 =cut
  93
  94 # the replace method can be inherited from FS::Record
  95
  96 =item check
  97
  98 Checks all fields to make sure this is a valid sales person.  If there is
  99 an error, returns the error, otherwise returns false.  Called by the insert
 100 and replace methods.
 101
 102 =cut
 103
 104 # the check method should currently be supplied - FS::Record contains some
 105 # data checking routines
 106
 107 sub check {
 108   my $self = shift;
 109
 110   my $error =
 111     $self->ut_numbern('salesnum')
 112     || $self->ut_text('salesperson')
 113     || $self->ut_foreign_key('agentnum', 'agent', 'agentnum')
 114     || $self->ut_foreign_keyn('sales_custnum', 'cust_main', 'custnum')
 115     || $self->ut_enum('disabled', [ '', 'Y' ])
 116   ;
 117   return $error if $error;
 118
 119   $self->SUPER::check;
 120 }
 121
 122 =item sales_cust_main
 123
 124 Returns the FS::cust_main object (see L<FS::cust_main>), if any, for this
 125 sales person.
 126
 127 =cut
 128
 129 sub sales_cust_main {
 130   my $self = shift;
 131   qsearchs( 'cust_main', { 'custnum' => $self->sales_custnum } );
 132 }
 133
 134 =item cust_bill_pkg START END OPTIONS
 135
 136 Returns the package line items (see L<FS::cust_bill_pkg>) for which this
 137 sales person could receive commission.
 138
 139 START and END are an optional date range to limit the results.
 140
 141 OPTIONS may contain:
 142 - I<cust_main_sales>: if this is a true value, sales of packages that have no
 143 package sales person will be included if this is their customer sales person.
 144 - I<classnum>: limit to this package classnum.
 145 - I<paid>: limit to sales that have no unpaid balance.
 146
 147 =cut
 148
 149 sub sales_where {
 150   my $self = shift;
 151   my $salesnum = $self->salesnum;
 152   die "bad salesnum" unless $salesnum =~ /^(\d+)$/;
 153   my %opt = @_;
 154
 155   my $cmp_salesnum = 'cust_pkg.salesnum';
 156   if ($opt{cust_main_sales}) {
 157     $cmp_salesnum = 'COALESCE(cust_pkg.salesnum, cust_main.salesnum)';
 158   }
 159
 160   my @where = ( "$cmp_salesnum    = $salesnum",
 161                 "sales_pkg_class.salesnum = $salesnum"
 162               );
 163
 164   # sales_pkg_class number-of-months limit, grr
 165   # (we should be able to just check for the cust_event record from the
 166   # commission credit, but the report is supposed to act as a check on that)
 167   #
 168   # Pg-specific, of course
 169   my $setup_date = 'TO_TIMESTAMP( cust_pkg.setup )';
 170   my $interval = "(sales_pkg_class.commission_duration || ' months')::interval";
 171   my $charge_date = 'TO_TIMESTAMP( cust_bill._date )';
 172   push @where, "CASE WHEN sales_pkg_class.commission_duration IS NOT NULL ".
 173                "THEN $charge_date < $setup_date + $interval ".
 174                "ELSE TRUE END";
 175
 176   @where;
 177 }
 178
 179 sub commission_where {
 180   my $self = shift;
 181   'cust_credit.commission_salesnum = ' . $self->salesnum;
 182 }
 183
 184 # slightly modify it
 185 sub cust_bill_pkg_search {
 186   my $self = shift;
 187   my $search = $self->SUPER::cust_bill_pkg_search(@_);
 188   $search->{addl_from} .= '
 189     JOIN sales_pkg_class ON( COALESCE(sales_pkg_class.classnum, 0) = COALESCE(part_pkg.classnum, 0) )';
 190
 191   return $search;
 192 }
 193
 194 =back
 195
 196 =head1 BUGS
 197
 198 =head1 SEE ALSO
 199
 200 L<FS::Record>, schema.html from the base documentation.
 201
 202 =cut
 203
 204 1;
 205