FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   # to simplify tokenization upgrades
  51   die "Conf selfservice-payment_gateway no longer supported"
  52     if $conf->config('selfservice-payment_gateway');
  53
  54   $conf->touch('payment_receipt')
  55     if $conf->exists('payment_receipt_email')
  56     || $conf->config('payment_receipt_msgnum');
  57
  58   $conf->touch('geocode-require_nw_coordinates')
  59     if $conf->exists('svc_broadband-require-nw-coordinates');
  60
  61   unless ( $conf->config('echeck-country') ) {
  62     if ( $conf->exists('cust_main-require-bank-branch') ) {
  63       $conf->set('echeck-country', 'CA');
  64     } elsif ( $conf->exists('echeck-nonus') ) {
  65       $conf->set('echeck-country', 'XX');
  66     } else {
  67       $conf->set('echeck-country', 'US');
  68     }
  69   }
  70
  71   my @agents = qsearch('agent', {});
  72
  73   upgrade_overlimit_groups($conf);
  74   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  75
  76   upgrade_invoice_from($conf);
  77   foreach my $agent (@agents) {
  78     upgrade_invoice_from($conf,$agent->agentnum,1);
  79   }
  80
  81   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  82   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  83     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  84       qw( quotation_html quotation_latex quotation_latexnotes );
  85
  86   # change 'fslongtable' to 'longtable'
  87   # in invoice and quotation main templates, and also in all secondary
  88   # invoice templates
  89   my @latex_confs =
  90     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  91
  92   foreach my $c (@latex_confs) {
  93     my $value = $c->value;
  94     if (length($value) and $value =~ /fslongtable/) {
  95       $value =~ s/fslongtable/longtable/g;
  96       $conf->set($c->name, $value, $c->agentnum);
  97     }
  98   }
  99
 100   # if there's a USPS tools login, assume that's the standardization method
 101   # you want to use
 102   $conf->set('address_standardize_method', 'usps')
 103     if $conf->exists('usps_webtools-userid')
 104     && length($conf->config('usps_webtools-userid')) > 0
 105     && ! $conf->exists('address_standardize_method');
 106
 107   # this option has been renamed/expanded
 108   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 109     $conf->touch('cust_main-enable_spouse');
 110     $conf->delete('cust_main-enable_spouse_birthdate');
 111   }
 112
 113   # renamed/repurposed
 114   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 115     $conf->touch('part_pkg-show_fcc_options');
 116     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 117     warn "
 118 You have FCC Form 477 package options enabled.
 119
 120 Starting with the October 2014 filing date, the FCC has redesigned
 121 Form 477 and introduced new service categories.  See bin/convert-477-options
 122 to update your package configuration for the new report.
 123
 124 If you need to continue using the old Form 477 report, turn on the
 125 'old_fcc_report' configuration option.
 126 ";
 127   }
 128
 129   # boolean invoice_sections_by_location option is now
 130   # invoice_sections_method = 'location'
 131   my @invoice_sections_confs =
 132     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 133   foreach my $c (@invoice_sections_confs) {
 134     $c->name =~ /^(\w+)sections_by_location$/;
 135     $conf->delete($c->name);
 136     my $newname = $1.'sections_method';
 137     $conf->set($newname, 'location');
 138   }
 139
 140   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 141   if ( $conf->exists('enable_taxproducts') ) {
 142
 143     $conf->delete('enable_taxproducts');
 144     $conf->set('tax_data_vendor', 'cch');
 145
 146   }
 147
 148   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 149   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 150     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 151     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 152   }
 153
 154   # boolean+text previous_balance-exclude_from_total is now two separate options
 155   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 156   if ( defined $total_new_charges && length($total_new_charges) > 0 ) {
 157     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 158     $conf->set('previous_balance-exclude_from_total', '');
 159   }
 160
 161   # switch from specifying an email address to boolean check
 162   if ( $conf->exists('batch-errors_to') ) {
 163     $conf->touch('batch-errors_not_fatal');
 164     $conf->delete('batch-errors_to');
 165   }
 166
 167   if ( $conf->exists('voip-cust_email_csv_cdr') ) {
 168     $conf->set('voip_cdr_email_attach', 'csv');
 169     $conf->delete('voip-cust_email_csv_cdr') ;
 170   }
 171
 172   if ($conf->exists('unsuspendauto') && !$conf->config('unsuspend_balance')) {
 173     $conf->set('unsuspend_balance','Zero');
 174     $conf->delete('unsuspendauto');
 175   }
 176
 177   my $cust_fields = $conf->config('cust-fields');
 178   if ( defined $cust_fields && $cust_fields =~ / \| Payment Type/ ) {
 179     # so we can potentially use 'Payment Types' or somesuch in the future
 180     $cust_fields =~ s/ \| Payment Type( \|)/$1/;
 181     $cust_fields =~ s/ \| Payment Type$//;
 182     $conf->set('cust-fields',$cust_fields);
 183   }
 184
 185   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 186
 187   # if translate-auto-insert is enabled for a locale, ensure that invoice
 188   # terms are in the msgcat (is there a better place for this?)
 189   if (my $auto_locale = $conf->config('translate-auto-insert')) {
 190     my $lh = FS::L10N->get_handle($auto_locale);
 191     foreach (@FS::Conf::invoice_terms) {
 192       $lh->maketext($_) if length($_);
 193     }
 194   }
 195
 196   unless ( FS::upgrade_journal->is_done('deprecate_unmask_ss') ) {
 197     if ( $conf->config_bool( 'unmask_ss' )) {
 198       warn "'unmask_ssn' deprecated from global configuration\n";
 199       for my $access_group ( qsearch( access_group => {} )) {
 200         $access_group->grant_access_right( 'Unmask customer SSN' );
 201         warn " - 'Unmask customer SSN' access right granted to '" .
 202              $access_group->groupname . "' employee group\n";
 203       }
 204     }
 205     FS::upgrade_journal->set_done('deprecate_unmask_ss');
 206   }
 207
 208 }
 209
 210 sub upgrade_overlimit_groups {
 211     my $conf = shift;
 212     my $agentnum = shift;
 213     my @groups = $conf->config('overlimit_groups',$agentnum);
 214     if(scalar(@groups)) {
 215         my $groups = join(',',@groups);
 216         my @groupnums;
 217         my $error = '';
 218         if ( $groups !~ /^[\d,]+$/ ) {
 219             foreach my $groupname ( @groups ) {
 220                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 221                 unless ( $g ) {
 222                     $g = new FS::radius_group {
 223                                     'groupname' => $groupname,
 224                                     'description' => $groupname,
 225                                     };
 226                     $error = $g->insert;
 227                     die $error if $error;
 228                 }
 229                 push @groupnums, $g->groupnum;
 230             }
 231             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 232         }
 233     }
 234 }
 235
 236 sub upgrade_invoice_from {
 237   my ($conf, $agentnum, $agentonly) = @_;
 238   if (
 239           ! $conf->exists('invoice_from_name',$agentnum,$agentonly)
 240        && $conf->exists('invoice_from',$agentnum,$agentonly)
 241        && $conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/
 242   ) {
 243     my $realemail = $1;
 244     $realemail =~ s/^\s*//; # remove leading spaces
 245     $realemail =~ s/\s*$//; # remove trailing spaces
 246     my $realname = $conf->config('invoice_from',$agentnum);
 247     $realname =~ s/\<.*\>//; # remove email address
 248     $realname =~ s/^\s*//; # remove leading spaces
 249     $realname =~ s/\s*$//; # remove trailing spaces
 250     # properly quote names that contain punctuation
 251     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 252       $realname = '"' . $realname . '"';
 253     }
 254     $conf->set('invoice_from_name', $realname, $agentnum);
 255     $conf->set('invoice_from', $realemail, $agentnum);
 256   }
 257 }
 258
 259 =item upgrade
 260
 261 =cut
 262
 263 sub upgrade {
 264   my %opt = @_;
 265
 266   my $data = upgrade_data(%opt);
 267
 268   my $oldAutoCommit = $FS::UID::AutoCommit;
 269   local $FS::UID::AutoCommit = 0;
 270   local $FS::UID::AutoCommit = 0;
 271
 272   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 273
 274
 275   foreach my $table ( keys %$data ) {
 276
 277     my $class = "FS::$table";
 278     eval "use $class;";
 279     die $@ if $@;
 280
 281     if ( $class->can('_upgrade_data') ) {
 282       warn "Upgrading $table...\n";
 283
 284       my $start = time;
 285
 286       $class->_upgrade_data(%opt);
 287
 288       # New interface for async upgrades: a class can declare a
 289       # "queueable_upgrade" method, which will run as part of the normal
 290       # upgrade, but if the -j option is passed, will instead be run from
 291       # the job queue.
 292       if ( $class->can('queueable_upgrade') ) {
 293         my $jobname = $class . '::queueable_upgrade';
 294         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 295         if ($num_jobs > 0) {
 296           warn "$class upgrade already scheduled.\n";
 297         } else {
 298           if ( $opt{'queue'} ) {
 299             warn "Scheduling $class upgrade.\n";
 300             my $job = FS::queue->new({ job => $jobname });
 301             $job->insert($class, %opt);
 302           } else {
 303             $class->queueable_upgrade(%opt);
 304           }
 305         } #$num_jobs == 0
 306       }
 307
 308       if ( $oldAutoCommit ) {
 309         warn "  committing\n";
 310         dbh->commit or die dbh->errstr;
 311       }
 312
 313       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 314       warn "  done in ". (time-$start). " seconds\n";
 315
 316     } else {
 317       warn "WARNING: asked for upgrade of $table,".
 318            " but FS::$table has no _upgrade_data method\n";
 319     }
 320
 321 #    my @records = @{ $data->{$table} };
 322 #
 323 #    foreach my $record ( @records ) {
 324 #      my $args = delete($record->{'_upgrade_args'}) || [];
 325 #      my $object = $class->new( $record );
 326 #      my $error = $object->insert( @$args );
 327 #      die "error inserting record into $table: $error\n"
 328 #        if $error;
 329 #    }
 330
 331   }
 332
 333   local($FS::cust_main::ignore_expired_card) = 1;
 334   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 335   local($FS::cust_main::ignore_banned_card) = 1;
 336   local($FS::cust_main::skip_fuzzyfiles) = 1;
 337
 338   local($FS::cust_payby::ignore_expired_card) = 1;
 339   local($FS::cust_payby::ignore_banned_card) = 1;
 340
 341   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 342   # kind of a weird spot for this, but it's better than duplicating
 343   # all this code in each class...
 344   my @decrypt_tables = qw( cust_main cust_pay_void cust_pay cust_refund cust_pay_pending );
 345   foreach my $table ( @decrypt_tables ) {
 346       my @objects = qsearch({
 347         'table'     => $table,
 348         'hashref'   => {},
 349         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 350                        " AND LENGTH(payinfo) > 100",
 351       });
 352       foreach my $object ( @objects ) {
 353           my $payinfo = $object->decrypt($object->payinfo);
 354           if ( $payinfo eq $object->payinfo ) {
 355             warn "error decrypting payinfo for $table: $payinfo\n";
 356             next;
 357           }
 358           $object->payinfo($payinfo);
 359           my $error = $object->replace;
 360           die $error if $error;
 361       }
 362   }
 363
 364 }
 365
 366 =item upgrade_data
 367
 368 =cut
 369
 370 sub upgrade_data {
 371   my %opt = @_;
 372
 373   tie my %hash, 'Tie::IxHash',
 374
 375     #remap log levels
 376     'log' => [],
 377
 378     #payby conditions to new ones
 379     'part_event_condition' => [],
 380
 381     #payby actions to new ones
 382     'part_event' => [],
 383
 384     #fix whitespace - before cust_main
 385     'cust_location' => [],
 386
 387     # need before cust_main tokenization upgrade,
 388     # blocks tokenization upgrade if deprecated features still in use
 389     'agent_payment_gateway' => [],
 390
 391     #remove bad source_paynum before cust_main
 392     'cust_refund' => [],
 393
 394     #cust_main (tokenizes cards, remove paycvv from history, locations, cust_payby, etc)
 395     # (handles payinfo encryption/tokenization across all relevant tables)
 396     'cust_main' => [],
 397
 398     #contact -> cust_contact / prospect_contact
 399     'contact' => [],
 400
 401     #msgcat
 402     'msgcat' => [],
 403
 404     #reason type and reasons
 405     'reason_type'     => [],
 406     'cust_pkg_reason' => [],
 407
 408     #need part_pkg before cust_credit...
 409     'part_pkg' => [],
 410
 411     #customer credits
 412     'cust_credit' => [],
 413
 414     # reason / void_reason migration to reasonnum / void_reasonnum
 415     'cust_credit_void' => [],
 416     'cust_bill_void' => [],
 417     # also fix some tax allocation records
 418     'cust_bill_pkg_void' => [],
 419
 420     #duplicate history records
 421     'h_cust_svc'  => [],
 422
 423     #populate cust_pay.otaker
 424     'cust_pay'    => [],
 425
 426     #populate part_pkg_taxclass for starters
 427     'part_pkg_taxclass' => [],
 428
 429     #remove bad pending records
 430     'cust_pay_pending' => [],
 431
 432     #replace invnum and pkgnum with billpkgnum
 433     'cust_bill_pkg_detail' => [],
 434
 435     #usage_classes if we have none
 436     'usage_class' => [],
 437
 438     #phone_type if we have none
 439     'phone_type' => [],
 440
 441     #fixup access rights
 442     'access_right' => [],
 443
 444     #change recur_flat and enable_prorate
 445     'part_pkg_option' => [],
 446
 447     #add weights to pkg_category
 448     'pkg_category' => [],
 449
 450     #cdrbatch fixes
 451     'cdr' => [],
 452
 453     #otaker->usernum
 454     'cust_attachment' => [],
 455     #'cust_credit' => [],
 456     #'cust_main' => [],
 457     'cust_main_note' => [],
 458     #'cust_pay' => [],
 459     'cust_pay_void' => [],
 460     'cust_pkg' => [],
 461     #'cust_pkg_reason' => [],
 462     'cust_pkg_discount' => [],
 463     #'cust_refund' => [],
 464     'banned_pay' => [],
 465
 466     #paycardtype
 467     'cust_payby' => [],
 468
 469     #default namespace
 470     'payment_gateway' => [],
 471
 472     #migrate to templates
 473     'msg_template' => [],
 474
 475     #return unprovisioned numbers to availability
 476     'phone_avail' => [],
 477
 478     #insert scripcondition
 479     'TicketSystem' => [],
 480
 481     #insert LATA data if not already present
 482     'lata' => [],
 483
 484     #insert MSA data if not already present
 485     'msa' => [],
 486
 487     # migrate to radius_group and groupnum instead of groupname
 488     'radius_usergroup' => [],
 489     'part_svc'         => [],
 490     'part_export'      => [],
 491
 492     #insert default tower_sector if not present
 493     'tower' => [],
 494
 495     #repair improperly deleted services
 496     'cust_svc' => [],
 497
 498     #routernum/blocknum
 499     'svc_broadband' => [],
 500
 501     #set up payment gateways if needed
 502     'pay_batch' => [],
 503
 504     #flag monthly tax exemptions
 505     'cust_tax_exempt_pkg' => [],
 506
 507     #kick off tax location history upgrade
 508     'cust_bill_pkg' => [],
 509
 510     #fix taxable line item links
 511     'cust_bill_pkg_tax_location' => [],
 512
 513     #populate state FIPS codes if not already done
 514     'state' => [],
 515
 516     #set default locations on quoted packages
 517     'quotation_pkg' => [],
 518
 519     #populate tax statuses
 520     'tax_status' => [],
 521
 522     #mark certain taxes as system-maintained,
 523     # and fix whitespace
 524     'cust_main_county' => [],
 525
 526     #'compliance solutions' -> 'compliance_solutions'
 527     'tax_rate' => [],
 528     'tax_rate_location' => [],
 529
 530     #upgrade part_event_condition_option agentnum to a multiple hash value
 531     'part_event_condition_option' =>[],
 532
 533     #fix ip format
 534     'svc_circuit' => [],
 535
 536     #fix ip format
 537     'svc_hardware' => [],
 538
 539     #fix ip format
 540     'svc_pbx' => [],
 541
 542     #fix ip format
 543     'tower_sector' => [],
 544
 545
 546   ;
 547
 548   \%hash;
 549
 550 }
 551
 552 =item upgrade_schema
 553
 554 =cut
 555
 556 sub upgrade_schema {
 557   my %opt = @_;
 558
 559   my $data = upgrade_schema_data(%opt);
 560
 561   my $oldAutoCommit = $FS::UID::AutoCommit;
 562   local $FS::UID::AutoCommit = 0;
 563   local $FS::UID::AutoCommit = 0;
 564
 565   foreach my $table ( keys %$data ) {
 566
 567     my $class = "FS::$table";
 568     eval "use $class;";
 569     die $@ if $@;
 570
 571     if ( $class->can('_upgrade_schema') ) {
 572       warn "Upgrading $table schema...\n";
 573
 574       my $start = time;
 575
 576       $class->_upgrade_schema(%opt);
 577
 578       if ( $oldAutoCommit ) {
 579         warn "  committing\n";
 580         dbh->commit or die dbh->errstr;
 581       }
 582
 583       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 584       warn "  done in ". (time-$start). " seconds\n";
 585
 586     } else {
 587       warn "WARNING: asked for schema upgrade of $table,".
 588            " but FS::$table has no _upgrade_schema method\n";
 589     }
 590
 591   }
 592
 593 }
 594
 595 =item upgrade_schema_data
 596
 597 =cut
 598
 599 sub upgrade_schema_data {
 600   my %opt = @_;
 601
 602   #auto-find tables/classes with an _update_schema method?
 603
 604   tie my %hash, 'Tie::IxHash',
 605
 606     #fix classnum character(1)
 607     'cust_bill_pkg_detail' => [],
 608     #add necessary columns to RT schema
 609     'TicketSystem' => [],
 610     #remove h_access_user_log if it exists (since our regular auto schema
 611     # upgrade doesn't have the drop tables flag turned on)
 612     'access_user_log' => [],
 613     #remove possible dangling records
 614     'password_history' => [],
 615     'cust_pay_pending' => [],
 616     #remove records referencing removed things with their FKs
 617     'pkg_referral' => [],
 618     'cust_bill_pkg_discount' => [],
 619     'cust_msg' => [],
 620     'cust_bill_pay_batch' => [],
 621     'cust_event_fee' => [],
 622     'radius_attr' => [],
 623     'queue_depend' => [],
 624     'cust_main_invoice' => [],
 625     #update records referencing removed things with their FKs
 626     'cust_pkg' => [],
 627   ;
 628
 629   \%hash;
 630
 631 }
 632
 633 sub upgrade_sqlradius {
 634   #my %opt = @_;
 635
 636   my $conf = new FS::Conf;
 637
 638   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 639
 640   foreach my $part_export ( @part_export ) {
 641
 642     my $errmsg = 'Error adding FreesideStatus to '.
 643                  $part_export->option('datasrc'). ': ';
 644
 645     my $dbh = DBI->connect(
 646       ( map $part_export->option($_), qw ( datasrc username password ) ),
 647       { PrintError => 0, PrintWarn => 0 }
 648     ) or do {
 649       warn $errmsg.$DBI::errstr;
 650       next;
 651     };
 652
 653     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 654     my $group = "UserName";
 655     $group .= ",Realm"
 656       if ref($part_export) =~ /withdomain/
 657       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 658
 659     my $sth_alter = $dbh->prepare(
 660       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 661     );
 662     if ( $sth_alter ) {
 663       if ( $sth_alter->execute ) {
 664         my $sth_update = $dbh->prepare(
 665          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 666         ) or die $errmsg.$dbh->errstr;
 667         $sth_update->execute or die $errmsg.$sth_update->errstr;
 668       } else {
 669         my $error = $sth_alter->errstr;
 670         warn $errmsg.$error
 671           unless $error =~ /Duplicate column name/i  #mysql
 672               || $error =~ /already exists/i;        #Pg
 673 ;
 674       }
 675     } else {
 676       my $error = $dbh->errstr;
 677       warn $errmsg.$error; #unless $error =~ /exists/i;
 678     }
 679
 680     my $sth_index = $dbh->prepare(
 681       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 682     );
 683     if ( $sth_index ) {
 684       unless ( $sth_index->execute ) {
 685         my $error = $sth_index->errstr;
 686         warn $errmsg.$error
 687           unless $error =~ /Duplicate key name/i #mysql
 688               || $error =~ /already exists/i;    #Pg
 689       }
 690     } else {
 691       my $error = $dbh->errstr;
 692       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 693     }
 694
 695     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 696       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 697       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 698
 699     my $sth = $dbh->prepare("SELECT UserName,
 700                                     Realm,
 701                                     $str2time max(AcctStartTime)),
 702                                     $str2time max(AcctStopTime))
 703                               FROM radacct
 704                               WHERE FreesideStatus = 'done'
 705                                 AND $times
 706                               GROUP BY $group
 707                             ")
 708       or die $errmsg.$dbh->errstr;
 709     $sth->execute() or die $errmsg.$sth->errstr;
 710
 711     while (my $row = $sth->fetchrow_arrayref ) {
 712       my ($username, $realm, $start, $stop) = @$row;
 713
 714       $username = lc($username) unless $conf->exists('username-uppercase');
 715
 716       my $exportnum = $part_export->exportnum;
 717       my $extra_sql = " AND exportnum = $exportnum ".
 718                       " AND exportsvcnum IS NOT NULL ";
 719
 720       if ( ref($part_export) =~ /withdomain/ ) {
 721         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 722                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 723       }
 724
 725       my $svc_acct = qsearchs({
 726         'select'    => 'svc_acct.*',
 727         'table'     => 'svc_acct',
 728         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 729                        'LEFT JOIN export_svc USING ( svcpart )',
 730         'hashref'   => { 'username' => $username },
 731         'extra_sql' => $extra_sql,
 732       });
 733
 734       if ($svc_acct) {
 735         $svc_acct->last_login($start)
 736           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 737         $svc_acct->last_logout($stop)
 738           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 739       }
 740     }
 741   }
 742
 743 }
 744
 745 =back
 746
 747 =head1 BUGS
 748
 749 Sure.
 750
 751 =head1 SEE ALSO
 752
 753 =cut
 754
 755 1;