path: root/httemplate/search/cust_bill_pkg.cgi

<& elements/search.html,
                 'title'       => emt('Line items'),
                 'name'        => emt('line items'),
                 'query'       => $query,
                 'count_query' => $count_query,
                 'count_addl'  => [ $money_char. '%.2f total',
                                    $unearned ? ( $money_char. '%.2f unearned revenue' ) : (),
                                  ],
                 'header'      => [
                   @pkgnum_header,
                   emt('Pkg Def'),
                   emt('Description'),
                   @post_desc_header,
                   ( $unearned
                     ? ( emt('Unearned'), 
                         emt('Owed'), # useful in 'paid' mode?
                         emt('Payment date') )
                     : ( emt('Setup charge') )
                   ),
                   ( $use_usage eq 'usage'
                     ? emt('Usage charge')
                     : emt('Recurring charge')
                   ),
                   ( $unearned
                     ? ( emt('Charge start'), emt('Charge end') )
                     : ()
                   ),
                   emt('Invoice'),
                   emt('Date'),
                   emt('Paid'),
                   emt('Credited'),
                   FS::UI::Web::cust_header(),
                 ],
                 'fields'      => [
                   @pkgnum,
                   sub { $_[0]->pkgnum > 0
                           # possibly use override.pkg but i think this correct
                           ? $_[0]->get('pkgpart')
                           : ''
                       },
                   sub { $_[0]->pkgnum > 0
                           # possibly use override.pkg but i think this correct
                           ? $_[0]->get('pkg')     
                           : $_[0]->get('itemdesc')
                       },
                   @post_desc,
                   #strikethrough or "N/A ($amount)" or something these when
                   # they're not applicable to pkg_tax search
                   sub { my $cust_bill_pkg = shift;
                         if ( $unearned ) {

                           sprintf($money_char.'%.2f', 
                             $cust_bill_pkg->unearned_revenue)

                         } else {
                           sprintf($money_char.'%.2f', $cust_bill_pkg->setup );
                         }
                       },
                   ( $unearned
                     ? ( $owed_sub, $payment_date_sub, )
                     : ()
                   ),
                   sub { my $row = shift;
                         my $value = 0;
                         if ( $use_usage eq 'recurring' or $unearned ) {
                           $value = $row->recur - $row->usage;
                         } elsif ( $use_usage eq 'usage' ) {
                           $value = $row->usage;
                         } else {
                           $value = $row->recur;
                         }
                         sprintf($money_char.'%.2f', $value );
                       },
                   ( $unearned
                     ? ( sub { time2str('%b %d %Y', shift->sdate ) },
                       # shift edate back a day
                       # 82799 = 3600*23 - 1
                       # (to avoid skipping a day during DST)
                         sub { time2str('%b %d %Y', shift->edate - 82799 ) },
                       )
                     : ()
                   ),
                   'invnum',
                   sub { time2str('%b %d %Y', shift->_date ) },
                   sub { sprintf($money_char.'%.2f', shift->get('pay_amount')) },
                   sub { sprintf($money_char.'%.2f', shift->get('credit_amount')) },
                   \&FS::UI::Web::cust_fields,
                 ],
                 'sort_fields' => [
                   @pkgnum_null,
                   '',
                   '',
                   @post_desc_null,
                   'setup', #broken in $unearned case i guess
                   ( $unearned ? ('', '') : () ),
                   ( $use_usage eq 'recurring' or $unearned
                        ? 'recur - usage' :
                     $use_usage eq 'usage' 
                        ? 'usage'
                        : 'recur'
                   ),
                   ( $unearned ? ('sdate', 'edate') : () ),
                   'invnum',
                   '_date',
                   #'pay_amount',
                   #'credit_amount',
                 ],
                 'links'       => [
                   @pkgnum_null,
                   '',
                   '',
                   @post_desc_null,
                   '',
                   ( $unearned ? ( '', '' ) : () ),
                   '',
                   ( $unearned ? ( '', '' ) : () ),
                   $ilink,
                   $ilink,
                   $pay_link,
                   $credit_link,
                   ( map { $_ ne 'Cust. Status' ? $clink : '' }
                         FS::UI::Web::cust_header()
                   ),
                 ],
                 #'align' => 'rlrrrc'.FS::UI::Web::cust_aligns(),
                 'align' => $pkgnum_align.
                            'rl'.
                            $post_desc_align.
                            'r'.
                            ( $unearned ? 'rc' : '' ).
                            'r'.
                            ( $unearned ? 'cc' : '' ).
                            'rcrr'.
                            FS::UI::Web::cust_aligns(),
                 'color' => [ 
                              @pkgnum_null,
                              '',
                              '',
                              @post_desc_null,
                              '',
                              ( $unearned ? ( '', '' ) : () ),
                              '',
                              ( $unearned ? ( '', '' ) : () ),
                              '',
                              '',
                              '',
                              '',
                              FS::UI::Web::cust_colors(),
                            ],
                 'style' => [ 
                              @pkgnum_null,
                              '',
                              '',
                              @post_desc_null,
                              '',
                              ( $unearned ? ( '', '' ) : () ),
                              '',
                              ( $unearned ? ( '', '' ) : () ),
                              '',
                              '',
                              '',
                              '',
                              FS::UI::Web::cust_styles(),
                            ],
