FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $dbdef_file $dbdef $setup_hack $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $me %dbdef_cache );
   6 use subs qw(reload_dbdef);
   7 use Exporter;
   8 use Carp qw(carp cluck croak confess);
   9 use File::CounterFile;
  10 use Locale::Country;
  11 use DBI qw(:sql_types);
  12 use DBIx::DBSchema 0.19;
  13 use FS::UID qw(dbh checkruid getotaker datasrc driver_name);
  14 use FS::SearchCache;
  15 use FS::Msgcat qw(gettext);
  16
  17 @ISA = qw(Exporter);
  18 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch);
  19
  20 $DEBUG = 0;
  21 $me = '[FS::Record]';
  22
  23 #ask FS::UID to run this stuff for us later
  24 $FS::UID::callback{'FS::Record'} = sub {
  25   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  26   $dbdef_file = "/usr/local/etc/freeside/dbdef.". datasrc;
  27   &reload_dbdef unless $setup_hack; #$setup_hack needed now?
  28 };
  29
  30 =head1 NAME
  31
  32 FS::Record - Database record objects
  33
  34 =head1 SYNOPSIS
  35
  36     use FS::Record;
  37     use FS::Record qw(dbh fields qsearch qsearchs dbdef);
  38
  39     $record = new FS::Record 'table', \%hash;
  40     $record = new FS::Record 'table', { 'column' => 'value', ... };
  41
  42     $record  = qsearchs FS::Record 'table', \%hash;
  43     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  44     @records = qsearch  FS::Record 'table', \%hash;
  45     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  46
  47     $table = $record->table;
  48     $dbdef_table = $record->dbdef_table;
  49
  50     $value = $record->get('column');
  51     $value = $record->getfield('column');
  52     $value = $record->column;
  53
  54     $record->set( 'column' => 'value' );
  55     $record->setfield( 'column' => 'value' );
  56     $record->column('value');
  57
  58     %hash = $record->hash;
  59
  60     $hashref = $record->hashref;
  61
  62     $error = $record->insert;
  63     #$error = $record->add; #deprecated
  64
  65     $error = $record->delete;
  66     #$error = $record->del; #deprecated
  67
  68     $error = $new_record->replace($old_record);
  69     #$error = $new_record->rep($old_record); #deprecated
  70
  71     $value = $record->unique('column');
  72
  73     $error = $record->ut_float('column');
  74     $error = $record->ut_number('column');
  75     $error = $record->ut_numbern('column');
  76     $error = $record->ut_money('column');
  77     $error = $record->ut_text('column');
  78     $error = $record->ut_textn('column');
  79     $error = $record->ut_alpha('column');
  80     $error = $record->ut_alphan('column');
  81     $error = $record->ut_phonen('column');
  82     $error = $record->ut_anything('column');
  83     $error = $record->ut_name('column');
  84
  85     $dbdef = reload_dbdef;
  86     $dbdef = reload_dbdef "/non/standard/filename";
  87     $dbdef = dbdef;
  88
  89     $quoted_value = _quote($value,'table','field');
  90
  91     #depriciated
  92     $fields = hfields('table');
  93     if ( $fields->{Field} ) { # etc.
  94
  95     @fields = fields 'table'; #as a subroutine
  96     @fields = $record->fields; #as a method call
  97
  98
  99 =head1 DESCRIPTION
 100
 101 (Mostly) object-oriented interface to database records.  Records are currently
 102 implemented on top of DBI.  FS::Record is intended as a base class for
 103 table-specific classes to inherit from, i.e. FS::cust_main.
 104
 105 =head1 CONSTRUCTORS
 106
 107 =over 4
 108
 109 =item new [ TABLE, ] HASHREF
 110
 111 Creates a new record.  It doesn't store it in the database, though.  See
 112 L<"insert"> for that.
 113
 114 Note that the object stores this hash reference, not a distinct copy of the
 115 hash it points to.  You can ask the object for a copy with the I<hash>
 116 method.
 117
 118 TABLE can only be omitted when a dervived class overrides the table method.
 119
 120 =cut
 121
 122 sub new {
 123   my $proto = shift;
 124   my $class = ref($proto) || $proto;
 125   my $self = {};
 126   bless ($self, $class);
 127
 128   unless ( defined ( $self->table ) ) {
 129     $self->{'Table'} = shift;
 130     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 131   }
 132
 133   my $hashref = $self->{'Hash'} = shift;
 134
 135   foreach my $field ( grep !defined($hashref->{$_}), $self->fields ) {
 136     $hashref->{$field}='';
 137   }
 138
 139   $self->_cache($hashref, shift) if $self->can('_cache') && @_;
 140
 141   $self;
 142 }
 143
 144 sub new_or_cached {
 145   my $proto = shift;
 146   my $class = ref($proto) || $proto;
 147   my $self = {};
 148   bless ($self, $class);
 149
 150   $self->{'Table'} = shift unless defined ( $self->table );
 151
 152   my $hashref = $self->{'Hash'} = shift;
 153   my $cache = shift;
 154   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 155     my $obj = $cache->cache->{$hashref->{$cache->key}};
 156     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 157     $obj;
 158   } else {
 159     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 160   }
 161
 162 }
 163
 164 sub create {
 165   my $proto = shift;
 166   my $class = ref($proto) || $proto;
 167   my $self = {};
 168   bless ($self, $class);
 169   if ( defined $self->table ) {
 170     cluck "create constructor is depriciated, use new!";
 171     $self->new(@_);
 172   } else {
 173     croak "FS::Record::create called (not from a subclass)!";
 174   }
 175 }
 176
 177 =item qsearch TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ
 178
 179 Searches the database for all records matching (at least) the key/value pairs
 180 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 181 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 182 objects.
 183
 184 ###oops, argh, FS::Record::new only lets us create database fields.
 185 #Normal behaviour if SELECT is not specified is `*', as in
 186 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 187 #feature where you can specify SELECT - remember, the objects returned,
 188 #although blessed into the appropriate `FS::TABLE' package, will only have the
 189 #fields you specify.  This might have unwanted results if you then go calling
 190 #regular FS::TABLE methods
 191 #on it.
 192
 193 =cut
 194
 195 sub qsearch {
 196   my($stable, $record, $select, $extra_sql, $cache ) = @_;
 197   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 198   #for jsearch
 199   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 200   $stable = $1;
 201   $select ||= '*';
 202   my $dbh = dbh;
 203
 204   my $table = $cache ? $cache->table : $stable;
 205
 206   my @fields = grep exists($record->{$_}), fields($table);
 207
 208   my $statement = "SELECT $select FROM $stable";
 209   if ( @fields ) {
 210     $statement .= ' WHERE '. join(' AND ', map {
 211
 212       my $op = '=';
 213       my $column = $_;
 214       if ( ref($record->{$_}) ) {
 215         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 216         #$op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name !~ /^Pg$/i;
 217         if ( uc($op) eq 'ILIKE' ) {
 218           $op = 'LIKE';
 219           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 220           $column = "LOWER($_)";
 221         }
 222         $record->{$_} = $record->{$_}{'value'}
 223       }
 224
 225       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 226         if ( $op eq '=' ) {
 227           if ( driver_name eq 'Pg' ) {
 228             my $type = $dbdef->table($table)->column($column)->type;
 229             if ( $type =~ /(int|serial)/i ) {
 230               qq-( $column IS NULL )-;
 231             } else {
 232               qq-( $column IS NULL OR $column = '' )-;
 233             }
 234           } else {
 235             qq-( $column IS NULL OR $column = "" )-;
 236           }
 237         } elsif ( $op eq '!=' ) {
 238           if ( driver_name eq 'Pg' ) {
 239             my $type = $dbdef->table($table)->column($column)->type;
 240             if ( $type =~ /(int|serial)/i ) {
 241               qq-( $column IS NOT NULL )-;
 242             } else {
 243               qq-( $column IS NOT NULL AND $column != '' )-;
 244             }
 245           } else {
 246             qq-( $column IS NOT NULL AND $column != "" )-;
 247           }
 248         } else {
 249           if ( driver_name eq 'Pg' ) {
 250             qq-( $column $op '' )-;
 251           } else {
 252             qq-( $column $op "" )-;
 253           }
 254         }
 255       } else {
 256         "$column $op ?";
 257       }
 258     } @fields );
 259   }
 260   $statement .= " $extra_sql" if defined($extra_sql);
 261
 262   warn "[debug]$me $statement\n" if $DEBUG > 1;
 263   my $sth = $dbh->prepare($statement)
 264     or croak "$dbh->errstr doing $statement";
 265
 266   my $bind = 1;
 267
 268   foreach my $field (
 269     grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 270   ) {
 271     if ( $record->{$field} =~ /^\d+(\.\d+)?$/
 272          && $dbdef->table($table)->column($field)->type =~ /(int|serial)/i
 273     ) {
 274       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_INTEGER } );
 275     } else {
 276       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_VARCHAR } );
 277     }
 278   }
 279
 280 #  $sth->execute( map $record->{$_},
 281 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 282 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 283
 284   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 285
 286   $dbh->commit or croak $dbh->errstr if $FS::UID::AutoCommit;
 287
 288   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 289     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 290       #derivied class didn't override new method, so this optimization is safe
 291       if ( $cache ) {
 292         map {
 293           new_or_cached( "FS::$table", { %{$_} }, $cache )
 294         } @{$sth->fetchall_arrayref( {} )};
 295       } else {
 296         map {
 297           new( "FS::$table", { %{$_} } )
 298         } @{$sth->fetchall_arrayref( {} )};
 299       }
 300     } else {
 301       warn "untested code (class FS::$table uses custom new method)";
 302       map {
 303         eval 'FS::'. $table. '->new( { %{$_} } )';
 304       } @{$sth->fetchall_arrayref( {} )};
 305     }
 306   } else {
 307     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 308     map {
 309       FS::Record->new( $table, { %{$_} } );
 310     } @{$sth->fetchall_arrayref( {} )};
 311   }
 312
 313 }
 314
 315 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 316
 317 Experimental JOINed search method.  Using this method, you can execute a
 318 single SELECT spanning multiple tables, and cache the results for subsequent
 319 method calls.  Interface will almost definately change in an incompatible
 320 fashion.
 321
 322 Arguments:
 323
 324 =cut
 325
 326 sub jsearch {
 327   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 328   my $cache = FS::SearchCache->new( $ptable, $pkey );
 329   my %saw;
 330   ( $cache,
 331     grep { !$saw{$_->getfield($pkey)}++ }
 332       qsearch($table, $record, $select, $extra_sql, $cache )
 333   );
 334 }
 335
 336 =item qsearchs TABLE, HASHREF
 337
 338 Same as qsearch, except that if more than one record matches, it B<carp>s but
 339 returns the first.  If this happens, you either made a logic error in asking
 340 for a single item, or your data is corrupted.
 341
 342 =cut
 343
 344 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 345   my $table = $_[0];
 346   my(@result) = qsearch(@_);
 347   carp "warning: Multiple records in scalar search ($table)"
 348     if scalar(@result) > 1;
 349   #should warn more vehemently if the search was on a primary key?
 350   scalar(@result) ? ($result[0]) : ();
 351 }
 352
 353 =back
 354
 355 =head1 METHODS
 356
 357 =over 4
 358
 359 =item table
 360
 361 Returns the table name.
 362
 363 =cut
 364
 365 sub table {
 366 #  cluck "warning: FS::Record::table depriciated; supply one in subclass!";
 367   my $self = shift;
 368   $self -> {'Table'};
 369 }
 370
 371 =item dbdef_table
 372
 373 Returns the DBIx::DBSchema::Table object for the table.
 374
 375 =cut
 376
 377 sub dbdef_table {
 378   my($self)=@_;
 379   my($table)=$self->table;
 380   $dbdef->table($table);
 381 }
 382
 383 =item get, getfield COLUMN
 384
 385 Returns the value of the column/field/key COLUMN.
 386
 387 =cut
 388
 389 sub get {
 390   my($self,$field) = @_;
 391   # to avoid "Use of unitialized value" errors
 392   if ( defined ( $self->{Hash}->{$field} ) ) {
 393     $self->{Hash}->{$field};
 394   } else {
 395     '';
 396   }
 397 }
 398 sub getfield {
 399   my $self = shift;
 400   $self->get(@_);
 401 }
 402
 403 =item set, setfield COLUMN, VALUE
 404
 405 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 406
 407 =cut
 408
 409 sub set {
 410   my($self,$field,$value) = @_;
 411   $self->{'Hash'}->{$field} = $value;
 412 }
 413 sub setfield {
 414   my $self = shift;
 415   $self->set(@_);
 416 }
 417
 418 =item AUTLOADED METHODS
 419
 420 $record->column is a synonym for $record->get('column');
 421
 422 $record->column('value') is a synonym for $record->set('column','value');
 423
 424 =cut
 425
 426 # readable/safe
 427 sub AUTOLOAD {
 428   my($self,$value)=@_;
 429   my($field)=$AUTOLOAD;
 430   $field =~ s/.*://;
 431   if ( defined($value) ) {
 432     confess "errant AUTOLOAD $field for $self (arg $value)"
 433       unless ref($self) && $self->can('setfield');
 434     $self->setfield($field,$value);
 435   } else {
 436     confess "errant AUTOLOAD $field for $self (no args)"
 437       unless ref($self) && $self->can('getfield');
 438     $self->getfield($field);
 439   }
 440 }
 441
 442 # efficient
 443 #sub AUTOLOAD {
 444 #  my $field = $AUTOLOAD;
 445 #  $field =~ s/.*://;
 446 #  if ( defined($_[1]) ) {
 447 #    $_[0]->setfield($field, $_[1]);
 448 #  } else {
 449 #    $_[0]->getfield($field);
 450 #  }
 451 #}
 452
 453 =item hash
 454
 455 Returns a list of the column/value pairs, usually for assigning to a new hash.
 456
 457 To make a distinct duplicate of an FS::Record object, you can do:
 458
 459     $new = new FS::Record ( $old->table, { $old->hash } );
 460
 461 =cut
 462
 463 sub hash {
 464   my($self) = @_;
 465   %{ $self->{'Hash'} };
 466 }
 467
 468 =item hashref
 469
 470 Returns a reference to the column/value hash.
 471
 472 =cut
 473
 474 sub hashref {
 475   my($self) = @_;
 476   $self->{'Hash'};
 477 }
 478
 479 =item insert
 480
 481 Inserts this record to the database.  If there is an error, returns the error,
 482 otherwise returns false.
 483
 484 =cut
 485
 486 sub insert {
 487   my $self = shift;
 488
 489   my $error = $self->check;
 490   return $error if $error;
 491
 492   #single-field unique keys are given a value if false
 493   #(like MySQL's AUTO_INCREMENT)
 494   foreach ( $self->dbdef_table->unique->singles ) {
 495     $self->unique($_) unless $self->getfield($_);
 496   }
 497   #and also the primary key
 498   my $primary_key = $self->dbdef_table->primary_key;
 499   $self->unique($primary_key)
 500     if $primary_key && ! $self->getfield($primary_key);
 501
 502   #false laziness w/delete
 503   my @fields =
 504     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 505     $self->fields
 506   ;
 507   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
 508   #eslaf
 509
 510   my $statement = "INSERT INTO ". $self->table. " ( ".
 511       join( ', ', @fields ).
 512     ") VALUES (".
 513       join( ', ', @values ).
 514     ")"
 515   ;
 516   warn "[debug]$me $statement\n" if $DEBUG > 1;
 517   my $sth = dbh->prepare($statement) or return dbh->errstr;
 518
 519   my $h_sth;
 520   if ( defined $dbdef->table('h_'. $self->table) ) {
 521     my $h_statement = $self->_h_statement('insert');
 522     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 523     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 524   } else {
 525     $h_sth = '';
 526   }
 527
 528   local $SIG{HUP} = 'IGNORE';
 529   local $SIG{INT} = 'IGNORE';
 530   local $SIG{QUIT} = 'IGNORE';
 531   local $SIG{TERM} = 'IGNORE';
 532   local $SIG{TSTP} = 'IGNORE';
 533   local $SIG{PIPE} = 'IGNORE';
 534
 535   $sth->execute or return $sth->errstr;
 536   $h_sth->execute or return $h_sth->errstr if $h_sth;
 537   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 538
 539   '';
 540 }
 541
 542 =item add
 543
 544 Depriciated (use insert instead).
 545
 546 =cut
 547
 548 sub add {
 549   cluck "warning: FS::Record::add depriciated!";
 550   insert @_; #call method in this scope
 551 }
 552
 553 =item delete
 554
 555 Delete this record from the database.  If there is an error, returns the error,
 556 otherwise returns false.
 557
 558 =cut
 559
 560 sub delete {
 561   my $self = shift;
 562
 563   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 564     map {
 565       $self->getfield($_) eq ''
 566         #? "( $_ IS NULL OR $_ = \"\" )"
 567         ? ( driver_name =~ /^Pg$/i
 568               ? "$_ IS NULL"
 569               : "( $_ IS NULL OR $_ = \"\" )"
 570           )
 571         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 572     } ( $self->dbdef_table->primary_key )
 573           ? ( $self->dbdef_table->primary_key)
 574           : $self->fields
 575   );
 576   warn "[debug]$me $statement\n" if $DEBUG > 1;
 577   my $sth = dbh->prepare($statement) or return dbh->errstr;
 578
 579   my $h_sth;
 580   if ( defined $dbdef->table('h_'. $self->table) ) {
 581     my $h_statement = $self->_h_statement('delete');
 582     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 583     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 584   } else {
 585     $h_sth = '';
 586   }
 587
 588   local $SIG{HUP} = 'IGNORE';
 589   local $SIG{INT} = 'IGNORE';
 590   local $SIG{QUIT} = 'IGNORE';
 591   local $SIG{TERM} = 'IGNORE';
 592   local $SIG{TSTP} = 'IGNORE';
 593   local $SIG{PIPE} = 'IGNORE';
 594
 595   my $rc = $sth->execute or return $sth->errstr;
 596   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 597   $h_sth->execute or return $h_sth->errstr if $h_sth;
 598   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 599
 600   #no need to needlessly destoy the data either (causes problems actually)
 601   #undef $self; #no need to keep object!
 602
 603   '';
 604 }
 605
 606 =item del
 607
 608 Depriciated (use delete instead).
 609
 610 =cut
 611
 612 sub del {
 613   cluck "warning: FS::Record::del depriciated!";
 614   &delete(@_); #call method in this scope
 615 }
 616
 617 =item replace OLD_RECORD
 618
 619 Replace the OLD_RECORD with this one in the database.  If there is an error,
 620 returns the error, otherwise returns false.
 621
 622 =cut
 623
 624 sub replace {
 625   my ( $new, $old ) = ( shift, shift );
 626   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
 627
 628   return "Records not in same table!" unless $new->table eq $old->table;
 629
 630   my $primary_key = $old->dbdef_table->primary_key;
 631   return "Can't change $primary_key"
 632     if $primary_key
 633        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 634
 635   my $error = $new->check;
 636   return $error if $error;
 637
 638   my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 639   unless ( @diff ) {
 640     carp "[warning]$me $new -> replace $old: records identical";
 641     return '';
 642   }
 643
 644   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 645     map {
 646       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 647     } @diff
 648   ). ' WHERE '.
 649     join(' AND ',
 650       map {
 651         $old->getfield($_) eq ''
 652           #? "( $_ IS NULL OR $_ = \"\" )"
 653           ? ( driver_name =~ /^Pg$/i
 654                 ? "$_ IS NULL"
 655                 : "( $_ IS NULL OR $_ = \"\" )"
 656             )
 657           : "$_ = ". _quote($old->getfield($_),$old->table,$_)
 658       } ( $primary_key ? ( $primary_key ) : $old->fields )
 659     )
 660   ;
 661   warn "[debug]$me $statement\n" if $DEBUG > 1;
 662   my $sth = dbh->prepare($statement) or return dbh->errstr;
 663
 664   my $h_old_sth;
 665   if ( defined $dbdef->table('h_'. $old->table) ) {
 666     my $h_old_statement = $old->_h_statement('replace_old');
 667     warn "[debug]$me $h_old_statement\n" if $DEBUG > 2;
 668     $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
 669   } else {
 670     $h_old_sth = '';
 671   }
 672
 673   my $h_new_sth;
 674   if ( defined $dbdef->table('h_'. $new->table) ) {
 675     my $h_new_statement = $new->_h_statement('replace_new');
 676     warn "[debug]$me $h_new_statement\n" if $DEBUG > 2;
 677     $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
 678   } else {
 679     $h_new_sth = '';
 680   }
 681
 682   local $SIG{HUP} = 'IGNORE';
 683   local $SIG{INT} = 'IGNORE';
 684   local $SIG{QUIT} = 'IGNORE';
 685   local $SIG{TERM} = 'IGNORE';
 686   local $SIG{TSTP} = 'IGNORE';
 687   local $SIG{PIPE} = 'IGNORE';
 688
 689   my $rc = $sth->execute or return $sth->errstr;
 690   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
 691   $h_old_sth->execute or return $h_old_sth->errstr if $h_old_sth;
 692   $h_new_sth->execute or return $h_new_sth->errstr if $h_new_sth;
 693   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 694
 695   '';
 696
 697 }
 698
 699 =item rep
 700
 701 Depriciated (use replace instead).
 702
 703 =cut
 704
 705 sub rep {
 706   cluck "warning: FS::Record::rep depriciated!";
 707   replace @_; #call method in this scope
 708 }
 709
 710 =item check
 711
 712 Not yet implemented, croaks.  Derived classes should provide a check method.
 713
 714 =cut
 715
 716 sub check {
 717   confess "FS::Record::check not implemented; supply one in subclass!";
 718 }
 719
 720 sub _h_statement {
 721   my( $self, $action ) = @_;
 722
 723   my @fields =
 724     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 725     $self->fields
 726   ;
 727   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
 728
 729   "INSERT INTO h_". $self->table. " ( ".
 730       join(', ', qw(history_date history_user history_action), @fields ).
 731     ") VALUES (".
 732       join(', ', time, dbh->quote(getotaker()), dbh->quote($action), @values).
 733     ")"
 734   ;
 735 }
 736
 737 =item unique COLUMN
 738
 739 Replaces COLUMN in record with a unique number.  Called by the B<add> method
 740 on primary keys and single-field unique columns (see L<DBIx::DBSchema::Table>).
 741 Returns the new value.
 742
 743 =cut
 744
 745 sub unique {
 746   my($self,$field) = @_;
 747   my($table)=$self->table;
 748
 749   #croak("&FS::UID::checkruid failed") unless &checkruid;
 750
 751   croak "Unique called on field $field, but it is ",
 752         $self->getfield($field),
 753         ", not null!"
 754     if $self->getfield($field);
 755
 756   #warn "table $table is tainted" if is_tainted($table);
 757   #warn "field $field is tainted" if is_tainted($field);
 758
 759   my($counter) = new File::CounterFile "$table.$field",0;
 760 # hack for web demo
 761 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
 762 #  my($user)=$1;
 763 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
 764 # endhack
 765
 766   my($index)=$counter->inc;
 767   $index=$counter->inc
 768     while qsearchs($table,{$field=>$index}); #just in case
 769
 770   $index =~ /^(\d*)$/;
 771   $index=$1;
 772
 773   $self->setfield($field,$index);
 774
 775 }
 776
 777 =item ut_float COLUMN
 778
 779 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
 780 null.  If there is an error, returns the error, otherwise returns false.
 781
 782 =cut
 783
 784 sub ut_float {
 785   my($self,$field)=@_ ;
 786   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
 787    $self->getfield($field) =~ /^(\d+)$/ ||
 788    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
 789    $self->getfield($field) =~ /^(\d+e\d+)$/)
 790     or return "Illegal or empty (float) $field: ". $self->getfield($field);
 791   $self->setfield($field,$1);
 792   '';
 793 }
 794
 795 =item ut_number COLUMN
 796
 797 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
 798 is an error, returns the error, otherwise returns false.
 799
 800 =cut
 801
 802 sub ut_number {
 803   my($self,$field)=@_;
 804   $self->getfield($field) =~ /^(\d+)$/
 805     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
 806   $self->setfield($field,$1);
 807   '';
 808 }
 809
 810 =item ut_numbern COLUMN
 811
 812 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
 813 an error, returns the error, otherwise returns false.
 814
 815 =cut
 816
 817 sub ut_numbern {
 818   my($self,$field)=@_;
 819   $self->getfield($field) =~ /^(\d*)$/
 820     or return "Illegal (numeric) $field: ". $self->getfield($field);
 821   $self->setfield($field,$1);
 822   '';
 823 }
 824
 825 =item ut_money COLUMN
 826
 827 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
 828 is an error, returns the error, otherwise returns false.
 829
 830 =cut
 831
 832 sub ut_money {
 833   my($self,$field)=@_;
 834   $self->setfield($field, 0) if $self->getfield($field) eq '';
 835   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
 836     or return "Illegal (money) $field: ". $self->getfield($field);
 837   #$self->setfield($field, "$1$2$3" || 0);
 838   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
 839   '';
 840 }
 841
 842 =item ut_text COLUMN
 843
 844 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 845 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / =
 846 May not be null.  If there is an error, returns the error, otherwise returns
 847 false.
 848
 849 =cut
 850
 851 sub ut_text {
 852   my($self,$field)=@_;
 853   #warn "msgcat ". \&msgcat. "\n";
 854   #warn "notexist ". \&notexist. "\n";
 855   #warn "AUTOLOAD ". \&AUTOLOAD. "\n";
 856   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]+)$/
 857     or return gettext('illegal_or_empty_text'). " $field: ".
 858                $self->getfield($field);
 859   $self->setfield($field,$1);
 860   '';
 861 }
 862
 863 =item ut_textn COLUMN
 864
 865 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 866 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 867 May be null.  If there is an error, returns the error, otherwise returns false.
 868
 869 =cut
 870
 871 sub ut_textn {
 872   my($self,$field)=@_;
 873   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 874     or return gettext('illegal_text'). " $field: ". $self->getfield($field);
 875   $self->setfield($field,$1);
 876   '';
 877 }
 878
 879 =item ut_alpha COLUMN
 880
 881 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
 882 an error, returns the error, otherwise returns false.
 883
 884 =cut
 885
 886 sub ut_alpha {
 887   my($self,$field)=@_;
 888   $self->getfield($field) =~ /^(\w+)$/
 889     or return "Illegal or empty (alphanumeric) $field: ".
 890               $self->getfield($field);
 891   $self->setfield($field,$1);
 892   '';
 893 }
 894
 895 =item ut_alpha COLUMN
 896
 897 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
 898 error, returns the error, otherwise returns false.
 899
 900 =cut
 901
 902 sub ut_alphan {
 903   my($self,$field)=@_;
 904   $self->getfield($field) =~ /^(\w*)$/
 905     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
 906   $self->setfield($field,$1);
 907   '';
 908 }
 909
 910 =item ut_phonen COLUMN [ COUNTRY ]
 911
 912 Check/untaint phone numbers.  May be null.  If there is an error, returns
 913 the error, otherwise returns false.
 914
 915 Takes an optional two-letter ISO country code; without it or with unsupported
 916 countries, ut_phonen simply calls ut_alphan.
 917
 918 =cut
 919
 920 sub ut_phonen {
 921   my( $self, $field, $country ) = @_;
 922   return $self->ut_alphan($field) unless defined $country;
 923   my $phonen = $self->getfield($field);
 924   if ( $phonen eq '' ) {
 925     $self->setfield($field,'');
 926   } elsif ( $country eq 'US' || $country eq 'CA' ) {
 927     $phonen =~ s/\D//g;
 928     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
 929       or return gettext('illegal_phone'). " $field: ". $self->getfield($field);
 930     $phonen = "$1-$2-$3";
 931     $phonen .= " x$4" if $4;
 932     $self->setfield($field,$phonen);
 933   } else {
 934     warn "warning: don't know how to check phone numbers for country $country";
 935     return $self->ut_textn($field);
 936   }
 937   '';
 938 }
 939
 940 =item ut_ip COLUMN
 941
 942 Check/untaint ip addresses.  IPv4 only for now.
 943
 944 =cut
 945
 946 sub ut_ip {
 947   my( $self, $field ) = @_;
 948   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
 949     or return "Illegal (IP address) $field: ". $self->getfield($field);
 950   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
 951   $self->setfield($field, "$1.$2.$3.$4");
 952   '';
 953 }
 954
 955 =item ut_ipn COLUMN
 956
 957 Check/untaint ip addresses.  IPv4 only for now.  May be null.
 958
 959 =cut
 960
 961 sub ut_ipn {
 962   my( $self, $field ) = @_;
 963   if ( $self->getfield($field) =~ /^()$/ ) {
 964     $self->setfield($field,'');
 965     '';
 966   } else {
 967     $self->ut_ip($field);
 968   }
 969 }
 970
 971 =item ut_domain COLUMN
 972
 973 Check/untaint host and domain names.
 974
 975 =cut
 976
 977 sub ut_domain {
 978   my( $self, $field ) = @_;
 979   #$self->getfield($field) =~/^(\w+\.)*\w+$/
 980   $self->getfield($field) =~/^(([\w\-]+\.)*\w+)$/
 981     or return "Illegal (domain) $field: ". $self->getfield($field);
 982   $self->setfield($field,$1);
 983   '';
 984 }
 985
 986 =item ut_name COLUMN
 987
 988 Check/untaint proper names; allows alphanumerics, spaces and the following
 989 punctuation: , . - '
 990
 991 May not be null.
 992
 993 =cut
 994
 995 sub ut_name {
 996   my( $self, $field ) = @_;
 997   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
 998     or return gettext('illegal_name'). " $field: ". $self->getfield($field);
 999   $self->setfield($field,$1);
1000   '';
1001 }
1002
1003 =item ut_zip COLUMN
1004
1005 Check/untaint zip codes.
1006
1007 =cut
1008
1009 sub ut_zip {
1010   my( $self, $field, $country ) = @_;
1011   if ( $country eq 'US' ) {
1012     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
1013       or return gettext('illegal_zip'). " $field for country $country: ".
1014                 $self->getfield($field);
1015     $self->setfield($field,$1);
1016   } else {
1017     $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
1018       or return gettext('illegal_zip'). " $field: ". $self->getfield($field);
1019     $self->setfield($field,$1);
1020   }
1021   '';
1022 }
1023
1024 =item ut_country COLUMN
1025
1026 Check/untaint country codes.  Country names are changed to codes, if possible -
1027 see L<Locale::Country>.
1028
1029 =cut
1030
1031 sub ut_country {
1032   my( $self, $field ) = @_;
1033   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
1034     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
1035          && country2code($1) ) {
1036       $self->setfield($field,uc(country2code($1)));
1037     }
1038   }
1039   $self->getfield($field) =~ /^(\w\w)$/
1040     or return "Illegal (country) $field: ". $self->getfield($field);
1041   $self->setfield($field,uc($1));
1042   '';
1043 }
1044
1045 =item ut_anything COLUMN
1046
1047 Untaints arbitrary data.  Be careful.
1048
1049 =cut
1050
1051 sub ut_anything {
1052   my( $self, $field ) = @_;
1053   $self->getfield($field) =~ /^(.*)$/s
1054     or return "Illegal $field: ". $self->getfield($field);
1055   $self->setfield($field,$1);
1056   '';
1057 }
1058
1059 =item ut_enum COLUMN CHOICES_ARRAYREF
1060
1061 Check/untaint a column, supplying all possible choices, like the "enum" type.
1062
1063 =cut
1064
1065 sub ut_enum {
1066   my( $self, $field, $choices ) = @_;
1067   foreach my $choice ( @$choices ) {
1068     if ( $self->getfield($field) eq $choice ) {
1069       $self->setfield($choice);
1070       return '';
1071     }
1072   }
1073   return "Illegal (enum) field $field: ". $self->getfield($field);
1074 }
1075
1076 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1077
1078 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
1079 on the column first.
1080
1081 =cut
1082
1083 sub ut_foreign_key {
1084   my( $self, $field, $table, $foreign ) = @_;
1085   qsearchs($table, { $foreign => $self->getfield($field) })
1086     or return "Can't find $field ". $self->getfield($field).
1087               " in $table.$foreign";
1088   '';
1089 }
1090
1091 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1092
1093 Like ut_foreign_key, except the null value is also allowed.
1094
1095 =cut
1096
1097 sub ut_foreign_keyn {
1098   my( $self, $field, $table, $foreign ) = @_;
1099   $self->getfield($field)
1100     ? $self->ut_foreign_key($field, $table, $foreign)
1101     : '';
1102 }
1103
1104 =item fields [ TABLE ]
1105
1106 This can be used as both a subroutine and a method call.  It returns a list
1107 of the columns in this record's table, or an explicitly specified table.
1108 (See L<DBIx::DBSchema::Table>).
1109
1110 =cut
1111
1112 # Usage: @fields = fields($table);
1113 #        @fields = $record->fields;
1114 sub fields {
1115   my $something = shift;
1116   my $table;
1117   if ( ref($something) ) {
1118     $table = $something->table;
1119   } else {
1120     $table = $something;
1121   }
1122   #croak "Usage: \@fields = fields(\$table)\n   or: \@fields = \$record->fields" unless $table;
1123   my($table_obj) = $dbdef->table($table);
1124   confess "Unknown table $table" unless $table_obj;
1125   $table_obj->columns;
1126 }
1127
1128 =back
1129
1130 =head1 SUBROUTINES
1131
1132 =over 4
1133
1134 =item reload_dbdef([FILENAME])
1135
1136 Load a database definition (see L<DBIx::DBSchema>), optionally from a
1137 non-default filename.  This command is executed at startup unless
1138 I<$FS::Record::setup_hack> is true.  Returns a DBIx::DBSchema object.
1139
1140 =cut
1141
1142 sub reload_dbdef {
1143   my $file = shift || $dbdef_file;
1144
1145   unless ( exists $dbdef_cache{$file} ) {
1146     warn "[debug]$me loading dbdef for $file\n" if $DEBUG;
1147     $dbdef_cache{$file} = DBIx::DBSchema->load( $file )
1148                             or die "can't load database schema from $file";
1149   } else {
1150     warn "[debug]$me re-using cached dbdef for $file\n" if $DEBUG;
1151   }
1152   $dbdef = $dbdef_cache{$file};
1153 }
1154
1155 =item dbdef
1156
1157 Returns the current database definition.  See L<DBIx::DBSchema>.
1158
1159 =cut
1160
1161 sub dbdef { $dbdef; }
1162
1163 =item _quote VALUE, TABLE, COLUMN
1164
1165 This is an internal function used to construct SQL statements.  It returns
1166 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
1167 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
1168
1169 =cut
1170
1171 sub _quote {
1172   my($value, $table, $column) = @_;
1173   my $column_obj = $dbdef->table($table)->column($column);
1174   my $column_type = $column_obj->type;
1175
1176   if ( $value eq '' && $column_type =~ /^int/ ) {
1177     if ( $column_obj->null ) {
1178       'NULL';
1179     } else {
1180       cluck "WARNING: Attempting to set non-null integer $table.$column null; ".
1181             "using 0 instead";
1182       0;
1183     }
1184   } elsif ( $value =~ /^\d+(\.\d+)?$/ &&
1185             ! $column_type =~ /(char|binary|text)$/i ) {
1186     $value;
1187   } else {
1188     dbh->quote($value);
1189   }
1190 }
1191
1192 =item hfields TABLE
1193
1194 This is depriciated.  Don't use it.
1195
1196 It returns a hash-type list with the fields of this record's table set true.
1197
1198 =cut
1199
1200 sub hfields {
1201   carp "warning: hfields is depriciated";
1202   my($table)=@_;
1203   my(%hash);
1204   foreach (fields($table)) {
1205     $hash{$_}=1;
1206   }
1207   \%hash;
1208 }
1209
1210 sub _dump {
1211   my($self)=@_;
1212   join("\n", map {
1213     "$_: ". $self->getfield($_). "|"
1214   } (fields($self->table)) );
1215 }
1216
1217 sub DESTROY { return; }
1218
1219 #sub DESTROY {
1220 #  my $self = shift;
1221 #  #use Carp qw(cluck);
1222 #  #cluck "DESTROYING $self";
1223 #  warn "DESTROYING $self";
1224 #}
1225
1226 #sub is_tainted {
1227 #             return ! eval { join('',@_), kill 0; 1; };
1228 #         }
1229
1230 =back
1231
1232 =head1 BUGS
1233
1234 This module should probably be renamed, since much of the functionality is
1235 of general use.  It is not completely unlike Adapter::DBI (see below).
1236
1237 Exported qsearch and qsearchs should be depriciated in favor of method calls
1238 (against an FS::Record object like the old search and searchs that qsearch
1239 and qsearchs were on top of.)
1240
1241 The whole fields / hfields mess should be removed.
1242
1243 The various WHERE clauses should be subroutined.
1244
1245 table string should be depriciated in favor of DBIx::DBSchema::Table.
1246
1247 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1248 true maps to the database (and WHERE clauses) would also help.
1249
1250 The ut_ methods should ask the dbdef for a default length.
1251
1252 ut_sqltype (like ut_varchar) should all be defined
1253
1254 A fallback check method should be provided which uses the dbdef.
1255
1256 The ut_money method assumes money has two decimal digits.
1257
1258 The Pg money kludge in the new method only strips `$'.
1259
1260 The ut_phonen method only checks US-style phone numbers.
1261
1262 The _quote function should probably use ut_float instead of a regex.
1263
1264 All the subroutines probably should be methods, here or elsewhere.
1265
1266 Probably should borrow/use some dbdef methods where appropriate (like sub
1267 fields)
1268
1269 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1270 or allow it to be set.  Working around it is ugly any way around - DBI should
1271 be fixed.  (only affects RDBMS which return uppercase column names)
1272
1273 ut_zip should take an optional country like ut_phone.
1274
1275 =head1 SEE ALSO
1276
1277 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1278
1279 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1280
1281 =cut
1282
1283 1;
1284