FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf $money_char );
   5 use vars qw( $invoice_lines @buf ); #yuck
   6 use Fcntl qw(:flock); #for spool_csv
   7 use List::Util qw(min max);
   8 use IPC::Run3;
   9 use Date::Format;
  10 use Text::Template 1.20;
  11 use File::Temp 0.14;
  12 use String::ShellQuote;
  13 use HTML::Entities;
  14 use Locale::Country;
  15 use FS::UID qw( datasrc );
  16 use FS::Misc qw( send_email send_fax );
  17 use FS::Record qw( qsearch qsearchs dbh );
  18 use FS::cust_main_Mixin;
  19 use FS::cust_main;
  20 use FS::cust_bill_pkg;
  21 use FS::cust_credit;
  22 use FS::cust_pay;
  23 use FS::cust_pkg;
  24 use FS::cust_credit_bill;
  25 use FS::pay_batch;
  26 use FS::cust_pay_batch;
  27 use FS::cust_bill_event;
  28 use FS::part_pkg;
  29 use FS::cust_bill_pay;
  30 use FS::cust_bill_pay_batch;
  31 use FS::part_bill_event;
  32 use FS::payby;
  33
  34 @ISA = qw( FS::cust_main_Mixin FS::Record );
  35
  36 $DEBUG = 0;
  37 $me = '[FS::cust_bill]';
  38
  39 #ask FS::UID to run this stuff for us later
  40 FS::UID->install_callback( sub {
  41   $conf = new FS::Conf;
  42   $money_char = $conf->config('money_char') || '$';
  43 } );
  44
  45 =head1 NAME
  46
  47 FS::cust_bill - Object methods for cust_bill records
  48
  49 =head1 SYNOPSIS
  50
  51   use FS::cust_bill;
  52
  53   $record = new FS::cust_bill \%hash;
  54   $record = new FS::cust_bill { 'column' => 'value' };
  55
  56   $error = $record->insert;
  57
  58   $error = $new_record->replace($old_record);
  59
  60   $error = $record->delete;
  61
  62   $error = $record->check;
  63
  64   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  65
  66   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  67
  68   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  69
  70   @cust_pay_objects = $cust_bill->cust_pay;
  71
  72   $tax_amount = $record->tax;
  73
  74   @lines = $cust_bill->print_text;
  75   @lines = $cust_bill->print_text $time;
  76
  77 =head1 DESCRIPTION
  78
  79 An FS::cust_bill object represents an invoice; a declaration that a customer
  80 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
  81 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
  82 following fields are currently supported:
  83
  84 =over 4
  85
  86 =item invnum - primary key (assigned automatically for new invoices)
  87
  88 =item custnum - customer (see L<FS::cust_main>)
  89
  90 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  91 L<Time::Local> and L<Date::Parse> for conversion functions.
  92
  93 =item charged - amount of this invoice
  94
  95 =item printed - deprecated
  96
  97 =item closed - books closed flag, empty or `Y'
  98
  99 =back
 100
 101 =head1 METHODS
 102
 103 =over 4
 104
 105 =item new HASHREF
 106
 107 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 108 Invoices are normally created by calling the bill method of a customer object
 109 (see L<FS::cust_main>).
 110
 111 =cut
 112
 113 sub table { 'cust_bill'; }
 114
 115 sub cust_linked { $_[0]->cust_main_custnum; }
 116 sub cust_unlinked_msg {
 117   my $self = shift;
 118   "WARNING: can't find cust_main.custnum ". $self->custnum.
 119   ' (cust_bill.invnum '. $self->invnum. ')';
 120 }
 121
 122 =item insert
 123
 124 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 125 returns the error, otherwise returns false.
 126
 127 =item delete
 128
 129 This method now works but you probably shouldn't use it.  Instead, apply a
 130 credit against the invoice.
 131
 132 Using this method to delete invoices outright is really, really bad.  There
 133 would be no record you ever posted this invoice, and there are no check to
 134 make sure charged = 0 or that there are no associated cust_bill_pkg records.
 135
 136 Really, don't use it.
 137
 138 =cut
 139
 140 sub delete {
 141   my $self = shift;
 142   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 143   $self->SUPER::delete(@_);
 144 }
 145
 146 =item replace OLD_RECORD
 147
 148 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 149 returns the error, otherwise returns false.
 150
 151 Only printed may be changed.  printed is normally updated by calling the
 152 collect method of a customer object (see L<FS::cust_main>).
 153
 154 =cut
 155
 156 #replace can be inherited from Record.pm
 157
 158 # replace_check is now the preferred way to #implement replace data checks
 159 # (so $object->replace() works without an argument)
 160
 161 sub replace_check {
 162   my( $new, $old ) = ( shift, shift );
 163   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 164   #return "Can't change _date!" unless $old->_date eq $new->_date;
 165   return "Can't change _date!" unless $old->_date == $new->_date;
 166   return "Can't change charged!" unless $old->charged == $new->charged
 167                                      || $old->charged == 0;
 168
 169   '';
 170 }
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid invoice.  If there is an error,
 175 returns the error, otherwise returns false.  Called by the insert and replace
 176 methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('invnum')
 185     || $self->ut_number('custnum')
 186     || $self->ut_numbern('_date')
 187     || $self->ut_money('charged')
 188     || $self->ut_numbern('printed')
 189     || $self->ut_enum('closed', [ '', 'Y' ])
 190   ;
 191   return $error if $error;
 192
 193   return "Unknown customer"
 194     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 195
 196   $self->_date(time) unless $self->_date;
 197
 198   $self->printed(0) if $self->printed eq '';
 199
 200   $self->SUPER::check;
 201 }
 202
 203 =item previous
 204
 205 Returns a list consisting of the total previous balance for this customer,
 206 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 207
 208 =cut
 209
 210 sub previous {
 211   my $self = shift;
 212   my $total = 0;
 213   my @cust_bill = sort { $a->_date <=> $b->_date }
 214     grep { $_->owed != 0 && $_->_date < $self->_date }
 215       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 216   ;
 217   foreach ( @cust_bill ) { $total += $_->owed; }
 218   $total, @cust_bill;
 219 }
 220
 221 =item cust_bill_pkg
 222
 223 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 224
 225 =cut
 226
 227 sub cust_bill_pkg {
 228   my $self = shift;
 229   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 230 }
 231
 232 =item cust_pkg
 233
 234 Returns the packages (see L<FS::cust_pkg>) corresponding to the line items for
 235 this invoice.
 236
 237 =cut
 238
 239 sub cust_pkg {
 240   my $self = shift;
 241   my @cust_pkg = map { $_->cust_pkg } $self->cust_bill_pkg;
 242   my %saw = ();
 243   grep { ! $saw{$_->pkgnum}++ } @cust_pkg;
 244 }
 245
 246 =item open_cust_bill_pkg
 247
 248 Returns the open line items for this invoice.
 249
 250 Note that cust_bill_pkg with both setup and recur fees are returned as two
 251 separate line items, each with only one fee.
 252
 253 =cut
 254
 255 # modeled after cust_main::open_cust_bill
 256 sub open_cust_bill_pkg {
 257   my $self = shift;
 258
 259   # grep { $_->owed > 0 } $self->cust_bill_pkg
 260
 261   my %other = ( 'recur' => 'setup',
 262                 'setup' => 'recur', );
 263   my @open = ();
 264   foreach my $field ( qw( recur setup )) {
 265     push @open, map  { $_->set( $other{$field}, 0 ); $_; }
 266                 grep { $_->owed($field) > 0 }
 267                 $self->cust_bill_pkg;
 268   }
 269
 270   @open;
 271 }
 272
 273 =item cust_bill_event
 274
 275 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 276 invoice.
 277
 278 =cut
 279
 280 sub cust_bill_event {
 281   my $self = shift;
 282   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 283 }
 284
 285
 286 =item cust_main
 287
 288 Returns the customer (see L<FS::cust_main>) for this invoice.
 289
 290 =cut
 291
 292 sub cust_main {
 293   my $self = shift;
 294   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 295 }
 296
 297 =item cust_suspend_if_balance_over AMOUNT
 298
 299 Suspends the customer associated with this invoice if the total amount owed on
 300 this invoice and all older invoices is greater than the specified amount.
 301
 302 Returns a list: an empty list on success or a list of errors.
 303
 304 =cut
 305
 306 sub cust_suspend_if_balance_over {
 307   my( $self, $amount ) = ( shift, shift );
 308   my $cust_main = $self->cust_main;
 309   if ( $cust_main->total_owed_date($self->_date) < $amount ) {
 310     return ();
 311   } else {
 312     $cust_main->suspend(@_);
 313   }
 314 }
 315
 316 =item cust_credit
 317
 318 Depreciated.  See the cust_credited method.
 319
 320  #Returns a list consisting of the total previous credited (see
 321  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 322  #outstanding credits (FS::cust_credit objects).
 323
 324 =cut
 325
 326 sub cust_credit {
 327   use Carp;
 328   croak "FS::cust_bill->cust_credit depreciated; see ".
 329         "FS::cust_bill->cust_credit_bill";
 330   #my $self = shift;
 331   #my $total = 0;
 332   #my @cust_credit = sort { $a->_date <=> $b->_date }
 333   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 334   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 335   #;
 336   #foreach (@cust_credit) { $total += $_->credited; }
 337   #$total, @cust_credit;
 338 }
 339
 340 =item cust_pay
 341
 342 Depreciated.  See the cust_bill_pay method.
 343
 344 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 345
 346 =cut
 347
 348 sub cust_pay {
 349   use Carp;
 350   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 351   #my $self = shift;
 352   #sort { $a->_date <=> $b->_date }
 353   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 354   #;
 355 }
 356
 357 =item cust_bill_pay
 358
 359 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 360
 361 =cut
 362
 363 sub cust_bill_pay {
 364   my $self = shift;
 365   sort { $a->_date <=> $b->_date }
 366     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 367 }
 368
 369 =item cust_credited
 370
 371 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 372
 373 =cut
 374
 375 sub cust_credited {
 376   my $self = shift;
 377   sort { $a->_date <=> $b->_date }
 378     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 379   ;
 380 }
 381
 382 =item tax
 383
 384 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 385
 386 =cut
 387
 388 sub tax {
 389   my $self = shift;
 390   my $total = 0;
 391   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 392                                              'pkgnum' => 0 } );
 393   foreach (@taxlines) { $total += $_->setup; }
 394   $total;
 395 }
 396
 397 =item owed
 398
 399 Returns the amount owed (still outstanding) on this invoice, which is charged
 400 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 401 applications (see L<FS::cust_credit_bill>).
 402
 403 =cut
 404
 405 sub owed {
 406   my $self = shift;
 407   my $balance = $self->charged;
 408   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 409   $balance -= $_->amount foreach ( $self->cust_credited );
 410   $balance = sprintf( "%.2f", $balance);
 411   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 412   $balance;
 413 }
 414
 415 =item apply_payments_and_credits
 416
 417 =cut
 418
 419 sub apply_payments_and_credits {
 420   my $self = shift;
 421
 422   my @payments = grep { $_->unapplied > 0 } $self->cust_main->cust_pay;
 423   my @credits  = grep { $_->credited > 0 } $self->cust_main->cust_credit;
 424
 425   while ( $self->owed > 0 and ( @payments || @credits ) ) {
 426
 427     my $app = '';
 428     if ( @payments && @credits ) {
 429
 430       #decide which goes first by weight of top (unapplied) line item
 431
 432       my @open_lineitems = $self->open_cust_bill_pkg;
 433
 434       my $max_pay_weight =
 435         max( map  { $_->part_pkg->pay_weight || 0 }
 436              grep { $_ }
 437              map  { $_->cust_pkg }
 438                   @open_lineitems
 439            );
 440       my $max_credit_weight =
 441         max( map  { $_->part_pkg->credit_weight || 0 }
 442              grep { $_ }
 443              map  { $_->cust_pkg }
 444                   @open_lineitems
 445            );
 446
 447       #if both are the same... payments first?  it has to be something
 448       if ( $max_pay_weight >= $max_credit_weight ) {
 449         $app = 'pay';
 450       } else {
 451         $app = 'credit';
 452       }
 453
 454     } elsif ( @payments ) {
 455       $app = 'pay';
 456     } elsif ( @credits ) {
 457       $app = 'credit';
 458     } else {
 459       die "guru meditation #12 and 35";
 460     }
 461
 462     if ( $app eq 'pay' ) {
 463
 464       my $payment = shift @payments;
 465
 466       $app = new FS::cust_bill_pay {
 467         'paynum'  => $payment->paynum,
 468         'amount'  => sprintf('%.2f', min( $payment->unapplied, $self->owed ) ),
 469       };
 470
 471     } elsif ( $app eq 'credit' ) {
 472
 473       my $credit = shift @credits;
 474
 475       $app = new FS::cust_credit_bill {
 476         'crednum' => $credit->crednum,
 477         'amount'  => sprintf('%.2f', min( $credit->credited, $self->owed ) ),
 478       };
 479
 480     } else {
 481       die "guru meditation #12 and 35";
 482     }
 483
 484     $app->invnum( $self->invnum );
 485
 486     my $error = $app->insert;
 487     die $error if $error;
 488
 489   }
 490
 491 }
 492
 493 =item generate_email PARAMHASH
 494
 495 PARAMHASH can contain the following:
 496
 497 =over 4
 498
 499 =item from       => sender address, required
 500
 501 =item tempate    => alternate template name, optional
 502
 503 =item print_text => text attachment arrayref, optional
 504
 505 =item subject    => email subject, optional
 506
 507 =back
 508
 509 Returns an argument list to be passed to L<FS::Misc::send_email>.
 510
 511 =cut
 512
 513 use MIME::Entity;
 514
 515 sub generate_email {
 516
 517   my $self = shift;
 518   my %args = @_;
 519
 520   my $me = '[FS::cust_bill::generate_email]';
 521
 522   my %return = (
 523     'from'      => $args{'from'},
 524     'subject'   => (($args{'subject'}) ? $args{'subject'} : 'Invoice'),
 525   );
 526
 527   if (ref($args{'to'}) eq 'ARRAY') {
 528     $return{'to'} = $args{'to'};
 529   } else {
 530     $return{'to'} = [ grep { $_ !~ /^(POST|FAX)$/ }
 531                            $self->cust_main->invoicing_list
 532                     ];
 533   }
 534
 535   if ( $conf->exists('invoice_html') ) {
 536
 537     warn "$me creating HTML/text multipart message"
 538       if $DEBUG;
 539
 540     $return{'nobody'} = 1;
 541
 542     my $alternative = build MIME::Entity
 543       'Type'        => 'multipart/alternative',
 544       'Encoding'    => '7bit',
 545       'Disposition' => 'inline'
 546     ;
 547
 548     my $data;
 549     if ( $conf->exists('invoice_email_pdf')
 550          and scalar($conf->config('invoice_email_pdf_note')) ) {
 551
 552       warn "$me using 'invoice_email_pdf_note' in multipart message"
 553         if $DEBUG;
 554       $data = [ map { $_ . "\n" }
 555                     $conf->config('invoice_email_pdf_note')
 556               ];
 557
 558     } else {
 559
 560       warn "$me not using 'invoice_email_pdf_note' in multipart message"
 561         if $DEBUG;
 562       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 563         $data = $args{'print_text'};
 564       } else {
 565         $data = [ $self->print_text('', $args{'template'}) ];
 566       }
 567
 568     }
 569
 570     $alternative->attach(
 571       'Type'        => 'text/plain',
 572       #'Encoding'    => 'quoted-printable',
 573       'Encoding'    => '7bit',
 574       'Data'        => $data,
 575       'Disposition' => 'inline',
 576     );
 577
 578     $args{'from'} =~ /\@([\w\.\-]+)/;
 579     my $from = $1 || 'example.com';
 580     my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
 581
 582     my $path = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
 583     my $file;
 584     if ( defined($args{'template'}) && length($args{'template'})
 585          && -e "$path/logo_". $args{'template'}. ".png"
 586        )
 587     {
 588       $file = "$path/logo_". $args{'template'}. ".png";
 589     } else {
 590       $file = "$path/logo.png";
 591     }
 592
 593     my $image = build MIME::Entity
 594       'Type'       => 'image/png',
 595       'Encoding'   => 'base64',
 596       'Path'       => $file,
 597       'Filename'   => 'logo.png',
 598       'Content-ID' => "<$content_id>",
 599     ;
 600
 601     $alternative->attach(
 602       'Type'        => 'text/html',
 603       'Encoding'    => 'quoted-printable',
 604       'Data'        => [ '<html>',
 605                          '  <head>',
 606                          '    <title>',
 607                          '      '. encode_entities($return{'subject'}),
 608                          '    </title>',
 609                          '  </head>',
 610                          '  <body bgcolor="#e8e8e8">',
 611                          $self->print_html('', $args{'template'}, $content_id),
 612                          '  </body>',
 613                          '</html>',
 614                        ],
 615       'Disposition' => 'inline',
 616       #'Filename'    => 'invoice.pdf',
 617     );
 618
 619     if ( $conf->exists('invoice_email_pdf') ) {
 620
 621       #attaching pdf too:
 622       # multipart/mixed
 623       #   multipart/related
 624       #     multipart/alternative
 625       #       text/plain
 626       #       text/html
 627       #     image/png
 628       #   application/pdf
 629
 630       my $related = build MIME::Entity 'Type'     => 'multipart/related',
 631                                        'Encoding' => '7bit';
 632
 633       #false laziness w/Misc::send_email
 634       $related->head->replace('Content-type',
 635         $related->mime_type.
 636         '; boundary="'. $related->head->multipart_boundary. '"'.
 637         '; type=multipart/alternative'
 638       );
 639
 640       $related->add_part($alternative);
 641
 642       $related->add_part($image);
 643
 644       my $pdf = build MIME::Entity $self->mimebuild_pdf('', $args{'template'});
 645
 646       $return{'mimeparts'} = [ $related, $pdf ];
 647
 648     } else {
 649
 650       #no other attachment:
 651       # multipart/related
 652       #   multipart/alternative
 653       #     text/plain
 654       #     text/html
 655       #   image/png
 656
 657       $return{'content-type'} = 'multipart/related';
 658       $return{'mimeparts'} = [ $alternative, $image ];
 659       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
 660       #$return{'disposition'} = 'inline';
 661
 662     }
 663
 664   } else {
 665
 666     if ( $conf->exists('invoice_email_pdf') ) {
 667       warn "$me creating PDF attachment"
 668         if $DEBUG;
 669
 670       #mime parts arguments a la MIME::Entity->build().
 671       $return{'mimeparts'} = [
 672         { $self->mimebuild_pdf('', $args{'template'}) }
 673       ];
 674     }
 675
 676     if ( $conf->exists('invoice_email_pdf')
 677          and scalar($conf->config('invoice_email_pdf_note')) ) {
 678
 679       warn "$me using 'invoice_email_pdf_note'"
 680         if $DEBUG;
 681       $return{'body'} = [ map { $_ . "\n" }
 682                               $conf->config('invoice_email_pdf_note')
 683                         ];
 684
 685     } else {
 686
 687       warn "$me not using 'invoice_email_pdf_note'"
 688         if $DEBUG;
 689       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
 690         $return{'body'} = $args{'print_text'};
 691       } else {
 692         $return{'body'} = [ $self->print_text('', $args{'template'}) ];
 693       }
 694
 695     }
 696
 697   }
 698
 699   %return;
 700
 701 }
 702
 703 =item mimebuild_pdf
 704
 705 Returns a list suitable for passing to MIME::Entity->build(), representing
 706 this invoice as PDF attachment.
 707
 708 =cut
 709
 710 sub mimebuild_pdf {
 711   my $self = shift;
 712   (
 713     'Type'        => 'application/pdf',
 714     'Encoding'    => 'base64',
 715     'Data'        => [ $self->print_pdf(@_) ],
 716     'Disposition' => 'attachment',
 717     'Filename'    => 'invoice.pdf',
 718   );
 719 }
 720
 721 =item send [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 722
 723 Sends this invoice to the destinations configured for this customer: sends
 724 email, prints and/or faxes.  See L<FS::cust_main_invoice>.
 725
 726 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 727
 728 AGENTNUM, if specified, means that this invoice will only be sent for customers
 729 of the specified agent or agent(s).  AGENTNUM can be a scalar agentnum (for a
 730 single agent) or an arrayref of agentnums.
 731
 732 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 733
 734 =cut
 735
 736 sub queueable_send {
 737   my %opt = @_;
 738
 739   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 740     or die "invalid invoice number: " . $opt{invnum};
 741
 742   my @args = ( $opt{template}, $opt{agentnum} );
 743   push @args, $opt{invoice_from}
 744     if exists($opt{invoice_from}) && $opt{invoice_from};
 745
 746   my $error = $self->send( @args );
 747   die $error if $error;
 748
 749 }
 750
 751 sub send {
 752   my $self = shift;
 753   my $template = scalar(@_) ? shift : '';
 754   if ( scalar(@_) && $_[0]  ) {
 755     my $agentnums = ref($_[0]) ? shift : [ shift ];
 756     return 'N/A' unless grep { $_ == $self->cust_main->agentnum } @$agentnums;
 757   }
 758
 759   my $invoice_from =
 760     scalar(@_)
 761       ? shift
 762       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 763
 764   my @invoicing_list = $self->cust_main->invoicing_list;
 765
 766   $self->email($template, $invoice_from)
 767     if grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list or !@invoicing_list;
 768
 769   $self->print($template)
 770     if grep { $_ eq 'POST' } @invoicing_list; #postal
 771
 772   $self->fax($template)
 773     if grep { $_ eq 'FAX' } @invoicing_list; #fax
 774
 775   '';
 776
 777 }
 778
 779 =item email [ TEMPLATENAME  [ , INVOICE_FROM ] ]
 780
 781 Emails this invoice.
 782
 783 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 784
 785 INVOICE_FROM, if specified, overrides the default email invoice From: address.
 786
 787 =cut
 788
 789 sub queueable_email {
 790   my %opt = @_;
 791
 792   my $self = qsearchs('cust_bill', { 'invnum' => $opt{invnum} } )
 793     or die "invalid invoice number: " . $opt{invnum};
 794
 795   my @args = ( $opt{template} );
 796   push @args, $opt{invoice_from}
 797     if exists($opt{invoice_from}) && $opt{invoice_from};
 798
 799   my $error = $self->email( @args );
 800   die $error if $error;
 801
 802 }
 803
 804 sub email {
 805   my $self = shift;
 806   my $template = scalar(@_) ? shift : '';
 807   my $invoice_from =
 808     scalar(@_)
 809       ? shift
 810       : ( $self->_agent_invoice_from || $conf->config('invoice_from') );
 811
 812   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 813                             $self->cust_main->invoicing_list;
 814
 815   #better to notify this person than silence
 816   @invoicing_list = ($invoice_from) unless @invoicing_list;
 817
 818   my $error = send_email(
 819     $self->generate_email(
 820       'from'       => $invoice_from,
 821       'to'         => [ grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list ],
 822       'template'   => $template,
 823     )
 824   );
 825   die "can't email invoice: $error\n" if $error;
 826   #die "$error\n" if $error;
 827
 828 }
 829
 830 =item lpr_data [ TEMPLATENAME ]
 831
 832 Returns the postscript or plaintext for this invoice as an arrayref.
 833
 834 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 835
 836 =cut
 837
 838 sub lpr_data {
 839   my( $self, $template) = @_;
 840   $conf->exists('invoice_latex')
 841     ? [ $self->print_ps('', $template) ]
 842     : [ $self->print_text('', $template) ];
 843 }
 844
 845 =item print [ TEMPLATENAME ]
 846
 847 Prints this invoice.
 848
 849 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 850
 851 =cut
 852
 853 sub print {
 854   my $self = shift;
 855   my $template = scalar(@_) ? shift : '';
 856
 857   my $lpr = $conf->config('lpr');
 858
 859   my $outerr = '';
 860   run3 $lpr, $self->lpr_data($template), \$outerr, \$outerr;
 861   if ( $? ) {
 862     $outerr = ": $outerr" if length($outerr);
 863     die "Error from $lpr (exit status ". ($?>>8). ")$outerr\n";
 864   }
 865
 866 }
 867
 868 =item fax [ TEMPLATENAME ]
 869
 870 Faxes this invoice.
 871
 872 TEMPLATENAME, if specified, is the name of a suffix for alternate invoices.
 873
 874 =cut
 875
 876 sub fax {
 877   my $self = shift;
 878   my $template = scalar(@_) ? shift : '';
 879
 880   die 'FAX invoice destination not (yet?) supported with plain text invoices.'
 881     unless $conf->exists('invoice_latex');
 882
 883   my $dialstring = $self->cust_main->getfield('fax');
 884   #Check $dialstring?
 885
 886   my $error = send_fax( 'docdata'    => $self->lpr_data($template),
 887                         'dialstring' => $dialstring,
 888                       );
 889   die $error if $error;
 890
 891 }
 892
 893 =item send_if_newest [ TEMPLATENAME [ , AGENTNUM [ , INVOICE_FROM ] ] ]
 894
 895 Like B<send>, but only sends the invoice if it is the newest open invoice for
 896 this customer.
 897
 898 =cut
 899
 900 sub send_if_newest {
 901   my $self = shift;
 902
 903   return ''
 904     if scalar(
 905                grep { $_->owed > 0 }
 906                     qsearch('cust_bill', {
 907                       'custnum' => $self->custnum,
 908                       #'_date'   => { op=>'>', value=>$self->_date },
 909                       'invnum'  => { op=>'>', value=>$self->invnum },
 910                     } )
 911              );
 912
 913   $self->send(@_);
 914 }
 915
 916 =item send_csv OPTION => VALUE, ...
 917
 918 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 919
 920 Options are:
 921
 922 protocol - currently only "ftp"
 923 server
 924 username
 925 password
 926 dir
 927
 928 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 929 and YYMMDDHHMMSS is a timestamp.
 930
 931 See L</print_csv> for a description of the output format.
 932
 933 =cut
 934
 935 sub send_csv {
 936   my($self, %opt) = @_;
 937
 938   #create file(s)
 939
 940   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
 941   mkdir $spooldir, 0700 unless -d $spooldir;
 942
 943   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
 944   my $file = "$spooldir/$tracctnum.csv";
 945
 946   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
 947
 948   open(CSV, ">$file") or die "can't open $file: $!";
 949   print CSV $header;
 950
 951   print CSV $detail;
 952
 953   close CSV;
 954
 955   my $net;
 956   if ( $opt{protocol} eq 'ftp' ) {
 957     eval "use Net::FTP;";
 958     die $@ if $@;
 959     $net = Net::FTP->new($opt{server}) or die @$;
 960   } else {
 961     die "unknown protocol: $opt{protocol}";
 962   }
 963
 964   $net->login( $opt{username}, $opt{password} )
 965     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
 966
 967   $net->binary or die "can't set binary mode";
 968
 969   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
 970
 971   $net->put($file) or die "can't put $file: $!";
 972
 973   $net->quit;
 974
 975   unlink $file;
 976
 977 }
 978
 979 =item spool_csv
 980
 981 Spools CSV invoice data.
 982
 983 Options are:
 984
 985 =over 4
 986
 987 =item format - 'default' or 'billco'
 988
 989 =item dest - if set (to POST, EMAIL or FAX), only sends spools invoices if the customer has the corresponding invoice destinations set (see L<FS::cust_main_invoice>).
 990
 991 =item agent_spools - if set to a true value, will spool to per-agent files rather than a single global file
 992
 993 =item balanceover - if set, only spools the invoice if the total amount owed on this invoice and all older invoices is greater than the specified amount.
 994
 995 =back
 996
 997 =cut
 998
 999 sub spool_csv {
1000   my($self, %opt) = @_;
1001
1002   my $cust_main = $self->cust_main;
1003
1004   if ( $opt{'dest'} ) {
1005     my %invoicing_list = map { /^(POST|FAX)$/ or 'EMAIL' =~ /^(.*)$/; $1 => 1 }
1006                              $cust_main->invoicing_list;
1007     return 'N/A' unless $invoicing_list{$opt{'dest'}}
1008                      || ! keys %invoicing_list;
1009   }
1010
1011   if ( $opt{'balanceover'} ) {
1012     return 'N/A'
1013       if $cust_main->total_owed_date($self->_date) < $opt{'balanceover'};
1014   }
1015
1016   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
1017   mkdir $spooldir, 0700 unless -d $spooldir;
1018
1019   my $tracctnum = $self->invnum. time2str('-%Y%m%d%H%M%S', time);
1020
1021   my $file =
1022     "$spooldir/".
1023     ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1024     ( lc($opt{'format'}) eq 'billco' ? '-header' : '' ) .
1025     '.csv';
1026
1027   my ( $header, $detail ) = $self->print_csv(%opt, 'tracctnum' => $tracctnum );
1028
1029   open(CSV, ">>$file") or die "can't open $file: $!";
1030   flock(CSV, LOCK_EX);
1031   seek(CSV, 0, 2);
1032
1033   print CSV $header;
1034
1035   if ( lc($opt{'format'}) eq 'billco' ) {
1036
1037     flock(CSV, LOCK_UN);
1038     close CSV;
1039
1040     $file =
1041       "$spooldir/".
1042       ( $opt{'agent_spools'} ? 'agentnum'.$cust_main->agentnum : 'spool' ).
1043       '-detail.csv';
1044
1045     open(CSV,">>$file") or die "can't open $file: $!";
1046     flock(CSV, LOCK_EX);
1047     seek(CSV, 0, 2);
1048   }
1049
1050   print CSV $detail;
1051
1052   flock(CSV, LOCK_UN);
1053   close CSV;
1054
1055   return '';
1056
1057 }
1058
1059 =item print_csv OPTION => VALUE, ...
1060
1061 Returns CSV data for this invoice.
1062
1063 Options are:
1064
1065 format - 'default' or 'billco'
1066
1067 Returns a list consisting of two scalars.  The first is a single line of CSV
1068 header information for this invoice.  The second is one or more lines of CSV
1069 detail information for this invoice.
1070
1071 If I<format> is not specified or "default", the fields of the CSV file are as
1072 follows:
1073
1074 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
1075
1076 =over 4
1077
1078 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
1079
1080 B<record_type> is C<cust_bill> for the initial header line only.  The
1081 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
1082 fields are filled in.
1083
1084 B<record_type> is C<cust_bill_pkg> for detail lines.  Only the first two fields
1085 (B<record_type> and B<invnum>) and the last five fields (B<pkg> through B<edate>)
1086 are filled in.
1087
1088 =item invnum - invoice number
1089
1090 =item custnum - customer number
1091
1092 =item _date - invoice date
1093
1094 =item charged - total invoice amount
1095
1096 =item first - customer first name
1097
1098 =item last - customer first name
1099
1100 =item company - company name
1101
1102 =item address1 - address line 1
1103
1104 =item address2 - address line 1
1105
1106 =item city
1107
1108 =item state
1109
1110 =item zip
1111
1112 =item country
1113
1114 =item pkg - line item description
1115
1116 =item setup - line item setup fee (one or both of B<setup> and B<recur> will be defined)
1117
1118 =item recur - line item recurring fee (one or both of B<setup> and B<recur> will be defined)
1119
1120 =item sdate - start date for recurring fee
1121
1122 =item edate - end date for recurring fee
1123
1124 =back
1125
1126 If I<format> is "billco", the fields of the header CSV file are as follows:
1127
1128   +-------------------------------------------------------------------+
1129   |                        FORMAT HEADER FILE                         |
1130   |-------------------------------------------------------------------|
1131   | Field | Description                   | Name       | Type | Width |
1132   | 1     | N/A-Leave Empty               | RC         | CHAR |     2 |
1133   | 2     | N/A-Leave Empty               | CUSTID     | CHAR |    15 |
1134   | 3     | Transaction Account No        | TRACCTNUM  | CHAR |    15 |
1135   | 4     | Transaction Invoice No        | TRINVOICE  | CHAR |    15 |
1136   | 5     | Transaction Zip Code          | TRZIP      | CHAR |     5 |
1137   | 6     | Transaction Company Bill To   | TRCOMPANY  | CHAR |    30 |
1138   | 7     | Transaction Contact Bill To   | TRNAME     | CHAR |    30 |
1139   | 8     | Additional Address Unit Info  | TRADDR1    | CHAR |    30 |
1140   | 9     | Bill To Street Address        | TRADDR2    | CHAR |    30 |
1141   | 10    | Ancillary Billing Information | TRADDR3    | CHAR |    30 |
1142   | 11    | Transaction City Bill To      | TRCITY     | CHAR |    20 |
1143   | 12    | Transaction State Bill To     | TRSTATE    | CHAR |     2 |
1144   | 13    | Bill Cycle Close Date         | CLOSEDATE  | CHAR |    10 |
1145   | 14    | Bill Due Date                 | DUEDATE    | CHAR |    10 |
1146   | 15    | Previous Balance              | BALFWD     | NUM* |     9 |
1147   | 16    | Pmt/CR Applied                | CREDAPPLY  | NUM* |     9 |
1148   | 17    | Total Current Charges         | CURRENTCHG | NUM* |     9 |
1149   | 18    | Total Amt Due                 | TOTALDUE   | NUM* |     9 |
1150   | 19    | Total Amt Due                 | AMTDUE     | NUM* |     9 |
1151   | 20    | 30 Day Aging                  | AMT30      | NUM* |     9 |
1152   | 21    | 60 Day Aging                  | AMT60      | NUM* |     9 |
1153   | 22    | 90 Day Aging                  | AMT90      | NUM* |     9 |
1154   | 23    | Y/N                           | AGESWITCH  | CHAR |     1 |
1155   | 24    | Remittance automation         | SCANLINE   | CHAR |   100 |
1156   | 25    | Total Taxes & Fees            | TAXTOT     | NUM* |     9 |
1157   | 26    | Customer Reference Number     | CUSTREF    | CHAR |    15 |
1158   | 27    | Federal Tax***                | FEDTAX     | NUM* |     9 |
1159   | 28    | State Tax***                  | STATETAX   | NUM* |     9 |
1160   | 29    | Other Taxes & Fees***         | OTHERTAX   | NUM* |     9 |
1161   +-------+-------------------------------+------------+------+-------+
1162
1163 If I<format> is "billco", the fields of the detail CSV file are as follows:
1164
1165                                   FORMAT FOR DETAIL FILE
1166         |                            |           |      |
1167   Field | Description                | Name      | Type | Width
1168   1     | N/A-Leave Empty            | RC        | CHAR |     2
1169   2     | N/A-Leave Empty            | CUSTID    | CHAR |    15
1170   3     | Account Number             | TRACCTNUM | CHAR |    15
1171   4     | Invoice Number             | TRINVOICE | CHAR |    15
1172   5     | Line Sequence (sort order) | LINESEQ   | NUM  |     6
1173   6     | Transaction Detail         | DETAILS   | CHAR |   100
1174   7     | Amount                     | AMT       | NUM* |     9
1175   8     | Line Format Control**      | LNCTRL    | CHAR |     2
1176   9     | Grouping Code              | GROUP     | CHAR |     2
1177   10    | User Defined               | ACCT CODE | CHAR |    15
1178
1179 =cut
1180
1181 sub print_csv {
1182   my($self, %opt) = @_;
1183
1184   eval "use Text::CSV_XS";
1185   die $@ if $@;
1186
1187   my $cust_main = $self->cust_main;
1188
1189   my $csv = Text::CSV_XS->new({'always_quote'=>1});
1190
1191   if ( lc($opt{'format'}) eq 'billco' ) {
1192
1193     my $taxtotal = 0;
1194     $taxtotal += $_->{'amount'} foreach $self->_items_tax;
1195
1196     my $duedate = '';
1197     if (    $conf->exists('invoice_default_terms')
1198          && $conf->config('invoice_default_terms')=~ /^\s*Net\s*(\d+)\s*$/ ) {
1199       $duedate = time2str("%m/%d/%Y", $self->_date + ($1*86400) );
1200     }
1201
1202     my( $previous_balance, @unused ) = $self->previous; #previous balance
1203
1204     my $pmt_cr_applied = 0;
1205     $pmt_cr_applied += $_->{'amount'}
1206       foreach ( $self->_items_payments, $self->_items_credits ) ;
1207
1208     my $totaldue = sprintf('%.2f', $self->owed + $previous_balance);
1209
1210     $csv->combine(
1211       '',                         #  1 | N/A-Leave Empty               CHAR   2
1212       '',                         #  2 | N/A-Leave Empty               CHAR  15
1213       $opt{'tracctnum'},          #  3 | Transaction Account No        CHAR  15
1214       $self->invnum,              #  4 | Transaction Invoice No        CHAR  15
1215       $cust_main->zip,            #  5 | Transaction Zip Code          CHAR   5
1216       $cust_main->company,        #  6 | Transaction Company Bill To   CHAR  30
1217       #$cust_main->payname,        #  7 | Transaction Contact Bill To   CHAR  30
1218       $cust_main->contact,        #  7 | Transaction Contact Bill To   CHAR  30
1219       $cust_main->address2,       #  8 | Additional Address Unit Info  CHAR  30
1220       $cust_main->address1,       #  9 | Bill To Street Address        CHAR  30
1221       '',                         # 10 | Ancillary Billing Information CHAR  30
1222       $cust_main->city,           # 11 | Transaction City Bill To      CHAR  20
1223       $cust_main->state,          # 12 | Transaction State Bill To     CHAR   2
1224
1225       # XXX ?
1226       time2str("%m/%d/%Y", $self->_date), # 13 | Bill Cycle Close Date CHAR  10
1227
1228       # XXX ?
1229       $duedate,                   # 14 | Bill Due Date                 CHAR  10
1230
1231       $previous_balance,          # 15 | Previous Balance              NUM*   9
1232       $pmt_cr_applied,            # 16 | Pmt/CR Applied                NUM*   9
1233       sprintf("%.2f", $self->charged), # 17 | Total Current Charges    NUM*   9
1234       $totaldue,                  # 18 | Total Amt Due                 NUM*   9
1235       $totaldue,                  # 19 | Total Amt Due                 NUM*   9
1236       '',                         # 20 | 30 Day Aging                  NUM*   9
1237       '',                         # 21 | 60 Day Aging                  NUM*   9
1238       '',                         # 22 | 90 Day Aging                  NUM*   9
1239       'N',                        # 23 | Y/N                           CHAR   1
1240       '',                         # 24 | Remittance automation         CHAR 100
1241       $taxtotal,                  # 25 | Total Taxes & Fees            NUM*   9
1242       $self->custnum,             # 26 | Customer Reference Number     CHAR  15
1243       '0',                        # 27 | Federal Tax***                NUM*   9
1244       sprintf("%.2f", $taxtotal), # 28 | State Tax***                  NUM*   9
1245       '0',                        # 29 | Other Taxes & Fees***         NUM*   9
1246     );
1247
1248   } else {
1249
1250     $csv->combine(
1251       'cust_bill',
1252       $self->invnum,
1253       $self->custnum,
1254       time2str("%x", $self->_date),
1255       sprintf("%.2f", $self->charged),
1256       ( map { $cust_main->getfield($_) }
1257           qw( first last company address1 address2 city state zip country ) ),
1258       map { '' } (1..5),
1259     ) or die "can't create csv";
1260   }
1261
1262   my $header = $csv->string. "\n";
1263
1264   my $detail = '';
1265   if ( lc($opt{'format'}) eq 'billco' ) {
1266
1267     my $lineseq = 0;
1268     foreach my $item ( $self->_items_pkg ) {
1269
1270       $csv->combine(
1271         '',                     #  1 | N/A-Leave Empty            CHAR   2
1272         '',                     #  2 | N/A-Leave Empty            CHAR  15
1273         $opt{'tracctnum'},      #  3 | Account Number             CHAR  15
1274         $self->invnum,          #  4 | Invoice Number             CHAR  15
1275         $lineseq++,             #  5 | Line Sequence (sort order) NUM    6
1276         $item->{'description'}, #  6 | Transaction Detail         CHAR 100
1277         $item->{'amount'},      #  7 | Amount                     NUM*   9
1278         '',                     #  8 | Line Format Control**      CHAR   2
1279         '',                     #  9 | Grouping Code              CHAR   2
1280         '',                     # 10 | User Defined               CHAR  15
1281       );
1282
1283       $detail .= $csv->string. "\n";
1284
1285     }
1286
1287   } else {
1288
1289     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1290
1291       my($pkg, $setup, $recur, $sdate, $edate);
1292       if ( $cust_bill_pkg->pkgnum ) {
1293
1294         ($pkg, $setup, $recur, $sdate, $edate) = (
1295           $cust_bill_pkg->cust_pkg->part_pkg->pkg,
1296           ( $cust_bill_pkg->setup != 0
1297             ? sprintf("%.2f", $cust_bill_pkg->setup )
1298             : '' ),
1299           ( $cust_bill_pkg->recur != 0
1300             ? sprintf("%.2f", $cust_bill_pkg->recur )
1301             : '' ),
1302           ( $cust_bill_pkg->sdate
1303             ? time2str("%x", $cust_bill_pkg->sdate)
1304             : '' ),
1305           ($cust_bill_pkg->edate
1306             ?time2str("%x", $cust_bill_pkg->edate)
1307             : '' ),
1308         );
1309
1310       } else { #pkgnum tax
1311         next unless $cust_bill_pkg->setup != 0;
1312         my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
1313                          ? ( $cust_bill_pkg->itemdesc || 'Tax' )
1314                          : 'Tax';
1315         ($pkg, $setup, $recur, $sdate, $edate) =
1316           ( $itemdesc, sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
1317       }
1318
1319       $csv->combine(
1320         'cust_bill_pkg',
1321         $self->invnum,
1322         ( map { '' } (1..11) ),
1323         ($pkg, $setup, $recur, $sdate, $edate)
1324       ) or die "can't create csv";
1325
1326       $detail .= $csv->string. "\n";
1327
1328     }
1329
1330   }
1331
1332   ( $header, $detail );
1333
1334 }
1335
1336 =item comp
1337
1338 Pays this invoice with a compliemntary payment.  If there is an error,
1339 returns the error, otherwise returns false.
1340
1341 =cut
1342
1343 sub comp {
1344   my $self = shift;
1345   my $cust_pay = new FS::cust_pay ( {
1346     'invnum'   => $self->invnum,
1347     'paid'     => $self->owed,
1348     '_date'    => '',
1349     'payby'    => 'COMP',
1350     'payinfo'  => $self->cust_main->payinfo,
1351     'paybatch' => '',
1352   } );
1353   $cust_pay->insert;
1354 }
1355
1356 =item realtime_card
1357
1358 Attempts to pay this invoice with a credit card payment via a
1359 Business::OnlinePayment realtime gateway.  See
1360 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1361 for supported processors.
1362
1363 =cut
1364
1365 sub realtime_card {
1366   my $self = shift;
1367   $self->realtime_bop( 'CC', @_ );
1368 }
1369
1370 =item realtime_ach
1371
1372 Attempts to pay this invoice with an electronic check (ACH) payment via a
1373 Business::OnlinePayment realtime gateway.  See
1374 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1375 for supported processors.
1376
1377 =cut
1378
1379 sub realtime_ach {
1380   my $self = shift;
1381   $self->realtime_bop( 'ECHECK', @_ );
1382 }
1383
1384 =item realtime_lec
1385
1386 Attempts to pay this invoice with phone bill (LEC) payment via a
1387 Business::OnlinePayment realtime gateway.  See
1388 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
1389 for supported processors.
1390
1391 =cut
1392
1393 sub realtime_lec {
1394   my $self = shift;
1395   $self->realtime_bop( 'LEC', @_ );
1396 }
1397
1398 sub realtime_bop {
1399   my( $self, $method ) = @_;
1400
1401   my $cust_main = $self->cust_main;
1402   my $balance = $cust_main->balance;
1403   my $amount = ( $balance < $self->owed ) ? $balance : $self->owed;
1404   $amount = sprintf("%.2f", $amount);
1405   return "not run (balance $balance)" unless $amount > 0;
1406
1407   my $description = 'Internet Services';
1408   if ( $conf->exists('business-onlinepayment-description') ) {
1409     my $dtempl = $conf->config('business-onlinepayment-description');
1410
1411     my $agent_obj = $cust_main->agent
1412       or die "can't retreive agent for $cust_main (agentnum ".
1413              $cust_main->agentnum. ")";
1414     my $agent = $agent_obj->agent;
1415     my $pkgs = join(', ',
1416       map { $_->cust_pkg->part_pkg->pkg }
1417         grep { $_->pkgnum } $self->cust_bill_pkg
1418     );
1419     $description = eval qq("$dtempl");
1420   }
1421
1422   $cust_main->realtime_bop($method, $amount,
1423     'description' => $description,
1424     'invnum'      => $self->invnum,
1425   );
1426
1427 }
1428
1429 =item batch_card OPTION => VALUE...
1430
1431 Adds a payment for this invoice to the pending credit card batch (see
1432 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
1433 runs the payment using a realtime gateway.
1434
1435 =cut
1436
1437 sub batch_card {
1438   my ($self, %options) = @_;
1439   my $cust_main = $self->cust_main;
1440
1441   $options{invnum} = $self->invnum;
1442
1443   $cust_main->batch_card(%options);
1444 }
1445
1446 sub _agent_template {
1447   my $self = shift;
1448   $self->_agent_plandata('agent_templatename');
1449 }
1450
1451 sub _agent_invoice_from {
1452   my $self = shift;
1453   $self->_agent_plandata('agent_invoice_from');
1454 }
1455
1456 sub _agent_plandata {
1457   my( $self, $option ) = @_;
1458
1459   my $part_bill_event = qsearchs( 'part_bill_event',
1460     {
1461       'payby'     => $self->cust_main->payby,
1462       'plan'      => 'send_agent',
1463       'plandata'  => { 'op'    => '~',
1464                        'value' => "(^|\n)agentnum ".
1465                                    '([0-9]*, )*'.
1466                                   $self->cust_main->agentnum.
1467                                    '(, [0-9]*)*'.
1468                                   "(\n|\$)",
1469                      },
1470     },
1471     '',
1472     'ORDER BY seconds LIMIT 1'
1473   );
1474
1475   return '' unless $part_bill_event;
1476
1477   if ( $part_bill_event->plandata =~ /^$option (.*)$/m ) {
1478     return $1;
1479   } else {
1480     warn "can't parse part_bill_event eventpart#". $part_bill_event->eventpart.
1481          " plandata for $option";
1482     return '';
1483   }
1484
1485 }
1486
1487 =item print_text [ TIME [ , TEMPLATE ] ]
1488
1489 Returns an text invoice, as a list of lines.
1490
1491 TIME an optional value used to control the printing of overdue messages.  The
1492 default is now.  It isn't the date of the invoice; that's the `_date' field.
1493 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1494 L<Time::Local> and L<Date::Parse> for conversion functions.
1495
1496 =cut
1497
1498 #still some false laziness w/_items stuff (and send_csv)
1499 sub print_text {
1500
1501   my( $self, $today, $template ) = @_;
1502   $today ||= time;
1503
1504 #  my $invnum = $self->invnum;
1505   my $cust_main = $self->cust_main;
1506   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
1507     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
1508
1509   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1510 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
1511   #my $balance_due = $self->owed + $pr_total - $cr_total;
1512   my $balance_due = $self->owed + $pr_total;
1513
1514   #my @collect = ();
1515   #my($description,$amount);
1516   @buf = ();
1517
1518   #previous balance
1519   foreach ( @pr_cust_bill ) {
1520     push @buf, [
1521       "Previous Balance, Invoice #". $_->invnum.
1522                  " (". time2str("%x",$_->_date). ")",
1523       $money_char. sprintf("%10.2f",$_->owed)
1524     ];
1525   }
1526   if (@pr_cust_bill) {
1527     push @buf,['','-----------'];
1528     push @buf,[ 'Total Previous Balance',
1529                 $money_char. sprintf("%10.2f",$pr_total ) ];
1530     push @buf,['',''];
1531   }
1532
1533   #new charges
1534   foreach my $cust_bill_pkg (
1535     ( grep {   $_->pkgnum } $self->cust_bill_pkg ),  #packages first
1536     ( grep { ! $_->pkgnum } $self->cust_bill_pkg ),  #then taxes
1537   ) {
1538
1539     my $desc = $cust_bill_pkg->desc;
1540
1541     if ( $cust_bill_pkg->pkgnum > 0 ) {
1542
1543       if ( $cust_bill_pkg->setup != 0 ) {
1544         my $description = $desc;
1545         $description .= ' Setup' if $cust_bill_pkg->recur != 0;
1546         push @buf, [ $description,
1547                      $money_char. sprintf("%10.2f", $cust_bill_pkg->setup) ];
1548         push @buf,
1549           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] }
1550               $cust_bill_pkg->cust_pkg->h_labels($self->_date);
1551       }
1552
1553       if ( $cust_bill_pkg->recur != 0 ) {
1554         push @buf, [
1555           "$desc (" . time2str("%x", $cust_bill_pkg->sdate) . " - " .
1556                       time2str("%x", $cust_bill_pkg->edate) . ")",
1557           $money_char. sprintf("%10.2f", $cust_bill_pkg->recur)
1558         ];
1559         push @buf,
1560           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] }
1561               $cust_bill_pkg->cust_pkg->h_labels( $cust_bill_pkg->edate,
1562                                                   $cust_bill_pkg->sdate );
1563       }
1564
1565       push @buf, map { [ "  $_", '' ] } $cust_bill_pkg->details;
1566
1567     } else { #pkgnum tax or one-shot line item
1568
1569       if ( $cust_bill_pkg->setup != 0 ) {
1570         push @buf, [ $desc,
1571                      $money_char. sprintf("%10.2f", $cust_bill_pkg->setup) ];
1572       }
1573       if ( $cust_bill_pkg->recur != 0 ) {
1574         push @buf, [ "$desc (". time2str("%x", $cust_bill_pkg->sdate). " - "
1575                               . time2str("%x", $cust_bill_pkg->edate). ")",
1576                      $money_char. sprintf("%10.2f", $cust_bill_pkg->recur)
1577                    ];
1578       }
1579
1580     }
1581
1582   }
1583
1584   push @buf,['','-----------'];
1585   push @buf,['Total New Charges',
1586              $money_char. sprintf("%10.2f",$self->charged) ];
1587   push @buf,['',''];
1588
1589   push @buf,['','-----------'];
1590   push @buf,['Total Charges',
1591              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
1592   push @buf,['',''];
1593
1594   #credits
1595   foreach ( $self->cust_credited ) {
1596
1597     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
1598
1599     my $reason = substr($_->cust_credit->reason,0,32);
1600     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
1601     $reason = " ($reason) " if $reason;
1602     push @buf,[
1603       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
1604         $reason,
1605       $money_char. sprintf("%10.2f",$_->amount)
1606     ];
1607   }
1608   #foreach ( @cr_cust_credit ) {
1609   #  push @buf,[
1610   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
1611   #    $money_char. sprintf("%10.2f",$_->credited)
1612   #  ];
1613   #}
1614
1615   #get & print payments
1616   foreach ( $self->cust_bill_pay ) {
1617
1618     #something more elaborate if $_->amount ne ->cust_pay->paid ?
1619
1620     push @buf,[
1621       "Payment received ". time2str("%x",$_->cust_pay->_date ),
1622       $money_char. sprintf("%10.2f",$_->amount )
1623     ];
1624   }
1625
1626   #balance due
1627   my $balance_due_msg = $self->balance_due_msg;
1628
1629   push @buf,['','-----------'];
1630   push @buf,[$balance_due_msg, $money_char.
1631     sprintf("%10.2f", $balance_due ) ];
1632
1633   #create the template
1634   $template ||= $self->_agent_template;
1635   my $templatefile = 'invoice_template';
1636   $templatefile .= "_$template" if length($template);
1637   my @invoice_template = $conf->config($templatefile)
1638     or die "cannot load config file $templatefile";
1639   $invoice_lines = 0;
1640   my $wasfunc = 0;
1641   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1642     /invoice_lines\((\d*)\)/;
1643     $invoice_lines += $1 || scalar(@buf);
1644     $wasfunc=1;
1645   }
1646   die "no invoice_lines() functions in template?" unless $wasfunc;
1647   my $invoice_template = new Text::Template (
1648     TYPE   => 'ARRAY',
1649     SOURCE => [ map "$_\n", @invoice_template ],
1650   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
1651   $invoice_template->compile()
1652     or die "can't compile template: $Text::Template::ERROR";
1653
1654   #setup template variables
1655   package FS::cust_bill::_template; #!
1656   use vars qw( $custnum $invnum $date $agent @address $overdue
1657                $page $total_pages @buf );
1658
1659   $custnum = $self->custnum;
1660   $invnum = $self->invnum;
1661   $date = $self->_date;
1662   $agent = $self->cust_main->agent->agent;
1663   $page = 1;
1664
1665   if ( $FS::cust_bill::invoice_lines ) {
1666     $total_pages =
1667       int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
1668     $total_pages++
1669       if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
1670   } else {
1671     $total_pages = 1;
1672   }
1673
1674   #format address (variable for the template)
1675   my $l = 0;
1676   @address = ( '', '', '', '', '', '' );
1677   package FS::cust_bill; #!
1678   $FS::cust_bill::_template::address[$l++] =
1679     $cust_main->payname.
1680       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
1681         ? " (P.O. #". $cust_main->payinfo. ")"
1682         : ''
1683       )
1684   ;
1685   $FS::cust_bill::_template::address[$l++] = $cust_main->company
1686     if $cust_main->company;
1687   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
1688   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
1689     if $cust_main->address2;
1690   $FS::cust_bill::_template::address[$l++] =
1691     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
1692
1693   my $countrydefault = $conf->config('countrydefault') || 'US';
1694   $FS::cust_bill::_template::address[$l++] = code2country($cust_main->country)
1695     unless $cust_main->country eq $countrydefault;
1696
1697         #  #overdue? (variable for the template)
1698         #  $FS::cust_bill::_template::overdue = (
1699         #    $balance_due > 0
1700         #    && $today > $self->_date
1701         ##    && $self->printed > 1
1702         #    && $self->printed > 0
1703         #  );
1704
1705   #and subroutine for the template
1706   sub FS::cust_bill::_template::invoice_lines {
1707     my $lines = shift || scalar(@buf);
1708     map {
1709       scalar(@buf) ? shift @buf : [ '', '' ];
1710     }
1711     ( 1 .. $lines );
1712   }
1713
1714   #and fill it in
1715   $FS::cust_bill::_template::page = 1;
1716   my $lines;
1717   my @collect;
1718   while (@buf) {
1719     push @collect, split("\n",
1720       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
1721     );
1722     $FS::cust_bill::_template::page++;
1723   }
1724
1725   map "$_\n", @collect;
1726
1727 }
1728
1729 =item print_latex [ TIME [ , TEMPLATE ] ]
1730
1731 Internal method - returns a filename of a filled-in LaTeX template for this
1732 invoice (Note: add ".tex" to get the actual filename).
1733
1734 See print_ps and print_pdf for methods that return PostScript and PDF output.
1735
1736 TIME an optional value used to control the printing of overdue messages.  The
1737 default is now.  It isn't the date of the invoice; that's the `_date' field.
1738 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1739 L<Time::Local> and L<Date::Parse> for conversion functions.
1740
1741 =cut
1742
1743 #still some false laziness w/print_text and print_html (and send_csv) (mostly print_text should use _items stuff though)
1744 sub print_latex {
1745
1746   my( $self, $today, $template ) = @_;
1747   $today ||= time;
1748   warn "FS::cust_bill::print_latex called on $self with suffix $template\n"
1749     if $DEBUG;
1750
1751   my $cust_main = $self->cust_main;
1752   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
1753     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
1754
1755   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1756 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
1757   #my $balance_due = $self->owed + $pr_total - $cr_total;
1758   my $balance_due = $self->owed + $pr_total;
1759
1760   #create the template
1761   $template ||= $self->_agent_template;
1762   my $templatefile = 'invoice_latex';
1763   my $suffix = length($template) ? "_$template" : '';
1764   $templatefile .= $suffix;
1765   my @invoice_template = map "$_\n", $conf->config($templatefile)
1766     or die "cannot load config file $templatefile";
1767
1768   my($format, $text_template);
1769   if ( grep { /^%%Detail/ } @invoice_template ) {
1770     #change this to a die when the old code is removed
1771     warn "old-style invoice template $templatefile; ".
1772          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
1773     $format = 'old';
1774   } else {
1775     $format = 'Text::Template';
1776     $text_template = new Text::Template(
1777       TYPE => 'ARRAY',
1778       SOURCE => \@invoice_template,
1779       DELIMITERS => [ '[@--', '--@]' ],
1780     );
1781
1782     $text_template->compile()
1783       or die 'While compiling ' . $templatefile . ': ' . $Text::Template::ERROR;
1784   }
1785
1786   my $returnaddress;
1787   if ( length($conf->config_orbase('invoice_latexreturnaddress', $template)) ) {
1788     $returnaddress = join("\n",
1789       $conf->config_orbase('invoice_latexreturnaddress', $template)
1790     );
1791   } else {
1792     $returnaddress = '~';
1793   }
1794
1795   my %invoice_data = (
1796     'custnum'      => $self->custnum,
1797     'invnum'       => $self->invnum,
1798     'date'         => time2str('%b %o, %Y', $self->_date),
1799     'today'        => time2str('%b %o, %Y', $today),
1800     'agent'        => _latex_escape($cust_main->agent->agent),
1801     'payname'      => _latex_escape($cust_main->payname),
1802     'company'      => _latex_escape($cust_main->company),
1803     'address1'     => _latex_escape($cust_main->address1),
1804     'address2'     => _latex_escape($cust_main->address2),
1805     'city'         => _latex_escape($cust_main->city),
1806     'state'        => _latex_escape($cust_main->state),
1807     'zip'          => _latex_escape($cust_main->zip),
1808     'footer'       => join("\n", $conf->config_orbase('invoice_latexfooter', $template) ),
1809     'smallfooter'  => join("\n", $conf->config_orbase('invoice_latexsmallfooter', $template) ),
1810     'returnaddress' => $returnaddress,
1811     'quantity'     => 1,
1812     'terms'        => $conf->config('invoice_default_terms') || 'Payable upon receipt',
1813     #'notes'        => join("\n", $conf->config('invoice_latexnotes') ),
1814     'conf_dir'     => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
1815   );
1816
1817   my $countrydefault = $conf->config('countrydefault') || 'US';
1818   if ( $cust_main->country eq $countrydefault ) {
1819     $invoice_data{'country'} = '';
1820   } else {
1821     $invoice_data{'country'} = _latex_escape(code2country($cust_main->country));
1822   }
1823
1824   $invoice_data{'notes'} =
1825     join("\n",
1826 #  #do variable substitutions in notes
1827 #      map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1828         $conf->config_orbase('invoice_latexnotes', $template)
1829     );
1830   warn "invoice notes: ". $invoice_data{'notes'}. "\n"
1831     if $DEBUG;
1832
1833   $invoice_data{'footer'} =~ s/\n+$//;
1834   $invoice_data{'smallfooter'} =~ s/\n+$//;
1835   $invoice_data{'notes'} =~ s/\n+$//;
1836
1837   $invoice_data{'po_line'} =
1838     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
1839       ? _latex_escape("Purchase Order #". $cust_main->payinfo)
1840       : '~';
1841
1842   my @filled_in = ();
1843   if ( $format eq 'old' ) {
1844
1845     my @line_item = ();
1846     my @total_item = ();
1847     while ( @invoice_template ) {
1848       my $line = shift @invoice_template;
1849
1850       if ( $line =~ /^%%Detail\s*$/ ) {
1851
1852         while ( ( my $line_item_line = shift @invoice_template )
1853                 !~ /^%%EndDetail\s*$/                            ) {
1854           push @line_item, $line_item_line;
1855         }
1856         foreach my $line_item ( $self->_items ) {
1857         #foreach my $line_item ( $self->_items_pkg ) {
1858           $invoice_data{'ref'} = $line_item->{'pkgnum'};
1859           $invoice_data{'description'} =
1860             _latex_escape($line_item->{'description'});
1861           if ( exists $line_item->{'ext_description'} ) {
1862             $invoice_data{'description'} .=
1863               "\\tabularnewline\n~~".
1864               join( "\\tabularnewline\n~~",
1865                     map _latex_escape($_), @{$line_item->{'ext_description'}}
1866                   );
1867           }
1868           $invoice_data{'amount'} = $line_item->{'amount'};
1869           $invoice_data{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
1870           push @filled_in,
1871             map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b } @line_item;
1872         }
1873
1874       } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1875
1876         while ( ( my $total_item_line = shift @invoice_template )
1877                 !~ /^%%EndTotalDetails\s*$/                      ) {
1878           push @total_item, $total_item_line;
1879         }
1880
1881         my @total_fill = ();
1882
1883         my $taxtotal = 0;
1884         foreach my $tax ( $self->_items_tax ) {
1885           $invoice_data{'total_item'} = _latex_escape($tax->{'description'});
1886           $taxtotal += $tax->{'amount'};
1887           $invoice_data{'total_amount'} = '\dollar '. $tax->{'amount'};
1888           push @total_fill,
1889             map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1890                 @total_item;
1891         }
1892
1893         if ( $taxtotal ) {
1894           $invoice_data{'total_item'} = 'Sub-total';
1895           $invoice_data{'total_amount'} =
1896             '\dollar '. sprintf('%.2f', $self->charged - $taxtotal );
1897           unshift @total_fill,
1898             map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1899                 @total_item;
1900         }
1901
1902         $invoice_data{'total_item'} = '\textbf{Total}';
1903         $invoice_data{'total_amount'} =
1904           '\textbf{\dollar '. sprintf('%.2f', $self->charged + $pr_total ). '}';
1905         push @total_fill,
1906           map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1907               @total_item;
1908
1909         #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
1910
1911         # credits
1912         foreach my $credit ( $self->_items_credits ) {
1913           $invoice_data{'total_item'} = _latex_escape($credit->{'description'});
1914           #$credittotal
1915           $invoice_data{'total_amount'} = '-\dollar '. $credit->{'amount'};
1916           push @total_fill,
1917             map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1918                 @total_item;
1919         }
1920
1921         # payments
1922         foreach my $payment ( $self->_items_payments ) {
1923           $invoice_data{'total_item'} = _latex_escape($payment->{'description'});
1924           #$paymenttotal
1925           $invoice_data{'total_amount'} = '-\dollar '. $payment->{'amount'};
1926           push @total_fill,
1927             map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1928                 @total_item;
1929         }
1930
1931         $invoice_data{'total_item'} = '\textbf{'. $self->balance_due_msg. '}';
1932         $invoice_data{'total_amount'} =
1933           '\textbf{\dollar '. sprintf('%.2f', $self->owed + $pr_total ). '}';
1934         push @total_fill,
1935           map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
1936               @total_item;
1937
1938         push @filled_in, @total_fill;
1939
1940       } else {
1941         #$line =~ s/\$(\w+)/$invoice_data{$1}/eg;
1942         $line =~ s/\$(\w+)/exists($invoice_data{$1}) ? $invoice_data{$1} : nounder($1)/eg;
1943         push @filled_in, $line;
1944       }
1945
1946     }
1947
1948     sub nounder {
1949       my $var = $1;
1950       $var =~ s/_/\-/g;
1951       $var;
1952     }
1953
1954   } elsif ( $format eq 'Text::Template' ) {
1955
1956     my @detail_items = ();
1957     my @total_items = ();
1958
1959     $invoice_data{'detail_items'} = \@detail_items;
1960     $invoice_data{'total_items'} = \@total_items;
1961
1962     foreach my $line_item ( $self->_items ) {
1963       my $detail = {
1964         ext_description => [],
1965       };
1966       $detail->{'ref'} = $line_item->{'pkgnum'};
1967       $detail->{'quantity'} = 1;
1968       $detail->{'description'} = _latex_escape($line_item->{'description'});
1969       if ( exists $line_item->{'ext_description'} ) {
1970         @{$detail->{'ext_description'}} = map {
1971           _latex_escape($_);
1972         } @{$line_item->{'ext_description'}};
1973       }
1974       $detail->{'amount'} = $line_item->{'amount'};
1975       $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
1976
1977       push @detail_items, $detail;
1978     }
1979
1980
1981     my $taxtotal = 0;
1982     foreach my $tax ( $self->_items_tax ) {
1983       my $total = {};
1984       $total->{'total_item'} = _latex_escape($tax->{'description'});
1985       $taxtotal += $tax->{'amount'};
1986       $total->{'total_amount'} = '\dollar '. $tax->{'amount'};
1987       push @total_items, $total;
1988     }
1989
1990     if ( $taxtotal ) {
1991       my $total = {};
1992       $total->{'total_item'} = 'Sub-total';
1993       $total->{'total_amount'} =
1994         '\dollar '. sprintf('%.2f', $self->charged - $taxtotal );
1995       unshift @total_items, $total;
1996     }
1997
1998     {
1999       my $total = {};
2000       $total->{'total_item'} = '\textbf{Total}';
2001       $total->{'total_amount'} =
2002         '\textbf{\dollar '. sprintf('%.2f', $self->charged + $pr_total ). '}';
2003       push @total_items, $total;
2004     }
2005
2006     #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
2007
2008     # credits
2009     foreach my $credit ( $self->_items_credits ) {
2010       my $total;
2011       $total->{'total_item'} = _latex_escape($credit->{'description'});
2012       #$credittotal
2013       $total->{'total_amount'} = '-\dollar '. $credit->{'amount'};
2014       push @total_items, $total;
2015     }
2016
2017     # payments
2018     foreach my $payment ( $self->_items_payments ) {
2019       my $total = {};
2020       $total->{'total_item'} = _latex_escape($payment->{'description'});
2021       #$paymenttotal
2022       $total->{'total_amount'} = '-\dollar '. $payment->{'amount'};
2023       push @total_items, $total;
2024     }
2025
2026     {
2027       my $total;
2028       $total->{'total_item'} = '\textbf{'. $self->balance_due_msg. '}';
2029       $total->{'total_amount'} =
2030         '\textbf{\dollar '. sprintf('%.2f', $self->owed + $pr_total ). '}';
2031       push @total_items, $total;
2032     }
2033
2034   } else {
2035     die "guru meditation #54";
2036   }
2037
2038   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
2039   my $fh = new File::Temp( TEMPLATE => 'invoice.'. $self->invnum. '.XXXXXXXX',
2040                            DIR      => $dir,
2041                            SUFFIX   => '.tex',
2042                            UNLINK   => 0,
2043                          ) or die "can't open temp file: $!\n";
2044   if ( $format eq 'old' ) {
2045     print $fh join('', @filled_in );
2046   } elsif ( $format eq 'Text::Template' ) {
2047     $text_template->fill_in(OUTPUT => $fh, HASH => \%invoice_data);
2048   } else {
2049     die "guru meditation #32";
2050   }
2051   close $fh;
2052
2053   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
2054   return $1;
2055
2056 }
2057
2058 =item print_ps [ TIME [ , TEMPLATE ] ]
2059
2060 Returns an postscript invoice, as a scalar.
2061
2062 TIME an optional value used to control the printing of overdue messages.  The
2063 default is now.  It isn't the date of the invoice; that's the `_date' field.
2064 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2065 L<Time::Local> and L<Date::Parse> for conversion functions.
2066
2067 =cut
2068
2069 sub print_ps {
2070   my $self = shift;
2071
2072   my $file = $self->print_latex(@_);
2073
2074   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
2075   chdir($dir);
2076
2077   my $sfile = shell_quote $file;
2078
2079   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2080     or die "pslatex $file.tex failed; see $file.log for details?\n";
2081   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2082     or die "pslatex $file.tex failed; see $file.log for details?\n";
2083
2084   system('dvips', '-q', '-t', 'letter', "$file.dvi", '-o', "$file.ps" ) == 0
2085     or die "dvips failed";
2086
2087   open(POSTSCRIPT, "<$file.ps")
2088     or die "can't open $file.ps: $! (error in LaTeX template?)\n";
2089
2090   unlink("$file.dvi", "$file.log", "$file.aux", "$file.ps", "$file.tex");
2091
2092   my $ps = '';
2093   while (<POSTSCRIPT>) {
2094     $ps .= $_;
2095   }
2096
2097   close POSTSCRIPT;
2098
2099   return $ps;
2100
2101 }
2102
2103 =item print_pdf [ TIME [ , TEMPLATE ] ]
2104
2105 Returns an PDF invoice, as a scalar.
2106
2107 TIME an optional value used to control the printing of overdue messages.  The
2108 default is now.  It isn't the date of the invoice; that's the `_date' field.
2109 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2110 L<Time::Local> and L<Date::Parse> for conversion functions.
2111
2112 =cut
2113
2114 sub print_pdf {
2115   my $self = shift;
2116
2117   my $file = $self->print_latex(@_);
2118
2119   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
2120   chdir($dir);
2121
2122   #system('pdflatex', "$file.tex");
2123   #system('pdflatex', "$file.tex");
2124   #! LaTeX Error: Unknown graphics extension: .eps.
2125
2126   my $sfile = shell_quote $file;
2127
2128   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2129     or die "pslatex $file.tex failed; see $file.log for details?\n";
2130   system("pslatex $sfile.tex >/dev/null 2>&1") == 0
2131     or die "pslatex $file.tex failed; see $file.log for details?\n";
2132
2133   #system('dvipdf', "$file.dvi", "$file.pdf" );
2134   system(
2135     "dvips -q -t letter -f $sfile.dvi ".
2136     "| gs -q -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=$sfile.pdf ".
2137     "     -c save pop -"
2138   ) == 0
2139     or die "dvips | gs failed: $!";
2140
2141   open(PDF, "<$file.pdf")
2142     or die "can't open $file.pdf: $! (error in LaTeX template?)\n";
2143
2144   unlink("$file.dvi", "$file.log", "$file.aux", "$file.pdf", "$file.tex");
2145
2146   my $pdf = '';
2147   while (<PDF>) {
2148     $pdf .= $_;
2149   }
2150
2151   close PDF;
2152
2153   return $pdf;
2154
2155 }
2156
2157 =item print_html [ TIME [ , TEMPLATE [ , CID ] ] ]
2158
2159 Returns an HTML invoice, as a scalar.
2160
2161 TIME an optional value used to control the printing of overdue messages.  The
2162 default is now.  It isn't the date of the invoice; that's the `_date' field.
2163 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
2164 L<Time::Local> and L<Date::Parse> for conversion functions.
2165
2166 CID is a MIME Content-ID used to create a "cid:" URL for the logo image, used
2167 when emailing the invoice as part of a multipart/related MIME email.
2168
2169 =cut
2170
2171 #some falze laziness w/print_text and print_latex (and send_csv)
2172 sub print_html {
2173   my( $self, $today, $template, $cid ) = @_;
2174   $today ||= time;
2175
2176   my $cust_main = $self->cust_main;
2177   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
2178     unless $cust_main->payname && $cust_main->payby !~ /^(CHEK|DCHK)$/;
2179
2180   $template ||= $self->_agent_template;
2181   my $templatefile = 'invoice_html';
2182   my $suffix = length($template) ? "_$template" : '';
2183   $templatefile .= $suffix;
2184   my @html_template = map "$_\n", $conf->config($templatefile)
2185     or die "cannot load config file $templatefile";
2186
2187   my $html_template = new Text::Template(
2188     TYPE   => 'ARRAY',
2189     SOURCE => \@html_template,
2190     DELIMITERS => [ '<%=', '%>' ],
2191   );
2192
2193   $html_template->compile()
2194     or die 'While compiling ' . $templatefile . ': ' . $Text::Template::ERROR;
2195
2196   my %invoice_data = (
2197     'custnum'      => $self->custnum,
2198     'invnum'       => $self->invnum,
2199     'date'         => time2str('%b&nbsp;%o,&nbsp;%Y', $self->_date),
2200     'today'        => time2str('%b %o, %Y', $today),
2201     'agent'        => encode_entities($cust_main->agent->agent),
2202     'payname'      => encode_entities($cust_main->payname),
2203     'company'      => encode_entities($cust_main->company),
2204     'address1'     => encode_entities($cust_main->address1),
2205     'address2'     => encode_entities($cust_main->address2),
2206     'city'         => encode_entities($cust_main->city),
2207     'state'        => encode_entities($cust_main->state),
2208     'zip'          => encode_entities($cust_main->zip),
2209     'terms'        => $conf->config('invoice_default_terms')
2210                       || 'Payable upon receipt',
2211     'cid'          => $cid,
2212     'template'     => $template,
2213 #    'conf_dir'     => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
2214   );
2215
2216   if (
2217          defined( $conf->config_orbase('invoice_htmlreturnaddress', $template) )
2218       && length(  $conf->config_orbase('invoice_htmlreturnaddress', $template) )
2219   ) {
2220     $invoice_data{'returnaddress'} =
2221       join("\n", $conf->config('invoice_htmlreturnaddress', $template) );
2222   } else {
2223     $invoice_data{'returnaddress'} =
2224       join("\n", map {
2225                        s/~/&nbsp;/g;
2226                        s/\\\\\*?\s*$/<BR>/;
2227                        s/\\hyphenation\{[\w\s\-]+\}//;
2228                        $_;
2229                      }
2230                      $conf->config_orbase( 'invoice_latexreturnaddress',
2231                                            $template
2232                                          )
2233           );
2234   }
2235
2236   my $countrydefault = $conf->config('countrydefault') || 'US';
2237   if ( $cust_main->country eq $countrydefault ) {
2238     $invoice_data{'country'} = '';
2239   } else {
2240     $invoice_data{'country'} =
2241       encode_entities(code2country($cust_main->country));
2242   }
2243
2244   if (
2245          defined( $conf->config_orbase('invoice_htmlnotes', $template) )
2246       && length(  $conf->config_orbase('invoice_htmlnotes', $template) )
2247   ) {
2248     $invoice_data{'notes'} =
2249       join("\n", $conf->config_orbase('invoice_htmlnotes', $template) );
2250   } else {
2251     $invoice_data{'notes'} =
2252       join("\n", map {
2253                        s/%%(.*)$/<!-- $1 -->/;
2254                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/;
2255                        s/\\begin\{enumerate\}/<ol>/;
2256                        s/\\item /  <li>/;
2257                        s/\\end\{enumerate\}/<\/ol>/;
2258                        s/\\textbf\{(.*)\}/<b>$1<\/b>/;
2259                        s/\\\\\*/ /;
2260                        $_;
2261                      }
2262                      $conf->config_orbase('invoice_latexnotes', $template)
2263           );
2264   }
2265
2266 #  #do variable substitutions in notes
2267 #  $invoice_data{'notes'} =
2268 #    join("\n",
2269 #      map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
2270 #        $conf->config_orbase('invoice_latexnotes', $suffix)
2271 #    );
2272
2273   if (
2274          defined( $conf->config_orbase('invoice_htmlfooter', $template) )
2275       && length(  $conf->config_orbase('invoice_htmlfooter', $template) )
2276   ) {
2277    $invoice_data{'footer'} =
2278      join("\n", $conf->config_orbase('invoice_htmlfooter', $template) );
2279   } else {
2280    $invoice_data{'footer'} =
2281        join("\n", map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; }
2282                       $conf->config_orbase('invoice_latexfooter', $template)
2283            );
2284   }
2285
2286   $invoice_data{'po_line'} =
2287     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
2288       ? encode_entities("Purchase Order #". $cust_main->payinfo)
2289       : '';
2290
2291   my $money_char = $conf->config('money_char') || '$';
2292
2293   foreach my $line_item ( $self->_items ) {
2294     my $detail = {
2295       ext_description => [],
2296     };
2297     $detail->{'ref'} = $line_item->{'pkgnum'};
2298     $detail->{'description'} = encode_entities($line_item->{'description'});
2299     if ( exists $line_item->{'ext_description'} ) {
2300       @{$detail->{'ext_description'}} = map {
2301         encode_entities($_);
2302       } @{$line_item->{'ext_description'}};
2303     }
2304     $detail->{'amount'} = $money_char. $line_item->{'amount'};
2305     $detail->{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
2306
2307     push @{$invoice_data{'detail_items'}}, $detail;
2308   }
2309
2310
2311   my $taxtotal = 0;
2312   foreach my $tax ( $self->_items_tax ) {
2313     my $total = {};
2314     $total->{'total_item'} = encode_entities($tax->{'description'});
2315     $taxtotal += $tax->{'amount'};
2316     $total->{'total_amount'} = $money_char. $tax->{'amount'};
2317     push @{$invoice_data{'total_items'}}, $total;
2318   }
2319
2320   if ( $taxtotal ) {
2321     my $total = {};
2322     $total->{'total_item'} = 'Sub-total';
2323     $total->{'total_amount'} =
2324       $money_char. sprintf('%.2f', $self->charged - $taxtotal );
2325     unshift @{$invoice_data{'total_items'}}, $total;
2326   }
2327
2328   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
2329   {
2330     my $total = {};
2331     $total->{'total_item'} = '<b>Total</b>';
2332     $total->{'total_amount'} =
2333       "<b>$money_char".  sprintf('%.2f', $self->charged + $pr_total ). '</b>';
2334     push @{$invoice_data{'total_items'}}, $total;
2335   }
2336
2337   #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
2338
2339   # credits
2340   foreach my $credit ( $self->_items_credits ) {
2341     my $total;
2342     $total->{'total_item'} = encode_entities($credit->{'description'});
2343     #$credittotal
2344     $total->{'total_amount'} = "-$money_char". $credit->{'amount'};
2345     push @{$invoice_data{'total_items'}}, $total;
2346   }
2347
2348   # payments
2349   foreach my $payment ( $self->_items_payments ) {
2350     my $total = {};
2351     $total->{'total_item'} = encode_entities($payment->{'description'});
2352     #$paymenttotal
2353     $total->{'total_amount'} = "-$money_char". $payment->{'amount'};
2354     push @{$invoice_data{'total_items'}}, $total;
2355   }
2356
2357   {
2358     my $total;
2359     $total->{'total_item'} = '<b>'. $self->balance_due_msg. '</b>';
2360     $total->{'total_amount'} =
2361       "<b>$money_char".  sprintf('%.2f', $self->owed + $pr_total ). '</b>';
2362     push @{$invoice_data{'total_items'}}, $total;
2363   }
2364
2365   $html_template->fill_in( HASH => \%invoice_data);
2366 }
2367
2368 # quick subroutine for print_latex
2369 #
2370 # There are ten characters that LaTeX treats as special characters, which
2371 # means that they do not simply typeset themselves:
2372 #      # $ % & ~ _ ^ \ { }
2373 #
2374 # TeX ignores blanks following an escaped character; if you want a blank (as
2375 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
2376
2377 sub _latex_escape {
2378   my $value = shift;
2379   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
2380   $value =~ s/([<>])/\$$1\$/g;
2381   $value;
2382 }
2383
2384 #utility methods for print_*
2385
2386 sub balance_due_msg {
2387   my $self = shift;
2388   my $msg = 'Balance Due';
2389   return $msg unless $conf->exists('invoice_default_terms');
2390   if ( $conf->config('invoice_default_terms') =~ /^\s*Net\s*(\d+)\s*$/ ) {
2391     $msg .= ' - Please pay by '. time2str("%x", $self->_date + ($1*86400) );
2392   } elsif ( $conf->config('invoice_default_terms') ) {
2393     $msg .= ' - '. $conf->config('invoice_default_terms');
2394   }
2395   $msg;
2396 }
2397
2398 sub _items {
2399   my $self = shift;
2400   my @display = scalar(@_)
2401                 ? @_
2402                 : qw( _items_previous _items_pkg );
2403                 #: qw( _items_pkg );
2404                 #: qw( _items_previous _items_pkg _items_tax _items_credits _items_payments );
2405   my @b = ();
2406   foreach my $display ( @display ) {
2407     push @b, $self->$display(@_);
2408   }
2409   @b;
2410 }
2411
2412 sub _items_previous {
2413   my $self = shift;
2414   my $cust_main = $self->cust_main;
2415   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
2416   my @b = ();
2417   foreach ( @pr_cust_bill ) {
2418     push @b, {
2419       'description' => 'Previous Balance, Invoice #'. $_->invnum.
2420                        ' ('. time2str('%x',$_->_date). ')',
2421       #'pkgpart'     => 'N/A',
2422       'pkgnum'      => 'N/A',
2423       'amount'      => sprintf("%.2f", $_->owed),
2424     };
2425   }
2426   @b;
2427
2428   #{
2429   #    'description'     => 'Previous Balance',
2430   #    #'pkgpart'         => 'N/A',
2431   #    'pkgnum'          => 'N/A',
2432   #    'amount'          => sprintf("%10.2f", $pr_total ),
2433   #    'ext_description' => [ map {
2434   #                                 "Invoice ". $_->invnum.
2435   #                                 " (". time2str("%x",$_->_date). ") ".
2436   #                                 sprintf("%10.2f", $_->owed)
2437   #                         } @pr_cust_bill ],
2438
2439   #};
2440 }
2441
2442 sub _items_pkg {
2443   my $self = shift;
2444   my @cust_bill_pkg = grep { $_->pkgnum } $self->cust_bill_pkg;
2445   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2446 }
2447
2448 sub _items_tax {
2449   my $self = shift;
2450   my @cust_bill_pkg = grep { ! $_->pkgnum } $self->cust_bill_pkg;
2451   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2452 }
2453
2454 sub _items_cust_bill_pkg {
2455   my $self = shift;
2456   my $cust_bill_pkg = shift;
2457
2458   my @b = ();
2459   foreach my $cust_bill_pkg ( @$cust_bill_pkg ) {
2460
2461     my $desc = $cust_bill_pkg->desc;
2462
2463     if ( $cust_bill_pkg->pkgnum > 0 ) {
2464
2465       if ( $cust_bill_pkg->setup != 0 ) {
2466         my $description = $desc;
2467         $description .= ' Setup' if $cust_bill_pkg->recur != 0;
2468         my @d = $cust_bill_pkg->cust_pkg->h_labels_short($self->_date);
2469         push @d, $cust_bill_pkg->details if $cust_bill_pkg->recur == 0;
2470         push @b, {
2471           description     => $description,
2472           #pkgpart         => $part_pkg->pkgpart,
2473           pkgnum          => $cust_bill_pkg->pkgnum,
2474           amount          => sprintf("%.2f", $cust_bill_pkg->setup),
2475           ext_description => \@d,
2476         };
2477       }
2478
2479       if ( $cust_bill_pkg->recur != 0 ) {
2480         push @b, {
2481           description     => "$desc (" .
2482                                time2str('%x', $cust_bill_pkg->sdate). ' - '.
2483                                time2str('%x', $cust_bill_pkg->edate). ')',
2484           #pkgpart         => $part_pkg->pkgpart,
2485           pkgnum          => $cust_bill_pkg->pkgnum,
2486           amount          => sprintf("%.2f", $cust_bill_pkg->recur),
2487           ext_description =>
2488             [ $cust_bill_pkg->cust_pkg->h_labels_short( $cust_bill_pkg->edate,
2489                                                         $cust_bill_pkg->sdate),
2490               $cust_bill_pkg->details,
2491             ],
2492         };
2493       }
2494
2495     } else { #pkgnum tax or one-shot line item (??)
2496
2497       if ( $cust_bill_pkg->setup != 0 ) {
2498         push @b, {
2499           'description' => $desc,
2500           'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
2501         };
2502       }
2503       if ( $cust_bill_pkg->recur != 0 ) {
2504         push @b, {
2505           'description' => "$desc (".
2506                            time2str("%x", $cust_bill_pkg->sdate). ' - '.
2507                            time2str("%x", $cust_bill_pkg->edate). ')',
2508           'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
2509         };
2510       }
2511
2512     }
2513
2514   }
2515
2516   @b;
2517
2518 }
2519
2520 sub _items_credits {
2521   my $self = shift;
2522
2523   my @b;
2524   #credits
2525   foreach ( $self->cust_credited ) {
2526
2527     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
2528
2529     my $reason = $_->cust_credit->reason;
2530     #my $reason = substr($_->cust_credit->reason,0,32);
2531     #$reason .= '...' if length($reason) < length($_->cust_credit->reason);
2532     $reason = " ($reason) " if $reason;
2533     push @b, {
2534       #'description' => 'Credit ref\#'. $_->crednum.
2535       #                 " (". time2str("%x",$_->cust_credit->_date) .")".
2536       #                 $reason,
2537       'description' => 'Credit applied '.
2538                        time2str("%x",$_->cust_credit->_date). $reason,
2539       'amount'      => sprintf("%.2f",$_->amount),
2540     };
2541   }
2542   #foreach ( @cr_cust_credit ) {
2543   #  push @buf,[
2544   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
2545   #    $money_char. sprintf("%10.2f",$_->credited)
2546   #  ];
2547   #}
2548
2549   @b;
2550
2551 }
2552
2553 sub _items_payments {
2554   my $self = shift;
2555
2556   my @b;
2557   #get & print payments
2558   foreach ( $self->cust_bill_pay ) {
2559
2560     #something more elaborate if $_->amount ne ->cust_pay->paid ?
2561
2562     push @b, {
2563       'description' => "Payment received ".
2564                        time2str("%x",$_->cust_pay->_date ),
2565       'amount'      => sprintf("%.2f", $_->amount )
2566     };
2567   }
2568
2569   @b;
2570
2571 }
2572
2573
2574 =back
2575
2576 =head1 SUBROUTINES
2577
2578 =over 4
2579
2580 =item reprint
2581
2582 =cut
2583
2584 sub process_reprint {
2585   process_re_X('print', @_);
2586 }
2587
2588 =item reemail
2589
2590 =cut
2591
2592 sub process_reemail {
2593   process_re_X('email', @_);
2594 }
2595
2596 =item refax
2597
2598 =cut
2599
2600 sub process_refax {
2601   process_re_X('fax', @_);
2602 }
2603
2604 use Storable qw(thaw);
2605 use Data::Dumper;
2606 use MIME::Base64;
2607 sub process_re_X {
2608   my( $method, $job ) = ( shift, shift );
2609   warn "process_re_X $method for job $job\n" if $DEBUG;
2610
2611   my $param = thaw(decode_base64(shift));
2612   warn Dumper($param) if $DEBUG;
2613
2614   re_X(
2615     $method,
2616     $job,
2617     %$param,
2618   );
2619
2620 }
2621
2622 sub re_X {
2623   my($method, $job, %param ) = @_;
2624 #              [ 'begin', 'end', 'agentnum', 'open', 'days', 'newest_percust' ],
2625   if ( $DEBUG ) {
2626     warn "re_X $method for job $job with param:\n".
2627          join( '', map { "  $_ => ". $param{$_}. "\n" } keys %param );
2628   }
2629
2630   #some false laziness w/search/cust_bill.html
2631   my $distinct = '';
2632   my $orderby = 'ORDER BY cust_bill._date';
2633
2634   my @where;
2635
2636   if ( $param{'begin'} =~ /^(\d+)$/ ) {
2637     push @where, "cust_bill._date >= $1";
2638   }
2639   if ( $param{'end'} =~ /^(\d+)$/ ) {
2640     push @where, "cust_bill._date < $1";
2641   }
2642   if ( $param{'agentnum'} =~ /^(\d+)$/ ) {
2643     push @where, "cust_main.agentnum = $1";
2644   }
2645
2646   my $owed =
2647     "charged - ( SELECT COALESCE(SUM(amount),0) FROM cust_bill_pay
2648                  WHERE cust_bill_pay.invnum = cust_bill.invnum )
2649              - ( SELECT COALESCE(SUM(amount),0) FROM cust_credit_bill
2650                  WHERE cust_credit_bill.invnum = cust_bill.invnum )";
2651
2652   push @where, "0 != $owed"
2653     if $param{'open'};
2654
2655   push @where, "cust_bill._date < ". (time-86400*$param{'days'})
2656     if $param{'days'};
2657
2658   my $extra_sql = scalar(@where) ? 'WHERE '. join(' AND ', @where) : '';
2659
2660   my $addl_from = 'left join cust_main using ( custnum )';
2661
2662   if ( $param{'newest_percust'} ) {
2663     $distinct = 'DISTINCT ON ( cust_bill.custnum )';
2664     $orderby = 'ORDER BY cust_bill.custnum ASC, cust_bill._date DESC';
2665     #$count_query = "SELECT COUNT(DISTINCT cust_bill.custnum), 'N/A', 'N/A'";
2666   }
2667
2668   my @cust_bill = qsearch( 'cust_bill',
2669                            {},
2670                            "$distinct cust_bill.*",
2671                            $extra_sql,
2672                            '',
2673                            $addl_from
2674                          );
2675
2676   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
2677   foreach my $cust_bill ( @cust_bill ) {
2678     $cust_bill->$method();
2679
2680     if ( $job ) { #progressbar foo
2681       $num++;
2682       if ( time - $min_sec > $last ) {
2683         my $error = $job->update_statustext(
2684           int( 100 * $num / scalar(@cust_bill) )
2685         );
2686         die $error if $error;
2687         $last = time;
2688       }
2689     }
2690
2691   }
2692
2693 }
2694
2695 =back
2696
2697 =head1 BUGS
2698
2699 The delete method.
2700
2701 print_text formatting (and some logic :/) is in source, but needs to be
2702 slurped in from a file.  Also number of lines ($=).
2703
2704 =head1 SEE ALSO
2705
2706 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
2707 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
2708 documentation.
2709
2710 =cut
2711
2712 1;
2713