FS/FS/access_user.pm

   1 package FS::access_user;
   2
   3 use strict;
   4 use base qw( FS::m2m_Common FS::option_Common );
   5 use vars qw( $DEBUG $me $conf $htpasswd_file );
   6 use FS::UID;
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs dbh );
   9 use FS::access_user_pref;
  10 use FS::access_usergroup;
  11 use FS::agent;
  12 use FS::cust_main;
  13 use FS::sales;
  14 use FS::sched_item;
  15
  16 $DEBUG = 0;
  17 $me = '[FS::access_user]';
  18
  19 #kludge htpasswd for now (i hope this bootstraps okay)
  20 FS::UID->install_callback( sub {
  21   $conf = new FS::Conf;
  22   $htpasswd_file = $conf->base_dir. '/htpasswd';
  23 } );
  24
  25 =head1 NAME
  26
  27 FS::access_user - Object methods for access_user records
  28
  29 =head1 SYNOPSIS
  30
  31   use FS::access_user;
  32
  33   $record = new FS::access_user \%hash;
  34   $record = new FS::access_user { 'column' => 'value' };
  35
  36   $error = $record->insert;
  37
  38   $error = $new_record->replace($old_record);
  39
  40   $error = $record->delete;
  41
  42   $error = $record->check;
  43
  44 =head1 DESCRIPTION
  45
  46 An FS::access_user object represents an internal access user.  FS::access_user
  47 inherits from FS::Record.  The following fields are currently supported:
  48
  49 =over 4
  50
  51 =item usernum - primary key
  52
  53 =item username -
  54
  55 =item _password -
  56
  57 =item last -
  58
  59 =item first -
  60
  61 =item disabled - empty or 'Y'
  62
  63 =back
  64
  65 =head1 METHODS
  66
  67 =over 4
  68
  69 =item new HASHREF
  70
  71 Creates a new internal access user.  To add the user to the database, see L<"insert">.
  72
  73 Note that this stores the hash reference, not a distinct copy of the hash it
  74 points to.  You can ask the object for a copy with the I<hash> method.
  75
  76 =cut
  77
  78 # the new method can be inherited from FS::Record, if a table method is defined
  79
  80 sub table { 'access_user'; }
  81
  82 sub _option_table    { 'access_user_pref'; }
  83 sub _option_namecol  { 'prefname'; }
  84 sub _option_valuecol { 'prefvalue'; }
  85
  86 =item insert
  87
  88 Adds this record to the database.  If there is an error, returns the error,
  89 otherwise returns false.
  90
  91 =cut
  92
  93 sub insert {
  94   my $self = shift;
  95
  96   my $error = $self->check;
  97   return $error if $error;
  98
  99   local $SIG{HUP} = 'IGNORE';
 100   local $SIG{INT} = 'IGNORE';
 101   local $SIG{QUIT} = 'IGNORE';
 102   local $SIG{TERM} = 'IGNORE';
 103   local $SIG{TSTP} = 'IGNORE';
 104   local $SIG{PIPE} = 'IGNORE';
 105
 106   my $oldAutoCommit = $FS::UID::AutoCommit;
 107   local $FS::UID::AutoCommit = 0;
 108   my $dbh = dbh;
 109
 110   $error = $self->htpasswd_kludge();
 111   if ( $error ) {
 112     $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 113     return $error;
 114   }
 115
 116   $error = $self->SUPER::insert(@_);
 117
 118   if ( $error ) {
 119     $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 120
 121     #make sure it isn't a dup username?  or you could nuke people's passwords
 122     #blah.  really just should do our own login w/cookies
 123     #and auth out of the db in the first place
 124     #my $hterror = $self->htpasswd_kludge('-D');
 125     #$error .= " - additionally received error cleaning up htpasswd file: $hterror"
 126     return $error;
 127
 128   } else {
 129     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 130     '';
 131   }
 132
 133 }
 134
 135 sub htpasswd_kludge {
 136   my $self = shift;
 137
 138   return '' if $self->is_system_user;
 139
 140   unshift @_, '-c' unless -e $htpasswd_file;
 141   if (
 142        system('htpasswd', '-b', @_,
 143                           $htpasswd_file,
 144                           $self->username,
 145                           $self->_password,
 146              ) == 0
 147      )
 148   {
 149     return '';
 150   } else {
 151     return 'htpasswd exited unsucessfully';
 152   }
 153 }
 154
 155 =item delete
 156
 157 Delete this record from the database.
 158
 159 =cut
 160
 161 sub delete {
 162   my $self = shift;
 163
 164   local $SIG{HUP} = 'IGNORE';
 165   local $SIG{INT} = 'IGNORE';
 166   local $SIG{QUIT} = 'IGNORE';
 167   local $SIG{TERM} = 'IGNORE';
 168   local $SIG{TSTP} = 'IGNORE';
 169   local $SIG{PIPE} = 'IGNORE';
 170
 171   my $oldAutoCommit = $FS::UID::AutoCommit;
 172   local $FS::UID::AutoCommit = 0;
 173   my $dbh = dbh;
 174
 175   my $error =
 176        $self->SUPER::delete(@_)
 177     || $self->htpasswd_kludge('-D')
 178   ;
 179
 180   if ( $error ) {
 181     $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 182     return $error;
 183   } else {
 184     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 185     '';
 186   }
 187
 188 }
 189
 190 =item replace OLD_RECORD
 191
 192 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 193 returns the error, otherwise returns false.
 194
 195 =cut
 196
 197 sub replace {
 198   my $new = shift;
 199
 200   my $old = ( ref($_[0]) eq ref($new) )
 201               ? shift
 202               : $new->replace_old;
 203
 204   local $SIG{HUP} = 'IGNORE';
 205   local $SIG{INT} = 'IGNORE';
 206   local $SIG{QUIT} = 'IGNORE';
 207   local $SIG{TERM} = 'IGNORE';
 208   local $SIG{TSTP} = 'IGNORE';
 209   local $SIG{PIPE} = 'IGNORE';
 210
 211   my $oldAutoCommit = $FS::UID::AutoCommit;
 212   local $FS::UID::AutoCommit = 0;
 213   my $dbh = dbh;
 214
 215   if ( $new->_password ne $old->_password ) {
 216     my $error = $new->htpasswd_kludge();
 217     if ( $error ) {
 218       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 219       return $error;
 220     }
 221   } elsif ( $old->disabled && !$new->disabled
 222               && $new->_password =~ /changeme/i ) {
 223     return "Must change password when enabling this account";
 224   }
 225
 226   my $error = $new->SUPER::replace($old, @_);
 227
 228   if ( $error ) {
 229     $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 230     return $error;
 231   } else {
 232     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 233     '';
 234   }
 235
 236 }
 237
 238 =item check
 239
 240 Checks all fields to make sure this is a valid internal access user.  If there is
 241 an error, returns the error, otherwise returns false.  Called by the insert
 242 and replace methods.
 243
 244 =cut
 245
 246 # the check method should currently be supplied - FS::Record contains some
 247 # data checking routines
 248
 249 sub check {
 250   my $self = shift;
 251
 252   my $error =
 253     $self->ut_numbern('usernum')
 254     || $self->ut_alpha_lower('username')
 255     || $self->ut_text('_password')
 256     || $self->ut_text('last')
 257     || $self->ut_text('first')
 258     || $self->ut_foreign_keyn('user_custnum', 'cust_main', 'custnum')
 259     || $self->ut_foreign_keyn('report_salesnum', 'sales', 'salesnum')
 260     || $self->ut_enum('disabled', [ '', 'Y' ] )
 261   ;
 262   return $error if $error;
 263
 264   $self->SUPER::check;
 265 }
 266
 267 =item name
 268
 269 Returns a name string for this user: "Last, First".
 270
 271 =cut
 272
 273 sub name {
 274   my $self = shift;
 275   return $self->username
 276     if $self->get('last') eq 'Lastname' && $self->first eq 'Firstname';
 277   return $self->get('last'). ', '. $self->first;
 278 }
 279
 280 =item user_cust_main
 281
 282 Returns the FS::cust_main object (see L<FS::cust_main>), if any, for this
 283 user.
 284
 285 =cut
 286
 287 sub user_cust_main {
 288   my $self = shift;
 289   qsearchs( 'cust_main', { 'custnum' => $self->user_custnum } );
 290 }
 291
 292 =item report_sales
 293
 294 Returns the FS::sales object (see L<FS::sales>), if any, for this
 295 user.
 296
 297 =cut
 298
 299 sub report_sales {
 300   my $self = shift;
 301   qsearchs( 'sales', { 'salesnum' => $self->report_salesnum } );
 302 }
 303
 304 =item access_usergroup
 305
 306 Returns links to the the groups this user is a part of, as FS::access_usergroup
 307 objects (see L<FS::access_usergroup>).
 308
 309 =cut
 310
 311 sub access_usergroup {
 312   my $self = shift;
 313   qsearch( 'access_usergroup', { 'usernum' => $self->usernum } );
 314 }
 315
 316 #=item access_groups
 317 #
 318 #=cut
 319 #
 320 #sub access_groups {
 321 #
 322 #}
 323 #
 324 #=item access_groupnames
 325 #
 326 #=cut
 327 #
 328 #sub access_groupnames {
 329 #
 330 #}
 331
 332 =item agentnums
 333
 334 Returns a list of agentnums this user can view (via group membership).
 335
 336 =cut
 337
 338 sub agentnums {
 339   my $self = shift;
 340   my $sth = dbh->prepare(
 341     "SELECT DISTINCT agentnum FROM access_usergroup
 342                               JOIN access_groupagent USING ( groupnum )
 343        WHERE usernum = ?"
 344   ) or die dbh->errstr;
 345   $sth->execute($self->usernum) or die $sth->errstr;
 346   map { $_->[0] } @{ $sth->fetchall_arrayref };
 347 }
 348
 349 =item agentnums_href
 350
 351 Returns a hashref of agentnums this user can view.
 352
 353 =cut
 354
 355 sub agentnums_href {
 356   my $self = shift;
 357   scalar( { map { $_ => 1 } $self->agentnums } );
 358 }
 359
 360 =item agentnums_sql [ HASHREF | OPTION => VALUE ... ]
 361
 362 Returns an sql fragement to select only agentnums this user can view.
 363
 364 Options are passed as a hashref or a list.  Available options are:
 365
 366 =over 4
 367
 368 =item null
 369
 370 The frament will also allow the selection of null agentnums.
 371
 372 =item null_right
 373
 374 The fragment will also allow the selection of null agentnums if the current
 375 user has the provided access right
 376
 377 =item table
 378
 379 Optional table name in which agentnum is being checked.  Sometimes required to
 380 resolve 'column reference "agentnum" is ambiguous' errors.
 381
 382 =item viewall_right
 383
 384 All agents will be viewable if the current user has the provided access right.
 385 Defaults to 'View customers of all agents'.
 386
 387 =back
 388
 389 =cut
 390
 391 sub agentnums_sql {
 392   my( $self ) = shift;
 393   my %opt = ref($_[0]) ? %{$_[0]} : @_;
 394
 395   my $agentnum = $opt{'table'} ? $opt{'table'}.'.agentnum' : 'agentnum';
 396
 397   my @or = ();
 398
 399   my $viewall_right = $opt{'viewall_right'} || 'View customers of all agents';
 400   if ( $self->access_right($viewall_right) ) {
 401     push @or, "$agentnum IS NOT NULL";
 402   } else {
 403     push @or, "$agentnum IN (". join(',', $self->agentnums). ')';
 404   }
 405
 406   push @or, "$agentnum IS NULL"
 407     if $opt{'null'}
 408     || ( $opt{'null_right'} && $self->access_right($opt{'null_right'}) );
 409
 410   return ' 1 = 0 ' unless scalar(@or);
 411   '( '. join( ' OR ', @or ). ' )';
 412
 413 }
 414
 415 =item agentnum
 416
 417 Returns true if the user can view the specified agent.
 418
 419 =cut
 420
 421 sub agentnum {
 422   my( $self, $agentnum ) = @_;
 423   my $sth = dbh->prepare(
 424     "SELECT COUNT(*) FROM access_usergroup
 425                      JOIN access_groupagent USING ( groupnum )
 426        WHERE usernum = ? AND agentnum = ?"
 427   ) or die dbh->errstr;
 428   $sth->execute($self->usernum, $agentnum) or die $sth->errstr;
 429   $sth->fetchrow_arrayref->[0];
 430 }
 431
 432 =item agents [ HASHREF | OPTION => VALUE ... ]
 433
 434 Returns the list of agents this user can view (via group membership), as
 435 FS::agent objects.  Accepts the same options as the agentnums_sql method.
 436
 437 =cut
 438
 439 sub agents {
 440   my $self = shift;
 441   qsearch({
 442     'table'     => 'agent',
 443     'hashref'   => { disabled=>'' },
 444     'extra_sql' => ' AND '. $self->agentnums_sql(@_),
 445     'order_by'  => 'ORDER BY agent',
 446   });
 447 }
 448
 449 =item access_right RIGHTNAME | LISTREF
 450
 451 Given a right name or a list reference of right names, returns true if this
 452 user has this right, or, for a list, one of the rights (currently via group
 453 membership, eventually also via user overrides).
 454
 455 =cut
 456
 457 sub access_right {
 458   my( $self, $rightname ) = @_;
 459
 460   $rightname = [ $rightname ] unless ref($rightname);
 461
 462   warn "$me access_right called on ". join(', ', @$rightname). "\n"
 463     if $DEBUG;
 464
 465   #some caching of ACL requests for low-hanging fruit perf improvement
 466   #since we get a new $CurrentUser object each page view there shouldn't be any
 467   #issues with stickiness
 468   if ( $self->{_ACLcache} ) {
 469
 470     unless ( grep !exists($self->{_ACLcache}{$_}), @$rightname ) {
 471       warn "$me ACL cache hit for ". join(', ', @$rightname). "\n"
 472         if $DEBUG;
 473       return scalar( grep $self->{_ACLcache}{$_}, @$rightname );
 474     }
 475
 476     warn "$me ACL cache miss for ". join(', ', @$rightname). "\n"
 477       if $DEBUG;
 478
 479   } else {
 480
 481     warn "initializing ACL cache\n"
 482       if $DEBUG;
 483     $self->{_ACLcache} = {};
 484
 485   }
 486
 487   my $has_right = ' rightname IN ('. join(',', map '?', @$rightname ). ') ';
 488
 489   my $sth = dbh->prepare("
 490     SELECT groupnum FROM access_usergroup
 491                     LEFT JOIN access_group USING ( groupnum )
 492                     LEFT JOIN access_right
 493                          ON ( access_group.groupnum = access_right.rightobjnum )
 494       WHERE usernum = ?
 495         AND righttype = 'FS::access_group'
 496         AND $has_right
 497       LIMIT 1
 498   ") or die dbh->errstr;
 499   $sth->execute($self->usernum, @$rightname) or die $sth->errstr;
 500   my $row = $sth->fetchrow_arrayref;
 501
 502   my $return = $row ? $row->[0] : '';
 503
 504   #just caching the single-rightname hits should be enough of a win for now
 505   if ( scalar(@$rightname) == 1 ) {
 506     $self->{_ACLcache}{${$rightname}[0]} = $return;
 507   }
 508
 509   $return;
 510
 511 }
 512
 513 =item default_customer_view
 514
 515 Returns the default customer view for this user, from the
 516 "default_customer_view" user preference, the "cust_main-default_view" config,
 517 or the hardcoded default, "basics" (formerly "jumbo" prior to 3.0).
 518
 519 =cut
 520
 521 sub default_customer_view {
 522   my $self = shift;
 523
 524   $self->option('default_customer_view')
 525     || $conf->config('cust_main-default_view')
 526     || 'basics'; #s/jumbo/basics/ starting with 3.0
 527
 528 }
 529
 530 =item spreadsheet_format [ OVERRIDE ]
 531
 532 Returns a hashref of this user's Excel spreadsheet download settings:
 533 'extension' (xls or xlsx), 'class' (Spreadsheet::WriteExcel or
 534 Excel::Writer::XLSX), and 'mime_type'.  If OVERRIDE is 'XLS' or 'XLSX',
 535 use that instead of the user's setting.
 536
 537 =cut
 538
 539 # is there a better place to put this?
 540 my %formats = (
 541   XLS => {
 542     extension => '.xls',
 543     class => 'Spreadsheet::WriteExcel',
 544     mime_type => 'application/vnd.ms-excel',
 545   },
 546   XLSX => {
 547     extension => '.xlsx',
 548     class => 'Excel::Writer::XLSX',
 549     mime_type => # it's on wikipedia, it must be true
 550       'application/vnd.openxmlformats-officedocument.spreadsheetml.sheet',
 551   }
 552 );
 553
 554 sub spreadsheet_format {
 555   my $self = shift;
 556   my $override = shift;
 557
 558   my $f =  $override
 559         || $self->option('spreadsheet_format')
 560         || $conf->config('spreadsheet_format')
 561         || 'XLS';
 562
 563   $formats{$f};
 564 }
 565
 566 =item is_system_user
 567
 568 Returns true if this user has the name of a known system account.  These
 569 users will not appear in the htpasswd file and can't have passwords set.
 570
 571 =cut
 572
 573 sub is_system_user {
 574   my $self = shift;
 575   return grep { $_ eq $self->username } ( qw(
 576     fs_queue
 577     fs_daily
 578     fs_selfservice
 579     fs_signup
 580     fs_bootstrap
 581     fs_selfserv
 582     fs_api
 583 ) );
 584 }
 585
 586 sub sched_item {
 587   my $self = shift;
 588   qsearch( 'sched_item', { 'usernum' => $self->usernum } );
 589 }
 590
 591 =back
 592
 593 =head1 BUGS
 594
 595 =head1 SEE ALSO
 596
 597 L<FS::Record>, schema.html from the base documentation.
 598
 599 =cut
 600
 601 1;
 602