&>
<%init>

#LOTS of false laziness below w/cust_credit_bill_pkg.cgi

my $curuser = $FS::CurrentUser::CurrentUser;

die "access denied" unless $curuser->access_right('Financial reports');

my $conf = new FS::Conf;

my $unearned = '';
my $unearned_mode = '';
my $unearned_base = '';
my $unearned_sql = '';

my @select = ( 'cust_bill_pkg.*', 'cust_bill._date' );

my @pkgnum_header = ();
my @pkgnum = ();
my @pkgnum_null;
my $pkgnum_align = '';
if ( $curuser->option('show_pkgnum') ) {
  push @select, 'cust_bill_pkg.pkgnum';
  push @pkgnum_header, 'Pkg Num';
  push @pkgnum, sub { $_[0]->pkgnum > 0 ? $_[0]->pkgnum : '' };
  push @pkgnum_null, '';
  $pkgnum_align .= 'r';
}

my @post_desc_header = ();
my @post_desc = ();
my @post_desc_null = ();
my $post_desc_align = '';
if ( $conf->exists('enable_taxclasses') ) {
  push @post_desc_header, 'Tax class';
  push @post_desc, 'taxclass';
  push @post_desc_null, '';
  $post_desc_align .= 'l';
  push @select, 'part_pkg.taxclass'; # or should this use override?
}

#here is the agent virtualization
my $agentnums_sql =
  $FS::CurrentUser::CurrentUser->agentnums_sql( 'table' => 'cust_main' );

my @where = ( $agentnums_sql );

my($beginning, $ending) = FS::UI::Web::parse_beginning_ending($cgi);

if ( $cgi->param('status') =~ /^([a-z]+)$/ ) {
  push @where, FS::cust_main->cust_status_sql . " = '$1'";
}

if ( $cgi->param('distribute') == 1 ) {
  push @where, "sdate <= $ending",
               "edate >  $beginning",
  ;
}
else {
  push @where, "cust_bill._date >= $beginning",
               "cust_bill._date <= $ending";
}

if ( $cgi->param('agentnum') =~ /^(\d+)$/ ) {
  push @where, "cust_main.agentnum = $1";
}

if ( $cgi->param('refnum') =~ /^(\d+)$/ ) {
  push @where, "cust_main.refnum = $1";
}

