FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12
  13 @EXPORT_OK = qw( smart_search );
  14
  15 # 1 is mostly method/subroutine entry and options
  16 # 2 traces progress of some operations
  17 # 3 is even more information including possibly sensitive data
  18 $DEBUG = 0;
  19 $me = '[FS::cust_main::Search]';
  20
  21 @fuzzyfields = ( 'first', 'last', 'company', 'address1' );
  22
  23 install_callback FS::UID sub {
  24   $conf = new FS::Conf;
  25   #yes, need it for stuff below (prolly should be cached)
  26 };
  27
  28 =head1 NAME
  29
  30 FS::cust_main::Search - Customer searching
  31
  32 =head1 SYNOPSIS
  33
  34   use FS::cust_main::Search;
  35
  36   FS::cust_main::Search::smart_search(%options);
  37
  38   FS::cust_main::Search::email_search(%options);
  39
  40   FS::cust_main::Search->search( \%options );
  41
  42   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  43
  44 =head1 SUBROUTINES
  45
  46 =over 4
  47
  48 =item smart_search OPTION => VALUE ...
  49
  50 Accepts the following options: I<search>, the string to search for.  The string
  51 will be searched for as a customer number, phone number, name or company name,
  52 as an exact, or, in some cases, a substring or fuzzy match (see the source code
  53 for the exact heuristics used); I<no_fuzzy_on_exact>, causes smart_search to
  54 skip fuzzy matching when an exact match is found.
  55
  56 Any additional options are treated as an additional qualifier on the search
  57 (i.e. I<agentnum>).
  58
  59 Returns a (possibly empty) array of FS::cust_main objects.
  60
  61 =cut
  62
  63 sub smart_search {
  64   my %options = @_;
  65
  66   #here is the agent virtualization
  67   my $agentnums_sql =
  68     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  69
  70   my @cust_main = ();
  71
  72   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  73   my $search = delete $options{'search'};
  74   ( my $alphanum_search = $search ) =~ s/\W//g;
  75
  76   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  77
  78     #false laziness w/Record::ut_phone
  79     my $phonen = "$1-$2-$3";
  80     $phonen .= " x$4" if $4;
  81
  82     push @cust_main, qsearch( {
  83       'table'   => 'cust_main',
  84       'hashref' => { %options },
  85       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
  86                      ' ( '.
  87                          join(' OR ', map "$_ = '$phonen'",
  88                                           qw( daytime night fax
  89                                               ship_daytime ship_night ship_fax )
  90                              ).
  91                      ' ) '.
  92                      " AND $agentnums_sql", #agent virtualization
  93     } );
  94
  95     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
  96       #try looking for matches with extensions unless one was specified
  97
  98       push @cust_main, qsearch( {
  99         'table'   => 'cust_main',
 100         'hashref' => { %options },
 101         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 102                        ' ( '.
 103                            join(' OR ', map "$_ LIKE '$phonen\%'",
 104                                             qw( daytime night
 105                                                 ship_daytime ship_night )
 106                                ).
 107                        ' ) '.
 108                        " AND $agentnums_sql", #agent virtualization
 109       } );
 110
 111     }
 112
 113   # custnum search (also try agent_custid), with some tweaking options if your
 114   # legacy cust "numbers" have letters
 115   }
 116
 117
 118   if ( $search =~ /@/ ) {
 119       push @cust_main,
 120           map $_->cust_main,
 121               qsearch( {
 122                          'table'     => 'cust_main_invoice',
 123                          'hashref'   => { 'dest' => $search },
 124                        }
 125                      );
 126   } elsif ( $search =~ /^\s*(\d+)\s*$/
 127          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 128               && $search =~ /^\s*(\w\w?\d+)\s*$/
 129             )
 130          || ( $conf->config('cust_main-custnum-display_special')
 131            # it's not currently possible for special prefixes to contain
 132            # digits, so just strip off any alphabetic prefix and match
 133            # the rest to custnum
 134               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 135             )
 136          || ( $conf->exists('address1-search' )
 137               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 138             )
 139      )
 140   {
 141
 142     my $num = $1;
 143
 144     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 145       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 146                                 ? ' AND agent_custid IS NULL ' : '';
 147       push @cust_main, qsearch( {
 148         'table'     => 'cust_main',
 149         'hashref'   => { 'custnum' => $num, %options },
 150         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 151       } );
 152     }
 153
 154     # for all agents this user can see, if any of them have custnum prefixes
 155     # that match the search string, include customers that match the rest
 156     # of the custnum and belong to that agent
 157     foreach my $agentnum ( $FS::CurrentUser::CurrentUser->agentnums ) {
 158       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 159       next if !$p;
 160       if ( $p eq substr($num, 0, length($p)) ) {
 161         push @cust_main, qsearch( {
 162           'table'   => 'cust_main',
 163           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 164                          'agentnum' => $agentnum,
 165                           %options,
 166                        },
 167         } );
 168       }
 169     }
 170
 171     push @cust_main, qsearch( {
 172         'table'     => 'cust_main',
 173         'hashref'   => { 'agent_custid' => $num, %options },
 174         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 175     } );
 176
 177     if ( $conf->exists('address1-search') ) {
 178       my $len = length($num);
 179       $num = lc($num);
 180       foreach my $prefix ( '', 'ship_' ) {
 181         push @cust_main, qsearch( {
 182           'table'     => 'cust_main',
 183           'hashref'   => { %options, },
 184           'extra_sql' =>
 185             ( keys(%options) ? ' AND ' : ' WHERE ' ).
 186             " LOWER(SUBSTRING(${prefix}address1 FROM 1 FOR $len)) = '$num' ".
 187             " AND $agentnums_sql",
 188         } );
 189       }
 190     }
 191
 192   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 193
 194     my($company, $last, $first) = ( $1, $2, $3 );
 195
 196     # "Company (Last, First)"
 197     #this is probably something a browser remembered,
 198     #so just do an exact search (but case-insensitive, so USPS standardization
 199     #doesn't throw a wrench in the works)
 200
 201     foreach my $prefix ( '', 'ship_' ) {
 202       push @cust_main, qsearch( {
 203         'table'     => 'cust_main',
 204         'hashref'   => { %options },
 205         'extra_sql' =>
 206           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 207           join(' AND ',
 208             " LOWER(${prefix}first)   = ". dbh->quote(lc($first)),
 209             " LOWER(${prefix}last)    = ". dbh->quote(lc($last)),
 210             " LOWER(${prefix}company) = ". dbh->quote(lc($company)),
 211             $agentnums_sql,
 212           ),
 213       } );
 214     }
 215
 216   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 217                                               # try (ship_){last,company}
 218
 219     my $value = lc($1);
 220
 221     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 222     # # full strings the browser remembers won't work
 223     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 224
 225     use Lingua::EN::NameParse;
 226     my $NameParse = new Lingua::EN::NameParse(
 227              auto_clean     => 1,
 228              allow_reversed => 1,
 229     );
 230
 231     my($last, $first) = ( '', '' );
 232     #maybe disable this too and just rely on NameParse?
 233     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 234
 235       ($last, $first) = ( $1, $2 );
 236
 237     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 238     } elsif ( ! $NameParse->parse($value) ) {
 239
 240       my %name = $NameParse->components;
 241       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 242       $last  = $name{'surname_1'};
 243
 244     }
 245
 246     if ( $first && $last ) {
 247
 248       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 249
 250       #exact
 251       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 252       $sql .= "
 253         (     ( LOWER(last) = $q_last AND LOWER(first) = $q_first )
 254            OR ( LOWER(ship_last) = $q_last AND LOWER(ship_first) = $q_first )
 255         )";
 256
 257       push @cust_main, qsearch( {
 258         'table'     => 'cust_main',
 259         'hashref'   => \%options,
 260         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 261       } );
 262
 263       # or it just be something that was typed in... (try that in a sec)
 264
 265     }
 266
 267     my $q_value = dbh->quote($value);
 268
 269     #exact
 270     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 271     $sql .= " (    LOWER(last)          = $q_value
 272                 OR LOWER(company)       = $q_value
 273                 OR LOWER(ship_last)     = $q_value
 274                 OR LOWER(ship_company)  = $q_value
 275             ";
 276     $sql .= "   OR LOWER(address1)      = $q_value
 277                 OR LOWER(ship_address1) = $q_value
 278             "
 279       if $conf->exists('address1-search');
 280     $sql .= " )";
 281
 282     push @cust_main, qsearch( {
 283       'table'     => 'cust_main',
 284       'hashref'   => \%options,
 285       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 286     } );
 287
 288     #no exact match, trying substring/fuzzy
 289     #always do substring & fuzzy (unless they're explicity config'ed off)
 290     #getting complaints searches are not returning enough
 291     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 292
 293       #still some false laziness w/search (was search/cust_main.cgi)
 294
 295       #substring
 296
 297       my @hashrefs = (
 298         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 299         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 300       );
 301
 302       if ( $first && $last ) {
 303
 304         push @hashrefs,
 305           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 306             'last'         => { op=>'ILIKE', value=>"%$last%" },
 307           },
 308           { 'ship_first'   => { op=>'ILIKE', value=>"%$first%" },
 309             'ship_last'    => { op=>'ILIKE', value=>"%$last%" },
 310           },
 311         ;
 312
 313       } else {
 314
 315         push @hashrefs,
 316           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 317           { 'ship_last'    => { op=>'ILIKE', value=>"%$value%" }, },
 318         ;
 319       }
 320
 321       if ( $conf->exists('address1-search') ) {
 322         push @hashrefs,
 323           { 'address1'      => { op=>'ILIKE', value=>"%$value%" }, },
 324           { 'ship_address1' => { op=>'ILIKE', value=>"%$value%" }, },
 325         ;
 326       }
 327
 328       foreach my $hashref ( @hashrefs ) {
 329
 330         push @cust_main, qsearch( {
 331           'table'     => 'cust_main',
 332           'hashref'   => { %$hashref,
 333                            %options,
 334                          },
 335           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 336         } );
 337
 338       }
 339
 340       #fuzzy
 341       my @fuzopts = (
 342         \%options,                #hashref
 343         '',                       #select
 344         " AND $agentnums_sql",    #extra_sql  #agent virtualization
 345       );
 346
 347       if ( $first && $last ) {
 348         push @cust_main, FS::cust_main::Search->fuzzy_search(
 349           { 'last'   => $last,    #fuzzy hashref
 350             'first'  => $first }, #
 351           @fuzopts
 352         );
 353       }
 354       foreach my $field ( 'last', 'company' ) {
 355         push @cust_main,
 356           FS::cust_main::Search->fuzzy_search( { $field => $value }, @fuzopts );
 357       }
 358       if ( $conf->exists('address1-search') ) {
 359         push @cust_main,
 360           FS::cust_main::Search->fuzzy_search( { 'address1' => $value }, @fuzopts );
 361       }
 362
 363     }
 364
 365   }
 366
 367   #eliminate duplicates
 368   my %saw = ();
 369   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 370
 371   @cust_main;
 372
 373 }
 374
 375 =item email_search
 376
 377 Accepts the following options: I<email>, the email address to search for.  The
 378 email address will be searched for as an email invoice destination and as an
 379 svc_acct account.
 380
 381 #Any additional options are treated as an additional qualifier on the search
 382 #(i.e. I<agentnum>).
 383
 384 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 385 none or one).
 386
 387 =cut
 388
 389 sub email_search {
 390   my %options = @_;
 391
 392   local($DEBUG) = 1;
 393
 394   my $email = delete $options{'email'};
 395
 396   #we're only being used by RT at the moment... no agent virtualization yet
 397   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 398
 399   my @cust_main = ();
 400
 401   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 402
 403     my ( $user, $domain ) = ( $1, $2 );
 404
 405     warn "$me smart_search: searching for $user in domain $domain"
 406       if $DEBUG;
 407
 408     push @cust_main,
 409       map $_->cust_main,
 410           qsearch( {
 411                      'table'     => 'cust_main_invoice',
 412                      'hashref'   => { 'dest' => $email },
 413                    }
 414                  );
 415
 416     push @cust_main,
 417       map  $_->cust_main,
 418       grep $_,
 419       map  $_->cust_svc->cust_pkg,
 420           qsearch( {
 421                      'table'     => 'svc_acct',
 422                      'hashref'   => { 'username' => $user, },
 423                      'extra_sql' =>
 424                        'AND ( SELECT domain FROM svc_domain
 425                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 426                             ) = '. dbh->quote($domain),
 427                    }
 428                  );
 429   }
 430
 431   my %saw = ();
 432   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 433
 434   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 435     if $DEBUG;
 436
 437   @cust_main;
 438
 439 }
 440
 441 =back
 442
 443 =head1 CLASS METHODS
 444
 445 =over 4
 446
 447 =item search HASHREF
 448
 449 (Class method)
 450
 451 Returns a qsearch hash expression to search for parameters specified in
 452 HASHREF.  Valid parameters are
 453
 454 =over 4
 455
 456 =item agentnum
 457
 458 =item status
 459
 460 =item address
 461
 462 =item refnum
 463
 464 =item cancelled_pkgs
 465
 466 bool
 467
 468 =item signupdate
 469
 470 listref of start date, end date
 471
 472 =item birthdate
 473
 474 listref of start date, end date
 475
 476 =item spouse_birthdate
 477
 478 listref of start date, end date
 479
 480 =item payby
 481
 482 listref
 483
 484 =item paydate_year
 485
 486 =item paydate_month
 487
 488 =item current_balance
 489
 490 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 491
 492 =item cust_fields
 493
 494 =item flattened_pkgs
 495
 496 bool
 497
 498 =back
 499
 500 =cut
 501
 502 sub search {
 503   my ($class, $params) = @_;
 504
 505   my $dbh = dbh;
 506
 507   my @where = ();
 508   my $orderby;
 509
 510   # initialize these to prevent warnings
 511   $params = {
 512     'custnum'       => '',
 513     'agentnum'      => '',
 514     'usernum'       => '',
 515     'status'        => '',
 516     'address'       => '',
 517     'paydate_year'  => '',
 518     'invoice_terms' => '',
 519     'custbatch'     => '',
 520     %$params
 521   };
 522
 523   ##
 524   # explicit custnum(s)
 525   ##
 526
 527   if ( $params->{'custnum'} ) {
 528     my @custnums = ref($params->{'custnum'}) ?
 529                       @{ $params->{'custnum'} } :
 530                       $params->{'custnum'};
 531     push @where,
 532       'cust_main.custnum IN (' .
 533       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 534       ')' if scalar(@custnums) > 0;
 535   }
 536
 537   ##
 538   # parse agent
 539   ##
 540
 541   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 542     push @where,
 543       "cust_main.agentnum = $1";
 544   }
 545
 546   ##
 547   # do the same for user
 548   ##
 549
 550   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 551     push @where,
 552       "cust_main.usernum = $1";
 553   }
 554
 555   ##
 556   # parse status
 557   ##
 558
 559   #prospect ordered active inactive suspended cancelled
 560   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 561     my $method = $params->{'status'}. '_sql';
 562     #push @where, $class->$method();
 563     push @where, FS::cust_main->$method();
 564   }
 565
 566   ##
 567   # address
 568   ##
 569   if ( $params->{'address'} =~ /\S/ ) {
 570     my $address = dbh->quote('%'. lc($params->{'address'}). '%');
 571     push @where, '('. join(' OR ',
 572                              map "LOWER($_) LIKE $address",
 573                                qw(address1 address2 ship_address1 ship_address2)
 574                           ).
 575                  ')';
 576   }
 577
 578   ###
 579   # refnum
 580   ###
 581   if ( $params->{'refnum'}  ) {
 582
 583     my @refnum = ref( $params->{'refnum'} )
 584                    ? @{ $params->{'refnum'} }
 585                    :  ( $params->{'refnum'} );
 586
 587     @refnum = grep /^(\d*)$/, @refnum;
 588
 589     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 590       if @refnum;
 591
 592   }
 593
 594   ##
 595   # parse cancelled package checkbox
 596   ##
 597
 598   my $pkgwhere = "";
 599
 600   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 601     unless $params->{'cancelled_pkgs'};
 602
 603   ##
 604   # parse without census tract checkbox
 605   ##
 606
 607   push @where, "(censustract = '' or censustract is null)"
 608     if $params->{'no_censustract'};
 609
 610   ##
 611   # parse with hardcoded tax location checkbox
 612   ##
 613
 614   push @where, "geocode is not null"
 615     if $params->{'with_geocode'};
 616
 617   ##
 618   # dates
 619   ##
 620
 621   foreach my $field (qw( signupdate birthdate spouse_birthdate )) {
 622
 623     next unless exists($params->{$field});
 624
 625     my($beginning, $ending, $hour) = @{$params->{$field}};
 626
 627     push @where,
 628       "cust_main.$field IS NOT NULL",
 629       "cust_main.$field >= $beginning",
 630       "cust_main.$field <= $ending";
 631
 632     if($field eq 'signupdate' && defined $hour) {
 633       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 634         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 635       }
 636       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 637         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 638       }
 639       else {
 640         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 641       }
 642     }
 643
 644     $orderby ||= "ORDER BY cust_main.$field";
 645
 646   }
 647
 648   ###
 649   # classnum
 650   ###
 651
 652   if ( $params->{'classnum'} ) {
 653
 654     my @classnum = ref( $params->{'classnum'} )
 655                      ? @{ $params->{'classnum'} }
 656                      :  ( $params->{'classnum'} );
 657
 658     @classnum = grep /^(\d*)$/, @classnum;
 659
 660     if ( @classnum ) {
 661       push @where, '( '. join(' OR ', map {
 662                                             $_ ? "cust_main.classnum = $_"
 663                                                : "cust_main.classnum IS NULL"
 664                                           }
 665                                           @classnum
 666                              ).
 667                    ' )';
 668     }
 669
 670   }
 671
 672   ###
 673   # payby
 674   ###
 675
 676   if ( $params->{'payby'} ) {
 677
 678     my @payby = ref( $params->{'payby'} )
 679                   ? @{ $params->{'payby'} }
 680                   :  ( $params->{'payby'} );
 681
 682     @payby = grep /^([A-Z]{4})$/, @payby;
 683
 684     push @where, '( '. join(' OR ', map "cust_main.payby = '$_'", @payby). ' )'
 685       if @payby;
 686
 687   }
 688
 689   ###
 690   # paydate_year / paydate_month
 691   ###
 692
 693   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 694     my $year = $1;
 695     $params->{'paydate_month'} =~ /^(\d\d?)$/
 696       or die "paydate_year without paydate_month?";
 697     my $month = $1;
 698
 699     push @where,
 700       'paydate IS NOT NULL',
 701       "paydate != ''",
 702       "CAST(paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 703 ;
 704   }
 705
 706   ###
 707   # invoice terms
 708   ###
 709
 710   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 711     my $terms = $1;
 712     if ( $1 eq 'NULL' ) {
 713       push @where,
 714         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 715     } else {
 716       push @where,
 717         "cust_main.invoice_terms IS NOT NULL",
 718         "cust_main.invoice_terms = '$1'";
 719     }
 720   }
 721
 722   ##
 723   # amounts
 724   ##
 725
 726   if ( $params->{'current_balance'} ) {
 727
 728     #my $balance_sql = $class->balance_sql();
 729     my $balance_sql = FS::cust_main->balance_sql();
 730
 731     my @current_balance =
 732       ref( $params->{'current_balance'} )
 733       ? @{ $params->{'current_balance'} }
 734       :  ( $params->{'current_balance'} );
 735
 736     push @where, map { s/current_balance/$balance_sql/; $_ }
 737                      @current_balance;
 738
 739   }
 740
 741   ##
 742   # custbatch
 743   ##
 744
 745   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 746     push @where,
 747       "cust_main.custbatch = '$1'";
 748   }
 749
 750   if ( $params->{'tagnum'} ) {
 751     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 752
 753     @tagnums = grep /^(\d+)$/, @tagnums;
 754
 755     if ( @tagnums ) {
 756         my $tags_where = "0 < (select count(1) from cust_tag where "
 757                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 758                 . join(',', @tagnums) . "))";
 759
 760         push @where, $tags_where;
 761     }
 762   }
 763
 764
 765   ##
 766   # setup queries, subs, etc. for the search
 767   ##
 768
 769   $orderby ||= 'ORDER BY custnum';
 770
 771   # here is the agent virtualization
 772   push @where,
 773     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
 774
 775   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
 776
 777   my $addl_from = '';
 778
 779   my $count_query = "SELECT COUNT(*) FROM cust_main $extra_sql";
 780
 781   my @select = (
 782                  'cust_main.custnum',
 783                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
 784                );
 785
 786   my(@extra_headers) = ();
 787   my(@extra_fields)  = ();
 788
 789   if ($params->{'flattened_pkgs'}) {
 790
 791     #my $pkg_join = '';
 792     $addl_from .= ' LEFT JOIN cust_pkg USING ( custnum ) ';
 793
 794     if ($dbh->{Driver}->{Name} eq 'Pg') {
 795
 796       push @select, "array_to_string(array(select pkg from cust_pkg left join part_pkg using ( pkgpart ) where cust_main.custnum = cust_pkg.custnum $pkgwhere),'|') as magic";
 797
 798     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
 799       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
 800       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
 801       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
 802     } else {
 803       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 804            "omitting package information from report.";
 805     }
 806
 807     my $header_query = "SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count FROM cust_main $addl_from $extra_sql $pkgwhere group by cust_main.custnum order by count desc limit 1";
 808
 809     my $sth = dbh->prepare($header_query) or die dbh->errstr;
 810     $sth->execute() or die $sth->errstr;
 811     my $headerrow = $sth->fetchrow_arrayref;
 812     my $headercount = $headerrow ? $headerrow->[0] : 0;
 813     while($headercount) {
 814       unshift @extra_headers, "Package ". $headercount;
 815       unshift @extra_fields, eval q!sub {my $c = shift;
 816                                          my @a = split '\|', $c->magic;
 817                                          my $p = $a[!.--$headercount. q!];
 818                                          $p;
 819                                         };!;
 820     }
 821
 822   }
 823
 824   if ( $params->{'with_geocode'} ) {
 825
 826     unshift @extra_headers, 'Tax location override', 'Calculated tax location';
 827     unshift @extra_fields, sub { my $c = shift; $c->get('geocode'); },
 828                            sub { my $c = shift;
 829                                  $c->set('geocode', '');
 830                                  $c->geocode('cch'); #XXX only cch right now
 831                                };
 832     push @select, 'geocode';
 833     push @select, 'zip' unless grep { $_ eq 'zip' } @select;
 834     push @select, 'ship_zip' unless grep { $_ eq 'ship_zip' } @select;
 835   }
 836
 837   my $select = join(', ', @select);
 838
 839   my $sql_query = {
 840     'table'         => 'cust_main',
 841     'select'        => $select,
 842     'addl_from'     => $addl_from,
 843     'hashref'       => {},
 844     'extra_sql'     => $extra_sql,
 845     'order_by'      => $orderby,
 846     'count_query'   => $count_query,
 847     'extra_headers' => \@extra_headers,
 848     'extra_fields'  => \@extra_fields,
 849   };
 850
 851 }
 852
 853 =item fuzzy_search FUZZY_HASHREF [ HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ ]
 854
 855 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
 856 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
 857 specified (the appropriate ship_ field is also searched).
 858
 859 Additional options are the same as FS::Record::qsearch
 860
 861 =cut
 862
 863 sub fuzzy_search {
 864   my( $self, $fuzzy, $hash, @opt) = @_;
 865   #$self
 866   $hash ||= {};
 867   my @cust_main = ();
 868
 869   check_and_rebuild_fuzzyfiles();
 870   foreach my $field ( keys %$fuzzy ) {
 871
 872     my $all = $self->all_X($field);
 873     next unless scalar(@$all);
 874
 875     my %match = ();
 876     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, ['i'], @$all ) );
 877
 878     my @fcust = ();
 879     foreach ( keys %match ) {
 880       push @fcust, qsearch('cust_main', { %$hash, $field=>$_}, @opt);
 881       push @fcust, qsearch('cust_main', { %$hash, "ship_$field"=>$_}, @opt);
 882     }
 883     my %fsaw = ();
 884     push @cust_main, grep { ! $fsaw{$_->custnum}++ } @fcust;
 885   }
 886
 887   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
 888   my %saw = ();
 889   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
 890
 891   @cust_main;
 892
 893 }
 894
 895 =back
 896
 897 =head1 UTILITY SUBROUTINES
 898
 899 =over 4
 900
 901 =item check_and_rebuild_fuzzyfiles
 902
 903 =cut
 904
 905 sub check_and_rebuild_fuzzyfiles {
 906   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 907   rebuild_fuzzyfiles() if grep { ! -e "$dir/cust_main.$_" } @fuzzyfields;
 908 }
 909
 910 =item rebuild_fuzzyfiles
 911
 912 =cut
 913
 914 sub rebuild_fuzzyfiles {
 915
 916   use Fcntl qw(:flock);
 917
 918   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 919   mkdir $dir, 0700 unless -d $dir;
 920
 921   foreach my $fuzzy ( @fuzzyfields ) {
 922
 923     open(LOCK,">>$dir/cust_main.$fuzzy")
 924       or die "can't open $dir/cust_main.$fuzzy: $!";
 925     flock(LOCK,LOCK_EX)
 926       or die "can't lock $dir/cust_main.$fuzzy: $!";
 927
 928     open (CACHE, '>:encoding(UTF-8)', "$dir/cust_main.$fuzzy.tmp")
 929       or die "can't open $dir/cust_main.$fuzzy.tmp: $!";
 930
 931     foreach my $field ( $fuzzy, "ship_$fuzzy" ) {
 932       my $sth = dbh->prepare("SELECT $field FROM cust_main".
 933                              " WHERE $field != '' AND $field IS NOT NULL");
 934       $sth->execute or die $sth->errstr;
 935
 936       while ( my $row = $sth->fetchrow_arrayref ) {
 937         print CACHE $row->[0]. "\n";
 938       }
 939
 940     }
 941
 942     close CACHE or die "can't close $dir/cust_main.$fuzzy.tmp: $!";
 943
 944     rename "$dir/cust_main.$fuzzy.tmp", "$dir/cust_main.$fuzzy";
 945     close LOCK;
 946   }
 947
 948 }
 949
 950 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
 951
 952 =cut
 953
 954 sub append_fuzzyfiles {
 955   #my( $first, $last, $company ) = @_;
 956
 957   check_and_rebuild_fuzzyfiles();
 958
 959   use Fcntl qw(:flock);
 960
 961   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 962
 963   foreach my $field (@fuzzyfields) {
 964     my $value = shift;
 965
 966     if ( $value ) {
 967
 968       open(CACHE, '>>:encoding(UTF-8)', "$dir/cust_main.$field" )
 969         or die "can't open $dir/cust_main.$field: $!";
 970       flock(CACHE,LOCK_EX)
 971         or die "can't lock $dir/cust_main.$field: $!";
 972
 973       print CACHE "$value\n";
 974
 975       flock(CACHE,LOCK_UN)
 976         or die "can't unlock $dir/cust_main.$field: $!";
 977       close CACHE;
 978     }
 979
 980   }
 981
 982   1;
 983 }
 984
 985 =item all_X
 986
 987 =cut
 988
 989 sub all_X {
 990   my( $self, $field ) = @_;
 991   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 992   open(CACHE, '<:encoding(UTF-8)', "$dir/cust_main.$field")
 993     or die "can't open $dir/cust_main.$field: $!";
 994   my @array = map { chomp; $_; } <CACHE>;
 995   close CACHE;
 996   \@array;
 997 }
 998
 999 =head1 BUGS
1000
1001 Bed bugs
1002
1003 =head1 SEE ALSO
1004
1005 L<FS::cust_main>, L<FS::Record>
1006
1007 =cut
1008
1009 1;
1010