FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   # to simplify tokenization upgrades
  51   die "Conf selfservice-payment_gateway no longer supported"
  52     if $conf->config('selfservice-payment_gateway');
  53
  54   $conf->touch('payment_receipt')
  55     if $conf->exists('payment_receipt_email')
  56     || $conf->config('payment_receipt_msgnum');
  57
  58   $conf->touch('geocode-require_nw_coordinates')
  59     if $conf->exists('svc_broadband-require-nw-coordinates');
  60
  61   unless ( $conf->config('echeck-country') ) {
  62     if ( $conf->exists('cust_main-require-bank-branch') ) {
  63       $conf->set('echeck-country', 'CA');
  64     } elsif ( $conf->exists('echeck-nonus') ) {
  65       $conf->set('echeck-country', 'XX');
  66     } else {
  67       $conf->set('echeck-country', 'US');
  68     }
  69   }
  70
  71   my @agents = qsearch('agent', {});
  72
  73   upgrade_overlimit_groups($conf);
  74   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  75
  76   upgrade_invoice_from($conf);
  77   foreach my $agent (@agents) {
  78     upgrade_invoice_from($conf,$agent->agentnum,1);
  79   }
  80
  81   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  82   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  83     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  84       qw( quotation_html quotation_latex quotation_latexnotes );
  85
  86   # change 'fslongtable' to 'longtable'
  87   # in invoice and quotation main templates, and also in all secondary
  88   # invoice templates
  89   my @latex_confs =
  90     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  91
  92   foreach my $c (@latex_confs) {
  93     my $value = $c->value;
  94     if (length($value) and $value =~ /fslongtable/) {
  95       $value =~ s/fslongtable/longtable/g;
  96       $conf->set($c->name, $value, $c->agentnum);
  97     }
  98   }
  99
 100   # if there's a USPS tools login, assume that's the standardization method
 101   # you want to use
 102   $conf->set('address_standardize_method', 'usps')
 103     if $conf->exists('usps_webtools-userid')
 104     && length($conf->config('usps_webtools-userid')) > 0
 105     && ! $conf->exists('address_standardize_method');
 106
 107   # this option has been renamed/expanded
 108   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 109     $conf->touch('cust_main-enable_spouse');
 110     $conf->delete('cust_main-enable_spouse_birthdate');
 111   }
 112
 113   # renamed/repurposed
 114   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 115     $conf->touch('part_pkg-show_fcc_options');
 116     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 117     warn "
 118 You have FCC Form 477 package options enabled.
 119
 120 Starting with the October 2014 filing date, the FCC has redesigned
 121 Form 477 and introduced new service categories.  See bin/convert-477-options
 122 to update your package configuration for the new report.
 123
 124 If you need to continue using the old Form 477 report, turn on the
 125 'old_fcc_report' configuration option.
 126 ";
 127   }
 128
 129   # boolean invoice_sections_by_location option is now
 130   # invoice_sections_method = 'location'
 131   my @invoice_sections_confs =
 132     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 133   foreach my $c (@invoice_sections_confs) {
 134     $c->name =~ /^(\w+)sections_by_location$/;
 135     $conf->delete($c->name);
 136     my $newname = $1.'sections_method';
 137     $conf->set($newname, 'location');
 138   }
 139
 140   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 141   if ( $conf->exists('enable_taxproducts') ) {
 142
 143     $conf->delete('enable_taxproducts');
 144     $conf->set('tax_data_vendor', 'cch');
 145
 146   }
 147
 148   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 149   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 150     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 151     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 152   }
 153
 154   # boolean+text previous_balance-exclude_from_total is now two separate options
 155   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 156   if (length($total_new_charges) > 0) {
 157     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 158     $conf->set('previous_balance-exclude_from_total', '');
 159   }
 160
 161   # switch from specifying an email address to boolean check
 162   if ( $conf->exists('batch-errors_to') ) {
 163     $conf->touch('batch-errors_not_fatal');
 164     $conf->delete('batch-errors_to');
 165   }
 166
 167   if ( $conf->exists('voip-cust_email_csv_cdr') ) {
 168     $conf->set('voip_cdr_email_attach', 'csv');
 169     $conf->delete('voip-cust_email_csv_cdr') ;
 170   }
 171
 172   if ($conf->exists('unsuspendauto') && !$conf->config('unsuspend_balance')) {
 173     $conf->set('unsuspend_balance','Zero');
 174     $conf->delete('unsuspendauto');
 175   }
 176
 177   if ($conf->config('cust-fields') =~ / \| Payment Type/) {
 178     my $cust_fields = $conf->config('cust-fields');
 179     # so we can potentially use 'Payment Types' or somesuch in the future
 180     $cust_fields =~ s/ \| Payment Type( \|)/$1/;
 181     $cust_fields =~ s/ \| Payment Type$//;
 182     $conf->set('cust-fields',$cust_fields);
 183   }
 184
 185   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 186
 187   # if translate-auto-insert is enabled for a locale, ensure that invoice
 188   # terms are in the msgcat (is there a better place for this?)
 189   if (my $auto_locale = $conf->config('translate-auto-insert')) {
 190     my $lh = FS::L10N->get_handle($auto_locale);
 191     foreach (@FS::Conf::invoice_terms) {
 192       $lh->maketext($_) if length($_);
 193     }
 194   }
 195 }
 196
 197 sub upgrade_overlimit_groups {
 198     my $conf = shift;
 199     my $agentnum = shift;
 200     my @groups = $conf->config('overlimit_groups',$agentnum);
 201     if(scalar(@groups)) {
 202         my $groups = join(',',@groups);
 203         my @groupnums;
 204         my $error = '';
 205         if ( $groups !~ /^[\d,]+$/ ) {
 206             foreach my $groupname ( @groups ) {
 207                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 208                 unless ( $g ) {
 209                     $g = new FS::radius_group {
 210                                     'groupname' => $groupname,
 211                                     'description' => $groupname,
 212                                     };
 213                     $error = $g->insert;
 214                     die $error if $error;
 215                 }
 216                 push @groupnums, $g->groupnum;
 217             }
 218             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 219         }
 220     }
 221 }
 222
 223 sub upgrade_invoice_from {
 224   my ($conf, $agentnum, $agentonly) = @_;
 225   if (
 226           ! $conf->exists('invoice_from_name',$agentnum,$agentonly)
 227        && $conf->exists('invoice_from',$agentnum,$agentonly)
 228        && $conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/
 229   ) {
 230     my $realemail = $1;
 231     $realemail =~ s/^\s*//; # remove leading spaces
 232     $realemail =~ s/\s*$//; # remove trailing spaces
 233     my $realname = $conf->config('invoice_from',$agentnum);
 234     $realname =~ s/\<.*\>//; # remove email address
 235     $realname =~ s/^\s*//; # remove leading spaces
 236     $realname =~ s/\s*$//; # remove trailing spaces
 237     # properly quote names that contain punctuation
 238     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 239       $realname = '"' . $realname . '"';
 240     }
 241     $conf->set('invoice_from_name', $realname, $agentnum);
 242     $conf->set('invoice_from', $realemail, $agentnum);
 243   }
 244 }
 245
 246 =item upgrade
 247
 248 =cut
 249
 250 sub upgrade {
 251   my %opt = @_;
 252
 253   my $data = upgrade_data(%opt);
 254
 255   my $oldAutoCommit = $FS::UID::AutoCommit;
 256   local $FS::UID::AutoCommit = 0;
 257   local $FS::UID::AutoCommit = 0;
 258
 259   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 260
 261
 262   foreach my $table ( keys %$data ) {
 263
 264     my $class = "FS::$table";
 265     eval "use $class;";
 266     die $@ if $@;
 267
 268     if ( $class->can('_upgrade_data') ) {
 269       warn "Upgrading $table...\n";
 270
 271       my $start = time;
 272
 273       $class->_upgrade_data(%opt);
 274
 275       # New interface for async upgrades: a class can declare a
 276       # "queueable_upgrade" method, which will run as part of the normal
 277       # upgrade, but if the -j option is passed, will instead be run from
 278       # the job queue.
 279       if ( $class->can('queueable_upgrade') ) {
 280         my $jobname = $class . '::queueable_upgrade';
 281         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 282         if ($num_jobs > 0) {
 283           warn "$class upgrade already scheduled.\n";
 284         } else {
 285           if ( $opt{'queue'} ) {
 286             warn "Scheduling $class upgrade.\n";
 287             my $job = FS::queue->new({ job => $jobname });
 288             $job->insert($class, %opt);
 289           } else {
 290             $class->queueable_upgrade(%opt);
 291           }
 292         } #$num_jobs == 0
 293       }
 294
 295       if ( $oldAutoCommit ) {
 296         warn "  committing\n";
 297         dbh->commit or die dbh->errstr;
 298       }
 299
 300       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 301       warn "  done in ". (time-$start). " seconds\n";
 302
 303     } else {
 304       warn "WARNING: asked for upgrade of $table,".
 305            " but FS::$table has no _upgrade_data method\n";
 306     }
 307
 308 #    my @records = @{ $data->{$table} };
 309 #
 310 #    foreach my $record ( @records ) {
 311 #      my $args = delete($record->{'_upgrade_args'}) || [];
 312 #      my $object = $class->new( $record );
 313 #      my $error = $object->insert( @$args );
 314 #      die "error inserting record into $table: $error\n"
 315 #        if $error;
 316 #    }
 317
 318   }
 319
 320   local($FS::cust_main::ignore_expired_card) = 1;
 321   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 322   local($FS::cust_main::ignore_banned_card) = 1;
 323   local($FS::cust_main::skip_fuzzyfiles) = 1;
 324
 325   local($FS::cust_payby::ignore_expired_card) = 1;
 326   local($FS::cust_payby::ignore_banned_card) = 1;
 327
 328   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 329   # kind of a weird spot for this, but it's better than duplicating
 330   # all this code in each class...
 331   my @decrypt_tables = qw( cust_main cust_pay_void cust_pay cust_refund cust_pay_pending );
 332   foreach my $table ( @decrypt_tables ) {
 333       my @objects = qsearch({
 334         'table'     => $table,
 335         'hashref'   => {},
 336         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 337                        " AND LENGTH(payinfo) > 100",
 338       });
 339       foreach my $object ( @objects ) {
 340           my $payinfo = $object->decrypt($object->payinfo);
 341           if ( $payinfo eq $object->payinfo ) {
 342             warn "error decrypting payinfo for $table: $payinfo\n";
 343             next;
 344           }
 345           $object->payinfo($payinfo);
 346           my $error = $object->replace;
 347           die $error if $error;
 348       }
 349   }
 350
 351 }
 352
 353 =item upgrade_data
 354
 355 =cut
 356
 357 sub upgrade_data {
 358   my %opt = @_;
 359
 360   tie my %hash, 'Tie::IxHash',
 361
 362     #remap log levels
 363         'log' => [],
 364
 365     #payby conditions to new ones
 366     'part_event_condition' => [],
 367
 368     #payby actions to new ones
 369     'part_event' => [],
 370
 371     #fix whitespace - before cust_main
 372     'cust_location' => [],
 373
 374     # need before cust_main tokenization upgrade,
 375     # blocks tokenization upgrade if deprecated features still in use
 376     'agent_payment_gateway' => [],
 377
 378     #cust_main (tokenizes cards, remove paycvv from history, locations, cust_payby, etc)
 379     # (handles payinfo encryption/tokenization across all relevant tables)
 380     'cust_main' => [],
 381
 382     #contact -> cust_contact / prospect_contact
 383     'contact' => [],
 384
 385     #msgcat
 386     'msgcat' => [],
 387
 388     #reason type and reasons
 389     'reason_type'     => [],
 390     'cust_pkg_reason' => [],
 391
 392     #need part_pkg before cust_credit...
 393     'part_pkg' => [],
 394
 395     #customer credits
 396     'cust_credit' => [],
 397
 398     # reason / void_reason migration to reasonnum / void_reasonnum
 399     'cust_credit_void' => [],
 400     'cust_bill_void' => [],
 401     # also fix some tax allocation records
 402     'cust_bill_pkg_void' => [],
 403
 404     #duplicate history records
 405     'h_cust_svc'  => [],
 406
 407     #populate cust_pay.otaker
 408     'cust_pay'    => [],
 409
 410     #populate part_pkg_taxclass for starters
 411     'part_pkg_taxclass' => [],
 412
 413     #remove bad pending records
 414     'cust_pay_pending' => [],
 415
 416     #replace invnum and pkgnum with billpkgnum
 417     'cust_bill_pkg_detail' => [],
 418
 419     #usage_classes if we have none
 420     'usage_class' => [],
 421
 422     #phone_type if we have none
 423     'phone_type' => [],
 424
 425     #fixup access rights
 426     'access_right' => [],
 427
 428     #change recur_flat and enable_prorate
 429     'part_pkg_option' => [],
 430
 431     #add weights to pkg_category
 432     'pkg_category' => [],
 433
 434     #cdrbatch fixes
 435     'cdr' => [],
 436
 437     #otaker->usernum
 438     'cust_attachment' => [],
 439     #'cust_credit' => [],
 440     #'cust_main' => [],
 441     'cust_main_note' => [],
 442     #'cust_pay' => [],
 443     'cust_pay_void' => [],
 444     'cust_pkg' => [],
 445     #'cust_pkg_reason' => [],
 446     'cust_pkg_discount' => [],
 447     'cust_refund' => [],
 448     'banned_pay' => [],
 449
 450     #paycardtype
 451     'cust_payby' => [],
 452
 453     #default namespace
 454     'payment_gateway' => [],
 455
 456     #migrate to templates
 457     'msg_template' => [],
 458
 459     #return unprovisioned numbers to availability
 460     'phone_avail' => [],
 461
 462     #insert scripcondition
 463     'TicketSystem' => [],
 464
 465     #insert LATA data if not already present
 466     'lata' => [],
 467
 468     #insert MSA data if not already present
 469     'msa' => [],
 470
 471     # migrate to radius_group and groupnum instead of groupname
 472     'radius_usergroup' => [],
 473     'part_svc'         => [],
 474     'part_export'      => [],
 475
 476     #insert default tower_sector if not present
 477     'tower' => [],
 478
 479     #repair improperly deleted services
 480     'cust_svc' => [],
 481
 482     #routernum/blocknum
 483     'svc_broadband' => [],
 484
 485     #set up payment gateways if needed
 486     'pay_batch' => [],
 487
 488     #flag monthly tax exemptions
 489     'cust_tax_exempt_pkg' => [],
 490
 491     #kick off tax location history upgrade
 492     'cust_bill_pkg' => [],
 493
 494     #fix taxable line item links
 495     'cust_bill_pkg_tax_location' => [],
 496
 497     #populate state FIPS codes if not already done
 498     'state' => [],
 499
 500     #set default locations on quoted packages
 501     'quotation_pkg' => [],
 502
 503     #populate tax statuses
 504     'tax_status' => [],
 505
 506     #mark certain taxes as system-maintained,
 507     # and fix whitespace
 508     'cust_main_county' => [],
 509
 510     #'compliance solutions' -> 'compliance_solutions'
 511     'tax_rate' => [],
 512     'tax_rate_location' => [],
 513
 514     #upgrade part_event_condition_option agentnum to a multiple hash value
 515     'part_event_condition_option' =>[],
 516   ;
 517
 518   \%hash;
 519
 520 }
 521
 522 =item upgrade_schema
 523
 524 =cut
 525
 526 sub upgrade_schema {
 527   my %opt = @_;
 528
 529   my $data = upgrade_schema_data(%opt);
 530
 531   my $oldAutoCommit = $FS::UID::AutoCommit;
 532   local $FS::UID::AutoCommit = 0;
 533   local $FS::UID::AutoCommit = 0;
 534
 535   foreach my $table ( keys %$data ) {
 536
 537     my $class = "FS::$table";
 538     eval "use $class;";
 539     die $@ if $@;
 540
 541     if ( $class->can('_upgrade_schema') ) {
 542       warn "Upgrading $table schema...\n";
 543
 544       my $start = time;
 545
 546       $class->_upgrade_schema(%opt);
 547
 548       if ( $oldAutoCommit ) {
 549         warn "  committing\n";
 550         dbh->commit or die dbh->errstr;
 551       }
 552
 553       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 554       warn "  done in ". (time-$start). " seconds\n";
 555
 556     } else {
 557       warn "WARNING: asked for schema upgrade of $table,".
 558            " but FS::$table has no _upgrade_schema method\n";
 559     }
 560
 561   }
 562
 563 }
 564
 565 =item upgrade_schema_data
 566
 567 =cut
 568
 569 sub upgrade_schema_data {
 570   my %opt = @_;
 571
 572   #auto-find tables/classes with an _update_schema method?
 573
 574   tie my %hash, 'Tie::IxHash',
 575
 576     #fix classnum character(1)
 577     'cust_bill_pkg_detail' => [],
 578     #add necessary columns to RT schema
 579     'TicketSystem' => [],
 580     #remove h_access_user_log if it exists (since our regular auto schema
 581     # upgrade doesn't have the drop tables flag turned on)
 582     'access_user_log' => [],
 583     #remove possible dangling records
 584     'password_history' => [],
 585     'cust_pay_pending' => [],
 586     #remove records referencing removed things with their FKs
 587     'pkg_referral' => [],
 588     'cust_bill_pkg_discount' => [],
 589     'cust_msg' => [],
 590     'cust_bill_pay_batch' => [],
 591     'cust_event_fee' => [],
 592     'radius_attr' => [],
 593     'queue_depend' => [],
 594     'cust_main_invoice' => [],
 595     #update records referencing removed things with their FKs
 596     'cust_pkg' => [],
 597   ;
 598
 599   \%hash;
 600
 601 }
 602
 603 sub upgrade_sqlradius {
 604   #my %opt = @_;
 605
 606   my $conf = new FS::Conf;
 607
 608   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 609
 610   foreach my $part_export ( @part_export ) {
 611
 612     my $errmsg = 'Error adding FreesideStatus to '.
 613                  $part_export->option('datasrc'). ': ';
 614
 615     my $dbh = DBI->connect(
 616       ( map $part_export->option($_), qw ( datasrc username password ) ),
 617       { PrintError => 0, PrintWarn => 0 }
 618     ) or do {
 619       warn $errmsg.$DBI::errstr;
 620       next;
 621     };
 622
 623     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 624     my $group = "UserName";
 625     $group .= ",Realm"
 626       if ref($part_export) =~ /withdomain/
 627       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 628
 629     my $sth_alter = $dbh->prepare(
 630       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 631     );
 632     if ( $sth_alter ) {
 633       if ( $sth_alter->execute ) {
 634         my $sth_update = $dbh->prepare(
 635          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 636         ) or die $errmsg.$dbh->errstr;
 637         $sth_update->execute or die $errmsg.$sth_update->errstr;
 638       } else {
 639         my $error = $sth_alter->errstr;
 640         warn $errmsg.$error
 641           unless $error =~ /Duplicate column name/i  #mysql
 642               || $error =~ /already exists/i;        #Pg
 643 ;
 644       }
 645     } else {
 646       my $error = $dbh->errstr;
 647       warn $errmsg.$error; #unless $error =~ /exists/i;
 648     }
 649
 650     my $sth_index = $dbh->prepare(
 651       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 652     );
 653     if ( $sth_index ) {
 654       unless ( $sth_index->execute ) {
 655         my $error = $sth_index->errstr;
 656         warn $errmsg.$error
 657           unless $error =~ /Duplicate key name/i #mysql
 658               || $error =~ /already exists/i;    #Pg
 659       }
 660     } else {
 661       my $error = $dbh->errstr;
 662       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 663     }
 664
 665     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 666       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 667       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 668
 669     my $sth = $dbh->prepare("SELECT UserName,
 670                                     Realm,
 671                                     $str2time max(AcctStartTime)),
 672                                     $str2time max(AcctStopTime))
 673                               FROM radacct
 674                               WHERE FreesideStatus = 'done'
 675                                 AND $times
 676                               GROUP BY $group
 677                             ")
 678       or die $errmsg.$dbh->errstr;
 679     $sth->execute() or die $errmsg.$sth->errstr;
 680
 681     while (my $row = $sth->fetchrow_arrayref ) {
 682       my ($username, $realm, $start, $stop) = @$row;
 683
 684       $username = lc($username) unless $conf->exists('username-uppercase');
 685
 686       my $exportnum = $part_export->exportnum;
 687       my $extra_sql = " AND exportnum = $exportnum ".
 688                       " AND exportsvcnum IS NOT NULL ";
 689
 690       if ( ref($part_export) =~ /withdomain/ ) {
 691         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 692                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 693       }
 694
 695       my $svc_acct = qsearchs({
 696         'select'    => 'svc_acct.*',
 697         'table'     => 'svc_acct',
 698         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 699                        'LEFT JOIN export_svc USING ( svcpart )',
 700         'hashref'   => { 'username' => $username },
 701         'extra_sql' => $extra_sql,
 702       });
 703
 704       if ($svc_acct) {
 705         $svc_acct->last_login($start)
 706           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 707         $svc_acct->last_logout($stop)
 708           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 709       }
 710     }
 711   }
 712
 713 }
 714
 715 =back
 716
 717 =head1 BUGS
 718
 719 Sure.
 720
 721 =head1 SEE ALSO
 722
 723 =cut
 724
 725 1;
 726