# cust_classnum (false laziness w/ elements/cust_main_dayranges.html, elements/cust_pay_or_refund.html, prepaid_income.html, cust_bill_pay.html, cust_bill_pkg_referral.html, unearned_detail.html, cust_credit.html, cust_credit_refund.html, cust_main::Search::search_sql)
if ( grep { $_ eq 'cust_classnum' } $cgi->param ) {
  my @classnums = grep /^\d*$/, $cgi->param('cust_classnum');
  push @where, 'COALESCE( cust_main.classnum, 0) IN ( '.
                   join(',', map { $_ || '0' } @classnums ).
               ' )'
    if @classnums;
}


# custnum
if ( $cgi->param('custnum') =~ /^(\d+)$/ ) {
  push @where, "cust_main.custnum = $1";
}

#classnum
# not specified: all classes
# 0: empty class
# N: classnum
my $use_override = $cgi->param('use_override');
if ( $cgi->param('classnum') =~ /^(\d+)$/ ) {
  my $comparison = '';
  if ( $1 == 0 ) {
    $comparison = "IS NULL";
  } else {
    $comparison = "= $1";
  }

  if ( $use_override ) {
    push @where, "(
      part_pkg.classnum $comparison AND pkgpart_override IS NULL OR
      override.classnum $comparison AND pkgpart_override IS NOT NULL
    )";
  } else {
    push @where, "part_pkg.classnum $comparison";
  }
}

if ( $cgi->param('taxclass')
     && ! $cgi->param('istax')  #no part_pkg.taxclass in this case
                                #(should we save a taxclass or a link to taxnum
                                # in cust_bill_pkg or something like
                                # cust_bill_pkg_tax_location?)
   )
{

  #override taxclass when use_override is specified?  probably
  #if ( $use_override ) {
  #
  #  push @where,
  #    ' ( '. join(' OR ',
  #                  map {
  #                        ' (    part_pkg.taxclass = '. dbh->quote($_).
  #                        '      AND pkgpart_override IS NULL '.
  #                        '   OR '.
  #                        '      override.taxclass = '. dbh->quote($_).
  #                        '      AND pkgpart_override IS NOT NULL '.
  #                        ' ) '
  #                      }
  #                      $cgi->param('taxclass')
  #               ).
  #    ' ) ';
  #
  #} else {

    push @where, ' part_pkg.taxclass IN ( '.
                   join(', ', map dbh->quote($_), $cgi->param('taxclass') ).
                 ' ) ';

  #}

}

my @loc_param = qw( district city county state country );

if ( $cgi->param('out') ) {

  my ( $loc_sql, @param ) = FS::cust_pkg->location_sql( 'ornull' => 1 );
  while ( $loc_sql =~ /\?/ ) { #easier to do our own substitution
    $loc_sql =~ s/\?/'cust_main_county.'.shift(@param)/e;
  }

  $loc_sql =~ s/cust_pkg\.locationnum/cust_bill_pkg_tax_location.locationnum/g
    if $cgi->param('istax');

  push @where, "
    0 = (
          SELECT COUNT(*) FROM cust_main_county
           WHERE cust_main_county.tax > 0
             AND $loc_sql
        )
  ";

  #not linked to by anything, but useful for debugging "out of taxable region"
  if ( grep $cgi->param($_), @loc_param ) {

    my %ph = map { $_ => dbh->quote( scalar($cgi->param($_)) ) } @loc_param;

    my ( $loc_sql, @param ) = FS::cust_pkg->location_sql;
    while ( $loc_sql =~ /\?/ ) { #easier to do our own substitution
      $loc_sql =~ s/\?/$ph{shift(@param)}/e;
    }

    push @where, $loc_sql;

  }

} elsif ( $cgi->param('country') ) {

  my @counties = $cgi->param('county');
   
  if ( scalar(@counties) > 1 ) {

    #hacky, could be more efficient.  care if it is ever used for more than the
    # tax-report_groups filtering kludge

    my $locs_sql =
      ' ( '. join(' OR ', map {

          my %ph = ( 'county' => dbh->quote($_),
                     map { $_ => dbh->quote( $cgi->param($_) ) }
                       qw( district city state country )
                   );

          my ( $loc_sql, @param ) = FS::cust_pkg->location_sql;
          while ( $loc_sql =~ /\?/ ) { #easier to do our own substitution
            $loc_sql =~ s/\?/$ph{shift(@param)}/e;
          }

          $loc_sql;

        } @counties

      ). ' ) ';

    push @where, $locs_sql;

  } else {

    my %ph = map { $_ => dbh->quote( scalar($cgi->param($_)) ) } @loc_param;

    my ( $loc_sql, @param ) = FS::cust_pkg->location_sql;
    while ( $loc_sql =~ /\?/ ) { #easier to do our own substitution
      $loc_sql =~ s/\?/$ph{shift(@param)}/e;
    }

    push @where, $loc_sql;

  }
   
  if ( $cgi->param('istax') ) {
    if ( $cgi->param('taxname') ) {
      push @where, 'itemdesc = '. dbh->quote( $cgi->param('taxname') );
    #} elsif ( $cgi->param('taxnameNULL') {
    } else {
      push @where, "( itemdesc IS NULL OR itemdesc = '' OR itemdesc = 'Tax' )";
    }
  } elsif ( $cgi->param('nottax') ) {
    #what can we usefully do with "taxname" ????  look up a class???
  } else {
    #warn "neither nottax nor istax parameters specified";
  }

  if ( $cgi->param('taxclassNULL')
       && ! $cgi->param('istax')  #no part_pkg.taxclass in this case
                                  #(see comment above?)
     )
  {
    my %hash = ( 'country' => scalar($cgi->param('country')) );
    foreach (qw( state county )) {
      $hash{$_} = scalar($cgi->param($_)) if $cgi->param($_);
    }
    my $cust_main_county = qsearchs('cust_main_county', \%hash);
    die "unknown base region for empty taxclass" unless $cust_main_county;

    my $same_sql = $cust_main_county->sql_taxclass_sameregion;
    $same_sql =~ s/taxclass/part_pkg.taxclass/g;
    push @where, $same_sql if $same_sql;

  }

} elsif ( scalar( grep( /locationtaxid/, $cgi->param ) ) ) {

  push @where, FS::tax_rate_location->location_sql(
                 map { $_ => (scalar($cgi->param($_)) || '') }
                   qw( district city county state locationtaxid )
               );

}

# unearned revenue mode
if ( $cgi->param('unearned_now') =~ /^(\d+)$/ ) {

  $unearned = $1;
  $unearned_mode = $cgi->param('mode');

  push @where, "cust_bill_pkg.sdate < $unearned",
               "cust_bill_pkg.edate > $unearned",
               "cust_bill_pkg.recur != 0",
               "part_pkg.freq != '0'";

  if ( !$cgi->param('include_monthly') ) {
    push @where,
               "part_pkg.freq != '1'",
               "part_pkg.freq NOT LIKE '%h'",
               "part_pkg.freq NOT LIKE '%d'",
               "part_pkg.freq NOT LIKE '%w'";
  }

  my $usage_sql = FS::cust_bill_pkg->usage_sql;
  push @select, "($usage_sql) AS usage"; # we need this
  my $paid_sql = 'GREATEST(' .
    FS::cust_bill_pkg->paid_sql($unearned, '', setuprecur => 'recur') .
    " - $usage_sql, 0)";

  push @select, "$paid_sql AS paid_no_usage"; # need this either way

  if ( $unearned_mode eq 'paid' ) {
    # then use the amount paid, minus usage charges
    $unearned_base = $paid_sql;
  }
  else {
    # use the amount billed, minus usage charges and credits
    $unearned_base = "GREATEST( cust_bill_pkg.recur - ".
      FS::cust_bill_pkg->credited_sql($unearned, '', setuprecur => 'recur') .
      " - $usage_sql, 0)";
      # include only rows that have some non-usage, non-credited portion
  }
  # whatever we're using as the base, only show rows where it's positive
  push @where, "$unearned_base > 0";

  my $period = "CAST(cust_bill_pkg.edate - cust_bill_pkg.sdate AS REAL)";
  my $elapsed = "GREATEST( $unearned - cust_bill_pkg.sdate, 0 )";
  my $remaining = "(1 - $elapsed/$period)";

  $unearned_sql = "CAST( $unearned_base * $remaining AS DECIMAL(10,2) )";
  push @select, "$unearned_sql AS unearned_revenue";

  # last payment/credit date
  my %t = (pay => 'cust_bill_pay', credit => 'cust_credit_bill');
  foreach my $x (qw(pay credit)) {
    my $table = $t{$x};
    my $link = $table.'_pkg';
    my $pkey = dbdef->table($table)->primary_key;
    my $last_date_sql = "SELECT MAX(_date) 
    FROM $table JOIN $link USING ($pkey)
    WHERE $link.billpkgnum = cust_bill_pkg.billpkgnum 
    AND $table._date <= $unearned";
    push @select, "($last_date_sql) AS last_$x";
  }

}

if ( $cgi->param('itemdesc') ) {
  if ( $cgi->param('itemdesc') eq 'Tax' ) {
    push @where, "(itemdesc='Tax' OR itemdesc is null)";
  } else {
    push @where, 'itemdesc='. dbh->quote($cgi->param('itemdesc'));
  }
}

if ( $cgi->param('report_group') =~ /^(=|!=) (.*)$/ && $cgi->param('istax') ) {
  my ( $group_op, $group_value ) = ( $1, $2 );
  if ( $group_op eq '=' ) {
    #push @where, 'itemdesc LIKE '. dbh->quote($group_value.'%');
    push @where, 'itemdesc = '. dbh->quote($group_value);
  } elsif ( $group_op eq '!=' ) {
    push @where, '( itemdesc != '. dbh->quote($group_value) .' OR itemdesc IS NULL )';
  } else {
    die "guru meditation #00de: group_op $group_op\n";
  }
  
}

push @where, 'cust_bill_pkg.pkgnum != 0' if $cgi->param('nottax');
push @where, 'cust_bill_pkg.pkgnum  = 0' if $cgi->param('istax');

if ( $cgi->param('cust_tax') ) {
  #false laziness -ish w/report_tax.cgi
  my $cust_exempt;
  if ( $cgi->param('taxname') ) {
    my $q_taxname = dbh->quote($cgi->param('taxname'));
    $cust_exempt =
      "( tax = 'Y'
         OR EXISTS ( SELECT 1 FROM cust_main_exemption
                       WHERE cust_main_exemption.custnum = cust_main.custnum
                         AND cust_main_exemption.taxname = $q_taxname )
       )
      ";
  } else {
    $cust_exempt = " tax = 'Y' ";
  }

  push @where, $cust_exempt;
}

my $use_usage = $cgi->param('use_usage');

my $count_query;
if ( $cgi->param('pkg_tax') ) {

  $count_query =
    "SELECT COUNT(*),
            SUM(
                 ( CASE WHEN part_pkg.setuptax = 'Y'
                        THEN cust_bill_pkg.setup
                        ELSE 0
                   END
                 )
                 +
                 ( CASE WHEN part_pkg.recurtax = 'Y'
                        THEN cust_bill_pkg.recur
                        ELSE 0
                   END
                 )
               )
    ";

  push @where, "(    ( part_pkg.setuptax = 'Y' AND cust_bill_pkg.setup > 0 )
                  OR ( part_pkg.recurtax = 'Y' AND cust_bill_pkg.recur > 0 ) )",
               "( tax != 'Y' OR tax IS NULL )";

} elsif ( $cgi->param('taxable') ) {

  my $setup_taxable = "(
    CASE WHEN part_pkg.setuptax = 'Y'
         THEN 0
         ELSE cust_bill_pkg.setup
    END
  )";

  my $recur_taxable = "(
    CASE WHEN part_pkg.recurtax = 'Y'
         THEN 0
         ELSE cust_bill_pkg.recur
    END
  )";

  my $exempt = "(
    SELECT COALESCE( SUM(amount), 0 ) FROM cust_tax_exempt_pkg
      WHERE cust_tax_exempt_pkg.billpkgnum = cust_bill_pkg.billpkgnum
  )";

  $count_query =
    "SELECT COUNT(*), SUM( $setup_taxable + $recur_taxable - $exempt )";

  push @where,
    #not tax-exempt package (setup or recur)
    "(
          ( ( part_pkg.setuptax != 'Y' OR part_pkg.setuptax IS NULL )
            AND cust_bill_pkg.setup > 0 )
       OR
          ( ( part_pkg.recurtax != 'Y' OR part_pkg.recurtax IS NULL )
            AND cust_bill_pkg.recur > 0 )
    )",
    #not a tax_exempt customer
    "( tax != 'Y' OR tax IS NULL )";
    #not covered in full by a monthly tax exemption (texas tax)
    "0 < ( $setup_taxable + $recur_taxable - $exempt )",

} else {

  if ( $use_usage ) {
    $count_query = "SELECT COUNT(*), ";
  } else {
    $count_query = "SELECT COUNT(DISTINCT billpkgnum), ";
  }

  if ( $unearned ) {
    $count_query .= "SUM( $unearned_base ), SUM( $unearned_sql )";
  } elsif ( $use_usage eq 'recurring' ) {
    $count_query .= "SUM(cust_bill_pkg.setup + cust_bill_pkg.recur - usage)";
  } elsif ( $use_usage eq 'usage' ) {
    $count_query .= "SUM(usage)";
  } elsif ( scalar( grep( /locationtaxid/, $cgi->param ) ) ) {
    $count_query .= "SUM( COALESCE(cust_bill_pkg_tax_rate_location.amount, cust_bill_pkg.setup + cust_bill_pkg.recur))";
  } elsif ( $cgi->param('iscredit') eq 'rate') {
    $count_query .= "SUM( cust_credit_bill_pkg.amount )";
  } else {
    $count_query .= "SUM(cust_bill_pkg.setup + cust_bill_pkg.recur)";
  }

}

my $join_cust =  '        JOIN cust_bill USING ( invnum )
                     LEFT JOIN cust_main USING ( custnum ) ';

# we want the package and its definition if available
my $join_pkg = 
' LEFT JOIN cust_pkg      USING (pkgnum) 
  LEFT JOIN part_pkg      USING (pkgpart)';

my $part_pkg = 'part_pkg';
if ( $cgi->param('use_override') ) { #"Separate sub-packages from parents"
  # still need the real part_pkg for tax applicability, 
  # so alias this one
  $join_pkg .= " LEFT JOIN part_pkg AS override ON (
  COALESCE(cust_bill_pkg.pkgpart_override, cust_pkg.pkgpart, 0) = override.pkgpart
  )";
  $part_pkg = 'override';
}

if ( $cgi->param('nottax') ) {

  $join_pkg .= ' LEFT JOIN cust_location USING ( locationnum ) '
    if $conf->exists('tax-pkg_address');

} elsif ( $cgi->param('istax') ) {

  #false laziness w/report_tax.cgi $taxfromwhere
  if ( scalar( grep( /locationtaxid/, $cgi->param ) ) ||
            $cgi->param('iscredit') eq 'rate') {

    $join_pkg .=
      ' LEFT JOIN cust_bill_pkg_tax_rate_location USING ( billpkgnum ) '.
      ' LEFT JOIN tax_rate_location USING ( taxratelocationnum ) ';

  } elsif ( $conf->exists('tax-pkg_address') ) {

    $join_pkg .= '
      LEFT JOIN cust_bill_pkg_tax_location USING ( billpkgnum )
      LEFT JOIN cust_location ON cust_bill_pkg_tax_location.locationnum
                                 = cust_location.locationnum
    ';

    #quelle kludge, somewhat false laziness w/report_tax.cgi
    s/cust_pkg\.locationnum/cust_bill_pkg_tax_location.locationnum/g for @where;
  }

  if ( $cgi->param('iscredit') ) {
    $join_pkg .= ' JOIN cust_credit_bill_pkg USING ( billpkgnum';
    if ( $cgi->param('iscredit') eq 'rate' ) {
      $join_pkg .= ', billpkgtaxratelocationnum )';
    } elsif ( $conf->exists('tax-pkg_address') ) {
      $join_pkg .= ', billpkgtaxlocationnum )';
      push @where, "billpkgtaxratelocationnum IS NULL";
    } else {
      $join_pkg .= ' )';
      push @where, "billpkgtaxratelocationnum IS NULL";
    }
  }

} # nottax / istax


#total payments
my $pay_sub = "SELECT SUM(cust_bill_pay_pkg.amount)
                 FROM cust_bill_pay_pkg
                   WHERE cust_bill_pkg.billpkgnum = cust_bill_pay_pkg.billpkgnum
              ";
push @select, "($pay_sub) AS pay_amount";

#total credits
my $credit_sub = "
  SELECT SUM(cust_credit_bill_pkg.amount)
    FROM cust_credit_bill_pkg
      WHERE cust_bill_pkg.billpkgnum = cust_credit_bill_pkg.billpkgnum
";
push @select, "($credit_sub) AS credit_amount";

my $where = ' WHERE '. join(' AND ', @where);

if ($use_usage) {
  $count_query .=
    " FROM (SELECT cust_bill_pkg.setup, cust_bill_pkg.recur, 
             ( SELECT COALESCE( SUM(amount), 0 ) FROM cust_bill_pkg_detail
               WHERE cust_bill_pkg.billpkgnum = cust_bill_pkg_detail.billpkgnum
             ) AS usage FROM cust_bill_pkg  $join_cust $join_pkg $where
           ) AS countquery";
} else {
  $count_query .= " FROM cust_bill_pkg $join_cust $join_pkg $where";
}

push @select, 'part_pkg.pkgpart',
              'part_pkg.pkg',
              'part_pkg.freq';

push @select, 'cust_main.custnum',
              FS::UI::Web::cust_sql_fields();

my $query = {
  'table'     => 'cust_bill_pkg',
  'addl_from' => "$join_cust $join_pkg",
  'hashref'   => {},
  'select'    => join(",\n", @select ),
  'extra_sql' => $where,
  'order_by'  => 'ORDER BY cust_bill._date, billpkgnum',
};

my $ilink = [ "${p}view/cust_bill.cgi?", 'invnum' ];
my $clink = [ "${p}view/cust_main.cgi?", 'custnum' ];
my $pay_link    = ''; #[, 'billpkgnum', ];
my $credit_link = [ "${p}search/cust_credit_bill_pkg.html?billpkgnum=", 'billpkgnum', ];

my $conf = new FS::Conf;
my $money_char = $conf->config('money_char') || '$';

my $owed_sub = sub {
  $money_char . shift->get('owed') # owed_recur is not correct here
};
my $payment_date_sub = sub {
  #my $cust_bill_pkg = shift;
  my @cust_pay = sort { $a->_date <=> $b->_date }
                      map $_->cust_bill_pay->cust_pay,
                          shift->cust_bill_pay_pkg('recur') #recur :/
    or return '';
  time2str('%b %d %Y', $cust_pay[-1]->_date );
};

warn "\n\nQUERY:\n".Dumper($query)."\n\nCOUNT_QUERY:\n$count_query\n\n"
  if $cgi->param('debug');

</%init>